configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 AC_ARG_ENABLE(autotools,
  56    [AS_HELP_STRING([--enable-autotools],
  57                    [Enable the use of this autotools based build configuration])],
  58    [enable_autotools=$enableval], [enable_autotools=no])
  59
  60 if test "x$enable_autotools" != "xyes" ; then
  61     AC_MSG_ERROR([the autotools build system has been deprecated in favour of
  62     meson and will be removed eventually. For instructions on how to use meson
  63     see https://www.mesa3d.org/meson.html.
  64     If you still want to use the autotools build, then add --enable-autotools
  65     to the configure command line.])
  66 fi
  67
  68 # Support silent build rules, requires at least automake-1.11. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  72     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  73
  74 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  75
  76 dnl Set internal versions
  77 OSMESA_VERSION=8
  78 AC_SUBST([OSMESA_VERSION])
  79 OPENCL_VERSION=1
  80 AC_SUBST([OPENCL_VERSION])
  81
  82 # The idea is that libdrm is distributed as one cohesive package, even
  83 # though it is composed of multiple libraries. However some drivers
  84 # may have different version requirements than others. This list
  85 # codifies which drivers need which version of libdrm. Any libdrm
  86 # version dependencies in non-driver-specific code should be reflected
  87 # in the first entry.
  88 LIBDRM_REQUIRED=2.4.75
  89 LIBDRM_RADEON_REQUIRED=2.4.71
  90 LIBDRM_AMDGPU_REQUIRED=2.4.95
  91 LIBDRM_INTEL_REQUIRED=2.4.75
  92 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  93 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  94 LIBDRM_ETNAVIV_REQUIRED=2.4.89
  95 LIBDRM_VC4_REQUIRED=2.4.89
  96
  97 dnl Versions for external dependencies
  98 DRI2PROTO_REQUIRED=2.8
  99 GLPROTO_REQUIRED=1.4.14
 100 LIBOMXIL_BELLAGIO_REQUIRED=0.0
 101 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
 102 LIBVA_REQUIRED=0.39.0
 103 VDPAU_REQUIRED=1.1
 104 WAYLAND_REQUIRED=1.11
 105 WAYLAND_EGL_BACKEND_REQUIRED=3
 106 WAYLAND_PROTOCOLS_REQUIRED=1.8
 107 XCB_REQUIRED=1.9.3
 108 XCBDRI2_REQUIRED=1.8
 109 XCBDRI3_MODIFIERS_REQUIRED=1.13
 110 XCBGLX_REQUIRED=1.8.1
 111 XCBPRESENT_MODIFIERS_REQUIRED=1.13
 112 XDAMAGE_REQUIRED=1.1
 113 XSHMFENCE_REQUIRED=1.1
 114 XVMC_REQUIRED=1.0.6
 115 PYTHON_MAKO_REQUIRED=0.8.0
 116 LIBSENSORS_REQUIRED=4.0.0
 117 ZLIB_REQUIRED=1.2.3
 118
 119 dnl LLVM versions
 120 LLVM_REQUIRED_GALLIUM=3.3.0
 121 LLVM_REQUIRED_OPENCL=3.9.0
 122 LLVM_REQUIRED_R600=3.9.0
 123 LLVM_REQUIRED_RADEONSI=7.0.0
 124 LLVM_REQUIRED_RADV=7.0.0
 125 LLVM_REQUIRED_SWR=6.0.0
 126
 127 dnl Check for progs
 128 AC_PROG_CPP
 129 AC_PROG_CC
 130 AC_PROG_CXX
 131 dnl add this here, so the help for this environmnet variable is close to
 132 dnl other CC/CXX flags related help
 133 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 134                               enabled by default and different  from -std=c++11)])
 135 AM_PROG_CC_C_O
 136 AC_PROG_GREP
 137 AC_PROG_NM
 138 AM_PROG_AS
 139 AX_CHECK_GNU_MAKE
 140 AM_PATH_PYTHON([2.7],, [AM_PATH_PYTHON([3.4],, [:])])
 141
 142 AC_PROG_SED
 143 AC_PROG_MKDIR_P
 144
 145 AC_SYS_LARGEFILE
 146
 147
 148 LT_PREREQ([2.2])
 149 LT_INIT([disable-static])
 150
 151 AC_CHECK_PROG(RM, rm, [rm -f])
 152
 153 AX_PROG_BISON([],
 154               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 155                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 156 AX_PROG_FLEX([],
 157              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 158                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 159
 160 AC_CHECK_PROG(INDENT, indent, indent, cat)
 161 if test "x$INDENT" != "xcat"; then
 162     # Only GNU indent is supported
 163     INDENT_VERSION=`indent --version | grep GNU`
 164     if test $? -eq 0; then
 165        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 166     else
 167        INDENT="cat"
 168     fi
 169 fi
 170
 171 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 172
 173 if test "$PYTHON" = ":"; then
 174     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 175         AC_MSG_ERROR([Python not found - unable to generate sources])
 176     fi
 177 else
 178     if test "x$acv_mako_found" = xno; then
 179         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 180             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 181         fi
 182     fi
 183 fi
 184
 185 AC_PROG_INSTALL
 186
 187 dnl We need a POSIX shell for parts of the build. Assume we have one
 188 dnl in most cases.
 189 case "$host_os" in
 190 solaris*)
 191     # Solaris /bin/sh is too old/non-POSIX compliant
 192     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 193     SHELL="$POSIX_SHELL"
 194     ;;
 195 esac
 196
 197 dnl clang is mostly GCC-compatible, but its version is much lower,
 198 dnl so we have to check for it.
 199 AC_MSG_CHECKING([if compiling with clang])
 200
 201 AC_COMPILE_IFELSE(
 202 [AC_LANG_PROGRAM([], [[
 203 #ifndef __clang__
 204        not clang
 205 #endif
 206 ]])],
 207 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 208
 209 AC_MSG_RESULT([$acv_mesa_CLANG])
 210
 211 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 212 dnl versions are explictly not supported.
 213 GEN_ASM_OFFSETS=no
 214 USE_GNU99=no
 215 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 216     AC_MSG_CHECKING([whether gcc version is sufficient])
 217     major=0
 218     minor=0
 219
 220     GCC_VERSION=`$CC -dumpversion`
 221     if test $? -eq 0; then
 222         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 223         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 224     fi
 225
 226     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 227         AC_MSG_RESULT([no])
 228         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 229     else
 230         AC_MSG_RESULT([yes])
 231     fi
 232
 233     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 234         USE_GNU99=yes
 235     fi
 236     if test "x$cross_compiling" = xyes; then
 237         GEN_ASM_OFFSETS=yes
 238     fi
 239 fi
 240
 241 dnl We don't support building Mesa with Sun C compiler
 242 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 243 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 244 if test "x$SUNCC" = xyes; then
 245     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 246 fi
 247
 248 dnl Check for compiler builtins
 249 AX_GCC_BUILTIN([__builtin_bswap32])
 250 AX_GCC_BUILTIN([__builtin_bswap64])
 251 AX_GCC_BUILTIN([__builtin_clz])
 252 AX_GCC_BUILTIN([__builtin_clzll])
 253 AX_GCC_BUILTIN([__builtin_ctz])
 254 AX_GCC_BUILTIN([__builtin_expect])
 255 AX_GCC_BUILTIN([__builtin_ffs])
 256 AX_GCC_BUILTIN([__builtin_ffsll])
 257 AX_GCC_BUILTIN([__builtin_popcount])
 258 AX_GCC_BUILTIN([__builtin_popcountll])
 259 AX_GCC_BUILTIN([__builtin_unreachable])
 260
 261 AX_GCC_FUNC_ATTRIBUTE([const])
 262 AX_GCC_FUNC_ATTRIBUTE([flatten])
 263 AX_GCC_FUNC_ATTRIBUTE([format])
 264 AX_GCC_FUNC_ATTRIBUTE([malloc])
 265 AX_GCC_FUNC_ATTRIBUTE([packed])
 266 AX_GCC_FUNC_ATTRIBUTE([pure])
 267 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 268 AX_GCC_FUNC_ATTRIBUTE([unused])
 269 AX_GCC_FUNC_ATTRIBUTE([visibility])
 270 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 271 AX_GCC_FUNC_ATTRIBUTE([weak])
 272 AX_GCC_FUNC_ATTRIBUTE([alias])
 273 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 274
 275 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 276
 277 dnl Make sure the pkg-config macros are defined
 278 m4_ifndef([PKG_PROG_PKG_CONFIG],
 279     [m4_fatal([Could not locate the pkg-config autoconf macros.
 280   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 281   are in a different location, try setting the environment variable
 282   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 283 PKG_PROG_PKG_CONFIG()
 284
 285 dnl LIB_DIR - library basename
 286 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 287 AC_SUBST([LIB_DIR])
 288
 289 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 290 _SAVE_LDFLAGS="$LDFLAGS"
 291 _SAVE_CPPFLAGS="$CPPFLAGS"
 292
 293 dnl Compiler macros
 294 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 295 AC_SUBST([DEFINES])
 296 android=no
 297 case "$host_os" in
 298 *-android*)
 299     android=yes
 300     ;;
 301 linux*|*-gnu*|gnu*|cygwin*)
 302     DEFINES="$DEFINES -D_GNU_SOURCE"
 303     ;;
 304 solaris*)
 305     DEFINES="$DEFINES -DSVR4"
 306     ;;
 307 esac
 308
 309 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 310
 311 # Toggle Werror since at some point clang started treating unknown -W
 312 # flags as warnings, succeeding with the build, yet issuing an annoying
 313 # warning.
 314 save_CFLAGS="$CFLAGS"
 315 export CFLAGS="$CFLAGS -Werror"
 316
 317 dnl
 318 dnl Check compiler flags
 319 dnl
 320 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 321 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 322 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 323 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 324 dnl Dylan Baker: gcc and clang always accepr -Wno-*, hence check for the original warning, then set the no-* flag
 325 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CFLAGS="$CFLAGS -Wno-missing-field-initializers"])
 326 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CFLAGS="$CFLAGS -Wno-format-truncation"])
 327 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 328
 329 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 330 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 331
 332 CFLAGS="$save_CFLAGS"
 333
 334 # Toggle Werror since at some point clang started treating unknown -W
 335 # flags as warnings, succeeding with the build, yet issuing an annoying
 336 # warning.
 337 dnl
 338 dnl Check C++ compiler flags
 339 dnl
 340 AC_LANG_PUSH([C++])
 341 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 342 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 343 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 344 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 345 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"])
 346 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CXXFLAGS="$CXXFLAGS -Wno-format-truncation"])
 347 AC_LANG_POP([C++])
 348
 349 # Flags to help ensure that certain portions of the code -- and only those
 350 # portions -- can be built with MSVC:
 351 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 352 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 353 #   supports most of C99)
 354 # - the rest has no compiler compiler restrictions
 355 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 356 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 357 AC_LANG_PUSH([C++])
 358 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 359 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 360 AC_LANG_POP([C++])
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 if test "x$GCC" = xyes; then
 366     if test "x$USE_GNU99" = xyes; then
 367         CFLAGS="$CFLAGS -std=gnu99"
 368     else
 369         CFLAGS="$CFLAGS -std=c99"
 370     fi
 371 fi
 372
 373 dnl
 374 dnl Check whether C++11 is supported, if the environment variable
 375 dnl CXX11_CXXFLAGS is set it takes precedence.
 376 dnl
 377
 378 AC_LANG_PUSH([C++])
 379
 380 check_cxx11_available() {
 381     output_support=$1
 382     AC_COMPILE_IFELSE(
 383         [AC_LANG_PROGRAM([
 384              #if !(__cplusplus >= 201103L)
 385              #error
 386              #endif
 387              #include <tuple>
 388         ])
 389     ], [
 390          AC_MSG_RESULT(yes)
 391          cxx11_support=yes
 392     ], AC_MSG_RESULT(no))
 393     eval "$output_support=\$cxx11_support"
 394 }
 395
 396 HAVE_CXX11=no
 397 save_CXXFLAGS="$CXXFLAGS"
 398
 399 dnl If the user provides a flag to enable c++11, then we test only this
 400 if test "x$CXX11_CXXFLAGS" != "x"; then
 401    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 402    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 403    check_cxx11_available HAVE_CXX11
 404 else
 405    dnl test whether c++11 is enabled by default
 406    AC_MSG_CHECKING(whether c++11 is enabled by default)
 407    check_cxx11_available HAVE_CXX11
 408
 409    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 410    if test "x$HAVE_CXX11" != "xyes"; then
 411        CXX11_CXXFLAGS=-std=c++11
 412        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 413        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 414        check_cxx11_available HAVE_CXX11
 415    fi
 416 fi
 417
 418 CXXFLAGS="$save_CXXFLAGS"
 419 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 420 AC_SUBST(CXX11_CXXFLAGS)
 421 AC_LANG_POP([C++])
 422
 423 dnl even if the compiler appears to support it, using visibility attributes isn't
 424 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 425 case "$host_os" in
 426 cygwin*)
 427     VISIBILITY_CFLAGS=""
 428     VISIBILITY_CXXFLAGS=""
 429     ;;
 430 esac
 431
 432 AC_SUBST([VISIBILITY_CFLAGS])
 433 AC_SUBST([VISIBILITY_CXXFLAGS])
 434
 435 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 436 dnl option is not supported. Hence, check for -Wfoo instead.
 437 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 438 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 439 AC_SUBST([WNO_OVERRIDE_INIT])
 440
 441 dnl
 442 dnl Optional flags, check for compiler support
 443 dnl
 444 SSE41_CFLAGS="-msse4.1"
 445 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 446 dnl stack, but on x86-32 such alignment is not guaranteed.
 447 case "$target_cpu" in
 448 i?86)
 449     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 450     ;;
 451 esac
 452 save_CFLAGS="$CFLAGS"
 453 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 454 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 455 #include <smmintrin.h>
 456 int param;
 457 int main () {
 458     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 459     c = _mm_max_epu32(a, b);
 460     return _mm_cvtsi128_si32(c);
 461 }]])], SSE41_SUPPORTED=1)
 462 CFLAGS="$save_CFLAGS"
 463 if test "x$SSE41_SUPPORTED" = x1; then
 464     DEFINES="$DEFINES -DUSE_SSE41"
 465 fi
 466 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 467 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 468
 469 dnl Check for new-style atomic builtins. We first check without linking to
 470 dnl -latomic.
 471 AC_MSG_CHECKING(whether __atomic_load_n is supported)
 472 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 473 #include <stdint.h>
 474 int main() {
 475     struct {
 476         uint64_t *v;
 477     } x;
 478     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 479            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 480 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 481
 482 dnl If that didn't work, we try linking with -latomic, which is needed on some
 483 dnl platforms.
 484 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
 485    save_LDFLAGS=$LDFLAGS
 486    LDFLAGS="$LDFLAGS -latomic"
 487    AC_LINK_IFELSE([AC_LANG_SOURCE([[
 488    #include <stdint.h>
 489    int main() {
 490         struct {
 491             uint64_t *v;
 492         } x;
 493         return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 494                (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 495    }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
 496           GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 497    LDFLAGS=$save_LDFLAGS
 498 fi
 499 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
 500
 501 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
 502     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 503 fi
 504 AC_SUBST([LIBATOMIC_LIBS])
 505
 506 dnl Check if host supports 64-bit atomics
 507 dnl note that lack of support usually results in link (not compile) error
 508 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 509 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 510 #include <stdint.h>
 511 uint64_t v;
 512 int main() {
 513     return __sync_add_and_fetch(&v, (uint64_t)1);
 514 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 515 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 516     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 517 fi
 518 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 519
 520 dnl Check for Endianness
 521 AC_C_BIGENDIAN(
 522    little_endian=no,
 523    little_endian=yes,
 524    little_endian=no,
 525    little_endian=no
 526 )
 527
 528 dnl Check for POWER8 Architecture
 529 PWR8_CFLAGS="-mpower8-vector"
 530 have_pwr8_intrinsics=no
 531 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 532 save_CFLAGS=$CFLAGS
 533 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 534 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 535 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 536 #error "Need GCC >= 4.8 for sane POWER8 support"
 537 #endif
 538 #include <altivec.h>
 539 int main () {
 540     vector unsigned char r;
 541     vector unsigned int v = vec_splat_u32 (1);
 542     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 543     return 0;
 544 }]])], have_pwr8_intrinsics=yes)
 545 CFLAGS=$save_CFLAGS
 546
 547 AC_ARG_ENABLE(pwr8,
 548    [AS_HELP_STRING([--disable-pwr8],
 549                    [disable POWER8-specific instructions])],
 550    [enable_pwr8=$enableval], [enable_pwr8=auto])
 551
 552 if test "x$enable_pwr8" = xno ; then
 553    have_pwr8_intrinsics=disabled
 554 fi
 555
 556 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 557    DEFINES="$DEFINES -D_ARCH_PWR8"
 558    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 559    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 560 else
 561    PWR8_CFLAGS=
 562 fi
 563
 564 AC_MSG_RESULT($have_pwr8_intrinsics)
 565 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 566    AC_MSG_ERROR([POWER8 compiler support not detected])
 567 fi
 568
 569 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 570    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 571 fi
 572
 573 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 574
 575 dnl Can't have static and shared libraries, default to static if user
 576 dnl explicitly requested. If both disabled, set to static since shared
 577 dnl was explicitly requested.
 578 case "x$enable_static$enable_shared" in
 579 xyesyes)
 580     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 581     ;;
 582 xnono)
 583     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 584     ;;
 585 esac
 586
 587 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 588
 589 dnl
 590 dnl other compiler options
 591 dnl
 592 AC_ARG_ENABLE([debug],
 593     [AS_HELP_STRING([--enable-debug],
 594         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 595     [enable_debug="$enableval"],
 596     [enable_debug=no]
 597 )
 598
 599 AC_ARG_ENABLE([profile],
 600     [AS_HELP_STRING([--enable-profile],
 601         [enable profiling of code @<:@default=disabled@:>@])],
 602     [enable_profile="$enableval"],
 603     [enable_profile=no]
 604 )
 605
 606 AC_ARG_ENABLE([sanitize],
 607     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 608         [enable code sanitizer @<:@default=disabled@:>@])],
 609     [enable_sanitize="$enableval"],
 610     [enable_sanitize=no])
 611
 612 if test "x$enable_profile" = xyes; then
 613     DEFINES="$DEFINES -DPROFILE"
 614     if test "x$GCC" = xyes; then
 615         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 616     fi
 617     if test "x$GXX" = xyes; then
 618         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 619     fi
 620 fi
 621
 622 if test "x$enable_debug" = xyes; then
 623     DEFINES="$DEFINES -DDEBUG"
 624     if test "x$enable_profile" = xyes; then
 625         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 626     fi
 627     if test "x$GCC" = xyes; then
 628         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 629             CFLAGS="$CFLAGS -g"
 630         fi
 631         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 632             CFLAGS="$CFLAGS -O0"
 633         fi
 634     fi
 635     if test "x$GXX" = xyes; then
 636         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 637             CXXFLAGS="$CXXFLAGS -g"
 638         fi
 639         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 640             CXXFLAGS="$CXXFLAGS -O0"
 641         fi
 642     fi
 643 else
 644    DEFINES="$DEFINES -DNDEBUG"
 645 fi
 646
 647 if test "x$enable_sanitize" != xno; then
 648     if test "x$enable_profile" = xyes; then
 649         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 650     fi
 651
 652     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 653     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 654     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 655
 656     AC_LINK_IFELSE(
 657         [AC_LANG_SOURCE([int main(){return 0;}])],
 658         [],
 659         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 660 fi
 661
 662 dnl
 663 dnl Check if linker supports -Bsymbolic
 664 dnl
 665 save_LDFLAGS=$LDFLAGS
 666 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 667 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 668 AC_LINK_IFELSE(
 669     [AC_LANG_SOURCE([int main() { return 0;}])],
 670     [AC_MSG_RESULT([yes])
 671         BSYMBOLIC="-Wl,-Bsymbolic";],
 672     [AC_MSG_RESULT([no])
 673         BSYMBOLIC="";])
 674 LDFLAGS=$save_LDFLAGS
 675
 676 AC_SUBST([BSYMBOLIC])
 677
 678 dnl
 679 dnl Check if linker supports garbage collection
 680 dnl
 681 save_LDFLAGS=$LDFLAGS
 682 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 683 AC_MSG_CHECKING([whether ld supports --gc-sections])
 684 AC_LINK_IFELSE(
 685     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 686     [AC_MSG_RESULT([yes])
 687         GC_SECTIONS="-Wl,--gc-sections";],
 688     [AC_MSG_RESULT([no])
 689         GC_SECTIONS="";])
 690 LDFLAGS=$save_LDFLAGS
 691
 692 AC_SUBST([GC_SECTIONS])
 693
 694 dnl
 695 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 696 dnl so when these flags are passed to ld via libtool the checks will fail
 697 dnl
 698 case "$host_os" in
 699 openbsd* | darwin* )
 700     LD_NO_UNDEFINED="" ;;
 701 *)
 702     if test "x$enable_sanitize" = xno; then
 703         LD_NO_UNDEFINED="-Wl,--no-undefined"
 704     else
 705         LD_NO_UNDEFINED=""
 706     fi
 707     ;;
 708 esac
 709
 710 AC_SUBST([LD_NO_UNDEFINED])
 711
 712 dnl
 713 dnl Check if linker supports version scripts
 714 dnl
 715 AC_MSG_CHECKING([if the linker supports version-scripts])
 716 save_LDFLAGS=$LDFLAGS
 717 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 718 AC_LINK_IFELSE(
 719     [AC_LANG_SOURCE([int main() { return 0;}])],
 720     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 721     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 722 LDFLAGS=$save_LDFLAGS
 723 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 724
 725 dnl
 726 dnl Check if linker supports dynamic list files
 727 dnl
 728 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 729 save_LDFLAGS=$LDFLAGS
 730 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 731 AC_LINK_IFELSE(
 732     [AC_LANG_SOURCE([int main() { return 0;}])],
 733     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 734     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 735 LDFLAGS=$save_LDFLAGS
 736 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 737
 738 dnl
 739 dnl OSX linker does not support build-id
 740 dnl
 741 case "$host_os" in
 742 darwin*)
 743     LD_BUILD_ID=""
 744     ;;
 745 *)
 746     LD_BUILD_ID="-Wl,--build-id=sha1"
 747     ;;
 748 esac
 749 AC_SUBST([LD_BUILD_ID])
 750
 751 dnl
 752 dnl compatibility symlinks
 753 dnl
 754 case "$host_os" in
 755 linux* )
 756     HAVE_COMPAT_SYMLINKS=yes ;;
 757 * )
 758     HAVE_COMPAT_SYMLINKS=no ;;
 759 esac
 760
 761 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 762
 763 dnl
 764 dnl library names
 765 dnl
 766 dnl Unfortunately we need to do a few things that libtool can't help us with,
 767 dnl so we need some knowledge of shared library filenames:
 768 dnl
 769 dnl LIB_EXT is the extension used when creating symlinks for alternate
 770 dnl filenames for a shared library which will be dynamically loaded
 771 dnl
 772 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 773 dnl the file for a shared library we wish to link with
 774 dnl
 775 case "$host_os" in
 776 darwin* )
 777     LIB_EXT='dylib'
 778     IMP_LIB_EXT=$LIB_EXT
 779     ;;
 780 cygwin* )
 781     LIB_EXT='dll'
 782     IMP_LIB_EXT='dll.a'
 783     ;;
 784 aix* )
 785     LIB_EXT='a'
 786     IMP_LIB_EXT=$LIB_EXT
 787     ;;
 788 * )
 789     LIB_EXT='so'
 790     IMP_LIB_EXT=$LIB_EXT
 791     ;;
 792 esac
 793
 794 AC_SUBST([LIB_EXT])
 795
 796 dnl
 797 dnl Arch/platform-specific settings
 798 dnl
 799 AC_ARG_ENABLE([asm],
 800     [AS_HELP_STRING([--disable-asm],
 801         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 802     [enable_asm="$enableval"],
 803     [enable_asm=yes]
 804 )
 805 asm_arch=""
 806 AC_MSG_CHECKING([whether to enable assembly])
 807 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 808 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 809 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 810     case "$host_cpu" in
 811     i?86 | x86_64 | amd64)
 812         if test "x$host_cpu" != "x$target_cpu"; then
 813             enable_asm=no
 814             AC_MSG_RESULT([no, cross compiling])
 815         fi
 816         ;;
 817     esac
 818 fi
 819 # check for supported arches
 820 if test "x$enable_asm" = xyes; then
 821     case "$host_cpu" in
 822     i?86)
 823         case "$host_os" in
 824         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 825             asm_arch=x86
 826             ;;
 827         esac
 828         ;;
 829     x86_64|amd64)
 830         case "$host_os" in
 831         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 832             asm_arch=x86_64
 833             ;;
 834         esac
 835         ;;
 836     sparc*)
 837         case "$host_os" in
 838         linux*)
 839             asm_arch=sparc
 840             ;;
 841         esac
 842         ;;
 843     powerpc64le)
 844         case "$host_os" in
 845         linux*)
 846             asm_arch=ppc64le
 847             ;;
 848         esac
 849         ;;
 850     aarch64)
 851         case "$host_os" in
 852         linux*)
 853             asm_arch=aarch64
 854             ;;
 855         esac
 856         ;;
 857     arm)
 858         case "$host_os" in
 859         linux*)
 860             asm_arch=arm
 861             ;;
 862         esac
 863         ;;
 864     esac
 865
 866     case "$asm_arch" in
 867     x86)
 868         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 869         AC_MSG_RESULT([yes, x86])
 870         ;;
 871     x86_64|amd64)
 872         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 873         AC_MSG_RESULT([yes, x86_64])
 874         ;;
 875     sparc)
 876         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 877         AC_MSG_RESULT([yes, sparc])
 878         ;;
 879     ppc64le)
 880         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 881         AC_MSG_RESULT([yes, ppc64le])
 882         ;;
 883     aarch64)
 884         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 885         AC_MSG_RESULT([yes, aarch64])
 886         ;;
 887     arm)
 888         DEFINES="$DEFINES -DUSE_ARM_ASM"
 889         AC_MSG_RESULT([yes, arm])
 890         ;;
 891     *)
 892         AC_MSG_RESULT([no, platform not supported])
 893         ;;
 894     esac
 895 fi
 896
 897 AC_HEADER_MAJOR
 898 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 899 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 900 AC_CHECK_HEADERS([endian.h])
 901 AC_CHECK_HEADER([dlfcn.h], [DEFINES="$DEFINES -DHAVE_DLFCN_H"])
 902 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 903 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 904 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 905 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 906
 907 AC_MSG_CHECKING([whether strtod has locale support])
 908 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 909     #define _GNU_SOURCE
 910     #include <stdlib.h>
 911     #include <locale.h>
 912     #ifdef HAVE_XLOCALE_H
 913     #include <xlocale.h>
 914     #endif
 915     int main() {
 916        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 917        const char *s = "1.0";
 918        char *end;
 919        double d = strtod_l(s, end, loc);
 920        float f = strtof_l(s, end, loc);
 921        freelocale(loc);
 922        return 0;
 923     }]])],
 924   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 925    AC_MSG_RESULT([yes]),
 926    AC_MSG_RESULT([no]))
 927
 928 dnl Check to see if dlopen is in default libraries (like Solaris, which
 929 dnl has it in libc), or if libdl is needed to get it.
 930 AC_CHECK_FUNC([dlopen], [],
 931     [AC_CHECK_LIB([dl], [dlopen],
 932        [DLOPEN_LIBS="-ldl"])])
 933 AC_SUBST([DLOPEN_LIBS])
 934
 935 dnl Check if that library also has dladdr
 936 save_LIBS="$LIBS"
 937 LIBS="$LIBS $DLOPEN_LIBS"
 938 AC_CHECK_FUNCS([dladdr])
 939 LIBS="$save_LIBS"
 940
 941 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 942
 943 case "$host_os" in
 944 darwin*)
 945     ;;
 946 *)
 947     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 948                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 949                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 950     AC_SUBST([CLOCK_LIB])
 951     ;;
 952 esac
 953
 954 dnl See if posix_memalign is available
 955 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 956
 957 dnl Check for zlib
 958 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 959 DEFINES="$DEFINES -DHAVE_ZLIB"
 960
 961 dnl Check for pthreads
 962 AX_PTHREAD
 963 if test "x$ax_pthread_ok" = xno; then
 964     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 965 fi
 966 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 967 dnl to -pthread, which causes problems if we need -lpthread to appear in
 968 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 969 dnl is not valid for that platform.
 970 if test "x$android" = xno; then
 971     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 972 fi
 973 dnl According to the manual when using pthreads, one should add -pthread to
 974 dnl both compile and link-time arguments.
 975 dnl In practise that should be sufficient for all platforms, since any
 976 dnl platforms build with GCC and Clang support the flag.
 977 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 978
 979 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 980 dnl project. Even then there's a notable issue as described in the project README
 981 case "$host_os" in
 982 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 983     pthread_stubs_possible="no"
 984     ;;
 985 * )
 986     pthread_stubs_possible="yes"
 987     ;;
 988 esac
 989
 990 if test "x$pthread_stubs_possible" = xyes; then
 991     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 992 fi
 993
 994 save_LIBS="$LIBS"
 995 LIBS="$PTHREAD_LIBS"
 996 AC_MSG_CHECKING(whether pthread_setaffinity_np is supported)
 997 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 998     #define _GNU_SOURCE
 999     #include <pthread.h>
1000     int main() {
1001        void *a = (void*) &pthread_setaffinity_np;
1002        long b = (long) a;
1003        return (int) b;
1004     }]])],
1005   [DEFINES="$DEFINES -DHAVE_PTHREAD_SETAFFINITY"];
1006    AC_MSG_RESULT([yes]),
1007    AC_MSG_RESULT([no]))
1008 LIBS="$save_LIBS"
1009
1010 dnl Check for futex for fast inline simple_mtx_t.
1011 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
1012
1013 dnl SELinux awareness.
1014 AC_ARG_ENABLE([selinux],
1015     [AS_HELP_STRING([--enable-selinux],
1016         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
1017     [MESA_SELINUX="$enableval"],
1018     [MESA_SELINUX=no])
1019 if test "x$enable_selinux" = "xyes"; then
1020     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
1021         [AC_CHECK_HEADER([selinux/selinux.h],[],
1022                          [AC_MSG_ERROR([SELinux headers not found])])
1023          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
1024                       [AC_MSG_ERROR([SELinux library not found])])
1025          SELINUX_LIBS="-lselinux"])
1026     DEFINES="$DEFINES -DMESA_SELINUX"
1027 fi
1028 AC_SUBST([SELINUX_CFLAGS])
1029 AC_SUBST([SELINUX_LIBS])
1030
1031 dnl
1032 dnl LLVM
1033 dnl
1034 AC_ARG_ENABLE([llvm-shared-libs],
1035     [AS_HELP_STRING([--enable-llvm-shared-libs],
1036         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1037     [enable_llvm_shared_libs="$enableval"],
1038     [enable_llvm_shared_libs=yes])
1039
1040 AC_ARG_WITH([llvm-prefix],
1041     [AS_HELP_STRING([--with-llvm-prefix],
1042         [Prefix for LLVM installations in non-standard locations])],
1043     [llvm_prefix="$withval"],
1044     [llvm_prefix=''])
1045
1046 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1047 if test "x$have_libelf" = xno; then
1048    LIBELF_LIBS=''
1049    LIBELF_CFLAGS=''
1050    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1051    AC_SUBST([LIBELF_LIBS])
1052    AC_SUBST([LIBELF_CFLAGS])
1053 fi
1054
1055 if test -z "$LLVM_CONFIG"; then
1056     if test -n "$llvm_prefix"; then
1057         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1058     else
1059         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1060     fi
1061 fi
1062
1063 llvm_add_component() {
1064     new_llvm_component=$1
1065     driver_name=$2
1066
1067     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1068         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1069     else
1070         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1071     fi
1072 }
1073
1074 llvm_add_optional_component() {
1075     new_llvm_component=$1
1076     driver_name=$2
1077
1078     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1079         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1080     fi
1081 }
1082
1083 llvm_add_default_components() {
1084     driver_name=$1
1085
1086     # Required default components
1087     llvm_add_component "bitwriter" $driver_name
1088     llvm_add_component "engine" $driver_name
1089     llvm_add_component "mcdisassembler" $driver_name
1090     llvm_add_component "mcjit" $driver_name
1091
1092     # Optional default components
1093     llvm_add_optional_component "inteljitevents" $driver_name
1094 }
1095
1096 llvm_add_target() {
1097     new_llvm_target=$1
1098     driver_name=$2
1099
1100     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1101         llvm_add_component $new_llvm_target $driver_name
1102     else
1103         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1104     fi
1105 }
1106
1107 # Call this inside ` ` to get the return value.
1108 # $1 is the llvm-config command with arguments.
1109 strip_unwanted_llvm_flags() {
1110     echo " `$1` " | sed -E \
1111         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1112         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1113         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1114         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1115         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1116         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1117         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1118         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1119         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1120         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1121         -e 's/^[[[:space:]]]//' \
1122         -e 's/[[[:space:]]]$//'
1123 }
1124
1125 llvm_set_environment_variables() {
1126     if test "x$LLVM_CONFIG" != xno; then
1127         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1128         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1129         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1130         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1131
1132         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1133         save_CFLAGS="$CFLAGS"
1134         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1135
1136         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1137             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1138         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1139             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1140         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1141             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1142
1143         CFLAGS="$save_CFLAGS"
1144
1145         # Only needed for LLVM < 3.6.0
1146         if test -z "$LLVM_VERSION_PATCH"; then
1147             LLVM_VERSION_PATCH=0
1148         fi
1149
1150         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1151
1152         FOUND_LLVM=yes
1153     else
1154         FOUND_LLVM=no
1155         LLVM_VERSION_INT=0
1156     fi
1157 }
1158
1159 require_llvm() {
1160     if test "x$enable_llvm" != "xyes"; then
1161         AC_MSG_ERROR([--enable-llvm is required when building $1])
1162     fi
1163 }
1164
1165 llvm_require_version() {
1166     require_llvm $2
1167
1168     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1169     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1170     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1171
1172     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1173         # major > required major
1174         #  --> OK
1175         return
1176     fi
1177
1178     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1179         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1180             # major = required major and
1181             # minor > required minor
1182             #  --> OK
1183             return
1184         else
1185             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1186                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1187                     # major = required major and
1188                     # minor = required minor and
1189                     # patch >= required patch
1190                     #  --> OK
1191                     return
1192                 fi
1193             fi
1194         fi
1195     fi
1196
1197     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1198 }
1199
1200 radeon_llvm_check() {
1201     if test ${LLVM_VERSION_INT} -lt 307; then
1202         amdgpu_llvm_target_name='r600'
1203     else
1204         amdgpu_llvm_target_name='amdgpu'
1205     fi
1206
1207     llvm_require_version $*
1208
1209     llvm_add_target $amdgpu_llvm_target_name $2
1210
1211     llvm_add_default_components $2
1212     llvm_add_component "bitreader" $2
1213     llvm_add_component "ipo" $2
1214
1215     if test "x$have_libelf" != xyes; then
1216        AC_MSG_ERROR([$2 requires libelf when using llvm])
1217     fi
1218 }
1219
1220 llvm_set_environment_variables
1221
1222 AC_SUBST([LLVM_CFLAGS])
1223 AC_SUBST([LLVM_CXXFLAGS])
1224 AC_SUBST([LLVM_LIBS])
1225 AC_SUBST([LLVM_LDFLAGS])
1226 AC_SUBST([LLVM_INCLUDEDIR])
1227
1228 dnl
1229 dnl libunwind
1230 dnl
1231 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1232 AC_ARG_ENABLE([libunwind],
1233     [AS_HELP_STRING([--enable-libunwind],
1234             [Use libunwind for backtracing (default: auto)])],
1235         [LIBUNWIND="$enableval"],
1236         [LIBUNWIND="$HAVE_LIBUNWIND"])
1237
1238 if test "x$LIBUNWIND" = "xyes"; then
1239     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1240     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1241 fi
1242
1243
1244 dnl Options for APIs
1245 AC_ARG_ENABLE([opengl],
1246     [AS_HELP_STRING([--disable-opengl],
1247         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1248     [enable_opengl="$enableval"],
1249     [enable_opengl=yes])
1250 AC_ARG_ENABLE([gles1],
1251     [AS_HELP_STRING([--disable-gles1],
1252         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1253     [enable_gles1="$enableval"],
1254     [enable_gles1=yes])
1255 AC_ARG_ENABLE([gles2],
1256     [AS_HELP_STRING([--disable-gles2],
1257         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1258     [enable_gles2="$enableval"],
1259     [enable_gles2=yes])
1260
1261 AC_ARG_ENABLE([dri],
1262     [AS_HELP_STRING([--enable-dri],
1263         [enable DRI modules @<:@default=enabled@:>@])],
1264     [enable_dri="$enableval"],
1265     [enable_dri=yes])
1266
1267 AC_ARG_ENABLE([gallium-extra-hud],
1268     [AS_HELP_STRING([--enable-gallium-extra-hud],
1269         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1270     [enable_gallium_extra_hud="$enableval"],
1271     [enable_gallium_extra_hud=no])
1272 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1273 if test "x$enable_gallium_extra_hud" = xyes ; then
1274     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1275 fi
1276
1277 #TODO: no pkgconfig .pc available for libsensors.
1278 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1279 AC_ARG_ENABLE([lmsensors],
1280     [AS_HELP_STRING([--enable-lmsensors],
1281         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1282     [enable_lmsensors="$enableval"],
1283     [enable_lmsensors=no])
1284 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1285 if test "x$enable_lmsensors" = xyes ; then
1286     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1287     LIBSENSORS_LIBS="-lsensors"
1288 else
1289     LIBSENSORS_LIBS=""
1290 fi
1291 AC_SUBST(LIBSENSORS_LIBS)
1292
1293 case "$host_os" in
1294 linux*)
1295     dri3_default=yes
1296     ;;
1297 *)
1298     dri3_default=no
1299     ;;
1300 esac
1301
1302 if test "x$enable_dri" = xno; then
1303     dri3_default=no
1304 fi
1305
1306 AC_ARG_ENABLE([dri3],
1307     [AS_HELP_STRING([--enable-dri3],
1308         [enable DRI3 @<:@default=auto@:>@])],
1309     [enable_dri3="$enableval"],
1310     [enable_dri3="$dri3_default"])
1311 AC_ARG_ENABLE([glx],
1312     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1313         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1314     [enable_glx="$enableval"],
1315     [enable_glx=yes])
1316 AC_ARG_ENABLE([osmesa],
1317     [AS_HELP_STRING([--enable-osmesa],
1318         [enable OSMesa library @<:@default=disabled@:>@])],
1319     [enable_osmesa="$enableval"],
1320     [enable_osmesa=no])
1321 AC_ARG_ENABLE([gallium-osmesa],
1322     [AS_HELP_STRING([--enable-gallium-osmesa],
1323         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1324     [enable_gallium_osmesa="$enableval"],
1325     [enable_gallium_osmesa=no])
1326 AC_ARG_ENABLE([egl],
1327     [AS_HELP_STRING([--disable-egl],
1328         [disable EGL library @<:@default=enabled@:>@])],
1329     [enable_egl="$enableval"],
1330     [enable_egl=yes])
1331
1332 AC_ARG_ENABLE([xa],
1333     [AS_HELP_STRING([--enable-xa],
1334         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1335     [enable_xa="$enableval"],
1336     [enable_xa=no])
1337 AC_ARG_ENABLE([gbm],
1338    [AS_HELP_STRING([--enable-gbm],
1339          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1340    [enable_gbm="$enableval"],
1341    [case "$host_os" in
1342        cygwin* | darwin*)
1343           enable_gbm=no
1344           ;;
1345        *)
1346           enable_gbm=yes
1347           ;;
1348     esac])
1349 AC_ARG_ENABLE([nine],
1350     [AS_HELP_STRING([--enable-nine],
1351         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1352     [enable_nine="$enableval"],
1353     [enable_nine=no])
1354
1355 AC_ARG_ENABLE([xvmc],
1356    [AS_HELP_STRING([--enable-xvmc],
1357          [enable xvmc library @<:@default=auto@:>@])],
1358    [enable_xvmc="$enableval"],
1359    [enable_xvmc=auto])
1360 AC_ARG_ENABLE([vdpau],
1361    [AS_HELP_STRING([--enable-vdpau],
1362          [enable vdpau library @<:@default=auto@:>@])],
1363    [enable_vdpau="$enableval"],
1364    [enable_vdpau=auto])
1365 AC_ARG_ENABLE([omx],
1366    [AS_HELP_STRING([--enable-omx],
1367          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1368    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1369    [])
1370 AC_ARG_ENABLE([omx-bellagio],
1371    [AS_HELP_STRING([--enable-omx-bellagio],
1372          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1373    [enable_omx_bellagio="$enableval"],
1374    [enable_omx_bellagio=no])
1375 AC_ARG_ENABLE([omx-tizonia],
1376    [AS_HELP_STRING([--enable-omx-tizonia],
1377          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1378    [enable_omx_tizonia="$enableval"],
1379    [enable_omx_tizonia=no])
1380 AC_ARG_ENABLE([va],
1381    [AS_HELP_STRING([--enable-va],
1382          [enable va library @<:@default=auto@:>@])],
1383    [enable_va="$enableval"],
1384    [enable_va=auto])
1385 AC_ARG_ENABLE([opencl],
1386    [AS_HELP_STRING([--enable-opencl],
1387          [enable OpenCL library @<:@default=disabled@:>@])],
1388    [enable_opencl="$enableval"],
1389    [enable_opencl=no])
1390 AC_ARG_ENABLE([opencl_icd],
1391    [AS_HELP_STRING([--enable-opencl-icd],
1392           [Build an OpenCL ICD library to be loaded by an ICD implementation
1393            @<:@default=enabled@:>@])],
1394     [enable_opencl_icd="$enableval"],
1395     [enable_opencl_icd=yes])
1396
1397 AC_ARG_ENABLE([gallium-tests],
1398     [AS_HELP_STRING([--enable-gallium-tests],
1399         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1400     [enable_gallium_tests="$enableval"],
1401     [enable_gallium_tests=no])
1402
1403 # Option for Gallium drivers
1404
1405 # Keep this in sync with the --with-gallium-drivers help string default value
1406 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1407
1408 AC_ARG_WITH([gallium-drivers],
1409     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1410         [comma delimited Gallium drivers list, e.g.
1411         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv,imx"
1412         @<:@default=r300,r600,svga,swrast@:>@])],
1413     [with_gallium_drivers="$withval"],
1414     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1415
1416 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1417 # here so that the script doesn't choke on an unknown driver name later.
1418 case "$with_gallium_drivers" in
1419     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1420     no) with_gallium_drivers='' ;;
1421 esac
1422
1423 if test "x$enable_opengl" = xno -a \
1424         "x$enable_gles1" = xno -a \
1425         "x$enable_gles2" = xno -a \
1426         "x$enable_nine" = xno -a \
1427         "x$enable_xa" = xno -a \
1428         "x$enable_xvmc" = xno -a \
1429         "x$enable_vdpau" = xno -a \
1430         "x$enable_omx_bellagio" = xno -a \
1431         "x$enable_omx_tizonia" = xno -a \
1432         "x$enable_va" = xno -a \
1433         "x$enable_opencl" = xno; then
1434     AC_MSG_ERROR([at least one API should be enabled])
1435 fi
1436
1437 if test "x$enable_omx_bellagio" = xyes -a \
1438         "x$enable_omx_tizonia" = xyes; then
1439    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1440 fi
1441
1442 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1443 if test "x$enable_opengl" = xno -a \
1444         "x$enable_gles1" = xyes; then
1445     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1446 fi
1447
1448 if test "x$enable_opengl" = xno -a \
1449         "x$enable_gles2" = xyes; then
1450     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1451 fi
1452
1453 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1454 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1455 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1456 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1457                                         "x$enable_gles1" = xyes -o \
1458                                         "x$enable_gles2" = xyes)
1459 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1460                                       "x$enable_opengl" = xyes -o \
1461                                       "x$enable_gles1" = xyes -o \
1462                                       "x$enable_gles2" = xyes)
1463
1464 # Validate GLX options
1465 if test "x$enable_glx" = xyes; then
1466     if test "x$enable_dri" = xyes; then
1467         enable_glx=dri
1468     elif test -n "$with_gallium_drivers"; then
1469         enable_glx=gallium-xlib
1470     else
1471         enable_glx=xlib
1472     fi
1473 fi
1474 case "x$enable_glx" in
1475 xdri | xxlib | xgallium-xlib)
1476     # GLX requires OpenGL
1477     if test "x$enable_opengl" = xno; then
1478         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1479     fi
1480
1481     # Check individual dependencies
1482     case "x$enable_glx" in
1483     xdri)
1484         if test "x$enable_dri" = xno; then
1485             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1486         fi
1487         ;;
1488     xxlib)
1489         if test "x$enable_dri" = xyes; then
1490             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1491         fi
1492         ;;
1493     xgallium-xlib )
1494         if test "x$enable_dri" = xyes; then
1495             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1496         fi
1497         if test -z "$with_gallium_drivers"; then
1498             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1499         fi
1500         ;;
1501     esac
1502     ;;
1503 xno)
1504     ;;
1505 *)
1506     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1507     ;;
1508 esac
1509
1510 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1511 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1512 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1513 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1514
1515 DEFAULT_GL_LIB_NAME=GL
1516
1517 dnl
1518 dnl Libglvnd configuration
1519 dnl
1520 AC_ARG_ENABLE([libglvnd],
1521     [AS_HELP_STRING([--enable-libglvnd],
1522         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1523     [enable_libglvnd="$enableval"],
1524     [enable_libglvnd=no])
1525 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1526
1527 if test "x$enable_libglvnd" = xyes ; then
1528     case "x$enable_glx" in
1529     xxlib | xgallium-xlib )
1530         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1531         ;;
1532     esac
1533
1534     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1535     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1536     AC_SUBST([LIBGLVND_DATADIR])
1537
1538     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1539     DEFAULT_GL_LIB_NAME=GLX_mesa
1540
1541     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1542         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1543     fi
1544 fi
1545
1546 AC_ARG_WITH([gl-lib-name],
1547   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1548     [specify GL library name @<:@default=GL@:>@])],
1549   [AC_MSG_ERROR([--with-gl-lib-name is no longer supported. Rename the library manually if needed.])],
1550   [])
1551 AC_ARG_WITH([osmesa-lib-name],
1552   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1553     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1554   [AC_MSG_ERROR([--with-osmesa-lib-name is no longer supported. Rename the library manually if needed.])],
1555   [])
1556 GL_LIB="$DEFAULT_GL_LIB_NAME"
1557 OSMESA_LIB=OSMesa
1558
1559 dnl
1560 dnl Mangled Mesa support
1561 dnl
1562 AC_ARG_ENABLE([mangling],
1563   [AS_HELP_STRING([--enable-mangling],
1564     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1565   [enable_mangling="${enableval}"],
1566   [enable_mangling=no]
1567 )
1568 if test "x${enable_mangling}" = "xyes" ; then
1569   if test "x$enable_libglvnd" = xyes; then
1570     AC_MSG_ERROR([Conflicting options --enable-mangling and --enable-libglvnd.])
1571   fi
1572   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1573   GL_LIB="Mangled${GL_LIB}"
1574   OSMESA_LIB="Mangled${OSMESA_LIB}"
1575 fi
1576 AC_SUBST([GL_LIB])
1577 AC_SUBST([OSMESA_LIB])
1578
1579 dnl HACK when building glx + glvnd we ship gl.pc, despite that glvnd should do it
1580 dnl Thus we need to use GL as a DSO name.
1581 if test "x$enable_libglvnd" = xyes -a "x$enable_glx" != xno; then
1582   GL_PKGCONF_LIB="GL"
1583 else
1584   GL_PKGCONF_LIB="$GL_LIB"
1585 fi
1586 AC_SUBST([GL_PKGCONF_LIB])
1587
1588 # Check for libdrm
1589 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1590                   [have_libdrm=yes], [have_libdrm=no])
1591 if test "x$have_libdrm" = xyes; then
1592     DEFINES="$DEFINES -DHAVE_LIBDRM"
1593 fi
1594
1595 require_libdrm() {
1596     if test "x$have_libdrm" != xyes; then
1597        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1598     fi
1599 }
1600
1601
1602 # Select which platform-dependent DRI code gets built
1603 case "$host_os" in
1604 darwin*)
1605     dri_platform='apple' ;;
1606 cygwin*)
1607     dri_platform='windows' ;;
1608 gnu*)
1609     dri_platform='none' ;;
1610 *)
1611     dri_platform='drm' ;;
1612 esac
1613
1614 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1615     have_drisw_kms='yes'
1616 fi
1617
1618 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1619 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1620 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1621 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1622 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1623 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1624 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1625 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1626 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1627 AM_CONDITIONAL(HAVE_XLEASE, test "x$have_xlease" = xyes )
1628
1629 AC_ARG_ENABLE([shared-glapi],
1630     [AS_HELP_STRING([--enable-shared-glapi],
1631         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1632     [enable_shared_glapi="$enableval"],
1633     [enable_shared_glapi=yes])
1634
1635 case "x$enable_opengl$enable_gles1$enable_gles2" in
1636 x*yes*yes*)
1637     if test "x$enable_shared_glapi" = xno; then
1638         AC_MSG_ERROR([shared GLAPI required when building two or more of
1639                       the following APIs - opengl, gles1 gles2])
1640     fi
1641     ;;
1642 esac
1643
1644 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1645
1646 # Build the pipe-drivers as separate libraries/modules.
1647 # Do not touch this unless you know what you are doing.
1648 # XXX: Expose via configure option ?
1649 enable_shared_pipe_drivers=no
1650
1651 dnl
1652 dnl Driver specific build directories
1653 dnl
1654
1655 if test "x$enable_gallium_osmesa" = xyes; then
1656     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1657         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1658     fi
1659     if test "x$enable_osmesa" = xyes; then
1660         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1661     fi
1662 fi
1663
1664 require_dri_shared_libs_and_glapi() {
1665     if test "x$enable_static" = xyes; then
1666         AC_MSG_ERROR([$1 cannot be build as static library])
1667     fi
1668
1669     if test "x$enable_dri" != xyes; then
1670         # There is only a single backend which won't be build/used otherwise.
1671         # XXX: Revisit this as the egl/haiku is a thing.
1672         AC_MSG_ERROR([$1 requires --enable-dri])
1673     fi
1674
1675     if test "x$enable_shared_glapi" != xyes; then
1676         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1677     fi
1678 }
1679
1680 if test "x$enable_dri" = xyes; then
1681     require_dri_shared_libs_and_glapi "DRI"
1682
1683     # not a hard requirement as swrast does not depend on it
1684     if test "x$have_libdrm" = xyes; then
1685         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1686     fi
1687 fi
1688
1689 AC_ARG_ENABLE([driglx-direct],
1690     [AS_HELP_STRING([--disable-driglx-direct],
1691         [disable direct rendering in GLX and EGL for DRI \
1692             @<:@default=enabled@:>@])],
1693     [driglx_direct="$enableval"],
1694     [driglx_direct="yes"])
1695
1696 dnl
1697 dnl libGL configuration per driver
1698 dnl
1699 if test "x$enable_glx" != xno; then
1700     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1701 fi
1702 case "x$enable_glx" in
1703 xxlib | xgallium-xlib)
1704     # Xlib-based GLX
1705     dri_modules="x11 xext xcb"
1706     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1707     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1708     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1709     GL_LIB_DEPS="$XLIBGL_LIBS"
1710     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1711     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1712     ;;
1713 xdri)
1714     # DRI-based GLX
1715
1716     require_dri_shared_libs_and_glapi "GLX"
1717
1718     # find the DRI deps for libGL
1719     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1720
1721     if test x"$driglx_direct" = xyes; then
1722         if test x"$dri_platform" = xdrm ; then
1723             DEFINES="$DEFINES -DGLX_USE_DRM"
1724             require_libdrm "Direct rendering"
1725
1726             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1727             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1728
1729             if test x"$enable_dri" = xyes; then
1730                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1731             fi
1732
1733             dri_modules="$dri_modules xxf86vm"
1734         fi
1735         if test x"$dri_platform" = xapple ; then
1736             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1737         fi
1738         if test x"$dri_platform" = xwindows ; then
1739             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1740         fi
1741     fi
1742
1743     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1744     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1745     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1746     GL_LIB_DEPS="$DRIGL_LIBS"
1747
1748     # need DRM libs, $PTHREAD_LIBS, etc.
1749     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1750     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1751     ;;
1752 esac
1753
1754 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1755 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1756 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1757 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1758
1759 AC_SUBST([X11_INCLUDES])
1760 AC_SUBST([GL_LIB_DEPS])
1761 AC_SUBST([GL_PC_REQ_PRIV])
1762 AC_SUBST([GL_PC_LIB_PRIV])
1763 AC_SUBST([GL_PC_CFLAGS])
1764 AC_SUBST([DRI_PC_REQ_PRIV])
1765 AC_SUBST([GLESv1_CM_LIB_DEPS])
1766 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1767 AC_SUBST([GLESv2_LIB_DEPS])
1768 AC_SUBST([GLESv2_PC_LIB_PRIV])
1769
1770 dnl
1771 dnl More GLX setup
1772 dnl
1773 case "x$enable_glx" in
1774 xxlib | xgallium-xlib)
1775     DEFINES="$DEFINES -DUSE_XSHM"
1776     ;;
1777 xdri)
1778     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1779     if test "x$driglx_direct" = xyes; then
1780         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1781     fi
1782     ;;
1783 esac
1784
1785 dnl
1786 dnl TLS detection
1787 dnl
1788
1789 AC_ARG_ENABLE([glx-tls],
1790     [AS_HELP_STRING([--enable-glx-tls],
1791         [enable TLS support in GLX @<:@default=enabled@:>@])],
1792     [GLX_USE_TLS="$enableval"],
1793     [GLX_USE_TLS=yes])
1794 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1795
1796 if test "x$GLX_USE_TLS" = xyes; then
1797     DEFINES="$DEFINES -DGLX_USE_TLS"
1798 fi
1799
1800 dnl Read-only text section on x86 hardened platforms
1801 AC_ARG_ENABLE([glx-read-only-text],
1802     [AS_HELP_STRING([--enable-glx-read-only-text],
1803         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1804     [enable_glx_read_only_text="$enableval"],
1805     [enable_glx_read_only_text=no])
1806 if test "x$enable_glx_read_only_text" = xyes; then
1807     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1808 fi
1809
1810 dnl
1811 dnl DEPRECATED: EGL Platforms configuration
1812 dnl
1813 AC_ARG_WITH([egl-platforms],
1814     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1815         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1816     [with_egl_platforms="$withval"],
1817     [with_egl_platforms=auto])
1818
1819 if test "x$with_egl_platforms" = xauto; then
1820     with_egl_platforms="x11,surfaceless"
1821     if test "x$enable_gbm" = xyes; then
1822         with_egl_platforms="$with_egl_platforms,drm"
1823     fi
1824 else
1825     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1826 fi
1827
1828 dnl
1829 dnl Platforms configuration
1830 dnl
1831 AC_ARG_WITH([platforms],
1832     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1833         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1834         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1835     [with_platforms="$withval"],
1836     [with_platforms=auto])
1837
1838 # Reuse the autodetection rather than duplicating it.
1839 if test "x$with_platforms" = xauto; then
1840     with_platforms=$with_egl_platforms
1841 fi
1842
1843 # Do per platform setups and checks
1844 platforms=`IFS=', '; echo $with_platforms`
1845 for plat in $platforms; do
1846     case "$plat" in
1847     wayland)
1848
1849         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1850         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1851         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1852         if test "x$enable_egl" = xyes; then
1853           PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl-backend >= $WAYLAND_EGL_BACKEND_REQUIRED])
1854         fi
1855         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1856
1857         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1858                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1859                           WAYLAND_SCANNER='')
1860         PKG_CHECK_EXISTS([wayland-scanner >= 1.15],
1861                           AC_SUBST(SCANNER_ARG, 'private-code'),
1862                           AC_SUBST(SCANNER_ARG, 'code'))
1863
1864         if test "x$WAYLAND_SCANNER" = x; then
1865             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1866         fi
1867
1868         if test "x$WAYLAND_SCANNER" = "x:"; then
1869                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1870         fi
1871         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1872         ;;
1873
1874     x11)
1875         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1876         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1877         ;;
1878
1879     drm)
1880         test "x$enable_gbm" = "xno" &&
1881                 AC_MSG_ERROR([EGL platform drm needs gbm])
1882         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1883         ;;
1884
1885     surfaceless)
1886         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1887         ;;
1888
1889     android)
1890         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1891         if test -n "$with_gallium_drivers"; then
1892             PKG_CHECK_MODULES([BACKTRACE], [backtrace])
1893         fi
1894         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1895         ;;
1896
1897     *)
1898         AC_MSG_ERROR([platform '$plat' does not exist])
1899         ;;
1900     esac
1901
1902     case "$plat" in
1903     wayland|drm|surfaceless)
1904         require_libdrm "Platform $plat"
1905         ;;
1906     esac
1907 done
1908 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1909
1910 if test "x$enable_glx" != xno; then
1911     if ! echo "$platforms" | grep -q 'x11'; then
1912         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1913     fi
1914 fi
1915
1916 if test x"$enable_dri3" = xyes; then
1917     DEFINES="$DEFINES -DHAVE_DRI3"
1918
1919     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1920     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1921     dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1922     PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1923
1924     if test "x$have_dri3_modifiers" == xyes; then
1925         DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1926     fi
1927 fi
1928
1929
1930 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1931     have_xlease=yes
1932 else
1933     have_xlease=no
1934 fi
1935
1936 if test x"$have_xlease" = xyes; then
1937     randr_modules="x11-xcb xcb-randr"
1938     PKG_CHECK_MODULES([XCB_RANDR], [$randr_modules])
1939     xlib_randr_modules="xrandr"
1940     PKG_CHECK_MODULES([XLIB_RANDR], [$xlib_randr_modules])
1941 fi
1942
1943 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1944 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1945 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1946 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1947 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1948
1949 AC_ARG_ENABLE(xlib-lease,
1950     [AS_HELP_STRING([--enable-xlib-lease]
1951                     [enable VK_acquire_xlib_display using X leases])],
1952     [enable_xlib_lease=$enableval], [enable_xlib_lease=auto])
1953 case "x$enable_xlib_lease" in
1954 xyes)
1955     ;;
1956 xno)
1957     ;;
1958 *)
1959     if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1960         enable_xlib_lease=yes
1961     else
1962         enable_xlib_lease=no
1963     fi
1964 esac
1965
1966 AM_CONDITIONAL(HAVE_XLIB_LEASE, test "x$enable_xlib_lease" = xyes)
1967
1968 dnl
1969 dnl More DRI setup
1970 dnl
1971 dnl Directory for DRI drivers
1972 AC_ARG_WITH([dri-driverdir],
1973     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1974         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1975     [DRI_DRIVER_INSTALL_DIR="$withval"],
1976     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1977 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1978 dnl Extra search path for DRI drivers
1979 AC_ARG_WITH([dri-searchpath],
1980     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1981         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1982     [DRI_DRIVER_SEARCH_DIR="$withval"],
1983     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1984 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1985 dnl Which drivers to build - default is chosen by platform
1986 AC_ARG_WITH([dri-drivers],
1987     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1988         [comma delimited classic DRI drivers list, e.g.
1989         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1990     [with_dri_drivers="$withval"],
1991     [with_dri_drivers=auto])
1992
1993 if test "x$with_dri_drivers" = xauto; then
1994     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1995         with_dri_drivers="yes"
1996     else
1997         with_dri_drivers="no"
1998     fi
1999 fi
2000 if test "x$with_dri_drivers" = xno; then
2001     with_dri_drivers=''
2002 fi
2003
2004 # Check for expat
2005 PKG_CHECK_MODULES([EXPAT], [expat],,
2006     [PKG_CHECK_MODULES([EXPAT], [expat21])]
2007 )
2008
2009 dnl If $with_dri_drivers is yes, drivers will be added through
2010 dnl platform checks. Set DEFINES and LIB_DEPS
2011 if test "x$enable_dri" = xyes; then
2012     # Platform specific settings and drivers to build
2013     case "$host_os" in
2014     linux*)
2015         case "$host_cpu" in
2016         powerpc* | sparc*)
2017             # Build only the drivers for cards that exist on PowerPC/sparc
2018             if test "x$with_dri_drivers" = "xyes"; then
2019                 with_dri_drivers="r200 radeon swrast"
2020             fi
2021             ;;
2022         esac
2023         ;;
2024     cygwin*)
2025         if test "x$with_dri_drivers" = "xyes"; then
2026             with_dri_drivers="swrast"
2027         fi
2028         ;;
2029     darwin*)
2030         DEFINES="$DEFINES -DBUILDING_MESA"
2031         if test "x$with_dri_drivers" = "xyes"; then
2032             with_dri_drivers="swrast"
2033         fi
2034         ;;
2035     esac
2036
2037     # default drivers
2038     if test "x$with_dri_drivers" = "xyes"; then
2039         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
2040     fi
2041
2042     # put all the necessary libs together
2043     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
2044 fi
2045
2046 AC_SUBST([DRI_LIB_DEPS])
2047
2048 DRI_DIRS=''
2049 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
2050 if test -n "$with_dri_drivers"; then
2051     if test "x$enable_opengl" != xyes; then
2052         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
2053     fi
2054
2055     dri_drivers=`IFS=', '; echo $with_dri_drivers`
2056     for driver in $dri_drivers; do
2057         DRI_DIRS="$DRI_DIRS $driver"
2058         case "x$driver" in
2059         xi915)
2060             require_libdrm "i915"
2061             HAVE_I915_DRI=yes
2062             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2063             ;;
2064         xi965)
2065             require_libdrm "i965"
2066             HAVE_I965_DRI=yes
2067             ;;
2068         xnouveau)
2069             require_libdrm "nouveau"
2070             HAVE_NOUVEAU_DRI=yes
2071             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
2072             ;;
2073         xradeon)
2074             require_libdrm "radeon"
2075             HAVE_RADEON_DRI=yes;
2076             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2077             ;;
2078         xr200)
2079             require_libdrm "r200"
2080             HAVE_R200_DRI=yes
2081             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2082             ;;
2083         xswrast)
2084             HAVE_SWRAST_DRI=yes
2085             ;;
2086         *)
2087             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2088             ;;
2089         esac
2090     done
2091     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2092 fi
2093
2094
2095 dnl
2096 dnl Gallium LLVM
2097 dnl Deprecated: kept for backwards compatibility
2098 dnl
2099 AC_ARG_ENABLE([gallium-llvm],
2100     [AS_HELP_STRING([--enable-gallium-llvm],
2101         [DEPRECATED: use --enable-llvm instead])],
2102     [enable_gallium_llvm="$enableval"],
2103     [enable_gallium_llvm=auto])
2104
2105 if test "x$enable_gallium_llvm" != xauto; then
2106    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2107    enable_llvm=$enable_gallium_llvm
2108 fi
2109
2110 dnl
2111 dnl LLVM
2112 dnl
2113 AC_ARG_ENABLE([llvm],
2114     [AS_HELP_STRING([--enable-llvm],
2115         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2116     [enable_llvm="$enableval"],
2117     [enable_llvm=auto])
2118
2119 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2120     if test "x$FOUND_LLVM" = xyes; then
2121         case "$host_cpu" in
2122         i*86|x86_64|amd64) enable_llvm=yes;;
2123         *) enable_llvm=no;;
2124         esac
2125     else
2126         enable_llvm=no
2127     fi
2128 fi
2129
2130 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2131     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2132 fi
2133
2134 #
2135 # Vulkan driver configuration
2136 #
2137
2138 AC_ARG_WITH([vulkan-drivers],
2139     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2140         [comma delimited Vulkan drivers list, e.g.
2141         "intel,radeon"
2142         @<:@default=no@:>@])],
2143     [with_vulkan_drivers="$withval"],
2144     [with_vulkan_drivers="no"])
2145
2146 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2147 # here so that the script doesn't choke on an unknown driver name later.
2148 case "x$with_vulkan_drivers" in
2149     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2150     xno) with_vulkan_drivers='' ;;
2151 esac
2152
2153 AC_ARG_WITH([vulkan-icddir],
2154     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2155         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2156     [VULKAN_ICD_INSTALL_DIR="$withval"],
2157     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2158 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2159
2160 require_x11_dri3() {
2161     if echo "$platforms" | grep -q 'x11'; then
2162         if test "x$enable_dri3" != xyes; then
2163             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2164         fi
2165     fi
2166 }
2167
2168 if test -n "$with_vulkan_drivers"; then
2169     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2170         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2171     fi
2172
2173     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2174     for driver in $VULKAN_DRIVERS; do
2175         case "x$driver" in
2176         xintel)
2177             require_libdrm "ANV"
2178             require_x11_dri3 "ANV"
2179             HAVE_INTEL_VULKAN=yes
2180             ;;
2181         xradeon)
2182             require_libdrm "radv"
2183             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2184             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2185             require_x11_dri3 "radv"
2186             if test "x$acv_mako_found" = xno; then
2187                 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
2188             fi
2189             HAVE_RADEON_VULKAN=yes
2190             ;;
2191         *)
2192             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2193             ;;
2194         esac
2195     done
2196     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2197 fi
2198
2199
2200 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2201 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2202 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2203                                   "x$enable_osmesa" = xyes -o \
2204                                   -n "$DRI_DIRS")
2205
2206 dnl
2207 dnl OSMesa configuration
2208 dnl
2209
2210 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2211 AC_ARG_WITH([osmesa-bits],
2212     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2213         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2214     [osmesa_bits="$withval"],
2215     [osmesa_bits=8])
2216 if test "x$osmesa_bits" != x8; then
2217     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2218         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2219         osmesa_bits=8
2220     fi
2221 fi
2222 case "x$osmesa_bits" in
2223 x8)
2224     OSMESA_LIB="${OSMESA_LIB}"
2225     ;;
2226 x16|x32)
2227     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2228     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2229     ;;
2230 *)
2231     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2232     ;;
2233 esac
2234
2235 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2236     # only link libraries with osmesa if shared
2237     if test "$enable_static" = no; then
2238         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2239     else
2240         OSMESA_LIB_DEPS=""
2241     fi
2242     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2243 fi
2244
2245 AC_SUBST([OSMESA_LIB_DEPS])
2246 AC_SUBST([OSMESA_PC_REQ])
2247 AC_SUBST([OSMESA_PC_LIB_PRIV])
2248
2249 dnl
2250 dnl gbm configuration
2251 dnl
2252 if test "x$enable_gbm" = xyes; then
2253     require_dri_shared_libs_and_glapi "gbm"
2254 fi
2255 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2256 # FINISHME: GBM has a number of dependencies which we should add below
2257 GBM_PC_REQ_PRIV=""
2258 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2259 AC_SUBST([GBM_PC_REQ_PRIV])
2260 AC_SUBST([GBM_PC_LIB_PRIV])
2261
2262 dnl
2263 dnl EGL configuration
2264 dnl
2265
2266 if test "x$enable_egl" = xyes; then
2267     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2268
2269     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2270
2271     require_dri_shared_libs_and_glapi "egl"
2272 fi
2273 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2274 AC_SUBST([EGL_LIB_DEPS])
2275
2276 gallium_st="mesa"
2277
2278 dnl
2279 dnl XA configuration
2280 dnl
2281 if test "x$enable_xa" = xyes; then
2282     if test "x$with_gallium_drivers" = xswrast; then
2283        AC_MSG_ERROR([
2284           Building xa requires at least one non swrast gallium driver.
2285           If you are looking to use libxatracker.so with the VMware driver,
2286           make sure to include svga in the gallium drivers list, apart from
2287           enabling XA.
2288           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2289     fi
2290     gallium_st="$gallium_st xa"
2291 fi
2292 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2293
2294 if echo $platforms | grep -q "x11"; then
2295     have_xvmc_platform=yes
2296 else
2297     have_xvmc_platform=no
2298 fi
2299
2300 if echo $platforms | grep -q "x11"; then
2301     have_vdpau_platform=yes
2302 else
2303     have_vdpau_platform=no
2304 fi
2305
2306 if echo $platforms | egrep -q "x11|drm"; then
2307     have_omx_platform=yes
2308 else
2309     have_omx_platform=no
2310 fi
2311
2312 if echo $platforms | egrep -q "x11|drm|wayland"; then
2313     have_va_platform=yes
2314 else
2315     have_va_platform=no
2316 fi
2317
2318 dnl
2319 dnl Gallium G3DVL configuration
2320 dnl
2321 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2322     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2323         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2324     fi
2325
2326     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2327         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2328     fi
2329
2330     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2331         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2332     fi
2333
2334     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2335        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2336     fi
2337
2338     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2339         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2340     fi
2341 fi
2342
2343 if test "x$enable_dri" = xyes -o \
2344         "x$enable_xvmc" = xyes -o \
2345         "x$enable_vdpau" = xyes -o \
2346         "x$enable_omx_bellagio" = xyes -o \
2347         "x$enable_omx_tizonia" = xyes -o \
2348         "x$enable_va" = xyes; then
2349     need_gallium_vl=yes
2350 fi
2351 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2352
2353 if test "x$enable_xvmc" = xyes -o \
2354         "x$enable_vdpau" = xyes -o \
2355         "x$enable_omx_bellagio" = xyes -o \
2356         "x$enable_omx_tizonia" = xyes -o \
2357         "x$enable_va" = xyes; then
2358     if echo $platforms | grep -q "x11"; then
2359         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2360     fi
2361     need_gallium_vl_winsys=yes
2362 fi
2363 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2364
2365 if test "x$enable_xvmc" = xyes; then
2366     if test "x$have_xvmc_platform" != xyes; then
2367         AC_MSG_ERROR([XVMC requires the x11 platforms])
2368     fi
2369     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2370     gallium_st="$gallium_st xvmc"
2371 fi
2372 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2373
2374 if test "x$enable_vdpau" = xyes; then
2375     if test "x$have_vdpau_platform" != xyes; then
2376         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2377     fi
2378     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2379     gallium_st="$gallium_st vdpau"
2380     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2381 fi
2382 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2383
2384 if test "x$enable_omx_bellagio" = xyes; then
2385     if test "x$have_omx_platform" != xyes; then
2386         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2387     fi
2388     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2389     gallium_st="$gallium_st omx_bellagio"
2390     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2391 else
2392     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2393 fi
2394 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2395
2396 if test "x$enable_omx_tizonia" = xyes; then
2397     if test "x$have_omx_platform" != xyes; then
2398         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2399     fi
2400     PKG_CHECK_MODULES([OMX_TIZONIA],
2401                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2402                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2403                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2404     gallium_st="$gallium_st omx_tizonia"
2405     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2406 else
2407     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2408 fi
2409 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2410
2411 if test "x$enable_va" = xyes; then
2412     if test "x$have_va_platform" != xyes; then
2413         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2414     fi
2415     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2416     gallium_st="$gallium_st va"
2417 fi
2418 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2419
2420 dnl
2421 dnl Nine Direct3D9 configuration
2422 dnl
2423 if test "x$enable_nine" = xyes; then
2424     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2425         AC_MSG_ERROR([nine requires the gallium swrast driver])
2426     fi
2427     if test "x$with_gallium_drivers" = xswrast; then
2428         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2429     fi
2430     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2431         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2432     fi
2433
2434     if test "x$enable_dri3" = xno; then
2435         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2436     fi
2437
2438     gallium_st="$gallium_st nine"
2439 fi
2440 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2441
2442 dnl
2443 dnl OpenCL configuration
2444 dnl
2445
2446 AC_ARG_WITH([clang-libdir],
2447    [AS_HELP_STRING([--with-clang-libdir],
2448          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2449    [CLANG_LIBDIR="$withval"],
2450    [CLANG_LIBDIR=''])
2451
2452 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2453
2454 if test "x$enable_opencl" = xyes; then
2455     if test -z "$with_gallium_drivers"; then
2456         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2457     fi
2458
2459     if test "x$HAVE_CXX11" != "xyes"; then
2460        AC_MSG_ERROR([clover requires c++11 support])
2461     fi
2462
2463     if test "x$have_libclc" = xno; then
2464         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2465                     Make sure the directory containing libclc.pc is specified in your
2466                     PKG_CONFIG_PATH environment variable.
2467                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2468     else
2469         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2470         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2471         AC_SUBST([LIBCLC_INCLUDEDIR])
2472         AC_SUBST([LIBCLC_LIBEXECDIR])
2473     fi
2474
2475     gallium_st="$gallium_st clover"
2476
2477     if test "x$enable_opencl_icd" = xyes; then
2478         OPENCL_LIBNAME="MesaOpenCL"
2479     else
2480         OPENCL_LIBNAME="OpenCL"
2481     fi
2482
2483     if test "x$have_libelf" != xyes; then
2484        AC_MSG_ERROR([Clover requires libelf])
2485     fi
2486
2487     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2488         altivec_enabled=no
2489         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2490         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2491         #error "AltiVec not enabled"
2492         #endif
2493         ])], altivec_enabled=yes)
2494
2495         if test "$altivec_enabled" = yes; then
2496             CLOVER_STD_OVERRIDE="-std=gnu++11"
2497         fi
2498         AC_SUBST([CLOVER_STD_OVERRIDE])
2499     fi
2500
2501     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2502
2503     llvm_add_default_components "opencl"
2504     llvm_add_component "all-targets" "opencl"
2505     llvm_add_component "coverage" "opencl"
2506     llvm_add_component "linker" "opencl"
2507     llvm_add_component "instrumentation" "opencl"
2508     llvm_add_component "ipo" "opencl"
2509     llvm_add_component "irreader" "opencl"
2510     llvm_add_component "lto" "opencl"
2511     llvm_add_component "option" "opencl"
2512     llvm_add_component "objcarcopts" "opencl"
2513     llvm_add_component "profiledata" "opencl"
2514     llvm_add_optional_component "coroutines" "opencl"
2515
2516     dnl Check for Clang internal headers
2517     if test -z "$CLANG_LIBDIR"; then
2518         CLANG_LIBDIR=${LLVM_LIBDIR}
2519     fi
2520     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2521     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2522         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2523 fi
2524 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2525 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2526 AC_SUBST([OPENCL_LIBNAME])
2527 AC_SUBST([CLANG_RESOURCE_DIR])
2528
2529 dnl
2530 dnl Gallium configuration
2531 dnl
2532 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2533
2534 # libEGL wants to default to the first platform specified in
2535 # ./configure.  parse that here.
2536 if test "x$platforms" != "x"; then
2537     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2538     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2539 else
2540     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2541 fi
2542
2543 AC_SUBST([EGL_NATIVE_PLATFORM])
2544 AC_SUBST([EGL_CFLAGS])
2545
2546 # If we don't have the X11 platform, set this define so we don't try to include
2547 # the X11 headers.
2548 if ! echo "$platforms" | grep -q 'x11'; then
2549     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2550     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2551 fi
2552
2553 dnl Directory for XVMC libs
2554 AC_ARG_WITH([xvmc-libdir],
2555     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2556         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2557     [XVMC_LIB_INSTALL_DIR="$withval"],
2558     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2559 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2560
2561 dnl
2562 dnl Gallium Tests
2563 dnl
2564 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2565
2566 dnl Directory for VDPAU libs
2567 AC_ARG_WITH([vdpau-libdir],
2568     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2569         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2570     [VDPAU_LIB_INSTALL_DIR="$withval"],
2571     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2572 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2573
2574 dnl Directory for OMX_BELLAGIO libs
2575
2576 AC_ARG_WITH([omx-bellagio-libdir],
2577     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2578         [directory for the OMX_BELLAGIO libraries])],
2579     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2580     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2581                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2582 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2583
2584 dnl Directory for OMX_TIZONIA libs
2585
2586 AC_ARG_WITH([omx-tizonia-libdir],
2587     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2588         [directory for the OMX_TIZONIA libraries])],
2589     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2590     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2591 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2592
2593 dnl Directory for VA libs
2594
2595 AC_ARG_WITH([va-libdir],
2596     [AS_HELP_STRING([--with-va-libdir=DIR],
2597         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2598     [VA_LIB_INSTALL_DIR="$withval"],
2599     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2600 AC_SUBST([VA_LIB_INSTALL_DIR])
2601
2602 AC_ARG_WITH([d3d-libdir],
2603     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2604         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2605     [D3D_DRIVER_INSTALL_DIR="$withval"],
2606     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2607 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2608
2609 dnl Architectures to build SWR library for
2610
2611 AC_ARG_WITH([swr-archs],
2612     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2613         [comma delimited swr architectures list, e.g.
2614         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2615     [with_swr_archs="$withval"],
2616     [with_swr_archs="avx,avx2"])
2617
2618 dnl
2619 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2620 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2621 dnl architectures.
2622 dnl
2623 r300_require_llvm() {
2624     case "$host" in *gnux32) return;; esac
2625     case "$host_cpu" in
2626     i*86|x86_64|amd64) require_llvm $1
2627         ;;
2628     esac
2629 }
2630
2631 dnl
2632 dnl DRM is needed by X, Wayland, and offscreen rendering.
2633 dnl Surfaceless is an alternative for the last one.
2634 dnl
2635 require_basic_egl() {
2636     case "$with_platforms" in
2637         *drm*|*surfaceless*|*android*)
2638             ;;
2639         *)
2640             AC_MSG_ERROR([$1 requires one of these:
2641                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2642                   2) --with-platforms=surfaceless (offscreen only)
2643                   3) --with-platforms=android (Android only)
2644                   Recommended options: drm,x11])
2645             ;;
2646     esac
2647 }
2648
2649 swr_require_cxx_feature_flags() {
2650     feature_name="$1"
2651     preprocessor_test="$2"
2652     option_list="$3"
2653     output_var="$4"
2654
2655     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2656     AC_LANG_PUSH([C++])
2657     save_CXXFLAGS="$CXXFLAGS"
2658     save_IFS="$IFS"
2659     IFS=","
2660     found=0
2661     for opts in $option_list
2662     do
2663         unset IFS
2664         CXXFLAGS="$opts $save_CXXFLAGS"
2665         AC_COMPILE_IFELSE(
2666             [AC_LANG_PROGRAM(
2667                 [   #if !($preprocessor_test)
2668                     #error
2669                     #endif
2670                 ])],
2671             [found=1; break],
2672             [])
2673         IFS=","
2674     done
2675     IFS="$save_IFS"
2676     CXXFLAGS="$save_CXXFLAGS"
2677     AC_LANG_POP([C++])
2678     if test $found -eq 1; then
2679         AC_MSG_RESULT([$opts])
2680         eval "$output_var=\$opts"
2681         return 0
2682     fi
2683     AC_MSG_RESULT([no])
2684     AC_MSG_ERROR([swr requires $feature_name support])
2685     return 1
2686 }
2687
2688 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2689 if test -n "$with_gallium_drivers"; then
2690     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2691     for driver in $gallium_drivers; do
2692         case "x$driver" in
2693         xsvga)
2694             HAVE_GALLIUM_SVGA=yes
2695             require_libdrm "svga"
2696             ;;
2697         xi915)
2698             HAVE_GALLIUM_I915=yes
2699             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2700             require_libdrm "Gallium i915"
2701             ;;
2702         xr300)
2703             HAVE_GALLIUM_R300=yes
2704             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2705             require_libdrm "r300"
2706             r300_require_llvm "r300"
2707             ;;
2708         xr600)
2709             HAVE_GALLIUM_R600=yes
2710             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2711             require_libdrm "r600"
2712             if test "x$enable_llvm" = xyes; then
2713                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2714
2715                 llvm_add_component "asmparser" "r600"
2716                 llvm_add_component "bitreader" "r600"
2717             fi
2718             ;;
2719         xradeonsi)
2720             HAVE_GALLIUM_RADEONSI=yes
2721             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2722             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2723             require_libdrm "radeonsi"
2724             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2725             if test "x$enable_egl" = xyes; then
2726                 require_basic_egl "radeonsi"
2727             fi
2728             ;;
2729         xnouveau)
2730             HAVE_GALLIUM_NOUVEAU=yes
2731             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2732             require_libdrm "nouveau"
2733             ;;
2734         xfreedreno)
2735             HAVE_GALLIUM_FREEDRENO=yes
2736             require_libdrm "freedreno"
2737             ;;
2738         xetnaviv)
2739             HAVE_GALLIUM_ETNAVIV=yes
2740             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2741             require_libdrm "etnaviv"
2742             ;;
2743        ximx)
2744             HAVE_GALLIUM_IMX=yes
2745             ;;
2746         xtegra)
2747             HAVE_GALLIUM_TEGRA=yes
2748             require_libdrm "tegra"
2749             ;;
2750         xswrast)
2751             HAVE_GALLIUM_SOFTPIPE=yes
2752             if test "x$enable_llvm" = xyes; then
2753                 HAVE_GALLIUM_LLVMPIPE=yes
2754             fi
2755             ;;
2756         xswr)
2757             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2758
2759             if test "x$HAVE_CXX11" != "xyes"; then
2760                 AC_MSG_ERROR([swr requires c++11 support])
2761             fi
2762
2763             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2764                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2765                 SWR_AVX_CXXFLAGS
2766             AC_SUBST([SWR_AVX_CXXFLAGS])
2767
2768             swr_archs=`IFS=', '; echo $with_swr_archs`
2769             for arch in $swr_archs; do
2770                 case "x$arch" in
2771                 xavx)
2772                     HAVE_SWR_AVX=yes
2773                     ;;
2774                 xavx2)
2775                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2776                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2777                         SWR_AVX2_CXXFLAGS
2778                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2779                     HAVE_SWR_AVX2=yes
2780                     ;;
2781                 xknl)
2782                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2783                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2784                         SWR_KNL_CXXFLAGS
2785                     AC_SUBST([SWR_KNL_CXXFLAGS])
2786                     HAVE_SWR_KNL=yes
2787                     ;;
2788                 xskx)
2789                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2790                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2791                         SWR_SKX_CXXFLAGS
2792                     AC_SUBST([SWR_SKX_CXXFLAGS])
2793                     HAVE_SWR_SKX=yes
2794                     ;;
2795                 *)
2796                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2797                     ;;
2798                 esac
2799             done
2800
2801             if test "x$HAVE_SWR_AVX" != xyes -a \
2802                     "x$HAVE_SWR_AVX2" != xyes -a \
2803                     "x$HAVE_SWR_KNL" != xyes -a \
2804                     "x$HAVE_SWR_SKX" != xyes; then
2805                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2806             fi
2807
2808             # test if more than one swr arch configured
2809             if test `echo $swr_archs | wc -w` -eq 1; then
2810                 HAVE_SWR_BUILTIN=yes
2811             fi
2812
2813             HAVE_GALLIUM_SWR=yes
2814             ;;
2815         xvc4)
2816             HAVE_GALLIUM_VC4=yes
2817             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED])
2818
2819             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2820                               [USE_VC4_SIMULATOR=yes;
2821                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2822                               [USE_VC4_SIMULATOR=no])
2823             ;;
2824         xv3d)
2825             HAVE_GALLIUM_V3D=yes
2826
2827             PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2828                               [USE_V3D_SIMULATOR=yes;
2829                                DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2830                               [USE_V3D_SIMULATOR=no])
2831             ;;
2832         xpl111)
2833             HAVE_GALLIUM_PL111=yes
2834             ;;
2835         xvirgl)
2836             HAVE_GALLIUM_VIRGL=yes
2837             require_libdrm "virgl"
2838             if test "x$enable_egl" = xyes; then
2839                 require_basic_egl "virgl"
2840             fi
2841             ;;
2842         *)
2843             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2844             ;;
2845         esac
2846     done
2847 fi
2848
2849 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2850 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x6.0.0 -a \
2851                                               "x$LLVM_VERSION" != x6.0.1)
2852
2853 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2854     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2855     llvm_add_default_components "gallium"
2856 fi
2857
2858 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2859 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2860 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2861 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2862 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2863
2864 dnl We need to validate some needed dependencies for renderonly drivers.
2865
2866 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2867     AC_MSG_ERROR([Building with imx requires etnaviv])
2868 fi
2869
2870 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2871     AC_MSG_ERROR([Building with pl111 requires vc4])
2872 fi
2873
2874 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2875     AC_MSG_ERROR([Building with tegra requires nouveau])
2876 fi
2877
2878 detect_old_buggy_llvm() {
2879     dnl llvm-config may not give the right answer when llvm is a built as a
2880     dnl single shared library, so we must work the library name out for
2881     dnl ourselves.
2882     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2883     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2884     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2885     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2886
2887     if test "x$llvm_have_one_so" = xyes; then
2888         dnl LLVM was built using auto*, so there is only one shared object.
2889         LLVM_LIBS="-l$LLVM_SO_NAME"
2890     else
2891         dnl If LLVM was built with CMake, there will be one shared object per
2892         dnl component.
2893         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2894                [AC_MSG_ERROR([Could not find llvm shared libraries:
2895                 Please make sure you have built llvm with the --enable-shared option
2896                 and that your llvm libraries are installed in $LLVM_LIBDIR
2897                 If you have installed your llvm libraries to a different directory you
2898                 can use the --with-llvm-prefix= configure flag to specify this directory.
2899                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2900                 If you do not want to build with llvm shared libraries and instead want to
2901                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2902                 invocation and rebuild.])])
2903
2904         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2905         dnl install uses a shared object for each component and we have
2906         dnl already added all of these objects to LLVM_LIBS.
2907     fi
2908 }
2909
2910 dnl
2911 dnl Set defines and buildtime variables only when using LLVM.
2912 dnl
2913 if test "x$enable_llvm" = xyes; then
2914     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2915
2916     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2917     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2918     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2919     LLVM_CXXFLAGS="$CXX11_CXXFLAGS $LLVM_CXXFLAGS"
2920
2921     dnl Set LLVM_LIBS - This is done after the driver configuration so
2922     dnl that drivers can add additional components to LLVM_COMPONENTS.
2923     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2924     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2925     dnl this was causing the same libraries to be appear multiple times
2926     dnl in LLVM_LIBS.
2927
2928     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2929         if test "x$enable_llvm_shared_libs" = xyes; then
2930             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2931         else
2932             dnl Invoking llvm-config with both -libs and --system-libs produces the
2933             dnl two separate lines - each for the set of libraries.
2934                 dnl Call the program twice, effectively folding them into a single line.
2935             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2936             dnl We need to link to llvm system libs when using static libs
2937             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2938         fi
2939     else
2940         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2941         if test "x$enable_llvm_shared_libs" = xyes; then
2942             detect_old_buggy_llvm
2943         else
2944             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2945             dnl We need to link to llvm system libs when using static libs
2946             dnl However, only llvm 3.5+ provides --system-libs
2947             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2948                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2949             fi
2950         fi
2951     fi
2952
2953     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2954     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2955     dnl the LLVM library propagated in the Libs.private of the respective .pc
2956     dnl file which ensures complete dependency information when statically
2957     dnl linking.
2958     if test "x$enable_glx" == xgallium-xlib; then
2959         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2960     fi
2961     if test "x$enable_gallium_osmesa" = xyes; then
2962         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2963     fi
2964 fi
2965
2966 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2967 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2968 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2969 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2970 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2971 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2972 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2973 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2974 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2975 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2976 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2977 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2978 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2979 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2980 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2981                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2982                                          "x$HAVE_GALLIUM_SWR" = xyes)
2983 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2984 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2985 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2986
2987 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2988
2989 if test "x$enable_dri" = xyes; then
2990     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2991 fi
2992
2993 if test "x$have_drisw_kms" = xyes; then
2994     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2995 fi
2996 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2997
2998 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2999 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
3000 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
3001 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
3002 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
3003 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
3004
3005 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
3006 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
3007
3008 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
3009                                       "x$HAVE_RADEON_VULKAN" = xyes)
3010
3011 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
3012                                       "x$HAVE_GALLIUM_V3D" = xyes)
3013
3014 AM_CONDITIONAL(HAVE_FREEDRENO_DRIVERS, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
3015 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
3016                                         "x$HAVE_I965_DRI" = xyes)
3017
3018 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
3019                                             "x$HAVE_GALLIUM_R600" = xyes -o \
3020                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
3021 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
3022 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
3023 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
3024 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
3025 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
3026
3027 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
3028 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
3029 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
3030 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
3031                                         "x$enable_gallium_osmesa" = xyes)
3032
3033 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
3034 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
3035 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
3036 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
3037 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
3038 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
3039
3040 AC_SUBST([NINE_MAJOR], 1)
3041 AC_SUBST([NINE_MINOR], 0)
3042 AC_SUBST([NINE_PATCH], 0)
3043 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
3044
3045 AC_SUBST([VDPAU_MAJOR], 1)
3046 AC_SUBST([VDPAU_MINOR], 0)
3047
3048 if test "x$enable_va" = xyes; then
3049     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
3050     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
3051 fi
3052 AC_SUBST([VA_MAJOR], $VA_MAJOR)
3053 AC_SUBST([VA_MINOR], $VA_MINOR)
3054
3055 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
3056
3057 AC_SUBST([XVMC_MAJOR], 1)
3058 AC_SUBST([XVMC_MINOR], 0)
3059
3060 AC_SUBST([XA_MAJOR], 2)
3061 AC_SUBST([XA_MINOR], 5)
3062 AC_SUBST([XA_PATCH], 0)
3063 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
3064
3065 AC_ARG_ENABLE(valgrind,
3066               [AS_HELP_STRING([--enable-valgrind],
3067                              [Build mesa with valgrind support (default: auto)])],
3068                              [VALGRIND=$enableval], [VALGRIND=auto])
3069 if test "x$VALGRIND" != xno; then
3070     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
3071 fi
3072 AC_MSG_CHECKING([whether to enable Valgrind support])
3073 if test "x$VALGRIND" = xauto; then
3074     VALGRIND="$have_valgrind"
3075 fi
3076
3077 if test "x$VALGRIND" = "xyes"; then
3078     if ! test "x$have_valgrind" = xyes; then
3079         AC_MSG_ERROR([Valgrind support required but not present])
3080     fi
3081     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
3082 fi
3083
3084 AC_MSG_RESULT([$VALGRIND])
3085
3086 dnl Restore LDFLAGS and CPPFLAGS
3087 LDFLAGS="$_SAVE_LDFLAGS"
3088 CPPFLAGS="$_SAVE_CPPFLAGS"
3089
3090 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3091 if test "x$acv_mesa_CLANG" = xyes; then
3092     CFLAGS="$CFLAGS -Qunused-arguments"
3093     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3094 fi
3095
3096 dnl Add user CFLAGS and CXXFLAGS
3097 CFLAGS="$CFLAGS $USER_CFLAGS"
3098 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3099
3100 dnl Substitute the config
3101 AC_CONFIG_FILES([Makefile
3102                  src/Makefile
3103                  src/amd/Makefile
3104                  src/amd/vulkan/Makefile
3105                  src/broadcom/Makefile
3106                  src/compiler/Makefile
3107                  src/freedreno/Makefile
3108                  src/egl/Makefile
3109                  src/egl/main/egl.pc
3110                  src/egl/wayland/wayland-drm/Makefile
3111                  src/gallium/Makefile
3112                  src/gallium/auxiliary/Makefile
3113                  src/gallium/auxiliary/pipe-loader/Makefile
3114                  src/gallium/drivers/freedreno/Makefile
3115                  src/gallium/drivers/i915/Makefile
3116                  src/gallium/drivers/llvmpipe/Makefile
3117                  src/gallium/drivers/nouveau/Makefile
3118                  src/gallium/drivers/pl111/Makefile
3119                  src/gallium/drivers/r300/Makefile
3120                  src/gallium/drivers/r600/Makefile
3121                  src/gallium/drivers/radeonsi/Makefile
3122                  src/gallium/drivers/softpipe/Makefile
3123                  src/gallium/drivers/svga/Makefile
3124                  src/gallium/drivers/swr/Makefile
3125                  src/gallium/drivers/tegra/Makefile
3126                  src/gallium/drivers/etnaviv/Makefile
3127                  src/gallium/drivers/imx/Makefile
3128                  src/gallium/drivers/v3d/Makefile
3129                  src/gallium/drivers/vc4/Makefile
3130                  src/gallium/drivers/virgl/Makefile
3131                  src/gallium/state_trackers/clover/Makefile
3132                  src/gallium/state_trackers/dri/Makefile
3133                  src/gallium/state_trackers/glx/xlib/Makefile
3134                  src/gallium/state_trackers/nine/Makefile
3135                  src/gallium/state_trackers/omx/Makefile
3136                  src/gallium/state_trackers/omx/bellagio/Makefile
3137                  src/gallium/state_trackers/omx/tizonia/Makefile
3138                  src/gallium/state_trackers/osmesa/Makefile
3139                  src/gallium/state_trackers/va/Makefile
3140                  src/gallium/state_trackers/vdpau/Makefile
3141                  src/gallium/state_trackers/xa/Makefile
3142                  src/gallium/state_trackers/xa/xa_tracker.h
3143                  src/gallium/state_trackers/xvmc/Makefile
3144                  src/gallium/targets/d3dadapter9/Makefile
3145                  src/gallium/targets/d3dadapter9/d3d.pc
3146                  src/gallium/targets/dri/Makefile
3147                  src/gallium/targets/libgl-xlib/Makefile
3148                  src/gallium/targets/omx/Makefile
3149                  src/gallium/targets/opencl/Makefile
3150                  src/gallium/targets/opencl/mesa.icd
3151                  src/gallium/targets/osmesa/Makefile
3152                  src/gallium/targets/osmesa/osmesa.pc
3153                  src/gallium/targets/pipe-loader/Makefile
3154                  src/gallium/targets/va/Makefile
3155                  src/gallium/targets/vdpau/Makefile
3156                  src/gallium/targets/xa/Makefile
3157                  src/gallium/targets/xa/xatracker.pc
3158                  src/gallium/targets/xvmc/Makefile
3159                  src/gallium/tests/trivial/Makefile
3160                  src/gallium/tests/unit/Makefile
3161                  src/gallium/winsys/etnaviv/drm/Makefile
3162                  src/gallium/winsys/imx/drm/Makefile
3163                  src/gallium/winsys/freedreno/drm/Makefile
3164                  src/gallium/winsys/i915/drm/Makefile
3165                  src/gallium/winsys/nouveau/drm/Makefile
3166                  src/gallium/winsys/pl111/drm/Makefile
3167                  src/gallium/winsys/radeon/drm/Makefile
3168                  src/gallium/winsys/amdgpu/drm/Makefile
3169                  src/gallium/winsys/svga/drm/Makefile
3170                  src/gallium/winsys/sw/dri/Makefile
3171                  src/gallium/winsys/sw/kms-dri/Makefile
3172                  src/gallium/winsys/sw/null/Makefile
3173                  src/gallium/winsys/sw/wrapper/Makefile
3174                  src/gallium/winsys/sw/xlib/Makefile
3175                  src/gallium/winsys/tegra/drm/Makefile
3176                  src/gallium/winsys/v3d/drm/Makefile
3177                  src/gallium/winsys/vc4/drm/Makefile
3178                  src/gallium/winsys/virgl/drm/Makefile
3179                  src/gallium/winsys/virgl/vtest/Makefile
3180                  src/gbm/Makefile
3181                  src/gbm/main/gbm.pc
3182                  src/glx/Makefile
3183                  src/glx/apple/Makefile
3184                  src/glx/tests/Makefile
3185                  src/glx/windows/Makefile
3186                  src/glx/windows/windowsdriproto.pc
3187                  src/gtest/Makefile
3188                  src/intel/Makefile
3189                  src/loader/Makefile
3190                  src/mapi/Makefile
3191                  src/mapi/es1api/glesv1_cm.pc
3192                  src/mapi/es2api/glesv2.pc
3193                  src/mapi/glapi/gen/Makefile
3194                  src/mesa/Makefile
3195                  src/mesa/gl.pc
3196                  src/mesa/drivers/dri/dri.pc
3197                  src/mesa/drivers/dri/common/Makefile
3198                  src/mesa/drivers/dri/i915/Makefile
3199                  src/mesa/drivers/dri/i965/Makefile
3200                  src/mesa/drivers/dri/Makefile
3201                  src/mesa/drivers/dri/nouveau/Makefile
3202                  src/mesa/drivers/dri/r200/Makefile
3203                  src/mesa/drivers/dri/radeon/Makefile
3204                  src/mesa/drivers/dri/swrast/Makefile
3205                  src/mesa/drivers/osmesa/Makefile
3206                  src/mesa/drivers/osmesa/osmesa.pc
3207                  src/mesa/drivers/x11/Makefile
3208                  src/mesa/main/tests/Makefile
3209                  src/mesa/state_tracker/tests/Makefile
3210                  src/util/Makefile
3211                  src/util/tests/fast_idiv_by_const/Makefile
3212                  src/util/tests/hash_table/Makefile
3213                  src/util/tests/set/Makefile
3214                  src/util/tests/string_buffer/Makefile
3215                  src/util/tests/vma/Makefile
3216                  src/util/xmlpool/Makefile
3217                  src/vulkan/Makefile])
3218
3219 AC_OUTPUT
3220
3221 # Fix up dependencies in *.Plo files, where we changed the extension of a
3222 # source file
3223 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3224
3225 rm -f src/compiler/spirv/spirv_info.lo
3226 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3227
3228 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3229 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3230
3231 dnl
3232 dnl Output some configuration info for the user
3233 dnl
3234 echo ""
3235 echo "        prefix:          $prefix"
3236 echo "        exec_prefix:     $exec_prefix"
3237 echo "        libdir:          $libdir"
3238 echo "        includedir:      $includedir"
3239
3240 dnl API info
3241 echo ""
3242 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3243
3244 dnl Driver info
3245 echo ""
3246 case "x$enable_osmesa$enable_gallium_osmesa" in
3247 xnoyes)
3248         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3249         ;;
3250 xyesno)
3251         echo "        OSMesa:          lib$OSMESA_LIB"
3252         ;;
3253 xnono)
3254         echo "        OSMesa:          no"
3255         ;;
3256 esac
3257
3258 echo ""
3259 if test "x$enable_dri" != xno; then
3260         echo "        DRI platform:    $dri_platform"
3261         if test -z "$DRI_DIRS"; then
3262             echo "        DRI drivers:     no"
3263         else
3264             echo "        DRI drivers:     $DRI_DIRS"
3265         fi
3266         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3267 fi
3268
3269 case "x$enable_glx" in
3270 xdri)
3271     echo "        GLX:             DRI-based"
3272     ;;
3273 xxlib)
3274     echo "        GLX:             Xlib-based"
3275     ;;
3276 xgallium-xlib)
3277     echo "        GLX:             Xlib-based (Gallium)"
3278     ;;
3279 *)
3280     echo "        GLX:             $enable_glx"
3281     ;;
3282 esac
3283
3284 dnl EGL
3285 echo ""
3286 echo "        EGL:             $enable_egl"
3287 if test "$enable_egl" = yes; then
3288
3289     egl_drivers=""
3290     if test "x$enable_dri" != "xno"; then
3291         egl_drivers="$egl_drivers builtin:egl_dri2"
3292     fi
3293     if test "x$enable_dri3" != "xno"; then
3294         egl_drivers="$egl_drivers builtin:egl_dri3"
3295     fi
3296
3297     echo "        EGL drivers:    $egl_drivers"
3298 fi
3299 if test "x$enable_gbm" = xyes; then
3300     echo "        GBM:             yes"
3301 else
3302     echo "        GBM:             no"
3303 fi
3304
3305     echo "        EGL/Vulkan/VL platforms:   $platforms"
3306
3307 # Vulkan
3308 echo ""
3309 if test "x$VULKAN_DRIVERS" != x; then
3310     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3311     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3312 else
3313     echo "        Vulkan drivers:  no"
3314 fi
3315
3316 echo ""
3317 if test "x$enable_llvm" = xyes; then
3318     echo "        llvm:            yes"
3319     echo "        llvm-config:     $LLVM_CONFIG"
3320     echo "        llvm-version:    $LLVM_VERSION"
3321 else
3322     echo "        llvm:            no"
3323 fi
3324
3325 echo ""
3326 if test -n "$with_gallium_drivers"; then
3327     echo "        Gallium drivers: $gallium_drivers"
3328     echo "        Gallium st:      $gallium_st"
3329 else
3330     echo "        Gallium:         no"
3331 fi
3332
3333 echo ""
3334 if test "x$enable_gallium_extra_hud" != xyes; then
3335     echo "        HUD extra stats: no"
3336 else
3337     echo "        HUD extra stats: yes"
3338 fi
3339
3340 if test "x$enable_lmsensors" != xyes; then
3341     echo "        HUD lmsensors:   no"
3342 else
3343     echo "        HUD lmsensors:   yes"
3344 fi
3345
3346 echo ""
3347 if test "x$HAVE_GALLIUM_SWR" != x; then
3348     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3349         echo "        SWR archs:       $swr_archs (builtin)"
3350     else
3351         echo "        SWR archs:       $swr_archs"
3352     fi
3353 fi
3354
3355 dnl Libraries
3356 echo ""
3357 echo "        Shared libs:     $enable_shared"
3358 echo "        Static libs:     $enable_static"
3359 echo "        Shared-glapi:    $enable_shared_glapi"
3360
3361 dnl Compiler options
3362 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3363 cflags=`echo $CFLAGS | \
3364     $SED 's/^ *//;s/  */ /;s/ *$//'`
3365 cxxflags=`echo $CXXFLAGS | \
3366     $SED 's/^ *//;s/  */ /;s/ *$//'`
3367 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3368 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3369 echo ""
3370 echo "        CFLAGS:          $cflags"
3371 echo "        CXXFLAGS:        $cxxflags"
3372 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3373 echo "        LDFLAGS:         $ldflags"
3374 echo "        Macros:          $defines"
3375 echo ""
3376 if test "x$enable_llvm" = xyes; then
3377     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3378     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3379     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3380     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3381     echo ""
3382 fi
3383 echo "        PYTHON:         $PYTHON"
3384
3385 echo ""
3386 echo "        Run '${MAKE-make}' to build Mesa"
3387 echo ""