configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 dnl http://people.gnome.org/~walters/docs/build-api.txt
  18 dnl We don't support srcdir != builddir.
  19 echo \#buildapi-variable-no-builddir >/dev/null
  20
  21 # Support silent build rules, requires at least automake-1.11. Disable
  22 # by either passing --disable-silent-rules to configure or passing V=1
  23 # to make
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  25     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  26
  27 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  28
  29 dnl Set internal versions
  30 OSMESA_VERSION=8
  31 AC_SUBST([OSMESA_VERSION])
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.46
  36 LIBDRM_INTEL_REQUIRED=2.4.38
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  39 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AX_PYTHON_MODULE([libxml2], [needed])
  54 AC_PROG_SED
  55 AC_PROG_MKDIR_P
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 GEN_ASM_OFFSETS=no
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120
 121     if test "x$cross_compiling" = xyes; then
 122         GEN_ASM_OFFSETS=yes
 123     fi
 124 fi
 125 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 126
 127 dnl Make sure the pkg-config macros are defined
 128 m4_ifndef([PKG_PROG_PKG_CONFIG],
 129     [m4_fatal([Could not locate the pkg-config autoconf macros.
 130   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 131   are in a different location, try setting the environment variable
 132   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 133 PKG_PROG_PKG_CONFIG()
 134
 135 dnl LIB_DIR - library basename
 136 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 137 AC_SUBST([LIB_DIR])
 138
 139 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 140 _SAVE_LDFLAGS="$LDFLAGS"
 141 _SAVE_CPPFLAGS="$CPPFLAGS"
 142
 143 dnl Compiler macros
 144 DEFINES=""
 145 AC_SUBST([DEFINES])
 146 case "$host_os" in
 147 linux*|*-gnu*|gnu*)
 148     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 149     ;;
 150 solaris*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 152     ;;
 153 cygwin*)
 154     DEFINES="$DEFINES -DHAVE_PTHREAD"
 155     ;;
 156 esac
 157
 158 dnl Add flags for gcc and g++
 159 if test "x$GCC" = xyes; then
 160     case "$host_os" in
 161     cygwin*)
 162         CFLAGS="$CFLAGS -Wall -std=gnu99"
 163         ;;
 164     *)
 165         CFLAGS="$CFLAGS -Wall -std=c99"
 166         ;;
 167     esac
 168
 169     # Enable -Werror=implicit-function-declaration and
 170     # -Werror=missing-prototypes, if available, or otherwise, just
 171     # -Wmissing-prototypes.  This is particularly useful to avoid
 172     # generating a loadable driver module that has undefined symbols.
 173     save_CFLAGS="$CFLAGS"
 174     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 175     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 176     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 177     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 178                    AC_MSG_RESULT([yes]),
 179                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 180                     AC_MSG_RESULT([no])]);
 181
 182     # Enable -fvisibility=hidden if using a gcc that supports it
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 185     VISIBILITY_CFLAGS="-fvisibility=hidden"
 186     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 188                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 189
 190     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 191     CFLAGS=$save_CFLAGS
 192
 193     # Work around aliasing bugs - developers should comment this out
 194     CFLAGS="$CFLAGS -fno-strict-aliasing"
 195
 196     # gcc's builtin memcmp is slower than glibc's
 197     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 198     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 199 fi
 200 if test "x$GXX" = xyes; then
 201     CXXFLAGS="$CXXFLAGS -Wall"
 202
 203     # Enable -fvisibility=hidden if using a gcc that supports it
 204     save_CXXFLAGS="$CXXFLAGS"
 205     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 206     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 207     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 208     AC_LANG_PUSH([C++])
 209     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 210                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 211     AC_LANG_POP([C++])
 212
 213     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 214     CXXFLAGS=$save_CXXFLAGS
 215
 216     # Work around aliasing bugs - developers should comment this out
 217     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 218
 219     # gcc's builtin memcmp is slower than glibc's
 220     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 221     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 222 fi
 223
 224 dnl even if the compiler appears to support it, using visibility attributes isn't
 225 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 226 case "$host_os" in
 227 cygwin*)
 228     VISIBILITY_CFLAGS=""
 229     VISIBILITY_CXXFLAGS=""
 230     ;;
 231 esac
 232
 233 AC_SUBST([VISIBILITY_CFLAGS])
 234 AC_SUBST([VISIBILITY_CXXFLAGS])
 235
 236 dnl
 237 dnl Hacks to enable 32 or 64 bit build
 238 dnl
 239 AC_ARG_ENABLE([32-bit],
 240     [AS_HELP_STRING([--enable-32-bit],
 241         [build 32-bit libraries @<:@default=auto@:>@])],
 242     [enable_32bit="$enableval"],
 243     [enable_32bit=auto]
 244 )
 245 if test "x$enable_32bit" = xyes; then
 246     if test "x$GCC" = xyes; then
 247         CFLAGS="$CFLAGS -m32"
 248         CCASFLAGS="$CCASFLAGS -m32"
 249     fi
 250     if test "x$GXX" = xyes; then
 251         CXXFLAGS="$CXXFLAGS -m32"
 252     fi
 253 fi
 254 AC_ARG_ENABLE([64-bit],
 255     [AS_HELP_STRING([--enable-64-bit],
 256         [build 64-bit libraries @<:@default=auto@:>@])],
 257     [enable_64bit="$enableval"],
 258     [enable_64bit=auto]
 259 )
 260 if test "x$enable_64bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m64"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m64"
 266     fi
 267 fi
 268
 269 dnl Can't have static and shared libraries, default to static if user
 270 dnl explicitly requested. If both disabled, set to static since shared
 271 dnl was explicitly requested.
 272 case "x$enable_static$enable_shared" in
 273 xyesyes )
 274     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 275     enable_shared=no
 276     ;;
 277 xnono )
 278     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 279     enable_static=yes
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 284
 285 dnl
 286 dnl other compiler options
 287 dnl
 288 AC_ARG_ENABLE([debug],
 289     [AS_HELP_STRING([--enable-debug],
 290         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 291     [enable_debug="$enableval"],
 292     [enable_debug=no]
 293 )
 294 if test "x$enable_debug" = xyes; then
 295     DEFINES="$DEFINES -DDEBUG"
 296     if test "x$GCC" = xyes; then
 297         CFLAGS="$CFLAGS -g -O0"
 298     fi
 299     if test "x$GXX" = xyes; then
 300         CXXFLAGS="$CXXFLAGS -g -O0"
 301     fi
 302 fi
 303
 304 dnl
 305 dnl library names
 306 dnl
 307 LIB_PREFIX_GLOB='lib'
 308 LIB_VERSION_SEPARATOR='.'
 309 if test "$enable_static" = yes; then
 310     LIB_EXTENSION='a'
 311 else
 312     case "$host_os" in
 313     darwin* )
 314         LIB_EXTENSION='dylib' ;;
 315     cygwin* )
 316         dnl prefix can be 'cyg' or 'lib'
 317         LIB_PREFIX_GLOB='???'
 318         LIB_VERSION_SEPARATOR='-'
 319         LIB_EXTENSION='dll' ;;
 320     aix* )
 321         LIB_EXTENSION='a' ;;
 322     * )
 323         LIB_EXTENSION='so' ;;
 324     esac
 325 fi
 326 AC_ARG_WITH([gl-lib-name],
 327   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 328     [specify GL library name @<:@default=GL@:>@])],
 329   [GL_LIB=$withval],
 330   [GL_LIB=GL])
 331 AC_ARG_WITH([osmesa-lib-name],
 332   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 333     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 334   [OSMESA_LIB=$withval],
 335   [OSMESA_LIB=OSMesa])
 336 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 337 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 338
 339 dnl
 340 dnl Mangled Mesa support
 341 dnl
 342 AC_ARG_ENABLE([mangling],
 343   [AS_HELP_STRING([--enable-mangling],
 344     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 345   [enable_mangling="${enableval}"],
 346   [enable_mangling=no]
 347 )
 348 if test "x${enable_mangling}" = "xyes" ; then
 349   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 350   GL_LIB="Mangled${GL_LIB}"
 351   OSMESA_LIB="Mangled${OSMESA_LIB}"
 352 fi
 353 AC_SUBST([GL_LIB])
 354 AC_SUBST([OSMESA_LIB])
 355
 356 dnl
 357 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 358 dnl
 359 AC_ARG_ENABLE([texture-float],
 360     [AS_HELP_STRING([--enable-texture-float],
 361         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 362     [enable_texture_float="$enableval"],
 363     [enable_texture_float=no]
 364 )
 365 if test "x$enable_texture_float" = xyes; then
 366     AC_MSG_WARN([Floating-point textures enabled.])
 367     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 368     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 369 fi
 370
 371 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 372 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 373 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 374 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 375 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 376 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 377 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 378
 379 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 380 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 381 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 382 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386
 387 AC_SUBST([GL_LIB_NAME])
 388 AC_SUBST([OSMESA_LIB_NAME])
 389 AC_SUBST([EGL_LIB_NAME])
 390 AC_SUBST([GLESv1_CM_LIB_NAME])
 391 AC_SUBST([GLESv2_LIB_NAME])
 392 AC_SUBST([VG_LIB_NAME])
 393 AC_SUBST([GLAPI_LIB_NAME])
 394
 395 AC_SUBST([GL_LIB_GLOB])
 396 AC_SUBST([EGL_LIB_GLOB])
 397 AC_SUBST([GLESv1_CM_LIB_GLOB])
 398 AC_SUBST([GLESv2_LIB_GLOB])
 399 AC_SUBST([VG_LIB_GLOB])
 400 AC_SUBST([GLAPI_LIB_GLOB])
 401
 402 dnl
 403 dnl Arch/platform-specific settings
 404 dnl
 405 AC_ARG_ENABLE([asm],
 406     [AS_HELP_STRING([--disable-asm],
 407         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 408     [enable_asm="$enableval"],
 409     [enable_asm=yes]
 410 )
 411 asm_arch=""
 412 AC_MSG_CHECKING([whether to enable assembly])
 413 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 414 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 415 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 416     case "$host_cpu" in
 417     i?86 | x86_64 | amd64)
 418         enable_asm=no
 419         AC_MSG_RESULT([no, cross compiling])
 420         ;;
 421     esac
 422 fi
 423 # check for supported arches
 424 if test "x$enable_asm" = xyes; then
 425     case "$host_cpu" in
 426     i?86)
 427         case "$host_os" in
 428         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 429             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 430             ;;
 431         gnu*)
 432             asm_arch=x86
 433             ;;
 434         esac
 435         ;;
 436     x86_64|amd64)
 437         case "$host_os" in
 438         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 439             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 440             ;;
 441         esac
 442         ;;
 443     sparc*)
 444         case "$host_os" in
 445         linux*)
 446             asm_arch=sparc
 447             ;;
 448         esac
 449         ;;
 450     esac
 451
 452     case "$asm_arch" in
 453     x86)
 454         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 455         AC_MSG_RESULT([yes, x86])
 456         ;;
 457     x86_64|amd64)
 458         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 459         AC_MSG_RESULT([yes, x86_64])
 460         ;;
 461     sparc)
 462         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 463         AC_MSG_RESULT([yes, sparc])
 464         ;;
 465     *)
 466         AC_MSG_RESULT([no, platform not supported])
 467         ;;
 468     esac
 469 fi
 470
 471 dnl Check to see if dlopen is in default libraries (like Solaris, which
 472 dnl has it in libc), or if libdl is needed to get it.
 473 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 474     [AC_CHECK_LIB([dl], [dlopen],
 475        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 476 AC_SUBST([DLOPEN_LIBS])
 477
 478 case "$host_os" in
 479 darwin*|mingw*)
 480     ;;
 481 *)
 482     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 483                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 484                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 485     AC_SUBST([CLOCK_LIB])
 486     ;;
 487 esac
 488
 489 dnl See if posix_memalign is available
 490 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 491
 492 dnl Check for pthreads
 493 AX_PTHREAD
 494 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 495 dnl to -pthread, which causes problems if we need -lpthread to appear in
 496 dnl pkgconfig files.
 497 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 498
 499 dnl SELinux awareness.
 500 AC_ARG_ENABLE([selinux],
 501     [AS_HELP_STRING([--enable-selinux],
 502         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 503     [MESA_SELINUX="$enableval"],
 504     [MESA_SELINUX=no])
 505 if test "x$enable_selinux" = "xyes"; then
 506     AC_CHECK_HEADER([selinux/selinux.h],[],
 507                     [AC_MSG_ERROR([SELinux headers not found])])
 508     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 509                  [AC_MSG_ERROR([SELinux library not found])])
 510     SELINUX_LIBS="-lselinux"
 511     DEFINES="$DEFINES -DMESA_SELINUX"
 512 fi
 513 AC_SUBST([SELINUX_LIBS])
 514
 515 dnl Options for APIs
 516 AC_ARG_ENABLE([opengl],
 517     [AS_HELP_STRING([--disable-opengl],
 518         [disable support for standard OpenGL API @<:@default=no@:>@])],
 519     [enable_opengl="$enableval"],
 520     [enable_opengl=yes])
 521 AC_ARG_ENABLE([gles1],
 522     [AS_HELP_STRING([--enable-gles1],
 523         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 524     [enable_gles1="$enableval"],
 525     [enable_gles1=no])
 526 AC_ARG_ENABLE([gles2],
 527     [AS_HELP_STRING([--enable-gles2],
 528         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 529     [enable_gles2="$enableval"],
 530     [enable_gles2=no])
 531 AC_ARG_ENABLE([openvg],
 532     [AS_HELP_STRING([--enable-openvg],
 533         [enable support for OpenVG API @<:@default=no@:>@])],
 534     [enable_openvg="$enableval"],
 535     [enable_openvg=no])
 536
 537 AC_ARG_ENABLE([dri],
 538     [AS_HELP_STRING([--enable-dri],
 539         [enable DRI modules @<:@default=enabled@:>@])],
 540     [enable_dri="$enableval"],
 541     [enable_dri=yes])
 542 AC_ARG_ENABLE([glx],
 543     [AS_HELP_STRING([--enable-glx],
 544         [enable GLX library @<:@default=enabled@:>@])],
 545     [enable_glx="$enableval"],
 546     [enable_glx=yes])
 547 AC_ARG_ENABLE([osmesa],
 548     [AS_HELP_STRING([--enable-osmesa],
 549         [enable OSMesa library @<:@default=disabled@:>@])],
 550     [enable_osmesa="$enableval"],
 551     [enable_osmesa=no])
 552 AC_ARG_ENABLE([gallium-osmesa],
 553     [AS_HELP_STRING([--enable-gallium-osmesa],
 554         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 555     [enable_gallium_osmesa="$enableval"],
 556     [enable_gallium_osmesa=no])
 557 AC_ARG_ENABLE([egl],
 558     [AS_HELP_STRING([--disable-egl],
 559         [disable EGL library @<:@default=enabled@:>@])],
 560     [enable_egl="$enableval"],
 561     [enable_egl=yes])
 562
 563 AC_ARG_ENABLE([xorg],
 564     [AS_HELP_STRING([--enable-xorg],
 565         [enable support for X.Org DDX API @<:@default=no@:>@])],
 566     [enable_xorg="$enableval"],
 567     [enable_xorg=no])
 568 AC_ARG_ENABLE([xa],
 569     [AS_HELP_STRING([--enable-xa],
 570         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 571     [enable_xa="$enableval"],
 572     [enable_xa=no])
 573 AC_ARG_ENABLE([gbm],
 574    [AS_HELP_STRING([--enable-gbm],
 575          [enable gbm library @<:@default=auto@:>@])],
 576    [enable_gbm="$enableval"],
 577    [enable_gbm=auto])
 578
 579 AC_ARG_ENABLE([xvmc],
 580    [AS_HELP_STRING([--enable-xvmc],
 581          [enable xvmc library @<:@default=auto@:>@])],
 582    [enable_xvmc="$enableval"],
 583    [enable_xvmc=auto])
 584 AC_ARG_ENABLE([vdpau],
 585    [AS_HELP_STRING([--enable-vdpau],
 586          [enable vdpau library @<:@default=auto@:>@])],
 587    [enable_vdpau="$enableval"],
 588    [enable_vdpau=auto])
 589 AC_ARG_ENABLE([opencl],
 590    [AS_HELP_STRING([--enable-opencl],
 591          [enable OpenCL library NOTE: Enabling this option will also enable
 592           --with-llvm-shared-libs
 593           @<:@default=no@:>@])],
 594    [],
 595    [enable_opencl=no])
 596 AC_ARG_ENABLE([xlib-glx],
 597     [AS_HELP_STRING([--enable-xlib-glx],
 598         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 599     [enable_xlib_glx="$enableval"],
 600     [enable_xlib_glx=no])
 601 AC_ARG_ENABLE([gallium-egl],
 602     [AS_HELP_STRING([--enable-gallium-egl],
 603         [enable optional EGL state tracker (not required
 604          for EGL support in Gallium with OpenGL and OpenGL ES)
 605          @<:@default=disable@:>@])],
 606     [enable_gallium_egl="$enableval"],
 607     [enable_gallium_egl=no])
 608 AC_ARG_ENABLE([gallium-gbm],
 609     [AS_HELP_STRING([--enable-gallium-gbm],
 610         [enable optional gbm state tracker (not required for
 611          gbm support in Gallium)
 612          @<:@default=auto@:>@])],
 613     [enable_gallium_gbm="$enableval"],
 614     [enable_gallium_gbm=auto])
 615
 616 AC_ARG_ENABLE([r600-llvm-compiler],
 617     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 618         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 619     [enable_r600_llvm="$enableval"],
 620     [enable_r600_llvm=no])
 621
 622 AC_ARG_ENABLE([gallium-tests],
 623     [AS_HELP_STRING([--enable-gallium-tests],
 624         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 625     [enable_gallium_tests="$enableval"],
 626     [enable_gallium_tests=no])
 627
 628 # Option for Gallium drivers
 629
 630 # Keep this in sync with the --with-gallium-drivers help string default value
 631 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 632
 633 AC_ARG_WITH([gallium-drivers],
 634     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 635         [comma delimited Gallium drivers list, e.g.
 636         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 637         @<:@default=r300,r600,svga,swrast@:>@])],
 638     [with_gallium_drivers="$withval"],
 639     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 640
 641 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 642 # here so that the script doesn't choke on an unknown driver name later.
 643 case "$with_gallium_drivers" in
 644     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 645     no) with_gallium_drivers='' ;;
 646 esac
 647
 648 if test "x$enable_opengl" = xno -a \
 649         "x$enable_gles1" = xno -a \
 650         "x$enable_gles2" = xno -a \
 651         "x$enable_openvg" = xno -a \
 652         "x$enable_xorg" = xno -a \
 653         "x$enable_xa" = xno -a \
 654         "x$enable_xvmc" = xno -a \
 655         "x$enable_vdpau" = xno -a \
 656         "x$enable_opencl" = xno; then
 657     AC_MSG_ERROR([at least one API should be enabled])
 658 fi
 659
 660 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 661 if test "x$enable_opengl" = xno -a \
 662         "x$enable_gles1" = xyes; then
 663     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 664 fi
 665
 666 if test "x$enable_opengl" = xno -a \
 667         "x$enable_gles2" = xyes; then
 668     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 669 fi
 670
 671 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 672 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 673 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 674 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 675                                         "x$enable_gles1" = xyes -o \
 676                                         "x$enable_gles2" = xyes)
 677
 678 if test "x$enable_glx" = xno; then
 679     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 680     enable_xlib_glx=no
 681 fi
 682
 683 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 684     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 685 fi
 686
 687 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 688     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 689 fi
 690
 691 # Disable GLX if OpenGL is not enabled
 692 if test "x$enable_glx$enable_opengl" = xyesno; then
 693     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 694     enable_glx=no
 695 fi
 696
 697 # Disable GLX if DRI and Xlib-GLX are not enabled
 698 if test "x$enable_glx" = xyes -a \
 699         "x$enable_dri" = xno -a \
 700         "x$enable_xlib_glx" = xno; then
 701     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 702     enable_glx=no
 703 fi
 704
 705 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 706                                   "x$enable_dri" = xyes)
 707 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 708 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 709                                   "x$enable_osmesa" = xyes)
 710
 711 AC_ARG_ENABLE([shared-glapi],
 712     [AS_HELP_STRING([--enable-shared-glapi],
 713         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 714     [enable_shared_glapi="$enableval"],
 715     [enable_shared_glapi="$enable_dri"])
 716
 717 # Shared GLAPI is only useful for DRI
 718 if test "x$enable_dri" = xno; then
 719     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 720     enable_shared_glapi=no
 721 fi
 722
 723 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 724
 725 dnl
 726 dnl Driver specific build directories
 727 dnl
 728 GALLIUM_TARGET_DIRS=""
 729 GALLIUM_WINSYS_DIRS="sw"
 730 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 731 GALLIUM_STATE_TRACKERS_DIRS=""
 732
 733 case "x$enable_glx$enable_xlib_glx" in
 734 xyesyes)
 735     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 736     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 737     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 738     NEED_WINSYS_XLIB="yes"
 739     ;;
 740 esac
 741
 742 if test "x$enable_dri" = xyes; then
 743     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 744     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 745 fi
 746
 747 if test "x$enable_gallium_osmesa" = xyes; then
 748     if test -z "$with_gallium_drivers"; then
 749         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 750     fi
 751     if test "x$enable_osmesa" = xyes; then
 752         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 753     fi
 754     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 755     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 756 fi
 757
 758 AC_SUBST([MESA_LLVM])
 759
 760 # Check for libdrm
 761 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 762                   [have_libdrm=yes], [have_libdrm=no])
 763
 764 if test "x$enable_dri" = xyes; then
 765     # DRI must be shared, I think
 766     if test "$enable_static" = yes; then
 767         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 768     fi
 769
 770     # not a hard requirement as swrast does not depend on it
 771     if test "x$have_libdrm" = xyes; then
 772         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 773     fi
 774 fi
 775
 776 dnl Direct rendering or just indirect rendering
 777 case "$host_os" in
 778 gnu*)
 779     dnl Disable by default on GNU/Hurd
 780     driglx_direct_default="no"
 781     ;;
 782 cygwin*)
 783     dnl Disable by default on cygwin
 784     driglx_direct_default="no"
 785     ;;
 786 *)
 787     driglx_direct_default="yes"
 788     ;;
 789 esac
 790 AC_ARG_ENABLE([driglx-direct],
 791     [AS_HELP_STRING([--disable-driglx-direct],
 792         [disable direct rendering in GLX and EGL for DRI \
 793             @<:@default=auto@:>@])],
 794     [driglx_direct="$enableval"],
 795     [driglx_direct="$driglx_direct_default"])
 796
 797 dnl
 798 dnl libGL configuration per driver
 799 dnl
 800 case "x$enable_glx$enable_xlib_glx" in
 801 xyesyes)
 802     # Xlib-based GLX
 803     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 804     GL_PC_REQ_PRIV="x11 xext"
 805     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 806     GL_LIB_DEPS="$XLIBGL_LIBS"
 807     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 808     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 809     ;;
 810 xyesno)
 811     # DRI-based GLX
 812     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 813     if test x"$driglx_direct" = xyes; then
 814         if test "x$have_libdrm" != xyes; then
 815             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 816         fi
 817         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 818         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 819     fi
 820
 821     # find the DRI deps for libGL
 822     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 823
 824     # add xf86vidmode if available
 825     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 826     if test "$HAVE_XF86VIDMODE" = yes ; then
 827         dri_modules="$dri_modules xxf86vm"
 828     fi
 829
 830     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 831     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 832     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 833     GL_LIB_DEPS="$DRIGL_LIBS"
 834
 835     # need DRM libs, $PTHREAD_LIBS, etc.
 836     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 837     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 838     ;;
 839 esac
 840
 841 # This is outside the case (above) so that it is invoked even for non-GLX
 842 # builds.
 843 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 844
 845 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 846 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 847 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 848 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 849
 850 AC_SUBST([X11_INCLUDES])
 851 AC_SUBST([GL_LIB_DEPS])
 852 AC_SUBST([GL_PC_REQ_PRIV])
 853 AC_SUBST([GL_PC_LIB_PRIV])
 854 AC_SUBST([GL_PC_CFLAGS])
 855 AC_SUBST([DRI_PC_REQ_PRIV])
 856 AC_SUBST([GLESv1_CM_LIB_DEPS])
 857 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 858 AC_SUBST([GLESv2_LIB_DEPS])
 859 AC_SUBST([GLESv2_PC_LIB_PRIV])
 860
 861 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 862
 863 AC_SUBST([HAVE_XF86VIDMODE])
 864
 865 dnl
 866 dnl More GLX setup
 867 dnl
 868 case "x$enable_glx$enable_xlib_glx" in
 869 xyesyes)
 870     DEFINES="$DEFINES -DUSE_XSHM"
 871     ;;
 872 xyesno)
 873     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 874     if test "x$driglx_direct" = xyes; then
 875         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 876     fi
 877     ;;
 878 esac
 879
 880 dnl
 881 dnl TLS detection
 882 dnl
 883
 884 AC_ARG_ENABLE([glx-tls],
 885     [AS_HELP_STRING([--enable-glx-tls],
 886         [enable TLS support in GLX @<:@default=disabled@:>@])],
 887     [GLX_USE_TLS="$enableval"],
 888     [GLX_USE_TLS=no])
 889 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 890
 891 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 892       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 893
 894 dnl
 895 dnl More DRI setup
 896 dnl
 897 dnl Directory for DRI drivers
 898 AC_ARG_WITH([dri-driverdir],
 899     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 900         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 901     [DRI_DRIVER_INSTALL_DIR="$withval"],
 902     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 903 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 904 dnl Extra search path for DRI drivers
 905 AC_ARG_WITH([dri-searchpath],
 906     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 907         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 908     [DRI_DRIVER_SEARCH_DIR="$withval"],
 909     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 910 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 911 dnl Which drivers to build - default is chosen by platform
 912 AC_ARG_WITH([dri-drivers],
 913     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 914         [comma delimited DRI drivers list, e.g.
 915         "swrast,i965,radeon" @<:@default=auto@:>@])],
 916     [with_dri_drivers="$withval"],
 917     [with_dri_drivers=yes])
 918 if test "x$with_dri_drivers" = x; then
 919     with_dri_drivers=no
 920 fi
 921
 922 dnl If $with_dri_drivers is yes, directories will be added through
 923 dnl platform checks
 924 DRI_DIRS=""
 925 case "$with_dri_drivers" in
 926 no) ;;
 927 yes)
 928     # classic DRI drivers
 929     if test "x$enable_opengl" = xyes; then
 930         DRI_DIRS="yes"
 931     fi
 932     ;;
 933 *)
 934     # verify the requested driver directories exist
 935     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 936     for driver in $dri_drivers; do
 937         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 938             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 939     done
 940     DRI_DIRS="$dri_drivers"
 941     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 942         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 943     fi
 944     ;;
 945 esac
 946
 947 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 948 if test "x$enable_dri" = xyes; then
 949     # Platform specific settings and drivers to build
 950     case "$host_os" in
 951     linux*)
 952         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 953         DEFINES="$DEFINES -DHAVE_ALIAS"
 954
 955         case "$host_cpu" in
 956         x86_64|amd64)
 957             if test "x$DRI_DIRS" = "xyes"; then
 958                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 959             fi
 960             ;;
 961         powerpc*)
 962             # Build only the drivers for cards that exist on PowerPC.
 963             if test "x$DRI_DIRS" = "xyes"; then
 964                 DRI_DIRS="r200 radeon swrast"
 965             fi
 966             ;;
 967         sparc*)
 968             # Build only the drivers for cards that exist on sparc
 969             if test "x$DRI_DIRS" = "xyes"; then
 970                 DRI_DIRS="r200 radeon swrast"
 971             fi
 972             ;;
 973         esac
 974         ;;
 975     freebsd* | dragonfly* | *netbsd* | openbsd*)
 976         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 977         DEFINES="$DEFINES -DHAVE_ALIAS"
 978
 979         if test "x$DRI_DIRS" = "xyes"; then
 980             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 981         fi
 982         ;;
 983     gnu*)
 984         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 985         DEFINES="$DEFINES -DHAVE_ALIAS"
 986         ;;
 987     solaris*)
 988         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 989         ;;
 990     cygwin*)
 991         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 992         if test "x$DRI_DIRS" = "xyes"; then
 993             DRI_DIRS="swrast"
 994         fi
 995         ;;
 996     esac
 997
 998     # default drivers
 999     if test "x$DRI_DIRS" = "xyes"; then
1000         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1001     fi
1002
1003     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1004
1005     # Check for expat
1006     EXPAT_INCLUDES=""
1007     EXPAT_LIB=-lexpat
1008     AC_ARG_WITH([expat],
1009         [AS_HELP_STRING([--with-expat=DIR],
1010             [expat install directory])],[
1011         EXPAT_INCLUDES="-I$withval/include"
1012         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1013         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1014         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1015         ])
1016     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1017     save_LIBS="$LIBS"
1018     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1019         [AC_MSG_ERROR([Expat required for DRI.])])
1020     LIBS="$save_LIBS"
1021
1022     # If we are building any DRI driver other than swrast.
1023     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1024         # ... libdrm is required
1025         if test "x$have_libdrm" != xyes; then
1026             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1027         fi
1028         # ... and build dricommon
1029         HAVE_COMMON_DRI=yes
1030     fi
1031
1032     # put all the necessary libs together
1033     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1034     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1035 fi
1036 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1037 AC_SUBST([EXPAT_INCLUDES])
1038 AC_SUBST([DRI_LIB_DEPS])
1039 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1040
1041 case $DRI_DIRS in
1042 *i915*|*i965*)
1043     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1044
1045     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1046         case $d in
1047         i915)
1048             HAVE_I915_DRI=yes;
1049             ;;
1050         i965)
1051             HAVE_I965_DRI=yes;
1052             ;;
1053         esac
1054     done
1055
1056     ;;
1057 esac
1058
1059 case $DRI_DIRS in
1060 *nouveau*)
1061     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1062     HAVE_NOUVEAU_DRI=yes;
1063     ;;
1064 esac
1065
1066 case $DRI_DIRS in
1067 *radeon*|*r200*)
1068     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1069
1070     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1071         case $d in
1072         radeon)
1073             HAVE_RADEON_DRI=yes;
1074             ;;
1075         r200)
1076             HAVE_R200_DRI=yes;
1077             ;;
1078         esac
1079     done
1080
1081     ;;
1082 esac
1083
1084 case $DRI_DIRS in
1085 *swrast*)
1086     HAVE_SWRAST_DRI=yes;
1087     ;;
1088 esac
1089
1090 dnl
1091 dnl OSMesa configuration
1092 dnl
1093
1094 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1095 AC_ARG_WITH([osmesa-bits],
1096     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1097         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1098     [osmesa_bits="$withval"],
1099     [osmesa_bits=8])
1100 if test "x$osmesa_bits" != x8; then
1101     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1102         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1103         osmesa_bits=8
1104     fi
1105 fi
1106 case "x$osmesa_bits" in
1107 x8)
1108     OSMESA_LIB="${OSMESA_LIB}"
1109     ;;
1110 x16|x32)
1111     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1112     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1113     ;;
1114 *)
1115     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1116     ;;
1117 esac
1118
1119 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1120     # only link libraries with osmesa if shared
1121     if test "$enable_static" = no; then
1122         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1123     else
1124         OSMESA_LIB_DEPS=""
1125     fi
1126     OSMESA_MESA_DEPS=""
1127     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1128 fi
1129
1130 AC_SUBST([OSMESA_LIB_DEPS])
1131 AC_SUBST([OSMESA_MESA_DEPS])
1132 AC_SUBST([OSMESA_PC_REQ])
1133 AC_SUBST([OSMESA_PC_LIB_PRIV])
1134
1135 dnl
1136 dnl gbm configuration
1137 dnl
1138 if test "x$enable_gbm" = xauto; then
1139     case "$with_egl_platforms" in
1140         *drm*)
1141             enable_gbm=yes ;;
1142          *)
1143             enable_gbm=no ;;
1144     esac
1145 fi
1146 if test "x$enable_gbm" = xyes; then
1147     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1148                       AC_MSG_ERROR([gbm needs udev]))
1149
1150     if test "x$enable_dri" = xyes; then
1151         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1152         if test "x$enable_shared_glapi" = xno; then
1153             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1154         fi
1155     fi
1156 fi
1157 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1158 GBM_PC_REQ_PRIV="libudev"
1159 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1160 AC_SUBST([GBM_PC_REQ_PRIV])
1161 AC_SUBST([GBM_PC_LIB_PRIV])
1162
1163 dnl
1164 dnl EGL configuration
1165 dnl
1166 EGL_CLIENT_APIS=""
1167
1168 if test "x$enable_egl" = xyes; then
1169     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1170
1171     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1172
1173     if test "$enable_static" != yes; then
1174         # build egl_glx when libGL is built
1175         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1176                           [have_libudev=yes],[have_libudev=no])
1177         if test "$have_libudev" = yes; then
1178             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1179         fi
1180
1181         if test "x$enable_dri" = xyes; then
1182             HAVE_EGL_DRIVER_DRI2=1
1183         fi
1184
1185     fi
1186 fi
1187 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1188 AC_SUBST([EGL_LIB_DEPS])
1189
1190 dnl
1191 dnl EGL Gallium configuration
1192 dnl
1193 if test "x$enable_gallium_egl" = xyes; then
1194     if test "x$with_gallium_drivers" = x; then
1195         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1196     fi
1197     if test "x$enable_egl" = xno; then
1198         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1199     fi
1200     if test "x$have_libdrm" != xyes; then
1201         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1202     fi
1203
1204     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1205     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1206 fi
1207 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1208
1209 dnl
1210 dnl gbm Gallium configuration
1211 dnl
1212 if test "x$enable_gallium_gbm" = xauto; then
1213     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1214         yesyesyes*drm*)
1215             enable_gallium_gbm=yes ;;
1216          *)
1217             enable_gallium_gbm=no ;;
1218     esac
1219 fi
1220 if test "x$enable_gallium_gbm" = xyes; then
1221     if test "x$with_gallium_drivers" = x; then
1222         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1223     fi
1224     if test "x$enable_gbm" = xno; then
1225         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1226     fi
1227     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1228     if test "x$enable_dri" = xno; then
1229         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1230     fi
1231
1232     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1233     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1234     enable_gallium_loader=yes
1235 fi
1236 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1237
1238 dnl
1239 dnl X.Org DDX configuration
1240 dnl
1241 if test "x$enable_xorg" = xyes; then
1242     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1243     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1244     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1245     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1246         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1247         HAVE_XEXTPROTO_71="no")
1248     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1249 fi
1250 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1251
1252 dnl
1253 dnl XA configuration
1254 dnl
1255 if test "x$enable_xa" = xyes; then
1256 AC_PROG_AWK
1257 AC_PROG_GREP
1258 AC_CHECK_PROG(NM, nm, "nm")
1259 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1260 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1261 enable_xa=no
1262 fi
1263 fi
1264 if test "x$enable_xa" = xyes; then
1265     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1266     AC_SUBST(AWK)
1267     AC_SUBST(GREP)
1268     AC_SUBST(NM)
1269 fi
1270 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1271
1272 dnl
1273 dnl OpenVG configuration
1274 dnl
1275 VG_LIB_DEPS=""
1276
1277 if test "x$enable_openvg" = xyes; then
1278     if test "x$enable_egl" = xno; then
1279         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1280     fi
1281     if test "x$with_gallium_drivers" = x; then
1282         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1283     fi
1284     if test "x$enable_gallium_egl" = xno; then
1285         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1286     fi
1287
1288     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1289     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1290     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1291     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1292     AC_SUBST([VG_PC_LIB_PRIV])
1293 fi
1294 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1295
1296 dnl
1297 dnl Gallium G3DVL configuration
1298 dnl
1299 if test -n "$with_gallium_drivers"; then
1300     if test "x$enable_xvmc" = xauto; then
1301         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1302     fi
1303
1304     if test "x$enable_vdpau" = xauto; then
1305         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1306     fi
1307 fi
1308
1309 if test "x$enable_xvmc" = xyes; then
1310     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1311     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1312 fi
1313 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1314
1315 if test "x$enable_vdpau" = xyes; then
1316     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1317     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1318 fi
1319 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1320
1321 dnl
1322 dnl OpenCL configuration
1323 dnl
1324
1325 AC_ARG_WITH([libclc-path],
1326    [AS_HELP_STRING([--with-libclc-path],
1327          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1328    [LIBCLC_PATH="$withval"],
1329    [LIBCLC_PATH=""])
1330
1331 if test "x$LIBCLC_PATH" != x; then
1332    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1333                   Please review the updated build instructions for clover:
1334                   http://dri.freedesktop.org/wiki/GalliumCompute])
1335 fi
1336
1337
1338 AC_ARG_WITH([clang-libdir],
1339    [AS_HELP_STRING([--with-clang-libdir],
1340          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1341    [CLANG_LIBDIR="$withval"],
1342    [CLANG_LIBDIR=""])
1343
1344 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1345 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1346 AC_SUBST([LIBCLC_INCLUDEDIR])
1347 AC_SUBST([LIBCLC_LIBEXECDIR])
1348
1349 if test "x$enable_opencl" = xyes; then
1350     if test "x$with_gallium_drivers" = x; then
1351         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1352     fi
1353
1354     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1355         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1356     fi
1357
1358     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1359         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1360     fi
1361
1362     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1363     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1364     enable_gallium_loader=yes
1365 fi
1366 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1367
1368 dnl
1369 dnl Gallium configuration
1370 dnl
1371 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1372
1373 AC_SUBST([LLVM_BINDIR])
1374 AC_SUBST([LLVM_CFLAGS])
1375 AC_SUBST([LLVM_CPPFLAGS])
1376 AC_SUBST([LLVM_CXXFLAGS])
1377 AC_SUBST([LLVM_LIBDIR])
1378 AC_SUBST([LLVM_LIBS])
1379 AC_SUBST([LLVM_LDFLAGS])
1380 AC_SUBST([LLVM_INCLUDEDIR])
1381 AC_SUBST([LLVM_VERSION])
1382 AC_SUBST([CLANG_RESOURCE_DIR])
1383
1384 case "x$enable_opengl$enable_gles1$enable_gles2" in
1385 x*yes*)
1386     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1387     ;;
1388 esac
1389
1390 AC_SUBST([VG_LIB_DEPS])
1391 AC_SUBST([EGL_CLIENT_APIS])
1392
1393 dnl
1394 dnl EGL Platforms configuration
1395 dnl
1396 AC_ARG_WITH([egl-platforms],
1397     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1398         [comma delimited native platforms libEGL supports, e.g.
1399         "x11,drm" @<:@default=auto@:>@])],
1400     [with_egl_platforms="$withval"],
1401     [if test "x$enable_egl" = xyes; then
1402         with_egl_platforms="x11"
1403     else
1404         with_egl_platforms=""
1405     fi])
1406
1407 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1408     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1409 fi
1410
1411 # Do per-EGL platform setups and checks
1412 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1413 for plat in $egl_platforms; do
1414         case "$plat" in
1415         wayland)
1416                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1417                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1418
1419                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1420                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1421                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1422                 ;;
1423
1424         x11)
1425                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1426
1427                 if test "x$enable_glx" = xyes; then
1428                         HAVE_EGL_DRIVER_GLX=1
1429                 fi
1430                 ;;
1431
1432         drm)
1433                 test "x$enable_gbm" = "xno" &&
1434                         AC_MSG_ERROR([EGL platform drm needs gbm])
1435                 ;;
1436
1437         android|fbdev|gdi|null)
1438                 ;;
1439
1440         *)
1441                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1442                 ;;
1443         esac
1444
1445         case "$plat$have_libudev" in
1446                 waylandno|drmno)
1447                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1448         esac
1449 done
1450
1451 # libEGL wants to default to the first platform specified in
1452 # ./configure.  parse that here.
1453 if test "x$egl_platforms" != "x"; then
1454     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1455     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1456 else
1457     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1458 fi
1459
1460 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1461     NEED_WINSYS_XLIB=yes
1462 fi
1463 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1464 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1465 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1466 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1467 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1468
1469 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1470 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1471
1472 AC_SUBST([EGL_NATIVE_PLATFORM])
1473 AC_SUBST([EGL_CFLAGS])
1474
1475 # If we don't have the X11 platform, set this define so we don't try to include
1476 # the X11 headers.
1477 if ! echo "$egl_platforms" | grep -q 'x11'; then
1478     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1479     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1480 fi
1481
1482 AC_ARG_WITH([egl-driver-dir],
1483     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1484                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1485     [EGL_DRIVER_INSTALL_DIR="$withval"],
1486     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1487 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1488
1489 AC_ARG_WITH([xorg-driver-dir],
1490     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1491                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1492     [XORG_DRIVER_INSTALL_DIR="$withval"],
1493     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1494 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1495
1496 AC_ARG_WITH([max-width],
1497     [AS_HELP_STRING([--with-max-width=N],
1498                     [Maximum framebuffer width (4096)])],
1499     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1500      AS_IF([test "${withval}" -gt "4096"],
1501            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1502 )
1503 AC_ARG_WITH([max-height],
1504     [AS_HELP_STRING([--with-max-height=N],
1505                     [Maximum framebuffer height (4096)])],
1506     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1507      AS_IF([test "${withval}" -gt "4096"],
1508            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1509 )
1510
1511 dnl
1512 dnl Gallium LLVM
1513 dnl
1514 AC_ARG_ENABLE([gallium-llvm],
1515     [AS_HELP_STRING([--enable-gallium-llvm],
1516         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1517     [enable_gallium_llvm="$enableval"],
1518     [enable_gallium_llvm=auto])
1519
1520 AC_ARG_WITH([llvm-shared-libs],
1521     [AS_HELP_STRING([--with-llvm-shared-libs],
1522         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1523     [],
1524     [with_llvm_shared_libs=no])
1525 AS_IF([test x$enable_opencl = xyes],
1526     [
1527         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1528         with_llvm_shared_libs=yes
1529     ])
1530
1531 AC_ARG_WITH([llvm-prefix],
1532     [AS_HELP_STRING([--with-llvm-prefix],
1533         [Prefix for LLVM installations in non-standard locations])],
1534     [llvm_prefix="$withval"],
1535     [llvm_prefix=""])
1536
1537
1538 # Call this inside ` ` to get the return value.
1539 # $1 is the llvm-config command with arguments.
1540 strip_unwanted_llvm_flags() {
1541     # Use \> (marks the end of the word)
1542     echo `$1` | sed \
1543         -e 's/-DNDEBUG\>//g' \
1544         -e 's/-pedantic\>//g' \
1545         -e 's/-Wcovered-switch-default\>//g' \
1546         -e 's/-O.\>//g' \
1547         -e 's/-g\>//g' \
1548         -e 's/-Wall\>//g' \
1549         -e 's/-fomit-frame-pointer\>//g'
1550 }
1551
1552
1553 if test "x$with_gallium_drivers" = x; then
1554     enable_gallium_llvm=no
1555 fi
1556 if test "x$enable_gallium_llvm" = xauto; then
1557     case "$host_cpu" in
1558     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1559     esac
1560 fi
1561 if test "x$enable_gallium_llvm" = xyes; then
1562     if test "x$llvm_prefix" != x; then
1563         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1564     else
1565         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1566     fi
1567
1568     if test "x$LLVM_CONFIG" != xno; then
1569         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1570         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1571         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1572         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1573         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1574         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1575         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1576         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1577
1578         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1579             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1580         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1581             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1582
1583         if test "x${LLVM_VERSION_MAJOR}" != x; then
1584             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1585         else
1586             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1587         fi
1588
1589         LLVM_COMPONENTS="engine bitwriter"
1590         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1591             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1592         fi
1593
1594         if test "x$enable_opencl" = xyes; then
1595             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1596             # LLVM 3.3 >= 177971 requires IRReader
1597             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1598                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1599             fi
1600             # LLVM 3.4 requires Option
1601             if $LLVM_CONFIG --components | grep -qw 'option'; then
1602                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1603             fi
1604         fi
1605         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1606         MESA_LLVM=1
1607
1608         dnl Check for Clang internal headers
1609         if test "x$enable_opencl" = xyes; then
1610             if test "x$CLANG_LIBDIR" = x; then
1611                 CLANG_LIBDIR=${LLVM_LIBDIR}
1612             fi
1613             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1614             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1615                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1616         fi
1617     else
1618         MESA_LLVM=0
1619         LLVM_VERSION_INT=0
1620     fi
1621 else
1622     MESA_LLVM=0
1623     LLVM_VERSION_INT=0
1624 fi
1625
1626 dnl Directory for XVMC libs
1627 AC_ARG_WITH([xvmc-libdir],
1628     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1629         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1630     [XVMC_LIB_INSTALL_DIR="$withval"],
1631     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1632 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1633
1634 dnl
1635 dnl Gallium Tests
1636 dnl
1637 if test "x$enable_gallium_tests" = xyes; then
1638     enable_gallium_loader=yes
1639 fi
1640 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1641
1642 if test "x$enable_gallium_loader" = xyes; then
1643     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1644 fi
1645 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1646
1647 dnl Directory for VDPAU libs
1648 AC_ARG_WITH([vdpau-libdir],
1649     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1650         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1651     [VDPAU_LIB_INSTALL_DIR="$withval"],
1652     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1653 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1654
1655 dnl Directory for OpenCL libs
1656 AC_ARG_WITH([opencl-libdir],
1657     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1658         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1659     [OPENCL_LIB_INSTALL_DIR="$withval"],
1660     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1661 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1662
1663 dnl
1664 dnl Gallium helper functions
1665 dnl
1666 gallium_check_st() {
1667     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1668          if test "x$have_libdrm" != xyes; then
1669             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1670          fi
1671          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1672     fi
1673     if test "x$enable_dri" = xyes && test "x$2" != x; then
1674          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1675          HAVE_COMMON_DRI=yes
1676     fi
1677     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1678          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1679     fi
1680     if test "x$enable_xa" = xyes && test "x$4" != x; then
1681          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1682     fi
1683     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1684          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1685     fi
1686     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1687          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1688     fi
1689 }
1690
1691 gallium_require_llvm() {
1692     if test "x$MESA_LLVM" = x0; then
1693         case "$host_cpu" in
1694         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1695         esac
1696     fi
1697 }
1698
1699 gallium_require_drm_loader() {
1700     if test "x$enable_gallium_loader" = xyes; then
1701         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1702                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1703         if test "x$have_libdrm" != xyes; then
1704             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1705         fi
1706         enable_gallium_drm_loader=yes
1707     fi
1708 }
1709
1710 radeon_llvm_check() {
1711     LLVM_REQUIRED_VERSION_MAJOR="3"
1712     LLVM_REQUIRED_VERSION_MINOR="3"
1713     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1714         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1715     fi
1716     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1717         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1718                       sources with the --enable-experimental-targets=R600
1719                       configure flag])
1720     fi
1721     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1722     NEED_RADEON_LLVM=yes
1723     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1724                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1725 }
1726
1727 dnl Gallium drivers
1728 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1729         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1730         "x$enable_vdpau" = xyes; then
1731     NEED_NONNULL_WINSYS=yes
1732 fi
1733 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1734
1735 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1736 if test "x$with_gallium_drivers" != x; then
1737     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1738     for driver in $gallium_drivers; do
1739         case "x$driver" in
1740         xsvga)
1741             HAVE_GALLIUM_SVGA=yes
1742             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1743             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1744             ;;
1745         xi915)
1746             HAVE_GALLIUM_I915=yes
1747             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1748             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1749             if test "x$MESA_LLVM" = x1; then
1750                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1751             fi
1752             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1753             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1754             ;;
1755         xilo)
1756             HAVE_GALLIUM_ILO=yes
1757             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1758             gallium_require_drm_loader
1759             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1760             gallium_check_st "intel/drm" "dri-ilo"
1761             ;;
1762         xr300)
1763             HAVE_GALLIUM_R300=yes
1764             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1765             gallium_require_llvm "Gallium R300"
1766             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1767             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1768             ;;
1769         xr600)
1770             HAVE_GALLIUM_R600=yes
1771             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1772             gallium_require_drm_loader
1773             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1774             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1775                 radeon_llvm_check
1776                 R600_NEED_RADEON_GALLIUM=yes;
1777                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1778             fi
1779             if test "x$enable_r600_llvm" = xyes; then
1780                 USE_R600_LLVM_COMPILER=yes;
1781             fi
1782             if test "x$enable_opencl" = xyes; then
1783                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1784             fi
1785             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1786             ;;
1787         xradeonsi)
1788             HAVE_GALLIUM_RADEONSI=yes
1789             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1790             gallium_require_drm_loader
1791             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1792             radeon_llvm_check
1793             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1794             ;;
1795         xnouveau)
1796             HAVE_GALLIUM_NOUVEAU=yes
1797             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1798             gallium_require_drm_loader
1799             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1800             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1801             ;;
1802         xfreedreno)
1803             HAVE_GALLIUM_FREEDRENO=yes
1804             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1805             gallium_require_drm_loader
1806             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1807             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1808             ;;
1809         xswrast)
1810             HAVE_GALLIUM_SOFTPIPE=yes
1811             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1812             if test "x$MESA_LLVM" = x1; then
1813                 HAVE_GALLIUM_LLVMPIPE=yes
1814                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1815             fi
1816
1817             if test "x$enable_dri" = xyes; then
1818                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1819                 HAVE_COMMON_DRI=yes
1820             fi
1821             if test "x$enable_vdpau" = xyes; then
1822                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1823             fi
1824             if test "x$enable_xvmc" = xyes; then
1825                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1826             fi
1827             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1828                 NEED_WINSYS_XLIB=yes
1829                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1830             fi
1831             ;;
1832         *)
1833             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1834             ;;
1835         esac
1836     done
1837 fi
1838
1839 dnl Set LLVM_LIBS - This is done after the driver configuration so
1840 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1841 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1842 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1843 dnl this was causing the same libraries to be appear multiple times
1844 dnl in LLVM_LIBS.
1845
1846 if test "x$MESA_LLVM" != x0; then
1847
1848     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1849
1850     if test "x$with_llvm_shared_libs" = xyes; then
1851         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1852         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1853         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1854
1855         if test "x$llvm_have_one_so" = xyes; then
1856             dnl LLVM was built using auto*, so there is only one shared object.
1857             LLVM_LIBS="-l$LLVM_SO_NAME"
1858         else
1859             dnl If LLVM was built with CMake, there will be one shared object per
1860             dnl component.
1861             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1862                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1863         Please make sure you have built llvm with the --enable-shared option
1864         and that your llvm libraries are installed in $LLVM_LIBDIR
1865         If you have installed your llvm libraries to a different directory you
1866         can use the --with-llvm-prefix= configure flag to specify this directory.
1867         NOTE: Mesa is attempting to use llvm shared libraries because you have
1868         passed one of the following options to configure:
1869                 --with-llvm-shared-libs
1870                 --enable-opencl
1871         If you do not want to build with llvm shared libraries and instead want to
1872         use llvm static libraries then remove these options from your configure
1873         invocation and reconfigure.])])
1874
1875            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1876            dnl install uses a shared object for each compoenent and we have
1877            dnl already added all of these objects to LLVM_LIBS.
1878         fi
1879     fi
1880 fi
1881
1882 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1883 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1884 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1885 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1886 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1887 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1888 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1889 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1890 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1892
1893 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1894                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1895                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1896 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1897                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1898                                                   && test "x$MESA_LLVM" = x1)
1899
1900 if test "x$enable_gallium_loader" = xyes; then
1901     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1902
1903     if test "x$enable_gallium_drm_loader" = xyes; then
1904         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1905         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1906                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1907         if test "x$pipe_loader_have_xcb" = xyes; then
1908             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1909             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1910         fi
1911     fi
1912
1913     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1914     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1915 fi
1916
1917 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1918 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1919 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1920 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1921 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1922 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1923 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1924
1925 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1926                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1927                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1928                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1929 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1930                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1931 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1932 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1933 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
1934 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1935 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1936 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1937 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1938 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1939 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1940
1941 AC_SUBST([ELF_LIB])
1942
1943 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1944                                      "x$enable_xlib_glx" = xyes -o \
1945                                      "x$enable_osmesa" = xyes -o \
1946                                      "x$enable_gallium_osmesa" = xyes)
1947 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1948 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1949 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1950
1951 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1952 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1953 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1954
1955 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
1956
1957 AC_SUBST([VDPAU_MAJOR], 1)
1958 AC_SUBST([VDPAU_MINOR], 0)
1959
1960 AC_SUBST([XVMC_MAJOR], 1)
1961 AC_SUBST([XVMC_MINOR], 0)
1962
1963 AC_SUBST([XA_MAJOR], 2)
1964 AC_SUBST([XA_MINOR], 0)
1965 AC_SUBST([XA_TINY], 0)
1966 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1967
1968 dnl Restore LDFLAGS and CPPFLAGS
1969 LDFLAGS="$_SAVE_LDFLAGS"
1970 CPPFLAGS="$_SAVE_CPPFLAGS"
1971
1972 dnl Add user CFLAGS and CXXFLAGS
1973 CFLAGS="$CFLAGS $USER_CFLAGS"
1974 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1975
1976 dnl Substitute the config
1977 AC_CONFIG_FILES([Makefile
1978                 src/Makefile
1979                 src/egl/Makefile
1980                 src/egl/drivers/Makefile
1981                 src/egl/drivers/dri2/Makefile
1982                 src/egl/drivers/glx/Makefile
1983                 src/egl/main/Makefile
1984                 src/egl/main/egl.pc
1985                 src/egl/wayland/Makefile
1986                 src/egl/wayland/wayland-drm/Makefile
1987                 src/egl/wayland/wayland-egl/Makefile
1988                 src/egl/wayland/wayland-egl/wayland-egl.pc
1989                 src/gallium/auxiliary/Makefile
1990                 src/gallium/auxiliary/pipe-loader/Makefile
1991                 src/gallium/drivers/Makefile
1992                 src/gallium/drivers/freedreno/Makefile
1993                 src/gallium/drivers/freedreno/a2xx/Makefile
1994                 src/gallium/drivers/freedreno/a3xx/Makefile
1995                 src/gallium/drivers/i915/Makefile
1996                 src/gallium/drivers/ilo/Makefile
1997                 src/gallium/drivers/llvmpipe/Makefile
1998                 src/gallium/drivers/nouveau/Makefile
1999                 src/gallium/drivers/r300/Makefile
2000                 src/gallium/drivers/r600/Makefile
2001                 src/gallium/drivers/radeon/Makefile
2002                 src/gallium/drivers/radeonsi/Makefile
2003                 src/gallium/drivers/rbug/Makefile
2004                 src/gallium/drivers/softpipe/Makefile
2005                 src/gallium/drivers/svga/Makefile
2006                 src/gallium/drivers/trace/Makefile
2007                 src/gallium/state_trackers/Makefile
2008                 src/gallium/state_trackers/clover/Makefile
2009                 src/gallium/state_trackers/dri/Makefile
2010                 src/gallium/state_trackers/dri/drm/Makefile
2011                 src/gallium/state_trackers/dri/sw/Makefile
2012                 src/gallium/state_trackers/egl/Makefile
2013                 src/gallium/state_trackers/gbm/Makefile
2014                 src/gallium/state_trackers/glx/Makefile
2015                 src/gallium/state_trackers/osmesa/Makefile
2016                 src/gallium/state_trackers/vdpau/Makefile
2017                 src/gallium/state_trackers/vega/Makefile
2018                 src/gallium/state_trackers/xa/Makefile
2019                 src/gallium/state_trackers/xorg/Makefile
2020                 src/gallium/state_trackers/xvmc/Makefile
2021                 src/gallium/targets/Makefile
2022                 src/gallium/targets/dri-freedreno/Makefile
2023                 src/gallium/targets/dri-i915/Makefile
2024                 src/gallium/targets/dri-ilo/Makefile
2025                 src/gallium/targets/dri-nouveau/Makefile
2026                 src/gallium/targets/dri-r300/Makefile
2027                 src/gallium/targets/dri-r600/Makefile
2028                 src/gallium/targets/dri-radeonsi/Makefile
2029                 src/gallium/targets/dri-swrast/Makefile
2030                 src/gallium/targets/dri-vmwgfx/Makefile
2031                 src/gallium/targets/egl-static/Makefile
2032                 src/gallium/targets/gbm/Makefile
2033                 src/gallium/targets/opencl/Makefile
2034                 src/gallium/targets/osmesa/Makefile
2035                 src/gallium/targets/osmesa/osmesa.pc
2036                 src/gallium/targets/pipe-loader/Makefile
2037                 src/gallium/targets/libgl-xlib/Makefile
2038                 src/gallium/targets/vdpau-nouveau/Makefile
2039                 src/gallium/targets/vdpau-r300/Makefile
2040                 src/gallium/targets/vdpau-r600/Makefile
2041                 src/gallium/targets/vdpau-radeonsi/Makefile
2042                 src/gallium/targets/vdpau-softpipe/Makefile
2043                 src/gallium/targets/xa-vmwgfx/Makefile
2044                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2045                 src/gallium/targets/xorg-i915/Makefile
2046                 src/gallium/targets/xorg-nouveau/Makefile
2047                 src/gallium/targets/xorg-r600/Makefile
2048                 src/gallium/targets/xorg-radeonsi/Makefile
2049                 src/gallium/targets/xvmc-nouveau/Makefile
2050                 src/gallium/targets/xvmc-r300/Makefile
2051                 src/gallium/targets/xvmc-r600/Makefile
2052                 src/gallium/targets/xvmc-softpipe/Makefile
2053                 src/gallium/tests/trivial/Makefile
2054                 src/gallium/tests/unit/Makefile
2055                 src/gallium/winsys/Makefile
2056                 src/gallium/winsys/freedreno/drm/Makefile
2057                 src/gallium/winsys/i915/drm/Makefile
2058                 src/gallium/winsys/i915/sw/Makefile
2059                 src/gallium/winsys/intel/drm/Makefile
2060                 src/gallium/winsys/nouveau/drm/Makefile
2061                 src/gallium/winsys/radeon/drm/Makefile
2062                 src/gallium/winsys/svga/drm/Makefile
2063                 src/gallium/winsys/sw/dri/Makefile
2064                 src/gallium/winsys/sw/fbdev/Makefile
2065                 src/gallium/winsys/sw/null/Makefile
2066                 src/gallium/winsys/sw/wayland/Makefile
2067                 src/gallium/winsys/sw/wrapper/Makefile
2068                 src/gallium/winsys/sw/xlib/Makefile
2069                 src/gbm/Makefile
2070                 src/gbm/main/gbm.pc
2071                 src/glsl/Makefile
2072                 src/glx/Makefile
2073                 src/glx/tests/Makefile
2074                 src/gtest/Makefile
2075                 src/mapi/Makefile
2076                 src/mapi/es1api/Makefile
2077                 src/mapi/es1api/glesv1_cm.pc
2078                 src/mapi/es2api/Makefile
2079                 src/mapi/es2api/glesv2.pc
2080                 src/mapi/glapi/Makefile
2081                 src/mapi/glapi/gen/Makefile
2082                 src/mapi/glapi/tests/Makefile
2083                 src/mapi/shared-glapi/Makefile
2084                 src/mapi/shared-glapi/tests/Makefile
2085                 src/mapi/vgapi/Makefile
2086                 src/mapi/vgapi/vg.pc
2087                 src/mesa/Makefile
2088                 src/mesa/gl.pc
2089                 src/mesa/drivers/dri/dri.pc
2090                 src/mesa/drivers/dri/common/Makefile
2091                 src/mesa/drivers/dri/common/xmlpool/Makefile
2092                 src/mesa/drivers/dri/i915/Makefile
2093                 src/mesa/drivers/dri/i965/Makefile
2094                 src/mesa/drivers/dri/Makefile
2095                 src/mesa/drivers/dri/nouveau/Makefile
2096                 src/mesa/drivers/dri/r200/Makefile
2097                 src/mesa/drivers/dri/radeon/Makefile
2098                 src/mesa/drivers/dri/swrast/Makefile
2099                 src/mesa/drivers/osmesa/Makefile
2100                 src/mesa/drivers/osmesa/osmesa.pc
2101                 src/mesa/drivers/x11/Makefile
2102                 src/mesa/libdricore/Makefile
2103                 src/mesa/main/tests/Makefile
2104                 src/mesa/main/tests/hash_table/Makefile
2105                 src/mesa/program/Makefile
2106                 src/mesa/x86-64/Makefile
2107                 src/mesa/x86/Makefile])
2108
2109 dnl Sort the dirs alphabetically
2110 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2111 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2112 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2113 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2114
2115 AC_OUTPUT
2116
2117 dnl
2118 dnl Output some configuration info for the user
2119 dnl
2120 echo ""
2121 echo "        prefix:          $prefix"
2122 echo "        exec_prefix:     $exec_prefix"
2123 echo "        libdir:          $libdir"
2124 echo "        includedir:      $includedir"
2125
2126 dnl API info
2127 echo ""
2128 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2129 echo "        OpenVG:          $enable_openvg"
2130
2131 dnl Driver info
2132 echo ""
2133 case "x$enable_osmesa$enable_gallium_osmesa" in
2134 xnoyes)
2135         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2136         ;;
2137 xyesno)
2138         echo "        OSMesa:          lib$OSMESA_LIB"
2139         ;;
2140 xnono)
2141         echo "        OSMesa:          no"
2142         ;;
2143 esac
2144
2145 if test "x$enable_dri" != xno; then
2146         # cleanup the drivers var
2147         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2148         if test "x$DRI_DIRS" = x; then
2149             echo "        DRI drivers:     no"
2150         else
2151             echo "        DRI drivers:     $dri_dirs"
2152         fi
2153         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2154 fi
2155
2156 case "x$enable_glx$enable_xlib_glx" in
2157 xyesyes)
2158     echo "        GLX:             Xlib-based"
2159     ;;
2160 xyesno)
2161     echo "        GLX:             DRI-based"
2162     ;;
2163 *)
2164     echo "        GLX:             $enable_glx"
2165     ;;
2166 esac
2167
2168 dnl EGL
2169 echo ""
2170 echo "        EGL:             $enable_egl"
2171 if test "$enable_egl" = yes; then
2172     echo "        EGL platforms:   $egl_platforms"
2173
2174     egl_drivers=""
2175     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2176         egl_drivers="$egl_drivers builtin:egl_glx"
2177     fi
2178     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2179         egl_drivers="$egl_drivers builtin:egl_dri2"
2180     fi
2181
2182     if test "x$enable_gallium_egl" = xyes; then
2183         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2184         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2185     else
2186         echo "        EGL drivers:    $egl_drivers"
2187     fi
2188 fi
2189
2190 echo ""
2191 if test "x$MESA_LLVM" = x1; then
2192     echo "        llvm:            yes"
2193     echo "        llvm-config:     $LLVM_CONFIG"
2194     echo "        llvm-version:    $LLVM_VERSION"
2195 else
2196     echo "        llvm:            no"
2197 fi
2198
2199 echo ""
2200 if test -n "$with_gallium_drivers"; then
2201     echo "        Gallium:         yes"
2202     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2203     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2204     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2205     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2206 else
2207     echo "        Gallium:         no"
2208 fi
2209
2210
2211 dnl Libraries
2212 echo ""
2213 echo "        Shared libs:     $enable_shared"
2214 echo "        Static libs:     $enable_static"
2215 echo "        Shared-glapi:    $enable_shared_glapi"
2216
2217 dnl Compiler options
2218 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2219 cflags=`echo $CFLAGS | \
2220     $SED 's/^ *//;s/  */ /;s/ *$//'`
2221 cxxflags=`echo $CXXFLAGS | \
2222     $SED 's/^ *//;s/  */ /;s/ *$//'`
2223 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2224 echo ""
2225 echo "        CFLAGS:          $cflags"
2226 echo "        CXXFLAGS:        $cxxflags"
2227 echo "        Macros:          $defines"
2228 echo ""
2229 if test "x$MESA_LLVM" = x1; then
2230     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2231     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2232     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2233     echo ""
2234 fi
2235 echo "        PYTHON2:         $PYTHON2"
2236
2237 echo ""
2238 echo "        Run '${MAKE-make}' to build Mesa"
2239 echo ""