configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.8.0
  93 LIBSENSORS_REQUIRED=4.0.0
  94
  95 dnl LLVM versions
  96 LLVM_REQUIRED_GALLIUM=3.3.0
  97 LLVM_REQUIRED_OPENCL=3.6.0
  98 LLVM_REQUIRED_R600=3.6.0
  99 LLVM_REQUIRED_RADEONSI=3.6.0
 100 LLVM_REQUIRED_RADV=3.9.0
 101 LLVM_REQUIRED_SWR=3.6.0
 102
 103 dnl Check for progs
 104 AC_PROG_CPP
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 AM_PROG_CC_C_O
 108 AM_PROG_AS
 109 AX_CHECK_GNU_MAKE
 110 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 111 AC_PROG_SED
 112 AC_PROG_MKDIR_P
 113
 114 AC_SYS_LARGEFILE
 115
 116 LT_PREREQ([2.2])
 117 LT_INIT([disable-static])
 118
 119 AC_CHECK_PROG(RM, rm, [rm -f])
 120 AC_CHECK_PROG(XXD, xxd, [xxd])
 121
 122 AX_PROG_BISON([],
 123               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 124                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 125 AX_PROG_FLEX([],
 126              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 127                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 128
 129 AC_CHECK_PROG(INDENT, indent, indent, cat)
 130 if test "x$INDENT" != "xcat"; then
 131     # Only GNU indent is supported
 132     INDENT_VERSION=`indent --version | grep GNU`
 133     if test $? -eq 0; then
 134        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 135     else
 136        INDENT="cat"
 137     fi
 138 fi
 139
 140 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 141
 142 if test -z "$PYTHON2"; then
 143     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 144         AC_MSG_ERROR([Python not found - unable to generate sources])
 145     fi
 146 else
 147     if test "x$acv_mako_found" = xno; then
 148         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 149             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 150         fi
 151     fi
 152 fi
 153
 154 AC_PROG_INSTALL
 155
 156 dnl We need a POSIX shell for parts of the build. Assume we have one
 157 dnl in most cases.
 158 case "$host_os" in
 159 solaris*)
 160     # Solaris /bin/sh is too old/non-POSIX compliant
 161     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 162     SHELL="$POSIX_SHELL"
 163     ;;
 164 esac
 165
 166 dnl clang is mostly GCC-compatible, but its version is much lower,
 167 dnl so we have to check for it.
 168 AC_MSG_CHECKING([if compiling with clang])
 169
 170 AC_COMPILE_IFELSE(
 171 [AC_LANG_PROGRAM([], [[
 172 #ifndef __clang__
 173        not clang
 174 #endif
 175 ]])],
 176 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 177
 178 AC_MSG_RESULT([$acv_mesa_CLANG])
 179
 180 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 181 dnl versions are explictly not supported.
 182 GEN_ASM_OFFSETS=no
 183 USE_GNU99=no
 184 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 185     AC_MSG_CHECKING([whether gcc version is sufficient])
 186     major=0
 187     minor=0
 188
 189     GCC_VERSION=`$CC -dumpversion`
 190     if test $? -eq 0; then
 191         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 192         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 193     fi
 194
 195     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 196         AC_MSG_RESULT([no])
 197         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 198     else
 199         AC_MSG_RESULT([yes])
 200     fi
 201
 202     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 203         USE_GNU99=yes
 204     fi
 205     if test "x$cross_compiling" = xyes; then
 206         GEN_ASM_OFFSETS=yes
 207     fi
 208 fi
 209
 210 dnl We don't support building Mesa with Sun C compiler
 211 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 212 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 213 if test "x$SUNCC" = xyes; then
 214     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 215 fi
 216
 217 dnl Check for compiler builtins
 218 AX_GCC_BUILTIN([__builtin_bswap32])
 219 AX_GCC_BUILTIN([__builtin_bswap64])
 220 AX_GCC_BUILTIN([__builtin_clz])
 221 AX_GCC_BUILTIN([__builtin_clzll])
 222 AX_GCC_BUILTIN([__builtin_ctz])
 223 AX_GCC_BUILTIN([__builtin_expect])
 224 AX_GCC_BUILTIN([__builtin_ffs])
 225 AX_GCC_BUILTIN([__builtin_ffsll])
 226 AX_GCC_BUILTIN([__builtin_popcount])
 227 AX_GCC_BUILTIN([__builtin_popcountll])
 228 AX_GCC_BUILTIN([__builtin_unreachable])
 229
 230 AX_GCC_FUNC_ATTRIBUTE([const])
 231 AX_GCC_FUNC_ATTRIBUTE([flatten])
 232 AX_GCC_FUNC_ATTRIBUTE([format])
 233 AX_GCC_FUNC_ATTRIBUTE([malloc])
 234 AX_GCC_FUNC_ATTRIBUTE([packed])
 235 AX_GCC_FUNC_ATTRIBUTE([pure])
 236 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 237 AX_GCC_FUNC_ATTRIBUTE([unused])
 238 AX_GCC_FUNC_ATTRIBUTE([visibility])
 239 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 240 AX_GCC_FUNC_ATTRIBUTE([weak])
 241
 242 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 243
 244 dnl Make sure the pkg-config macros are defined
 245 m4_ifndef([PKG_PROG_PKG_CONFIG],
 246     [m4_fatal([Could not locate the pkg-config autoconf macros.
 247   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 248   are in a different location, try setting the environment variable
 249   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 250 PKG_PROG_PKG_CONFIG()
 251
 252 dnl LIB_DIR - library basename
 253 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 254 AC_SUBST([LIB_DIR])
 255
 256 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 257 _SAVE_LDFLAGS="$LDFLAGS"
 258 _SAVE_CPPFLAGS="$CPPFLAGS"
 259
 260 dnl Compiler macros
 261 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 262 AC_SUBST([DEFINES])
 263 android=no
 264 case "$host_os" in
 265 *-android)
 266     android=yes
 267     ;;
 268 linux*|*-gnu*|gnu*|cygwin*)
 269     DEFINES="$DEFINES -D_GNU_SOURCE"
 270     ;;
 271 solaris*)
 272     DEFINES="$DEFINES -DSVR4"
 273     ;;
 274 esac
 275
 276 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 277
 278 dnl Add flags for gcc and g++
 279 if test "x$GCC" = xyes; then
 280     CFLAGS="$CFLAGS -Wall"
 281
 282     if test "x$USE_GNU99" = xyes; then
 283         CFLAGS="$CFLAGS -std=gnu99"
 284     else
 285         CFLAGS="$CFLAGS -std=c99"
 286     fi
 287
 288     # Enable -Werror=implicit-function-declaration and
 289     # -Werror=missing-prototypes, if available, or otherwise, just
 290     # -Wmissing-prototypes.  This is particularly useful to avoid
 291     # generating a loadable driver module that has undefined symbols.
 292     save_CFLAGS="$CFLAGS"
 293     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 294     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 295     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 296     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 297                    AC_MSG_RESULT([yes]),
 298                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 299                     AC_MSG_RESULT([no])]);
 300
 301     # Enable -fvisibility=hidden if using a gcc that supports it
 302     save_CFLAGS="$CFLAGS"
 303     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 304     VISIBILITY_CFLAGS="-fvisibility=hidden"
 305     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 306     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 307                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 308
 309     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 310     CFLAGS=$save_CFLAGS
 311
 312     # We don't want floating-point math functions to set errno or trap
 313     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 314
 315     # Flags to help ensure that certain portions of the code -- and only those
 316     # portions -- can be built with MSVC:
 317     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 318     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 319     #   supports most of C99)
 320     # - the rest has no compiler compiler restrictions
 321     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 322     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 323
 324     # Enable -Werror=vla if compiler supports it
 325     save_CFLAGS="$CFLAGS"
 326     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 327     CFLAGS="$CFLAGS -Werror=vla"
 328     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 329                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 330                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 331                     AC_MSG_RESULT([yes])],
 332                     AC_MSG_RESULT([no]));
 333     CFLAGS="$save_CFLAGS"
 334 fi
 335 if test "x$GXX" = xyes; then
 336     CXXFLAGS="$CXXFLAGS -Wall"
 337
 338     # Enable -fvisibility=hidden if using a gcc that supports it
 339     save_CXXFLAGS="$CXXFLAGS"
 340     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 341     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 342     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 343     AC_LANG_PUSH([C++])
 344     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 345                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 346     AC_LANG_POP([C++])
 347
 348     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 349     CXXFLAGS=$save_CXXFLAGS
 350
 351     # We don't want floating-point math functions to set errno or trap
 352     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 353 fi
 354
 355 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 356 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 357
 358 dnl even if the compiler appears to support it, using visibility attributes isn't
 359 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 360 case "$host_os" in
 361 cygwin*)
 362     VISIBILITY_CFLAGS=""
 363     VISIBILITY_CXXFLAGS=""
 364     ;;
 365 esac
 366
 367 AC_SUBST([VISIBILITY_CFLAGS])
 368 AC_SUBST([VISIBILITY_CXXFLAGS])
 369
 370 dnl
 371 dnl Optional flags, check for compiler support
 372 dnl
 373 SSE41_CFLAGS="-msse4.1"
 374 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 375 dnl stack, but on x86-32 such alignment is not guaranteed.
 376 case "$target_cpu" in
 377 i?86)
 378     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 379     ;;
 380 esac
 381 save_CFLAGS="$CFLAGS"
 382 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 383 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 384 #include <smmintrin.h>
 385 int param;
 386 int main () {
 387     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 388     c = _mm_max_epu32(a, b);
 389     return _mm_cvtsi128_si32(c);
 390 }]])], SSE41_SUPPORTED=1)
 391 CFLAGS="$save_CFLAGS"
 392 if test "x$SSE41_SUPPORTED" = x1; then
 393     DEFINES="$DEFINES -DUSE_SSE41"
 394 fi
 395 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 396 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 397
 398 dnl Check for new-style atomic builtins
 399 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 400 int main() {
 401     int n;
 402     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 403 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 404 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 405     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 406 fi
 407 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 408
 409 dnl Check for Endianness
 410 AC_C_BIGENDIAN(
 411    little_endian=no,
 412    little_endian=yes,
 413    little_endian=no,
 414    little_endian=no
 415 )
 416
 417 dnl Check for POWER8 Architecture
 418 PWR8_CFLAGS="-mpower8-vector"
 419 have_pwr8_intrinsics=no
 420 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 421 save_CFLAGS=$CFLAGS
 422 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 423 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 424 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 425 #error "Need GCC >= 4.8 for sane POWER8 support"
 426 #endif
 427 #include <altivec.h>
 428 int main () {
 429     vector unsigned char r;
 430     vector unsigned int v = vec_splat_u32 (1);
 431     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 432     return 0;
 433 }]])], have_pwr8_intrinsics=yes)
 434 CFLAGS=$save_CFLAGS
 435
 436 AC_ARG_ENABLE(pwr8,
 437    [AC_HELP_STRING([--disable-pwr8-inst],
 438                    [disable POWER8-specific instructions])],
 439    [enable_pwr8=$enableval], [enable_pwr8=auto])
 440
 441 if test "x$enable_pwr8" = xno ; then
 442    have_pwr8_intrinsics=disabled
 443 fi
 444
 445 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 446    DEFINES="$DEFINES -D_ARCH_PWR8"
 447    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 448    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 449 else
 450    PWR8_CFLAGS=
 451 fi
 452
 453 AC_MSG_RESULT($have_pwr8_intrinsics)
 454 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 455    AC_MSG_ERROR([POWER8 compiler support not detected])
 456 fi
 457
 458 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 459    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 460 fi
 461
 462 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 463
 464 dnl Can't have static and shared libraries, default to static if user
 465 dnl explicitly requested. If both disabled, set to static since shared
 466 dnl was explicitly requested.
 467 case "x$enable_static$enable_shared" in
 468 xyesyes)
 469     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 470     enable_shared=no
 471     ;;
 472 xnono)
 473     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 474     enable_shared=yes
 475     ;;
 476 esac
 477
 478 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 479
 480 dnl
 481 dnl other compiler options
 482 dnl
 483 AC_ARG_ENABLE([debug],
 484     [AS_HELP_STRING([--enable-debug],
 485         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 486     [enable_debug="$enableval"],
 487     [enable_debug=no]
 488 )
 489
 490 AC_ARG_ENABLE([profile],
 491     [AS_HELP_STRING([--enable-profile],
 492         [enable profiling of code @<:@default=disabled@:>@])],
 493     [enable_profile="$enableval"],
 494     [enable_profile=no]
 495 )
 496
 497 if test "x$enable_profile" = xyes; then
 498     DEFINES="$DEFINES -DPROFILE"
 499     if test "x$GCC" = xyes; then
 500         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 501     fi
 502     if test "x$GXX" = xyes; then
 503         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 504     fi
 505 fi
 506
 507 if test "x$enable_debug" = xyes; then
 508     DEFINES="$DEFINES -DDEBUG"
 509     if test "x$enable_profile" = xyes; then
 510         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 511     fi
 512     if test "x$GCC" = xyes; then
 513         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 514             CFLAGS="$CFLAGS -g"
 515         fi
 516         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 517             CFLAGS="$CFLAGS -O0"
 518         fi
 519     fi
 520     if test "x$GXX" = xyes; then
 521         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 522             CXXFLAGS="$CXXFLAGS -g"
 523         fi
 524         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 525             CXXFLAGS="$CXXFLAGS -O0"
 526         fi
 527     fi
 528 else
 529    DEFINES="$DEFINES -DNDEBUG"
 530 fi
 531
 532 DEFAULT_GL_LIB_NAME=GL
 533
 534 dnl
 535 dnl Check if linker supports -Bsymbolic
 536 dnl
 537 save_LDFLAGS=$LDFLAGS
 538 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 539 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 540 AC_LINK_IFELSE(
 541     [AC_LANG_SOURCE([int main() { return 0;}])],
 542     [AC_MSG_RESULT([yes])
 543         BSYMBOLIC="-Wl,-Bsymbolic";],
 544     [AC_MSG_RESULT([no])
 545         BSYMBOLIC="";])
 546 LDFLAGS=$save_LDFLAGS
 547
 548 AC_SUBST([BSYMBOLIC])
 549
 550 dnl
 551 dnl Check if linker supports garbage collection
 552 dnl
 553 save_LDFLAGS=$LDFLAGS
 554 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 555 AC_MSG_CHECKING([whether ld supports --gc-sections])
 556 AC_LINK_IFELSE(
 557     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 558     [AC_MSG_RESULT([yes])
 559         GC_SECTIONS="-Wl,--gc-sections";],
 560     [AC_MSG_RESULT([no])
 561         GC_SECTIONS="";])
 562 LDFLAGS=$save_LDFLAGS
 563
 564 AC_SUBST([GC_SECTIONS])
 565
 566 dnl
 567 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 568 dnl so when these flags are passed to ld via libtool the checks will fail
 569 dnl
 570 case "$host_os" in
 571 openbsd* | darwin* )
 572     LD_NO_UNDEFINED="" ;;
 573 *)
 574     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 575 esac
 576
 577 AC_SUBST([LD_NO_UNDEFINED])
 578
 579 dnl
 580 dnl Check if linker supports version scripts
 581 dnl
 582 AC_MSG_CHECKING([if the linker supports version-scripts])
 583 save_LDFLAGS=$LDFLAGS
 584 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 585 cat > conftest.map <<EOF
 586 VERSION_1 {
 587      global:
 588          main;
 589
 590      local:
 591          *;
 592 };
 593 EOF
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([int main() { return 0;}])],
 596     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 597     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 598 LDFLAGS=$save_LDFLAGS
 599 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 600
 601 dnl
 602 dnl Check if linker supports dynamic list files
 603 dnl
 604 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 605 save_LDFLAGS=$LDFLAGS
 606 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 607 cat > conftest.dyn <<EOF
 608 {
 609         radeon_drm_winsys_create;
 610 };
 611 EOF
 612 AC_LINK_IFELSE(
 613     [AC_LANG_SOURCE([int main() { return 0;}])],
 614     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 615     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 616 LDFLAGS=$save_LDFLAGS
 617 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 618
 619 dnl
 620 dnl compatibility symlinks
 621 dnl
 622 case "$host_os" in
 623 linux* )
 624     HAVE_COMPAT_SYMLINKS=yes ;;
 625 * )
 626     HAVE_COMPAT_SYMLINKS=no ;;
 627 esac
 628
 629 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 630
 631 DEFAULT_GL_LIB_NAME=GL
 632
 633 dnl
 634 dnl Libglvnd configuration
 635 dnl
 636 AC_ARG_ENABLE([libglvnd],
 637     [AS_HELP_STRING([--enable-libglvnd],
 638         [Build for libglvnd @<:@default=disabled@:>@])],
 639     [enable_libglvnd="$enableval"],
 640     [enable_libglvnd=no])
 641 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 642 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 643 if test "x$enable_libglvnd" = xyes ; then
 644     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 645     DEFAULT_GL_LIB_NAME=GLX_mesa
 646 fi
 647
 648 dnl
 649 dnl library names
 650 dnl
 651 dnl Unfortunately we need to do a few things that libtool can't help us with,
 652 dnl so we need some knowledge of shared library filenames:
 653 dnl
 654 dnl LIB_EXT is the extension used when creating symlinks for alternate
 655 dnl filenames for a shared library which will be dynamically loaded
 656 dnl
 657 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 658 dnl the file for a shared library we wish to link with
 659 dnl
 660 case "$host_os" in
 661 darwin* )
 662     LIB_EXT='dylib'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 cygwin* )
 666     LIB_EXT='dll'
 667     IMP_LIB_EXT='dll.a'
 668     ;;
 669 aix* )
 670     LIB_EXT='a'
 671     IMP_LIB_EXT=$LIB_EXT
 672     ;;
 673 * )
 674     LIB_EXT='so'
 675     IMP_LIB_EXT=$LIB_EXT
 676     ;;
 677 esac
 678
 679 AC_SUBST([LIB_EXT])
 680
 681 AC_ARG_WITH([gl-lib-name],
 682   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 683     [specify GL library name @<:@default=GL@:>@])],
 684   [GL_LIB=$withval],
 685   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 686 AC_ARG_WITH([osmesa-lib-name],
 687   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 688     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 689   [OSMESA_LIB=$withval],
 690   [OSMESA_LIB=OSMesa])
 691 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 692 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 693
 694 dnl
 695 dnl Mangled Mesa support
 696 dnl
 697 AC_ARG_ENABLE([mangling],
 698   [AS_HELP_STRING([--enable-mangling],
 699     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 700   [enable_mangling="${enableval}"],
 701   [enable_mangling=no]
 702 )
 703 if test "x${enable_mangling}" = "xyes" ; then
 704   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 705   GL_LIB="Mangled${GL_LIB}"
 706   OSMESA_LIB="Mangled${OSMESA_LIB}"
 707 fi
 708 AC_SUBST([GL_LIB])
 709 AC_SUBST([OSMESA_LIB])
 710
 711 dnl
 712 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 713 dnl
 714 AC_ARG_ENABLE([texture-float],
 715     [AS_HELP_STRING([--enable-texture-float],
 716         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 717     [enable_texture_float="$enableval"],
 718     [enable_texture_float=no]
 719 )
 720 if test "x$enable_texture_float" = xyes; then
 721     AC_MSG_WARN([Floating-point textures enabled.])
 722     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 723     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 724 fi
 725
 726 dnl
 727 dnl Arch/platform-specific settings
 728 dnl
 729 AC_ARG_ENABLE([asm],
 730     [AS_HELP_STRING([--disable-asm],
 731         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 732     [enable_asm="$enableval"],
 733     [enable_asm=yes]
 734 )
 735 asm_arch=""
 736 AC_MSG_CHECKING([whether to enable assembly])
 737 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 738 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 739 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 740     case "$host_cpu" in
 741     i?86 | x86_64 | amd64)
 742         if test "x$host_cpu" != "x$target_cpu"; then
 743             enable_asm=no
 744             AC_MSG_RESULT([no, cross compiling])
 745         fi
 746         ;;
 747     esac
 748 fi
 749 # check for supported arches
 750 if test "x$enable_asm" = xyes; then
 751     case "$host_cpu" in
 752     i?86)
 753         case "$host_os" in
 754         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 755             asm_arch=x86
 756             ;;
 757         esac
 758         ;;
 759     x86_64|amd64)
 760         case "$host_os" in
 761         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 762             asm_arch=x86_64
 763             ;;
 764         esac
 765         ;;
 766     sparc*)
 767         case "$host_os" in
 768         linux*)
 769             asm_arch=sparc
 770             ;;
 771         esac
 772         ;;
 773     esac
 774
 775     case "$asm_arch" in
 776     x86)
 777         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 778         AC_MSG_RESULT([yes, x86])
 779         ;;
 780     x86_64|amd64)
 781         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 782         AC_MSG_RESULT([yes, x86_64])
 783         ;;
 784     sparc)
 785         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 786         AC_MSG_RESULT([yes, sparc])
 787         ;;
 788     *)
 789         AC_MSG_RESULT([no, platform not supported])
 790         ;;
 791     esac
 792 fi
 793
 794 AC_HEADER_MAJOR
 795 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 796 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 797 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 798 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 799
 800 dnl Check to see if dlopen is in default libraries (like Solaris, which
 801 dnl has it in libc), or if libdl is needed to get it.
 802 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 803     [AC_CHECK_LIB([dl], [dlopen],
 804        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 805 AC_SUBST([DLOPEN_LIBS])
 806
 807 dnl Check if that library also has dladdr
 808 save_LIBS="$LIBS"
 809 LIBS="$LIBS $DLOPEN_LIBS"
 810 AC_CHECK_FUNCS([dladdr])
 811 LIBS="$save_LIBS"
 812
 813 case "$host_os" in
 814 darwin*)
 815     ;;
 816 *)
 817     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 818                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 819                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 820     AC_SUBST([CLOCK_LIB])
 821     ;;
 822 esac
 823
 824 dnl See if posix_memalign is available
 825 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 826
 827 dnl Check for pthreads
 828 AX_PTHREAD
 829 if test "x$ax_pthread_ok" = xno; then
 830     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 831 fi
 832 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 833 dnl to -pthread, which causes problems if we need -lpthread to appear in
 834 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 835 dnl is not valid for that platform.
 836 if test "x$android" = xno; then
 837     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 838 fi
 839
 840 dnl pthread-stubs is mandatory on targets where it exists
 841 case "$host_os" in
 842 cygwin* )
 843     pthread_stubs_possible="no"
 844     ;;
 845 * )
 846     pthread_stubs_possible="yes"
 847     ;;
 848 esac
 849
 850 if test "x$pthread_stubs_possible" = xyes; then
 851     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 852     AC_SUBST(PTHREADSTUBS_CFLAGS)
 853     AC_SUBST(PTHREADSTUBS_LIBS)
 854 fi
 855
 856 dnl SELinux awareness.
 857 AC_ARG_ENABLE([selinux],
 858     [AS_HELP_STRING([--enable-selinux],
 859         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 860     [MESA_SELINUX="$enableval"],
 861     [MESA_SELINUX=no])
 862 if test "x$enable_selinux" = "xyes"; then
 863     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 864         [AC_CHECK_HEADER([selinux/selinux.h],[],
 865                          [AC_MSG_ERROR([SELinux headers not found])])
 866          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 867                       [AC_MSG_ERROR([SELinux library not found])])
 868          SELINUX_LIBS="-lselinux"])
 869     DEFINES="$DEFINES -DMESA_SELINUX"
 870 fi
 871 AC_SUBST([SELINUX_CFLAGS])
 872 AC_SUBST([SELINUX_LIBS])
 873
 874 dnl
 875 dnl LLVM
 876 dnl
 877 AC_ARG_ENABLE([llvm-shared-libs],
 878     [AS_HELP_STRING([--enable-llvm-shared-libs],
 879         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 880     [enable_llvm_shared_libs="$enableval"],
 881     [enable_llvm_shared_libs=yes])
 882
 883 AC_ARG_WITH([llvm-prefix],
 884     [AS_HELP_STRING([--with-llvm-prefix],
 885         [Prefix for LLVM installations in non-standard locations])],
 886     [llvm_prefix="$withval"],
 887     [llvm_prefix=''])
 888
 889 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 890 if test "x$have_libelf" = xno; then
 891    LIBELF_LIBS=''
 892    LIBELF_CFLAGS=''
 893    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 894    AC_SUBST([LIBELF_LIBS])
 895    AC_SUBST([LIBELF_CFLAGS])
 896 fi
 897
 898 if test -z "$LLVM_CONFIG"; then
 899     if test -n "$llvm_prefix"; then
 900         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 901     else
 902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 903     fi
 904 fi
 905
 906 llvm_add_component() {
 907     new_llvm_component=$1
 908     driver_name=$2
 909
 910     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 911         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 912     else
 913         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 914     fi
 915 }
 916
 917 llvm_add_default_components() {
 918     driver_name=$1
 919
 920     # Required default components
 921     llvm_add_component "bitwriter" $driver_name
 922     llvm_add_component "engine" $driver_name
 923     llvm_add_component "mcdisassembler" $driver_name
 924     llvm_add_component "mcjit" $driver_name
 925
 926     # Optional default components
 927     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 928         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 929     fi
 930 }
 931
 932 llvm_add_target() {
 933     new_llvm_target=$1
 934     driver_name=$2
 935
 936     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 937         llvm_add_component $new_llvm_target $driver_name
 938     else
 939         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 940     fi
 941 }
 942
 943 # Call this inside ` ` to get the return value.
 944 # $1 is the llvm-config command with arguments.
 945 strip_unwanted_llvm_flags() {
 946     # Use \> (marks the end of the word)
 947     echo `$1` | sed \
 948         -e 's/-march=\S*//g' \
 949         -e 's/-mtune=\S*//g' \
 950         -e 's/-mcpu=\S*//g' \
 951         -e 's/-DNDEBUG\>//g' \
 952         -e 's/-D_GNU_SOURCE\>//g' \
 953         -e 's/-pedantic\>//g' \
 954         -e 's/-Wcovered-switch-default\>//g' \
 955         -e 's/-O.\>//g' \
 956         -e 's/-g\>//g' \
 957         -e 's/-Wall\>//g' \
 958         -e 's/-Wcast-qual\>//g' \
 959         -e 's/-Woverloaded-virtual\>//g' \
 960         -e 's/-fcolor-diagnostics\>//g' \
 961         -e 's/-fdata-sections\>//g' \
 962         -e 's/-ffunction-sections\>//g' \
 963         -e 's/-fno-exceptions\>//g' \
 964         -e 's/-fomit-frame-pointer\>//g' \
 965         -e 's/-fvisibility-inlines-hidden\>//g' \
 966         -e 's/-fPIC\>//g' \
 967         -e 's/-fstack-protector-strong\>//g'
 968 }
 969
 970 llvm_set_environment_variables() {
 971     if test "x$LLVM_CONFIG" != xno; then
 972         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 973         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 974         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 975         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 976         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 977         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 978         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 979         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 980
 981         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 982             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 983         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 984             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 985         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 986             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 987
 988         # Only needed for LLVM < 3.6.0
 989         if test -z "$LLVM_VERSION_PATCH"; then
 990             LLVM_VERSION_PATCH=0
 991         fi
 992
 993         if test "$LLVM_VERSION_MINOR" -lt 10; then
 994             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 995         else
 996             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}"
 997         fi
 998
 999         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1000         MESA_LLVM=1
1001     else
1002         MESA_LLVM=0
1003         LLVM_VERSION_INT=0
1004     fi
1005 }
1006
1007 llvm_check_version_for() {
1008     if test "x$MESA_LLVM" = x0; then
1009         AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1010         return
1011     fi
1012
1013     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1014     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1015     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1016
1017     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1018         # major > required major
1019         #  --> OK
1020         return
1021     fi
1022
1023     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1024         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1025             # major = required major and
1026             # minor > required minor
1027             #  --> OK
1028             return
1029         else
1030             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1031                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1032                     # major = required major and
1033                     # minor = required minor and
1034                     # patch >= required patch
1035                     #  --> OK
1036                     return
1037                 fi
1038             fi
1039         fi
1040     fi
1041
1042     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1043 }
1044
1045 radeon_llvm_check() {
1046     if test ${LLVM_VERSION_INT} -lt 307; then
1047         amdgpu_llvm_target_name='r600'
1048     else
1049         amdgpu_llvm_target_name='amdgpu'
1050     fi
1051
1052     llvm_check_version_for $*
1053
1054     llvm_add_target $amdgpu_llvm_target_name $2
1055
1056     llvm_add_default_components $2
1057     llvm_add_component "bitreader" $2
1058     llvm_add_component "ipo" $2
1059
1060     NEED_RADEON_LLVM=yes
1061     if test "x$have_libelf" != xyes; then
1062        AC_MSG_ERROR([$1 requires libelf when using llvm])
1063     fi
1064 }
1065
1066 llvm_set_environment_variables
1067
1068 AC_SUBST([MESA_LLVM])
1069 AC_SUBST([LLVM_BINDIR])
1070 AC_SUBST([LLVM_CFLAGS])
1071 AC_SUBST([LLVM_CPPFLAGS])
1072 AC_SUBST([LLVM_CXXFLAGS])
1073 AC_SUBST([LLVM_LIBDIR])
1074 AC_SUBST([LLVM_LIBS])
1075 AC_SUBST([LLVM_LDFLAGS])
1076 AC_SUBST([LLVM_INCLUDEDIR])
1077 AC_SUBST([LLVM_VERSION])
1078
1079 dnl Options for APIs
1080 AC_ARG_ENABLE([opengl],
1081     [AS_HELP_STRING([--disable-opengl],
1082         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1083     [enable_opengl="$enableval"],
1084     [enable_opengl=yes])
1085 AC_ARG_ENABLE([gles1],
1086     [AS_HELP_STRING([--disable-gles1],
1087         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1088     [enable_gles1="$enableval"],
1089     [enable_gles1=yes])
1090 AC_ARG_ENABLE([gles2],
1091     [AS_HELP_STRING([--disable-gles2],
1092         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1093     [enable_gles2="$enableval"],
1094     [enable_gles2=yes])
1095
1096 AC_ARG_ENABLE([dri],
1097     [AS_HELP_STRING([--enable-dri],
1098         [enable DRI modules @<:@default=enabled@:>@])],
1099     [enable_dri="$enableval"],
1100     [enable_dri=yes])
1101
1102 AC_ARG_ENABLE([gallium-extra-hud],
1103     [AS_HELP_STRING([--enable-gallium-extra-hud],
1104         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1105     [enable_gallium_extra_hud="$enableval"],
1106     [enable_gallium_extra_hud=no])
1107 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1108 if test "x$enable_gallium_extra_hud" = xyes ; then
1109     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1110 fi
1111
1112 #TODO: no pkgconfig .pc available for libsensors.
1113 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1114 AC_ARG_ENABLE([lmsensors],
1115     [AS_HELP_STRING([--enable-lmsensors],
1116         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1117     [enable_lmsensors="$enableval"],
1118     [enable_lmsensors=no])
1119 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1120 if test "x$enable_lmsensors" = xyes ; then
1121     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1122     LIBSENSORS_LDFLAGS="-lsensors"
1123 else
1124     LIBSENSORS_LDFLAGS=""
1125 fi
1126 AC_SUBST(LIBSENSORS_LDFLAGS)
1127
1128 case "$host_os" in
1129 linux*)
1130     dri3_default=yes
1131     ;;
1132 *)
1133     dri3_default=no
1134     ;;
1135 esac
1136
1137 if test "x$enable_dri" = xno; then
1138     dri3_default=no
1139 fi
1140
1141 AC_ARG_ENABLE([dri3],
1142     [AS_HELP_STRING([--enable-dri3],
1143         [enable DRI3 @<:@default=auto@:>@])],
1144     [enable_dri3="$enableval"],
1145     [enable_dri3="$dri3_default"])
1146 AC_ARG_ENABLE([glx],
1147     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1148         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1149     [enable_glx="$enableval"],
1150     [enable_glx=yes])
1151 AC_ARG_ENABLE([osmesa],
1152     [AS_HELP_STRING([--enable-osmesa],
1153         [enable OSMesa library @<:@default=disabled@:>@])],
1154     [enable_osmesa="$enableval"],
1155     [enable_osmesa=no])
1156 AC_ARG_ENABLE([gallium-osmesa],
1157     [AS_HELP_STRING([--enable-gallium-osmesa],
1158         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1159     [enable_gallium_osmesa="$enableval"],
1160     [enable_gallium_osmesa=no])
1161 AC_ARG_ENABLE([egl],
1162     [AS_HELP_STRING([--disable-egl],
1163         [disable EGL library @<:@default=enabled@:>@])],
1164     [enable_egl="$enableval"],
1165     [enable_egl=yes])
1166
1167 AC_ARG_ENABLE([xa],
1168     [AS_HELP_STRING([--enable-xa],
1169         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1170     [enable_xa="$enableval"],
1171     [enable_xa=no])
1172 AC_ARG_ENABLE([gbm],
1173    [AS_HELP_STRING([--enable-gbm],
1174          [enable gbm library @<:@default=yes except cygwin@:>@])],
1175    [enable_gbm="$enableval"],
1176    [case "$host_os" in
1177        cygwin*)
1178           enable_gbm=no
1179           ;;
1180        *)
1181           enable_gbm=yes
1182           ;;
1183     esac])
1184 AC_ARG_ENABLE([nine],
1185     [AS_HELP_STRING([--enable-nine],
1186         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1187     [enable_nine="$enableval"],
1188     [enable_nine=no])
1189
1190 AC_ARG_ENABLE([xvmc],
1191    [AS_HELP_STRING([--enable-xvmc],
1192          [enable xvmc library @<:@default=auto@:>@])],
1193    [enable_xvmc="$enableval"],
1194    [enable_xvmc=auto])
1195 AC_ARG_ENABLE([vdpau],
1196    [AS_HELP_STRING([--enable-vdpau],
1197          [enable vdpau library @<:@default=auto@:>@])],
1198    [enable_vdpau="$enableval"],
1199    [enable_vdpau=auto])
1200 AC_ARG_ENABLE([omx],
1201    [AS_HELP_STRING([--enable-omx],
1202          [enable OpenMAX library @<:@default=disabled@:>@])],
1203    [enable_omx="$enableval"],
1204    [enable_omx=no])
1205 AC_ARG_ENABLE([va],
1206    [AS_HELP_STRING([--enable-va],
1207          [enable va library @<:@default=auto@:>@])],
1208    [enable_va="$enableval"],
1209    [enable_va=auto])
1210 AC_ARG_ENABLE([opencl],
1211    [AS_HELP_STRING([--enable-opencl],
1212          [enable OpenCL library @<:@default=disabled@:>@])],
1213    [enable_opencl="$enableval"],
1214    [enable_opencl=no])
1215 AC_ARG_ENABLE([opencl_icd],
1216    [AS_HELP_STRING([--enable-opencl-icd],
1217           [Build an OpenCL ICD library to be loaded by an ICD implementation
1218            @<:@default=disabled@:>@])],
1219     [enable_opencl_icd="$enableval"],
1220     [enable_opencl_icd=no])
1221
1222 AC_ARG_ENABLE([gallium-tests],
1223     [AS_HELP_STRING([--enable-gallium-tests],
1224         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1225     [enable_gallium_tests="$enableval"],
1226     [enable_gallium_tests=no])
1227
1228 # Option for Gallium drivers
1229
1230 # Keep this in sync with the --with-gallium-drivers help string default value
1231 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1232
1233 AC_ARG_WITH([gallium-drivers],
1234     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1235         [comma delimited Gallium drivers list, e.g.
1236         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1237         @<:@default=r300,r600,svga,swrast@:>@])],
1238     [with_gallium_drivers="$withval"],
1239     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1240
1241 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1242 # here so that the script doesn't choke on an unknown driver name later.
1243 case "$with_gallium_drivers" in
1244     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1245     no) with_gallium_drivers='' ;;
1246 esac
1247
1248 if test "x$enable_opengl" = xno -a \
1249         "x$enable_gles1" = xno -a \
1250         "x$enable_gles2" = xno -a \
1251         "x$enable_nine" = xno -a \
1252         "x$enable_xa" = xno -a \
1253         "x$enable_xvmc" = xno -a \
1254         "x$enable_vdpau" = xno -a \
1255         "x$enable_omx" = xno -a \
1256         "x$enable_va" = xno -a \
1257         "x$enable_opencl" = xno; then
1258     AC_MSG_ERROR([at least one API should be enabled])
1259 fi
1260
1261 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1262 if test "x$enable_opengl" = xno -a \
1263         "x$enable_gles1" = xyes; then
1264     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1265 fi
1266
1267 if test "x$enable_opengl" = xno -a \
1268         "x$enable_gles2" = xyes; then
1269     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1270 fi
1271
1272 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1273 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1274 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1275 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1276                                         "x$enable_gles1" = xyes -o \
1277                                         "x$enable_gles2" = xyes)
1278
1279 # Validate GLX options
1280 if test "x$enable_glx" = xyes; then
1281     if test "x$enable_dri" = xyes; then
1282         enable_glx=dri
1283     elif test -n "$with_gallium_drivers"; then
1284         enable_glx=gallium-xlib
1285     else
1286         enable_glx=xlib
1287     fi
1288 fi
1289 case "x$enable_glx" in
1290 xdri | xxlib | xgallium-xlib)
1291     # GLX requires OpenGL
1292     if test "x$enable_opengl" = xno; then
1293         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1294     fi
1295
1296     # Check individual dependencies
1297     case "x$enable_glx" in
1298     xdri)
1299         if test "x$enable_dri" = xno; then
1300             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1301         fi
1302         ;;
1303     xxlib)
1304         if test "x$enable_dri" = xyes; then
1305             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1306         fi
1307         ;;
1308     xgallium-xlib )
1309         if test "x$enable_dri" = xyes; then
1310             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1311         fi
1312         if test -z "$with_gallium_drivers"; then
1313             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1314         fi
1315         ;;
1316     esac
1317     ;;
1318 xno)
1319     ;;
1320 *)
1321     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1322     ;;
1323 esac
1324
1325 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1326 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1327 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1328 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1329
1330 dnl
1331 dnl Libglvnd configuration
1332 dnl
1333 AC_ARG_ENABLE([libglvnd],
1334     [AS_HELP_STRING([--enable-libglvnd],
1335         [Build for libglvnd @<:@default=disabled@:>@])],
1336     [enable_libglvnd="$enableval"],
1337     [enable_libglvnd=no])
1338 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1339 if test "x$enable_libglvnd" = xyes ; then
1340     dnl XXX: update once we can handle more than libGL/glx.
1341     dnl Namely: we should error out if neither of the glvnd enabled libraries
1342     dnl are built
1343     case "x$enable_glx" in
1344     xno)
1345         AC_MSG_ERROR([cannot build libglvnd without GLX])
1346         ;;
1347     xxlib | xgallium-xlib )
1348         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1349         ;;
1350     xdri)
1351         ;;
1352     esac
1353
1354     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1355     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1356     DEFAULT_GL_LIB_NAME=GLX_mesa
1357 fi
1358
1359 # Check for libdrm
1360 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1361                   [have_libdrm=yes], [have_libdrm=no])
1362 if test "x$have_libdrm" = xyes; then
1363         DEFINES="$DEFINES -DHAVE_LIBDRM"
1364 fi
1365
1366 require_libdrm() {
1367     if test "x$have_libdrm" != xyes; then
1368        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1369     fi
1370 }
1371
1372
1373 # Select which platform-dependent DRI code gets built
1374 case "$host_os" in
1375 darwin*)
1376     dri_platform='apple' ;;
1377 cygwin*)
1378     dri_platform='windows' ;;
1379 gnu*)
1380     dri_platform='none' ;;
1381 *)
1382     dri_platform='drm' ;;
1383 esac
1384
1385 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1386     have_drisw_kms='yes'
1387 fi
1388
1389 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1390 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1391 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1392 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1393 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1394 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1395 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1396 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1397 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1398
1399 AC_ARG_ENABLE([shared-glapi],
1400     [AS_HELP_STRING([--enable-shared-glapi],
1401         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1402     [enable_shared_glapi="$enableval"],
1403     [enable_shared_glapi=yes])
1404
1405 case "x$enable_opengl$enable_gles1$enable_gles2" in
1406 x*yes*yes*)
1407     if test "x$enable_shared_glapi" = xno; then
1408         AC_MSG_ERROR([shared GLAPI required when building two or more of
1409                       the following APIs - opengl, gles1 gles2])
1410     fi
1411     ;;
1412 esac
1413
1414 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1415
1416 # Build the pipe-drivers as separate libraries/modules.
1417 # Do not touch this unless you know what you are doing.
1418 # XXX: Expose via configure option ?
1419 enable_shared_pipe_drivers=no
1420
1421 dnl
1422 dnl Driver specific build directories
1423 dnl
1424
1425 if test "x$enable_gallium_osmesa" = xyes; then
1426     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1427         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1428     fi
1429     if test "x$enable_osmesa" = xyes; then
1430         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1431     fi
1432 fi
1433
1434 # SHA1 hashing
1435 AC_ARG_WITH([sha1],
1436         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1437         [choose SHA1 implementation])])
1438 case "x$with_sha1" in
1439 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1440   ;;
1441 *)
1442         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1443 esac
1444
1445 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1446 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1447         with_sha1=libc
1448 fi
1449 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1450         AC_MSG_ERROR([sha1 in libc requested but not found])
1451 fi
1452 if test "x$with_sha1" = xlibc; then
1453         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1454                 [Use libc SHA1 functions])
1455         SHA1_LIBS=""
1456 fi
1457 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1458 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1459         with_sha1=CommonCrypto
1460 fi
1461 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1462         AC_MSG_ERROR([CommonCrypto requested but not found])
1463 fi
1464 if test "x$with_sha1" = xCommonCrypto; then
1465         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1466                 [Use CommonCrypto SHA1 functions])
1467         SHA1_LIBS=""
1468 fi
1469 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1470 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1471 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1472         with_sha1=CryptoAPI
1473 fi
1474 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1475         AC_MSG_ERROR([CryptoAPI requested but not found])
1476 fi
1477 if test "x$with_sha1" = xCryptoAPI; then
1478         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1479                 [Use CryptoAPI SHA1 functions])
1480         SHA1_LIBS=""
1481 fi
1482 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1483 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1484         with_sha1=libmd
1485 fi
1486 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1487         AC_MSG_ERROR([libmd requested but not found])
1488 fi
1489 if test "x$with_sha1" = xlibmd; then
1490         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1491                   [Use libmd SHA1 functions])
1492         SHA1_LIBS=-lmd
1493 fi
1494 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1495 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1496    with_sha1=libsha1
1497 fi
1498 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1499         AC_MSG_ERROR([libsha1 requested but not found])
1500 fi
1501 if test "x$with_sha1" = xlibsha1; then
1502         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1503                   [Use libsha1 for SHA1])
1504         SHA1_LIBS=-lsha1
1505 fi
1506 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1507 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1508         with_sha1=libnettle
1509 fi
1510 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1511         AC_MSG_ERROR([libnettle requested but not found])
1512 fi
1513 if test "x$with_sha1" = xlibnettle; then
1514         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1515                   [Use libnettle SHA1 functions])
1516         SHA1_LIBS=-lnettle
1517 fi
1518 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1519 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1520         with_sha1=libgcrypt
1521 fi
1522 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1523         AC_MSG_ERROR([libgcrypt requested but not found])
1524 fi
1525 if test "x$with_sha1" = xlibgcrypt; then
1526         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1527                   [Use libgcrypt SHA1 functions])
1528         SHA1_LIBS=-lgcrypt
1529 fi
1530 # We don't need all of the OpenSSL libraries, just libcrypto
1531 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1532 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1533                   [HAVE_OPENSSL_PKC=no])
1534 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1535         if test "x$with_sha1" = x; then
1536                 with_sha1=libcrypto
1537         fi
1538 else
1539         if test "x$with_sha1" = xlibcrypto; then
1540                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1541         fi
1542 fi
1543 if test "x$with_sha1" = xlibcrypto; then
1544         if test "x$HAVE_LIBCRYPTO" = xyes; then
1545                 SHA1_LIBS=-lcrypto
1546         else
1547                 SHA1_LIBS="$OPENSSL_LIBS"
1548                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1549         fi
1550 fi
1551 AC_MSG_CHECKING([for SHA1 implementation])
1552 AC_MSG_RESULT([$with_sha1])
1553 AC_SUBST(SHA1_LIBS)
1554 AC_SUBST(SHA1_CFLAGS)
1555
1556 # Enable a define for SHA1
1557 if test "x$with_sha1" != "x"; then
1558         DEFINES="$DEFINES -DHAVE_SHA1"
1559 fi
1560
1561 # Allow user to configure out the shader-cache feature
1562 AC_ARG_ENABLE([shader-cache],
1563     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1564     [enable_shader_cache="$enableval"],
1565     [if test "x$with_sha1" != "x"; then
1566         enable_shader_cache=yes
1567      else
1568         enable_shader_cache=no
1569      fi])
1570 if test "x$with_sha1" = "x"; then
1571     if test "x$enable_shader_cache" = "xyes"; then
1572         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1573     fi
1574 fi
1575 if test "x$enable_shader_cache" = "xyes"; then
1576    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1577 fi
1578
1579 if test "x$enable_dri" = xyes; then
1580     if test "$enable_static" = yes; then
1581         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1582     fi
1583
1584     # not a hard requirement as swrast does not depend on it
1585     if test "x$have_libdrm" = xyes; then
1586         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1587     fi
1588 fi
1589
1590 AC_ARG_ENABLE([driglx-direct],
1591     [AS_HELP_STRING([--disable-driglx-direct],
1592         [disable direct rendering in GLX and EGL for DRI \
1593             @<:@default=auto@:>@])],
1594     [driglx_direct="$enableval"],
1595     [driglx_direct="yes"])
1596
1597 dnl
1598 dnl libGL configuration per driver
1599 dnl
1600 case "x$enable_glx" in
1601 xxlib | xgallium-xlib)
1602     # Xlib-based GLX
1603     dri_modules="x11 xext xcb"
1604     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1605     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1606     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1607     GL_LIB_DEPS="$XLIBGL_LIBS"
1608     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1609     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1610     ;;
1611 xdri)
1612     # DRI-based GLX
1613     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1614
1615     # find the DRI deps for libGL
1616     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1617
1618     if test x"$driglx_direct" = xyes; then
1619         if test x"$dri_platform" = xdrm ; then
1620             DEFINES="$DEFINES -DGLX_USE_DRM"
1621             require_libdrm "Direct rendering"
1622
1623             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1624             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1625             if test x"$enable_dri3" = xyes; then
1626                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1627                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1628             fi
1629
1630             if test x"$enable_dri" = xyes; then
1631                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1632             fi
1633
1634             if test x"$enable_dri3" = xyes; then
1635                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1636                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1637                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1638             fi
1639         fi
1640         if test x"$dri_platform" = xapple ; then
1641             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1642         fi
1643         if test x"$dri_platform" = xwindows ; then
1644             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1645         fi
1646     fi
1647
1648     # add xf86vidmode if available
1649     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1650     if test "$HAVE_XF86VIDMODE" = yes ; then
1651         dri_modules="$dri_modules xxf86vm"
1652     fi
1653
1654     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1655     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1656     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1657     GL_LIB_DEPS="$DRIGL_LIBS"
1658
1659     # need DRM libs, $PTHREAD_LIBS, etc.
1660     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1661     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1662     ;;
1663 esac
1664
1665 # This is outside the case (above) so that it is invoked even for non-GLX
1666 # builds.
1667 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1668
1669 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1670 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1671 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1672 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1673
1674 AC_SUBST([X11_INCLUDES])
1675 AC_SUBST([GL_LIB_DEPS])
1676 AC_SUBST([GL_PC_REQ_PRIV])
1677 AC_SUBST([GL_PC_LIB_PRIV])
1678 AC_SUBST([GL_PC_CFLAGS])
1679 AC_SUBST([DRI_PC_REQ_PRIV])
1680 AC_SUBST([GLESv1_CM_LIB_DEPS])
1681 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1682 AC_SUBST([GLESv2_LIB_DEPS])
1683 AC_SUBST([GLESv2_PC_LIB_PRIV])
1684
1685 AC_SUBST([HAVE_XF86VIDMODE])
1686
1687 dnl
1688 dnl More GLX setup
1689 dnl
1690 case "x$enable_glx" in
1691 xxlib | xgallium-xlib)
1692     DEFINES="$DEFINES -DUSE_XSHM"
1693     ;;
1694 xdri)
1695     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1696     if test "x$driglx_direct" = xyes; then
1697         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1698     fi
1699     ;;
1700 esac
1701
1702 dnl
1703 dnl TLS detection
1704 dnl
1705
1706 AC_ARG_ENABLE([glx-tls],
1707     [AS_HELP_STRING([--enable-glx-tls],
1708         [enable TLS support in GLX @<:@default=enabled@:>@])],
1709     [GLX_USE_TLS="$enableval"],
1710     [GLX_USE_TLS=yes])
1711 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1712
1713 if test "x$GLX_USE_TLS" = xyes; then
1714     DEFINES="$DEFINES -DGLX_USE_TLS"
1715 fi
1716
1717 dnl Read-only text section on x86 hardened platforms
1718 AC_ARG_ENABLE([glx-read-only-text],
1719     [AS_HELP_STRING([--enable-glx-read-only-text],
1720         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1721     [enable_glx_read_only_text="$enableval"],
1722     [enable_glx_read_only_text=no])
1723 if test "x$enable_glx_read_only_text" = xyes; then
1724     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1725 fi
1726
1727 dnl
1728 dnl More DRI setup
1729 dnl
1730 dnl Directory for DRI drivers
1731 AC_ARG_WITH([dri-driverdir],
1732     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1733         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1734     [DRI_DRIVER_INSTALL_DIR="$withval"],
1735     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1736 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1737 dnl Extra search path for DRI drivers
1738 AC_ARG_WITH([dri-searchpath],
1739     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1740         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1741     [DRI_DRIVER_SEARCH_DIR="$withval"],
1742     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1743 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1744 dnl Which drivers to build - default is chosen by platform
1745 AC_ARG_WITH([dri-drivers],
1746     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1747         [comma delimited classic DRI drivers list, e.g.
1748         "swrast,i965,radeon" @<:@default=auto@:>@])],
1749     [with_dri_drivers="$withval"],
1750     [with_dri_drivers=auto])
1751
1752 if test "x$with_dri_drivers" = xauto; then
1753     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1754         with_dri_drivers="yes"
1755     else
1756         with_dri_drivers="no"
1757     fi
1758 fi
1759 if test "x$with_dri_drivers" = xno; then
1760     with_dri_drivers=''
1761 fi
1762
1763 dnl If $with_dri_drivers is yes, drivers will be added through
1764 dnl platform checks. Set DEFINES and LIB_DEPS
1765 if test "x$enable_dri" = xyes; then
1766     # Platform specific settings and drivers to build
1767     case "$host_os" in
1768     linux*)
1769         DEFINES="$DEFINES -DHAVE_ALIAS"
1770         if test "x$enable_dri3" = xyes; then
1771             DEFINES="$DEFINES -DHAVE_DRI3"
1772         fi
1773
1774         case "$host_cpu" in
1775         powerpc* | sparc*)
1776             # Build only the drivers for cards that exist on PowerPC/sparc
1777             if test "x$with_dri_drivers" = "xyes"; then
1778                 with_dri_drivers="r200 radeon swrast"
1779             fi
1780             ;;
1781         esac
1782         ;;
1783     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1784         DEFINES="$DEFINES -DHAVE_ALIAS"
1785         ;;
1786     gnu*)
1787         DEFINES="$DEFINES -DHAVE_ALIAS"
1788         ;;
1789     cygwin*)
1790         if test "x$with_dri_drivers" = "xyes"; then
1791             with_dri_drivers="swrast"
1792         fi
1793         ;;
1794     darwin*)
1795         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1796         if test "x$with_dri_drivers" = "xyes"; then
1797             with_dri_drivers="swrast"
1798         fi
1799         ;;
1800     esac
1801
1802     # default drivers
1803     if test "x$with_dri_drivers" = "xyes"; then
1804         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1805     fi
1806
1807     # Check for expat
1808     PKG_CHECK_MODULES([EXPAT], [expat], [],
1809         # expat version 2.0 and earlier do not provide expat.pc
1810         [AC_CHECK_HEADER([expat.h],[],
1811                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1812          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1813                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1814          EXPAT_LIBS="-lexpat"])
1815
1816     # put all the necessary libs together
1817     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1818 fi
1819
1820 AC_SUBST([DRI_LIB_DEPS])
1821
1822 DRI_DIRS=''
1823 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1824 if test -n "$with_dri_drivers"; then
1825     if test "x$enable_opengl" != xyes; then
1826         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1827     fi
1828
1829     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1830     for driver in $dri_drivers; do
1831         DRI_DIRS="$DRI_DIRS $driver"
1832         case "x$driver" in
1833         xi915)
1834             HAVE_I915_DRI=yes;
1835             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1836             ;;
1837         xi965)
1838             HAVE_I965_DRI=yes;
1839             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1840             ;;
1841         xnouveau)
1842             HAVE_NOUVEAU_DRI=yes;
1843             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1844             ;;
1845         xradeon)
1846             HAVE_RADEON_DRI=yes;
1847             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1848             ;;
1849         xr200)
1850             HAVE_R200_DRI=yes;
1851             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1852             ;;
1853         xswrast)
1854             HAVE_SWRAST_DRI=yes;
1855             ;;
1856         *)
1857             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1858             ;;
1859         esac
1860     done
1861     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1862 fi
1863
1864
1865 #
1866 # Vulkan driver configuration
1867 #
1868
1869 AC_ARG_WITH([vulkan-drivers],
1870     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1871         [comma delimited Vulkan drivers list, e.g.
1872         "intel"
1873         @<:@default=no@:>@])],
1874     [with_vulkan_drivers="$withval"],
1875     [with_vulkan_drivers="no"])
1876
1877 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1878 # here so that the script doesn't choke on an unknown driver name later.
1879 case "x$with_vulkan_drivers" in
1880     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1881     xno) with_vulkan_drivers='' ;;
1882 esac
1883
1884 AC_ARG_WITH([vulkan-icddir],
1885     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1886         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1887     [VULKAN_ICD_INSTALL_DIR="$withval"],
1888     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1889 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1890
1891 if test -n "$with_vulkan_drivers"; then
1892     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1893     for driver in $VULKAN_DRIVERS; do
1894         case "x$driver" in
1895         xintel)
1896             if test "x$HAVE_I965_DRI" != xyes; then
1897                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1898             fi
1899             if test "x$with_sha1" == "x"; then
1900                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1901             fi
1902             HAVE_INTEL_VULKAN=yes;
1903
1904             ;;
1905         xradeon)
1906             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1907             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1908             HAVE_RADEON_VULKAN=yes;
1909             if test "x$with_sha1" == "x"; then
1910                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1911             fi
1912             ;;
1913         *)
1914             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1915             ;;
1916         esac
1917     done
1918     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1919 fi
1920
1921
1922 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1923 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1924                                   "x$enable_osmesa" = xyes -o \
1925                                   -n "$DRI_DIRS")
1926
1927 dnl
1928 dnl OSMesa configuration
1929 dnl
1930
1931 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1932 AC_ARG_WITH([osmesa-bits],
1933     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1934         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1935     [osmesa_bits="$withval"],
1936     [osmesa_bits=8])
1937 if test "x$osmesa_bits" != x8; then
1938     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1939         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1940         osmesa_bits=8
1941     fi
1942 fi
1943 case "x$osmesa_bits" in
1944 x8)
1945     OSMESA_LIB="${OSMESA_LIB}"
1946     ;;
1947 x16|x32)
1948     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1949     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1950     ;;
1951 *)
1952     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1953     ;;
1954 esac
1955
1956 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1957     # only link libraries with osmesa if shared
1958     if test "$enable_static" = no; then
1959         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1960     else
1961         OSMESA_LIB_DEPS=""
1962     fi
1963     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1964 fi
1965
1966 AC_SUBST([OSMESA_LIB_DEPS])
1967 AC_SUBST([OSMESA_PC_REQ])
1968 AC_SUBST([OSMESA_PC_LIB_PRIV])
1969
1970 dnl
1971 dnl gbm configuration
1972 dnl
1973 if test "x$enable_gbm" = xyes; then
1974     if test "x$enable_dri" = xyes; then
1975         if test "x$enable_shared_glapi" = xno; then
1976             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1977         fi
1978     else
1979         # Strictly speaking libgbm does not require --enable-dri, although
1980         # both of its backends do. Thus one can build libgbm without any
1981         # backends if --disable-dri is set.
1982         # To avoid unnecessary complexity of checking if at least one backend
1983         # is available when building, just mandate --enable-dri.
1984         AC_MSG_ERROR([gbm requires --enable-dri])
1985     fi
1986 fi
1987 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1988 # FINISHME: GBM has a number of dependencies which we should add below
1989 GBM_PC_REQ_PRIV=""
1990 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1991 AC_SUBST([GBM_PC_REQ_PRIV])
1992 AC_SUBST([GBM_PC_LIB_PRIV])
1993
1994 dnl
1995 dnl EGL configuration
1996 dnl
1997 EGL_CLIENT_APIS=""
1998
1999 if test "x$enable_egl" = xyes; then
2000     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2001
2002     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2003
2004     if test "$enable_static" != yes; then
2005         if test "x$enable_dri" = xyes; then
2006             HAVE_EGL_DRIVER_DRI2=1
2007             if test "x$enable_shared_glapi" = xno; then
2008                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
2009             fi
2010             if test "x$enable_dri3" = xyes; then
2011                 HAVE_EGL_DRIVER_DRI3=1
2012                 if test "x$enable_shared_glapi" = xno; then
2013                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
2014                 fi
2015             fi
2016         else
2017             # Avoid building an "empty" libEGL. Drop/update this
2018             # when other backends (haiku?) come along.
2019             AC_MSG_ERROR([egl requires --enable-dri])
2020         fi
2021
2022     fi
2023 fi
2024 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2025 AC_SUBST([EGL_LIB_DEPS])
2026
2027 gallium_st="mesa"
2028
2029 dnl
2030 dnl XA configuration
2031 dnl
2032 if test "x$enable_xa" = xyes; then
2033     if test "x$with_gallium_drivers" = xswrast; then
2034        AC_MSG_ERROR([
2035           Building xa requires at least one non swrast gallium driver.
2036           If you are looking to use libxatracker.so with the VMware driver,
2037           make sure to include svga in the gallium drivers list, apart from
2038           enabling XA.
2039           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2040     fi
2041     gallium_st="$gallium_st xa"
2042 fi
2043 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2044
2045 dnl
2046 dnl Gallium G3DVL configuration
2047 dnl
2048 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2049     if test "x$enable_xvmc" = xauto; then
2050         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2051     fi
2052
2053     if test "x$enable_vdpau" = xauto; then
2054         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2055     fi
2056
2057     if test "x$enable_omx" = xauto; then
2058         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2059     fi
2060
2061     if test "x$enable_va" = xauto; then
2062         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2063     fi
2064 fi
2065
2066 if test "x$enable_dri" = xyes -o \
2067         "x$enable_xvmc" = xyes -o \
2068         "x$enable_vdpau" = xyes -o \
2069         "x$enable_omx" = xyes -o \
2070         "x$enable_va" = xyes; then
2071     need_gallium_vl=yes
2072 fi
2073 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2074
2075 if test "x$enable_xvmc" = xyes -o \
2076         "x$enable_vdpau" = xyes -o \
2077         "x$enable_omx" = xyes -o \
2078         "x$enable_va" = xyes; then
2079     if test x"$enable_dri3" = xyes; then
2080         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2081                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2082     else
2083         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2084     fi
2085     need_gallium_vl_winsys=yes
2086 fi
2087 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2088
2089 if test "x$enable_xvmc" = xyes; then
2090     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2091     gallium_st="$gallium_st xvmc"
2092 fi
2093 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2094
2095 if test "x$enable_vdpau" = xyes; then
2096     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2097     gallium_st="$gallium_st vdpau"
2098     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2099 fi
2100 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2101
2102 if test "x$enable_omx" = xyes; then
2103     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2104     gallium_st="$gallium_st omx"
2105 fi
2106 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2107
2108 if test "x$enable_va" = xyes; then
2109     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2110     gallium_st="$gallium_st va"
2111 fi
2112 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2113
2114 dnl
2115 dnl Nine Direct3D9 configuration
2116 dnl
2117 if test "x$enable_nine" = xyes; then
2118     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2119         AC_MSG_ERROR([nine requires the gallium swrast driver])
2120     fi
2121     if test "x$with_gallium_drivers" = xswrast; then
2122         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2123     fi
2124     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2125         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2126     fi
2127
2128     if test "x$enable_dri3" = xno; then
2129         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2130     fi
2131
2132     gallium_st="$gallium_st nine"
2133 fi
2134 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2135
2136 dnl
2137 dnl OpenCL configuration
2138 dnl
2139
2140 AC_ARG_WITH([clang-libdir],
2141    [AS_HELP_STRING([--with-clang-libdir],
2142          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2143    [CLANG_LIBDIR="$withval"],
2144    [CLANG_LIBDIR=''])
2145
2146 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2147
2148 if test "x$enable_opencl" = xyes; then
2149     if test -z "$with_gallium_drivers"; then
2150         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2151     fi
2152
2153     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2154         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2155     fi
2156
2157     if test "x$have_libclc" = xno; then
2158         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2159                     Make sure the directory containing libclc.pc is specified in your
2160                     PKG_CONFIG_PATH environment variable.
2161                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2162     else
2163         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2164         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2165         AC_SUBST([LIBCLC_INCLUDEDIR])
2166         AC_SUBST([LIBCLC_LIBEXECDIR])
2167     fi
2168
2169     gallium_st="$gallium_st clover"
2170
2171     if test "x$enable_opencl_icd" = xyes; then
2172         OPENCL_LIBNAME="MesaOpenCL"
2173     else
2174         OPENCL_LIBNAME="OpenCL"
2175     fi
2176
2177     if test "x$have_libelf" != xyes; then
2178        AC_MSG_ERROR([Clover requires libelf])
2179     fi
2180
2181     llvm_check_version_for $LLVM_REQUIRED_OPENCL "opencl"
2182
2183     llvm_add_default_components "opencl"
2184     llvm_add_component "all-targets" "opencl"
2185     llvm_add_component "linker" "opencl"
2186     llvm_add_component "instrumentation" "opencl"
2187     llvm_add_component "ipo" "opencl"
2188     llvm_add_component "irreader" "opencl"
2189     llvm_add_component "option" "opencl"
2190     llvm_add_component "objcarcopts" "opencl"
2191     llvm_add_component "profiledata" "opencl"
2192
2193     dnl Check for Clang internal headers
2194     if test -z "$CLANG_LIBDIR"; then
2195         CLANG_LIBDIR=${LLVM_LIBDIR}
2196     fi
2197     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2198     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2199         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2200 fi
2201 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2202 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2203 AC_SUBST([OPENCL_LIBNAME])
2204 AC_SUBST([CLANG_RESOURCE_DIR])
2205
2206 dnl
2207 dnl Gallium configuration
2208 dnl
2209 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2210
2211 case "x$enable_opengl$enable_gles1$enable_gles2" in
2212 x*yes*)
2213     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2214     ;;
2215 esac
2216
2217 AC_SUBST([VG_LIB_DEPS])
2218 AC_SUBST([EGL_CLIENT_APIS])
2219
2220 dnl
2221 dnl EGL Platforms configuration
2222 dnl
2223 AC_ARG_WITH([egl-platforms],
2224     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2225         [comma delimited native platforms libEGL supports, e.g.
2226         "x11,drm" @<:@default=auto@:>@])],
2227     [with_egl_platforms="$withval"],
2228     [if test "x$enable_egl" = xyes; then
2229         if test "x$enable_gbm" = xyes; then
2230            with_egl_platforms="x11,drm"
2231         else
2232            with_egl_platforms="x11"
2233         fi
2234     else
2235         with_egl_platforms=""
2236     fi])
2237
2238 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2239     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2240 fi
2241
2242 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2243         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2244         WAYLAND_SCANNER='')
2245 if test "x$WAYLAND_SCANNER" = x; then
2246     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2247 fi
2248
2249 # Do per-EGL platform setups and checks
2250 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2251 for plat in $egl_platforms; do
2252         case "$plat" in
2253         wayland)
2254
2255                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2256
2257                 if test "x$WAYLAND_SCANNER" = x; then
2258                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2259                 fi
2260                 ;;
2261
2262         x11)
2263                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2264                 ;;
2265
2266         drm)
2267                 test "x$enable_gbm" = "xno" &&
2268                         AC_MSG_ERROR([EGL platform drm needs gbm])
2269                 ;;
2270
2271         surfaceless)
2272                 ;;
2273
2274         android)
2275                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2276                 ;;
2277
2278         *)
2279                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2280                 ;;
2281         esac
2282
2283         case "$plat" in
2284         wayland|drm|surfaceless)
2285                 require_libdrm "Platform $plat"
2286                 ;;
2287         esac
2288 done
2289
2290 # libEGL wants to default to the first platform specified in
2291 # ./configure.  parse that here.
2292 if test "x$egl_platforms" != "x"; then
2293     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2294     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2295 else
2296     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2297 fi
2298
2299 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2300 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2301 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2302 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2303 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2304
2305 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2306
2307 AC_SUBST([EGL_NATIVE_PLATFORM])
2308 AC_SUBST([EGL_CFLAGS])
2309
2310 # If we don't have the X11 platform, set this define so we don't try to include
2311 # the X11 headers.
2312 if ! echo "$egl_platforms" | grep -q 'x11'; then
2313     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2314     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2315 fi
2316
2317 dnl
2318 dnl Gallium LLVM
2319 dnl
2320 AC_ARG_ENABLE([gallium-llvm],
2321     [AS_HELP_STRING([--enable-gallium-llvm],
2322         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2323     [enable_gallium_llvm="$enableval"],
2324     [enable_gallium_llvm=auto])
2325
2326 if test -z "$with_gallium_drivers"; then
2327     enable_gallium_llvm=no
2328 fi
2329 if test "x$enable_gallium_llvm" = xauto; then
2330     case "$host_cpu" in
2331     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2332     esac
2333 fi
2334
2335 dnl Directory for XVMC libs
2336 AC_ARG_WITH([xvmc-libdir],
2337     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2338         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2339     [XVMC_LIB_INSTALL_DIR="$withval"],
2340     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2341 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2342
2343 dnl
2344 dnl Gallium Tests
2345 dnl
2346 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2347
2348 dnl Directory for VDPAU libs
2349 AC_ARG_WITH([vdpau-libdir],
2350     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2351         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2352     [VDPAU_LIB_INSTALL_DIR="$withval"],
2353     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2354 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2355
2356 dnl Directory for OMX libs
2357
2358 AC_ARG_WITH([omx-libdir],
2359     [AS_HELP_STRING([--with-omx-libdir=DIR],
2360         [directory for the OMX libraries])],
2361     [OMX_LIB_INSTALL_DIR="$withval"],
2362     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2363 AC_SUBST([OMX_LIB_INSTALL_DIR])
2364
2365 dnl Directory for VA libs
2366
2367 AC_ARG_WITH([va-libdir],
2368     [AS_HELP_STRING([--with-va-libdir=DIR],
2369         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2370     [VA_LIB_INSTALL_DIR="$withval"],
2371     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2372 AC_SUBST([VA_LIB_INSTALL_DIR])
2373
2374 AC_ARG_WITH([d3d-libdir],
2375     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2376         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2377     [D3D_DRIVER_INSTALL_DIR="$withval"],
2378     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2379 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2380
2381 dnl
2382 dnl Gallium helper functions
2383 dnl
2384 gallium_require_llvm() {
2385     if test "x$enable_gallium_llvm" = "xyes"; then
2386         llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2387     else
2388         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2389     fi
2390 }
2391
2392 dnl
2393 dnl DRM is needed by X, Wayland, and offscreen rendering.
2394 dnl Surfaceless is an alternative for the last one.
2395 dnl
2396 require_basic_egl() {
2397     case "$with_egl_platforms" in
2398         *drm*|*surfaceless*)
2399             ;;
2400         *)
2401             AC_MSG_ERROR([$1 requires one of these:
2402                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2403                   2) --with-egl-platforms=surfaceless (offscreen only)
2404                   Recommended options: drm,x11])
2405             ;;
2406     esac
2407 }
2408
2409 radeon_gallium_llvm_check() {
2410     if test "x$enable_gallium_llvm" != "xyes"; then
2411         AC_MSG_ERROR([--enable-gallium-llvm is required when building $2])
2412     fi
2413     radeon_llvm_check $*
2414 }
2415
2416 swr_require_cxx_feature_flags() {
2417     feature_name="$1"
2418     preprocessor_test="$2"
2419     option_list="$3"
2420     output_var="$4"
2421
2422     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2423     AC_LANG_PUSH([C++])
2424     save_CXXFLAGS="$CXXFLAGS"
2425     save_IFS="$IFS"
2426     IFS=","
2427     found=0
2428     for opts in $option_list
2429     do
2430         unset IFS
2431         CXXFLAGS="$opts $save_CXXFLAGS"
2432         AC_COMPILE_IFELSE(
2433             [AC_LANG_PROGRAM(
2434                 [   #if !($preprocessor_test)
2435                     #error
2436                     #endif
2437                 ])],
2438             [found=1; break],
2439             [])
2440         IFS=","
2441     done
2442     IFS="$save_IFS"
2443     CXXFLAGS="$save_CXXFLAGS"
2444     AC_LANG_POP([C++])
2445     if test $found -eq 1; then
2446         AC_MSG_RESULT([$opts])
2447         eval "$output_var=\$opts"
2448         return 0
2449     fi
2450     AC_MSG_RESULT([no])
2451     AC_MSG_ERROR([swr requires $feature_name support])
2452     return 1
2453 }
2454
2455 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2456 if test -n "$with_gallium_drivers"; then
2457     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2458     for driver in $gallium_drivers; do
2459         case "x$driver" in
2460         xsvga)
2461             HAVE_GALLIUM_SVGA=yes
2462             require_libdrm "svga"
2463             ;;
2464         xi915)
2465             HAVE_GALLIUM_I915=yes
2466             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2467             require_libdrm "Gallium i915"
2468             ;;
2469         xilo)
2470             HAVE_GALLIUM_ILO=yes
2471             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2472             require_libdrm "Gallium i965/ilo"
2473             ;;
2474         xr300)
2475             HAVE_GALLIUM_R300=yes
2476             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2477             require_libdrm "r300"
2478             gallium_require_llvm "r300"
2479             ;;
2480         xr600)
2481             HAVE_GALLIUM_R600=yes
2482             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2483             require_libdrm "r600"
2484             if test "x$enable_opencl" = xyes; then
2485                 radeon_gallium_llvm_check $LLVM_REQUIRED_R600 "r600"
2486
2487                 llvm_add_component "asmparser" "r600"
2488                 llvm_add_component "bitreader" "r600"
2489             fi
2490             ;;
2491         xradeonsi)
2492             HAVE_GALLIUM_RADEONSI=yes
2493             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2494             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2495             require_libdrm "radeonsi"
2496             radeon_gallium_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2497             require_basic_egl "radeonsi"
2498             ;;
2499         xnouveau)
2500             HAVE_GALLIUM_NOUVEAU=yes
2501             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2502             require_libdrm "nouveau"
2503             ;;
2504         xfreedreno)
2505             HAVE_GALLIUM_FREEDRENO=yes
2506             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2507             require_libdrm "freedreno"
2508             ;;
2509         xswrast)
2510             HAVE_GALLIUM_SOFTPIPE=yes
2511             if test "x$MESA_LLVM" = x1 && test "x$enable_gallium_llvm" == "xyes";  then
2512                 HAVE_GALLIUM_LLVMPIPE=yes
2513             fi
2514             ;;
2515         xswr)
2516             llvm_check_version_for $LLVM_REQUIRED_SWR "swr"
2517             gallium_require_llvm "swr"
2518
2519             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2520                 ",-std=c++11" \
2521                 SWR_CXX11_CXXFLAGS
2522             AC_SUBST([SWR_CXX11_CXXFLAGS])
2523
2524             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2525                 ",-mavx,-march=core-avx" \
2526                 SWR_AVX_CXXFLAGS
2527             AC_SUBST([SWR_AVX_CXXFLAGS])
2528
2529             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2530                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2531                 SWR_AVX2_CXXFLAGS
2532             AC_SUBST([SWR_AVX2_CXXFLAGS])
2533
2534             HAVE_GALLIUM_SWR=yes
2535             ;;
2536         xvc4)
2537             HAVE_GALLIUM_VC4=yes
2538             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2539             require_libdrm "vc4"
2540
2541             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2542                               [USE_VC4_SIMULATOR=yes;
2543                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2544                               [USE_VC4_SIMULATOR=no])
2545             ;;
2546         xvirgl)
2547             HAVE_GALLIUM_VIRGL=yes
2548             require_libdrm "virgl"
2549             require_basic_egl "virgl"
2550             ;;
2551         *)
2552             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2553             ;;
2554         esac
2555     done
2556 fi
2557
2558 if test "x$enable_gallium_llvm" == "xyes"; then
2559     llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2560     llvm_add_default_components "gallium"
2561 fi
2562
2563 dnl Set LLVM_LIBS - This is done after the driver configuration so
2564 dnl that drivers can add additional components to LLVM_COMPONENTS.
2565 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2566 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2567 dnl this was causing the same libraries to be appear multiple times
2568 dnl in LLVM_LIBS.
2569
2570 if test "x$MESA_LLVM" != x0; then
2571
2572     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2573        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2574     fi
2575     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2576
2577     dnl llvm-config may not give the right answer when llvm is a built as a
2578     dnl single shared library, so we must work the library name out for
2579     dnl ourselves.
2580     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2581     if test "x$enable_llvm_shared_libs" = xyes; then
2582         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2583         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2584         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2585
2586         if test "x$llvm_have_one_so" = xyes; then
2587             dnl LLVM was built using auto*, so there is only one shared object.
2588             LLVM_LIBS="-l$LLVM_SO_NAME"
2589         else
2590             dnl If LLVM was built with CMake, there will be one shared object per
2591             dnl component.
2592             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2593                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2594         Please make sure you have built llvm with the --enable-shared option
2595         and that your llvm libraries are installed in $LLVM_LIBDIR
2596         If you have installed your llvm libraries to a different directory you
2597         can use the --with-llvm-prefix= configure flag to specify this directory.
2598         NOTE: Mesa is attempting to use llvm shared libraries by default.
2599         If you do not want to build with llvm shared libraries and instead want to
2600         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2601         invocation and rebuild.])])
2602
2603            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2604            dnl install uses a shared object for each component and we have
2605            dnl already added all of these objects to LLVM_LIBS.
2606         fi
2607     else
2608         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2609         dnl We need to link to llvm system libs when using static libs
2610         dnl However, only llvm 3.5+ provides --system-libs
2611         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2612             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2613         fi
2614     fi
2615 fi
2616
2617 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2618 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2621 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2622 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2624                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2625 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2626 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2627 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2628 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2629 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2630 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2631                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2632                                          "x$HAVE_GALLIUM_SWR" = xyes)
2633 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2634 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2635
2636 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2637
2638 if test "x$enable_dri" = xyes; then
2639     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2640 fi
2641
2642 if test "x$have_drisw_kms" = xyes; then
2643     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2644 fi
2645 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2646
2647 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2648 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2649 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2650 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2651 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2652 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2653
2654 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2655 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2656
2657 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2658                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2659                                       "x$HAVE_RADEON_VULKAN" = xyes)
2660
2661 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2662                                         "x$HAVE_I965_DRI" = xyes)
2663
2664 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2665                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2666                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2667 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2668 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2669 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2670 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$MESA_LLVM" = x1 -a \
2671                                        "x$enable_gallium_llvm" = xyes)
2672 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2673 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2674     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2675 fi
2676
2677 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2678 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2679 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2680 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2681                                         "x$enable_gallium_osmesa" = xyes)
2682
2683 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2684 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2685 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2686
2687 AC_SUBST([NINE_MAJOR], 1)
2688 AC_SUBST([NINE_MINOR], 0)
2689 AC_SUBST([NINE_TINY], 0)
2690 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2691
2692 AC_SUBST([VDPAU_MAJOR], 1)
2693 AC_SUBST([VDPAU_MINOR], 0)
2694
2695 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2696 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2697 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2698 AC_SUBST([VA_MINOR], $VA_MINOR)
2699
2700 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2701
2702 AC_SUBST([XVMC_MAJOR], 1)
2703 AC_SUBST([XVMC_MINOR], 0)
2704
2705 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2706 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2707 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2708 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2709
2710 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2711 AC_SUBST([XA_MINOR], $XA_MINOR)
2712 AC_SUBST([XA_TINY], $XA_TINY)
2713 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2714
2715 AC_ARG_ENABLE(valgrind,
2716               [AS_HELP_STRING([--enable-valgrind],
2717                              [Build mesa with valgrind support (default: auto)])],
2718                              [VALGRIND=$enableval], [VALGRIND=auto])
2719 if test "x$VALGRIND" != xno; then
2720         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2721 fi
2722 AC_MSG_CHECKING([whether to enable Valgrind support])
2723 if test "x$VALGRIND" = xauto; then
2724         VALGRIND="$have_valgrind"
2725 fi
2726
2727 if test "x$VALGRIND" = "xyes"; then
2728         if ! test "x$have_valgrind" = xyes; then
2729                 AC_MSG_ERROR([Valgrind support required but not present])
2730         fi
2731         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2732 fi
2733
2734 AC_MSG_RESULT([$VALGRIND])
2735
2736 dnl Restore LDFLAGS and CPPFLAGS
2737 LDFLAGS="$_SAVE_LDFLAGS"
2738 CPPFLAGS="$_SAVE_CPPFLAGS"
2739
2740 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2741 if test "x$acv_mesa_CLANG" = xyes; then
2742     CFLAGS="$CFLAGS -Qunused-arguments"
2743     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2744 fi
2745
2746 dnl Add user CFLAGS and CXXFLAGS
2747 CFLAGS="$CFLAGS $USER_CFLAGS"
2748 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2749
2750 dnl Substitute the config
2751 AC_CONFIG_FILES([Makefile
2752                 src/Makefile
2753                 src/amd/Makefile
2754                 src/amd/vulkan/Makefile
2755                 src/compiler/Makefile
2756                 src/egl/Makefile
2757                 src/egl/main/egl.pc
2758                 src/egl/wayland/wayland-drm/Makefile
2759                 src/egl/wayland/wayland-egl/Makefile
2760                 src/egl/wayland/wayland-egl/wayland-egl.pc
2761                 src/gallium/Makefile
2762                 src/gallium/auxiliary/Makefile
2763                 src/gallium/auxiliary/pipe-loader/Makefile
2764                 src/gallium/drivers/freedreno/Makefile
2765                 src/gallium/drivers/ddebug/Makefile
2766                 src/gallium/drivers/i915/Makefile
2767                 src/gallium/drivers/ilo/Makefile
2768                 src/gallium/drivers/llvmpipe/Makefile
2769                 src/gallium/drivers/noop/Makefile
2770                 src/gallium/drivers/nouveau/Makefile
2771                 src/gallium/drivers/r300/Makefile
2772                 src/gallium/drivers/r600/Makefile
2773                 src/gallium/drivers/radeon/Makefile
2774                 src/gallium/drivers/radeonsi/Makefile
2775                 src/gallium/drivers/rbug/Makefile
2776                 src/gallium/drivers/softpipe/Makefile
2777                 src/gallium/drivers/svga/Makefile
2778                 src/gallium/drivers/swr/Makefile
2779                 src/gallium/drivers/trace/Makefile
2780                 src/gallium/drivers/vc4/Makefile
2781                 src/gallium/drivers/virgl/Makefile
2782                 src/gallium/state_trackers/clover/Makefile
2783                 src/gallium/state_trackers/dri/Makefile
2784                 src/gallium/state_trackers/glx/xlib/Makefile
2785                 src/gallium/state_trackers/nine/Makefile
2786                 src/gallium/state_trackers/omx/Makefile
2787                 src/gallium/state_trackers/osmesa/Makefile
2788                 src/gallium/state_trackers/va/Makefile
2789                 src/gallium/state_trackers/vdpau/Makefile
2790                 src/gallium/state_trackers/xa/Makefile
2791                 src/gallium/state_trackers/xvmc/Makefile
2792                 src/gallium/targets/d3dadapter9/Makefile
2793                 src/gallium/targets/d3dadapter9/d3d.pc
2794                 src/gallium/targets/dri/Makefile
2795                 src/gallium/targets/libgl-xlib/Makefile
2796                 src/gallium/targets/omx/Makefile
2797                 src/gallium/targets/opencl/Makefile
2798                 src/gallium/targets/opencl/mesa.icd
2799                 src/gallium/targets/osmesa/Makefile
2800                 src/gallium/targets/osmesa/osmesa.pc
2801                 src/gallium/targets/pipe-loader/Makefile
2802                 src/gallium/targets/va/Makefile
2803                 src/gallium/targets/vdpau/Makefile
2804                 src/gallium/targets/xa/Makefile
2805                 src/gallium/targets/xa/xatracker.pc
2806                 src/gallium/targets/xvmc/Makefile
2807                 src/gallium/tests/trivial/Makefile
2808                 src/gallium/tests/unit/Makefile
2809                 src/gallium/winsys/freedreno/drm/Makefile
2810                 src/gallium/winsys/i915/drm/Makefile
2811                 src/gallium/winsys/intel/drm/Makefile
2812                 src/gallium/winsys/nouveau/drm/Makefile
2813                 src/gallium/winsys/radeon/drm/Makefile
2814                 src/gallium/winsys/amdgpu/drm/Makefile
2815                 src/gallium/winsys/svga/drm/Makefile
2816                 src/gallium/winsys/sw/dri/Makefile
2817                 src/gallium/winsys/sw/kms-dri/Makefile
2818                 src/gallium/winsys/sw/null/Makefile
2819                 src/gallium/winsys/sw/wrapper/Makefile
2820                 src/gallium/winsys/sw/xlib/Makefile
2821                 src/gallium/winsys/vc4/drm/Makefile
2822                 src/gallium/winsys/virgl/drm/Makefile
2823                 src/gallium/winsys/virgl/vtest/Makefile
2824                 src/gbm/Makefile
2825                 src/gbm/main/gbm.pc
2826                 src/glx/Makefile
2827                 src/glx/apple/Makefile
2828                 src/glx/tests/Makefile
2829                 src/glx/windows/Makefile
2830                 src/glx/windows/windowsdriproto.pc
2831                 src/gtest/Makefile
2832                 src/intel/Makefile
2833                 src/intel/tools/Makefile
2834                 src/intel/vulkan/Makefile
2835                 src/loader/Makefile
2836                 src/mapi/Makefile
2837                 src/mapi/es1api/glesv1_cm.pc
2838                 src/mapi/es2api/glesv2.pc
2839                 src/mapi/glapi/gen/Makefile
2840                 src/mesa/Makefile
2841                 src/mesa/gl.pc
2842                 src/mesa/drivers/dri/dri.pc
2843                 src/mesa/drivers/dri/common/Makefile
2844                 src/mesa/drivers/dri/common/xmlpool/Makefile
2845                 src/mesa/drivers/dri/i915/Makefile
2846                 src/mesa/drivers/dri/i965/Makefile
2847                 src/mesa/drivers/dri/Makefile
2848                 src/mesa/drivers/dri/nouveau/Makefile
2849                 src/mesa/drivers/dri/r200/Makefile
2850                 src/mesa/drivers/dri/radeon/Makefile
2851                 src/mesa/drivers/dri/swrast/Makefile
2852                 src/mesa/drivers/osmesa/Makefile
2853                 src/mesa/drivers/osmesa/osmesa.pc
2854                 src/mesa/drivers/x11/Makefile
2855                 src/mesa/main/tests/Makefile
2856                 src/util/Makefile
2857                 src/util/tests/hash_table/Makefile
2858                 src/vulkan/wsi/Makefile])
2859
2860 AC_OUTPUT
2861
2862 # Fix up dependencies in *.Plo files, where we changed the extension of a
2863 # source file
2864 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2865
2866
2867 dnl
2868 dnl Output some configuration info for the user
2869 dnl
2870 echo ""
2871 echo "        prefix:          $prefix"
2872 echo "        exec_prefix:     $exec_prefix"
2873 echo "        libdir:          $libdir"
2874 echo "        includedir:      $includedir"
2875
2876 dnl API info
2877 echo ""
2878 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2879
2880 dnl Driver info
2881 echo ""
2882 case "x$enable_osmesa$enable_gallium_osmesa" in
2883 xnoyes)
2884         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2885         ;;
2886 xyesno)
2887         echo "        OSMesa:          lib$OSMESA_LIB"
2888         ;;
2889 xnono)
2890         echo "        OSMesa:          no"
2891         ;;
2892 esac
2893
2894 echo ""
2895 if test "x$enable_dri" != xno; then
2896         echo "        DRI platform:    $dri_platform"
2897         if test -z "$DRI_DIRS"; then
2898             echo "        DRI drivers:     no"
2899         else
2900             echo "        DRI drivers:     $DRI_DIRS"
2901         fi
2902         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2903 fi
2904
2905 case "x$enable_glx" in
2906 xdri)
2907     echo "        GLX:             DRI-based"
2908     ;;
2909 xxlib)
2910     echo "        GLX:             Xlib-based"
2911     ;;
2912 xgallium-xlib)
2913     echo "        GLX:             Xlib-based (Gallium)"
2914     ;;
2915 *)
2916     echo "        GLX:             $enable_glx"
2917     ;;
2918 esac
2919
2920 dnl EGL
2921 echo ""
2922 echo "        EGL:             $enable_egl"
2923 if test "$enable_egl" = yes; then
2924     echo "        EGL platforms:   $egl_platforms"
2925
2926     egl_drivers=""
2927     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2928         egl_drivers="$egl_drivers builtin:egl_dri2"
2929     fi
2930     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2931         egl_drivers="$egl_drivers builtin:egl_dri3"
2932     fi
2933
2934     echo "        EGL drivers:    $egl_drivers"
2935 fi
2936 if test "x$enable_gbm" = xyes; then
2937     echo "        GBM:             yes"
2938 else
2939     echo "        GBM:             no"
2940 fi
2941
2942 # Vulkan
2943 echo ""
2944 if test "x$VULKAN_DRIVERS" != x; then
2945     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2946     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2947 else
2948     echo "        Vulkan drivers:  no"
2949 fi
2950
2951 echo ""
2952 if test "x$MESA_LLVM" = x1; then
2953     echo "        llvm:            yes"
2954     echo "        llvm-config:     $LLVM_CONFIG"
2955     echo "        llvm-version:    $LLVM_VERSION"
2956 else
2957     echo "        llvm:            no"
2958 fi
2959
2960 echo ""
2961 if test -n "$with_gallium_drivers"; then
2962     echo "        Gallium drivers: $gallium_drivers"
2963     echo "        Gallium st:      $gallium_st"
2964 else
2965     echo "        Gallium:         no"
2966 fi
2967
2968 echo ""
2969 if test "x$enable_gallium_extra_hud" != xyes; then
2970     echo "        HUD extra stats: no"
2971 else
2972     echo "        HUD extra stats: yes"
2973 fi
2974
2975 if test "x$enable_lmsensors" != xyes; then
2976     echo "        HUD lmsensors:   no"
2977 else
2978     echo "        HUD lmsensors:   yes"
2979 fi
2980
2981 dnl Shader cache
2982 echo ""
2983 echo "        Shader cache:    $enable_shader_cache"
2984 if test "x$enable_shader_cache" = "xyes"; then
2985     echo "        With SHA1 from:  $with_sha1"
2986 fi
2987
2988 dnl Libraries
2989 echo ""
2990 echo "        Shared libs:     $enable_shared"
2991 echo "        Static libs:     $enable_static"
2992 echo "        Shared-glapi:    $enable_shared_glapi"
2993
2994 dnl Compiler options
2995 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2996 cflags=`echo $CFLAGS | \
2997     $SED 's/^ *//;s/  */ /;s/ *$//'`
2998 cxxflags=`echo $CXXFLAGS | \
2999     $SED 's/^ *//;s/  */ /;s/ *$//'`
3000 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3001 echo ""
3002 echo "        CFLAGS:          $cflags"
3003 echo "        CXXFLAGS:        $cxxflags"
3004 echo "        Macros:          $defines"
3005 echo ""
3006 if test "x$MESA_LLVM" = x1; then
3007     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3008     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3009     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3010     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3011     echo ""
3012 fi
3013 echo "        PYTHON2:         $PYTHON2"
3014
3015 echo ""
3016 echo "        Run '${MAKE-make}' to build Mesa"
3017 echo ""