configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.38
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 _SAVE_CPPFLAGS="$CPPFLAGS"
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DPTHREADS"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     CFLAGS="$CFLAGS -Wall -std=c99"
 171
 172     # Enable -Werror=implicit-function-declaration and
 173     # -Werror=missing-prototypes, if available, or otherwise, just
 174     # -Wmissing-prototypes.  This is particularly useful to avoid
 175     # generating a loadable driver module that has undefined symbols.
 176     save_CFLAGS="$CFLAGS"
 177     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 178     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 179     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 180     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 181                    AC_MSG_RESULT([yes]),
 182                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 183                     AC_MSG_RESULT([no])]);
 184
 185     # Enable -fvisibility=hidden if using a gcc that supports it
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 188     VISIBILITY_CFLAGS="-fvisibility=hidden"
 189     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 191                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 192
 193     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 194     CFLAGS=$save_CFLAGS
 195
 196     # Work around aliasing bugs - developers should comment this out
 197     CFLAGS="$CFLAGS -fno-strict-aliasing"
 198
 199     # gcc's builtin memcmp is slower than glibc's
 200     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 201     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 202 fi
 203 if test "x$GXX" = xyes; then
 204     CXXFLAGS="$CXXFLAGS -Wall"
 205
 206     # Enable -fvisibility=hidden if using a gcc that supports it
 207     save_CXXFLAGS="$CXXFLAGS"
 208     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 209     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 210     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 211     AC_LANG_PUSH([C++])
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 214     AC_LANG_POP([C++])
 215
 216     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 217     CXXFLAGS=$save_CXXFLAGS
 218
 219     # Work around aliasing bugs - developers should comment this out
 220     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 221
 222     # gcc's builtin memcmp is slower than glibc's
 223     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 224     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 225 fi
 226
 227 dnl even if the compiler appears to support it, using visibility attributes isn't
 228 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 229 case "$host_os" in
 230 cygwin*)
 231     VISIBILITY_CFLAGS=""
 232     VISIBILITY_CXXFLAGS=""
 233     ;;
 234 esac
 235
 236 AC_SUBST([VISIBILITY_CFLAGS])
 237 AC_SUBST([VISIBILITY_CXXFLAGS])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 dnl
 287 dnl mklib options
 288 dnl
 289 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 290 if test "$enable_static" = yes; then
 291     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 292 fi
 293 AC_SUBST([MKLIB_OPTIONS])
 294
 295 dnl
 296 dnl other compiler options
 297 dnl
 298 AC_ARG_ENABLE([debug],
 299     [AS_HELP_STRING([--enable-debug],
 300         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 301     [enable_debug="$enableval"],
 302     [enable_debug=no]
 303 )
 304 if test "x$enable_debug" = xyes; then
 305     DEFINES="$DEFINES -DDEBUG"
 306     if test "x$GCC" = xyes; then
 307         CFLAGS="$CFLAGS -g"
 308     fi
 309     if test "x$GXX" = xyes; then
 310         CXXFLAGS="$CXXFLAGS -g"
 311     fi
 312 fi
 313
 314 dnl
 315 dnl library names
 316 dnl
 317 LIB_PREFIX_GLOB='lib'
 318 LIB_VERSION_SEPARATOR='.'
 319 if test "$enable_static" = yes; then
 320     LIB_EXTENSION='a'
 321 else
 322     case "$host_os" in
 323     darwin* )
 324         LIB_EXTENSION='dylib' ;;
 325     cygwin* )
 326         dnl prefix can be 'cyg' or 'lib'
 327         LIB_PREFIX_GLOB='???'
 328         LIB_VERSION_SEPARATOR='-'
 329         LIB_EXTENSION='dll' ;;
 330     aix* )
 331         LIB_EXTENSION='a' ;;
 332     * )
 333         LIB_EXTENSION='so' ;;
 334     esac
 335 fi
 336 AC_ARG_WITH([gl-lib-name],
 337   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 338     [specify GL library name @<:@default=GL@:>@])],
 339   [GL_LIB=$withval],
 340   [GL_LIB=GL])
 341 AC_ARG_WITH([glu-lib-name],
 342   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 343     [specify GLU library name @<:@default=GLU@:>@])],
 344   [GLU_LIB=$withval],
 345   [GLU_LIB=GLU])
 346 AC_ARG_WITH([osmesa-lib-name],
 347   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 348     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 349   [OSMESA_LIB=$withval],
 350   [OSMESA_LIB=OSMesa])
 351 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 352 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 353 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 354
 355 dnl
 356 dnl Mangled Mesa support
 357 dnl
 358 AC_ARG_ENABLE([mangling],
 359   [AS_HELP_STRING([--enable-mangling],
 360     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 361   [enable_mangling="${enableval}"],
 362   [enable_mangling=no]
 363 )
 364 if test "x${enable_mangling}" = "xyes" ; then
 365   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 366   GL_LIB="Mangled${GL_LIB}"
 367   GLU_LIB="Mangled${GLU_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([GLU_LIB])
 372 AC_SUBST([OSMESA_LIB])
 373
 374 dnl
 375 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 376 dnl
 377 AC_ARG_ENABLE([texture-float],
 378     [AS_HELP_STRING([--enable-texture-float],
 379         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 380     [enable_texture_float="$enableval"],
 381     [enable_texture_float=no]
 382 )
 383 if test "x$enable_texture_float" = xyes; then
 384     AC_MSG_WARN([Floating-point textures enabled.])
 385     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 386     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 387 fi
 388
 389 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 390 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 391 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 392 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 393 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 394 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 395 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 396 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 397
 398 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406
 407 AC_SUBST([GL_LIB_NAME])
 408 AC_SUBST([GLU_LIB_NAME])
 409 AC_SUBST([OSMESA_LIB_NAME])
 410 AC_SUBST([EGL_LIB_NAME])
 411 AC_SUBST([GLESv1_CM_LIB_NAME])
 412 AC_SUBST([GLESv2_LIB_NAME])
 413 AC_SUBST([VG_LIB_NAME])
 414 AC_SUBST([GLAPI_LIB_NAME])
 415
 416 AC_SUBST([GL_LIB_GLOB])
 417 AC_SUBST([GLU_LIB_GLOB])
 418 AC_SUBST([EGL_LIB_GLOB])
 419 AC_SUBST([GLESv1_CM_LIB_GLOB])
 420 AC_SUBST([GLESv2_LIB_GLOB])
 421 AC_SUBST([VG_LIB_GLOB])
 422 AC_SUBST([GLAPI_LIB_GLOB])
 423
 424 dnl
 425 dnl Arch/platform-specific settings
 426 dnl
 427 AC_ARG_ENABLE([asm],
 428     [AS_HELP_STRING([--disable-asm],
 429         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 430     [enable_asm="$enableval"],
 431     [enable_asm=yes]
 432 )
 433 asm_arch=""
 434 MESA_ASM_FILES=""
 435 AC_MSG_CHECKING([whether to enable assembly])
 436 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 437 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 438 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 439     case "$host_cpu" in
 440     i?86 | x86_64)
 441         enable_asm=no
 442         AC_MSG_RESULT([no, cross compiling])
 443         ;;
 444     esac
 445 fi
 446 # check for supported arches
 447 if test "x$enable_asm" = xyes; then
 448     case "$host_cpu" in
 449     i?86)
 450         case "$host_os" in
 451         linux* | *freebsd* | dragonfly* | *netbsd*)
 452             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 453             ;;
 454         esac
 455         ;;
 456     x86_64)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 460             ;;
 461         esac
 462         ;;
 463     sparc*)
 464         case "$host_os" in
 465         linux*)
 466             asm_arch=sparc
 467             ;;
 468         esac
 469         ;;
 470     esac
 471
 472     case "$asm_arch" in
 473     x86)
 474         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 475         MESA_ASM_FILES='$(X86_FILES)'
 476         AC_MSG_RESULT([yes, x86])
 477         ;;
 478     x86_64)
 479         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 480         MESA_ASM_FILES='$(X86_64_FILES)'
 481         AC_MSG_RESULT([yes, x86_64])
 482         ;;
 483     sparc)
 484         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 485         MESA_ASM_FILES='$(SPARC_FILES)'
 486         AC_MSG_RESULT([yes, sparc])
 487         ;;
 488     *)
 489         AC_MSG_RESULT([no, platform not supported])
 490         ;;
 491     esac
 492 fi
 493 AC_SUBST([MESA_ASM_FILES])
 494
 495 dnl PIC code macro
 496 MESA_PIC_FLAGS
 497
 498 dnl Check to see if dlopen is in default libraries (like Solaris, which
 499 dnl has it in libc), or if libdl is needed to get it.
 500 AC_CHECK_FUNC([dlopen], [],
 501     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 502 AC_SUBST([DLOPEN_LIBS])
 503
 504 dnl See if posix_memalign is available
 505 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 506
 507 dnl SELinux awareness.
 508 AC_ARG_ENABLE([selinux],
 509     [AS_HELP_STRING([--enable-selinux],
 510         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 511     [MESA_SELINUX="$enableval"],
 512     [MESA_SELINUX=no])
 513 if test "x$enable_selinux" = "xyes"; then
 514     AC_CHECK_HEADER([selinux/selinux.h],[],
 515                     [AC_MSG_ERROR([SELinux headers not found])])
 516     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 517                  [AC_MSG_ERROR([SELinux library not found])])
 518     SELINUX_LIBS="-lselinux"
 519     DEFINES="$DEFINES -DMESA_SELINUX"
 520 fi
 521
 522 dnl Options for APIs
 523 AC_ARG_ENABLE([opengl],
 524     [AS_HELP_STRING([--disable-opengl],
 525         [disable support for standard OpenGL API @<:@default=no@:>@])],
 526     [enable_opengl="$enableval"],
 527     [enable_opengl=yes])
 528 AC_ARG_ENABLE([gles1],
 529     [AS_HELP_STRING([--enable-gles1],
 530         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 531     [enable_gles1="$enableval"],
 532     [enable_gles1=no])
 533 AC_ARG_ENABLE([gles2],
 534     [AS_HELP_STRING([--enable-gles2],
 535         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 536     [enable_gles2="$enableval"],
 537     [enable_gles2=no])
 538 AC_ARG_ENABLE([openvg],
 539     [AS_HELP_STRING([--enable-openvg],
 540         [enable support for OpenVG API @<:@default=no@:>@])],
 541     [enable_openvg="$enableval"],
 542     [enable_openvg=no])
 543
 544 AC_ARG_ENABLE([dri],
 545     [AS_HELP_STRING([--enable-dri],
 546         [enable DRI modules @<:@default=enabled@:>@])],
 547     [enable_dri="$enableval"],
 548     [enable_dri=yes])
 549 AC_ARG_ENABLE([glx],
 550     [AS_HELP_STRING([--enable-glx],
 551         [enable GLX library @<:@default=enabled@:>@])],
 552     [enable_glx="$enableval"],
 553     [enable_glx=yes])
 554 AC_ARG_ENABLE([osmesa],
 555     [AS_HELP_STRING([--enable-osmesa],
 556         [enable OSMesa library @<:@default=disabled@:>@])],
 557     [enable_osmesa="$enableval"],
 558     [enable_osmesa=no])
 559 AC_ARG_ENABLE([egl],
 560     [AS_HELP_STRING([--disable-egl],
 561         [disable EGL library @<:@default=enabled@:>@])],
 562     [enable_egl="$enableval"],
 563     [enable_egl=yes])
 564
 565 AC_ARG_ENABLE([xorg],
 566     [AS_HELP_STRING([--enable-xorg],
 567         [enable support for X.Org DDX API @<:@default=no@:>@])],
 568     [enable_xorg="$enableval"],
 569     [enable_xorg=no])
 570 AC_ARG_ENABLE([xa],
 571     [AS_HELP_STRING([--enable-xa],
 572         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 573     [enable_xa="$enableval"],
 574     [enable_xa=no])
 575 AC_ARG_ENABLE([d3d1x],
 576     [AS_HELP_STRING([--enable-d3d1x],
 577         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 578     [enable_d3d1x="$enableval"],
 579     [enable_d3d1x=no])
 580 AC_ARG_ENABLE([gbm],
 581    [AS_HELP_STRING([--enable-gbm],
 582          [enable gbm library @<:@default=auto@:>@])],
 583    [enable_gbm="$enableval"],
 584    [enable_gbm=auto])
 585
 586 AC_ARG_ENABLE([xvmc],
 587    [AS_HELP_STRING([--enable-xvmc],
 588          [enable xvmc library @<:@default=auto@:>@])],
 589    [enable_xvmc="$enableval"],
 590    [enable_xvmc=auto])
 591 AC_ARG_ENABLE([vdpau],
 592    [AS_HELP_STRING([--enable-vdpau],
 593          [enable vdpau library @<:@default=auto@:>@])],
 594    [enable_vdpau="$enableval"],
 595    [enable_vdpau=auto])
 596 AC_ARG_ENABLE([va],
 597    [AS_HELP_STRING([--enable-va],
 598          [enable va library @<:@default=auto@:>@])],
 599    [enable_va="$enableval"],
 600    [enable_va=auto])
 601 AC_ARG_ENABLE([opencl],
 602    [AS_HELP_STRING([--enable-opencl],
 603          [enable OpenCL library @<:@default=no@:>@])],
 604    [enable_opencl="$enableval"],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([xlib_glx],
 607     [AS_HELP_STRING([--enable-xlib-glx],
 608         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 609     [enable_xlib_glx="$enableval"],
 610     [enable_xlib_glx=no])
 611 AC_ARG_ENABLE([gallium_egl],
 612     [AS_HELP_STRING([--enable-gallium-egl],
 613         [enable optional EGL state tracker (not required
 614          for EGL support in Gallium with OpenGL and OpenGL ES)
 615          @<:@default=disable@:>@])],
 616     [enable_gallium_egl="$enableval"],
 617     [enable_gallium_egl=no])
 618 AC_ARG_ENABLE([gallium_gbm],
 619     [AS_HELP_STRING([--enable-gallium-gbm],
 620         [enable optional gbm state tracker (not required for
 621          gbm support in Gallium)
 622          @<:@default=auto@:>@])],
 623     [enable_gallium_gbm="$enableval"],
 624     [enable_gallium_gbm=auto])
 625
 626 AC_ARG_ENABLE([r600-llvm-compiler],
 627     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 628         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 629     [enable_r600_llvm="$enableval"],
 630     [enable_r600_llvm=no])
 631
 632 AC_ARG_ENABLE([gallium_tests],
 633     [AS_HELP_STRING([--enable-gallium-tests],
 634         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 635     [enable_gallium_tests="$enableval"],
 636     [enable_gallium_tests=no])
 637
 638 # Option for Gallium drivers
 639 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 640
 641 AC_ARG_WITH([gallium-drivers],
 642     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 643         [comma delimited Gallium drivers list, e.g.
 644         "i915,nouveau,r300,r600,svga,swrast"
 645         @<:@default=r300,r600,swrast@:>@])],
 646     [with_gallium_drivers="$withval"],
 647     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 648
 649 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 650 # here so that the script doesn't choke on an unknown driver name later.
 651 case "$with_gallium_drivers" in
 652     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 653     no) with_gallium_drivers='' ;;
 654 esac
 655
 656 if test "x$enable_opengl" = xno -a \
 657         "x$enable_gles1" = xno -a \
 658         "x$enable_gles2" = xno -a \
 659         "x$enable_openvg" = xno -a \
 660         "x$enable_xorg" = xno -a \
 661         "x$enable_xa" = xno -a \
 662         "x$enable_d3d1x" = xno -a \
 663         "x$enable_xvmc" = xno -a \
 664         "x$enable_vdpau" = xno -a \
 665         "x$enable_va" = xno -a \
 666         "x$enable_opencl" = xno; then
 667     AC_MSG_ERROR([at least one API should be enabled])
 668 fi
 669
 670 API_DEFINES=""
 671 if test "x$enable_opengl" = xno; then
 672     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 673 else
 674     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 675 fi
 676 if test "x$enable_gles1" = xyes; then
 677     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 678 fi
 679 if test "x$enable_gles2" = xyes; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 681 fi
 682 AC_SUBST([API_DEFINES])
 683
 684 AC_ARG_ENABLE([shared-glapi],
 685     [AS_HELP_STRING([--enable-shared-glapi],
 686         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 687     [enable_shared_glapi="$enableval"],
 688     [enable_shared_glapi=yes])
 689
 690 SHARED_GLAPI="0"
 691 if test "x$enable_shared_glapi" = xyes; then
 692     SHARED_GLAPI="1"
 693     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 694     # the remap table)
 695     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 696     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 697 fi
 698 AC_SUBST([SHARED_GLAPI])
 699 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 700
 701 if test "x$enable_glx" = xno; then
 702     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 703     enable_xlib_glx=no
 704 fi
 705
 706 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 707     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 708 fi
 709
 710 # Disable GLX if DRI and Xlib-GLX are not enabled
 711 if test "x$enable_glx" = xyes -a \
 712         "x$enable_dri" = xno -a \
 713         "x$enable_xlib_glx" = xno; then
 714     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 715     enable_glx=no
 716 fi
 717
 718 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 719
 720 dnl
 721 dnl Driver specific build directories
 722 dnl
 723
 724 dnl this variable will be prepended to SRC_DIRS and is not exported
 725 CORE_DIRS=""
 726
 727 SRC_DIRS="gtest"
 728 GLU_DIRS="sgi"
 729 GALLIUM_DIRS="auxiliary drivers state_trackers"
 730 GALLIUM_TARGET_DIRS=""
 731 GALLIUM_WINSYS_DIRS="sw"
 732 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 733 GALLIUM_STATE_TRACKERS_DIRS=""
 734
 735 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 736 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 737 x*yes*)
 738     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 739     ;;
 740 esac
 741
 742 # build glapi if OpenGL is enabled
 743 if test "x$enable_opengl" = xyes; then
 744     CORE_DIRS="$CORE_DIRS mapi/glapi"
 745 fi
 746
 747 # build es1api if OpenGL ES 1.x is enabled
 748 if test "x$enable_gles1" = xyes; then
 749     CORE_DIRS="$CORE_DIRS mapi/es1api"
 750 fi
 751
 752 # build es2api if OpenGL ES 2.x is enabled
 753 if test "x$enable_gles2" = xyes; then
 754     CORE_DIRS="$CORE_DIRS mapi/es2api"
 755 fi
 756
 757 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 758 case "x$enable_opengl$enable_gles1$enable_gles2" in
 759 x*yes*)
 760     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 761     ;;
 762 esac
 763
 764 case "x$enable_glx$enable_xlib_glx" in
 765 xyesyes)
 766     DRIVER_DIRS="$DRIVER_DIRS x11"
 767     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 768     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 769     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 770     HAVE_WINSYS_XLIB="yes"
 771     ;;
 772 xyesno)
 773     # DRI-based GLX
 774     SRC_DIRS="$SRC_DIRS glx"
 775     ;;
 776 esac
 777
 778 if test "x$enable_dri" = xyes; then
 779     DRIVER_DIRS="$DRIVER_DIRS dri"
 780
 781     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 782     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 783     HAVE_ST_DRI="yes"
 784 fi
 785
 786 if test "x$enable_osmesa" = xyes; then
 787     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 788 fi
 789
 790 AC_SUBST([SRC_DIRS])
 791 AC_SUBST([GLU_DIRS])
 792 AC_SUBST([DRIVER_DIRS])
 793 AC_SUBST([GALLIUM_DIRS])
 794 AC_SUBST([GALLIUM_TARGET_DIRS])
 795 AC_SUBST([GALLIUM_WINSYS_DIRS])
 796 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 797 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 798 AC_SUBST([MESA_LLVM])
 799
 800 # Check for libdrm
 801 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 802                   [have_libdrm=yes], [have_libdrm=no])
 803
 804 if test "x$enable_dri" = xyes; then
 805     # DRI must be shared, I think
 806     if test "$enable_static" = yes; then
 807         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 808     fi
 809
 810     # not a hard requirement as swrast does not depend on it
 811     if test "x$have_libdrm" = xyes; then
 812         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 813     fi
 814 fi
 815
 816 dnl Find out if X is available.
 817 PKG_CHECK_MODULES([X11], [x11])
 818
 819 dnl Try to tell the user that the --x-* options are only used when
 820 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 821 m4_divert_once([HELP_BEGIN],
 822 [These options are only used when the X libraries cannot be found by the
 823 pkg-config utility.])
 824
 825 dnl We need X for xlib and dri, so bomb now if it's not found
 826 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 827     AC_MSG_ERROR([X11 development libraries needed for GLX])
 828 fi
 829
 830 if test "x$enable_glx" = xyes; then
 831     DEFINES="$DEFINES -DUSE_XCB"
 832 fi
 833
 834 dnl Direct rendering or just indirect rendering
 835 case "$host_os" in
 836 gnu*)
 837     dnl Disable by default on GNU/Hurd
 838     driglx_direct_default="no"
 839     ;;
 840 cygwin*)
 841     dnl Disable by default on cygwin
 842     driglx_direct_default="no"
 843     ;;
 844 *)
 845     driglx_direct_default="yes"
 846     ;;
 847 esac
 848 AC_ARG_ENABLE([driglx-direct],
 849     [AS_HELP_STRING([--disable-driglx-direct],
 850         [enable direct rendering in GLX and EGL for DRI \
 851             @<:@default=auto@:>@])],
 852     [driglx_direct="$enableval"],
 853     [driglx_direct="$driglx_direct_default"])
 854
 855 dnl
 856 dnl libGL configuration per driver
 857 dnl
 858 case "x$enable_glx$enable_xlib_glx" in
 859 xyesyes)
 860     # Xlib-based GLX
 861     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 862     GL_PC_REQ_PRIV="x11 xext"
 863     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 864     GL_LIB_DEPS="$XLIBGL_LIBS"
 865     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 866     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 867     ;;
 868 xyesno)
 869     # DRI-based GLX
 870     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 871     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 872     if test x"$driglx_direct" = xyes; then
 873         if test "x$have_libdrm" != xyes; then
 874             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 875         fi
 876         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 877         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 878     fi
 879
 880     # find the DRI deps for libGL
 881     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 882
 883     # add xf86vidmode if available
 884     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 885     if test "$HAVE_XF86VIDMODE" = yes ; then
 886         dri_modules="$dri_modules xxf86vm"
 887     fi
 888
 889     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 890     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 891     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 892     GL_LIB_DEPS="$DRIGL_LIBS"
 893
 894     # need DRM libs, -lpthread, etc.
 895     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 896     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 897     ;;
 898 esac
 899
 900 # This is outside the case (above) so that it is invoked even for non-GLX
 901 # builds.
 902 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 903
 904 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 905 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 906 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 907 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 908
 909 AC_SUBST([GL_LIB_DEPS])
 910 AC_SUBST([GL_PC_REQ_PRIV])
 911 AC_SUBST([GL_PC_LIB_PRIV])
 912 AC_SUBST([GL_PC_CFLAGS])
 913 AC_SUBST([DRI_PC_REQ_PRIV])
 914 AC_SUBST([GLESv1_CM_LIB_DEPS])
 915 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 916 AC_SUBST([GLESv2_LIB_DEPS])
 917 AC_SUBST([GLESv2_PC_LIB_PRIV])
 918
 919 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
 920 AC_SUBST([GLAPI_LIB_DEPS])
 921
 922
 923 dnl dri libraries are linking with mesa
 924 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.la'
 925 GALLIUM_DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
 926
 927 dnl ... or dricore?
 928 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
 929     DRI_LIB_DEPS="\$(TOP)/src/mesa/libdricore/libdricore${VERSION}.la"
 930     GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 931     HAVE_DRICORE=yes
 932 fi
 933 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
 934
 935 AC_SUBST([HAVE_XF86VIDMODE])
 936
 937 dnl
 938 dnl More GLX setup
 939 dnl
 940 case "x$enable_glx$enable_xlib_glx" in
 941 xyesyes)
 942     DEFINES="$DEFINES -DUSE_XSHM"
 943     ;;
 944 xyesno)
 945     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 946     if test "x$driglx_direct" = xyes; then
 947         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 948     fi
 949     ;;
 950 esac
 951
 952 dnl
 953 dnl TLS detection
 954 dnl
 955
 956 AC_ARG_ENABLE([glx-tls],
 957     [AS_HELP_STRING([--enable-glx-tls],
 958         [enable TLS support in GLX @<:@default=disabled@:>@])],
 959     [GLX_USE_TLS="$enableval"],
 960     [GLX_USE_TLS=no])
 961 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 962
 963 AS_IF([test "x$GLX_USE_TLS" = xyes],
 964       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 965
 966 dnl
 967 dnl More DRI setup
 968 dnl
 969 dnl Directory for DRI drivers
 970 AC_ARG_WITH([dri-driverdir],
 971     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 972         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 973     [DRI_DRIVER_INSTALL_DIR="$withval"],
 974     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 975 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 976 dnl Extra search path for DRI drivers
 977 AC_ARG_WITH([dri-searchpath],
 978     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 979         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 980     [DRI_DRIVER_SEARCH_DIR="$withval"],
 981     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 982 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 983 dnl Which drivers to build - default is chosen by platform
 984 AC_ARG_WITH([dri-drivers],
 985     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 986         [comma delimited DRI drivers list, e.g.
 987         "swrast,i965,radeon" @<:@default=auto@:>@])],
 988     [with_dri_drivers="$withval"],
 989     [with_dri_drivers=yes])
 990 if test "x$with_dri_drivers" = x; then
 991     with_dri_drivers=no
 992 fi
 993
 994 dnl If $with_dri_drivers is yes, directories will be added through
 995 dnl platform checks
 996 DRI_DIRS=""
 997 case "$with_dri_drivers" in
 998 no) ;;
 999 yes)
1000     # classic DRI drivers require FEATURE_GL to build
1001     if test "x$enable_opengl" = xyes; then
1002         DRI_DIRS="yes"
1003     fi
1004     ;;
1005 *)
1006     # verify the requested driver directories exist
1007     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1008     for driver in $dri_drivers; do
1009         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1010             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1011     done
1012     DRI_DIRS="$dri_drivers"
1013     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1014         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1015     fi
1016     ;;
1017 esac
1018
1019 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1020 if test "x$enable_dri" = xyes; then
1021     # Platform specific settings and drivers to build
1022     case "$host_os" in
1023     linux*)
1024         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1025         DEFINES="$DEFINES -DHAVE_ALIAS"
1026
1027         case "$host_cpu" in
1028         x86_64)
1029             if test "x$DRI_DIRS" = "xyes"; then
1030                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1031             fi
1032             ;;
1033         powerpc*)
1034             # Build only the drivers for cards that exist on PowerPC.
1035             if test "x$DRI_DIRS" = "xyes"; then
1036                 DRI_DIRS="r200 radeon swrast"
1037             fi
1038             ;;
1039         sparc*)
1040             # Build only the drivers for cards that exist on sparc
1041             if test "x$DRI_DIRS" = "xyes"; then
1042                 DRI_DIRS="r200 radeon swrast"
1043             fi
1044             ;;
1045         esac
1046         ;;
1047     freebsd* | dragonfly* | *netbsd*)
1048         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1049         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1050
1051         if test "x$DRI_DIRS" = "xyes"; then
1052             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1053         fi
1054         ;;
1055     gnu*)
1056         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1057         DEFINES="$DEFINES -DHAVE_ALIAS"
1058         ;;
1059     solaris*)
1060         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1061         ;;
1062     cygwin*)
1063         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1064         if test "x$DRI_DIRS" = "xyes"; then
1065             DRI_DIRS="swrast"
1066         fi
1067         ;;
1068     esac
1069
1070     # default drivers
1071     if test "x$DRI_DIRS" = "xyes"; then
1072         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1073     fi
1074
1075     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1076
1077     # Check for expat
1078     if test "x$enable_dri" = xyes; then
1079         EXPAT_INCLUDES=""
1080         EXPAT_LIB=-lexpat
1081         AC_ARG_WITH([expat],
1082             [AS_HELP_STRING([--with-expat=DIR],
1083                 [expat install directory])],[
1084             EXPAT_INCLUDES="-I$withval/include"
1085             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1086             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1087             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1088             ])
1089         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1090         save_LIBS="$LIBS"
1091         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1092             [AC_MSG_ERROR([Expat required for DRI.])])
1093         LIBS="$save_LIBS"
1094     fi
1095
1096     # if we are building any dri driver other than swrast ...
1097     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1098         # ... libdrm is required
1099         if test "x$have_libdrm" != xyes; then
1100             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1101         fi
1102         # ... and build dricommon
1103         HAVE_COMMON_DRI=yes
1104     fi
1105
1106     # put all the necessary libs together
1107     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1108     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1109 fi
1110 AC_SUBST([DRI_DIRS])
1111 AC_SUBST([EXPAT_INCLUDES])
1112 AC_SUBST([DRI_LIB_DEPS])
1113 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1114
1115 case $DRI_DIRS in
1116 *i915*|*i965*)
1117     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1118
1119     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1120         case $d in
1121         i915)
1122             HAVE_I915_DRI=yes;
1123             ;;
1124         i965)
1125             HAVE_I965_DRI=yes;
1126             ;;
1127         esac
1128     done
1129
1130     ;;
1131 esac
1132
1133 case $DRI_DIRS in
1134 *nouveau*)
1135     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1136     HAVE_NOUVEAU_DRI=yes;
1137     ;;
1138 esac
1139
1140 case $DRI_DIRS in
1141 *radeon*|*r200*)
1142     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1143
1144     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1145         case $d in
1146         radeon)
1147             HAVE_RADEON_DRI=yes;
1148             ;;
1149         r200)
1150             HAVE_R200_DRI=yes;
1151             ;;
1152         esac
1153     done
1154
1155     ;;
1156 esac
1157
1158 case $DRI_DIRS in
1159 *swrast*)
1160     HAVE_SWRAST_DRI=yes;
1161     ;;
1162 esac
1163
1164 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1165 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1166 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1167 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1168 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1169 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1170 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1171
1172 dnl
1173 dnl OSMesa configuration
1174 dnl
1175
1176 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1177 AC_ARG_WITH([osmesa-bits],
1178     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1179         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1180     [osmesa_bits="$withval"],
1181     [osmesa_bits=8])
1182 if test "x$osmesa_bits" != x8; then
1183     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1184         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1185         osmesa_bits=8
1186     fi
1187 fi
1188 case "x$osmesa_bits" in
1189 x8)
1190     OSMESA_LIB="${OSMESA_LIB}"
1191     ;;
1192 x16|x32)
1193     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1194     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1195     ;;
1196 *)
1197     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1198     ;;
1199 esac
1200
1201 if test "x$enable_osmesa" = xyes; then
1202     # only link libraries with osmesa if shared
1203     if test "$enable_static" = no; then
1204         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1205     else
1206         OSMESA_LIB_DEPS=""
1207     fi
1208     OSMESA_MESA_DEPS=""
1209     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1210 fi
1211
1212 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1213
1214 AC_SUBST([OSMESA_LIB_DEPS])
1215 AC_SUBST([OSMESA_MESA_DEPS])
1216 AC_SUBST([OSMESA_PC_REQ])
1217 AC_SUBST([OSMESA_PC_LIB_PRIV])
1218 AC_SUBST([OSMESA_VERSION])
1219
1220 dnl
1221 dnl gbm configuration
1222 dnl
1223 if test "x$enable_gbm" = xauto; then
1224     case "$with_egl_platforms" in
1225         *drm*)
1226             enable_gbm=yes ;;
1227          *)
1228             enable_gbm=no ;;
1229     esac
1230 fi
1231 if test "x$enable_gbm" = xyes; then
1232     SRC_DIRS="$SRC_DIRS gbm"
1233
1234     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1235                       AC_MSG_ERROR([gbm needs udev]))
1236
1237     if test "x$enable_dri" = xyes; then
1238         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1239         if test "$SHARED_GLAPI" -eq 0; then
1240             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1241         fi
1242     fi
1243 fi
1244 GBM_PC_REQ_PRIV="libudev"
1245 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1246 AC_SUBST([GBM_PC_REQ_PRIV])
1247 AC_SUBST([GBM_PC_LIB_PRIV])
1248
1249 dnl
1250 dnl EGL configuration
1251 dnl
1252 EGL_CLIENT_APIS=""
1253
1254 if test "x$enable_egl" = xyes; then
1255     SRC_DIRS="$SRC_DIRS egl"
1256     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1257
1258     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1259
1260     if test "$enable_static" != yes; then
1261         # build egl_glx when libGL is built
1262         if test "x$enable_glx" = xyes; then
1263             HAVE_EGL_DRIVER_GLX=1
1264         fi
1265
1266         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1267                           [have_libudev=yes],[have_libudev=no])
1268         if test "$have_libudev" = yes; then
1269             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1270         fi
1271
1272         if test "x$enable_dri" = xyes; then
1273             HAVE_EGL_DRIVER_DRI2=1
1274         fi
1275
1276     fi
1277 fi
1278 AC_SUBST([EGL_LIB_DEPS])
1279
1280 dnl
1281 dnl EGL Gallium configuration
1282 dnl
1283 if test "x$enable_gallium_egl" = xyes; then
1284     if test "x$with_gallium_drivers" = x; then
1285         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1286     fi
1287     if test "x$enable_egl" = xno; then
1288         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1289     fi
1290     if test "x$have_libdrm" != xyes; then
1291         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1292     fi
1293
1294     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1295     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1296     HAVE_ST_EGL="yes"
1297 fi
1298
1299 dnl
1300 dnl gbm Gallium configuration
1301 dnl
1302 if test "x$enable_gallium_gbm" = xauto; then
1303     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1304         yesyesyes*drm*)
1305             enable_gallium_gbm=yes ;;
1306          *)
1307             enable_gallium_gbm=no ;;
1308     esac
1309 fi
1310 if test "x$enable_gallium_gbm" = xyes; then
1311     if test "x$with_gallium_drivers" = x; then
1312         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1313     fi
1314     if test "x$enable_gbm" = xno; then
1315         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1316     fi
1317     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1318     if test "x$enable_dri" = xno; then
1319         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1320     fi
1321
1322     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1323     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1324     HAVE_ST_GBM="yes"
1325     enable_gallium_loader=yes
1326 fi
1327
1328 dnl
1329 dnl X.Org DDX configuration
1330 dnl
1331 if test "x$enable_xorg" = xyes; then
1332     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1333     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1334     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1335     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1336         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1337         HAVE_XEXTPROTO_71="no")
1338     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1339     HAVE_ST_XORG=yes
1340 fi
1341
1342 dnl
1343 dnl XA configuration
1344 dnl
1345 if test "x$enable_xa" = xyes; then
1346 AC_PROG_AWK
1347 AC_PROG_GREP
1348 AC_CHECK_PROG(NM, nm, "nm")
1349 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1350 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1351 enable_xa=no
1352 fi
1353 fi
1354 if test "x$enable_xa" = xyes; then
1355     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1356     HAVE_ST_XA=yes
1357     AC_SUBST(AWK)
1358     AC_SUBST(GREP)
1359     AC_SUBST(NM)
1360 fi
1361
1362 dnl
1363 dnl OpenVG configuration
1364 dnl
1365 VG_LIB_DEPS=""
1366
1367 if test "x$enable_openvg" = xyes; then
1368     if test "x$enable_egl" = xno; then
1369         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1370     fi
1371     if test "x$with_gallium_drivers" = x; then
1372         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1373     fi
1374     if test "x$enable_gallium_egl" = xno; then
1375         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1376     fi
1377
1378     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1379     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1380     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1381     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1382     HAVE_ST_VEGA=yes
1383 fi
1384
1385 dnl
1386 dnl D3D1X configuration
1387 dnl
1388
1389 if test "x$enable_d3d1x" = xyes; then
1390     if test "x$with_gallium_drivers" = x; then
1391         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1392     fi
1393
1394     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1395     HAVE_ST_D3D1X=yes
1396 fi
1397
1398 dnl
1399 dnl Gallium G3DVL configuration
1400 dnl
1401 AC_ARG_ENABLE([gallium-g3dvl],
1402     [AS_HELP_STRING([--enable-gallium-g3dvl],
1403         [build gallium g3dvl @<:@default=disabled@:>@])],
1404     [enable_gallium_g3dvl="$enableval"],
1405     [enable_gallium_g3dvl=no])
1406 if test "x$enable_gallium_g3dvl" = xyes; then
1407     if test "x$with_gallium_drivers" = x; then
1408         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1409     fi
1410
1411     if test "x$enable_xvmc" = xauto; then
1412         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1413     fi
1414
1415     if test "x$enable_vdpau" = xauto; then
1416         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1417     fi
1418
1419     if test "x$enable_va" = xauto; then
1420         #don't enable vaapi state tracker even if package exists
1421         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1422         enable_va=no
1423     fi
1424 fi
1425
1426 if test "x$enable_xvmc" = xyes; then
1427     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1428     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1429     HAVE_ST_XVMC="yes"
1430 fi
1431
1432 if test "x$enable_vdpau" = xyes; then
1433     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1434     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1435     HAVE_ST_VDPAU="yes"
1436 fi
1437
1438 if test "x$enable_va" = xyes; then
1439     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1440     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1441     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1442     HAVE_ST_VA="yes"
1443 fi
1444
1445 dnl
1446 dnl OpenCL configuration
1447 dnl
1448
1449 AC_ARG_WITH([libclc-path],
1450    [AS_HELP_STRING([--with-libclc-path],
1451          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1452    [LIBCLC_PATH="$withval"],
1453    [LIBCLC_PATH=""])
1454
1455 AC_ARG_WITH([clang-libdir],
1456    [AS_HELP_STRING([--with-clang-libdir],
1457          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1458    [CLANG_LIBDIR="$withval"],
1459    [CLANG_LIBDIR=""])
1460
1461 AC_SUBST([LIBCLC_PATH])
1462
1463 if test "x$enable_opencl" = xyes; then
1464     if test "x$with_gallium_drivers" = x; then
1465         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1466     fi
1467
1468     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1469         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1470     fi
1471
1472     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1473     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1474     enable_gallium_loader=yes
1475 fi
1476
1477 dnl
1478 dnl GLU configuration
1479 dnl
1480 AC_ARG_ENABLE([glu],
1481     [AS_HELP_STRING([--disable-glu],
1482         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1483     [enable_glu="$enableval"],
1484     [enable_glu=yes])
1485
1486 if test "x$enable_glu" = xyes; then
1487     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1488         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1489         enable_glu=no
1490     fi
1491 fi
1492
1493 if test "x$enable_glu" = xyes; then
1494     SRC_DIRS="$SRC_DIRS glu"
1495
1496     if test "x$enable_glx" = xno; then
1497         # Link libGLU to libOSMesa instead of libGL
1498         GLU_LIB_DEPS=""
1499         GLU_PC_REQ="osmesa"
1500         if test "$enable_static" = no; then
1501             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1502         else
1503             GLU_MESA_DEPS=""
1504         fi
1505     else
1506         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1507         GLU_PC_REQ="gl"
1508         GLU_PC_LIB_PRIV="-lm"
1509         if test "$enable_static" = no; then
1510             GLU_LIB_DEPS="-lm"
1511             GLU_MESA_DEPS='-l$(GL_LIB)'
1512         else
1513             GLU_LIB_DEPS=""
1514             GLU_MESA_DEPS=""
1515         fi
1516     fi
1517 fi
1518 if test "$enable_static" = no; then
1519     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1520 fi
1521 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1522 AC_SUBST([GLU_LIB_DEPS])
1523 AC_SUBST([GLU_MESA_DEPS])
1524 AC_SUBST([GLU_PC_REQ])
1525 AC_SUBST([GLU_PC_REQ_PRIV])
1526 AC_SUBST([GLU_PC_LIB_PRIV])
1527 AC_SUBST([GLU_PC_CFLAGS])
1528
1529 AC_SUBST([PROGRAM_DIRS])
1530
1531 dnl
1532 dnl Gallium configuration
1533 dnl
1534 if test "x$with_gallium_drivers" != x; then
1535     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1536 fi
1537
1538 AC_SUBST([LLVM_BINDIR])
1539 AC_SUBST([LLVM_CFLAGS])
1540 AC_SUBST([LLVM_CPPFLAGS])
1541 AC_SUBST([LLVM_CXXFLAGS])
1542 AC_SUBST([LLVM_LIBDIR])
1543 AC_SUBST([LLVM_LIBS])
1544 AC_SUBST([LLVM_LDFLAGS])
1545 AC_SUBST([LLVM_INCLUDEDIR])
1546 AC_SUBST([LLVM_VERSION])
1547 AC_SUBST([CLANG_RESOURCE_DIR])
1548
1549 case "x$enable_opengl$enable_gles1$enable_gles2" in
1550 x*yes*)
1551     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1552     ;;
1553 esac
1554
1555 AC_SUBST([VG_LIB_DEPS])
1556 AC_SUBST([EGL_CLIENT_APIS])
1557
1558 dnl
1559 dnl EGL Platforms configuration
1560 dnl
1561 AC_ARG_WITH([egl-platforms],
1562     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1563         [comma delimited native platforms libEGL supports, e.g.
1564         "x11,drm" @<:@default=auto@:>@])],
1565     [with_egl_platforms="$withval"],
1566     [if test "x$enable_egl" = xyes; then
1567         with_egl_platforms="x11"
1568     else
1569         with_egl_platforms=""
1570     fi])
1571
1572 EGL_PLATFORMS=""
1573
1574 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1575     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1576 fi
1577
1578 # Do per-EGL platform setups and checks
1579 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1580 for plat in $egl_platforms; do
1581         case "$plat" in
1582         fbdev|null)
1583                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1584                 ;;
1585
1586         wayland)
1587                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1588                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1589                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1590
1591                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1592                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1593                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1594                 ;;
1595
1596         x11)
1597                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1598                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1599                 save_LIBS="$LIBS"
1600                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1601                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1602                 LIBS="$save_LIBS"
1603                 ;;
1604
1605         drm)
1606                 test "x$enable_gbm" = "xno" &&
1607                         AC_MSG_ERROR([EGL platform drm needs gbm])
1608                 ;;
1609
1610         android|gdi)
1611                 ;;
1612
1613         *)
1614                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1615                 ;;
1616         esac
1617
1618         case "$plat$have_libudev" in
1619                 waylandno|drmno)
1620                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1621         esac
1622 done
1623
1624 # libEGL wants to default to the first platform specified in
1625 # ./configure.  parse that here.
1626 if test "x$egl_platforms" != "x"; then
1627     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1628     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1629 else
1630     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1631 fi
1632
1633 EGL_PLATFORMS="$egl_platforms"
1634
1635 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1636 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1637 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1638 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1639 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1640
1641 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1642 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1643
1644 AC_SUBST([EGL_NATIVE_PLATFORM])
1645 AC_SUBST([EGL_PLATFORMS])
1646 AC_SUBST([EGL_CFLAGS])
1647
1648 AC_ARG_WITH([egl-driver-dir],
1649     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1650                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1651     [EGL_DRIVER_INSTALL_DIR="$withval"],
1652     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1653 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1654
1655 AC_ARG_WITH([xorg-driver-dir],
1656     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1657                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1658     [XORG_DRIVER_INSTALL_DIR="$withval"],
1659     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1660 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1661
1662 AC_ARG_WITH([max-width],
1663     [AS_HELP_STRING([--with-max-width=N],
1664                     [Maximum framebuffer width (4096)])],
1665     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1666      AS_IF([test "${withval}" -gt "4096"],
1667            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1668 )
1669 AC_ARG_WITH([max-height],
1670     [AS_HELP_STRING([--with-max-height=N],
1671                     [Maximum framebuffer height (4096)])],
1672     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1673      AS_IF([test "${withval}" -gt "4096"],
1674            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1675 )
1676
1677 dnl
1678 dnl Gallium LLVM
1679 dnl
1680 AC_ARG_ENABLE([gallium-llvm],
1681     [AS_HELP_STRING([--enable-gallium-llvm],
1682         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1683     [enable_gallium_llvm="$enableval"],
1684     [enable_gallium_llvm=auto])
1685
1686 AC_ARG_WITH([llvm-shared-libs],
1687     [AS_HELP_STRING([--with-llvm-shared-libs],
1688         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1689     [with_llvm_shared_libs=yes],
1690     [with_llvm_shared_libs=no])
1691
1692 AC_ARG_WITH([llvm-prefix],
1693     [AS_HELP_STRING([--with-llvm-prefix],
1694         [Prefix for LLVM installations in non-standard locations])],
1695     [llvm_prefix="$withval"],
1696     [llvm_prefix=""])
1697
1698
1699 if test "x$with_gallium_drivers" = x; then
1700     enable_gallium_llvm=no
1701 fi
1702 if test "x$enable_gallium_llvm" = xauto; then
1703     case "$host_cpu" in
1704     i*86|x86_64) enable_gallium_llvm=yes;;
1705     esac
1706 fi
1707 if test "x$enable_gallium_llvm" = xyes; then
1708     if test "x$llvm_prefix" != x; then
1709         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1710     else
1711         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1712     fi
1713
1714     if test "x$LLVM_CONFIG" != xno; then
1715         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1716         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1717         if test "x$with_llvm_shared_libs" = xyes; then
1718             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1719             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1720         else
1721             LLVM_COMPONENTS="engine bitwriter"
1722             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1723                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1724             fi
1725             if test "x$enable_opencl" = xyes; then
1726                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1727             fi
1728             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1729         fi
1730         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1731         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1732         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1733         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1734         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1735         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1736         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1737         MESA_LLVM=1
1738
1739         dnl Check for Clang interanl headers
1740         if test "x$enable_opencl" = xyes; then
1741             if test "x$CLANG_LIBDIR" = x; then
1742                 CLANG_LIBDIR=${LLVM_LIBDIR}
1743             fi
1744             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1745             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1746                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1747         fi
1748     else
1749         MESA_LLVM=0
1750     fi
1751 else
1752     MESA_LLVM=0
1753 fi
1754
1755 dnl Directory for XVMC libs
1756 AC_ARG_WITH([xvmc-libdir],
1757     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1758         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1759     [XVMC_LIB_INSTALL_DIR="$withval"],
1760     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1761 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1762
1763 dnl
1764 dnl Gallium Tests
1765 dnl
1766 if test "x$enable_gallium_tests" = xyes; then
1767     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1768     enable_gallium_loader=yes
1769 fi
1770
1771 dnl Directory for VDPAU libs
1772 AC_ARG_WITH([vdpau-libdir],
1773     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1774         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1775     [VDPAU_LIB_INSTALL_DIR="$withval"],
1776     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1777 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1778
1779 dnl Directory for VA libs
1780 AC_ARG_WITH([va-libdir],
1781     [AS_HELP_STRING([--with-va-libdir=DIR],
1782         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1783     [VA_LIB_INSTALL_DIR="$withval"],
1784     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1785 AC_SUBST([VA_LIB_INSTALL_DIR])
1786
1787 dnl Directory for OpenCL libs
1788 AC_ARG_WITH([opencl-libdir],
1789     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1790         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1791     [OPENCL_LIB_INSTALL_DIR="$withval"],
1792     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1793 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1794
1795 dnl
1796 dnl Gallium helper functions
1797 dnl
1798 gallium_check_st() {
1799     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1800          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1801          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1802          if test "x$have_libdrm" != xyes; then
1803             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1804          fi
1805          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1806     fi
1807     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1808          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1809     fi
1810     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1811          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1812     fi
1813     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1814          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1815     fi
1816     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1817          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1818     fi
1819     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1820          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1821     fi
1822     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1823          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1824     fi
1825 }
1826
1827 gallium_require_llvm() {
1828     if test "x$MESA_LLVM" = x0; then
1829         case "$host_cpu" in
1830         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1831         esac
1832     fi
1833 }
1834
1835 gallium_require_drm_loader() {
1836     if test "x$enable_gallium_loader" = xyes; then
1837         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1838                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1839         if test "x$have_libdrm" != xyes; then
1840             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1841         fi
1842         enable_gallium_drm_loader=yes
1843     fi
1844 }
1845
1846 dnl Gallium drivers
1847 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1848 if test "x$with_gallium_drivers" != x; then
1849     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1850     for driver in $gallium_drivers; do
1851         case "x$driver" in
1852         xsvga)
1853             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1854             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1855             ;;
1856         xi915)
1857             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1858             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1859             if test "x$MESA_LLVM" = x1; then
1860                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1861             fi
1862             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1863             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1864             ;;
1865         xr300)
1866             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1867             gallium_require_llvm "Gallium R300"
1868             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1869             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1870             ;;
1871         xr600)
1872             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1873             gallium_require_drm_loader
1874             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1875             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1876                 if test "x$LLVM_VERSION" != "x3.1"; then
1877                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1878                 fi
1879                 NEED_RADEON_GALLIUM=yes;
1880             fi
1881             if test "x$enable_r600_llvm" = xyes; then
1882                 USE_R600_LLVM_COMPILER=yes;
1883             fi
1884             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1885                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1886             fi
1887             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1888             ;;
1889         xradeonsi)
1890             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1891             gallium_require_drm_loader
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1893             if test "x$LLVM_VERSION" != "x3.1"; then
1894                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1895             fi
1896             NEED_RADEON_GALLIUM=yes;
1897             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1898             ;;
1899         xnouveau)
1900             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1901             gallium_require_drm_loader
1902             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1903             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1904             ;;
1905         xswrast)
1906             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1907             if test "x$MESA_LLVM" = x1; then
1908                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1909             fi
1910
1911             if test "x$HAVE_ST_DRI" = xyes; then
1912                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1913             fi
1914             if test "x$HAVE_ST_VDPAU" = xyes; then
1915                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1916             fi
1917             if test "x$HAVE_ST_XVMC" = xyes; then
1918                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1919             fi
1920             if test "x$HAVE_ST_VA" = xyes; then
1921                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1922             fi
1923             if test "x$HAVE_ST_VDPAU" = xyes ||
1924                test "x$HAVE_ST_XVMC" = xyes ||
1925                test "x$HAVE_ST_VA" = xyes; then
1926                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1927                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1928                fi
1929             fi
1930             ;;
1931         *)
1932             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1933             ;;
1934         esac
1935     done
1936 fi
1937
1938 if test "x$enable_gallium_loader" = xyes; then
1939     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1940     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1941     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1942     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1943
1944     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1945         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1946         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1947     fi
1948
1949     if test "x$enable_gallium_drm_loader" = xyes; then
1950         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1951         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1952                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1953         if test "x$pipe_loader_have_xcb" = xyes; then
1954             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1955             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1956         fi
1957     fi
1958
1959     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1960     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1961 fi
1962
1963 dnl Tell Automake which drivers to build
1964 for driver in $GALLIUM_DRIVERS_DIRS; do
1965     case "x$driver" in
1966         xgalahad)
1967             HAVE_GALAHAD_GALLIUM=yes;
1968             ;;
1969         xidentity)
1970             HAVE_IDENTITY_GALLIUM=yes;
1971             ;;
1972         xnoop)
1973             HAVE_NOOP_GALLIUM=yes;
1974             ;;
1975         *)
1976             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1977             ;;
1978     esac
1979 done
1980
1981 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1982 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1983 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1984 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1985 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1986 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1987 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1988 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1989 AC_SUBST([GALLIUM_MAKE_DIRS])
1990
1991 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1992 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
1993
1994 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1995 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1996 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1997
1998 dnl prepend CORE_DIRS to SRC_DIRS
1999 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2000
2001 dnl Restore LDFLAGS and CPPFLAGS
2002 LDFLAGS="$_SAVE_LDFLAGS"
2003 CPPFLAGS="$_SAVE_CPPFLAGS"
2004
2005 dnl Add user CFLAGS and CXXFLAGS
2006 CFLAGS="$CFLAGS $USER_CFLAGS"
2007 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2008
2009 dnl Substitute the config
2010 AC_CONFIG_FILES([configs/current
2011                 Makefile
2012                 src/Makefile
2013                 src/gallium/Makefile
2014                 src/gallium/auxiliary/pipe-loader/Makefile
2015                 src/gallium/state_trackers/clover/Makefile
2016                 src/gallium/drivers/Makefile
2017                 src/gallium/drivers/r300/Makefile
2018                 src/gallium/drivers/r600/Makefile
2019                 src/gallium/targets/opencl/Makefile
2020                 src/gbm/Makefile
2021                 src/gbm/main/gbm.pc
2022                 src/egl/drivers/Makefile
2023                 src/egl/drivers/dri2/Makefile
2024                 src/egl/drivers/glx/Makefile
2025                 src/egl/Makefile
2026                 src/egl/main/Makefile
2027                 src/egl/main/egl.pc
2028                 src/egl/wayland/Makefile
2029                 src/egl/wayland/wayland-egl/Makefile
2030                 src/egl/wayland/wayland-egl/wayland-egl.pc
2031                 src/egl/wayland/wayland-drm/Makefile
2032                 src/glsl/Makefile
2033                 src/glsl/glcpp/Makefile
2034                 src/glsl/tests/Makefile
2035                 src/glx/Makefile
2036                 src/glx/tests/Makefile
2037                 src/mapi/glapi/Makefile
2038                 src/mapi/glapi/gen/Makefile
2039                 src/mapi/shared-glapi/Makefile
2040                 src/mapi/glapi/tests/Makefile
2041                 src/mapi/shared-glapi/tests/Makefile
2042                 src/gtest/Makefile
2043                 src/mesa/Makefile
2044                 src/mesa/libdricore/Makefile
2045                 src/mesa/main/tests/Makefile
2046                 src/mesa/x86/Makefile
2047                 src/mesa/x86-64/Makefile
2048                 src/mesa/drivers/Makefile
2049                 src/mesa/drivers/dri/dri.pc
2050                 src/mesa/drivers/dri/Makefile
2051                 src/mesa/drivers/dri/common/Makefile
2052                 src/mesa/drivers/dri/i915/Makefile
2053                 src/mesa/drivers/dri/i965/Makefile
2054                 src/mesa/drivers/dri/nouveau/Makefile
2055                 src/mesa/drivers/dri/r200/Makefile
2056                 src/mesa/drivers/dri/radeon/Makefile
2057                 src/mesa/drivers/dri/swrast/Makefile
2058                 src/mesa/drivers/osmesa/Makefile
2059                 src/mesa/drivers/x11/Makefile
2060                 src/mesa/gl.pc
2061                 src/mesa/drivers/osmesa/osmesa.pc])
2062
2063 dnl Sort the dirs alphabetically
2064 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2065 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2066 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2067 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2068 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2069
2070 AC_OUTPUT
2071
2072 dnl
2073 dnl Output some configuration info for the user
2074 dnl
2075 echo ""
2076 echo "        prefix:          $prefix"
2077 echo "        exec_prefix:     $exec_prefix"
2078 echo "        libdir:          $libdir"
2079 echo "        includedir:      $includedir"
2080
2081 dnl API info
2082 echo ""
2083 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2084 echo "        OpenVG:          $enable_openvg"
2085
2086 dnl Driver info
2087 echo ""
2088 if test "x$enable_osmesa" != xno; then
2089         echo "        OSMesa:          lib$OSMESA_LIB"
2090 else
2091         echo "        OSMesa:          no"
2092 fi
2093
2094 if test "x$enable_dri" != xno; then
2095         # cleanup the drivers var
2096         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2097         if test "x$DRI_DIRS" = x; then
2098             echo "        DRI drivers:     no"
2099         else
2100             echo "        DRI drivers:     $dri_dirs"
2101         fi
2102         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2103 fi
2104
2105 case "x$enable_glx$enable_xlib_glx" in
2106 xyesyes)
2107     echo "        GLX:             Xlib-based"
2108     ;;
2109 xyesno)
2110     echo "        GLX:             DRI-based"
2111     ;;
2112 *)
2113     echo "        GLX:             $enable_glx"
2114     ;;
2115 esac
2116
2117 echo ""
2118 echo "        GLU:             $enable_glu"
2119
2120 dnl EGL
2121 echo ""
2122 echo "        EGL:             $enable_egl"
2123 if test "$enable_egl" = yes; then
2124     echo "        EGL platforms:   $EGL_PLATFORMS"
2125
2126     egl_drivers=""
2127     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2128         egl_drivers="$egl_drivers builtin:egl_glx"
2129     fi
2130     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2131         egl_drivers="$egl_drivers builtin:egl_dri2"
2132     fi
2133
2134     if test "x$HAVE_ST_EGL" = xyes; then
2135         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2136         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2137     else
2138         echo "        EGL drivers:    $egl_drivers"
2139     fi
2140 fi
2141
2142 echo ""
2143 if test "x$MESA_LLVM" = x1; then
2144     echo "        llvm:            yes"
2145     echo "        llvm-config:     $LLVM_CONFIG"
2146     echo "        llvm-version:    $LLVM_VERSION"
2147 else
2148     echo "        llvm:            no"
2149 fi
2150
2151 echo ""
2152 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2153     echo "        Gallium:         yes"
2154     echo "        Gallium dirs:    $GALLIUM_DIRS"
2155     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2156     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2157     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2158     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2159 else
2160     echo "        Gallium:         no"
2161 fi
2162
2163
2164 dnl Libraries
2165 echo ""
2166 echo "        Shared libs:     $enable_shared"
2167 echo "        Static libs:     $enable_static"
2168 echo "        Shared-glapi:    $enable_shared_glapi"
2169
2170 dnl Compiler options
2171 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2172 cflags=`echo $CFLAGS $PIC_FLAGS | \
2173     $SED 's/^ *//;s/  */ /;s/ *$//'`
2174 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2175     $SED 's/^ *//;s/  */ /;s/ *$//'`
2176 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2177 echo ""
2178 echo "        CFLAGS:          $cflags"
2179 echo "        CXXFLAGS:        $cxxflags"
2180 echo "        Macros:          $defines"
2181 echo ""
2182 echo "        PYTHON2:         $PYTHON2"
2183
2184 echo ""
2185 echo "        Run '${MAKE-make}' to build Mesa"
2186 echo ""