configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.46
  32 LIBDRM_INTEL_REQUIRED=2.4.38
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 123
 124 dnl Make sure the pkg-config macros are defined
 125 m4_ifndef([PKG_PROG_PKG_CONFIG],
 126     [m4_fatal([Could not locate the pkg-config autoconf macros.
 127   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 128   are in a different location, try setting the environment variable
 129   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 130 PKG_PROG_PKG_CONFIG()
 131
 132 dnl LIB_DIR - library basename
 133 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 134 AC_SUBST([LIB_DIR])
 135
 136 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 137 _SAVE_LDFLAGS="$LDFLAGS"
 138 _SAVE_CPPFLAGS="$CPPFLAGS"
 139
 140 dnl Compiler macros
 141 DEFINES=""
 142 AC_SUBST([DEFINES])
 143 case "$host_os" in
 144 linux*|*-gnu*|gnu*)
 145     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 146     ;;
 147 solaris*)
 148     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 149     ;;
 150 cygwin*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD"
 152     ;;
 153 esac
 154
 155 dnl Add flags for gcc and g++
 156 if test "x$GCC" = xyes; then
 157     case "$host_os" in
 158     cygwin*)
 159         CFLAGS="$CFLAGS -Wall -std=gnu99"
 160         ;;
 161     *)
 162         CFLAGS="$CFLAGS -Wall -std=c99"
 163         ;;
 164     esac
 165
 166     # Enable -Werror=implicit-function-declaration and
 167     # -Werror=missing-prototypes, if available, or otherwise, just
 168     # -Wmissing-prototypes.  This is particularly useful to avoid
 169     # generating a loadable driver module that has undefined symbols.
 170     save_CFLAGS="$CFLAGS"
 171     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 172     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 173     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 174     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 175                    AC_MSG_RESULT([yes]),
 176                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 177                     AC_MSG_RESULT([no])]);
 178
 179     # Enable -fvisibility=hidden if using a gcc that supports it
 180     save_CFLAGS="$CFLAGS"
 181     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 182     VISIBILITY_CFLAGS="-fvisibility=hidden"
 183     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 185                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 186
 187     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 188     CFLAGS=$save_CFLAGS
 189
 190     # Work around aliasing bugs - developers should comment this out
 191     CFLAGS="$CFLAGS -fno-strict-aliasing"
 192
 193     # gcc's builtin memcmp is slower than glibc's
 194     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 195     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 196 fi
 197 if test "x$GXX" = xyes; then
 198     CXXFLAGS="$CXXFLAGS -Wall"
 199
 200     # Enable -fvisibility=hidden if using a gcc that supports it
 201     save_CXXFLAGS="$CXXFLAGS"
 202     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 203     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 204     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 205     AC_LANG_PUSH([C++])
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 208     AC_LANG_POP([C++])
 209
 210     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 211     CXXFLAGS=$save_CXXFLAGS
 212
 213     # Work around aliasing bugs - developers should comment this out
 214     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 215
 216     # gcc's builtin memcmp is slower than glibc's
 217     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 218     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 219 fi
 220
 221 dnl even if the compiler appears to support it, using visibility attributes isn't
 222 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 223 case "$host_os" in
 224 cygwin*)
 225     VISIBILITY_CFLAGS=""
 226     VISIBILITY_CXXFLAGS=""
 227     ;;
 228 esac
 229
 230 AC_SUBST([VISIBILITY_CFLAGS])
 231 AC_SUBST([VISIBILITY_CXXFLAGS])
 232
 233 dnl
 234 dnl Hacks to enable 32 or 64 bit build
 235 dnl
 236 AC_ARG_ENABLE([32-bit],
 237     [AS_HELP_STRING([--enable-32-bit],
 238         [build 32-bit libraries @<:@default=auto@:>@])],
 239     [enable_32bit="$enableval"],
 240     [enable_32bit=auto]
 241 )
 242 if test "x$enable_32bit" = xyes; then
 243     if test "x$GCC" = xyes; then
 244         CFLAGS="$CFLAGS -m32"
 245         CCASFLAGS="$CCASFLAGS -m32"
 246     fi
 247     if test "x$GXX" = xyes; then
 248         CXXFLAGS="$CXXFLAGS -m32"
 249     fi
 250 fi
 251 AC_ARG_ENABLE([64-bit],
 252     [AS_HELP_STRING([--enable-64-bit],
 253         [build 64-bit libraries @<:@default=auto@:>@])],
 254     [enable_64bit="$enableval"],
 255     [enable_64bit=auto]
 256 )
 257 if test "x$enable_64bit" = xyes; then
 258     if test "x$GCC" = xyes; then
 259         CFLAGS="$CFLAGS -m64"
 260     fi
 261     if test "x$GXX" = xyes; then
 262         CXXFLAGS="$CXXFLAGS -m64"
 263     fi
 264 fi
 265
 266 dnl Can't have static and shared libraries, default to static if user
 267 dnl explicitly requested. If both disabled, set to static since shared
 268 dnl was explicitly requested.
 269 case "x$enable_static$enable_shared" in
 270 xyesyes )
 271     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 272     enable_shared=no
 273     ;;
 274 xnono )
 275     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 276     enable_static=yes
 277     ;;
 278 esac
 279
 280 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 281
 282 dnl
 283 dnl other compiler options
 284 dnl
 285 AC_ARG_ENABLE([debug],
 286     [AS_HELP_STRING([--enable-debug],
 287         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 288     [enable_debug="$enableval"],
 289     [enable_debug=no]
 290 )
 291 if test "x$enable_debug" = xyes; then
 292     DEFINES="$DEFINES -DDEBUG"
 293     if test "x$GCC" = xyes; then
 294         CFLAGS="$CFLAGS -g -O0"
 295     fi
 296     if test "x$GXX" = xyes; then
 297         CXXFLAGS="$CXXFLAGS -g -O0"
 298     fi
 299 fi
 300
 301 dnl
 302 dnl library names
 303 dnl
 304 LIB_PREFIX_GLOB='lib'
 305 LIB_VERSION_SEPARATOR='.'
 306 if test "$enable_static" = yes; then
 307     LIB_EXTENSION='a'
 308 else
 309     case "$host_os" in
 310     darwin* )
 311         LIB_EXTENSION='dylib' ;;
 312     cygwin* )
 313         dnl prefix can be 'cyg' or 'lib'
 314         LIB_PREFIX_GLOB='???'
 315         LIB_VERSION_SEPARATOR='-'
 316         LIB_EXTENSION='dll' ;;
 317     aix* )
 318         LIB_EXTENSION='a' ;;
 319     * )
 320         LIB_EXTENSION='so' ;;
 321     esac
 322 fi
 323 AC_ARG_WITH([gl-lib-name],
 324   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 325     [specify GL library name @<:@default=GL@:>@])],
 326   [GL_LIB=$withval],
 327   [GL_LIB=GL])
 328 AC_ARG_WITH([osmesa-lib-name],
 329   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 330     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 331   [OSMESA_LIB=$withval],
 332   [OSMESA_LIB=OSMesa])
 333 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 334 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 335
 336 dnl
 337 dnl Mangled Mesa support
 338 dnl
 339 AC_ARG_ENABLE([mangling],
 340   [AS_HELP_STRING([--enable-mangling],
 341     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 342   [enable_mangling="${enableval}"],
 343   [enable_mangling=no]
 344 )
 345 if test "x${enable_mangling}" = "xyes" ; then
 346   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 347   GL_LIB="Mangled${GL_LIB}"
 348   OSMESA_LIB="Mangled${OSMESA_LIB}"
 349 fi
 350 AC_SUBST([GL_LIB])
 351 AC_SUBST([OSMESA_LIB])
 352
 353 dnl
 354 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 355 dnl
 356 AC_ARG_ENABLE([texture-float],
 357     [AS_HELP_STRING([--enable-texture-float],
 358         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 359     [enable_texture_float="$enableval"],
 360     [enable_texture_float=no]
 361 )
 362 if test "x$enable_texture_float" = xyes; then
 363     AC_MSG_WARN([Floating-point textures enabled.])
 364     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 365     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 366 fi
 367
 368 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 369 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 370 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 371 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 372 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 373 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 374 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 375
 376 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 377 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 378 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 379 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 380 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 381 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 382 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383
 384 AC_SUBST([GL_LIB_NAME])
 385 AC_SUBST([OSMESA_LIB_NAME])
 386 AC_SUBST([EGL_LIB_NAME])
 387 AC_SUBST([GLESv1_CM_LIB_NAME])
 388 AC_SUBST([GLESv2_LIB_NAME])
 389 AC_SUBST([VG_LIB_NAME])
 390 AC_SUBST([GLAPI_LIB_NAME])
 391
 392 AC_SUBST([GL_LIB_GLOB])
 393 AC_SUBST([EGL_LIB_GLOB])
 394 AC_SUBST([GLESv1_CM_LIB_GLOB])
 395 AC_SUBST([GLESv2_LIB_GLOB])
 396 AC_SUBST([VG_LIB_GLOB])
 397 AC_SUBST([GLAPI_LIB_GLOB])
 398
 399 dnl
 400 dnl Arch/platform-specific settings
 401 dnl
 402 AC_ARG_ENABLE([asm],
 403     [AS_HELP_STRING([--disable-asm],
 404         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 405     [enable_asm="$enableval"],
 406     [enable_asm=yes]
 407 )
 408 asm_arch=""
 409 AC_MSG_CHECKING([whether to enable assembly])
 410 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 411 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 412 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 413     case "$host_cpu" in
 414     i?86 | x86_64 | amd64)
 415         enable_asm=no
 416         AC_MSG_RESULT([no, cross compiling])
 417         ;;
 418     esac
 419 fi
 420 # check for supported arches
 421 if test "x$enable_asm" = xyes; then
 422     case "$host_cpu" in
 423     i?86)
 424         case "$host_os" in
 425         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 426             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 427             ;;
 428         gnu*)
 429             asm_arch=x86
 430             ;;
 431         esac
 432         ;;
 433     x86_64|amd64)
 434         case "$host_os" in
 435         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 436             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 437             ;;
 438         esac
 439         ;;
 440     sparc*)
 441         case "$host_os" in
 442         linux*)
 443             asm_arch=sparc
 444             ;;
 445         esac
 446         ;;
 447     esac
 448
 449     case "$asm_arch" in
 450     x86)
 451         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 452         AC_MSG_RESULT([yes, x86])
 453         ;;
 454     x86_64|amd64)
 455         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 456         AC_MSG_RESULT([yes, x86_64])
 457         ;;
 458     sparc)
 459         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 460         AC_MSG_RESULT([yes, sparc])
 461         ;;
 462     *)
 463         AC_MSG_RESULT([no, platform not supported])
 464         ;;
 465     esac
 466 fi
 467
 468 dnl Check to see if dlopen is in default libraries (like Solaris, which
 469 dnl has it in libc), or if libdl is needed to get it.
 470 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 471     [AC_CHECK_LIB([dl], [dlopen],
 472        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 473 AC_SUBST([DLOPEN_LIBS])
 474
 475 case "$host_os" in
 476 darwin*|mingw*)
 477     ;;
 478 *)
 479     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 480                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 481                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 482     AC_SUBST([CLOCK_LIB])
 483     ;;
 484 esac
 485
 486 dnl See if posix_memalign is available
 487 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 488
 489 dnl Check for pthreads
 490 AX_PTHREAD
 491 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 492 dnl to -pthread, which causes problems if we need -lpthread to appear in
 493 dnl pkgconfig files.
 494 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 495
 496 dnl SELinux awareness.
 497 AC_ARG_ENABLE([selinux],
 498     [AS_HELP_STRING([--enable-selinux],
 499         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 500     [MESA_SELINUX="$enableval"],
 501     [MESA_SELINUX=no])
 502 if test "x$enable_selinux" = "xyes"; then
 503     AC_CHECK_HEADER([selinux/selinux.h],[],
 504                     [AC_MSG_ERROR([SELinux headers not found])])
 505     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 506                  [AC_MSG_ERROR([SELinux library not found])])
 507     SELINUX_LIBS="-lselinux"
 508     DEFINES="$DEFINES -DMESA_SELINUX"
 509 fi
 510 AC_SUBST([SELINUX_LIBS])
 511
 512 dnl Options for APIs
 513 AC_ARG_ENABLE([opengl],
 514     [AS_HELP_STRING([--disable-opengl],
 515         [disable support for standard OpenGL API @<:@default=no@:>@])],
 516     [enable_opengl="$enableval"],
 517     [enable_opengl=yes])
 518 AC_ARG_ENABLE([gles1],
 519     [AS_HELP_STRING([--enable-gles1],
 520         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 521     [enable_gles1="$enableval"],
 522     [enable_gles1=no])
 523 AC_ARG_ENABLE([gles2],
 524     [AS_HELP_STRING([--enable-gles2],
 525         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 526     [enable_gles2="$enableval"],
 527     [enable_gles2=no])
 528 AC_ARG_ENABLE([openvg],
 529     [AS_HELP_STRING([--enable-openvg],
 530         [enable support for OpenVG API @<:@default=no@:>@])],
 531     [enable_openvg="$enableval"],
 532     [enable_openvg=no])
 533
 534 AC_ARG_ENABLE([dri],
 535     [AS_HELP_STRING([--enable-dri],
 536         [enable DRI modules @<:@default=enabled@:>@])],
 537     [enable_dri="$enableval"],
 538     [enable_dri=yes])
 539 AC_ARG_ENABLE([dri3],
 540     [AS_HELP_STRING([--enable-dri3],
 541         [enable DRI3 @<:@default=enabled@:>@])],
 542     [enable_dri3="$enableval"],
 543     [enable_dri3=yes])
 544 AC_ARG_ENABLE([glx],
 545     [AS_HELP_STRING([--enable-glx],
 546         [enable GLX library @<:@default=enabled@:>@])],
 547     [enable_glx="$enableval"],
 548     [enable_glx=yes])
 549 AC_ARG_ENABLE([osmesa],
 550     [AS_HELP_STRING([--enable-osmesa],
 551         [enable OSMesa library @<:@default=disabled@:>@])],
 552     [enable_osmesa="$enableval"],
 553     [enable_osmesa=no])
 554 AC_ARG_ENABLE([gallium-osmesa],
 555     [AS_HELP_STRING([--enable-gallium-osmesa],
 556         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 557     [enable_gallium_osmesa="$enableval"],
 558     [enable_gallium_osmesa=no])
 559 AC_ARG_ENABLE([egl],
 560     [AS_HELP_STRING([--disable-egl],
 561         [disable EGL library @<:@default=enabled@:>@])],
 562     [enable_egl="$enableval"],
 563     [enable_egl=yes])
 564
 565 AC_ARG_ENABLE([xa],
 566     [AS_HELP_STRING([--enable-xa],
 567         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 568     [enable_xa="$enableval"],
 569     [enable_xa=no])
 570 AC_ARG_ENABLE([gbm],
 571    [AS_HELP_STRING([--enable-gbm],
 572          [enable gbm library @<:@default=auto@:>@])],
 573    [enable_gbm="$enableval"],
 574    [enable_gbm=auto])
 575
 576 AC_ARG_ENABLE([xvmc],
 577    [AS_HELP_STRING([--enable-xvmc],
 578          [enable xvmc library @<:@default=auto@:>@])],
 579    [enable_xvmc="$enableval"],
 580    [enable_xvmc=auto])
 581 AC_ARG_ENABLE([vdpau],
 582    [AS_HELP_STRING([--enable-vdpau],
 583          [enable vdpau library @<:@default=auto@:>@])],
 584    [enable_vdpau="$enableval"],
 585    [enable_vdpau=auto])
 586 AC_ARG_ENABLE([opencl],
 587    [AS_HELP_STRING([--enable-opencl],
 588          [enable OpenCL library NOTE: Enabling this option will also enable
 589           --with-llvm-shared-libs
 590           @<:@default=no@:>@])],
 591    [],
 592    [enable_opencl=no])
 593 AC_ARG_ENABLE([opencl_icd],
 594    [AS_HELP_STRING([--enable-opencl-icd],
 595           [Build an OpenCL ICD library to be loaded by an ICD implementation
 596            @<:@default=no@:>@])],
 597     [enable_opencl_icd="$enableval"],
 598     [enable_opencl_icd=no])
 599 AC_ARG_ENABLE([xlib-glx],
 600     [AS_HELP_STRING([--enable-xlib-glx],
 601         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 602     [enable_xlib_glx="$enableval"],
 603     [enable_xlib_glx=no])
 604 AC_ARG_ENABLE([gallium-egl],
 605     [AS_HELP_STRING([--enable-gallium-egl],
 606         [enable optional EGL state tracker (not required
 607          for EGL support in Gallium with OpenGL and OpenGL ES)
 608          @<:@default=disable@:>@])],
 609     [enable_gallium_egl="$enableval"],
 610     [enable_gallium_egl=no])
 611 AC_ARG_ENABLE([gallium-gbm],
 612     [AS_HELP_STRING([--enable-gallium-gbm],
 613         [enable optional gbm state tracker (not required for
 614          gbm support in Gallium)
 615          @<:@default=auto@:>@])],
 616     [enable_gallium_gbm="$enableval"],
 617     [enable_gallium_gbm=auto])
 618
 619 AC_ARG_ENABLE([r600-llvm-compiler],
 620     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 621         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 622     [enable_r600_llvm="$enableval"],
 623     [enable_r600_llvm=no])
 624
 625 AC_ARG_ENABLE([gallium-tests],
 626     [AS_HELP_STRING([--enable-gallium-tests],
 627         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 628     [enable_gallium_tests="$enableval"],
 629     [enable_gallium_tests=no])
 630
 631 # Option for Gallium drivers
 632
 633 # Keep this in sync with the --with-gallium-drivers help string default value
 634 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 635
 636 AC_ARG_WITH([gallium-drivers],
 637     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 638         [comma delimited Gallium drivers list, e.g.
 639         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 640         @<:@default=r300,r600,svga,swrast@:>@])],
 641     [with_gallium_drivers="$withval"],
 642     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 643
 644 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 645 # here so that the script doesn't choke on an unknown driver name later.
 646 case "$with_gallium_drivers" in
 647     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 648     no) with_gallium_drivers='' ;;
 649 esac
 650
 651 if test "x$enable_opengl" = xno -a \
 652         "x$enable_gles1" = xno -a \
 653         "x$enable_gles2" = xno -a \
 654         "x$enable_openvg" = xno -a \
 655         "x$enable_xa" = xno -a \
 656         "x$enable_xvmc" = xno -a \
 657         "x$enable_vdpau" = xno -a \
 658         "x$enable_opencl" = xno; then
 659     AC_MSG_ERROR([at least one API should be enabled])
 660 fi
 661
 662 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 663 if test "x$enable_opengl" = xno -a \
 664         "x$enable_gles1" = xyes; then
 665     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 666 fi
 667
 668 if test "x$enable_opengl" = xno -a \
 669         "x$enable_gles2" = xyes; then
 670     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 671 fi
 672
 673 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 674 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 675 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 676 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 677                                         "x$enable_gles1" = xyes -o \
 678                                         "x$enable_gles2" = xyes)
 679
 680 if test "x$enable_glx" = xno; then
 681     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 682     enable_xlib_glx=no
 683 fi
 684
 685 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 686     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 687 fi
 688
 689 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 690     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 691 fi
 692
 693 # Disable GLX if OpenGL is not enabled
 694 if test "x$enable_glx$enable_opengl" = xyesno; then
 695     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 696     enable_glx=no
 697 fi
 698
 699 # Disable GLX if DRI and Xlib-GLX are not enabled
 700 if test "x$enable_glx" = xyes -a \
 701         "x$enable_dri" = xno -a \
 702         "x$enable_xlib_glx" = xno; then
 703     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 704     enable_glx=no
 705 fi
 706
 707 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 708                                   "x$enable_dri" = xyes)
 709 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 710 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 711
 712 AC_ARG_ENABLE([shared-glapi],
 713     [AS_HELP_STRING([--enable-shared-glapi],
 714         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 715     [enable_shared_glapi="$enableval"],
 716     [enable_shared_glapi="$enable_dri"])
 717
 718 # Shared GLAPI is only useful for DRI
 719 if test "x$enable_dri" = xno; then
 720     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 721     enable_shared_glapi=no
 722 fi
 723
 724 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 725
 726 dnl
 727 dnl Driver specific build directories
 728 dnl
 729 GALLIUM_TARGET_DIRS=""
 730 GALLIUM_WINSYS_DIRS="sw"
 731 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 732 GALLIUM_STATE_TRACKERS_DIRS=""
 733
 734 case "x$enable_glx$enable_xlib_glx" in
 735 xyesyes)
 736     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 737     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 738     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 739     NEED_WINSYS_XLIB="yes"
 740     ;;
 741 esac
 742
 743 if test "x$enable_dri" = xyes; then
 744     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 745     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 746 fi
 747
 748 if test "x$enable_gallium_osmesa" = xyes; then
 749     if test -z "$with_gallium_drivers"; then
 750         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 751     fi
 752     if test "x$enable_osmesa" = xyes; then
 753         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 754     fi
 755     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 756     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 757 fi
 758
 759 AC_SUBST([MESA_LLVM])
 760
 761 # Check for libdrm
 762 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 763                   [have_libdrm=yes], [have_libdrm=no])
 764
 765 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 766                   have_libudev=yes, have_libudev=no)
 767
 768 if test "x$enable_dri" = xyes; then
 769     # DRI must be shared, I think
 770     if test "$enable_static" = yes; then
 771         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 772     fi
 773
 774     # not a hard requirement as swrast does not depend on it
 775     if test "x$have_libdrm" = xyes; then
 776         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 777     fi
 778 fi
 779
 780 dnl Direct rendering or just indirect rendering
 781 case "$host_os" in
 782 gnu*)
 783     dnl Disable by default on GNU/Hurd
 784     driglx_direct_default="no"
 785     ;;
 786 cygwin*)
 787     dnl Disable by default on cygwin
 788     driglx_direct_default="no"
 789     ;;
 790 *)
 791     driglx_direct_default="yes"
 792     ;;
 793 esac
 794 AC_ARG_ENABLE([driglx-direct],
 795     [AS_HELP_STRING([--disable-driglx-direct],
 796         [disable direct rendering in GLX and EGL for DRI \
 797             @<:@default=auto@:>@])],
 798     [driglx_direct="$enableval"],
 799     [driglx_direct="$driglx_direct_default"])
 800
 801 dnl
 802 dnl libGL configuration per driver
 803 dnl
 804 case "x$enable_glx$enable_xlib_glx" in
 805 xyesyes)
 806     # Xlib-based GLX
 807     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 808     GL_PC_REQ_PRIV="x11 xext"
 809     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 810     GL_LIB_DEPS="$XLIBGL_LIBS"
 811     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 812     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 813     ;;
 814 xyesno)
 815     # DRI-based GLX
 816     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 817     if test x"$driglx_direct" = xyes; then
 818         if test "x$have_libdrm" != xyes; then
 819             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 820         fi
 821         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 822         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 823         if test x"$enable_dri3" = xyes; then
 824             if test x"$have_libudev" != xyes; then
 825               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 826             fi
 827             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 828             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 829         fi
 830     fi
 831
 832     # find the DRI deps for libGL
 833     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 834
 835     if test x"$enable_dri3" = xyes; then
 836         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence"
 837     fi
 838
 839     # add xf86vidmode if available
 840     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 841     if test "$HAVE_XF86VIDMODE" = yes ; then
 842         dri_modules="$dri_modules xxf86vm"
 843     fi
 844
 845     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 846     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 847     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 848     GL_LIB_DEPS="$DRIGL_LIBS"
 849
 850     if test x"$enable_dri3$have_libudev" = xyesyes; then
 851         X11_INCLUDES="$X11_INCLUDES $LIBUDEV_CFLAGS"
 852         GL_LIB_DEPS="$GL_LIB_DEPS $LIBUDEV_LIBS"
 853     fi
 854
 855     # need DRM libs, $PTHREAD_LIBS, etc.
 856     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 857     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 858     ;;
 859 esac
 860
 861 # This is outside the case (above) so that it is invoked even for non-GLX
 862 # builds.
 863 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 864
 865 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 866 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 868 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 869
 870 AC_SUBST([X11_INCLUDES])
 871 AC_SUBST([GL_LIB_DEPS])
 872 AC_SUBST([GL_PC_REQ_PRIV])
 873 AC_SUBST([GL_PC_LIB_PRIV])
 874 AC_SUBST([GL_PC_CFLAGS])
 875 AC_SUBST([DRI_PC_REQ_PRIV])
 876 AC_SUBST([GLESv1_CM_LIB_DEPS])
 877 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 878 AC_SUBST([GLESv2_LIB_DEPS])
 879 AC_SUBST([GLESv2_PC_LIB_PRIV])
 880
 881 AC_SUBST([HAVE_XF86VIDMODE])
 882
 883 dnl
 884 dnl More GLX setup
 885 dnl
 886 case "x$enable_glx$enable_xlib_glx" in
 887 xyesyes)
 888     DEFINES="$DEFINES -DUSE_XSHM"
 889     ;;
 890 xyesno)
 891     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 892     if test "x$driglx_direct" = xyes; then
 893         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 894     fi
 895     ;;
 896 esac
 897
 898 dnl
 899 dnl TLS detection
 900 dnl
 901
 902 AC_ARG_ENABLE([glx-tls],
 903     [AS_HELP_STRING([--enable-glx-tls],
 904         [enable TLS support in GLX @<:@default=disabled@:>@])],
 905     [GLX_USE_TLS="$enableval"],
 906     [GLX_USE_TLS=no])
 907 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 908
 909 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 910       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 911
 912 dnl
 913 dnl More DRI setup
 914 dnl
 915 dnl Directory for DRI drivers
 916 AC_ARG_WITH([dri-driverdir],
 917     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 918         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 919     [DRI_DRIVER_INSTALL_DIR="$withval"],
 920     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 921 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 922 dnl Extra search path for DRI drivers
 923 AC_ARG_WITH([dri-searchpath],
 924     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 925         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 926     [DRI_DRIVER_SEARCH_DIR="$withval"],
 927     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 928 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 929 dnl Which drivers to build - default is chosen by platform
 930 AC_ARG_WITH([dri-drivers],
 931     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 932         [comma delimited DRI drivers list, e.g.
 933         "swrast,i965,radeon" @<:@default=auto@:>@])],
 934     [with_dri_drivers="$withval"],
 935     [with_dri_drivers=yes])
 936 if test "x$with_dri_drivers" = x; then
 937     with_dri_drivers=no
 938 fi
 939
 940 dnl If $with_dri_drivers is yes, directories will be added through
 941 dnl platform checks
 942 DRI_DIRS=""
 943 case "$with_dri_drivers" in
 944 no) ;;
 945 yes)
 946     # classic DRI drivers
 947     if test "x$enable_opengl" = xyes; then
 948         DRI_DIRS="yes"
 949     fi
 950     ;;
 951 *)
 952     # verify the requested driver directories exist
 953     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 954     for driver in $dri_drivers; do
 955         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 956             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 957     done
 958     DRI_DIRS="$dri_drivers"
 959     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 960         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 961     fi
 962     ;;
 963 esac
 964
 965 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 966 if test "x$enable_dri" = xyes; then
 967     # Platform specific settings and drivers to build
 968     case "$host_os" in
 969     linux*)
 970         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 971         DEFINES="$DEFINES -DHAVE_ALIAS"
 972         if test "x$enable_dri3" = xyes; then
 973             DEFINES="$DEFINES -DHAVE_DRI3"
 974         fi
 975
 976         case "$host_cpu" in
 977         x86_64|amd64)
 978             if test "x$DRI_DIRS" = "xyes"; then
 979                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 980             fi
 981             ;;
 982         powerpc*)
 983             # Build only the drivers for cards that exist on PowerPC.
 984             if test "x$DRI_DIRS" = "xyes"; then
 985                 DRI_DIRS="r200 radeon swrast"
 986             fi
 987             ;;
 988         sparc*)
 989             # Build only the drivers for cards that exist on sparc
 990             if test "x$DRI_DIRS" = "xyes"; then
 991                 DRI_DIRS="r200 radeon swrast"
 992             fi
 993             ;;
 994         esac
 995         ;;
 996     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 997         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 998         DEFINES="$DEFINES -DHAVE_ALIAS"
 999
1000         if test "x$DRI_DIRS" = "xyes"; then
1001             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1002         fi
1003         ;;
1004     gnu*)
1005         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1006         DEFINES="$DEFINES -DHAVE_ALIAS"
1007         ;;
1008     solaris*)
1009         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1010         ;;
1011     cygwin*)
1012         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1013         if test "x$DRI_DIRS" = "xyes"; then
1014             DRI_DIRS="swrast"
1015         fi
1016         ;;
1017     esac
1018
1019     # default drivers
1020     if test "x$DRI_DIRS" = "xyes"; then
1021         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1022     fi
1023
1024     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1025
1026     # Check for expat
1027     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1028     if test "x$have_expat" = "xyes"; then
1029        PKG_CHECK_MODULES([EXPAT], [expat], [],
1030                          AC_MSG_ERROR([Expat required for DRI.]))
1031     else
1032        # expat version 2.0 and earlier do not provide expat.pc
1033        EXPAT_LIBS=-lexpat
1034     fi
1035
1036     # If we are building any DRI driver other than swrast.
1037     if test -n "$DRI_DIRS"; then
1038         if test x"$DRI_DIRS" != xswrast; then
1039             # ... libdrm is required
1040             if test "x$have_libdrm" != xyes; then
1041                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1042             fi
1043             DRICOMMON_NEED_LIBDRM=yes
1044         else
1045             DRICOMMON_NEED_LIBDRM=no
1046         fi
1047     fi
1048
1049     # put all the necessary libs together
1050     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1051     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1052
1053     DRI_DRIVER_LDFLAGS="-module -avoid-version -shared -Wl,-Bsymbolic"
1054 fi
1055
1056 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1057 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1058                                   "x$enable_osmesa" = xyes -o \
1059                                   -n "$DRI_DIRS")
1060 AC_SUBST([DRI_LIB_DEPS])
1061 AC_SUBST([DRI_DRIVER_LDFLAGS])
1062 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1063
1064 case $DRI_DIRS in
1065 *i915*|*i965*)
1066     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1067
1068     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1069         case $d in
1070         i915)
1071             HAVE_I915_DRI=yes;
1072             ;;
1073         i965)
1074             HAVE_I965_DRI=yes;
1075             ;;
1076         esac
1077     done
1078
1079     ;;
1080 esac
1081
1082 case $DRI_DIRS in
1083 *nouveau*)
1084     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1085     HAVE_NOUVEAU_DRI=yes;
1086     ;;
1087 esac
1088
1089 case $DRI_DIRS in
1090 *radeon*|*r200*)
1091     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1092
1093     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1094         case $d in
1095         radeon)
1096             HAVE_RADEON_DRI=yes;
1097             ;;
1098         r200)
1099             HAVE_R200_DRI=yes;
1100             ;;
1101         esac
1102     done
1103
1104     ;;
1105 esac
1106
1107 case $DRI_DIRS in
1108 *swrast*)
1109     HAVE_SWRAST_DRI=yes;
1110     ;;
1111 esac
1112
1113 dnl
1114 dnl OSMesa configuration
1115 dnl
1116
1117 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1118 AC_ARG_WITH([osmesa-bits],
1119     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1120         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1121     [osmesa_bits="$withval"],
1122     [osmesa_bits=8])
1123 if test "x$osmesa_bits" != x8; then
1124     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1125         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1126         osmesa_bits=8
1127     fi
1128 fi
1129 case "x$osmesa_bits" in
1130 x8)
1131     OSMESA_LIB="${OSMESA_LIB}"
1132     ;;
1133 x16|x32)
1134     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1135     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1136     ;;
1137 *)
1138     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1139     ;;
1140 esac
1141
1142 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1143     # only link libraries with osmesa if shared
1144     if test "$enable_static" = no; then
1145         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1146     else
1147         OSMESA_LIB_DEPS=""
1148     fi
1149     OSMESA_MESA_DEPS=""
1150     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1151 fi
1152
1153 AC_SUBST([OSMESA_LIB_DEPS])
1154 AC_SUBST([OSMESA_MESA_DEPS])
1155 AC_SUBST([OSMESA_PC_REQ])
1156 AC_SUBST([OSMESA_PC_LIB_PRIV])
1157
1158 dnl
1159 dnl gbm configuration
1160 dnl
1161 if test "x$enable_gbm" = xauto; then
1162     case "$with_egl_platforms" in
1163         *drm*)
1164             enable_gbm=yes ;;
1165          *)
1166             enable_gbm=no ;;
1167     esac
1168 fi
1169 if test "x$enable_gbm" = xyes; then
1170     if test x"$have_libudev" != xyes; then
1171         AC_MSG_ERROR([gbm needs udev])
1172     fi
1173
1174     if test "x$enable_dri" = xyes; then
1175         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1176         if test "x$enable_shared_glapi" = xno; then
1177             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1178         fi
1179     fi
1180 fi
1181 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1182 GBM_PC_REQ_PRIV="libudev"
1183 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1184 AC_SUBST([GBM_PC_REQ_PRIV])
1185 AC_SUBST([GBM_PC_LIB_PRIV])
1186
1187 dnl
1188 dnl EGL configuration
1189 dnl
1190 EGL_CLIENT_APIS=""
1191
1192 if test "x$enable_egl" = xyes; then
1193     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1194
1195     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1196
1197     if test "$enable_static" != yes; then
1198         # build egl_glx when libGL is built
1199         if test "$have_libudev" = yes; then
1200             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1201         fi
1202
1203         if test "x$enable_dri" = xyes; then
1204             HAVE_EGL_DRIVER_DRI2=1
1205         fi
1206
1207     fi
1208 fi
1209 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1210 AC_SUBST([EGL_LIB_DEPS])
1211
1212 dnl
1213 dnl EGL Gallium configuration
1214 dnl
1215 if test "x$enable_gallium_egl" = xyes; then
1216     if test "x$with_gallium_drivers" = x; then
1217         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1218     fi
1219     if test "x$enable_egl" = xno; then
1220         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1221     fi
1222     if test "x$have_libdrm" != xyes; then
1223         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1224     fi
1225
1226     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1227     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1228 fi
1229 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1230
1231 dnl
1232 dnl gbm Gallium configuration
1233 dnl
1234 if test "x$enable_gallium_gbm" = xauto; then
1235     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1236         yesyesyes*drm*)
1237             enable_gallium_gbm=yes ;;
1238          *)
1239             enable_gallium_gbm=no ;;
1240     esac
1241 fi
1242 if test "x$enable_gallium_gbm" = xyes; then
1243     if test "x$with_gallium_drivers" = x; then
1244         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1245     fi
1246     if test "x$enable_gbm" = xno; then
1247         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1248     fi
1249     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1250     if test "x$enable_dri" = xno; then
1251         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1252     fi
1253
1254     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1255     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1256     enable_gallium_loader=yes
1257 fi
1258 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1259
1260 dnl
1261 dnl XA configuration
1262 dnl
1263 if test "x$enable_xa" = xyes; then
1264     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1265 fi
1266 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1267
1268 dnl
1269 dnl OpenVG configuration
1270 dnl
1271 VG_LIB_DEPS=""
1272
1273 if test "x$enable_openvg" = xyes; then
1274     if test "x$enable_egl" = xno; then
1275         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1276     fi
1277     if test "x$with_gallium_drivers" = x; then
1278         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1279     fi
1280     if test "x$enable_gallium_egl" = xno; then
1281         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1282     fi
1283
1284     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1285     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1286     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1287     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1288     AC_SUBST([VG_PC_LIB_PRIV])
1289 fi
1290 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1291
1292 dnl
1293 dnl Gallium G3DVL configuration
1294 dnl
1295 if test -n "$with_gallium_drivers"; then
1296     if test "x$enable_xvmc" = xauto; then
1297         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1298     fi
1299
1300     if test "x$enable_vdpau" = xauto; then
1301         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1302     fi
1303 fi
1304
1305 if test "x$enable_xvmc" = xyes; then
1306     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1307     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1308 fi
1309 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1310
1311 if test "x$enable_vdpau" = xyes; then
1312     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1313     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1314 fi
1315 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1316
1317 dnl
1318 dnl OpenCL configuration
1319 dnl
1320
1321 AC_ARG_WITH([libclc-path],
1322    [AS_HELP_STRING([--with-libclc-path],
1323          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1324    [LIBCLC_PATH="$withval"],
1325    [LIBCLC_PATH=""])
1326
1327 if test "x$LIBCLC_PATH" != x; then
1328    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1329                   Please review the updated build instructions for clover:
1330                   http://dri.freedesktop.org/wiki/GalliumCompute])
1331 fi
1332
1333
1334 AC_ARG_WITH([clang-libdir],
1335    [AS_HELP_STRING([--with-clang-libdir],
1336          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1337    [CLANG_LIBDIR="$withval"],
1338    [CLANG_LIBDIR=""])
1339
1340 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1341
1342 if test "x$enable_opencl" = xyes; then
1343     if test "x$with_gallium_drivers" = x; then
1344         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1345     fi
1346
1347     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1348         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1349     fi
1350
1351     if test "x$have_libclc" = xno; then
1352         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1353                     Make sure the directory containing libclc.pc is specified in your
1354                     PKG_CONFIG_PATH environment variable.
1355                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1356     else
1357         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1358         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1359         AC_SUBST([LIBCLC_INCLUDEDIR])
1360         AC_SUBST([LIBCLC_LIBEXECDIR])
1361     fi
1362
1363     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1364     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1365     enable_gallium_loader=yes
1366
1367     if test "x$enable_opencl_icd" = xyes; then
1368         OPENCL_LIBNAME="MesaOpenCL"
1369     else
1370         OPENCL_LIBNAME="OpenCL"
1371     fi
1372 fi
1373 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1374 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1375 AC_SUBST([OPENCL_LIBNAME])
1376
1377 dnl
1378 dnl Gallium configuration
1379 dnl
1380 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1381
1382 AC_SUBST([LLVM_BINDIR])
1383 AC_SUBST([LLVM_CFLAGS])
1384 AC_SUBST([LLVM_CPPFLAGS])
1385 AC_SUBST([LLVM_CXXFLAGS])
1386 AC_SUBST([LLVM_LIBDIR])
1387 AC_SUBST([LLVM_LIBS])
1388 AC_SUBST([LLVM_LDFLAGS])
1389 AC_SUBST([LLVM_INCLUDEDIR])
1390 AC_SUBST([LLVM_VERSION])
1391 AC_SUBST([CLANG_RESOURCE_DIR])
1392
1393 case "x$enable_opengl$enable_gles1$enable_gles2" in
1394 x*yes*)
1395     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1396     ;;
1397 esac
1398
1399 AC_SUBST([VG_LIB_DEPS])
1400 AC_SUBST([EGL_CLIENT_APIS])
1401
1402 dnl
1403 dnl EGL Platforms configuration
1404 dnl
1405 AC_ARG_WITH([egl-platforms],
1406     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1407         [comma delimited native platforms libEGL supports, e.g.
1408         "x11,drm" @<:@default=auto@:>@])],
1409     [with_egl_platforms="$withval"],
1410     [if test "x$enable_egl" = xyes; then
1411         with_egl_platforms="x11"
1412     else
1413         with_egl_platforms=""
1414     fi])
1415
1416 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1417     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1418 fi
1419
1420 # Do per-EGL platform setups and checks
1421 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1422 for plat in $egl_platforms; do
1423         case "$plat" in
1424         wayland)
1425                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1426                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1427
1428                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1429                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1430                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1431                 ;;
1432
1433         x11)
1434                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1435
1436                 if test "x$enable_glx" = xyes; then
1437                         HAVE_EGL_DRIVER_GLX=1
1438                 fi
1439                 ;;
1440
1441         drm)
1442                 test "x$enable_gbm" = "xno" &&
1443                         AC_MSG_ERROR([EGL platform drm needs gbm])
1444                 ;;
1445
1446         android|fbdev|gdi|null)
1447                 ;;
1448
1449         *)
1450                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1451                 ;;
1452         esac
1453
1454         case "$plat$have_libudev" in
1455                 waylandno|drmno)
1456                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1457         esac
1458 done
1459
1460 # libEGL wants to default to the first platform specified in
1461 # ./configure.  parse that here.
1462 if test "x$egl_platforms" != "x"; then
1463     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1464     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1465 else
1466     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1467 fi
1468
1469 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1470     NEED_WINSYS_XLIB=yes
1471 fi
1472 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1473 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1474 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1475 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1476 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1477
1478 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1479 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1480
1481 AC_SUBST([EGL_NATIVE_PLATFORM])
1482 AC_SUBST([EGL_CFLAGS])
1483
1484 # If we don't have the X11 platform, set this define so we don't try to include
1485 # the X11 headers.
1486 if ! echo "$egl_platforms" | grep -q 'x11'; then
1487     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1488     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1489 fi
1490
1491 AC_ARG_WITH([egl-driver-dir],
1492     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1493                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1494     [EGL_DRIVER_INSTALL_DIR="$withval"],
1495     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1496 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1497
1498 AC_ARG_WITH([max-width],
1499     [AS_HELP_STRING([--with-max-width=N],
1500                     [Maximum framebuffer width (4096)])],
1501     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1502      AS_IF([test "${withval}" -gt "4096"],
1503            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1504 )
1505 AC_ARG_WITH([max-height],
1506     [AS_HELP_STRING([--with-max-height=N],
1507                     [Maximum framebuffer height (4096)])],
1508     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1509      AS_IF([test "${withval}" -gt "4096"],
1510            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1511 )
1512
1513 dnl
1514 dnl Gallium LLVM
1515 dnl
1516 AC_ARG_ENABLE([gallium-llvm],
1517     [AS_HELP_STRING([--enable-gallium-llvm],
1518         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1519     [enable_gallium_llvm="$enableval"],
1520     [enable_gallium_llvm=auto])
1521
1522 AC_ARG_WITH([llvm-shared-libs],
1523     [AS_HELP_STRING([--with-llvm-shared-libs],
1524         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1525     [],
1526     [with_llvm_shared_libs=no])
1527
1528 AC_ARG_WITH([llvm-prefix],
1529     [AS_HELP_STRING([--with-llvm-prefix],
1530         [Prefix for LLVM installations in non-standard locations])],
1531     [llvm_prefix="$withval"],
1532     [llvm_prefix=""])
1533
1534
1535 # Call this inside ` ` to get the return value.
1536 # $1 is the llvm-config command with arguments.
1537 strip_unwanted_llvm_flags() {
1538     # Use \> (marks the end of the word)
1539     echo `$1` | sed \
1540         -e 's/-DNDEBUG\>//g' \
1541         -e 's/-pedantic\>//g' \
1542         -e 's/-Wcovered-switch-default\>//g' \
1543         -e 's/-O.\>//g' \
1544         -e 's/-g\>//g' \
1545         -e 's/-Wall\>//g' \
1546         -e 's/-fomit-frame-pointer\>//g'
1547 }
1548
1549
1550 if test "x$with_gallium_drivers" = x; then
1551     enable_gallium_llvm=no
1552 fi
1553 if test "x$enable_gallium_llvm" = xauto; then
1554     case "$host_cpu" in
1555     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1556     esac
1557 fi
1558 if test "x$enable_gallium_llvm" = xyes; then
1559     if test "x$llvm_prefix" != x; then
1560         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1561     else
1562         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1563     fi
1564
1565     if test "x$LLVM_CONFIG" != xno; then
1566         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1567         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1568         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1569         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1570         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1571         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1572         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1573         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1574
1575         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1576             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1577         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1578             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1579
1580         if test "x${LLVM_VERSION_MAJOR}" != x; then
1581             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1582         else
1583             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1584         fi
1585
1586         LLVM_COMPONENTS="engine bitwriter"
1587         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1588             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1589         fi
1590
1591         if test "x$enable_opencl" = xyes; then
1592             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1593             # LLVM 3.3 >= 177971 requires IRReader
1594             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1595                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1596             fi
1597             # LLVM 3.4 requires Option
1598             if $LLVM_CONFIG --components | grep -qw 'option'; then
1599                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1600             fi
1601         fi
1602         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1603         MESA_LLVM=1
1604
1605         dnl Check for Clang internal headers
1606         if test "x$enable_opencl" = xyes; then
1607             if test "x$CLANG_LIBDIR" = x; then
1608                 CLANG_LIBDIR=${LLVM_LIBDIR}
1609             fi
1610             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1611             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1612                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1613         fi
1614     else
1615         MESA_LLVM=0
1616         LLVM_VERSION_INT=0
1617     fi
1618 else
1619     MESA_LLVM=0
1620     LLVM_VERSION_INT=0
1621 fi
1622
1623 dnl Directory for XVMC libs
1624 AC_ARG_WITH([xvmc-libdir],
1625     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1626         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1627     [XVMC_LIB_INSTALL_DIR="$withval"],
1628     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1629 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1630
1631 dnl
1632 dnl Gallium Tests
1633 dnl
1634 if test "x$enable_gallium_tests" = xyes; then
1635     enable_gallium_loader=yes
1636 fi
1637 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1638
1639 if test "x$enable_gallium_loader" = xyes; then
1640     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1641 fi
1642 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1643
1644 dnl Directory for VDPAU libs
1645 AC_ARG_WITH([vdpau-libdir],
1646     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1647         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1648     [VDPAU_LIB_INSTALL_DIR="$withval"],
1649     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1650 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1651
1652 dnl Directory for OpenCL libs
1653 AC_ARG_WITH([opencl-libdir],
1654     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1655         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1656     [OPENCL_LIB_INSTALL_DIR="$withval"],
1657     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1658 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1659
1660 dnl
1661 dnl Gallium helper functions
1662 dnl
1663 gallium_check_st() {
1664     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1665          if test "x$have_libdrm" != xyes; then
1666             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1667          fi
1668          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1669     fi
1670     if test "x$enable_dri" = xyes && test "x$2" != x; then
1671          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1672     fi
1673     if test "x$enable_xa" = xyes && test "x$3" != x; then
1674          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1675     fi
1676     if test "x$enable_xvmc" = xyes && test "x$4" != x; then
1677          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1678     fi
1679     if test "x$enable_vdpau" = xyes && test "x$5" != x; then
1680          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1681     fi
1682 }
1683
1684 gallium_require_llvm() {
1685     if test "x$MESA_LLVM" = x0; then
1686         case "$host_cpu" in
1687         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1688         esac
1689     fi
1690 }
1691
1692 gallium_require_drm_loader() {
1693     if test "x$enable_gallium_loader" = xyes; then
1694         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1695                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1696         if test "x$have_libdrm" != xyes; then
1697             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1698         fi
1699         enable_gallium_drm_loader=yes
1700     fi
1701 }
1702
1703 radeon_llvm_check() {
1704     LLVM_REQUIRED_VERSION_MAJOR="3"
1705     LLVM_REQUIRED_VERSION_MINOR="3"
1706     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1707         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1708     fi
1709     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1710         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1711                       sources with the --enable-experimental-targets=R600
1712                       configure flag])
1713     fi
1714     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1715     NEED_RADEON_LLVM=yes
1716     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1717                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1718 }
1719
1720 dnl Gallium drivers
1721 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1722         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1723     NEED_NONNULL_WINSYS=yes
1724 fi
1725 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1726
1727 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1728 if test "x$with_gallium_drivers" != x; then
1729     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1730     for driver in $gallium_drivers; do
1731         case "x$driver" in
1732         xsvga)
1733             HAVE_GALLIUM_SVGA=yes
1734             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1735             gallium_check_st "svga/drm" "dri-vmwgfx" "xa-vmwgfx"
1736             ;;
1737         xi915)
1738             HAVE_GALLIUM_I915=yes
1739             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1740             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1741             if test "x$MESA_LLVM" = x1; then
1742                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1743             fi
1744             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1745             gallium_check_st "i915/drm" "dri-i915"
1746             DRICOMMON_NEED_LIBDRM=yes
1747             ;;
1748         xilo)
1749             HAVE_GALLIUM_ILO=yes
1750             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1751             gallium_require_drm_loader
1752             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1753             gallium_check_st "intel/drm" "dri-ilo"
1754             DRICOMMON_NEED_LIBDRM=yes
1755             ;;
1756         xr300)
1757             HAVE_GALLIUM_R300=yes
1758             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1759             gallium_require_llvm "Gallium R300"
1760             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1761             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1762             DRICOMMON_NEED_LIBDRM=yes
1763             ;;
1764         xr600)
1765             HAVE_GALLIUM_R600=yes
1766             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1767             gallium_require_drm_loader
1768             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1769             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1770                 radeon_llvm_check
1771                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1772             fi
1773             if test "x$enable_r600_llvm" = xyes; then
1774                 USE_R600_LLVM_COMPILER=yes;
1775             fi
1776             if test "x$enable_opencl" = xyes; then
1777                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1778             fi
1779             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau"
1780             DRICOMMON_NEED_LIBDRM=yes
1781             ;;
1782         xradeonsi)
1783             HAVE_GALLIUM_RADEONSI=yes
1784             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1785             gallium_require_drm_loader
1786             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1787             radeon_llvm_check
1788             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau"
1789             DRICOMMON_NEED_LIBDRM=yes
1790             ;;
1791         xnouveau)
1792             HAVE_GALLIUM_NOUVEAU=yes
1793             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1794             gallium_require_drm_loader
1795             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1796             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1797             DRICOMMON_NEED_LIBDRM=yes
1798             ;;
1799         xfreedreno)
1800             HAVE_GALLIUM_FREEDRENO=yes
1801             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1802             gallium_require_drm_loader
1803             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1804             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1805             DRICOMMON_NEED_LIBDRM=yes
1806             ;;
1807         xswrast)
1808             HAVE_GALLIUM_SOFTPIPE=yes
1809             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1810             if test "x$MESA_LLVM" = x1; then
1811                 HAVE_GALLIUM_LLVMPIPE=yes
1812                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1813             fi
1814
1815             if test "x$enable_dri" = xyes; then
1816                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1817             fi
1818             ;;
1819         *)
1820             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1821             ;;
1822         esac
1823     done
1824 fi
1825
1826 dnl Set LLVM_LIBS - This is done after the driver configuration so
1827 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1828 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1829 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1830 dnl this was causing the same libraries to be appear multiple times
1831 dnl in LLVM_LIBS.
1832
1833 if test "x$MESA_LLVM" != x0; then
1834
1835     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1836
1837     if test "x$with_llvm_shared_libs" = xyes; then
1838         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1839         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1840         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1841
1842         if test "x$llvm_have_one_so" = xyes; then
1843             dnl LLVM was built using auto*, so there is only one shared object.
1844             LLVM_LIBS="-l$LLVM_SO_NAME"
1845         else
1846             dnl If LLVM was built with CMake, there will be one shared object per
1847             dnl component.
1848             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1849                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1850         Please make sure you have built llvm with the --enable-shared option
1851         and that your llvm libraries are installed in $LLVM_LIBDIR
1852         If you have installed your llvm libraries to a different directory you
1853         can use the --with-llvm-prefix= configure flag to specify this directory.
1854         NOTE: Mesa is attempting to use llvm shared libraries because you have
1855         passed one of the following options to configure:
1856                 --with-llvm-shared-libs
1857                 --enable-opencl
1858         If you do not want to build with llvm shared libraries and instead want to
1859         use llvm static libraries then remove these options from your configure
1860         invocation and reconfigure.])])
1861
1862            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1863            dnl install uses a shared object for each compoenent and we have
1864            dnl already added all of these objects to LLVM_LIBS.
1865         fi
1866     fi
1867 fi
1868
1869 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1870 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1871 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1872 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1873 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1874 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1875 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1876 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1877 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1878 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1879
1880 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1881                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1882                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1883 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1884                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1885                                                   && test "x$MESA_LLVM" = x1)
1886
1887 if test "x$enable_gallium_loader" = xyes; then
1888     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1889
1890     if test "x$enable_gallium_drm_loader" = xyes; then
1891         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1892         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1893                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1894         if test "x$pipe_loader_have_xcb" = xyes; then
1895             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1896             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1897         fi
1898     fi
1899
1900     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1901     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1902 fi
1903
1904 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1905 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1906 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1907 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1908 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1909 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1910
1911 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1912                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1913                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1914                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1915 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1916                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1917 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1918 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1919 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1920 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1921 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1922 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1923 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1924
1925 AC_SUBST([ELF_LIB])
1926
1927 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1928 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1929 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1930 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1931
1932 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1933 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1934 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1935
1936 AC_SUBST([VDPAU_MAJOR], 1)
1937 AC_SUBST([VDPAU_MINOR], 0)
1938
1939 AC_SUBST([XVMC_MAJOR], 1)
1940 AC_SUBST([XVMC_MINOR], 0)
1941
1942 AC_SUBST([XA_MAJOR], 2)
1943 AC_SUBST([XA_MINOR], 0)
1944 AC_SUBST([XA_TINY], 0)
1945 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1946
1947 dnl Restore LDFLAGS and CPPFLAGS
1948 LDFLAGS="$_SAVE_LDFLAGS"
1949 CPPFLAGS="$_SAVE_CPPFLAGS"
1950
1951 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1952 if test "x$acv_mesa_CLANG" = xyes; then
1953     CFLAGS="$CFLAGS -Qunused-arguments"
1954     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1955 fi
1956
1957 dnl Add user CFLAGS and CXXFLAGS
1958 CFLAGS="$CFLAGS $USER_CFLAGS"
1959 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1960
1961 dnl Substitute the config
1962 AC_CONFIG_FILES([Makefile
1963                 src/Makefile
1964                 src/egl/Makefile
1965                 src/egl/drivers/Makefile
1966                 src/egl/drivers/dri2/Makefile
1967                 src/egl/drivers/glx/Makefile
1968                 src/egl/main/Makefile
1969                 src/egl/main/egl.pc
1970                 src/egl/wayland/Makefile
1971                 src/egl/wayland/wayland-drm/Makefile
1972                 src/egl/wayland/wayland-egl/Makefile
1973                 src/egl/wayland/wayland-egl/wayland-egl.pc
1974                 src/gallium/auxiliary/Makefile
1975                 src/gallium/auxiliary/pipe-loader/Makefile
1976                 src/gallium/drivers/Makefile
1977                 src/gallium/drivers/freedreno/Makefile
1978                 src/gallium/drivers/freedreno/a2xx/Makefile
1979                 src/gallium/drivers/freedreno/a3xx/Makefile
1980                 src/gallium/drivers/galahad/Makefile
1981                 src/gallium/drivers/i915/Makefile
1982                 src/gallium/drivers/identity/Makefile
1983                 src/gallium/drivers/ilo/Makefile
1984                 src/gallium/drivers/llvmpipe/Makefile
1985                 src/gallium/drivers/noop/Makefile
1986                 src/gallium/drivers/nouveau/Makefile
1987                 src/gallium/drivers/r300/Makefile
1988                 src/gallium/drivers/r600/Makefile
1989                 src/gallium/drivers/radeon/Makefile
1990                 src/gallium/drivers/radeonsi/Makefile
1991                 src/gallium/drivers/rbug/Makefile
1992                 src/gallium/drivers/softpipe/Makefile
1993                 src/gallium/drivers/svga/Makefile
1994                 src/gallium/drivers/trace/Makefile
1995                 src/gallium/state_trackers/Makefile
1996                 src/gallium/state_trackers/clover/Makefile
1997                 src/gallium/state_trackers/dri/Makefile
1998                 src/gallium/state_trackers/dri/drm/Makefile
1999                 src/gallium/state_trackers/dri/sw/Makefile
2000                 src/gallium/state_trackers/egl/Makefile
2001                 src/gallium/state_trackers/gbm/Makefile
2002                 src/gallium/state_trackers/glx/xlib/Makefile
2003                 src/gallium/state_trackers/osmesa/Makefile
2004                 src/gallium/state_trackers/vdpau/Makefile
2005                 src/gallium/state_trackers/vega/Makefile
2006                 src/gallium/state_trackers/xa/Makefile
2007                 src/gallium/state_trackers/xvmc/Makefile
2008                 src/gallium/targets/Makefile
2009                 src/gallium/targets/dri-freedreno/Makefile
2010                 src/gallium/targets/dri-i915/Makefile
2011                 src/gallium/targets/dri-ilo/Makefile
2012                 src/gallium/targets/dri-nouveau/Makefile
2013                 src/gallium/targets/dri-swrast/Makefile
2014                 src/gallium/targets/dri-vmwgfx/Makefile
2015                 src/gallium/targets/egl-static/Makefile
2016                 src/gallium/targets/gbm/Makefile
2017                 src/gallium/targets/opencl/Makefile
2018                 src/gallium/targets/osmesa/Makefile
2019                 src/gallium/targets/osmesa/osmesa.pc
2020                 src/gallium/targets/pipe-loader/Makefile
2021                 src/gallium/targets/radeonsi/dri/Makefile
2022                 src/gallium/targets/radeonsi/vdpau/Makefile
2023                 src/gallium/targets/r300/dri/Makefile
2024                 src/gallium/targets/r600/dri/Makefile
2025                 src/gallium/targets/r600/vdpau/Makefile
2026                 src/gallium/targets/r600/xvmc/Makefile
2027                 src/gallium/targets/libgl-xlib/Makefile
2028                 src/gallium/targets/vdpau-nouveau/Makefile
2029                 src/gallium/targets/xa-vmwgfx/Makefile
2030                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2031                 src/gallium/targets/xvmc-nouveau/Makefile
2032                 src/gallium/tests/trivial/Makefile
2033                 src/gallium/tests/unit/Makefile
2034                 src/gallium/winsys/Makefile
2035                 src/gallium/winsys/freedreno/drm/Makefile
2036                 src/gallium/winsys/i915/drm/Makefile
2037                 src/gallium/winsys/i915/sw/Makefile
2038                 src/gallium/winsys/intel/drm/Makefile
2039                 src/gallium/winsys/nouveau/drm/Makefile
2040                 src/gallium/winsys/radeon/drm/Makefile
2041                 src/gallium/winsys/svga/drm/Makefile
2042                 src/gallium/winsys/sw/dri/Makefile
2043                 src/gallium/winsys/sw/fbdev/Makefile
2044                 src/gallium/winsys/sw/null/Makefile
2045                 src/gallium/winsys/sw/wayland/Makefile
2046                 src/gallium/winsys/sw/wrapper/Makefile
2047                 src/gallium/winsys/sw/xlib/Makefile
2048                 src/gbm/Makefile
2049                 src/gbm/main/gbm.pc
2050                 src/glsl/Makefile
2051                 src/glx/Makefile
2052                 src/glx/tests/Makefile
2053                 src/gtest/Makefile
2054                 src/mapi/Makefile
2055                 src/mapi/es1api/Makefile
2056                 src/mapi/es1api/glesv1_cm.pc
2057                 src/mapi/es2api/Makefile
2058                 src/mapi/es2api/glesv2.pc
2059                 src/mapi/glapi/Makefile
2060                 src/mapi/glapi/gen/Makefile
2061                 src/mapi/glapi/tests/Makefile
2062                 src/mapi/shared-glapi/Makefile
2063                 src/mapi/shared-glapi/tests/Makefile
2064                 src/mapi/vgapi/Makefile
2065                 src/mapi/vgapi/vg.pc
2066                 src/mesa/Makefile
2067                 src/mesa/gl.pc
2068                 src/mesa/drivers/dri/dri.pc
2069                 src/mesa/drivers/dri/common/Makefile
2070                 src/mesa/drivers/dri/common/xmlpool/Makefile
2071                 src/mesa/drivers/dri/i915/Makefile
2072                 src/mesa/drivers/dri/i965/Makefile
2073                 src/mesa/drivers/dri/Makefile
2074                 src/mesa/drivers/dri/nouveau/Makefile
2075                 src/mesa/drivers/dri/r200/Makefile
2076                 src/mesa/drivers/dri/radeon/Makefile
2077                 src/mesa/drivers/dri/swrast/Makefile
2078                 src/mesa/drivers/osmesa/Makefile
2079                 src/mesa/drivers/osmesa/osmesa.pc
2080                 src/mesa/drivers/x11/Makefile
2081                 src/mesa/main/tests/Makefile
2082                 src/mesa/main/tests/hash_table/Makefile])
2083
2084 dnl Sort the dirs alphabetically
2085 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2086 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2087 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2088 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2089
2090 AC_OUTPUT
2091
2092 dnl
2093 dnl Output some configuration info for the user
2094 dnl
2095 echo ""
2096 echo "        prefix:          $prefix"
2097 echo "        exec_prefix:     $exec_prefix"
2098 echo "        libdir:          $libdir"
2099 echo "        includedir:      $includedir"
2100
2101 dnl API info
2102 echo ""
2103 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2104 echo "        OpenVG:          $enable_openvg"
2105
2106 dnl Driver info
2107 echo ""
2108 case "x$enable_osmesa$enable_gallium_osmesa" in
2109 xnoyes)
2110         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2111         ;;
2112 xyesno)
2113         echo "        OSMesa:          lib$OSMESA_LIB"
2114         ;;
2115 xnono)
2116         echo "        OSMesa:          no"
2117         ;;
2118 esac
2119
2120 if test "x$enable_dri" != xno; then
2121         # cleanup the drivers var
2122         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2123         if test "x$DRI_DIRS" = x; then
2124             echo "        DRI drivers:     no"
2125         else
2126             echo "        DRI drivers:     $dri_dirs"
2127         fi
2128         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2129 fi
2130
2131 case "x$enable_glx$enable_xlib_glx" in
2132 xyesyes)
2133     echo "        GLX:             Xlib-based"
2134     ;;
2135 xyesno)
2136     echo "        GLX:             DRI-based"
2137     ;;
2138 *)
2139     echo "        GLX:             $enable_glx"
2140     ;;
2141 esac
2142
2143 dnl EGL
2144 echo ""
2145 echo "        EGL:             $enable_egl"
2146 if test "$enable_egl" = yes; then
2147     echo "        EGL platforms:   $egl_platforms"
2148
2149     egl_drivers=""
2150     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2151         egl_drivers="$egl_drivers builtin:egl_glx"
2152     fi
2153     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2154         egl_drivers="$egl_drivers builtin:egl_dri2"
2155     fi
2156
2157     if test "x$enable_gallium_egl" = xyes; then
2158         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2159         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2160     else
2161         echo "        EGL drivers:    $egl_drivers"
2162     fi
2163 fi
2164
2165 echo ""
2166 if test "x$MESA_LLVM" = x1; then
2167     echo "        llvm:            yes"
2168     echo "        llvm-config:     $LLVM_CONFIG"
2169     echo "        llvm-version:    $LLVM_VERSION"
2170 else
2171     echo "        llvm:            no"
2172 fi
2173
2174 echo ""
2175 if test -n "$with_gallium_drivers"; then
2176     echo "        Gallium:         yes"
2177     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2178     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2179     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2180     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2181 else
2182     echo "        Gallium:         no"
2183 fi
2184
2185
2186 dnl Libraries
2187 echo ""
2188 echo "        Shared libs:     $enable_shared"
2189 echo "        Static libs:     $enable_static"
2190 echo "        Shared-glapi:    $enable_shared_glapi"
2191
2192 dnl Compiler options
2193 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2194 cflags=`echo $CFLAGS | \
2195     $SED 's/^ *//;s/  */ /;s/ *$//'`
2196 cxxflags=`echo $CXXFLAGS | \
2197     $SED 's/^ *//;s/  */ /;s/ *$//'`
2198 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2199 echo ""
2200 echo "        CFLAGS:          $cflags"
2201 echo "        CXXFLAGS:        $cxxflags"
2202 echo "        Macros:          $defines"
2203 echo ""
2204 if test "x$MESA_LLVM" = x1; then
2205     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2206     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2207     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2208     echo ""
2209 fi
2210 echo "        PYTHON2:         $PYTHON2"
2211
2212 echo ""
2213 echo "        Run '${MAKE-make}' to build Mesa"
2214 echo ""