configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.2.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  24     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  25
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27
  28 dnl Set internal versions
  29 OSMESA_VERSION=8
  30 AC_SUBST([OSMESA_VERSION])
  31
  32 dnl Versions for external dependencies
  33 LIBDRM_REQUIRED=2.4.24
  34 LIBDRM_RADEON_REQUIRED=2.4.42
  35 LIBDRM_INTEL_REQUIRED=2.4.38
  36 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  37 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  38 DRI2PROTO_REQUIRED=2.6
  39 GLPROTO_REQUIRED=1.4.14
  40 LIBDRM_XORG_REQUIRED=2.4.24
  41 LIBKMS_XORG_REQUIRED=1.0.0
  42
  43 dnl Check for progs
  44 AC_PROG_CPP
  45 AC_PROG_CC
  46 AX_PROG_CC_FOR_BUILD
  47 AC_PROG_CXX
  48 AX_PROG_CXX_FOR_BUILD
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AX_PYTHON_MODULE([libxml2], [needed])
  54 AC_PROG_SED
  55 AC_PROG_MKDIR_P
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 103     AC_MSG_CHECKING([whether gcc version is sufficient])
 104     major=0
 105     minor=0
 106
 107     GCC_VERSION=`$CC -dumpversion`
 108     if test $? -eq 0; then
 109         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 110         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 111     fi
 112
 113     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 114         AC_MSG_RESULT([no])
 115         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 116     else
 117         AC_MSG_RESULT([yes])
 118     fi
 119 fi
 120
 121 dnl Make sure the pkg-config macros are defined
 122 m4_ifndef([PKG_PROG_PKG_CONFIG],
 123     [m4_fatal([Could not locate the pkg-config autoconf macros.
 124   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 125   are in a different location, try setting the environment variable
 126   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 127 PKG_PROG_PKG_CONFIG()
 128
 129 dnl LIB_DIR - library basename
 130 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 131 AC_SUBST([LIB_DIR])
 132
 133 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 134 _SAVE_LDFLAGS="$LDFLAGS"
 135 _SAVE_CPPFLAGS="$CPPFLAGS"
 136
 137 dnl build host compiler macros
 138 DEFINES_FOR_BUILD=""
 139 AC_SUBST([DEFINES_FOR_BUILD])
 140 case "$build_os" in
 141 linux*|*-gnu*|gnu*)
 142     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 143     ;;
 144 solaris*)
 145     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 146     ;;
 147 cygwin*)
 148     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 149     ;;
 150 esac
 151
 152 dnl Compiler macros
 153 DEFINES=""
 154 AC_SUBST([DEFINES])
 155 case "$host_os" in
 156 linux*|*-gnu*|gnu*)
 157     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 158     ;;
 159 solaris*)
 160     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 161     ;;
 162 cygwin*)
 163     DEFINES="$DEFINES -DHAVE_PTHREAD"
 164     ;;
 165 esac
 166
 167 dnl Add flags for gcc and g++
 168 if test "x$GCC" = xyes; then
 169     case "$host_os" in
 170     cygwin*)
 171         CFLAGS="$CFLAGS -Wall -std=gnu99"
 172         ;;
 173     *)
 174         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 175         CFLAGS="$CFLAGS -Wall -std=c99"
 176         ;;
 177     esac
 178
 179     # Enable -Werror=implicit-function-declaration and
 180     # -Werror=missing-prototypes, if available, or otherwise, just
 181     # -Wmissing-prototypes.  This is particularly useful to avoid
 182     # generating a loadable driver module that has undefined symbols.
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 185     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 186     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 188                    AC_MSG_RESULT([yes]),
 189                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 190                     AC_MSG_RESULT([no])]);
 191
 192     # Enable -fvisibility=hidden if using a gcc that supports it
 193     save_CFLAGS="$CFLAGS"
 194     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 195     VISIBILITY_CFLAGS="-fvisibility=hidden"
 196     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 197     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 198                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 199
 200     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 201     CFLAGS=$save_CFLAGS
 202
 203     # Work around aliasing bugs - developers should comment this out
 204     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 205     CFLAGS="$CFLAGS -fno-strict-aliasing"
 206
 207     # gcc's builtin memcmp is slower than glibc's
 208     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 209     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 210     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 211 fi
 212 if test "x$GXX" = xyes; then
 213     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 231     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 232
 233     # gcc's builtin memcmp is slower than glibc's
 234     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 235     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 236     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 237 fi
 238
 239 dnl even if the compiler appears to support it, using visibility attributes isn't
 240 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 241 case "$host_os" in
 242 cygwin*)
 243     VISIBILITY_CFLAGS=""
 244     VISIBILITY_CXXFLAGS=""
 245     ;;
 246 esac
 247
 248 AC_SUBST([VISIBILITY_CFLAGS])
 249 AC_SUBST([VISIBILITY_CXXFLAGS])
 250
 251 dnl
 252 dnl Hacks to enable 32 or 64 bit build
 253 dnl
 254 AC_ARG_ENABLE([32-bit],
 255     [AS_HELP_STRING([--enable-32-bit],
 256         [build 32-bit libraries @<:@default=auto@:>@])],
 257     [enable_32bit="$enableval"],
 258     [enable_32bit=auto]
 259 )
 260 if test "x$enable_32bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m32"
 263         CCASFLAGS="$CCASFLAGS -m32"
 264     fi
 265     if test "x$GXX" = xyes; then
 266         CXXFLAGS="$CXXFLAGS -m32"
 267     fi
 268 fi
 269 AC_ARG_ENABLE([64-bit],
 270     [AS_HELP_STRING([--enable-64-bit],
 271         [build 64-bit libraries @<:@default=auto@:>@])],
 272     [enable_64bit="$enableval"],
 273     [enable_64bit=auto]
 274 )
 275 if test "x$enable_64bit" = xyes; then
 276     if test "x$GCC" = xyes; then
 277         CFLAGS="$CFLAGS -m64"
 278     fi
 279     if test "x$GXX" = xyes; then
 280         CXXFLAGS="$CXXFLAGS -m64"
 281     fi
 282 fi
 283
 284 dnl Can't have static and shared libraries, default to static if user
 285 dnl explicitly requested. If both disabled, set to static since shared
 286 dnl was explicitly requested.
 287 case "x$enable_static$enable_shared" in
 288 xyesyes )
 289     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 290     enable_shared=no
 291     ;;
 292 xnono )
 293     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 294     enable_static=yes
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 299
 300 dnl
 301 dnl other compiler options
 302 dnl
 303 AC_ARG_ENABLE([debug],
 304     [AS_HELP_STRING([--enable-debug],
 305         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 306     [enable_debug="$enableval"],
 307     [enable_debug=no]
 308 )
 309 if test "x$enable_debug" = xyes; then
 310     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 311     if test "x$GCC_FOR_BUILD" = xyes; then
 312         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 313     fi
 314     if test "x$GXX_FOR_BUILD" = xyes; then
 315         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 316     fi
 317
 318     DEFINES="$DEFINES -DDEBUG"
 319     if test "x$GCC" = xyes; then
 320         CFLAGS="$CFLAGS -g -O0"
 321     fi
 322     if test "x$GXX" = xyes; then
 323         CXXFLAGS="$CXXFLAGS -g -O0"
 324     fi
 325 fi
 326
 327 dnl
 328 dnl library names
 329 dnl
 330 LIB_PREFIX_GLOB='lib'
 331 LIB_VERSION_SEPARATOR='.'
 332 if test "$enable_static" = yes; then
 333     LIB_EXTENSION='a'
 334 else
 335     case "$host_os" in
 336     darwin* )
 337         LIB_EXTENSION='dylib' ;;
 338     cygwin* )
 339         dnl prefix can be 'cyg' or 'lib'
 340         LIB_PREFIX_GLOB='???'
 341         LIB_VERSION_SEPARATOR='-'
 342         LIB_EXTENSION='dll' ;;
 343     aix* )
 344         LIB_EXTENSION='a' ;;
 345     * )
 346         LIB_EXTENSION='so' ;;
 347     esac
 348 fi
 349 AC_ARG_WITH([gl-lib-name],
 350   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 351     [specify GL library name @<:@default=GL@:>@])],
 352   [GL_LIB=$withval],
 353   [GL_LIB=GL])
 354 AC_ARG_WITH([osmesa-lib-name],
 355   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 356     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 357   [OSMESA_LIB=$withval],
 358   [OSMESA_LIB=OSMesa])
 359 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 360 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 361
 362 dnl
 363 dnl Mangled Mesa support
 364 dnl
 365 AC_ARG_ENABLE([mangling],
 366   [AS_HELP_STRING([--enable-mangling],
 367     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 368   [enable_mangling="${enableval}"],
 369   [enable_mangling=no]
 370 )
 371 if test "x${enable_mangling}" = "xyes" ; then
 372   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 373   GL_LIB="Mangled${GL_LIB}"
 374   OSMESA_LIB="Mangled${OSMESA_LIB}"
 375 fi
 376 AC_SUBST([GL_LIB])
 377 AC_SUBST([OSMESA_LIB])
 378
 379 dnl
 380 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 381 dnl
 382 AC_ARG_ENABLE([texture-float],
 383     [AS_HELP_STRING([--enable-texture-float],
 384         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 385     [enable_texture_float="$enableval"],
 386     [enable_texture_float=no]
 387 )
 388 if test "x$enable_texture_float" = xyes; then
 389     AC_MSG_WARN([Floating-point textures enabled.])
 390     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 391     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 392 fi
 393
 394 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 395 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 396 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 397 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 398 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 399 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 400 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 401
 402 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409
 410 AC_SUBST([GL_LIB_NAME])
 411 AC_SUBST([OSMESA_LIB_NAME])
 412 AC_SUBST([EGL_LIB_NAME])
 413 AC_SUBST([GLESv1_CM_LIB_NAME])
 414 AC_SUBST([GLESv2_LIB_NAME])
 415 AC_SUBST([VG_LIB_NAME])
 416 AC_SUBST([GLAPI_LIB_NAME])
 417
 418 AC_SUBST([GL_LIB_GLOB])
 419 AC_SUBST([EGL_LIB_GLOB])
 420 AC_SUBST([GLESv1_CM_LIB_GLOB])
 421 AC_SUBST([GLESv2_LIB_GLOB])
 422 AC_SUBST([VG_LIB_GLOB])
 423 AC_SUBST([GLAPI_LIB_GLOB])
 424
 425 dnl
 426 dnl Arch/platform-specific settings
 427 dnl
 428 AC_ARG_ENABLE([asm],
 429     [AS_HELP_STRING([--disable-asm],
 430         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 431     [enable_asm="$enableval"],
 432     [enable_asm=yes]
 433 )
 434 asm_arch=""
 435 MESA_ASM_FILES=""
 436 AC_MSG_CHECKING([whether to enable assembly])
 437 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 438 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 439 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 440     case "$host_cpu" in
 441     i?86 | x86_64)
 442         enable_asm=no
 443         AC_MSG_RESULT([no, cross compiling])
 444         ;;
 445     esac
 446 fi
 447 # check for supported arches
 448 if test "x$enable_asm" = xyes; then
 449     case "$host_cpu" in
 450     i?86)
 451         case "$host_os" in
 452         linux* | *freebsd* | dragonfly* | *netbsd*)
 453             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 454             ;;
 455         esac
 456         ;;
 457     x86_64)
 458         case "$host_os" in
 459         linux* | *freebsd* | dragonfly* | *netbsd*)
 460             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 461             ;;
 462         esac
 463         ;;
 464     sparc*)
 465         case "$host_os" in
 466         linux*)
 467             asm_arch=sparc
 468             ;;
 469         esac
 470         ;;
 471     esac
 472
 473     case "$asm_arch" in
 474     x86)
 475         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 476         MESA_ASM_FILES='$(X86_FILES)'
 477         AC_MSG_RESULT([yes, x86])
 478         ;;
 479     x86_64)
 480         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 481         MESA_ASM_FILES='$(X86_64_FILES)'
 482         AC_MSG_RESULT([yes, x86_64])
 483         ;;
 484     sparc)
 485         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 486         MESA_ASM_FILES='$(SPARC_FILES)'
 487         AC_MSG_RESULT([yes, sparc])
 488         ;;
 489     *)
 490         AC_MSG_RESULT([no, platform not supported])
 491         ;;
 492     esac
 493 fi
 494 AC_SUBST([MESA_ASM_FILES])
 495
 496 dnl Check to see if dlopen is in default libraries (like Solaris, which
 497 dnl has it in libc), or if libdl is needed to get it.
 498 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 499     [AC_CHECK_LIB([dl], [dlopen],
 500        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 501 AC_SUBST([DLOPEN_LIBS])
 502
 503 case "$host_os" in
 504 darwin*|mingw*)
 505     ;;
 506 *)
 507     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 508                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 509                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 510     AC_SUBST([CLOCK_LIB])
 511     ;;
 512 esac
 513
 514 dnl See if posix_memalign is available
 515 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 516
 517 dnl Check for pthreads
 518 AX_PTHREAD
 519 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 520 dnl to -pthread, which causes problems if we need -lpthread to appear in
 521 dnl pkgconfig files.
 522 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 523
 524 dnl SELinux awareness.
 525 AC_ARG_ENABLE([selinux],
 526     [AS_HELP_STRING([--enable-selinux],
 527         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 528     [MESA_SELINUX="$enableval"],
 529     [MESA_SELINUX=no])
 530 if test "x$enable_selinux" = "xyes"; then
 531     AC_CHECK_HEADER([selinux/selinux.h],[],
 532                     [AC_MSG_ERROR([SELinux headers not found])])
 533     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 534                  [AC_MSG_ERROR([SELinux library not found])])
 535     SELINUX_LIBS="-lselinux"
 536     DEFINES="$DEFINES -DMESA_SELINUX"
 537 fi
 538 AC_SUBST([SELINUX_LIBS])
 539
 540 dnl Options for APIs
 541 AC_ARG_ENABLE([opengl],
 542     [AS_HELP_STRING([--disable-opengl],
 543         [disable support for standard OpenGL API @<:@default=no@:>@])],
 544     [enable_opengl="$enableval"],
 545     [enable_opengl=yes])
 546 AC_ARG_ENABLE([gles1],
 547     [AS_HELP_STRING([--enable-gles1],
 548         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 549     [enable_gles1="$enableval"],
 550     [enable_gles1=no])
 551 AC_ARG_ENABLE([gles2],
 552     [AS_HELP_STRING([--enable-gles2],
 553         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 554     [enable_gles2="$enableval"],
 555     [enable_gles2=no])
 556 AC_ARG_ENABLE([openvg],
 557     [AS_HELP_STRING([--enable-openvg],
 558         [enable support for OpenVG API @<:@default=no@:>@])],
 559     [enable_openvg="$enableval"],
 560     [enable_openvg=no])
 561
 562 AC_ARG_ENABLE([dri],
 563     [AS_HELP_STRING([--enable-dri],
 564         [enable DRI modules @<:@default=enabled@:>@])],
 565     [enable_dri="$enableval"],
 566     [enable_dri=yes])
 567 AC_ARG_ENABLE([glx],
 568     [AS_HELP_STRING([--enable-glx],
 569         [enable GLX library @<:@default=enabled@:>@])],
 570     [enable_glx="$enableval"],
 571     [enable_glx=yes])
 572 AC_ARG_ENABLE([osmesa],
 573     [AS_HELP_STRING([--enable-osmesa],
 574         [enable OSMesa library @<:@default=disabled@:>@])],
 575     [enable_osmesa="$enableval"],
 576     [enable_osmesa=no])
 577 AC_ARG_ENABLE([egl],
 578     [AS_HELP_STRING([--disable-egl],
 579         [disable EGL library @<:@default=enabled@:>@])],
 580     [enable_egl="$enableval"],
 581     [enable_egl=yes])
 582
 583 AC_ARG_ENABLE([xorg],
 584     [AS_HELP_STRING([--enable-xorg],
 585         [enable support for X.Org DDX API @<:@default=no@:>@])],
 586     [enable_xorg="$enableval"],
 587     [enable_xorg=no])
 588 AC_ARG_ENABLE([xa],
 589     [AS_HELP_STRING([--enable-xa],
 590         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 591     [enable_xa="$enableval"],
 592     [enable_xa=no])
 593 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 594 enable_d3d1x=no
 595 dnl AC_ARG_ENABLE([d3d1x],
 596 dnl     [AS_HELP_STRING([--enable-d3d1x],
 597 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 598 dnl     [enable_d3d1x="$enableval"],
 599 dnl     [enable_d3d1x=no])
 600 AC_ARG_ENABLE([gbm],
 601    [AS_HELP_STRING([--enable-gbm],
 602          [enable gbm library @<:@default=auto@:>@])],
 603    [enable_gbm="$enableval"],
 604    [enable_gbm=auto])
 605
 606 AC_ARG_ENABLE([xvmc],
 607    [AS_HELP_STRING([--enable-xvmc],
 608          [enable xvmc library @<:@default=auto@:>@])],
 609    [enable_xvmc="$enableval"],
 610    [enable_xvmc=auto])
 611 AC_ARG_ENABLE([vdpau],
 612    [AS_HELP_STRING([--enable-vdpau],
 613          [enable vdpau library @<:@default=auto@:>@])],
 614    [enable_vdpau="$enableval"],
 615    [enable_vdpau=auto])
 616 AC_ARG_ENABLE([opencl],
 617    [AS_HELP_STRING([--enable-opencl],
 618          [enable OpenCL library NOTE: Enabling this option will also enable
 619           --with-llvm-shared-libs
 620           @<:@default=no@:>@])],
 621    [],
 622    [enable_opencl=no])
 623 AC_ARG_ENABLE([xlib_glx],
 624     [AS_HELP_STRING([--enable-xlib-glx],
 625         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 626     [enable_xlib_glx="$enableval"],
 627     [enable_xlib_glx=no])
 628 AC_ARG_ENABLE([gallium_egl],
 629     [AS_HELP_STRING([--enable-gallium-egl],
 630         [enable optional EGL state tracker (not required
 631          for EGL support in Gallium with OpenGL and OpenGL ES)
 632          @<:@default=disable@:>@])],
 633     [enable_gallium_egl="$enableval"],
 634     [enable_gallium_egl=no])
 635 AC_ARG_ENABLE([gallium_gbm],
 636     [AS_HELP_STRING([--enable-gallium-gbm],
 637         [enable optional gbm state tracker (not required for
 638          gbm support in Gallium)
 639          @<:@default=auto@:>@])],
 640     [enable_gallium_gbm="$enableval"],
 641     [enable_gallium_gbm=auto])
 642
 643 AC_ARG_ENABLE([r600-llvm-compiler],
 644     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 645         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 646     [enable_r600_llvm="$enableval"],
 647     [enable_r600_llvm=no])
 648
 649 AC_ARG_ENABLE([gallium_tests],
 650     [AS_HELP_STRING([--enable-gallium-tests],
 651         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 652     [enable_gallium_tests="$enableval"],
 653     [enable_gallium_tests=no])
 654
 655 # Option for Gallium drivers
 656
 657 # Keep this in sync with the --with-gallium-drivers help string default value
 658 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 659
 660 AC_ARG_WITH([gallium-drivers],
 661     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 662         [comma delimited Gallium drivers list, e.g.
 663         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 664         @<:@default=r300,r600,svga,swrast@:>@])],
 665     [with_gallium_drivers="$withval"],
 666     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 667
 668 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 669 # here so that the script doesn't choke on an unknown driver name later.
 670 case "$with_gallium_drivers" in
 671     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 672     no) with_gallium_drivers='' ;;
 673 esac
 674
 675 if test "x$enable_opengl" = xno -a \
 676         "x$enable_gles1" = xno -a \
 677         "x$enable_gles2" = xno -a \
 678         "x$enable_openvg" = xno -a \
 679         "x$enable_xorg" = xno -a \
 680         "x$enable_xa" = xno -a \
 681         "x$enable_d3d1x" = xno -a \
 682         "x$enable_xvmc" = xno -a \
 683         "x$enable_vdpau" = xno -a \
 684         "x$enable_opencl" = xno; then
 685     AC_MSG_ERROR([at least one API should be enabled])
 686 fi
 687
 688 API_DEFINES=""
 689 if test "x$enable_opengl" = xno; then
 690     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 691 else
 692     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 693 fi
 694 if test "x$enable_gles1" = xyes; then
 695     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 696 fi
 697 if test "x$enable_gles2" = xyes; then
 698     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 699 fi
 700 AC_SUBST([API_DEFINES])
 701
 702 if test "x$enable_glx" = xno; then
 703     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 704     enable_xlib_glx=no
 705 fi
 706
 707 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 708     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 709 fi
 710
 711 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 712     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 713 fi
 714
 715 # Disable GLX if OpenGL is not enabled
 716 if test "x$enable_glx$enable_opengl" = xyesno; then
 717     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 718     enable_glx=no
 719 fi
 720
 721 # Disable GLX if DRI and Xlib-GLX are not enabled
 722 if test "x$enable_glx" = xyes -a \
 723         "x$enable_dri" = xno -a \
 724         "x$enable_xlib_glx" = xno; then
 725     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 726     enable_glx=no
 727 fi
 728
 729 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 730 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 731                                   "x$enable_osmesa" = xyes)
 732
 733 AC_ARG_ENABLE([shared-glapi],
 734     [AS_HELP_STRING([--enable-shared-glapi],
 735         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 736     [enable_shared_glapi="$enableval"],
 737     [enable_shared_glapi="$enable_dri"])
 738
 739 # Shared GLAPI is only useful for DRI
 740 if test "x$enable_dri" = xno; then
 741     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 742     enable_shared_glapi=no
 743 fi
 744
 745 if test "x$enable_shared_glapi" = xyes; then
 746     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 747     # the remap table)
 748     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 749     CORE_DIRS="mapi/shared-glapi"
 750 fi
 751 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 752
 753 dnl
 754 dnl Driver specific build directories
 755 dnl
 756 GALLIUM_DIRS="auxiliary drivers state_trackers"
 757 GALLIUM_TARGET_DIRS=""
 758 GALLIUM_WINSYS_DIRS="sw"
 759 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 760 GALLIUM_STATE_TRACKERS_DIRS=""
 761
 762 # build glapi if OpenGL is enabled
 763 if test "x$enable_opengl" = xyes; then
 764     CORE_DIRS="$CORE_DIRS mapi/glapi"
 765 fi
 766
 767 # build es1api if OpenGL ES 1.x is enabled
 768 if test "x$enable_gles1" = xyes; then
 769     CORE_DIRS="$CORE_DIRS mapi/es1api"
 770 fi
 771
 772 # build es2api if OpenGL ES 2.x is enabled
 773 if test "x$enable_gles2" = xyes; then
 774     CORE_DIRS="$CORE_DIRS mapi/es2api"
 775 fi
 776
 777 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 778 case "x$enable_opengl$enable_gles1$enable_gles2" in
 779 x*yes*)
 780     CORE_DIRS="mapi/glapi/gen $CORE_DIRS gtest glsl mesa"
 781     ;;
 782 esac
 783
 784 case "x$enable_glx$enable_xlib_glx" in
 785 xyesyes)
 786     DRIVER_DIRS="$DRIVER_DIRS x11"
 787     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 788     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 789     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 790     HAVE_WINSYS_XLIB="yes"
 791     ;;
 792 xyesno)
 793     # DRI-based GLX
 794     SRC_DIRS="$SRC_DIRS glx"
 795     ;;
 796 esac
 797
 798 if test "x$enable_dri" = xyes; then
 799     DRIVER_DIRS="$DRIVER_DIRS dri"
 800
 801     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 802     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 803     HAVE_ST_DRI="yes"
 804 fi
 805
 806 if test "x$enable_osmesa" = xyes; then
 807     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 808 fi
 809
 810 AC_SUBST([SRC_DIRS])
 811 AC_SUBST([DRIVER_DIRS])
 812 AC_SUBST([GALLIUM_DIRS])
 813 AC_SUBST([GALLIUM_TARGET_DIRS])
 814 AC_SUBST([GALLIUM_WINSYS_DIRS])
 815 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 816 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 817 AC_SUBST([MESA_LLVM])
 818
 819 # Check for libdrm
 820 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 821                   [have_libdrm=yes], [have_libdrm=no])
 822
 823 if test "x$enable_dri" = xyes; then
 824     # DRI must be shared, I think
 825     if test "$enable_static" = yes; then
 826         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 827     fi
 828
 829     # not a hard requirement as swrast does not depend on it
 830     if test "x$have_libdrm" = xyes; then
 831         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 832     fi
 833 fi
 834
 835 dnl Direct rendering or just indirect rendering
 836 case "$host_os" in
 837 gnu*)
 838     dnl Disable by default on GNU/Hurd
 839     driglx_direct_default="no"
 840     ;;
 841 cygwin*)
 842     dnl Disable by default on cygwin
 843     driglx_direct_default="no"
 844     ;;
 845 *)
 846     driglx_direct_default="yes"
 847     ;;
 848 esac
 849 AC_ARG_ENABLE([driglx-direct],
 850     [AS_HELP_STRING([--disable-driglx-direct],
 851         [disable direct rendering in GLX and EGL for DRI \
 852             @<:@default=auto@:>@])],
 853     [driglx_direct="$enableval"],
 854     [driglx_direct="$driglx_direct_default"])
 855
 856 dnl
 857 dnl libGL configuration per driver
 858 dnl
 859 case "x$enable_glx$enable_xlib_glx" in
 860 xyesyes)
 861     # Xlib-based GLX
 862     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 863     GL_PC_REQ_PRIV="x11 xext"
 864     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 865     GL_LIB_DEPS="$XLIBGL_LIBS"
 866     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 868     ;;
 869 xyesno)
 870     # DRI-based GLX
 871     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 872     if test x"$driglx_direct" = xyes; then
 873         if test "x$have_libdrm" != xyes; then
 874             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 875         fi
 876         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 877         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 878     fi
 879
 880     # find the DRI deps for libGL
 881     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 882
 883     # add xf86vidmode if available
 884     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 885     if test "$HAVE_XF86VIDMODE" = yes ; then
 886         dri_modules="$dri_modules xxf86vm"
 887     fi
 888
 889     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 890     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 891     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 892     GL_LIB_DEPS="$DRIGL_LIBS"
 893
 894     # need DRM libs, $PTHREAD_LIBS, etc.
 895     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 897     ;;
 898 esac
 899
 900 # This is outside the case (above) so that it is invoked even for non-GLX
 901 # builds.
 902 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 903
 904 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 905 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 906 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 907 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 908
 909 AC_SUBST([X11_INCLUDES])
 910 AC_SUBST([GL_LIB_DEPS])
 911 AC_SUBST([GL_PC_REQ_PRIV])
 912 AC_SUBST([GL_PC_LIB_PRIV])
 913 AC_SUBST([GL_PC_CFLAGS])
 914 AC_SUBST([DRI_PC_REQ_PRIV])
 915 AC_SUBST([GLESv1_CM_LIB_DEPS])
 916 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 917 AC_SUBST([GLESv2_LIB_DEPS])
 918 AC_SUBST([GLESv2_PC_LIB_PRIV])
 919
 920 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 921
 922 AC_SUBST([HAVE_XF86VIDMODE])
 923
 924 dnl
 925 dnl More GLX setup
 926 dnl
 927 case "x$enable_glx$enable_xlib_glx" in
 928 xyesyes)
 929     DEFINES="$DEFINES -DUSE_XSHM"
 930     ;;
 931 xyesno)
 932     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 933     if test "x$driglx_direct" = xyes; then
 934         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 935     fi
 936     ;;
 937 esac
 938
 939 dnl
 940 dnl TLS detection
 941 dnl
 942
 943 AC_ARG_ENABLE([glx-tls],
 944     [AS_HELP_STRING([--enable-glx-tls],
 945         [enable TLS support in GLX @<:@default=disabled@:>@])],
 946     [GLX_USE_TLS="$enableval"],
 947     [GLX_USE_TLS=no])
 948 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 949
 950 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 951       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 952
 953 dnl
 954 dnl More DRI setup
 955 dnl
 956 dnl Directory for DRI drivers
 957 AC_ARG_WITH([dri-driverdir],
 958     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 959         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 960     [DRI_DRIVER_INSTALL_DIR="$withval"],
 961     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 962 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 963 dnl Extra search path for DRI drivers
 964 AC_ARG_WITH([dri-searchpath],
 965     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 966         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 967     [DRI_DRIVER_SEARCH_DIR="$withval"],
 968     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 969 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 970 dnl Which drivers to build - default is chosen by platform
 971 AC_ARG_WITH([dri-drivers],
 972     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 973         [comma delimited DRI drivers list, e.g.
 974         "swrast,i965,radeon" @<:@default=auto@:>@])],
 975     [with_dri_drivers="$withval"],
 976     [with_dri_drivers=yes])
 977 if test "x$with_dri_drivers" = x; then
 978     with_dri_drivers=no
 979 fi
 980
 981 dnl If $with_dri_drivers is yes, directories will be added through
 982 dnl platform checks
 983 DRI_DIRS=""
 984 case "$with_dri_drivers" in
 985 no) ;;
 986 yes)
 987     # classic DRI drivers require FEATURE_GL to build
 988     if test "x$enable_opengl" = xyes; then
 989         DRI_DIRS="yes"
 990     fi
 991     ;;
 992 *)
 993     # verify the requested driver directories exist
 994     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 995     for driver in $dri_drivers; do
 996         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 997             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 998     done
 999     DRI_DIRS="$dri_drivers"
1000     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1001         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1002     fi
1003     ;;
1004 esac
1005
1006 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1007 if test "x$enable_dri" = xyes; then
1008     # Platform specific settings and drivers to build
1009     case "$host_os" in
1010     linux*)
1011         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1012         DEFINES="$DEFINES -DHAVE_ALIAS"
1013
1014         case "$host_cpu" in
1015         x86_64)
1016             if test "x$DRI_DIRS" = "xyes"; then
1017                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1018             fi
1019             ;;
1020         powerpc*)
1021             # Build only the drivers for cards that exist on PowerPC.
1022             if test "x$DRI_DIRS" = "xyes"; then
1023                 DRI_DIRS="r200 radeon swrast"
1024             fi
1025             ;;
1026         sparc*)
1027             # Build only the drivers for cards that exist on sparc
1028             if test "x$DRI_DIRS" = "xyes"; then
1029                 DRI_DIRS="r200 radeon swrast"
1030             fi
1031             ;;
1032         esac
1033         ;;
1034     freebsd* | dragonfly* | *netbsd*)
1035         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1036         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1037
1038         if test "x$DRI_DIRS" = "xyes"; then
1039             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1040         fi
1041         ;;
1042     gnu*)
1043         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1044         DEFINES="$DEFINES -DHAVE_ALIAS"
1045         ;;
1046     solaris*)
1047         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1048         ;;
1049     cygwin*)
1050         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1051         if test "x$DRI_DIRS" = "xyes"; then
1052             DRI_DIRS="swrast"
1053         fi
1054         ;;
1055     esac
1056
1057     # default drivers
1058     if test "x$DRI_DIRS" = "xyes"; then
1059         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1060     fi
1061
1062     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1063
1064     # Check for expat
1065     if test "x$enable_dri" = xyes; then
1066         EXPAT_INCLUDES=""
1067         EXPAT_LIB=-lexpat
1068         AC_ARG_WITH([expat],
1069             [AS_HELP_STRING([--with-expat=DIR],
1070                 [expat install directory])],[
1071             EXPAT_INCLUDES="-I$withval/include"
1072             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1073             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1074             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1075             ])
1076         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1077         save_LIBS="$LIBS"
1078         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1079             [AC_MSG_ERROR([Expat required for DRI.])])
1080         LIBS="$save_LIBS"
1081     fi
1082
1083     # if we are building any dri driver other than swrast or using the dri state tracker ...
1084     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast -a "x$enable_dri" = xyes; then
1085         # ... libdrm is required
1086         if test "x$have_libdrm" != xyes; then
1087             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1088         fi
1089         # ... and build dricommon
1090         HAVE_COMMON_DRI=yes
1091     fi
1092
1093     # put all the necessary libs together
1094     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1095     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1096 fi
1097 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1098 AC_SUBST([DRI_DIRS])
1099 AC_SUBST([EXPAT_INCLUDES])
1100 AC_SUBST([DRI_LIB_DEPS])
1101 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1102
1103 case $DRI_DIRS in
1104 *i915*|*i965*)
1105     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1106
1107     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1108         case $d in
1109         i915)
1110             HAVE_I915_DRI=yes;
1111             ;;
1112         i965)
1113             HAVE_I965_DRI=yes;
1114             ;;
1115         esac
1116     done
1117
1118     ;;
1119 esac
1120
1121 case $DRI_DIRS in
1122 *nouveau*)
1123     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1124     HAVE_NOUVEAU_DRI=yes;
1125     ;;
1126 esac
1127
1128 case $DRI_DIRS in
1129 *radeon*|*r200*)
1130     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1131
1132     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1133         case $d in
1134         radeon)
1135             HAVE_RADEON_DRI=yes;
1136             ;;
1137         r200)
1138             HAVE_R200_DRI=yes;
1139             ;;
1140         esac
1141     done
1142
1143     ;;
1144 esac
1145
1146 case $DRI_DIRS in
1147 *swrast*)
1148     HAVE_SWRAST_DRI=yes;
1149     ;;
1150 esac
1151
1152 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1153 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1154 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1156 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1157 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1158 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1159
1160 dnl
1161 dnl OSMesa configuration
1162 dnl
1163
1164 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1165 AC_ARG_WITH([osmesa-bits],
1166     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1167         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1168     [osmesa_bits="$withval"],
1169     [osmesa_bits=8])
1170 if test "x$osmesa_bits" != x8; then
1171     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1172         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1173         osmesa_bits=8
1174     fi
1175 fi
1176 case "x$osmesa_bits" in
1177 x8)
1178     OSMESA_LIB="${OSMESA_LIB}"
1179     ;;
1180 x16|x32)
1181     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1182     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1183     ;;
1184 *)
1185     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1186     ;;
1187 esac
1188
1189 if test "x$enable_osmesa" = xyes; then
1190     # only link libraries with osmesa if shared
1191     if test "$enable_static" = no; then
1192         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1193     else
1194         OSMESA_LIB_DEPS=""
1195     fi
1196     OSMESA_MESA_DEPS=""
1197     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1198 fi
1199
1200 AC_SUBST([OSMESA_LIB_DEPS])
1201 AC_SUBST([OSMESA_MESA_DEPS])
1202 AC_SUBST([OSMESA_PC_REQ])
1203 AC_SUBST([OSMESA_PC_LIB_PRIV])
1204
1205 dnl
1206 dnl gbm configuration
1207 dnl
1208 if test "x$enable_gbm" = xauto; then
1209     case "$with_egl_platforms" in
1210         *drm*)
1211             enable_gbm=yes ;;
1212          *)
1213             enable_gbm=no ;;
1214     esac
1215 fi
1216 if test "x$enable_gbm" = xyes; then
1217     SRC_DIRS="$SRC_DIRS gbm"
1218
1219     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1220                       AC_MSG_ERROR([gbm needs udev]))
1221
1222     if test "x$enable_dri" = xyes; then
1223         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1224         if test "x$enable_shared_glapi" = xno; then
1225             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1226         fi
1227     fi
1228 fi
1229 GBM_PC_REQ_PRIV="libudev"
1230 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1231 AC_SUBST([GBM_PC_REQ_PRIV])
1232 AC_SUBST([GBM_PC_LIB_PRIV])
1233
1234 dnl
1235 dnl EGL configuration
1236 dnl
1237 EGL_CLIENT_APIS=""
1238
1239 if test "x$enable_egl" = xyes; then
1240     SRC_DIRS="$SRC_DIRS egl"
1241     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1242
1243     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1244
1245     if test "$enable_static" != yes; then
1246         # build egl_glx when libGL is built
1247         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1248                           [have_libudev=yes],[have_libudev=no])
1249         if test "$have_libudev" = yes; then
1250             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1251         fi
1252
1253         if test "x$enable_dri" = xyes; then
1254             HAVE_EGL_DRIVER_DRI2=1
1255         fi
1256
1257     fi
1258 fi
1259 AC_SUBST([EGL_LIB_DEPS])
1260
1261 dnl
1262 dnl EGL Gallium configuration
1263 dnl
1264 if test "x$enable_gallium_egl" = xyes; then
1265     if test "x$with_gallium_drivers" = x; then
1266         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1267     fi
1268     if test "x$enable_egl" = xno; then
1269         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1270     fi
1271     if test "x$have_libdrm" != xyes; then
1272         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1273     fi
1274
1275     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1276     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1277     HAVE_ST_EGL="yes"
1278 fi
1279
1280 dnl
1281 dnl gbm Gallium configuration
1282 dnl
1283 if test "x$enable_gallium_gbm" = xauto; then
1284     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1285         yesyesyes*drm*)
1286             enable_gallium_gbm=yes ;;
1287          *)
1288             enable_gallium_gbm=no ;;
1289     esac
1290 fi
1291 if test "x$enable_gallium_gbm" = xyes; then
1292     if test "x$with_gallium_drivers" = x; then
1293         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1294     fi
1295     if test "x$enable_gbm" = xno; then
1296         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1297     fi
1298     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1299     if test "x$enable_dri" = xno; then
1300         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1301     fi
1302
1303     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1304     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1305     HAVE_ST_GBM="yes"
1306     enable_gallium_loader=yes
1307 fi
1308
1309 dnl
1310 dnl X.Org DDX configuration
1311 dnl
1312 if test "x$enable_xorg" = xyes; then
1313     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1314     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1315     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1316     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1317         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1318         HAVE_XEXTPROTO_71="no")
1319     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1320     HAVE_ST_XORG=yes
1321 fi
1322
1323 dnl
1324 dnl XA configuration
1325 dnl
1326 if test "x$enable_xa" = xyes; then
1327 AC_PROG_AWK
1328 AC_PROG_GREP
1329 AC_CHECK_PROG(NM, nm, "nm")
1330 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1331 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1332 enable_xa=no
1333 fi
1334 fi
1335 if test "x$enable_xa" = xyes; then
1336     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1337     HAVE_ST_XA=yes
1338     AC_SUBST(AWK)
1339     AC_SUBST(GREP)
1340     AC_SUBST(NM)
1341 fi
1342
1343 dnl
1344 dnl OpenVG configuration
1345 dnl
1346 VG_LIB_DEPS=""
1347
1348 if test "x$enable_openvg" = xyes; then
1349     if test "x$enable_egl" = xno; then
1350         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1351     fi
1352     if test "x$with_gallium_drivers" = x; then
1353         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1354     fi
1355     if test "x$enable_gallium_egl" = xno; then
1356         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1357     fi
1358
1359     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1360     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1361     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1362     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1363     HAVE_ST_VEGA=yes
1364     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1365     AC_SUBST([VG_PC_LIB_PRIV])
1366 fi
1367 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1368
1369 dnl
1370 dnl D3D1X configuration
1371 dnl
1372
1373 if test "x$enable_d3d1x" = xyes; then
1374     if test "x$with_gallium_drivers" = x; then
1375         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1376     fi
1377
1378     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1379     HAVE_ST_D3D1X=yes
1380 fi
1381
1382 dnl
1383 dnl Gallium G3DVL configuration
1384 dnl
1385 AC_ARG_ENABLE([gallium-g3dvl],
1386     [AS_HELP_STRING([--enable-gallium-g3dvl],
1387         [build gallium g3dvl @<:@default=disabled@:>@])],
1388     [enable_gallium_g3dvl="$enableval"],
1389     [enable_gallium_g3dvl=no])
1390 if test "x$enable_gallium_g3dvl" = xyes; then
1391     if test "x$with_gallium_drivers" = x; then
1392         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1393     fi
1394
1395     if test "x$enable_xvmc" = xauto; then
1396         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1397     fi
1398
1399     if test "x$enable_vdpau" = xauto; then
1400         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1401     fi
1402 fi
1403
1404 if test "x$enable_xvmc" = xyes; then
1405     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1406     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1407     HAVE_ST_XVMC="yes"
1408 fi
1409
1410 if test "x$enable_vdpau" = xyes; then
1411     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1412     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1413     HAVE_ST_VDPAU="yes"
1414 fi
1415
1416 dnl
1417 dnl OpenCL configuration
1418 dnl
1419
1420 AC_ARG_WITH([libclc-path],
1421    [AS_HELP_STRING([--with-libclc-path],
1422          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1423    [LIBCLC_PATH="$withval"],
1424    [LIBCLC_PATH=""])
1425
1426 if test "x$LIBCLC_PATH" != x; then
1427    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1428                   Please review the updated build instructions for clover:
1429                   http://dri.freedesktop.org/wiki/GalliumCompute])
1430 fi
1431
1432
1433 AC_ARG_WITH([clang-libdir],
1434    [AS_HELP_STRING([--with-clang-libdir],
1435          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1436    [CLANG_LIBDIR="$withval"],
1437    [CLANG_LIBDIR=""])
1438
1439 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1440 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1441 AC_SUBST([LIBCLC_INCLUDEDIR])
1442 AC_SUBST([LIBCLC_LIBEXECDIR])
1443
1444 if test "x$enable_opencl" = xyes; then
1445     if test "x$with_gallium_drivers" = x; then
1446         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1447     fi
1448
1449     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1450         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1451     fi
1452
1453     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1454         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1455     fi
1456
1457     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1458     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1459     enable_gallium_loader=yes
1460 fi
1461
1462 if test "x$enable_gallium_gbm" = xyes || test "x$enable_opencl" = xyes; then
1463     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1464 fi
1465
1466 dnl
1467 dnl Gallium configuration
1468 dnl
1469 if test "x$with_gallium_drivers" != x; then
1470     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1471 fi
1472 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1473
1474 AC_SUBST([LLVM_BINDIR])
1475 AC_SUBST([LLVM_CFLAGS])
1476 AC_SUBST([LLVM_CPPFLAGS])
1477 AC_SUBST([LLVM_CXXFLAGS])
1478 AC_SUBST([LLVM_LIBDIR])
1479 AC_SUBST([LLVM_LIBS])
1480 AC_SUBST([LLVM_LDFLAGS])
1481 AC_SUBST([LLVM_INCLUDEDIR])
1482 AC_SUBST([LLVM_VERSION])
1483 AC_SUBST([CLANG_RESOURCE_DIR])
1484
1485 case "x$enable_opengl$enable_gles1$enable_gles2" in
1486 x*yes*)
1487     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1488     HAVE_OPENGL=yes
1489     ;;
1490 esac
1491 AM_CONDITIONAL(HAVE_OPENGL, test "x$HAVE_OPENGL" = xyes)
1492
1493 AC_SUBST([VG_LIB_DEPS])
1494 AC_SUBST([EGL_CLIENT_APIS])
1495
1496 dnl
1497 dnl EGL Platforms configuration
1498 dnl
1499 AC_ARG_WITH([egl-platforms],
1500     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1501         [comma delimited native platforms libEGL supports, e.g.
1502         "x11,drm" @<:@default=auto@:>@])],
1503     [with_egl_platforms="$withval"],
1504     [if test "x$enable_egl" = xyes; then
1505         with_egl_platforms="x11"
1506     else
1507         with_egl_platforms=""
1508     fi])
1509
1510 EGL_PLATFORMS=""
1511
1512 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1513     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1514 fi
1515
1516 # Do per-EGL platform setups and checks
1517 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1518 for plat in $egl_platforms; do
1519         case "$plat" in
1520         fbdev|null)
1521                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1522                 ;;
1523
1524         wayland)
1525                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1526                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1527
1528                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1529                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1530                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1531                 ;;
1532
1533         x11)
1534                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1535
1536                 if test "x$enable_glx" = xyes; then
1537                         HAVE_EGL_DRIVER_GLX=1
1538                 fi
1539                 ;;
1540
1541         drm)
1542                 test "x$enable_gbm" = "xno" &&
1543                         AC_MSG_ERROR([EGL platform drm needs gbm])
1544                 ;;
1545
1546         android|gdi)
1547                 ;;
1548
1549         *)
1550                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1551                 ;;
1552         esac
1553
1554         case "$plat$have_libudev" in
1555                 waylandno|drmno)
1556                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1557         esac
1558 done
1559
1560 # libEGL wants to default to the first platform specified in
1561 # ./configure.  parse that here.
1562 if test "x$egl_platforms" != "x"; then
1563     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1564     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1565 else
1566     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1567 fi
1568
1569 EGL_PLATFORMS="$egl_platforms"
1570
1571 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1572 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1573 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1574 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1575 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1576
1577 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1578 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1579
1580 AC_SUBST([EGL_NATIVE_PLATFORM])
1581 AC_SUBST([EGL_PLATFORMS])
1582 AC_SUBST([EGL_CFLAGS])
1583
1584 AC_ARG_WITH([egl-driver-dir],
1585     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1586                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1587     [EGL_DRIVER_INSTALL_DIR="$withval"],
1588     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1589 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1590
1591 AC_ARG_WITH([xorg-driver-dir],
1592     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1593                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1594     [XORG_DRIVER_INSTALL_DIR="$withval"],
1595     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1596 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1597
1598 AC_ARG_WITH([max-width],
1599     [AS_HELP_STRING([--with-max-width=N],
1600                     [Maximum framebuffer width (4096)])],
1601     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1602      AS_IF([test "${withval}" -gt "4096"],
1603            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1604 )
1605 AC_ARG_WITH([max-height],
1606     [AS_HELP_STRING([--with-max-height=N],
1607                     [Maximum framebuffer height (4096)])],
1608     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1609      AS_IF([test "${withval}" -gt "4096"],
1610            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1611 )
1612
1613 dnl
1614 dnl Gallium LLVM
1615 dnl
1616 AC_ARG_ENABLE([gallium-llvm],
1617     [AS_HELP_STRING([--enable-gallium-llvm],
1618         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1619     [enable_gallium_llvm="$enableval"],
1620     [enable_gallium_llvm=auto])
1621
1622 AC_ARG_WITH([llvm-shared-libs],
1623     [AS_HELP_STRING([--with-llvm-shared-libs],
1624         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1625     [],
1626     [with_llvm_shared_libs=no])
1627 AS_IF([test x$enable_opencl = xyes],
1628     [
1629         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1630         with_llvm_shared_libs=yes
1631     ])
1632
1633 AC_ARG_WITH([llvm-prefix],
1634     [AS_HELP_STRING([--with-llvm-prefix],
1635         [Prefix for LLVM installations in non-standard locations])],
1636     [llvm_prefix="$withval"],
1637     [llvm_prefix=""])
1638
1639
1640 # Call this inside ` ` to get the return value.
1641 # $1 is the llvm-config command with arguments.
1642 strip_unwanted_llvm_flags() {
1643     # Use \> (marks the end of the word)
1644     echo `$1` | sed \
1645         -e 's/-DNDEBUG\>//g' \
1646         -e 's/-pedantic\>//g' \
1647         -e 's/-Wcovered-switch-default\>//g' \
1648         -e 's/-O.\>//g' \
1649         -e 's/-g\>//g' \
1650         -e 's/-Wall\>//g' \
1651         -e 's/-fomit-frame-pointer\>//g'
1652 }
1653
1654
1655 if test "x$with_gallium_drivers" = x; then
1656     enable_gallium_llvm=no
1657 fi
1658 if test "x$enable_gallium_llvm" = xauto; then
1659     case "$host_cpu" in
1660     i*86|x86_64) enable_gallium_llvm=yes;;
1661     esac
1662 fi
1663 if test "x$enable_gallium_llvm" = xyes; then
1664     if test "x$llvm_prefix" != x; then
1665         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1666     else
1667         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1668     fi
1669
1670     if test "x$LLVM_CONFIG" != xno; then
1671         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1672         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1673         LLVM_COMPONENTS="engine bitwriter"
1674         if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1675             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1676         fi
1677         if $LLVM_CONFIG --components | grep -q '\<oprofilejit\>'; then
1678             LLVM_COMPONENTS="${LLVM_COMPONENTS} oprofilejit"
1679         fi
1680
1681         if test "x$enable_opencl" = xyes; then
1682             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1683         fi
1684         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1685         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1686         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1687         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1688         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1689         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1690         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1691         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1692         MESA_LLVM=1
1693
1694         dnl Check for Clang interanl headers
1695         if test "x$enable_opencl" = xyes; then
1696             if test "x$CLANG_LIBDIR" = x; then
1697                 CLANG_LIBDIR=${LLVM_LIBDIR}
1698             fi
1699             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1700             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1701                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1702         fi
1703     else
1704         MESA_LLVM=0
1705         LLVM_VERSION_INT=0
1706     fi
1707 else
1708     MESA_LLVM=0
1709     LLVM_VERSION_INT=0
1710 fi
1711
1712 dnl Directory for XVMC libs
1713 AC_ARG_WITH([xvmc-libdir],
1714     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1715         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1716     [XVMC_LIB_INSTALL_DIR="$withval"],
1717     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1718 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1719
1720 dnl
1721 dnl Gallium Tests
1722 dnl
1723 if test "x$enable_gallium_tests" = xyes; then
1724     SRC_DIRS="$SRC_DIRS gallium/tests/trivial gallium/tests/unit"
1725     enable_gallium_loader=yes
1726 fi
1727
1728 dnl Directory for VDPAU libs
1729 AC_ARG_WITH([vdpau-libdir],
1730     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1731         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1732     [VDPAU_LIB_INSTALL_DIR="$withval"],
1733     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1734 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1735
1736 dnl Directory for OpenCL libs
1737 AC_ARG_WITH([opencl-libdir],
1738     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1739         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1740     [OPENCL_LIB_INSTALL_DIR="$withval"],
1741     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1742 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1743
1744 dnl
1745 dnl Gallium helper functions
1746 dnl
1747 gallium_check_st() {
1748     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1749          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1750          test "x$HAVE_ST_VDPAU" = xyes; then
1751          if test "x$have_libdrm" != xyes; then
1752             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1753          fi
1754          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1755     fi
1756     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1757          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1758     fi
1759     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1760          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1761     fi
1762     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1763          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1764     fi
1765     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1766          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1767     fi
1768     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1769          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1770     fi
1771 }
1772
1773 gallium_require_llvm() {
1774     if test "x$MESA_LLVM" = x0; then
1775         case "$host_cpu" in
1776         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1777         esac
1778     fi
1779 }
1780
1781 gallium_require_drm_loader() {
1782     if test "x$enable_gallium_loader" = xyes; then
1783         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1784                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1785         if test "x$have_libdrm" != xyes; then
1786             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1787         fi
1788         enable_gallium_drm_loader=yes
1789     fi
1790 }
1791
1792 radeon_llvm_check() {
1793     LLVM_REQUIRED_VERSION_MAJOR="3"
1794     LLVM_REQUIRED_VERSION_MINOR="2"
1795     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1796         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with R600 target enabled is required.
1797                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1798                      git://people.freedesktop.org/~tstellar/llvm master
1799                      and build with --enable-experimental-targets=R600])
1800     fi
1801     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1802         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1803                       sources with the --enable-experimental-targets=R600
1804                       configure flag])
1805     fi
1806     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1807     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600"
1808 }
1809
1810 dnl Gallium drivers
1811 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1812 if test "x$with_gallium_drivers" != x; then
1813     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1814     for driver in $gallium_drivers; do
1815         case "x$driver" in
1816         xsvga)
1817             HAVE_GALLIUM_SVGA=yes
1818             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1819             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1820             ;;
1821         xi915)
1822             HAVE_GALLIUM_I915=yes
1823             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1824             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1825             if test "x$MESA_LLVM" = x1; then
1826                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1827             fi
1828             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1829             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1830             ;;
1831         xr300)
1832             HAVE_GALLIUM_R300=yes
1833             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1834             gallium_require_llvm "Gallium R300"
1835             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1836             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1837             ;;
1838         xr600)
1839             HAVE_GALLIUM_R600=yes
1840             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1841             gallium_require_drm_loader
1842             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1843             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1844                 radeon_llvm_check
1845                 NEED_RADEON_GALLIUM=yes;
1846                 R600_NEED_RADEON_GALLIUM=yes;
1847                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo bitreader asmparser"
1848             fi
1849             if test "x$enable_r600_llvm" = xyes; then
1850                 USE_R600_LLVM_COMPILER=yes;
1851             fi
1852             if test "x$enable_opencl" = xyes; then
1853                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1854             fi
1855             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1856             ;;
1857         xradeonsi)
1858             HAVE_GALLIUM_RADEONSI=yes
1859             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1860             gallium_require_drm_loader
1861             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1862             radeon_llvm_check
1863             NEED_RADEON_GALLIUM=yes;
1864             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1865             ;;
1866         xnouveau)
1867             HAVE_GALLIUM_NOUVEAU=yes
1868             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1869             gallium_require_drm_loader
1870             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1871             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1872             ;;
1873         xswrast)
1874             HAVE_GALLIUM_SOFTPIPE=yes
1875             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1876             if test "x$MESA_LLVM" = x1; then
1877                 HAVE_GALLIUM_LLVMPIPE=yes
1878                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1879             fi
1880
1881             if test "x$HAVE_ST_DRI" = xyes; then
1882                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1883             fi
1884             if test "x$HAVE_ST_VDPAU" = xyes; then
1885                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1886             fi
1887             if test "x$HAVE_ST_XVMC" = xyes; then
1888                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1889             fi
1890             if test "x$HAVE_ST_VDPAU" = xyes ||
1891                test "x$HAVE_ST_XVMC" = xyes; then
1892                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1893                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1894                fi
1895             fi
1896             ;;
1897         *)
1898             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1899             ;;
1900         esac
1901     done
1902 fi
1903
1904 dnl Set LLVM_LIBS - This is done after the driver configuration so
1905 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1906 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1907 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1908 dnl this was causing the same libraries to be appear multiple times
1909 dnl in LLVM_LIBS.
1910
1911 if test "x$MESA_LLVM" != x0; then
1912
1913     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1914
1915     if test "x$with_llvm_shared_libs" = xyes; then
1916         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1917         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1918         AC_CHECK_FILE("$LLVM_LIBDIR/lib$LLVM_SO_NAME.so", llvm_have_one_so=yes,)
1919
1920         if test "x$llvm_have_one_so" = xyes; then
1921             dnl LLVM was built using auto*, so there is only one shared object.
1922             LLVM_LIBS="-l$LLVM_SO_NAME"
1923         else
1924             dnl If LLVM was built with CMake, there will be one shared object per
1925             dnl component.
1926             AC_CHECK_FILE("$LLVM_LIBDIR/libLLVMTarget.so",,
1927                     AC_MSG_ERROR([Could not find llvm shared libraries:
1928         Please make sure you have built llvm with the --enable-shared option
1929         and that your llvm libraries are installed in $LLVM_LIBDIR
1930         If you have installed your llvm libraries to a different directory you
1931         can use the --with-llvm-prefix= configure flag to specify this directory.
1932         NOTE: Mesa is attempting to use llvm shared libraries because you have
1933         passed one of the following options to configure:
1934                 --with-llvm-shared-libs
1935                 --enable-opencl
1936         If you do not want to build with llvm shared libraries and instead want to
1937         use llvm static libraries then remove these options from your configure
1938         invocation and reconfigure.]))
1939
1940            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1941            dnl install uses a shared object for each compoenent and we have
1942            dnl already added all of these objects to LLVM_LIBS.
1943         fi
1944     fi
1945 fi
1946
1947 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1948 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1949 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1950 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1951 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1952 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1953 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1954 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1955
1956 if test "x$enable_gallium_loader" = xyes; then
1957     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1958     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1959     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1960     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1961
1962     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1963         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1964         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1965     fi
1966
1967     if test "x$enable_gallium_drm_loader" = xyes; then
1968         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1969         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1970                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1971         if test "x$pipe_loader_have_xcb" = xyes; then
1972             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1973             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1974         fi
1975     fi
1976
1977     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1978     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1979 fi
1980
1981 dnl Tell Automake which drivers to build
1982 for driver in $GALLIUM_DRIVERS_DIRS; do
1983     case "x$driver" in
1984         xgalahad)
1985             HAVE_GALAHAD_GALLIUM=yes;
1986             ;;
1987         xidentity)
1988             HAVE_IDENTITY_GALLIUM=yes;
1989             ;;
1990         xnoop)
1991             HAVE_NOOP_GALLIUM=yes;
1992             ;;
1993         *)
1994             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1995             ;;
1996     esac
1997 done
1998
1999 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2000 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2001 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2002 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2003 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
2004 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2005 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2006 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2007 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2008 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2009 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
2010
2011 AC_SUBST([GALLIUM_MAKE_DIRS])
2012
2013 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
2014                                      "x$enable_xlib_glx" = xyes -o \
2015                                      "x$enable_osmesa" = xyes)
2016 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2017
2018 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2019 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2020 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2021
2022 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
2023
2024 AC_SUBST([VDPAU_MAJOR], 1)
2025 AC_SUBST([VDPAU_MINOR], 0)
2026
2027 AC_SUBST([XVMC_MAJOR], 1)
2028 AC_SUBST([XVMC_MINOR], 0)
2029
2030 AC_SUBST([XA_MAJOR], 1)
2031 AC_SUBST([XA_MINOR], 0)
2032 AC_SUBST([XA_TINY], 0)
2033 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2034
2035 dnl prepend CORE_DIRS to SRC_DIRS
2036 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2037
2038 dnl Restore LDFLAGS and CPPFLAGS
2039 LDFLAGS="$_SAVE_LDFLAGS"
2040 CPPFLAGS="$_SAVE_CPPFLAGS"
2041
2042 dnl Add user CFLAGS and CXXFLAGS
2043 CFLAGS="$CFLAGS $USER_CFLAGS"
2044 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2045
2046 dnl Substitute the config
2047 AC_CONFIG_FILES([Makefile
2048                 src/Makefile
2049                 src/egl/Makefile
2050                 src/egl/drivers/Makefile
2051                 src/egl/drivers/dri2/Makefile
2052                 src/egl/drivers/glx/Makefile
2053                 src/egl/main/Makefile
2054                 src/egl/main/egl.pc
2055                 src/egl/wayland/Makefile
2056                 src/egl/wayland/wayland-drm/Makefile
2057                 src/egl/wayland/wayland-egl/Makefile
2058                 src/egl/wayland/wayland-egl/wayland-egl.pc
2059                 src/gallium/Makefile
2060                 src/gallium/auxiliary/Makefile
2061                 src/gallium/auxiliary/pipe-loader/Makefile
2062                 src/gallium/drivers/Makefile
2063                 src/gallium/drivers/i915/Makefile
2064                 src/gallium/drivers/llvmpipe/Makefile
2065                 src/gallium/drivers/nouveau/Makefile
2066                 src/gallium/drivers/nv30/Makefile
2067                 src/gallium/drivers/nv50/Makefile
2068                 src/gallium/drivers/nvc0/Makefile
2069                 src/gallium/drivers/r300/Makefile
2070                 src/gallium/drivers/r600/Makefile
2071                 src/gallium/drivers/radeon/Makefile
2072                 src/gallium/drivers/radeonsi/Makefile
2073                 src/gallium/drivers/rbug/Makefile
2074                 src/gallium/drivers/softpipe/Makefile
2075                 src/gallium/drivers/svga/Makefile
2076                 src/gallium/drivers/trace/Makefile
2077                 src/gallium/state_trackers/Makefile
2078                 src/gallium/state_trackers/clover/Makefile
2079                 src/gallium/state_trackers/dri/Makefile
2080                 src/gallium/state_trackers/dri/drm/Makefile
2081                 src/gallium/state_trackers/dri/sw/Makefile
2082                 src/gallium/state_trackers/egl/Makefile
2083                 src/gallium/state_trackers/gbm/Makefile
2084                 src/gallium/state_trackers/glx/Makefile
2085                 src/gallium/state_trackers/vdpau/Makefile
2086                 src/gallium/state_trackers/vega/Makefile
2087                 src/gallium/state_trackers/xa/Makefile
2088                 src/gallium/state_trackers/xorg/Makefile
2089                 src/gallium/state_trackers/xvmc/Makefile
2090                 src/gallium/targets/Makefile
2091                 src/gallium/targets/dri-i915/Makefile
2092                 src/gallium/targets/dri-nouveau/Makefile
2093                 src/gallium/targets/dri-r300/Makefile
2094                 src/gallium/targets/dri-r600/Makefile
2095                 src/gallium/targets/dri-radeonsi/Makefile
2096                 src/gallium/targets/dri-swrast/Makefile
2097                 src/gallium/targets/dri-vmwgfx/Makefile
2098                 src/gallium/targets/egl-static/Makefile
2099                 src/gallium/targets/gbm/Makefile
2100                 src/gallium/targets/opencl/Makefile
2101                 src/gallium/targets/pipe-loader/Makefile
2102                 src/gallium/targets/libgl-xlib/Makefile
2103                 src/gallium/targets/vdpau-nouveau/Makefile
2104                 src/gallium/targets/vdpau-r300/Makefile
2105                 src/gallium/targets/vdpau-r600/Makefile
2106                 src/gallium/targets/vdpau-radeonsi/Makefile
2107                 src/gallium/targets/vdpau-softpipe/Makefile
2108                 src/gallium/targets/xa-vmwgfx/Makefile
2109                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2110                 src/gallium/targets/xorg-i915/Makefile
2111                 src/gallium/targets/xorg-nouveau/Makefile
2112                 src/gallium/targets/xorg-r600/Makefile
2113                 src/gallium/targets/xorg-radeonsi/Makefile
2114                 src/gallium/targets/xvmc-nouveau/Makefile
2115                 src/gallium/targets/xvmc-r300/Makefile
2116                 src/gallium/targets/xvmc-r600/Makefile
2117                 src/gallium/targets/xvmc-softpipe/Makefile
2118                 src/gallium/tests/trivial/Makefile
2119                 src/gallium/tests/unit/Makefile
2120                 src/gallium/winsys/Makefile
2121                 src/gallium/winsys/i915/drm/Makefile
2122                 src/gallium/winsys/i915/sw/Makefile
2123                 src/gallium/winsys/nouveau/drm/Makefile
2124                 src/gallium/winsys/radeon/drm/Makefile
2125                 src/gallium/winsys/svga/drm/Makefile
2126                 src/gallium/winsys/sw/Makefile
2127                 src/gallium/winsys/sw/dri/Makefile
2128                 src/gallium/winsys/sw/fbdev/Makefile
2129                 src/gallium/winsys/sw/null/Makefile
2130                 src/gallium/winsys/sw/wayland/Makefile
2131                 src/gallium/winsys/sw/wrapper/Makefile
2132                 src/gallium/winsys/sw/xlib/Makefile
2133                 src/gbm/Makefile
2134                 src/gbm/main/gbm.pc
2135                 src/glsl/Makefile
2136                 src/glsl/builtin_compiler/Makefile
2137                 src/glx/Makefile
2138                 src/glx/tests/Makefile
2139                 src/gtest/Makefile
2140                 src/mapi/es1api/Makefile
2141                 src/mapi/es1api/glesv1_cm.pc
2142                 src/mapi/es2api/Makefile
2143                 src/mapi/es2api/glesv2.pc
2144                 src/mapi/glapi/Makefile
2145                 src/mapi/glapi/gen/Makefile
2146                 src/mapi/glapi/tests/Makefile
2147                 src/mapi/shared-glapi/Makefile
2148                 src/mapi/shared-glapi/tests/Makefile
2149                 src/mapi/vgapi/Makefile
2150                 src/mapi/vgapi/vg.pc
2151                 src/mesa/Makefile
2152                 src/mesa/gl.pc
2153                 src/mesa/drivers/Makefile
2154                 src/mesa/drivers/dri/dri.pc
2155                 src/mesa/drivers/dri/common/Makefile
2156                 src/mesa/drivers/dri/common/xmlpool/Makefile
2157                 src/mesa/drivers/dri/i915/Makefile
2158                 src/mesa/drivers/dri/i965/Makefile
2159                 src/mesa/drivers/dri/Makefile
2160                 src/mesa/drivers/dri/nouveau/Makefile
2161                 src/mesa/drivers/dri/r200/Makefile
2162                 src/mesa/drivers/dri/radeon/Makefile
2163                 src/mesa/drivers/dri/swrast/Makefile
2164                 src/mesa/drivers/osmesa/Makefile
2165                 src/mesa/drivers/osmesa/osmesa.pc
2166                 src/mesa/drivers/x11/Makefile
2167                 src/mesa/libdricore/Makefile
2168                 src/mesa/main/tests/Makefile
2169                 src/mesa/main/tests/hash_table/Makefile
2170                 src/mesa/program/Makefile
2171                 src/mesa/x86-64/Makefile
2172                 src/mesa/x86/Makefile])
2173
2174 dnl Sort the dirs alphabetically
2175 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2176 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2177 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2178 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2179 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2180
2181 AC_OUTPUT
2182
2183 dnl
2184 dnl Output some configuration info for the user
2185 dnl
2186 echo ""
2187 echo "        prefix:          $prefix"
2188 echo "        exec_prefix:     $exec_prefix"
2189 echo "        libdir:          $libdir"
2190 echo "        includedir:      $includedir"
2191
2192 dnl API info
2193 echo ""
2194 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2195 echo "        OpenVG:          $enable_openvg"
2196
2197 dnl Driver info
2198 echo ""
2199 if test "x$enable_osmesa" != xno; then
2200         echo "        OSMesa:          lib$OSMESA_LIB"
2201 else
2202         echo "        OSMesa:          no"
2203 fi
2204
2205 if test "x$enable_dri" != xno; then
2206         # cleanup the drivers var
2207         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2208         if test "x$DRI_DIRS" = x; then
2209             echo "        DRI drivers:     no"
2210         else
2211             echo "        DRI drivers:     $dri_dirs"
2212         fi
2213         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2214 fi
2215
2216 case "x$enable_glx$enable_xlib_glx" in
2217 xyesyes)
2218     echo "        GLX:             Xlib-based"
2219     ;;
2220 xyesno)
2221     echo "        GLX:             DRI-based"
2222     ;;
2223 *)
2224     echo "        GLX:             $enable_glx"
2225     ;;
2226 esac
2227
2228 dnl EGL
2229 echo ""
2230 echo "        EGL:             $enable_egl"
2231 if test "$enable_egl" = yes; then
2232     echo "        EGL platforms:   $EGL_PLATFORMS"
2233
2234     egl_drivers=""
2235     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2236         egl_drivers="$egl_drivers builtin:egl_glx"
2237     fi
2238     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2239         egl_drivers="$egl_drivers builtin:egl_dri2"
2240     fi
2241
2242     if test "x$HAVE_ST_EGL" = xyes; then
2243         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2244         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2245     else
2246         echo "        EGL drivers:    $egl_drivers"
2247     fi
2248 fi
2249
2250 echo ""
2251 if test "x$MESA_LLVM" = x1; then
2252     echo "        llvm:            yes"
2253     echo "        llvm-config:     $LLVM_CONFIG"
2254     echo "        llvm-version:    $LLVM_VERSION"
2255 else
2256     echo "        llvm:            no"
2257 fi
2258
2259 echo ""
2260 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2261     echo "        Gallium:         yes"
2262     echo "        Gallium dirs:    $GALLIUM_DIRS"
2263     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2264     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2265     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2266     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2267 else
2268     echo "        Gallium:         no"
2269 fi
2270
2271
2272 dnl Libraries
2273 echo ""
2274 echo "        Shared libs:     $enable_shared"
2275 echo "        Static libs:     $enable_static"
2276 echo "        Shared-glapi:    $enable_shared_glapi"
2277
2278 dnl Compiler options
2279 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2280 cflags=`echo $CFLAGS | \
2281     $SED 's/^ *//;s/  */ /;s/ *$//'`
2282 cxxflags=`echo $CXXFLAGS | \
2283     $SED 's/^ *//;s/  */ /;s/ *$//'`
2284 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2285 echo ""
2286 echo "        CFLAGS:          $cflags"
2287 echo "        CXXFLAGS:        $cxxflags"
2288 echo "        Macros:          $defines"
2289 echo ""
2290 if test "x$MESA_LLVM" = x1; then
2291     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2292     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2293     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2294     echo ""
2295 fi
2296 echo "        PYTHON2:         $PYTHON2"
2297
2298 echo ""
2299 echo "        Run '${MAKE-make}' to build Mesa"
2300 echo ""