configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.3
  22 DRI2PROTO_REQUIRED=1.99.3
  23
  24 dnl Check for progs
  25 AC_PROG_CPP
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_CHECK_PROGS([MAKE], [gmake make])
  29 AC_PATH_PROG([MKDEP], [makedepend])
  30 AC_PATH_PROG([SED], [sed])
  31
  32 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  33 dnl configuration in that case.
  34 AC_PROG_INSTALL
  35 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  36
  37 dnl We need a POSIX shell for parts of the build. Assume we have one
  38 dnl in most cases.
  39 case "$host_os" in
  40 solaris*)
  41     # Solaris /bin/sh is too old/non-POSIX compliant
  42     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  43     SHELL="$POSIX_SHELL"
  44     ;;
  45 esac
  46
  47 MKDEP_OPTIONS=-fdepend
  48 dnl Ask gcc where it's keeping its secret headers
  49 if test "x$GCC" = xyes; then
  50     for dir in include include-fixed; do
  51         GCC_INCLUDES=`$CC -print-file-name=$dir`
  52         if test "x$GCC_INCLUDES" != x && \
  53            test "$GCC_INCLUDES" != "$dir" && \
  54            test -d "$GCC_INCLUDES"; then
  55             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  56         fi
  57     done
  58 fi
  59 AC_SUBST([MKDEP_OPTIONS])
  60
  61 dnl Make sure the pkg-config macros are defined
  62 m4_ifndef([PKG_PROG_PKG_CONFIG],
  63     [m4_fatal([Could not locate the pkg-config autoconf macros.
  64   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  65   are in a different location, try setting the environment variable
  66   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  67 PKG_PROG_PKG_CONFIG()
  68
  69 dnl LIB_DIR - library basename
  70 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  71 AC_SUBST([LIB_DIR])
  72
  73 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  74 _SAVE_LDFLAGS="$LDFLAGS"
  75 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  76 AC_SUBST([EXTRA_LIB_PATH])
  77
  78 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  79 _SAVE_CPPFLAGS="$CPPFLAGS"
  80 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  81 AC_SUBST([X11_INCLUDES])
  82
  83 dnl Compiler macros
  84 DEFINES=""
  85 AC_SUBST([DEFINES])
  86 case "$host_os" in
  87 linux*|*-gnu*|gnu*)
  88     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  89     ;;
  90 solaris*)
  91     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  92     ;;
  93 esac
  94
  95 dnl Add flags for gcc and g++
  96 if test "x$GCC" = xyes; then
  97     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
  98
  99     # Work around aliasing bugs - developers should comment this out
 100     CFLAGS="$CFLAGS -fno-strict-aliasing"
 101 fi
 102 if test "x$GXX" = xyes; then
 103     CXXFLAGS="$CXXFLAGS -Wall"
 104
 105     # Work around aliasing bugs - developers should comment this out
 106     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 107 fi
 108
 109 dnl These should be unnecessary, but let the user set them if they want
 110 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 111     Default is to use CFLAGS.])
 112 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 113     compiler. Default is to use CFLAGS.])
 114 AC_SUBST([OPT_FLAGS])
 115 AC_SUBST([ARCH_FLAGS])
 116
 117 dnl
 118 dnl Hacks to enable 32 or 64 bit build
 119 dnl
 120 AC_ARG_ENABLE([32-bit],
 121     [AS_HELP_STRING([--enable-32-bit],
 122         [build 32-bit libraries @<:@default=auto@:>@])],
 123     [enable_32bit="$enableval"],
 124     [enable_32bit=auto]
 125 )
 126 if test "x$enable_32bit" = xyes; then
 127     if test "x$GCC" = xyes; then
 128         CFLAGS="$CFLAGS -m32"
 129     fi
 130     if test "x$GXX" = xyes; then
 131         CXXFLAGS="$CXXFLAGS -m32"
 132     fi
 133 fi
 134 AC_ARG_ENABLE([64-bit],
 135     [AS_HELP_STRING([--enable-64-bit],
 136         [build 64-bit libraries @<:@default=auto@:>@])],
 137     [enable_64bit="$enableval"],
 138     [enable_64bit=auto]
 139 )
 140 if test "x$enable_64bit" = xyes; then
 141     if test "x$GCC" = xyes; then
 142         CFLAGS="$CFLAGS -m64"
 143     fi
 144     if test "x$GXX" = xyes; then
 145         CXXFLAGS="$CXXFLAGS -m64"
 146     fi
 147 fi
 148
 149 dnl
 150 dnl shared/static libraries, mimic libtool options
 151 dnl
 152 AC_ARG_ENABLE([static],
 153     [AS_HELP_STRING([--enable-static],
 154         [build static libraries @<:@default=disabled@:>@])],
 155     [enable_static="$enableval"],
 156     [enable_static=no]
 157 )
 158 case "x$enable_static" in
 159 xyes|xno ) ;;
 160 x ) enable_static=no ;;
 161 * )
 162     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 163     ;;
 164 esac
 165 AC_ARG_ENABLE([shared],
 166     [AS_HELP_STRING([--disable-shared],
 167         [build shared libraries @<:@default=enabled@:>@])],
 168     [enable_shared="$enableval"],
 169     [enable_shared=yes]
 170 )
 171 case "x$enable_shared" in
 172 xyes|xno ) ;;
 173 x ) enable_shared=yes ;;
 174 * )
 175     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 176     ;;
 177 esac
 178
 179 dnl Can't have static and shared libraries, default to static if user
 180 dnl explicitly requested. If both disabled, set to static since shared
 181 dnl was explicitly requirested.
 182 case "x$enable_static$enable_shared" in
 183 xyesyes )
 184     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 185     enable_shared=no
 186     ;;
 187 xnono )
 188     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 189     enable_static=yes
 190     ;;
 191 esac
 192
 193 dnl
 194 dnl mklib options
 195 dnl
 196 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 197 if test "$enable_static" = yes; then
 198     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 199 fi
 200 AC_SUBST([MKLIB_OPTIONS])
 201
 202 dnl
 203 dnl other compiler options
 204 dnl
 205 AC_ARG_ENABLE([debug],
 206     [AS_HELP_STRING([--enable-debug],
 207         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 208     [enable_debug="$enableval"],
 209     [enable_debug=no]
 210 )
 211 if test "x$enable_debug" = xyes; then
 212     DEFINES="$DEFINES -DDEBUG"
 213     if test "x$GCC" = xyes; then
 214         CFLAGS="$CFLAGS -g"
 215     fi
 216     if test "x$GXX" = xyes; then
 217         CXXFLAGS="$CXXFLAGS -g"
 218     fi
 219 fi
 220
 221 dnl
 222 dnl library names
 223 dnl
 224 if test "$enable_static" = yes; then
 225     LIB_EXTENSION='a'
 226 else
 227     case "$host_os" in
 228     darwin* )
 229         LIB_EXTENSION='dylib' ;;
 230     * )
 231         LIB_EXTENSION='so' ;;
 232     esac
 233 fi
 234
 235 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 236 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 237 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 238 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 239 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 240
 241 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 242 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 243 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 244 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 245 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 246
 247 AC_SUBST([GL_LIB_NAME])
 248 AC_SUBST([GLU_LIB_NAME])
 249 AC_SUBST([GLUT_LIB_NAME])
 250 AC_SUBST([GLW_LIB_NAME])
 251 AC_SUBST([OSMESA_LIB_NAME])
 252
 253 AC_SUBST([GL_LIB_GLOB])
 254 AC_SUBST([GLU_LIB_GLOB])
 255 AC_SUBST([GLUT_LIB_GLOB])
 256 AC_SUBST([GLW_LIB_GLOB])
 257 AC_SUBST([OSMESA_LIB_GLOB])
 258
 259 dnl
 260 dnl Arch/platform-specific settings
 261 dnl
 262 AC_ARG_ENABLE([asm],
 263     [AS_HELP_STRING([--disable-asm],
 264         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 265     [enable_asm="$enableval"],
 266     [enable_asm=yes]
 267 )
 268 asm_arch=""
 269 ASM_FLAGS=""
 270 MESA_ASM_SOURCES=""
 271 GLAPI_ASM_SOURCES=""
 272 AC_MSG_CHECKING([whether to enable assembly])
 273 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 274 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 275 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 276     case "$host_cpu" in
 277     i?86 | x86_64)
 278         enable_asm=no
 279         AC_MSG_RESULT([no, cross compiling])
 280         ;;
 281     esac
 282 fi
 283 # check for supported arches
 284 if test "x$enable_asm" = xyes; then
 285     case "$host_cpu" in
 286     i?86)
 287         case "$host_os" in
 288         linux* | *freebsd* | dragonfly*)
 289             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 290             ;;
 291         esac
 292         ;;
 293     x86_64)
 294         case "$host_os" in
 295         linux* | *freebsd* | dragonfly*)
 296             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 297             ;;
 298         esac
 299         ;;
 300     powerpc)
 301         case "$host_os" in
 302         linux*)
 303             asm_arch=ppc
 304             ;;
 305         esac
 306         ;;
 307     sparc*)
 308         case "$host_os" in
 309         linux*)
 310             asm_arch=sparc
 311             ;;
 312         esac
 313         ;;
 314     esac
 315
 316     case "$asm_arch" in
 317     x86)
 318         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 319         MESA_ASM_SOURCES='$(X86_SOURCES)'
 320         GLAPI_ASM_SOURCES='$(X86_API)'
 321         AC_MSG_RESULT([yes, x86])
 322         ;;
 323     x86_64)
 324         ASM_FLAGS="-DUSE_X86_64_ASM"
 325         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 326         GLAPI_ASM_SOURCES='$(X86-64_API)'
 327         AC_MSG_RESULT([yes, x86_64])
 328         ;;
 329     ppc)
 330         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 331         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 332         AC_MSG_RESULT([yes, ppc])
 333         ;;
 334     sparc)
 335         ASM_FLAGS="-DUSE_SPARC_ASM"
 336         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 337         GLAPI_ASM_SOURCES='$(SPARC_API)'
 338         AC_MSG_RESULT([yes, sparc])
 339         ;;
 340     *)
 341         AC_MSG_RESULT([no, platform not supported])
 342         ;;
 343     esac
 344 fi
 345 AC_SUBST([ASM_FLAGS])
 346 AC_SUBST([MESA_ASM_SOURCES])
 347 AC_SUBST([GLAPI_ASM_SOURCES])
 348
 349 dnl PIC code macro
 350 MESA_PIC_FLAGS
 351
 352 dnl Check to see if dlopen is in default libraries (like Solaris, which
 353 dnl has it in libc), or if libdl is needed to get it.
 354 AC_CHECK_FUNC([dlopen], [],
 355     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 356
 357 dnl See if posix_memalign is available
 358 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 359
 360 dnl SELinux awareness.
 361 AC_ARG_ENABLE([selinux],
 362     [AS_HELP_STRING([--enable-selinux],
 363         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 364     [MESA_SELINUX="$enableval"],
 365     [MESA_SELINUX=no])
 366 if test "x$enable_selinux" = "xyes"; then
 367     AC_CHECK_HEADER([selinux/selinux.h],[],
 368                     [AC_MSG_ERROR([SELinux headers not found])])
 369     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 370                  [AC_MSG_ERROR([SELinux library not found])])
 371     SELINUX_LIBS="-lselinux"
 372     DEFINES="$DEFINES -DMESA_SELINUX"
 373 fi
 374
 375 dnl
 376 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 377 dnl More later: directfb, fbdev, ...
 378 dnl
 379 default_driver="xlib"
 380
 381 case "$host_os" in
 382 linux*)
 383     case "$host_cpu" in
 384     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 385     esac
 386     ;;
 387 *freebsd* | dragonfly*)
 388     case "$host_cpu" in
 389     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 390     esac
 391     ;;
 392 esac
 393
 394 AC_ARG_WITH([driver],
 395     [AS_HELP_STRING([--with-driver=DRIVER],
 396         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 397     [mesa_driver="$withval"],
 398     [mesa_driver="$default_driver"])
 399 dnl Check for valid option
 400 case "x$mesa_driver" in
 401 xxlib|xdri|xosmesa)
 402     ;;
 403 *)
 404     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 405     ;;
 406 esac
 407
 408 dnl
 409 dnl Driver specific build directories
 410 dnl
 411 SRC_DIRS="mesa glew"
 412 GLU_DIRS="sgi"
 413 WINDOW_SYSTEM=""
 414 GALLIUM_DIRS="auxiliary drivers state_trackers"
 415 GALLIUM_WINSYS_DIRS=""
 416 GALLIUM_WINSYS_DRM_DIRS=""
 417 GALLIUM_AUXILIARY_DIRS="rbug draw translate cso_cache pipebuffer tgsi sct rtasm util indices"
 418 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 419 GALLIUM_STATE_TRACKERS_DIRS=""
 420
 421 case "$mesa_driver" in
 422 xlib)
 423     DRIVER_DIRS="x11"
 424     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 425     ;;
 426 dri)
 427     SRC_DIRS="glx/x11 $SRC_DIRS"
 428     DRIVER_DIRS="dri"
 429     WINDOW_SYSTEM="dri"
 430     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 431     ;;
 432 osmesa)
 433     DRIVER_DIRS="osmesa"
 434     ;;
 435 esac
 436 AC_SUBST([SRC_DIRS])
 437 AC_SUBST([GLU_DIRS])
 438 AC_SUBST([DRIVER_DIRS])
 439 AC_SUBST([WINDOW_SYSTEM])
 440 AC_SUBST([GALLIUM_DIRS])
 441 AC_SUBST([GALLIUM_WINSYS_DIRS])
 442 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 443 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 444 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 445 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 446
 447 dnl
 448 dnl User supplied program configuration
 449 dnl
 450 if test -d "$srcdir/progs/demos"; then
 451     default_demos=yes
 452 else
 453     default_demos=no
 454 fi
 455 AC_ARG_WITH([demos],
 456     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 457         [optional comma delimited demo directories to build
 458         @<:@default=auto if source available@:>@])],
 459     [with_demos="$withval"],
 460     [with_demos="$default_demos"])
 461 if test "x$with_demos" = x; then
 462     with_demos=no
 463 fi
 464
 465 dnl If $with_demos is yes, directories will be added as libs available
 466 PROGRAM_DIRS=""
 467 case "$with_demos" in
 468 no) ;;
 469 yes)
 470     # If the driver isn't osmesa, we have libGL and can build xdemos
 471     if test "$mesa_driver" != osmesa; then
 472         PROGRAM_DIRS="xdemos"
 473     fi
 474     ;;
 475 *)
 476     # verify the requested demos directories exist
 477     demos=`IFS=,; echo $with_demos`
 478     for demo in $demos; do
 479         test -d "$srcdir/progs/$demo" || \
 480             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 481     done
 482     PROGRAM_DIRS="$demos"
 483     ;;
 484 esac
 485
 486 dnl
 487 dnl Find out if X is available. The variable have_x is set if libX11 is
 488 dnl found to mimic AC_PATH_XTRA.
 489 dnl
 490 if test -n "$PKG_CONFIG"; then
 491     AC_MSG_CHECKING([pkg-config files for X11 are available])
 492     PKG_CHECK_EXISTS([x11],[
 493         x11_pkgconfig=yes
 494         have_x=yes
 495         ],[
 496         x11_pkgconfig=no
 497     ])
 498     AC_MSG_RESULT([$x11_pkgconfig])
 499 else
 500     x11_pkgconfig=no
 501 fi
 502 dnl Use the autoconf macro if no pkg-config files
 503 if test "$x11_pkgconfig" = no; then
 504     AC_PATH_XTRA
 505 fi
 506
 507 dnl Try to tell the user that the --x-* options are only used when
 508 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 509 m4_divert_once([HELP_BEGIN],
 510 [These options are only used when the X libraries cannot be found by the
 511 pkg-config utility.])
 512
 513 dnl We need X for xlib and dri, so bomb now if it's not found
 514 case "$mesa_driver" in
 515 xlib|dri)
 516     if test "$no_x" = yes; then
 517         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 518     fi
 519     ;;
 520 esac
 521
 522 dnl XCB - this is only used for GLX right now
 523 AC_ARG_ENABLE([xcb],
 524     [AS_HELP_STRING([--enable-xcb],
 525         [use XCB for GLX @<:@default=disabled@:>@])],
 526     [enable_xcb="$enableval"],
 527     [enable_xcb=no])
 528 if test "x$enable_xcb" = xyes; then
 529     DEFINES="$DEFINES -DUSE_XCB"
 530 else
 531     enable_xcb=no
 532 fi
 533
 534 dnl
 535 dnl libGL configuration per driver
 536 dnl
 537 case "$mesa_driver" in
 538 xlib)
 539     if test "$x11_pkgconfig" = yes; then
 540         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 541         GL_PC_REQ_PRIV="x11 xext"
 542         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 543         GL_LIB_DEPS="$XLIBGL_LIBS"
 544     else
 545         # should check these...
 546         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 547         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 548         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 549         GL_PC_CFLAGS="$X11_INCLUDES"
 550     fi
 551     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 552     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 553
 554     # if static, move the external libraries to the programs
 555     # and empty the libraries for libGL
 556     if test "$enable_static" = yes; then
 557         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 558         GL_LIB_DEPS=""
 559     fi
 560     ;;
 561 dri)
 562     # DRI must be shared, I think
 563     if test "$enable_static" = yes; then
 564         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 565     fi
 566
 567     # Check for libdrm
 568     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 569     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 570     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 571     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 572
 573     # find the DRI deps for libGL
 574     if test "$x11_pkgconfig" = yes; then
 575         # add xcb modules if necessary
 576         dri_modules="x11 xext xxf86vm xdamage xfixes"
 577         if test "$enable_xcb" = yes; then
 578             dri_modules="$dri_modules x11-xcb xcb-glx"
 579         fi
 580
 581         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 582         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 583         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 584         GL_LIB_DEPS="$DRIGL_LIBS"
 585     else
 586         # should check these...
 587         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 588         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 589         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 590         GL_PC_CFLAGS="$X11_INCLUDES"
 591
 592         # XCB can only be used from pkg-config
 593         if test "$enable_xcb" = yes; then
 594             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 595             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 596             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 597             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 598         fi
 599     fi
 600
 601     # need DRM libs, -lpthread, etc.
 602     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 603     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 604     ;;
 605 osmesa)
 606     # No libGL for osmesa
 607     GL_LIB_DEPS=""
 608     ;;
 609 esac
 610 AC_SUBST([GL_LIB_DEPS])
 611 AC_SUBST([GL_PC_REQ_PRIV])
 612 AC_SUBST([GL_PC_LIB_PRIV])
 613 AC_SUBST([GL_PC_CFLAGS])
 614 AC_SUBST([DRI_PC_REQ_PRIV])
 615
 616 dnl
 617 dnl More X11 setup
 618 dnl
 619 if test "$mesa_driver" = xlib; then
 620     DEFINES="$DEFINES -DUSE_XSHM"
 621 fi
 622
 623 dnl
 624 dnl More DRI setup
 625 dnl
 626 AC_ARG_ENABLE([glx-tls],
 627     [AS_HELP_STRING([--enable-glx-tls],
 628         [enable TLS support in GLX @<:@default=disabled@:>@])],
 629     [GLX_USE_TLS="$enableval"],
 630     [GLX_USE_TLS=no])
 631 dnl Directory for DRI drivers
 632 AC_ARG_WITH([dri-driverdir],
 633     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 634         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 635     [DRI_DRIVER_INSTALL_DIR="$withval"],
 636     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 637 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 638 dnl Direct rendering or just indirect rendering
 639 AC_ARG_ENABLE([driglx-direct],
 640     [AS_HELP_STRING([--disable-driglx-direct],
 641         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 642     [driglx_direct="$enableval"],
 643     [driglx_direct="yes"])
 644 dnl Which drivers to build - default is chosen by platform
 645 AC_ARG_WITH([dri-drivers],
 646     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 647         [comma delimited DRI drivers list, e.g.
 648         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 649     [with_dri_drivers="$withval"],
 650     [with_dri_drivers=yes])
 651 if test "x$with_dri_drivers" = x; then
 652     with_dri_drivers=no
 653 fi
 654
 655 dnl If $with_dri_drivers is yes, directories will be added through
 656 dnl platform checks
 657 DRI_DIRS=""
 658 case "$with_dri_drivers" in
 659 no) ;;
 660 yes)
 661     DRI_DIRS="yes"
 662     ;;
 663 *)
 664     # verify the requested driver directories exist
 665     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 666     for driver in $dri_drivers; do
 667         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 668             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 669     done
 670     DRI_DIRS="$dri_drivers"
 671     ;;
 672 esac
 673
 674 dnl Just default to no EGL for now
 675 USING_EGL=0
 676 AC_SUBST([USING_EGL])
 677
 678 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 679 if test "$mesa_driver" = dri; then
 680     # Use TLS in GLX?
 681     if test "x$GLX_USE_TLS" = xyes; then
 682         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 683     fi
 684
 685     if test "x$USING_EGL" = x1; then
 686         PROGRAM_DIRS="egl"
 687     fi
 688
 689     # Platform specific settings and drivers to build
 690     case "$host_os" in
 691     linux*)
 692         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 693         if test "x$driglx_direct" = xyes; then
 694             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 695         fi
 696         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 697
 698         case "$host_cpu" in
 699         x86_64)
 700             # ffb, gamma, and sis are missing because they have not be
 701             # converted to use the new interface.  i810 are missing
 702             # because there is no x86-64 system where they could *ever*
 703             # be used.
 704             if test "x$DRI_DIRS" = "xyes"; then
 705                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 706                     savage tdfx unichrome swrast"
 707             fi
 708             ;;
 709         powerpc*)
 710             # Build only the drivers for cards that exist on PowerPC.
 711             # At some point MGA will be added, but not yet.
 712             if test "x$DRI_DIRS" = "xyes"; then
 713                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 714             fi
 715             ;;
 716         sparc*)
 717             # Build only the drivers for cards that exist on sparc`
 718             if test "x$DRI_DIRS" = "xyes"; then
 719                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 720             fi
 721             ;;
 722         esac
 723         ;;
 724     freebsd* | dragonfly*)
 725         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 726         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 727         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 728         if test "x$driglx_direct" = xyes; then
 729             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 730         fi
 731         if test "x$GXX" = xyes; then
 732             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 733         fi
 734
 735         # ffb and gamma are missing because they have not been converted
 736         # to use the new interface.
 737         if test "x$DRI_DIRS" = "xyes"; then
 738             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 739                 unichrome savage sis swrast"
 740         fi
 741         ;;
 742     gnu*)
 743         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 744         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 745         ;;
 746     solaris*)
 747         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 748         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 749         if test "x$driglx_direct" = xyes; then
 750             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 751         fi
 752         ;;
 753     esac
 754
 755     # default drivers
 756     if test "x$DRI_DIRS" = "xyes"; then
 757         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 758             savage sis tdfx trident unichrome ffb swrast"
 759     fi
 760
 761     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 762
 763     # Check for expat
 764     EXPAT_INCLUDES=""
 765     EXPAT_LIB=-lexpat
 766     AC_ARG_WITH([expat],
 767         [AS_HELP_STRING([--with-expat=DIR],
 768             [expat install directory])],[
 769         EXPAT_INCLUDES="-I$withval/include"
 770         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 771         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 772         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 773         ])
 774     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 775     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 776         [AC_MSG_ERROR([Expat required for DRI.])])
 777
 778     # put all the necessary libs together
 779     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 780 fi
 781 AC_SUBST([DRI_DIRS])
 782 AC_SUBST([EXPAT_INCLUDES])
 783 AC_SUBST([DRI_LIB_DEPS])
 784
 785 dnl
 786 dnl OSMesa configuration
 787 dnl
 788 if test "$mesa_driver" = xlib; then
 789     default_gl_osmesa=yes
 790 else
 791     default_gl_osmesa=no
 792 fi
 793 AC_ARG_ENABLE([gl-osmesa],
 794     [AS_HELP_STRING([--enable-gl-osmesa],
 795         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 796     [gl_osmesa="$enableval"],
 797     [gl_osmesa="$default_gl_osmesa"])
 798 if test "x$gl_osmesa" = xyes; then
 799     if test "$mesa_driver" = osmesa; then
 800         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 801     else
 802         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 803     fi
 804 fi
 805
 806 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 807 AC_ARG_WITH([osmesa-bits],
 808     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 809         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 810     [osmesa_bits="$withval"],
 811     [osmesa_bits=8])
 812 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 813     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 814     osmesa_bits=8
 815 fi
 816 case "x$osmesa_bits" in
 817 x8)
 818     OSMESA_LIB=OSMesa
 819     ;;
 820 x16|x32)
 821     OSMESA_LIB="OSMesa$osmesa_bits"
 822     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 823     ;;
 824 *)
 825     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 826     ;;
 827 esac
 828 AC_SUBST([OSMESA_LIB])
 829
 830 case "$mesa_driver" in
 831 osmesa)
 832     # only link libraries with osmesa if shared
 833     if test "$enable_static" = no; then
 834         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 835     else
 836         OSMESA_LIB_DEPS=""
 837     fi
 838     OSMESA_MESA_DEPS=""
 839     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 840     ;;
 841 *)
 842     # Link OSMesa to libGL otherwise
 843     OSMESA_LIB_DEPS=""
 844     # only link libraries with osmesa if shared
 845     if test "$enable_static" = no; then
 846         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 847     else
 848         OSMESA_MESA_DEPS=""
 849     fi
 850     OSMESA_PC_REQ="gl"
 851     ;;
 852 esac
 853 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 854 AC_SUBST([OSMESA_LIB_DEPS])
 855 AC_SUBST([OSMESA_MESA_DEPS])
 856 AC_SUBST([OSMESA_PC_REQ])
 857 AC_SUBST([OSMESA_PC_LIB_PRIV])
 858
 859 dnl
 860 dnl EGL configuration
 861 dnl
 862 AC_ARG_ENABLE([egl],
 863     [AS_HELP_STRING([--disable-egl],
 864         [disable EGL library @<:@default=enabled@:>@])],
 865     [enable_egl="$enableval"],
 866     [enable_egl=yes])
 867 if test "x$enable_egl" = xyes; then
 868     SRC_DIRS="$SRC_DIRS egl"
 869
 870     if test "$x11_pkgconfig" = yes; then
 871         PKG_CHECK_MODULES([EGL], [x11])
 872         EGL_LIB_DEPS="$EGL_LIBS"
 873     else
 874         # should check these...
 875         EGL_LIB_DEPS="$X_LIBS -lX11"
 876     fi
 877     EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS"
 878 fi
 879 AC_SUBST([EGL_LIB_DEPS])
 880
 881 dnl
 882 dnl GLU configuration
 883 dnl
 884 AC_ARG_ENABLE([glu],
 885     [AS_HELP_STRING([--disable-glu],
 886         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 887     [enable_glu="$enableval"],
 888     [enable_glu=yes])
 889 if test "x$enable_glu" = xyes; then
 890     SRC_DIRS="$SRC_DIRS glu"
 891
 892     case "$mesa_driver" in
 893     osmesa)
 894         # If GLU is available and we have libOSMesa (not 16 or 32),
 895         # we can build the osdemos
 896         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 897             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 898         fi
 899
 900         # Link libGLU to libOSMesa instead of libGL
 901         GLU_LIB_DEPS=""
 902         GLU_PC_REQ="osmesa"
 903         if test "$enable_static" = no; then
 904             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 905         else
 906             GLU_MESA_DEPS=""
 907         fi
 908         ;;
 909     *)
 910         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 911         GLU_PC_REQ="gl"
 912         GLU_PC_LIB_PRIV="-lm"
 913         if test "$enable_static" = no; then
 914             GLU_LIB_DEPS="-lm"
 915             GLU_MESA_DEPS='-l$(GL_LIB)'
 916         else
 917             GLU_LIB_DEPS=""
 918             GLU_MESA_DEPS=""
 919             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 920         fi
 921         ;;
 922     esac
 923 fi
 924 if test "$enable_static" = no; then
 925     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 926 fi
 927 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 928 AC_SUBST([GLU_LIB_DEPS])
 929 AC_SUBST([GLU_MESA_DEPS])
 930 AC_SUBST([GLU_PC_REQ])
 931 AC_SUBST([GLU_PC_REQ_PRIV])
 932 AC_SUBST([GLU_PC_LIB_PRIV])
 933 AC_SUBST([GLU_PC_CFLAGS])
 934
 935 dnl
 936 dnl GLw configuration
 937 dnl
 938 AC_ARG_ENABLE([glw],
 939     [AS_HELP_STRING([--disable-glw],
 940         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 941     [enable_glw="$enableval"],
 942     [enable_glw=yes])
 943 dnl Don't build GLw on osmesa
 944 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 945     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 946     enable_glw=no
 947 fi
 948 AC_ARG_ENABLE([motif],
 949     [AS_HELP_STRING([--enable-motif],
 950         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 951     [enable_motif="$enableval"],
 952     [enable_motif=no])
 953
 954 if test "x$enable_glw" = xyes; then
 955     SRC_DIRS="$SRC_DIRS glw"
 956     if test "$x11_pkgconfig" = yes; then
 957         PKG_CHECK_MODULES([GLW],[x11 xt])
 958         GLW_PC_REQ_PRIV="x11 xt"
 959         GLW_LIB_DEPS="$GLW_LIBS"
 960     else
 961         # should check these...
 962         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 963         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 964         GLW_PC_CFLAGS="$X11_INCLUDES"
 965     fi
 966
 967     GLW_SOURCES="GLwDrawA.c"
 968     MOTIF_CFLAGS=
 969     if test "x$enable_motif" = xyes; then
 970         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 971         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 972         if test "x$MOTIF_CONFIG" != xno; then
 973             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 974             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 975         else
 976             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 977                 [AC_MSG_ERROR([Can't locate Motif headers])])
 978             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 979                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 980         fi
 981         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 982         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 983         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 984         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 985     fi
 986
 987     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 988     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
 989     if test "$enable_static" = no; then
 990         GLW_MESA_DEPS='-l$(GL_LIB)'
 991         GLW_LIB_DEPS="$GLW_LIB_DEPS"
 992     else
 993         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 994         GLW_LIB_DEPS=""
 995         GLW_MESA_DEPS=""
 996     fi
 997 fi
 998 AC_SUBST([GLW_LIB_DEPS])
 999 AC_SUBST([GLW_MESA_DEPS])
1000 AC_SUBST([GLW_SOURCES])
1001 AC_SUBST([MOTIF_CFLAGS])
1002 AC_SUBST([GLW_PC_REQ_PRIV])
1003 AC_SUBST([GLW_PC_LIB_PRIV])
1004 AC_SUBST([GLW_PC_CFLAGS])
1005
1006 dnl
1007 dnl GLUT configuration
1008 dnl
1009 if test -f "$srcdir/include/GL/glut.h"; then
1010     default_glut=yes
1011 else
1012     default_glut=no
1013 fi
1014 AC_ARG_ENABLE([glut],
1015     [AS_HELP_STRING([--disable-glut],
1016         [enable GLUT library @<:@default=enabled if source available@:>@])],
1017     [enable_glut="$enableval"],
1018     [enable_glut="$default_glut"])
1019
1020 dnl Can't build glut if GLU not available
1021 if test "x$enable_glu$enable_glut" = xnoyes; then
1022     AC_MSG_WARN([Disabling glut since GLU is disabled])
1023     enable_glut=no
1024 fi
1025 dnl Don't build glut on osmesa
1026 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1027     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1028     enable_glut=no
1029 fi
1030
1031 if test "x$enable_glut" = xyes; then
1032     SRC_DIRS="$SRC_DIRS glut/glx"
1033     GLUT_CFLAGS=""
1034     if test "x$GCC" = xyes; then
1035         GLUT_CFLAGS="-fexceptions"
1036     fi
1037     if test "$x11_pkgconfig" = yes; then
1038         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1039         GLUT_PC_REQ_PRIV="x11 xmu xi"
1040         GLUT_LIB_DEPS="$GLUT_LIBS"
1041     else
1042         # should check these...
1043         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1044         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1045         GLUT_PC_CFLAGS="$X11_INCLUDES"
1046     fi
1047     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1048     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1049
1050     # If glut is available, we can build most programs
1051     if test "$with_demos" = yes; then
1052         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1053     fi
1054
1055     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1056     if test "$enable_static" = no; then
1057         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1058     else
1059         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1060         GLUT_LIB_DEPS=""
1061         GLUT_MESA_DEPS=""
1062     fi
1063 fi
1064 AC_SUBST([GLUT_LIB_DEPS])
1065 AC_SUBST([GLUT_MESA_DEPS])
1066 AC_SUBST([GLUT_CFLAGS])
1067 AC_SUBST([GLUT_PC_REQ_PRIV])
1068 AC_SUBST([GLUT_PC_LIB_PRIV])
1069 AC_SUBST([GLUT_PC_CFLAGS])
1070
1071 dnl
1072 dnl Program library dependencies
1073 dnl    Only libm is added here if necessary as the libraries should
1074 dnl    be pulled in by the linker
1075 dnl
1076 if test "x$APP_LIB_DEPS" = x; then
1077     case "$host_os" in
1078     solaris*)
1079         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1080         ;;
1081     *)
1082         APP_LIB_DEPS="-lm"
1083         ;;
1084     esac
1085 fi
1086 AC_SUBST([APP_LIB_DEPS])
1087 AC_SUBST([PROGRAM_DIRS])
1088
1089 dnl
1090 dnl Gallium configuration
1091 dnl
1092 AC_ARG_ENABLE([gallium],
1093     [AS_HELP_STRING([--disable-gallium],
1094         [build gallium @<:@default=enabled@:>@])],
1095     [enable_gallium="$enableval"],
1096     [enable_gallium=yes])
1097 if test "x$enable_gallium" = xyes; then
1098     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1099 fi
1100
1101 dnl
1102 dnl Gallium state trackers configuration
1103 dnl
1104 AC_ARG_WITH([state-trackers],
1105     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1106         [comma delimited state_trackers list, e.g.
1107         "egl,glx" @<:@default=auto@:>@])],
1108     [with_state_trackers="$withval"],
1109     [with_state_trackers=yes])
1110
1111 case "$with_state_trackers" in
1112 no)
1113     GALLIUM_STATE_TRACKERS_DIRS=""
1114     ;;
1115 yes)
1116     # look at what else is built
1117     case "$mesa_driver" in
1118     xlib)
1119         GALLIUM_STATE_TRACKERS_DIRS=glx
1120         ;;
1121     dri)
1122         test "x$enable_egl" = xyes && GALLIUM_STATE_TRACKERS_DIRS=egl
1123         ;;
1124     esac
1125     ;;
1126 *)
1127     # verify the requested state tracker exist
1128     state_trackers=`IFS=', '; echo $with_state_trackers`
1129     for tracker in $state_trackers; do
1130         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1131             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1132
1133         if test "$tracker" = egl && test "x$enable_egl" != xyes; then
1134             AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1135         fi
1136     done
1137     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1138     ;;
1139 esac
1140
1141 AC_ARG_WITH([xorg-driver-dir],
1142     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1143                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1144     [XORG_DRIVER_INSTALL_DIR="$withval"],
1145     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1146 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1147
1148 dnl
1149 dnl Gallium Intel configuration
1150 dnl
1151 AC_ARG_ENABLE([gallium-intel],
1152     [AS_HELP_STRING([--disable-gallium-intel],
1153         [build gallium intel @<:@default=enabled@:>@])],
1154     [enable_gallium_intel="$enableval"],
1155     [enable_gallium_intel=yes])
1156 if test "x$enable_gallium_intel" = xyes; then
1157     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1158     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1159 fi
1160
1161 dnl
1162 dnl Gallium Radeon configuration
1163 dnl
1164 AC_ARG_ENABLE([gallium-radeon],
1165     [AS_HELP_STRING([--enable-gallium-radeon],
1166         [build gallium radeon @<:@default=disabled@:>@])],
1167     [enable_gallium_radeon="$enableval"],
1168     [enable_gallium_radeon=no])
1169 if test "x$enable_gallium_radeon" = xyes; then
1170     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1171     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1172 fi
1173
1174 dnl
1175 dnl Gallium Radeon configuration
1176 dnl
1177 AC_ARG_ENABLE([gallium-nouveau],
1178     [AS_HELP_STRING([--enable-gallium-nouveau],
1179         [build gallium nouveau @<:@default=disabled@:>@])],
1180     [enable_gallium_nouveau="$enableval"],
1181     [enable_gallium_nouveau=no])
1182 if test "x$enable_gallium_nouveau" = xyes; then
1183     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1184     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv04 nv10 nv20 nv30 nv40 nv50"
1185 fi
1186
1187
1188 dnl Restore LDFLAGS and CPPFLAGS
1189 LDFLAGS="$_SAVE_LDFLAGS"
1190 CPPFLAGS="$_SAVE_CPPFLAGS"
1191
1192 dnl Substitute the config
1193 AC_CONFIG_FILES([configs/autoconf])
1194
1195 dnl Replace the configs/current symlink
1196 AC_CONFIG_COMMANDS([configs],[
1197 if test -f configs/current || test -L configs/current; then
1198     rm -f configs/current
1199 fi
1200 ln -s autoconf configs/current
1201 ])
1202
1203 AC_OUTPUT
1204
1205 dnl
1206 dnl Output some configuration info for the user
1207 dnl
1208 echo ""
1209 echo "        prefix:          $prefix"
1210 echo "        exec_prefix:     $exec_prefix"
1211 echo "        libdir:          $libdir"
1212 echo "        includedir:      $includedir"
1213
1214 dnl Driver info
1215 echo ""
1216 echo "        Driver:          $mesa_driver"
1217 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1218     echo "        OSMesa:          lib$OSMESA_LIB"
1219 else
1220     echo "        OSMesa:          no"
1221 fi
1222 if test "$mesa_driver" = dri; then
1223     # cleanup the drivers var
1224     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1225 if test "x$DRI_DIRS" = x; then
1226     echo "        DRI drivers:     no"
1227 else
1228     echo "        DRI drivers:     $dri_dirs"
1229 fi
1230     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1231 fi
1232 echo "        Use XCB:         $enable_xcb"
1233
1234 echo ""
1235 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1236     echo "        Gallium:         yes"
1237     echo "        Gallium dirs:    $GALLIUM_DIRS"
1238     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1239     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1240     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1241     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1242     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1243 else
1244     echo "        Gallium:         no"
1245 fi
1246
1247 dnl Libraries
1248 echo ""
1249 echo "        Shared libs:     $enable_shared"
1250 echo "        Static libs:     $enable_static"
1251 echo "        EGL:             $enable_egl"
1252 echo "        GLU:             $enable_glu"
1253 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1254 echo "        glut:            $enable_glut"
1255
1256 dnl Programs
1257 # cleanup the programs var for display
1258 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1259 if test "x$program_dirs" = x; then
1260     echo "        Demos:           no"
1261 else
1262     echo "        Demos:           $program_dirs"
1263 fi
1264
1265 dnl Compiler options
1266 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1267 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1268     $SED 's/^ *//;s/  */ /;s/ *$//'`
1269 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1270     $SED 's/^ *//;s/  */ /;s/ *$//'`
1271 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1272 echo ""
1273 echo "        CFLAGS:          $cflags"
1274 echo "        CXXFLAGS:        $cxxflags"
1275 echo "        Macros:          $defines"
1276
1277 echo ""
1278 echo "        Run '${MAKE-make}' to build Mesa"
1279 echo ""