configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCB_REQUIRED=1.9.3
  45 XCBDRI2_REQUIRED=1.8
  46 XCBGLX_REQUIRED=1.8.1
  47 XSHMFENCE_REQUIRED=1.1
  48 XVMC_REQUIRED=1.0.6
  49
  50 dnl Check for progs
  51 AC_PROG_CPP
  52 AC_PROG_CC
  53 AC_PROG_CXX
  54 AM_PROG_CC_C_O
  55 AM_PROG_AS
  56 AX_CHECK_GNU_MAKE
  57 AC_CHECK_PROGS([PYTHON2], [python2 python])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 AC_SYS_LARGEFILE
  62
  63 LT_PREREQ([2.2])
  64 LT_INIT([disable-static])
  65
  66 AX_PROG_BISON([],
  67               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  68                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  69 AX_PROG_FLEX([],
  70              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  71                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133 AX_GCC_BUILTIN([__builtin_clz])
 134 AX_GCC_BUILTIN([__builtin_clzll])
 135 AX_GCC_BUILTIN([__builtin_ctz])
 136 AX_GCC_BUILTIN([__builtin_expect])
 137 AX_GCC_BUILTIN([__builtin_ffs])
 138 AX_GCC_BUILTIN([__builtin_ffsll])
 139 AX_GCC_BUILTIN([__builtin_popcount])
 140 AX_GCC_BUILTIN([__builtin_popcountll])
 141 AX_GCC_BUILTIN([__builtin_unreachable])
 142
 143 AX_GCC_FUNC_ATTRIBUTE([flatten])
 144 AX_GCC_FUNC_ATTRIBUTE([format])
 145 AX_GCC_FUNC_ATTRIBUTE([malloc])
 146 AX_GCC_FUNC_ATTRIBUTE([packed])
 147
 148 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 149
 150 dnl Make sure the pkg-config macros are defined
 151 m4_ifndef([PKG_PROG_PKG_CONFIG],
 152     [m4_fatal([Could not locate the pkg-config autoconf macros.
 153   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 154   are in a different location, try setting the environment variable
 155   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 156 PKG_PROG_PKG_CONFIG()
 157
 158 dnl LIB_DIR - library basename
 159 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 160 AC_SUBST([LIB_DIR])
 161
 162 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 163 _SAVE_LDFLAGS="$LDFLAGS"
 164 _SAVE_CPPFLAGS="$CPPFLAGS"
 165
 166 dnl Compiler macros
 167 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 168 AC_SUBST([DEFINES])
 169 case "$host_os" in
 170 linux*|*-gnu*|gnu*)
 171     DEFINES="$DEFINES -D_GNU_SOURCE"
 172     ;;
 173 solaris*)
 174     DEFINES="$DEFINES -DSVR4"
 175     ;;
 176 cygwin*)
 177     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 178     ;;
 179 esac
 180
 181 dnl Add flags for gcc and g++
 182 if test "x$GCC" = xyes; then
 183     CFLAGS="$CFLAGS -Wall -std=c99"
 184
 185     # Enable -Werror=implicit-function-declaration and
 186     # -Werror=missing-prototypes, if available, or otherwise, just
 187     # -Wmissing-prototypes.  This is particularly useful to avoid
 188     # generating a loadable driver module that has undefined symbols.
 189     save_CFLAGS="$CFLAGS"
 190     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 191     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 192     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 193     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 194                    AC_MSG_RESULT([yes]),
 195                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 196                     AC_MSG_RESULT([no])]);
 197
 198     # Enable -fvisibility=hidden if using a gcc that supports it
 199     save_CFLAGS="$CFLAGS"
 200     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 201     VISIBILITY_CFLAGS="-fvisibility=hidden"
 202     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 203     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 204                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 205
 206     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 207     CFLAGS=$save_CFLAGS
 208
 209     # Work around aliasing bugs - developers should comment this out
 210     CFLAGS="$CFLAGS -fno-strict-aliasing"
 211
 212     # gcc's builtin memcmp is slower than glibc's
 213     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 214     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 215 fi
 216 if test "x$GXX" = xyes; then
 217     CXXFLAGS="$CXXFLAGS -Wall"
 218
 219     # Enable -fvisibility=hidden if using a gcc that supports it
 220     save_CXXFLAGS="$CXXFLAGS"
 221     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 222     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 223     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 224     AC_LANG_PUSH([C++])
 225     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 226                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 227     AC_LANG_POP([C++])
 228
 229     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 230     CXXFLAGS=$save_CXXFLAGS
 231
 232     # Work around aliasing bugs - developers should comment this out
 233     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 234
 235     # gcc's builtin memcmp is slower than glibc's
 236     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 237     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 238 fi
 239
 240 dnl even if the compiler appears to support it, using visibility attributes isn't
 241 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 242 case "$host_os" in
 243 cygwin*)
 244     VISIBILITY_CFLAGS=""
 245     VISIBILITY_CXXFLAGS=""
 246     ;;
 247 esac
 248
 249 AC_SUBST([VISIBILITY_CFLAGS])
 250 AC_SUBST([VISIBILITY_CXXFLAGS])
 251
 252 dnl
 253 dnl Optional flags, check for compiler support
 254 dnl
 255 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 256 if test "x$SSE41_SUPPORTED" = x1; then
 257     DEFINES="$DEFINES -DUSE_SSE41"
 258 fi
 259 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 260
 261 dnl Can't have static and shared libraries, default to static if user
 262 dnl explicitly requested. If both disabled, set to static since shared
 263 dnl was explicitly requested.
 264 case "x$enable_static$enable_shared" in
 265 xyesyes)
 266     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 267     enable_shared=no
 268     ;;
 269 xnono)
 270     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 271     enable_shared=yes
 272     ;;
 273 esac
 274
 275 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 276
 277 dnl
 278 dnl other compiler options
 279 dnl
 280 AC_ARG_ENABLE([debug],
 281     [AS_HELP_STRING([--enable-debug],
 282         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 283     [enable_debug="$enableval"],
 284     [enable_debug=no]
 285 )
 286 if test "x$enable_debug" = xyes; then
 287     DEFINES="$DEFINES -DDEBUG"
 288     if test "x$GCC" = xyes; then
 289         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 290             CFLAGS="$CFLAGS -g"
 291         fi
 292         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 293             CFLAGS="$CFLAGS -O0"
 294         fi
 295     fi
 296     if test "x$GXX" = xyes; then
 297         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 298             CXXFLAGS="$CXXFLAGS -g"
 299         fi
 300         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 301             CXXFLAGS="$CXXFLAGS -O0"
 302         fi
 303     fi
 304 fi
 305
 306 dnl
 307 dnl Check if linker supports -Bsymbolic
 308 dnl
 309 save_LDFLAGS=$LDFLAGS
 310 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 311 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 312 AC_LINK_IFELSE(
 313     [AC_LANG_SOURCE([int main() { return 0;}])],
 314     [AC_MSG_RESULT([yes])
 315         BSYMBOLIC="-Wl,-Bsymbolic";],
 316     [AC_MSG_RESULT([no])
 317         BSYMBOLIC="";])
 318 LDFLAGS=$save_LDFLAGS
 319
 320 AC_SUBST([BSYMBOLIC])
 321
 322 dnl
 323 dnl Check if linker supports garbage collection
 324 dnl
 325 save_LDFLAGS=$LDFLAGS
 326 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 327 AC_MSG_CHECKING([whether ld supports --gc-sections])
 328 AC_LINK_IFELSE(
 329     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 330     [AC_MSG_RESULT([yes])
 331         GC_SECTIONS="-Wl,--gc-sections";],
 332     [AC_MSG_RESULT([no])
 333         GC_SECTIONS="";])
 334 LDFLAGS=$save_LDFLAGS
 335
 336 AC_SUBST([GC_SECTIONS])
 337
 338 dnl
 339 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 340 dnl so when these flags are passed to ld via libtool the checks will fail
 341 dnl
 342 case "$host_os" in
 343 openbsd* | darwin* )
 344     LD_NO_UNDEFINED="" ;;
 345 *)
 346     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 347 esac
 348
 349 AC_SUBST([LD_NO_UNDEFINED])
 350
 351 dnl
 352 dnl Check if linker supports version scripts
 353 dnl
 354 AC_MSG_CHECKING([if the linker supports version-scripts])
 355 save_LDFLAGS=$LDFLAGS
 356 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 357 cat > conftest.map <<EOF
 358 VERSION_1 {
 359      global:
 360          main;
 361
 362      local:
 363          *;
 364 };
 365 EOF
 366 AC_LINK_IFELSE(
 367     [AC_LANG_SOURCE([int main() { return 0;}])],
 368     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 369     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 370 LDFLAGS=$save_LDFLAGS
 371 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 372
 373 dnl
 374 dnl Check if linker supports dynamic list files
 375 dnl
 376 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 377 save_LDFLAGS=$LDFLAGS
 378 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 379 cat > conftest.dyn <<EOF
 380 {
 381         radeon_drm_winsys_create;
 382 };
 383 EOF
 384 AC_LINK_IFELSE(
 385     [AC_LANG_SOURCE([int main() { return 0;}])],
 386     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 387     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 388 LDFLAGS=$save_LDFLAGS
 389 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 390
 391 dnl
 392 dnl compatibility symlinks
 393 dnl
 394 case "$host_os" in
 395 linux* )
 396     HAVE_COMPAT_SYMLINKS=yes ;;
 397 * )
 398     HAVE_COMPAT_SYMLINKS=no ;;
 399 esac
 400
 401 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 402
 403 dnl
 404 dnl library names
 405 dnl
 406 case "$host_os" in
 407 darwin* )
 408     LIB_EXT='dylib' ;;
 409 cygwin* )
 410     LIB_EXT='dll' ;;
 411 aix* )
 412     LIB_EXT='a' ;;
 413 * )
 414     LIB_EXT='so' ;;
 415 esac
 416
 417 AC_SUBST([LIB_EXT])
 418
 419 AC_ARG_WITH([gl-lib-name],
 420   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 421     [specify GL library name @<:@default=GL@:>@])],
 422   [GL_LIB=$withval],
 423   [GL_LIB=GL])
 424 AC_ARG_WITH([osmesa-lib-name],
 425   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 426     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 427   [OSMESA_LIB=$withval],
 428   [OSMESA_LIB=OSMesa])
 429 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 430 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 431
 432 dnl
 433 dnl Mangled Mesa support
 434 dnl
 435 AC_ARG_ENABLE([mangling],
 436   [AS_HELP_STRING([--enable-mangling],
 437     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 438   [enable_mangling="${enableval}"],
 439   [enable_mangling=no]
 440 )
 441 if test "x${enable_mangling}" = "xyes" ; then
 442   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 443   GL_LIB="Mangled${GL_LIB}"
 444   OSMESA_LIB="Mangled${OSMESA_LIB}"
 445 fi
 446 AC_SUBST([GL_LIB])
 447 AC_SUBST([OSMESA_LIB])
 448
 449 dnl
 450 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 451 dnl
 452 AC_ARG_ENABLE([texture-float],
 453     [AS_HELP_STRING([--enable-texture-float],
 454         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 455     [enable_texture_float="$enableval"],
 456     [enable_texture_float=no]
 457 )
 458 if test "x$enable_texture_float" = xyes; then
 459     AC_MSG_WARN([Floating-point textures enabled.])
 460     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 461     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 462 fi
 463
 464 dnl
 465 dnl Arch/platform-specific settings
 466 dnl
 467 AC_ARG_ENABLE([asm],
 468     [AS_HELP_STRING([--disable-asm],
 469         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 470     [enable_asm="$enableval"],
 471     [enable_asm=yes]
 472 )
 473 asm_arch=""
 474 AC_MSG_CHECKING([whether to enable assembly])
 475 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 476 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 477 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 478     case "$host_cpu" in
 479     i?86 | x86_64 | amd64)
 480         enable_asm=no
 481         AC_MSG_RESULT([no, cross compiling])
 482         ;;
 483     esac
 484 fi
 485 # check for supported arches
 486 if test "x$enable_asm" = xyes; then
 487     case "$host_cpu" in
 488     i?86)
 489         case "$host_os" in
 490         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 491             asm_arch=x86
 492             ;;
 493         esac
 494         ;;
 495     x86_64|amd64)
 496         case "$host_os" in
 497         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 498             asm_arch=x86_64
 499             ;;
 500         esac
 501         ;;
 502     sparc*)
 503         case "$host_os" in
 504         linux*)
 505             asm_arch=sparc
 506             ;;
 507         esac
 508         ;;
 509     esac
 510
 511     case "$asm_arch" in
 512     x86)
 513         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 514         AC_MSG_RESULT([yes, x86])
 515         ;;
 516     x86_64|amd64)
 517         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 518         AC_MSG_RESULT([yes, x86_64])
 519         ;;
 520     sparc)
 521         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 522         AC_MSG_RESULT([yes, sparc])
 523         ;;
 524     *)
 525         AC_MSG_RESULT([no, platform not supported])
 526         ;;
 527     esac
 528 fi
 529
 530 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 531 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 532
 533 dnl Check to see if dlopen is in default libraries (like Solaris, which
 534 dnl has it in libc), or if libdl is needed to get it.
 535 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 536     [AC_CHECK_LIB([dl], [dlopen],
 537        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 538 AC_SUBST([DLOPEN_LIBS])
 539
 540 dnl Check if that library also has dladdr
 541 save_LIBS="$LIBS"
 542 LIBS="$LIBS $DLOPEN_LIBS"
 543 AC_CHECK_FUNCS([dladdr])
 544 LIBS="$save_LIBS"
 545
 546 case "$host_os" in
 547 darwin*|mingw*)
 548     ;;
 549 *)
 550     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 551                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 552                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 553     AC_SUBST([CLOCK_LIB])
 554     ;;
 555 esac
 556
 557 dnl See if posix_memalign is available
 558 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 559
 560 dnl Check for pthreads
 561 case "$host_os" in
 562 mingw*)
 563     ;;
 564 *)
 565     AX_PTHREAD
 566     ;;
 567 esac
 568 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 569 dnl to -pthread, which causes problems if we need -lpthread to appear in
 570 dnl pkgconfig files.
 571 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 572
 573 dnl SELinux awareness.
 574 AC_ARG_ENABLE([selinux],
 575     [AS_HELP_STRING([--enable-selinux],
 576         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 577     [MESA_SELINUX="$enableval"],
 578     [MESA_SELINUX=no])
 579 if test "x$enable_selinux" = "xyes"; then
 580     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 581         [AC_CHECK_HEADER([selinux/selinux.h],[],
 582                          [AC_MSG_ERROR([SELinux headers not found])])
 583          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 584                       [AC_MSG_ERROR([SELinux library not found])])
 585          SELINUX_LIBS="-lselinux"])
 586     DEFINES="$DEFINES -DMESA_SELINUX"
 587 fi
 588 AC_SUBST([SELINUX_CFLAGS])
 589 AC_SUBST([SELINUX_LIBS])
 590
 591 dnl Options for APIs
 592 AC_ARG_ENABLE([opengl],
 593     [AS_HELP_STRING([--disable-opengl],
 594         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 595     [enable_opengl="$enableval"],
 596     [enable_opengl=yes])
 597 AC_ARG_ENABLE([gles1],
 598     [AS_HELP_STRING([--enable-gles1],
 599         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 600     [enable_gles1="$enableval"],
 601     [enable_gles1=no])
 602 AC_ARG_ENABLE([gles2],
 603     [AS_HELP_STRING([--enable-gles2],
 604         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 605     [enable_gles2="$enableval"],
 606     [enable_gles2=no])
 607 AC_ARG_ENABLE([openvg],
 608     [AS_HELP_STRING([--enable-openvg],
 609         [enable support for OpenVG API @<:@default=disabled@:>@])],
 610     [enable_openvg="$enableval"],
 611     [enable_openvg=no])
 612
 613 AC_ARG_ENABLE([dri],
 614     [AS_HELP_STRING([--enable-dri],
 615         [enable DRI modules @<:@default=enabled@:>@])],
 616     [enable_dri="$enableval"],
 617     [enable_dri=yes])
 618
 619 case "$host_os" in
 620 linux*)
 621     dri3_default=yes
 622     ;;
 623 *)
 624     dri3_default=no
 625     ;;
 626 esac
 627 AC_ARG_ENABLE([dri3],
 628     [AS_HELP_STRING([--enable-dri3],
 629         [enable DRI3 @<:@default=auto@:>@])],
 630     [enable_dri3="$enableval"],
 631     [enable_dri3="$dri3_default"])
 632 AC_ARG_ENABLE([glx],
 633     [AS_HELP_STRING([--enable-glx],
 634         [enable GLX library @<:@default=enabled@:>@])],
 635     [enable_glx="$enableval"],
 636     [enable_glx=yes])
 637 AC_ARG_ENABLE([osmesa],
 638     [AS_HELP_STRING([--enable-osmesa],
 639         [enable OSMesa library @<:@default=disabled@:>@])],
 640     [enable_osmesa="$enableval"],
 641     [enable_osmesa=no])
 642 AC_ARG_ENABLE([gallium-osmesa],
 643     [AS_HELP_STRING([--enable-gallium-osmesa],
 644         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 645     [enable_gallium_osmesa="$enableval"],
 646     [enable_gallium_osmesa=no])
 647 AC_ARG_ENABLE([egl],
 648     [AS_HELP_STRING([--disable-egl],
 649         [disable EGL library @<:@default=enabled@:>@])],
 650     [enable_egl="$enableval"],
 651     [enable_egl=yes])
 652
 653 AC_ARG_ENABLE([xa],
 654     [AS_HELP_STRING([--enable-xa],
 655         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 656     [enable_xa="$enableval"],
 657     [enable_xa=no])
 658 AC_ARG_ENABLE([gbm],
 659    [AS_HELP_STRING([--enable-gbm],
 660          [enable gbm library @<:@default=auto@:>@])],
 661    [enable_gbm="$enableval"],
 662    [enable_gbm=auto])
 663
 664 AC_ARG_ENABLE([xvmc],
 665    [AS_HELP_STRING([--enable-xvmc],
 666          [enable xvmc library @<:@default=auto@:>@])],
 667    [enable_xvmc="$enableval"],
 668    [enable_xvmc=auto])
 669 AC_ARG_ENABLE([vdpau],
 670    [AS_HELP_STRING([--enable-vdpau],
 671          [enable vdpau library @<:@default=auto@:>@])],
 672    [enable_vdpau="$enableval"],
 673    [enable_vdpau=auto])
 674 AC_ARG_ENABLE([omx],
 675    [AS_HELP_STRING([--enable-omx],
 676          [enable OpenMAX library @<:@default=disabled@:>@])],
 677    [enable_omx="$enableval"],
 678    [enable_omx=no])
 679 AC_ARG_ENABLE([va],
 680    [AS_HELP_STRING([--enable-va],
 681          [enable va library @<:@default=auto@:>@])],
 682    [enable_va="$enableval"],
 683    [enable_va=auto])
 684 AC_ARG_ENABLE([opencl],
 685    [AS_HELP_STRING([--enable-opencl],
 686          [enable OpenCL library @<:@default=disabled@:>@])],
 687    [enable_opencl="$enableval"],
 688    [enable_opencl=no])
 689 AC_ARG_ENABLE([opencl_icd],
 690    [AS_HELP_STRING([--enable-opencl-icd],
 691           [Build an OpenCL ICD library to be loaded by an ICD implementation
 692            @<:@default=disabled@:>@])],
 693     [enable_opencl_icd="$enableval"],
 694     [enable_opencl_icd=no])
 695 AC_ARG_ENABLE([xlib-glx],
 696     [AS_HELP_STRING([--enable-xlib-glx],
 697         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 698     [enable_xlib_glx="$enableval"],
 699     [enable_xlib_glx=no])
 700 AC_ARG_ENABLE([gallium-egl],
 701     [AS_HELP_STRING([--enable-gallium-egl],
 702         [enable optional EGL state tracker (not required
 703          for EGL support in Gallium with OpenGL and OpenGL ES)
 704          @<:@default=disabled@:>@])],
 705     [enable_gallium_egl="$enableval"],
 706     [enable_gallium_egl=no])
 707 AC_ARG_ENABLE([gallium-gbm],
 708     [AS_HELP_STRING([--enable-gallium-gbm],
 709         [enable optional gbm state tracker (not required for
 710          gbm support in Gallium)
 711          @<:@default=auto@:>@])],
 712     [enable_gallium_gbm="$enableval"],
 713     [enable_gallium_gbm=auto])
 714
 715 AC_ARG_ENABLE([r600-llvm-compiler],
 716     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 717         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 718     [enable_r600_llvm="$enableval"],
 719     [enable_r600_llvm=no])
 720
 721 AC_ARG_ENABLE([gallium-tests],
 722     [AS_HELP_STRING([--enable-gallium-tests],
 723         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 724     [enable_gallium_tests="$enableval"],
 725     [enable_gallium_tests=no])
 726
 727 # Option for Gallium drivers
 728
 729 # Keep this in sync with the --with-gallium-drivers help string default value
 730 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 731
 732 AC_ARG_WITH([gallium-drivers],
 733     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 734         [comma delimited Gallium drivers list, e.g.
 735         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 736         @<:@default=r300,r600,svga,swrast@:>@])],
 737     [with_gallium_drivers="$withval"],
 738     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 739
 740 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 741 # here so that the script doesn't choke on an unknown driver name later.
 742 case "$with_gallium_drivers" in
 743     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 744     no) with_gallium_drivers='' ;;
 745 esac
 746
 747 if test "x$enable_opengl" = xno -a \
 748         "x$enable_gles1" = xno -a \
 749         "x$enable_gles2" = xno -a \
 750         "x$enable_openvg" = xno -a \
 751         "x$enable_xa" = xno -a \
 752         "x$enable_xvmc" = xno -a \
 753         "x$enable_vdpau" = xno -a \
 754         "x$enable_omx" = xno -a \
 755         "x$enable_va" = xno -a \
 756         "x$enable_opencl" = xno; then
 757     AC_MSG_ERROR([at least one API should be enabled])
 758 fi
 759
 760 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 761 if test "x$enable_opengl" = xno -a \
 762         "x$enable_gles1" = xyes; then
 763     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 764 fi
 765
 766 if test "x$enable_opengl" = xno -a \
 767         "x$enable_gles2" = xyes; then
 768     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 769 fi
 770
 771 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 772 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 773 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 774 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 775                                         "x$enable_gles1" = xyes -o \
 776                                         "x$enable_gles2" = xyes)
 777
 778 if test "x$enable_glx" = xno; then
 779     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 780     enable_xlib_glx=no
 781 fi
 782
 783 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 784     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 785 fi
 786
 787 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 788     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 789 fi
 790
 791 # Disable GLX if OpenGL is not enabled
 792 if test "x$enable_glx$enable_opengl" = xyesno; then
 793     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 794     enable_glx=no
 795 fi
 796
 797 # Disable GLX if DRI and Xlib-GLX are not enabled
 798 if test "x$enable_glx" = xyes -a \
 799         "x$enable_dri" = xno -a \
 800         "x$enable_xlib_glx" = xno; then
 801     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 802     enable_glx=no
 803 fi
 804
 805 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 806                                   "x$enable_dri" = xyes)
 807
 808 # Select which platform-dependent DRI code gets built
 809 case "$host_os" in
 810 darwin*)
 811     dri_platform='apple' ;;
 812 gnu*|mingw*|cygwin*)
 813     dri_platform='none' ;;
 814 *)
 815     dri_platform='drm' ;;
 816 esac
 817
 818 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 819 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 820 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 821 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 822 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 823
 824 AC_ARG_ENABLE([shared-glapi],
 825     [AS_HELP_STRING([--enable-shared-glapi],
 826         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 827     [enable_shared_glapi="$enableval"],
 828     [enable_shared_glapi=yes])
 829
 830 case "x$enable_opengl$enable_gles1$enable_gles2" in
 831 x*yes*yes*)
 832     if test "x$enable_shared_glapi" = xno; then
 833         AC_MSG_ERROR([shared GLAPI required when building two or more of
 834                       the following APIs - opengl, gles1 gles2])
 835     fi
 836     ;;
 837 esac
 838
 839 # Building Xlib-GLX requires shared glapi to be disabled.
 840 if test "x$enable_xlib_glx" = xyes; then
 841     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 842     enable_shared_glapi=no
 843 fi
 844
 845 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 846
 847 # Build the pipe-drivers as separate libraries/modules.
 848 # Do not touch this unless you know what you are doing.
 849 # XXX: Expose via configure option ?
 850 enable_shared_pipe_drivers=no
 851
 852 dnl
 853 dnl Driver specific build directories
 854 dnl
 855
 856 case "x$enable_glx$enable_xlib_glx" in
 857 xyesyes)
 858     NEED_WINSYS_XLIB="yes"
 859     ;;
 860 esac
 861
 862 if test "x$enable_dri" = xyes; then
 863     enable_gallium_loader="$enable_shared_pipe_drivers"
 864 fi
 865
 866 if test "x$enable_gallium_osmesa" = xyes; then
 867     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 868         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 869     fi
 870     if test "x$enable_osmesa" = xyes; then
 871         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 872     fi
 873 fi
 874
 875 AC_SUBST([MESA_LLVM])
 876
 877 # Check for libdrm
 878 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 879                   [have_libdrm=yes], [have_libdrm=no])
 880 if test "x$have_libdrm" = xyes; then
 881         DEFINES="$DEFINES -DHAVE_LIBDRM"
 882 fi
 883
 884 case "$host_os" in
 885 linux*)
 886     need_pci_id=yes ;;
 887 *)
 888     need_pci_id=no ;;
 889 esac
 890
 891 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 892                   have_libudev=yes, have_libudev=no)
 893
 894 AC_ARG_ENABLE([sysfs],
 895     [AS_HELP_STRING([--enable-sysfs],
 896         [enable /sys PCI identification @<:@default=disabled@:>@])],
 897     [have_sysfs="$enableval"],
 898     [have_sysfs=no]
 899 )
 900
 901 if test "x$enable_dri" = xyes; then
 902     if test "$enable_static" = yes; then
 903         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 904     fi
 905
 906     # not a hard requirement as swrast does not depend on it
 907     if test "x$have_libdrm" = xyes; then
 908         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 909     fi
 910 fi
 911
 912 AC_ARG_ENABLE([driglx-direct],
 913     [AS_HELP_STRING([--disable-driglx-direct],
 914         [disable direct rendering in GLX and EGL for DRI \
 915             @<:@default=auto@:>@])],
 916     [driglx_direct="$enableval"],
 917     [driglx_direct="yes"])
 918
 919 dnl
 920 dnl libGL configuration per driver
 921 dnl
 922 case "x$enable_glx$enable_xlib_glx" in
 923 xyesyes)
 924     # Xlib-based GLX
 925     dri_modules="x11 xext xcb"
 926     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 927     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 928     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 929     GL_LIB_DEPS="$XLIBGL_LIBS"
 930     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 931     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 932     ;;
 933 xyesno)
 934     # DRI-based GLX
 935     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 936
 937     # find the DRI deps for libGL
 938     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 939
 940     if test x"$driglx_direct" = xyes; then
 941         if test x"$dri_platform" = xdrm ; then
 942             DEFINES="$DEFINES -DGLX_USE_DRM"
 943             if test "x$have_libdrm" != xyes; then
 944                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 945             fi
 946
 947             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 948             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 949             if test x"$enable_dri3" = xyes; then
 950                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 951                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 952             fi
 953
 954             if test x"$enable_dri" = xyes; then
 955                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 956             fi
 957
 958             if test x"$enable_dri3" = xyes; then
 959                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 960                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 961             fi
 962         fi
 963         if test x"$dri_platform" = xapple ; then
 964             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 965         fi
 966     fi
 967
 968     # add xf86vidmode if available
 969     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 970     if test "$HAVE_XF86VIDMODE" = yes ; then
 971         dri_modules="$dri_modules xxf86vm"
 972     fi
 973
 974     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 975     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 976     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 977     GL_LIB_DEPS="$DRIGL_LIBS"
 978
 979     # need DRM libs, $PTHREAD_LIBS, etc.
 980     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 981     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 982     ;;
 983 esac
 984
 985 have_pci_id=no
 986 if test "$have_libudev" = yes; then
 987     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 988     have_pci_id=yes
 989 fi
 990
 991 if test "$have_sysfs" = yes; then
 992     DEFINES="$DEFINES -DHAVE_SYSFS"
 993     have_pci_id=yes
 994 fi
 995
 996 # This is outside the case (above) so that it is invoked even for non-GLX
 997 # builds.
 998 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 999
1000 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1001 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1002 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1003 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1004
1005 AC_SUBST([X11_INCLUDES])
1006 AC_SUBST([GL_LIB_DEPS])
1007 AC_SUBST([GL_PC_REQ_PRIV])
1008 AC_SUBST([GL_PC_LIB_PRIV])
1009 AC_SUBST([GL_PC_CFLAGS])
1010 AC_SUBST([DRI_PC_REQ_PRIV])
1011 AC_SUBST([GLESv1_CM_LIB_DEPS])
1012 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1013 AC_SUBST([GLESv2_LIB_DEPS])
1014 AC_SUBST([GLESv2_PC_LIB_PRIV])
1015
1016 AC_SUBST([HAVE_XF86VIDMODE])
1017
1018 dnl
1019 dnl More GLX setup
1020 dnl
1021 case "x$enable_glx$enable_xlib_glx" in
1022 xyesyes)
1023     DEFINES="$DEFINES -DUSE_XSHM"
1024     ;;
1025 xyesno)
1026     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1027     if test "x$driglx_direct" = xyes; then
1028         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1029     fi
1030     ;;
1031 esac
1032
1033 dnl
1034 dnl TLS detection
1035 dnl
1036
1037 AC_ARG_ENABLE([glx-tls],
1038     [AS_HELP_STRING([--enable-glx-tls],
1039         [enable TLS support in GLX @<:@default=disabled@:>@])],
1040     [GLX_USE_TLS="$enableval"],
1041     [GLX_USE_TLS=no])
1042 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1043
1044 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1045       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1046
1047 dnl
1048 dnl More DRI setup
1049 dnl
1050 dnl Directory for DRI drivers
1051 AC_ARG_WITH([dri-driverdir],
1052     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1053         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1054     [DRI_DRIVER_INSTALL_DIR="$withval"],
1055     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1056 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1057 dnl Extra search path for DRI drivers
1058 AC_ARG_WITH([dri-searchpath],
1059     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1060         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1061     [DRI_DRIVER_SEARCH_DIR="$withval"],
1062     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1063 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1064 dnl Which drivers to build - default is chosen by platform
1065 AC_ARG_WITH([dri-drivers],
1066     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1067         [comma delimited classic DRI drivers list, e.g.
1068         "swrast,i965,radeon" @<:@default=auto@:>@])],
1069     [with_dri_drivers="$withval"],
1070     [with_dri_drivers=auto])
1071
1072 if test "x$with_dri_drivers" = xauto; then
1073     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1074         with_dri_drivers="yes"
1075     else
1076         with_dri_drivers="no"
1077     fi
1078 fi
1079 if test "x$with_dri_drivers" = xno; then
1080     with_dri_drivers=''
1081 fi
1082
1083 dnl If $with_dri_drivers is yes, drivers will be added through
1084 dnl platform checks. Set DEFINES and LIB_DEPS
1085 if test "x$enable_dri" = xyes; then
1086     # Platform specific settings and drivers to build
1087     case "$host_os" in
1088     linux*)
1089         DEFINES="$DEFINES -DHAVE_ALIAS"
1090         if test "x$enable_dri3" = xyes; then
1091             DEFINES="$DEFINES -DHAVE_DRI3"
1092         fi
1093
1094         if test "x$have_pci_id" != xyes; then
1095             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1096         fi
1097
1098         case "$host_cpu" in
1099         powerpc* | sparc*)
1100             # Build only the drivers for cards that exist on PowerPC/sparc
1101             if test "x$with_dri_drivers" = "xyes"; then
1102                 with_dri_drivers="r200 radeon swrast"
1103             fi
1104             ;;
1105         esac
1106         ;;
1107     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1108         DEFINES="$DEFINES -DHAVE_ALIAS"
1109         ;;
1110     gnu*)
1111         DEFINES="$DEFINES -DHAVE_ALIAS"
1112         ;;
1113     cygwin*)
1114         if test "x$with_dri_drivers" = "xyes"; then
1115             with_dri_drivers="swrast"
1116         fi
1117         ;;
1118     darwin*)
1119         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1120         if test "x$with_dri_drivers" = "xyes"; then
1121             with_dri_drivers="swrast"
1122         fi
1123         ;;
1124     esac
1125
1126     # default drivers
1127     if test "x$with_dri_drivers" = "xyes"; then
1128         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1129     fi
1130
1131     # Check for expat
1132     PKG_CHECK_MODULES([EXPAT], [expat], [],
1133         # expat version 2.0 and earlier do not provide expat.pc
1134         [AC_CHECK_HEADER([expat.h],[],
1135                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1136          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1137                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1138          EXPAT_LIBS="-lexpat"])
1139
1140     DRICOMMON_NEED_LIBDRM=no
1141     # If we are building any DRI driver other than swrast.
1142     if test -n "$with_dri_drivers"; then
1143         if test "x$with_dri_drivers" != xswrast; then
1144             # ... libdrm is required
1145             if test "x$have_libdrm" != xyes; then
1146                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1147             fi
1148             DRICOMMON_NEED_LIBDRM=yes
1149         fi
1150     fi
1151
1152     # If we're building any gallium DRI driver other than swrast
1153     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1154         if test "x$with_gallium_drivers" != xswrast; then
1155             # ... build a libdrm aware dricommon
1156             DRICOMMON_NEED_LIBDRM=yes
1157         fi
1158     fi
1159
1160     # put all the necessary libs together
1161     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1162 fi
1163
1164 AC_SUBST([DRI_LIB_DEPS])
1165
1166 DRI_DIRS=''
1167 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1168 if test -n "$with_dri_drivers"; then
1169     if test "x$enable_opengl" != xyes; then
1170         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1171     fi
1172
1173     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1174     for driver in $dri_drivers; do
1175         DRI_DIRS="$DRI_DIRS $driver"
1176         case "x$driver" in
1177         xi915)
1178             HAVE_I915_DRI=yes;
1179             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1180             ;;
1181         xi965)
1182             HAVE_I965_DRI=yes;
1183             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1184             ;;
1185         xnouveau)
1186             HAVE_NOUVEAU_DRI=yes;
1187             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1188             ;;
1189         xradeon)
1190             HAVE_RADEON_DRI=yes;
1191             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1192             ;;
1193         xr200)
1194             HAVE_R200_DRI=yes;
1195             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1196             ;;
1197         xswrast)
1198             HAVE_SWRAST_DRI=yes;
1199             ;;
1200         *)
1201             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1202             ;;
1203         esac
1204     done
1205     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1206 fi
1207
1208 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1209 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1210                                   "x$enable_osmesa" = xyes -o \
1211                                   -n "$DRI_DIRS")
1212
1213 dnl
1214 dnl OSMesa configuration
1215 dnl
1216
1217 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1218 AC_ARG_WITH([osmesa-bits],
1219     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1220         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1221     [osmesa_bits="$withval"],
1222     [osmesa_bits=8])
1223 if test "x$osmesa_bits" != x8; then
1224     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1225         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1226         osmesa_bits=8
1227     fi
1228 fi
1229 case "x$osmesa_bits" in
1230 x8)
1231     OSMESA_LIB="${OSMESA_LIB}"
1232     ;;
1233 x16|x32)
1234     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1235     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1236     ;;
1237 *)
1238     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1239     ;;
1240 esac
1241
1242 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1243     # only link libraries with osmesa if shared
1244     if test "$enable_static" = no; then
1245         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1246     else
1247         OSMESA_LIB_DEPS=""
1248     fi
1249     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1250 fi
1251
1252 AC_SUBST([OSMESA_LIB_DEPS])
1253 AC_SUBST([OSMESA_PC_REQ])
1254 AC_SUBST([OSMESA_PC_LIB_PRIV])
1255
1256 dnl
1257 dnl gbm configuration
1258 dnl
1259 if test "x$enable_gbm" = xauto; then
1260     case "$with_egl_platforms" in
1261         *drm*)
1262             enable_gbm=yes ;;
1263          *)
1264             enable_gbm=no ;;
1265     esac
1266 fi
1267 if test "x$enable_gbm" = xyes; then
1268     if test "x$need_pci_id$have_pci_id" = xyesno; then
1269         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1270     fi
1271
1272     if test "x$enable_dri" = xyes; then
1273         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1274         if test "x$enable_shared_glapi" = xno; then
1275             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1276         fi
1277     else
1278         # Strictly speaking libgbm does not require --enable-dri, although
1279         # both of its backends do. Thus one can build libgbm without any
1280         # backends if --disable-dri is set.
1281         # To avoid unnecessary complexity of checking if at least one backend
1282         # is available when building, just mandate --enable-dri.
1283         AC_MSG_ERROR([gbm requires --enable-dri])
1284     fi
1285 fi
1286 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1287 if test "x$need_pci_id$have_libudev" = xyesyes; then
1288     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1289 else
1290     GBM_PC_REQ_PRIV=""
1291 fi
1292 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1293 AC_SUBST([GBM_PC_REQ_PRIV])
1294 AC_SUBST([GBM_PC_LIB_PRIV])
1295
1296 dnl
1297 dnl EGL configuration
1298 dnl
1299 EGL_CLIENT_APIS=""
1300
1301 if test "x$enable_egl" = xyes; then
1302     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1303
1304     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1305
1306     if test "$enable_static" != yes; then
1307         if test "x$enable_dri" = xyes; then
1308             HAVE_EGL_DRIVER_DRI2=1
1309         fi
1310
1311     fi
1312 fi
1313 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1314 AC_SUBST([EGL_LIB_DEPS])
1315
1316 dnl
1317 dnl EGL Gallium configuration
1318 dnl
1319 if test "x$enable_gallium_egl" = xyes; then
1320     if test -z "$with_gallium_drivers"; then
1321         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1322     fi
1323     if test "x$enable_egl" = xno; then
1324         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1325     fi
1326     if test "x$have_libdrm" != xyes; then
1327         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1328     fi
1329 # XXX: Uncomment once converted to use static/shared pipe-drivers
1330 #    enable_gallium_loader=$enable_shared_pipe_drivers
1331 fi
1332 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1333
1334 dnl
1335 dnl gbm Gallium configuration
1336 dnl
1337 if test "x$enable_gallium_gbm" = xauto; then
1338     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1339         yesyesyes*drm*)
1340             enable_gallium_gbm=yes ;;
1341          *)
1342             enable_gallium_gbm=no ;;
1343     esac
1344 fi
1345 if test "x$enable_gallium_gbm" = xyes; then
1346     if test -z "$with_gallium_drivers"; then
1347         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1348     fi
1349     if test "x$enable_gbm" = xno; then
1350         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1351     fi
1352
1353     if test "x$enable_gallium_egl" != xyes; then
1354         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1355     fi
1356
1357     enable_gallium_loader=$enable_shared_pipe_drivers
1358 fi
1359 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1360
1361 dnl
1362 dnl XA configuration
1363 dnl
1364 if test "x$enable_xa" = xyes; then
1365     if test "x$with_gallium_drivers" = xswrast; then
1366        AC_MSG_ERROR([
1367           Building xa requires at least one non swrast gallium driver.
1368           If you are looking to use libxatracker.so with the VMware driver,
1369           make sure to include svga in the gallium drivers list, apart from
1370           enabling XA.
1371           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1372     fi
1373     enable_gallium_loader=$enable_shared_pipe_drivers
1374 fi
1375 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1376
1377 dnl
1378 dnl OpenVG configuration
1379 dnl
1380 VG_LIB_DEPS=""
1381
1382 if test "x$enable_openvg" = xyes; then
1383     if test "x$enable_egl" = xno; then
1384         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1385     fi
1386     if test -z "$with_gallium_drivers"; then
1387         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1388     fi
1389     if test "x$enable_gallium_egl" = xno; then
1390         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1391     fi
1392
1393     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1394     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1395     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1396     AC_SUBST([VG_PC_LIB_PRIV])
1397 fi
1398 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1399
1400 dnl
1401 dnl Gallium G3DVL configuration
1402 dnl
1403 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1404     if test "x$enable_xvmc" = xauto; then
1405         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1406     fi
1407
1408     if test "x$enable_vdpau" = xauto; then
1409         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1410     fi
1411
1412     if test "x$enable_omx" = xauto; then
1413         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1414     fi
1415
1416     if test "x$enable_va" = xauto; then
1417         PKG_CHECK_EXISTS([libva], [enable_va=yes], [enable_va=no])
1418     fi
1419 fi
1420
1421 if test "x$enable_xvmc" = xyes; then
1422     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1423     enable_gallium_loader=$enable_shared_pipe_drivers
1424 fi
1425 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1426
1427 if test "x$enable_vdpau" = xyes; then
1428     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1429                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb xcb-dri2`"])
1430     enable_gallium_loader=$enable_shared_pipe_drivers
1431 fi
1432 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1433
1434 if test "x$enable_omx" = xyes; then
1435     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1436     enable_gallium_loader=$enable_shared_pipe_drivers
1437 fi
1438 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1439
1440 if test "x$enable_va" = xyes; then
1441     PKG_CHECK_MODULES([VA], [libva >= 0.35.0 x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1442                       [VA_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1443     enable_gallium_loader=$enable_shared_pipe_drivers
1444 fi
1445 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1446
1447 dnl
1448 dnl OpenCL configuration
1449 dnl
1450
1451 AC_ARG_WITH([libclc-path],
1452    [AS_HELP_STRING([--with-libclc-path],
1453          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1454    [LIBCLC_PATH="$withval"],
1455    [LIBCLC_PATH=''])
1456
1457 if test -n "$LIBCLC_PATH"; then
1458    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1459                   Please review the updated build instructions for clover:
1460                   http://dri.freedesktop.org/wiki/GalliumCompute])
1461 fi
1462
1463
1464 AC_ARG_WITH([clang-libdir],
1465    [AS_HELP_STRING([--with-clang-libdir],
1466          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1467    [CLANG_LIBDIR="$withval"],
1468    [CLANG_LIBDIR=''])
1469
1470 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1471 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1472
1473 if test "x$enable_opencl" = xyes; then
1474     if test -z "$with_gallium_drivers"; then
1475         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1476     fi
1477
1478     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1479         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1480     fi
1481
1482     if test "x$have_libclc" = xno; then
1483         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1484                     Make sure the directory containing libclc.pc is specified in your
1485                     PKG_CONFIG_PATH environment variable.
1486                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1487     else
1488         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1489         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1490         AC_SUBST([LIBCLC_INCLUDEDIR])
1491         AC_SUBST([LIBCLC_LIBEXECDIR])
1492     fi
1493
1494     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1495     enable_gallium_loader=yes
1496
1497     if test "x$enable_opencl_icd" = xyes; then
1498         OPENCL_LIBNAME="MesaOpenCL"
1499     else
1500         OPENCL_LIBNAME="OpenCL"
1501     fi
1502
1503     if test "x$have_libelf" != xyes; then
1504        AC_MSG_ERROR([Clover requires libelf])
1505     fi
1506 fi
1507 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1508 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1509 AC_SUBST([OPENCL_LIBNAME])
1510
1511 dnl
1512 dnl Gallium configuration
1513 dnl
1514 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1515
1516 AC_SUBST([LLVM_BINDIR])
1517 AC_SUBST([LLVM_CFLAGS])
1518 AC_SUBST([LLVM_CPPFLAGS])
1519 AC_SUBST([LLVM_CXXFLAGS])
1520 AC_SUBST([LLVM_LIBDIR])
1521 AC_SUBST([LLVM_LIBS])
1522 AC_SUBST([LLVM_LDFLAGS])
1523 AC_SUBST([LLVM_INCLUDEDIR])
1524 AC_SUBST([LLVM_VERSION])
1525 AC_SUBST([CLANG_RESOURCE_DIR])
1526
1527 case "x$enable_opengl$enable_gles1$enable_gles2" in
1528 x*yes*)
1529     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1530     ;;
1531 esac
1532
1533 AC_SUBST([VG_LIB_DEPS])
1534 AC_SUBST([EGL_CLIENT_APIS])
1535
1536 dnl
1537 dnl EGL Platforms configuration
1538 dnl
1539 AC_ARG_WITH([egl-platforms],
1540     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1541         [comma delimited native platforms libEGL supports, e.g.
1542         "x11,drm" @<:@default=auto@:>@])],
1543     [with_egl_platforms="$withval"],
1544     [if test "x$enable_egl" = xyes; then
1545         with_egl_platforms="x11"
1546     else
1547         with_egl_platforms=""
1548     fi])
1549
1550 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1551     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1552 fi
1553
1554 # Do per-EGL platform setups and checks
1555 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1556 for plat in $egl_platforms; do
1557         case "$plat" in
1558         wayland)
1559                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1560
1561                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1562                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1563                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1564                 ;;
1565
1566         x11)
1567                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1568                 ;;
1569
1570         drm)
1571                 test "x$enable_gbm" = "xno" &&
1572                         AC_MSG_ERROR([EGL platform drm needs gbm])
1573                 test "x$have_libdrm" != xyes &&
1574                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1575                 ;;
1576
1577         android|fbdev|gdi|null)
1578                 ;;
1579
1580         *)
1581                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1582                 ;;
1583         esac
1584
1585         case "$plat$need_pci_id$have_pci_id" in
1586                 waylandyesno|drmyesno)
1587                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1588         esac
1589 done
1590
1591 # libEGL wants to default to the first platform specified in
1592 # ./configure.  parse that here.
1593 if test "x$egl_platforms" != "x"; then
1594     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1595     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1596 else
1597     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1598 fi
1599
1600 if echo "$egl_platforms" | grep -q 'x11'; then
1601     NEED_WINSYS_XLIB=yes
1602 fi
1603 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1604 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1605 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1606 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1607 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1608
1609 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1610
1611 AC_SUBST([EGL_NATIVE_PLATFORM])
1612 AC_SUBST([EGL_CFLAGS])
1613
1614 # If we don't have the X11 platform, set this define so we don't try to include
1615 # the X11 headers.
1616 if ! echo "$egl_platforms" | grep -q 'x11'; then
1617     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1618     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1619 fi
1620
1621 AC_ARG_WITH([max-width],
1622     [AS_HELP_STRING([--with-max-width=N],
1623                     [Maximum framebuffer width (4096)])],
1624     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1625      AS_IF([test "${withval}" -gt "4096"],
1626            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1627 )
1628 AC_ARG_WITH([max-height],
1629     [AS_HELP_STRING([--with-max-height=N],
1630                     [Maximum framebuffer height (4096)])],
1631     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1632      AS_IF([test "${withval}" -gt "4096"],
1633            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1634 )
1635
1636 dnl
1637 dnl Gallium LLVM
1638 dnl
1639 AC_ARG_ENABLE([gallium-llvm],
1640     [AS_HELP_STRING([--enable-gallium-llvm],
1641         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1642     [enable_gallium_llvm="$enableval"],
1643     [enable_gallium_llvm=auto])
1644
1645 AC_ARG_ENABLE([llvm-shared-libs],
1646     [AS_HELP_STRING([--enable-llvm-shared-libs],
1647         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1648     [enable_llvm_shared_libs="$enableval"],
1649     [enable_llvm_shared_libs=yes])
1650
1651 AC_ARG_WITH([llvm-prefix],
1652     [AS_HELP_STRING([--with-llvm-prefix],
1653         [Prefix for LLVM installations in non-standard locations])],
1654     [llvm_prefix="$withval"],
1655     [llvm_prefix=''])
1656
1657
1658 # Call this inside ` ` to get the return value.
1659 # $1 is the llvm-config command with arguments.
1660 strip_unwanted_llvm_flags() {
1661     # Use \> (marks the end of the word)
1662     echo `$1` | sed \
1663         -e 's/-DNDEBUG\>//g' \
1664         -e 's/-D_GNU_SOURCE\>//g' \
1665         -e 's/-pedantic\>//g' \
1666         -e 's/-Wcovered-switch-default\>//g' \
1667         -e 's/-O.\>//g' \
1668         -e 's/-g\>//g' \
1669         -e 's/-Wall\>//g' \
1670         -e 's/-Wcast-qual\>//g' \
1671         -e 's/-Woverloaded-virtual\>//g' \
1672         -e 's/-fcolor-diagnostics\>//g' \
1673         -e 's/-fdata-sections\>//g' \
1674         -e 's/-ffunction-sections\>//g' \
1675         -e 's/-fno-exceptions\>//g' \
1676         -e 's/-fomit-frame-pointer\>//g' \
1677         -e 's/-fvisibility-inlines-hidden\>//g' \
1678         -e 's/-fPIC\>//g' \
1679         -e 's/-fstack-protector-strong\>//g'
1680 }
1681
1682
1683 if test -z "$with_gallium_drivers"; then
1684     enable_gallium_llvm=no
1685 fi
1686 if test "x$enable_gallium_llvm" = xauto; then
1687     case "$host_cpu" in
1688     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1689     esac
1690 fi
1691 if test "x$enable_gallium_llvm" = xyes; then
1692     if test -n "$llvm_prefix"; then
1693         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1694     else
1695         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1696     fi
1697
1698     if test "x$LLVM_CONFIG" != xno; then
1699         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1700         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1701         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1702         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1703         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1704         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1705         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1706         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1707
1708         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1709             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1710         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1711             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1712
1713         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1714         if test -z "$LLVM_VERSION_PATCH"; then
1715             LLVM_VERSION_PATCH=0
1716         fi
1717
1718         if test -n "${LLVM_VERSION_MAJOR}"; then
1719             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1720         else
1721             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1722         fi
1723
1724         LLVM_REQUIRED_VERSION_MAJOR="3"
1725         LLVM_REQUIRED_VERSION_MINOR="3"
1726         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1727             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1728         fi
1729
1730         LLVM_COMPONENTS="engine bitwriter"
1731         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1732             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1733         fi
1734
1735         if test "x$enable_opencl" = xyes; then
1736             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1737             # LLVM 3.3 >= 177971 requires IRReader
1738             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1739                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1740             fi
1741             # LLVM 3.4 requires Option
1742             if $LLVM_CONFIG --components | grep -qw 'option'; then
1743                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1744             fi
1745             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1746             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1747                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1748             fi
1749             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1750                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1751             fi
1752         fi
1753         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1754         MESA_LLVM=1
1755
1756         dnl Check for Clang internal headers
1757         if test "x$enable_opencl" = xyes; then
1758             if test -z "$CLANG_LIBDIR"; then
1759                 CLANG_LIBDIR=${LLVM_LIBDIR}
1760             fi
1761             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1762             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1763                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1764         fi
1765     else
1766         MESA_LLVM=0
1767         LLVM_VERSION_INT=0
1768     fi
1769 else
1770     MESA_LLVM=0
1771     LLVM_VERSION_INT=0
1772
1773     if test "x$enable_opencl" = xyes; then
1774         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1775     fi
1776 fi
1777
1778 dnl Directory for XVMC libs
1779 AC_ARG_WITH([xvmc-libdir],
1780     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1781         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1782     [XVMC_LIB_INSTALL_DIR="$withval"],
1783     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1784 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1785
1786 dnl
1787 dnl Gallium Tests
1788 dnl
1789 if test "x$enable_gallium_tests" = xyes; then
1790     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1791     enable_gallium_loader=yes
1792 fi
1793 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1794
1795 dnl Directory for VDPAU libs
1796 AC_ARG_WITH([vdpau-libdir],
1797     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1798         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1799     [VDPAU_LIB_INSTALL_DIR="$withval"],
1800     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1801 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1802
1803 dnl Directory for OMX libs
1804
1805 AC_ARG_WITH([omx-libdir],
1806     [AS_HELP_STRING([--with-omx-libdir=DIR],
1807         [directory for the OMX libraries])],
1808     [OMX_LIB_INSTALL_DIR="$withval"],
1809     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1810 AC_SUBST([OMX_LIB_INSTALL_DIR])
1811
1812 dnl Directory for VA libs
1813
1814 AC_ARG_WITH([va-libdir],
1815     [AS_HELP_STRING([--with-va-libdir=DIR],
1816         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1817     [VA_LIB_INSTALL_DIR="$withval"],
1818     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1819 AC_SUBST([VA_LIB_INSTALL_DIR])
1820
1821 dnl
1822 dnl Gallium helper functions
1823 dnl
1824 gallium_require_drm() {
1825     if test "x$have_libdrm" != xyes; then
1826        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1827     fi
1828 }
1829
1830 gallium_require_llvm() {
1831     if test "x$MESA_LLVM" = x0; then
1832         case "$host" in *gnux32) return;; esac
1833         case "$host_cpu" in
1834         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1835         esac
1836     fi
1837 }
1838
1839 gallium_require_drm_loader() {
1840     if test "x$enable_gallium_loader" = xyes; then
1841         if test "x$need_pci_id$have_pci_id" = xyesno; then
1842             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1843         fi
1844         enable_gallium_drm_loader=yes
1845     fi
1846     if test "x$enable_va" = xyes && test "x$7" != x; then
1847          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1848     fi
1849 }
1850
1851 require_egl_drm() {
1852     case "$with_egl_platforms" in
1853         *drm*)
1854             ;;
1855          *)
1856             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1857             ;;
1858     esac
1859     if test "x$enable_gbm" != xyes; then
1860             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1861     fi
1862 }
1863
1864 radeon_llvm_check() {
1865     if test "x$enable_gallium_llvm" != "xyes"; then
1866         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1867     fi
1868     LLVM_REQUIRED_VERSION_MAJOR="3"
1869     LLVM_REQUIRED_VERSION_MINOR="4"
1870     LLVM_REQUIRED_VERSION_PATCH="2"
1871     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1872         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1873     fi
1874     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1875         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1876                       sources with the --enable-experimental-targets=R600
1877                       configure flag])
1878     fi
1879     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1880     NEED_RADEON_LLVM=yes
1881     if test "x$have_libelf" != xyes; then
1882        AC_MSG_ERROR([$1 requires libelf when using llvm])
1883     fi
1884 }
1885
1886 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1887 if test -n "$with_gallium_drivers"; then
1888     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1889     for driver in $gallium_drivers; do
1890         case "x$driver" in
1891         xsvga)
1892             HAVE_GALLIUM_SVGA=yes
1893             gallium_require_drm "svga"
1894             gallium_require_drm_loader
1895             ;;
1896         xi915)
1897             HAVE_GALLIUM_I915=yes
1898             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1899             gallium_require_drm "Gallium i915"
1900             gallium_require_drm_loader
1901             ;;
1902         xilo)
1903             HAVE_GALLIUM_ILO=yes
1904             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1905             gallium_require_drm "Gallium i965/ilo"
1906             gallium_require_drm_loader
1907             ;;
1908         xr300)
1909             HAVE_GALLIUM_R300=yes
1910             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1911             gallium_require_drm "Gallium R300"
1912             gallium_require_drm_loader
1913             gallium_require_llvm "Gallium R300"
1914             ;;
1915         xr600)
1916             HAVE_GALLIUM_R600=yes
1917             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1918             gallium_require_drm "Gallium R600"
1919             gallium_require_drm_loader
1920             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1921                 radeon_llvm_check "r600g"
1922                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1923             fi
1924             if test "x$enable_r600_llvm" = xyes; then
1925                 USE_R600_LLVM_COMPILER=yes;
1926             fi
1927             if test "x$enable_opencl" = xyes; then
1928                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1929             fi
1930             ;;
1931         xradeonsi)
1932             HAVE_GALLIUM_RADEONSI=yes
1933             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1934             gallium_require_drm "radeonsi"
1935             gallium_require_drm_loader
1936             radeon_llvm_check "radeonsi"
1937             require_egl_drm "radeonsi"
1938             ;;
1939         xnouveau)
1940             HAVE_GALLIUM_NOUVEAU=yes
1941             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1942             gallium_require_drm "nouveau"
1943             gallium_require_drm_loader
1944             ;;
1945         xfreedreno)
1946             HAVE_GALLIUM_FREEDRENO=yes
1947             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1948             gallium_require_drm "freedreno"
1949             gallium_require_drm_loader
1950             ;;
1951         xswrast)
1952             HAVE_GALLIUM_SOFTPIPE=yes
1953             if test "x$MESA_LLVM" = x1; then
1954                 HAVE_GALLIUM_LLVMPIPE=yes
1955             fi
1956             ;;
1957         xvc4)
1958             HAVE_GALLIUM_VC4=yes
1959             gallium_require_drm "vc4"
1960             gallium_require_drm_loader
1961
1962             case "$host_cpu" in
1963                 i?86 | x86_64 | amd64)
1964                 USE_VC4_SIMULATOR=yes
1965                 ;;
1966             esac
1967             ;;
1968         *)
1969             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1970             ;;
1971         esac
1972     done
1973 fi
1974
1975 dnl Set LLVM_LIBS - This is done after the driver configuration so
1976 dnl that drivers can add additional components to LLVM_COMPONENTS.
1977 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1978 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1979 dnl this was causing the same libraries to be appear multiple times
1980 dnl in LLVM_LIBS.
1981
1982 if test "x$MESA_LLVM" != x0; then
1983
1984     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1985
1986     if test "x$enable_llvm_shared_libs" = xyes; then
1987         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1988         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1989         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1990
1991         if test "x$llvm_have_one_so" = xyes; then
1992             dnl LLVM was built using auto*, so there is only one shared object.
1993             LLVM_LIBS="-l$LLVM_SO_NAME"
1994         else
1995             dnl If LLVM was built with CMake, there will be one shared object per
1996             dnl component.
1997             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1998                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1999         Please make sure you have built llvm with the --enable-shared option
2000         and that your llvm libraries are installed in $LLVM_LIBDIR
2001         If you have installed your llvm libraries to a different directory you
2002         can use the --with-llvm-prefix= configure flag to specify this directory.
2003         NOTE: Mesa is attempting to use llvm shared libraries by default.
2004         If you do not want to build with llvm shared libraries and instead want to
2005         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2006         invocation and rebuild.])])
2007
2008            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2009            dnl install uses a shared object for each component and we have
2010            dnl already added all of these objects to LLVM_LIBS.
2011         fi
2012     else
2013         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2014         dnl We need to link to llvm system libs when using static libs
2015         dnl However, only llvm 3.5+ provides --system-libs
2016         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2017             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2018         fi
2019     fi
2020 fi
2021
2022 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2023 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2024 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2025 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2026 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2027 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2028 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2029                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2030 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2031 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2032 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2033 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2034 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2035
2036 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2037
2038 # NOTE: anything using xcb or other client side libs ends up in separate
2039 #       _CLIENT variables.  The pipe loader is built in two variants,
2040 #       one that is standalone and does not link any x client libs (for
2041 #       use by XA tracker in particular, but could be used in any case
2042 #       where communication with xserver is not desired).
2043 if test "x$enable_gallium_loader" = xyes; then
2044     if test "x$NEED_WINSYS_XLIB" = xyes; then
2045         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2046     fi
2047
2048     if test "x$enable_dri" = xyes; then
2049         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2050     fi
2051
2052     if test "x$enable_gallium_drm_loader" = xyes; then
2053         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2054         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2055                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2056         if test "x$pipe_loader_have_xcb" = xyes; then
2057             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2058             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2059         fi
2060     fi
2061
2062     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2063     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2064
2065     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2066     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2067     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2068     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2069 fi
2070
2071 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2072 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2073 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2074 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2075 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2076 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2077
2078 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2079                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2080                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2081 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2082 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2083 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2084 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2085 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2086 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2087 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2088 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2089 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2090     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2091 fi
2092
2093 AC_SUBST([ELF_LIB])
2094
2095 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2096 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2097 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2098 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2099 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2100
2101 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2102 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2103 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2104
2105 AC_SUBST([VDPAU_MAJOR], 1)
2106 AC_SUBST([VDPAU_MINOR], 0)
2107
2108 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2109 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2110 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2111 AC_SUBST([VA_MINOR], $VA_MINOR)
2112
2113 AC_SUBST([XVMC_MAJOR], 1)
2114 AC_SUBST([XVMC_MINOR], 0)
2115
2116 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2117 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2118 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2119 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2120
2121 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2122 AC_SUBST([XA_MINOR], $XA_MINOR)
2123 AC_SUBST([XA_TINY], $XA_TINY)
2124 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2125
2126 dnl Restore LDFLAGS and CPPFLAGS
2127 LDFLAGS="$_SAVE_LDFLAGS"
2128 CPPFLAGS="$_SAVE_CPPFLAGS"
2129
2130 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2131 if test "x$acv_mesa_CLANG" = xyes; then
2132     CFLAGS="$CFLAGS -Qunused-arguments"
2133     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2134 fi
2135
2136 dnl Add user CFLAGS and CXXFLAGS
2137 CFLAGS="$CFLAGS $USER_CFLAGS"
2138 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2139
2140 dnl Substitute the config
2141 AC_CONFIG_FILES([Makefile
2142                 src/Makefile
2143                 src/egl/drivers/dri2/Makefile
2144                 src/egl/main/Makefile
2145                 src/egl/main/egl.pc
2146                 src/egl/wayland/Makefile
2147                 src/egl/wayland/wayland-drm/Makefile
2148                 src/egl/wayland/wayland-egl/Makefile
2149                 src/egl/wayland/wayland-egl/wayland-egl.pc
2150                 src/gallium/Makefile
2151                 src/gallium/auxiliary/Makefile
2152                 src/gallium/auxiliary/pipe-loader/Makefile
2153                 src/gallium/drivers/freedreno/Makefile
2154                 src/gallium/drivers/galahad/Makefile
2155                 src/gallium/drivers/i915/Makefile
2156                 src/gallium/drivers/identity/Makefile
2157                 src/gallium/drivers/ilo/Makefile
2158                 src/gallium/drivers/llvmpipe/Makefile
2159                 src/gallium/drivers/noop/Makefile
2160                 src/gallium/drivers/nouveau/Makefile
2161                 src/gallium/drivers/r300/Makefile
2162                 src/gallium/drivers/r600/Makefile
2163                 src/gallium/drivers/radeon/Makefile
2164                 src/gallium/drivers/radeonsi/Makefile
2165                 src/gallium/drivers/rbug/Makefile
2166                 src/gallium/drivers/softpipe/Makefile
2167                 src/gallium/drivers/svga/Makefile
2168                 src/gallium/drivers/trace/Makefile
2169                 src/gallium/drivers/vc4/Makefile
2170                 src/gallium/drivers/vc4/kernel/Makefile
2171                 src/gallium/state_trackers/clover/Makefile
2172                 src/gallium/state_trackers/dri/Makefile
2173                 src/gallium/state_trackers/egl/Makefile
2174                 src/gallium/state_trackers/gbm/Makefile
2175                 src/gallium/state_trackers/glx/xlib/Makefile
2176                 src/gallium/state_trackers/omx/Makefile
2177                 src/gallium/state_trackers/osmesa/Makefile
2178                 src/gallium/state_trackers/va/Makefile
2179                 src/gallium/state_trackers/vdpau/Makefile
2180                 src/gallium/state_trackers/vega/Makefile
2181                 src/gallium/state_trackers/xa/Makefile
2182                 src/gallium/state_trackers/xvmc/Makefile
2183                 src/gallium/targets/dri/Makefile
2184                 src/gallium/targets/egl-static/Makefile
2185                 src/gallium/targets/gbm/Makefile
2186                 src/gallium/targets/libgl-xlib/Makefile
2187                 src/gallium/targets/omx/Makefile
2188                 src/gallium/targets/opencl/Makefile
2189                 src/gallium/targets/osmesa/Makefile
2190                 src/gallium/targets/osmesa/osmesa.pc
2191                 src/gallium/targets/pipe-loader/Makefile
2192                 src/gallium/targets/va/Makefile
2193                 src/gallium/targets/vdpau/Makefile
2194                 src/gallium/targets/xa/Makefile
2195                 src/gallium/targets/xa/xatracker.pc
2196                 src/gallium/targets/xvmc/Makefile
2197                 src/gallium/tests/trivial/Makefile
2198                 src/gallium/tests/unit/Makefile
2199                 src/gallium/winsys/freedreno/drm/Makefile
2200                 src/gallium/winsys/i915/drm/Makefile
2201                 src/gallium/winsys/intel/drm/Makefile
2202                 src/gallium/winsys/nouveau/drm/Makefile
2203                 src/gallium/winsys/radeon/drm/Makefile
2204                 src/gallium/winsys/svga/drm/Makefile
2205                 src/gallium/winsys/sw/dri/Makefile
2206                 src/gallium/winsys/sw/fbdev/Makefile
2207                 src/gallium/winsys/sw/kms-dri/Makefile
2208                 src/gallium/winsys/sw/null/Makefile
2209                 src/gallium/winsys/sw/wayland/Makefile
2210                 src/gallium/winsys/sw/wrapper/Makefile
2211                 src/gallium/winsys/sw/xlib/Makefile
2212                 src/gallium/winsys/vc4/drm/Makefile
2213                 src/gbm/Makefile
2214                 src/gbm/main/gbm.pc
2215                 src/glsl/Makefile
2216                 src/glx/Makefile
2217                 src/glx/apple/Makefile
2218                 src/glx/tests/Makefile
2219                 src/gtest/Makefile
2220                 src/loader/Makefile
2221                 src/mapi/Makefile
2222                 src/mapi/es1api/glesv1_cm.pc
2223                 src/mapi/es2api/glesv2.pc
2224                 src/mapi/glapi/gen/Makefile
2225                 src/mapi/vgapi/Makefile
2226                 src/mapi/vgapi/vg.pc
2227                 src/mesa/Makefile
2228                 src/mesa/gl.pc
2229                 src/mesa/drivers/dri/dri.pc
2230                 src/mesa/drivers/dri/common/Makefile
2231                 src/mesa/drivers/dri/common/xmlpool/Makefile
2232                 src/mesa/drivers/dri/i915/Makefile
2233                 src/mesa/drivers/dri/i965/Makefile
2234                 src/mesa/drivers/dri/Makefile
2235                 src/mesa/drivers/dri/nouveau/Makefile
2236                 src/mesa/drivers/dri/r200/Makefile
2237                 src/mesa/drivers/dri/radeon/Makefile
2238                 src/mesa/drivers/dri/swrast/Makefile
2239                 src/mesa/drivers/osmesa/Makefile
2240                 src/mesa/drivers/osmesa/osmesa.pc
2241                 src/mesa/drivers/x11/Makefile
2242                 src/mesa/main/tests/Makefile
2243                 src/util/Makefile
2244                 src/util/tests/hash_table/Makefile])
2245
2246 AC_OUTPUT
2247
2248 dnl
2249 dnl Output some configuration info for the user
2250 dnl
2251 echo ""
2252 echo "        prefix:          $prefix"
2253 echo "        exec_prefix:     $exec_prefix"
2254 echo "        libdir:          $libdir"
2255 echo "        includedir:      $includedir"
2256
2257 dnl API info
2258 echo ""
2259 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2260 echo "        OpenVG:          $enable_openvg"
2261
2262 dnl Driver info
2263 echo ""
2264 case "x$enable_osmesa$enable_gallium_osmesa" in
2265 xnoyes)
2266         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2267         ;;
2268 xyesno)
2269         echo "        OSMesa:          lib$OSMESA_LIB"
2270         ;;
2271 xnono)
2272         echo "        OSMesa:          no"
2273         ;;
2274 esac
2275
2276 echo ""
2277 if test "x$enable_dri" != xno; then
2278         echo "        DRI platform:    $dri_platform"
2279         if test -z "$DRI_DIRS"; then
2280             echo "        DRI drivers:     no"
2281         else
2282             echo "        DRI drivers:     $DRI_DIRS"
2283         fi
2284         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2285 fi
2286
2287 case "x$enable_glx$enable_xlib_glx" in
2288 xyesyes)
2289     echo "        GLX:             Xlib-based"
2290     ;;
2291 xyesno)
2292     echo "        GLX:             DRI-based"
2293     ;;
2294 *)
2295     echo "        GLX:             $enable_glx"
2296     ;;
2297 esac
2298
2299 dnl EGL
2300 echo ""
2301 echo "        EGL:             $enable_egl"
2302 if test "$enable_egl" = yes; then
2303     echo "        EGL platforms:   $egl_platforms"
2304
2305     egl_drivers=""
2306     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2307         egl_drivers="$egl_drivers builtin:egl_dri2"
2308     fi
2309
2310     if test "x$enable_gallium_egl" = xyes; then
2311         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2312         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2313     else
2314         echo "        EGL drivers:    $egl_drivers"
2315     fi
2316 fi
2317
2318 echo ""
2319 if test "x$MESA_LLVM" = x1; then
2320     echo "        llvm:            yes"
2321     echo "        llvm-config:     $LLVM_CONFIG"
2322     echo "        llvm-version:    $LLVM_VERSION"
2323 else
2324     echo "        llvm:            no"
2325 fi
2326
2327 echo ""
2328 if test -n "$with_gallium_drivers"; then
2329     echo "        Gallium:         yes"
2330 else
2331     echo "        Gallium:         no"
2332 fi
2333
2334
2335 dnl Libraries
2336 echo ""
2337 echo "        Shared libs:     $enable_shared"
2338 echo "        Static libs:     $enable_static"
2339 echo "        Shared-glapi:    $enable_shared_glapi"
2340
2341 dnl Compiler options
2342 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2343 cflags=`echo $CFLAGS | \
2344     $SED 's/^ *//;s/  */ /;s/ *$//'`
2345 cxxflags=`echo $CXXFLAGS | \
2346     $SED 's/^ *//;s/  */ /;s/ *$//'`
2347 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2348 echo ""
2349 echo "        CFLAGS:          $cflags"
2350 echo "        CXXFLAGS:        $cxxflags"
2351 echo "        Macros:          $defines"
2352 echo ""
2353 if test "x$MESA_LLVM" = x1; then
2354     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2355     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2356     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2357     echo ""
2358 fi
2359 echo "        PYTHON2:         $PYTHON2"
2360
2361 echo ""
2362 echo "        Run '${MAKE-make}' to build Mesa"
2363 echo ""