configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.2.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  24     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  25
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27
  28 dnl Set internal versions
  29 OSMESA_VERSION=8
  30 AC_SUBST([OSMESA_VERSION])
  31
  32 dnl Versions for external dependencies
  33 LIBDRM_REQUIRED=2.4.24
  34 LIBDRM_RADEON_REQUIRED=2.4.42
  35 LIBDRM_INTEL_REQUIRED=2.4.38
  36 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  37 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  38 DRI2PROTO_REQUIRED=2.6
  39 GLPROTO_REQUIRED=1.4.14
  40 LIBDRM_XORG_REQUIRED=2.4.24
  41 LIBKMS_XORG_REQUIRED=1.0.0
  42
  43 dnl Check for progs
  44 AC_PROG_CPP
  45 AC_PROG_CC
  46 AX_PROG_CC_FOR_BUILD
  47 AC_PROG_CXX
  48 AX_PROG_CXX_FOR_BUILD
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AX_PYTHON_MODULE([libxml2], [needed])
  54 AC_PROG_SED
  55 AC_PROG_MKDIR_P
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 103     AC_MSG_CHECKING([whether gcc version is sufficient])
 104     major=0
 105     minor=0
 106
 107     GCC_VERSION=`$CC -dumpversion`
 108     if test $? -eq 0; then
 109         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 110         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 111     fi
 112
 113     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 114         AC_MSG_RESULT([no])
 115         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 116     else
 117         AC_MSG_RESULT([yes])
 118     fi
 119 fi
 120
 121 dnl Make sure the pkg-config macros are defined
 122 m4_ifndef([PKG_PROG_PKG_CONFIG],
 123     [m4_fatal([Could not locate the pkg-config autoconf macros.
 124   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 125   are in a different location, try setting the environment variable
 126   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 127 PKG_PROG_PKG_CONFIG()
 128
 129 dnl LIB_DIR - library basename
 130 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 131 AC_SUBST([LIB_DIR])
 132
 133 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 134 _SAVE_LDFLAGS="$LDFLAGS"
 135 _SAVE_CPPFLAGS="$CPPFLAGS"
 136
 137 dnl build host compiler macros
 138 DEFINES_FOR_BUILD=""
 139 AC_SUBST([DEFINES_FOR_BUILD])
 140 case "$build_os" in
 141 linux*|*-gnu*|gnu*)
 142     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 143     ;;
 144 solaris*)
 145     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 146     ;;
 147 cygwin*)
 148     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 149     ;;
 150 esac
 151
 152 dnl Compiler macros
 153 DEFINES=""
 154 AC_SUBST([DEFINES])
 155 case "$host_os" in
 156 linux*|*-gnu*|gnu*)
 157     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 158     ;;
 159 solaris*)
 160     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 161     ;;
 162 cygwin*)
 163     DEFINES="$DEFINES -DHAVE_PTHREAD"
 164     ;;
 165 esac
 166
 167 dnl Add flags for gcc and g++
 168 if test "x$GCC" = xyes; then
 169     case "$host_os" in
 170     cygwin*)
 171         CFLAGS="$CFLAGS -Wall -std=gnu99"
 172         ;;
 173     *)
 174         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 175         CFLAGS="$CFLAGS -Wall -std=c99"
 176         ;;
 177     esac
 178
 179     # Enable -Werror=implicit-function-declaration and
 180     # -Werror=missing-prototypes, if available, or otherwise, just
 181     # -Wmissing-prototypes.  This is particularly useful to avoid
 182     # generating a loadable driver module that has undefined symbols.
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 185     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 186     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 188                    AC_MSG_RESULT([yes]),
 189                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 190                     AC_MSG_RESULT([no])]);
 191
 192     # Enable -fvisibility=hidden if using a gcc that supports it
 193     save_CFLAGS="$CFLAGS"
 194     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 195     VISIBILITY_CFLAGS="-fvisibility=hidden"
 196     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 197     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 198                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 199
 200     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 201     CFLAGS=$save_CFLAGS
 202
 203     # Work around aliasing bugs - developers should comment this out
 204     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 205     CFLAGS="$CFLAGS -fno-strict-aliasing"
 206
 207     # gcc's builtin memcmp is slower than glibc's
 208     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 209     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 210     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 211 fi
 212 if test "x$GXX" = xyes; then
 213     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 231     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 232
 233     # gcc's builtin memcmp is slower than glibc's
 234     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 235     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 236     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 237 fi
 238
 239 dnl even if the compiler appears to support it, using visibility attributes isn't
 240 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 241 case "$host_os" in
 242 cygwin*)
 243     VISIBILITY_CFLAGS=""
 244     VISIBILITY_CXXFLAGS=""
 245     ;;
 246 esac
 247
 248 AC_SUBST([VISIBILITY_CFLAGS])
 249 AC_SUBST([VISIBILITY_CXXFLAGS])
 250
 251 dnl
 252 dnl Hacks to enable 32 or 64 bit build
 253 dnl
 254 AC_ARG_ENABLE([32-bit],
 255     [AS_HELP_STRING([--enable-32-bit],
 256         [build 32-bit libraries @<:@default=auto@:>@])],
 257     [enable_32bit="$enableval"],
 258     [enable_32bit=auto]
 259 )
 260 if test "x$enable_32bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m32"
 263         CCASFLAGS="$CCASFLAGS -m32"
 264     fi
 265     if test "x$GXX" = xyes; then
 266         CXXFLAGS="$CXXFLAGS -m32"
 267     fi
 268 fi
 269 AC_ARG_ENABLE([64-bit],
 270     [AS_HELP_STRING([--enable-64-bit],
 271         [build 64-bit libraries @<:@default=auto@:>@])],
 272     [enable_64bit="$enableval"],
 273     [enable_64bit=auto]
 274 )
 275 if test "x$enable_64bit" = xyes; then
 276     if test "x$GCC" = xyes; then
 277         CFLAGS="$CFLAGS -m64"
 278     fi
 279     if test "x$GXX" = xyes; then
 280         CXXFLAGS="$CXXFLAGS -m64"
 281     fi
 282 fi
 283
 284 dnl Can't have static and shared libraries, default to static if user
 285 dnl explicitly requested. If both disabled, set to static since shared
 286 dnl was explicitly requested.
 287 case "x$enable_static$enable_shared" in
 288 xyesyes )
 289     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 290     enable_shared=no
 291     ;;
 292 xnono )
 293     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 294     enable_static=yes
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 299
 300 dnl
 301 dnl other compiler options
 302 dnl
 303 AC_ARG_ENABLE([debug],
 304     [AS_HELP_STRING([--enable-debug],
 305         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 306     [enable_debug="$enableval"],
 307     [enable_debug=no]
 308 )
 309 if test "x$enable_debug" = xyes; then
 310     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 311     if test "x$GCC_FOR_BUILD" = xyes; then
 312         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 313     fi
 314     if test "x$GXX_FOR_BUILD" = xyes; then
 315         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 316     fi
 317
 318     DEFINES="$DEFINES -DDEBUG"
 319     if test "x$GCC" = xyes; then
 320         CFLAGS="$CFLAGS -g -O0"
 321     fi
 322     if test "x$GXX" = xyes; then
 323         CXXFLAGS="$CXXFLAGS -g -O0"
 324     fi
 325 fi
 326
 327 dnl
 328 dnl library names
 329 dnl
 330 LIB_PREFIX_GLOB='lib'
 331 LIB_VERSION_SEPARATOR='.'
 332 if test "$enable_static" = yes; then
 333     LIB_EXTENSION='a'
 334 else
 335     case "$host_os" in
 336     darwin* )
 337         LIB_EXTENSION='dylib' ;;
 338     cygwin* )
 339         dnl prefix can be 'cyg' or 'lib'
 340         LIB_PREFIX_GLOB='???'
 341         LIB_VERSION_SEPARATOR='-'
 342         LIB_EXTENSION='dll' ;;
 343     aix* )
 344         LIB_EXTENSION='a' ;;
 345     * )
 346         LIB_EXTENSION='so' ;;
 347     esac
 348 fi
 349 AC_ARG_WITH([gl-lib-name],
 350   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 351     [specify GL library name @<:@default=GL@:>@])],
 352   [GL_LIB=$withval],
 353   [GL_LIB=GL])
 354 AC_ARG_WITH([osmesa-lib-name],
 355   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 356     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 357   [OSMESA_LIB=$withval],
 358   [OSMESA_LIB=OSMesa])
 359 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 360 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 361
 362 dnl
 363 dnl Mangled Mesa support
 364 dnl
 365 AC_ARG_ENABLE([mangling],
 366   [AS_HELP_STRING([--enable-mangling],
 367     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 368   [enable_mangling="${enableval}"],
 369   [enable_mangling=no]
 370 )
 371 if test "x${enable_mangling}" = "xyes" ; then
 372   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 373   GL_LIB="Mangled${GL_LIB}"
 374   OSMESA_LIB="Mangled${OSMESA_LIB}"
 375 fi
 376 AC_SUBST([GL_LIB])
 377 AC_SUBST([OSMESA_LIB])
 378
 379 dnl
 380 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 381 dnl
 382 AC_ARG_ENABLE([texture-float],
 383     [AS_HELP_STRING([--enable-texture-float],
 384         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 385     [enable_texture_float="$enableval"],
 386     [enable_texture_float=no]
 387 )
 388 if test "x$enable_texture_float" = xyes; then
 389     AC_MSG_WARN([Floating-point textures enabled.])
 390     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 391     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 392 fi
 393
 394 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 395 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 396 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 397 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 398 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 399 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 400 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 401
 402 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409
 410 AC_SUBST([GL_LIB_NAME])
 411 AC_SUBST([OSMESA_LIB_NAME])
 412 AC_SUBST([EGL_LIB_NAME])
 413 AC_SUBST([GLESv1_CM_LIB_NAME])
 414 AC_SUBST([GLESv2_LIB_NAME])
 415 AC_SUBST([VG_LIB_NAME])
 416 AC_SUBST([GLAPI_LIB_NAME])
 417
 418 AC_SUBST([GL_LIB_GLOB])
 419 AC_SUBST([EGL_LIB_GLOB])
 420 AC_SUBST([GLESv1_CM_LIB_GLOB])
 421 AC_SUBST([GLESv2_LIB_GLOB])
 422 AC_SUBST([VG_LIB_GLOB])
 423 AC_SUBST([GLAPI_LIB_GLOB])
 424
 425 dnl
 426 dnl Arch/platform-specific settings
 427 dnl
 428 AC_ARG_ENABLE([asm],
 429     [AS_HELP_STRING([--disable-asm],
 430         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 431     [enable_asm="$enableval"],
 432     [enable_asm=yes]
 433 )
 434 asm_arch=""
 435 MESA_ASM_FILES=""
 436 AC_MSG_CHECKING([whether to enable assembly])
 437 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 438 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 439 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 440     case "$host_cpu" in
 441     i?86 | x86_64)
 442         enable_asm=no
 443         AC_MSG_RESULT([no, cross compiling])
 444         ;;
 445     esac
 446 fi
 447 # check for supported arches
 448 if test "x$enable_asm" = xyes; then
 449     case "$host_cpu" in
 450     i?86)
 451         case "$host_os" in
 452         linux* | *freebsd* | dragonfly* | *netbsd*)
 453             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 454             ;;
 455         esac
 456         ;;
 457     x86_64)
 458         case "$host_os" in
 459         linux* | *freebsd* | dragonfly* | *netbsd*)
 460             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 461             ;;
 462         esac
 463         ;;
 464     sparc*)
 465         case "$host_os" in
 466         linux*)
 467             asm_arch=sparc
 468             ;;
 469         esac
 470         ;;
 471     esac
 472
 473     case "$asm_arch" in
 474     x86)
 475         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 476         MESA_ASM_FILES='$(X86_FILES)'
 477         AC_MSG_RESULT([yes, x86])
 478         ;;
 479     x86_64)
 480         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 481         MESA_ASM_FILES='$(X86_64_FILES)'
 482         AC_MSG_RESULT([yes, x86_64])
 483         ;;
 484     sparc)
 485         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 486         MESA_ASM_FILES='$(SPARC_FILES)'
 487         AC_MSG_RESULT([yes, sparc])
 488         ;;
 489     *)
 490         AC_MSG_RESULT([no, platform not supported])
 491         ;;
 492     esac
 493 fi
 494 AC_SUBST([MESA_ASM_FILES])
 495
 496 dnl Check to see if dlopen is in default libraries (like Solaris, which
 497 dnl has it in libc), or if libdl is needed to get it.
 498 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 499     [AC_CHECK_LIB([dl], [dlopen],
 500        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 501 AC_SUBST([DLOPEN_LIBS])
 502
 503 case "$host_os" in
 504 darwin*|mingw*)
 505     ;;
 506 *)
 507     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 508                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 509                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 510     AC_SUBST([CLOCK_LIB])
 511     ;;
 512 esac
 513
 514 dnl See if posix_memalign is available
 515 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 516
 517 dnl Check for pthreads
 518 AX_PTHREAD
 519 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 520 dnl to -pthread, which causes problems if we need -lpthread to appear in
 521 dnl pkgconfig files.
 522 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 523
 524 dnl SELinux awareness.
 525 AC_ARG_ENABLE([selinux],
 526     [AS_HELP_STRING([--enable-selinux],
 527         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 528     [MESA_SELINUX="$enableval"],
 529     [MESA_SELINUX=no])
 530 if test "x$enable_selinux" = "xyes"; then
 531     AC_CHECK_HEADER([selinux/selinux.h],[],
 532                     [AC_MSG_ERROR([SELinux headers not found])])
 533     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 534                  [AC_MSG_ERROR([SELinux library not found])])
 535     SELINUX_LIBS="-lselinux"
 536     DEFINES="$DEFINES -DMESA_SELINUX"
 537 fi
 538 AC_SUBST([SELINUX_LIBS])
 539
 540 dnl Options for APIs
 541 AC_ARG_ENABLE([opengl],
 542     [AS_HELP_STRING([--disable-opengl],
 543         [disable support for standard OpenGL API @<:@default=no@:>@])],
 544     [enable_opengl="$enableval"],
 545     [enable_opengl=yes])
 546 AC_ARG_ENABLE([gles1],
 547     [AS_HELP_STRING([--enable-gles1],
 548         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 549     [enable_gles1="$enableval"],
 550     [enable_gles1=no])
 551 AC_ARG_ENABLE([gles2],
 552     [AS_HELP_STRING([--enable-gles2],
 553         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 554     [enable_gles2="$enableval"],
 555     [enable_gles2=no])
 556 AC_ARG_ENABLE([openvg],
 557     [AS_HELP_STRING([--enable-openvg],
 558         [enable support for OpenVG API @<:@default=no@:>@])],
 559     [enable_openvg="$enableval"],
 560     [enable_openvg=no])
 561
 562 AC_ARG_ENABLE([dri],
 563     [AS_HELP_STRING([--enable-dri],
 564         [enable DRI modules @<:@default=enabled@:>@])],
 565     [enable_dri="$enableval"],
 566     [enable_dri=yes])
 567 AC_ARG_ENABLE([glx],
 568     [AS_HELP_STRING([--enable-glx],
 569         [enable GLX library @<:@default=enabled@:>@])],
 570     [enable_glx="$enableval"],
 571     [enable_glx=yes])
 572 AC_ARG_ENABLE([osmesa],
 573     [AS_HELP_STRING([--enable-osmesa],
 574         [enable OSMesa library @<:@default=disabled@:>@])],
 575     [enable_osmesa="$enableval"],
 576     [enable_osmesa=no])
 577 AC_ARG_ENABLE([egl],
 578     [AS_HELP_STRING([--disable-egl],
 579         [disable EGL library @<:@default=enabled@:>@])],
 580     [enable_egl="$enableval"],
 581     [enable_egl=yes])
 582
 583 AC_ARG_ENABLE([xorg],
 584     [AS_HELP_STRING([--enable-xorg],
 585         [enable support for X.Org DDX API @<:@default=no@:>@])],
 586     [enable_xorg="$enableval"],
 587     [enable_xorg=no])
 588 AC_ARG_ENABLE([xa],
 589     [AS_HELP_STRING([--enable-xa],
 590         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 591     [enable_xa="$enableval"],
 592     [enable_xa=no])
 593 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 594 enable_d3d1x=no
 595 dnl AC_ARG_ENABLE([d3d1x],
 596 dnl     [AS_HELP_STRING([--enable-d3d1x],
 597 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 598 dnl     [enable_d3d1x="$enableval"],
 599 dnl     [enable_d3d1x=no])
 600 AC_ARG_ENABLE([gbm],
 601    [AS_HELP_STRING([--enable-gbm],
 602          [enable gbm library @<:@default=auto@:>@])],
 603    [enable_gbm="$enableval"],
 604    [enable_gbm=auto])
 605
 606 AC_ARG_ENABLE([xvmc],
 607    [AS_HELP_STRING([--enable-xvmc],
 608          [enable xvmc library @<:@default=auto@:>@])],
 609    [enable_xvmc="$enableval"],
 610    [enable_xvmc=auto])
 611 AC_ARG_ENABLE([vdpau],
 612    [AS_HELP_STRING([--enable-vdpau],
 613          [enable vdpau library @<:@default=auto@:>@])],
 614    [enable_vdpau="$enableval"],
 615    [enable_vdpau=auto])
 616 AC_ARG_ENABLE([opencl],
 617    [AS_HELP_STRING([--enable-opencl],
 618          [enable OpenCL library NOTE: Enabling this option will also enable
 619           --with-llvm-shared-libs
 620           @<:@default=no@:>@])],
 621    [],
 622    [enable_opencl=no])
 623 AC_ARG_ENABLE([xlib_glx],
 624     [AS_HELP_STRING([--enable-xlib-glx],
 625         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 626     [enable_xlib_glx="$enableval"],
 627     [enable_xlib_glx=no])
 628 AC_ARG_ENABLE([gallium_egl],
 629     [AS_HELP_STRING([--enable-gallium-egl],
 630         [enable optional EGL state tracker (not required
 631          for EGL support in Gallium with OpenGL and OpenGL ES)
 632          @<:@default=disable@:>@])],
 633     [enable_gallium_egl="$enableval"],
 634     [enable_gallium_egl=no])
 635 AC_ARG_ENABLE([gallium_gbm],
 636     [AS_HELP_STRING([--enable-gallium-gbm],
 637         [enable optional gbm state tracker (not required for
 638          gbm support in Gallium)
 639          @<:@default=auto@:>@])],
 640     [enable_gallium_gbm="$enableval"],
 641     [enable_gallium_gbm=auto])
 642
 643 AC_ARG_ENABLE([r600-llvm-compiler],
 644     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 645         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 646     [enable_r600_llvm="$enableval"],
 647     [enable_r600_llvm=no])
 648
 649 AC_ARG_ENABLE([gallium_tests],
 650     [AS_HELP_STRING([--enable-gallium-tests],
 651         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 652     [enable_gallium_tests="$enableval"],
 653     [enable_gallium_tests=no])
 654
 655 # Option for Gallium drivers
 656
 657 # Keep this in sync with the --with-gallium-drivers help string default value
 658 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 659
 660 AC_ARG_WITH([gallium-drivers],
 661     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 662         [comma delimited Gallium drivers list, e.g.
 663         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 664         @<:@default=r300,r600,svga,swrast@:>@])],
 665     [with_gallium_drivers="$withval"],
 666     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 667
 668 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 669 # here so that the script doesn't choke on an unknown driver name later.
 670 case "$with_gallium_drivers" in
 671     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 672     no) with_gallium_drivers='' ;;
 673 esac
 674
 675 if test "x$enable_opengl" = xno -a \
 676         "x$enable_gles1" = xno -a \
 677         "x$enable_gles2" = xno -a \
 678         "x$enable_openvg" = xno -a \
 679         "x$enable_xorg" = xno -a \
 680         "x$enable_xa" = xno -a \
 681         "x$enable_d3d1x" = xno -a \
 682         "x$enable_xvmc" = xno -a \
 683         "x$enable_vdpau" = xno -a \
 684         "x$enable_opencl" = xno; then
 685     AC_MSG_ERROR([at least one API should be enabled])
 686 fi
 687
 688 API_DEFINES=""
 689 if test "x$enable_opengl" = xno; then
 690     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 691 else
 692     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 693 fi
 694 if test "x$enable_gles1" = xyes; then
 695     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 696 fi
 697 if test "x$enable_gles2" = xyes; then
 698     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 699 fi
 700 AC_SUBST([API_DEFINES])
 701
 702 if test "x$enable_glx" = xno; then
 703     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 704     enable_xlib_glx=no
 705 fi
 706
 707 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 708     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 709 fi
 710
 711 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 712     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 713 fi
 714
 715 # Disable GLX if OpenGL is not enabled
 716 if test "x$enable_glx$enable_opengl" = xyesno; then
 717     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 718     enable_glx=no
 719 fi
 720
 721 # Disable GLX if DRI and Xlib-GLX are not enabled
 722 if test "x$enable_glx" = xyes -a \
 723         "x$enable_dri" = xno -a \
 724         "x$enable_xlib_glx" = xno; then
 725     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 726     enable_glx=no
 727 fi
 728
 729 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 730 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 731                                   "x$enable_osmesa" = xyes)
 732
 733 AC_ARG_ENABLE([shared-glapi],
 734     [AS_HELP_STRING([--enable-shared-glapi],
 735         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 736     [enable_shared_glapi="$enableval"],
 737     [enable_shared_glapi="$enable_dri"])
 738
 739 # Shared GLAPI is only useful for DRI
 740 if test "x$enable_dri" = xno; then
 741     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 742     enable_shared_glapi=no
 743 fi
 744
 745 if test "x$enable_shared_glapi" = xyes; then
 746     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 747     # the remap table)
 748     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 749     CORE_DIRS="mapi/shared-glapi"
 750 fi
 751 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 752
 753 dnl
 754 dnl Driver specific build directories
 755 dnl
 756 GALLIUM_DIRS="auxiliary drivers state_trackers"
 757 GALLIUM_TARGET_DIRS=""
 758 GALLIUM_WINSYS_DIRS="sw"
 759 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 760 GALLIUM_STATE_TRACKERS_DIRS=""
 761
 762 # build glapi if OpenGL is enabled
 763 if test "x$enable_opengl" = xyes; then
 764     CORE_DIRS="$CORE_DIRS mapi/glapi"
 765 fi
 766
 767 # build es1api if OpenGL ES 1.x is enabled
 768 if test "x$enable_gles1" = xyes; then
 769     CORE_DIRS="$CORE_DIRS mapi/es1api"
 770 fi
 771
 772 # build es2api if OpenGL ES 2.x is enabled
 773 if test "x$enable_gles2" = xyes; then
 774     CORE_DIRS="$CORE_DIRS mapi/es2api"
 775 fi
 776
 777 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 778 case "x$enable_opengl$enable_gles1$enable_gles2" in
 779 x*yes*)
 780     CORE_DIRS="mapi/glapi/gen $CORE_DIRS gtest glsl mesa"
 781     ;;
 782 esac
 783
 784 case "x$enable_glx$enable_xlib_glx" in
 785 xyesyes)
 786     DRIVER_DIRS="$DRIVER_DIRS x11"
 787     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 788     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 789     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 790     HAVE_WINSYS_XLIB="yes"
 791     ;;
 792 xyesno)
 793     # DRI-based GLX
 794     SRC_DIRS="$SRC_DIRS glx"
 795     ;;
 796 esac
 797
 798 if test "x$enable_dri" = xyes; then
 799     DRIVER_DIRS="$DRIVER_DIRS dri"
 800
 801     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 802     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 803     HAVE_ST_DRI="yes"
 804 fi
 805
 806 if test "x$enable_osmesa" = xyes; then
 807     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 808 fi
 809
 810 AC_SUBST([SRC_DIRS])
 811 AC_SUBST([DRIVER_DIRS])
 812 AC_SUBST([GALLIUM_DIRS])
 813 AC_SUBST([GALLIUM_TARGET_DIRS])
 814 AC_SUBST([GALLIUM_WINSYS_DIRS])
 815 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 816 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 817 AC_SUBST([MESA_LLVM])
 818
 819 # Check for libdrm
 820 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 821                   [have_libdrm=yes], [have_libdrm=no])
 822
 823 if test "x$enable_dri" = xyes; then
 824     # DRI must be shared, I think
 825     if test "$enable_static" = yes; then
 826         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 827     fi
 828
 829     # not a hard requirement as swrast does not depend on it
 830     if test "x$have_libdrm" = xyes; then
 831         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 832     fi
 833 fi
 834
 835 dnl Direct rendering or just indirect rendering
 836 case "$host_os" in
 837 gnu*)
 838     dnl Disable by default on GNU/Hurd
 839     driglx_direct_default="no"
 840     ;;
 841 cygwin*)
 842     dnl Disable by default on cygwin
 843     driglx_direct_default="no"
 844     ;;
 845 *)
 846     driglx_direct_default="yes"
 847     ;;
 848 esac
 849 AC_ARG_ENABLE([driglx-direct],
 850     [AS_HELP_STRING([--disable-driglx-direct],
 851         [disable direct rendering in GLX and EGL for DRI \
 852             @<:@default=auto@:>@])],
 853     [driglx_direct="$enableval"],
 854     [driglx_direct="$driglx_direct_default"])
 855
 856 dnl
 857 dnl libGL configuration per driver
 858 dnl
 859 case "x$enable_glx$enable_xlib_glx" in
 860 xyesyes)
 861     # Xlib-based GLX
 862     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 863     GL_PC_REQ_PRIV="x11 xext"
 864     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 865     GL_LIB_DEPS="$XLIBGL_LIBS"
 866     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 868     ;;
 869 xyesno)
 870     # DRI-based GLX
 871     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 872     if test x"$driglx_direct" = xyes; then
 873         if test "x$have_libdrm" != xyes; then
 874             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 875         fi
 876         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 877         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 878     fi
 879
 880     # find the DRI deps for libGL
 881     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 882
 883     # add xf86vidmode if available
 884     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 885     if test "$HAVE_XF86VIDMODE" = yes ; then
 886         dri_modules="$dri_modules xxf86vm"
 887     fi
 888
 889     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 890     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 891     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 892     GL_LIB_DEPS="$DRIGL_LIBS"
 893
 894     # need DRM libs, $PTHREAD_LIBS, etc.
 895     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 897     ;;
 898 esac
 899
 900 # This is outside the case (above) so that it is invoked even for non-GLX
 901 # builds.
 902 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 903
 904 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 905 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 906 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 907 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 908
 909 AC_SUBST([X11_INCLUDES])
 910 AC_SUBST([GL_LIB_DEPS])
 911 AC_SUBST([GL_PC_REQ_PRIV])
 912 AC_SUBST([GL_PC_LIB_PRIV])
 913 AC_SUBST([GL_PC_CFLAGS])
 914 AC_SUBST([DRI_PC_REQ_PRIV])
 915 AC_SUBST([GLESv1_CM_LIB_DEPS])
 916 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 917 AC_SUBST([GLESv2_LIB_DEPS])
 918 AC_SUBST([GLESv2_PC_LIB_PRIV])
 919
 920 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 921
 922 AC_SUBST([HAVE_XF86VIDMODE])
 923
 924 dnl
 925 dnl More GLX setup
 926 dnl
 927 case "x$enable_glx$enable_xlib_glx" in
 928 xyesyes)
 929     DEFINES="$DEFINES -DUSE_XSHM"
 930     ;;
 931 xyesno)
 932     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 933     if test "x$driglx_direct" = xyes; then
 934         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 935     fi
 936     ;;
 937 esac
 938
 939 dnl
 940 dnl TLS detection
 941 dnl
 942
 943 AC_ARG_ENABLE([glx-tls],
 944     [AS_HELP_STRING([--enable-glx-tls],
 945         [enable TLS support in GLX @<:@default=disabled@:>@])],
 946     [GLX_USE_TLS="$enableval"],
 947     [GLX_USE_TLS=no])
 948 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 949
 950 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 951       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 952
 953 dnl
 954 dnl More DRI setup
 955 dnl
 956 dnl Directory for DRI drivers
 957 AC_ARG_WITH([dri-driverdir],
 958     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 959         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 960     [DRI_DRIVER_INSTALL_DIR="$withval"],
 961     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 962 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 963 dnl Extra search path for DRI drivers
 964 AC_ARG_WITH([dri-searchpath],
 965     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 966         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 967     [DRI_DRIVER_SEARCH_DIR="$withval"],
 968     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 969 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 970 dnl Which drivers to build - default is chosen by platform
 971 AC_ARG_WITH([dri-drivers],
 972     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 973         [comma delimited DRI drivers list, e.g.
 974         "swrast,i965,radeon" @<:@default=auto@:>@])],
 975     [with_dri_drivers="$withval"],
 976     [with_dri_drivers=yes])
 977 if test "x$with_dri_drivers" = x; then
 978     with_dri_drivers=no
 979 fi
 980
 981 dnl If $with_dri_drivers is yes, directories will be added through
 982 dnl platform checks
 983 DRI_DIRS=""
 984 case "$with_dri_drivers" in
 985 no) ;;
 986 yes)
 987     # classic DRI drivers require FEATURE_GL to build
 988     if test "x$enable_opengl" = xyes; then
 989         DRI_DIRS="yes"
 990     fi
 991     ;;
 992 *)
 993     # verify the requested driver directories exist
 994     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 995     for driver in $dri_drivers; do
 996         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 997             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 998     done
 999     DRI_DIRS="$dri_drivers"
1000     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1001         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1002     fi
1003     ;;
1004 esac
1005
1006 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1007 if test "x$enable_dri" = xyes; then
1008     # Platform specific settings and drivers to build
1009     case "$host_os" in
1010     linux*)
1011         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1012         DEFINES="$DEFINES -DHAVE_ALIAS"
1013
1014         case "$host_cpu" in
1015         x86_64)
1016             if test "x$DRI_DIRS" = "xyes"; then
1017                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1018             fi
1019             ;;
1020         powerpc*)
1021             # Build only the drivers for cards that exist on PowerPC.
1022             if test "x$DRI_DIRS" = "xyes"; then
1023                 DRI_DIRS="r200 radeon swrast"
1024             fi
1025             ;;
1026         sparc*)
1027             # Build only the drivers for cards that exist on sparc
1028             if test "x$DRI_DIRS" = "xyes"; then
1029                 DRI_DIRS="r200 radeon swrast"
1030             fi
1031             ;;
1032         esac
1033         ;;
1034     freebsd* | dragonfly* | *netbsd*)
1035         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1036         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1037
1038         if test "x$DRI_DIRS" = "xyes"; then
1039             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1040         fi
1041         ;;
1042     gnu*)
1043         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1044         DEFINES="$DEFINES -DHAVE_ALIAS"
1045         ;;
1046     solaris*)
1047         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1048         ;;
1049     cygwin*)
1050         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1051         if test "x$DRI_DIRS" = "xyes"; then
1052             DRI_DIRS="swrast"
1053         fi
1054         ;;
1055     esac
1056
1057     # default drivers
1058     if test "x$DRI_DIRS" = "xyes"; then
1059         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1060     fi
1061
1062     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1063
1064     # Check for expat
1065     EXPAT_INCLUDES=""
1066     EXPAT_LIB=-lexpat
1067     AC_ARG_WITH([expat],
1068         [AS_HELP_STRING([--with-expat=DIR],
1069             [expat install directory])],[
1070         EXPAT_INCLUDES="-I$withval/include"
1071         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1072         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1073         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1074         ])
1075     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1076     save_LIBS="$LIBS"
1077     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1078         [AC_MSG_ERROR([Expat required for DRI.])])
1079     LIBS="$save_LIBS"
1080
1081     # If we are building any DRI driver other than swrast.
1082     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1083         # ... libdrm is required
1084         if test "x$have_libdrm" != xyes; then
1085             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1086         fi
1087         # ... and build dricommon
1088         HAVE_COMMON_DRI=yes
1089     fi
1090
1091     # put all the necessary libs together
1092     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1093     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1094 fi
1095 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1096 AC_SUBST([DRI_DIRS])
1097 AC_SUBST([EXPAT_INCLUDES])
1098 AC_SUBST([DRI_LIB_DEPS])
1099 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1100
1101 case $DRI_DIRS in
1102 *i915*|*i965*)
1103     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1104
1105     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1106         case $d in
1107         i915)
1108             HAVE_I915_DRI=yes;
1109             ;;
1110         i965)
1111             HAVE_I965_DRI=yes;
1112             ;;
1113         esac
1114     done
1115
1116     ;;
1117 esac
1118
1119 case $DRI_DIRS in
1120 *nouveau*)
1121     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1122     HAVE_NOUVEAU_DRI=yes;
1123     ;;
1124 esac
1125
1126 case $DRI_DIRS in
1127 *radeon*|*r200*)
1128     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1129
1130     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1131         case $d in
1132         radeon)
1133             HAVE_RADEON_DRI=yes;
1134             ;;
1135         r200)
1136             HAVE_R200_DRI=yes;
1137             ;;
1138         esac
1139     done
1140
1141     ;;
1142 esac
1143
1144 case $DRI_DIRS in
1145 *swrast*)
1146     HAVE_SWRAST_DRI=yes;
1147     ;;
1148 esac
1149
1150 dnl
1151 dnl OSMesa configuration
1152 dnl
1153
1154 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1155 AC_ARG_WITH([osmesa-bits],
1156     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1157         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1158     [osmesa_bits="$withval"],
1159     [osmesa_bits=8])
1160 if test "x$osmesa_bits" != x8; then
1161     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1162         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1163         osmesa_bits=8
1164     fi
1165 fi
1166 case "x$osmesa_bits" in
1167 x8)
1168     OSMESA_LIB="${OSMESA_LIB}"
1169     ;;
1170 x16|x32)
1171     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1172     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1173     ;;
1174 *)
1175     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1176     ;;
1177 esac
1178
1179 if test "x$enable_osmesa" = xyes; then
1180     # only link libraries with osmesa if shared
1181     if test "$enable_static" = no; then
1182         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1183     else
1184         OSMESA_LIB_DEPS=""
1185     fi
1186     OSMESA_MESA_DEPS=""
1187     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1188 fi
1189
1190 AC_SUBST([OSMESA_LIB_DEPS])
1191 AC_SUBST([OSMESA_MESA_DEPS])
1192 AC_SUBST([OSMESA_PC_REQ])
1193 AC_SUBST([OSMESA_PC_LIB_PRIV])
1194
1195 dnl
1196 dnl gbm configuration
1197 dnl
1198 if test "x$enable_gbm" = xauto; then
1199     case "$with_egl_platforms" in
1200         *drm*)
1201             enable_gbm=yes ;;
1202          *)
1203             enable_gbm=no ;;
1204     esac
1205 fi
1206 if test "x$enable_gbm" = xyes; then
1207     SRC_DIRS="$SRC_DIRS gbm"
1208
1209     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1210                       AC_MSG_ERROR([gbm needs udev]))
1211
1212     if test "x$enable_dri" = xyes; then
1213         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1214         if test "x$enable_shared_glapi" = xno; then
1215             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1216         fi
1217     fi
1218 fi
1219 GBM_PC_REQ_PRIV="libudev"
1220 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1221 AC_SUBST([GBM_PC_REQ_PRIV])
1222 AC_SUBST([GBM_PC_LIB_PRIV])
1223
1224 dnl
1225 dnl EGL configuration
1226 dnl
1227 EGL_CLIENT_APIS=""
1228
1229 if test "x$enable_egl" = xyes; then
1230     SRC_DIRS="$SRC_DIRS egl"
1231     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1232
1233     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1234
1235     if test "$enable_static" != yes; then
1236         # build egl_glx when libGL is built
1237         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1238                           [have_libudev=yes],[have_libudev=no])
1239         if test "$have_libudev" = yes; then
1240             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1241         fi
1242
1243         if test "x$enable_dri" = xyes; then
1244             HAVE_EGL_DRIVER_DRI2=1
1245         fi
1246
1247     fi
1248 fi
1249 AC_SUBST([EGL_LIB_DEPS])
1250
1251 dnl
1252 dnl EGL Gallium configuration
1253 dnl
1254 if test "x$enable_gallium_egl" = xyes; then
1255     if test "x$with_gallium_drivers" = x; then
1256         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1257     fi
1258     if test "x$enable_egl" = xno; then
1259         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1260     fi
1261     if test "x$have_libdrm" != xyes; then
1262         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1263     fi
1264
1265     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1266     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1267     HAVE_ST_EGL="yes"
1268 fi
1269
1270 dnl
1271 dnl gbm Gallium configuration
1272 dnl
1273 if test "x$enable_gallium_gbm" = xauto; then
1274     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1275         yesyesyes*drm*)
1276             enable_gallium_gbm=yes ;;
1277          *)
1278             enable_gallium_gbm=no ;;
1279     esac
1280 fi
1281 if test "x$enable_gallium_gbm" = xyes; then
1282     if test "x$with_gallium_drivers" = x; then
1283         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1284     fi
1285     if test "x$enable_gbm" = xno; then
1286         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1287     fi
1288     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1289     if test "x$enable_dri" = xno; then
1290         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1291     fi
1292
1293     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1294     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1295     HAVE_ST_GBM="yes"
1296     enable_gallium_loader=yes
1297 fi
1298
1299 dnl
1300 dnl X.Org DDX configuration
1301 dnl
1302 if test "x$enable_xorg" = xyes; then
1303     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1304     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1305     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1306     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1307         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1308         HAVE_XEXTPROTO_71="no")
1309     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1310     HAVE_ST_XORG=yes
1311 fi
1312
1313 dnl
1314 dnl XA configuration
1315 dnl
1316 if test "x$enable_xa" = xyes; then
1317 AC_PROG_AWK
1318 AC_PROG_GREP
1319 AC_CHECK_PROG(NM, nm, "nm")
1320 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1321 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1322 enable_xa=no
1323 fi
1324 fi
1325 if test "x$enable_xa" = xyes; then
1326     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1327     HAVE_ST_XA=yes
1328     AC_SUBST(AWK)
1329     AC_SUBST(GREP)
1330     AC_SUBST(NM)
1331 fi
1332
1333 dnl
1334 dnl OpenVG configuration
1335 dnl
1336 VG_LIB_DEPS=""
1337
1338 if test "x$enable_openvg" = xyes; then
1339     if test "x$enable_egl" = xno; then
1340         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1341     fi
1342     if test "x$with_gallium_drivers" = x; then
1343         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1344     fi
1345     if test "x$enable_gallium_egl" = xno; then
1346         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1347     fi
1348
1349     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1350     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1351     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1352     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1353     HAVE_ST_VEGA=yes
1354     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1355     AC_SUBST([VG_PC_LIB_PRIV])
1356 fi
1357 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1358
1359 dnl
1360 dnl D3D1X configuration
1361 dnl
1362
1363 if test "x$enable_d3d1x" = xyes; then
1364     if test "x$with_gallium_drivers" = x; then
1365         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1366     fi
1367
1368     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1369     HAVE_ST_D3D1X=yes
1370 fi
1371
1372 dnl
1373 dnl Gallium G3DVL configuration
1374 dnl
1375 AC_ARG_ENABLE([gallium-g3dvl],
1376     [AS_HELP_STRING([--enable-gallium-g3dvl],
1377         [build gallium g3dvl @<:@default=disabled@:>@])],
1378     [enable_gallium_g3dvl="$enableval"],
1379     [enable_gallium_g3dvl=no])
1380 if test "x$enable_gallium_g3dvl" = xyes; then
1381     if test "x$with_gallium_drivers" = x; then
1382         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1383     fi
1384
1385     if test "x$enable_xvmc" = xauto; then
1386         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1387     fi
1388
1389     if test "x$enable_vdpau" = xauto; then
1390         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1391     fi
1392 fi
1393
1394 if test "x$enable_xvmc" = xyes; then
1395     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1396     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1397     HAVE_ST_XVMC="yes"
1398 fi
1399
1400 if test "x$enable_vdpau" = xyes; then
1401     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1402     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1403     HAVE_ST_VDPAU="yes"
1404 fi
1405
1406 dnl
1407 dnl OpenCL configuration
1408 dnl
1409
1410 AC_ARG_WITH([libclc-path],
1411    [AS_HELP_STRING([--with-libclc-path],
1412          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1413    [LIBCLC_PATH="$withval"],
1414    [LIBCLC_PATH=""])
1415
1416 if test "x$LIBCLC_PATH" != x; then
1417    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1418                   Please review the updated build instructions for clover:
1419                   http://dri.freedesktop.org/wiki/GalliumCompute])
1420 fi
1421
1422
1423 AC_ARG_WITH([clang-libdir],
1424    [AS_HELP_STRING([--with-clang-libdir],
1425          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1426    [CLANG_LIBDIR="$withval"],
1427    [CLANG_LIBDIR=""])
1428
1429 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1430 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1431 AC_SUBST([LIBCLC_INCLUDEDIR])
1432 AC_SUBST([LIBCLC_LIBEXECDIR])
1433
1434 if test "x$enable_opencl" = xyes; then
1435     if test "x$with_gallium_drivers" = x; then
1436         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1437     fi
1438
1439     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1440         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1441     fi
1442
1443     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1444         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1445     fi
1446
1447     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1448     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1449     enable_gallium_loader=yes
1450 fi
1451
1452 if test "x$enable_gallium_gbm" = xyes || test "x$enable_opencl" = xyes; then
1453     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1454 fi
1455
1456 dnl
1457 dnl Gallium configuration
1458 dnl
1459 if test "x$with_gallium_drivers" != x; then
1460     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1461 fi
1462 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1463
1464 AC_SUBST([LLVM_BINDIR])
1465 AC_SUBST([LLVM_CFLAGS])
1466 AC_SUBST([LLVM_CPPFLAGS])
1467 AC_SUBST([LLVM_CXXFLAGS])
1468 AC_SUBST([LLVM_LIBDIR])
1469 AC_SUBST([LLVM_LIBS])
1470 AC_SUBST([LLVM_LDFLAGS])
1471 AC_SUBST([LLVM_INCLUDEDIR])
1472 AC_SUBST([LLVM_VERSION])
1473 AC_SUBST([CLANG_RESOURCE_DIR])
1474
1475 case "x$enable_opengl$enable_gles1$enable_gles2" in
1476 x*yes*)
1477     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1478     HAVE_OPENGL=yes
1479     ;;
1480 esac
1481 AM_CONDITIONAL(HAVE_OPENGL, test "x$HAVE_OPENGL" = xyes)
1482
1483 AC_SUBST([VG_LIB_DEPS])
1484 AC_SUBST([EGL_CLIENT_APIS])
1485
1486 dnl
1487 dnl EGL Platforms configuration
1488 dnl
1489 AC_ARG_WITH([egl-platforms],
1490     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1491         [comma delimited native platforms libEGL supports, e.g.
1492         "x11,drm" @<:@default=auto@:>@])],
1493     [with_egl_platforms="$withval"],
1494     [if test "x$enable_egl" = xyes; then
1495         with_egl_platforms="x11"
1496     else
1497         with_egl_platforms=""
1498     fi])
1499
1500 EGL_PLATFORMS=""
1501
1502 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1503     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1504 fi
1505
1506 # Do per-EGL platform setups and checks
1507 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1508 for plat in $egl_platforms; do
1509         case "$plat" in
1510         fbdev|null)
1511                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1512                 ;;
1513
1514         wayland)
1515                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1516                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1517
1518                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1519                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1520                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1521                 ;;
1522
1523         x11)
1524                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1525
1526                 if test "x$enable_glx" = xyes; then
1527                         HAVE_EGL_DRIVER_GLX=1
1528                 fi
1529                 ;;
1530
1531         drm)
1532                 test "x$enable_gbm" = "xno" &&
1533                         AC_MSG_ERROR([EGL platform drm needs gbm])
1534                 ;;
1535
1536         android|gdi)
1537                 ;;
1538
1539         *)
1540                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1541                 ;;
1542         esac
1543
1544         case "$plat$have_libudev" in
1545                 waylandno|drmno)
1546                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1547         esac
1548 done
1549
1550 # libEGL wants to default to the first platform specified in
1551 # ./configure.  parse that here.
1552 if test "x$egl_platforms" != "x"; then
1553     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1554     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1555 else
1556     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1557 fi
1558
1559 EGL_PLATFORMS="$egl_platforms"
1560
1561 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1562 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1563 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1564 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1565 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1566
1567 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1568 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1569
1570 AC_SUBST([EGL_NATIVE_PLATFORM])
1571 AC_SUBST([EGL_PLATFORMS])
1572 AC_SUBST([EGL_CFLAGS])
1573
1574 AC_ARG_WITH([egl-driver-dir],
1575     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1576                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1577     [EGL_DRIVER_INSTALL_DIR="$withval"],
1578     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1579 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1580
1581 AC_ARG_WITH([xorg-driver-dir],
1582     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1583                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1584     [XORG_DRIVER_INSTALL_DIR="$withval"],
1585     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1586 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1587
1588 AC_ARG_WITH([max-width],
1589     [AS_HELP_STRING([--with-max-width=N],
1590                     [Maximum framebuffer width (4096)])],
1591     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1592      AS_IF([test "${withval}" -gt "4096"],
1593            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1594 )
1595 AC_ARG_WITH([max-height],
1596     [AS_HELP_STRING([--with-max-height=N],
1597                     [Maximum framebuffer height (4096)])],
1598     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1599      AS_IF([test "${withval}" -gt "4096"],
1600            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1601 )
1602
1603 dnl
1604 dnl Gallium LLVM
1605 dnl
1606 AC_ARG_ENABLE([gallium-llvm],
1607     [AS_HELP_STRING([--enable-gallium-llvm],
1608         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1609     [enable_gallium_llvm="$enableval"],
1610     [enable_gallium_llvm=auto])
1611
1612 AC_ARG_WITH([llvm-shared-libs],
1613     [AS_HELP_STRING([--with-llvm-shared-libs],
1614         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1615     [],
1616     [with_llvm_shared_libs=no])
1617 AS_IF([test x$enable_opencl = xyes],
1618     [
1619         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1620         with_llvm_shared_libs=yes
1621     ])
1622
1623 AC_ARG_WITH([llvm-prefix],
1624     [AS_HELP_STRING([--with-llvm-prefix],
1625         [Prefix for LLVM installations in non-standard locations])],
1626     [llvm_prefix="$withval"],
1627     [llvm_prefix=""])
1628
1629
1630 # Call this inside ` ` to get the return value.
1631 # $1 is the llvm-config command with arguments.
1632 strip_unwanted_llvm_flags() {
1633     # Use \> (marks the end of the word)
1634     echo `$1` | sed \
1635         -e 's/-DNDEBUG\>//g' \
1636         -e 's/-pedantic\>//g' \
1637         -e 's/-Wcovered-switch-default\>//g' \
1638         -e 's/-O.\>//g' \
1639         -e 's/-g\>//g' \
1640         -e 's/-Wall\>//g' \
1641         -e 's/-fomit-frame-pointer\>//g'
1642 }
1643
1644
1645 if test "x$with_gallium_drivers" = x; then
1646     enable_gallium_llvm=no
1647 fi
1648 if test "x$enable_gallium_llvm" = xauto; then
1649     case "$host_cpu" in
1650     i*86|x86_64) enable_gallium_llvm=yes;;
1651     esac
1652 fi
1653 if test "x$enable_gallium_llvm" = xyes; then
1654     if test "x$llvm_prefix" != x; then
1655         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1656     else
1657         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1658     fi
1659
1660     if test "x$LLVM_CONFIG" != xno; then
1661         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1662         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1663         LLVM_COMPONENTS="engine bitwriter"
1664         if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1665             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1666         fi
1667         if $LLVM_CONFIG --components | grep -q '\<oprofilejit\>'; then
1668             LLVM_COMPONENTS="${LLVM_COMPONENTS} oprofilejit"
1669         fi
1670
1671         if test "x$enable_opencl" = xyes; then
1672             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1673         fi
1674         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1675         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1676         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1677         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1678         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1679         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1680         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1681         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1682         MESA_LLVM=1
1683
1684         dnl Check for Clang interanl headers
1685         if test "x$enable_opencl" = xyes; then
1686             if test "x$CLANG_LIBDIR" = x; then
1687                 CLANG_LIBDIR=${LLVM_LIBDIR}
1688             fi
1689             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1690             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1691                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1692         fi
1693     else
1694         MESA_LLVM=0
1695         LLVM_VERSION_INT=0
1696     fi
1697 else
1698     MESA_LLVM=0
1699     LLVM_VERSION_INT=0
1700 fi
1701
1702 dnl Directory for XVMC libs
1703 AC_ARG_WITH([xvmc-libdir],
1704     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1705         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1706     [XVMC_LIB_INSTALL_DIR="$withval"],
1707     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1708 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1709
1710 dnl
1711 dnl Gallium Tests
1712 dnl
1713 if test "x$enable_gallium_tests" = xyes; then
1714     SRC_DIRS="$SRC_DIRS gallium/tests/trivial gallium/tests/unit"
1715     enable_gallium_loader=yes
1716 fi
1717
1718 dnl Directory for VDPAU libs
1719 AC_ARG_WITH([vdpau-libdir],
1720     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1721         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1722     [VDPAU_LIB_INSTALL_DIR="$withval"],
1723     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1724 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1725
1726 dnl Directory for OpenCL libs
1727 AC_ARG_WITH([opencl-libdir],
1728     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1729         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1730     [OPENCL_LIB_INSTALL_DIR="$withval"],
1731     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1732 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1733
1734 dnl
1735 dnl Gallium helper functions
1736 dnl
1737 gallium_check_st() {
1738     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1739          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1740          test "x$HAVE_ST_VDPAU" = xyes; then
1741          if test "x$have_libdrm" != xyes; then
1742             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1743          fi
1744          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1745     fi
1746     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1747          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1748          HAVE_COMMON_DRI=yes
1749     fi
1750     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1751          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1752     fi
1753     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1754          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1755     fi
1756     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1757          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1758     fi
1759     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1760          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1761     fi
1762 }
1763
1764 gallium_require_llvm() {
1765     if test "x$MESA_LLVM" = x0; then
1766         case "$host_cpu" in
1767         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1768         esac
1769     fi
1770 }
1771
1772 gallium_require_drm_loader() {
1773     if test "x$enable_gallium_loader" = xyes; then
1774         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1775                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1776         if test "x$have_libdrm" != xyes; then
1777             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1778         fi
1779         enable_gallium_drm_loader=yes
1780     fi
1781 }
1782
1783 radeon_llvm_check() {
1784     LLVM_REQUIRED_VERSION_MAJOR="3"
1785     LLVM_REQUIRED_VERSION_MINOR="2"
1786     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1787         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with R600 target enabled is required.
1788                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1789                      git://people.freedesktop.org/~tstellar/llvm master
1790                      and build with --enable-experimental-targets=R600])
1791     fi
1792     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1793         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1794                       sources with the --enable-experimental-targets=R600
1795                       configure flag])
1796     fi
1797     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1798     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600"
1799 }
1800
1801 dnl Gallium drivers
1802 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1803 if test "x$with_gallium_drivers" != x; then
1804     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1805     for driver in $gallium_drivers; do
1806         case "x$driver" in
1807         xsvga)
1808             HAVE_GALLIUM_SVGA=yes
1809             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1810             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1811             ;;
1812         xi915)
1813             HAVE_GALLIUM_I915=yes
1814             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1815             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1816             if test "x$MESA_LLVM" = x1; then
1817                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1818             fi
1819             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1820             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1821             ;;
1822         xr300)
1823             HAVE_GALLIUM_R300=yes
1824             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1825             gallium_require_llvm "Gallium R300"
1826             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1827             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1828             ;;
1829         xr600)
1830             HAVE_GALLIUM_R600=yes
1831             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1832             gallium_require_drm_loader
1833             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1834             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1835                 radeon_llvm_check
1836                 NEED_RADEON_GALLIUM=yes;
1837                 R600_NEED_RADEON_GALLIUM=yes;
1838                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo bitreader asmparser"
1839             fi
1840             if test "x$enable_r600_llvm" = xyes; then
1841                 USE_R600_LLVM_COMPILER=yes;
1842             fi
1843             if test "x$enable_opencl" = xyes; then
1844                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1845             fi
1846             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1847             ;;
1848         xradeonsi)
1849             HAVE_GALLIUM_RADEONSI=yes
1850             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1851             gallium_require_drm_loader
1852             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1853             radeon_llvm_check
1854             NEED_RADEON_GALLIUM=yes;
1855             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1856             ;;
1857         xnouveau)
1858             HAVE_GALLIUM_NOUVEAU=yes
1859             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1860             gallium_require_drm_loader
1861             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1862             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1863             ;;
1864         xswrast)
1865             HAVE_GALLIUM_SOFTPIPE=yes
1866             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1867             if test "x$MESA_LLVM" = x1; then
1868                 HAVE_GALLIUM_LLVMPIPE=yes
1869                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1870             fi
1871
1872             if test "x$HAVE_ST_DRI" = xyes; then
1873                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1874             fi
1875             if test "x$HAVE_ST_VDPAU" = xyes; then
1876                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1877             fi
1878             if test "x$HAVE_ST_XVMC" = xyes; then
1879                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1880             fi
1881             if test "x$HAVE_ST_VDPAU" = xyes ||
1882                test "x$HAVE_ST_XVMC" = xyes; then
1883                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1884                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1885                fi
1886             fi
1887             ;;
1888         *)
1889             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1890             ;;
1891         esac
1892     done
1893 fi
1894
1895 dnl Set LLVM_LIBS - This is done after the driver configuration so
1896 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1897 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1898 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1899 dnl this was causing the same libraries to be appear multiple times
1900 dnl in LLVM_LIBS.
1901
1902 if test "x$MESA_LLVM" != x0; then
1903
1904     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1905
1906     if test "x$with_llvm_shared_libs" = xyes; then
1907         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1908         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1909         AC_CHECK_FILE("$LLVM_LIBDIR/lib$LLVM_SO_NAME.so", llvm_have_one_so=yes,)
1910
1911         if test "x$llvm_have_one_so" = xyes; then
1912             dnl LLVM was built using auto*, so there is only one shared object.
1913             LLVM_LIBS="-l$LLVM_SO_NAME"
1914         else
1915             dnl If LLVM was built with CMake, there will be one shared object per
1916             dnl component.
1917             AC_CHECK_FILE("$LLVM_LIBDIR/libLLVMTarget.so",,
1918                     AC_MSG_ERROR([Could not find llvm shared libraries:
1919         Please make sure you have built llvm with the --enable-shared option
1920         and that your llvm libraries are installed in $LLVM_LIBDIR
1921         If you have installed your llvm libraries to a different directory you
1922         can use the --with-llvm-prefix= configure flag to specify this directory.
1923         NOTE: Mesa is attempting to use llvm shared libraries because you have
1924         passed one of the following options to configure:
1925                 --with-llvm-shared-libs
1926                 --enable-opencl
1927         If you do not want to build with llvm shared libraries and instead want to
1928         use llvm static libraries then remove these options from your configure
1929         invocation and reconfigure.]))
1930
1931            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1932            dnl install uses a shared object for each compoenent and we have
1933            dnl already added all of these objects to LLVM_LIBS.
1934         fi
1935     fi
1936 fi
1937
1938 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1939 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1940 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1941 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1942 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1943 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1944 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1945 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1946
1947 if test "x$enable_gallium_loader" = xyes; then
1948     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1949     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1950     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1951     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1952
1953     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1954         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1955         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1956     fi
1957
1958     if test "x$enable_gallium_drm_loader" = xyes; then
1959         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1960         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1961                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1962         if test "x$pipe_loader_have_xcb" = xyes; then
1963             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1964             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1965         fi
1966     fi
1967
1968     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1969     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1970 fi
1971
1972 dnl Tell Automake which drivers to build
1973 for driver in $GALLIUM_DRIVERS_DIRS; do
1974     case "x$driver" in
1975         xgalahad)
1976             HAVE_GALAHAD_GALLIUM=yes;
1977             ;;
1978         xidentity)
1979             HAVE_IDENTITY_GALLIUM=yes;
1980             ;;
1981         xnoop)
1982             HAVE_NOOP_GALLIUM=yes;
1983             ;;
1984         *)
1985             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1986             ;;
1987     esac
1988 done
1989
1990 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1991 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1992 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1993 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1994 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1995 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1996 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1997
1998 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1999 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2000 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2001 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2002 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
2003 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2004 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2005 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2006 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2007 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2008 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
2009
2010 AC_SUBST([GALLIUM_MAKE_DIRS])
2011
2012 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
2013                                      "x$enable_xlib_glx" = xyes -o \
2014                                      "x$enable_osmesa" = xyes)
2015 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2016
2017 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2018 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2019 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2020
2021 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
2022
2023 AC_SUBST([VDPAU_MAJOR], 1)
2024 AC_SUBST([VDPAU_MINOR], 0)
2025
2026 AC_SUBST([XVMC_MAJOR], 1)
2027 AC_SUBST([XVMC_MINOR], 0)
2028
2029 AC_SUBST([XA_MAJOR], 1)
2030 AC_SUBST([XA_MINOR], 0)
2031 AC_SUBST([XA_TINY], 0)
2032 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2033
2034 dnl prepend CORE_DIRS to SRC_DIRS
2035 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2036
2037 dnl Restore LDFLAGS and CPPFLAGS
2038 LDFLAGS="$_SAVE_LDFLAGS"
2039 CPPFLAGS="$_SAVE_CPPFLAGS"
2040
2041 dnl Add user CFLAGS and CXXFLAGS
2042 CFLAGS="$CFLAGS $USER_CFLAGS"
2043 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2044
2045 dnl Substitute the config
2046 AC_CONFIG_FILES([Makefile
2047                 src/Makefile
2048                 src/egl/Makefile
2049                 src/egl/drivers/Makefile
2050                 src/egl/drivers/dri2/Makefile
2051                 src/egl/drivers/glx/Makefile
2052                 src/egl/main/Makefile
2053                 src/egl/main/egl.pc
2054                 src/egl/wayland/Makefile
2055                 src/egl/wayland/wayland-drm/Makefile
2056                 src/egl/wayland/wayland-egl/Makefile
2057                 src/egl/wayland/wayland-egl/wayland-egl.pc
2058                 src/gallium/Makefile
2059                 src/gallium/auxiliary/Makefile
2060                 src/gallium/auxiliary/pipe-loader/Makefile
2061                 src/gallium/drivers/Makefile
2062                 src/gallium/drivers/i915/Makefile
2063                 src/gallium/drivers/llvmpipe/Makefile
2064                 src/gallium/drivers/nouveau/Makefile
2065                 src/gallium/drivers/nv30/Makefile
2066                 src/gallium/drivers/nv50/Makefile
2067                 src/gallium/drivers/nvc0/Makefile
2068                 src/gallium/drivers/r300/Makefile
2069                 src/gallium/drivers/r600/Makefile
2070                 src/gallium/drivers/radeon/Makefile
2071                 src/gallium/drivers/radeonsi/Makefile
2072                 src/gallium/drivers/rbug/Makefile
2073                 src/gallium/drivers/softpipe/Makefile
2074                 src/gallium/drivers/svga/Makefile
2075                 src/gallium/drivers/trace/Makefile
2076                 src/gallium/state_trackers/Makefile
2077                 src/gallium/state_trackers/clover/Makefile
2078                 src/gallium/state_trackers/dri/Makefile
2079                 src/gallium/state_trackers/dri/drm/Makefile
2080                 src/gallium/state_trackers/dri/sw/Makefile
2081                 src/gallium/state_trackers/egl/Makefile
2082                 src/gallium/state_trackers/gbm/Makefile
2083                 src/gallium/state_trackers/glx/Makefile
2084                 src/gallium/state_trackers/vdpau/Makefile
2085                 src/gallium/state_trackers/vega/Makefile
2086                 src/gallium/state_trackers/xa/Makefile
2087                 src/gallium/state_trackers/xorg/Makefile
2088                 src/gallium/state_trackers/xvmc/Makefile
2089                 src/gallium/targets/Makefile
2090                 src/gallium/targets/dri-i915/Makefile
2091                 src/gallium/targets/dri-nouveau/Makefile
2092                 src/gallium/targets/dri-r300/Makefile
2093                 src/gallium/targets/dri-r600/Makefile
2094                 src/gallium/targets/dri-radeonsi/Makefile
2095                 src/gallium/targets/dri-swrast/Makefile
2096                 src/gallium/targets/dri-vmwgfx/Makefile
2097                 src/gallium/targets/egl-static/Makefile
2098                 src/gallium/targets/gbm/Makefile
2099                 src/gallium/targets/opencl/Makefile
2100                 src/gallium/targets/pipe-loader/Makefile
2101                 src/gallium/targets/libgl-xlib/Makefile
2102                 src/gallium/targets/vdpau-nouveau/Makefile
2103                 src/gallium/targets/vdpau-r300/Makefile
2104                 src/gallium/targets/vdpau-r600/Makefile
2105                 src/gallium/targets/vdpau-radeonsi/Makefile
2106                 src/gallium/targets/vdpau-softpipe/Makefile
2107                 src/gallium/targets/xa-vmwgfx/Makefile
2108                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2109                 src/gallium/targets/xorg-i915/Makefile
2110                 src/gallium/targets/xorg-nouveau/Makefile
2111                 src/gallium/targets/xorg-r600/Makefile
2112                 src/gallium/targets/xorg-radeonsi/Makefile
2113                 src/gallium/targets/xvmc-nouveau/Makefile
2114                 src/gallium/targets/xvmc-r300/Makefile
2115                 src/gallium/targets/xvmc-r600/Makefile
2116                 src/gallium/targets/xvmc-softpipe/Makefile
2117                 src/gallium/tests/trivial/Makefile
2118                 src/gallium/tests/unit/Makefile
2119                 src/gallium/winsys/Makefile
2120                 src/gallium/winsys/i915/drm/Makefile
2121                 src/gallium/winsys/i915/sw/Makefile
2122                 src/gallium/winsys/nouveau/drm/Makefile
2123                 src/gallium/winsys/radeon/drm/Makefile
2124                 src/gallium/winsys/svga/drm/Makefile
2125                 src/gallium/winsys/sw/Makefile
2126                 src/gallium/winsys/sw/dri/Makefile
2127                 src/gallium/winsys/sw/fbdev/Makefile
2128                 src/gallium/winsys/sw/null/Makefile
2129                 src/gallium/winsys/sw/wayland/Makefile
2130                 src/gallium/winsys/sw/wrapper/Makefile
2131                 src/gallium/winsys/sw/xlib/Makefile
2132                 src/gbm/Makefile
2133                 src/gbm/main/gbm.pc
2134                 src/glsl/Makefile
2135                 src/glsl/builtin_compiler/Makefile
2136                 src/glx/Makefile
2137                 src/glx/tests/Makefile
2138                 src/gtest/Makefile
2139                 src/mapi/es1api/Makefile
2140                 src/mapi/es1api/glesv1_cm.pc
2141                 src/mapi/es2api/Makefile
2142                 src/mapi/es2api/glesv2.pc
2143                 src/mapi/glapi/Makefile
2144                 src/mapi/glapi/gen/Makefile
2145                 src/mapi/glapi/tests/Makefile
2146                 src/mapi/shared-glapi/Makefile
2147                 src/mapi/shared-glapi/tests/Makefile
2148                 src/mapi/vgapi/Makefile
2149                 src/mapi/vgapi/vg.pc
2150                 src/mesa/Makefile
2151                 src/mesa/gl.pc
2152                 src/mesa/drivers/Makefile
2153                 src/mesa/drivers/dri/dri.pc
2154                 src/mesa/drivers/dri/common/Makefile
2155                 src/mesa/drivers/dri/common/xmlpool/Makefile
2156                 src/mesa/drivers/dri/i915/Makefile
2157                 src/mesa/drivers/dri/i965/Makefile
2158                 src/mesa/drivers/dri/Makefile
2159                 src/mesa/drivers/dri/nouveau/Makefile
2160                 src/mesa/drivers/dri/r200/Makefile
2161                 src/mesa/drivers/dri/radeon/Makefile
2162                 src/mesa/drivers/dri/swrast/Makefile
2163                 src/mesa/drivers/osmesa/Makefile
2164                 src/mesa/drivers/osmesa/osmesa.pc
2165                 src/mesa/drivers/x11/Makefile
2166                 src/mesa/libdricore/Makefile
2167                 src/mesa/main/tests/Makefile
2168                 src/mesa/main/tests/hash_table/Makefile
2169                 src/mesa/program/Makefile
2170                 src/mesa/x86-64/Makefile
2171                 src/mesa/x86/Makefile])
2172
2173 dnl Sort the dirs alphabetically
2174 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2175 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2176 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2177 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2178 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2179
2180 AC_OUTPUT
2181
2182 dnl
2183 dnl Output some configuration info for the user
2184 dnl
2185 echo ""
2186 echo "        prefix:          $prefix"
2187 echo "        exec_prefix:     $exec_prefix"
2188 echo "        libdir:          $libdir"
2189 echo "        includedir:      $includedir"
2190
2191 dnl API info
2192 echo ""
2193 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2194 echo "        OpenVG:          $enable_openvg"
2195
2196 dnl Driver info
2197 echo ""
2198 if test "x$enable_osmesa" != xno; then
2199         echo "        OSMesa:          lib$OSMESA_LIB"
2200 else
2201         echo "        OSMesa:          no"
2202 fi
2203
2204 if test "x$enable_dri" != xno; then
2205         # cleanup the drivers var
2206         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2207         if test "x$DRI_DIRS" = x; then
2208             echo "        DRI drivers:     no"
2209         else
2210             echo "        DRI drivers:     $dri_dirs"
2211         fi
2212         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2213 fi
2214
2215 case "x$enable_glx$enable_xlib_glx" in
2216 xyesyes)
2217     echo "        GLX:             Xlib-based"
2218     ;;
2219 xyesno)
2220     echo "        GLX:             DRI-based"
2221     ;;
2222 *)
2223     echo "        GLX:             $enable_glx"
2224     ;;
2225 esac
2226
2227 dnl EGL
2228 echo ""
2229 echo "        EGL:             $enable_egl"
2230 if test "$enable_egl" = yes; then
2231     echo "        EGL platforms:   $EGL_PLATFORMS"
2232
2233     egl_drivers=""
2234     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2235         egl_drivers="$egl_drivers builtin:egl_glx"
2236     fi
2237     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2238         egl_drivers="$egl_drivers builtin:egl_dri2"
2239     fi
2240
2241     if test "x$HAVE_ST_EGL" = xyes; then
2242         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2243         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2244     else
2245         echo "        EGL drivers:    $egl_drivers"
2246     fi
2247 fi
2248
2249 echo ""
2250 if test "x$MESA_LLVM" = x1; then
2251     echo "        llvm:            yes"
2252     echo "        llvm-config:     $LLVM_CONFIG"
2253     echo "        llvm-version:    $LLVM_VERSION"
2254 else
2255     echo "        llvm:            no"
2256 fi
2257
2258 echo ""
2259 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2260     echo "        Gallium:         yes"
2261     echo "        Gallium dirs:    $GALLIUM_DIRS"
2262     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2263     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2264     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2265     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2266 else
2267     echo "        Gallium:         no"
2268 fi
2269
2270
2271 dnl Libraries
2272 echo ""
2273 echo "        Shared libs:     $enable_shared"
2274 echo "        Static libs:     $enable_static"
2275 echo "        Shared-glapi:    $enable_shared_glapi"
2276
2277 dnl Compiler options
2278 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2279 cflags=`echo $CFLAGS | \
2280     $SED 's/^ *//;s/  */ /;s/ *$//'`
2281 cxxflags=`echo $CXXFLAGS | \
2282     $SED 's/^ *//;s/  */ /;s/ *$//'`
2283 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2284 echo ""
2285 echo "        CFLAGS:          $cflags"
2286 echo "        CXXFLAGS:        $cxxflags"
2287 echo "        Macros:          $defines"
2288 echo ""
2289 if test "x$MESA_LLVM" = x1; then
2290     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2291     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2292     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2293     echo ""
2294 fi
2295 echo "        PYTHON2:         $PYTHON2"
2296
2297 echo ""
2298 echo "        Run '${MAKE-make}' to build Mesa"
2299 echo ""