configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.60
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126 if test -n "$PYTHON2" -a "x$acv_mako_found" != "xyes"; then
 127     AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 128 fi
 129
 130 AC_PROG_INSTALL
 131
 132 dnl We need a POSIX shell for parts of the build. Assume we have one
 133 dnl in most cases.
 134 case "$host_os" in
 135 solaris*)
 136     # Solaris /bin/sh is too old/non-POSIX compliant
 137     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 138     SHELL="$POSIX_SHELL"
 139     ;;
 140 esac
 141
 142 dnl clang is mostly GCC-compatible, but its version is much lower,
 143 dnl so we have to check for it.
 144 AC_MSG_CHECKING([if compiling with clang])
 145
 146 AC_COMPILE_IFELSE(
 147 [AC_LANG_PROGRAM([], [[
 148 #ifndef __clang__
 149        not clang
 150 #endif
 151 ]])],
 152 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 153
 154 AC_MSG_RESULT([$acv_mesa_CLANG])
 155
 156 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 157 dnl versions are explictly not supported.
 158 GEN_ASM_OFFSETS=no
 159 USE_GNU99=no
 160 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 161     AC_MSG_CHECKING([whether gcc version is sufficient])
 162     major=0
 163     minor=0
 164
 165     GCC_VERSION=`$CC -dumpversion`
 166     if test $? -eq 0; then
 167         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 168         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 169     fi
 170
 171     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 172         AC_MSG_RESULT([no])
 173         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 174     else
 175         AC_MSG_RESULT([yes])
 176     fi
 177
 178     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 179         USE_GNU99=yes
 180     fi
 181     if test "x$cross_compiling" = xyes; then
 182         GEN_ASM_OFFSETS=yes
 183     fi
 184 fi
 185
 186 dnl Check for compiler builtins
 187 AX_GCC_BUILTIN([__builtin_bswap32])
 188 AX_GCC_BUILTIN([__builtin_bswap64])
 189 AX_GCC_BUILTIN([__builtin_clz])
 190 AX_GCC_BUILTIN([__builtin_clzll])
 191 AX_GCC_BUILTIN([__builtin_ctz])
 192 AX_GCC_BUILTIN([__builtin_expect])
 193 AX_GCC_BUILTIN([__builtin_ffs])
 194 AX_GCC_BUILTIN([__builtin_ffsll])
 195 AX_GCC_BUILTIN([__builtin_popcount])
 196 AX_GCC_BUILTIN([__builtin_popcountll])
 197 AX_GCC_BUILTIN([__builtin_unreachable])
 198
 199 AX_GCC_FUNC_ATTRIBUTE([flatten])
 200 AX_GCC_FUNC_ATTRIBUTE([format])
 201 AX_GCC_FUNC_ATTRIBUTE([malloc])
 202 AX_GCC_FUNC_ATTRIBUTE([packed])
 203 AX_GCC_FUNC_ATTRIBUTE([unused])
 204
 205 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 206
 207 dnl Make sure the pkg-config macros are defined
 208 m4_ifndef([PKG_PROG_PKG_CONFIG],
 209     [m4_fatal([Could not locate the pkg-config autoconf macros.
 210   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 211   are in a different location, try setting the environment variable
 212   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 213 PKG_PROG_PKG_CONFIG()
 214
 215 dnl LIB_DIR - library basename
 216 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 217 AC_SUBST([LIB_DIR])
 218
 219 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 220 _SAVE_LDFLAGS="$LDFLAGS"
 221 _SAVE_CPPFLAGS="$CPPFLAGS"
 222
 223 dnl Compiler macros
 224 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 225 AC_SUBST([DEFINES])
 226 case "$host_os" in
 227 linux*|*-gnu*|gnu*)
 228     DEFINES="$DEFINES -D_GNU_SOURCE"
 229     ;;
 230 solaris*)
 231     DEFINES="$DEFINES -DSVR4"
 232     ;;
 233 cygwin*)
 234     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 235     ;;
 236 esac
 237
 238 dnl Add flags for gcc and g++
 239 if test "x$GCC" = xyes; then
 240     CFLAGS="$CFLAGS -Wall"
 241
 242     if test "x$USE_GNU99" = xyes; then
 243         CFLAGS="$CFLAGS -std=gnu99"
 244     else
 245         CFLAGS="$CFLAGS -std=c99"
 246     fi
 247
 248     # Enable -Werror=implicit-function-declaration and
 249     # -Werror=missing-prototypes, if available, or otherwise, just
 250     # -Wmissing-prototypes.  This is particularly useful to avoid
 251     # generating a loadable driver module that has undefined symbols.
 252     save_CFLAGS="$CFLAGS"
 253     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 254     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 255     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 256     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 257                    AC_MSG_RESULT([yes]),
 258                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 259                     AC_MSG_RESULT([no])]);
 260
 261     # Enable -fvisibility=hidden if using a gcc that supports it
 262     save_CFLAGS="$CFLAGS"
 263     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 264     VISIBILITY_CFLAGS="-fvisibility=hidden"
 265     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 266     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 267                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 268
 269     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 270     CFLAGS=$save_CFLAGS
 271
 272     # Work around aliasing bugs - developers should comment this out
 273     CFLAGS="$CFLAGS -fno-strict-aliasing"
 274
 275     # gcc's builtin memcmp is slower than glibc's
 276     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 277     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 278
 279     # Flags to help ensure that certain portions of the code -- and only those
 280     # portions -- can be built with MSVC:
 281     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 282     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 283     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 284     #   supports most of C99)
 285     # - the rest has no compiler compiler restrictions
 286     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 287     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 288
 289     # Enable -Werror=vla if compiler supports it
 290     save_CFLAGS="$CFLAGS"
 291     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 292     CFLAGS="$CFLAGS -Werror=vla"
 293     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 294                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 295                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 296                     AC_MSG_RESULT([yes])],
 297                     AC_MSG_RESULT([no]));
 298     CFLAGS="$save_CFLAGS"
 299
 300     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 301     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 302 fi
 303 if test "x$GXX" = xyes; then
 304     CXXFLAGS="$CXXFLAGS -Wall"
 305
 306     # Enable -fvisibility=hidden if using a gcc that supports it
 307     save_CXXFLAGS="$CXXFLAGS"
 308     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 309     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 310     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 311     AC_LANG_PUSH([C++])
 312     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 313                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 314     AC_LANG_POP([C++])
 315
 316     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 317     CXXFLAGS=$save_CXXFLAGS
 318
 319     # Work around aliasing bugs - developers should comment this out
 320     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 321
 322     # gcc's builtin memcmp is slower than glibc's
 323     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 324     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 325 fi
 326
 327 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 328 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 329 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 330 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 331
 332 dnl even if the compiler appears to support it, using visibility attributes isn't
 333 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 334 case "$host_os" in
 335 cygwin*)
 336     VISIBILITY_CFLAGS=""
 337     VISIBILITY_CXXFLAGS=""
 338     ;;
 339 esac
 340
 341 AC_SUBST([VISIBILITY_CFLAGS])
 342 AC_SUBST([VISIBILITY_CXXFLAGS])
 343
 344 dnl
 345 dnl Optional flags, check for compiler support
 346 dnl
 347 SSE41_CFLAGS="-msse4.1"
 348 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 349 dnl stack, but on x86-32 such alignment is not guaranteed.
 350 case "$target_cpu" in
 351 i?86)
 352     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 353     ;;
 354 esac
 355 save_CFLAGS="$CFLAGS"
 356 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 357 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 358 #include <smmintrin.h>
 359 int main () {
 360     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 361     c = _mm_max_epu32(a, b);
 362     return 0;
 363 }]])], SSE41_SUPPORTED=1)
 364 CFLAGS="$save_CFLAGS"
 365 if test "x$SSE41_SUPPORTED" = x1; then
 366     DEFINES="$DEFINES -DUSE_SSE41"
 367 fi
 368 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 369 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 370
 371 dnl Can't have static and shared libraries, default to static if user
 372 dnl explicitly requested. If both disabled, set to static since shared
 373 dnl was explicitly requested.
 374 case "x$enable_static$enable_shared" in
 375 xyesyes)
 376     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 377     enable_shared=no
 378     ;;
 379 xnono)
 380     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 381     enable_shared=yes
 382     ;;
 383 esac
 384
 385 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 386
 387 dnl
 388 dnl other compiler options
 389 dnl
 390 AC_ARG_ENABLE([debug],
 391     [AS_HELP_STRING([--enable-debug],
 392         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 393     [enable_debug="$enableval"],
 394     [enable_debug=no]
 395 )
 396 if test "x$enable_debug" = xyes; then
 397     DEFINES="$DEFINES -DDEBUG"
 398     if test "x$GCC" = xyes; then
 399         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 400             CFLAGS="$CFLAGS -g"
 401         fi
 402         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 403             CFLAGS="$CFLAGS -O0"
 404         fi
 405     fi
 406     if test "x$GXX" = xyes; then
 407         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 408             CXXFLAGS="$CXXFLAGS -g"
 409         fi
 410         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 411             CXXFLAGS="$CXXFLAGS -O0"
 412         fi
 413     fi
 414 else
 415    DEFINES="$DEFINES -DNDEBUG"
 416 fi
 417
 418 dnl
 419 dnl Check if linker supports -Bsymbolic
 420 dnl
 421 save_LDFLAGS=$LDFLAGS
 422 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 423 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 424 AC_LINK_IFELSE(
 425     [AC_LANG_SOURCE([int main() { return 0;}])],
 426     [AC_MSG_RESULT([yes])
 427         BSYMBOLIC="-Wl,-Bsymbolic";],
 428     [AC_MSG_RESULT([no])
 429         BSYMBOLIC="";])
 430 LDFLAGS=$save_LDFLAGS
 431
 432 AC_SUBST([BSYMBOLIC])
 433
 434 dnl
 435 dnl Check if linker supports garbage collection
 436 dnl
 437 save_LDFLAGS=$LDFLAGS
 438 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 439 AC_MSG_CHECKING([whether ld supports --gc-sections])
 440 AC_LINK_IFELSE(
 441     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 442     [AC_MSG_RESULT([yes])
 443         GC_SECTIONS="-Wl,--gc-sections";],
 444     [AC_MSG_RESULT([no])
 445         GC_SECTIONS="";])
 446 LDFLAGS=$save_LDFLAGS
 447
 448 AC_SUBST([GC_SECTIONS])
 449
 450 dnl
 451 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 452 dnl so when these flags are passed to ld via libtool the checks will fail
 453 dnl
 454 case "$host_os" in
 455 openbsd* | darwin* )
 456     LD_NO_UNDEFINED="" ;;
 457 *)
 458     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 459 esac
 460
 461 AC_SUBST([LD_NO_UNDEFINED])
 462
 463 dnl
 464 dnl Check if linker supports version scripts
 465 dnl
 466 AC_MSG_CHECKING([if the linker supports version-scripts])
 467 save_LDFLAGS=$LDFLAGS
 468 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 469 cat > conftest.map <<EOF
 470 VERSION_1 {
 471      global:
 472          main;
 473
 474      local:
 475          *;
 476 };
 477 EOF
 478 AC_LINK_IFELSE(
 479     [AC_LANG_SOURCE([int main() { return 0;}])],
 480     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 481     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 482 LDFLAGS=$save_LDFLAGS
 483 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 484
 485 dnl
 486 dnl Check if linker supports dynamic list files
 487 dnl
 488 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 489 save_LDFLAGS=$LDFLAGS
 490 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 491 cat > conftest.dyn <<EOF
 492 {
 493         radeon_drm_winsys_create;
 494 };
 495 EOF
 496 AC_LINK_IFELSE(
 497     [AC_LANG_SOURCE([int main() { return 0;}])],
 498     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 499     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 500 LDFLAGS=$save_LDFLAGS
 501 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 502
 503 dnl
 504 dnl compatibility symlinks
 505 dnl
 506 case "$host_os" in
 507 linux* )
 508     HAVE_COMPAT_SYMLINKS=yes ;;
 509 * )
 510     HAVE_COMPAT_SYMLINKS=no ;;
 511 esac
 512
 513 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 514
 515 dnl
 516 dnl library names
 517 dnl
 518 case "$host_os" in
 519 darwin* )
 520     LIB_EXT='dylib' ;;
 521 cygwin* )
 522     LIB_EXT='dll' ;;
 523 aix* )
 524     LIB_EXT='a' ;;
 525 * )
 526     LIB_EXT='so' ;;
 527 esac
 528
 529 AC_SUBST([LIB_EXT])
 530
 531 AC_ARG_WITH([gl-lib-name],
 532   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 533     [specify GL library name @<:@default=GL@:>@])],
 534   [GL_LIB=$withval],
 535   [GL_LIB=GL])
 536 AC_ARG_WITH([osmesa-lib-name],
 537   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 538     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 539   [OSMESA_LIB=$withval],
 540   [OSMESA_LIB=OSMesa])
 541 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 542 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 543
 544 dnl
 545 dnl Mangled Mesa support
 546 dnl
 547 AC_ARG_ENABLE([mangling],
 548   [AS_HELP_STRING([--enable-mangling],
 549     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 550   [enable_mangling="${enableval}"],
 551   [enable_mangling=no]
 552 )
 553 if test "x${enable_mangling}" = "xyes" ; then
 554   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 555   GL_LIB="Mangled${GL_LIB}"
 556   OSMESA_LIB="Mangled${OSMESA_LIB}"
 557 fi
 558 AC_SUBST([GL_LIB])
 559 AC_SUBST([OSMESA_LIB])
 560
 561 dnl
 562 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 563 dnl
 564 AC_ARG_ENABLE([texture-float],
 565     [AS_HELP_STRING([--enable-texture-float],
 566         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 567     [enable_texture_float="$enableval"],
 568     [enable_texture_float=no]
 569 )
 570 if test "x$enable_texture_float" = xyes; then
 571     AC_MSG_WARN([Floating-point textures enabled.])
 572     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 573     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 574 fi
 575
 576 dnl
 577 dnl Arch/platform-specific settings
 578 dnl
 579 AC_ARG_ENABLE([asm],
 580     [AS_HELP_STRING([--disable-asm],
 581         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 582     [enable_asm="$enableval"],
 583     [enable_asm=yes]
 584 )
 585 asm_arch=""
 586 AC_MSG_CHECKING([whether to enable assembly])
 587 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 588 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 589 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 590     case "$host_cpu" in
 591     i?86 | x86_64 | amd64)
 592         enable_asm=no
 593         AC_MSG_RESULT([no, cross compiling])
 594         ;;
 595     esac
 596 fi
 597 # check for supported arches
 598 if test "x$enable_asm" = xyes; then
 599     case "$host_cpu" in
 600     i?86)
 601         case "$host_os" in
 602         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 603             asm_arch=x86
 604             ;;
 605         esac
 606         ;;
 607     x86_64|amd64)
 608         case "$host_os" in
 609         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 610             asm_arch=x86_64
 611             ;;
 612         esac
 613         ;;
 614     sparc*)
 615         case "$host_os" in
 616         linux*)
 617             asm_arch=sparc
 618             ;;
 619         esac
 620         ;;
 621     esac
 622
 623     case "$asm_arch" in
 624     x86)
 625         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 626         AC_MSG_RESULT([yes, x86])
 627         ;;
 628     x86_64|amd64)
 629         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 630         AC_MSG_RESULT([yes, x86_64])
 631         ;;
 632     sparc)
 633         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 634         AC_MSG_RESULT([yes, sparc])
 635         ;;
 636     *)
 637         AC_MSG_RESULT([no, platform not supported])
 638         ;;
 639     esac
 640 fi
 641
 642 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 643 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 644
 645 dnl Check to see if dlopen is in default libraries (like Solaris, which
 646 dnl has it in libc), or if libdl is needed to get it.
 647 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 648     [AC_CHECK_LIB([dl], [dlopen],
 649        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 650 AC_SUBST([DLOPEN_LIBS])
 651
 652 dnl Check if that library also has dladdr
 653 save_LIBS="$LIBS"
 654 LIBS="$LIBS $DLOPEN_LIBS"
 655 AC_CHECK_FUNCS([dladdr])
 656 LIBS="$save_LIBS"
 657
 658 case "$host_os" in
 659 darwin*)
 660     ;;
 661 *)
 662     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 663                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 664                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 665     AC_SUBST([CLOCK_LIB])
 666     ;;
 667 esac
 668
 669 dnl See if posix_memalign is available
 670 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 671
 672 dnl Check for pthreads
 673 AX_PTHREAD
 674 if test "x$ax_pthread_ok" = xno; then
 675     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 676 fi
 677 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 678 dnl to -pthread, which causes problems if we need -lpthread to appear in
 679 dnl pkgconfig files.
 680 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 681
 682 dnl SELinux awareness.
 683 AC_ARG_ENABLE([selinux],
 684     [AS_HELP_STRING([--enable-selinux],
 685         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 686     [MESA_SELINUX="$enableval"],
 687     [MESA_SELINUX=no])
 688 if test "x$enable_selinux" = "xyes"; then
 689     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 690         [AC_CHECK_HEADER([selinux/selinux.h],[],
 691                          [AC_MSG_ERROR([SELinux headers not found])])
 692          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 693                       [AC_MSG_ERROR([SELinux library not found])])
 694          SELINUX_LIBS="-lselinux"])
 695     DEFINES="$DEFINES -DMESA_SELINUX"
 696 fi
 697 AC_SUBST([SELINUX_CFLAGS])
 698 AC_SUBST([SELINUX_LIBS])
 699
 700 dnl Options for APIs
 701 AC_ARG_ENABLE([opengl],
 702     [AS_HELP_STRING([--disable-opengl],
 703         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 704     [enable_opengl="$enableval"],
 705     [enable_opengl=yes])
 706 AC_ARG_ENABLE([gles1],
 707     [AS_HELP_STRING([--enable-gles1],
 708         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 709     [enable_gles1="$enableval"],
 710     [enable_gles1=no])
 711 AC_ARG_ENABLE([gles2],
 712     [AS_HELP_STRING([--enable-gles2],
 713         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 714     [enable_gles2="$enableval"],
 715     [enable_gles2=no])
 716
 717 AC_ARG_ENABLE([dri],
 718     [AS_HELP_STRING([--enable-dri],
 719         [enable DRI modules @<:@default=enabled@:>@])],
 720     [enable_dri="$enableval"],
 721     [enable_dri=yes])
 722
 723 case "$host_os" in
 724 linux*)
 725     dri3_default=yes
 726     ;;
 727 *)
 728     dri3_default=no
 729     ;;
 730 esac
 731 AC_ARG_ENABLE([dri3],
 732     [AS_HELP_STRING([--enable-dri3],
 733         [enable DRI3 @<:@default=auto@:>@])],
 734     [enable_dri3="$enableval"],
 735     [enable_dri3="$dri3_default"])
 736 AC_ARG_ENABLE([glx],
 737     [AS_HELP_STRING([--enable-glx],
 738         [enable GLX library @<:@default=enabled@:>@])],
 739     [enable_glx="$enableval"],
 740     [enable_glx=yes])
 741 AC_ARG_ENABLE([osmesa],
 742     [AS_HELP_STRING([--enable-osmesa],
 743         [enable OSMesa library @<:@default=disabled@:>@])],
 744     [enable_osmesa="$enableval"],
 745     [enable_osmesa=no])
 746 AC_ARG_ENABLE([gallium-osmesa],
 747     [AS_HELP_STRING([--enable-gallium-osmesa],
 748         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 749     [enable_gallium_osmesa="$enableval"],
 750     [enable_gallium_osmesa=no])
 751 AC_ARG_ENABLE([egl],
 752     [AS_HELP_STRING([--disable-egl],
 753         [disable EGL library @<:@default=enabled@:>@])],
 754     [enable_egl="$enableval"],
 755     [enable_egl=yes])
 756
 757 AC_ARG_ENABLE([xa],
 758     [AS_HELP_STRING([--enable-xa],
 759         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 760     [enable_xa="$enableval"],
 761     [enable_xa=no])
 762 AC_ARG_ENABLE([gbm],
 763    [AS_HELP_STRING([--enable-gbm],
 764          [enable gbm library @<:@default=auto@:>@])],
 765    [enable_gbm="$enableval"],
 766    [enable_gbm=auto])
 767 AC_ARG_ENABLE([nine],
 768     [AS_HELP_STRING([--enable-nine],
 769         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 770     [enable_nine="$enableval"],
 771     [enable_nine=no])
 772
 773 AC_ARG_ENABLE([xvmc],
 774    [AS_HELP_STRING([--enable-xvmc],
 775          [enable xvmc library @<:@default=auto@:>@])],
 776    [enable_xvmc="$enableval"],
 777    [enable_xvmc=auto])
 778 AC_ARG_ENABLE([vdpau],
 779    [AS_HELP_STRING([--enable-vdpau],
 780          [enable vdpau library @<:@default=auto@:>@])],
 781    [enable_vdpau="$enableval"],
 782    [enable_vdpau=auto])
 783 AC_ARG_ENABLE([omx],
 784    [AS_HELP_STRING([--enable-omx],
 785          [enable OpenMAX library @<:@default=disabled@:>@])],
 786    [enable_omx="$enableval"],
 787    [enable_omx=no])
 788 AC_ARG_ENABLE([va],
 789    [AS_HELP_STRING([--enable-va],
 790          [enable va library @<:@default=auto@:>@])],
 791    [enable_va="$enableval"],
 792    [enable_va=auto])
 793 AC_ARG_ENABLE([opencl],
 794    [AS_HELP_STRING([--enable-opencl],
 795          [enable OpenCL library @<:@default=disabled@:>@])],
 796    [enable_opencl="$enableval"],
 797    [enable_opencl=no])
 798 AC_ARG_ENABLE([opencl_icd],
 799    [AS_HELP_STRING([--enable-opencl-icd],
 800           [Build an OpenCL ICD library to be loaded by an ICD implementation
 801            @<:@default=disabled@:>@])],
 802     [enable_opencl_icd="$enableval"],
 803     [enable_opencl_icd=no])
 804 AC_ARG_ENABLE([xlib-glx],
 805     [AS_HELP_STRING([--enable-xlib-glx],
 806         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 807     [enable_xlib_glx="$enableval"],
 808     [enable_xlib_glx=no])
 809
 810 AC_ARG_ENABLE([r600-llvm-compiler],
 811     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 812         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 813     [enable_r600_llvm="$enableval"],
 814     [enable_r600_llvm=no])
 815
 816 AC_ARG_ENABLE([gallium-tests],
 817     [AS_HELP_STRING([--enable-gallium-tests],
 818         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 819     [enable_gallium_tests="$enableval"],
 820     [enable_gallium_tests=no])
 821
 822 # Option for Gallium drivers
 823
 824 # Keep this in sync with the --with-gallium-drivers help string default value
 825 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 826
 827 AC_ARG_WITH([gallium-drivers],
 828     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 829         [comma delimited Gallium drivers list, e.g.
 830         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 831         @<:@default=r300,r600,svga,swrast@:>@])],
 832     [with_gallium_drivers="$withval"],
 833     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 834
 835 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 836 # here so that the script doesn't choke on an unknown driver name later.
 837 case "$with_gallium_drivers" in
 838     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 839     no) with_gallium_drivers='' ;;
 840 esac
 841
 842 if test "x$enable_opengl" = xno -a \
 843         "x$enable_gles1" = xno -a \
 844         "x$enable_gles2" = xno -a \
 845         "x$enable_nine" = xno -a \
 846         "x$enable_xa" = xno -a \
 847         "x$enable_xvmc" = xno -a \
 848         "x$enable_vdpau" = xno -a \
 849         "x$enable_omx" = xno -a \
 850         "x$enable_va" = xno -a \
 851         "x$enable_opencl" = xno; then
 852     AC_MSG_ERROR([at least one API should be enabled])
 853 fi
 854
 855 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 856 if test "x$enable_opengl" = xno -a \
 857         "x$enable_gles1" = xyes; then
 858     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 859 fi
 860
 861 if test "x$enable_opengl" = xno -a \
 862         "x$enable_gles2" = xyes; then
 863     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 864 fi
 865
 866 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 867 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 868 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 869 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 870                                         "x$enable_gles1" = xyes -o \
 871                                         "x$enable_gles2" = xyes)
 872
 873 if test "x$enable_glx" = xno; then
 874     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 875     enable_xlib_glx=no
 876 fi
 877
 878 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 879     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 880 fi
 881
 882 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 883     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 884 fi
 885
 886 # Disable GLX if OpenGL is not enabled
 887 if test "x$enable_glx$enable_opengl" = xyesno; then
 888     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 889     enable_glx=no
 890 fi
 891
 892 # Disable GLX if DRI and Xlib-GLX are not enabled
 893 if test "x$enable_glx" = xyes -a \
 894         "x$enable_dri" = xno -a \
 895         "x$enable_xlib_glx" = xno; then
 896     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 897     enable_glx=no
 898 fi
 899
 900 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 901                                   "x$enable_dri" = xyes)
 902
 903 # Select which platform-dependent DRI code gets built
 904 case "$host_os" in
 905 darwin*)
 906     dri_platform='apple' ;;
 907 gnu*|cygwin*)
 908     dri_platform='none' ;;
 909 *)
 910     dri_platform='drm' ;;
 911 esac
 912
 913 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 914 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 915 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 916 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 917 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 918
 919 AC_ARG_ENABLE([shared-glapi],
 920     [AS_HELP_STRING([--enable-shared-glapi],
 921         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 922     [enable_shared_glapi="$enableval"],
 923     [enable_shared_glapi=yes])
 924
 925 case "x$enable_opengl$enable_gles1$enable_gles2" in
 926 x*yes*yes*)
 927     if test "x$enable_shared_glapi" = xno; then
 928         AC_MSG_ERROR([shared GLAPI required when building two or more of
 929                       the following APIs - opengl, gles1 gles2])
 930     fi
 931     ;;
 932 esac
 933
 934 # Building Xlib-GLX requires shared glapi to be disabled.
 935 if test "x$enable_xlib_glx" = xyes; then
 936     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 937     enable_shared_glapi=no
 938 fi
 939
 940 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 941
 942 # Build the pipe-drivers as separate libraries/modules.
 943 # Do not touch this unless you know what you are doing.
 944 # XXX: Expose via configure option ?
 945 enable_shared_pipe_drivers=no
 946
 947 dnl
 948 dnl Driver specific build directories
 949 dnl
 950
 951 case "x$enable_glx$enable_xlib_glx" in
 952 xyesyes)
 953     NEED_WINSYS_XLIB="yes"
 954     ;;
 955 esac
 956
 957 if test "x$enable_dri" = xyes; then
 958     enable_gallium_loader="$enable_shared_pipe_drivers"
 959 fi
 960
 961 if test "x$enable_gallium_osmesa" = xyes; then
 962     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 963         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 964     fi
 965     if test "x$enable_osmesa" = xyes; then
 966         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 967     fi
 968 fi
 969
 970 AC_SUBST([MESA_LLVM])
 971
 972 # SHA1 hashing
 973 AC_ARG_WITH([sha1],
 974         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 975         [choose SHA1 implementation])])
 976 case "x$with_sha1" in
 977 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 978   ;;
 979 *)
 980         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 981 esac
 982
 983 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 984 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 985         with_sha1=libc
 986 fi
 987 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 988         AC_MSG_ERROR([sha1 in libc requested but not found])
 989 fi
 990 if test "x$with_sha1" = xlibc; then
 991         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 992                 [Use libc SHA1 functions])
 993         SHA1_LIBS=""
 994 fi
 995 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 996 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 997         with_sha1=CommonCrypto
 998 fi
 999 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1000         AC_MSG_ERROR([CommonCrypto requested but not found])
1001 fi
1002 if test "x$with_sha1" = xCommonCrypto; then
1003         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1004                 [Use CommonCrypto SHA1 functions])
1005         SHA1_LIBS=""
1006 fi
1007 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1008 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1009 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1010         with_sha1=CryptoAPI
1011 fi
1012 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1013         AC_MSG_ERROR([CryptoAPI requested but not found])
1014 fi
1015 if test "x$with_sha1" = xCryptoAPI; then
1016         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1017                 [Use CryptoAPI SHA1 functions])
1018         SHA1_LIBS=""
1019 fi
1020 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1021 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1022         with_sha1=libmd
1023 fi
1024 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1025         AC_MSG_ERROR([libmd requested but not found])
1026 fi
1027 if test "x$with_sha1" = xlibmd; then
1028         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1029                   [Use libmd SHA1 functions])
1030         SHA1_LIBS=-lmd
1031 fi
1032 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1033 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1034    with_sha1=libsha1
1035 fi
1036 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1037         AC_MSG_ERROR([libsha1 requested but not found])
1038 fi
1039 if test "x$with_sha1" = xlibsha1; then
1040         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1041                   [Use libsha1 for SHA1])
1042         SHA1_LIBS=-lsha1
1043 fi
1044 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1045 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1046         with_sha1=libnettle
1047 fi
1048 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1049         AC_MSG_ERROR([libnettle requested but not found])
1050 fi
1051 if test "x$with_sha1" = xlibnettle; then
1052         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1053                   [Use libnettle SHA1 functions])
1054         SHA1_LIBS=-lnettle
1055 fi
1056 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1057 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1058         with_sha1=libgcrypt
1059 fi
1060 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1061         AC_MSG_ERROR([libgcrypt requested but not found])
1062 fi
1063 if test "x$with_sha1" = xlibgcrypt; then
1064         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1065                   [Use libgcrypt SHA1 functions])
1066         SHA1_LIBS=-lgcrypt
1067 fi
1068 # We don't need all of the OpenSSL libraries, just libcrypto
1069 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1070 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1071                   [HAVE_OPENSSL_PKC=no])
1072 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1073         if test "x$with_sha1" = x; then
1074                 with_sha1=libcrypto
1075         fi
1076 else
1077         if test "x$with_sha1" = xlibcrypto; then
1078                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1079         fi
1080 fi
1081 if test "x$with_sha1" = xlibcrypto; then
1082         if test "x$HAVE_LIBCRYPTO" = xyes; then
1083                 SHA1_LIBS=-lcrypto
1084         else
1085                 SHA1_LIBS="$OPENSSL_LIBS"
1086                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1087         fi
1088 fi
1089 AC_MSG_CHECKING([for SHA1 implementation])
1090 AC_MSG_RESULT([$with_sha1])
1091 AC_SUBST(SHA1_LIBS)
1092 AC_SUBST(SHA1_CFLAGS)
1093
1094 # Allow user to configure out the shader-cache feature
1095 AC_ARG_ENABLE([shader-cache],
1096     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1097     [enable_shader_cache="$enableval"],
1098     [if test "x$with_sha1" != "x"; then
1099         enable_shader_cache=yes
1100      else
1101         enable_shader_cache=no
1102      fi])
1103 if test "x$with_sha1" = "x"; then
1104     if test "x$enable_shader_cache" = "xyes"; then
1105         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1106     fi
1107 fi
1108 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1109
1110 # Check for libdrm
1111 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1112                   [have_libdrm=yes], [have_libdrm=no])
1113 if test "x$have_libdrm" = xyes; then
1114         DEFINES="$DEFINES -DHAVE_LIBDRM"
1115 fi
1116
1117 case "$host_os" in
1118 linux*)
1119     need_pci_id=yes ;;
1120 *)
1121     need_pci_id=no ;;
1122 esac
1123
1124 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1125                   have_libudev=yes, have_libudev=no)
1126
1127 AC_ARG_ENABLE([sysfs],
1128     [AS_HELP_STRING([--enable-sysfs],
1129         [enable /sys PCI identification @<:@default=disabled@:>@])],
1130     [have_sysfs="$enableval"],
1131     [have_sysfs=no]
1132 )
1133
1134 if test "x$enable_dri" = xyes; then
1135     if test "$enable_static" = yes; then
1136         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1137     fi
1138
1139     # not a hard requirement as swrast does not depend on it
1140     if test "x$have_libdrm" = xyes; then
1141         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1142     fi
1143 fi
1144
1145 AC_ARG_ENABLE([driglx-direct],
1146     [AS_HELP_STRING([--disable-driglx-direct],
1147         [disable direct rendering in GLX and EGL for DRI \
1148             @<:@default=auto@:>@])],
1149     [driglx_direct="$enableval"],
1150     [driglx_direct="yes"])
1151
1152 dnl
1153 dnl libGL configuration per driver
1154 dnl
1155 case "x$enable_glx$enable_xlib_glx" in
1156 xyesyes)
1157     # Xlib-based GLX
1158     dri_modules="x11 xext xcb"
1159     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1160     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1161     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1162     GL_LIB_DEPS="$XLIBGL_LIBS"
1163     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1164     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1165     ;;
1166 xyesno)
1167     # DRI-based GLX
1168     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1169
1170     # find the DRI deps for libGL
1171     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1172
1173     if test x"$driglx_direct" = xyes; then
1174         if test x"$dri_platform" = xdrm ; then
1175             DEFINES="$DEFINES -DGLX_USE_DRM"
1176             if test "x$have_libdrm" != xyes; then
1177                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1178             fi
1179
1180             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1181             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1182             if test x"$enable_dri3" = xyes; then
1183                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1184                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1185             fi
1186
1187             if test x"$enable_dri" = xyes; then
1188                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1189             fi
1190
1191             if test x"$enable_dri3" = xyes; then
1192                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1193                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1194             fi
1195         fi
1196         if test x"$dri_platform" = xapple ; then
1197             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1198         fi
1199     fi
1200
1201     # add xf86vidmode if available
1202     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1203     if test "$HAVE_XF86VIDMODE" = yes ; then
1204         dri_modules="$dri_modules xxf86vm"
1205     fi
1206
1207     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1208     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1209     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1210     GL_LIB_DEPS="$DRIGL_LIBS"
1211
1212     # need DRM libs, $PTHREAD_LIBS, etc.
1213     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1214     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1215     ;;
1216 esac
1217
1218 have_pci_id=no
1219 if test "$have_libudev" = yes; then
1220     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1221     have_pci_id=yes
1222 fi
1223
1224 if test "$have_sysfs" = yes; then
1225     DEFINES="$DEFINES -DHAVE_SYSFS"
1226     have_pci_id=yes
1227 fi
1228
1229 # This is outside the case (above) so that it is invoked even for non-GLX
1230 # builds.
1231 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1232
1233 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1234 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1235 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1236 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1237
1238 AC_SUBST([X11_INCLUDES])
1239 AC_SUBST([GL_LIB_DEPS])
1240 AC_SUBST([GL_PC_REQ_PRIV])
1241 AC_SUBST([GL_PC_LIB_PRIV])
1242 AC_SUBST([GL_PC_CFLAGS])
1243 AC_SUBST([DRI_PC_REQ_PRIV])
1244 AC_SUBST([GLESv1_CM_LIB_DEPS])
1245 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1246 AC_SUBST([GLESv2_LIB_DEPS])
1247 AC_SUBST([GLESv2_PC_LIB_PRIV])
1248
1249 AC_SUBST([HAVE_XF86VIDMODE])
1250
1251 dnl
1252 dnl More GLX setup
1253 dnl
1254 case "x$enable_glx$enable_xlib_glx" in
1255 xyesyes)
1256     DEFINES="$DEFINES -DUSE_XSHM"
1257     ;;
1258 xyesno)
1259     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1260     if test "x$driglx_direct" = xyes; then
1261         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1262     fi
1263     ;;
1264 esac
1265
1266 dnl
1267 dnl TLS detection
1268 dnl
1269
1270 AC_ARG_ENABLE([glx-tls],
1271     [AS_HELP_STRING([--enable-glx-tls],
1272         [enable TLS support in GLX @<:@default=disabled@:>@])],
1273     [GLX_USE_TLS="$enableval"],
1274     [GLX_USE_TLS=no])
1275 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1276
1277 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1278       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1279
1280 dnl
1281 dnl More DRI setup
1282 dnl
1283 dnl Directory for DRI drivers
1284 AC_ARG_WITH([dri-driverdir],
1285     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1286         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1287     [DRI_DRIVER_INSTALL_DIR="$withval"],
1288     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1289 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1290 dnl Extra search path for DRI drivers
1291 AC_ARG_WITH([dri-searchpath],
1292     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1293         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1294     [DRI_DRIVER_SEARCH_DIR="$withval"],
1295     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1296 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1297 dnl Which drivers to build - default is chosen by platform
1298 AC_ARG_WITH([dri-drivers],
1299     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1300         [comma delimited classic DRI drivers list, e.g.
1301         "swrast,i965,radeon" @<:@default=auto@:>@])],
1302     [with_dri_drivers="$withval"],
1303     [with_dri_drivers=auto])
1304
1305 if test "x$with_dri_drivers" = xauto; then
1306     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1307         with_dri_drivers="yes"
1308     else
1309         with_dri_drivers="no"
1310     fi
1311 fi
1312 if test "x$with_dri_drivers" = xno; then
1313     with_dri_drivers=''
1314 fi
1315
1316 dnl If $with_dri_drivers is yes, drivers will be added through
1317 dnl platform checks. Set DEFINES and LIB_DEPS
1318 if test "x$enable_dri" = xyes; then
1319     # Platform specific settings and drivers to build
1320     case "$host_os" in
1321     linux*)
1322         DEFINES="$DEFINES -DHAVE_ALIAS"
1323         if test "x$enable_dri3" = xyes; then
1324             DEFINES="$DEFINES -DHAVE_DRI3"
1325         fi
1326
1327         if test "x$have_pci_id" != xyes; then
1328             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1329         fi
1330
1331         case "$host_cpu" in
1332         powerpc* | sparc*)
1333             # Build only the drivers for cards that exist on PowerPC/sparc
1334             if test "x$with_dri_drivers" = "xyes"; then
1335                 with_dri_drivers="r200 radeon swrast"
1336             fi
1337             ;;
1338         esac
1339         ;;
1340     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1341         DEFINES="$DEFINES -DHAVE_ALIAS"
1342         ;;
1343     gnu*)
1344         DEFINES="$DEFINES -DHAVE_ALIAS"
1345         ;;
1346     cygwin*)
1347         if test "x$with_dri_drivers" = "xyes"; then
1348             with_dri_drivers="swrast"
1349         fi
1350         ;;
1351     darwin*)
1352         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1353         if test "x$with_dri_drivers" = "xyes"; then
1354             with_dri_drivers="swrast"
1355         fi
1356         ;;
1357     esac
1358
1359     # default drivers
1360     if test "x$with_dri_drivers" = "xyes"; then
1361         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1362     fi
1363
1364     # Check for expat
1365     PKG_CHECK_MODULES([EXPAT], [expat], [],
1366         # expat version 2.0 and earlier do not provide expat.pc
1367         [AC_CHECK_HEADER([expat.h],[],
1368                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1369          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1370                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1371          EXPAT_LIBS="-lexpat"])
1372
1373     DRICOMMON_NEED_LIBDRM=no
1374     # If we are building any DRI driver other than swrast.
1375     if test -n "$with_dri_drivers"; then
1376         if test "x$with_dri_drivers" != xswrast; then
1377             # ... libdrm is required
1378             if test "x$have_libdrm" != xyes; then
1379                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1380             fi
1381             DRICOMMON_NEED_LIBDRM=yes
1382         fi
1383     fi
1384
1385     # If we're building any gallium DRI driver other than swrast
1386     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1387         if test "x$with_gallium_drivers" != xswrast; then
1388             # ... build a libdrm aware dricommon
1389             DRICOMMON_NEED_LIBDRM=yes
1390         fi
1391     fi
1392
1393     # put all the necessary libs together
1394     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1395 fi
1396
1397 AC_SUBST([DRI_LIB_DEPS])
1398
1399 DRI_DIRS=''
1400 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1401 if test -n "$with_dri_drivers"; then
1402     if test "x$enable_opengl" != xyes; then
1403         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1404     fi
1405
1406     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1407     for driver in $dri_drivers; do
1408         DRI_DIRS="$DRI_DIRS $driver"
1409         case "x$driver" in
1410         xi915)
1411             HAVE_I915_DRI=yes;
1412             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1413             ;;
1414         xi965)
1415             HAVE_I965_DRI=yes;
1416             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1417             ;;
1418         xnouveau)
1419             HAVE_NOUVEAU_DRI=yes;
1420             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1421             ;;
1422         xradeon)
1423             HAVE_RADEON_DRI=yes;
1424             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1425             ;;
1426         xr200)
1427             HAVE_R200_DRI=yes;
1428             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1429             ;;
1430         xswrast)
1431             HAVE_SWRAST_DRI=yes;
1432             ;;
1433         *)
1434             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1435             ;;
1436         esac
1437     done
1438     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1439 fi
1440
1441 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1442 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1443                                   "x$enable_osmesa" = xyes -o \
1444                                   -n "$DRI_DIRS")
1445
1446 dnl
1447 dnl OSMesa configuration
1448 dnl
1449
1450 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1451 AC_ARG_WITH([osmesa-bits],
1452     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1453         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1454     [osmesa_bits="$withval"],
1455     [osmesa_bits=8])
1456 if test "x$osmesa_bits" != x8; then
1457     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1458         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1459         osmesa_bits=8
1460     fi
1461 fi
1462 case "x$osmesa_bits" in
1463 x8)
1464     OSMESA_LIB="${OSMESA_LIB}"
1465     ;;
1466 x16|x32)
1467     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1468     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1469     ;;
1470 *)
1471     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1472     ;;
1473 esac
1474
1475 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1476     # only link libraries with osmesa if shared
1477     if test "$enable_static" = no; then
1478         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1479     else
1480         OSMESA_LIB_DEPS=""
1481     fi
1482     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1483 fi
1484
1485 AC_SUBST([OSMESA_LIB_DEPS])
1486 AC_SUBST([OSMESA_PC_REQ])
1487 AC_SUBST([OSMESA_PC_LIB_PRIV])
1488
1489 dnl
1490 dnl gbm configuration
1491 dnl
1492 if test "x$enable_gbm" = xauto; then
1493     case "$with_egl_platforms" in
1494         *drm*)
1495             enable_gbm=yes ;;
1496          *)
1497             enable_gbm=no ;;
1498     esac
1499 fi
1500 if test "x$enable_gbm" = xyes; then
1501     if test "x$need_pci_id$have_pci_id" = xyesno; then
1502         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1503     fi
1504
1505     if test "x$enable_dri" = xyes; then
1506         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1507         if test "x$enable_shared_glapi" = xno; then
1508             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1509         fi
1510     else
1511         # Strictly speaking libgbm does not require --enable-dri, although
1512         # both of its backends do. Thus one can build libgbm without any
1513         # backends if --disable-dri is set.
1514         # To avoid unnecessary complexity of checking if at least one backend
1515         # is available when building, just mandate --enable-dri.
1516         AC_MSG_ERROR([gbm requires --enable-dri])
1517     fi
1518 fi
1519 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1520 if test "x$need_pci_id$have_libudev" = xyesyes; then
1521     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1522 else
1523     GBM_PC_REQ_PRIV=""
1524 fi
1525 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1526 AC_SUBST([GBM_PC_REQ_PRIV])
1527 AC_SUBST([GBM_PC_LIB_PRIV])
1528
1529 dnl
1530 dnl EGL configuration
1531 dnl
1532 EGL_CLIENT_APIS=""
1533
1534 if test "x$enable_egl" = xyes; then
1535     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1536
1537     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1538
1539     if test "$enable_static" != yes; then
1540         if test "x$enable_dri" = xyes; then
1541             HAVE_EGL_DRIVER_DRI2=1
1542         fi
1543
1544     fi
1545 fi
1546 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1547 AC_SUBST([EGL_LIB_DEPS])
1548
1549 dnl
1550 dnl XA configuration
1551 dnl
1552 if test "x$enable_xa" = xyes; then
1553     if test "x$with_gallium_drivers" = xswrast; then
1554        AC_MSG_ERROR([
1555           Building xa requires at least one non swrast gallium driver.
1556           If you are looking to use libxatracker.so with the VMware driver,
1557           make sure to include svga in the gallium drivers list, apart from
1558           enabling XA.
1559           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1560     fi
1561     enable_gallium_loader=$enable_shared_pipe_drivers
1562 fi
1563 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1564
1565 dnl
1566 dnl Gallium G3DVL configuration
1567 dnl
1568 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1569     if test "x$enable_xvmc" = xauto; then
1570         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1571     fi
1572
1573     if test "x$enable_vdpau" = xauto; then
1574         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1575     fi
1576
1577     if test "x$enable_omx" = xauto; then
1578         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1579     fi
1580
1581     if test "x$enable_va" = xauto; then
1582         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1583     fi
1584 fi
1585
1586 if test "x$enable_dri" = xyes -o \
1587         "x$enable_xvmc" = xyes -o \
1588         "x$enable_vdpau" = xyes -o \
1589         "x$enable_omx" = xyes -o \
1590         "x$enable_va" = xyes; then
1591     need_gallium_vl=yes
1592 fi
1593 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1594
1595 if test "x$enable_xvmc" = xyes -o \
1596         "x$enable_vdpau" = xyes -o \
1597         "x$enable_omx" = xyes -o \
1598         "x$enable_va" = xyes; then
1599     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1600     need_gallium_vl_winsys=yes
1601 fi
1602 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1603
1604 if test "x$enable_xvmc" = xyes; then
1605     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1606     enable_gallium_loader=$enable_shared_pipe_drivers
1607 fi
1608 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1609
1610 if test "x$enable_vdpau" = xyes; then
1611     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1612     enable_gallium_loader=$enable_shared_pipe_drivers
1613 fi
1614 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1615
1616 if test "x$enable_omx" = xyes; then
1617     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1618     enable_gallium_loader=$enable_shared_pipe_drivers
1619 fi
1620 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1621
1622 if test "x$enable_va" = xyes; then
1623     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1624     enable_gallium_loader=$enable_shared_pipe_drivers
1625 fi
1626 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1627
1628 dnl
1629 dnl Nine Direct3D9 configuration
1630 dnl
1631 if test "x$enable_nine" = xyes; then
1632     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1633         AC_MSG_ERROR([nine requires the gallium swrast driver])
1634     fi
1635     if test "x$with_gallium_drivers" == xswrast; then
1636         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1637     fi
1638     if test "x$enable_dri3" = xno; then
1639         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1640     fi
1641
1642     enable_gallium_loader=$enable_shared_pipe_drivers
1643 fi
1644 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1645
1646 dnl
1647 dnl OpenCL configuration
1648 dnl
1649
1650 AC_ARG_WITH([libclc-path],
1651    [AS_HELP_STRING([--with-libclc-path],
1652          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1653    [LIBCLC_PATH="$withval"],
1654    [LIBCLC_PATH=''])
1655
1656 if test -n "$LIBCLC_PATH"; then
1657    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1658                   Please review the updated build instructions for clover:
1659                   http://dri.freedesktop.org/wiki/GalliumCompute])
1660 fi
1661
1662
1663 AC_ARG_WITH([clang-libdir],
1664    [AS_HELP_STRING([--with-clang-libdir],
1665          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1666    [CLANG_LIBDIR="$withval"],
1667    [CLANG_LIBDIR=''])
1668
1669 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1670 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1671
1672 if test "x$enable_opencl" = xyes; then
1673     if test -z "$with_gallium_drivers"; then
1674         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1675     fi
1676
1677     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1678         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1679     fi
1680
1681     if test "x$have_libclc" = xno; then
1682         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1683                     Make sure the directory containing libclc.pc is specified in your
1684                     PKG_CONFIG_PATH environment variable.
1685                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1686     else
1687         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1688         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1689         AC_SUBST([LIBCLC_INCLUDEDIR])
1690         AC_SUBST([LIBCLC_LIBEXECDIR])
1691     fi
1692
1693     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1694     enable_gallium_loader=yes
1695
1696     if test "x$enable_opencl_icd" = xyes; then
1697         OPENCL_LIBNAME="MesaOpenCL"
1698     else
1699         OPENCL_LIBNAME="OpenCL"
1700     fi
1701
1702     if test "x$have_libelf" != xyes; then
1703        AC_MSG_ERROR([Clover requires libelf])
1704     fi
1705 fi
1706 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1707 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1708 AC_SUBST([OPENCL_LIBNAME])
1709
1710 dnl
1711 dnl Gallium configuration
1712 dnl
1713 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1714
1715 AC_SUBST([LLVM_BINDIR])
1716 AC_SUBST([LLVM_CFLAGS])
1717 AC_SUBST([LLVM_CPPFLAGS])
1718 AC_SUBST([LLVM_CXXFLAGS])
1719 AC_SUBST([LLVM_LIBDIR])
1720 AC_SUBST([LLVM_LIBS])
1721 AC_SUBST([LLVM_LDFLAGS])
1722 AC_SUBST([LLVM_INCLUDEDIR])
1723 AC_SUBST([LLVM_VERSION])
1724 AC_SUBST([CLANG_RESOURCE_DIR])
1725
1726 case "x$enable_opengl$enable_gles1$enable_gles2" in
1727 x*yes*)
1728     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1729     ;;
1730 esac
1731
1732 AC_SUBST([VG_LIB_DEPS])
1733 AC_SUBST([EGL_CLIENT_APIS])
1734
1735 dnl
1736 dnl EGL Platforms configuration
1737 dnl
1738 AC_ARG_WITH([egl-platforms],
1739     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1740         [comma delimited native platforms libEGL supports, e.g.
1741         "x11,drm" @<:@default=auto@:>@])],
1742     [with_egl_platforms="$withval"],
1743     [if test "x$enable_egl" = xyes; then
1744         with_egl_platforms="x11"
1745     else
1746         with_egl_platforms=""
1747     fi])
1748
1749 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1750     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1751 fi
1752
1753 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1754         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1755         WAYLAND_SCANNER='')
1756 if test "x$WAYLAND_SCANNER" = x; then
1757     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1758 fi
1759
1760 # Do per-EGL platform setups and checks
1761 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1762 for plat in $egl_platforms; do
1763         case "$plat" in
1764         wayland)
1765                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1766
1767                 if test "x$WAYLAND_SCANNER" = x; then
1768                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1769                 fi
1770                 ;;
1771
1772         x11)
1773                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1774                 ;;
1775
1776         drm)
1777                 test "x$enable_gbm" = "xno" &&
1778                         AC_MSG_ERROR([EGL platform drm needs gbm])
1779                 test "x$have_libdrm" != xyes &&
1780                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1781                 ;;
1782
1783         android|gdi|null)
1784                 ;;
1785
1786         *)
1787                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1788                 ;;
1789         esac
1790
1791         case "$plat$need_pci_id$have_pci_id" in
1792                 waylandyesno|drmyesno)
1793                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1794         esac
1795 done
1796
1797 # libEGL wants to default to the first platform specified in
1798 # ./configure.  parse that here.
1799 if test "x$egl_platforms" != "x"; then
1800     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1801     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1802 else
1803     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1804 fi
1805
1806 if echo "$egl_platforms" | grep -q 'x11'; then
1807     NEED_WINSYS_XLIB=yes
1808 fi
1809 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1810 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1811 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1812 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1813
1814 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1815
1816 AC_SUBST([EGL_NATIVE_PLATFORM])
1817 AC_SUBST([EGL_CFLAGS])
1818
1819 # If we don't have the X11 platform, set this define so we don't try to include
1820 # the X11 headers.
1821 if ! echo "$egl_platforms" | grep -q 'x11'; then
1822     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1823     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1824 fi
1825
1826 AC_ARG_WITH([max-width],
1827     [AS_HELP_STRING([--with-max-width=N],
1828                     [Maximum framebuffer width (4096)])],
1829     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1830      AS_IF([test "${withval}" -gt "4096"],
1831            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1832 )
1833 AC_ARG_WITH([max-height],
1834     [AS_HELP_STRING([--with-max-height=N],
1835                     [Maximum framebuffer height (4096)])],
1836     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1837      AS_IF([test "${withval}" -gt "4096"],
1838            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1839 )
1840
1841 dnl
1842 dnl Gallium LLVM
1843 dnl
1844 AC_ARG_ENABLE([gallium-llvm],
1845     [AS_HELP_STRING([--enable-gallium-llvm],
1846         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1847     [enable_gallium_llvm="$enableval"],
1848     [enable_gallium_llvm=auto])
1849
1850 AC_ARG_ENABLE([llvm-shared-libs],
1851     [AS_HELP_STRING([--enable-llvm-shared-libs],
1852         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1853     [enable_llvm_shared_libs="$enableval"],
1854     [enable_llvm_shared_libs=yes])
1855
1856 AC_ARG_WITH([llvm-prefix],
1857     [AS_HELP_STRING([--with-llvm-prefix],
1858         [Prefix for LLVM installations in non-standard locations])],
1859     [llvm_prefix="$withval"],
1860     [llvm_prefix=''])
1861
1862
1863 # Call this inside ` ` to get the return value.
1864 # $1 is the llvm-config command with arguments.
1865 strip_unwanted_llvm_flags() {
1866     # Use \> (marks the end of the word)
1867     echo `$1` | sed \
1868         -e 's/-DNDEBUG\>//g' \
1869         -e 's/-D_GNU_SOURCE\>//g' \
1870         -e 's/-pedantic\>//g' \
1871         -e 's/-Wcovered-switch-default\>//g' \
1872         -e 's/-O.\>//g' \
1873         -e 's/-g\>//g' \
1874         -e 's/-Wall\>//g' \
1875         -e 's/-Wcast-qual\>//g' \
1876         -e 's/-Woverloaded-virtual\>//g' \
1877         -e 's/-fcolor-diagnostics\>//g' \
1878         -e 's/-fdata-sections\>//g' \
1879         -e 's/-ffunction-sections\>//g' \
1880         -e 's/-fno-exceptions\>//g' \
1881         -e 's/-fomit-frame-pointer\>//g' \
1882         -e 's/-fvisibility-inlines-hidden\>//g' \
1883         -e 's/-fPIC\>//g' \
1884         -e 's/-fstack-protector-strong\>//g'
1885 }
1886
1887
1888 if test -z "$with_gallium_drivers"; then
1889     enable_gallium_llvm=no
1890 fi
1891 if test "x$enable_gallium_llvm" = xauto; then
1892     case "$host_cpu" in
1893     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1894     esac
1895 fi
1896 if test "x$enable_gallium_llvm" = xyes; then
1897     if test -n "$llvm_prefix"; then
1898         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1899     else
1900         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1901     fi
1902
1903     if test "x$LLVM_CONFIG" != xno; then
1904         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1905         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1906         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1907         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1908         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1909         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1910         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1911         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1912
1913         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1914             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1915         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1916             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1917
1918         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1919         if test -z "$LLVM_VERSION_PATCH"; then
1920             LLVM_VERSION_PATCH=0
1921         fi
1922
1923         if test -n "${LLVM_VERSION_MAJOR}"; then
1924             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1925         else
1926             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1927         fi
1928
1929         LLVM_REQUIRED_VERSION_MAJOR="3"
1930         LLVM_REQUIRED_VERSION_MINOR="3"
1931         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1932             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1933         fi
1934
1935         LLVM_COMPONENTS="engine bitwriter"
1936         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1937             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1938         fi
1939
1940         if test "x$enable_opencl" = xyes; then
1941             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1942             # LLVM 3.3 >= 177971 requires IRReader
1943             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1944                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1945             fi
1946             # LLVM 3.4 requires Option
1947             if $LLVM_CONFIG --components | grep -qw 'option'; then
1948                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1949             fi
1950             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1951             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1952                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1953             fi
1954             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1955                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1956             fi
1957         fi
1958         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1959         MESA_LLVM=1
1960
1961         dnl Check for Clang internal headers
1962         if test "x$enable_opencl" = xyes; then
1963             if test -z "$CLANG_LIBDIR"; then
1964                 CLANG_LIBDIR=${LLVM_LIBDIR}
1965             fi
1966             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1967             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1968                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1969         fi
1970     else
1971         MESA_LLVM=0
1972         LLVM_VERSION_INT=0
1973     fi
1974 else
1975     MESA_LLVM=0
1976     LLVM_VERSION_INT=0
1977
1978     if test "x$enable_opencl" = xyes; then
1979         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1980     fi
1981 fi
1982
1983 dnl Directory for XVMC libs
1984 AC_ARG_WITH([xvmc-libdir],
1985     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1986         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1987     [XVMC_LIB_INSTALL_DIR="$withval"],
1988     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1989 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1990
1991 dnl
1992 dnl Gallium Tests
1993 dnl
1994 if test "x$enable_gallium_tests" = xyes; then
1995     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1996     enable_gallium_loader=yes
1997 fi
1998 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1999
2000 dnl Directory for VDPAU libs
2001 AC_ARG_WITH([vdpau-libdir],
2002     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2003         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2004     [VDPAU_LIB_INSTALL_DIR="$withval"],
2005     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2006 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2007
2008 dnl Directory for OMX libs
2009
2010 AC_ARG_WITH([omx-libdir],
2011     [AS_HELP_STRING([--with-omx-libdir=DIR],
2012         [directory for the OMX libraries])],
2013     [OMX_LIB_INSTALL_DIR="$withval"],
2014     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2015 AC_SUBST([OMX_LIB_INSTALL_DIR])
2016
2017 dnl Directory for VA libs
2018
2019 AC_ARG_WITH([va-libdir],
2020     [AS_HELP_STRING([--with-va-libdir=DIR],
2021         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2022     [VA_LIB_INSTALL_DIR="$withval"],
2023     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2024 AC_SUBST([VA_LIB_INSTALL_DIR])
2025
2026 AC_ARG_WITH([d3d-libdir],
2027     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2028         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2029     [D3D_DRIVER_INSTALL_DIR="$withval"],
2030     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2031 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2032
2033 dnl
2034 dnl Gallium helper functions
2035 dnl
2036 gallium_require_drm() {
2037     if test "x$have_libdrm" != xyes; then
2038        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2039     fi
2040 }
2041
2042 gallium_require_llvm() {
2043     if test "x$MESA_LLVM" = x0; then
2044         case "$host" in *gnux32) return;; esac
2045         case "$host_cpu" in
2046         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2047         esac
2048     fi
2049 }
2050
2051 gallium_require_drm_loader() {
2052     if test "x$enable_gallium_loader" = xyes; then
2053         if test "x$need_pci_id$have_pci_id" = xyesno; then
2054             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2055         fi
2056         enable_gallium_drm_loader=yes
2057     fi
2058     if test "x$enable_va" = xyes && test "x$7" != x; then
2059          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2060     fi
2061 }
2062
2063 require_egl_drm() {
2064     case "$with_egl_platforms" in
2065         *drm*)
2066             ;;
2067          *)
2068             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2069             ;;
2070     esac
2071     if test "x$enable_gbm" != xyes; then
2072             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2073     fi
2074 }
2075
2076 radeon_llvm_check() {
2077     if test "x$enable_gallium_llvm" != "xyes"; then
2078         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2079     fi
2080     LLVM_REQUIRED_VERSION_MAJOR="3"
2081     LLVM_REQUIRED_VERSION_MINOR="4"
2082     LLVM_REQUIRED_VERSION_PATCH="2"
2083     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2084         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2085     fi
2086     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2087         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2088                       sources with the --enable-experimental-targets=R600
2089                       configure flag])
2090     fi
2091     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2092     NEED_RADEON_LLVM=yes
2093     if test "x$have_libelf" != xyes; then
2094        AC_MSG_ERROR([$1 requires libelf when using llvm])
2095     fi
2096 }
2097
2098 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2099 if test -n "$with_gallium_drivers"; then
2100     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2101     for driver in $gallium_drivers; do
2102         case "x$driver" in
2103         xsvga)
2104             HAVE_GALLIUM_SVGA=yes
2105             gallium_require_drm "svga"
2106             gallium_require_drm_loader
2107             ;;
2108         xi915)
2109             HAVE_GALLIUM_I915=yes
2110             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2111             gallium_require_drm "Gallium i915"
2112             gallium_require_drm_loader
2113             ;;
2114         xilo)
2115             HAVE_GALLIUM_ILO=yes
2116             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2117             gallium_require_drm "Gallium i965/ilo"
2118             gallium_require_drm_loader
2119             ;;
2120         xr300)
2121             HAVE_GALLIUM_R300=yes
2122             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2123             gallium_require_drm "Gallium R300"
2124             gallium_require_drm_loader
2125             gallium_require_llvm "Gallium R300"
2126             ;;
2127         xr600)
2128             HAVE_GALLIUM_R600=yes
2129             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2130             gallium_require_drm "Gallium R600"
2131             gallium_require_drm_loader
2132             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2133                 radeon_llvm_check "r600g"
2134                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2135             fi
2136             if test "x$enable_r600_llvm" = xyes; then
2137                 USE_R600_LLVM_COMPILER=yes;
2138             fi
2139             if test "x$enable_opencl" = xyes; then
2140                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2141             fi
2142             ;;
2143         xradeonsi)
2144             HAVE_GALLIUM_RADEONSI=yes
2145             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2146             gallium_require_drm "radeonsi"
2147             gallium_require_drm_loader
2148             radeon_llvm_check "radeonsi"
2149             require_egl_drm "radeonsi"
2150             ;;
2151         xnouveau)
2152             HAVE_GALLIUM_NOUVEAU=yes
2153             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2154             gallium_require_drm "nouveau"
2155             gallium_require_drm_loader
2156             ;;
2157         xfreedreno)
2158             HAVE_GALLIUM_FREEDRENO=yes
2159             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2160             gallium_require_drm "freedreno"
2161             gallium_require_drm_loader
2162             ;;
2163         xswrast)
2164             HAVE_GALLIUM_SOFTPIPE=yes
2165             if test "x$MESA_LLVM" = x1; then
2166                 HAVE_GALLIUM_LLVMPIPE=yes
2167             fi
2168             ;;
2169         xvc4)
2170             HAVE_GALLIUM_VC4=yes
2171             gallium_require_drm "vc4"
2172             gallium_require_drm_loader
2173
2174             case "$host_cpu" in
2175                 i?86 | x86_64 | amd64)
2176                 USE_VC4_SIMULATOR=yes
2177                 ;;
2178             esac
2179             ;;
2180         *)
2181             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2182             ;;
2183         esac
2184     done
2185 fi
2186
2187 dnl Set LLVM_LIBS - This is done after the driver configuration so
2188 dnl that drivers can add additional components to LLVM_COMPONENTS.
2189 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2190 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2191 dnl this was causing the same libraries to be appear multiple times
2192 dnl in LLVM_LIBS.
2193
2194 if test "x$MESA_LLVM" != x0; then
2195
2196     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2197
2198     if test "x$enable_llvm_shared_libs" = xyes; then
2199         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2200         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2201         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2202
2203         if test "x$llvm_have_one_so" = xyes; then
2204             dnl LLVM was built using auto*, so there is only one shared object.
2205             LLVM_LIBS="-l$LLVM_SO_NAME"
2206         else
2207             dnl If LLVM was built with CMake, there will be one shared object per
2208             dnl component.
2209             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2210                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2211         Please make sure you have built llvm with the --enable-shared option
2212         and that your llvm libraries are installed in $LLVM_LIBDIR
2213         If you have installed your llvm libraries to a different directory you
2214         can use the --with-llvm-prefix= configure flag to specify this directory.
2215         NOTE: Mesa is attempting to use llvm shared libraries by default.
2216         If you do not want to build with llvm shared libraries and instead want to
2217         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2218         invocation and rebuild.])])
2219
2220            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2221            dnl install uses a shared object for each component and we have
2222            dnl already added all of these objects to LLVM_LIBS.
2223         fi
2224     else
2225         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2226         dnl We need to link to llvm system libs when using static libs
2227         dnl However, only llvm 3.5+ provides --system-libs
2228         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2229             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2230         fi
2231     fi
2232 fi
2233
2234 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2235 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2236 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2237 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2238 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2239 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2240 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2241                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2242 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2243 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2244 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2245 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2246 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2247
2248 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2249
2250 # NOTE: anything using xcb or other client side libs ends up in separate
2251 #       _CLIENT variables.  The pipe loader is built in two variants,
2252 #       one that is standalone and does not link any x client libs (for
2253 #       use by XA tracker in particular, but could be used in any case
2254 #       where communication with xserver is not desired).
2255 if test "x$enable_gallium_loader" = xyes; then
2256     if test "x$NEED_WINSYS_XLIB" = xyes; then
2257         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2258     fi
2259
2260     if test "x$enable_dri" = xyes; then
2261         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2262     fi
2263
2264     if test "x$enable_gallium_drm_loader" = xyes; then
2265         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2266         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2267                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2268         if test "x$pipe_loader_have_xcb" = xyes; then
2269             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2270             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2271         fi
2272     fi
2273
2274     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2275     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2276
2277     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2278     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2279     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2280     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2281 fi
2282
2283 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2284 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2285 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2286 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2287 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2288 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2289
2290 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2291                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2292                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2293 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2294 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2295 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2296 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2297 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2298 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2299 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2300 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2301 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2302     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2303 fi
2304
2305 AC_SUBST([ELF_LIB])
2306
2307 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2308 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2309 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2310 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2311 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2312
2313 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2314 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2315 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2316
2317 AC_SUBST([NINE_MAJOR], 1)
2318 AC_SUBST([NINE_MINOR], 0)
2319 AC_SUBST([NINE_TINY], 0)
2320 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2321
2322 AC_SUBST([VDPAU_MAJOR], 1)
2323 AC_SUBST([VDPAU_MINOR], 0)
2324
2325 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2326 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2327 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2328 AC_SUBST([VA_MINOR], $VA_MINOR)
2329
2330 AC_SUBST([XVMC_MAJOR], 1)
2331 AC_SUBST([XVMC_MINOR], 0)
2332
2333 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2334 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2335 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2336 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2337
2338 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2339 AC_SUBST([XA_MINOR], $XA_MINOR)
2340 AC_SUBST([XA_TINY], $XA_TINY)
2341 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2342
2343 dnl Restore LDFLAGS and CPPFLAGS
2344 LDFLAGS="$_SAVE_LDFLAGS"
2345 CPPFLAGS="$_SAVE_CPPFLAGS"
2346
2347 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2348 if test "x$acv_mesa_CLANG" = xyes; then
2349     CFLAGS="$CFLAGS -Qunused-arguments"
2350     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2351 fi
2352
2353 dnl Add user CFLAGS and CXXFLAGS
2354 CFLAGS="$CFLAGS $USER_CFLAGS"
2355 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2356
2357 dnl Substitute the config
2358 AC_CONFIG_FILES([Makefile
2359                 src/Makefile
2360                 src/egl/drivers/dri2/Makefile
2361                 src/egl/main/Makefile
2362                 src/egl/main/egl.pc
2363                 src/egl/wayland/wayland-drm/Makefile
2364                 src/egl/wayland/wayland-egl/Makefile
2365                 src/egl/wayland/wayland-egl/wayland-egl.pc
2366                 src/gallium/Makefile
2367                 src/gallium/auxiliary/Makefile
2368                 src/gallium/auxiliary/pipe-loader/Makefile
2369                 src/gallium/drivers/freedreno/Makefile
2370                 src/gallium/drivers/i915/Makefile
2371                 src/gallium/drivers/ilo/Makefile
2372                 src/gallium/drivers/llvmpipe/Makefile
2373                 src/gallium/drivers/noop/Makefile
2374                 src/gallium/drivers/nouveau/Makefile
2375                 src/gallium/drivers/r300/Makefile
2376                 src/gallium/drivers/r600/Makefile
2377                 src/gallium/drivers/radeon/Makefile
2378                 src/gallium/drivers/radeonsi/Makefile
2379                 src/gallium/drivers/rbug/Makefile
2380                 src/gallium/drivers/softpipe/Makefile
2381                 src/gallium/drivers/svga/Makefile
2382                 src/gallium/drivers/trace/Makefile
2383                 src/gallium/drivers/vc4/Makefile
2384                 src/gallium/drivers/vc4/kernel/Makefile
2385                 src/gallium/state_trackers/clover/Makefile
2386                 src/gallium/state_trackers/dri/Makefile
2387                 src/gallium/state_trackers/glx/xlib/Makefile
2388                 src/gallium/state_trackers/nine/Makefile
2389                 src/gallium/state_trackers/omx/Makefile
2390                 src/gallium/state_trackers/osmesa/Makefile
2391                 src/gallium/state_trackers/va/Makefile
2392                 src/gallium/state_trackers/vdpau/Makefile
2393                 src/gallium/state_trackers/xa/Makefile
2394                 src/gallium/state_trackers/xvmc/Makefile
2395                 src/gallium/targets/d3dadapter9/Makefile
2396                 src/gallium/targets/d3dadapter9/d3d.pc
2397                 src/gallium/targets/dri/Makefile
2398                 src/gallium/targets/libgl-xlib/Makefile
2399                 src/gallium/targets/omx/Makefile
2400                 src/gallium/targets/opencl/Makefile
2401                 src/gallium/targets/osmesa/Makefile
2402                 src/gallium/targets/osmesa/osmesa.pc
2403                 src/gallium/targets/pipe-loader/Makefile
2404                 src/gallium/targets/va/Makefile
2405                 src/gallium/targets/vdpau/Makefile
2406                 src/gallium/targets/xa/Makefile
2407                 src/gallium/targets/xa/xatracker.pc
2408                 src/gallium/targets/xvmc/Makefile
2409                 src/gallium/tests/trivial/Makefile
2410                 src/gallium/tests/unit/Makefile
2411                 src/gallium/winsys/freedreno/drm/Makefile
2412                 src/gallium/winsys/i915/drm/Makefile
2413                 src/gallium/winsys/intel/drm/Makefile
2414                 src/gallium/winsys/nouveau/drm/Makefile
2415                 src/gallium/winsys/radeon/drm/Makefile
2416                 src/gallium/winsys/svga/drm/Makefile
2417                 src/gallium/winsys/sw/dri/Makefile
2418                 src/gallium/winsys/sw/kms-dri/Makefile
2419                 src/gallium/winsys/sw/null/Makefile
2420                 src/gallium/winsys/sw/wrapper/Makefile
2421                 src/gallium/winsys/sw/xlib/Makefile
2422                 src/gallium/winsys/vc4/drm/Makefile
2423                 src/gbm/Makefile
2424                 src/gbm/main/gbm.pc
2425                 src/glsl/Makefile
2426                 src/glx/Makefile
2427                 src/glx/apple/Makefile
2428                 src/glx/tests/Makefile
2429                 src/gtest/Makefile
2430                 src/loader/Makefile
2431                 src/mapi/Makefile
2432                 src/mapi/es1api/glesv1_cm.pc
2433                 src/mapi/es2api/glesv2.pc
2434                 src/mapi/glapi/gen/Makefile
2435                 src/mesa/Makefile
2436                 src/mesa/gl.pc
2437                 src/mesa/drivers/dri/dri.pc
2438                 src/mesa/drivers/dri/common/Makefile
2439                 src/mesa/drivers/dri/common/xmlpool/Makefile
2440                 src/mesa/drivers/dri/i915/Makefile
2441                 src/mesa/drivers/dri/i965/Makefile
2442                 src/mesa/drivers/dri/Makefile
2443                 src/mesa/drivers/dri/nouveau/Makefile
2444                 src/mesa/drivers/dri/r200/Makefile
2445                 src/mesa/drivers/dri/radeon/Makefile
2446                 src/mesa/drivers/dri/swrast/Makefile
2447                 src/mesa/drivers/osmesa/Makefile
2448                 src/mesa/drivers/osmesa/osmesa.pc
2449                 src/mesa/drivers/x11/Makefile
2450                 src/mesa/main/tests/Makefile
2451                 src/util/Makefile
2452                 src/util/tests/hash_table/Makefile])
2453
2454 AC_OUTPUT
2455
2456 dnl
2457 dnl Output some configuration info for the user
2458 dnl
2459 echo ""
2460 echo "        prefix:          $prefix"
2461 echo "        exec_prefix:     $exec_prefix"
2462 echo "        libdir:          $libdir"
2463 echo "        includedir:      $includedir"
2464
2465 dnl API info
2466 echo ""
2467 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2468
2469 dnl Driver info
2470 echo ""
2471 case "x$enable_osmesa$enable_gallium_osmesa" in
2472 xnoyes)
2473         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2474         ;;
2475 xyesno)
2476         echo "        OSMesa:          lib$OSMESA_LIB"
2477         ;;
2478 xnono)
2479         echo "        OSMesa:          no"
2480         ;;
2481 esac
2482
2483 echo ""
2484 if test "x$enable_dri" != xno; then
2485         echo "        DRI platform:    $dri_platform"
2486         if test -z "$DRI_DIRS"; then
2487             echo "        DRI drivers:     no"
2488         else
2489             echo "        DRI drivers:     $DRI_DIRS"
2490         fi
2491         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2492 fi
2493
2494 case "x$enable_glx$enable_xlib_glx" in
2495 xyesyes)
2496     echo "        GLX:             Xlib-based"
2497     ;;
2498 xyesno)
2499     echo "        GLX:             DRI-based"
2500     ;;
2501 *)
2502     echo "        GLX:             $enable_glx"
2503     ;;
2504 esac
2505
2506 dnl EGL
2507 echo ""
2508 echo "        EGL:             $enable_egl"
2509 if test "$enable_egl" = yes; then
2510     echo "        EGL platforms:   $egl_platforms"
2511
2512     egl_drivers=""
2513     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2514         egl_drivers="$egl_drivers builtin:egl_dri2"
2515     fi
2516
2517     echo "        EGL drivers:    $egl_drivers"
2518 fi
2519
2520 echo ""
2521 if test "x$MESA_LLVM" = x1; then
2522     echo "        llvm:            yes"
2523     echo "        llvm-config:     $LLVM_CONFIG"
2524     echo "        llvm-version:    $LLVM_VERSION"
2525 else
2526     echo "        llvm:            no"
2527 fi
2528
2529 echo ""
2530 if test -n "$with_gallium_drivers"; then
2531     echo "        Gallium:         yes"
2532 else
2533     echo "        Gallium:         no"
2534 fi
2535
2536 dnl Shader cache
2537 echo ""
2538 echo "        Shader cache:    $enable_shader_cache"
2539 if test "x$enable_shader_cache" = "xyes"; then
2540     echo "        With SHA1 from:  $with_sha1"
2541 fi
2542
2543 dnl Libraries
2544 echo ""
2545 echo "        Shared libs:     $enable_shared"
2546 echo "        Static libs:     $enable_static"
2547 echo "        Shared-glapi:    $enable_shared_glapi"
2548
2549 dnl Compiler options
2550 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2551 cflags=`echo $CFLAGS | \
2552     $SED 's/^ *//;s/  */ /;s/ *$//'`
2553 cxxflags=`echo $CXXFLAGS | \
2554     $SED 's/^ *//;s/  */ /;s/ *$//'`
2555 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2556 echo ""
2557 echo "        CFLAGS:          $cflags"
2558 echo "        CXXFLAGS:        $cxxflags"
2559 echo "        Macros:          $defines"
2560 echo ""
2561 if test "x$MESA_LLVM" = x1; then
2562     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2563     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2564     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2565     echo ""
2566 fi
2567 echo "        PYTHON2:         $PYTHON2"
2568
2569 echo ""
2570 echo "        Run '${MAKE-make}' to build Mesa"
2571 echo ""