configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.67
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 102 AC_CHECK_PROGS([PYTHON3], [python3.5 python3.4 python3])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112
 113 AX_PROG_BISON([],
 114               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 115                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 116 AX_PROG_FLEX([],
 117              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 118                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 119
 120 AC_CHECK_PROG(INDENT, indent, indent, cat)
 121 if test "x$INDENT" != "xcat"; then
 122     # Only GNU indent is supported
 123     INDENT_VERSION=`indent --version | grep GNU`
 124     if test $? -eq 0; then
 125        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 126     else
 127        INDENT="cat"
 128     fi
 129 fi
 130
 131 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 132
 133 if test -z "$PYTHON2"; then
 134     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 135         AC_MSG_ERROR([Python not found - unable to generate sources])
 136     fi
 137 else
 138     if test "x$acv_mako_found" = xno; then
 139         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 140             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 141         fi
 142     fi
 143 fi
 144
 145 if test -z "$PYTHON3"; then
 146     if test ! -f "$srcdir/src/intel/genxml/gen9_pack.h"; then
 147         AC_MSG_ERROR([Python3 not found - unable to generate sources])
 148     fi
 149 fi
 150
 151 AC_PROG_INSTALL
 152
 153 dnl We need a POSIX shell for parts of the build. Assume we have one
 154 dnl in most cases.
 155 case "$host_os" in
 156 solaris*)
 157     # Solaris /bin/sh is too old/non-POSIX compliant
 158     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 159     SHELL="$POSIX_SHELL"
 160     ;;
 161 esac
 162
 163 dnl clang is mostly GCC-compatible, but its version is much lower,
 164 dnl so we have to check for it.
 165 AC_MSG_CHECKING([if compiling with clang])
 166
 167 AC_COMPILE_IFELSE(
 168 [AC_LANG_PROGRAM([], [[
 169 #ifndef __clang__
 170        not clang
 171 #endif
 172 ]])],
 173 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 174
 175 AC_MSG_RESULT([$acv_mesa_CLANG])
 176
 177 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 178 dnl versions are explictly not supported.
 179 GEN_ASM_OFFSETS=no
 180 USE_GNU99=no
 181 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 182     AC_MSG_CHECKING([whether gcc version is sufficient])
 183     major=0
 184     minor=0
 185
 186     GCC_VERSION=`$CC -dumpversion`
 187     if test $? -eq 0; then
 188         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 189         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 193         AC_MSG_RESULT([no])
 194         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 195     else
 196         AC_MSG_RESULT([yes])
 197     fi
 198
 199     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 200         USE_GNU99=yes
 201     fi
 202     if test "x$cross_compiling" = xyes; then
 203         GEN_ASM_OFFSETS=yes
 204     fi
 205 fi
 206
 207 dnl We don't support building Mesa with Sun C compiler
 208 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 209 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 210 if test "x$SUNCC" = xyes; then
 211     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 212 fi
 213
 214 dnl Check for compiler builtins
 215 AX_GCC_BUILTIN([__builtin_bswap32])
 216 AX_GCC_BUILTIN([__builtin_bswap64])
 217 AX_GCC_BUILTIN([__builtin_clz])
 218 AX_GCC_BUILTIN([__builtin_clzll])
 219 AX_GCC_BUILTIN([__builtin_ctz])
 220 AX_GCC_BUILTIN([__builtin_expect])
 221 AX_GCC_BUILTIN([__builtin_ffs])
 222 AX_GCC_BUILTIN([__builtin_ffsll])
 223 AX_GCC_BUILTIN([__builtin_popcount])
 224 AX_GCC_BUILTIN([__builtin_popcountll])
 225 AX_GCC_BUILTIN([__builtin_unreachable])
 226
 227 AX_GCC_FUNC_ATTRIBUTE([const])
 228 AX_GCC_FUNC_ATTRIBUTE([flatten])
 229 AX_GCC_FUNC_ATTRIBUTE([format])
 230 AX_GCC_FUNC_ATTRIBUTE([malloc])
 231 AX_GCC_FUNC_ATTRIBUTE([packed])
 232 AX_GCC_FUNC_ATTRIBUTE([pure])
 233 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 234 AX_GCC_FUNC_ATTRIBUTE([unused])
 235 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 236
 237 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 238
 239 dnl Make sure the pkg-config macros are defined
 240 m4_ifndef([PKG_PROG_PKG_CONFIG],
 241     [m4_fatal([Could not locate the pkg-config autoconf macros.
 242   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 243   are in a different location, try setting the environment variable
 244   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 245 PKG_PROG_PKG_CONFIG()
 246
 247 dnl LIB_DIR - library basename
 248 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 249 AC_SUBST([LIB_DIR])
 250
 251 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 252 _SAVE_LDFLAGS="$LDFLAGS"
 253 _SAVE_CPPFLAGS="$CPPFLAGS"
 254
 255 dnl Compiler macros
 256 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 257 AC_SUBST([DEFINES])
 258 case "$host_os" in
 259 linux*|*-gnu*|gnu*)
 260     DEFINES="$DEFINES -D_GNU_SOURCE"
 261     ;;
 262 solaris*)
 263     DEFINES="$DEFINES -DSVR4"
 264     ;;
 265 cygwin*)
 266     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 267     ;;
 268 esac
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # Work around aliasing bugs - developers should comment this out
 305     CFLAGS="$CFLAGS -fno-strict-aliasing"
 306
 307     # We don't want floating-point math functions to set errno or trap
 308     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 309
 310     # gcc's builtin memcmp is slower than glibc's
 311     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 312     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 313
 314     # Flags to help ensure that certain portions of the code -- and only those
 315     # portions -- can be built with MSVC:
 316     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 317     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 318     #   supports most of C99)
 319     # - the rest has no compiler compiler restrictions
 320     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 321     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 322
 323     # Enable -Werror=vla if compiler supports it
 324     save_CFLAGS="$CFLAGS"
 325     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 326     CFLAGS="$CFLAGS -Werror=vla"
 327     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 328                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 329                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 330                     AC_MSG_RESULT([yes])],
 331                     AC_MSG_RESULT([no]));
 332     CFLAGS="$save_CFLAGS"
 333 fi
 334 if test "x$GXX" = xyes; then
 335     CXXFLAGS="$CXXFLAGS -Wall"
 336
 337     # Enable -fvisibility=hidden if using a gcc that supports it
 338     save_CXXFLAGS="$CXXFLAGS"
 339     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 340     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 341     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 342     AC_LANG_PUSH([C++])
 343     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 344                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 345     AC_LANG_POP([C++])
 346
 347     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 348     CXXFLAGS=$save_CXXFLAGS
 349
 350     # Work around aliasing bugs - developers should comment this out
 351     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 352
 353     # gcc's builtin memcmp is slower than glibc's
 354     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 355     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 356 fi
 357
 358 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 359 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 360
 361 dnl even if the compiler appears to support it, using visibility attributes isn't
 362 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 363 case "$host_os" in
 364 cygwin*)
 365     VISIBILITY_CFLAGS=""
 366     VISIBILITY_CXXFLAGS=""
 367     ;;
 368 esac
 369
 370 AC_SUBST([VISIBILITY_CFLAGS])
 371 AC_SUBST([VISIBILITY_CXXFLAGS])
 372
 373 dnl
 374 dnl Optional flags, check for compiler support
 375 dnl
 376 SSE41_CFLAGS="-msse4.1"
 377 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 378 dnl stack, but on x86-32 such alignment is not guaranteed.
 379 case "$target_cpu" in
 380 i?86)
 381     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 382     ;;
 383 esac
 384 save_CFLAGS="$CFLAGS"
 385 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 386 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 387 #include <smmintrin.h>
 388 int param;
 389 int main () {
 390     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 391     c = _mm_max_epu32(a, b);
 392     return _mm_cvtsi128_si32(c);
 393 }]])], SSE41_SUPPORTED=1)
 394 CFLAGS="$save_CFLAGS"
 395 if test "x$SSE41_SUPPORTED" = x1; then
 396     DEFINES="$DEFINES -DUSE_SSE41"
 397 fi
 398 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 399 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 dnl
 525 dnl Check if linker supports -Bsymbolic
 526 dnl
 527 save_LDFLAGS=$LDFLAGS
 528 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 529 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 530 AC_LINK_IFELSE(
 531     [AC_LANG_SOURCE([int main() { return 0;}])],
 532     [AC_MSG_RESULT([yes])
 533         BSYMBOLIC="-Wl,-Bsymbolic";],
 534     [AC_MSG_RESULT([no])
 535         BSYMBOLIC="";])
 536 LDFLAGS=$save_LDFLAGS
 537
 538 AC_SUBST([BSYMBOLIC])
 539
 540 dnl
 541 dnl Check if linker supports garbage collection
 542 dnl
 543 save_LDFLAGS=$LDFLAGS
 544 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 545 AC_MSG_CHECKING([whether ld supports --gc-sections])
 546 AC_LINK_IFELSE(
 547     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 548     [AC_MSG_RESULT([yes])
 549         GC_SECTIONS="-Wl,--gc-sections";],
 550     [AC_MSG_RESULT([no])
 551         GC_SECTIONS="";])
 552 LDFLAGS=$save_LDFLAGS
 553
 554 AC_SUBST([GC_SECTIONS])
 555
 556 dnl
 557 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 558 dnl so when these flags are passed to ld via libtool the checks will fail
 559 dnl
 560 case "$host_os" in
 561 openbsd* | darwin* )
 562     LD_NO_UNDEFINED="" ;;
 563 *)
 564     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 565 esac
 566
 567 AC_SUBST([LD_NO_UNDEFINED])
 568
 569 dnl
 570 dnl Check if linker supports version scripts
 571 dnl
 572 AC_MSG_CHECKING([if the linker supports version-scripts])
 573 save_LDFLAGS=$LDFLAGS
 574 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 575 cat > conftest.map <<EOF
 576 VERSION_1 {
 577      global:
 578          main;
 579
 580      local:
 581          *;
 582 };
 583 EOF
 584 AC_LINK_IFELSE(
 585     [AC_LANG_SOURCE([int main() { return 0;}])],
 586     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 587     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 588 LDFLAGS=$save_LDFLAGS
 589 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 590
 591 dnl
 592 dnl Check if linker supports dynamic list files
 593 dnl
 594 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 595 save_LDFLAGS=$LDFLAGS
 596 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 597 cat > conftest.dyn <<EOF
 598 {
 599         radeon_drm_winsys_create;
 600 };
 601 EOF
 602 AC_LINK_IFELSE(
 603     [AC_LANG_SOURCE([int main() { return 0;}])],
 604     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 605     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 606 LDFLAGS=$save_LDFLAGS
 607 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 608
 609 dnl
 610 dnl compatibility symlinks
 611 dnl
 612 case "$host_os" in
 613 linux* )
 614     HAVE_COMPAT_SYMLINKS=yes ;;
 615 * )
 616     HAVE_COMPAT_SYMLINKS=no ;;
 617 esac
 618
 619 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 620
 621 dnl
 622 dnl library names
 623 dnl
 624 dnl Unfortunately we need to do a few things that libtool can't help us with,
 625 dnl so we need some knowledge of shared library filenames:
 626 dnl
 627 dnl LIB_EXT is the extension used when creating symlinks for alternate
 628 dnl filenames for a shared library which will be dynamically loaded
 629 dnl
 630 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 631 dnl the file for a shared library we wish to link with
 632 dnl
 633 case "$host_os" in
 634 darwin* )
 635     LIB_EXT='dylib'
 636     IMP_LIB_EXT=$LIB_EXT
 637     ;;
 638 cygwin* )
 639     LIB_EXT='dll'
 640     IMP_LIB_EXT='dll.a'
 641     ;;
 642 aix* )
 643     LIB_EXT='a'
 644     IMP_LIB_EXT=$LIB_EXT
 645     ;;
 646 * )
 647     LIB_EXT='so'
 648     IMP_LIB_EXT=$LIB_EXT
 649     ;;
 650 esac
 651
 652 AC_SUBST([LIB_EXT])
 653
 654 AC_ARG_WITH([gl-lib-name],
 655   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 656     [specify GL library name @<:@default=GL@:>@])],
 657   [GL_LIB=$withval],
 658   [GL_LIB=GL])
 659 AC_ARG_WITH([osmesa-lib-name],
 660   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 661     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 662   [OSMESA_LIB=$withval],
 663   [OSMESA_LIB=OSMesa])
 664 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 665 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 666
 667 dnl
 668 dnl Mangled Mesa support
 669 dnl
 670 AC_ARG_ENABLE([mangling],
 671   [AS_HELP_STRING([--enable-mangling],
 672     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 673   [enable_mangling="${enableval}"],
 674   [enable_mangling=no]
 675 )
 676 if test "x${enable_mangling}" = "xyes" ; then
 677   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 678   GL_LIB="Mangled${GL_LIB}"
 679   OSMESA_LIB="Mangled${OSMESA_LIB}"
 680 fi
 681 AC_SUBST([GL_LIB])
 682 AC_SUBST([OSMESA_LIB])
 683
 684 dnl
 685 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 686 dnl
 687 AC_ARG_ENABLE([texture-float],
 688     [AS_HELP_STRING([--enable-texture-float],
 689         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 690     [enable_texture_float="$enableval"],
 691     [enable_texture_float=no]
 692 )
 693 if test "x$enable_texture_float" = xyes; then
 694     AC_MSG_WARN([Floating-point textures enabled.])
 695     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 696     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 697 fi
 698
 699 dnl
 700 dnl Arch/platform-specific settings
 701 dnl
 702 AC_ARG_ENABLE([asm],
 703     [AS_HELP_STRING([--disable-asm],
 704         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 705     [enable_asm="$enableval"],
 706     [enable_asm=yes]
 707 )
 708 asm_arch=""
 709 AC_MSG_CHECKING([whether to enable assembly])
 710 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 711 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 712 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 713     case "$host_cpu" in
 714     i?86 | x86_64 | amd64)
 715         if test "x$host_cpu" != "x$target_cpu"; then
 716             enable_asm=no
 717             AC_MSG_RESULT([no, cross compiling])
 718         fi
 719         ;;
 720     esac
 721 fi
 722 # check for supported arches
 723 if test "x$enable_asm" = xyes; then
 724     case "$host_cpu" in
 725     i?86)
 726         case "$host_os" in
 727         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 728             asm_arch=x86
 729             ;;
 730         esac
 731         ;;
 732     x86_64|amd64)
 733         case "$host_os" in
 734         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 735             asm_arch=x86_64
 736             ;;
 737         esac
 738         ;;
 739     sparc*)
 740         case "$host_os" in
 741         linux*)
 742             asm_arch=sparc
 743             ;;
 744         esac
 745         ;;
 746     esac
 747
 748     case "$asm_arch" in
 749     x86)
 750         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 751         AC_MSG_RESULT([yes, x86])
 752         ;;
 753     x86_64|amd64)
 754         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 755         AC_MSG_RESULT([yes, x86_64])
 756         ;;
 757     sparc)
 758         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 759         AC_MSG_RESULT([yes, sparc])
 760         ;;
 761     *)
 762         AC_MSG_RESULT([no, platform not supported])
 763         ;;
 764     esac
 765 fi
 766
 767 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 768 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 769 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 770 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 771
 772 dnl Check to see if dlopen is in default libraries (like Solaris, which
 773 dnl has it in libc), or if libdl is needed to get it.
 774 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 775     [AC_CHECK_LIB([dl], [dlopen],
 776        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 777 AC_SUBST([DLOPEN_LIBS])
 778
 779 dnl Check if that library also has dladdr
 780 save_LIBS="$LIBS"
 781 LIBS="$LIBS $DLOPEN_LIBS"
 782 AC_CHECK_FUNCS([dladdr])
 783 LIBS="$save_LIBS"
 784
 785 case "$host_os" in
 786 darwin*)
 787     ;;
 788 *)
 789     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 790                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 791                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 792     AC_SUBST([CLOCK_LIB])
 793     ;;
 794 esac
 795
 796 dnl See if posix_memalign is available
 797 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 798
 799 dnl Check for pthreads
 800 AX_PTHREAD
 801 if test "x$ax_pthread_ok" = xno; then
 802     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 803 fi
 804 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 805 dnl to -pthread, which causes problems if we need -lpthread to appear in
 806 dnl pkgconfig files.
 807 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 808
 809 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 810 AC_SUBST(PTHREADSTUBS_CFLAGS)
 811 AC_SUBST(PTHREADSTUBS_LIBS)
 812
 813 dnl SELinux awareness.
 814 AC_ARG_ENABLE([selinux],
 815     [AS_HELP_STRING([--enable-selinux],
 816         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 817     [MESA_SELINUX="$enableval"],
 818     [MESA_SELINUX=no])
 819 if test "x$enable_selinux" = "xyes"; then
 820     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 821         [AC_CHECK_HEADER([selinux/selinux.h],[],
 822                          [AC_MSG_ERROR([SELinux headers not found])])
 823          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 824                       [AC_MSG_ERROR([SELinux library not found])])
 825          SELINUX_LIBS="-lselinux"])
 826     DEFINES="$DEFINES -DMESA_SELINUX"
 827 fi
 828 AC_SUBST([SELINUX_CFLAGS])
 829 AC_SUBST([SELINUX_LIBS])
 830
 831 dnl Options for APIs
 832 AC_ARG_ENABLE([opengl],
 833     [AS_HELP_STRING([--disable-opengl],
 834         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 835     [enable_opengl="$enableval"],
 836     [enable_opengl=yes])
 837 AC_ARG_ENABLE([gles1],
 838     [AS_HELP_STRING([--disable-gles1],
 839         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 840     [enable_gles1="$enableval"],
 841     [enable_gles1=yes])
 842 AC_ARG_ENABLE([gles2],
 843     [AS_HELP_STRING([--disable-gles2],
 844         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 845     [enable_gles2="$enableval"],
 846     [enable_gles2=yes])
 847
 848 AC_ARG_ENABLE([dri],
 849     [AS_HELP_STRING([--enable-dri],
 850         [enable DRI modules @<:@default=enabled@:>@])],
 851     [enable_dri="$enableval"],
 852     [enable_dri=yes])
 853
 854 case "$host_os" in
 855 linux*)
 856     dri3_default=yes
 857     ;;
 858 *)
 859     dri3_default=no
 860     ;;
 861 esac
 862
 863 if test "x$enable_dri" = xno; then
 864     dri3_default=no
 865 fi
 866
 867 AC_ARG_ENABLE([dri3],
 868     [AS_HELP_STRING([--enable-dri3],
 869         [enable DRI3 @<:@default=auto@:>@])],
 870     [enable_dri3="$enableval"],
 871     [enable_dri3="$dri3_default"])
 872 AC_ARG_ENABLE([glx],
 873     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 874         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 875     [enable_glx="$enableval"],
 876     [enable_glx=yes])
 877 AC_ARG_ENABLE([osmesa],
 878     [AS_HELP_STRING([--enable-osmesa],
 879         [enable OSMesa library @<:@default=disabled@:>@])],
 880     [enable_osmesa="$enableval"],
 881     [enable_osmesa=no])
 882 AC_ARG_ENABLE([gallium-osmesa],
 883     [AS_HELP_STRING([--enable-gallium-osmesa],
 884         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 885     [enable_gallium_osmesa="$enableval"],
 886     [enable_gallium_osmesa=no])
 887 AC_ARG_ENABLE([egl],
 888     [AS_HELP_STRING([--disable-egl],
 889         [disable EGL library @<:@default=enabled@:>@])],
 890     [enable_egl="$enableval"],
 891     [enable_egl=yes])
 892
 893 AC_ARG_ENABLE([xa],
 894     [AS_HELP_STRING([--enable-xa],
 895         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 896     [enable_xa="$enableval"],
 897     [enable_xa=no])
 898 AC_ARG_ENABLE([gbm],
 899    [AS_HELP_STRING([--enable-gbm],
 900          [enable gbm library @<:@default=auto@:>@])],
 901    [enable_gbm="$enableval"],
 902    [enable_gbm=auto])
 903 AC_ARG_ENABLE([nine],
 904     [AS_HELP_STRING([--enable-nine],
 905         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 906     [enable_nine="$enableval"],
 907     [enable_nine=no])
 908
 909 AC_ARG_ENABLE([xvmc],
 910    [AS_HELP_STRING([--enable-xvmc],
 911          [enable xvmc library @<:@default=auto@:>@])],
 912    [enable_xvmc="$enableval"],
 913    [enable_xvmc=auto])
 914 AC_ARG_ENABLE([vdpau],
 915    [AS_HELP_STRING([--enable-vdpau],
 916          [enable vdpau library @<:@default=auto@:>@])],
 917    [enable_vdpau="$enableval"],
 918    [enable_vdpau=auto])
 919 AC_ARG_ENABLE([omx],
 920    [AS_HELP_STRING([--enable-omx],
 921          [enable OpenMAX library @<:@default=disabled@:>@])],
 922    [enable_omx="$enableval"],
 923    [enable_omx=no])
 924 AC_ARG_ENABLE([va],
 925    [AS_HELP_STRING([--enable-va],
 926          [enable va library @<:@default=auto@:>@])],
 927    [enable_va="$enableval"],
 928    [enable_va=auto])
 929 AC_ARG_ENABLE([opencl],
 930    [AS_HELP_STRING([--enable-opencl],
 931          [enable OpenCL library @<:@default=disabled@:>@])],
 932    [enable_opencl="$enableval"],
 933    [enable_opencl=no])
 934 AC_ARG_ENABLE([opencl_icd],
 935    [AS_HELP_STRING([--enable-opencl-icd],
 936           [Build an OpenCL ICD library to be loaded by an ICD implementation
 937            @<:@default=disabled@:>@])],
 938     [enable_opencl_icd="$enableval"],
 939     [enable_opencl_icd=no])
 940
 941 AC_ARG_ENABLE([gallium-tests],
 942     [AS_HELP_STRING([--enable-gallium-tests],
 943         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 944     [enable_gallium_tests="$enableval"],
 945     [enable_gallium_tests=no])
 946
 947 # Option for Gallium drivers
 948
 949 # Keep this in sync with the --with-gallium-drivers help string default value
 950 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 951
 952 AC_ARG_WITH([gallium-drivers],
 953     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 954         [comma delimited Gallium drivers list, e.g.
 955         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 956         @<:@default=r300,r600,svga,swrast@:>@])],
 957     [with_gallium_drivers="$withval"],
 958     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 959
 960 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 961 # here so that the script doesn't choke on an unknown driver name later.
 962 case "$with_gallium_drivers" in
 963     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 964     no) with_gallium_drivers='' ;;
 965 esac
 966
 967 if test "x$enable_opengl" = xno -a \
 968         "x$enable_gles1" = xno -a \
 969         "x$enable_gles2" = xno -a \
 970         "x$enable_nine" = xno -a \
 971         "x$enable_xa" = xno -a \
 972         "x$enable_xvmc" = xno -a \
 973         "x$enable_vdpau" = xno -a \
 974         "x$enable_omx" = xno -a \
 975         "x$enable_va" = xno -a \
 976         "x$enable_opencl" = xno; then
 977     AC_MSG_ERROR([at least one API should be enabled])
 978 fi
 979
 980 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 981 if test "x$enable_opengl" = xno -a \
 982         "x$enable_gles1" = xyes; then
 983     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 984 fi
 985
 986 if test "x$enable_opengl" = xno -a \
 987         "x$enable_gles2" = xyes; then
 988     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 989 fi
 990
 991 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 992 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 993 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 994 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 995                                         "x$enable_gles1" = xyes -o \
 996                                         "x$enable_gles2" = xyes)
 997
 998 # Validate GLX options
 999 if test "x$enable_glx" = xyes; then
1000     if test "x$enable_dri" = xyes; then
1001         enable_glx=dri
1002     elif test -n "$with_gallium_drivers"; then
1003         enable_glx=gallium-xlib
1004     else
1005         enable_glx=xlib
1006     fi
1007 fi
1008 case "x$enable_glx" in
1009 xdri | xxlib | xgallium-xlib)
1010     # GLX requires OpenGL
1011     if test "x$enable_opengl" = xno; then
1012         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1013     fi
1014
1015     # Check individual dependencies
1016     case "x$enable_glx" in
1017     xdri)
1018         if test "x$enable_dri" = xno; then
1019             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1020         fi
1021         ;;
1022     xxlib)
1023         if test "x$enable_dri" = xyes; then
1024             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1025         fi
1026         ;;
1027     xgallium-xlib )
1028         if test "x$enable_dri" = xyes; then
1029             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1030         fi
1031         if test -z "$with_gallium_drivers"; then
1032             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1033         fi
1034         ;;
1035     esac
1036     ;;
1037 xno)
1038     ;;
1039 *)
1040     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1041     ;;
1042 esac
1043
1044 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1045 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1046 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1047
1048 # Check for libdrm
1049 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1050                   [have_libdrm=yes], [have_libdrm=no])
1051 if test "x$have_libdrm" = xyes; then
1052         DEFINES="$DEFINES -DHAVE_LIBDRM"
1053 fi
1054
1055 # Select which platform-dependent DRI code gets built
1056 case "$host_os" in
1057 darwin*)
1058     dri_platform='apple' ;;
1059 gnu*|cygwin*)
1060     dri_platform='none' ;;
1061 *)
1062     dri_platform='drm' ;;
1063 esac
1064
1065 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1066     have_drisw_kms='yes'
1067 fi
1068
1069 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1070 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1071 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1072 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1073 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1074 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1075
1076 AC_ARG_ENABLE([shared-glapi],
1077     [AS_HELP_STRING([--enable-shared-glapi],
1078         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1079     [enable_shared_glapi="$enableval"],
1080     [enable_shared_glapi=yes])
1081
1082 case "x$enable_opengl$enable_gles1$enable_gles2" in
1083 x*yes*yes*)
1084     if test "x$enable_shared_glapi" = xno; then
1085         AC_MSG_ERROR([shared GLAPI required when building two or more of
1086                       the following APIs - opengl, gles1 gles2])
1087     fi
1088     ;;
1089 esac
1090
1091 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1092
1093 # Build the pipe-drivers as separate libraries/modules.
1094 # Do not touch this unless you know what you are doing.
1095 # XXX: Expose via configure option ?
1096 enable_shared_pipe_drivers=no
1097
1098 dnl
1099 dnl Driver specific build directories
1100 dnl
1101
1102 if test "x$enable_gallium_osmesa" = xyes; then
1103     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1104         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1105     fi
1106     if test "x$enable_osmesa" = xyes; then
1107         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1108     fi
1109 fi
1110
1111 AC_SUBST([MESA_LLVM])
1112
1113 # SHA1 hashing
1114 AC_ARG_WITH([sha1],
1115         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1116         [choose SHA1 implementation])])
1117 case "x$with_sha1" in
1118 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1119   ;;
1120 *)
1121         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1122 esac
1123
1124 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1125 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1126         with_sha1=libc
1127 fi
1128 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1129         AC_MSG_ERROR([sha1 in libc requested but not found])
1130 fi
1131 if test "x$with_sha1" = xlibc; then
1132         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1133                 [Use libc SHA1 functions])
1134         SHA1_LIBS=""
1135 fi
1136 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1137 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1138         with_sha1=CommonCrypto
1139 fi
1140 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1141         AC_MSG_ERROR([CommonCrypto requested but not found])
1142 fi
1143 if test "x$with_sha1" = xCommonCrypto; then
1144         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1145                 [Use CommonCrypto SHA1 functions])
1146         SHA1_LIBS=""
1147 fi
1148 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1149 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1150 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1151         with_sha1=CryptoAPI
1152 fi
1153 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1154         AC_MSG_ERROR([CryptoAPI requested but not found])
1155 fi
1156 if test "x$with_sha1" = xCryptoAPI; then
1157         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1158                 [Use CryptoAPI SHA1 functions])
1159         SHA1_LIBS=""
1160 fi
1161 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1162 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1163         with_sha1=libmd
1164 fi
1165 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1166         AC_MSG_ERROR([libmd requested but not found])
1167 fi
1168 if test "x$with_sha1" = xlibmd; then
1169         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1170                   [Use libmd SHA1 functions])
1171         SHA1_LIBS=-lmd
1172 fi
1173 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1174 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1175    with_sha1=libsha1
1176 fi
1177 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1178         AC_MSG_ERROR([libsha1 requested but not found])
1179 fi
1180 if test "x$with_sha1" = xlibsha1; then
1181         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1182                   [Use libsha1 for SHA1])
1183         SHA1_LIBS=-lsha1
1184 fi
1185 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1186 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1187         with_sha1=libnettle
1188 fi
1189 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1190         AC_MSG_ERROR([libnettle requested but not found])
1191 fi
1192 if test "x$with_sha1" = xlibnettle; then
1193         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1194                   [Use libnettle SHA1 functions])
1195         SHA1_LIBS=-lnettle
1196 fi
1197 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1198 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1199         with_sha1=libgcrypt
1200 fi
1201 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1202         AC_MSG_ERROR([libgcrypt requested but not found])
1203 fi
1204 if test "x$with_sha1" = xlibgcrypt; then
1205         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1206                   [Use libgcrypt SHA1 functions])
1207         SHA1_LIBS=-lgcrypt
1208 fi
1209 # We don't need all of the OpenSSL libraries, just libcrypto
1210 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1211 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1212                   [HAVE_OPENSSL_PKC=no])
1213 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1214         if test "x$with_sha1" = x; then
1215                 with_sha1=libcrypto
1216         fi
1217 else
1218         if test "x$with_sha1" = xlibcrypto; then
1219                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1220         fi
1221 fi
1222 if test "x$with_sha1" = xlibcrypto; then
1223         if test "x$HAVE_LIBCRYPTO" = xyes; then
1224                 SHA1_LIBS=-lcrypto
1225         else
1226                 SHA1_LIBS="$OPENSSL_LIBS"
1227                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1228         fi
1229 fi
1230 AC_MSG_CHECKING([for SHA1 implementation])
1231 AC_MSG_RESULT([$with_sha1])
1232 AC_SUBST(SHA1_LIBS)
1233 AC_SUBST(SHA1_CFLAGS)
1234
1235 # Enable a define for SHA1
1236 if test "x$with_sha1" != "x"; then
1237         DEFINES="$DEFINES -DHAVE_SHA1"
1238 fi
1239
1240 # Allow user to configure out the shader-cache feature
1241 AC_ARG_ENABLE([shader-cache],
1242     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1243     [enable_shader_cache="$enableval"],
1244     [if test "x$with_sha1" != "x"; then
1245         enable_shader_cache=yes
1246      else
1247         enable_shader_cache=no
1248      fi])
1249 if test "x$with_sha1" = "x"; then
1250     if test "x$enable_shader_cache" = "xyes"; then
1251         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1252     fi
1253 fi
1254 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1255
1256 case "$host_os" in
1257 linux*)
1258     need_pci_id=yes ;;
1259 *)
1260     need_pci_id=no ;;
1261 esac
1262
1263 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1264                   have_libudev=yes, have_libudev=no)
1265
1266 AC_ARG_ENABLE([sysfs],
1267     [AS_HELP_STRING([--enable-sysfs],
1268         [enable /sys PCI identification @<:@default=disabled@:>@])],
1269     [have_sysfs="$enableval"],
1270     [have_sysfs=no]
1271 )
1272
1273 if test "x$enable_dri" = xyes; then
1274     if test "$enable_static" = yes; then
1275         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1276     fi
1277
1278     # not a hard requirement as swrast does not depend on it
1279     if test "x$have_libdrm" = xyes; then
1280         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1281     fi
1282 fi
1283
1284 AC_ARG_ENABLE([driglx-direct],
1285     [AS_HELP_STRING([--disable-driglx-direct],
1286         [disable direct rendering in GLX and EGL for DRI \
1287             @<:@default=auto@:>@])],
1288     [driglx_direct="$enableval"],
1289     [driglx_direct="yes"])
1290
1291 dnl
1292 dnl libGL configuration per driver
1293 dnl
1294 case "x$enable_glx" in
1295 xxlib | xgallium-xlib)
1296     # Xlib-based GLX
1297     dri_modules="x11 xext xcb"
1298     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1299     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1300     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1301     GL_LIB_DEPS="$XLIBGL_LIBS"
1302     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1303     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1304     ;;
1305 xdri)
1306     # DRI-based GLX
1307     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1308
1309     # find the DRI deps for libGL
1310     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1311
1312     if test x"$driglx_direct" = xyes; then
1313         if test x"$dri_platform" = xdrm ; then
1314             DEFINES="$DEFINES -DGLX_USE_DRM"
1315             if test "x$have_libdrm" != xyes; then
1316                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1317             fi
1318
1319             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1320             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1321             if test x"$enable_dri3" = xyes; then
1322                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1323                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1324             fi
1325
1326             if test x"$enable_dri" = xyes; then
1327                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1328             fi
1329
1330             if test x"$enable_dri3" = xyes; then
1331                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1332                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1333                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1334             fi
1335         fi
1336         if test x"$dri_platform" = xapple ; then
1337             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1338         fi
1339     fi
1340
1341     # add xf86vidmode if available
1342     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1343     if test "$HAVE_XF86VIDMODE" = yes ; then
1344         dri_modules="$dri_modules xxf86vm"
1345     fi
1346
1347     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1348     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1349     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1350     GL_LIB_DEPS="$DRIGL_LIBS"
1351
1352     # need DRM libs, $PTHREAD_LIBS, etc.
1353     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1354     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1355     ;;
1356 esac
1357
1358 have_pci_id=no
1359 if test "$have_libudev" = yes; then
1360     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1361     have_pci_id=yes
1362 fi
1363
1364 if test "$have_sysfs" = yes; then
1365     DEFINES="$DEFINES -DHAVE_SYSFS"
1366     have_pci_id=yes
1367 fi
1368
1369 # This is outside the case (above) so that it is invoked even for non-GLX
1370 # builds.
1371 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1372
1373 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1374 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1375 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1376 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1377
1378 AC_SUBST([X11_INCLUDES])
1379 AC_SUBST([GL_LIB_DEPS])
1380 AC_SUBST([GL_PC_REQ_PRIV])
1381 AC_SUBST([GL_PC_LIB_PRIV])
1382 AC_SUBST([GL_PC_CFLAGS])
1383 AC_SUBST([DRI_PC_REQ_PRIV])
1384 AC_SUBST([GLESv1_CM_LIB_DEPS])
1385 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1386 AC_SUBST([GLESv2_LIB_DEPS])
1387 AC_SUBST([GLESv2_PC_LIB_PRIV])
1388
1389 AC_SUBST([HAVE_XF86VIDMODE])
1390
1391 dnl
1392 dnl More GLX setup
1393 dnl
1394 case "x$enable_glx" in
1395 xxlib | xgallium-xlib)
1396     DEFINES="$DEFINES -DUSE_XSHM"
1397     ;;
1398 xdri)
1399     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1400     if test "x$driglx_direct" = xyes; then
1401         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1402     fi
1403     ;;
1404 esac
1405
1406 dnl
1407 dnl TLS detection
1408 dnl
1409
1410 AC_ARG_ENABLE([glx-tls],
1411     [AS_HELP_STRING([--enable-glx-tls],
1412         [enable TLS support in GLX @<:@default=disabled@:>@])],
1413     [GLX_USE_TLS="$enableval"],
1414     [GLX_USE_TLS=no])
1415 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1416
1417 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1418       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1419
1420 dnl Read-only text section on x86 hardened platforms
1421 AC_ARG_ENABLE([glx-read-only-text],
1422     [AS_HELP_STRING([--enable-glx-read-only-text],
1423         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1424     [enable_glx_read_only_text="$enableval"],
1425     [enable_glx_read_only_text=no])
1426 if test "x$enable_glx_read_only_text" = xyes; then
1427     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1428 fi
1429
1430 dnl
1431 dnl More DRI setup
1432 dnl
1433 dnl Directory for DRI drivers
1434 AC_ARG_WITH([dri-driverdir],
1435     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1436         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1437     [DRI_DRIVER_INSTALL_DIR="$withval"],
1438     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1439 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1440 dnl Extra search path for DRI drivers
1441 AC_ARG_WITH([dri-searchpath],
1442     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1443         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1444     [DRI_DRIVER_SEARCH_DIR="$withval"],
1445     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1446 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1447 dnl Which drivers to build - default is chosen by platform
1448 AC_ARG_WITH([dri-drivers],
1449     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1450         [comma delimited classic DRI drivers list, e.g.
1451         "swrast,i965,radeon" @<:@default=auto@:>@])],
1452     [with_dri_drivers="$withval"],
1453     [with_dri_drivers=auto])
1454
1455 if test "x$with_dri_drivers" = xauto; then
1456     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1457         with_dri_drivers="yes"
1458     else
1459         with_dri_drivers="no"
1460     fi
1461 fi
1462 if test "x$with_dri_drivers" = xno; then
1463     with_dri_drivers=''
1464 fi
1465
1466 dnl If $with_dri_drivers is yes, drivers will be added through
1467 dnl platform checks. Set DEFINES and LIB_DEPS
1468 if test "x$enable_dri" = xyes; then
1469     # Platform specific settings and drivers to build
1470     case "$host_os" in
1471     linux*)
1472         DEFINES="$DEFINES -DHAVE_ALIAS"
1473         if test "x$enable_dri3" = xyes; then
1474             DEFINES="$DEFINES -DHAVE_DRI3"
1475         fi
1476
1477         if test "x$have_pci_id" != xyes; then
1478             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1479         fi
1480
1481         case "$host_cpu" in
1482         powerpc* | sparc*)
1483             # Build only the drivers for cards that exist on PowerPC/sparc
1484             if test "x$with_dri_drivers" = "xyes"; then
1485                 with_dri_drivers="r200 radeon swrast"
1486             fi
1487             ;;
1488         esac
1489         ;;
1490     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1491         DEFINES="$DEFINES -DHAVE_ALIAS"
1492         ;;
1493     gnu*)
1494         DEFINES="$DEFINES -DHAVE_ALIAS"
1495         ;;
1496     cygwin*)
1497         if test "x$with_dri_drivers" = "xyes"; then
1498             with_dri_drivers="swrast"
1499         fi
1500         ;;
1501     darwin*)
1502         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1503         if test "x$with_dri_drivers" = "xyes"; then
1504             with_dri_drivers="swrast"
1505         fi
1506         ;;
1507     esac
1508
1509     # default drivers
1510     if test "x$with_dri_drivers" = "xyes"; then
1511         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1512     fi
1513
1514     # Check for expat
1515     PKG_CHECK_MODULES([EXPAT], [expat], [],
1516         # expat version 2.0 and earlier do not provide expat.pc
1517         [AC_CHECK_HEADER([expat.h],[],
1518                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1519          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1520                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1521          EXPAT_LIBS="-lexpat"])
1522
1523     # put all the necessary libs together
1524     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1525 fi
1526
1527 AC_SUBST([DRI_LIB_DEPS])
1528
1529 DRI_DIRS=''
1530 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1531 if test -n "$with_dri_drivers"; then
1532     if test "x$enable_opengl" != xyes; then
1533         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1534     fi
1535
1536     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1537     for driver in $dri_drivers; do
1538         DRI_DIRS="$DRI_DIRS $driver"
1539         case "x$driver" in
1540         xi915)
1541             HAVE_I915_DRI=yes;
1542             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1543             ;;
1544         xi965)
1545             HAVE_I965_DRI=yes;
1546             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1547             ;;
1548         xnouveau)
1549             HAVE_NOUVEAU_DRI=yes;
1550             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1551             ;;
1552         xradeon)
1553             HAVE_RADEON_DRI=yes;
1554             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1555             ;;
1556         xr200)
1557             HAVE_R200_DRI=yes;
1558             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1559             ;;
1560         xswrast)
1561             HAVE_SWRAST_DRI=yes;
1562             ;;
1563         *)
1564             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1565             ;;
1566         esac
1567     done
1568     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1569 fi
1570
1571
1572 #
1573 # Vulkan driver configuration
1574 #
1575
1576 AC_ARG_WITH([vulkan-drivers],
1577     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1578         [comma delimited Vulkan drivers list, e.g.
1579         "intel"
1580         @<:@default=no@:>@])],
1581     [with_vulkan_drivers="$withval"],
1582     [with_vulkan_drivers="no"])
1583
1584 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1585 # here so that the script doesn't choke on an unknown driver name later.
1586 case "x$with_vulkan_drivers" in
1587     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1588     xno) with_vulkan_drivers='' ;;
1589 esac
1590
1591 AC_ARG_WITH([vulkan-icddir],
1592     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1593         [directory for the Vulkan driver icd files @<:@${sysconfdir}/vulkan/icd.d@:>@])],
1594     [VULKAN_ICD_INSTALL_DIR="$withval"],
1595     [VULKAN_ICD_INSTALL_DIR='${sysconfdir}/vulkan/icd.d'])
1596 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1597
1598 if test -n "$with_vulkan_drivers"; then
1599     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1600     for driver in $VULKAN_DRIVERS; do
1601         case "x$driver" in
1602         xintel)
1603             if test "x$HAVE_I965_DRI" != xyes; then
1604                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1605             fi
1606             if test "x$with_sha1" == "x"; then
1607                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1608             fi
1609             HAVE_INTEL_VULKAN=yes;
1610
1611             ;;
1612         *)
1613             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1614             ;;
1615         esac
1616     done
1617     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1618 fi
1619
1620
1621 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1622 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1623                                   "x$enable_osmesa" = xyes -o \
1624                                   -n "$DRI_DIRS")
1625
1626 dnl
1627 dnl OSMesa configuration
1628 dnl
1629
1630 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1631 AC_ARG_WITH([osmesa-bits],
1632     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1633         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1634     [osmesa_bits="$withval"],
1635     [osmesa_bits=8])
1636 if test "x$osmesa_bits" != x8; then
1637     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1638         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1639         osmesa_bits=8
1640     fi
1641 fi
1642 case "x$osmesa_bits" in
1643 x8)
1644     OSMESA_LIB="${OSMESA_LIB}"
1645     ;;
1646 x16|x32)
1647     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1648     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1649     ;;
1650 *)
1651     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1652     ;;
1653 esac
1654
1655 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1656     # only link libraries with osmesa if shared
1657     if test "$enable_static" = no; then
1658         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1659     else
1660         OSMESA_LIB_DEPS=""
1661     fi
1662     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1663 fi
1664
1665 AC_SUBST([OSMESA_LIB_DEPS])
1666 AC_SUBST([OSMESA_PC_REQ])
1667 AC_SUBST([OSMESA_PC_LIB_PRIV])
1668
1669 dnl
1670 dnl gbm configuration
1671 dnl
1672 if test "x$enable_gbm" = xauto; then
1673     case "$with_egl_platforms" in
1674         *drm*)
1675             enable_gbm=yes ;;
1676          *)
1677             enable_gbm=no ;;
1678     esac
1679 fi
1680 if test "x$enable_gbm" = xyes; then
1681     if test "x$need_pci_id$have_pci_id" = xyesno; then
1682         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1683     fi
1684
1685     if test "x$enable_dri" = xyes; then
1686         if test "x$enable_shared_glapi" = xno; then
1687             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1688         fi
1689     else
1690         # Strictly speaking libgbm does not require --enable-dri, although
1691         # both of its backends do. Thus one can build libgbm without any
1692         # backends if --disable-dri is set.
1693         # To avoid unnecessary complexity of checking if at least one backend
1694         # is available when building, just mandate --enable-dri.
1695         AC_MSG_ERROR([gbm requires --enable-dri])
1696     fi
1697 fi
1698 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1699 if test "x$need_pci_id$have_libudev" = xyesyes; then
1700     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1701 else
1702     GBM_PC_REQ_PRIV=""
1703 fi
1704 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1705 AC_SUBST([GBM_PC_REQ_PRIV])
1706 AC_SUBST([GBM_PC_LIB_PRIV])
1707
1708 dnl
1709 dnl EGL configuration
1710 dnl
1711 EGL_CLIENT_APIS=""
1712
1713 if test "x$enable_egl" = xyes; then
1714     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1715
1716     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1717
1718     if test "$enable_static" != yes; then
1719         if test "x$enable_dri" = xyes; then
1720             HAVE_EGL_DRIVER_DRI2=1
1721             if test "x$enable_shared_glapi" = xno; then
1722                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1723             fi
1724             if test "x$enable_dri3" = xyes; then
1725                 HAVE_EGL_DRIVER_DRI3=1
1726                 if test "x$enable_shared_glapi" = xno; then
1727                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1728                 fi
1729             fi
1730         else
1731             # Avoid building an "empty" libEGL. Drop/update this
1732             # when other backends (haiku?) come along.
1733             AC_MSG_ERROR([egl requires --enable-dri])
1734         fi
1735
1736     fi
1737 fi
1738 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1739 AC_SUBST([EGL_LIB_DEPS])
1740
1741 gallium_st="mesa"
1742
1743 dnl
1744 dnl XA configuration
1745 dnl
1746 if test "x$enable_xa" = xyes; then
1747     if test "x$with_gallium_drivers" = xswrast; then
1748        AC_MSG_ERROR([
1749           Building xa requires at least one non swrast gallium driver.
1750           If you are looking to use libxatracker.so with the VMware driver,
1751           make sure to include svga in the gallium drivers list, apart from
1752           enabling XA.
1753           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1754     fi
1755     gallium_st="$gallium_st xa"
1756 fi
1757 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1758
1759 dnl
1760 dnl Gallium G3DVL configuration
1761 dnl
1762 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1763     if test "x$enable_xvmc" = xauto; then
1764         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1765     fi
1766
1767     if test "x$enable_vdpau" = xauto; then
1768         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1769     fi
1770
1771     if test "x$enable_omx" = xauto; then
1772         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1773     fi
1774
1775     if test "x$enable_va" = xauto; then
1776         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1777     fi
1778 fi
1779
1780 if test "x$enable_dri" = xyes -o \
1781         "x$enable_xvmc" = xyes -o \
1782         "x$enable_vdpau" = xyes -o \
1783         "x$enable_omx" = xyes -o \
1784         "x$enable_va" = xyes; then
1785     need_gallium_vl=yes
1786 fi
1787 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1788
1789 if test "x$enable_xvmc" = xyes -o \
1790         "x$enable_vdpau" = xyes -o \
1791         "x$enable_omx" = xyes -o \
1792         "x$enable_va" = xyes; then
1793     if test x"$enable_dri3" = xyes; then
1794         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1795                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1796     else
1797         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1798     fi
1799     need_gallium_vl_winsys=yes
1800 fi
1801 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1802
1803 if test "x$enable_xvmc" = xyes; then
1804     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1805     gallium_st="$gallium_st xvmc"
1806 fi
1807 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1808
1809 if test "x$enable_vdpau" = xyes; then
1810     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1811     gallium_st="$gallium_st vdpau"
1812     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1813 fi
1814 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1815
1816 if test "x$enable_omx" = xyes; then
1817     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1818     gallium_st="$gallium_st omx"
1819 fi
1820 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1821
1822 if test "x$enable_va" = xyes; then
1823     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1824     gallium_st="$gallium_st va"
1825 fi
1826 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1827
1828 dnl
1829 dnl Nine Direct3D9 configuration
1830 dnl
1831 if test "x$enable_nine" = xyes; then
1832     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1833         AC_MSG_ERROR([nine requires the gallium swrast driver])
1834     fi
1835     if test "x$with_gallium_drivers" = xswrast; then
1836         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1837     fi
1838     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1839         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1840     fi
1841
1842     if test "x$enable_dri3" = xno; then
1843         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1844     fi
1845
1846     gallium_st="$gallium_st nine"
1847 fi
1848 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1849
1850 dnl
1851 dnl OpenCL configuration
1852 dnl
1853
1854 AC_ARG_WITH([clang-libdir],
1855    [AS_HELP_STRING([--with-clang-libdir],
1856          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1857    [CLANG_LIBDIR="$withval"],
1858    [CLANG_LIBDIR=''])
1859
1860 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1861 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1862
1863 if test "x$have_libelf" = xno; then
1864    LIBELF_LIBS=''
1865    LIBELF_CFLAGS=''
1866    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1867    AC_SUBST([LIBELF_LIBS])
1868    AC_SUBST([LIBELF_CFLAGS])
1869 fi
1870
1871 if test "x$enable_opencl" = xyes; then
1872     if test -z "$with_gallium_drivers"; then
1873         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1874     fi
1875
1876     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1877         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1878     fi
1879
1880     if test "x$have_libclc" = xno; then
1881         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1882                     Make sure the directory containing libclc.pc is specified in your
1883                     PKG_CONFIG_PATH environment variable.
1884                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1885     else
1886         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1887         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1888         AC_SUBST([LIBCLC_INCLUDEDIR])
1889         AC_SUBST([LIBCLC_LIBEXECDIR])
1890     fi
1891
1892     gallium_st="$gallium_st clover"
1893
1894     if test "x$enable_opencl_icd" = xyes; then
1895         OPENCL_LIBNAME="MesaOpenCL"
1896     else
1897         OPENCL_LIBNAME="OpenCL"
1898     fi
1899
1900     if test "x$have_libelf" != xyes; then
1901        AC_MSG_ERROR([Clover requires libelf])
1902     fi
1903 fi
1904 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1905 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1906 AC_SUBST([OPENCL_LIBNAME])
1907
1908 dnl
1909 dnl Gallium configuration
1910 dnl
1911 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1912
1913 AC_SUBST([LLVM_BINDIR])
1914 AC_SUBST([LLVM_CFLAGS])
1915 AC_SUBST([LLVM_CPPFLAGS])
1916 AC_SUBST([LLVM_CXXFLAGS])
1917 AC_SUBST([LLVM_LIBDIR])
1918 AC_SUBST([LLVM_LIBS])
1919 AC_SUBST([LLVM_LDFLAGS])
1920 AC_SUBST([LLVM_INCLUDEDIR])
1921 AC_SUBST([LLVM_VERSION])
1922 AC_SUBST([CLANG_RESOURCE_DIR])
1923
1924 case "x$enable_opengl$enable_gles1$enable_gles2" in
1925 x*yes*)
1926     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1927     ;;
1928 esac
1929
1930 AC_SUBST([VG_LIB_DEPS])
1931 AC_SUBST([EGL_CLIENT_APIS])
1932
1933 dnl
1934 dnl EGL Platforms configuration
1935 dnl
1936 AC_ARG_WITH([egl-platforms],
1937     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1938         [comma delimited native platforms libEGL supports, e.g.
1939         "x11,drm" @<:@default=auto@:>@])],
1940     [with_egl_platforms="$withval"],
1941     [if test "x$enable_egl" = xyes; then
1942         with_egl_platforms="x11"
1943     else
1944         with_egl_platforms=""
1945     fi])
1946
1947 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1948     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1949 fi
1950
1951 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1952         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1953         WAYLAND_SCANNER='')
1954 if test "x$WAYLAND_SCANNER" = x; then
1955     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1956 fi
1957
1958 # Do per-EGL platform setups and checks
1959 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1960 for plat in $egl_platforms; do
1961         case "$plat" in
1962         wayland)
1963                 test "x$have_libdrm" != xyes &&
1964                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1965
1966                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1967
1968                 if test "x$WAYLAND_SCANNER" = x; then
1969                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1970                 fi
1971                 ;;
1972
1973         x11)
1974                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1975                 ;;
1976
1977         drm)
1978                 test "x$enable_gbm" = "xno" &&
1979                         AC_MSG_ERROR([EGL platform drm needs gbm])
1980                 test "x$have_libdrm" != xyes &&
1981                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1982                 ;;
1983
1984         surfaceless)
1985                 test "x$have_libdrm" != xyes &&
1986                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1987                 ;;
1988
1989         *)
1990                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1991                 ;;
1992         esac
1993
1994         case "$plat$need_pci_id$have_pci_id" in
1995                 waylandyesno|drmyesno)
1996                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1997         esac
1998 done
1999
2000 # libEGL wants to default to the first platform specified in
2001 # ./configure.  parse that here.
2002 if test "x$egl_platforms" != "x"; then
2003     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2004     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2005 else
2006     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2007 fi
2008
2009 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2010 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2011 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2012 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2013
2014 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2015
2016 AC_SUBST([EGL_NATIVE_PLATFORM])
2017 AC_SUBST([EGL_CFLAGS])
2018
2019 # If we don't have the X11 platform, set this define so we don't try to include
2020 # the X11 headers.
2021 if ! echo "$egl_platforms" | grep -q 'x11'; then
2022     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2023     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2024 fi
2025
2026 dnl
2027 dnl Gallium LLVM
2028 dnl
2029 AC_ARG_ENABLE([gallium-llvm],
2030     [AS_HELP_STRING([--enable-gallium-llvm],
2031         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2032     [enable_gallium_llvm="$enableval"],
2033     [enable_gallium_llvm=auto])
2034
2035 AC_ARG_ENABLE([llvm-shared-libs],
2036     [AS_HELP_STRING([--enable-llvm-shared-libs],
2037         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2038     [enable_llvm_shared_libs="$enableval"],
2039     [enable_llvm_shared_libs=yes])
2040
2041 AC_ARG_WITH([llvm-prefix],
2042     [AS_HELP_STRING([--with-llvm-prefix],
2043         [Prefix for LLVM installations in non-standard locations])],
2044     [llvm_prefix="$withval"],
2045     [llvm_prefix=''])
2046
2047
2048 # Call this inside ` ` to get the return value.
2049 # $1 is the llvm-config command with arguments.
2050 strip_unwanted_llvm_flags() {
2051     # Use \> (marks the end of the word)
2052     echo `$1` | sed \
2053         -e 's/-DNDEBUG\>//g' \
2054         -e 's/-D_GNU_SOURCE\>//g' \
2055         -e 's/-pedantic\>//g' \
2056         -e 's/-Wcovered-switch-default\>//g' \
2057         -e 's/-O.\>//g' \
2058         -e 's/-g\>//g' \
2059         -e 's/-Wall\>//g' \
2060         -e 's/-Wcast-qual\>//g' \
2061         -e 's/-Woverloaded-virtual\>//g' \
2062         -e 's/-fcolor-diagnostics\>//g' \
2063         -e 's/-fdata-sections\>//g' \
2064         -e 's/-ffunction-sections\>//g' \
2065         -e 's/-fno-exceptions\>//g' \
2066         -e 's/-fomit-frame-pointer\>//g' \
2067         -e 's/-fvisibility-inlines-hidden\>//g' \
2068         -e 's/-fPIC\>//g' \
2069         -e 's/-fstack-protector-strong\>//g'
2070 }
2071
2072 llvm_check_version_for() {
2073     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2074         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2075     fi
2076 }
2077
2078
2079
2080 if test -z "$with_gallium_drivers"; then
2081     enable_gallium_llvm=no
2082 fi
2083 if test "x$enable_gallium_llvm" = xauto; then
2084     case "$host_cpu" in
2085     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2086     esac
2087 fi
2088 if test "x$enable_gallium_llvm" = xyes; then
2089     if test -n "$llvm_prefix"; then
2090         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2091     else
2092         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2093     fi
2094
2095     if test "x$LLVM_CONFIG" != xno; then
2096         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2097         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2098         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2099         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2100         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2101         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2102         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2103         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2104
2105         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2106             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2107         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2108             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2109
2110         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2111         if test -z "$LLVM_VERSION_PATCH"; then
2112             LLVM_VERSION_PATCH=0
2113         fi
2114
2115         if test -n "${LLVM_VERSION_MAJOR}"; then
2116             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2117         else
2118             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2119         fi
2120
2121         LLVM_REQUIRED_VERSION_MAJOR="3"
2122         LLVM_REQUIRED_VERSION_MINOR="3"
2123         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2124             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2125         fi
2126
2127         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2128
2129         if test "x$enable_opencl" = xyes; then
2130             llvm_check_version_for "3" "5" "0" "opencl"
2131
2132             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2133             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2134         fi
2135         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2136         MESA_LLVM=1
2137
2138         dnl Check for Clang internal headers
2139         if test "x$enable_opencl" = xyes; then
2140             if test -z "$CLANG_LIBDIR"; then
2141                 CLANG_LIBDIR=${LLVM_LIBDIR}
2142             fi
2143             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2144             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2145                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2146         fi
2147     else
2148         MESA_LLVM=0
2149         LLVM_VERSION_INT=0
2150     fi
2151 else
2152     MESA_LLVM=0
2153     LLVM_VERSION_INT=0
2154
2155     if test "x$enable_opencl" = xyes; then
2156         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2157     fi
2158 fi
2159
2160 dnl Directory for XVMC libs
2161 AC_ARG_WITH([xvmc-libdir],
2162     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2163         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2164     [XVMC_LIB_INSTALL_DIR="$withval"],
2165     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2166 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2167
2168 dnl
2169 dnl Gallium Tests
2170 dnl
2171 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2172
2173 dnl Directory for VDPAU libs
2174 AC_ARG_WITH([vdpau-libdir],
2175     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2176         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2177     [VDPAU_LIB_INSTALL_DIR="$withval"],
2178     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2179 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2180
2181 dnl Directory for OMX libs
2182
2183 AC_ARG_WITH([omx-libdir],
2184     [AS_HELP_STRING([--with-omx-libdir=DIR],
2185         [directory for the OMX libraries])],
2186     [OMX_LIB_INSTALL_DIR="$withval"],
2187     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2188 AC_SUBST([OMX_LIB_INSTALL_DIR])
2189
2190 dnl Directory for VA libs
2191
2192 AC_ARG_WITH([va-libdir],
2193     [AS_HELP_STRING([--with-va-libdir=DIR],
2194         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2195     [VA_LIB_INSTALL_DIR="$withval"],
2196     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2197 AC_SUBST([VA_LIB_INSTALL_DIR])
2198
2199 AC_ARG_WITH([d3d-libdir],
2200     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2201         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2202     [D3D_DRIVER_INSTALL_DIR="$withval"],
2203     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2204 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2205
2206 dnl
2207 dnl Gallium helper functions
2208 dnl
2209 gallium_require_drm() {
2210     if test "x$have_libdrm" != xyes; then
2211        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2212     fi
2213 }
2214
2215 gallium_require_llvm() {
2216     if test "x$MESA_LLVM" = x0; then
2217         case "$host" in *gnux32) return;; esac
2218         case "$host_cpu" in
2219         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2220         esac
2221     fi
2222 }
2223
2224 gallium_require_drm_loader() {
2225     if test "x$need_pci_id$have_pci_id" = xyesno; then
2226         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2227     fi
2228 }
2229
2230 dnl This is for Glamor. Skip this if OpenGL is disabled.
2231 require_egl_drm() {
2232     if test "x$enable_opengl" = xno; then
2233         return 0
2234     fi
2235
2236     case "$with_egl_platforms" in
2237         *drm*)
2238             ;;
2239          *)
2240             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2241             ;;
2242     esac
2243     if test "x$enable_gbm" != xyes; then
2244             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2245     fi
2246 }
2247
2248 radeon_llvm_check() {
2249     if test ${LLVM_VERSION_INT} -lt 307; then
2250         amdgpu_llvm_target_name='r600'
2251     else
2252         amdgpu_llvm_target_name='amdgpu'
2253     fi
2254     if test "x$enable_gallium_llvm" != "xyes"; then
2255         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2256     fi
2257     llvm_check_version_for "3" "6" "0" $1
2258     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2259         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2260     fi
2261     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2262     NEED_RADEON_LLVM=yes
2263     if test "x$have_libelf" != xyes; then
2264        AC_MSG_ERROR([$1 requires libelf when using llvm])
2265     fi
2266 }
2267
2268 swr_llvm_check() {
2269     gallium_require_llvm $1
2270     if test ${LLVM_VERSION_INT} -lt 306; then
2271         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2272     fi
2273     if test "x$enable_gallium_llvm" != "xyes"; then
2274         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2275     fi
2276 }
2277
2278 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2279 if test -n "$with_gallium_drivers"; then
2280     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2281     for driver in $gallium_drivers; do
2282         case "x$driver" in
2283         xsvga)
2284             HAVE_GALLIUM_SVGA=yes
2285             gallium_require_drm "svga"
2286             gallium_require_drm_loader
2287             ;;
2288         xi915)
2289             HAVE_GALLIUM_I915=yes
2290             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2291             gallium_require_drm "Gallium i915"
2292             gallium_require_drm_loader
2293             ;;
2294         xilo)
2295             HAVE_GALLIUM_ILO=yes
2296             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2297             gallium_require_drm "Gallium i965/ilo"
2298             gallium_require_drm_loader
2299             ;;
2300         xr300)
2301             HAVE_GALLIUM_R300=yes
2302             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2303             gallium_require_drm "Gallium R300"
2304             gallium_require_drm_loader
2305             gallium_require_llvm "Gallium R300"
2306             ;;
2307         xr600)
2308             HAVE_GALLIUM_R600=yes
2309             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2310             gallium_require_drm "Gallium R600"
2311             gallium_require_drm_loader
2312             if test "x$enable_opencl" = xyes; then
2313                 radeon_llvm_check "r600g"
2314                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2315             fi
2316             ;;
2317         xradeonsi)
2318             HAVE_GALLIUM_RADEONSI=yes
2319             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2320             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2321             gallium_require_drm "radeonsi"
2322             gallium_require_drm_loader
2323             radeon_llvm_check "radeonsi"
2324             require_egl_drm "radeonsi"
2325             ;;
2326         xnouveau)
2327             HAVE_GALLIUM_NOUVEAU=yes
2328             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2329             gallium_require_drm "nouveau"
2330             gallium_require_drm_loader
2331             ;;
2332         xfreedreno)
2333             HAVE_GALLIUM_FREEDRENO=yes
2334             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2335             gallium_require_drm "freedreno"
2336             gallium_require_drm_loader
2337             ;;
2338         xswrast)
2339             HAVE_GALLIUM_SOFTPIPE=yes
2340             if test "x$MESA_LLVM" = x1; then
2341                 HAVE_GALLIUM_LLVMPIPE=yes
2342             fi
2343             ;;
2344         xswr)
2345             swr_llvm_check "swr"
2346
2347             AC_MSG_CHECKING([whether $CXX supports c++11/AVX/AVX2])
2348             AVX_CXXFLAGS="-march=core-avx-i"
2349             AVX2_CXXFLAGS="-march=core-avx2"
2350
2351             AC_LANG_PUSH([C++])
2352             save_CXXFLAGS="$CXXFLAGS"
2353             CXXFLAGS="-std=c++11 $CXXFLAGS"
2354             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2355                               [AC_MSG_ERROR([c++11 compiler support not detected])])
2356             CXXFLAGS="$save_CXXFLAGS"
2357
2358             save_CXXFLAGS="$CXXFLAGS"
2359             CXXFLAGS="$AVX_CXXFLAGS $CXXFLAGS"
2360             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2361                               [AC_MSG_ERROR([AVX compiler support not detected])])
2362             CXXFLAGS="$save_CXXFLAGS"
2363
2364             save_CFLAGS="$CXXFLAGS"
2365             CXXFLAGS="$AVX2_CXXFLAGS $CXXFLAGS"
2366             AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],[],
2367                               [AC_MSG_ERROR([AVX2 compiler support not detected])])
2368             CXXFLAGS="$save_CXXFLAGS"
2369             AC_LANG_POP([C++])
2370
2371             HAVE_GALLIUM_SWR=yes
2372             ;;
2373         xvc4)
2374             HAVE_GALLIUM_VC4=yes
2375             gallium_require_drm "vc4"
2376             gallium_require_drm_loader
2377
2378             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2379                               [USE_VC4_SIMULATOR=yes;
2380                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2381                               [USE_VC4_SIMULATOR=no])
2382             ;;
2383         xvirgl)
2384             HAVE_GALLIUM_VIRGL=yes
2385             gallium_require_drm "virgl"
2386             gallium_require_drm_loader
2387             require_egl_drm "virgl"
2388             ;;
2389         *)
2390             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2391             ;;
2392         esac
2393     done
2394 fi
2395
2396 dnl Set LLVM_LIBS - This is done after the driver configuration so
2397 dnl that drivers can add additional components to LLVM_COMPONENTS.
2398 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2399 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2400 dnl this was causing the same libraries to be appear multiple times
2401 dnl in LLVM_LIBS.
2402
2403 if test "x$MESA_LLVM" != x0; then
2404
2405     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2406        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2407     fi
2408     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2409
2410     dnl llvm-config may not give the right answer when llvm is a built as a
2411     dnl single shared library, so we must work the library name out for
2412     dnl ourselves.
2413     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2414     if test "x$enable_llvm_shared_libs" = xyes; then
2415         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2416         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2417         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2418
2419         if test "x$llvm_have_one_so" = xyes; then
2420             dnl LLVM was built using auto*, so there is only one shared object.
2421             LLVM_LIBS="-l$LLVM_SO_NAME"
2422         else
2423             dnl If LLVM was built with CMake, there will be one shared object per
2424             dnl component.
2425             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2426                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2427         Please make sure you have built llvm with the --enable-shared option
2428         and that your llvm libraries are installed in $LLVM_LIBDIR
2429         If you have installed your llvm libraries to a different directory you
2430         can use the --with-llvm-prefix= configure flag to specify this directory.
2431         NOTE: Mesa is attempting to use llvm shared libraries by default.
2432         If you do not want to build with llvm shared libraries and instead want to
2433         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2434         invocation and rebuild.])])
2435
2436            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2437            dnl install uses a shared object for each component and we have
2438            dnl already added all of these objects to LLVM_LIBS.
2439         fi
2440     else
2441         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2442         dnl We need to link to llvm system libs when using static libs
2443         dnl However, only llvm 3.5+ provides --system-libs
2444         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2445             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2446         fi
2447     fi
2448 fi
2449
2450 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2451 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2452 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2453 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2454 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2455 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2456 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2457                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2458 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2459 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2460 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2461 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2462 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2463 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2464                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2465                                          "x$HAVE_GALLIUM_SWR" = xyes)
2466 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2467 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2468
2469 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2470
2471 if test "x$enable_dri" = xyes; then
2472     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2473 fi
2474
2475 if test "x$have_drisw_kms" = xyes; then
2476     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2477 fi
2478 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2479
2480 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2481 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2482 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2483 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2484 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2485 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2486
2487 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2488
2489 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2490                                         "x$HAVE_I965_DRI" = xyes)
2491
2492 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2493                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2494                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2495 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2496 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2497 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2498 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2499 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2500 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2501     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2502 fi
2503
2504 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2505 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2506 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2507
2508 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2509 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2510 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2511
2512 AC_SUBST([NINE_MAJOR], 1)
2513 AC_SUBST([NINE_MINOR], 0)
2514 AC_SUBST([NINE_TINY], 0)
2515 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2516
2517 AC_SUBST([VDPAU_MAJOR], 1)
2518 AC_SUBST([VDPAU_MINOR], 0)
2519
2520 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2521 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2522 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2523 AC_SUBST([VA_MINOR], $VA_MINOR)
2524
2525 AC_SUBST([XVMC_MAJOR], 1)
2526 AC_SUBST([XVMC_MINOR], 0)
2527
2528 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2529 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2530 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2531 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2532
2533 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2534 AC_SUBST([XA_MINOR], $XA_MINOR)
2535 AC_SUBST([XA_TINY], $XA_TINY)
2536 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2537
2538 AC_ARG_ENABLE(valgrind,
2539               [AS_HELP_STRING([--enable-valgrind],
2540                              [Build mesa with valgrind support (default: auto)])],
2541                              [VALGRIND=$enableval], [VALGRIND=auto])
2542 if test "x$VALGRIND" != xno; then
2543         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2544 fi
2545 AC_MSG_CHECKING([whether to enable Valgrind support])
2546 if test "x$VALGRIND" = xauto; then
2547         VALGRIND="$have_valgrind"
2548 fi
2549
2550 if test "x$VALGRIND" = "xyes"; then
2551         if ! test "x$have_valgrind" = xyes; then
2552                 AC_MSG_ERROR([Valgrind support required but not present])
2553         fi
2554         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2555 fi
2556
2557 AC_MSG_RESULT([$VALGRIND])
2558
2559 dnl Restore LDFLAGS and CPPFLAGS
2560 LDFLAGS="$_SAVE_LDFLAGS"
2561 CPPFLAGS="$_SAVE_CPPFLAGS"
2562
2563 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2564 if test "x$acv_mesa_CLANG" = xyes; then
2565     CFLAGS="$CFLAGS -Qunused-arguments"
2566     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2567 fi
2568
2569 dnl Add user CFLAGS and CXXFLAGS
2570 CFLAGS="$CFLAGS $USER_CFLAGS"
2571 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2572
2573 dnl Substitute the config
2574 AC_CONFIG_FILES([Makefile
2575                 src/Makefile
2576                 src/compiler/Makefile
2577                 src/egl/Makefile
2578                 src/egl/main/egl.pc
2579                 src/egl/wayland/wayland-drm/Makefile
2580                 src/egl/wayland/wayland-egl/Makefile
2581                 src/egl/wayland/wayland-egl/wayland-egl.pc
2582                 src/gallium/Makefile
2583                 src/gallium/auxiliary/Makefile
2584                 src/gallium/auxiliary/pipe-loader/Makefile
2585                 src/gallium/drivers/freedreno/Makefile
2586                 src/gallium/drivers/ddebug/Makefile
2587                 src/gallium/drivers/i915/Makefile
2588                 src/gallium/drivers/ilo/Makefile
2589                 src/gallium/drivers/llvmpipe/Makefile
2590                 src/gallium/drivers/noop/Makefile
2591                 src/gallium/drivers/nouveau/Makefile
2592                 src/gallium/drivers/r300/Makefile
2593                 src/gallium/drivers/r600/Makefile
2594                 src/gallium/drivers/radeon/Makefile
2595                 src/gallium/drivers/radeonsi/Makefile
2596                 src/gallium/drivers/rbug/Makefile
2597                 src/gallium/drivers/softpipe/Makefile
2598                 src/gallium/drivers/svga/Makefile
2599                 src/gallium/drivers/swr/Makefile
2600                 src/gallium/drivers/trace/Makefile
2601                 src/gallium/drivers/vc4/Makefile
2602                 src/gallium/drivers/virgl/Makefile
2603                 src/gallium/state_trackers/clover/Makefile
2604                 src/gallium/state_trackers/dri/Makefile
2605                 src/gallium/state_trackers/glx/xlib/Makefile
2606                 src/gallium/state_trackers/nine/Makefile
2607                 src/gallium/state_trackers/omx/Makefile
2608                 src/gallium/state_trackers/osmesa/Makefile
2609                 src/gallium/state_trackers/va/Makefile
2610                 src/gallium/state_trackers/vdpau/Makefile
2611                 src/gallium/state_trackers/xa/Makefile
2612                 src/gallium/state_trackers/xvmc/Makefile
2613                 src/gallium/targets/d3dadapter9/Makefile
2614                 src/gallium/targets/d3dadapter9/d3d.pc
2615                 src/gallium/targets/dri/Makefile
2616                 src/gallium/targets/libgl-xlib/Makefile
2617                 src/gallium/targets/omx/Makefile
2618                 src/gallium/targets/opencl/Makefile
2619                 src/gallium/targets/opencl/mesa.icd
2620                 src/gallium/targets/osmesa/Makefile
2621                 src/gallium/targets/osmesa/osmesa.pc
2622                 src/gallium/targets/pipe-loader/Makefile
2623                 src/gallium/targets/va/Makefile
2624                 src/gallium/targets/vdpau/Makefile
2625                 src/gallium/targets/xa/Makefile
2626                 src/gallium/targets/xa/xatracker.pc
2627                 src/gallium/targets/xvmc/Makefile
2628                 src/gallium/tests/trivial/Makefile
2629                 src/gallium/tests/unit/Makefile
2630                 src/gallium/winsys/freedreno/drm/Makefile
2631                 src/gallium/winsys/i915/drm/Makefile
2632                 src/gallium/winsys/intel/drm/Makefile
2633                 src/gallium/winsys/nouveau/drm/Makefile
2634                 src/gallium/winsys/radeon/drm/Makefile
2635                 src/gallium/winsys/amdgpu/drm/Makefile
2636                 src/gallium/winsys/svga/drm/Makefile
2637                 src/gallium/winsys/sw/dri/Makefile
2638                 src/gallium/winsys/sw/kms-dri/Makefile
2639                 src/gallium/winsys/sw/null/Makefile
2640                 src/gallium/winsys/sw/wrapper/Makefile
2641                 src/gallium/winsys/sw/xlib/Makefile
2642                 src/gallium/winsys/vc4/drm/Makefile
2643                 src/gallium/winsys/virgl/drm/Makefile
2644                 src/gallium/winsys/virgl/vtest/Makefile
2645                 src/gbm/Makefile
2646                 src/gbm/main/gbm.pc
2647                 src/glx/Makefile
2648                 src/glx/apple/Makefile
2649                 src/glx/tests/Makefile
2650                 src/gtest/Makefile
2651                 src/intel/Makefile
2652                 src/intel/genxml/Makefile
2653                 src/intel/isl/Makefile
2654                 src/intel/vulkan/Makefile
2655                 src/loader/Makefile
2656                 src/mapi/Makefile
2657                 src/mapi/es1api/glesv1_cm.pc
2658                 src/mapi/es2api/glesv2.pc
2659                 src/mapi/glapi/gen/Makefile
2660                 src/mesa/Makefile
2661                 src/mesa/gl.pc
2662                 src/mesa/drivers/dri/dri.pc
2663                 src/mesa/drivers/dri/common/Makefile
2664                 src/mesa/drivers/dri/common/xmlpool/Makefile
2665                 src/mesa/drivers/dri/i915/Makefile
2666                 src/mesa/drivers/dri/i965/Makefile
2667                 src/mesa/drivers/dri/Makefile
2668                 src/mesa/drivers/dri/nouveau/Makefile
2669                 src/mesa/drivers/dri/r200/Makefile
2670                 src/mesa/drivers/dri/radeon/Makefile
2671                 src/mesa/drivers/dri/swrast/Makefile
2672                 src/mesa/drivers/osmesa/Makefile
2673                 src/mesa/drivers/osmesa/osmesa.pc
2674                 src/mesa/drivers/x11/Makefile
2675                 src/mesa/main/tests/Makefile
2676                 src/util/Makefile
2677                 src/util/tests/hash_table/Makefile])
2678
2679 AC_OUTPUT
2680
2681 # Fix up dependencies in *.Plo files, where we changed the extension of a
2682 # source file
2683 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2684 $SED -i -e 's/gen6_blorp.cpp/gen6_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen6_blorp.Plo
2685 $SED -i -e 's/gen7_blorp.cpp/gen7_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen7_blorp.Plo
2686 $SED -i -e 's/gen8_blorp.cpp/gen8_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen8_blorp.Plo
2687
2688
2689 dnl
2690 dnl Output some configuration info for the user
2691 dnl
2692 echo ""
2693 echo "        prefix:          $prefix"
2694 echo "        exec_prefix:     $exec_prefix"
2695 echo "        libdir:          $libdir"
2696 echo "        includedir:      $includedir"
2697
2698 dnl API info
2699 echo ""
2700 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2701
2702 dnl Driver info
2703 echo ""
2704 case "x$enable_osmesa$enable_gallium_osmesa" in
2705 xnoyes)
2706         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2707         ;;
2708 xyesno)
2709         echo "        OSMesa:          lib$OSMESA_LIB"
2710         ;;
2711 xnono)
2712         echo "        OSMesa:          no"
2713         ;;
2714 esac
2715
2716 echo ""
2717 if test "x$enable_dri" != xno; then
2718         echo "        DRI platform:    $dri_platform"
2719         if test -z "$DRI_DIRS"; then
2720             echo "        DRI drivers:     no"
2721         else
2722             echo "        DRI drivers:     $DRI_DIRS"
2723         fi
2724         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2725 fi
2726
2727 case "x$enable_glx" in
2728 xdri)
2729     echo "        GLX:             DRI-based"
2730     ;;
2731 xxlib)
2732     echo "        GLX:             Xlib-based"
2733     ;;
2734 xgallium-xlib)
2735     echo "        GLX:             Xlib-based (Gallium)"
2736     ;;
2737 *)
2738     echo "        GLX:             $enable_glx"
2739     ;;
2740 esac
2741
2742 dnl EGL
2743 echo ""
2744 echo "        EGL:             $enable_egl"
2745 if test "$enable_egl" = yes; then
2746     echo "        EGL platforms:   $egl_platforms"
2747
2748     egl_drivers=""
2749     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2750         egl_drivers="$egl_drivers builtin:egl_dri2"
2751     fi
2752     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2753         egl_drivers="$egl_drivers builtin:egl_dri3"
2754     fi
2755
2756     echo "        EGL drivers:    $egl_drivers"
2757 fi
2758
2759 # Vulkan
2760 echo ""
2761 if test "x$VULKAN_DRIVERS" != x; then
2762     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2763     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2764 else
2765     echo "        Vulkan drivers:  no"
2766 fi
2767
2768 echo ""
2769 if test "x$MESA_LLVM" = x1; then
2770     echo "        llvm:            yes"
2771     echo "        llvm-config:     $LLVM_CONFIG"
2772     echo "        llvm-version:    $LLVM_VERSION"
2773 else
2774     echo "        llvm:            no"
2775 fi
2776
2777 echo ""
2778 if test -n "$with_gallium_drivers"; then
2779     echo "        Gallium drivers: $gallium_drivers"
2780     echo "        Gallium st:      $gallium_st"
2781 else
2782     echo "        Gallium:         no"
2783 fi
2784
2785 dnl Shader cache
2786 echo ""
2787 echo "        Shader cache:    $enable_shader_cache"
2788 if test "x$enable_shader_cache" = "xyes"; then
2789     echo "        With SHA1 from:  $with_sha1"
2790 fi
2791
2792 dnl Libraries
2793 echo ""
2794 echo "        Shared libs:     $enable_shared"
2795 echo "        Static libs:     $enable_static"
2796 echo "        Shared-glapi:    $enable_shared_glapi"
2797
2798 dnl Compiler options
2799 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2800 cflags=`echo $CFLAGS | \
2801     $SED 's/^ *//;s/  */ /;s/ *$//'`
2802 cxxflags=`echo $CXXFLAGS | \
2803     $SED 's/^ *//;s/  */ /;s/ *$//'`
2804 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2805 echo ""
2806 echo "        CFLAGS:          $cflags"
2807 echo "        CXXFLAGS:        $cxxflags"
2808 echo "        Macros:          $defines"
2809 echo ""
2810 if test "x$MESA_LLVM" = x1; then
2811     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2812     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2813     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2814     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2815     echo ""
2816 fi
2817 echo "        PYTHON2:         $PYTHON2"
2818 echo "        PYTHON3:         $PYTHON3"
2819
2820 echo ""
2821 echo "        Run '${MAKE-make}' to build Mesa"
2822 echo ""