configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  30 USER_CFLAGS="$CFLAGS"
  31 USER_CXXFLAGS="$CXXFLAGS"
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.31
  36 LIBDRM_INTEL_REQUIRED=2.4.37
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54 AC_PATH_PROG([MKDEP], [makedepend])
  55
  56 if test "x$MKDEP" = "x"; then
  57     AC_MSG_ERROR([makedepend is required to build Mesa])
  58 fi
  59
  60 AC_PROG_YACC
  61 AC_PATH_PROG([YACC_INST], $YACC)
  62 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  63     if test -z "$YACC_INST"; then
  64         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  65     fi
  66 fi
  67 AC_PROG_LEX
  68
  69 AC_PATH_PROG([PERL], [perl])
  70
  71 AC_CHECK_PROG(INDENT, indent, indent, cat)
  72 if test "x$INDENT" != "xcat"; then
  73     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  74 fi
  75
  76 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  77 dnl configuration in that case.
  78 AC_PROG_INSTALL
  79 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  80
  81 dnl We need a POSIX shell for parts of the build. Assume we have one
  82 dnl in most cases.
  83 case "$host_os" in
  84 solaris*)
  85     # Solaris /bin/sh is too old/non-POSIX compliant
  86     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  87     SHELL="$POSIX_SHELL"
  88     ;;
  89 esac
  90
  91 dnl clang is mostly GCC-compatible, but its version is much lower,
  92 dnl so we have to check for it.
  93 AC_MSG_CHECKING([if compiling with clang])
  94
  95 AC_COMPILE_IFELSE(
  96 [AC_LANG_PROGRAM([], [[
  97 #ifndef __clang__
  98        not clang
  99 #endif
 100 ]])],
 101 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 102
 103 AC_MSG_RESULT([$acv_mesa_CLANG])
 104
 105 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 106 dnl versions are explictly not supported.
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124 fi
 125
 126
 127 MKDEP_OPTIONS=-fdepend
 128 dnl Ask gcc where it's keeping its secret headers
 129 if test "x$GCC" = xyes; then
 130     for dir in include include-fixed; do
 131         GCC_INCLUDES=`$CC -print-file-name=$dir`
 132         if test "x$GCC_INCLUDES" != x && \
 133            test "$GCC_INCLUDES" != "$dir" && \
 134            test -d "$GCC_INCLUDES"; then
 135             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 136         fi
 137     done
 138 fi
 139 AC_SUBST([MKDEP_OPTIONS])
 140
 141 dnl Make sure the pkg-config macros are defined
 142 m4_ifndef([PKG_PROG_PKG_CONFIG],
 143     [m4_fatal([Could not locate the pkg-config autoconf macros.
 144   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 145   are in a different location, try setting the environment variable
 146   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 147 PKG_PROG_PKG_CONFIG()
 148
 149 dnl LIB_DIR - library basename
 150 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 151 AC_SUBST([LIB_DIR])
 152
 153 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 154 _SAVE_LDFLAGS="$LDFLAGS"
 155 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 156 AC_SUBST([EXTRA_LIB_PATH])
 157
 158 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 159 _SAVE_CPPFLAGS="$CPPFLAGS"
 160 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 161 AC_SUBST([X11_INCLUDES])
 162
 163 dnl Compiler macros
 164 DEFINES=""
 165 AC_SUBST([DEFINES])
 166 case "$host_os" in
 167 linux*|*-gnu*|gnu*)
 168     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 169     ;;
 170 solaris*)
 171     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 172     ;;
 173 cygwin*)
 174     DEFINES="$DEFINES -DPTHREADS"
 175     ;;
 176 esac
 177
 178 dnl Add flags for gcc and g++
 179 if test "x$GCC" = xyes; then
 180     CFLAGS="$CFLAGS -Wall -std=c99"
 181
 182     # Enable -Werror=implicit-function-declaration and
 183     # -Werror=missing-prototypes, if available, or otherwise, just
 184     # -Wmissing-prototypes.  This is particularly useful to avoid
 185     # generating a loadable driver module that has undefined symbols.
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 188     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 189     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 191                    AC_MSG_RESULT([yes]),
 192                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 193                     AC_MSG_RESULT([no])]);
 194
 195     # Enable -fvisibility=hidden if using a gcc that supports it
 196     save_CFLAGS="$CFLAGS"
 197     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 198     VISIBILITY_CFLAGS="-fvisibility=hidden"
 199     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 200     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 201                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 202
 203     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 204     CFLAGS=$save_CFLAGS
 205
 206     # Work around aliasing bugs - developers should comment this out
 207     CFLAGS="$CFLAGS -fno-strict-aliasing"
 208
 209     # gcc's builtin memcmp is slower than glibc's
 210     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 231
 232     # gcc's builtin memcmp is slower than glibc's
 233     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 234     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 235 fi
 236
 237 dnl even if the compiler appears to support it, using visibility attributes isn't
 238 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 239 case "$host_os" in
 240 cygwin*)
 241     VISIBILITY_CFLAGS=""
 242     VISIBILITY_CXXFLAGS=""
 243     ;;
 244 esac
 245
 246 AC_SUBST([VISIBILITY_CFLAGS])
 247 AC_SUBST([VISIBILITY_CXXFLAGS])
 248
 249 dnl
 250 dnl Hacks to enable 32 or 64 bit build
 251 dnl
 252 AC_ARG_ENABLE([32-bit],
 253     [AS_HELP_STRING([--enable-32-bit],
 254         [build 32-bit libraries @<:@default=auto@:>@])],
 255     [enable_32bit="$enableval"],
 256     [enable_32bit=auto]
 257 )
 258 if test "x$enable_32bit" = xyes; then
 259     if test "x$GCC" = xyes; then
 260         CFLAGS="$CFLAGS -m32"
 261         CCASFLAGS="$CCASFLAGS -m32"
 262     fi
 263     if test "x$GXX" = xyes; then
 264         CXXFLAGS="$CXXFLAGS -m32"
 265     fi
 266 fi
 267 AC_ARG_ENABLE([64-bit],
 268     [AS_HELP_STRING([--enable-64-bit],
 269         [build 64-bit libraries @<:@default=auto@:>@])],
 270     [enable_64bit="$enableval"],
 271     [enable_64bit=auto]
 272 )
 273 if test "x$enable_64bit" = xyes; then
 274     if test "x$GCC" = xyes; then
 275         CFLAGS="$CFLAGS -m64"
 276     fi
 277     if test "x$GXX" = xyes; then
 278         CXXFLAGS="$CXXFLAGS -m64"
 279     fi
 280 fi
 281
 282 dnl Can't have static and shared libraries, default to static if user
 283 dnl explicitly requested. If both disabled, set to static since shared
 284 dnl was explicitly requested.
 285 case "x$enable_static$enable_shared" in
 286 xyesyes )
 287     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 288     enable_shared=no
 289     ;;
 290 xnono )
 291     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 292     enable_static=yes
 293     ;;
 294 esac
 295
 296 dnl
 297 dnl mklib options
 298 dnl
 299 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 300 if test "$enable_static" = yes; then
 301     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 302 fi
 303 AC_SUBST([MKLIB_OPTIONS])
 304
 305 dnl
 306 dnl other compiler options
 307 dnl
 308 AC_ARG_ENABLE([debug],
 309     [AS_HELP_STRING([--enable-debug],
 310         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 311     [enable_debug="$enableval"],
 312     [enable_debug=no]
 313 )
 314 if test "x$enable_debug" = xyes; then
 315     DEFINES="$DEFINES -DDEBUG"
 316     if test "x$GCC" = xyes; then
 317         CFLAGS="$CFLAGS -g"
 318     fi
 319     if test "x$GXX" = xyes; then
 320         CXXFLAGS="$CXXFLAGS -g"
 321     fi
 322 fi
 323
 324 dnl
 325 dnl library names
 326 dnl
 327 LIB_PREFIX_GLOB='lib'
 328 LIB_VERSION_SEPARATOR='.'
 329 if test "$enable_static" = yes; then
 330     LIB_EXTENSION='a'
 331 else
 332     case "$host_os" in
 333     darwin* )
 334         LIB_EXTENSION='dylib' ;;
 335     cygwin* )
 336         dnl prefix can be 'cyg' or 'lib'
 337         LIB_PREFIX_GLOB='???'
 338         LIB_VERSION_SEPARATOR='-'
 339         LIB_EXTENSION='dll' ;;
 340     aix* )
 341         LIB_EXTENSION='a' ;;
 342     * )
 343         LIB_EXTENSION='so' ;;
 344     esac
 345 fi
 346 AC_ARG_WITH([gl-lib-name],
 347   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 348     [specify GL library name @<:@default=GL@:>@])],
 349   [GL_LIB=$withval],
 350   [GL_LIB=GL])
 351 AC_ARG_WITH([glu-lib-name],
 352   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 353     [specify GLU library name @<:@default=GLU@:>@])],
 354   [GLU_LIB=$withval],
 355   [GLU_LIB=GLU])
 356 AC_ARG_WITH([osmesa-lib-name],
 357   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 358     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 359   [OSMESA_LIB=$withval],
 360   [OSMESA_LIB=OSMesa])
 361 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 362 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 363 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 364
 365 dnl
 366 dnl Mangled Mesa support
 367 dnl
 368 AC_ARG_ENABLE([mangling],
 369   [AS_HELP_STRING([--enable-mangling],
 370     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 371   [enable_mangling="${enableval}"],
 372   [enable_mangling=no]
 373 )
 374 if test "x${enable_mangling}" = "xyes" ; then
 375   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 376   GL_LIB="Mangled${GL_LIB}"
 377   GLU_LIB="Mangled${GLU_LIB}"
 378   OSMESA_LIB="Mangled${OSMESA_LIB}"
 379 fi
 380 AC_SUBST([GL_LIB])
 381 AC_SUBST([GLU_LIB])
 382 AC_SUBST([OSMESA_LIB])
 383
 384 dnl
 385 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 386 dnl
 387 AC_ARG_ENABLE([texture-float],
 388     [AS_HELP_STRING([--enable-texture-float],
 389         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 390     [enable_texture_float="$enableval"],
 391     [enable_texture_float=no]
 392 )
 393 if test "x$enable_texture_float" = xyes; then
 394     AC_MSG_WARN([Floating-point textures enabled.])
 395     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 396     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 397 fi
 398
 399 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 400 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 401 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 402 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 403 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 404 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 405 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 406 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 407
 408 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 411 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 412 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 413 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 414 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 415 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 416
 417 AC_SUBST([GL_LIB_NAME])
 418 AC_SUBST([GLU_LIB_NAME])
 419 AC_SUBST([OSMESA_LIB_NAME])
 420 AC_SUBST([EGL_LIB_NAME])
 421 AC_SUBST([GLESv1_CM_LIB_NAME])
 422 AC_SUBST([GLESv2_LIB_NAME])
 423 AC_SUBST([VG_LIB_NAME])
 424 AC_SUBST([GLAPI_LIB_NAME])
 425
 426 AC_SUBST([GL_LIB_GLOB])
 427 AC_SUBST([GLU_LIB_GLOB])
 428 AC_SUBST([EGL_LIB_GLOB])
 429 AC_SUBST([GLESv1_CM_LIB_GLOB])
 430 AC_SUBST([GLESv2_LIB_GLOB])
 431 AC_SUBST([VG_LIB_GLOB])
 432 AC_SUBST([GLAPI_LIB_GLOB])
 433
 434 dnl
 435 dnl Arch/platform-specific settings
 436 dnl
 437 AC_ARG_ENABLE([asm],
 438     [AS_HELP_STRING([--disable-asm],
 439         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 440     [enable_asm="$enableval"],
 441     [enable_asm=yes]
 442 )
 443 asm_arch=""
 444 MESA_ASM_FILES=""
 445 AC_MSG_CHECKING([whether to enable assembly])
 446 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 447 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 448 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 449     case "$host_cpu" in
 450     i?86 | x86_64)
 451         enable_asm=no
 452         AC_MSG_RESULT([no, cross compiling])
 453         ;;
 454     esac
 455 fi
 456 # check for supported arches
 457 if test "x$enable_asm" = xyes; then
 458     case "$host_cpu" in
 459     i?86)
 460         case "$host_os" in
 461         linux* | *freebsd* | dragonfly* | *netbsd*)
 462             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 463             ;;
 464         esac
 465         ;;
 466     x86_64)
 467         case "$host_os" in
 468         linux* | *freebsd* | dragonfly* | *netbsd*)
 469             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 470             ;;
 471         esac
 472         ;;
 473     powerpc)
 474         case "$host_os" in
 475         linux*)
 476             asm_arch=ppc
 477             ;;
 478         esac
 479         ;;
 480     sparc*)
 481         case "$host_os" in
 482         linux*)
 483             asm_arch=sparc
 484             ;;
 485         esac
 486         ;;
 487     esac
 488
 489     case "$asm_arch" in
 490     x86)
 491         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 492         MESA_ASM_FILES='$(X86_FILES)'
 493         AC_MSG_RESULT([yes, x86])
 494         ;;
 495     x86_64)
 496         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 497         MESA_ASM_FILES='$(X86_64_FILES)'
 498         AC_MSG_RESULT([yes, x86_64])
 499         ;;
 500     sparc)
 501         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 502         MESA_ASM_FILES='$(SPARC_FILES)'
 503         AC_MSG_RESULT([yes, sparc])
 504         ;;
 505     *)
 506         AC_MSG_RESULT([no, platform not supported])
 507         ;;
 508     esac
 509 fi
 510 AC_SUBST([MESA_ASM_FILES])
 511
 512 dnl PIC code macro
 513 MESA_PIC_FLAGS
 514
 515 dnl Check to see if dlopen is in default libraries (like Solaris, which
 516 dnl has it in libc), or if libdl is needed to get it.
 517 AC_CHECK_FUNC([dlopen], [],
 518     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 519 AC_SUBST([DLOPEN_LIBS])
 520
 521 dnl See if posix_memalign is available
 522 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 523
 524 dnl SELinux awareness.
 525 AC_ARG_ENABLE([selinux],
 526     [AS_HELP_STRING([--enable-selinux],
 527         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 528     [MESA_SELINUX="$enableval"],
 529     [MESA_SELINUX=no])
 530 if test "x$enable_selinux" = "xyes"; then
 531     AC_CHECK_HEADER([selinux/selinux.h],[],
 532                     [AC_MSG_ERROR([SELinux headers not found])])
 533     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 534                  [AC_MSG_ERROR([SELinux library not found])])
 535     SELINUX_LIBS="-lselinux"
 536     DEFINES="$DEFINES -DMESA_SELINUX"
 537 fi
 538
 539 dnl Options for APIs
 540 AC_ARG_ENABLE([opengl],
 541     [AS_HELP_STRING([--disable-opengl],
 542         [disable support for standard OpenGL API @<:@default=no@:>@])],
 543     [enable_opengl="$enableval"],
 544     [enable_opengl=yes])
 545 AC_ARG_ENABLE([gles1],
 546     [AS_HELP_STRING([--enable-gles1],
 547         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 548     [enable_gles1="$enableval"],
 549     [enable_gles1=no])
 550 AC_ARG_ENABLE([gles2],
 551     [AS_HELP_STRING([--enable-gles2],
 552         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 553     [enable_gles2="$enableval"],
 554     [enable_gles2=no])
 555 AC_ARG_ENABLE([openvg],
 556     [AS_HELP_STRING([--enable-openvg],
 557         [enable support for OpenVG API @<:@default=no@:>@])],
 558     [enable_openvg="$enableval"],
 559     [enable_openvg=no])
 560
 561 AC_ARG_ENABLE([dri],
 562     [AS_HELP_STRING([--enable-dri],
 563         [enable DRI modules @<:@default=auto@:>@])],
 564     [enable_dri="$enableval"],
 565     [enable_dri=auto])
 566 AC_ARG_ENABLE([glx],
 567     [AS_HELP_STRING([--enable-glx],
 568         [enable GLX library @<:@default=auto@:>@])],
 569     [enable_glx="$enableval"],
 570     [enable_glx=auto])
 571 AC_ARG_ENABLE([osmesa],
 572     [AS_HELP_STRING([--enable-osmesa],
 573         [enable OSMesa library @<:@default=auto@:>@])],
 574     [enable_osmesa="$enableval"],
 575     [enable_osmesa=auto])
 576 AC_ARG_ENABLE([egl],
 577     [AS_HELP_STRING([--disable-egl],
 578         [disable EGL library @<:@default=enabled@:>@])],
 579     [enable_egl="$enableval"],
 580     [enable_egl=yes])
 581
 582 AC_ARG_ENABLE([xorg],
 583     [AS_HELP_STRING([--enable-xorg],
 584         [enable support for X.Org DDX API @<:@default=no@:>@])],
 585     [enable_xorg="$enableval"],
 586     [enable_xorg=no])
 587 AC_ARG_ENABLE([xa],
 588     [AS_HELP_STRING([--enable-xa],
 589         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 590     [enable_xa="$enableval"],
 591     [enable_xa=no])
 592 AC_ARG_ENABLE([d3d1x],
 593     [AS_HELP_STRING([--enable-d3d1x],
 594         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 595     [enable_d3d1x="$enableval"],
 596     [enable_d3d1x=no])
 597 AC_ARG_ENABLE([gbm],
 598    [AS_HELP_STRING([--enable-gbm],
 599          [enable gbm library @<:@default=auto@:>@])],
 600    [enable_gbm="$enableval"],
 601    [enable_gbm=auto])
 602
 603 AC_ARG_ENABLE([xvmc],
 604    [AS_HELP_STRING([--enable-xvmc],
 605          [enable xvmc library @<:@default=auto@:>@])],
 606    [enable_xvmc="$enableval"],
 607    [enable_xvmc=auto])
 608 AC_ARG_ENABLE([vdpau],
 609    [AS_HELP_STRING([--enable-vdpau],
 610          [enable vdpau library @<:@default=auto@:>@])],
 611    [enable_vdpau="$enableval"],
 612    [enable_vdpau=auto])
 613 AC_ARG_ENABLE([va],
 614    [AS_HELP_STRING([--enable-va],
 615          [enable va library @<:@default=auto@:>@])],
 616    [enable_va="$enableval"],
 617    [enable_va=auto])
 618 AC_ARG_ENABLE([opencl],
 619    [AS_HELP_STRING([--enable-opencl],
 620          [enable OpenCL library @<:@default=no@:>@])],
 621    [enable_opencl="$enableval"],
 622    [enable_opencl=no])
 623 AC_ARG_ENABLE([xlib_glx],
 624     [AS_HELP_STRING([--enable-xlib-glx],
 625         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 626     [enable_xlib_glx="$enableval"],
 627     [enable_xlib_glx=auto])
 628 AC_ARG_ENABLE([gallium_egl],
 629     [AS_HELP_STRING([--enable-gallium-egl],
 630         [enable optional EGL state tracker (not required
 631          for EGL support in Gallium with OpenGL and OpenGL ES)
 632          @<:@default=disable@:>@])],
 633     [enable_gallium_egl="$enableval"],
 634     [enable_gallium_egl=no])
 635 AC_ARG_ENABLE([gallium_gbm],
 636     [AS_HELP_STRING([--enable-gallium-gbm],
 637         [enable optional gbm state tracker (not required for
 638          gbm support in Gallium)
 639          @<:@default=auto@:>@])],
 640     [enable_gallium_gbm="$enableval"],
 641     [enable_gallium_gbm=auto])
 642
 643 AC_ARG_ENABLE([r600-llvm-compiler],
 644     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 645         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 646     [enable_r600_llvm="$enableval"],
 647     [enable_r600_llvm=no])
 648
 649 AC_ARG_ENABLE([gallium_tests],
 650     [AS_HELP_STRING([--enable-gallium-tests],
 651         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 652     [enable_gallium_tests="$enableval"],
 653     [enable_gallium_tests=no])
 654
 655 # Option for Gallium drivers
 656 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 657
 658 AC_ARG_WITH([gallium-drivers],
 659     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 660         [comma delimited Gallium drivers list, e.g.
 661         "i915,nouveau,r300,r600,svga,swrast"
 662         @<:@default=r300,r600,swrast@:>@])],
 663     [with_gallium_drivers="$withval"],
 664     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 665
 666 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 667 # here so that the script doesn't choke on an unknown driver name later.
 668 case "$with_gallium_drivers" in
 669     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 670     no) with_gallium_drivers='' ;;
 671 esac
 672
 673 if test "x$enable_opengl" = xno -a \
 674         "x$enable_gles1" = xno -a \
 675         "x$enable_gles2" = xno -a \
 676         "x$enable_openvg" = xno -a \
 677         "x$enable_xorg" = xno -a \
 678         "x$enable_xa" = xno -a \
 679         "x$enable_d3d1x" = xno -a \
 680         "x$enable_xvmc" = xno -a \
 681         "x$enable_vdpau" = xno -a \
 682         "x$enable_va" = xno -a \
 683         "x$enable_opencl" = xno; then
 684     AC_MSG_ERROR([at least one API should be enabled])
 685 fi
 686
 687 API_DEFINES=""
 688 if test "x$enable_opengl" = xno; then
 689     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 690 else
 691     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 692 fi
 693 if test "x$enable_gles1" = xyes; then
 694     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 695 fi
 696 if test "x$enable_gles2" = xyes; then
 697     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 698 fi
 699 AC_SUBST([API_DEFINES])
 700
 701 AC_ARG_ENABLE([shared-glapi],
 702     [AS_HELP_STRING([--enable-shared-glapi],
 703         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 704     [enable_shared_glapi="$enableval"],
 705     [enable_shared_glapi=no])
 706
 707 SHARED_GLAPI="0"
 708 if test "x$enable_shared_glapi" = xyes; then
 709     SHARED_GLAPI="1"
 710     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 711     # the remap table)
 712     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 713     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 714 fi
 715 AC_SUBST([SHARED_GLAPI])
 716 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 717
 718 dnl
 719 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 720 dnl More later: fbdev, ...
 721 dnl
 722 default_driver="xlib"
 723
 724 case "$host_os" in
 725 linux*)
 726     default_driver="dri";;
 727     ;;
 728 *freebsd* | dragonfly* | *netbsd*)
 729     case "$host_cpu" in
 730     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 731     esac
 732     ;;
 733 esac
 734
 735 if test "x$enable_opengl" = xno; then
 736     default_driver="no"
 737 fi
 738
 739 AC_ARG_WITH([driver],
 740     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 741     [mesa_driver="$withval"],
 742     [mesa_driver=auto])
 743 dnl Check for valid option
 744 case "x$mesa_driver" in
 745 xxlib|xdri|xosmesa|xno)
 746     if test "x$enable_dri" != xauto -o \
 747             "x$enable_glx" != xauto -o \
 748             "x$enable_osmesa" != xauto -o \
 749             "x$enable_xlib_glx" != xauto; then
 750         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 751     fi
 752     ;;
 753 xauto)
 754     mesa_driver="$default_driver"
 755     ;;
 756 *)
 757     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 758     ;;
 759 esac
 760
 761 # map $mesa_driver to APIs
 762 if test "x$enable_dri" = xauto; then
 763     case "x$mesa_driver" in
 764     xdri) enable_dri=yes ;;
 765     *)    enable_dri=no ;;
 766     esac
 767 fi
 768
 769 if test "x$enable_glx" = xauto; then
 770     case "x$mesa_driver" in
 771     xdri|xxlib) enable_glx=yes ;;
 772     *)          enable_glx=no ;;
 773     esac
 774 fi
 775
 776 if test "x$enable_osmesa" = xauto; then
 777     case "x$mesa_driver" in
 778     xxlib|xosmesa) enable_osmesa=yes ;;
 779     *)             enable_osmesa=no ;;
 780     esac
 781 fi
 782
 783 if test "x$enable_xlib_glx" = xauto; then
 784     case "x$mesa_driver" in
 785     xxlib) enable_xlib_glx=yes ;;
 786     *)     enable_xlib_glx=no ;;
 787     esac
 788 fi
 789
 790 if test "x$enable_glx" = xno; then
 791     enable_xlib_glx=no
 792 fi
 793
 794 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 795
 796 dnl
 797 dnl Driver specific build directories
 798 dnl
 799
 800 dnl this variable will be prepended to SRC_DIRS and is not exported
 801 CORE_DIRS=""
 802
 803 SRC_DIRS="gtest"
 804 GLU_DIRS="sgi"
 805 GALLIUM_DIRS="auxiliary drivers state_trackers"
 806 GALLIUM_TARGET_DIRS=""
 807 GALLIUM_WINSYS_DIRS="sw"
 808 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 809 GALLIUM_STATE_TRACKERS_DIRS=""
 810
 811 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 812 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 813 x*yes*)
 814     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 815     ;;
 816 esac
 817
 818 # build glapi if OpenGL is enabled
 819 if test "x$enable_opengl" = xyes; then
 820     CORE_DIRS="$CORE_DIRS mapi/glapi"
 821 fi
 822
 823 # build es1api if OpenGL ES 1.x is enabled
 824 if test "x$enable_gles1" = xyes; then
 825     CORE_DIRS="$CORE_DIRS mapi/es1api"
 826 fi
 827
 828 # build es2api if OpenGL ES 2.x is enabled
 829 if test "x$enable_gles2" = xyes; then
 830     CORE_DIRS="$CORE_DIRS mapi/es2api"
 831 fi
 832
 833 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 834 case "x$enable_opengl$enable_gles1$enable_gles2" in
 835 x*yes*)
 836     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 837     ;;
 838 esac
 839
 840 case "x$enable_glx$enable_xlib_glx" in
 841 xyesyes)
 842     DRIVER_DIRS="$DRIVER_DIRS x11"
 843     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 844     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 845     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 846     HAVE_WINSYS_XLIB="yes"
 847     ;;
 848 xyesno)
 849     # DRI-based GLX
 850     SRC_DIRS="$SRC_DIRS glx"
 851     ;;
 852 esac
 853
 854 if test "x$enable_dri" = xyes; then
 855     DRIVER_DIRS="$DRIVER_DIRS dri"
 856
 857     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 858     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 859     HAVE_ST_DRI="yes"
 860 fi
 861
 862 if test "x$enable_osmesa" = xyes; then
 863     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 864 fi
 865
 866 AC_SUBST([SRC_DIRS])
 867 AC_SUBST([GLU_DIRS])
 868 AC_SUBST([DRIVER_DIRS])
 869 AC_SUBST([GALLIUM_DIRS])
 870 AC_SUBST([GALLIUM_TARGET_DIRS])
 871 AC_SUBST([GALLIUM_WINSYS_DIRS])
 872 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 873 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 874 AC_SUBST([MESA_LLVM])
 875
 876 # Check for libdrm
 877 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 878                   [have_libdrm=yes], [have_libdrm=no])
 879
 880 if test "x$enable_dri" = xyes; then
 881     # DRI must be shared, I think
 882     if test "$enable_static" = yes; then
 883         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 884     fi
 885
 886     # not a hard requirement as swrast does not depend on it
 887     if test "x$have_libdrm" = xyes; then
 888         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 889     fi
 890 fi
 891
 892 dnl
 893 dnl Find out if X is available. The variable have_x is set if libX11 is
 894 dnl found to mimic AC_PATH_XTRA.
 895 dnl
 896 if test -n "$PKG_CONFIG"; then
 897     AC_MSG_CHECKING([pkg-config files for X11 are available])
 898     PKG_CHECK_EXISTS([x11],[
 899         x11_pkgconfig=yes
 900         have_x=yes
 901         ],[
 902         x11_pkgconfig=no
 903     ])
 904     AC_MSG_RESULT([$x11_pkgconfig])
 905 else
 906     x11_pkgconfig=no
 907 fi
 908 dnl Use the autoconf macro if no pkg-config files
 909 if test "$x11_pkgconfig" = yes; then
 910     PKG_CHECK_MODULES([X11], [x11])
 911 else
 912     AC_PATH_XTRA
 913     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 914     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 915     AC_SUBST([X11_CFLAGS])
 916     AC_SUBST([X11_LIBS])
 917 fi
 918
 919 dnl Try to tell the user that the --x-* options are only used when
 920 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 921 m4_divert_once([HELP_BEGIN],
 922 [These options are only used when the X libraries cannot be found by the
 923 pkg-config utility.])
 924
 925 dnl We need X for xlib and dri, so bomb now if it's not found
 926 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 927     AC_MSG_ERROR([X11 development libraries needed for GLX])
 928 fi
 929
 930 if test "x$enable_glx" = xyes; then
 931     DEFINES="$DEFINES -DUSE_XCB"
 932 fi
 933
 934 dnl Direct rendering or just indirect rendering
 935 case "$host_os" in
 936 gnu*)
 937     dnl Disable by default on GNU/Hurd
 938     driglx_direct_default="no"
 939     ;;
 940 cygwin*)
 941     dnl Disable by default on cygwin
 942     driglx_direct_default="no"
 943     ;;
 944 *)
 945     driglx_direct_default="yes"
 946     ;;
 947 esac
 948 AC_ARG_ENABLE([driglx-direct],
 949     [AS_HELP_STRING([--disable-driglx-direct],
 950         [enable direct rendering in GLX and EGL for DRI \
 951             @<:@default=auto@:>@])],
 952     [driglx_direct="$enableval"],
 953     [driglx_direct="$driglx_direct_default"])
 954
 955 dnl
 956 dnl libGL configuration per driver
 957 dnl
 958 case "x$enable_glx$enable_xlib_glx" in
 959 xyesyes)
 960     # Xlib-based GLX
 961     if test "$x11_pkgconfig" = yes; then
 962         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 963         GL_PC_REQ_PRIV="x11 xext"
 964         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 965         GL_LIB_DEPS="$XLIBGL_LIBS"
 966     else
 967         # should check these...
 968         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 969         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 970         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 971         GL_PC_CFLAGS="$X11_INCLUDES"
 972     fi
 973     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 974     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 975     ;;
 976 xyesno)
 977     # DRI-based GLX
 978     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 979     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 980     if test x"$driglx_direct" = xyes; then
 981         if test "x$have_libdrm" != xyes; then
 982             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 983         fi
 984         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 985         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 986     fi
 987
 988     # find the DRI deps for libGL
 989     if test "$x11_pkgconfig" = yes; then
 990         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 991
 992         # add xf86vidmode if available
 993         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 994         if test "$HAVE_XF86VIDMODE" = yes ; then
 995             dri_modules="$dri_modules xxf86vm"
 996         fi
 997
 998         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 999         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1000         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1001         GL_LIB_DEPS="$DRIGL_LIBS"
1002     else
1003         # should check these...
1004         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1005         if test "x$HAVE_XF86VIDMODE" == xyes; then
1006            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1007         else
1008            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1009         fi
1010         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1011         GL_PC_CFLAGS="$X11_INCLUDES"
1012
1013         # XCB can only be used from pkg-config
1014         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx >= 1.8.1])
1015         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1016         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1017         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1018     fi
1019
1020     # need DRM libs, -lpthread, etc.
1021     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1022     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1023     ;;
1024 esac
1025
1026 # This is outside the case (above) so that it is invoked even for non-GLX
1027 # builds.
1028 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1029
1030 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1031 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1032 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1033 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1034
1035 AC_SUBST([GL_LIB_DEPS])
1036 AC_SUBST([GL_PC_REQ_PRIV])
1037 AC_SUBST([GL_PC_LIB_PRIV])
1038 AC_SUBST([GL_PC_CFLAGS])
1039 AC_SUBST([DRI_PC_REQ_PRIV])
1040 AC_SUBST([GLESv1_CM_LIB_DEPS])
1041 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1042 AC_SUBST([GLESv2_LIB_DEPS])
1043 AC_SUBST([GLESv2_PC_LIB_PRIV])
1044
1045 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1046 AC_SUBST([GLAPI_LIB_DEPS])
1047
1048
1049 dnl dri libraries are linking with mesa
1050 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.la'
1051 GALLIUM_DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1052
1053 dnl ... or dricore?
1054 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1055     DRI_LIB_DEPS="\$(TOP)/src/mesa/libdricore/libdricore${VERSION}.la"
1056     GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
1057     HAVE_DRICORE=yes
1058 fi
1059 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
1060
1061 AC_SUBST([HAVE_XF86VIDMODE])
1062
1063 dnl
1064 dnl More GLX setup
1065 dnl
1066 case "x$enable_glx$enable_xlib_glx" in
1067 xyesyes)
1068     DEFINES="$DEFINES -DUSE_XSHM"
1069     ;;
1070 xyesno)
1071     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1072     if test "x$driglx_direct" = xyes; then
1073         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1074     fi
1075     ;;
1076 esac
1077
1078 dnl
1079 dnl TLS detection
1080 dnl
1081
1082 AC_ARG_ENABLE([glx-tls],
1083     [AS_HELP_STRING([--enable-glx-tls],
1084         [enable TLS support in GLX @<:@default=disabled@:>@])],
1085     [GLX_USE_TLS="$enableval"],
1086     [GLX_USE_TLS=no])
1087 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1088
1089 AS_IF([test "x$GLX_USE_TLS" = xyes],
1090       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1091
1092 dnl
1093 dnl More DRI setup
1094 dnl
1095 dnl Directory for DRI drivers
1096 AC_ARG_WITH([dri-driverdir],
1097     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1098         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1099     [DRI_DRIVER_INSTALL_DIR="$withval"],
1100     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1101 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1102 dnl Extra search path for DRI drivers
1103 AC_ARG_WITH([dri-searchpath],
1104     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1105         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1106     [DRI_DRIVER_SEARCH_DIR="$withval"],
1107     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1108 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1109 dnl Which drivers to build - default is chosen by platform
1110 AC_ARG_WITH([dri-drivers],
1111     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1112         [comma delimited DRI drivers list, e.g.
1113         "swrast,i965,radeon" @<:@default=auto@:>@])],
1114     [with_dri_drivers="$withval"],
1115     [with_dri_drivers=yes])
1116 if test "x$with_dri_drivers" = x; then
1117     with_dri_drivers=no
1118 fi
1119
1120 dnl If $with_dri_drivers is yes, directories will be added through
1121 dnl platform checks
1122 DRI_DIRS=""
1123 case "$with_dri_drivers" in
1124 no) ;;
1125 yes)
1126     # classic DRI drivers require FEATURE_GL to build
1127     if test "x$enable_opengl" = xyes; then
1128         DRI_DIRS="yes"
1129     fi
1130     ;;
1131 *)
1132     # verify the requested driver directories exist
1133     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1134     for driver in $dri_drivers; do
1135         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1136             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1137     done
1138     DRI_DIRS="$dri_drivers"
1139     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1140         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1141     fi
1142     ;;
1143 esac
1144
1145 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1146 if test "x$enable_dri" = xyes; then
1147     # Platform specific settings and drivers to build
1148     case "$host_os" in
1149     linux*)
1150         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1151         DEFINES="$DEFINES -DHAVE_ALIAS"
1152
1153         case "$host_cpu" in
1154         x86_64)
1155             if test "x$DRI_DIRS" = "xyes"; then
1156                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1157             fi
1158             ;;
1159         powerpc*)
1160             # Build only the drivers for cards that exist on PowerPC.
1161             if test "x$DRI_DIRS" = "xyes"; then
1162                 DRI_DIRS="r200 radeon swrast"
1163             fi
1164             ;;
1165         sparc*)
1166             # Build only the drivers for cards that exist on sparc
1167             if test "x$DRI_DIRS" = "xyes"; then
1168                 DRI_DIRS="r200 radeon swrast"
1169             fi
1170             ;;
1171         esac
1172         ;;
1173     freebsd* | dragonfly* | *netbsd*)
1174         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1175         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1176
1177         if test "x$DRI_DIRS" = "xyes"; then
1178             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1179         fi
1180         ;;
1181     gnu*)
1182         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1183         DEFINES="$DEFINES -DHAVE_ALIAS"
1184         ;;
1185     solaris*)
1186         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1187         ;;
1188     cygwin*)
1189         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1190         if test "x$DRI_DIRS" = "xyes"; then
1191             DRI_DIRS="swrast"
1192         fi
1193         ;;
1194     esac
1195
1196     # default drivers
1197     if test "x$DRI_DIRS" = "xyes"; then
1198         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1199     fi
1200
1201     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1202
1203     # Check for expat
1204     if test "x$enable_dri" = xyes; then
1205         EXPAT_INCLUDES=""
1206         EXPAT_LIB=-lexpat
1207         AC_ARG_WITH([expat],
1208             [AS_HELP_STRING([--with-expat=DIR],
1209                 [expat install directory])],[
1210             EXPAT_INCLUDES="-I$withval/include"
1211             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1212             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1213             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1214             ])
1215         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1216         save_LIBS="$LIBS"
1217         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1218             [AC_MSG_ERROR([Expat required for DRI.])])
1219         LIBS="$save_LIBS"
1220     fi
1221
1222     # if we are building any dri driver other than swrast ...
1223     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1224         # ... libdrm is required
1225         if test "x$have_libdrm" != xyes; then
1226             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1227         fi
1228         # ... and build dricommon
1229         HAVE_COMMON_DRI=yes
1230     fi
1231
1232     # put all the necessary libs together
1233     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1234     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1235 fi
1236 AC_SUBST([DRI_DIRS])
1237 AC_SUBST([EXPAT_INCLUDES])
1238 AC_SUBST([DRI_LIB_DEPS])
1239 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1240
1241 case $DRI_DIRS in
1242 *i915*|*i965*)
1243     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1244
1245     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1246         case $d in
1247         i915)
1248             HAVE_I915_DRI=yes;
1249             ;;
1250         i965)
1251             HAVE_I965_DRI=yes;
1252             ;;
1253         esac
1254     done
1255
1256     ;;
1257 esac
1258
1259 case $DRI_DIRS in
1260 *nouveau*)
1261     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1262     HAVE_NOUVEAU_DRI=yes;
1263     ;;
1264 esac
1265
1266 case $DRI_DIRS in
1267 *radeon*|*r200*)
1268     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1269
1270     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1271         case $d in
1272         radeon)
1273             HAVE_RADEON_DRI=yes;
1274             ;;
1275         r200)
1276             HAVE_R200_DRI=yes;
1277             ;;
1278         esac
1279     done
1280
1281     ;;
1282 esac
1283
1284 case $DRI_DIRS in
1285 *swrast*)
1286     HAVE_SWRAST_DRI=yes;
1287     ;;
1288 esac
1289
1290 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1291 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1292 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1293 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1294 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1295 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1296 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1297
1298 dnl
1299 dnl OSMesa configuration
1300 dnl
1301
1302 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1303 AC_ARG_WITH([osmesa-bits],
1304     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1305         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1306     [osmesa_bits="$withval"],
1307     [osmesa_bits=8])
1308 if test "x$osmesa_bits" != x8; then
1309     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1310         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1311         osmesa_bits=8
1312     fi
1313 fi
1314 case "x$osmesa_bits" in
1315 x8)
1316     OSMESA_LIB="${OSMESA_LIB}"
1317     ;;
1318 x16|x32)
1319     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1320     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1321     ;;
1322 *)
1323     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1324     ;;
1325 esac
1326
1327 if test "x$enable_osmesa" = xyes; then
1328     # only link libraries with osmesa if shared
1329     if test "$enable_static" = no; then
1330         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1331     else
1332         OSMESA_LIB_DEPS=""
1333     fi
1334     OSMESA_MESA_DEPS=""
1335     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1336 fi
1337
1338 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1339
1340 AC_SUBST([OSMESA_LIB_DEPS])
1341 AC_SUBST([OSMESA_MESA_DEPS])
1342 AC_SUBST([OSMESA_PC_REQ])
1343 AC_SUBST([OSMESA_PC_LIB_PRIV])
1344 AC_SUBST([OSMESA_VERSION])
1345
1346 dnl
1347 dnl gbm configuration
1348 dnl
1349 if test "x$enable_gbm" = xauto; then
1350     case "$with_egl_platforms" in
1351         *drm*)
1352             enable_gbm=yes ;;
1353          *)
1354             enable_gbm=no ;;
1355     esac
1356 fi
1357 if test "x$enable_gbm" = xyes; then
1358     SRC_DIRS="$SRC_DIRS gbm"
1359
1360     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1361                       AC_MSG_ERROR([gbm needs udev]))
1362
1363     if test "x$enable_dri" = xyes; then
1364         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1365         if test "$SHARED_GLAPI" -eq 0; then
1366             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1367         fi
1368     fi
1369 fi
1370 GBM_PC_REQ_PRIV="libudev"
1371 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1372 AC_SUBST([GBM_PC_REQ_PRIV])
1373 AC_SUBST([GBM_PC_LIB_PRIV])
1374
1375 dnl
1376 dnl EGL configuration
1377 dnl
1378 EGL_CLIENT_APIS=""
1379
1380 if test "x$enable_egl" = xyes; then
1381     SRC_DIRS="$SRC_DIRS egl"
1382     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1383
1384     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1385
1386     if test "$enable_static" != yes; then
1387         # build egl_glx when libGL is built
1388         if test "x$enable_glx" = xyes; then
1389             HAVE_EGL_DRIVER_GLX=1
1390         fi
1391
1392         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1393                           [have_libudev=yes],[have_libudev=no])
1394         if test "$have_libudev" = yes; then
1395             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1396         fi
1397
1398         if test "x$enable_dri" = xyes; then
1399             HAVE_EGL_DRIVER_DRI2=1
1400         fi
1401
1402     fi
1403 fi
1404 AC_SUBST([EGL_LIB_DEPS])
1405
1406 dnl
1407 dnl EGL Gallium configuration
1408 dnl
1409 if test "x$enable_gallium_egl" = xyes; then
1410     if test "x$with_gallium_drivers" = x; then
1411         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1412     fi
1413     if test "x$enable_egl" = xno; then
1414         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1415     fi
1416     if test "x$have_libdrm" != xyes; then
1417         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1418     fi
1419
1420     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1421     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1422     HAVE_ST_EGL="yes"
1423 fi
1424
1425 dnl
1426 dnl gbm Gallium configuration
1427 dnl
1428 if test "x$enable_gallium_gbm" = xauto; then
1429     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1430         yesyesyes*drm*)
1431             enable_gallium_gbm=yes ;;
1432          *)
1433             enable_gallium_gbm=no ;;
1434     esac
1435 fi
1436 if test "x$enable_gallium_gbm" = xyes; then
1437     if test "x$with_gallium_drivers" = x; then
1438         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1439     fi
1440     if test "x$enable_gbm" = xno; then
1441         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1442     fi
1443     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1444     if test "x$enable_dri" = xno; then
1445         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1446     fi
1447
1448     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1449     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1450     HAVE_ST_GBM="yes"
1451     enable_gallium_loader=yes
1452 fi
1453
1454 dnl
1455 dnl X.Org DDX configuration
1456 dnl
1457 if test "x$enable_xorg" = xyes; then
1458     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1459     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1460     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1461     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1462         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1463         HAVE_XEXTPROTO_71="no")
1464     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1465     HAVE_ST_XORG=yes
1466 fi
1467
1468 dnl
1469 dnl XA configuration
1470 dnl
1471 if test "x$enable_xa" = xyes; then
1472 AC_PROG_AWK
1473 AC_PROG_GREP
1474 AC_CHECK_PROG(NM, nm, "nm")
1475 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1476 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1477 enable_xa=no
1478 fi
1479 fi
1480 if test "x$enable_xa" = xyes; then
1481     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1482     HAVE_ST_XA=yes
1483     AC_SUBST(AWK)
1484     AC_SUBST(GREP)
1485     AC_SUBST(NM)
1486 fi
1487
1488 dnl
1489 dnl OpenVG configuration
1490 dnl
1491 VG_LIB_DEPS=""
1492
1493 if test "x$enable_openvg" = xyes; then
1494     if test "x$enable_egl" = xno; then
1495         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1496     fi
1497     if test "x$with_gallium_drivers" = x; then
1498         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1499     fi
1500     if test "x$enable_gallium_egl" = xno; then
1501         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1502     fi
1503
1504     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1505     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1506     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1507     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1508     HAVE_ST_VEGA=yes
1509 fi
1510
1511 dnl
1512 dnl D3D1X configuration
1513 dnl
1514
1515 if test "x$enable_d3d1x" = xyes; then
1516     if test "x$with_gallium_drivers" = x; then
1517         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1518     fi
1519
1520     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1521     HAVE_ST_D3D1X=yes
1522 fi
1523
1524 dnl
1525 dnl Gallium G3DVL configuration
1526 dnl
1527 AC_ARG_ENABLE([gallium-g3dvl],
1528     [AS_HELP_STRING([--enable-gallium-g3dvl],
1529         [build gallium g3dvl @<:@default=disabled@:>@])],
1530     [enable_gallium_g3dvl="$enableval"],
1531     [enable_gallium_g3dvl=no])
1532 if test "x$enable_gallium_g3dvl" = xyes; then
1533     if test "x$with_gallium_drivers" = x; then
1534         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1535     fi
1536
1537     if test "x$enable_xvmc" = xauto; then
1538         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1539     fi
1540
1541     if test "x$enable_vdpau" = xauto; then
1542         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1543     fi
1544
1545     if test "x$enable_va" = xauto; then
1546         #don't enable vaapi state tracker even if package exists
1547         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1548         enable_va=no
1549     fi
1550 fi
1551
1552 if test "x$enable_xvmc" = xyes; then
1553     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1554     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1555     HAVE_ST_XVMC="yes"
1556 fi
1557
1558 if test "x$enable_vdpau" = xyes; then
1559     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1560     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1561     HAVE_ST_VDPAU="yes"
1562 fi
1563
1564 if test "x$enable_va" = xyes; then
1565     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1566     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1567     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1568     HAVE_ST_VA="yes"
1569 fi
1570
1571 dnl
1572 dnl OpenCL configuration
1573 dnl
1574
1575 AC_ARG_WITH([libclc-path],
1576    [AS_HELP_STRING([--with-libclc-path],
1577          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1578    [LIBCLC_PATH="$withval"],
1579    [LIBCLC_PATH=""])
1580
1581 AC_ARG_WITH([clang-libdir],
1582    [AS_HELP_STRING([--with-clang-libdir],
1583          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1584    [CLANG_LIBDIR="$withval"],
1585    [CLANG_LIBDIR=""])
1586
1587 AC_SUBST([LIBCLC_PATH])
1588
1589 if test "x$enable_opencl" = xyes; then
1590     if test "x$with_gallium_drivers" = x; then
1591         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1592     fi
1593
1594     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1595         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1596     fi
1597
1598     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1599     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1600     enable_gallium_loader=yes
1601 fi
1602
1603 dnl
1604 dnl GLU configuration
1605 dnl
1606 AC_ARG_ENABLE([glu],
1607     [AS_HELP_STRING([--disable-glu],
1608         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1609     [enable_glu="$enableval"],
1610     [enable_glu=yes])
1611
1612 if test "x$enable_glu" = xyes; then
1613     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1614         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1615         enable_glu=no
1616     fi
1617 fi
1618
1619 if test "x$enable_glu" = xyes; then
1620     SRC_DIRS="$SRC_DIRS glu"
1621
1622     if test "x$enable_glx" = xno; then
1623         # Link libGLU to libOSMesa instead of libGL
1624         GLU_LIB_DEPS=""
1625         GLU_PC_REQ="osmesa"
1626         if test "$enable_static" = no; then
1627             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1628         else
1629             GLU_MESA_DEPS=""
1630         fi
1631     else
1632         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1633         GLU_PC_REQ="gl"
1634         GLU_PC_LIB_PRIV="-lm"
1635         if test "$enable_static" = no; then
1636             GLU_LIB_DEPS="-lm"
1637             GLU_MESA_DEPS='-l$(GL_LIB)'
1638         else
1639             GLU_LIB_DEPS=""
1640             GLU_MESA_DEPS=""
1641         fi
1642     fi
1643 fi
1644 if test "$enable_static" = no; then
1645     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1646 fi
1647 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1648 AC_SUBST([GLU_LIB_DEPS])
1649 AC_SUBST([GLU_MESA_DEPS])
1650 AC_SUBST([GLU_PC_REQ])
1651 AC_SUBST([GLU_PC_REQ_PRIV])
1652 AC_SUBST([GLU_PC_LIB_PRIV])
1653 AC_SUBST([GLU_PC_CFLAGS])
1654
1655 AC_SUBST([PROGRAM_DIRS])
1656
1657 dnl
1658 dnl Gallium configuration
1659 dnl
1660 if test "x$with_gallium_drivers" != x; then
1661     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1662 fi
1663
1664 AC_SUBST([LLVM_BINDIR])
1665 AC_SUBST([LLVM_CFLAGS])
1666 AC_SUBST([LLVM_CPPFLAGS])
1667 AC_SUBST([LLVM_CXXFLAGS])
1668 AC_SUBST([LLVM_LIBDIR])
1669 AC_SUBST([LLVM_LIBS])
1670 AC_SUBST([LLVM_LDFLAGS])
1671 AC_SUBST([LLVM_INCLUDEDIR])
1672 AC_SUBST([LLVM_VERSION])
1673 AC_SUBST([CLANG_RESOURCE_DIR])
1674
1675 case "x$enable_opengl$enable_gles1$enable_gles2" in
1676 x*yes*)
1677     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1678     ;;
1679 esac
1680
1681 AC_SUBST([VG_LIB_DEPS])
1682 AC_SUBST([EGL_CLIENT_APIS])
1683
1684 dnl
1685 dnl EGL Platforms configuration
1686 dnl
1687 AC_ARG_WITH([egl-platforms],
1688     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1689         [comma delimited native platforms libEGL supports, e.g.
1690         "x11,drm" @<:@default=auto@:>@])],
1691     [with_egl_platforms="$withval"],
1692     [if test "x$enable_egl" = xyes; then
1693         with_egl_platforms="x11"
1694     else
1695         with_egl_platforms=""
1696     fi])
1697
1698 EGL_PLATFORMS=""
1699
1700 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1701     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1702 fi
1703
1704 # Do per-EGL platform setups and checks
1705 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1706 for plat in $egl_platforms; do
1707         case "$plat" in
1708         fbdev|null)
1709                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1710                 ;;
1711
1712         wayland)
1713                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1714                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1715                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1716
1717                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1718                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1719                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1720                 ;;
1721
1722         x11)
1723                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1724                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1725                 save_LIBS="$LIBS"
1726                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1727                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1728                 LIBS="$save_LIBS"
1729                 ;;
1730
1731         drm)
1732                 test "x$enable_gbm" = "xno" &&
1733                         AC_MSG_ERROR([EGL platform drm needs gbm])
1734                 ;;
1735
1736         android|gdi)
1737                 ;;
1738
1739         *)
1740                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1741                 ;;
1742         esac
1743
1744         case "$plat$have_libudev" in
1745                 waylandno|drmno)
1746                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1747         esac
1748 done
1749
1750 # libEGL wants to default to the first platform specified in
1751 # ./configure.  parse that here.
1752 if test "x$egl_platforms" != "x"; then
1753     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1754     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1755 else
1756     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1757 fi
1758
1759 EGL_PLATFORMS="$egl_platforms"
1760
1761 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1762 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1763 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1764 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1765 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1766
1767 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1768 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1769
1770 AC_SUBST([EGL_NATIVE_PLATFORM])
1771 AC_SUBST([EGL_PLATFORMS])
1772 AC_SUBST([EGL_CFLAGS])
1773
1774 AC_ARG_WITH([egl-driver-dir],
1775     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1776                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1777     [EGL_DRIVER_INSTALL_DIR="$withval"],
1778     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1779 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1780
1781 AC_ARG_WITH([xorg-driver-dir],
1782     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1783                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1784     [XORG_DRIVER_INSTALL_DIR="$withval"],
1785     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1786 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1787
1788 AC_ARG_WITH([max-width],
1789     [AS_HELP_STRING([--with-max-width=N],
1790                     [Maximum framebuffer width (4096)])],
1791     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1792      AS_IF([test "${withval}" -gt "4096"],
1793            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1794 )
1795 AC_ARG_WITH([max-height],
1796     [AS_HELP_STRING([--with-max-height=N],
1797                     [Maximum framebuffer height (4096)])],
1798     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1799      AS_IF([test "${withval}" -gt "4096"],
1800            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1801 )
1802
1803 dnl
1804 dnl Gallium LLVM
1805 dnl
1806 AC_ARG_ENABLE([gallium-llvm],
1807     [AS_HELP_STRING([--enable-gallium-llvm],
1808         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1809     [enable_gallium_llvm="$enableval"],
1810     [enable_gallium_llvm=auto])
1811
1812 AC_ARG_WITH([llvm-shared-libs],
1813     [AS_HELP_STRING([--with-llvm-shared-libs],
1814         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1815     [with_llvm_shared_libs=yes],
1816     [with_llvm_shared_libs=no])
1817
1818 AC_ARG_WITH([llvm-prefix],
1819     [AS_HELP_STRING([--with-llvm-prefix],
1820         [Prefix for LLVM installations in non-standard locations])],
1821     [llvm_prefix="$withval"],
1822     [llvm_prefix=""])
1823
1824
1825 if test "x$with_gallium_drivers" = x; then
1826     enable_gallium_llvm=no
1827 fi
1828 if test "x$enable_gallium_llvm" = xauto; then
1829     case "$host_cpu" in
1830     i*86|x86_64) enable_gallium_llvm=yes;;
1831     esac
1832 fi
1833 if test "x$enable_gallium_llvm" = xyes; then
1834     if test "x$llvm_prefix" != x; then
1835         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1836     else
1837         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1838     fi
1839
1840     if test "x$LLVM_CONFIG" != xno; then
1841         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1842         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1843         if test "x$with_llvm_shared_libs" = xyes; then
1844             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1845             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1846         else
1847             LLVM_COMPONENTS="engine bitwriter"
1848             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1849                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1850             fi
1851             if test "x$enable_opencl" = xyes; then
1852                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1853             fi
1854             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1855         fi
1856         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1857         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1858         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1859         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1860         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1861         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1862         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1863         MESA_LLVM=1
1864
1865         dnl Check for Clang interanl headers
1866         if test "x$enable_opencl" = xyes; then
1867             if test "x$CLANG_LIBDIR" = x; then
1868                 CLANG_LIBDIR=${LLVM_LIBDIR}
1869             fi
1870             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1871             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1872                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1873         fi
1874     else
1875         MESA_LLVM=0
1876     fi
1877 else
1878     MESA_LLVM=0
1879 fi
1880
1881 dnl Directory for XVMC libs
1882 AC_ARG_WITH([xvmc-libdir],
1883     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1884         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1885     [XVMC_LIB_INSTALL_DIR="$withval"],
1886     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1887 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1888
1889 dnl
1890 dnl Gallium Tests
1891 dnl
1892 if test "x$enable_gallium_tests" = xyes; then
1893     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1894     enable_gallium_loader=yes
1895 fi
1896
1897 dnl Directory for VDPAU libs
1898 AC_ARG_WITH([vdpau-libdir],
1899     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1900         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1901     [VDPAU_LIB_INSTALL_DIR="$withval"],
1902     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1903 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1904
1905 dnl Directory for VA libs
1906 AC_ARG_WITH([va-libdir],
1907     [AS_HELP_STRING([--with-va-libdir=DIR],
1908         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1909     [VA_LIB_INSTALL_DIR="$withval"],
1910     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1911 AC_SUBST([VA_LIB_INSTALL_DIR])
1912
1913 dnl Directory for OpenCL libs
1914 AC_ARG_WITH([opencl-libdir],
1915     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1916         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1917     [OPENCL_LIB_INSTALL_DIR="$withval"],
1918     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1919 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1920
1921 dnl
1922 dnl Gallium helper functions
1923 dnl
1924 gallium_check_st() {
1925     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1926          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1927          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1928          if test "x$have_libdrm" != xyes; then
1929             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1930          fi
1931          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1932     fi
1933     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1934          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1935     fi
1936     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1937          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1938     fi
1939     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1940          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1941     fi
1942     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1943          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1944     fi
1945     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1946          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1947     fi
1948     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1949          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1950     fi
1951 }
1952
1953 gallium_require_llvm() {
1954     if test "x$MESA_LLVM" = x0; then
1955         case "$host_cpu" in
1956         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1957         esac
1958     fi
1959 }
1960
1961 gallium_require_drm_loader() {
1962     if test "x$enable_gallium_loader" = xyes; then
1963         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1964                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1965         if test "x$have_libdrm" != xyes; then
1966             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1967         fi
1968         enable_gallium_drm_loader=yes
1969     fi
1970 }
1971
1972 dnl Gallium drivers
1973 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1974 if test "x$with_gallium_drivers" != x; then
1975     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1976     for driver in $gallium_drivers; do
1977         case "x$driver" in
1978         xsvga)
1979             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1980             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1981             ;;
1982         xi915)
1983             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1984             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1985             if test "x$MESA_LLVM" = x1; then
1986                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1987             fi
1988             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1989             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1990             ;;
1991         xr300)
1992             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1993             gallium_require_llvm "Gallium R300"
1994             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1995             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1996             ;;
1997         xr600)
1998             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1999             gallium_require_drm_loader
2000             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
2001             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2002                 if test "x$LLVM_VERSION" != "x3.1"; then
2003                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
2004                 fi
2005                 NEED_RADEON_GALLIUM=yes;
2006             fi
2007             if test "x$enable_r600_llvm" = xyes; then
2008                 USE_R600_LLVM_COMPILER=yes;
2009             fi
2010             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
2011                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
2012             fi
2013             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
2014             ;;
2015         xradeonsi)
2016             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2017             gallium_require_drm_loader
2018             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
2019             if test "x$LLVM_VERSION" != "x3.1"; then
2020                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
2021             fi
2022             NEED_RADEON_GALLIUM=yes;
2023             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
2024             ;;
2025         xnouveau)
2026             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2027             gallium_require_drm_loader
2028             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
2029             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
2030             ;;
2031         xswrast)
2032             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2033             if test "x$MESA_LLVM" = x1; then
2034                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2035             fi
2036
2037             if test "x$HAVE_ST_DRI" = xyes; then
2038                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2039             fi
2040             if test "x$HAVE_ST_VDPAU" = xyes; then
2041                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2042             fi
2043             if test "x$HAVE_ST_XVMC" = xyes; then
2044                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2045             fi
2046             if test "x$HAVE_ST_VA" = xyes; then
2047                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2048             fi
2049             if test "x$HAVE_ST_VDPAU" = xyes ||
2050                test "x$HAVE_ST_XVMC" = xyes ||
2051                test "x$HAVE_ST_VA" = xyes; then
2052                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2053                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2054                fi
2055             fi
2056             ;;
2057         *)
2058             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2059             ;;
2060         esac
2061     done
2062 fi
2063
2064 if test "x$enable_gallium_loader" = xyes; then
2065     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2066     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2067     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2068     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2069
2070     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2071         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2072         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2073     fi
2074
2075     if test "x$enable_gallium_drm_loader" = xyes; then
2076         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2077         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2078                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2079         if test "x$pipe_loader_have_xcb" = xyes; then
2080             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
2081             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2082         fi
2083     fi
2084
2085     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2086     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2087 fi
2088
2089 dnl Tell Automake which drivers to build
2090 for driver in $GALLIUM_DRIVERS_DIRS; do
2091     case "x$driver" in
2092         xgalahad)
2093             HAVE_GALAHAD_GALLIUM=yes;
2094             ;;
2095         xidentity)
2096             HAVE_IDENTITY_GALLIUM=yes;
2097             ;;
2098         xnoop)
2099             HAVE_NOOP_GALLIUM=yes;
2100             ;;
2101         *)
2102             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2103             ;;
2104     esac
2105 done
2106
2107 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2108 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2109 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2110 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2111 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2112 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2113 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2114 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2115 AC_SUBST([GALLIUM_MAKE_DIRS])
2116
2117 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2118 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2119
2120 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2121 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2122 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2123
2124 dnl prepend CORE_DIRS to SRC_DIRS
2125 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2126
2127 dnl Restore LDFLAGS and CPPFLAGS
2128 LDFLAGS="$_SAVE_LDFLAGS"
2129 CPPFLAGS="$_SAVE_CPPFLAGS"
2130
2131 dnl Add user CFLAGS and CXXFLAGS
2132 CFLAGS="$CFLAGS $USER_CFLAGS"
2133 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2134
2135 dnl Substitute the config
2136 AC_CONFIG_FILES([configs/current
2137                 Makefile
2138                 src/Makefile
2139                 src/gallium/Makefile
2140                 src/gallium/auxiliary/pipe-loader/Makefile
2141                 src/gallium/state_trackers/clover/Makefile
2142                 src/gallium/drivers/Makefile
2143                 src/gallium/drivers/r300/Makefile
2144                 src/gallium/drivers/r600/Makefile
2145                 src/gallium/targets/opencl/Makefile
2146                 src/gbm/Makefile
2147                 src/gbm/main/gbm.pc
2148                 src/egl/drivers/Makefile
2149                 src/egl/drivers/dri2/Makefile
2150                 src/egl/drivers/glx/Makefile
2151                 src/egl/Makefile
2152                 src/egl/main/Makefile
2153                 src/egl/main/egl.pc
2154                 src/egl/wayland/Makefile
2155                 src/egl/wayland/wayland-egl/Makefile
2156                 src/egl/wayland/wayland-egl/wayland-egl.pc
2157                 src/egl/wayland/wayland-drm/Makefile
2158                 src/glsl/Makefile
2159                 src/glsl/glcpp/Makefile
2160                 src/glsl/tests/Makefile
2161                 src/glx/Makefile
2162                 src/glx/tests/Makefile
2163                 src/mapi/glapi/Makefile
2164                 src/mapi/glapi/gen/Makefile
2165                 src/mapi/shared-glapi/Makefile
2166                 src/mapi/glapi/tests/Makefile
2167                 src/gtest/Makefile
2168                 src/mesa/Makefile
2169                 src/mesa/libdricore/Makefile
2170                 src/mesa/main/tests/Makefile
2171                 src/mesa/x86/Makefile
2172                 src/mesa/x86-64/Makefile
2173                 src/mesa/drivers/Makefile
2174                 src/mesa/drivers/dri/dri.pc
2175                 src/mesa/drivers/dri/Makefile
2176                 src/mesa/drivers/dri/common/Makefile
2177                 src/mesa/drivers/dri/i915/Makefile
2178                 src/mesa/drivers/dri/i965/Makefile
2179                 src/mesa/drivers/dri/nouveau/Makefile
2180                 src/mesa/drivers/dri/r200/Makefile
2181                 src/mesa/drivers/dri/radeon/Makefile
2182                 src/mesa/drivers/dri/swrast/Makefile
2183                 src/mesa/drivers/osmesa/Makefile
2184                 src/mesa/drivers/x11/Makefile
2185                 src/mesa/gl.pc
2186                 src/mesa/drivers/osmesa/osmesa.pc])
2187
2188 dnl Sort the dirs alphabetically
2189 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2190 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2191 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2192 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2193 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2194
2195 AC_OUTPUT
2196
2197 dnl
2198 dnl Output some configuration info for the user
2199 dnl
2200 echo ""
2201 echo "        prefix:          $prefix"
2202 echo "        exec_prefix:     $exec_prefix"
2203 echo "        libdir:          $libdir"
2204 echo "        includedir:      $includedir"
2205
2206 dnl API info
2207 echo ""
2208 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2209 echo "        OpenVG:          $enable_openvg"
2210
2211 dnl Driver info
2212 echo ""
2213 if test "x$enable_osmesa" != xno; then
2214         echo "        OSMesa:          lib$OSMESA_LIB"
2215 else
2216         echo "        OSMesa:          no"
2217 fi
2218
2219 if test "x$enable_dri" != xno; then
2220         # cleanup the drivers var
2221         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2222         if test "x$DRI_DIRS" = x; then
2223             echo "        DRI drivers:     no"
2224         else
2225             echo "        DRI drivers:     $dri_dirs"
2226         fi
2227         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2228 fi
2229
2230 case "x$enable_glx$enable_xlib_glx" in
2231 xyesyes)
2232     echo "        GLX:             Xlib-based"
2233     ;;
2234 xyesno)
2235     echo "        GLX:             DRI-based"
2236     ;;
2237 *)
2238     echo "        GLX:             $enable_glx"
2239     ;;
2240 esac
2241
2242 echo ""
2243 echo "        GLU:             $enable_glu"
2244
2245 dnl EGL
2246 echo ""
2247 echo "        EGL:             $enable_egl"
2248 if test "$enable_egl" = yes; then
2249     echo "        EGL platforms:   $EGL_PLATFORMS"
2250
2251     egl_drivers=""
2252     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2253         egl_drivers="$egl_drivers builtin:egl_glx"
2254     fi
2255     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2256         egl_drivers="$egl_drivers builtin:egl_dri2"
2257     fi
2258
2259     if test "x$HAVE_ST_EGL" = xyes; then
2260         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2261         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2262     else
2263         echo "        EGL drivers:    $egl_drivers"
2264     fi
2265 fi
2266
2267 echo ""
2268 if test "x$MESA_LLVM" = x1; then
2269     echo "        llvm:            yes"
2270     echo "        llvm-config:     $LLVM_CONFIG"
2271     echo "        llvm-version:    $LLVM_VERSION"
2272 else
2273     echo "        llvm:            no"
2274 fi
2275
2276 echo ""
2277 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2278     echo "        Gallium:         yes"
2279     echo "        Gallium dirs:    $GALLIUM_DIRS"
2280     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2281     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2282     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2283     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2284 else
2285     echo "        Gallium:         no"
2286 fi
2287
2288
2289 dnl Libraries
2290 echo ""
2291 echo "        Shared libs:     $enable_shared"
2292 echo "        Static libs:     $enable_static"
2293
2294 dnl Compiler options
2295 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2296 cflags=`echo $CFLAGS $PIC_FLAGS | \
2297     $SED 's/^ *//;s/  */ /;s/ *$//'`
2298 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2299     $SED 's/^ *//;s/  */ /;s/ *$//'`
2300 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2301 echo ""
2302 echo "        CFLAGS:          $cflags"
2303 echo "        CXXFLAGS:        $cxxflags"
2304 echo "        Macros:          $defines"
2305 echo ""
2306 echo "        PYTHON2:         $PYTHON2"
2307
2308 echo ""
2309 echo "        Run '${MAKE-make}' to build Mesa"
2310 echo ""