configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.55
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -D_XOPEN_SOURCE=700 -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     CFLAGS="$CFLAGS -Wall -std=c99"
 169
 170     # Enable -Werror=implicit-function-declaration and
 171     # -Werror=missing-prototypes, if available, or otherwise, just
 172     # -Wmissing-prototypes.  This is particularly useful to avoid
 173     # generating a loadable driver module that has undefined symbols.
 174     save_CFLAGS="$CFLAGS"
 175     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 176     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 177     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 178     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 179                    AC_MSG_RESULT([yes]),
 180                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 181                     AC_MSG_RESULT([no])]);
 182
 183     # Enable -fvisibility=hidden if using a gcc that supports it
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 186     VISIBILITY_CFLAGS="-fvisibility=hidden"
 187     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 189                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 190
 191     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 192     CFLAGS=$save_CFLAGS
 193
 194     # Work around aliasing bugs - developers should comment this out
 195     CFLAGS="$CFLAGS -fno-strict-aliasing"
 196
 197     # gcc's builtin memcmp is slower than glibc's
 198     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 199     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 200 fi
 201 if test "x$GXX" = xyes; then
 202     CXXFLAGS="$CXXFLAGS -Wall"
 203
 204     # Enable -fvisibility=hidden if using a gcc that supports it
 205     save_CXXFLAGS="$CXXFLAGS"
 206     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 207     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 208     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 209     AC_LANG_PUSH([C++])
 210     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 211                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 212     AC_LANG_POP([C++])
 213
 214     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 215     CXXFLAGS=$save_CXXFLAGS
 216
 217     # Work around aliasing bugs - developers should comment this out
 218     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 219
 220     # gcc's builtin memcmp is slower than glibc's
 221     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 222     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 223 fi
 224
 225 dnl even if the compiler appears to support it, using visibility attributes isn't
 226 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 227 case "$host_os" in
 228 cygwin*)
 229     VISIBILITY_CFLAGS=""
 230     VISIBILITY_CXXFLAGS=""
 231     ;;
 232 esac
 233
 234 AC_SUBST([VISIBILITY_CFLAGS])
 235 AC_SUBST([VISIBILITY_CXXFLAGS])
 236
 237 dnl
 238 dnl Optional flags, check for compiler support
 239 dnl
 240 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 241 if test "x$SSE41_SUPPORTED" = x1; then
 242     DEFINES="$DEFINES -DUSE_SSE41"
 243 fi
 244 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 245
 246 dnl Can't have static and shared libraries, default to static if user
 247 dnl explicitly requested. If both disabled, set to static since shared
 248 dnl was explicitly requested.
 249 case "x$enable_static$enable_shared" in
 250 xyesyes)
 251     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 252     enable_shared=no
 253     ;;
 254 xnono)
 255     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 256     enable_shared=yes
 257     ;;
 258 esac
 259
 260 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 261
 262 dnl
 263 dnl other compiler options
 264 dnl
 265 AC_ARG_ENABLE([debug],
 266     [AS_HELP_STRING([--enable-debug],
 267         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 268     [enable_debug="$enableval"],
 269     [enable_debug=no]
 270 )
 271 if test "x$enable_debug" = xyes; then
 272     DEFINES="$DEFINES -DDEBUG"
 273     if test "x$GCC" = xyes; then
 274         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 275             CFLAGS="$CFLAGS -g"
 276         fi
 277         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 278             CFLAGS="$CFLAGS -O0"
 279         fi
 280     fi
 281     if test "x$GXX" = xyes; then
 282         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 283             CXXFLAGS="$CXXFLAGS -g"
 284         fi
 285         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 286             CXXFLAGS="$CXXFLAGS -O0"
 287         fi
 288     fi
 289 fi
 290
 291 dnl
 292 dnl Check if linker supports -Bsymbolic
 293 dnl
 294 save_LDFLAGS=$LDFLAGS
 295 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 296 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 297 AC_LINK_IFELSE(
 298     [AC_LANG_SOURCE([int main() { return 0;}])],
 299     [AC_MSG_RESULT([yes])
 300         BSYMBOLIC="-Wl,-Bsymbolic";],
 301     [AC_MSG_RESULT([no])
 302         BSYMBOLIC="";])
 303 LDFLAGS=$save_LDFLAGS
 304
 305 AC_SUBST([BSYMBOLIC])
 306
 307 dnl
 308 dnl Check if linker supports garbage collection
 309 dnl
 310 save_LDFLAGS=$LDFLAGS
 311 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 312 AC_MSG_CHECKING([whether ld supports --gc-sections])
 313 AC_LINK_IFELSE(
 314     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 315     [AC_MSG_RESULT([yes])
 316         GC_SECTIONS="-Wl,--gc-sections";],
 317     [AC_MSG_RESULT([no])
 318         GC_SECTIONS="";])
 319 LDFLAGS=$save_LDFLAGS
 320
 321 AC_SUBST([GC_SECTIONS])
 322
 323 dnl
 324 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 325 dnl so when these flags are passed to ld via libtool the checks will fail
 326 dnl
 327 case "$host_os" in
 328 openbsd* | darwin* )
 329     LD_NO_UNDEFINED="" ;;
 330 *)
 331     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 332 esac
 333
 334 AC_SUBST([LD_NO_UNDEFINED])
 335
 336 dnl
 337 dnl Check if linker supports version scripts
 338 dnl
 339 AC_MSG_CHECKING([if the linker supports version-scripts])
 340 save_LDFLAGS=$LDFLAGS
 341 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 342 cat > conftest.map <<EOF
 343 VERSION_1 {
 344      global:
 345          main;
 346
 347      local:
 348          *;
 349 };
 350 EOF
 351 AC_LINK_IFELSE(
 352     [AC_LANG_SOURCE([int main() { return 0;}])],
 353     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 354     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 355 LDFLAGS=$save_LDFLAGS
 356 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 357
 358 dnl
 359 dnl compatibility symlinks
 360 dnl
 361 case "$host_os" in
 362 linux* )
 363     HAVE_COMPAT_SYMLINKS=yes ;;
 364 * )
 365     HAVE_COMPAT_SYMLINKS=no ;;
 366 esac
 367
 368 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 369
 370 dnl
 371 dnl library names
 372 dnl
 373 case "$host_os" in
 374 darwin* )
 375     LIB_EXT='dylib' ;;
 376 cygwin* )
 377     LIB_EXT='dll' ;;
 378 aix* )
 379     LIB_EXT='a' ;;
 380 * )
 381     LIB_EXT='so' ;;
 382 esac
 383
 384 AC_SUBST([LIB_EXT])
 385
 386 AC_ARG_WITH([gl-lib-name],
 387   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 388     [specify GL library name @<:@default=GL@:>@])],
 389   [GL_LIB=$withval],
 390   [GL_LIB=GL])
 391 AC_ARG_WITH([osmesa-lib-name],
 392   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 393     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 394   [OSMESA_LIB=$withval],
 395   [OSMESA_LIB=OSMesa])
 396 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 397 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 398
 399 dnl
 400 dnl Mangled Mesa support
 401 dnl
 402 AC_ARG_ENABLE([mangling],
 403   [AS_HELP_STRING([--enable-mangling],
 404     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 405   [enable_mangling="${enableval}"],
 406   [enable_mangling=no]
 407 )
 408 if test "x${enable_mangling}" = "xyes" ; then
 409   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 410   GL_LIB="Mangled${GL_LIB}"
 411   OSMESA_LIB="Mangled${OSMESA_LIB}"
 412 fi
 413 AC_SUBST([GL_LIB])
 414 AC_SUBST([OSMESA_LIB])
 415
 416 dnl
 417 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 418 dnl
 419 AC_ARG_ENABLE([texture-float],
 420     [AS_HELP_STRING([--enable-texture-float],
 421         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 422     [enable_texture_float="$enableval"],
 423     [enable_texture_float=no]
 424 )
 425 if test "x$enable_texture_float" = xyes; then
 426     AC_MSG_WARN([Floating-point textures enabled.])
 427     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 428     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 429 fi
 430
 431 dnl
 432 dnl Arch/platform-specific settings
 433 dnl
 434 AC_ARG_ENABLE([asm],
 435     [AS_HELP_STRING([--disable-asm],
 436         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 437     [enable_asm="$enableval"],
 438     [enable_asm=yes]
 439 )
 440 asm_arch=""
 441 AC_MSG_CHECKING([whether to enable assembly])
 442 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 443 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 444 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 445     case "$host_cpu" in
 446     i?86 | x86_64 | amd64)
 447         enable_asm=no
 448         AC_MSG_RESULT([no, cross compiling])
 449         ;;
 450     esac
 451 fi
 452 # check for supported arches
 453 if test "x$enable_asm" = xyes; then
 454     case "$host_cpu" in
 455     i?86)
 456         case "$host_os" in
 457         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 458             asm_arch=x86
 459             ;;
 460         esac
 461         ;;
 462     x86_64|amd64)
 463         case "$host_os" in
 464         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 465             asm_arch=x86_64
 466             ;;
 467         esac
 468         ;;
 469     sparc*)
 470         case "$host_os" in
 471         linux*)
 472             asm_arch=sparc
 473             ;;
 474         esac
 475         ;;
 476     esac
 477
 478     case "$asm_arch" in
 479     x86)
 480         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 481         AC_MSG_RESULT([yes, x86])
 482         ;;
 483     x86_64|amd64)
 484         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 485         AC_MSG_RESULT([yes, x86_64])
 486         ;;
 487     sparc)
 488         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 489         AC_MSG_RESULT([yes, sparc])
 490         ;;
 491     *)
 492         AC_MSG_RESULT([no, platform not supported])
 493         ;;
 494     esac
 495 fi
 496
 497 dnl Check to see if dlopen is in default libraries (like Solaris, which
 498 dnl has it in libc), or if libdl is needed to get it.
 499 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 500     [AC_CHECK_LIB([dl], [dlopen],
 501        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 502 AC_SUBST([DLOPEN_LIBS])
 503
 504 dnl Check if that library also has dladdr
 505 save_LIBS="$LIBS"
 506 LIBS="$LIBS $DLOPEN_LIBS"
 507 AC_CHECK_FUNCS([dladdr])
 508 LIBS="$save_LIBS"
 509
 510 case "$host_os" in
 511 darwin*|mingw*)
 512     ;;
 513 *)
 514     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 515                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 516                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 517     AC_SUBST([CLOCK_LIB])
 518     ;;
 519 esac
 520
 521 dnl See if posix_memalign is available
 522 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 523
 524 dnl Check for pthreads
 525 case "$host_os" in
 526 mingw*)
 527     ;;
 528 *)
 529     AX_PTHREAD
 530     ;;
 531 esac
 532 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 533 dnl to -pthread, which causes problems if we need -lpthread to appear in
 534 dnl pkgconfig files.
 535 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 536
 537 dnl SELinux awareness.
 538 AC_ARG_ENABLE([selinux],
 539     [AS_HELP_STRING([--enable-selinux],
 540         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 541     [MESA_SELINUX="$enableval"],
 542     [MESA_SELINUX=no])
 543 if test "x$enable_selinux" = "xyes"; then
 544     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 545         [AC_CHECK_HEADER([selinux/selinux.h],[],
 546                          [AC_MSG_ERROR([SELinux headers not found])])
 547          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 548                       [AC_MSG_ERROR([SELinux library not found])])
 549          SELINUX_LIBS="-lselinux"])
 550     DEFINES="$DEFINES -DMESA_SELINUX"
 551 fi
 552 AC_SUBST([SELINUX_CFLAGS])
 553 AC_SUBST([SELINUX_LIBS])
 554
 555 dnl Options for APIs
 556 AC_ARG_ENABLE([opengl],
 557     [AS_HELP_STRING([--disable-opengl],
 558         [disable support for standard OpenGL API @<:@default=no@:>@])],
 559     [enable_opengl="$enableval"],
 560     [enable_opengl=yes])
 561 AC_ARG_ENABLE([gles1],
 562     [AS_HELP_STRING([--enable-gles1],
 563         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 564     [enable_gles1="$enableval"],
 565     [enable_gles1=no])
 566 AC_ARG_ENABLE([gles2],
 567     [AS_HELP_STRING([--enable-gles2],
 568         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 569     [enable_gles2="$enableval"],
 570     [enable_gles2=no])
 571 AC_ARG_ENABLE([openvg],
 572     [AS_HELP_STRING([--enable-openvg],
 573         [enable support for OpenVG API @<:@default=no@:>@])],
 574     [enable_openvg="$enableval"],
 575     [enable_openvg=no])
 576
 577 AC_ARG_ENABLE([dri],
 578     [AS_HELP_STRING([--enable-dri],
 579         [enable DRI modules @<:@default=enabled@:>@])],
 580     [enable_dri="$enableval"],
 581     [enable_dri=yes])
 582
 583 case "$host_os" in
 584 linux*)
 585     dri3_default=yes
 586     ;;
 587 *)
 588     dri3_default=no
 589     ;;
 590 esac
 591 AC_ARG_ENABLE([dri3],
 592     [AS_HELP_STRING([--enable-dri3],
 593         [enable DRI3 @<:@default=auto@:>@])],
 594     [enable_dri3="$enableval"],
 595     [enable_dri3="$dri3_default"])
 596 AC_ARG_ENABLE([glx],
 597     [AS_HELP_STRING([--enable-glx],
 598         [enable GLX library @<:@default=enabled@:>@])],
 599     [enable_glx="$enableval"],
 600     [enable_glx=yes])
 601 AC_ARG_ENABLE([osmesa],
 602     [AS_HELP_STRING([--enable-osmesa],
 603         [enable OSMesa library @<:@default=disabled@:>@])],
 604     [enable_osmesa="$enableval"],
 605     [enable_osmesa=no])
 606 AC_ARG_ENABLE([gallium-osmesa],
 607     [AS_HELP_STRING([--enable-gallium-osmesa],
 608         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 609     [enable_gallium_osmesa="$enableval"],
 610     [enable_gallium_osmesa=no])
 611 AC_ARG_ENABLE([egl],
 612     [AS_HELP_STRING([--disable-egl],
 613         [disable EGL library @<:@default=enabled@:>@])],
 614     [enable_egl="$enableval"],
 615     [enable_egl=yes])
 616
 617 AC_ARG_ENABLE([xa],
 618     [AS_HELP_STRING([--enable-xa],
 619         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 620     [enable_xa="$enableval"],
 621     [enable_xa=no])
 622 AC_ARG_ENABLE([gbm],
 623    [AS_HELP_STRING([--enable-gbm],
 624          [enable gbm library @<:@default=auto@:>@])],
 625    [enable_gbm="$enableval"],
 626    [enable_gbm=auto])
 627
 628 AC_ARG_ENABLE([xvmc],
 629    [AS_HELP_STRING([--enable-xvmc],
 630          [enable xvmc library @<:@default=auto@:>@])],
 631    [enable_xvmc="$enableval"],
 632    [enable_xvmc=no])
 633 AC_ARG_ENABLE([vdpau],
 634    [AS_HELP_STRING([--enable-vdpau],
 635          [enable vdpau library @<:@default=auto@:>@])],
 636    [enable_vdpau="$enableval"],
 637    [enable_vdpau=auto])
 638 AC_ARG_ENABLE([omx],
 639    [AS_HELP_STRING([--enable-omx],
 640          [enable OpenMAX library @<:@default=no@:>@])],
 641    [enable_omx="$enableval"],
 642    [enable_omx=no])
 643 AC_ARG_ENABLE([opencl],
 644    [AS_HELP_STRING([--enable-opencl],
 645          [enable OpenCL library @<:@default=no@:>@])],
 646    [enable_opencl="$enableval"],
 647    [enable_opencl=no])
 648 AC_ARG_ENABLE([opencl_icd],
 649    [AS_HELP_STRING([--enable-opencl-icd],
 650           [Build an OpenCL ICD library to be loaded by an ICD implementation
 651            @<:@default=no@:>@])],
 652     [enable_opencl_icd="$enableval"],
 653     [enable_opencl_icd=no])
 654 AC_ARG_ENABLE([xlib-glx],
 655     [AS_HELP_STRING([--enable-xlib-glx],
 656         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 657     [enable_xlib_glx="$enableval"],
 658     [enable_xlib_glx=no])
 659 AC_ARG_ENABLE([gallium-egl],
 660     [AS_HELP_STRING([--enable-gallium-egl],
 661         [enable optional EGL state tracker (not required
 662          for EGL support in Gallium with OpenGL and OpenGL ES)
 663          @<:@default=disable@:>@])],
 664     [enable_gallium_egl="$enableval"],
 665     [enable_gallium_egl=no])
 666 AC_ARG_ENABLE([gallium-gbm],
 667     [AS_HELP_STRING([--enable-gallium-gbm],
 668         [enable optional gbm state tracker (not required for
 669          gbm support in Gallium)
 670          @<:@default=auto@:>@])],
 671     [enable_gallium_gbm="$enableval"],
 672     [enable_gallium_gbm=auto])
 673
 674 AC_ARG_ENABLE([r600-llvm-compiler],
 675     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 676         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 677     [enable_r600_llvm="$enableval"],
 678     [enable_r600_llvm=no])
 679
 680 AC_ARG_ENABLE([gallium-tests],
 681     [AS_HELP_STRING([--enable-gallium-tests],
 682         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 683     [enable_gallium_tests="$enableval"],
 684     [enable_gallium_tests=no])
 685
 686 # Option for Gallium drivers
 687
 688 # Keep this in sync with the --with-gallium-drivers help string default value
 689 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 690
 691 AC_ARG_WITH([gallium-drivers],
 692     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 693         [comma delimited Gallium drivers list, e.g.
 694         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 695         @<:@default=r300,r600,svga,swrast@:>@])],
 696     [with_gallium_drivers="$withval"],
 697     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 698
 699 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 700 # here so that the script doesn't choke on an unknown driver name later.
 701 case "$with_gallium_drivers" in
 702     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 703     no) with_gallium_drivers='' ;;
 704 esac
 705
 706 if test "x$enable_opengl" = xno -a \
 707         "x$enable_gles1" = xno -a \
 708         "x$enable_gles2" = xno -a \
 709         "x$enable_openvg" = xno -a \
 710         "x$enable_xa" = xno -a \
 711         "x$enable_xvmc" = xno -a \
 712         "x$enable_vdpau" = xno -a \
 713         "x$enable_omx" = xno -a \
 714         "x$enable_opencl" = xno; then
 715     AC_MSG_ERROR([at least one API should be enabled])
 716 fi
 717
 718 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 719 if test "x$enable_opengl" = xno -a \
 720         "x$enable_gles1" = xyes; then
 721     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 722 fi
 723
 724 if test "x$enable_opengl" = xno -a \
 725         "x$enable_gles2" = xyes; then
 726     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 727 fi
 728
 729 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 730 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 731 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 732 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 733                                         "x$enable_gles1" = xyes -o \
 734                                         "x$enable_gles2" = xyes)
 735
 736 if test "x$enable_glx" = xno; then
 737     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 738     enable_xlib_glx=no
 739 fi
 740
 741 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 742     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 743 fi
 744
 745 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 746     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 747 fi
 748
 749 # Disable GLX if OpenGL is not enabled
 750 if test "x$enable_glx$enable_opengl" = xyesno; then
 751     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 752     enable_glx=no
 753 fi
 754
 755 # Disable GLX if DRI and Xlib-GLX are not enabled
 756 if test "x$enable_glx" = xyes -a \
 757         "x$enable_dri" = xno -a \
 758         "x$enable_xlib_glx" = xno; then
 759     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 760     enable_glx=no
 761 fi
 762
 763 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 764                                   "x$enable_dri" = xyes)
 765
 766 # Select which platform-dependent DRI code gets built
 767 case "$host_os" in
 768 darwin*)
 769     dri_platform='apple' ;;
 770 gnu*|mingw*|cygwin*)
 771     dri_platform='none' ;;
 772 *)
 773     dri_platform='drm' ;;
 774 esac
 775
 776 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 777 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 778 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 779 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 780 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 781
 782 AC_ARG_ENABLE([shared-glapi],
 783     [AS_HELP_STRING([--enable-shared-glapi],
 784         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 785     [enable_shared_glapi="$enableval"],
 786     [enable_shared_glapi=yes])
 787
 788 case "x$enable_opengl$enable_gles1$enable_gles2" in
 789 x*yes*yes*)
 790     if test "x$enable_shared_glapi" = xno; then
 791         AC_MSG_ERROR([shared GLAPI required when building two or more of
 792                       the following APIs - opengl, gles1 gles2])
 793     fi
 794     ;;
 795 esac
 796
 797 # Building Xlib-GLX requires shared glapi to be disabled.
 798 if test "x$enable_xlib_glx" = xyes; then
 799     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 800     enable_shared_glapi=no
 801 fi
 802
 803 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 804
 805 dnl
 806 dnl Driver specific build directories
 807 dnl
 808 GALLIUM_TARGET_DIRS=""
 809 GALLIUM_WINSYS_DIRS="sw"
 810 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 811 GALLIUM_STATE_TRACKERS_DIRS=""
 812
 813 case "x$enable_glx$enable_xlib_glx" in
 814 xyesyes)
 815     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 816     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 817     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 818     NEED_WINSYS_XLIB="yes"
 819     ;;
 820 esac
 821
 822 if test "x$enable_dri" = xyes; then
 823     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 824     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 825     enable_gallium_loader=yes
 826 fi
 827
 828 if test "x$enable_gallium_osmesa" = xyes; then
 829     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 830         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 831     fi
 832     if test "x$enable_osmesa" = xyes; then
 833         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 834     fi
 835     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 836     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 837 fi
 838
 839 AC_SUBST([MESA_LLVM])
 840
 841 # Check for libdrm
 842 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 843                   [have_libdrm=yes], [have_libdrm=no])
 844 if test "x$have_libdrm" = xyes; then
 845         DEFINES="$DEFINES -DHAVE_LIBDRM"
 846 fi
 847
 848 case "$host_os" in
 849 linux*)
 850     need_pci_id=yes ;;
 851 *)
 852     need_pci_id=no ;;
 853 esac
 854
 855 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 856                   have_libudev=yes, have_libudev=no)
 857
 858 AC_ARG_ENABLE([sysfs],
 859     [AS_HELP_STRING([--enable-sysfs],
 860         [enable /sys PCI identification @<:@default=disabled@:>@])],
 861     [have_sysfs="$enableval"],
 862     [have_sysfs=no]
 863 )
 864
 865 if test "x$enable_dri" = xyes; then
 866     if test "$enable_static" = yes; then
 867         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 868     fi
 869
 870     # not a hard requirement as swrast does not depend on it
 871     if test "x$have_libdrm" = xyes; then
 872         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 873     fi
 874 fi
 875
 876 AC_ARG_ENABLE([driglx-direct],
 877     [AS_HELP_STRING([--disable-driglx-direct],
 878         [disable direct rendering in GLX and EGL for DRI \
 879             @<:@default=auto@:>@])],
 880     [driglx_direct="$enableval"],
 881     [driglx_direct="yes"])
 882
 883 dnl
 884 dnl libGL configuration per driver
 885 dnl
 886 case "x$enable_glx$enable_xlib_glx" in
 887 xyesyes)
 888     # Xlib-based GLX
 889     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 890     GL_PC_REQ_PRIV="x11 xext"
 891     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 892     GL_LIB_DEPS="$XLIBGL_LIBS"
 893     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 894     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 895     ;;
 896 xyesno)
 897     # DRI-based GLX
 898     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 899
 900     # find the DRI deps for libGL
 901     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 902
 903     if test x"$driglx_direct" = xyes; then
 904         if test x"$dri_platform" = xdrm ; then
 905             DEFINES="$DEFINES -DGLX_USE_DRM"
 906             if test "x$have_libdrm" != xyes; then
 907                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 908             fi
 909
 910             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 911             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 912             if test x"$enable_dri3" = xyes; then
 913                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 914                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 915             fi
 916
 917             if test x"$enable_dri" = xyes; then
 918                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 919             fi
 920
 921             if test x"$enable_dri3" = xyes; then
 922                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 923             fi
 924         fi
 925         if test x"$dri_platform" = xapple ; then
 926             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 927         fi
 928     fi
 929
 930     # add xf86vidmode if available
 931     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 932     if test "$HAVE_XF86VIDMODE" = yes ; then
 933         dri_modules="$dri_modules xxf86vm"
 934     fi
 935
 936     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 937     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 938     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 939     GL_LIB_DEPS="$DRIGL_LIBS"
 940
 941     # need DRM libs, $PTHREAD_LIBS, etc.
 942     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 943     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 944     ;;
 945 esac
 946
 947 have_pci_id=no
 948 if test "$have_libudev" = yes; then
 949     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 950     have_pci_id=yes
 951 fi
 952
 953 if test "$have_sysfs" = yes; then
 954     DEFINES="$DEFINES -DHAVE_SYSFS"
 955     have_pci_id=yes
 956 fi
 957
 958 # This is outside the case (above) so that it is invoked even for non-GLX
 959 # builds.
 960 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 961
 962 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 963 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 964 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 965 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 966
 967 AC_SUBST([X11_INCLUDES])
 968 AC_SUBST([GL_LIB_DEPS])
 969 AC_SUBST([GL_PC_REQ_PRIV])
 970 AC_SUBST([GL_PC_LIB_PRIV])
 971 AC_SUBST([GL_PC_CFLAGS])
 972 AC_SUBST([DRI_PC_REQ_PRIV])
 973 AC_SUBST([GLESv1_CM_LIB_DEPS])
 974 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 975 AC_SUBST([GLESv2_LIB_DEPS])
 976 AC_SUBST([GLESv2_PC_LIB_PRIV])
 977
 978 AC_SUBST([HAVE_XF86VIDMODE])
 979
 980 dnl
 981 dnl More GLX setup
 982 dnl
 983 case "x$enable_glx$enable_xlib_glx" in
 984 xyesyes)
 985     DEFINES="$DEFINES -DUSE_XSHM"
 986     ;;
 987 xyesno)
 988     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 989     if test "x$driglx_direct" = xyes; then
 990         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 991     fi
 992     ;;
 993 esac
 994
 995 dnl
 996 dnl TLS detection
 997 dnl
 998
 999 AC_ARG_ENABLE([glx-tls],
1000     [AS_HELP_STRING([--enable-glx-tls],
1001         [enable TLS support in GLX @<:@default=disabled@:>@])],
1002     [GLX_USE_TLS="$enableval"],
1003     [GLX_USE_TLS=no])
1004 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1005
1006 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1007       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1008
1009 dnl
1010 dnl More DRI setup
1011 dnl
1012 dnl Directory for DRI drivers
1013 AC_ARG_WITH([dri-driverdir],
1014     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1015         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1016     [DRI_DRIVER_INSTALL_DIR="$withval"],
1017     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1018 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1019 dnl Extra search path for DRI drivers
1020 AC_ARG_WITH([dri-searchpath],
1021     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1022         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1023     [DRI_DRIVER_SEARCH_DIR="$withval"],
1024     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1025 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1026 dnl Which drivers to build - default is chosen by platform
1027 AC_ARG_WITH([dri-drivers],
1028     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1029         [comma delimited classic DRI drivers list, e.g.
1030         "swrast,i965,radeon" @<:@default=auto@:>@])],
1031     [with_dri_drivers="$withval"],
1032     [with_dri_drivers=auto])
1033
1034 if test "x$with_dri_drivers" = xauto; then
1035     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1036         with_dri_drivers="yes"
1037     else
1038         with_dri_drivers="no"
1039     fi
1040 fi
1041 if test "x$with_dri_drivers" = xno; then
1042     with_dri_drivers=''
1043 fi
1044
1045 dnl If $with_dri_drivers is yes, drivers will be added through
1046 dnl platform checks. Set DEFINES and LIB_DEPS
1047 if test "x$enable_dri" = xyes; then
1048     # Platform specific settings and drivers to build
1049     case "$host_os" in
1050     linux*)
1051         DEFINES="$DEFINES -DHAVE_ALIAS"
1052         if test "x$enable_dri3" = xyes; then
1053             DEFINES="$DEFINES -DHAVE_DRI3"
1054         fi
1055
1056         if test "x$have_pci_id" != xyes; then
1057             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1058         fi
1059
1060         case "$host_cpu" in
1061         powerpc* | sparc*)
1062             # Build only the drivers for cards that exist on PowerPC/sparc
1063             if test "x$with_dri_drivers" = "xyes"; then
1064                 with_dri_drivers="r200 radeon swrast"
1065             fi
1066             ;;
1067         esac
1068         ;;
1069     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1070         DEFINES="$DEFINES -DHAVE_PTHREAD"
1071         DEFINES="$DEFINES -DHAVE_ALIAS"
1072         ;;
1073     gnu*)
1074         DEFINES="$DEFINES -DHAVE_ALIAS"
1075         ;;
1076     cygwin*)
1077         if test "x$with_dri_drivers" = "xyes"; then
1078             with_dri_drivers="swrast"
1079         fi
1080         ;;
1081     darwin*)
1082         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1083         if test "x$with_dri_drivers" = "xyes"; then
1084             with_dri_drivers="swrast"
1085         fi
1086         ;;
1087     esac
1088
1089     # default drivers
1090     if test "x$with_dri_drivers" = "xyes"; then
1091         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1092     fi
1093
1094     # Check for expat
1095     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1096     if test "x$have_expat" = "xyes"; then
1097        PKG_CHECK_MODULES([EXPAT], [expat], [],
1098                          AC_MSG_ERROR([Expat required for DRI.]))
1099     else
1100        # expat version 2.0 and earlier do not provide expat.pc
1101        EXPAT_LIBS=-lexpat
1102     fi
1103
1104     DRICOMMON_NEED_LIBDRM=no
1105     # If we are building any DRI driver other than swrast.
1106     if test -n "$with_dri_drivers"; then
1107         if test "x$with_dri_drivers" != xswrast; then
1108             # ... libdrm is required
1109             if test "x$have_libdrm" != xyes; then
1110                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1111             fi
1112             DRICOMMON_NEED_LIBDRM=yes
1113         fi
1114     fi
1115
1116     # If we're building any gallium DRI driver other than swrast
1117     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1118         if test "x$with_gallium_drivers" != xswrast; then
1119             # ... build a libdrm aware dricommon
1120             DRICOMMON_NEED_LIBDRM=yes
1121         fi
1122     fi
1123
1124     # put all the necessary libs together
1125     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1126 fi
1127
1128 AC_SUBST([DRI_LIB_DEPS])
1129
1130 DRI_DIRS=''
1131 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1132 if test -n "$with_dri_drivers"; then
1133     if test "x$enable_opengl" != xyes; then
1134         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1135     fi
1136
1137     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1138     for driver in $dri_drivers; do
1139         DRI_DIRS="$DRI_DIRS $driver"
1140         case "x$driver" in
1141         xi915)
1142             HAVE_I915_DRI=yes;
1143             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1144             ;;
1145         xi965)
1146             HAVE_I965_DRI=yes;
1147             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1148             ;;
1149         xnouveau)
1150             HAVE_NOUVEAU_DRI=yes;
1151             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1152             ;;
1153         xradeon)
1154             HAVE_RADEON_DRI=yes;
1155             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1156             ;;
1157         xr200)
1158             HAVE_R200_DRI=yes;
1159             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1160             ;;
1161         xswrast)
1162             HAVE_SWRAST_DRI=yes;
1163             ;;
1164         *)
1165             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1166             ;;
1167         esac
1168     done
1169     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1170 fi
1171
1172 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1173 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1174                                   "x$enable_osmesa" = xyes -o \
1175                                   -n "$DRI_DIRS")
1176
1177 dnl
1178 dnl OSMesa configuration
1179 dnl
1180
1181 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1182 AC_ARG_WITH([osmesa-bits],
1183     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1184         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1185     [osmesa_bits="$withval"],
1186     [osmesa_bits=8])
1187 if test "x$osmesa_bits" != x8; then
1188     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1189         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1190         osmesa_bits=8
1191     fi
1192 fi
1193 case "x$osmesa_bits" in
1194 x8)
1195     OSMESA_LIB="${OSMESA_LIB}"
1196     ;;
1197 x16|x32)
1198     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1199     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1200     ;;
1201 *)
1202     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1203     ;;
1204 esac
1205
1206 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1207     # only link libraries with osmesa if shared
1208     if test "$enable_static" = no; then
1209         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1210     else
1211         OSMESA_LIB_DEPS=""
1212     fi
1213     OSMESA_MESA_DEPS=""
1214     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1215 fi
1216
1217 AC_SUBST([OSMESA_LIB_DEPS])
1218 AC_SUBST([OSMESA_MESA_DEPS])
1219 AC_SUBST([OSMESA_PC_REQ])
1220 AC_SUBST([OSMESA_PC_LIB_PRIV])
1221
1222 dnl
1223 dnl gbm configuration
1224 dnl
1225 if test "x$enable_gbm" = xauto; then
1226     case "$with_egl_platforms" in
1227         *drm*)
1228             enable_gbm=yes ;;
1229          *)
1230             enable_gbm=no ;;
1231     esac
1232 fi
1233 if test "x$enable_gbm" = xyes; then
1234     if test "x$need_pci_id$have_pci_id" = xyesno; then
1235         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1236     fi
1237
1238     if test "x$enable_dri" = xyes; then
1239         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1240         if test "x$enable_shared_glapi" = xno; then
1241             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1242         fi
1243     else
1244         # Strictly speaking libgbm does not require --enable-dri, although
1245         # both of its backends do. Thus one can build libgbm without any
1246         # backends if --disable-dri is set.
1247         # To avoid unnecessary complexity of checking if at least one backend
1248         # is available when building, just mandate --enable-dri.
1249         AC_MSG_ERROR([gbm requires --enable-dri])
1250     fi
1251 fi
1252 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1253 if test "x$need_pci_id$have_libudev" = xyesyes; then
1254     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1255 else
1256     GBM_PC_REQ_PRIV=""
1257 fi
1258 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1259 AC_SUBST([GBM_PC_REQ_PRIV])
1260 AC_SUBST([GBM_PC_LIB_PRIV])
1261
1262 dnl
1263 dnl EGL configuration
1264 dnl
1265 EGL_CLIENT_APIS=""
1266
1267 if test "x$enable_egl" = xyes; then
1268     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1269
1270     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1271
1272     if test "$enable_static" != yes; then
1273         if test "x$enable_dri" = xyes; then
1274             HAVE_EGL_DRIVER_DRI2=1
1275         fi
1276
1277     fi
1278 fi
1279 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1280 AC_SUBST([EGL_LIB_DEPS])
1281
1282 dnl
1283 dnl EGL Gallium configuration
1284 dnl
1285 if test "x$enable_gallium_egl" = xyes; then
1286     if test -z "$with_gallium_drivers"; then
1287         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1288     fi
1289     if test "x$enable_egl" = xno; then
1290         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1291     fi
1292     if test "x$have_libdrm" != xyes; then
1293         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1294     fi
1295
1296     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1297     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1298 #    enable_gallium_loader=yes
1299 fi
1300 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1301
1302 dnl
1303 dnl gbm Gallium configuration
1304 dnl
1305 if test "x$enable_gallium_gbm" = xauto; then
1306     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1307         yesyesyes*drm*)
1308             enable_gallium_gbm=yes ;;
1309          *)
1310             enable_gallium_gbm=no ;;
1311     esac
1312 fi
1313 if test "x$enable_gallium_gbm" = xyes; then
1314     if test -z "$with_gallium_drivers"; then
1315         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1316     fi
1317     if test "x$enable_gbm" = xno; then
1318         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1319     fi
1320
1321     if test "x$enable_gallium_egl" != xyes; then
1322         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1323     fi
1324
1325     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1326     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1327     enable_gallium_loader=yes
1328 fi
1329 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1330
1331 dnl
1332 dnl XA configuration
1333 dnl
1334 if test "x$enable_xa" = xyes; then
1335     if test "x$with_gallium_drivers" = xswrast; then
1336        AC_MSG_ERROR([
1337           Building xa requires at least one non swrast gallium driver.
1338           If you are looking to use libxatracker.so with the VMware driver,
1339           make sure to include svga in the gallium drivers list, apart from
1340           enabling XA.
1341           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1342     fi
1343     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1344     enable_gallium_loader=yes
1345 fi
1346 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1347
1348 dnl
1349 dnl OpenVG configuration
1350 dnl
1351 VG_LIB_DEPS=""
1352
1353 if test "x$enable_openvg" = xyes; then
1354     if test "x$enable_egl" = xno; then
1355         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1356     fi
1357     if test -z "$with_gallium_drivers"; then
1358         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1359     fi
1360     if test "x$enable_gallium_egl" = xno; then
1361         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1362     fi
1363
1364     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1365     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1366     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1367     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1368     AC_SUBST([VG_PC_LIB_PRIV])
1369 fi
1370 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1371
1372 dnl
1373 dnl Gallium G3DVL configuration
1374 dnl
1375 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1376     if test "x$enable_xvmc" = xauto; then
1377         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1378     fi
1379
1380     if test "x$enable_vdpau" = xauto; then
1381         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1382     fi
1383
1384     if test "x$enable_omx" = xauto; then
1385         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1386     fi
1387 fi
1388
1389 if test "x$enable_xvmc" = xyes; then
1390     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1391     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1392     enable_gallium_loader=yes
1393 fi
1394 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1395
1396 if test "x$enable_vdpau" = xyes; then
1397     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1398                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1399     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1400     enable_gallium_loader=yes
1401 fi
1402 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1403
1404 if test "x$enable_omx" = xyes; then
1405     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1406     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1407     enable_gallium_loader=yes
1408 fi
1409 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1410
1411 dnl
1412 dnl OpenCL configuration
1413 dnl
1414
1415 AC_ARG_WITH([libclc-path],
1416    [AS_HELP_STRING([--with-libclc-path],
1417          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1418    [LIBCLC_PATH="$withval"],
1419    [LIBCLC_PATH=''])
1420
1421 if test -n "$LIBCLC_PATH"; then
1422    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1423                   Please review the updated build instructions for clover:
1424                   http://dri.freedesktop.org/wiki/GalliumCompute])
1425 fi
1426
1427
1428 AC_ARG_WITH([clang-libdir],
1429    [AS_HELP_STRING([--with-clang-libdir],
1430          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1431    [CLANG_LIBDIR="$withval"],
1432    [CLANG_LIBDIR=''])
1433
1434 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1435
1436 if test "x$enable_opencl" = xyes; then
1437     if test -z "$with_gallium_drivers"; then
1438         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1439     fi
1440
1441     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1442         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1443     fi
1444
1445     if test "x$have_libclc" = xno; then
1446         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1447                     Make sure the directory containing libclc.pc is specified in your
1448                     PKG_CONFIG_PATH environment variable.
1449                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1450     else
1451         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1452         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1453         AC_SUBST([LIBCLC_INCLUDEDIR])
1454         AC_SUBST([LIBCLC_LIBEXECDIR])
1455     fi
1456
1457     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1458     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1459     enable_gallium_loader=yes
1460
1461     if test "x$enable_opencl_icd" = xyes; then
1462         OPENCL_LIBNAME="MesaOpenCL"
1463     else
1464         OPENCL_LIBNAME="OpenCL"
1465     fi
1466 fi
1467 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1468 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1469 AC_SUBST([OPENCL_LIBNAME])
1470
1471 dnl
1472 dnl Gallium configuration
1473 dnl
1474 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1475
1476 AC_SUBST([LLVM_BINDIR])
1477 AC_SUBST([LLVM_CFLAGS])
1478 AC_SUBST([LLVM_CPPFLAGS])
1479 AC_SUBST([LLVM_CXXFLAGS])
1480 AC_SUBST([LLVM_LIBDIR])
1481 AC_SUBST([LLVM_LIBS])
1482 AC_SUBST([LLVM_LDFLAGS])
1483 AC_SUBST([LLVM_INCLUDEDIR])
1484 AC_SUBST([LLVM_VERSION])
1485 AC_SUBST([CLANG_RESOURCE_DIR])
1486
1487 case "x$enable_opengl$enable_gles1$enable_gles2" in
1488 x*yes*)
1489     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1490     ;;
1491 esac
1492
1493 AC_SUBST([VG_LIB_DEPS])
1494 AC_SUBST([EGL_CLIENT_APIS])
1495
1496 dnl
1497 dnl EGL Platforms configuration
1498 dnl
1499 AC_ARG_WITH([egl-platforms],
1500     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1501         [comma delimited native platforms libEGL supports, e.g.
1502         "x11,drm" @<:@default=auto@:>@])],
1503     [with_egl_platforms="$withval"],
1504     [if test "x$enable_egl" = xyes; then
1505         with_egl_platforms="x11"
1506     else
1507         with_egl_platforms=""
1508     fi])
1509
1510 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1511     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1512 fi
1513
1514 # Do per-EGL platform setups and checks
1515 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1516 for plat in $egl_platforms; do
1517         case "$plat" in
1518         wayland)
1519                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1520                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1521
1522                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1523                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1524                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1525                 ;;
1526
1527         x11)
1528                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1529                 ;;
1530
1531         drm)
1532                 test "x$enable_gbm" = "xno" &&
1533                         AC_MSG_ERROR([EGL platform drm needs gbm])
1534                 test "x$have_libdrm" != xyes &&
1535                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1536                 ;;
1537
1538         android|fbdev|gdi|null)
1539                 ;;
1540
1541         *)
1542                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1543                 ;;
1544         esac
1545
1546         case "$plat$need_pci_id$have_pci_id" in
1547                 waylandyesno|drmyesno)
1548                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1549         esac
1550 done
1551
1552 # libEGL wants to default to the first platform specified in
1553 # ./configure.  parse that here.
1554 if test "x$egl_platforms" != "x"; then
1555     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1556     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1557 else
1558     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1559 fi
1560
1561 if echo "$egl_platforms" | grep -q 'x11'; then
1562     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1563     NEED_WINSYS_XLIB=yes
1564 fi
1565 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1566 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1567 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1568 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1569 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1570
1571 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1572
1573 AC_SUBST([EGL_NATIVE_PLATFORM])
1574 AC_SUBST([EGL_CFLAGS])
1575
1576 # If we don't have the X11 platform, set this define so we don't try to include
1577 # the X11 headers.
1578 if ! echo "$egl_platforms" | grep -q 'x11'; then
1579     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1580     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1581 fi
1582
1583 AC_ARG_WITH([egl-driver-dir],
1584     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1585                     [directory for EGL drivers @<:@default=${libdir}/egl@:>@])],
1586     [EGL_DRIVER_INSTALL_DIR="$withval"],
1587     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1588 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1589
1590 AC_ARG_WITH([max-width],
1591     [AS_HELP_STRING([--with-max-width=N],
1592                     [Maximum framebuffer width (4096)])],
1593     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1594      AS_IF([test "${withval}" -gt "4096"],
1595            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1596 )
1597 AC_ARG_WITH([max-height],
1598     [AS_HELP_STRING([--with-max-height=N],
1599                     [Maximum framebuffer height (4096)])],
1600     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1601      AS_IF([test "${withval}" -gt "4096"],
1602            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1603 )
1604
1605 dnl
1606 dnl Gallium LLVM
1607 dnl
1608 AC_ARG_ENABLE([gallium-llvm],
1609     [AS_HELP_STRING([--enable-gallium-llvm],
1610         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1611     [enable_gallium_llvm="$enableval"],
1612     [enable_gallium_llvm=auto])
1613
1614 AC_ARG_ENABLE([llvm-shared-libs],
1615     [AS_HELP_STRING([--enable-llvm-shared-libs],
1616         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1617     [enable_llvm_shared_libs="$enableval"],
1618     [enable_llvm_shared_libs=yes])
1619
1620 AC_ARG_WITH([llvm-prefix],
1621     [AS_HELP_STRING([--with-llvm-prefix],
1622         [Prefix for LLVM installations in non-standard locations])],
1623     [llvm_prefix="$withval"],
1624     [llvm_prefix=''])
1625
1626
1627 # Call this inside ` ` to get the return value.
1628 # $1 is the llvm-config command with arguments.
1629 strip_unwanted_llvm_flags() {
1630     # Use \> (marks the end of the word)
1631     echo `$1` | sed \
1632         -e 's/-DNDEBUG\>//g' \
1633         -e 's/-pedantic\>//g' \
1634         -e 's/-Wcovered-switch-default\>//g' \
1635         -e 's/-O.\>//g' \
1636         -e 's/-g\>//g' \
1637         -e 's/-Wall\>//g' \
1638         -e 's/-Wcast-qual\>//g' \
1639         -e 's/-Woverloaded-virtual\>//g' \
1640         -e 's/-fcolor-diagnostics\>//g' \
1641         -e 's/-fdata-sections\>//g' \
1642         -e 's/-ffunction-sections\>//g' \
1643         -e 's/-fno-exceptions\>//g' \
1644         -e 's/-fomit-frame-pointer\>//g' \
1645         -e 's/-fvisibility-inlines-hidden\>//g' \
1646         -e 's/-fPIC\>//g' \
1647         -e 's/-fstack-protector-strong\>//g'
1648 }
1649
1650
1651 if test -z "$with_gallium_drivers"; then
1652     enable_gallium_llvm=no
1653 fi
1654 if test "x$enable_gallium_llvm" = xauto; then
1655     case "$host_cpu" in
1656     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1657     esac
1658 fi
1659 if test "x$enable_gallium_llvm" = xyes; then
1660     if test -n "$llvm_prefix"; then
1661         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1662     else
1663         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1664     fi
1665
1666     if test "x$LLVM_CONFIG" != xno; then
1667         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1668         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1669         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1670         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1671         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1672         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1673         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1674         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1675
1676         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1677             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1678         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1679             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1680
1681         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1682         dnl llvm-config.h
1683         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1684             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1685             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1686
1687         if test -n "${LLVM_VERSION_MAJOR}"; then
1688             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1689         else
1690             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1691         fi
1692
1693         LLVM_REQUIRED_VERSION_MAJOR="3"
1694         LLVM_REQUIRED_VERSION_MINOR="1"
1695         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1696             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1697         fi
1698
1699         LLVM_COMPONENTS="engine bitwriter"
1700         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1701             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1702         fi
1703
1704         if test "x$enable_opencl" = xyes; then
1705             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1706             # LLVM 3.3 >= 177971 requires IRReader
1707             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1708                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1709             fi
1710             # LLVM 3.4 requires Option
1711             if $LLVM_CONFIG --components | grep -qw 'option'; then
1712                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1713             fi
1714             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1715             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1716                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1717             fi
1718             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1719                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1720             fi
1721         fi
1722         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1723         MESA_LLVM=1
1724
1725         dnl Check for Clang internal headers
1726         if test "x$enable_opencl" = xyes; then
1727             if test -z "$CLANG_LIBDIR"; then
1728                 CLANG_LIBDIR=${LLVM_LIBDIR}
1729             fi
1730             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1731             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1732                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1733         fi
1734     else
1735         MESA_LLVM=0
1736         LLVM_VERSION_INT=0
1737     fi
1738 else
1739     MESA_LLVM=0
1740     LLVM_VERSION_INT=0
1741
1742     if test "x$enable_opencl" = xyes; then
1743         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1744     fi
1745 fi
1746
1747 dnl Directory for XVMC libs
1748 AC_ARG_WITH([xvmc-libdir],
1749     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1750         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1751     [XVMC_LIB_INSTALL_DIR="$withval"],
1752     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1753 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1754
1755 dnl
1756 dnl Gallium Tests
1757 dnl
1758 if test "x$enable_gallium_tests" = xyes; then
1759     enable_gallium_loader=yes
1760 fi
1761 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1762
1763 if test "x$enable_gallium_loader" = xyes; then
1764     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1765 fi
1766 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1767
1768 dnl Directory for VDPAU libs
1769 AC_ARG_WITH([vdpau-libdir],
1770     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1771         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1772     [VDPAU_LIB_INSTALL_DIR="$withval"],
1773     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1774 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1775
1776 OMX_LIB_INSTALL_DIR_DEFAULT=''
1777 if test "x$enable_omx" = xyes; then
1778     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1779 fi
1780
1781 AC_ARG_WITH([omx-libdir],
1782     [AS_HELP_STRING([--with-omx-libdir=DIR],
1783         [directory for the OMX libraries])],
1784     [OMX_LIB_INSTALL_DIR="$withval"],
1785     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1786 AC_SUBST([OMX_LIB_INSTALL_DIR])
1787
1788 dnl Directory for OpenCL libs
1789 AC_ARG_WITH([opencl-libdir],
1790     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1791         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1792     [OPENCL_LIB_INSTALL_DIR="$withval"],
1793     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1794 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1795
1796 dnl
1797 dnl Gallium helper functions
1798 dnl
1799 gallium_check_st() {
1800     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1801          if test "x$have_libdrm" != xyes; then
1802             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1803          fi
1804          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1805     fi
1806     if test "x$enable_dri" = xyes && test -n "$2"; then
1807          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1808     fi
1809     if test "x$enable_xa" = xyes && test -n "$3"; then
1810          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1811     fi
1812     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1813          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1814     fi
1815     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1816          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1817     fi
1818     if test "x$enable_omx" = xyes && test "x$6" != x; then
1819          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1820     fi
1821 }
1822
1823 gallium_require_llvm() {
1824     if test "x$MESA_LLVM" = x0; then
1825         case "$host" in *gnux32) return;; esac
1826         case "$host_cpu" in
1827         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1828         esac
1829     fi
1830 }
1831
1832 gallium_require_drm_loader() {
1833     if test "x$enable_gallium_loader" = xyes; then
1834         if test "x$need_pci_id$have_pci_id" = xyesno; then
1835             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1836         fi
1837         if test "x$have_libdrm" != xyes; then
1838             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1839         fi
1840         enable_gallium_drm_loader=yes
1841     fi
1842 }
1843
1844 require_egl_drm() {
1845     case "$with_egl_platforms" in
1846         *drm*)
1847             ;;
1848          *)
1849             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1850             ;;
1851     esac
1852     if test "x$enable_gbm" != xyes; then
1853             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1854     fi
1855 }
1856
1857 radeon_llvm_check() {
1858     if test "x$enable_gallium_llvm" != "xyes"; then
1859         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1860     fi
1861     LLVM_REQUIRED_VERSION_MAJOR="3"
1862     LLVM_REQUIRED_VERSION_MINOR="4"
1863     LLVM_REQUIRED_VERSION_PATCH="2"
1864     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1865         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1866     fi
1867     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1868         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1869                       sources with the --enable-experimental-targets=R600
1870                       configure flag])
1871     fi
1872     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1873     NEED_RADEON_LLVM=yes
1874     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1875                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1876 }
1877
1878 dnl Gallium drivers
1879 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1880         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1881     NEED_NONNULL_WINSYS=yes
1882 fi
1883 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1884
1885 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1886 if test -n "$with_gallium_drivers"; then
1887     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1888     for driver in $gallium_drivers; do
1889         case "x$driver" in
1890         xsvga)
1891             HAVE_GALLIUM_SVGA=yes
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1893             gallium_require_drm_loader
1894             gallium_check_st "svga/drm" "dri/vmwgfx" "xa/vmwgfx"
1895             ;;
1896         xi915)
1897             HAVE_GALLIUM_I915=yes
1898             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1899             gallium_require_drm_loader
1900             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1901             gallium_check_st "i915/drm" "dri/i915" "xa/i915"
1902             ;;
1903         xilo)
1904             HAVE_GALLIUM_ILO=yes
1905             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1906             gallium_require_drm_loader
1907             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1908             gallium_check_st "intel/drm" "dri/ilo" "xa/ilo"
1909             ;;
1910         xr300)
1911             HAVE_GALLIUM_R300=yes
1912             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1913             gallium_require_drm_loader
1914             gallium_require_llvm "Gallium R300"
1915             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1916             gallium_check_st "radeon/drm" "dri/r300"
1917             ;;
1918         xr600)
1919             HAVE_GALLIUM_R600=yes
1920             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1921             gallium_require_drm_loader
1922             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1923             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1924                 radeon_llvm_check "r600g"
1925                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1926             fi
1927             if test "x$enable_r600_llvm" = xyes; then
1928                 USE_R600_LLVM_COMPILER=yes;
1929             fi
1930             if test "x$enable_opencl" = xyes; then
1931                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1932             fi
1933             gallium_check_st "radeon/drm" "dri/r600" "" "xvmc/r600" "vdpau/r600" "omx/r600"
1934             ;;
1935         xradeonsi)
1936             HAVE_GALLIUM_RADEONSI=yes
1937             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1938             gallium_require_drm_loader
1939             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1940             radeon_llvm_check "radeonsi"
1941             require_egl_drm "radeonsi"
1942             gallium_check_st "radeon/drm" "dri/radeonsi" "" "" "vdpau/radeonsi" "omx/radeonsi"
1943             ;;
1944         xnouveau)
1945             HAVE_GALLIUM_NOUVEAU=yes
1946             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1947             gallium_require_drm_loader
1948             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1949             gallium_check_st "nouveau/drm" "dri/nouveau" "xa/nouveau" "xvmc/nouveau" "vdpau/nouveau" "omx/nouveau"
1950             ;;
1951         xfreedreno)
1952             HAVE_GALLIUM_FREEDRENO=yes
1953             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1954             gallium_require_drm_loader
1955             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1956             gallium_check_st "freedreno/drm" "dri/freedreno" "xa/freedreno" "" ""
1957             ;;
1958         xswrast)
1959             HAVE_GALLIUM_SOFTPIPE=yes
1960             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1961             if test "x$MESA_LLVM" = x1; then
1962                 HAVE_GALLIUM_LLVMPIPE=yes
1963                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1964             fi
1965
1966             if test "x$enable_dri" = xyes; then
1967                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/swrast"
1968             fi
1969
1970             if test "x$have_libdrm" = xyes; then
1971                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/kms-swrast"
1972             fi
1973             ;;
1974         xvc4)
1975             HAVE_GALLIUM_VC4=yes
1976             gallium_require_drm_loader
1977             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS vc4"
1978             gallium_check_st "vc4/drm" "dri-vc4" "" "" ""
1979
1980             case "$host_cpu" in
1981                 i?86 | x86_64 | amd64)
1982                 USE_VC4_SIMULATOR=yes
1983                 ;;
1984             esac
1985             ;;
1986         *)
1987             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1988             ;;
1989         esac
1990     done
1991 fi
1992
1993 dnl Set LLVM_LIBS - This is done after the driver configuration so
1994 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1995 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1996 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1997 dnl this was causing the same libraries to be appear multiple times
1998 dnl in LLVM_LIBS.
1999
2000 if test "x$MESA_LLVM" != x0; then
2001
2002     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2003
2004     if test "x$enable_llvm_shared_libs" = xyes; then
2005         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2006         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2007         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2008
2009         if test "x$llvm_have_one_so" = xyes; then
2010             dnl LLVM was built using auto*, so there is only one shared object.
2011             LLVM_LIBS="-l$LLVM_SO_NAME"
2012         else
2013             dnl If LLVM was built with CMake, there will be one shared object per
2014             dnl component.
2015             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2016                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2017         Please make sure you have built llvm with the --enable-shared option
2018         and that your llvm libraries are installed in $LLVM_LIBDIR
2019         If you have installed your llvm libraries to a different directory you
2020         can use the --with-llvm-prefix= configure flag to specify this directory.
2021         NOTE: Mesa is attempting to use llvm shared libraries by default.
2022         If you do not want to build with llvm shared libraries and instead want to
2023         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2024         invocation and rebuild.])])
2025
2026            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2027            dnl install uses a shared object for each compoenent and we have
2028            dnl already added all of these objects to LLVM_LIBS.
2029         fi
2030     else
2031         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2032     fi
2033 fi
2034
2035 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2036 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2037 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2038 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2039 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2040 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2041 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2042                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2043 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2044 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2045 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2046 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2047 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2048
2049 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2050                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2051 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2052                                                   && test "x$MESA_LLVM" = x1)
2053
2054 # Enable static gallium targets for now.
2055 # Do not touch this unless you know what you are doing.
2056 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "xyes" = xyes)
2057
2058 # NOTE: anything using xcb or other client side libs ends up in separate
2059 #       _CLIENT variables.  The pipe loader is built in two variants,
2060 #       one that is standalone and does not link any x client libs (for
2061 #       use by XA tracker in particular, but could be used in any case
2062 #       where communication with xserver is not desired).
2063 if test "x$enable_gallium_loader" = xyes; then
2064     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2065
2066     if test "x$NEED_WINSYS_XLIB" = xyes; then
2067         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2068     fi
2069
2070     if test "x$enable_dri" = xyes; then
2071         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2072     fi
2073
2074     if test "x$enable_gallium_drm_loader" = xyes; then
2075         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2076         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2077                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2078         if test "x$pipe_loader_have_xcb" = xyes; then
2079             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2080             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2081         fi
2082     fi
2083
2084     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2085     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2086
2087     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2088     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2089     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2090     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2091 fi
2092
2093 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2094 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2095 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2096 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2097 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2098 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2099
2100 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2101                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2102                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2103                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2104 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2105                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2106 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2107 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2108 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2109 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2110 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2111 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2112 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2113 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2114 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2115     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2116 fi
2117
2118 AC_SUBST([ELF_LIB])
2119
2120 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2121 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2122 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2123 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2124 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2125
2126 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2127 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2128 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2129
2130 AC_SUBST([VDPAU_MAJOR], 1)
2131 AC_SUBST([VDPAU_MINOR], 0)
2132
2133 AC_SUBST([XVMC_MAJOR], 1)
2134 AC_SUBST([XVMC_MINOR], 0)
2135
2136 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2137 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2138 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2139 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2140
2141 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2142 AC_SUBST([XA_MINOR], $XA_MINOR)
2143 AC_SUBST([XA_TINY], $XA_TINY)
2144 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2145
2146 dnl Restore LDFLAGS and CPPFLAGS
2147 LDFLAGS="$_SAVE_LDFLAGS"
2148 CPPFLAGS="$_SAVE_CPPFLAGS"
2149
2150 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2151 if test "x$acv_mesa_CLANG" = xyes; then
2152     CFLAGS="$CFLAGS -Qunused-arguments"
2153     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2154 fi
2155
2156 dnl Add user CFLAGS and CXXFLAGS
2157 CFLAGS="$CFLAGS $USER_CFLAGS"
2158 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2159
2160 dnl Substitute the config
2161 AC_CONFIG_FILES([Makefile
2162                 src/Makefile
2163                 src/egl/drivers/dri2/Makefile
2164                 src/egl/main/Makefile
2165                 src/egl/main/egl.pc
2166                 src/egl/wayland/Makefile
2167                 src/egl/wayland/wayland-drm/Makefile
2168                 src/egl/wayland/wayland-egl/Makefile
2169                 src/egl/wayland/wayland-egl/wayland-egl.pc
2170                 src/gallium/Makefile
2171                 src/gallium/auxiliary/Makefile
2172                 src/gallium/auxiliary/pipe-loader/Makefile
2173                 src/gallium/drivers/freedreno/Makefile
2174                 src/gallium/drivers/galahad/Makefile
2175                 src/gallium/drivers/i915/Makefile
2176                 src/gallium/drivers/identity/Makefile
2177                 src/gallium/drivers/ilo/Makefile
2178                 src/gallium/drivers/llvmpipe/Makefile
2179                 src/gallium/drivers/noop/Makefile
2180                 src/gallium/drivers/nouveau/Makefile
2181                 src/gallium/drivers/r300/Makefile
2182                 src/gallium/drivers/r600/Makefile
2183                 src/gallium/drivers/radeon/Makefile
2184                 src/gallium/drivers/radeonsi/Makefile
2185                 src/gallium/drivers/rbug/Makefile
2186                 src/gallium/drivers/softpipe/Makefile
2187                 src/gallium/drivers/svga/Makefile
2188                 src/gallium/drivers/trace/Makefile
2189                 src/gallium/drivers/vc4/Makefile
2190                 src/gallium/state_trackers/clover/Makefile
2191                 src/gallium/state_trackers/dri/Makefile
2192                 src/gallium/state_trackers/egl/Makefile
2193                 src/gallium/state_trackers/gbm/Makefile
2194                 src/gallium/state_trackers/glx/xlib/Makefile
2195                 src/gallium/state_trackers/omx/Makefile
2196                 src/gallium/state_trackers/osmesa/Makefile
2197                 src/gallium/state_trackers/vdpau/Makefile
2198                 src/gallium/state_trackers/vega/Makefile
2199                 src/gallium/state_trackers/xa/Makefile
2200                 src/gallium/state_trackers/xvmc/Makefile
2201                 src/gallium/targets/dri/Makefile
2202                 src/gallium/targets/egl-static/Makefile
2203                 src/gallium/targets/gbm/Makefile
2204                 src/gallium/targets/libgl-xlib/Makefile
2205                 src/gallium/targets/omx/Makefile
2206                 src/gallium/targets/opencl/Makefile
2207                 src/gallium/targets/osmesa/Makefile
2208                 src/gallium/targets/osmesa/osmesa.pc
2209                 src/gallium/targets/pipe-loader/Makefile
2210                 src/gallium/targets/vdpau/Makefile
2211                 src/gallium/targets/xa/Makefile
2212                 src/gallium/targets/xa/xatracker.pc
2213                 src/gallium/targets/xvmc/Makefile
2214                 src/gallium/tests/trivial/Makefile
2215                 src/gallium/tests/unit/Makefile
2216                 src/gallium/winsys/freedreno/drm/Makefile
2217                 src/gallium/winsys/i915/drm/Makefile
2218                 src/gallium/winsys/intel/drm/Makefile
2219                 src/gallium/winsys/nouveau/drm/Makefile
2220                 src/gallium/winsys/radeon/drm/Makefile
2221                 src/gallium/winsys/svga/drm/Makefile
2222                 src/gallium/winsys/sw/dri/Makefile
2223                 src/gallium/winsys/sw/fbdev/Makefile
2224                 src/gallium/winsys/sw/kms-dri/Makefile
2225                 src/gallium/winsys/sw/null/Makefile
2226                 src/gallium/winsys/sw/wayland/Makefile
2227                 src/gallium/winsys/sw/wrapper/Makefile
2228                 src/gallium/winsys/sw/xlib/Makefile
2229                 src/gallium/winsys/vc4/drm/Makefile
2230                 src/gbm/Makefile
2231                 src/gbm/main/gbm.pc
2232                 src/glsl/Makefile
2233                 src/glx/Makefile
2234                 src/glx/apple/Makefile
2235                 src/glx/tests/Makefile
2236                 src/gtest/Makefile
2237                 src/loader/Makefile
2238                 src/mapi/Makefile
2239                 src/mapi/es1api/Makefile
2240                 src/mapi/es1api/glesv1_cm.pc
2241                 src/mapi/es2api/Makefile
2242                 src/mapi/es2api/glesv2.pc
2243                 src/mapi/glapi/Makefile
2244                 src/mapi/glapi/gen/Makefile
2245                 src/mapi/glapi/tests/Makefile
2246                 src/mapi/shared-glapi/Makefile
2247                 src/mapi/shared-glapi/tests/Makefile
2248                 src/mapi/vgapi/Makefile
2249                 src/mapi/vgapi/vg.pc
2250                 src/mesa/Makefile
2251                 src/mesa/gl.pc
2252                 src/mesa/drivers/dri/dri.pc
2253                 src/mesa/drivers/dri/common/Makefile
2254                 src/mesa/drivers/dri/common/xmlpool/Makefile
2255                 src/mesa/drivers/dri/i915/Makefile
2256                 src/mesa/drivers/dri/i965/Makefile
2257                 src/mesa/drivers/dri/Makefile
2258                 src/mesa/drivers/dri/nouveau/Makefile
2259                 src/mesa/drivers/dri/r200/Makefile
2260                 src/mesa/drivers/dri/radeon/Makefile
2261                 src/mesa/drivers/dri/swrast/Makefile
2262                 src/mesa/drivers/osmesa/Makefile
2263                 src/mesa/drivers/osmesa/osmesa.pc
2264                 src/mesa/drivers/x11/Makefile
2265                 src/mesa/main/tests/Makefile
2266                 src/util/Makefile
2267                 src/util/tests/hash_table/Makefile])
2268
2269 dnl Sort the dirs alphabetically
2270 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2271 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2272 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2273 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2274
2275 AC_OUTPUT
2276
2277 dnl
2278 dnl Output some configuration info for the user
2279 dnl
2280 echo ""
2281 echo "        prefix:          $prefix"
2282 echo "        exec_prefix:     $exec_prefix"
2283 echo "        libdir:          $libdir"
2284 echo "        includedir:      $includedir"
2285
2286 dnl API info
2287 echo ""
2288 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2289 echo "        OpenVG:          $enable_openvg"
2290
2291 dnl Driver info
2292 echo ""
2293 case "x$enable_osmesa$enable_gallium_osmesa" in
2294 xnoyes)
2295         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2296         ;;
2297 xyesno)
2298         echo "        OSMesa:          lib$OSMESA_LIB"
2299         ;;
2300 xnono)
2301         echo "        OSMesa:          no"
2302         ;;
2303 esac
2304
2305 echo ""
2306 if test "x$enable_dri" != xno; then
2307         echo "        DRI platform:    $dri_platform"
2308         if test -z "$DRI_DIRS"; then
2309             echo "        DRI drivers:     no"
2310         else
2311             echo "        DRI drivers:     $DRI_DIRS"
2312         fi
2313         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2314 fi
2315
2316 case "x$enable_glx$enable_xlib_glx" in
2317 xyesyes)
2318     echo "        GLX:             Xlib-based"
2319     ;;
2320 xyesno)
2321     echo "        GLX:             DRI-based"
2322     ;;
2323 *)
2324     echo "        GLX:             $enable_glx"
2325     ;;
2326 esac
2327
2328 dnl EGL
2329 echo ""
2330 echo "        EGL:             $enable_egl"
2331 if test "$enable_egl" = yes; then
2332     echo "        EGL platforms:   $egl_platforms"
2333
2334     egl_drivers=""
2335     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2336         egl_drivers="$egl_drivers builtin:egl_dri2"
2337     fi
2338
2339     if test "x$enable_gallium_egl" = xyes; then
2340         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2341         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2342     else
2343         echo "        EGL drivers:    $egl_drivers"
2344     fi
2345 fi
2346
2347 echo ""
2348 if test "x$MESA_LLVM" = x1; then
2349     echo "        llvm:            yes"
2350     echo "        llvm-config:     $LLVM_CONFIG"
2351     echo "        llvm-version:    $LLVM_VERSION"
2352 else
2353     echo "        llvm:            no"
2354 fi
2355
2356 echo ""
2357 if test -n "$with_gallium_drivers"; then
2358     echo "        Gallium:         yes"
2359     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2360     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2361     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2362     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2363 else
2364     echo "        Gallium:         no"
2365 fi
2366
2367
2368 dnl Libraries
2369 echo ""
2370 echo "        Shared libs:     $enable_shared"
2371 echo "        Static libs:     $enable_static"
2372 echo "        Shared-glapi:    $enable_shared_glapi"
2373
2374 dnl Compiler options
2375 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2376 cflags=`echo $CFLAGS | \
2377     $SED 's/^ *//;s/  */ /;s/ *$//'`
2378 cxxflags=`echo $CXXFLAGS | \
2379     $SED 's/^ *//;s/  */ /;s/ *$//'`
2380 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2381 echo ""
2382 echo "        CFLAGS:          $cflags"
2383 echo "        CXXFLAGS:        $cxxflags"
2384 echo "        Macros:          $defines"
2385 echo ""
2386 if test "x$MESA_LLVM" = x1; then
2387     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2388     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2389     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2390     echo ""
2391 fi
2392 echo "        PYTHON2:         $PYTHON2"
2393
2394 echo ""
2395 echo "        Run '${MAKE-make}' to build Mesa"
2396 echo ""