configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.52
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82 PYTHON_MAKO_REQUIRED=0.3.4
  83
  84 dnl Check for progs
  85 AC_PROG_CPP
  86 AC_PROG_CC
  87 AC_PROG_CXX
  88 AM_PROG_CC_C_O
  89 AM_PROG_AS
  90 AX_CHECK_GNU_MAKE
  91 AC_CHECK_PROGS([PYTHON2], [python2 python])
  92 AC_PROG_SED
  93 AC_PROG_MKDIR_P
  94
  95 AC_SYS_LARGEFILE
  96
  97 LT_PREREQ([2.2])
  98 LT_INIT([disable-static])
  99
 100 AX_PROG_BISON([],
 101               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 102                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 103 AX_PROG_FLEX([],
 104              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 105                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 106
 107 AC_CHECK_PROG(INDENT, indent, indent, cat)
 108 if test "x$INDENT" != "xcat"; then
 109     # Only GNU indent is supported
 110     INDENT_VERSION=`indent --version | grep GNU`
 111     if test $? -eq 0; then
 112        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 113     else
 114        INDENT="cat"
 115     fi
 116 fi
 117
 118 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 119 if test -n "$PYTHON2" -a "x$acv_mako_found" = "xyes"; then
 120     AC_MSG_RESULT(yes)
 121 else
 122     AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 123 fi
 124
 125 AC_PROG_INSTALL
 126
 127 dnl We need a POSIX shell for parts of the build. Assume we have one
 128 dnl in most cases.
 129 case "$host_os" in
 130 solaris*)
 131     # Solaris /bin/sh is too old/non-POSIX compliant
 132     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 133     SHELL="$POSIX_SHELL"
 134     ;;
 135 esac
 136
 137 dnl clang is mostly GCC-compatible, but its version is much lower,
 138 dnl so we have to check for it.
 139 AC_MSG_CHECKING([if compiling with clang])
 140
 141 AC_COMPILE_IFELSE(
 142 [AC_LANG_PROGRAM([], [[
 143 #ifndef __clang__
 144        not clang
 145 #endif
 146 ]])],
 147 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 148
 149 AC_MSG_RESULT([$acv_mesa_CLANG])
 150
 151 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 152 dnl versions are explictly not supported.
 153 GEN_ASM_OFFSETS=no
 154 USE_GNU99=no
 155 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 156     AC_MSG_CHECKING([whether gcc version is sufficient])
 157     major=0
 158     minor=0
 159
 160     GCC_VERSION=`$CC -dumpversion`
 161     if test $? -eq 0; then
 162         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 163         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 164     fi
 165
 166     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 167         AC_MSG_RESULT([no])
 168         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 169     else
 170         AC_MSG_RESULT([yes])
 171     fi
 172
 173     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 174         USE_GNU99=yes
 175     fi
 176     if test "x$cross_compiling" = xyes; then
 177         GEN_ASM_OFFSETS=yes
 178     fi
 179 fi
 180
 181 dnl Check for compiler builtins
 182 AX_GCC_BUILTIN([__builtin_bswap32])
 183 AX_GCC_BUILTIN([__builtin_bswap64])
 184 AX_GCC_BUILTIN([__builtin_clz])
 185 AX_GCC_BUILTIN([__builtin_clzll])
 186 AX_GCC_BUILTIN([__builtin_ctz])
 187 AX_GCC_BUILTIN([__builtin_expect])
 188 AX_GCC_BUILTIN([__builtin_ffs])
 189 AX_GCC_BUILTIN([__builtin_ffsll])
 190 AX_GCC_BUILTIN([__builtin_popcount])
 191 AX_GCC_BUILTIN([__builtin_popcountll])
 192 AX_GCC_BUILTIN([__builtin_unreachable])
 193
 194 AX_GCC_FUNC_ATTRIBUTE([flatten])
 195 AX_GCC_FUNC_ATTRIBUTE([format])
 196 AX_GCC_FUNC_ATTRIBUTE([malloc])
 197 AX_GCC_FUNC_ATTRIBUTE([packed])
 198 AX_GCC_FUNC_ATTRIBUTE([unused])
 199
 200 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 201
 202 dnl Make sure the pkg-config macros are defined
 203 m4_ifndef([PKG_PROG_PKG_CONFIG],
 204     [m4_fatal([Could not locate the pkg-config autoconf macros.
 205   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 206   are in a different location, try setting the environment variable
 207   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 208 PKG_PROG_PKG_CONFIG()
 209
 210 dnl LIB_DIR - library basename
 211 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 212 AC_SUBST([LIB_DIR])
 213
 214 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 215 _SAVE_LDFLAGS="$LDFLAGS"
 216 _SAVE_CPPFLAGS="$CPPFLAGS"
 217
 218 dnl Compiler macros
 219 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 220 AC_SUBST([DEFINES])
 221 case "$host_os" in
 222 linux*|*-gnu*|gnu*)
 223     DEFINES="$DEFINES -D_GNU_SOURCE"
 224     ;;
 225 solaris*)
 226     DEFINES="$DEFINES -DSVR4"
 227     ;;
 228 cygwin*)
 229     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 230     ;;
 231 esac
 232
 233 dnl Add flags for gcc and g++
 234 if test "x$GCC" = xyes; then
 235     CFLAGS="$CFLAGS -Wall"
 236
 237     if test "x$USE_GNU99" = xyes; then
 238         CFLAGS="$CFLAGS -std=gnu99"
 239     else
 240         CFLAGS="$CFLAGS -std=c99"
 241     fi
 242
 243     # Enable -Werror=implicit-function-declaration and
 244     # -Werror=missing-prototypes, if available, or otherwise, just
 245     # -Wmissing-prototypes.  This is particularly useful to avoid
 246     # generating a loadable driver module that has undefined symbols.
 247     save_CFLAGS="$CFLAGS"
 248     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 249     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 250     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 251     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 252                    AC_MSG_RESULT([yes]),
 253                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 254                     AC_MSG_RESULT([no])]);
 255
 256     # Enable -fvisibility=hidden if using a gcc that supports it
 257     save_CFLAGS="$CFLAGS"
 258     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 259     VISIBILITY_CFLAGS="-fvisibility=hidden"
 260     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 261     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 262                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 263
 264     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 265     CFLAGS=$save_CFLAGS
 266
 267     # Work around aliasing bugs - developers should comment this out
 268     CFLAGS="$CFLAGS -fno-strict-aliasing"
 269
 270     # gcc's builtin memcmp is slower than glibc's
 271     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 272     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 273
 274     # Flags to help ensure that certain portions of the code -- and only those
 275     # portions -- can be built with MSVC:
 276     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 277     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 278     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 279     #   supports most of C99)
 280     # - the rest has no compiler compiler restrictions
 281     MSVC2013_COMPAT_CFLAGS="-Werror=vla -Werror=pointer-arith"
 282     MSVC2013_COMPAT_CXXFLAGS="-Werror=vla -Werror=pointer-arith"
 283     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 284     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 285 fi
 286 if test "x$GXX" = xyes; then
 287     CXXFLAGS="$CXXFLAGS -Wall"
 288
 289     # Enable -fvisibility=hidden if using a gcc that supports it
 290     save_CXXFLAGS="$CXXFLAGS"
 291     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 292     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 293     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 294     AC_LANG_PUSH([C++])
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 296                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 297     AC_LANG_POP([C++])
 298
 299     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 300     CXXFLAGS=$save_CXXFLAGS
 301
 302     # Work around aliasing bugs - developers should comment this out
 303     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 304
 305     # gcc's builtin memcmp is slower than glibc's
 306     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 307     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 308 fi
 309
 310 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 311 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 312 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 313 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 314
 315 dnl even if the compiler appears to support it, using visibility attributes isn't
 316 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 317 case "$host_os" in
 318 cygwin*)
 319     VISIBILITY_CFLAGS=""
 320     VISIBILITY_CXXFLAGS=""
 321     ;;
 322 esac
 323
 324 AC_SUBST([VISIBILITY_CFLAGS])
 325 AC_SUBST([VISIBILITY_CXXFLAGS])
 326
 327 dnl
 328 dnl Optional flags, check for compiler support
 329 dnl
 330 SSE41_CFLAGS="-msse4.1"
 331 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 332 dnl stack, but on x86-32 such alignment is not guaranteed.
 333 case "$target_cpu" in
 334 i?86)
 335     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 336     ;;
 337 esac
 338 save_CFLAGS="$CFLAGS"
 339 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 340 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 341 #include <smmintrin.h>
 342 int main () {
 343     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 344     c = _mm_max_epu32(a, b);
 345     return 0;
 346 }]])], SSE41_SUPPORTED=1)
 347 CFLAGS="$save_CFLAGS"
 348 if test "x$SSE41_SUPPORTED" = x1; then
 349     DEFINES="$DEFINES -DUSE_SSE41"
 350 fi
 351 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 352 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 353
 354 dnl Can't have static and shared libraries, default to static if user
 355 dnl explicitly requested. If both disabled, set to static since shared
 356 dnl was explicitly requested.
 357 case "x$enable_static$enable_shared" in
 358 xyesyes)
 359     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 360     enable_shared=no
 361     ;;
 362 xnono)
 363     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 364     enable_shared=yes
 365     ;;
 366 esac
 367
 368 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 369
 370 dnl
 371 dnl other compiler options
 372 dnl
 373 AC_ARG_ENABLE([debug],
 374     [AS_HELP_STRING([--enable-debug],
 375         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 376     [enable_debug="$enableval"],
 377     [enable_debug=no]
 378 )
 379 if test "x$enable_debug" = xyes; then
 380     DEFINES="$DEFINES -DDEBUG"
 381     if test "x$GCC" = xyes; then
 382         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 383             CFLAGS="$CFLAGS -g"
 384         fi
 385         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 386             CFLAGS="$CFLAGS -O0"
 387         fi
 388     fi
 389     if test "x$GXX" = xyes; then
 390         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 391             CXXFLAGS="$CXXFLAGS -g"
 392         fi
 393         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 394             CXXFLAGS="$CXXFLAGS -O0"
 395         fi
 396     fi
 397 else
 398    DEFINES="$DEFINES -DNDEBUG"
 399 fi
 400
 401 dnl
 402 dnl Check if linker supports -Bsymbolic
 403 dnl
 404 save_LDFLAGS=$LDFLAGS
 405 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 406 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 407 AC_LINK_IFELSE(
 408     [AC_LANG_SOURCE([int main() { return 0;}])],
 409     [AC_MSG_RESULT([yes])
 410         BSYMBOLIC="-Wl,-Bsymbolic";],
 411     [AC_MSG_RESULT([no])
 412         BSYMBOLIC="";])
 413 LDFLAGS=$save_LDFLAGS
 414
 415 AC_SUBST([BSYMBOLIC])
 416
 417 dnl
 418 dnl Check if linker supports garbage collection
 419 dnl
 420 save_LDFLAGS=$LDFLAGS
 421 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 422 AC_MSG_CHECKING([whether ld supports --gc-sections])
 423 AC_LINK_IFELSE(
 424     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 425     [AC_MSG_RESULT([yes])
 426         GC_SECTIONS="-Wl,--gc-sections";],
 427     [AC_MSG_RESULT([no])
 428         GC_SECTIONS="";])
 429 LDFLAGS=$save_LDFLAGS
 430
 431 AC_SUBST([GC_SECTIONS])
 432
 433 dnl
 434 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 435 dnl so when these flags are passed to ld via libtool the checks will fail
 436 dnl
 437 case "$host_os" in
 438 openbsd* | darwin* )
 439     LD_NO_UNDEFINED="" ;;
 440 *)
 441     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 442 esac
 443
 444 AC_SUBST([LD_NO_UNDEFINED])
 445
 446 dnl
 447 dnl Check if linker supports version scripts
 448 dnl
 449 AC_MSG_CHECKING([if the linker supports version-scripts])
 450 save_LDFLAGS=$LDFLAGS
 451 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 452 cat > conftest.map <<EOF
 453 VERSION_1 {
 454      global:
 455          main;
 456
 457      local:
 458          *;
 459 };
 460 EOF
 461 AC_LINK_IFELSE(
 462     [AC_LANG_SOURCE([int main() { return 0;}])],
 463     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 464     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 465 LDFLAGS=$save_LDFLAGS
 466 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 467
 468 dnl
 469 dnl Check if linker supports dynamic list files
 470 dnl
 471 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 472 save_LDFLAGS=$LDFLAGS
 473 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 474 cat > conftest.dyn <<EOF
 475 {
 476         radeon_drm_winsys_create;
 477 };
 478 EOF
 479 AC_LINK_IFELSE(
 480     [AC_LANG_SOURCE([int main() { return 0;}])],
 481     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 482     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 483 LDFLAGS=$save_LDFLAGS
 484 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 485
 486 dnl
 487 dnl compatibility symlinks
 488 dnl
 489 case "$host_os" in
 490 linux* )
 491     HAVE_COMPAT_SYMLINKS=yes ;;
 492 * )
 493     HAVE_COMPAT_SYMLINKS=no ;;
 494 esac
 495
 496 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 497
 498 dnl
 499 dnl library names
 500 dnl
 501 case "$host_os" in
 502 darwin* )
 503     LIB_EXT='dylib' ;;
 504 cygwin* )
 505     LIB_EXT='dll' ;;
 506 aix* )
 507     LIB_EXT='a' ;;
 508 * )
 509     LIB_EXT='so' ;;
 510 esac
 511
 512 AC_SUBST([LIB_EXT])
 513
 514 AC_ARG_WITH([gl-lib-name],
 515   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 516     [specify GL library name @<:@default=GL@:>@])],
 517   [GL_LIB=$withval],
 518   [GL_LIB=GL])
 519 AC_ARG_WITH([osmesa-lib-name],
 520   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 521     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 522   [OSMESA_LIB=$withval],
 523   [OSMESA_LIB=OSMesa])
 524 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 525 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 526
 527 dnl
 528 dnl Mangled Mesa support
 529 dnl
 530 AC_ARG_ENABLE([mangling],
 531   [AS_HELP_STRING([--enable-mangling],
 532     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 533   [enable_mangling="${enableval}"],
 534   [enable_mangling=no]
 535 )
 536 if test "x${enable_mangling}" = "xyes" ; then
 537   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 538   GL_LIB="Mangled${GL_LIB}"
 539   OSMESA_LIB="Mangled${OSMESA_LIB}"
 540 fi
 541 AC_SUBST([GL_LIB])
 542 AC_SUBST([OSMESA_LIB])
 543
 544 dnl
 545 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 546 dnl
 547 AC_ARG_ENABLE([texture-float],
 548     [AS_HELP_STRING([--enable-texture-float],
 549         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 550     [enable_texture_float="$enableval"],
 551     [enable_texture_float=no]
 552 )
 553 if test "x$enable_texture_float" = xyes; then
 554     AC_MSG_WARN([Floating-point textures enabled.])
 555     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 556     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 557 fi
 558
 559 dnl
 560 dnl Arch/platform-specific settings
 561 dnl
 562 AC_ARG_ENABLE([asm],
 563     [AS_HELP_STRING([--disable-asm],
 564         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 565     [enable_asm="$enableval"],
 566     [enable_asm=yes]
 567 )
 568 asm_arch=""
 569 AC_MSG_CHECKING([whether to enable assembly])
 570 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 571 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 572 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 573     case "$host_cpu" in
 574     i?86 | x86_64 | amd64)
 575         enable_asm=no
 576         AC_MSG_RESULT([no, cross compiling])
 577         ;;
 578     esac
 579 fi
 580 # check for supported arches
 581 if test "x$enable_asm" = xyes; then
 582     case "$host_cpu" in
 583     i?86)
 584         case "$host_os" in
 585         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 586             asm_arch=x86
 587             ;;
 588         esac
 589         ;;
 590     x86_64|amd64)
 591         case "$host_os" in
 592         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 593             asm_arch=x86_64
 594             ;;
 595         esac
 596         ;;
 597     sparc*)
 598         case "$host_os" in
 599         linux*)
 600             asm_arch=sparc
 601             ;;
 602         esac
 603         ;;
 604     esac
 605
 606     case "$asm_arch" in
 607     x86)
 608         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 609         AC_MSG_RESULT([yes, x86])
 610         ;;
 611     x86_64|amd64)
 612         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 613         AC_MSG_RESULT([yes, x86_64])
 614         ;;
 615     sparc)
 616         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 617         AC_MSG_RESULT([yes, sparc])
 618         ;;
 619     *)
 620         AC_MSG_RESULT([no, platform not supported])
 621         ;;
 622     esac
 623 fi
 624
 625 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 626 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 627
 628 dnl Check to see if dlopen is in default libraries (like Solaris, which
 629 dnl has it in libc), or if libdl is needed to get it.
 630 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 631     [AC_CHECK_LIB([dl], [dlopen],
 632        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 633 AC_SUBST([DLOPEN_LIBS])
 634
 635 dnl Check if that library also has dladdr
 636 save_LIBS="$LIBS"
 637 LIBS="$LIBS $DLOPEN_LIBS"
 638 AC_CHECK_FUNCS([dladdr])
 639 LIBS="$save_LIBS"
 640
 641 case "$host_os" in
 642 darwin*|mingw*)
 643     ;;
 644 *)
 645     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 646                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 647                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 648     AC_SUBST([CLOCK_LIB])
 649     ;;
 650 esac
 651
 652 dnl See if posix_memalign is available
 653 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 654
 655 dnl Check for pthreads
 656 case "$host_os" in
 657 mingw*)
 658     ;;
 659 *)
 660     AX_PTHREAD
 661     if test "x$ax_pthread_ok" = xno; then
 662         AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 663     fi
 664     ;;
 665 esac
 666 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 667 dnl to -pthread, which causes problems if we need -lpthread to appear in
 668 dnl pkgconfig files.
 669 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 670
 671 dnl SELinux awareness.
 672 AC_ARG_ENABLE([selinux],
 673     [AS_HELP_STRING([--enable-selinux],
 674         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 675     [MESA_SELINUX="$enableval"],
 676     [MESA_SELINUX=no])
 677 if test "x$enable_selinux" = "xyes"; then
 678     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 679         [AC_CHECK_HEADER([selinux/selinux.h],[],
 680                          [AC_MSG_ERROR([SELinux headers not found])])
 681          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 682                       [AC_MSG_ERROR([SELinux library not found])])
 683          SELINUX_LIBS="-lselinux"])
 684     DEFINES="$DEFINES -DMESA_SELINUX"
 685 fi
 686 AC_SUBST([SELINUX_CFLAGS])
 687 AC_SUBST([SELINUX_LIBS])
 688
 689 dnl Options for APIs
 690 AC_ARG_ENABLE([opengl],
 691     [AS_HELP_STRING([--disable-opengl],
 692         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 693     [enable_opengl="$enableval"],
 694     [enable_opengl=yes])
 695 AC_ARG_ENABLE([gles1],
 696     [AS_HELP_STRING([--enable-gles1],
 697         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 698     [enable_gles1="$enableval"],
 699     [enable_gles1=no])
 700 AC_ARG_ENABLE([gles2],
 701     [AS_HELP_STRING([--enable-gles2],
 702         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 703     [enable_gles2="$enableval"],
 704     [enable_gles2=no])
 705
 706 AC_ARG_ENABLE([dri],
 707     [AS_HELP_STRING([--enable-dri],
 708         [enable DRI modules @<:@default=enabled@:>@])],
 709     [enable_dri="$enableval"],
 710     [enable_dri=yes])
 711
 712 case "$host_os" in
 713 linux*)
 714     dri3_default=yes
 715     ;;
 716 *)
 717     dri3_default=no
 718     ;;
 719 esac
 720 AC_ARG_ENABLE([dri3],
 721     [AS_HELP_STRING([--enable-dri3],
 722         [enable DRI3 @<:@default=auto@:>@])],
 723     [enable_dri3="$enableval"],
 724     [enable_dri3="$dri3_default"])
 725 AC_ARG_ENABLE([glx],
 726     [AS_HELP_STRING([--enable-glx],
 727         [enable GLX library @<:@default=enabled@:>@])],
 728     [enable_glx="$enableval"],
 729     [enable_glx=yes])
 730 AC_ARG_ENABLE([osmesa],
 731     [AS_HELP_STRING([--enable-osmesa],
 732         [enable OSMesa library @<:@default=disabled@:>@])],
 733     [enable_osmesa="$enableval"],
 734     [enable_osmesa=no])
 735 AC_ARG_ENABLE([gallium-osmesa],
 736     [AS_HELP_STRING([--enable-gallium-osmesa],
 737         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 738     [enable_gallium_osmesa="$enableval"],
 739     [enable_gallium_osmesa=no])
 740 AC_ARG_ENABLE([egl],
 741     [AS_HELP_STRING([--disable-egl],
 742         [disable EGL library @<:@default=enabled@:>@])],
 743     [enable_egl="$enableval"],
 744     [enable_egl=yes])
 745
 746 AC_ARG_ENABLE([xa],
 747     [AS_HELP_STRING([--enable-xa],
 748         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 749     [enable_xa="$enableval"],
 750     [enable_xa=no])
 751 AC_ARG_ENABLE([gbm],
 752    [AS_HELP_STRING([--enable-gbm],
 753          [enable gbm library @<:@default=auto@:>@])],
 754    [enable_gbm="$enableval"],
 755    [enable_gbm=auto])
 756 AC_ARG_ENABLE([nine],
 757     [AS_HELP_STRING([--enable-nine],
 758         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 759     [enable_nine="$enableval"],
 760     [enable_nine=no])
 761
 762 AC_ARG_ENABLE([xvmc],
 763    [AS_HELP_STRING([--enable-xvmc],
 764          [enable xvmc library @<:@default=auto@:>@])],
 765    [enable_xvmc="$enableval"],
 766    [enable_xvmc=auto])
 767 AC_ARG_ENABLE([vdpau],
 768    [AS_HELP_STRING([--enable-vdpau],
 769          [enable vdpau library @<:@default=auto@:>@])],
 770    [enable_vdpau="$enableval"],
 771    [enable_vdpau=auto])
 772 AC_ARG_ENABLE([omx],
 773    [AS_HELP_STRING([--enable-omx],
 774          [enable OpenMAX library @<:@default=disabled@:>@])],
 775    [enable_omx="$enableval"],
 776    [enable_omx=no])
 777 AC_ARG_ENABLE([va],
 778    [AS_HELP_STRING([--enable-va],
 779          [enable va library @<:@default=auto@:>@])],
 780    [enable_va="$enableval"],
 781    [enable_va=auto])
 782 AC_ARG_ENABLE([opencl],
 783    [AS_HELP_STRING([--enable-opencl],
 784          [enable OpenCL library @<:@default=disabled@:>@])],
 785    [enable_opencl="$enableval"],
 786    [enable_opencl=no])
 787 AC_ARG_ENABLE([opencl_icd],
 788    [AS_HELP_STRING([--enable-opencl-icd],
 789           [Build an OpenCL ICD library to be loaded by an ICD implementation
 790            @<:@default=disabled@:>@])],
 791     [enable_opencl_icd="$enableval"],
 792     [enable_opencl_icd=no])
 793 AC_ARG_ENABLE([xlib-glx],
 794     [AS_HELP_STRING([--enable-xlib-glx],
 795         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 796     [enable_xlib_glx="$enableval"],
 797     [enable_xlib_glx=no])
 798
 799 AC_ARG_ENABLE([r600-llvm-compiler],
 800     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 801         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 802     [enable_r600_llvm="$enableval"],
 803     [enable_r600_llvm=no])
 804
 805 AC_ARG_ENABLE([gallium-tests],
 806     [AS_HELP_STRING([--enable-gallium-tests],
 807         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 808     [enable_gallium_tests="$enableval"],
 809     [enable_gallium_tests=no])
 810
 811 # Option for Gallium drivers
 812
 813 # Keep this in sync with the --with-gallium-drivers help string default value
 814 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 815
 816 AC_ARG_WITH([gallium-drivers],
 817     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 818         [comma delimited Gallium drivers list, e.g.
 819         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 820         @<:@default=r300,r600,svga,swrast@:>@])],
 821     [with_gallium_drivers="$withval"],
 822     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 823
 824 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 825 # here so that the script doesn't choke on an unknown driver name later.
 826 case "$with_gallium_drivers" in
 827     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 828     no) with_gallium_drivers='' ;;
 829 esac
 830
 831 if test "x$enable_opengl" = xno -a \
 832         "x$enable_gles1" = xno -a \
 833         "x$enable_gles2" = xno -a \
 834         "x$enable_nine" = xno -a \
 835         "x$enable_xa" = xno -a \
 836         "x$enable_xvmc" = xno -a \
 837         "x$enable_vdpau" = xno -a \
 838         "x$enable_omx" = xno -a \
 839         "x$enable_va" = xno -a \
 840         "x$enable_opencl" = xno; then
 841     AC_MSG_ERROR([at least one API should be enabled])
 842 fi
 843
 844 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 845 if test "x$enable_opengl" = xno -a \
 846         "x$enable_gles1" = xyes; then
 847     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 848 fi
 849
 850 if test "x$enable_opengl" = xno -a \
 851         "x$enable_gles2" = xyes; then
 852     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 853 fi
 854
 855 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 856 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 857 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 858 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 859                                         "x$enable_gles1" = xyes -o \
 860                                         "x$enable_gles2" = xyes)
 861
 862 if test "x$enable_glx" = xno; then
 863     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 864     enable_xlib_glx=no
 865 fi
 866
 867 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 868     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 869 fi
 870
 871 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 872     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 873 fi
 874
 875 # Disable GLX if OpenGL is not enabled
 876 if test "x$enable_glx$enable_opengl" = xyesno; then
 877     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 878     enable_glx=no
 879 fi
 880
 881 # Disable GLX if DRI and Xlib-GLX are not enabled
 882 if test "x$enable_glx" = xyes -a \
 883         "x$enable_dri" = xno -a \
 884         "x$enable_xlib_glx" = xno; then
 885     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 886     enable_glx=no
 887 fi
 888
 889 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 890                                   "x$enable_dri" = xyes)
 891
 892 # Select which platform-dependent DRI code gets built
 893 case "$host_os" in
 894 darwin*)
 895     dri_platform='apple' ;;
 896 gnu*|mingw*|cygwin*)
 897     dri_platform='none' ;;
 898 *)
 899     dri_platform='drm' ;;
 900 esac
 901
 902 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 903 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 904 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 905 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 906 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 907
 908 AC_ARG_ENABLE([shared-glapi],
 909     [AS_HELP_STRING([--enable-shared-glapi],
 910         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 911     [enable_shared_glapi="$enableval"],
 912     [enable_shared_glapi=yes])
 913
 914 case "x$enable_opengl$enable_gles1$enable_gles2" in
 915 x*yes*yes*)
 916     if test "x$enable_shared_glapi" = xno; then
 917         AC_MSG_ERROR([shared GLAPI required when building two or more of
 918                       the following APIs - opengl, gles1 gles2])
 919     fi
 920     ;;
 921 esac
 922
 923 # Building Xlib-GLX requires shared glapi to be disabled.
 924 if test "x$enable_xlib_glx" = xyes; then
 925     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 926     enable_shared_glapi=no
 927 fi
 928
 929 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 930
 931 # Build the pipe-drivers as separate libraries/modules.
 932 # Do not touch this unless you know what you are doing.
 933 # XXX: Expose via configure option ?
 934 enable_shared_pipe_drivers=no
 935
 936 dnl
 937 dnl Driver specific build directories
 938 dnl
 939
 940 case "x$enable_glx$enable_xlib_glx" in
 941 xyesyes)
 942     NEED_WINSYS_XLIB="yes"
 943     ;;
 944 esac
 945
 946 if test "x$enable_dri" = xyes; then
 947     enable_gallium_loader="$enable_shared_pipe_drivers"
 948 fi
 949
 950 if test "x$enable_gallium_osmesa" = xyes; then
 951     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 952         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 953     fi
 954     if test "x$enable_osmesa" = xyes; then
 955         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 956     fi
 957 fi
 958
 959 AC_SUBST([MESA_LLVM])
 960
 961 # SHA1 hashing
 962 AC_ARG_WITH([sha1],
 963         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 964         [choose SHA1 implementation])])
 965 case "x$with_sha1" in
 966 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 967   ;;
 968 *)
 969         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 970 esac
 971
 972 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 973 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 974         with_sha1=libc
 975 fi
 976 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 977         AC_MSG_ERROR([sha1 in libc requested but not found])
 978 fi
 979 if test "x$with_sha1" = xlibc; then
 980         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 981                 [Use libc SHA1 functions])
 982         SHA1_LIBS=""
 983 fi
 984 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 985 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 986         with_sha1=CommonCrypto
 987 fi
 988 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
 989         AC_MSG_ERROR([CommonCrypto requested but not found])
 990 fi
 991 if test "x$with_sha1" = xCommonCrypto; then
 992         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
 993                 [Use CommonCrypto SHA1 functions])
 994         SHA1_LIBS=""
 995 fi
 996 dnl stdcall functions cannot be tested with AC_CHECK_LIB
 997 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
 998 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
 999         with_sha1=CryptoAPI
1000 fi
1001 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1002         AC_MSG_ERROR([CryptoAPI requested but not found])
1003 fi
1004 if test "x$with_sha1" = xCryptoAPI; then
1005         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1006                 [Use CryptoAPI SHA1 functions])
1007         SHA1_LIBS=""
1008 fi
1009 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1010 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1011         with_sha1=libmd
1012 fi
1013 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1014         AC_MSG_ERROR([libmd requested but not found])
1015 fi
1016 if test "x$with_sha1" = xlibmd; then
1017         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1018                   [Use libmd SHA1 functions])
1019         SHA1_LIBS=-lmd
1020 fi
1021 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1022 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1023    with_sha1=libsha1
1024 fi
1025 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1026         AC_MSG_ERROR([libsha1 requested but not found])
1027 fi
1028 if test "x$with_sha1" = xlibsha1; then
1029         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1030                   [Use libsha1 for SHA1])
1031         SHA1_LIBS=-lsha1
1032 fi
1033 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1034 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1035         with_sha1=libnettle
1036 fi
1037 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1038         AC_MSG_ERROR([libnettle requested but not found])
1039 fi
1040 if test "x$with_sha1" = xlibnettle; then
1041         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1042                   [Use libnettle SHA1 functions])
1043         SHA1_LIBS=-lnettle
1044 fi
1045 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1046 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1047         with_sha1=libgcrypt
1048 fi
1049 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1050         AC_MSG_ERROR([libgcrypt requested but not found])
1051 fi
1052 if test "x$with_sha1" = xlibgcrypt; then
1053         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1054                   [Use libgcrypt SHA1 functions])
1055         SHA1_LIBS=-lgcrypt
1056 fi
1057 # We don't need all of the OpenSSL libraries, just libcrypto
1058 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1059 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1060                   [HAVE_OPENSSL_PKC=no])
1061 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1062         if test "x$with_sha1" = x; then
1063                 with_sha1=libcrypto
1064         fi
1065 else
1066         if test "x$with_sha1" = xlibcrypto; then
1067                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1068         fi
1069 fi
1070 if test "x$with_sha1" = xlibcrypto; then
1071         if test "x$HAVE_LIBCRYPTO" = xyes; then
1072                 SHA1_LIBS=-lcrypto
1073         else
1074                 SHA1_LIBS="$OPENSSL_LIBS"
1075                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1076         fi
1077 fi
1078 AC_MSG_CHECKING([for SHA1 implementation])
1079 AC_MSG_RESULT([$with_sha1])
1080 AC_SUBST(SHA1_LIBS)
1081 AC_SUBST(SHA1_CFLAGS)
1082
1083 # Allow user to configure out the shader-cache feature
1084 AC_ARG_ENABLE([shader-cache],
1085     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1086     [enable_shader_cache="$enableval"],
1087     [if test "x$with_sha1" != "x"; then
1088         enable_shader_cache=yes
1089      else
1090         enable_shader_cache=no
1091      fi])
1092 if test "x$with_sha1" = "x"; then
1093     if test "x$enable_shader_cache" = "xyes"; then
1094         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1095     fi
1096 fi
1097 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1098
1099 # Check for libdrm
1100 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1101                   [have_libdrm=yes], [have_libdrm=no])
1102 if test "x$have_libdrm" = xyes; then
1103         DEFINES="$DEFINES -DHAVE_LIBDRM"
1104 fi
1105
1106 case "$host_os" in
1107 linux*)
1108     need_pci_id=yes ;;
1109 *)
1110     need_pci_id=no ;;
1111 esac
1112
1113 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1114                   have_libudev=yes, have_libudev=no)
1115
1116 AC_ARG_ENABLE([sysfs],
1117     [AS_HELP_STRING([--enable-sysfs],
1118         [enable /sys PCI identification @<:@default=disabled@:>@])],
1119     [have_sysfs="$enableval"],
1120     [have_sysfs=no]
1121 )
1122
1123 if test "x$enable_dri" = xyes; then
1124     if test "$enable_static" = yes; then
1125         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1126     fi
1127
1128     # not a hard requirement as swrast does not depend on it
1129     if test "x$have_libdrm" = xyes; then
1130         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1131     fi
1132 fi
1133
1134 AC_ARG_ENABLE([driglx-direct],
1135     [AS_HELP_STRING([--disable-driglx-direct],
1136         [disable direct rendering in GLX and EGL for DRI \
1137             @<:@default=auto@:>@])],
1138     [driglx_direct="$enableval"],
1139     [driglx_direct="yes"])
1140
1141 dnl
1142 dnl libGL configuration per driver
1143 dnl
1144 case "x$enable_glx$enable_xlib_glx" in
1145 xyesyes)
1146     # Xlib-based GLX
1147     dri_modules="x11 xext xcb"
1148     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1149     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1150     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1151     GL_LIB_DEPS="$XLIBGL_LIBS"
1152     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1153     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1154     ;;
1155 xyesno)
1156     # DRI-based GLX
1157     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1158
1159     # find the DRI deps for libGL
1160     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1161
1162     if test x"$driglx_direct" = xyes; then
1163         if test x"$dri_platform" = xdrm ; then
1164             DEFINES="$DEFINES -DGLX_USE_DRM"
1165             if test "x$have_libdrm" != xyes; then
1166                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1167             fi
1168
1169             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1170             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1171             if test x"$enable_dri3" = xyes; then
1172                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1173                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1174             fi
1175
1176             if test x"$enable_dri" = xyes; then
1177                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1178             fi
1179
1180             if test x"$enable_dri3" = xyes; then
1181                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1182                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1183             fi
1184         fi
1185         if test x"$dri_platform" = xapple ; then
1186             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1187         fi
1188     fi
1189
1190     # add xf86vidmode if available
1191     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1192     if test "$HAVE_XF86VIDMODE" = yes ; then
1193         dri_modules="$dri_modules xxf86vm"
1194     fi
1195
1196     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1197     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1198     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1199     GL_LIB_DEPS="$DRIGL_LIBS"
1200
1201     # need DRM libs, $PTHREAD_LIBS, etc.
1202     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1203     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1204     ;;
1205 esac
1206
1207 have_pci_id=no
1208 if test "$have_libudev" = yes; then
1209     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1210     have_pci_id=yes
1211 fi
1212
1213 if test "$have_sysfs" = yes; then
1214     DEFINES="$DEFINES -DHAVE_SYSFS"
1215     have_pci_id=yes
1216 fi
1217
1218 # This is outside the case (above) so that it is invoked even for non-GLX
1219 # builds.
1220 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1221
1222 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1223 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1224 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1225 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1226
1227 AC_SUBST([X11_INCLUDES])
1228 AC_SUBST([GL_LIB_DEPS])
1229 AC_SUBST([GL_PC_REQ_PRIV])
1230 AC_SUBST([GL_PC_LIB_PRIV])
1231 AC_SUBST([GL_PC_CFLAGS])
1232 AC_SUBST([DRI_PC_REQ_PRIV])
1233 AC_SUBST([GLESv1_CM_LIB_DEPS])
1234 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1235 AC_SUBST([GLESv2_LIB_DEPS])
1236 AC_SUBST([GLESv2_PC_LIB_PRIV])
1237
1238 AC_SUBST([HAVE_XF86VIDMODE])
1239
1240 dnl
1241 dnl More GLX setup
1242 dnl
1243 case "x$enable_glx$enable_xlib_glx" in
1244 xyesyes)
1245     DEFINES="$DEFINES -DUSE_XSHM"
1246     ;;
1247 xyesno)
1248     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1249     if test "x$driglx_direct" = xyes; then
1250         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1251     fi
1252     ;;
1253 esac
1254
1255 dnl
1256 dnl TLS detection
1257 dnl
1258
1259 AC_ARG_ENABLE([glx-tls],
1260     [AS_HELP_STRING([--enable-glx-tls],
1261         [enable TLS support in GLX @<:@default=disabled@:>@])],
1262     [GLX_USE_TLS="$enableval"],
1263     [GLX_USE_TLS=no])
1264 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1265
1266 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1267       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1268
1269 dnl
1270 dnl More DRI setup
1271 dnl
1272 dnl Directory for DRI drivers
1273 AC_ARG_WITH([dri-driverdir],
1274     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1275         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1276     [DRI_DRIVER_INSTALL_DIR="$withval"],
1277     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1278 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1279 dnl Extra search path for DRI drivers
1280 AC_ARG_WITH([dri-searchpath],
1281     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1282         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1283     [DRI_DRIVER_SEARCH_DIR="$withval"],
1284     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1285 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1286 dnl Which drivers to build - default is chosen by platform
1287 AC_ARG_WITH([dri-drivers],
1288     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1289         [comma delimited classic DRI drivers list, e.g.
1290         "swrast,i965,radeon" @<:@default=auto@:>@])],
1291     [with_dri_drivers="$withval"],
1292     [with_dri_drivers=auto])
1293
1294 if test "x$with_dri_drivers" = xauto; then
1295     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1296         with_dri_drivers="yes"
1297     else
1298         with_dri_drivers="no"
1299     fi
1300 fi
1301 if test "x$with_dri_drivers" = xno; then
1302     with_dri_drivers=''
1303 fi
1304
1305 dnl If $with_dri_drivers is yes, drivers will be added through
1306 dnl platform checks. Set DEFINES and LIB_DEPS
1307 if test "x$enable_dri" = xyes; then
1308     # Platform specific settings and drivers to build
1309     case "$host_os" in
1310     linux*)
1311         DEFINES="$DEFINES -DHAVE_ALIAS"
1312         if test "x$enable_dri3" = xyes; then
1313             DEFINES="$DEFINES -DHAVE_DRI3"
1314         fi
1315
1316         if test "x$have_pci_id" != xyes; then
1317             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1318         fi
1319
1320         case "$host_cpu" in
1321         powerpc* | sparc*)
1322             # Build only the drivers for cards that exist on PowerPC/sparc
1323             if test "x$with_dri_drivers" = "xyes"; then
1324                 with_dri_drivers="r200 radeon swrast"
1325             fi
1326             ;;
1327         esac
1328         ;;
1329     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1330         DEFINES="$DEFINES -DHAVE_ALIAS"
1331         ;;
1332     gnu*)
1333         DEFINES="$DEFINES -DHAVE_ALIAS"
1334         ;;
1335     cygwin*)
1336         if test "x$with_dri_drivers" = "xyes"; then
1337             with_dri_drivers="swrast"
1338         fi
1339         ;;
1340     darwin*)
1341         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1342         if test "x$with_dri_drivers" = "xyes"; then
1343             with_dri_drivers="swrast"
1344         fi
1345         ;;
1346     esac
1347
1348     # default drivers
1349     if test "x$with_dri_drivers" = "xyes"; then
1350         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1351     fi
1352
1353     # Check for expat
1354     PKG_CHECK_MODULES([EXPAT], [expat], [],
1355         # expat version 2.0 and earlier do not provide expat.pc
1356         [AC_CHECK_HEADER([expat.h],[],
1357                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1358          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1359                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1360          EXPAT_LIBS="-lexpat"])
1361
1362     DRICOMMON_NEED_LIBDRM=no
1363     # If we are building any DRI driver other than swrast.
1364     if test -n "$with_dri_drivers"; then
1365         if test "x$with_dri_drivers" != xswrast; then
1366             # ... libdrm is required
1367             if test "x$have_libdrm" != xyes; then
1368                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1369             fi
1370             DRICOMMON_NEED_LIBDRM=yes
1371         fi
1372     fi
1373
1374     # If we're building any gallium DRI driver other than swrast
1375     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1376         if test "x$with_gallium_drivers" != xswrast; then
1377             # ... build a libdrm aware dricommon
1378             DRICOMMON_NEED_LIBDRM=yes
1379         fi
1380     fi
1381
1382     # put all the necessary libs together
1383     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1384 fi
1385
1386 AC_SUBST([DRI_LIB_DEPS])
1387
1388 DRI_DIRS=''
1389 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1390 if test -n "$with_dri_drivers"; then
1391     if test "x$enable_opengl" != xyes; then
1392         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1393     fi
1394
1395     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1396     for driver in $dri_drivers; do
1397         DRI_DIRS="$DRI_DIRS $driver"
1398         case "x$driver" in
1399         xi915)
1400             HAVE_I915_DRI=yes;
1401             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1402             ;;
1403         xi965)
1404             HAVE_I965_DRI=yes;
1405             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1406             ;;
1407         xnouveau)
1408             HAVE_NOUVEAU_DRI=yes;
1409             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1410             ;;
1411         xradeon)
1412             HAVE_RADEON_DRI=yes;
1413             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1414             ;;
1415         xr200)
1416             HAVE_R200_DRI=yes;
1417             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1418             ;;
1419         xswrast)
1420             HAVE_SWRAST_DRI=yes;
1421             ;;
1422         *)
1423             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1424             ;;
1425         esac
1426     done
1427     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1428 fi
1429
1430 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1431 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1432                                   "x$enable_osmesa" = xyes -o \
1433                                   -n "$DRI_DIRS")
1434
1435 dnl
1436 dnl OSMesa configuration
1437 dnl
1438
1439 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1440 AC_ARG_WITH([osmesa-bits],
1441     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1442         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1443     [osmesa_bits="$withval"],
1444     [osmesa_bits=8])
1445 if test "x$osmesa_bits" != x8; then
1446     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1447         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1448         osmesa_bits=8
1449     fi
1450 fi
1451 case "x$osmesa_bits" in
1452 x8)
1453     OSMESA_LIB="${OSMESA_LIB}"
1454     ;;
1455 x16|x32)
1456     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1457     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1458     ;;
1459 *)
1460     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1461     ;;
1462 esac
1463
1464 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1465     # only link libraries with osmesa if shared
1466     if test "$enable_static" = no; then
1467         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1468     else
1469         OSMESA_LIB_DEPS=""
1470     fi
1471     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1472 fi
1473
1474 AC_SUBST([OSMESA_LIB_DEPS])
1475 AC_SUBST([OSMESA_PC_REQ])
1476 AC_SUBST([OSMESA_PC_LIB_PRIV])
1477
1478 dnl
1479 dnl gbm configuration
1480 dnl
1481 if test "x$enable_gbm" = xauto; then
1482     case "$with_egl_platforms" in
1483         *drm*)
1484             enable_gbm=yes ;;
1485          *)
1486             enable_gbm=no ;;
1487     esac
1488 fi
1489 if test "x$enable_gbm" = xyes; then
1490     if test "x$need_pci_id$have_pci_id" = xyesno; then
1491         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1492     fi
1493
1494     if test "x$enable_dri" = xyes; then
1495         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1496         if test "x$enable_shared_glapi" = xno; then
1497             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1498         fi
1499     else
1500         # Strictly speaking libgbm does not require --enable-dri, although
1501         # both of its backends do. Thus one can build libgbm without any
1502         # backends if --disable-dri is set.
1503         # To avoid unnecessary complexity of checking if at least one backend
1504         # is available when building, just mandate --enable-dri.
1505         AC_MSG_ERROR([gbm requires --enable-dri])
1506     fi
1507 fi
1508 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1509 if test "x$need_pci_id$have_libudev" = xyesyes; then
1510     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1511 else
1512     GBM_PC_REQ_PRIV=""
1513 fi
1514 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1515 AC_SUBST([GBM_PC_REQ_PRIV])
1516 AC_SUBST([GBM_PC_LIB_PRIV])
1517
1518 dnl
1519 dnl EGL configuration
1520 dnl
1521 EGL_CLIENT_APIS=""
1522
1523 if test "x$enable_egl" = xyes; then
1524     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1525
1526     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1527
1528     if test "$enable_static" != yes; then
1529         if test "x$enable_dri" = xyes; then
1530             HAVE_EGL_DRIVER_DRI2=1
1531         fi
1532
1533     fi
1534 fi
1535 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1536 AC_SUBST([EGL_LIB_DEPS])
1537
1538 dnl
1539 dnl XA configuration
1540 dnl
1541 if test "x$enable_xa" = xyes; then
1542     if test "x$with_gallium_drivers" = xswrast; then
1543        AC_MSG_ERROR([
1544           Building xa requires at least one non swrast gallium driver.
1545           If you are looking to use libxatracker.so with the VMware driver,
1546           make sure to include svga in the gallium drivers list, apart from
1547           enabling XA.
1548           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1549     fi
1550     enable_gallium_loader=$enable_shared_pipe_drivers
1551 fi
1552 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1553
1554 dnl
1555 dnl Gallium G3DVL configuration
1556 dnl
1557 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1558     if test "x$enable_xvmc" = xauto; then
1559         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1560     fi
1561
1562     if test "x$enable_vdpau" = xauto; then
1563         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1564     fi
1565
1566     if test "x$enable_omx" = xauto; then
1567         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1568     fi
1569
1570     if test "x$enable_va" = xauto; then
1571         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1572     fi
1573 fi
1574
1575 if test "x$enable_dri" = xyes -o \
1576         "x$enable_xvmc" = xyes -o \
1577         "x$enable_vdpau" = xyes -o \
1578         "x$enable_omx" = xyes -o \
1579         "x$enable_va" = xyes; then
1580     need_gallium_vl=yes
1581 fi
1582 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1583
1584 if test "x$enable_xvmc" = xyes -o \
1585         "x$enable_vdpau" = xyes -o \
1586         "x$enable_omx" = xyes -o \
1587         "x$enable_va" = xyes; then
1588     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1589     need_gallium_vl_winsys=yes
1590 fi
1591 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1592
1593 if test "x$enable_xvmc" = xyes; then
1594     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1595     enable_gallium_loader=$enable_shared_pipe_drivers
1596 fi
1597 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1598
1599 if test "x$enable_vdpau" = xyes; then
1600     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1601     enable_gallium_loader=$enable_shared_pipe_drivers
1602 fi
1603 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1604
1605 if test "x$enable_omx" = xyes; then
1606     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1607     enable_gallium_loader=$enable_shared_pipe_drivers
1608 fi
1609 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1610
1611 if test "x$enable_va" = xyes; then
1612     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1613     enable_gallium_loader=$enable_shared_pipe_drivers
1614 fi
1615 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1616
1617 dnl
1618 dnl Nine Direct3D9 configuration
1619 dnl
1620 if test "x$enable_nine" = xyes; then
1621     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1622         AC_MSG_ERROR([nine requires the gallium swrast driver])
1623     fi
1624     if test "x$with_gallium_drivers" == xswrast; then
1625         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1626     fi
1627     if test "x$enable_dri3" = xno; then
1628         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1629     fi
1630
1631     enable_gallium_loader=$enable_shared_pipe_drivers
1632 fi
1633 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1634
1635 dnl
1636 dnl OpenCL configuration
1637 dnl
1638
1639 AC_ARG_WITH([libclc-path],
1640    [AS_HELP_STRING([--with-libclc-path],
1641          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1642    [LIBCLC_PATH="$withval"],
1643    [LIBCLC_PATH=''])
1644
1645 if test -n "$LIBCLC_PATH"; then
1646    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1647                   Please review the updated build instructions for clover:
1648                   http://dri.freedesktop.org/wiki/GalliumCompute])
1649 fi
1650
1651
1652 AC_ARG_WITH([clang-libdir],
1653    [AS_HELP_STRING([--with-clang-libdir],
1654          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1655    [CLANG_LIBDIR="$withval"],
1656    [CLANG_LIBDIR=''])
1657
1658 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1659 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1660
1661 if test "x$enable_opencl" = xyes; then
1662     if test -z "$with_gallium_drivers"; then
1663         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1664     fi
1665
1666     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1667         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1668     fi
1669
1670     if test "x$have_libclc" = xno; then
1671         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1672                     Make sure the directory containing libclc.pc is specified in your
1673                     PKG_CONFIG_PATH environment variable.
1674                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1675     else
1676         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1677         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1678         AC_SUBST([LIBCLC_INCLUDEDIR])
1679         AC_SUBST([LIBCLC_LIBEXECDIR])
1680     fi
1681
1682     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1683     enable_gallium_loader=yes
1684
1685     if test "x$enable_opencl_icd" = xyes; then
1686         OPENCL_LIBNAME="MesaOpenCL"
1687     else
1688         OPENCL_LIBNAME="OpenCL"
1689     fi
1690
1691     if test "x$have_libelf" != xyes; then
1692        AC_MSG_ERROR([Clover requires libelf])
1693     fi
1694 fi
1695 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1696 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1697 AC_SUBST([OPENCL_LIBNAME])
1698
1699 dnl
1700 dnl Gallium configuration
1701 dnl
1702 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1703
1704 AC_SUBST([LLVM_BINDIR])
1705 AC_SUBST([LLVM_CFLAGS])
1706 AC_SUBST([LLVM_CPPFLAGS])
1707 AC_SUBST([LLVM_CXXFLAGS])
1708 AC_SUBST([LLVM_LIBDIR])
1709 AC_SUBST([LLVM_LIBS])
1710 AC_SUBST([LLVM_LDFLAGS])
1711 AC_SUBST([LLVM_INCLUDEDIR])
1712 AC_SUBST([LLVM_VERSION])
1713 AC_SUBST([CLANG_RESOURCE_DIR])
1714
1715 case "x$enable_opengl$enable_gles1$enable_gles2" in
1716 x*yes*)
1717     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1718     ;;
1719 esac
1720
1721 AC_SUBST([VG_LIB_DEPS])
1722 AC_SUBST([EGL_CLIENT_APIS])
1723
1724 dnl
1725 dnl EGL Platforms configuration
1726 dnl
1727 AC_ARG_WITH([egl-platforms],
1728     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1729         [comma delimited native platforms libEGL supports, e.g.
1730         "x11,drm" @<:@default=auto@:>@])],
1731     [with_egl_platforms="$withval"],
1732     [if test "x$enable_egl" = xyes; then
1733         with_egl_platforms="x11"
1734     else
1735         with_egl_platforms=""
1736     fi])
1737
1738 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1739     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1740 fi
1741
1742 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1743         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1744         WAYLAND_SCANNER='')
1745 if test "x$WAYLAND_SCANNER" = x; then
1746     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1747 fi
1748
1749 # Do per-EGL platform setups and checks
1750 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1751 for plat in $egl_platforms; do
1752         case "$plat" in
1753         wayland)
1754                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1755
1756                 if test "x$WAYLAND_SCANNER" = x; then
1757                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1758                 fi
1759                 ;;
1760
1761         x11)
1762                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1763                 ;;
1764
1765         drm)
1766                 test "x$enable_gbm" = "xno" &&
1767                         AC_MSG_ERROR([EGL platform drm needs gbm])
1768                 test "x$have_libdrm" != xyes &&
1769                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1770                 ;;
1771
1772         android|fbdev|gdi|null)
1773                 ;;
1774
1775         *)
1776                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1777                 ;;
1778         esac
1779
1780         case "$plat$need_pci_id$have_pci_id" in
1781                 waylandyesno|drmyesno)
1782                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1783         esac
1784 done
1785
1786 # libEGL wants to default to the first platform specified in
1787 # ./configure.  parse that here.
1788 if test "x$egl_platforms" != "x"; then
1789     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1790     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1791 else
1792     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1793 fi
1794
1795 if echo "$egl_platforms" | grep -q 'x11'; then
1796     NEED_WINSYS_XLIB=yes
1797 fi
1798 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1799 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1800 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1801 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1802 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1803
1804 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1805
1806 AC_SUBST([EGL_NATIVE_PLATFORM])
1807 AC_SUBST([EGL_CFLAGS])
1808
1809 # If we don't have the X11 platform, set this define so we don't try to include
1810 # the X11 headers.
1811 if ! echo "$egl_platforms" | grep -q 'x11'; then
1812     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1813     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1814 fi
1815
1816 AC_ARG_WITH([max-width],
1817     [AS_HELP_STRING([--with-max-width=N],
1818                     [Maximum framebuffer width (4096)])],
1819     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1820      AS_IF([test "${withval}" -gt "4096"],
1821            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1822 )
1823 AC_ARG_WITH([max-height],
1824     [AS_HELP_STRING([--with-max-height=N],
1825                     [Maximum framebuffer height (4096)])],
1826     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1827      AS_IF([test "${withval}" -gt "4096"],
1828            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1829 )
1830
1831 dnl
1832 dnl Gallium LLVM
1833 dnl
1834 AC_ARG_ENABLE([gallium-llvm],
1835     [AS_HELP_STRING([--enable-gallium-llvm],
1836         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1837     [enable_gallium_llvm="$enableval"],
1838     [enable_gallium_llvm=auto])
1839
1840 AC_ARG_ENABLE([llvm-shared-libs],
1841     [AS_HELP_STRING([--enable-llvm-shared-libs],
1842         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1843     [enable_llvm_shared_libs="$enableval"],
1844     [enable_llvm_shared_libs=yes])
1845
1846 AC_ARG_WITH([llvm-prefix],
1847     [AS_HELP_STRING([--with-llvm-prefix],
1848         [Prefix for LLVM installations in non-standard locations])],
1849     [llvm_prefix="$withval"],
1850     [llvm_prefix=''])
1851
1852
1853 # Call this inside ` ` to get the return value.
1854 # $1 is the llvm-config command with arguments.
1855 strip_unwanted_llvm_flags() {
1856     # Use \> (marks the end of the word)
1857     echo `$1` | sed \
1858         -e 's/-DNDEBUG\>//g' \
1859         -e 's/-D_GNU_SOURCE\>//g' \
1860         -e 's/-pedantic\>//g' \
1861         -e 's/-Wcovered-switch-default\>//g' \
1862         -e 's/-O.\>//g' \
1863         -e 's/-g\>//g' \
1864         -e 's/-Wall\>//g' \
1865         -e 's/-Wcast-qual\>//g' \
1866         -e 's/-Woverloaded-virtual\>//g' \
1867         -e 's/-fcolor-diagnostics\>//g' \
1868         -e 's/-fdata-sections\>//g' \
1869         -e 's/-ffunction-sections\>//g' \
1870         -e 's/-fno-exceptions\>//g' \
1871         -e 's/-fomit-frame-pointer\>//g' \
1872         -e 's/-fvisibility-inlines-hidden\>//g' \
1873         -e 's/-fPIC\>//g' \
1874         -e 's/-fstack-protector-strong\>//g'
1875 }
1876
1877
1878 if test -z "$with_gallium_drivers"; then
1879     enable_gallium_llvm=no
1880 fi
1881 if test "x$enable_gallium_llvm" = xauto; then
1882     case "$host_cpu" in
1883     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1884     esac
1885 fi
1886 if test "x$enable_gallium_llvm" = xyes; then
1887     if test -n "$llvm_prefix"; then
1888         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1889     else
1890         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1891     fi
1892
1893     if test "x$LLVM_CONFIG" != xno; then
1894         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1895         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1896         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1897         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1898         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1899         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1900         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1901         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1902
1903         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1904             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1905         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1906             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1907
1908         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1909         if test -z "$LLVM_VERSION_PATCH"; then
1910             LLVM_VERSION_PATCH=0
1911         fi
1912
1913         if test -n "${LLVM_VERSION_MAJOR}"; then
1914             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1915         else
1916             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1917         fi
1918
1919         LLVM_REQUIRED_VERSION_MAJOR="3"
1920         LLVM_REQUIRED_VERSION_MINOR="3"
1921         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1922             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1923         fi
1924
1925         LLVM_COMPONENTS="engine bitwriter"
1926         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1927             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1928         fi
1929
1930         if test "x$enable_opencl" = xyes; then
1931             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1932             # LLVM 3.3 >= 177971 requires IRReader
1933             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1934                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1935             fi
1936             # LLVM 3.4 requires Option
1937             if $LLVM_CONFIG --components | grep -qw 'option'; then
1938                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1939             fi
1940             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1941             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1942                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1943             fi
1944             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1945                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1946             fi
1947         fi
1948         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1949         MESA_LLVM=1
1950
1951         dnl Check for Clang internal headers
1952         if test "x$enable_opencl" = xyes; then
1953             if test -z "$CLANG_LIBDIR"; then
1954                 CLANG_LIBDIR=${LLVM_LIBDIR}
1955             fi
1956             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1957             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1958                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1959         fi
1960     else
1961         MESA_LLVM=0
1962         LLVM_VERSION_INT=0
1963     fi
1964 else
1965     MESA_LLVM=0
1966     LLVM_VERSION_INT=0
1967
1968     if test "x$enable_opencl" = xyes; then
1969         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1970     fi
1971 fi
1972
1973 dnl Directory for XVMC libs
1974 AC_ARG_WITH([xvmc-libdir],
1975     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1976         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1977     [XVMC_LIB_INSTALL_DIR="$withval"],
1978     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1979 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1980
1981 dnl
1982 dnl Gallium Tests
1983 dnl
1984 if test "x$enable_gallium_tests" = xyes; then
1985     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1986     enable_gallium_loader=yes
1987 fi
1988 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1989
1990 dnl Directory for VDPAU libs
1991 AC_ARG_WITH([vdpau-libdir],
1992     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1993         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1994     [VDPAU_LIB_INSTALL_DIR="$withval"],
1995     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1996 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1997
1998 dnl Directory for OMX libs
1999
2000 AC_ARG_WITH([omx-libdir],
2001     [AS_HELP_STRING([--with-omx-libdir=DIR],
2002         [directory for the OMX libraries])],
2003     [OMX_LIB_INSTALL_DIR="$withval"],
2004     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2005 AC_SUBST([OMX_LIB_INSTALL_DIR])
2006
2007 dnl Directory for VA libs
2008
2009 AC_ARG_WITH([va-libdir],
2010     [AS_HELP_STRING([--with-va-libdir=DIR],
2011         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2012     [VA_LIB_INSTALL_DIR="$withval"],
2013     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2014 AC_SUBST([VA_LIB_INSTALL_DIR])
2015
2016 AC_ARG_WITH([d3d-libdir],
2017     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2018         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2019     [D3D_DRIVER_INSTALL_DIR="$withval"],
2020     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2021 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2022
2023 dnl
2024 dnl Gallium helper functions
2025 dnl
2026 gallium_require_drm() {
2027     if test "x$have_libdrm" != xyes; then
2028        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2029     fi
2030 }
2031
2032 gallium_require_llvm() {
2033     if test "x$MESA_LLVM" = x0; then
2034         case "$host" in *gnux32) return;; esac
2035         case "$host_cpu" in
2036         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2037         esac
2038     fi
2039 }
2040
2041 gallium_require_drm_loader() {
2042     if test "x$enable_gallium_loader" = xyes; then
2043         if test "x$need_pci_id$have_pci_id" = xyesno; then
2044             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2045         fi
2046         enable_gallium_drm_loader=yes
2047     fi
2048     if test "x$enable_va" = xyes && test "x$7" != x; then
2049          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2050     fi
2051 }
2052
2053 require_egl_drm() {
2054     case "$with_egl_platforms" in
2055         *drm*)
2056             ;;
2057          *)
2058             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2059             ;;
2060     esac
2061     if test "x$enable_gbm" != xyes; then
2062             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2063     fi
2064 }
2065
2066 radeon_llvm_check() {
2067     if test "x$enable_gallium_llvm" != "xyes"; then
2068         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2069     fi
2070     LLVM_REQUIRED_VERSION_MAJOR="3"
2071     LLVM_REQUIRED_VERSION_MINOR="4"
2072     LLVM_REQUIRED_VERSION_PATCH="2"
2073     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2074         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2075     fi
2076     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2077         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2078                       sources with the --enable-experimental-targets=R600
2079                       configure flag])
2080     fi
2081     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2082     NEED_RADEON_LLVM=yes
2083     if test "x$have_libelf" != xyes; then
2084        AC_MSG_ERROR([$1 requires libelf when using llvm])
2085     fi
2086 }
2087
2088 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2089 if test -n "$with_gallium_drivers"; then
2090     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2091     for driver in $gallium_drivers; do
2092         case "x$driver" in
2093         xsvga)
2094             HAVE_GALLIUM_SVGA=yes
2095             gallium_require_drm "svga"
2096             gallium_require_drm_loader
2097             ;;
2098         xi915)
2099             HAVE_GALLIUM_I915=yes
2100             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2101             gallium_require_drm "Gallium i915"
2102             gallium_require_drm_loader
2103             ;;
2104         xilo)
2105             HAVE_GALLIUM_ILO=yes
2106             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2107             gallium_require_drm "Gallium i965/ilo"
2108             gallium_require_drm_loader
2109             ;;
2110         xr300)
2111             HAVE_GALLIUM_R300=yes
2112             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2113             gallium_require_drm "Gallium R300"
2114             gallium_require_drm_loader
2115             gallium_require_llvm "Gallium R300"
2116             ;;
2117         xr600)
2118             HAVE_GALLIUM_R600=yes
2119             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2120             gallium_require_drm "Gallium R600"
2121             gallium_require_drm_loader
2122             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2123                 radeon_llvm_check "r600g"
2124                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2125             fi
2126             if test "x$enable_r600_llvm" = xyes; then
2127                 USE_R600_LLVM_COMPILER=yes;
2128             fi
2129             if test "x$enable_opencl" = xyes; then
2130                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2131             fi
2132             ;;
2133         xradeonsi)
2134             HAVE_GALLIUM_RADEONSI=yes
2135             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2136             gallium_require_drm "radeonsi"
2137             gallium_require_drm_loader
2138             radeon_llvm_check "radeonsi"
2139             require_egl_drm "radeonsi"
2140             ;;
2141         xnouveau)
2142             HAVE_GALLIUM_NOUVEAU=yes
2143             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2144             gallium_require_drm "nouveau"
2145             gallium_require_drm_loader
2146             ;;
2147         xfreedreno)
2148             HAVE_GALLIUM_FREEDRENO=yes
2149             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2150             gallium_require_drm "freedreno"
2151             gallium_require_drm_loader
2152             ;;
2153         xswrast)
2154             HAVE_GALLIUM_SOFTPIPE=yes
2155             if test "x$MESA_LLVM" = x1; then
2156                 HAVE_GALLIUM_LLVMPIPE=yes
2157             fi
2158             ;;
2159         xvc4)
2160             HAVE_GALLIUM_VC4=yes
2161             gallium_require_drm "vc4"
2162             gallium_require_drm_loader
2163
2164             case "$host_cpu" in
2165                 i?86 | x86_64 | amd64)
2166                 USE_VC4_SIMULATOR=yes
2167                 ;;
2168             esac
2169             ;;
2170         *)
2171             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2172             ;;
2173         esac
2174     done
2175 fi
2176
2177 dnl Set LLVM_LIBS - This is done after the driver configuration so
2178 dnl that drivers can add additional components to LLVM_COMPONENTS.
2179 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2180 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2181 dnl this was causing the same libraries to be appear multiple times
2182 dnl in LLVM_LIBS.
2183
2184 if test "x$MESA_LLVM" != x0; then
2185
2186     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2187
2188     if test "x$enable_llvm_shared_libs" = xyes; then
2189         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2190         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2191         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2192
2193         if test "x$llvm_have_one_so" = xyes; then
2194             dnl LLVM was built using auto*, so there is only one shared object.
2195             LLVM_LIBS="-l$LLVM_SO_NAME"
2196         else
2197             dnl If LLVM was built with CMake, there will be one shared object per
2198             dnl component.
2199             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2200                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2201         Please make sure you have built llvm with the --enable-shared option
2202         and that your llvm libraries are installed in $LLVM_LIBDIR
2203         If you have installed your llvm libraries to a different directory you
2204         can use the --with-llvm-prefix= configure flag to specify this directory.
2205         NOTE: Mesa is attempting to use llvm shared libraries by default.
2206         If you do not want to build with llvm shared libraries and instead want to
2207         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2208         invocation and rebuild.])])
2209
2210            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2211            dnl install uses a shared object for each component and we have
2212            dnl already added all of these objects to LLVM_LIBS.
2213         fi
2214     else
2215         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2216         dnl We need to link to llvm system libs when using static libs
2217         dnl However, only llvm 3.5+ provides --system-libs
2218         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2219             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2220         fi
2221     fi
2222 fi
2223
2224 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2225 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2226 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2227 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2228 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2229 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2230 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2231                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2232 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2233 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2234 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2235 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2236 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2237
2238 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2239
2240 # NOTE: anything using xcb or other client side libs ends up in separate
2241 #       _CLIENT variables.  The pipe loader is built in two variants,
2242 #       one that is standalone and does not link any x client libs (for
2243 #       use by XA tracker in particular, but could be used in any case
2244 #       where communication with xserver is not desired).
2245 if test "x$enable_gallium_loader" = xyes; then
2246     if test "x$NEED_WINSYS_XLIB" = xyes; then
2247         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2248     fi
2249
2250     if test "x$enable_dri" = xyes; then
2251         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2252     fi
2253
2254     if test "x$enable_gallium_drm_loader" = xyes; then
2255         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2256         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2257                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2258         if test "x$pipe_loader_have_xcb" = xyes; then
2259             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2260             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2261         fi
2262     fi
2263
2264     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2265     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2266
2267     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2268     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2269     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2270     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2271 fi
2272
2273 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2274 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2275 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2276 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2277 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2278 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2279
2280 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2281                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2282                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2283 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2284 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2285 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2286 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2287 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2288 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2289 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2290 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2291 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2292     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2293 fi
2294
2295 AC_SUBST([ELF_LIB])
2296
2297 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2298 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2299 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2300 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2301 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2302
2303 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2304 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2305 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2306
2307 AC_SUBST([NINE_MAJOR], 1)
2308 AC_SUBST([NINE_MINOR], 0)
2309 AC_SUBST([NINE_TINY], 0)
2310 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2311
2312 AC_SUBST([VDPAU_MAJOR], 1)
2313 AC_SUBST([VDPAU_MINOR], 0)
2314
2315 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2316 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2317 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2318 AC_SUBST([VA_MINOR], $VA_MINOR)
2319
2320 AC_SUBST([XVMC_MAJOR], 1)
2321 AC_SUBST([XVMC_MINOR], 0)
2322
2323 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2324 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2325 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2326 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2327
2328 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2329 AC_SUBST([XA_MINOR], $XA_MINOR)
2330 AC_SUBST([XA_TINY], $XA_TINY)
2331 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2332
2333 dnl Restore LDFLAGS and CPPFLAGS
2334 LDFLAGS="$_SAVE_LDFLAGS"
2335 CPPFLAGS="$_SAVE_CPPFLAGS"
2336
2337 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2338 if test "x$acv_mesa_CLANG" = xyes; then
2339     CFLAGS="$CFLAGS -Qunused-arguments"
2340     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2341 fi
2342
2343 dnl Add user CFLAGS and CXXFLAGS
2344 CFLAGS="$CFLAGS $USER_CFLAGS"
2345 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2346
2347 dnl Substitute the config
2348 AC_CONFIG_FILES([Makefile
2349                 src/Makefile
2350                 src/egl/drivers/dri2/Makefile
2351                 src/egl/main/Makefile
2352                 src/egl/main/egl.pc
2353                 src/egl/wayland/wayland-drm/Makefile
2354                 src/egl/wayland/wayland-egl/Makefile
2355                 src/egl/wayland/wayland-egl/wayland-egl.pc
2356                 src/gallium/Makefile
2357                 src/gallium/auxiliary/Makefile
2358                 src/gallium/auxiliary/pipe-loader/Makefile
2359                 src/gallium/drivers/freedreno/Makefile
2360                 src/gallium/drivers/galahad/Makefile
2361                 src/gallium/drivers/i915/Makefile
2362                 src/gallium/drivers/ilo/Makefile
2363                 src/gallium/drivers/llvmpipe/Makefile
2364                 src/gallium/drivers/noop/Makefile
2365                 src/gallium/drivers/nouveau/Makefile
2366                 src/gallium/drivers/r300/Makefile
2367                 src/gallium/drivers/r600/Makefile
2368                 src/gallium/drivers/radeon/Makefile
2369                 src/gallium/drivers/radeonsi/Makefile
2370                 src/gallium/drivers/rbug/Makefile
2371                 src/gallium/drivers/softpipe/Makefile
2372                 src/gallium/drivers/svga/Makefile
2373                 src/gallium/drivers/trace/Makefile
2374                 src/gallium/drivers/vc4/Makefile
2375                 src/gallium/drivers/vc4/kernel/Makefile
2376                 src/gallium/state_trackers/clover/Makefile
2377                 src/gallium/state_trackers/dri/Makefile
2378                 src/gallium/state_trackers/glx/xlib/Makefile
2379                 src/gallium/state_trackers/nine/Makefile
2380                 src/gallium/state_trackers/omx/Makefile
2381                 src/gallium/state_trackers/osmesa/Makefile
2382                 src/gallium/state_trackers/va/Makefile
2383                 src/gallium/state_trackers/vdpau/Makefile
2384                 src/gallium/state_trackers/xa/Makefile
2385                 src/gallium/state_trackers/xvmc/Makefile
2386                 src/gallium/targets/d3dadapter9/Makefile
2387                 src/gallium/targets/d3dadapter9/d3d.pc
2388                 src/gallium/targets/dri/Makefile
2389                 src/gallium/targets/libgl-xlib/Makefile
2390                 src/gallium/targets/omx/Makefile
2391                 src/gallium/targets/opencl/Makefile
2392                 src/gallium/targets/osmesa/Makefile
2393                 src/gallium/targets/osmesa/osmesa.pc
2394                 src/gallium/targets/pipe-loader/Makefile
2395                 src/gallium/targets/va/Makefile
2396                 src/gallium/targets/vdpau/Makefile
2397                 src/gallium/targets/xa/Makefile
2398                 src/gallium/targets/xa/xatracker.pc
2399                 src/gallium/targets/xvmc/Makefile
2400                 src/gallium/tests/trivial/Makefile
2401                 src/gallium/tests/unit/Makefile
2402                 src/gallium/winsys/freedreno/drm/Makefile
2403                 src/gallium/winsys/i915/drm/Makefile
2404                 src/gallium/winsys/intel/drm/Makefile
2405                 src/gallium/winsys/nouveau/drm/Makefile
2406                 src/gallium/winsys/radeon/drm/Makefile
2407                 src/gallium/winsys/svga/drm/Makefile
2408                 src/gallium/winsys/sw/dri/Makefile
2409                 src/gallium/winsys/sw/fbdev/Makefile
2410                 src/gallium/winsys/sw/kms-dri/Makefile
2411                 src/gallium/winsys/sw/null/Makefile
2412                 src/gallium/winsys/sw/wayland/Makefile
2413                 src/gallium/winsys/sw/wrapper/Makefile
2414                 src/gallium/winsys/sw/xlib/Makefile
2415                 src/gallium/winsys/vc4/drm/Makefile
2416                 src/gbm/Makefile
2417                 src/gbm/main/gbm.pc
2418                 src/glsl/Makefile
2419                 src/glx/Makefile
2420                 src/glx/apple/Makefile
2421                 src/glx/tests/Makefile
2422                 src/gtest/Makefile
2423                 src/loader/Makefile
2424                 src/mapi/Makefile
2425                 src/mapi/es1api/glesv1_cm.pc
2426                 src/mapi/es2api/glesv2.pc
2427                 src/mapi/glapi/gen/Makefile
2428                 src/mesa/Makefile
2429                 src/mesa/gl.pc
2430                 src/mesa/drivers/dri/dri.pc
2431                 src/mesa/drivers/dri/common/Makefile
2432                 src/mesa/drivers/dri/common/xmlpool/Makefile
2433                 src/mesa/drivers/dri/i915/Makefile
2434                 src/mesa/drivers/dri/i965/Makefile
2435                 src/mesa/drivers/dri/Makefile
2436                 src/mesa/drivers/dri/nouveau/Makefile
2437                 src/mesa/drivers/dri/r200/Makefile
2438                 src/mesa/drivers/dri/radeon/Makefile
2439                 src/mesa/drivers/dri/swrast/Makefile
2440                 src/mesa/drivers/osmesa/Makefile
2441                 src/mesa/drivers/osmesa/osmesa.pc
2442                 src/mesa/drivers/x11/Makefile
2443                 src/mesa/main/tests/Makefile
2444                 src/util/Makefile
2445                 src/util/tests/hash_table/Makefile])
2446
2447 AC_OUTPUT
2448
2449 dnl
2450 dnl Output some configuration info for the user
2451 dnl
2452 echo ""
2453 echo "        prefix:          $prefix"
2454 echo "        exec_prefix:     $exec_prefix"
2455 echo "        libdir:          $libdir"
2456 echo "        includedir:      $includedir"
2457
2458 dnl API info
2459 echo ""
2460 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2461
2462 dnl Driver info
2463 echo ""
2464 case "x$enable_osmesa$enable_gallium_osmesa" in
2465 xnoyes)
2466         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2467         ;;
2468 xyesno)
2469         echo "        OSMesa:          lib$OSMESA_LIB"
2470         ;;
2471 xnono)
2472         echo "        OSMesa:          no"
2473         ;;
2474 esac
2475
2476 echo ""
2477 if test "x$enable_dri" != xno; then
2478         echo "        DRI platform:    $dri_platform"
2479         if test -z "$DRI_DIRS"; then
2480             echo "        DRI drivers:     no"
2481         else
2482             echo "        DRI drivers:     $DRI_DIRS"
2483         fi
2484         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2485 fi
2486
2487 case "x$enable_glx$enable_xlib_glx" in
2488 xyesyes)
2489     echo "        GLX:             Xlib-based"
2490     ;;
2491 xyesno)
2492     echo "        GLX:             DRI-based"
2493     ;;
2494 *)
2495     echo "        GLX:             $enable_glx"
2496     ;;
2497 esac
2498
2499 dnl EGL
2500 echo ""
2501 echo "        EGL:             $enable_egl"
2502 if test "$enable_egl" = yes; then
2503     echo "        EGL platforms:   $egl_platforms"
2504
2505     egl_drivers=""
2506     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2507         egl_drivers="$egl_drivers builtin:egl_dri2"
2508     fi
2509
2510     echo "        EGL drivers:    $egl_drivers"
2511 fi
2512
2513 echo ""
2514 if test "x$MESA_LLVM" = x1; then
2515     echo "        llvm:            yes"
2516     echo "        llvm-config:     $LLVM_CONFIG"
2517     echo "        llvm-version:    $LLVM_VERSION"
2518 else
2519     echo "        llvm:            no"
2520 fi
2521
2522 echo ""
2523 if test -n "$with_gallium_drivers"; then
2524     echo "        Gallium:         yes"
2525 else
2526     echo "        Gallium:         no"
2527 fi
2528
2529 dnl Shader cache
2530 echo ""
2531 echo "        Shader cache:    $enable_shader_cache"
2532 if test "x$enable_shader_cache" = "xyes"; then
2533     echo "        With SHA1 from:  $with_sha1"
2534 fi
2535
2536 dnl Libraries
2537 echo ""
2538 echo "        Shared libs:     $enable_shared"
2539 echo "        Static libs:     $enable_static"
2540 echo "        Shared-glapi:    $enable_shared_glapi"
2541
2542 dnl Compiler options
2543 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2544 cflags=`echo $CFLAGS | \
2545     $SED 's/^ *//;s/  */ /;s/ *$//'`
2546 cxxflags=`echo $CXXFLAGS | \
2547     $SED 's/^ *//;s/  */ /;s/ *$//'`
2548 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2549 echo ""
2550 echo "        CFLAGS:          $cflags"
2551 echo "        CXXFLAGS:        $cxxflags"
2552 echo "        Macros:          $defines"
2553 echo ""
2554 if test "x$MESA_LLVM" = x1; then
2555     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2556     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2557     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2558     echo ""
2559 fi
2560 echo "        PYTHON2:         $PYTHON2"
2561
2562 echo ""
2563 echo "        Run '${MAKE-make}' to build Mesa"
2564 echo ""