configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,[],[
   9     m4_errprint([Error: Failed to get the Mesa version from the output of
  10        running `make -f bin/version.mk version'
  11 ])
  12     m4_exit([1])
  13 ])
  14
  15 dnl Tell the user about autoconf.html in the --help output
  16 m4_divert_once([HELP_END], [
  17 See docs/autoconf.html for more details on the options for Mesa.])
  18
  19 AC_INIT([Mesa],[mesa_version],
  20     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  21 AC_CONFIG_AUX_DIR([bin])
  22 AC_CANONICAL_HOST
  23
  24 dnl Versions for external dependencies
  25 LIBDRM_REQUIRED=2.4.3
  26 DRI2PROTO_REQUIRED=1.99.3
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl We need a POSIX shell for parts of the build. Assume we have one
  37 dnl in most cases.
  38 case "$host_os" in
  39 solaris*)
  40     # Solaris /bin/sh is too old/non-POSIX compliant
  41     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  42     SHELL="$POSIX_SHELL"
  43     ;;
  44 esac
  45
  46 MKDEP_OPTIONS=-fdepend
  47 dnl Ask gcc where it's keeping its secret headers
  48 if test "x$GCC" = xyes; then
  49     for dir in include include-fixed; do
  50         GCC_INCLUDES=`$CC -print-file-name=$dir`
  51         if test "x$GCC_INCLUDES" != x && \
  52            test "$GCC_INCLUDES" != "$dir" && \
  53            test -d "$GCC_INCLUDES"; then
  54             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  55         fi
  56     done
  57 fi
  58 AC_SUBST([MKDEP_OPTIONS])
  59
  60 dnl Make sure the pkg-config macros are defined
  61 m4_ifdef([PKG_PROG_PKG_CONFIG],[],[
  62     m4_errprint([Error: Could not locate the pkg-config autoconf macros.
  63        These are usually located in /usr/share/aclocal/pkg.m4. If your
  64        macros are in a different location, try setting the environment
  65        variable ACLOCAL="aclocal -I/other/macro/dir" before running
  66        autoreconf.
  67 ])
  68     m4_exit([1])
  69 ])
  70 PKG_PROG_PKG_CONFIG()
  71
  72 dnl LIB_DIR - library basename
  73 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  74 AC_SUBST([LIB_DIR])
  75
  76 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  77 _SAVE_LDFLAGS="$LDFLAGS"
  78 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  79 AC_SUBST([EXTRA_LIB_PATH])
  80
  81 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  82 _SAVE_CPPFLAGS="$CPPFLAGS"
  83 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  84 AC_SUBST([X11_INCLUDES])
  85
  86 dnl Compiler macros
  87 DEFINES=""
  88 AC_SUBST([DEFINES])
  89 case "$host_os" in
  90 linux*|*-gnu*)
  91     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  92     ;;
  93 solaris*)
  94     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  95     ;;
  96 esac
  97
  98 dnl Add flags for gcc and g++
  99 if test "x$GCC" = xyes; then
 100     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 101
 102     # Work around aliasing bugs - developers should comment this out
 103     CFLAGS="$CFLAGS -fno-strict-aliasing"
 104 fi
 105 if test "x$GXX" = xyes; then
 106     CXXFLAGS="$CXXFLAGS -Wall"
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 110 fi
 111
 112 dnl These should be unnecessary, but let the user set them if they want
 113 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 114     Default is to use CFLAGS.])
 115 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 116     compiler. Default is to use CFLAGS.])
 117 AC_SUBST([OPT_FLAGS])
 118 AC_SUBST([ARCH_FLAGS])
 119
 120 dnl
 121 dnl Hacks to enable 32 or 64 bit build
 122 dnl
 123 AC_ARG_ENABLE([32-bit],
 124     [AS_HELP_STRING([--enable-32-bit],
 125         [build 32-bit libraries @<:@default=auto@:>@])],
 126     [enable_32bit="$enableval"],
 127     [enable_32bit=auto]
 128 )
 129 if test "x$enable_32bit" = xyes; then
 130     if test "x$GCC" = xyes; then
 131         CFLAGS="$CFLAGS -m32"
 132     fi
 133     if test "x$GXX" = xyes; then
 134         CXXFLAGS="$CXXFLAGS -m32"
 135     fi
 136 fi
 137 AC_ARG_ENABLE([64-bit],
 138     [AS_HELP_STRING([--enable-64-bit],
 139         [build 64-bit libraries @<:@default=auto@:>@])],
 140     [enable_64bit="$enableval"],
 141     [enable_64bit=auto]
 142 )
 143 if test "x$enable_64bit" = xyes; then
 144     if test "x$GCC" = xyes; then
 145         CFLAGS="$CFLAGS -m64"
 146     fi
 147     if test "x$GXX" = xyes; then
 148         CXXFLAGS="$CXXFLAGS -m64"
 149     fi
 150 fi
 151
 152 dnl
 153 dnl shared/static libraries, mimic libtool options
 154 dnl
 155 AC_ARG_ENABLE([static],
 156     [AS_HELP_STRING([--enable-static],
 157         [build static libraries @<:@default=disabled@:>@])],
 158     [enable_static="$enableval"],
 159     [enable_static=no]
 160 )
 161 case "x$enable_static" in
 162 xyes|xno ) ;;
 163 x ) enable_static=no ;;
 164 * )
 165     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 166     ;;
 167 esac
 168 AC_ARG_ENABLE([shared],
 169     [AS_HELP_STRING([--disable-shared],
 170         [build shared libraries @<:@default=enabled@:>@])],
 171     [enable_shared="$enableval"],
 172     [enable_shared=yes]
 173 )
 174 case "x$enable_shared" in
 175 xyes|xno ) ;;
 176 x ) enable_shared=yes ;;
 177 * )
 178     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 179     ;;
 180 esac
 181
 182 dnl Can't have static and shared libraries, default to static if user
 183 dnl explicitly requested. If both disabled, set to static since shared
 184 dnl was explicitly requirested.
 185 case "x$enable_static$enable_shared" in
 186 xyesyes )
 187     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 188     enable_shared=no
 189     ;;
 190 xnono )
 191     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 192     enable_static=yes
 193     ;;
 194 esac
 195
 196 dnl
 197 dnl mklib options
 198 dnl
 199 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 200 if test "$enable_static" = yes; then
 201     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 202 fi
 203 AC_SUBST([MKLIB_OPTIONS])
 204
 205 dnl
 206 dnl other compiler options
 207 dnl
 208 AC_ARG_ENABLE([debug],
 209     [AS_HELP_STRING([--enable-debug],
 210         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 211     [enable_debug="$enableval"],
 212     [enable_debug=no]
 213 )
 214 if test "x$enable_debug" = xyes; then
 215     DEFINES="$DEFINES -DDEBUG"
 216     if test "x$GCC" = xyes; then
 217         CFLAGS="$CFLAGS -g"
 218     fi
 219     if test "x$GXX" = xyes; then
 220         CXXFLAGS="$CXXFLAGS -g"
 221     fi
 222 fi
 223
 224 dnl
 225 dnl library names
 226 dnl
 227 if test "$enable_static" = yes; then
 228     LIB_EXTENSION='a'
 229 else
 230     case "$host_os" in
 231     darwin* )
 232         LIB_EXTENSION='dylib' ;;
 233     * )
 234         LIB_EXTENSION='so' ;;
 235     esac
 236 fi
 237
 238 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 239 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 240 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 241 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 242 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 243
 244 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 245 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 246 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 247 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 248 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 249
 250 AC_SUBST([GL_LIB_NAME])
 251 AC_SUBST([GLU_LIB_NAME])
 252 AC_SUBST([GLUT_LIB_NAME])
 253 AC_SUBST([GLW_LIB_NAME])
 254 AC_SUBST([OSMESA_LIB_NAME])
 255
 256 AC_SUBST([GL_LIB_GLOB])
 257 AC_SUBST([GLU_LIB_GLOB])
 258 AC_SUBST([GLUT_LIB_GLOB])
 259 AC_SUBST([GLW_LIB_GLOB])
 260 AC_SUBST([OSMESA_LIB_GLOB])
 261
 262 dnl
 263 dnl Arch/platform-specific settings
 264 dnl
 265 AC_ARG_ENABLE([asm],
 266     [AS_HELP_STRING([--disable-asm],
 267         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 268     [enable_asm="$enableval"],
 269     [enable_asm=yes]
 270 )
 271 asm_arch=""
 272 ASM_FLAGS=""
 273 MESA_ASM_SOURCES=""
 274 GLAPI_ASM_SOURCES=""
 275 AC_MSG_CHECKING([whether to enable assembly])
 276 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 277 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 278 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 279     case "$host_cpu" in
 280     i?86 | x86_64)
 281         enable_asm=no
 282         AC_MSG_RESULT([no, cross compiling])
 283         ;;
 284     esac
 285 fi
 286 # check for supported arches
 287 if test "x$enable_asm" = xyes; then
 288     case "$host_cpu" in
 289     i?86)
 290         case "$host_os" in
 291         linux* | *freebsd* | dragonfly*)
 292             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 293             ;;
 294         esac
 295         ;;
 296     x86_64)
 297         case "$host_os" in
 298         linux* | *freebsd* | dragonfly*)
 299             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 300             ;;
 301         esac
 302         ;;
 303     powerpc)
 304         case "$host_os" in
 305         linux*)
 306             asm_arch=ppc
 307             ;;
 308         esac
 309         ;;
 310     sparc*)
 311         case "$host_os" in
 312         linux*)
 313             asm_arch=sparc
 314             ;;
 315         esac
 316         ;;
 317     esac
 318
 319     case "$asm_arch" in
 320     x86)
 321         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 322         MESA_ASM_SOURCES='$(X86_SOURCES)'
 323         GLAPI_ASM_SOURCES='$(X86_API)'
 324         AC_MSG_RESULT([yes, x86])
 325         ;;
 326     x86_64)
 327         ASM_FLAGS="-DUSE_X86_64_ASM"
 328         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 329         GLAPI_ASM_SOURCES='$(X86-64_API)'
 330         AC_MSG_RESULT([yes, x86_64])
 331         ;;
 332     ppc)
 333         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 334         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 335         AC_MSG_RESULT([yes, ppc])
 336         ;;
 337     sparc)
 338         ASM_FLAGS="-DUSE_SPARC_ASM"
 339         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 340         GLAPI_ASM_SOURCES='$(SPARC_API)'
 341         AC_MSG_RESULT([yes, sparc])
 342         ;;
 343     *)
 344         AC_MSG_RESULT([no, platform not supported])
 345         ;;
 346     esac
 347 fi
 348 AC_SUBST([ASM_FLAGS])
 349 AC_SUBST([MESA_ASM_SOURCES])
 350 AC_SUBST([GLAPI_ASM_SOURCES])
 351
 352 dnl PIC code macro
 353 MESA_PIC_FLAGS
 354
 355 dnl Check to see if dlopen is in default libraries (like Solaris, which
 356 dnl has it in libc), or if libdl is needed to get it.
 357 AC_CHECK_FUNC([dlopen], [],
 358     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 359
 360 dnl See if posix_memalign is available
 361 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 362
 363 dnl SELinux awareness.
 364 AC_ARG_ENABLE([selinux],
 365     [AS_HELP_STRING([--enable-selinux],
 366         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 367     [MESA_SELINUX="$enableval"],
 368     [MESA_SELINUX=no])
 369 if test "x$enable_selinux" = "xyes"; then
 370     AC_CHECK_HEADER([selinux/selinux.h],[],
 371                     [AC_MSG_ERROR([SELinux headers not found])])
 372     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 373                  [AC_MSG_ERROR([SELinux library not found])])
 374     SELINUX_LIBS="-lselinux"
 375     DEFINES="$DEFINES -DMESA_SELINUX"
 376 fi
 377
 378 dnl OS-specific libraries
 379 OS_LIBS=""
 380 case "$host_os" in
 381 solaris*)
 382     OS_LIBS="-lc"
 383     if test "x$GXX" != xyes; then
 384         OS_CPLUSPLUS_LIBS="-lCrun $OS_LIBS"
 385     fi
 386     ;;
 387 esac
 388
 389 dnl
 390 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 391 dnl More later: directfb, fbdev, ...
 392 dnl
 393 default_driver="xlib"
 394
 395 case "$host_os" in
 396 linux*)
 397     case "$host_cpu" in
 398     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 399     esac
 400     ;;
 401 *freebsd* | dragonfly*)
 402     case "$host_cpu" in
 403     i*86|x86_64) default_driver="dri";;
 404     esac
 405     ;;
 406 esac
 407
 408 AC_ARG_WITH([driver],
 409     [AS_HELP_STRING([--with-driver=DRIVER],
 410         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 411     [mesa_driver="$withval"],
 412     [mesa_driver="$default_driver"])
 413 dnl Check for valid option
 414 case "x$mesa_driver" in
 415 xxlib|xdri|xosmesa)
 416     ;;
 417 *)
 418     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 419     ;;
 420 esac
 421
 422 dnl
 423 dnl Driver specific build directories
 424 dnl
 425 SRC_DIRS="mesa egl glew"
 426 GLU_DIRS="sgi"
 427 WINDOW_SYSTEM=""
 428 GALLIUM_DIRS="auxiliary drivers state_trackers"
 429 GALLIUM_WINSYS_DIRS=""
 430 GALLIUM_WINSYS_DRM_DIRS=""
 431 GALLIUM_AUXILIARY_DIRS="draw translate cso_cache pipebuffer tgsi sct rtasm util"
 432 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 433 GALLIUM_STATE_TRACKERS_DIRS=""
 434
 435 case "$mesa_driver" in
 436 xlib)
 437     DRIVER_DIRS="x11"
 438     ;;
 439 dri)
 440     SRC_DIRS="glx/x11 $SRC_DIRS"
 441     DRIVER_DIRS="dri"
 442     WINDOW_SYSTEM="dri"
 443     GALLIUM_WINSYS_DIRS="drm $GALLIUM_WINSYS_DIRS"
 444     ;;
 445 osmesa)
 446     DRIVER_DIRS="osmesa"
 447     ;;
 448 esac
 449 AC_SUBST([SRC_DIRS])
 450 AC_SUBST([GLU_DIRS])
 451 AC_SUBST([DRIVER_DIRS])
 452 AC_SUBST([WINDOW_SYSTEM])
 453 AC_SUBST([GALLIUM_DIRS])
 454 AC_SUBST([GALLIUM_WINSYS_DIRS])
 455 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 456 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 457 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 458 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 459 AC_SUBST([RADEON_CFLAGS])
 460 AC_SUBST([RADEON_LDFLAGS])
 461
 462 dnl
 463 dnl User supplied program configuration
 464 dnl
 465 if test -d "$srcdir/progs/demos"; then
 466     default_demos=yes
 467 else
 468     default_demos=no
 469 fi
 470 AC_ARG_WITH([demos],
 471     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 472         [optional comma delimited demo directories to build
 473         @<:@default=auto if source available@:>@])],
 474     [with_demos="$withval"],
 475     [with_demos="$default_demos"])
 476 if test "x$with_demos" = x; then
 477     with_demos=no
 478 fi
 479
 480 dnl If $with_demos is yes, directories will be added as libs available
 481 PROGRAM_DIRS=""
 482 case "$with_demos" in
 483 no) ;;
 484 yes)
 485     # If the driver isn't osmesa, we have libGL and can build xdemos
 486     if test "$mesa_driver" != osmesa; then
 487         PROGRAM_DIRS="xdemos"
 488     fi
 489     ;;
 490 *)
 491     # verify the requested demos directories exist
 492     demos=`IFS=,; echo $with_demos`
 493     for demo in $demos; do
 494         test -d "$srcdir/progs/$demo" || \
 495             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 496     done
 497     PROGRAM_DIRS="$demos"
 498     ;;
 499 esac
 500
 501 dnl
 502 dnl Find out if X is available. The variable have_x is set if libX11 is
 503 dnl found to mimic AC_PATH_XTRA.
 504 dnl
 505 if test -n "$PKG_CONFIG"; then
 506     AC_MSG_CHECKING([pkg-config files for X11 are available])
 507     PKG_CHECK_EXISTS([x11],[
 508         x11_pkgconfig=yes
 509         have_x=yes
 510         ],[
 511         x11_pkgconfig=no
 512     ])
 513     AC_MSG_RESULT([$x11_pkgconfig])
 514 else
 515     x11_pkgconfig=no
 516 fi
 517 dnl Use the autoconf macro if no pkg-config files
 518 if test "$x11_pkgconfig" = no; then
 519     AC_PATH_XTRA
 520 fi
 521
 522 dnl Try to tell the user that the --x-* options are only used when
 523 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 524 m4_divert_once([HELP_BEGIN],
 525 [These options are only used when the X libraries cannot be found by the
 526 pkg-config utility.])
 527
 528 dnl We need X for xlib and dri, so bomb now if it's not found
 529 case "$mesa_driver" in
 530 xlib|dri)
 531     if test "$no_x" = yes; then
 532         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 533     fi
 534     ;;
 535 esac
 536
 537 dnl XCB - this is only used for GLX right now
 538 AC_ARG_ENABLE([xcb],
 539     [AS_HELP_STRING([--enable-xcb],
 540         [use XCB for GLX @<:@default=disabled@:>@])],
 541     [enable_xcb="$enableval"],
 542     [enable_xcb=no])
 543 if test "x$enable_xcb" = xyes; then
 544     DEFINES="$DEFINES -DUSE_XCB"
 545 else
 546     enable_xcb=no
 547 fi
 548
 549 dnl
 550 dnl libGL configuration per driver
 551 dnl
 552 case "$mesa_driver" in
 553 xlib)
 554     if test "$x11_pkgconfig" = yes; then
 555         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 556         GL_PC_REQ_PRIV="x11 xext"
 557         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 558         GL_LIB_DEPS="$XLIBGL_LIBS"
 559     else
 560         # should check these...
 561         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 562         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 563         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 564         GL_PC_CFLAGS="$X11_INCLUDES"
 565     fi
 566     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 567     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 568
 569     # if static, move the external libraries to the programs
 570     # and empty the libraries for libGL
 571     if test "$enable_static" = yes; then
 572         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 573         GL_LIB_DEPS=""
 574     fi
 575     ;;
 576 dri)
 577     # DRI must be shared, I think
 578     if test "$enable_static" = yes; then
 579         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 580     fi
 581
 582     # Check for libdrm
 583     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 584     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 585     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 586     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 587
 588     PKG_CHECK_MODULES([LIBDRM_RADEON], [libdrm_radeon], HAVE_LIBDRM_RADEON=yes, HAVE_LIBDRM_RADEON=no)
 589
 590     if test "$HAVE_LIBDRM_RADEON" = yes; then
 591         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 592         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 593     fi
 594
 595     # find the DRI deps for libGL
 596     if test "$x11_pkgconfig" = yes; then
 597         # add xcb modules if necessary
 598         dri_modules="x11 xext xxf86vm xdamage xfixes"
 599         if test "$enable_xcb" = yes; then
 600             dri_modules="$dri_modules x11-xcb xcb-glx"
 601         fi
 602
 603         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 604         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 605         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 606         GL_LIB_DEPS="$DRIGL_LIBS"
 607     else
 608         # should check these...
 609         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 610         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 611         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 612         GL_PC_CFLAGS="$X11_INCLUDES"
 613
 614         # XCB can only be used from pkg-config
 615         if test "$enable_xcb" = yes; then
 616             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 617             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 618             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 619             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 620         fi
 621     fi
 622
 623     # need DRM libs, -lpthread, etc.
 624     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 625     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 626     ;;
 627 osmesa)
 628     # No libGL for osmesa
 629     GL_LIB_DEPS="$OS_LIBS"
 630     ;;
 631 esac
 632 AC_SUBST([GL_LIB_DEPS])
 633 AC_SUBST([GL_PC_REQ_PRIV])
 634 AC_SUBST([GL_PC_LIB_PRIV])
 635 AC_SUBST([GL_PC_CFLAGS])
 636 AC_SUBST([DRI_PC_REQ_PRIV])
 637
 638 dnl
 639 dnl More X11 setup
 640 dnl
 641 if test "$mesa_driver" = xlib; then
 642     DEFINES="$DEFINES -DUSE_XSHM"
 643 fi
 644
 645 dnl
 646 dnl More DRI setup
 647 dnl
 648 AC_ARG_ENABLE([glx-tls],
 649     [AS_HELP_STRING([--enable-glx-tls],
 650         [enable TLS support in GLX @<:@default=disabled@:>@])],
 651     [GLX_USE_TLS="$enableval"],
 652     [GLX_USE_TLS=no])
 653 dnl Directory for DRI drivers
 654 AC_ARG_WITH([dri-driverdir],
 655     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 656         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 657     [DRI_DRIVER_INSTALL_DIR="$withval"],
 658     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 659 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 660 dnl Direct rendering or just indirect rendering
 661 AC_ARG_ENABLE([driglx-direct],
 662     [AS_HELP_STRING([--disable-driglx-direct],
 663         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 664     [driglx_direct="$enableval"],
 665     [driglx_direct="yes"])
 666 dnl Which drivers to build - default is chosen by platform
 667 AC_ARG_WITH([dri-drivers],
 668     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 669         [comma delimited DRI drivers list, e.g.
 670         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 671     [with_dri_drivers="$withval"],
 672     [with_dri_drivers=yes])
 673 if test "x$with_dri_drivers" = x; then
 674     with_dri_drivers=no
 675 fi
 676
 677 dnl If $with_dri_drivers is yes, directories will be added through
 678 dnl platform checks
 679 DRI_DIRS=""
 680 case "$with_dri_drivers" in
 681 no) ;;
 682 yes)
 683     DRI_DIRS="yes"
 684     ;;
 685 *)
 686     # verify the requested driver directories exist
 687     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 688     for driver in $dri_drivers; do
 689         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 690             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 691     done
 692     DRI_DIRS="$dri_drivers"
 693     ;;
 694 esac
 695
 696 dnl Just default to no EGL for now
 697 USING_EGL=0
 698 AC_SUBST([USING_EGL])
 699
 700 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 701 if test "$mesa_driver" = dri; then
 702     # Use TLS in GLX?
 703     if test "x$GLX_USE_TLS" = xyes; then
 704         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 705     fi
 706
 707     if test "x$USING_EGL" = x1; then
 708         PROGRAM_DIRS="egl"
 709     fi
 710
 711     # Platform specific settings and drivers to build
 712     case "$host_os" in
 713     linux*)
 714         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 715         if test "x$driglx_direct" = xyes; then
 716             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 717         fi
 718         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 719
 720         case "$host_cpu" in
 721         x86_64)
 722             # ffb, gamma, and sis are missing because they have not be
 723             # converted to use the new interface.  i810 are missing
 724             # because there is no x86-64 system where they could *ever*
 725             # be used.
 726             if test "x$DRI_DIRS" = "xyes"; then
 727                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 728                     savage tdfx unichrome swrast"
 729             fi
 730             ;;
 731         powerpc*)
 732             # Build only the drivers for cards that exist on PowerPC.
 733             # At some point MGA will be added, but not yet.
 734             if test "x$DRI_DIRS" = "xyes"; then
 735                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 736             fi
 737             ;;
 738         sparc*)
 739             # Build only the drivers for cards that exist on sparc`
 740             if test "x$DRI_DIRS" = "xyes"; then
 741                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 742             fi
 743             ;;
 744         esac
 745         ;;
 746     freebsd* | dragonfly*)
 747         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 748         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 749         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 750         if test "x$driglx_direct" = xyes; then
 751             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 752         fi
 753         if test "x$GXX" = xyes; then
 754             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 755         fi
 756
 757         # ffb and gamma are missing because they have not been converted
 758         # to use the new interface.
 759         if test "x$DRI_DIRS" = "xyes"; then
 760             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 761                 unichrome savage sis swrast"
 762         fi
 763         ;;
 764     solaris*)
 765         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 766         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 767         if test "x$driglx_direct" = xyes; then
 768             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 769         fi
 770         ;;
 771     esac
 772
 773     # default drivers
 774     if test "x$DRI_DIRS" = "xyes"; then
 775         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 776             savage sis tdfx trident unichrome ffb swrast"
 777     fi
 778
 779     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 780
 781     # Check for expat
 782     EXPAT_INCLUDES=""
 783     EXPAT_LIB=-lexpat
 784     AC_ARG_WITH([expat],
 785         [AS_HELP_STRING([--with-expat=DIR],
 786             [expat install directory])],[
 787         EXPAT_INCLUDES="-I$withval/include"
 788         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 789         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 790         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 791         ])
 792     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 793     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 794         [AC_MSG_ERROR([Expat required for DRI.])])
 795
 796     # put all the necessary libs together
 797     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 798 fi
 799 AC_SUBST([DRI_DIRS])
 800 AC_SUBST([EXPAT_INCLUDES])
 801 AC_SUBST([DRI_LIB_DEPS])
 802
 803 dnl
 804 dnl OSMesa configuration
 805 dnl
 806 if test "$mesa_driver" = xlib; then
 807     default_gl_osmesa=yes
 808 else
 809     default_gl_osmesa=no
 810 fi
 811 AC_ARG_ENABLE([gl-osmesa],
 812     [AS_HELP_STRING([--enable-gl-osmesa],
 813         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 814     [gl_osmesa="$enableval"],
 815     [gl_osmesa="$default_gl_osmesa"])
 816 if test "x$gl_osmesa" = xyes; then
 817     if test "$mesa_driver" = osmesa; then
 818         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 819     else
 820         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 821     fi
 822 fi
 823
 824 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 825 AC_ARG_WITH([osmesa-bits],
 826     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 827         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 828     [osmesa_bits="$withval"],
 829     [osmesa_bits=8])
 830 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 831     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 832     osmesa_bits=8
 833 fi
 834 case "x$osmesa_bits" in
 835 x8)
 836     OSMESA_LIB=OSMesa
 837     ;;
 838 x16|x32)
 839     OSMESA_LIB="OSMesa$osmesa_bits"
 840     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 841     ;;
 842 *)
 843     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 844     ;;
 845 esac
 846 AC_SUBST([OSMESA_LIB])
 847
 848 case "$mesa_driver" in
 849 osmesa)
 850     # only link libraries with osmesa if shared
 851     if test "$enable_static" = no; then
 852         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 853     else
 854         OSMESA_LIB_DEPS=""
 855     fi
 856     OSMESA_MESA_DEPS=""
 857     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS"
 858     ;;
 859 *)
 860     # Link OSMesa to libGL otherwise
 861     OSMESA_LIB_DEPS=""
 862     # only link libraries with osmesa if shared
 863     if test "$enable_static" = no; then
 864         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 865     else
 866         OSMESA_MESA_DEPS=""
 867     fi
 868     OSMESA_PC_REQ="gl"
 869     ;;
 870 esac
 871 if test "$enable_static" = no; then
 872     OSMESA_LIB_DEPS="$OSMESA_LIB_DEPS $OS_LIBS"
 873 fi
 874 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $OS_LIBS"
 875 AC_SUBST([OSMESA_LIB_DEPS])
 876 AC_SUBST([OSMESA_MESA_DEPS])
 877 AC_SUBST([OSMESA_PC_REQ])
 878 AC_SUBST([OSMESA_PC_LIB_PRIV])
 879
 880 dnl
 881 dnl EGL configuration
 882 dnl
 883 if test "$x11_pkgconfig" = yes; then
 884     PKG_CHECK_MODULES([EGL],[x11])
 885     EGL_LIB_DEPS="$EGL_LIBS"
 886 else
 887     # should check these...
 888     EGL_LIB_DEPS="$X_LIBS -lX11"
 889 fi
 890 EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS $OS_LIBS"
 891 AC_SUBST([EGL_LIB_DEPS])
 892
 893 dnl
 894 dnl GLU configuration
 895 dnl
 896 AC_ARG_ENABLE([glu],
 897     [AS_HELP_STRING([--disable-glu],
 898         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 899     [enable_glu="$enableval"],
 900     [enable_glu=yes])
 901 if test "x$enable_glu" = xyes; then
 902     SRC_DIRS="$SRC_DIRS glu"
 903
 904     case "$mesa_driver" in
 905     osmesa)
 906         # If GLU is available and we have libOSMesa (not 16 or 32),
 907         # we can build the osdemos
 908         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 909             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 910         fi
 911
 912         # Link libGLU to libOSMesa instead of libGL
 913         GLU_LIB_DEPS=""
 914         GLU_PC_REQ="osmesa"
 915         if test "$enable_static" = no; then
 916             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 917         else
 918             GLU_MESA_DEPS=""
 919         fi
 920         ;;
 921     *)
 922         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 923         GLU_PC_REQ="gl"
 924         GLU_PC_LIB_PRIV="-lm"
 925         if test "$enable_static" = no; then
 926             GLU_LIB_DEPS="-lm"
 927             GLU_MESA_DEPS='-l$(GL_LIB)'
 928         else
 929             GLU_LIB_DEPS=""
 930             GLU_MESA_DEPS=""
 931             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 932         fi
 933         ;;
 934     esac
 935 fi
 936 if test "$enable_static" = no; then
 937     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 938 fi
 939 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 940 AC_SUBST([GLU_LIB_DEPS])
 941 AC_SUBST([GLU_MESA_DEPS])
 942 AC_SUBST([GLU_PC_REQ])
 943 AC_SUBST([GLU_PC_REQ_PRIV])
 944 AC_SUBST([GLU_PC_LIB_PRIV])
 945 AC_SUBST([GLU_PC_CFLAGS])
 946
 947 dnl
 948 dnl GLw configuration
 949 dnl
 950 AC_ARG_ENABLE([glw],
 951     [AS_HELP_STRING([--disable-glw],
 952         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 953     [enable_glw="$enableval"],
 954     [enable_glw=yes])
 955 dnl Don't build GLw on osmesa
 956 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 957     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 958     enable_glw=no
 959 fi
 960 AC_ARG_ENABLE([motif],
 961     [AS_HELP_STRING([--enable-motif],
 962         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 963     [enable_motif="$enableval"],
 964     [enable_motif=no])
 965
 966 if test "x$enable_glw" = xyes; then
 967     SRC_DIRS="$SRC_DIRS glw"
 968     if test "$x11_pkgconfig" = yes; then
 969         PKG_CHECK_MODULES([GLW],[x11 xt])
 970         GLW_PC_REQ_PRIV="x11 xt"
 971         GLW_LIB_DEPS="$GLW_LIBS"
 972     else
 973         # should check these...
 974         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 975         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 976         GLW_PC_CFLAGS="$X11_INCLUDES"
 977     fi
 978
 979     GLW_SOURCES="GLwDrawA.c"
 980     MOTIF_CFLAGS=
 981     if test "x$enable_motif" = xyes; then
 982         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 983         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 984         if test "x$MOTIF_CONFIG" != xno; then
 985             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 986             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 987         else
 988             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 989                 [AC_MSG_ERROR([Can't locate Motif headers])])
 990             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 991                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 992         fi
 993         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 994         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 995         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 996         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 997     fi
 998
 999     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1000     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV $OS_LIBS"
1001     if test "$enable_static" = no; then
1002         GLW_MESA_DEPS='-l$(GL_LIB)'
1003         GLW_LIB_DEPS="$GLW_LIB_DEPS $OS_LIBS"
1004     else
1005         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1006         GLW_LIB_DEPS=""
1007         GLW_MESA_DEPS=""
1008     fi
1009 fi
1010 AC_SUBST([GLW_LIB_DEPS])
1011 AC_SUBST([GLW_MESA_DEPS])
1012 AC_SUBST([GLW_SOURCES])
1013 AC_SUBST([MOTIF_CFLAGS])
1014 AC_SUBST([GLW_PC_REQ_PRIV])
1015 AC_SUBST([GLW_PC_LIB_PRIV])
1016 AC_SUBST([GLW_PC_CFLAGS])
1017
1018 dnl
1019 dnl GLUT configuration
1020 dnl
1021 if test -f "$srcdir/include/GL/glut.h"; then
1022     default_glut=yes
1023 else
1024     default_glut=no
1025 fi
1026 AC_ARG_ENABLE([glut],
1027     [AS_HELP_STRING([--disable-glut],
1028         [enable GLUT library @<:@default=enabled if source available@:>@])],
1029     [enable_glut="$enableval"],
1030     [enable_glut="$default_glut"])
1031
1032 dnl Can't build glut if GLU not available
1033 if test "x$enable_glu$enable_glut" = xnoyes; then
1034     AC_MSG_WARN([Disabling glut since GLU is disabled])
1035     enable_glut=no
1036 fi
1037 dnl Don't build glut on osmesa
1038 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1039     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1040     enable_glut=no
1041 fi
1042
1043 if test "x$enable_glut" = xyes; then
1044     SRC_DIRS="$SRC_DIRS glut/glx"
1045     GLUT_CFLAGS=""
1046     if test "x$GCC" = xyes; then
1047         GLUT_CFLAGS="-fexceptions"
1048     fi
1049     if test "$x11_pkgconfig" = yes; then
1050         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1051         GLUT_PC_REQ_PRIV="x11 xmu xi"
1052         GLUT_LIB_DEPS="$GLUT_LIBS"
1053     else
1054         # should check these...
1055         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1056         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1057         GLUT_PC_CFLAGS="$X11_INCLUDES"
1058     fi
1059     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm $OS_LIBS"
1060     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm $OS_LIBS"
1061
1062     # If glut is available, we can build most programs
1063     if test "$with_demos" = yes; then
1064         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1065     fi
1066
1067     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1068     if test "$enable_static" = no; then
1069         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1070     else
1071         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1072         GLUT_LIB_DEPS=""
1073         GLUT_MESA_DEPS=""
1074     fi
1075 fi
1076 AC_SUBST([GLUT_LIB_DEPS])
1077 AC_SUBST([GLUT_MESA_DEPS])
1078 AC_SUBST([GLUT_CFLAGS])
1079 AC_SUBST([GLUT_PC_REQ_PRIV])
1080 AC_SUBST([GLUT_PC_LIB_PRIV])
1081 AC_SUBST([GLUT_PC_CFLAGS])
1082
1083 dnl
1084 dnl Program library dependencies
1085 dnl    Only libm is added here if necessary as the libraries should
1086 dnl    be pulled in by the linker
1087 dnl
1088 if test "x$APP_LIB_DEPS" = x; then
1089     case "$host_os" in
1090     solaris*)
1091         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1092         ;;
1093     *)
1094         APP_LIB_DEPS="-lm"
1095         ;;
1096     esac
1097 fi
1098 AC_SUBST([APP_LIB_DEPS])
1099 AC_SUBST([PROGRAM_DIRS])
1100
1101 dnl
1102 dnl Gallium configuration
1103 dnl
1104 AC_ARG_ENABLE([gallium],
1105     [AS_HELP_STRING([--disable-gallium],
1106         [build gallium @<:@default=enabled@:>@])],
1107     [enable_gallium="$enableval"],
1108     [enable_gallium=yes])
1109 if test "x$enable_gallium" = xyes; then
1110     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1111 fi
1112
1113 dnl
1114 dnl Gallium state trackers configuration
1115 dnl
1116 AC_ARG_WITH([state-trackers],
1117     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1118         [comma delimited state_trackers list, e.g.
1119         "egl,glx" @<:@default=auto@:>@])],
1120     [with_state_trackers="$withval"],
1121     [with_state_trackers=yes])
1122
1123 case "$with_state_trackers" in
1124 no)
1125     GALLIUM_STATE_TRACKERS_DIRS=""
1126     ;;
1127 yes)
1128     # look at what else is built
1129     case "$mesa_driver" in
1130     dri)
1131         GALLIUM_STATE_TRACKERS_DIRS=egl
1132         ;;
1133     esac
1134     ;;
1135 *)
1136     # verify the requested state tracker exist
1137     state_trackers=`IFS=', '; echo $with_state_trackers`
1138     for tracker in $state_trackers; do
1139         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1140             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1141     done
1142     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1143     ;;
1144 esac
1145
1146 AC_ARG_WITH([xorg-driver-dir],
1147     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1148                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1149     [XORG_DRIVER_INSTALL_DIR="$withval"],
1150     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1151 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1152
1153 dnl
1154 dnl Gallium Intel configuration
1155 dnl
1156 AC_ARG_ENABLE([gallium-intel],
1157     [AS_HELP_STRING([--disable-gallium-intel],
1158         [build gallium intel @<:@default=enabled@:>@])],
1159     [enable_gallium_intel="$enableval"],
1160     [enable_gallium_intel=yes])
1161 if test "x$enable_gallium_intel" = xyes; then
1162     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1163     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1164 fi
1165
1166 dnl
1167 dnl Gallium Radeon configuration
1168 dnl
1169 AC_ARG_ENABLE([gallium-radeon],
1170     [AS_HELP_STRING([--enable-gallium-radeon],
1171         [build gallium radeon @<:@default=disabled@:>@])],
1172     [enable_gallium_radeon="$enableval"],
1173     [enable_gallium_radeon=no])
1174 if test "x$enable_gallium_radeon" = xyes; then
1175     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1176     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1177 fi
1178
1179 dnl
1180 dnl Gallium Radeon configuration
1181 dnl
1182 AC_ARG_ENABLE([gallium-nouveau],
1183     [AS_HELP_STRING([--enable-gallium-nouveau],
1184         [build gallium nouveau @<:@default=disabled@:>@])],
1185     [enable_gallium_nouveau="$enableval"],
1186     [enable_gallium_nouveau=no])
1187 if test "x$enable_gallium_nouveau" = xyes; then
1188     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1189     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nv04 nv10 nv20 nv30 nv40 nv50"
1190 fi
1191
1192
1193 dnl Restore LDFLAGS and CPPFLAGS
1194 LDFLAGS="$_SAVE_LDFLAGS"
1195 CPPFLAGS="$_SAVE_CPPFLAGS"
1196
1197 dnl Substitute the config
1198 AC_CONFIG_FILES([configs/autoconf])
1199
1200 dnl Replace the configs/current symlink
1201 AC_CONFIG_COMMANDS([configs],[
1202 if test -f configs/current || test -L configs/current; then
1203     rm -f configs/current
1204 fi
1205 ln -s autoconf configs/current
1206 ])
1207
1208 AC_OUTPUT
1209
1210 dnl
1211 dnl Output some configuration info for the user
1212 dnl
1213 echo ""
1214 echo "        prefix:          $prefix"
1215 echo "        exec_prefix:     $exec_prefix"
1216 echo "        libdir:          $libdir"
1217 echo "        includedir:      $includedir"
1218
1219 dnl Driver info
1220 echo ""
1221 echo "        Driver:          $mesa_driver"
1222 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1223     echo "        OSMesa:          lib$OSMESA_LIB"
1224 else
1225     echo "        OSMesa:          no"
1226 fi
1227 if test "$mesa_driver" = dri; then
1228     # cleanup the drivers var
1229     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1230 if test "x$DRI_DIRS" = x; then
1231     echo "        DRI drivers:     no"
1232 else
1233     echo "        DRI drivers:     $dri_dirs"
1234 fi
1235     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1236 fi
1237 echo "        Use XCB:         $enable_xcb"
1238
1239 echo ""
1240 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1241     echo "        Gallium:         yes"
1242     echo "        Gallium dirs:    $GALLIUM_DIRS"
1243     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1244     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1245     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1246     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1247     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1248 else
1249     echo "        Gallium:         no"
1250 fi
1251
1252 dnl Libraries
1253 echo ""
1254 echo "        Shared libs:     $enable_shared"
1255 echo "        Static libs:     $enable_static"
1256 echo "        GLU:             $enable_glu"
1257 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1258 echo "        glut:            $enable_glut"
1259
1260 dnl Programs
1261 # cleanup the programs var for display
1262 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1263 if test "x$program_dirs" = x; then
1264     echo "        Demos:           no"
1265 else
1266     echo "        Demos:           $program_dirs"
1267 fi
1268
1269 dnl Compiler options
1270 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1271 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1272     $SED 's/^ *//;s/  */ /;s/ *$//'`
1273 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1274     $SED 's/^ *//;s/  */ /;s/ *$//'`
1275 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1276 echo ""
1277 echo "        CFLAGS:          $cflags"
1278 echo "        CXXFLAGS:        $cxxflags"
1279 echo "        Macros:          $defines"
1280
1281 echo ""
1282 echo "        Run '${MAKE-make}' to build Mesa"
1283 echo ""