configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 123
 124 dnl Make sure the pkg-config macros are defined
 125 m4_ifndef([PKG_PROG_PKG_CONFIG],
 126     [m4_fatal([Could not locate the pkg-config autoconf macros.
 127   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 128   are in a different location, try setting the environment variable
 129   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 130 PKG_PROG_PKG_CONFIG()
 131
 132 dnl LIB_DIR - library basename
 133 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 134 AC_SUBST([LIB_DIR])
 135
 136 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 137 _SAVE_LDFLAGS="$LDFLAGS"
 138 _SAVE_CPPFLAGS="$CPPFLAGS"
 139
 140 dnl Compiler macros
 141 DEFINES=""
 142 AC_SUBST([DEFINES])
 143 case "$host_os" in
 144 linux*|*-gnu*|gnu*)
 145     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 146     ;;
 147 solaris*)
 148     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 149     ;;
 150 cygwin*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD"
 152     ;;
 153 esac
 154
 155 dnl Add flags for gcc and g++
 156 if test "x$GCC" = xyes; then
 157     case "$host_os" in
 158     cygwin*)
 159         CFLAGS="$CFLAGS -Wall -std=gnu99"
 160         ;;
 161     *)
 162         CFLAGS="$CFLAGS -Wall -std=c99"
 163         ;;
 164     esac
 165
 166     # Enable -Werror=implicit-function-declaration and
 167     # -Werror=missing-prototypes, if available, or otherwise, just
 168     # -Wmissing-prototypes.  This is particularly useful to avoid
 169     # generating a loadable driver module that has undefined symbols.
 170     save_CFLAGS="$CFLAGS"
 171     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 172     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 173     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 174     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 175                    AC_MSG_RESULT([yes]),
 176                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 177                     AC_MSG_RESULT([no])]);
 178
 179     # Enable -fvisibility=hidden if using a gcc that supports it
 180     save_CFLAGS="$CFLAGS"
 181     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 182     VISIBILITY_CFLAGS="-fvisibility=hidden"
 183     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 185                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 186
 187     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 188     CFLAGS=$save_CFLAGS
 189
 190     # Work around aliasing bugs - developers should comment this out
 191     CFLAGS="$CFLAGS -fno-strict-aliasing"
 192
 193     # gcc's builtin memcmp is slower than glibc's
 194     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 195     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 196 fi
 197 if test "x$GXX" = xyes; then
 198     CXXFLAGS="$CXXFLAGS -Wall"
 199
 200     # Enable -fvisibility=hidden if using a gcc that supports it
 201     save_CXXFLAGS="$CXXFLAGS"
 202     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 203     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 204     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 205     AC_LANG_PUSH([C++])
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 208     AC_LANG_POP([C++])
 209
 210     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 211     CXXFLAGS=$save_CXXFLAGS
 212
 213     # Work around aliasing bugs - developers should comment this out
 214     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 215
 216     # gcc's builtin memcmp is slower than glibc's
 217     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 218     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 219 fi
 220
 221 dnl even if the compiler appears to support it, using visibility attributes isn't
 222 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 223 case "$host_os" in
 224 cygwin*)
 225     VISIBILITY_CFLAGS=""
 226     VISIBILITY_CXXFLAGS=""
 227     ;;
 228 esac
 229
 230 AC_SUBST([VISIBILITY_CFLAGS])
 231 AC_SUBST([VISIBILITY_CXXFLAGS])
 232
 233 dnl
 234 dnl Optional flags, check for compiler support
 235 dnl
 236 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 237 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 287
 288 dnl
 289 dnl other compiler options
 290 dnl
 291 AC_ARG_ENABLE([debug],
 292     [AS_HELP_STRING([--enable-debug],
 293         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 294     [enable_debug="$enableval"],
 295     [enable_debug=no]
 296 )
 297 if test "x$enable_debug" = xyes; then
 298     DEFINES="$DEFINES -DDEBUG"
 299     if test "x$GCC" = xyes; then
 300         CFLAGS="$CFLAGS -g -O0"
 301     fi
 302     if test "x$GXX" = xyes; then
 303         CXXFLAGS="$CXXFLAGS -g -O0"
 304     fi
 305 fi
 306
 307 dnl
 308 dnl library names
 309 dnl
 310 LIB_PREFIX_GLOB='lib'
 311 LIB_VERSION_SEPARATOR='.'
 312 if test "$enable_static" = yes; then
 313     LIB_EXTENSION='a'
 314 else
 315     case "$host_os" in
 316     darwin* )
 317         LIB_EXTENSION='dylib' ;;
 318     cygwin* )
 319         dnl prefix can be 'cyg' or 'lib'
 320         LIB_PREFIX_GLOB='???'
 321         LIB_VERSION_SEPARATOR='-'
 322         LIB_EXTENSION='dll' ;;
 323     aix* )
 324         LIB_EXTENSION='a' ;;
 325     * )
 326         LIB_EXTENSION='so' ;;
 327     esac
 328 fi
 329 AC_ARG_WITH([gl-lib-name],
 330   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 331     [specify GL library name @<:@default=GL@:>@])],
 332   [GL_LIB=$withval],
 333   [GL_LIB=GL])
 334 AC_ARG_WITH([osmesa-lib-name],
 335   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 336     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 337   [OSMESA_LIB=$withval],
 338   [OSMESA_LIB=OSMesa])
 339 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 340 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 341
 342 dnl
 343 dnl Mangled Mesa support
 344 dnl
 345 AC_ARG_ENABLE([mangling],
 346   [AS_HELP_STRING([--enable-mangling],
 347     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 348   [enable_mangling="${enableval}"],
 349   [enable_mangling=no]
 350 )
 351 if test "x${enable_mangling}" = "xyes" ; then
 352   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 353   GL_LIB="Mangled${GL_LIB}"
 354   OSMESA_LIB="Mangled${OSMESA_LIB}"
 355 fi
 356 AC_SUBST([GL_LIB])
 357 AC_SUBST([OSMESA_LIB])
 358
 359 dnl
 360 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 361 dnl
 362 AC_ARG_ENABLE([texture-float],
 363     [AS_HELP_STRING([--enable-texture-float],
 364         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 365     [enable_texture_float="$enableval"],
 366     [enable_texture_float=no]
 367 )
 368 if test "x$enable_texture_float" = xyes; then
 369     AC_MSG_WARN([Floating-point textures enabled.])
 370     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 371     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 372 fi
 373
 374 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 375 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 376 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 377 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 378 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 379 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 380 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 381
 382 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 387 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 388 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 389
 390 AC_SUBST([GL_LIB_NAME])
 391 AC_SUBST([OSMESA_LIB_NAME])
 392 AC_SUBST([EGL_LIB_NAME])
 393 AC_SUBST([GLESv1_CM_LIB_NAME])
 394 AC_SUBST([GLESv2_LIB_NAME])
 395 AC_SUBST([VG_LIB_NAME])
 396 AC_SUBST([GLAPI_LIB_NAME])
 397
 398 AC_SUBST([GL_LIB_GLOB])
 399 AC_SUBST([EGL_LIB_GLOB])
 400 AC_SUBST([GLESv1_CM_LIB_GLOB])
 401 AC_SUBST([GLESv2_LIB_GLOB])
 402 AC_SUBST([VG_LIB_GLOB])
 403 AC_SUBST([GLAPI_LIB_GLOB])
 404
 405 dnl
 406 dnl Arch/platform-specific settings
 407 dnl
 408 AC_ARG_ENABLE([asm],
 409     [AS_HELP_STRING([--disable-asm],
 410         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 411     [enable_asm="$enableval"],
 412     [enable_asm=yes]
 413 )
 414 asm_arch=""
 415 AC_MSG_CHECKING([whether to enable assembly])
 416 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 417 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 418 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 419     case "$host_cpu" in
 420     i?86 | x86_64 | amd64)
 421         enable_asm=no
 422         AC_MSG_RESULT([no, cross compiling])
 423         ;;
 424     esac
 425 fi
 426 # check for supported arches
 427 if test "x$enable_asm" = xyes; then
 428     case "$host_cpu" in
 429     i?86)
 430         case "$host_os" in
 431         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 432             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 433             ;;
 434         gnu*)
 435             asm_arch=x86
 436             ;;
 437         esac
 438         ;;
 439     x86_64|amd64)
 440         case "$host_os" in
 441         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 442             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 443             ;;
 444         esac
 445         ;;
 446     sparc*)
 447         case "$host_os" in
 448         linux*)
 449             asm_arch=sparc
 450             ;;
 451         esac
 452         ;;
 453     esac
 454
 455     case "$asm_arch" in
 456     x86)
 457         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 458         AC_MSG_RESULT([yes, x86])
 459         ;;
 460     x86_64|amd64)
 461         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 462         AC_MSG_RESULT([yes, x86_64])
 463         ;;
 464     sparc)
 465         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 466         AC_MSG_RESULT([yes, sparc])
 467         ;;
 468     *)
 469         AC_MSG_RESULT([no, platform not supported])
 470         ;;
 471     esac
 472 fi
 473
 474 dnl Check to see if dlopen is in default libraries (like Solaris, which
 475 dnl has it in libc), or if libdl is needed to get it.
 476 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 477     [AC_CHECK_LIB([dl], [dlopen],
 478        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 479 AC_SUBST([DLOPEN_LIBS])
 480
 481 case "$host_os" in
 482 darwin*|mingw*)
 483     ;;
 484 *)
 485     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 486                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 487                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 488     AC_SUBST([CLOCK_LIB])
 489     ;;
 490 esac
 491
 492 dnl See if posix_memalign is available
 493 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 494
 495 dnl Check for pthreads
 496 AX_PTHREAD
 497 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 498 dnl to -pthread, which causes problems if we need -lpthread to appear in
 499 dnl pkgconfig files.
 500 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 501
 502 dnl SELinux awareness.
 503 AC_ARG_ENABLE([selinux],
 504     [AS_HELP_STRING([--enable-selinux],
 505         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 506     [MESA_SELINUX="$enableval"],
 507     [MESA_SELINUX=no])
 508 if test "x$enable_selinux" = "xyes"; then
 509     AC_CHECK_HEADER([selinux/selinux.h],[],
 510                     [AC_MSG_ERROR([SELinux headers not found])])
 511     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 512                  [AC_MSG_ERROR([SELinux library not found])])
 513     SELINUX_LIBS="-lselinux"
 514     DEFINES="$DEFINES -DMESA_SELINUX"
 515 fi
 516 AC_SUBST([SELINUX_LIBS])
 517
 518 dnl Options for APIs
 519 AC_ARG_ENABLE([opengl],
 520     [AS_HELP_STRING([--disable-opengl],
 521         [disable support for standard OpenGL API @<:@default=no@:>@])],
 522     [enable_opengl="$enableval"],
 523     [enable_opengl=yes])
 524 AC_ARG_ENABLE([gles1],
 525     [AS_HELP_STRING([--enable-gles1],
 526         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 527     [enable_gles1="$enableval"],
 528     [enable_gles1=no])
 529 AC_ARG_ENABLE([gles2],
 530     [AS_HELP_STRING([--enable-gles2],
 531         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 532     [enable_gles2="$enableval"],
 533     [enable_gles2=no])
 534 AC_ARG_ENABLE([openvg],
 535     [AS_HELP_STRING([--enable-openvg],
 536         [enable support for OpenVG API @<:@default=no@:>@])],
 537     [enable_openvg="$enableval"],
 538     [enable_openvg=no])
 539
 540 AC_ARG_ENABLE([dri],
 541     [AS_HELP_STRING([--enable-dri],
 542         [enable DRI modules @<:@default=enabled@:>@])],
 543     [enable_dri="$enableval"],
 544     [enable_dri=yes])
 545 AC_ARG_ENABLE([dri3],
 546     [AS_HELP_STRING([--enable-dri3],
 547         [enable DRI3 @<:@default=enabled@:>@])],
 548     [enable_dri3="$enableval"],
 549     [enable_dri3=yes])
 550 AC_ARG_ENABLE([glx],
 551     [AS_HELP_STRING([--enable-glx],
 552         [enable GLX library @<:@default=enabled@:>@])],
 553     [enable_glx="$enableval"],
 554     [enable_glx=yes])
 555 AC_ARG_ENABLE([osmesa],
 556     [AS_HELP_STRING([--enable-osmesa],
 557         [enable OSMesa library @<:@default=disabled@:>@])],
 558     [enable_osmesa="$enableval"],
 559     [enable_osmesa=no])
 560 AC_ARG_ENABLE([gallium-osmesa],
 561     [AS_HELP_STRING([--enable-gallium-osmesa],
 562         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 563     [enable_gallium_osmesa="$enableval"],
 564     [enable_gallium_osmesa=no])
 565 AC_ARG_ENABLE([egl],
 566     [AS_HELP_STRING([--disable-egl],
 567         [disable EGL library @<:@default=enabled@:>@])],
 568     [enable_egl="$enableval"],
 569     [enable_egl=yes])
 570
 571 AC_ARG_ENABLE([xa],
 572     [AS_HELP_STRING([--enable-xa],
 573         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 574     [enable_xa="$enableval"],
 575     [enable_xa=no])
 576 AC_ARG_ENABLE([gbm],
 577    [AS_HELP_STRING([--enable-gbm],
 578          [enable gbm library @<:@default=auto@:>@])],
 579    [enable_gbm="$enableval"],
 580    [enable_gbm=auto])
 581
 582 AC_ARG_ENABLE([xvmc],
 583    [AS_HELP_STRING([--enable-xvmc],
 584          [enable xvmc library @<:@default=auto@:>@])],
 585    [enable_xvmc="$enableval"],
 586    [enable_xvmc=no])
 587 AC_ARG_ENABLE([vdpau],
 588    [AS_HELP_STRING([--enable-vdpau],
 589          [enable vdpau library @<:@default=auto@:>@])],
 590    [enable_vdpau="$enableval"],
 591    [enable_vdpau=auto])
 592 AC_ARG_ENABLE([omx],
 593    [AS_HELP_STRING([--enable-omx],
 594          [enable OpenMAX library @<:@default=no@:>@])],
 595    [enable_omx="$enableval"],
 596    [enable_omx=no])
 597 AC_ARG_ENABLE([opencl],
 598    [AS_HELP_STRING([--enable-opencl],
 599          [enable OpenCL library NOTE: Enabling this option will also enable
 600           --with-llvm-shared-libs
 601           @<:@default=no@:>@])],
 602    [],
 603    [enable_opencl=no])
 604 AC_ARG_ENABLE([opencl_icd],
 605    [AS_HELP_STRING([--enable-opencl-icd],
 606           [Build an OpenCL ICD library to be loaded by an ICD implementation
 607            @<:@default=no@:>@])],
 608     [enable_opencl_icd="$enableval"],
 609     [enable_opencl_icd=no])
 610 AC_ARG_ENABLE([xlib-glx],
 611     [AS_HELP_STRING([--enable-xlib-glx],
 612         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 613     [enable_xlib_glx="$enableval"],
 614     [enable_xlib_glx=no])
 615 AC_ARG_ENABLE([gallium-egl],
 616     [AS_HELP_STRING([--enable-gallium-egl],
 617         [enable optional EGL state tracker (not required
 618          for EGL support in Gallium with OpenGL and OpenGL ES)
 619          @<:@default=disable@:>@])],
 620     [enable_gallium_egl="$enableval"],
 621     [enable_gallium_egl=no])
 622 AC_ARG_ENABLE([gallium-gbm],
 623     [AS_HELP_STRING([--enable-gallium-gbm],
 624         [enable optional gbm state tracker (not required for
 625          gbm support in Gallium)
 626          @<:@default=auto@:>@])],
 627     [enable_gallium_gbm="$enableval"],
 628     [enable_gallium_gbm=auto])
 629
 630 AC_ARG_ENABLE([r600-llvm-compiler],
 631     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 632         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 633     [enable_r600_llvm="$enableval"],
 634     [enable_r600_llvm=no])
 635
 636 AC_ARG_ENABLE([gallium-tests],
 637     [AS_HELP_STRING([--enable-gallium-tests],
 638         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 639     [enable_gallium_tests="$enableval"],
 640     [enable_gallium_tests=no])
 641
 642 # Option for Gallium drivers
 643
 644 # Keep this in sync with the --with-gallium-drivers help string default value
 645 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 646
 647 AC_ARG_WITH([gallium-drivers],
 648     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 649         [comma delimited Gallium drivers list, e.g.
 650         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 651         @<:@default=r300,r600,svga,swrast@:>@])],
 652     [with_gallium_drivers="$withval"],
 653     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 654
 655 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 656 # here so that the script doesn't choke on an unknown driver name later.
 657 case "$with_gallium_drivers" in
 658     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 659     no) with_gallium_drivers='' ;;
 660 esac
 661
 662 if test "x$enable_opengl" = xno -a \
 663         "x$enable_gles1" = xno -a \
 664         "x$enable_gles2" = xno -a \
 665         "x$enable_openvg" = xno -a \
 666         "x$enable_xa" = xno -a \
 667         "x$enable_xvmc" = xno -a \
 668         "x$enable_vdpau" = xno -a \
 669         "x$enable_omx" = xno -a \
 670         "x$enable_opencl" = xno; then
 671     AC_MSG_ERROR([at least one API should be enabled])
 672 fi
 673
 674 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 675 if test "x$enable_opengl" = xno -a \
 676         "x$enable_gles1" = xyes; then
 677     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 678 fi
 679
 680 if test "x$enable_opengl" = xno -a \
 681         "x$enable_gles2" = xyes; then
 682     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 683 fi
 684
 685 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 686 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 687 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 688 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 689                                         "x$enable_gles1" = xyes -o \
 690                                         "x$enable_gles2" = xyes)
 691
 692 if test "x$enable_glx" = xno; then
 693     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 694     enable_xlib_glx=no
 695 fi
 696
 697 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 698     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 699 fi
 700
 701 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 702     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 703 fi
 704
 705 # Disable GLX if OpenGL is not enabled
 706 if test "x$enable_glx$enable_opengl" = xyesno; then
 707     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 708     enable_glx=no
 709 fi
 710
 711 # Disable GLX if DRI and Xlib-GLX are not enabled
 712 if test "x$enable_glx" = xyes -a \
 713         "x$enable_dri" = xno -a \
 714         "x$enable_xlib_glx" = xno; then
 715     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 716     enable_glx=no
 717 fi
 718
 719 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 720                                   "x$enable_dri" = xyes)
 721 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 722 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 723
 724 AC_ARG_ENABLE([shared-glapi],
 725     [AS_HELP_STRING([--enable-shared-glapi],
 726         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 727     [enable_shared_glapi="$enableval"],
 728     [enable_shared_glapi="$enable_dri"])
 729
 730 # Shared GLAPI is only useful for DRI
 731 if test "x$enable_dri" = xno; then
 732     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 733     enable_shared_glapi=no
 734 fi
 735
 736 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 737
 738 dnl
 739 dnl Driver specific build directories
 740 dnl
 741 GALLIUM_TARGET_DIRS=""
 742 GALLIUM_WINSYS_DIRS="sw"
 743 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 744 GALLIUM_STATE_TRACKERS_DIRS=""
 745
 746 case "x$enable_glx$enable_xlib_glx" in
 747 xyesyes)
 748     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 749     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 750     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 751     NEED_WINSYS_XLIB="yes"
 752     ;;
 753 esac
 754
 755 if test "x$enable_dri" = xyes; then
 756     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 757     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 758 fi
 759
 760 if test "x$enable_gallium_osmesa" = xyes; then
 761     if test -z "$with_gallium_drivers"; then
 762         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 763     fi
 764     if test "x$enable_osmesa" = xyes; then
 765         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 766     fi
 767     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 768     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 769 fi
 770
 771 AC_SUBST([MESA_LLVM])
 772
 773 # Check for libdrm
 774 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 775                   [have_libdrm=yes], [have_libdrm=no])
 776 if test "x$have_libdrm" = xyes; then
 777         DEFINES="$DEFINES -DHAVE_LIBDRM"
 778 fi
 779
 780 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 781                   have_libudev=yes, have_libudev=no)
 782
 783 if test "x$enable_dri" = xyes; then
 784     # DRI must be shared, I think
 785     if test "$enable_static" = yes; then
 786         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 787     fi
 788
 789     # not a hard requirement as swrast does not depend on it
 790     if test "x$have_libdrm" = xyes; then
 791         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 792     fi
 793 fi
 794
 795 dnl Direct rendering or just indirect rendering
 796 case "$host_os" in
 797 gnu*)
 798     dnl Disable by default on GNU/Hurd
 799     driglx_direct_default="no"
 800     ;;
 801 cygwin*)
 802     dnl Disable by default on cygwin
 803     driglx_direct_default="no"
 804     ;;
 805 *)
 806     driglx_direct_default="yes"
 807     ;;
 808 esac
 809 AC_ARG_ENABLE([driglx-direct],
 810     [AS_HELP_STRING([--disable-driglx-direct],
 811         [disable direct rendering in GLX and EGL for DRI \
 812             @<:@default=auto@:>@])],
 813     [driglx_direct="$enableval"],
 814     [driglx_direct="$driglx_direct_default"])
 815
 816 dnl
 817 dnl libGL configuration per driver
 818 dnl
 819 case "x$enable_glx$enable_xlib_glx" in
 820 xyesyes)
 821     # Xlib-based GLX
 822     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 823     GL_PC_REQ_PRIV="x11 xext"
 824     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 825     GL_LIB_DEPS="$XLIBGL_LIBS"
 826     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 827     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 828     ;;
 829 xyesno)
 830     # DRI-based GLX
 831     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 832     if test x"$driglx_direct" = xyes; then
 833         if test "x$have_libdrm" != xyes; then
 834             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 835         fi
 836         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 837         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 838         if test x"$enable_dri3" = xyes; then
 839             if test x"$have_libudev" != xyes; then
 840               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 841             fi
 842             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 843             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 844         fi
 845     fi
 846
 847     # find the DRI deps for libGL
 848     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 849
 850     if test x"$enable_dri3" = xyes; then
 851         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= 1.1"
 852     fi
 853
 854     # add xf86vidmode if available
 855     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 856     if test "$HAVE_XF86VIDMODE" = yes ; then
 857         dri_modules="$dri_modules xxf86vm"
 858     fi
 859
 860     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 861     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 862     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 863     GL_LIB_DEPS="$DRIGL_LIBS"
 864
 865     # need DRM libs, $PTHREAD_LIBS, etc.
 866     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 868     ;;
 869 esac
 870
 871 if test "$have_libudev" = yes; then
 872     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 873 fi
 874
 875 # This is outside the case (above) so that it is invoked even for non-GLX
 876 # builds.
 877 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 878
 879 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 880 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 881 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 882 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 883
 884 AC_SUBST([X11_INCLUDES])
 885 AC_SUBST([GL_LIB_DEPS])
 886 AC_SUBST([GL_PC_REQ_PRIV])
 887 AC_SUBST([GL_PC_LIB_PRIV])
 888 AC_SUBST([GL_PC_CFLAGS])
 889 AC_SUBST([DRI_PC_REQ_PRIV])
 890 AC_SUBST([GLESv1_CM_LIB_DEPS])
 891 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 892 AC_SUBST([GLESv2_LIB_DEPS])
 893 AC_SUBST([GLESv2_PC_LIB_PRIV])
 894
 895 AC_SUBST([HAVE_XF86VIDMODE])
 896
 897 dnl
 898 dnl More GLX setup
 899 dnl
 900 case "x$enable_glx$enable_xlib_glx" in
 901 xyesyes)
 902     DEFINES="$DEFINES -DUSE_XSHM"
 903     ;;
 904 xyesno)
 905     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 906     if test "x$driglx_direct" = xyes; then
 907         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 908     fi
 909     ;;
 910 esac
 911
 912 dnl
 913 dnl TLS detection
 914 dnl
 915
 916 AC_ARG_ENABLE([glx-tls],
 917     [AS_HELP_STRING([--enable-glx-tls],
 918         [enable TLS support in GLX @<:@default=disabled@:>@])],
 919     [GLX_USE_TLS="$enableval"],
 920     [GLX_USE_TLS=no])
 921 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 922
 923 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 924       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 925
 926 dnl
 927 dnl More DRI setup
 928 dnl
 929 dnl Directory for DRI drivers
 930 AC_ARG_WITH([dri-driverdir],
 931     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 932         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 933     [DRI_DRIVER_INSTALL_DIR="$withval"],
 934     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 935 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 936 dnl Extra search path for DRI drivers
 937 AC_ARG_WITH([dri-searchpath],
 938     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 939         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 940     [DRI_DRIVER_SEARCH_DIR="$withval"],
 941     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 942 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 943 dnl Which drivers to build - default is chosen by platform
 944 AC_ARG_WITH([dri-drivers],
 945     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 946         [comma delimited DRI drivers list, e.g.
 947         "swrast,i965,radeon" @<:@default=auto@:>@])],
 948     [with_dri_drivers="$withval"],
 949     [with_dri_drivers=yes])
 950 if test "x$with_dri_drivers" = x; then
 951     with_dri_drivers=no
 952 fi
 953
 954 dnl If $with_dri_drivers is yes, directories will be added through
 955 dnl platform checks
 956 DRI_DIRS=""
 957 case "$with_dri_drivers" in
 958 no) ;;
 959 yes)
 960     # classic DRI drivers
 961     if test "x$enable_opengl" = xyes; then
 962         DRI_DIRS="yes"
 963     fi
 964     ;;
 965 *)
 966     # verify the requested driver directories exist
 967     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 968     for driver in $dri_drivers; do
 969         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 970             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 971     done
 972     DRI_DIRS="$dri_drivers"
 973     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 974         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 975     fi
 976     ;;
 977 esac
 978
 979 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 980 if test "x$enable_dri" = xyes; then
 981     # Platform specific settings and drivers to build
 982     case "$host_os" in
 983     linux*)
 984         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 985         DEFINES="$DEFINES -DHAVE_ALIAS"
 986         if test "x$enable_dri3" = xyes; then
 987             DEFINES="$DEFINES -DHAVE_DRI3"
 988         fi
 989
 990         case "$host_cpu" in
 991         x86_64|amd64)
 992             if test "x$DRI_DIRS" = "xyes"; then
 993                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 994             fi
 995             ;;
 996         powerpc*)
 997             # Build only the drivers for cards that exist on PowerPC.
 998             if test "x$DRI_DIRS" = "xyes"; then
 999                 DRI_DIRS="r200 radeon swrast"
1000             fi
1001             ;;
1002         sparc*)
1003             # Build only the drivers for cards that exist on sparc
1004             if test "x$DRI_DIRS" = "xyes"; then
1005                 DRI_DIRS="r200 radeon swrast"
1006             fi
1007             ;;
1008         esac
1009         ;;
1010     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1011         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1012         DEFINES="$DEFINES -DHAVE_ALIAS"
1013
1014         if test "x$DRI_DIRS" = "xyes"; then
1015             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1016         fi
1017         ;;
1018     gnu*)
1019         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1020         DEFINES="$DEFINES -DHAVE_ALIAS"
1021         ;;
1022     solaris*)
1023         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1024         ;;
1025     cygwin*)
1026         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1027         if test "x$DRI_DIRS" = "xyes"; then
1028             DRI_DIRS="swrast"
1029         fi
1030         ;;
1031     esac
1032
1033     # default drivers
1034     if test "x$DRI_DIRS" = "xyes"; then
1035         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1036     fi
1037
1038     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1039
1040     # Check for expat
1041     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1042     if test "x$have_expat" = "xyes"; then
1043        PKG_CHECK_MODULES([EXPAT], [expat], [],
1044                          AC_MSG_ERROR([Expat required for DRI.]))
1045     else
1046        # expat version 2.0 and earlier do not provide expat.pc
1047        EXPAT_LIBS=-lexpat
1048     fi
1049
1050     # If we are building any DRI driver other than swrast.
1051     if test -n "$DRI_DIRS"; then
1052         if test x"$DRI_DIRS" != xswrast; then
1053             # ... libdrm is required
1054             if test "x$have_libdrm" != xyes; then
1055                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1056             fi
1057             DRICOMMON_NEED_LIBDRM=yes
1058         else
1059             DRICOMMON_NEED_LIBDRM=no
1060         fi
1061     fi
1062
1063     # put all the necessary libs together
1064     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1065     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1066
1067 fi
1068
1069 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1070 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1071                                   "x$enable_osmesa" = xyes -o \
1072                                   -n "$DRI_DIRS")
1073 AC_SUBST([DRI_LIB_DEPS])
1074 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1075
1076 case $DRI_DIRS in
1077 *i915*|*i965*)
1078     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1079
1080     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1081         case $d in
1082         i915)
1083             HAVE_I915_DRI=yes;
1084             ;;
1085         i965)
1086             HAVE_I965_DRI=yes;
1087             ;;
1088         esac
1089     done
1090
1091     ;;
1092 esac
1093
1094 case $DRI_DIRS in
1095 *nouveau*)
1096     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1097     HAVE_NOUVEAU_DRI=yes;
1098     ;;
1099 esac
1100
1101 case $DRI_DIRS in
1102 *radeon*|*r200*)
1103     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1104
1105     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1106         case $d in
1107         radeon)
1108             HAVE_RADEON_DRI=yes;
1109             ;;
1110         r200)
1111             HAVE_R200_DRI=yes;
1112             ;;
1113         esac
1114     done
1115
1116     ;;
1117 esac
1118
1119 case $DRI_DIRS in
1120 *swrast*)
1121     HAVE_SWRAST_DRI=yes;
1122     ;;
1123 esac
1124
1125 dnl
1126 dnl OSMesa configuration
1127 dnl
1128
1129 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1130 AC_ARG_WITH([osmesa-bits],
1131     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1132         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1133     [osmesa_bits="$withval"],
1134     [osmesa_bits=8])
1135 if test "x$osmesa_bits" != x8; then
1136     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1137         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1138         osmesa_bits=8
1139     fi
1140 fi
1141 case "x$osmesa_bits" in
1142 x8)
1143     OSMESA_LIB="${OSMESA_LIB}"
1144     ;;
1145 x16|x32)
1146     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1147     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1148     ;;
1149 *)
1150     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1151     ;;
1152 esac
1153
1154 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1155     # only link libraries with osmesa if shared
1156     if test "$enable_static" = no; then
1157         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1158     else
1159         OSMESA_LIB_DEPS=""
1160     fi
1161     OSMESA_MESA_DEPS=""
1162     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1163 fi
1164
1165 AC_SUBST([OSMESA_LIB_DEPS])
1166 AC_SUBST([OSMESA_MESA_DEPS])
1167 AC_SUBST([OSMESA_PC_REQ])
1168 AC_SUBST([OSMESA_PC_LIB_PRIV])
1169
1170 dnl
1171 dnl gbm configuration
1172 dnl
1173 if test "x$enable_gbm" = xauto; then
1174     case "$with_egl_platforms" in
1175         *drm*)
1176             enable_gbm=yes ;;
1177          *)
1178             enable_gbm=no ;;
1179     esac
1180 fi
1181 if test "x$enable_gbm" = xyes; then
1182     if test x"$have_libudev" != xyes; then
1183         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1184     fi
1185
1186     if test "x$enable_dri" = xyes; then
1187         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1188         if test "x$enable_shared_glapi" = xno; then
1189             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1190         fi
1191     fi
1192 fi
1193 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1194 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1195 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1196 AC_SUBST([GBM_PC_REQ_PRIV])
1197 AC_SUBST([GBM_PC_LIB_PRIV])
1198
1199 dnl
1200 dnl EGL configuration
1201 dnl
1202 EGL_CLIENT_APIS=""
1203
1204 if test "x$enable_egl" = xyes; then
1205     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1206
1207     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1208
1209     if test "$enable_static" != yes; then
1210         if test "x$enable_dri" = xyes; then
1211             HAVE_EGL_DRIVER_DRI2=1
1212         fi
1213
1214     fi
1215 fi
1216 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1217 AC_SUBST([EGL_LIB_DEPS])
1218
1219 dnl
1220 dnl EGL Gallium configuration
1221 dnl
1222 if test "x$enable_gallium_egl" = xyes; then
1223     if test "x$with_gallium_drivers" = x; then
1224         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1225     fi
1226     if test "x$enable_egl" = xno; then
1227         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1228     fi
1229     if test "x$have_libdrm" != xyes; then
1230         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1231     fi
1232
1233     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1234     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1235 fi
1236 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1237
1238 dnl
1239 dnl gbm Gallium configuration
1240 dnl
1241 if test "x$enable_gallium_gbm" = xauto; then
1242     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1243         yesyesyes*drm*)
1244             enable_gallium_gbm=yes ;;
1245          *)
1246             enable_gallium_gbm=no ;;
1247     esac
1248 fi
1249 if test "x$enable_gallium_gbm" = xyes; then
1250     if test "x$with_gallium_drivers" = x; then
1251         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1252     fi
1253     if test "x$enable_gbm" = xno; then
1254         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1255     fi
1256     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1257     if test "x$enable_dri" = xno; then
1258         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1259     fi
1260
1261     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1262     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1263     enable_gallium_loader=yes
1264 fi
1265 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1266
1267 dnl
1268 dnl XA configuration
1269 dnl
1270 if test "x$enable_xa" = xyes; then
1271     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1272     enable_gallium_loader=yes
1273 fi
1274 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1275
1276 dnl
1277 dnl OpenVG configuration
1278 dnl
1279 VG_LIB_DEPS=""
1280
1281 if test "x$enable_openvg" = xyes; then
1282     if test "x$enable_egl" = xno; then
1283         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1284     fi
1285     if test "x$with_gallium_drivers" = x; then
1286         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1287     fi
1288     if test "x$enable_gallium_egl" = xno; then
1289         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1290     fi
1291
1292     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1293     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1294     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1295     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1296     AC_SUBST([VG_PC_LIB_PRIV])
1297 fi
1298 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1299
1300 dnl
1301 dnl Gallium G3DVL configuration
1302 dnl
1303 if test -n "$with_gallium_drivers"; then
1304     if test "x$enable_xvmc" = xauto; then
1305         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1306     fi
1307
1308     if test "x$enable_vdpau" = xauto; then
1309         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1310     fi
1311
1312     if test "x$enable_omx" = xauto; then
1313         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1314     fi
1315 fi
1316
1317 if test "x$enable_xvmc" = xyes; then
1318     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1319     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1320 fi
1321 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1322
1323 if test "x$enable_vdpau" = xyes; then
1324     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1325     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1326 fi
1327 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1328
1329 if test "x$enable_omx" = xyes; then
1330     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= 0.0 x11-xcb xcb-dri2 >= 1.8])
1331     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1332 fi
1333 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1334
1335 dnl
1336 dnl OpenCL configuration
1337 dnl
1338
1339 AC_ARG_WITH([libclc-path],
1340    [AS_HELP_STRING([--with-libclc-path],
1341          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1342    [LIBCLC_PATH="$withval"],
1343    [LIBCLC_PATH=""])
1344
1345 if test "x$LIBCLC_PATH" != x; then
1346    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1347                   Please review the updated build instructions for clover:
1348                   http://dri.freedesktop.org/wiki/GalliumCompute])
1349 fi
1350
1351
1352 AC_ARG_WITH([clang-libdir],
1353    [AS_HELP_STRING([--with-clang-libdir],
1354          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1355    [CLANG_LIBDIR="$withval"],
1356    [CLANG_LIBDIR=""])
1357
1358 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1359
1360 if test "x$enable_opencl" = xyes; then
1361     if test "x$with_gallium_drivers" = x; then
1362         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1363     fi
1364
1365     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1366         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1367     fi
1368
1369     if test "x$have_libclc" = xno; then
1370         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1371                     Make sure the directory containing libclc.pc is specified in your
1372                     PKG_CONFIG_PATH environment variable.
1373                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1374     else
1375         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1376         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1377         AC_SUBST([LIBCLC_INCLUDEDIR])
1378         AC_SUBST([LIBCLC_LIBEXECDIR])
1379     fi
1380
1381     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1382     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1383     enable_gallium_loader=yes
1384
1385     if test "x$enable_opencl_icd" = xyes; then
1386         OPENCL_LIBNAME="MesaOpenCL"
1387     else
1388         OPENCL_LIBNAME="OpenCL"
1389     fi
1390 fi
1391 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1392 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1393 AC_SUBST([OPENCL_LIBNAME])
1394
1395 dnl
1396 dnl Gallium configuration
1397 dnl
1398 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1399
1400 AC_SUBST([LLVM_BINDIR])
1401 AC_SUBST([LLVM_CFLAGS])
1402 AC_SUBST([LLVM_CPPFLAGS])
1403 AC_SUBST([LLVM_CXXFLAGS])
1404 AC_SUBST([LLVM_LIBDIR])
1405 AC_SUBST([LLVM_LIBS])
1406 AC_SUBST([LLVM_LDFLAGS])
1407 AC_SUBST([LLVM_INCLUDEDIR])
1408 AC_SUBST([LLVM_VERSION])
1409 AC_SUBST([CLANG_RESOURCE_DIR])
1410
1411 case "x$enable_opengl$enable_gles1$enable_gles2" in
1412 x*yes*)
1413     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1414     ;;
1415 esac
1416
1417 AC_SUBST([VG_LIB_DEPS])
1418 AC_SUBST([EGL_CLIENT_APIS])
1419
1420 dnl
1421 dnl EGL Platforms configuration
1422 dnl
1423 AC_ARG_WITH([egl-platforms],
1424     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1425         [comma delimited native platforms libEGL supports, e.g.
1426         "x11,drm" @<:@default=auto@:>@])],
1427     [with_egl_platforms="$withval"],
1428     [if test "x$enable_egl" = xyes; then
1429         with_egl_platforms="x11"
1430     else
1431         with_egl_platforms=""
1432     fi])
1433
1434 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1435     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1436 fi
1437
1438 # Do per-EGL platform setups and checks
1439 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1440 for plat in $egl_platforms; do
1441         case "$plat" in
1442         wayland)
1443                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1444                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1445
1446                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1447                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1448                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1449                 ;;
1450
1451         x11)
1452                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1453                 ;;
1454
1455         drm)
1456                 test "x$enable_gbm" = "xno" &&
1457                         AC_MSG_ERROR([EGL platform drm needs gbm])
1458                 test "x$have_libdrm" != xyes &&
1459                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1460                 ;;
1461
1462         android|fbdev|gdi|null)
1463                 ;;
1464
1465         *)
1466                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1467                 ;;
1468         esac
1469
1470         case "$plat$have_libudev" in
1471                 waylandno|drmno)
1472                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1473         esac
1474 done
1475
1476 # libEGL wants to default to the first platform specified in
1477 # ./configure.  parse that here.
1478 if test "x$egl_platforms" != "x"; then
1479     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1480     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1481 else
1482     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1483 fi
1484
1485 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1486     NEED_WINSYS_XLIB=yes
1487 fi
1488 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1489 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1490 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1491 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1492 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1493
1494 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1495
1496 AC_SUBST([EGL_NATIVE_PLATFORM])
1497 AC_SUBST([EGL_CFLAGS])
1498
1499 # If we don't have the X11 platform, set this define so we don't try to include
1500 # the X11 headers.
1501 if ! echo "$egl_platforms" | grep -q 'x11'; then
1502     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1503     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1504 fi
1505
1506 AC_ARG_WITH([egl-driver-dir],
1507     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1508                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1509     [EGL_DRIVER_INSTALL_DIR="$withval"],
1510     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1511 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1512
1513 AC_ARG_WITH([max-width],
1514     [AS_HELP_STRING([--with-max-width=N],
1515                     [Maximum framebuffer width (4096)])],
1516     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1517      AS_IF([test "${withval}" -gt "4096"],
1518            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1519 )
1520 AC_ARG_WITH([max-height],
1521     [AS_HELP_STRING([--with-max-height=N],
1522                     [Maximum framebuffer height (4096)])],
1523     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1524      AS_IF([test "${withval}" -gt "4096"],
1525            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1526 )
1527
1528 dnl
1529 dnl Gallium LLVM
1530 dnl
1531 AC_ARG_ENABLE([gallium-llvm],
1532     [AS_HELP_STRING([--enable-gallium-llvm],
1533         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1534     [enable_gallium_llvm="$enableval"],
1535     [enable_gallium_llvm=auto])
1536
1537 AC_ARG_WITH([llvm-shared-libs],
1538     [AS_HELP_STRING([--with-llvm-shared-libs],
1539         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1540     [],
1541     [with_llvm_shared_libs=no])
1542
1543 AC_ARG_WITH([llvm-prefix],
1544     [AS_HELP_STRING([--with-llvm-prefix],
1545         [Prefix for LLVM installations in non-standard locations])],
1546     [llvm_prefix="$withval"],
1547     [llvm_prefix=""])
1548
1549
1550 # Call this inside ` ` to get the return value.
1551 # $1 is the llvm-config command with arguments.
1552 strip_unwanted_llvm_flags() {
1553     # Use \> (marks the end of the word)
1554     echo `$1` | sed \
1555         -e 's/-DNDEBUG\>//g' \
1556         -e 's/-pedantic\>//g' \
1557         -e 's/-Wcovered-switch-default\>//g' \
1558         -e 's/-O.\>//g' \
1559         -e 's/-g\>//g' \
1560         -e 's/-Wall\>//g' \
1561         -e 's/-fcolor-diagnostics\>//g' \
1562         -e 's/-fomit-frame-pointer\>//g'
1563 }
1564
1565
1566 if test "x$with_gallium_drivers" = x; then
1567     enable_gallium_llvm=no
1568 fi
1569 if test "x$enable_gallium_llvm" = xauto; then
1570     case "$host_cpu" in
1571     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1572     esac
1573 fi
1574 if test "x$enable_gallium_llvm" = xyes; then
1575     if test "x$llvm_prefix" != x; then
1576         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1577     else
1578         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1579     fi
1580
1581     if test "x$LLVM_CONFIG" != xno; then
1582         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1583         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1584         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1585         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1586         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1587         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1588         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1589         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1590
1591         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1592             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1593         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1594             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1595
1596         if test "x${LLVM_VERSION_MAJOR}" != x; then
1597             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1598         else
1599             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1600         fi
1601
1602         LLVM_COMPONENTS="engine bitwriter"
1603         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1604             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1605         fi
1606
1607         if test "x$enable_opencl" = xyes; then
1608             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1609             # LLVM 3.3 >= 177971 requires IRReader
1610             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1611                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1612             fi
1613             # LLVM 3.4 requires Option
1614             if $LLVM_CONFIG --components | grep -qw 'option'; then
1615                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1616             fi
1617         fi
1618         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1619         MESA_LLVM=1
1620
1621         dnl Check for Clang internal headers
1622         if test "x$enable_opencl" = xyes; then
1623             if test "x$CLANG_LIBDIR" = x; then
1624                 CLANG_LIBDIR=${LLVM_LIBDIR}
1625             fi
1626             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1627             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1628                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1629         fi
1630     else
1631         MESA_LLVM=0
1632         LLVM_VERSION_INT=0
1633     fi
1634 else
1635     MESA_LLVM=0
1636     LLVM_VERSION_INT=0
1637 fi
1638
1639 dnl Directory for XVMC libs
1640 AC_ARG_WITH([xvmc-libdir],
1641     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1642         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1643     [XVMC_LIB_INSTALL_DIR="$withval"],
1644     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1645 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1646
1647 dnl
1648 dnl Gallium Tests
1649 dnl
1650 if test "x$enable_gallium_tests" = xyes; then
1651     enable_gallium_loader=yes
1652 fi
1653 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1654
1655 if test "x$enable_gallium_loader" = xyes; then
1656     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1657 fi
1658 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1659
1660 dnl Directory for VDPAU libs
1661 AC_ARG_WITH([vdpau-libdir],
1662     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1663         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1664     [VDPAU_LIB_INSTALL_DIR="$withval"],
1665     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1666 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1667
1668 AC_ARG_WITH([omx-libdir],
1669     [AS_HELP_STRING([--with-omx-libdir=DIR],
1670         [directory for the OMX libraries])],
1671     [OMX_LIB_INSTALL_DIR="$withval"],
1672     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1673 AC_SUBST([OMX_LIB_INSTALL_DIR])
1674
1675 dnl Directory for OpenCL libs
1676 AC_ARG_WITH([opencl-libdir],
1677     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1678         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1679     [OPENCL_LIB_INSTALL_DIR="$withval"],
1680     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1681 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1682
1683 dnl
1684 dnl Gallium helper functions
1685 dnl
1686 gallium_check_st() {
1687     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1688          if test "x$have_libdrm" != xyes; then
1689             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1690          fi
1691          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1692     fi
1693     if test "x$enable_dri" = xyes && test "x$2" != x; then
1694          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1695     fi
1696     if test "x$enable_xa" = xyes && test "x$3" != x; then
1697          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1698     fi
1699     if test "x$enable_xvmc" = xyes && test "x$4" != x; then
1700          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1701     fi
1702     if test "x$enable_vdpau" = xyes && test "x$5" != x; then
1703          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1704     fi
1705     if test "x$enable_omx" = xyes && test "x$6" != x; then
1706          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1707     fi
1708 }
1709
1710 gallium_require_llvm() {
1711     if test "x$MESA_LLVM" = x0; then
1712         case "$host_cpu" in
1713         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1714         esac
1715     fi
1716 }
1717
1718 gallium_require_drm_loader() {
1719     if test "x$enable_gallium_loader" = xyes; then
1720         if test "x$have_libudev" != xyes; then
1721             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1722         fi
1723         if test "x$have_libdrm" != xyes; then
1724             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1725         fi
1726         enable_gallium_drm_loader=yes
1727     fi
1728 }
1729
1730 radeon_llvm_check() {
1731     if test "x$enable_gallium_llvm" != "xyes"; then
1732         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1733     fi
1734     LLVM_REQUIRED_VERSION_MAJOR="3"
1735     LLVM_REQUIRED_VERSION_MINOR="3"
1736     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1737         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1738     fi
1739     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1740         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1741                       sources with the --enable-experimental-targets=R600
1742                       configure flag])
1743     fi
1744     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1745     NEED_RADEON_LLVM=yes
1746     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1747                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1748 }
1749
1750 dnl Gallium drivers
1751 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1752         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1753     NEED_NONNULL_WINSYS=yes
1754 fi
1755 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1756
1757 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1758 if test "x$with_gallium_drivers" != x; then
1759     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1760     for driver in $gallium_drivers; do
1761         case "x$driver" in
1762         xsvga)
1763             HAVE_GALLIUM_SVGA=yes
1764             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1765             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1766             ;;
1767         xi915)
1768             HAVE_GALLIUM_I915=yes
1769             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1770             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1771             if test "x$MESA_LLVM" = x1; then
1772                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1773             fi
1774             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1775             gallium_check_st "i915/drm" "dri-i915"
1776             DRICOMMON_NEED_LIBDRM=yes
1777             ;;
1778         xilo)
1779             HAVE_GALLIUM_ILO=yes
1780             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1781             gallium_require_drm_loader
1782             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1783             gallium_check_st "intel/drm" "dri-ilo"
1784             DRICOMMON_NEED_LIBDRM=yes
1785             ;;
1786         xr300)
1787             HAVE_GALLIUM_R300=yes
1788             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1789             gallium_require_llvm "Gallium R300"
1790             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1791             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1792             DRICOMMON_NEED_LIBDRM=yes
1793             ;;
1794         xr600)
1795             HAVE_GALLIUM_R600=yes
1796             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1797             gallium_require_drm_loader
1798             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1799             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1800                 radeon_llvm_check "r600g"
1801                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1802             fi
1803             if test "x$enable_r600_llvm" = xyes; then
1804                 USE_R600_LLVM_COMPILER=yes;
1805             fi
1806             if test "x$enable_opencl" = xyes; then
1807                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1808             fi
1809             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1810             DRICOMMON_NEED_LIBDRM=yes
1811             ;;
1812         xradeonsi)
1813             HAVE_GALLIUM_RADEONSI=yes
1814             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1815             gallium_require_drm_loader
1816             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1817             radeon_llvm_check "radeonsi"
1818             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1819             DRICOMMON_NEED_LIBDRM=yes
1820             ;;
1821         xnouveau)
1822             HAVE_GALLIUM_NOUVEAU=yes
1823             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1824             gallium_require_drm_loader
1825             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1826             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1827             DRICOMMON_NEED_LIBDRM=yes
1828             ;;
1829         xfreedreno)
1830             HAVE_GALLIUM_FREEDRENO=yes
1831             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1832             gallium_require_drm_loader
1833             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1834             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1835             DRICOMMON_NEED_LIBDRM=yes
1836             ;;
1837         xswrast)
1838             HAVE_GALLIUM_SOFTPIPE=yes
1839             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1840             if test "x$MESA_LLVM" = x1; then
1841                 HAVE_GALLIUM_LLVMPIPE=yes
1842                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1843             fi
1844
1845             if test "x$enable_dri" = xyes; then
1846                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1847             fi
1848             ;;
1849         *)
1850             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1851             ;;
1852         esac
1853     done
1854 fi
1855
1856 dnl Set LLVM_LIBS - This is done after the driver configuration so
1857 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1858 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1859 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1860 dnl this was causing the same libraries to be appear multiple times
1861 dnl in LLVM_LIBS.
1862
1863 if test "x$MESA_LLVM" != x0; then
1864
1865     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1866
1867     if test "x$with_llvm_shared_libs" = xyes; then
1868         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1869         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1870         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1871
1872         if test "x$llvm_have_one_so" = xyes; then
1873             dnl LLVM was built using auto*, so there is only one shared object.
1874             LLVM_LIBS="-l$LLVM_SO_NAME"
1875         else
1876             dnl If LLVM was built with CMake, there will be one shared object per
1877             dnl component.
1878             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1879                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1880         Please make sure you have built llvm with the --enable-shared option
1881         and that your llvm libraries are installed in $LLVM_LIBDIR
1882         If you have installed your llvm libraries to a different directory you
1883         can use the --with-llvm-prefix= configure flag to specify this directory.
1884         NOTE: Mesa is attempting to use llvm shared libraries because you have
1885         passed one of the following options to configure:
1886                 --with-llvm-shared-libs
1887                 --enable-opencl
1888         If you do not want to build with llvm shared libraries and instead want to
1889         use llvm static libraries then remove these options from your configure
1890         invocation and reconfigure.])])
1891
1892            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1893            dnl install uses a shared object for each compoenent and we have
1894            dnl already added all of these objects to LLVM_LIBS.
1895         fi
1896     fi
1897 fi
1898
1899 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1900 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1901 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1902 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1903 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1904 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1905 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1906 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1907 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1908 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1909
1910 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1911                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1912                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1913 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1914                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1915                                                   && test "x$MESA_LLVM" = x1)
1916
1917 # NOTE: anything using xcb or other client side libs ends up in separate
1918 #       _CLIENT variables.  The pipe loader is built in two variants,
1919 #       one that is standalone and does not link any x client libs (for
1920 #       use by XA tracker in particular, but could be used in any case
1921 #       where communication with xserver is not desired).
1922 if test "x$enable_gallium_loader" = xyes; then
1923     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1924
1925     if test "x$enable_gallium_drm_loader" = xyes; then
1926         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1927         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1928                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1929         if test "x$pipe_loader_have_xcb" = xyes; then
1930             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1931             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1932         fi
1933     fi
1934
1935     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1936     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1937
1938     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1939     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1940     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1941     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1942 fi
1943
1944 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1945 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1946 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1947 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1948 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1949 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1950
1951 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1952                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1953                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1954                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1955 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1956                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1957 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1958 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1959 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1960 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1961 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1962 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1963 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1964
1965 AC_SUBST([ELF_LIB])
1966
1967 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1968 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1969 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1970 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1971 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1972
1973 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1974 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1975 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1976
1977 AC_SUBST([VDPAU_MAJOR], 1)
1978 AC_SUBST([VDPAU_MINOR], 0)
1979
1980 AC_SUBST([XVMC_MAJOR], 1)
1981 AC_SUBST([XVMC_MINOR], 0)
1982
1983 AC_SUBST([XA_MAJOR], 2)
1984 AC_SUBST([XA_MINOR], 2)
1985 AC_SUBST([XA_TINY], 0)
1986 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1987
1988 dnl Restore LDFLAGS and CPPFLAGS
1989 LDFLAGS="$_SAVE_LDFLAGS"
1990 CPPFLAGS="$_SAVE_CPPFLAGS"
1991
1992 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1993 if test "x$acv_mesa_CLANG" = xyes; then
1994     CFLAGS="$CFLAGS -Qunused-arguments"
1995     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1996 fi
1997
1998 dnl Add user CFLAGS and CXXFLAGS
1999 CFLAGS="$CFLAGS $USER_CFLAGS"
2000 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2001
2002 dnl Substitute the config
2003 AC_CONFIG_FILES([Makefile
2004                 src/Makefile
2005                 src/egl/Makefile
2006                 src/egl/drivers/Makefile
2007                 src/egl/drivers/dri2/Makefile
2008                 src/egl/main/Makefile
2009                 src/egl/main/egl.pc
2010                 src/egl/wayland/Makefile
2011                 src/egl/wayland/wayland-drm/Makefile
2012                 src/egl/wayland/wayland-egl/Makefile
2013                 src/egl/wayland/wayland-egl/wayland-egl.pc
2014                 src/gallium/auxiliary/Makefile
2015                 src/gallium/auxiliary/pipe-loader/Makefile
2016                 src/gallium/drivers/Makefile
2017                 src/gallium/drivers/freedreno/Makefile
2018                 src/gallium/drivers/galahad/Makefile
2019                 src/gallium/drivers/i915/Makefile
2020                 src/gallium/drivers/identity/Makefile
2021                 src/gallium/drivers/ilo/Makefile
2022                 src/gallium/drivers/llvmpipe/Makefile
2023                 src/gallium/drivers/noop/Makefile
2024                 src/gallium/drivers/nouveau/Makefile
2025                 src/gallium/drivers/r300/Makefile
2026                 src/gallium/drivers/r600/Makefile
2027                 src/gallium/drivers/radeon/Makefile
2028                 src/gallium/drivers/radeonsi/Makefile
2029                 src/gallium/drivers/rbug/Makefile
2030                 src/gallium/drivers/softpipe/Makefile
2031                 src/gallium/drivers/svga/Makefile
2032                 src/gallium/drivers/trace/Makefile
2033                 src/gallium/state_trackers/Makefile
2034                 src/gallium/state_trackers/clover/Makefile
2035                 src/gallium/state_trackers/dri/Makefile
2036                 src/gallium/state_trackers/dri/drm/Makefile
2037                 src/gallium/state_trackers/dri/sw/Makefile
2038                 src/gallium/state_trackers/egl/Makefile
2039                 src/gallium/state_trackers/gbm/Makefile
2040                 src/gallium/state_trackers/glx/xlib/Makefile
2041                 src/gallium/state_trackers/omx/Makefile
2042                 src/gallium/state_trackers/osmesa/Makefile
2043                 src/gallium/state_trackers/vdpau/Makefile
2044                 src/gallium/state_trackers/vega/Makefile
2045                 src/gallium/state_trackers/xa/Makefile
2046                 src/gallium/state_trackers/xvmc/Makefile
2047                 src/gallium/targets/Makefile
2048                 src/gallium/targets/dri-freedreno/Makefile
2049                 src/gallium/targets/dri-i915/Makefile
2050                 src/gallium/targets/dri-ilo/Makefile
2051                 src/gallium/targets/dri-nouveau/Makefile
2052                 src/gallium/targets/dri-swrast/Makefile
2053                 src/gallium/targets/dri-vmwgfx/Makefile
2054                 src/gallium/targets/egl-static/Makefile
2055                 src/gallium/targets/gbm/Makefile
2056                 src/gallium/targets/opencl/Makefile
2057                 src/gallium/targets/xa/Makefile
2058                 src/gallium/targets/xa/xatracker.pc
2059                 src/gallium/targets/osmesa/Makefile
2060                 src/gallium/targets/osmesa/osmesa.pc
2061                 src/gallium/targets/pipe-loader/Makefile
2062                 src/gallium/targets/radeonsi/dri/Makefile
2063                 src/gallium/targets/radeonsi/omx/Makefile
2064                 src/gallium/targets/radeonsi/vdpau/Makefile
2065                 src/gallium/targets/r300/dri/Makefile
2066                 src/gallium/targets/r600/dri/Makefile
2067                 src/gallium/targets/r600/omx/Makefile
2068                 src/gallium/targets/r600/vdpau/Makefile
2069                 src/gallium/targets/r600/xvmc/Makefile
2070                 src/gallium/targets/libgl-xlib/Makefile
2071                 src/gallium/targets/vdpau-nouveau/Makefile
2072                 src/gallium/targets/xvmc-nouveau/Makefile
2073                 src/gallium/tests/trivial/Makefile
2074                 src/gallium/tests/unit/Makefile
2075                 src/gallium/winsys/Makefile
2076                 src/gallium/winsys/freedreno/drm/Makefile
2077                 src/gallium/winsys/i915/drm/Makefile
2078                 src/gallium/winsys/i915/sw/Makefile
2079                 src/gallium/winsys/intel/drm/Makefile
2080                 src/gallium/winsys/nouveau/drm/Makefile
2081                 src/gallium/winsys/radeon/drm/Makefile
2082                 src/gallium/winsys/svga/drm/Makefile
2083                 src/gallium/winsys/sw/dri/Makefile
2084                 src/gallium/winsys/sw/fbdev/Makefile
2085                 src/gallium/winsys/sw/null/Makefile
2086                 src/gallium/winsys/sw/wayland/Makefile
2087                 src/gallium/winsys/sw/wrapper/Makefile
2088                 src/gallium/winsys/sw/xlib/Makefile
2089                 src/gbm/Makefile
2090                 src/gbm/main/gbm.pc
2091                 src/glsl/Makefile
2092                 src/glx/Makefile
2093                 src/glx/tests/Makefile
2094                 src/gtest/Makefile
2095                 src/loader/Makefile
2096                 src/mapi/Makefile
2097                 src/mapi/es1api/Makefile
2098                 src/mapi/es1api/glesv1_cm.pc
2099                 src/mapi/es2api/Makefile
2100                 src/mapi/es2api/glesv2.pc
2101                 src/mapi/glapi/Makefile
2102                 src/mapi/glapi/gen/Makefile
2103                 src/mapi/glapi/tests/Makefile
2104                 src/mapi/shared-glapi/Makefile
2105                 src/mapi/shared-glapi/tests/Makefile
2106                 src/mapi/vgapi/Makefile
2107                 src/mapi/vgapi/vg.pc
2108                 src/mesa/Makefile
2109                 src/mesa/gl.pc
2110                 src/mesa/drivers/dri/dri.pc
2111                 src/mesa/drivers/dri/common/Makefile
2112                 src/mesa/drivers/dri/common/xmlpool/Makefile
2113                 src/mesa/drivers/dri/i915/Makefile
2114                 src/mesa/drivers/dri/i965/Makefile
2115                 src/mesa/drivers/dri/Makefile
2116                 src/mesa/drivers/dri/nouveau/Makefile
2117                 src/mesa/drivers/dri/r200/Makefile
2118                 src/mesa/drivers/dri/radeon/Makefile
2119                 src/mesa/drivers/dri/swrast/Makefile
2120                 src/mesa/drivers/osmesa/Makefile
2121                 src/mesa/drivers/osmesa/osmesa.pc
2122                 src/mesa/drivers/x11/Makefile
2123                 src/mesa/main/tests/Makefile
2124                 src/mesa/main/tests/hash_table/Makefile])
2125
2126 dnl Sort the dirs alphabetically
2127 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2128 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2129 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2130 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2131
2132 AC_OUTPUT
2133
2134 dnl
2135 dnl Output some configuration info for the user
2136 dnl
2137 echo ""
2138 echo "        prefix:          $prefix"
2139 echo "        exec_prefix:     $exec_prefix"
2140 echo "        libdir:          $libdir"
2141 echo "        includedir:      $includedir"
2142
2143 dnl API info
2144 echo ""
2145 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2146 echo "        OpenVG:          $enable_openvg"
2147
2148 dnl Driver info
2149 echo ""
2150 case "x$enable_osmesa$enable_gallium_osmesa" in
2151 xnoyes)
2152         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2153         ;;
2154 xyesno)
2155         echo "        OSMesa:          lib$OSMESA_LIB"
2156         ;;
2157 xnono)
2158         echo "        OSMesa:          no"
2159         ;;
2160 esac
2161
2162 if test "x$enable_dri" != xno; then
2163         # cleanup the drivers var
2164         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2165         if test "x$DRI_DIRS" = x; then
2166             echo "        DRI drivers:     no"
2167         else
2168             echo "        DRI drivers:     $dri_dirs"
2169         fi
2170         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2171 fi
2172
2173 case "x$enable_glx$enable_xlib_glx" in
2174 xyesyes)
2175     echo "        GLX:             Xlib-based"
2176     ;;
2177 xyesno)
2178     echo "        GLX:             DRI-based"
2179     ;;
2180 *)
2181     echo "        GLX:             $enable_glx"
2182     ;;
2183 esac
2184
2185 dnl EGL
2186 echo ""
2187 echo "        EGL:             $enable_egl"
2188 if test "$enable_egl" = yes; then
2189     echo "        EGL platforms:   $egl_platforms"
2190
2191     egl_drivers=""
2192     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2193         egl_drivers="$egl_drivers builtin:egl_dri2"
2194     fi
2195
2196     if test "x$enable_gallium_egl" = xyes; then
2197         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2198         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2199     else
2200         echo "        EGL drivers:    $egl_drivers"
2201     fi
2202 fi
2203
2204 echo ""
2205 if test "x$MESA_LLVM" = x1; then
2206     echo "        llvm:            yes"
2207     echo "        llvm-config:     $LLVM_CONFIG"
2208     echo "        llvm-version:    $LLVM_VERSION"
2209 else
2210     echo "        llvm:            no"
2211 fi
2212
2213 echo ""
2214 if test -n "$with_gallium_drivers"; then
2215     echo "        Gallium:         yes"
2216     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2217     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2218     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2219     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2220 else
2221     echo "        Gallium:         no"
2222 fi
2223
2224
2225 dnl Libraries
2226 echo ""
2227 echo "        Shared libs:     $enable_shared"
2228 echo "        Static libs:     $enable_static"
2229 echo "        Shared-glapi:    $enable_shared_glapi"
2230
2231 dnl Compiler options
2232 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2233 cflags=`echo $CFLAGS | \
2234     $SED 's/^ *//;s/  */ /;s/ *$//'`
2235 cxxflags=`echo $CXXFLAGS | \
2236     $SED 's/^ *//;s/  */ /;s/ *$//'`
2237 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2238 echo ""
2239 echo "        CFLAGS:          $cflags"
2240 echo "        CXXFLAGS:        $cxxflags"
2241 echo "        Macros:          $defines"
2242 echo ""
2243 if test "x$MESA_LLVM" = x1; then
2244     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2245     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2246     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2247     echo ""
2248 fi
2249 echo "        PYTHON2:         $PYTHON2"
2250
2251 echo ""
2252 echo "        Run '${MAKE-make}' to build Mesa"
2253 echo ""