configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.68
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.8.0
  93 LIBSENSORS_REQUIRED=4.0.0
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112 AC_CHECK_PROG(XXD, xxd, [xxd])
 113
 114 AX_PROG_BISON([],
 115               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 116                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 117 AX_PROG_FLEX([],
 118              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 119                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 120
 121 AC_CHECK_PROG(INDENT, indent, indent, cat)
 122 if test "x$INDENT" != "xcat"; then
 123     # Only GNU indent is supported
 124     INDENT_VERSION=`indent --version | grep GNU`
 125     if test $? -eq 0; then
 126        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 127     else
 128        INDENT="cat"
 129     fi
 130 fi
 131
 132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 133
 134 if test -z "$PYTHON2"; then
 135     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 136         AC_MSG_ERROR([Python not found - unable to generate sources])
 137     fi
 138 else
 139     if test "x$acv_mako_found" = xno; then
 140         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 141             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 142         fi
 143     fi
 144 fi
 145
 146 AC_PROG_INSTALL
 147
 148 dnl We need a POSIX shell for parts of the build. Assume we have one
 149 dnl in most cases.
 150 case "$host_os" in
 151 solaris*)
 152     # Solaris /bin/sh is too old/non-POSIX compliant
 153     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 154     SHELL="$POSIX_SHELL"
 155     ;;
 156 esac
 157
 158 dnl clang is mostly GCC-compatible, but its version is much lower,
 159 dnl so we have to check for it.
 160 AC_MSG_CHECKING([if compiling with clang])
 161
 162 AC_COMPILE_IFELSE(
 163 [AC_LANG_PROGRAM([], [[
 164 #ifndef __clang__
 165        not clang
 166 #endif
 167 ]])],
 168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 169
 170 AC_MSG_RESULT([$acv_mesa_CLANG])
 171
 172 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 173 dnl versions are explictly not supported.
 174 GEN_ASM_OFFSETS=no
 175 USE_GNU99=no
 176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 177     AC_MSG_CHECKING([whether gcc version is sufficient])
 178     major=0
 179     minor=0
 180
 181     GCC_VERSION=`$CC -dumpversion`
 182     if test $? -eq 0; then
 183         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 184         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 188         AC_MSG_RESULT([no])
 189         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 190     else
 191         AC_MSG_RESULT([yes])
 192     fi
 193
 194     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 195         USE_GNU99=yes
 196     fi
 197     if test "x$cross_compiling" = xyes; then
 198         GEN_ASM_OFFSETS=yes
 199     fi
 200 fi
 201
 202 dnl We don't support building Mesa with Sun C compiler
 203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 205 if test "x$SUNCC" = xyes; then
 206     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 207 fi
 208
 209 dnl Check for compiler builtins
 210 AX_GCC_BUILTIN([__builtin_bswap32])
 211 AX_GCC_BUILTIN([__builtin_bswap64])
 212 AX_GCC_BUILTIN([__builtin_clz])
 213 AX_GCC_BUILTIN([__builtin_clzll])
 214 AX_GCC_BUILTIN([__builtin_ctz])
 215 AX_GCC_BUILTIN([__builtin_expect])
 216 AX_GCC_BUILTIN([__builtin_ffs])
 217 AX_GCC_BUILTIN([__builtin_ffsll])
 218 AX_GCC_BUILTIN([__builtin_popcount])
 219 AX_GCC_BUILTIN([__builtin_popcountll])
 220 AX_GCC_BUILTIN([__builtin_unreachable])
 221
 222 AX_GCC_FUNC_ATTRIBUTE([const])
 223 AX_GCC_FUNC_ATTRIBUTE([flatten])
 224 AX_GCC_FUNC_ATTRIBUTE([format])
 225 AX_GCC_FUNC_ATTRIBUTE([malloc])
 226 AX_GCC_FUNC_ATTRIBUTE([packed])
 227 AX_GCC_FUNC_ATTRIBUTE([pure])
 228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 229 AX_GCC_FUNC_ATTRIBUTE([unused])
 230 AX_GCC_FUNC_ATTRIBUTE([visibility])
 231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 232 AX_GCC_FUNC_ATTRIBUTE([weak])
 233
 234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 235
 236 dnl Make sure the pkg-config macros are defined
 237 m4_ifndef([PKG_PROG_PKG_CONFIG],
 238     [m4_fatal([Could not locate the pkg-config autoconf macros.
 239   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 240   are in a different location, try setting the environment variable
 241   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 242 PKG_PROG_PKG_CONFIG()
 243
 244 dnl LIB_DIR - library basename
 245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 246 AC_SUBST([LIB_DIR])
 247
 248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 249 _SAVE_LDFLAGS="$LDFLAGS"
 250 _SAVE_CPPFLAGS="$CPPFLAGS"
 251
 252 dnl Compiler macros
 253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 254 AC_SUBST([DEFINES])
 255 android=no
 256 case "$host_os" in
 257 *-android)
 258     android=yes
 259     ;;
 260 linux*|*-gnu*|gnu*|cygwin*)
 261     DEFINES="$DEFINES -D_GNU_SOURCE"
 262     ;;
 263 solaris*)
 264     DEFINES="$DEFINES -DSVR4"
 265     ;;
 266 esac
 267
 268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # We don't want floating-point math functions to set errno or trap
 305     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # We don't want floating-point math functions to set errno or trap
 344     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int param;
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 380     c = _mm_max_epu32(a, b);
 381     return _mm_cvtsi128_si32(c);
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Check for new-style atomic builtins
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 int main() {
 393     int n;
 394     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 397     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 398 fi
 399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 DEFAULT_GL_LIB_NAME=GL
 525
 526 dnl
 527 dnl Check if linker supports -Bsymbolic
 528 dnl
 529 save_LDFLAGS=$LDFLAGS
 530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 532 AC_LINK_IFELSE(
 533     [AC_LANG_SOURCE([int main() { return 0;}])],
 534     [AC_MSG_RESULT([yes])
 535         BSYMBOLIC="-Wl,-Bsymbolic";],
 536     [AC_MSG_RESULT([no])
 537         BSYMBOLIC="";])
 538 LDFLAGS=$save_LDFLAGS
 539
 540 AC_SUBST([BSYMBOLIC])
 541
 542 dnl
 543 dnl Check if linker supports garbage collection
 544 dnl
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";],
 552     [AC_MSG_RESULT([no])
 553         GC_SECTIONS="";])
 554 LDFLAGS=$save_LDFLAGS
 555
 556 AC_SUBST([GC_SECTIONS])
 557
 558 dnl
 559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 560 dnl so when these flags are passed to ld via libtool the checks will fail
 561 dnl
 562 case "$host_os" in
 563 openbsd* | darwin* )
 564     LD_NO_UNDEFINED="" ;;
 565 *)
 566     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 567 esac
 568
 569 AC_SUBST([LD_NO_UNDEFINED])
 570
 571 dnl
 572 dnl Check if linker supports version scripts
 573 dnl
 574 AC_MSG_CHECKING([if the linker supports version-scripts])
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 577 cat > conftest.map <<EOF
 578 VERSION_1 {
 579      global:
 580          main;
 581
 582      local:
 583          *;
 584 };
 585 EOF
 586 AC_LINK_IFELSE(
 587     [AC_LANG_SOURCE([int main() { return 0;}])],
 588     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 589     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 590 LDFLAGS=$save_LDFLAGS
 591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 592
 593 dnl
 594 dnl Check if linker supports dynamic list files
 595 dnl
 596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 597 save_LDFLAGS=$LDFLAGS
 598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 599 cat > conftest.dyn <<EOF
 600 {
 601         radeon_drm_winsys_create;
 602 };
 603 EOF
 604 AC_LINK_IFELSE(
 605     [AC_LANG_SOURCE([int main() { return 0;}])],
 606     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 607     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 608 LDFLAGS=$save_LDFLAGS
 609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 610
 611 dnl
 612 dnl compatibility symlinks
 613 dnl
 614 case "$host_os" in
 615 linux* )
 616     HAVE_COMPAT_SYMLINKS=yes ;;
 617 * )
 618     HAVE_COMPAT_SYMLINKS=no ;;
 619 esac
 620
 621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 622
 623 DEFAULT_GL_LIB_NAME=GL
 624
 625 dnl
 626 dnl Libglvnd configuration
 627 dnl
 628 AC_ARG_ENABLE([libglvnd],
 629     [AS_HELP_STRING([--enable-libglvnd],
 630         [Build for libglvnd @<:@default=disabled@:>@])],
 631     [enable_libglvnd="$enableval"],
 632     [enable_libglvnd=no])
 633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 635 if test "x$enable_libglvnd" = xyes ; then
 636     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 637     DEFAULT_GL_LIB_NAME=GLX_mesa
 638 fi
 639
 640 dnl
 641 dnl library names
 642 dnl
 643 dnl Unfortunately we need to do a few things that libtool can't help us with,
 644 dnl so we need some knowledge of shared library filenames:
 645 dnl
 646 dnl LIB_EXT is the extension used when creating symlinks for alternate
 647 dnl filenames for a shared library which will be dynamically loaded
 648 dnl
 649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 650 dnl the file for a shared library we wish to link with
 651 dnl
 652 case "$host_os" in
 653 darwin* )
 654     LIB_EXT='dylib'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 cygwin* )
 658     LIB_EXT='dll'
 659     IMP_LIB_EXT='dll.a'
 660     ;;
 661 aix* )
 662     LIB_EXT='a'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 * )
 666     LIB_EXT='so'
 667     IMP_LIB_EXT=$LIB_EXT
 668     ;;
 669 esac
 670
 671 AC_SUBST([LIB_EXT])
 672
 673 AC_ARG_WITH([gl-lib-name],
 674   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 675     [specify GL library name @<:@default=GL@:>@])],
 676   [GL_LIB=$withval],
 677   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AC_ARG_WITH([osmesa-lib-name],
 679   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 680     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 681   [OSMESA_LIB=$withval],
 682   [OSMESA_LIB=OSMesa])
 683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 685
 686 dnl
 687 dnl Mangled Mesa support
 688 dnl
 689 AC_ARG_ENABLE([mangling],
 690   [AS_HELP_STRING([--enable-mangling],
 691     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 692   [enable_mangling="${enableval}"],
 693   [enable_mangling=no]
 694 )
 695 if test "x${enable_mangling}" = "xyes" ; then
 696   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 697   GL_LIB="Mangled${GL_LIB}"
 698   OSMESA_LIB="Mangled${OSMESA_LIB}"
 699 fi
 700 AC_SUBST([GL_LIB])
 701 AC_SUBST([OSMESA_LIB])
 702
 703 dnl
 704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 705 dnl
 706 AC_ARG_ENABLE([texture-float],
 707     [AS_HELP_STRING([--enable-texture-float],
 708         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 709     [enable_texture_float="$enableval"],
 710     [enable_texture_float=no]
 711 )
 712 if test "x$enable_texture_float" = xyes; then
 713     AC_MSG_WARN([Floating-point textures enabled.])
 714     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 715     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 716 fi
 717
 718 dnl
 719 dnl Arch/platform-specific settings
 720 dnl
 721 AC_ARG_ENABLE([asm],
 722     [AS_HELP_STRING([--disable-asm],
 723         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 724     [enable_asm="$enableval"],
 725     [enable_asm=yes]
 726 )
 727 asm_arch=""
 728 AC_MSG_CHECKING([whether to enable assembly])
 729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 732     case "$host_cpu" in
 733     i?86 | x86_64 | amd64)
 734         if test "x$host_cpu" != "x$target_cpu"; then
 735             enable_asm=no
 736             AC_MSG_RESULT([no, cross compiling])
 737         fi
 738         ;;
 739     esac
 740 fi
 741 # check for supported arches
 742 if test "x$enable_asm" = xyes; then
 743     case "$host_cpu" in
 744     i?86)
 745         case "$host_os" in
 746         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 747             asm_arch=x86
 748             ;;
 749         esac
 750         ;;
 751     x86_64|amd64)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 754             asm_arch=x86_64
 755             ;;
 756         esac
 757         ;;
 758     sparc*)
 759         case "$host_os" in
 760         linux*)
 761             asm_arch=sparc
 762             ;;
 763         esac
 764         ;;
 765     esac
 766
 767     case "$asm_arch" in
 768     x86)
 769         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 770         AC_MSG_RESULT([yes, x86])
 771         ;;
 772     x86_64|amd64)
 773         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 774         AC_MSG_RESULT([yes, x86_64])
 775         ;;
 776     sparc)
 777         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 778         AC_MSG_RESULT([yes, sparc])
 779         ;;
 780     *)
 781         AC_MSG_RESULT([no, platform not supported])
 782         ;;
 783     esac
 784 fi
 785
 786 AC_HEADER_MAJOR
 787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 791
 792 dnl Check to see if dlopen is in default libraries (like Solaris, which
 793 dnl has it in libc), or if libdl is needed to get it.
 794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 795     [AC_CHECK_LIB([dl], [dlopen],
 796        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 797 AC_SUBST([DLOPEN_LIBS])
 798
 799 dnl Check if that library also has dladdr
 800 save_LIBS="$LIBS"
 801 LIBS="$LIBS $DLOPEN_LIBS"
 802 AC_CHECK_FUNCS([dladdr])
 803 LIBS="$save_LIBS"
 804
 805 case "$host_os" in
 806 darwin*)
 807     ;;
 808 *)
 809     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 810                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 811                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 812     AC_SUBST([CLOCK_LIB])
 813     ;;
 814 esac
 815
 816 dnl See if posix_memalign is available
 817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 818
 819 dnl Check for pthreads
 820 AX_PTHREAD
 821 if test "x$ax_pthread_ok" = xno; then
 822     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 823 fi
 824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 825 dnl to -pthread, which causes problems if we need -lpthread to appear in
 826 dnl pkgconfig files.
 827 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 828
 829 dnl pthread-stubs is mandatory on targets where it exists
 830 case "$host_os" in
 831 cygwin* )
 832     pthread_stubs_possible="no"
 833     ;;
 834 * )
 835     pthread_stubs_possible="yes"
 836     ;;
 837 esac
 838
 839 if test "x$pthread_stubs_possible" = xyes; then
 840     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 841     AC_SUBST(PTHREADSTUBS_CFLAGS)
 842     AC_SUBST(PTHREADSTUBS_LIBS)
 843 fi
 844
 845 dnl SELinux awareness.
 846 AC_ARG_ENABLE([selinux],
 847     [AS_HELP_STRING([--enable-selinux],
 848         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 849     [MESA_SELINUX="$enableval"],
 850     [MESA_SELINUX=no])
 851 if test "x$enable_selinux" = "xyes"; then
 852     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 853         [AC_CHECK_HEADER([selinux/selinux.h],[],
 854                          [AC_MSG_ERROR([SELinux headers not found])])
 855          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 856                       [AC_MSG_ERROR([SELinux library not found])])
 857          SELINUX_LIBS="-lselinux"])
 858     DEFINES="$DEFINES -DMESA_SELINUX"
 859 fi
 860 AC_SUBST([SELINUX_CFLAGS])
 861 AC_SUBST([SELINUX_LIBS])
 862
 863 dnl Options for APIs
 864 AC_ARG_ENABLE([opengl],
 865     [AS_HELP_STRING([--disable-opengl],
 866         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 867     [enable_opengl="$enableval"],
 868     [enable_opengl=yes])
 869 AC_ARG_ENABLE([gles1],
 870     [AS_HELP_STRING([--disable-gles1],
 871         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 872     [enable_gles1="$enableval"],
 873     [enable_gles1=yes])
 874 AC_ARG_ENABLE([gles2],
 875     [AS_HELP_STRING([--disable-gles2],
 876         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 877     [enable_gles2="$enableval"],
 878     [enable_gles2=yes])
 879
 880 AC_ARG_ENABLE([dri],
 881     [AS_HELP_STRING([--enable-dri],
 882         [enable DRI modules @<:@default=enabled@:>@])],
 883     [enable_dri="$enableval"],
 884     [enable_dri=yes])
 885
 886 AC_ARG_ENABLE([gallium-extra-hud],
 887     [AS_HELP_STRING([--enable-gallium-extra-hud],
 888         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
 889     [enable_gallium_extra_hud="$enableval"],
 890     [enable_gallium_extra_hud=no])
 891 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
 892 if test "x$enable_gallium_extra_hud" = xyes ; then
 893     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
 894 fi
 895
 896 #TODO: no pkgconfig .pc available for libsensors.
 897 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
 898 AC_ARG_ENABLE([lmsensors],
 899     [AS_HELP_STRING([--enable-lmsensors],
 900         [enable HUD lmsensor support @<:@default=disabled@:>@])],
 901     [enable_lmsensors="$enableval"],
 902     [enable_lmsensors=no])
 903 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
 904 if test "x$enable_lmsensors" = xyes ; then
 905     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
 906     LIBSENSORS_LDFLAGS="-lsensors"
 907 else
 908     LIBSENSORS_LDFLAGS=""
 909 fi
 910 AC_SUBST(LIBSENSORS_LDFLAGS)
 911
 912 case "$host_os" in
 913 linux*)
 914     dri3_default=yes
 915     ;;
 916 *)
 917     dri3_default=no
 918     ;;
 919 esac
 920
 921 if test "x$enable_dri" = xno; then
 922     dri3_default=no
 923 fi
 924
 925 AC_ARG_ENABLE([dri3],
 926     [AS_HELP_STRING([--enable-dri3],
 927         [enable DRI3 @<:@default=auto@:>@])],
 928     [enable_dri3="$enableval"],
 929     [enable_dri3="$dri3_default"])
 930 AC_ARG_ENABLE([glx],
 931     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 932         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 933     [enable_glx="$enableval"],
 934     [enable_glx=yes])
 935 AC_ARG_ENABLE([osmesa],
 936     [AS_HELP_STRING([--enable-osmesa],
 937         [enable OSMesa library @<:@default=disabled@:>@])],
 938     [enable_osmesa="$enableval"],
 939     [enable_osmesa=no])
 940 AC_ARG_ENABLE([gallium-osmesa],
 941     [AS_HELP_STRING([--enable-gallium-osmesa],
 942         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 943     [enable_gallium_osmesa="$enableval"],
 944     [enable_gallium_osmesa=no])
 945 AC_ARG_ENABLE([egl],
 946     [AS_HELP_STRING([--disable-egl],
 947         [disable EGL library @<:@default=enabled@:>@])],
 948     [enable_egl="$enableval"],
 949     [enable_egl=yes])
 950
 951 AC_ARG_ENABLE([xa],
 952     [AS_HELP_STRING([--enable-xa],
 953         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 954     [enable_xa="$enableval"],
 955     [enable_xa=no])
 956 AC_ARG_ENABLE([gbm],
 957    [AS_HELP_STRING([--enable-gbm],
 958          [enable gbm library @<:@default=yes except cygwin@:>@])],
 959    [enable_gbm="$enableval"],
 960    [case "$host_os" in
 961        cygwin*)
 962           enable_gbm=no
 963           ;;
 964        *)
 965           enable_gbm=yes
 966           ;;
 967     esac])
 968 AC_ARG_ENABLE([nine],
 969     [AS_HELP_STRING([--enable-nine],
 970         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 971     [enable_nine="$enableval"],
 972     [enable_nine=no])
 973
 974 AC_ARG_ENABLE([xvmc],
 975    [AS_HELP_STRING([--enable-xvmc],
 976          [enable xvmc library @<:@default=auto@:>@])],
 977    [enable_xvmc="$enableval"],
 978    [enable_xvmc=auto])
 979 AC_ARG_ENABLE([vdpau],
 980    [AS_HELP_STRING([--enable-vdpau],
 981          [enable vdpau library @<:@default=auto@:>@])],
 982    [enable_vdpau="$enableval"],
 983    [enable_vdpau=auto])
 984 AC_ARG_ENABLE([omx],
 985    [AS_HELP_STRING([--enable-omx],
 986          [enable OpenMAX library @<:@default=disabled@:>@])],
 987    [enable_omx="$enableval"],
 988    [enable_omx=no])
 989 AC_ARG_ENABLE([va],
 990    [AS_HELP_STRING([--enable-va],
 991          [enable va library @<:@default=auto@:>@])],
 992    [enable_va="$enableval"],
 993    [enable_va=auto])
 994 AC_ARG_ENABLE([opencl],
 995    [AS_HELP_STRING([--enable-opencl],
 996          [enable OpenCL library @<:@default=disabled@:>@])],
 997    [enable_opencl="$enableval"],
 998    [enable_opencl=no])
 999 AC_ARG_ENABLE([opencl_icd],
1000    [AS_HELP_STRING([--enable-opencl-icd],
1001           [Build an OpenCL ICD library to be loaded by an ICD implementation
1002            @<:@default=disabled@:>@])],
1003     [enable_opencl_icd="$enableval"],
1004     [enable_opencl_icd=no])
1005
1006 AC_ARG_ENABLE([gallium-tests],
1007     [AS_HELP_STRING([--enable-gallium-tests],
1008         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1009     [enable_gallium_tests="$enableval"],
1010     [enable_gallium_tests=no])
1011
1012 # Option for Gallium drivers
1013
1014 # Keep this in sync with the --with-gallium-drivers help string default value
1015 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1016
1017 AC_ARG_WITH([gallium-drivers],
1018     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1019         [comma delimited Gallium drivers list, e.g.
1020         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1021         @<:@default=r300,r600,svga,swrast@:>@])],
1022     [with_gallium_drivers="$withval"],
1023     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1024
1025 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1026 # here so that the script doesn't choke on an unknown driver name later.
1027 case "$with_gallium_drivers" in
1028     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1029     no) with_gallium_drivers='' ;;
1030 esac
1031
1032 if test "x$enable_opengl" = xno -a \
1033         "x$enable_gles1" = xno -a \
1034         "x$enable_gles2" = xno -a \
1035         "x$enable_nine" = xno -a \
1036         "x$enable_xa" = xno -a \
1037         "x$enable_xvmc" = xno -a \
1038         "x$enable_vdpau" = xno -a \
1039         "x$enable_omx" = xno -a \
1040         "x$enable_va" = xno -a \
1041         "x$enable_opencl" = xno; then
1042     AC_MSG_ERROR([at least one API should be enabled])
1043 fi
1044
1045 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1046 if test "x$enable_opengl" = xno -a \
1047         "x$enable_gles1" = xyes; then
1048     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1049 fi
1050
1051 if test "x$enable_opengl" = xno -a \
1052         "x$enable_gles2" = xyes; then
1053     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1054 fi
1055
1056 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1057 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1058 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1059 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1060                                         "x$enable_gles1" = xyes -o \
1061                                         "x$enable_gles2" = xyes)
1062
1063 # Validate GLX options
1064 if test "x$enable_glx" = xyes; then
1065     if test "x$enable_dri" = xyes; then
1066         enable_glx=dri
1067     elif test -n "$with_gallium_drivers"; then
1068         enable_glx=gallium-xlib
1069     else
1070         enable_glx=xlib
1071     fi
1072 fi
1073 case "x$enable_glx" in
1074 xdri | xxlib | xgallium-xlib)
1075     # GLX requires OpenGL
1076     if test "x$enable_opengl" = xno; then
1077         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1078     fi
1079
1080     # Check individual dependencies
1081     case "x$enable_glx" in
1082     xdri)
1083         if test "x$enable_dri" = xno; then
1084             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1085         fi
1086         ;;
1087     xxlib)
1088         if test "x$enable_dri" = xyes; then
1089             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1090         fi
1091         ;;
1092     xgallium-xlib )
1093         if test "x$enable_dri" = xyes; then
1094             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1095         fi
1096         if test -z "$with_gallium_drivers"; then
1097             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1098         fi
1099         ;;
1100     esac
1101     ;;
1102 xno)
1103     ;;
1104 *)
1105     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1106     ;;
1107 esac
1108
1109 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1110 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1111 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1112 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1113
1114 dnl
1115 dnl Libglvnd configuration
1116 dnl
1117 AC_ARG_ENABLE([libglvnd],
1118     [AS_HELP_STRING([--enable-libglvnd],
1119         [Build for libglvnd @<:@default=disabled@:>@])],
1120     [enable_libglvnd="$enableval"],
1121     [enable_libglvnd=no])
1122 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1123 if test "x$enable_libglvnd" = xyes ; then
1124     dnl XXX: update once we can handle more than libGL/glx.
1125     dnl Namely: we should error out if neither of the glvnd enabled libraries
1126     dnl are built
1127     case "x$enable_glx" in
1128     xno)
1129         AC_MSG_ERROR([cannot build libglvnd without GLX])
1130         ;;
1131     xxlib | xgallium-xlib )
1132         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1133         ;;
1134     xdri)
1135         ;;
1136     esac
1137
1138     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1139     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1140     DEFAULT_GL_LIB_NAME=GLX_mesa
1141 fi
1142
1143 # Check for libdrm
1144 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1145                   [have_libdrm=yes], [have_libdrm=no])
1146 if test "x$have_libdrm" = xyes; then
1147         DEFINES="$DEFINES -DHAVE_LIBDRM"
1148 fi
1149
1150 require_libdrm() {
1151     if test "x$have_libdrm" != xyes; then
1152        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1153     fi
1154 }
1155
1156
1157 # Select which platform-dependent DRI code gets built
1158 case "$host_os" in
1159 darwin*)
1160     dri_platform='apple' ;;
1161 cygwin*)
1162     dri_platform='windows' ;;
1163 gnu*)
1164     dri_platform='none' ;;
1165 *)
1166     dri_platform='drm' ;;
1167 esac
1168
1169 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1170     have_drisw_kms='yes'
1171 fi
1172
1173 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1174 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1175 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1176 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1177 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1178 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1179 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1180 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1181 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1182
1183 AC_ARG_ENABLE([shared-glapi],
1184     [AS_HELP_STRING([--enable-shared-glapi],
1185         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1186     [enable_shared_glapi="$enableval"],
1187     [enable_shared_glapi=yes])
1188
1189 case "x$enable_opengl$enable_gles1$enable_gles2" in
1190 x*yes*yes*)
1191     if test "x$enable_shared_glapi" = xno; then
1192         AC_MSG_ERROR([shared GLAPI required when building two or more of
1193                       the following APIs - opengl, gles1 gles2])
1194     fi
1195     ;;
1196 esac
1197
1198 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1199
1200 # Build the pipe-drivers as separate libraries/modules.
1201 # Do not touch this unless you know what you are doing.
1202 # XXX: Expose via configure option ?
1203 enable_shared_pipe_drivers=no
1204
1205 dnl
1206 dnl Driver specific build directories
1207 dnl
1208
1209 if test "x$enable_gallium_osmesa" = xyes; then
1210     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1211         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1212     fi
1213     if test "x$enable_osmesa" = xyes; then
1214         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1215     fi
1216 fi
1217
1218 AC_SUBST([MESA_LLVM])
1219
1220 # SHA1 hashing
1221 AC_ARG_WITH([sha1],
1222         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1223         [choose SHA1 implementation])])
1224 case "x$with_sha1" in
1225 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1226   ;;
1227 *)
1228         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1229 esac
1230
1231 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1232 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1233         with_sha1=libc
1234 fi
1235 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1236         AC_MSG_ERROR([sha1 in libc requested but not found])
1237 fi
1238 if test "x$with_sha1" = xlibc; then
1239         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1240                 [Use libc SHA1 functions])
1241         SHA1_LIBS=""
1242 fi
1243 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1244 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1245         with_sha1=CommonCrypto
1246 fi
1247 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1248         AC_MSG_ERROR([CommonCrypto requested but not found])
1249 fi
1250 if test "x$with_sha1" = xCommonCrypto; then
1251         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1252                 [Use CommonCrypto SHA1 functions])
1253         SHA1_LIBS=""
1254 fi
1255 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1256 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1257 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1258         with_sha1=CryptoAPI
1259 fi
1260 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1261         AC_MSG_ERROR([CryptoAPI requested but not found])
1262 fi
1263 if test "x$with_sha1" = xCryptoAPI; then
1264         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1265                 [Use CryptoAPI SHA1 functions])
1266         SHA1_LIBS=""
1267 fi
1268 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1269 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1270         with_sha1=libmd
1271 fi
1272 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1273         AC_MSG_ERROR([libmd requested but not found])
1274 fi
1275 if test "x$with_sha1" = xlibmd; then
1276         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1277                   [Use libmd SHA1 functions])
1278         SHA1_LIBS=-lmd
1279 fi
1280 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1281 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1282    with_sha1=libsha1
1283 fi
1284 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1285         AC_MSG_ERROR([libsha1 requested but not found])
1286 fi
1287 if test "x$with_sha1" = xlibsha1; then
1288         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1289                   [Use libsha1 for SHA1])
1290         SHA1_LIBS=-lsha1
1291 fi
1292 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1293 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1294         with_sha1=libnettle
1295 fi
1296 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1297         AC_MSG_ERROR([libnettle requested but not found])
1298 fi
1299 if test "x$with_sha1" = xlibnettle; then
1300         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1301                   [Use libnettle SHA1 functions])
1302         SHA1_LIBS=-lnettle
1303 fi
1304 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1305 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1306         with_sha1=libgcrypt
1307 fi
1308 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1309         AC_MSG_ERROR([libgcrypt requested but not found])
1310 fi
1311 if test "x$with_sha1" = xlibgcrypt; then
1312         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1313                   [Use libgcrypt SHA1 functions])
1314         SHA1_LIBS=-lgcrypt
1315 fi
1316 # We don't need all of the OpenSSL libraries, just libcrypto
1317 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1318 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1319                   [HAVE_OPENSSL_PKC=no])
1320 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1321         if test "x$with_sha1" = x; then
1322                 with_sha1=libcrypto
1323         fi
1324 else
1325         if test "x$with_sha1" = xlibcrypto; then
1326                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1327         fi
1328 fi
1329 if test "x$with_sha1" = xlibcrypto; then
1330         if test "x$HAVE_LIBCRYPTO" = xyes; then
1331                 SHA1_LIBS=-lcrypto
1332         else
1333                 SHA1_LIBS="$OPENSSL_LIBS"
1334                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1335         fi
1336 fi
1337 AC_MSG_CHECKING([for SHA1 implementation])
1338 AC_MSG_RESULT([$with_sha1])
1339 AC_SUBST(SHA1_LIBS)
1340 AC_SUBST(SHA1_CFLAGS)
1341
1342 # Enable a define for SHA1
1343 if test "x$with_sha1" != "x"; then
1344         DEFINES="$DEFINES -DHAVE_SHA1"
1345 fi
1346
1347 # Allow user to configure out the shader-cache feature
1348 AC_ARG_ENABLE([shader-cache],
1349     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1350     [enable_shader_cache="$enableval"],
1351     [if test "x$with_sha1" != "x"; then
1352         enable_shader_cache=yes
1353      else
1354         enable_shader_cache=no
1355      fi])
1356 if test "x$with_sha1" = "x"; then
1357     if test "x$enable_shader_cache" = "xyes"; then
1358         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1359     fi
1360 fi
1361 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1362 if test "x$enable_shader_cache" = "xyes"; then
1363    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1364 fi
1365
1366 if test "x$enable_dri" = xyes; then
1367     if test "$enable_static" = yes; then
1368         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1369     fi
1370
1371     # not a hard requirement as swrast does not depend on it
1372     if test "x$have_libdrm" = xyes; then
1373         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1374     fi
1375 fi
1376
1377 AC_ARG_ENABLE([driglx-direct],
1378     [AS_HELP_STRING([--disable-driglx-direct],
1379         [disable direct rendering in GLX and EGL for DRI \
1380             @<:@default=auto@:>@])],
1381     [driglx_direct="$enableval"],
1382     [driglx_direct="yes"])
1383
1384 dnl
1385 dnl libGL configuration per driver
1386 dnl
1387 case "x$enable_glx" in
1388 xxlib | xgallium-xlib)
1389     # Xlib-based GLX
1390     dri_modules="x11 xext xcb"
1391     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1392     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1393     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1394     GL_LIB_DEPS="$XLIBGL_LIBS"
1395     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1396     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1397     ;;
1398 xdri)
1399     # DRI-based GLX
1400     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1401
1402     # find the DRI deps for libGL
1403     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1404
1405     if test x"$driglx_direct" = xyes; then
1406         if test x"$dri_platform" = xdrm ; then
1407             DEFINES="$DEFINES -DGLX_USE_DRM"
1408             require_libdrm "Direct rendering"
1409
1410             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1411             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1412             if test x"$enable_dri3" = xyes; then
1413                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1414                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1415             fi
1416
1417             if test x"$enable_dri" = xyes; then
1418                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1419             fi
1420
1421             if test x"$enable_dri3" = xyes; then
1422                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1423                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1424                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1425             fi
1426         fi
1427         if test x"$dri_platform" = xapple ; then
1428             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1429         fi
1430         if test x"$dri_platform" = xwindows ; then
1431             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1432         fi
1433     fi
1434
1435     # add xf86vidmode if available
1436     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1437     if test "$HAVE_XF86VIDMODE" = yes ; then
1438         dri_modules="$dri_modules xxf86vm"
1439     fi
1440
1441     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1442     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1443     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1444     GL_LIB_DEPS="$DRIGL_LIBS"
1445
1446     # need DRM libs, $PTHREAD_LIBS, etc.
1447     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1448     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1449     ;;
1450 esac
1451
1452 # This is outside the case (above) so that it is invoked even for non-GLX
1453 # builds.
1454 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1455
1456 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1457 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1458 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1459 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1460
1461 AC_SUBST([X11_INCLUDES])
1462 AC_SUBST([GL_LIB_DEPS])
1463 AC_SUBST([GL_PC_REQ_PRIV])
1464 AC_SUBST([GL_PC_LIB_PRIV])
1465 AC_SUBST([GL_PC_CFLAGS])
1466 AC_SUBST([DRI_PC_REQ_PRIV])
1467 AC_SUBST([GLESv1_CM_LIB_DEPS])
1468 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1469 AC_SUBST([GLESv2_LIB_DEPS])
1470 AC_SUBST([GLESv2_PC_LIB_PRIV])
1471
1472 AC_SUBST([HAVE_XF86VIDMODE])
1473
1474 dnl
1475 dnl More GLX setup
1476 dnl
1477 case "x$enable_glx" in
1478 xxlib | xgallium-xlib)
1479     DEFINES="$DEFINES -DUSE_XSHM"
1480     ;;
1481 xdri)
1482     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1483     if test "x$driglx_direct" = xyes; then
1484         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1485     fi
1486     ;;
1487 esac
1488
1489 dnl
1490 dnl TLS detection
1491 dnl
1492
1493 AC_ARG_ENABLE([glx-tls],
1494     [AS_HELP_STRING([--enable-glx-tls],
1495         [enable TLS support in GLX @<:@default=disabled@:>@])],
1496     [GLX_USE_TLS="$enableval"],
1497     [GLX_USE_TLS=no])
1498 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1499
1500 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1501       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1502
1503 dnl Read-only text section on x86 hardened platforms
1504 AC_ARG_ENABLE([glx-read-only-text],
1505     [AS_HELP_STRING([--enable-glx-read-only-text],
1506         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1507     [enable_glx_read_only_text="$enableval"],
1508     [enable_glx_read_only_text=no])
1509 if test "x$enable_glx_read_only_text" = xyes; then
1510     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1511 fi
1512
1513 dnl
1514 dnl More DRI setup
1515 dnl
1516 dnl Directory for DRI drivers
1517 AC_ARG_WITH([dri-driverdir],
1518     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1519         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1520     [DRI_DRIVER_INSTALL_DIR="$withval"],
1521     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1522 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1523 dnl Extra search path for DRI drivers
1524 AC_ARG_WITH([dri-searchpath],
1525     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1526         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1527     [DRI_DRIVER_SEARCH_DIR="$withval"],
1528     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1529 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1530 dnl Which drivers to build - default is chosen by platform
1531 AC_ARG_WITH([dri-drivers],
1532     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1533         [comma delimited classic DRI drivers list, e.g.
1534         "swrast,i965,radeon" @<:@default=auto@:>@])],
1535     [with_dri_drivers="$withval"],
1536     [with_dri_drivers=auto])
1537
1538 if test "x$with_dri_drivers" = xauto; then
1539     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1540         with_dri_drivers="yes"
1541     else
1542         with_dri_drivers="no"
1543     fi
1544 fi
1545 if test "x$with_dri_drivers" = xno; then
1546     with_dri_drivers=''
1547 fi
1548
1549 dnl If $with_dri_drivers is yes, drivers will be added through
1550 dnl platform checks. Set DEFINES and LIB_DEPS
1551 if test "x$enable_dri" = xyes; then
1552     # Platform specific settings and drivers to build
1553     case "$host_os" in
1554     linux*)
1555         DEFINES="$DEFINES -DHAVE_ALIAS"
1556         if test "x$enable_dri3" = xyes; then
1557             DEFINES="$DEFINES -DHAVE_DRI3"
1558         fi
1559
1560         case "$host_cpu" in
1561         powerpc* | sparc*)
1562             # Build only the drivers for cards that exist on PowerPC/sparc
1563             if test "x$with_dri_drivers" = "xyes"; then
1564                 with_dri_drivers="r200 radeon swrast"
1565             fi
1566             ;;
1567         esac
1568         ;;
1569     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1570         DEFINES="$DEFINES -DHAVE_ALIAS"
1571         ;;
1572     gnu*)
1573         DEFINES="$DEFINES -DHAVE_ALIAS"
1574         ;;
1575     cygwin*)
1576         if test "x$with_dri_drivers" = "xyes"; then
1577             with_dri_drivers="swrast"
1578         fi
1579         ;;
1580     darwin*)
1581         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1582         if test "x$with_dri_drivers" = "xyes"; then
1583             with_dri_drivers="swrast"
1584         fi
1585         ;;
1586     esac
1587
1588     # default drivers
1589     if test "x$with_dri_drivers" = "xyes"; then
1590         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1591     fi
1592
1593     # Check for expat
1594     PKG_CHECK_MODULES([EXPAT], [expat], [],
1595         # expat version 2.0 and earlier do not provide expat.pc
1596         [AC_CHECK_HEADER([expat.h],[],
1597                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1598          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1599                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1600          EXPAT_LIBS="-lexpat"])
1601
1602     # put all the necessary libs together
1603     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1604 fi
1605
1606 AC_SUBST([DRI_LIB_DEPS])
1607
1608 DRI_DIRS=''
1609 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1610 if test -n "$with_dri_drivers"; then
1611     if test "x$enable_opengl" != xyes; then
1612         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1613     fi
1614
1615     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1616     for driver in $dri_drivers; do
1617         DRI_DIRS="$DRI_DIRS $driver"
1618         case "x$driver" in
1619         xi915)
1620             HAVE_I915_DRI=yes;
1621             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1622             ;;
1623         xi965)
1624             HAVE_I965_DRI=yes;
1625             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1626             ;;
1627         xnouveau)
1628             HAVE_NOUVEAU_DRI=yes;
1629             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1630             ;;
1631         xradeon)
1632             HAVE_RADEON_DRI=yes;
1633             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1634             ;;
1635         xr200)
1636             HAVE_R200_DRI=yes;
1637             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1638             ;;
1639         xswrast)
1640             HAVE_SWRAST_DRI=yes;
1641             ;;
1642         *)
1643             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1644             ;;
1645         esac
1646     done
1647     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1648 fi
1649
1650
1651 #
1652 # Vulkan driver configuration
1653 #
1654
1655 AC_ARG_WITH([vulkan-drivers],
1656     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1657         [comma delimited Vulkan drivers list, e.g.
1658         "intel"
1659         @<:@default=no@:>@])],
1660     [with_vulkan_drivers="$withval"],
1661     [with_vulkan_drivers="no"])
1662
1663 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1664 # here so that the script doesn't choke on an unknown driver name later.
1665 case "x$with_vulkan_drivers" in
1666     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1667     xno) with_vulkan_drivers='' ;;
1668 esac
1669
1670 AC_ARG_WITH([vulkan-icddir],
1671     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1672         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1673     [VULKAN_ICD_INSTALL_DIR="$withval"],
1674     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1675 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1676
1677 AC_ARG_ENABLE([vulkan-icd-full-driver-path],
1678    [AS_HELP_STRING([--disable-vulkan-icd-full-driver-path],
1679                    [create Vulkan ICD files with just a .so name and no path])],
1680    [vulkan_icd_driver_path="$enableval"],
1681    [vulkan_icd_driver_path="yes"])
1682 AM_CONDITIONAL(VULKAN_ICD_DRIVER_PATH, test "x$vulkan_icd_driver_path" = xyes)
1683
1684 if test -n "$with_vulkan_drivers"; then
1685     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1686     for driver in $VULKAN_DRIVERS; do
1687         case "x$driver" in
1688         xintel)
1689             if test "x$HAVE_I965_DRI" != xyes; then
1690                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1691             fi
1692             if test "x$with_sha1" == "x"; then
1693                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1694             fi
1695             HAVE_INTEL_VULKAN=yes;
1696
1697             ;;
1698         xradeon)
1699             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1700             HAVE_RADEON_VULKAN=yes;
1701             if test "x$with_sha1" == "x"; then
1702                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1703             fi
1704             ;;
1705         *)
1706             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1707             ;;
1708         esac
1709     done
1710     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1711 fi
1712
1713
1714 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1715 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1716                                   "x$enable_osmesa" = xyes -o \
1717                                   -n "$DRI_DIRS")
1718
1719 dnl
1720 dnl OSMesa configuration
1721 dnl
1722
1723 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1724 AC_ARG_WITH([osmesa-bits],
1725     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1726         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1727     [osmesa_bits="$withval"],
1728     [osmesa_bits=8])
1729 if test "x$osmesa_bits" != x8; then
1730     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1731         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1732         osmesa_bits=8
1733     fi
1734 fi
1735 case "x$osmesa_bits" in
1736 x8)
1737     OSMESA_LIB="${OSMESA_LIB}"
1738     ;;
1739 x16|x32)
1740     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1741     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1742     ;;
1743 *)
1744     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1745     ;;
1746 esac
1747
1748 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1749     # only link libraries with osmesa if shared
1750     if test "$enable_static" = no; then
1751         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1752     else
1753         OSMESA_LIB_DEPS=""
1754     fi
1755     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1756 fi
1757
1758 AC_SUBST([OSMESA_LIB_DEPS])
1759 AC_SUBST([OSMESA_PC_REQ])
1760 AC_SUBST([OSMESA_PC_LIB_PRIV])
1761
1762 dnl
1763 dnl gbm configuration
1764 dnl
1765 if test "x$enable_gbm" = xyes; then
1766     if test "x$enable_dri" = xyes; then
1767         if test "x$enable_shared_glapi" = xno; then
1768             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1769         fi
1770     else
1771         # Strictly speaking libgbm does not require --enable-dri, although
1772         # both of its backends do. Thus one can build libgbm without any
1773         # backends if --disable-dri is set.
1774         # To avoid unnecessary complexity of checking if at least one backend
1775         # is available when building, just mandate --enable-dri.
1776         AC_MSG_ERROR([gbm requires --enable-dri])
1777     fi
1778 fi
1779 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1780 # FINISHME: GBM has a number of dependencies which we should add below
1781 GBM_PC_REQ_PRIV=""
1782 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1783 AC_SUBST([GBM_PC_REQ_PRIV])
1784 AC_SUBST([GBM_PC_LIB_PRIV])
1785
1786 dnl
1787 dnl EGL configuration
1788 dnl
1789 EGL_CLIENT_APIS=""
1790
1791 if test "x$enable_egl" = xyes; then
1792     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1793
1794     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1795
1796     if test "$enable_static" != yes; then
1797         if test "x$enable_dri" = xyes; then
1798             HAVE_EGL_DRIVER_DRI2=1
1799             if test "x$enable_shared_glapi" = xno; then
1800                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1801             fi
1802             if test "x$enable_dri3" = xyes; then
1803                 HAVE_EGL_DRIVER_DRI3=1
1804                 if test "x$enable_shared_glapi" = xno; then
1805                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1806                 fi
1807             fi
1808         else
1809             # Avoid building an "empty" libEGL. Drop/update this
1810             # when other backends (haiku?) come along.
1811             AC_MSG_ERROR([egl requires --enable-dri])
1812         fi
1813
1814     fi
1815 fi
1816 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1817 AC_SUBST([EGL_LIB_DEPS])
1818
1819 gallium_st="mesa"
1820
1821 dnl
1822 dnl XA configuration
1823 dnl
1824 if test "x$enable_xa" = xyes; then
1825     if test "x$with_gallium_drivers" = xswrast; then
1826        AC_MSG_ERROR([
1827           Building xa requires at least one non swrast gallium driver.
1828           If you are looking to use libxatracker.so with the VMware driver,
1829           make sure to include svga in the gallium drivers list, apart from
1830           enabling XA.
1831           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1832     fi
1833     gallium_st="$gallium_st xa"
1834 fi
1835 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1836
1837 dnl
1838 dnl Gallium G3DVL configuration
1839 dnl
1840 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1841     if test "x$enable_xvmc" = xauto; then
1842         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1843     fi
1844
1845     if test "x$enable_vdpau" = xauto; then
1846         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1847     fi
1848
1849     if test "x$enable_omx" = xauto; then
1850         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1851     fi
1852
1853     if test "x$enable_va" = xauto; then
1854         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1855     fi
1856 fi
1857
1858 if test "x$enable_dri" = xyes -o \
1859         "x$enable_xvmc" = xyes -o \
1860         "x$enable_vdpau" = xyes -o \
1861         "x$enable_omx" = xyes -o \
1862         "x$enable_va" = xyes; then
1863     need_gallium_vl=yes
1864 fi
1865 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1866
1867 if test "x$enable_xvmc" = xyes -o \
1868         "x$enable_vdpau" = xyes -o \
1869         "x$enable_omx" = xyes -o \
1870         "x$enable_va" = xyes; then
1871     if test x"$enable_dri3" = xyes; then
1872         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1873                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1874     else
1875         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1876     fi
1877     need_gallium_vl_winsys=yes
1878 fi
1879 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1880
1881 if test "x$enable_xvmc" = xyes; then
1882     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1883     gallium_st="$gallium_st xvmc"
1884 fi
1885 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1886
1887 if test "x$enable_vdpau" = xyes; then
1888     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1889     gallium_st="$gallium_st vdpau"
1890     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1891 fi
1892 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1893
1894 if test "x$enable_omx" = xyes; then
1895     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1896     gallium_st="$gallium_st omx"
1897 fi
1898 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1899
1900 if test "x$enable_va" = xyes; then
1901     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1902     gallium_st="$gallium_st va"
1903 fi
1904 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1905
1906 dnl
1907 dnl Nine Direct3D9 configuration
1908 dnl
1909 if test "x$enable_nine" = xyes; then
1910     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1911         AC_MSG_ERROR([nine requires the gallium swrast driver])
1912     fi
1913     if test "x$with_gallium_drivers" = xswrast; then
1914         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1915     fi
1916     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1917         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1918     fi
1919
1920     if test "x$enable_dri3" = xno; then
1921         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1922     fi
1923
1924     gallium_st="$gallium_st nine"
1925 fi
1926 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1927
1928 dnl
1929 dnl OpenCL configuration
1930 dnl
1931
1932 AC_ARG_WITH([clang-libdir],
1933    [AS_HELP_STRING([--with-clang-libdir],
1934          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1935    [CLANG_LIBDIR="$withval"],
1936    [CLANG_LIBDIR=''])
1937
1938 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1939 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1940
1941 if test "x$have_libelf" = xno; then
1942    LIBELF_LIBS=''
1943    LIBELF_CFLAGS=''
1944    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1945    AC_SUBST([LIBELF_LIBS])
1946    AC_SUBST([LIBELF_CFLAGS])
1947 fi
1948
1949 if test "x$enable_opencl" = xyes; then
1950     if test -z "$with_gallium_drivers"; then
1951         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1952     fi
1953
1954     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1955         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1956     fi
1957
1958     if test "x$have_libclc" = xno; then
1959         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1960                     Make sure the directory containing libclc.pc is specified in your
1961                     PKG_CONFIG_PATH environment variable.
1962                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1963     else
1964         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1965         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1966         AC_SUBST([LIBCLC_INCLUDEDIR])
1967         AC_SUBST([LIBCLC_LIBEXECDIR])
1968     fi
1969
1970     gallium_st="$gallium_st clover"
1971
1972     if test "x$enable_opencl_icd" = xyes; then
1973         OPENCL_LIBNAME="MesaOpenCL"
1974     else
1975         OPENCL_LIBNAME="OpenCL"
1976     fi
1977
1978     if test "x$have_libelf" != xyes; then
1979        AC_MSG_ERROR([Clover requires libelf])
1980     fi
1981 fi
1982 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1983 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1984 AC_SUBST([OPENCL_LIBNAME])
1985
1986 dnl
1987 dnl Gallium configuration
1988 dnl
1989 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1990
1991 AC_SUBST([LLVM_BINDIR])
1992 AC_SUBST([LLVM_CFLAGS])
1993 AC_SUBST([LLVM_CPPFLAGS])
1994 AC_SUBST([LLVM_CXXFLAGS])
1995 AC_SUBST([LLVM_LIBDIR])
1996 AC_SUBST([LLVM_LIBS])
1997 AC_SUBST([LLVM_LDFLAGS])
1998 AC_SUBST([LLVM_INCLUDEDIR])
1999 AC_SUBST([LLVM_VERSION])
2000 AC_SUBST([CLANG_RESOURCE_DIR])
2001
2002 case "x$enable_opengl$enable_gles1$enable_gles2" in
2003 x*yes*)
2004     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2005     ;;
2006 esac
2007
2008 AC_SUBST([VG_LIB_DEPS])
2009 AC_SUBST([EGL_CLIENT_APIS])
2010
2011 dnl
2012 dnl EGL Platforms configuration
2013 dnl
2014 AC_ARG_WITH([egl-platforms],
2015     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2016         [comma delimited native platforms libEGL supports, e.g.
2017         "x11,drm" @<:@default=auto@:>@])],
2018     [with_egl_platforms="$withval"],
2019     [if test "x$enable_egl" = xyes; then
2020         with_egl_platforms="x11"
2021     else
2022         with_egl_platforms=""
2023     fi])
2024
2025 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2026     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2027 fi
2028
2029 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2030         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2031         WAYLAND_SCANNER='')
2032 if test "x$WAYLAND_SCANNER" = x; then
2033     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2034 fi
2035
2036 # Do per-EGL platform setups and checks
2037 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2038 for plat in $egl_platforms; do
2039         case "$plat" in
2040         wayland)
2041
2042                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2043
2044                 if test "x$WAYLAND_SCANNER" = x; then
2045                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2046                 fi
2047                 ;;
2048
2049         x11)
2050                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2051                 ;;
2052
2053         drm)
2054                 test "x$enable_gbm" = "xno" &&
2055                         AC_MSG_ERROR([EGL platform drm needs gbm])
2056                 ;;
2057
2058         surfaceless)
2059                 ;;
2060
2061         android)
2062                 ;;
2063
2064         *)
2065                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2066                 ;;
2067         esac
2068
2069         case "$plat" in
2070         wayland|drm|surfaceless)
2071                 require_libdrm "Platform $plat"
2072                 ;;
2073         esac
2074 done
2075
2076 # libEGL wants to default to the first platform specified in
2077 # ./configure.  parse that here.
2078 if test "x$egl_platforms" != "x"; then
2079     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2080     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2081 else
2082     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2083 fi
2084
2085 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2086 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2087 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2088 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2089 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2090
2091 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2092
2093 AC_SUBST([EGL_NATIVE_PLATFORM])
2094 AC_SUBST([EGL_CFLAGS])
2095
2096 # If we don't have the X11 platform, set this define so we don't try to include
2097 # the X11 headers.
2098 if ! echo "$egl_platforms" | grep -q 'x11'; then
2099     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2100     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2101 fi
2102
2103 dnl
2104 dnl Gallium LLVM
2105 dnl
2106 AC_ARG_ENABLE([gallium-llvm],
2107     [AS_HELP_STRING([--enable-gallium-llvm],
2108         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2109     [enable_gallium_llvm="$enableval"],
2110     [enable_gallium_llvm=auto])
2111
2112 AC_ARG_ENABLE([llvm-shared-libs],
2113     [AS_HELP_STRING([--enable-llvm-shared-libs],
2114         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2115     [enable_llvm_shared_libs="$enableval"],
2116     [enable_llvm_shared_libs=yes])
2117
2118 AC_ARG_WITH([llvm-prefix],
2119     [AS_HELP_STRING([--with-llvm-prefix],
2120         [Prefix for LLVM installations in non-standard locations])],
2121     [llvm_prefix="$withval"],
2122     [llvm_prefix=''])
2123
2124
2125 # Call this inside ` ` to get the return value.
2126 # $1 is the llvm-config command with arguments.
2127 strip_unwanted_llvm_flags() {
2128     # Use \> (marks the end of the word)
2129     echo `$1` | sed \
2130         -e 's/-march=\S*//g' \
2131         -e 's/-mtune=\S*//g' \
2132         -e 's/-mcpu=\S*//g' \
2133         -e 's/-DNDEBUG\>//g' \
2134         -e 's/-D_GNU_SOURCE\>//g' \
2135         -e 's/-pedantic\>//g' \
2136         -e 's/-Wcovered-switch-default\>//g' \
2137         -e 's/-O.\>//g' \
2138         -e 's/-g\>//g' \
2139         -e 's/-Wall\>//g' \
2140         -e 's/-Wcast-qual\>//g' \
2141         -e 's/-Woverloaded-virtual\>//g' \
2142         -e 's/-fcolor-diagnostics\>//g' \
2143         -e 's/-fdata-sections\>//g' \
2144         -e 's/-ffunction-sections\>//g' \
2145         -e 's/-fno-exceptions\>//g' \
2146         -e 's/-fomit-frame-pointer\>//g' \
2147         -e 's/-fvisibility-inlines-hidden\>//g' \
2148         -e 's/-fPIC\>//g' \
2149         -e 's/-fstack-protector-strong\>//g'
2150 }
2151
2152 llvm_check_version_for() {
2153     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2154         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2155     fi
2156 }
2157
2158
2159
2160 if test -z "$with_gallium_drivers"; then
2161     enable_gallium_llvm=no
2162 fi
2163 if test "x$enable_gallium_llvm" = xauto; then
2164     case "$host_cpu" in
2165     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2166     esac
2167 fi
2168 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2169     if test -n "$llvm_prefix"; then
2170         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2171     else
2172         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2173     fi
2174
2175     if test "x$LLVM_CONFIG" != xno; then
2176         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2177         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2178         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2179         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2180         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2181         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2182         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2183         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2184
2185         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2186             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2187         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2188             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2189
2190         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2191         if test -z "$LLVM_VERSION_PATCH"; then
2192             LLVM_VERSION_PATCH=0
2193         fi
2194
2195         if test -n "${LLVM_VERSION_MAJOR}"; then
2196             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2197         else
2198             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2199         fi
2200
2201         LLVM_REQUIRED_VERSION_MAJOR="3"
2202         LLVM_REQUIRED_VERSION_MINOR="3"
2203         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2204             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2205         fi
2206
2207         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2208
2209         if $LLVM_CONFIG --components | grep -q inteljitevents ; then
2210             LLVM_COMPONENTS="${LLVM_COMPONENTS} inteljitevents"
2211         fi
2212
2213         if test "x$enable_opencl" = xyes; then
2214             llvm_check_version_for "3" "6" "0" "opencl"
2215
2216             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2217             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2218         fi
2219         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2220         MESA_LLVM=1
2221
2222         dnl Check for Clang internal headers
2223         if test "x$enable_opencl" = xyes; then
2224             if test -z "$CLANG_LIBDIR"; then
2225                 CLANG_LIBDIR=${LLVM_LIBDIR}
2226             fi
2227             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2228             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2229                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2230         fi
2231     else
2232         MESA_LLVM=0
2233         LLVM_VERSION_INT=0
2234     fi
2235 else
2236     MESA_LLVM=0
2237     LLVM_VERSION_INT=0
2238
2239     if test "x$enable_opencl" = xyes; then
2240         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2241     fi
2242 fi
2243
2244 dnl Directory for XVMC libs
2245 AC_ARG_WITH([xvmc-libdir],
2246     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2247         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2248     [XVMC_LIB_INSTALL_DIR="$withval"],
2249     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2250 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2251
2252 dnl
2253 dnl Gallium Tests
2254 dnl
2255 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2256
2257 dnl Directory for VDPAU libs
2258 AC_ARG_WITH([vdpau-libdir],
2259     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2260         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2261     [VDPAU_LIB_INSTALL_DIR="$withval"],
2262     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2263 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2264
2265 dnl Directory for OMX libs
2266
2267 AC_ARG_WITH([omx-libdir],
2268     [AS_HELP_STRING([--with-omx-libdir=DIR],
2269         [directory for the OMX libraries])],
2270     [OMX_LIB_INSTALL_DIR="$withval"],
2271     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2272 AC_SUBST([OMX_LIB_INSTALL_DIR])
2273
2274 dnl Directory for VA libs
2275
2276 AC_ARG_WITH([va-libdir],
2277     [AS_HELP_STRING([--with-va-libdir=DIR],
2278         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2279     [VA_LIB_INSTALL_DIR="$withval"],
2280     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2281 AC_SUBST([VA_LIB_INSTALL_DIR])
2282
2283 AC_ARG_WITH([d3d-libdir],
2284     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2285         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2286     [D3D_DRIVER_INSTALL_DIR="$withval"],
2287     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2288 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2289
2290 dnl
2291 dnl Gallium helper functions
2292 dnl
2293 gallium_require_llvm() {
2294     if test "x$MESA_LLVM" = x0; then
2295         case "$host" in *gnux32) return;; esac
2296         case "$host_cpu" in
2297         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2298         esac
2299     fi
2300 }
2301
2302 dnl This is for Glamor. Skip this if OpenGL is disabled.
2303 require_egl_drm() {
2304     if test "x$enable_opengl" = xno; then
2305         return 0
2306     fi
2307
2308     case "$with_egl_platforms" in
2309         *drm*)
2310             ;;
2311          *)
2312             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2313             ;;
2314     esac
2315     if test "x$enable_gbm" != xyes; then
2316             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2317     fi
2318 }
2319
2320 radeon_llvm_check() {
2321     if test ${LLVM_VERSION_INT} -lt 307; then
2322         amdgpu_llvm_target_name='r600'
2323     else
2324         amdgpu_llvm_target_name='amdgpu'
2325     fi
2326     llvm_check_version_for $2 $3 $4 $1
2327     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2328         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2329     fi
2330     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2331     NEED_RADEON_LLVM=yes
2332     if test "x$have_libelf" != xyes; then
2333        AC_MSG_ERROR([$1 requires libelf when using llvm])
2334     fi
2335 }
2336
2337 radeon_gallium_llvm_check() {
2338     if test "x$enable_gallium_llvm" != "xyes"; then
2339         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2340     fi
2341     radeon_llvm_check $*
2342 }
2343
2344 swr_llvm_check() {
2345     gallium_require_llvm $1
2346     if test ${LLVM_VERSION_INT} -lt 306; then
2347         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2348     fi
2349     if test "x$enable_gallium_llvm" != "xyes"; then
2350         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2351     fi
2352 }
2353
2354 swr_require_cxx_feature_flags() {
2355     feature_name="$1"
2356     preprocessor_test="$2"
2357     option_list="$3"
2358     output_var="$4"
2359
2360     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2361     AC_LANG_PUSH([C++])
2362     save_CXXFLAGS="$CXXFLAGS"
2363     save_IFS="$IFS"
2364     IFS=","
2365     found=0
2366     for opts in $option_list
2367     do
2368         unset IFS
2369         CXXFLAGS="$opts $save_CXXFLAGS"
2370         AC_COMPILE_IFELSE(
2371             [AC_LANG_PROGRAM(
2372                 [   #if !($preprocessor_test)
2373                     #error
2374                     #endif
2375                 ])],
2376             [found=1; break],
2377             [])
2378         IFS=","
2379     done
2380     IFS="$save_IFS"
2381     CXXFLAGS="$save_CXXFLAGS"
2382     AC_LANG_POP([C++])
2383     if test $found -eq 1; then
2384         AC_MSG_RESULT([$opts])
2385         eval "$output_var=\$opts"
2386         return 0
2387     fi
2388     AC_MSG_RESULT([no])
2389     AC_MSG_ERROR([swr requires $feature_name support])
2390     return 1
2391 }
2392
2393 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2394 if test -n "$with_gallium_drivers"; then
2395     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2396     for driver in $gallium_drivers; do
2397         case "x$driver" in
2398         xsvga)
2399             HAVE_GALLIUM_SVGA=yes
2400             require_libdrm "svga"
2401             ;;
2402         xi915)
2403             HAVE_GALLIUM_I915=yes
2404             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2405             require_libdrm "Gallium i915"
2406             ;;
2407         xilo)
2408             HAVE_GALLIUM_ILO=yes
2409             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2410             require_libdrm "Gallium i965/ilo"
2411             ;;
2412         xr300)
2413             HAVE_GALLIUM_R300=yes
2414             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2415             require_libdrm "Gallium R300"
2416             gallium_require_llvm "Gallium R300"
2417             ;;
2418         xr600)
2419             HAVE_GALLIUM_R600=yes
2420             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2421             require_libdrm "Gallium R600"
2422             if test "x$enable_opencl" = xyes; then
2423                 radeon_gallium_llvm_check "r600g" "3" "6" "0"
2424                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2425             fi
2426             ;;
2427         xradeonsi)
2428             HAVE_GALLIUM_RADEONSI=yes
2429             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2430             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2431             require_libdrm "radeonsi"
2432             radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2433             require_egl_drm "radeonsi"
2434             ;;
2435         xnouveau)
2436             HAVE_GALLIUM_NOUVEAU=yes
2437             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2438             require_libdrm "nouveau"
2439             ;;
2440         xfreedreno)
2441             HAVE_GALLIUM_FREEDRENO=yes
2442             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2443             require_libdrm "freedreno"
2444             ;;
2445         xswrast)
2446             HAVE_GALLIUM_SOFTPIPE=yes
2447             if test "x$MESA_LLVM" = x1; then
2448                 HAVE_GALLIUM_LLVMPIPE=yes
2449             fi
2450             ;;
2451         xswr)
2452             swr_llvm_check "swr"
2453
2454             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2455                 ",-std=c++11" \
2456                 SWR_CXX11_CXXFLAGS
2457             AC_SUBST([SWR_CXX11_CXXFLAGS])
2458
2459             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2460                 ",-mavx,-march=core-avx" \
2461                 SWR_AVX_CXXFLAGS
2462             AC_SUBST([SWR_AVX_CXXFLAGS])
2463
2464             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2465                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2466                 SWR_AVX2_CXXFLAGS
2467             AC_SUBST([SWR_AVX2_CXXFLAGS])
2468
2469             HAVE_GALLIUM_SWR=yes
2470             ;;
2471         xvc4)
2472             HAVE_GALLIUM_VC4=yes
2473             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2474             require_libdrm "vc4"
2475
2476             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2477                               [USE_VC4_SIMULATOR=yes;
2478                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2479                               [USE_VC4_SIMULATOR=no])
2480             ;;
2481         xvirgl)
2482             HAVE_GALLIUM_VIRGL=yes
2483             require_libdrm "virgl"
2484             require_egl_drm "virgl"
2485             ;;
2486         *)
2487             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2488             ;;
2489         esac
2490     done
2491 fi
2492
2493 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2494     radeon_llvm_check "radv" "3" "9" "0"
2495 fi
2496
2497 dnl Set LLVM_LIBS - This is done after the driver configuration so
2498 dnl that drivers can add additional components to LLVM_COMPONENTS.
2499 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2500 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2501 dnl this was causing the same libraries to be appear multiple times
2502 dnl in LLVM_LIBS.
2503
2504 if test "x$MESA_LLVM" != x0; then
2505
2506     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2507        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2508     fi
2509     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2510
2511     dnl llvm-config may not give the right answer when llvm is a built as a
2512     dnl single shared library, so we must work the library name out for
2513     dnl ourselves.
2514     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2515     if test "x$enable_llvm_shared_libs" = xyes; then
2516         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2517         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2518         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2519
2520         if test "x$llvm_have_one_so" = xyes; then
2521             dnl LLVM was built using auto*, so there is only one shared object.
2522             LLVM_LIBS="-l$LLVM_SO_NAME"
2523         else
2524             dnl If LLVM was built with CMake, there will be one shared object per
2525             dnl component.
2526             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2527                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2528         Please make sure you have built llvm with the --enable-shared option
2529         and that your llvm libraries are installed in $LLVM_LIBDIR
2530         If you have installed your llvm libraries to a different directory you
2531         can use the --with-llvm-prefix= configure flag to specify this directory.
2532         NOTE: Mesa is attempting to use llvm shared libraries by default.
2533         If you do not want to build with llvm shared libraries and instead want to
2534         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2535         invocation and rebuild.])])
2536
2537            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2538            dnl install uses a shared object for each component and we have
2539            dnl already added all of these objects to LLVM_LIBS.
2540         fi
2541     else
2542         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2543         dnl We need to link to llvm system libs when using static libs
2544         dnl However, only llvm 3.5+ provides --system-libs
2545         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2546             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2547         fi
2548     fi
2549 fi
2550
2551 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2552 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2557 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2558                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2559 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2560 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2561 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2562 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2563 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2564 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2565                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2566                                          "x$HAVE_GALLIUM_SWR" = xyes)
2567 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2568 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2569
2570 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2571
2572 if test "x$enable_dri" = xyes; then
2573     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2574 fi
2575
2576 if test "x$have_drisw_kms" = xyes; then
2577     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2578 fi
2579 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2580
2581 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2582 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2583 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2584 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2585 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2586 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2587
2588 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2589 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2590
2591 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2592                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2593                                       "x$HAVE_RADEON_VULKAN" = xyes)
2594
2595 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2596                                         "x$HAVE_I965_DRI" = xyes)
2597
2598 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2599                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2600                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2601 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2602 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2603 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2604 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2605 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2606 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2607     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2608 fi
2609
2610 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2611 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2612 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2613 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2614                                         "x$enable_gallium_osmesa" = xyes)
2615
2616 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2617 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2618 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2619
2620 AC_SUBST([NINE_MAJOR], 1)
2621 AC_SUBST([NINE_MINOR], 0)
2622 AC_SUBST([NINE_TINY], 0)
2623 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2624
2625 AC_SUBST([VDPAU_MAJOR], 1)
2626 AC_SUBST([VDPAU_MINOR], 0)
2627
2628 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2629 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2630 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2631 AC_SUBST([VA_MINOR], $VA_MINOR)
2632
2633 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2634
2635 AC_SUBST([XVMC_MAJOR], 1)
2636 AC_SUBST([XVMC_MINOR], 0)
2637
2638 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2639 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2640 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2641 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2642
2643 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2644 AC_SUBST([XA_MINOR], $XA_MINOR)
2645 AC_SUBST([XA_TINY], $XA_TINY)
2646 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2647
2648 AC_SUBST([TIMESTAMP_CMD], '`test $(SOURCE_DATE_EPOCH) && echo $(SOURCE_DATE_EPOCH) || date +%s`')
2649
2650 AC_ARG_ENABLE(valgrind,
2651               [AS_HELP_STRING([--enable-valgrind],
2652                              [Build mesa with valgrind support (default: auto)])],
2653                              [VALGRIND=$enableval], [VALGRIND=auto])
2654 if test "x$VALGRIND" != xno; then
2655         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2656 fi
2657 AC_MSG_CHECKING([whether to enable Valgrind support])
2658 if test "x$VALGRIND" = xauto; then
2659         VALGRIND="$have_valgrind"
2660 fi
2661
2662 if test "x$VALGRIND" = "xyes"; then
2663         if ! test "x$have_valgrind" = xyes; then
2664                 AC_MSG_ERROR([Valgrind support required but not present])
2665         fi
2666         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2667 fi
2668
2669 AC_MSG_RESULT([$VALGRIND])
2670
2671 dnl Restore LDFLAGS and CPPFLAGS
2672 LDFLAGS="$_SAVE_LDFLAGS"
2673 CPPFLAGS="$_SAVE_CPPFLAGS"
2674
2675 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2676 if test "x$acv_mesa_CLANG" = xyes; then
2677     CFLAGS="$CFLAGS -Qunused-arguments"
2678     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2679 fi
2680
2681 dnl Add user CFLAGS and CXXFLAGS
2682 CFLAGS="$CFLAGS $USER_CFLAGS"
2683 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2684
2685 dnl Substitute the config
2686 AC_CONFIG_FILES([Makefile
2687                 src/Makefile
2688                 src/amd/Makefile
2689                 src/amd/common/Makefile
2690                 src/amd/vulkan/Makefile
2691                 src/compiler/Makefile
2692                 src/egl/Makefile
2693                 src/egl/main/egl.pc
2694                 src/egl/wayland/wayland-drm/Makefile
2695                 src/egl/wayland/wayland-egl/Makefile
2696                 src/egl/wayland/wayland-egl/wayland-egl.pc
2697                 src/gallium/Makefile
2698                 src/gallium/auxiliary/Makefile
2699                 src/gallium/auxiliary/pipe-loader/Makefile
2700                 src/gallium/drivers/freedreno/Makefile
2701                 src/gallium/drivers/ddebug/Makefile
2702                 src/gallium/drivers/i915/Makefile
2703                 src/gallium/drivers/ilo/Makefile
2704                 src/gallium/drivers/llvmpipe/Makefile
2705                 src/gallium/drivers/noop/Makefile
2706                 src/gallium/drivers/nouveau/Makefile
2707                 src/gallium/drivers/r300/Makefile
2708                 src/gallium/drivers/r600/Makefile
2709                 src/gallium/drivers/radeon/Makefile
2710                 src/gallium/drivers/radeonsi/Makefile
2711                 src/gallium/drivers/rbug/Makefile
2712                 src/gallium/drivers/softpipe/Makefile
2713                 src/gallium/drivers/svga/Makefile
2714                 src/gallium/drivers/swr/Makefile
2715                 src/gallium/drivers/trace/Makefile
2716                 src/gallium/drivers/vc4/Makefile
2717                 src/gallium/drivers/virgl/Makefile
2718                 src/gallium/state_trackers/clover/Makefile
2719                 src/gallium/state_trackers/dri/Makefile
2720                 src/gallium/state_trackers/glx/xlib/Makefile
2721                 src/gallium/state_trackers/nine/Makefile
2722                 src/gallium/state_trackers/omx/Makefile
2723                 src/gallium/state_trackers/osmesa/Makefile
2724                 src/gallium/state_trackers/va/Makefile
2725                 src/gallium/state_trackers/vdpau/Makefile
2726                 src/gallium/state_trackers/xa/Makefile
2727                 src/gallium/state_trackers/xvmc/Makefile
2728                 src/gallium/targets/d3dadapter9/Makefile
2729                 src/gallium/targets/d3dadapter9/d3d.pc
2730                 src/gallium/targets/dri/Makefile
2731                 src/gallium/targets/libgl-xlib/Makefile
2732                 src/gallium/targets/omx/Makefile
2733                 src/gallium/targets/opencl/Makefile
2734                 src/gallium/targets/opencl/mesa.icd
2735                 src/gallium/targets/osmesa/Makefile
2736                 src/gallium/targets/osmesa/osmesa.pc
2737                 src/gallium/targets/pipe-loader/Makefile
2738                 src/gallium/targets/va/Makefile
2739                 src/gallium/targets/vdpau/Makefile
2740                 src/gallium/targets/xa/Makefile
2741                 src/gallium/targets/xa/xatracker.pc
2742                 src/gallium/targets/xvmc/Makefile
2743                 src/gallium/tests/trivial/Makefile
2744                 src/gallium/tests/unit/Makefile
2745                 src/gallium/winsys/freedreno/drm/Makefile
2746                 src/gallium/winsys/i915/drm/Makefile
2747                 src/gallium/winsys/intel/drm/Makefile
2748                 src/gallium/winsys/nouveau/drm/Makefile
2749                 src/gallium/winsys/radeon/drm/Makefile
2750                 src/gallium/winsys/amdgpu/drm/Makefile
2751                 src/gallium/winsys/svga/drm/Makefile
2752                 src/gallium/winsys/sw/dri/Makefile
2753                 src/gallium/winsys/sw/kms-dri/Makefile
2754                 src/gallium/winsys/sw/null/Makefile
2755                 src/gallium/winsys/sw/wrapper/Makefile
2756                 src/gallium/winsys/sw/xlib/Makefile
2757                 src/gallium/winsys/vc4/drm/Makefile
2758                 src/gallium/winsys/virgl/drm/Makefile
2759                 src/gallium/winsys/virgl/vtest/Makefile
2760                 src/gbm/Makefile
2761                 src/gbm/main/gbm.pc
2762                 src/glx/Makefile
2763                 src/glx/apple/Makefile
2764                 src/glx/tests/Makefile
2765                 src/glx/windows/Makefile
2766                 src/glx/windows/windowsdriproto.pc
2767                 src/gtest/Makefile
2768                 src/intel/Makefile
2769                 src/intel/tools/Makefile
2770                 src/intel/vulkan/Makefile
2771                 src/loader/Makefile
2772                 src/mapi/Makefile
2773                 src/mapi/es1api/glesv1_cm.pc
2774                 src/mapi/es2api/glesv2.pc
2775                 src/mapi/glapi/gen/Makefile
2776                 src/mesa/Makefile
2777                 src/mesa/gl.pc
2778                 src/mesa/drivers/dri/dri.pc
2779                 src/mesa/drivers/dri/common/Makefile
2780                 src/mesa/drivers/dri/common/xmlpool/Makefile
2781                 src/mesa/drivers/dri/i915/Makefile
2782                 src/mesa/drivers/dri/i965/Makefile
2783                 src/mesa/drivers/dri/Makefile
2784                 src/mesa/drivers/dri/nouveau/Makefile
2785                 src/mesa/drivers/dri/r200/Makefile
2786                 src/mesa/drivers/dri/radeon/Makefile
2787                 src/mesa/drivers/dri/swrast/Makefile
2788                 src/mesa/drivers/osmesa/Makefile
2789                 src/mesa/drivers/osmesa/osmesa.pc
2790                 src/mesa/drivers/x11/Makefile
2791                 src/mesa/main/tests/Makefile
2792                 src/util/Makefile
2793                 src/util/tests/hash_table/Makefile
2794                 src/vulkan/wsi/Makefile])
2795
2796 AC_OUTPUT
2797
2798 # Fix up dependencies in *.Plo files, where we changed the extension of a
2799 # source file
2800 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2801
2802
2803 dnl
2804 dnl Output some configuration info for the user
2805 dnl
2806 echo ""
2807 echo "        prefix:          $prefix"
2808 echo "        exec_prefix:     $exec_prefix"
2809 echo "        libdir:          $libdir"
2810 echo "        includedir:      $includedir"
2811
2812 dnl API info
2813 echo ""
2814 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2815
2816 dnl Driver info
2817 echo ""
2818 case "x$enable_osmesa$enable_gallium_osmesa" in
2819 xnoyes)
2820         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2821         ;;
2822 xyesno)
2823         echo "        OSMesa:          lib$OSMESA_LIB"
2824         ;;
2825 xnono)
2826         echo "        OSMesa:          no"
2827         ;;
2828 esac
2829
2830 echo ""
2831 if test "x$enable_dri" != xno; then
2832         echo "        DRI platform:    $dri_platform"
2833         if test -z "$DRI_DIRS"; then
2834             echo "        DRI drivers:     no"
2835         else
2836             echo "        DRI drivers:     $DRI_DIRS"
2837         fi
2838         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2839 fi
2840
2841 case "x$enable_glx" in
2842 xdri)
2843     echo "        GLX:             DRI-based"
2844     ;;
2845 xxlib)
2846     echo "        GLX:             Xlib-based"
2847     ;;
2848 xgallium-xlib)
2849     echo "        GLX:             Xlib-based (Gallium)"
2850     ;;
2851 *)
2852     echo "        GLX:             $enable_glx"
2853     ;;
2854 esac
2855
2856 dnl EGL
2857 echo ""
2858 echo "        EGL:             $enable_egl"
2859 if test "$enable_egl" = yes; then
2860     echo "        EGL platforms:   $egl_platforms"
2861
2862     egl_drivers=""
2863     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2864         egl_drivers="$egl_drivers builtin:egl_dri2"
2865     fi
2866     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2867         egl_drivers="$egl_drivers builtin:egl_dri3"
2868     fi
2869
2870     echo "        EGL drivers:    $egl_drivers"
2871 fi
2872 if test "x$enable_gbm" = xyes; then
2873     echo "        GBM:             yes"
2874 else
2875     echo "        GBM:             no"
2876 fi
2877
2878 # Vulkan
2879 echo ""
2880 if test "x$VULKAN_DRIVERS" != x; then
2881     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2882     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2883 else
2884     echo "        Vulkan drivers:  no"
2885 fi
2886
2887 echo ""
2888 if test "x$MESA_LLVM" = x1; then
2889     echo "        llvm:            yes"
2890     echo "        llvm-config:     $LLVM_CONFIG"
2891     echo "        llvm-version:    $LLVM_VERSION"
2892 else
2893     echo "        llvm:            no"
2894 fi
2895
2896 echo ""
2897 if test -n "$with_gallium_drivers"; then
2898     echo "        Gallium drivers: $gallium_drivers"
2899     echo "        Gallium st:      $gallium_st"
2900 else
2901     echo "        Gallium:         no"
2902 fi
2903
2904 echo ""
2905 if test "x$enable_gallium_extra_hud" != xyes; then
2906     echo "        HUD extra stats: no"
2907 else
2908     echo "        HUD extra stats: yes"
2909 fi
2910
2911 if test "x$enable_lmsensors" != xyes; then
2912     echo "        HUD lmsensors:   no"
2913 else
2914     echo "        HUD lmsensors:   yes"
2915 fi
2916
2917 dnl Shader cache
2918 echo ""
2919 echo "        Shader cache:    $enable_shader_cache"
2920 if test "x$enable_shader_cache" = "xyes"; then
2921     echo "        With SHA1 from:  $with_sha1"
2922 fi
2923
2924 dnl Libraries
2925 echo ""
2926 echo "        Shared libs:     $enable_shared"
2927 echo "        Static libs:     $enable_static"
2928 echo "        Shared-glapi:    $enable_shared_glapi"
2929
2930 dnl Compiler options
2931 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2932 cflags=`echo $CFLAGS | \
2933     $SED 's/^ *//;s/  */ /;s/ *$//'`
2934 cxxflags=`echo $CXXFLAGS | \
2935     $SED 's/^ *//;s/  */ /;s/ *$//'`
2936 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2937 echo ""
2938 echo "        CFLAGS:          $cflags"
2939 echo "        CXXFLAGS:        $cxxflags"
2940 echo "        Macros:          $defines"
2941 echo ""
2942 if test "x$MESA_LLVM" = x1; then
2943     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2944     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2945     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2946     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2947     echo ""
2948 fi
2949 echo "        PYTHON2:         $PYTHON2"
2950
2951 echo ""
2952 echo "        Run '${MAKE-make}' to build Mesa"
2953 echo ""