configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,[],[
   9     m4_errprint([Error: Failed to get the Mesa version from the output of
  10        running `make -f bin/version.mk version'
  11 ])
  12     m4_exit([1])
  13 ])
  14
  15 dnl Tell the user about autoconf.html in the --help output
  16 m4_divert_once([HELP_END], [
  17 See docs/autoconf.html for more details on the options for Mesa.])
  18
  19 AC_INIT([Mesa],[mesa_version],
  20     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  21 AC_CONFIG_AUX_DIR([bin])
  22 AC_CANONICAL_HOST
  23
  24 dnl Versions for external dependencies
  25 LIBDRM_REQUIRED=2.4.3
  26 DRI2PROTO_REQUIRED=1.99.3
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl We need a POSIX shell for parts of the build. Assume we have one
  37 dnl in most cases.
  38 case "$host_os" in
  39 solaris*)
  40     # Solaris /bin/sh is too old/non-POSIX compliant
  41     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  42     SHELL="$POSIX_SHELL"
  43     ;;
  44 esac
  45
  46 MKDEP_OPTIONS=-fdepend
  47 dnl Ask gcc where it's keeping its secret headers
  48 if test "x$GCC" = xyes; then
  49     for dir in include include-fixed; do
  50         GCC_INCLUDES=`$CC -print-file-name=$dir`
  51         if test "x$GCC_INCLUDES" != x && \
  52            test "$GCC_INCLUDES" != "$dir" && \
  53            test -d "$GCC_INCLUDES"; then
  54             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  55         fi
  56     done
  57 fi
  58 AC_SUBST([MKDEP_OPTIONS])
  59
  60 dnl Make sure the pkg-config macros are defined
  61 m4_ifdef([PKG_PROG_PKG_CONFIG],[],[
  62     m4_errprint([Error: Could not locate the pkg-config autoconf macros.
  63        These are usually located in /usr/share/aclocal/pkg.m4. If your
  64        macros are in a different location, try setting the environment
  65        variable ACLOCAL="aclocal -I/other/macro/dir" before running
  66        autoreconf.
  67 ])
  68     m4_exit([1])
  69 ])
  70 PKG_PROG_PKG_CONFIG()
  71
  72 dnl LIB_DIR - library basename
  73 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  74 AC_SUBST([LIB_DIR])
  75
  76 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  77 _SAVE_LDFLAGS="$LDFLAGS"
  78 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  79 AC_SUBST([EXTRA_LIB_PATH])
  80
  81 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  82 _SAVE_CPPFLAGS="$CPPFLAGS"
  83 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  84 AC_SUBST([X11_INCLUDES])
  85
  86 dnl Compiler macros
  87 DEFINES=""
  88 AC_SUBST([DEFINES])
  89 case "$host_os" in
  90 linux*|*-gnu*)
  91     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  92     ;;
  93 solaris*)
  94     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  95     ;;
  96 esac
  97
  98 dnl Add flags for gcc and g++
  99 if test "x$GCC" = xyes; then
 100     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 101
 102     # Work around aliasing bugs - developers should comment this out
 103     CFLAGS="$CFLAGS -fno-strict-aliasing"
 104 fi
 105 if test "x$GXX" = xyes; then
 106     CXXFLAGS="$CXXFLAGS -Wall"
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 110 fi
 111
 112 dnl These should be unnecessary, but let the user set them if they want
 113 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 114     Default is to use CFLAGS.])
 115 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 116     compiler. Default is to use CFLAGS.])
 117 AC_SUBST([OPT_FLAGS])
 118 AC_SUBST([ARCH_FLAGS])
 119
 120 dnl
 121 dnl Hacks to enable 32 or 64 bit build
 122 dnl
 123 AC_ARG_ENABLE([32-bit],
 124     [AS_HELP_STRING([--enable-32-bit],
 125         [build 32-bit libraries @<:@default=auto@:>@])],
 126     [enable_32bit="$enableval"],
 127     [enable_32bit=auto]
 128 )
 129 if test "x$enable_32bit" = xyes; then
 130     if test "x$GCC" = xyes; then
 131         CFLAGS="$CFLAGS -m32"
 132     fi
 133     if test "x$GXX" = xyes; then
 134         CXXFLAGS="$CXXFLAGS -m32"
 135     fi
 136 fi
 137 AC_ARG_ENABLE([64-bit],
 138     [AS_HELP_STRING([--enable-64-bit],
 139         [build 64-bit libraries @<:@default=auto@:>@])],
 140     [enable_64bit="$enableval"],
 141     [enable_64bit=auto]
 142 )
 143 if test "x$enable_64bit" = xyes; then
 144     if test "x$GCC" = xyes; then
 145         CFLAGS="$CFLAGS -m64"
 146     fi
 147     if test "x$GXX" = xyes; then
 148         CXXFLAGS="$CXXFLAGS -m64"
 149     fi
 150 fi
 151
 152 dnl
 153 dnl shared/static libraries, mimic libtool options
 154 dnl
 155 AC_ARG_ENABLE([static],
 156     [AS_HELP_STRING([--enable-static],
 157         [build static libraries @<:@default=disabled@:>@])],
 158     [enable_static="$enableval"],
 159     [enable_static=no]
 160 )
 161 case "x$enable_static" in
 162 xyes|xno ) ;;
 163 x ) enable_static=no ;;
 164 * )
 165     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 166     ;;
 167 esac
 168 AC_ARG_ENABLE([shared],
 169     [AS_HELP_STRING([--disable-shared],
 170         [build shared libraries @<:@default=enabled@:>@])],
 171     [enable_shared="$enableval"],
 172     [enable_shared=yes]
 173 )
 174 case "x$enable_shared" in
 175 xyes|xno ) ;;
 176 x ) enable_shared=yes ;;
 177 * )
 178     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 179     ;;
 180 esac
 181
 182 dnl Can't have static and shared libraries, default to static if user
 183 dnl explicitly requested. If both disabled, set to static since shared
 184 dnl was explicitly requirested.
 185 case "x$enable_static$enable_shared" in
 186 xyesyes )
 187     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 188     enable_shared=no
 189     ;;
 190 xnono )
 191     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 192     enable_static=yes
 193     ;;
 194 esac
 195
 196 dnl
 197 dnl mklib options
 198 dnl
 199 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 200 if test "$enable_static" = yes; then
 201     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 202 fi
 203 AC_SUBST([MKLIB_OPTIONS])
 204
 205 dnl
 206 dnl other compiler options
 207 dnl
 208 AC_ARG_ENABLE([debug],
 209     [AS_HELP_STRING([--enable-debug],
 210         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 211     [enable_debug="$enableval"],
 212     [enable_debug=no]
 213 )
 214 if test "x$enable_debug" = xyes; then
 215     DEFINES="$DEFINES -DDEBUG"
 216     if test "x$GCC" = xyes; then
 217         CFLAGS="$CFLAGS -g"
 218     fi
 219     if test "x$GXX" = xyes; then
 220         CXXFLAGS="$CXXFLAGS -g"
 221     fi
 222 fi
 223
 224 dnl
 225 dnl library names
 226 dnl
 227 if test "$enable_static" = yes; then
 228     LIB_EXTENSION='a'
 229 else
 230     case "$host_os" in
 231     darwin* )
 232         LIB_EXTENSION='dylib' ;;
 233     * )
 234         LIB_EXTENSION='so' ;;
 235     esac
 236 fi
 237
 238 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 239 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 240 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 241 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 242 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 243
 244 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 245 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 246 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 247 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 248 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 249
 250 AC_SUBST([GL_LIB_NAME])
 251 AC_SUBST([GLU_LIB_NAME])
 252 AC_SUBST([GLUT_LIB_NAME])
 253 AC_SUBST([GLW_LIB_NAME])
 254 AC_SUBST([OSMESA_LIB_NAME])
 255
 256 AC_SUBST([GL_LIB_GLOB])
 257 AC_SUBST([GLU_LIB_GLOB])
 258 AC_SUBST([GLUT_LIB_GLOB])
 259 AC_SUBST([GLW_LIB_GLOB])
 260 AC_SUBST([OSMESA_LIB_GLOB])
 261
 262 dnl
 263 dnl Arch/platform-specific settings
 264 dnl
 265 AC_ARG_ENABLE([asm],
 266     [AS_HELP_STRING([--disable-asm],
 267         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 268     [enable_asm="$enableval"],
 269     [enable_asm=yes]
 270 )
 271 asm_arch=""
 272 ASM_FLAGS=""
 273 MESA_ASM_SOURCES=""
 274 GLAPI_ASM_SOURCES=""
 275 AC_MSG_CHECKING([whether to enable assembly])
 276 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 277 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 278 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 279     case "$host_cpu" in
 280     i?86 | x86_64)
 281         enable_asm=no
 282         AC_MSG_RESULT([no, cross compiling])
 283         ;;
 284     esac
 285 fi
 286 # check for supported arches
 287 if test "x$enable_asm" = xyes; then
 288     case "$host_cpu" in
 289     i?86)
 290         case "$host_os" in
 291         linux* | *freebsd* | dragonfly*)
 292             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 293             ;;
 294         esac
 295         ;;
 296     x86_64)
 297         case "$host_os" in
 298         linux* | *freebsd* | dragonfly*)
 299             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 300             ;;
 301         esac
 302         ;;
 303     powerpc)
 304         case "$host_os" in
 305         linux*)
 306             asm_arch=ppc
 307             ;;
 308         esac
 309         ;;
 310     sparc*)
 311         case "$host_os" in
 312         linux*)
 313             asm_arch=sparc
 314             ;;
 315         esac
 316         ;;
 317     esac
 318
 319     case "$asm_arch" in
 320     x86)
 321         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 322         MESA_ASM_SOURCES='$(X86_SOURCES)'
 323         GLAPI_ASM_SOURCES='$(X86_API)'
 324         AC_MSG_RESULT([yes, x86])
 325         ;;
 326     x86_64)
 327         ASM_FLAGS="-DUSE_X86_64_ASM"
 328         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 329         GLAPI_ASM_SOURCES='$(X86-64_API)'
 330         AC_MSG_RESULT([yes, x86_64])
 331         ;;
 332     ppc)
 333         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 334         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 335         AC_MSG_RESULT([yes, ppc])
 336         ;;
 337     sparc)
 338         ASM_FLAGS="-DUSE_SPARC_ASM"
 339         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 340         GLAPI_ASM_SOURCES='$(SPARC_API)'
 341         AC_MSG_RESULT([yes, sparc])
 342         ;;
 343     *)
 344         AC_MSG_RESULT([no, platform not supported])
 345         ;;
 346     esac
 347 fi
 348 AC_SUBST([ASM_FLAGS])
 349 AC_SUBST([MESA_ASM_SOURCES])
 350 AC_SUBST([GLAPI_ASM_SOURCES])
 351
 352 dnl PIC code macro
 353 MESA_PIC_FLAGS
 354
 355 dnl Check to see if dlopen is in default libraries (like Solaris, which
 356 dnl has it in libc), or if libdl is needed to get it.
 357 AC_CHECK_FUNC([dlopen], [],
 358     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 359
 360 dnl See if posix_memalign is available
 361 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 362
 363 dnl SELinux awareness.
 364 AC_ARG_ENABLE([selinux],
 365     [AS_HELP_STRING([--enable-selinux],
 366         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 367     [MESA_SELINUX="$enableval"],
 368     [MESA_SELINUX=no])
 369 if test "x$enable_selinux" = "xyes"; then
 370     AC_CHECK_HEADER([selinux/selinux.h],[],
 371                     [AC_MSG_ERROR([SELinux headers not found])])
 372     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 373                  [AC_MSG_ERROR([SELinux library not found])])
 374     SELINUX_LIBS="-lselinux"
 375     DEFINES="$DEFINES -DMESA_SELINUX"
 376 fi
 377
 378 dnl
 379 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 380 dnl More later: directfb, fbdev, ...
 381 dnl
 382 default_driver="xlib"
 383
 384 case "$host_os" in
 385 linux*)
 386     case "$host_cpu" in
 387     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 388     esac
 389     ;;
 390 *freebsd* | dragonfly*)
 391     case "$host_cpu" in
 392     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 393     esac
 394     ;;
 395 esac
 396
 397 AC_ARG_WITH([driver],
 398     [AS_HELP_STRING([--with-driver=DRIVER],
 399         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 400     [mesa_driver="$withval"],
 401     [mesa_driver="$default_driver"])
 402 dnl Check for valid option
 403 case "x$mesa_driver" in
 404 xxlib|xdri|xosmesa)
 405     ;;
 406 *)
 407     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 408     ;;
 409 esac
 410
 411 dnl
 412 dnl Driver specific build directories
 413 dnl
 414 SRC_DIRS="mesa egl glew"
 415 GLU_DIRS="sgi"
 416 WINDOW_SYSTEM=""
 417 GALLIUM_DIRS="auxiliary drivers state_trackers"
 418 GALLIUM_WINSYS_DIRS=""
 419 GALLIUM_WINSYS_DRM_DIRS=""
 420 GALLIUM_AUXILIARY_DIRS="draw translate cso_cache pipebuffer tgsi sct rtasm util"
 421 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 422 GALLIUM_STATE_TRACKERS_DIRS=""
 423
 424 case "$mesa_driver" in
 425 xlib)
 426     DRIVER_DIRS="x11"
 427     ;;
 428 dri)
 429     SRC_DIRS="glx/x11 $SRC_DIRS"
 430     DRIVER_DIRS="dri"
 431     WINDOW_SYSTEM="dri"
 432     GALLIUM_WINSYS_DIRS="drm $GALLIUM_WINSYS_DIRS"
 433     ;;
 434 osmesa)
 435     DRIVER_DIRS="osmesa"
 436     ;;
 437 esac
 438 AC_SUBST([SRC_DIRS])
 439 AC_SUBST([GLU_DIRS])
 440 AC_SUBST([DRIVER_DIRS])
 441 AC_SUBST([WINDOW_SYSTEM])
 442 AC_SUBST([GALLIUM_DIRS])
 443 AC_SUBST([GALLIUM_WINSYS_DIRS])
 444 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 445 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 446 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 447 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 448
 449 dnl
 450 dnl User supplied program configuration
 451 dnl
 452 if test -d "$srcdir/progs/demos"; then
 453     default_demos=yes
 454 else
 455     default_demos=no
 456 fi
 457 AC_ARG_WITH([demos],
 458     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 459         [optional comma delimited demo directories to build
 460         @<:@default=auto if source available@:>@])],
 461     [with_demos="$withval"],
 462     [with_demos="$default_demos"])
 463 if test "x$with_demos" = x; then
 464     with_demos=no
 465 fi
 466
 467 dnl If $with_demos is yes, directories will be added as libs available
 468 PROGRAM_DIRS=""
 469 case "$with_demos" in
 470 no) ;;
 471 yes)
 472     # If the driver isn't osmesa, we have libGL and can build xdemos
 473     if test "$mesa_driver" != osmesa; then
 474         PROGRAM_DIRS="xdemos"
 475     fi
 476     ;;
 477 *)
 478     # verify the requested demos directories exist
 479     demos=`IFS=,; echo $with_demos`
 480     for demo in $demos; do
 481         test -d "$srcdir/progs/$demo" || \
 482             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 483     done
 484     PROGRAM_DIRS="$demos"
 485     ;;
 486 esac
 487
 488 dnl
 489 dnl Find out if X is available. The variable have_x is set if libX11 is
 490 dnl found to mimic AC_PATH_XTRA.
 491 dnl
 492 if test -n "$PKG_CONFIG"; then
 493     AC_MSG_CHECKING([pkg-config files for X11 are available])
 494     PKG_CHECK_EXISTS([x11],[
 495         x11_pkgconfig=yes
 496         have_x=yes
 497         ],[
 498         x11_pkgconfig=no
 499     ])
 500     AC_MSG_RESULT([$x11_pkgconfig])
 501 else
 502     x11_pkgconfig=no
 503 fi
 504 dnl Use the autoconf macro if no pkg-config files
 505 if test "$x11_pkgconfig" = no; then
 506     AC_PATH_XTRA
 507 fi
 508
 509 dnl Try to tell the user that the --x-* options are only used when
 510 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 511 m4_divert_once([HELP_BEGIN],
 512 [These options are only used when the X libraries cannot be found by the
 513 pkg-config utility.])
 514
 515 dnl We need X for xlib and dri, so bomb now if it's not found
 516 case "$mesa_driver" in
 517 xlib|dri)
 518     if test "$no_x" = yes; then
 519         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 520     fi
 521     ;;
 522 esac
 523
 524 dnl XCB - this is only used for GLX right now
 525 AC_ARG_ENABLE([xcb],
 526     [AS_HELP_STRING([--enable-xcb],
 527         [use XCB for GLX @<:@default=disabled@:>@])],
 528     [enable_xcb="$enableval"],
 529     [enable_xcb=no])
 530 if test "x$enable_xcb" = xyes; then
 531     DEFINES="$DEFINES -DUSE_XCB"
 532 else
 533     enable_xcb=no
 534 fi
 535
 536 dnl
 537 dnl libGL configuration per driver
 538 dnl
 539 case "$mesa_driver" in
 540 xlib)
 541     if test "$x11_pkgconfig" = yes; then
 542         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 543         GL_PC_REQ_PRIV="x11 xext"
 544         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 545         GL_LIB_DEPS="$XLIBGL_LIBS"
 546     else
 547         # should check these...
 548         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 549         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 550         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 551         GL_PC_CFLAGS="$X11_INCLUDES"
 552     fi
 553     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 554     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 555
 556     # if static, move the external libraries to the programs
 557     # and empty the libraries for libGL
 558     if test "$enable_static" = yes; then
 559         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 560         GL_LIB_DEPS=""
 561     fi
 562     ;;
 563 dri)
 564     # DRI must be shared, I think
 565     if test "$enable_static" = yes; then
 566         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 567     fi
 568
 569     # Check for libdrm
 570     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 571     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 572     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 573     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 574
 575     # find the DRI deps for libGL
 576     if test "$x11_pkgconfig" = yes; then
 577         # add xcb modules if necessary
 578         dri_modules="x11 xext xxf86vm xdamage xfixes"
 579         if test "$enable_xcb" = yes; then
 580             dri_modules="$dri_modules x11-xcb xcb-glx"
 581         fi
 582
 583         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 584         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 585         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 586         GL_LIB_DEPS="$DRIGL_LIBS"
 587     else
 588         # should check these...
 589         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 590         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 591         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 592         GL_PC_CFLAGS="$X11_INCLUDES"
 593
 594         # XCB can only be used from pkg-config
 595         if test "$enable_xcb" = yes; then
 596             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 597             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 598             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 599             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 600         fi
 601     fi
 602
 603     # need DRM libs, -lpthread, etc.
 604     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 605     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 606     ;;
 607 osmesa)
 608     # No libGL for osmesa
 609     GL_LIB_DEPS=""
 610     ;;
 611 esac
 612 AC_SUBST([GL_LIB_DEPS])
 613 AC_SUBST([GL_PC_REQ_PRIV])
 614 AC_SUBST([GL_PC_LIB_PRIV])
 615 AC_SUBST([GL_PC_CFLAGS])
 616 AC_SUBST([DRI_PC_REQ_PRIV])
 617
 618 dnl
 619 dnl More X11 setup
 620 dnl
 621 if test "$mesa_driver" = xlib; then
 622     DEFINES="$DEFINES -DUSE_XSHM"
 623 fi
 624
 625 dnl
 626 dnl More DRI setup
 627 dnl
 628 AC_ARG_ENABLE([glx-tls],
 629     [AS_HELP_STRING([--enable-glx-tls],
 630         [enable TLS support in GLX @<:@default=disabled@:>@])],
 631     [GLX_USE_TLS="$enableval"],
 632     [GLX_USE_TLS=no])
 633 dnl Directory for DRI drivers
 634 AC_ARG_WITH([dri-driverdir],
 635     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 636         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 637     [DRI_DRIVER_INSTALL_DIR="$withval"],
 638     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 639 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 640 dnl Direct rendering or just indirect rendering
 641 AC_ARG_ENABLE([driglx-direct],
 642     [AS_HELP_STRING([--disable-driglx-direct],
 643         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 644     [driglx_direct="$enableval"],
 645     [driglx_direct="yes"])
 646 dnl Which drivers to build - default is chosen by platform
 647 AC_ARG_WITH([dri-drivers],
 648     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 649         [comma delimited DRI drivers list, e.g.
 650         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 651     [with_dri_drivers="$withval"],
 652     [with_dri_drivers=yes])
 653 if test "x$with_dri_drivers" = x; then
 654     with_dri_drivers=no
 655 fi
 656
 657 dnl If $with_dri_drivers is yes, directories will be added through
 658 dnl platform checks
 659 DRI_DIRS=""
 660 case "$with_dri_drivers" in
 661 no) ;;
 662 yes)
 663     DRI_DIRS="yes"
 664     ;;
 665 *)
 666     # verify the requested driver directories exist
 667     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 668     for driver in $dri_drivers; do
 669         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 670             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 671     done
 672     DRI_DIRS="$dri_drivers"
 673     ;;
 674 esac
 675
 676 dnl Just default to no EGL for now
 677 USING_EGL=0
 678 AC_SUBST([USING_EGL])
 679
 680 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 681 if test "$mesa_driver" = dri; then
 682     # Use TLS in GLX?
 683     if test "x$GLX_USE_TLS" = xyes; then
 684         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 685     fi
 686
 687     if test "x$USING_EGL" = x1; then
 688         PROGRAM_DIRS="egl"
 689     fi
 690
 691     # Platform specific settings and drivers to build
 692     case "$host_os" in
 693     linux*)
 694         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 695         if test "x$driglx_direct" = xyes; then
 696             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 697         fi
 698         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 699
 700         case "$host_cpu" in
 701         x86_64)
 702             # ffb, gamma, and sis are missing because they have not be
 703             # converted to use the new interface.  i810 are missing
 704             # because there is no x86-64 system where they could *ever*
 705             # be used.
 706             if test "x$DRI_DIRS" = "xyes"; then
 707                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 708                     savage tdfx unichrome swrast"
 709             fi
 710             ;;
 711         powerpc*)
 712             # Build only the drivers for cards that exist on PowerPC.
 713             # At some point MGA will be added, but not yet.
 714             if test "x$DRI_DIRS" = "xyes"; then
 715                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 716             fi
 717             ;;
 718         sparc*)
 719             # Build only the drivers for cards that exist on sparc`
 720             if test "x$DRI_DIRS" = "xyes"; then
 721                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 722             fi
 723             ;;
 724         esac
 725         ;;
 726     freebsd* | dragonfly*)
 727         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 728         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 729         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 730         if test "x$driglx_direct" = xyes; then
 731             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 732         fi
 733         if test "x$GXX" = xyes; then
 734             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 735         fi
 736
 737         # ffb and gamma are missing because they have not been converted
 738         # to use the new interface.
 739         if test "x$DRI_DIRS" = "xyes"; then
 740             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 741                 unichrome savage sis swrast"
 742         fi
 743         ;;
 744     solaris*)
 745         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 746         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 747         if test "x$driglx_direct" = xyes; then
 748             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 749         fi
 750         ;;
 751     esac
 752
 753     # default drivers
 754     if test "x$DRI_DIRS" = "xyes"; then
 755         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 756             savage sis tdfx trident unichrome ffb swrast"
 757     fi
 758
 759     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 760
 761     # Check for expat
 762     EXPAT_INCLUDES=""
 763     EXPAT_LIB=-lexpat
 764     AC_ARG_WITH([expat],
 765         [AS_HELP_STRING([--with-expat=DIR],
 766             [expat install directory])],[
 767         EXPAT_INCLUDES="-I$withval/include"
 768         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 769         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 770         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 771         ])
 772     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 773     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 774         [AC_MSG_ERROR([Expat required for DRI.])])
 775
 776     # put all the necessary libs together
 777     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 778 fi
 779 AC_SUBST([DRI_DIRS])
 780 AC_SUBST([EXPAT_INCLUDES])
 781 AC_SUBST([DRI_LIB_DEPS])
 782
 783 dnl
 784 dnl OSMesa configuration
 785 dnl
 786 if test "$mesa_driver" = xlib; then
 787     default_gl_osmesa=yes
 788 else
 789     default_gl_osmesa=no
 790 fi
 791 AC_ARG_ENABLE([gl-osmesa],
 792     [AS_HELP_STRING([--enable-gl-osmesa],
 793         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 794     [gl_osmesa="$enableval"],
 795     [gl_osmesa="$default_gl_osmesa"])
 796 if test "x$gl_osmesa" = xyes; then
 797     if test "$mesa_driver" = osmesa; then
 798         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 799     else
 800         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 801     fi
 802 fi
 803
 804 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 805 AC_ARG_WITH([osmesa-bits],
 806     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 807         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 808     [osmesa_bits="$withval"],
 809     [osmesa_bits=8])
 810 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 811     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 812     osmesa_bits=8
 813 fi
 814 case "x$osmesa_bits" in
 815 x8)
 816     OSMESA_LIB=OSMesa
 817     ;;
 818 x16|x32)
 819     OSMESA_LIB="OSMesa$osmesa_bits"
 820     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 821     ;;
 822 *)
 823     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 824     ;;
 825 esac
 826 AC_SUBST([OSMESA_LIB])
 827
 828 case "$mesa_driver" in
 829 osmesa)
 830     # only link libraries with osmesa if shared
 831     if test "$enable_static" = no; then
 832         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 833     else
 834         OSMESA_LIB_DEPS=""
 835     fi
 836     OSMESA_MESA_DEPS=""
 837     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS"
 838     ;;
 839 *)
 840     # Link OSMesa to libGL otherwise
 841     OSMESA_LIB_DEPS=""
 842     # only link libraries with osmesa if shared
 843     if test "$enable_static" = no; then
 844         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 845     else
 846         OSMESA_MESA_DEPS=""
 847     fi
 848     OSMESA_PC_REQ="gl"
 849     ;;
 850 esac
 851 if test "$enable_static" = no; then
 852     OSMESA_LIB_DEPS="$OSMESA_LIB_DEPS"
 853 fi
 854 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 855 AC_SUBST([OSMESA_LIB_DEPS])
 856 AC_SUBST([OSMESA_MESA_DEPS])
 857 AC_SUBST([OSMESA_PC_REQ])
 858 AC_SUBST([OSMESA_PC_LIB_PRIV])
 859
 860 dnl
 861 dnl EGL configuration
 862 dnl
 863 if test "$x11_pkgconfig" = yes; then
 864     PKG_CHECK_MODULES([EGL],[x11])
 865     EGL_LIB_DEPS="$EGL_LIBS"
 866 else
 867     # should check these...
 868     EGL_LIB_DEPS="$X_LIBS -lX11"
 869 fi
 870 EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS"
 871 AC_SUBST([EGL_LIB_DEPS])
 872
 873 dnl
 874 dnl GLU configuration
 875 dnl
 876 AC_ARG_ENABLE([glu],
 877     [AS_HELP_STRING([--disable-glu],
 878         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 879     [enable_glu="$enableval"],
 880     [enable_glu=yes])
 881 if test "x$enable_glu" = xyes; then
 882     SRC_DIRS="$SRC_DIRS glu"
 883
 884     case "$mesa_driver" in
 885     osmesa)
 886         # If GLU is available and we have libOSMesa (not 16 or 32),
 887         # we can build the osdemos
 888         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 889             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 890         fi
 891
 892         # Link libGLU to libOSMesa instead of libGL
 893         GLU_LIB_DEPS=""
 894         GLU_PC_REQ="osmesa"
 895         if test "$enable_static" = no; then
 896             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 897         else
 898             GLU_MESA_DEPS=""
 899         fi
 900         ;;
 901     *)
 902         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 903         GLU_PC_REQ="gl"
 904         GLU_PC_LIB_PRIV="-lm"
 905         if test "$enable_static" = no; then
 906             GLU_LIB_DEPS="-lm"
 907             GLU_MESA_DEPS='-l$(GL_LIB)'
 908         else
 909             GLU_LIB_DEPS=""
 910             GLU_MESA_DEPS=""
 911             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 912         fi
 913         ;;
 914     esac
 915 fi
 916 if test "$enable_static" = no; then
 917     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 918 fi
 919 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 920 AC_SUBST([GLU_LIB_DEPS])
 921 AC_SUBST([GLU_MESA_DEPS])
 922 AC_SUBST([GLU_PC_REQ])
 923 AC_SUBST([GLU_PC_REQ_PRIV])
 924 AC_SUBST([GLU_PC_LIB_PRIV])
 925 AC_SUBST([GLU_PC_CFLAGS])
 926
 927 dnl
 928 dnl GLw configuration
 929 dnl
 930 AC_ARG_ENABLE([glw],
 931     [AS_HELP_STRING([--disable-glw],
 932         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 933     [enable_glw="$enableval"],
 934     [enable_glw=yes])
 935 dnl Don't build GLw on osmesa
 936 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 937     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 938     enable_glw=no
 939 fi
 940 AC_ARG_ENABLE([motif],
 941     [AS_HELP_STRING([--enable-motif],
 942         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 943     [enable_motif="$enableval"],
 944     [enable_motif=no])
 945
 946 if test "x$enable_glw" = xyes; then
 947     SRC_DIRS="$SRC_DIRS glw"
 948     if test "$x11_pkgconfig" = yes; then
 949         PKG_CHECK_MODULES([GLW],[x11 xt])
 950         GLW_PC_REQ_PRIV="x11 xt"
 951         GLW_LIB_DEPS="$GLW_LIBS"
 952     else
 953         # should check these...
 954         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 955         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 956         GLW_PC_CFLAGS="$X11_INCLUDES"
 957     fi
 958
 959     GLW_SOURCES="GLwDrawA.c"
 960     MOTIF_CFLAGS=
 961     if test "x$enable_motif" = xyes; then
 962         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 963         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 964         if test "x$MOTIF_CONFIG" != xno; then
 965             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 966             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 967         else
 968             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 969                 [AC_MSG_ERROR([Can't locate Motif headers])])
 970             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 971                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 972         fi
 973         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 974         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 975         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 976         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 977     fi
 978
 979     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 980     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
 981     if test "$enable_static" = no; then
 982         GLW_MESA_DEPS='-l$(GL_LIB)'
 983         GLW_LIB_DEPS="$GLW_LIB_DEPS"
 984     else
 985         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 986         GLW_LIB_DEPS=""
 987         GLW_MESA_DEPS=""
 988     fi
 989 fi
 990 AC_SUBST([GLW_LIB_DEPS])
 991 AC_SUBST([GLW_MESA_DEPS])
 992 AC_SUBST([GLW_SOURCES])
 993 AC_SUBST([MOTIF_CFLAGS])
 994 AC_SUBST([GLW_PC_REQ_PRIV])
 995 AC_SUBST([GLW_PC_LIB_PRIV])
 996 AC_SUBST([GLW_PC_CFLAGS])
 997
 998 dnl
 999 dnl GLUT configuration
1000 dnl
1001 if test -f "$srcdir/include/GL/glut.h"; then
1002     default_glut=yes
1003 else
1004     default_glut=no
1005 fi
1006 AC_ARG_ENABLE([glut],
1007     [AS_HELP_STRING([--disable-glut],
1008         [enable GLUT library @<:@default=enabled if source available@:>@])],
1009     [enable_glut="$enableval"],
1010     [enable_glut="$default_glut"])
1011
1012 dnl Can't build glut if GLU not available
1013 if test "x$enable_glu$enable_glut" = xnoyes; then
1014     AC_MSG_WARN([Disabling glut since GLU is disabled])
1015     enable_glut=no
1016 fi
1017 dnl Don't build glut on osmesa
1018 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1019     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1020     enable_glut=no
1021 fi
1022
1023 if test "x$enable_glut" = xyes; then
1024     SRC_DIRS="$SRC_DIRS glut/glx"
1025     GLUT_CFLAGS=""
1026     if test "x$GCC" = xyes; then
1027         GLUT_CFLAGS="-fexceptions"
1028     fi
1029     if test "$x11_pkgconfig" = yes; then
1030         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1031         GLUT_PC_REQ_PRIV="x11 xmu xi"
1032         GLUT_LIB_DEPS="$GLUT_LIBS"
1033     else
1034         # should check these...
1035         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1036         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1037         GLUT_PC_CFLAGS="$X11_INCLUDES"
1038     fi
1039     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1040     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1041
1042     # If glut is available, we can build most programs
1043     if test "$with_demos" = yes; then
1044         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1045     fi
1046
1047     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1048     if test "$enable_static" = no; then
1049         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1050     else
1051         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1052         GLUT_LIB_DEPS=""
1053         GLUT_MESA_DEPS=""
1054     fi
1055 fi
1056 AC_SUBST([GLUT_LIB_DEPS])
1057 AC_SUBST([GLUT_MESA_DEPS])
1058 AC_SUBST([GLUT_CFLAGS])
1059 AC_SUBST([GLUT_PC_REQ_PRIV])
1060 AC_SUBST([GLUT_PC_LIB_PRIV])
1061 AC_SUBST([GLUT_PC_CFLAGS])
1062
1063 dnl
1064 dnl Program library dependencies
1065 dnl    Only libm is added here if necessary as the libraries should
1066 dnl    be pulled in by the linker
1067 dnl
1068 if test "x$APP_LIB_DEPS" = x; then
1069     case "$host_os" in
1070     solaris*)
1071         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1072         ;;
1073     *)
1074         APP_LIB_DEPS="-lm"
1075         ;;
1076     esac
1077 fi
1078 AC_SUBST([APP_LIB_DEPS])
1079 AC_SUBST([PROGRAM_DIRS])
1080
1081 dnl
1082 dnl Gallium configuration
1083 dnl
1084 AC_ARG_ENABLE([gallium],
1085     [AS_HELP_STRING([--disable-gallium],
1086         [build gallium @<:@default=enabled@:>@])],
1087     [enable_gallium="$enableval"],
1088     [enable_gallium=yes])
1089 if test "x$enable_gallium" = xyes; then
1090     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1091 fi
1092
1093 dnl
1094 dnl Gallium state trackers configuration
1095 dnl
1096 AC_ARG_WITH([state-trackers],
1097     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1098         [comma delimited state_trackers list, e.g.
1099         "egl,glx" @<:@default=auto@:>@])],
1100     [with_state_trackers="$withval"],
1101     [with_state_trackers=yes])
1102
1103 case "$with_state_trackers" in
1104 no)
1105     GALLIUM_STATE_TRACKERS_DIRS=""
1106     ;;
1107 yes)
1108     # look at what else is built
1109     case "$mesa_driver" in
1110     dri)
1111         GALLIUM_STATE_TRACKERS_DIRS=egl
1112         ;;
1113     esac
1114     ;;
1115 *)
1116     # verify the requested state tracker exist
1117     state_trackers=`IFS=', '; echo $with_state_trackers`
1118     for tracker in $state_trackers; do
1119         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1120             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1121     done
1122     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1123     ;;
1124 esac
1125
1126 AC_ARG_WITH([xorg-driver-dir],
1127     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1128                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1129     [XORG_DRIVER_INSTALL_DIR="$withval"],
1130     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1131 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1132
1133 dnl
1134 dnl Gallium Intel configuration
1135 dnl
1136 AC_ARG_ENABLE([gallium-intel],
1137     [AS_HELP_STRING([--disable-gallium-intel],
1138         [build gallium intel @<:@default=enabled@:>@])],
1139     [enable_gallium_intel="$enableval"],
1140     [enable_gallium_intel=yes])
1141 if test "x$enable_gallium_intel" = xyes; then
1142     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1143     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1144 fi
1145
1146 dnl
1147 dnl Gallium Radeon configuration
1148 dnl
1149 AC_ARG_ENABLE([gallium-radeon],
1150     [AS_HELP_STRING([--enable-gallium-radeon],
1151         [build gallium radeon @<:@default=disabled@:>@])],
1152     [enable_gallium_radeon="$enableval"],
1153     [enable_gallium_radeon=no])
1154 if test "x$enable_gallium_radeon" = xyes; then
1155     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1156     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1157 fi
1158
1159 dnl
1160 dnl Gallium Radeon configuration
1161 dnl
1162 AC_ARG_ENABLE([gallium-nouveau],
1163     [AS_HELP_STRING([--enable-gallium-nouveau],
1164         [build gallium nouveau @<:@default=disabled@:>@])],
1165     [enable_gallium_nouveau="$enableval"],
1166     [enable_gallium_nouveau=no])
1167 if test "x$enable_gallium_nouveau" = xyes; then
1168     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1169     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nv04 nv10 nv20 nv30 nv40 nv50"
1170 fi
1171
1172
1173 dnl Restore LDFLAGS and CPPFLAGS
1174 LDFLAGS="$_SAVE_LDFLAGS"
1175 CPPFLAGS="$_SAVE_CPPFLAGS"
1176
1177 dnl Substitute the config
1178 AC_CONFIG_FILES([configs/autoconf])
1179
1180 dnl Replace the configs/current symlink
1181 AC_CONFIG_COMMANDS([configs],[
1182 if test -f configs/current || test -L configs/current; then
1183     rm -f configs/current
1184 fi
1185 ln -s autoconf configs/current
1186 ])
1187
1188 AC_OUTPUT
1189
1190 dnl
1191 dnl Output some configuration info for the user
1192 dnl
1193 echo ""
1194 echo "        prefix:          $prefix"
1195 echo "        exec_prefix:     $exec_prefix"
1196 echo "        libdir:          $libdir"
1197 echo "        includedir:      $includedir"
1198
1199 dnl Driver info
1200 echo ""
1201 echo "        Driver:          $mesa_driver"
1202 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1203     echo "        OSMesa:          lib$OSMESA_LIB"
1204 else
1205     echo "        OSMesa:          no"
1206 fi
1207 if test "$mesa_driver" = dri; then
1208     # cleanup the drivers var
1209     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1210 if test "x$DRI_DIRS" = x; then
1211     echo "        DRI drivers:     no"
1212 else
1213     echo "        DRI drivers:     $dri_dirs"
1214 fi
1215     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1216 fi
1217 echo "        Use XCB:         $enable_xcb"
1218
1219 echo ""
1220 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1221     echo "        Gallium:         yes"
1222     echo "        Gallium dirs:    $GALLIUM_DIRS"
1223     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1224     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1225     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1226     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1227     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1228 else
1229     echo "        Gallium:         no"
1230 fi
1231
1232 dnl Libraries
1233 echo ""
1234 echo "        Shared libs:     $enable_shared"
1235 echo "        Static libs:     $enable_static"
1236 echo "        GLU:             $enable_glu"
1237 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1238 echo "        glut:            $enable_glut"
1239
1240 dnl Programs
1241 # cleanup the programs var for display
1242 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1243 if test "x$program_dirs" = x; then
1244     echo "        Demos:           no"
1245 else
1246     echo "        Demos:           $program_dirs"
1247 fi
1248
1249 dnl Compiler options
1250 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1251 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1252     $SED 's/^ *//;s/  */ /;s/ *$//'`
1253 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1254     $SED 's/^ *//;s/  */ /;s/ *$//'`
1255 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1256 echo ""
1257 echo "        CFLAGS:          $cflags"
1258 echo "        CXXFLAGS:        $cxxflags"
1259 echo "        Macros:          $defines"
1260
1261 echo ""
1262 echo "        Run '${MAKE-make}' to build Mesa"
1263 echo ""