configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 123
 124 dnl Make sure the pkg-config macros are defined
 125 m4_ifndef([PKG_PROG_PKG_CONFIG],
 126     [m4_fatal([Could not locate the pkg-config autoconf macros.
 127   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 128   are in a different location, try setting the environment variable
 129   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 130 PKG_PROG_PKG_CONFIG()
 131
 132 dnl LIB_DIR - library basename
 133 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 134 AC_SUBST([LIB_DIR])
 135
 136 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 137 _SAVE_LDFLAGS="$LDFLAGS"
 138 _SAVE_CPPFLAGS="$CPPFLAGS"
 139
 140 dnl Compiler macros
 141 DEFINES=""
 142 AC_SUBST([DEFINES])
 143 case "$host_os" in
 144 linux*|*-gnu*|gnu*)
 145     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 146     ;;
 147 solaris*)
 148     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 149     ;;
 150 cygwin*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD"
 152     ;;
 153 esac
 154
 155 dnl Add flags for gcc and g++
 156 if test "x$GCC" = xyes; then
 157     case "$host_os" in
 158     cygwin*)
 159         CFLAGS="$CFLAGS -Wall -std=gnu99"
 160         ;;
 161     *)
 162         CFLAGS="$CFLAGS -Wall -std=c99"
 163         ;;
 164     esac
 165
 166     # Enable -Werror=implicit-function-declaration and
 167     # -Werror=missing-prototypes, if available, or otherwise, just
 168     # -Wmissing-prototypes.  This is particularly useful to avoid
 169     # generating a loadable driver module that has undefined symbols.
 170     save_CFLAGS="$CFLAGS"
 171     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 172     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 173     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 174     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 175                    AC_MSG_RESULT([yes]),
 176                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 177                     AC_MSG_RESULT([no])]);
 178
 179     # Enable -fvisibility=hidden if using a gcc that supports it
 180     save_CFLAGS="$CFLAGS"
 181     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 182     VISIBILITY_CFLAGS="-fvisibility=hidden"
 183     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 185                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 186
 187     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 188     CFLAGS=$save_CFLAGS
 189
 190     # Work around aliasing bugs - developers should comment this out
 191     CFLAGS="$CFLAGS -fno-strict-aliasing"
 192
 193     # gcc's builtin memcmp is slower than glibc's
 194     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 195     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 196 fi
 197 if test "x$GXX" = xyes; then
 198     CXXFLAGS="$CXXFLAGS -Wall"
 199
 200     # Enable -fvisibility=hidden if using a gcc that supports it
 201     save_CXXFLAGS="$CXXFLAGS"
 202     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 203     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 204     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 205     AC_LANG_PUSH([C++])
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 208     AC_LANG_POP([C++])
 209
 210     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 211     CXXFLAGS=$save_CXXFLAGS
 212
 213     # Work around aliasing bugs - developers should comment this out
 214     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 215
 216     # gcc's builtin memcmp is slower than glibc's
 217     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 218     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 219 fi
 220
 221 dnl even if the compiler appears to support it, using visibility attributes isn't
 222 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 223 case "$host_os" in
 224 cygwin*)
 225     VISIBILITY_CFLAGS=""
 226     VISIBILITY_CXXFLAGS=""
 227     ;;
 228 esac
 229
 230 AC_SUBST([VISIBILITY_CFLAGS])
 231 AC_SUBST([VISIBILITY_CXXFLAGS])
 232
 233 dnl
 234 dnl Optional flags, check for compiler support
 235 dnl
 236 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 237 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 287
 288 dnl
 289 dnl other compiler options
 290 dnl
 291 AC_ARG_ENABLE([debug],
 292     [AS_HELP_STRING([--enable-debug],
 293         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 294     [enable_debug="$enableval"],
 295     [enable_debug=no]
 296 )
 297 if test "x$enable_debug" = xyes; then
 298     DEFINES="$DEFINES -DDEBUG"
 299     if test "x$GCC" = xyes; then
 300         CFLAGS="$CFLAGS -g -O0"
 301     fi
 302     if test "x$GXX" = xyes; then
 303         CXXFLAGS="$CXXFLAGS -g -O0"
 304     fi
 305 fi
 306
 307 dnl
 308 dnl library names
 309 dnl
 310 LIB_PREFIX_GLOB='lib'
 311 LIB_VERSION_SEPARATOR='.'
 312 if test "$enable_static" = yes; then
 313     LIB_EXTENSION='a'
 314 else
 315     case "$host_os" in
 316     darwin* )
 317         LIB_EXTENSION='dylib' ;;
 318     cygwin* )
 319         dnl prefix can be 'cyg' or 'lib'
 320         LIB_PREFIX_GLOB='???'
 321         LIB_VERSION_SEPARATOR='-'
 322         LIB_EXTENSION='dll' ;;
 323     aix* )
 324         LIB_EXTENSION='a' ;;
 325     * )
 326         LIB_EXTENSION='so' ;;
 327     esac
 328 fi
 329 AC_ARG_WITH([gl-lib-name],
 330   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 331     [specify GL library name @<:@default=GL@:>@])],
 332   [GL_LIB=$withval],
 333   [GL_LIB=GL])
 334 AC_ARG_WITH([osmesa-lib-name],
 335   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 336     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 337   [OSMESA_LIB=$withval],
 338   [OSMESA_LIB=OSMesa])
 339 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 340 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 341
 342 dnl
 343 dnl Mangled Mesa support
 344 dnl
 345 AC_ARG_ENABLE([mangling],
 346   [AS_HELP_STRING([--enable-mangling],
 347     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 348   [enable_mangling="${enableval}"],
 349   [enable_mangling=no]
 350 )
 351 if test "x${enable_mangling}" = "xyes" ; then
 352   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 353   GL_LIB="Mangled${GL_LIB}"
 354   OSMESA_LIB="Mangled${OSMESA_LIB}"
 355 fi
 356 AC_SUBST([GL_LIB])
 357 AC_SUBST([OSMESA_LIB])
 358
 359 dnl
 360 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 361 dnl
 362 AC_ARG_ENABLE([texture-float],
 363     [AS_HELP_STRING([--enable-texture-float],
 364         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 365     [enable_texture_float="$enableval"],
 366     [enable_texture_float=no]
 367 )
 368 if test "x$enable_texture_float" = xyes; then
 369     AC_MSG_WARN([Floating-point textures enabled.])
 370     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 371     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 372 fi
 373
 374 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 375 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 376 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 377 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 378 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 379 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 380 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 381
 382 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 387 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 388 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 389
 390 AC_SUBST([GL_LIB_NAME])
 391 AC_SUBST([OSMESA_LIB_NAME])
 392 AC_SUBST([EGL_LIB_NAME])
 393 AC_SUBST([GLESv1_CM_LIB_NAME])
 394 AC_SUBST([GLESv2_LIB_NAME])
 395 AC_SUBST([VG_LIB_NAME])
 396 AC_SUBST([GLAPI_LIB_NAME])
 397
 398 AC_SUBST([GL_LIB_GLOB])
 399 AC_SUBST([EGL_LIB_GLOB])
 400 AC_SUBST([GLESv1_CM_LIB_GLOB])
 401 AC_SUBST([GLESv2_LIB_GLOB])
 402 AC_SUBST([VG_LIB_GLOB])
 403 AC_SUBST([GLAPI_LIB_GLOB])
 404
 405 dnl
 406 dnl Arch/platform-specific settings
 407 dnl
 408 AC_ARG_ENABLE([asm],
 409     [AS_HELP_STRING([--disable-asm],
 410         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 411     [enable_asm="$enableval"],
 412     [enable_asm=yes]
 413 )
 414 asm_arch=""
 415 AC_MSG_CHECKING([whether to enable assembly])
 416 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 417 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 418 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 419     case "$host_cpu" in
 420     i?86 | x86_64 | amd64)
 421         enable_asm=no
 422         AC_MSG_RESULT([no, cross compiling])
 423         ;;
 424     esac
 425 fi
 426 # check for supported arches
 427 if test "x$enable_asm" = xyes; then
 428     case "$host_cpu" in
 429     i?86)
 430         case "$host_os" in
 431         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 432             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 433             ;;
 434         gnu*)
 435             asm_arch=x86
 436             ;;
 437         esac
 438         ;;
 439     x86_64|amd64)
 440         case "$host_os" in
 441         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 442             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 443             ;;
 444         esac
 445         ;;
 446     sparc*)
 447         case "$host_os" in
 448         linux*)
 449             asm_arch=sparc
 450             ;;
 451         esac
 452         ;;
 453     esac
 454
 455     case "$asm_arch" in
 456     x86)
 457         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 458         AC_MSG_RESULT([yes, x86])
 459         ;;
 460     x86_64|amd64)
 461         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 462         AC_MSG_RESULT([yes, x86_64])
 463         ;;
 464     sparc)
 465         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 466         AC_MSG_RESULT([yes, sparc])
 467         ;;
 468     *)
 469         AC_MSG_RESULT([no, platform not supported])
 470         ;;
 471     esac
 472 fi
 473
 474 dnl Check to see if dlopen is in default libraries (like Solaris, which
 475 dnl has it in libc), or if libdl is needed to get it.
 476 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 477     [AC_CHECK_LIB([dl], [dlopen],
 478        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 479 AC_SUBST([DLOPEN_LIBS])
 480
 481 case "$host_os" in
 482 darwin*|mingw*)
 483     ;;
 484 *)
 485     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 486                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 487                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 488     AC_SUBST([CLOCK_LIB])
 489     ;;
 490 esac
 491
 492 dnl See if posix_memalign is available
 493 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 494
 495 dnl Check for pthreads
 496 AX_PTHREAD
 497 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 498 dnl to -pthread, which causes problems if we need -lpthread to appear in
 499 dnl pkgconfig files.
 500 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 501
 502 dnl SELinux awareness.
 503 AC_ARG_ENABLE([selinux],
 504     [AS_HELP_STRING([--enable-selinux],
 505         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 506     [MESA_SELINUX="$enableval"],
 507     [MESA_SELINUX=no])
 508 if test "x$enable_selinux" = "xyes"; then
 509     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 510         [AC_CHECK_HEADER([selinux/selinux.h],[],
 511                          [AC_MSG_ERROR([SELinux headers not found])])
 512          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 513                       [AC_MSG_ERROR([SELinux library not found])])
 514          SELINUX_LIBS="-lselinux"])
 515     DEFINES="$DEFINES -DMESA_SELINUX"
 516 fi
 517 AC_SUBST([SELINUX_CFLAGS])
 518 AC_SUBST([SELINUX_LIBS])
 519
 520 dnl Options for APIs
 521 AC_ARG_ENABLE([opengl],
 522     [AS_HELP_STRING([--disable-opengl],
 523         [disable support for standard OpenGL API @<:@default=no@:>@])],
 524     [enable_opengl="$enableval"],
 525     [enable_opengl=yes])
 526 AC_ARG_ENABLE([gles1],
 527     [AS_HELP_STRING([--enable-gles1],
 528         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 529     [enable_gles1="$enableval"],
 530     [enable_gles1=no])
 531 AC_ARG_ENABLE([gles2],
 532     [AS_HELP_STRING([--enable-gles2],
 533         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 534     [enable_gles2="$enableval"],
 535     [enable_gles2=no])
 536 AC_ARG_ENABLE([openvg],
 537     [AS_HELP_STRING([--enable-openvg],
 538         [enable support for OpenVG API @<:@default=no@:>@])],
 539     [enable_openvg="$enableval"],
 540     [enable_openvg=no])
 541
 542 AC_ARG_ENABLE([dri],
 543     [AS_HELP_STRING([--enable-dri],
 544         [enable DRI modules @<:@default=enabled@:>@])],
 545     [enable_dri="$enableval"],
 546     [enable_dri=yes])
 547 AC_ARG_ENABLE([dri3],
 548     [AS_HELP_STRING([--enable-dri3],
 549         [enable DRI3 @<:@default=enabled@:>@])],
 550     [enable_dri3="$enableval"],
 551     [enable_dri3=yes])
 552 AC_ARG_ENABLE([glx],
 553     [AS_HELP_STRING([--enable-glx],
 554         [enable GLX library @<:@default=enabled@:>@])],
 555     [enable_glx="$enableval"],
 556     [enable_glx=yes])
 557 AC_ARG_ENABLE([osmesa],
 558     [AS_HELP_STRING([--enable-osmesa],
 559         [enable OSMesa library @<:@default=disabled@:>@])],
 560     [enable_osmesa="$enableval"],
 561     [enable_osmesa=no])
 562 AC_ARG_ENABLE([gallium-osmesa],
 563     [AS_HELP_STRING([--enable-gallium-osmesa],
 564         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 565     [enable_gallium_osmesa="$enableval"],
 566     [enable_gallium_osmesa=no])
 567 AC_ARG_ENABLE([egl],
 568     [AS_HELP_STRING([--disable-egl],
 569         [disable EGL library @<:@default=enabled@:>@])],
 570     [enable_egl="$enableval"],
 571     [enable_egl=yes])
 572
 573 AC_ARG_ENABLE([xa],
 574     [AS_HELP_STRING([--enable-xa],
 575         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 576     [enable_xa="$enableval"],
 577     [enable_xa=no])
 578 AC_ARG_ENABLE([gbm],
 579    [AS_HELP_STRING([--enable-gbm],
 580          [enable gbm library @<:@default=auto@:>@])],
 581    [enable_gbm="$enableval"],
 582    [enable_gbm=auto])
 583
 584 AC_ARG_ENABLE([xvmc],
 585    [AS_HELP_STRING([--enable-xvmc],
 586          [enable xvmc library @<:@default=auto@:>@])],
 587    [enable_xvmc="$enableval"],
 588    [enable_xvmc=no])
 589 AC_ARG_ENABLE([vdpau],
 590    [AS_HELP_STRING([--enable-vdpau],
 591          [enable vdpau library @<:@default=auto@:>@])],
 592    [enable_vdpau="$enableval"],
 593    [enable_vdpau=auto])
 594 AC_ARG_ENABLE([omx],
 595    [AS_HELP_STRING([--enable-omx],
 596          [enable OpenMAX library @<:@default=no@:>@])],
 597    [enable_omx="$enableval"],
 598    [enable_omx=no])
 599 AC_ARG_ENABLE([opencl],
 600    [AS_HELP_STRING([--enable-opencl],
 601          [enable OpenCL library NOTE: Enabling this option will also enable
 602           --with-llvm-shared-libs
 603           @<:@default=no@:>@])],
 604    [],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([opencl_icd],
 607    [AS_HELP_STRING([--enable-opencl-icd],
 608           [Build an OpenCL ICD library to be loaded by an ICD implementation
 609            @<:@default=no@:>@])],
 610     [enable_opencl_icd="$enableval"],
 611     [enable_opencl_icd=no])
 612 AC_ARG_ENABLE([xlib-glx],
 613     [AS_HELP_STRING([--enable-xlib-glx],
 614         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 615     [enable_xlib_glx="$enableval"],
 616     [enable_xlib_glx=no])
 617 AC_ARG_ENABLE([gallium-egl],
 618     [AS_HELP_STRING([--enable-gallium-egl],
 619         [enable optional EGL state tracker (not required
 620          for EGL support in Gallium with OpenGL and OpenGL ES)
 621          @<:@default=disable@:>@])],
 622     [enable_gallium_egl="$enableval"],
 623     [enable_gallium_egl=no])
 624 AC_ARG_ENABLE([gallium-gbm],
 625     [AS_HELP_STRING([--enable-gallium-gbm],
 626         [enable optional gbm state tracker (not required for
 627          gbm support in Gallium)
 628          @<:@default=auto@:>@])],
 629     [enable_gallium_gbm="$enableval"],
 630     [enable_gallium_gbm=auto])
 631
 632 AC_ARG_ENABLE([r600-llvm-compiler],
 633     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 634         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 635     [enable_r600_llvm="$enableval"],
 636     [enable_r600_llvm=no])
 637
 638 AC_ARG_ENABLE([gallium-tests],
 639     [AS_HELP_STRING([--enable-gallium-tests],
 640         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 641     [enable_gallium_tests="$enableval"],
 642     [enable_gallium_tests=no])
 643
 644 # Option for Gallium drivers
 645
 646 # Keep this in sync with the --with-gallium-drivers help string default value
 647 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 648
 649 AC_ARG_WITH([gallium-drivers],
 650     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 651         [comma delimited Gallium drivers list, e.g.
 652         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 653         @<:@default=r300,r600,svga,swrast@:>@])],
 654     [with_gallium_drivers="$withval"],
 655     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 656
 657 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 658 # here so that the script doesn't choke on an unknown driver name later.
 659 case "$with_gallium_drivers" in
 660     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 661     no) with_gallium_drivers='' ;;
 662 esac
 663
 664 if test "x$enable_opengl" = xno -a \
 665         "x$enable_gles1" = xno -a \
 666         "x$enable_gles2" = xno -a \
 667         "x$enable_openvg" = xno -a \
 668         "x$enable_xa" = xno -a \
 669         "x$enable_xvmc" = xno -a \
 670         "x$enable_vdpau" = xno -a \
 671         "x$enable_omx" = xno -a \
 672         "x$enable_opencl" = xno; then
 673     AC_MSG_ERROR([at least one API should be enabled])
 674 fi
 675
 676 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 677 if test "x$enable_opengl" = xno -a \
 678         "x$enable_gles1" = xyes; then
 679     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 680 fi
 681
 682 if test "x$enable_opengl" = xno -a \
 683         "x$enable_gles2" = xyes; then
 684     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 685 fi
 686
 687 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 688 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 689 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 690 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 691                                         "x$enable_gles1" = xyes -o \
 692                                         "x$enable_gles2" = xyes)
 693
 694 if test "x$enable_glx" = xno; then
 695     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 696     enable_xlib_glx=no
 697 fi
 698
 699 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 700     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 701 fi
 702
 703 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 704     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 705 fi
 706
 707 # Disable GLX if OpenGL is not enabled
 708 if test "x$enable_glx$enable_opengl" = xyesno; then
 709     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 710     enable_glx=no
 711 fi
 712
 713 # Disable GLX if DRI and Xlib-GLX are not enabled
 714 if test "x$enable_glx" = xyes -a \
 715         "x$enable_dri" = xno -a \
 716         "x$enable_xlib_glx" = xno; then
 717     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 718     enable_glx=no
 719 fi
 720
 721 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 722                                   "x$enable_dri" = xyes)
 723 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 724 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 725
 726 AC_ARG_ENABLE([shared-glapi],
 727     [AS_HELP_STRING([--enable-shared-glapi],
 728         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 729     [enable_shared_glapi="$enableval"],
 730     [enable_shared_glapi="$enable_dri"])
 731
 732 # Shared GLAPI is only useful for DRI
 733 if test "x$enable_dri" = xno; then
 734     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 735     enable_shared_glapi=no
 736 fi
 737
 738 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 739
 740 dnl
 741 dnl Driver specific build directories
 742 dnl
 743 GALLIUM_TARGET_DIRS=""
 744 GALLIUM_WINSYS_DIRS="sw"
 745 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 746 GALLIUM_STATE_TRACKERS_DIRS=""
 747
 748 case "x$enable_glx$enable_xlib_glx" in
 749 xyesyes)
 750     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 751     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 752     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 753     NEED_WINSYS_XLIB="yes"
 754     ;;
 755 esac
 756
 757 if test "x$enable_dri" = xyes; then
 758     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 759     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 760 fi
 761
 762 if test "x$enable_gallium_osmesa" = xyes; then
 763     if test -z "$with_gallium_drivers"; then
 764         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 765     fi
 766     if test "x$enable_osmesa" = xyes; then
 767         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 768     fi
 769     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 770     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 771 fi
 772
 773 AC_SUBST([MESA_LLVM])
 774
 775 # Check for libdrm
 776 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 777                   [have_libdrm=yes], [have_libdrm=no])
 778 if test "x$have_libdrm" = xyes; then
 779         DEFINES="$DEFINES -DHAVE_LIBDRM"
 780 fi
 781
 782 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 783                   have_libudev=yes, have_libudev=no)
 784
 785 if test "x$enable_dri" = xyes; then
 786     # DRI must be shared, I think
 787     if test "$enable_static" = yes; then
 788         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 789     fi
 790
 791     # not a hard requirement as swrast does not depend on it
 792     if test "x$have_libdrm" = xyes; then
 793         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 794     fi
 795 fi
 796
 797 dnl Direct rendering or just indirect rendering
 798 case "$host_os" in
 799 gnu*)
 800     dnl Disable by default on GNU/Hurd
 801     driglx_direct_default="no"
 802     ;;
 803 cygwin*)
 804     dnl Disable by default on cygwin
 805     driglx_direct_default="no"
 806     ;;
 807 *)
 808     driglx_direct_default="yes"
 809     ;;
 810 esac
 811 AC_ARG_ENABLE([driglx-direct],
 812     [AS_HELP_STRING([--disable-driglx-direct],
 813         [disable direct rendering in GLX and EGL for DRI \
 814             @<:@default=auto@:>@])],
 815     [driglx_direct="$enableval"],
 816     [driglx_direct="$driglx_direct_default"])
 817
 818 dnl
 819 dnl libGL configuration per driver
 820 dnl
 821 case "x$enable_glx$enable_xlib_glx" in
 822 xyesyes)
 823     # Xlib-based GLX
 824     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 825     GL_PC_REQ_PRIV="x11 xext"
 826     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 827     GL_LIB_DEPS="$XLIBGL_LIBS"
 828     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 829     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 830     ;;
 831 xyesno)
 832     # DRI-based GLX
 833     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 834     if test x"$driglx_direct" = xyes; then
 835         if test "x$have_libdrm" != xyes; then
 836             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 837         fi
 838         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 839         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 840         if test x"$enable_dri3" = xyes; then
 841             if test x"$have_libudev" != xyes; then
 842               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 843             fi
 844             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 845             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 846         fi
 847     fi
 848
 849     # find the DRI deps for libGL
 850     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 851
 852     if test x"$enable_dri3" = xyes; then
 853         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= 1.1"
 854     fi
 855
 856     # add xf86vidmode if available
 857     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 858     if test "$HAVE_XF86VIDMODE" = yes ; then
 859         dri_modules="$dri_modules xxf86vm"
 860     fi
 861
 862     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 863     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 864     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 865     GL_LIB_DEPS="$DRIGL_LIBS"
 866
 867     # need DRM libs, $PTHREAD_LIBS, etc.
 868     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 869     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 870     ;;
 871 esac
 872
 873 if test "$have_libudev" = yes; then
 874     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 875 fi
 876
 877 # This is outside the case (above) so that it is invoked even for non-GLX
 878 # builds.
 879 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 880
 881 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 882 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 883 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 884 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 885
 886 AC_SUBST([X11_INCLUDES])
 887 AC_SUBST([GL_LIB_DEPS])
 888 AC_SUBST([GL_PC_REQ_PRIV])
 889 AC_SUBST([GL_PC_LIB_PRIV])
 890 AC_SUBST([GL_PC_CFLAGS])
 891 AC_SUBST([DRI_PC_REQ_PRIV])
 892 AC_SUBST([GLESv1_CM_LIB_DEPS])
 893 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 894 AC_SUBST([GLESv2_LIB_DEPS])
 895 AC_SUBST([GLESv2_PC_LIB_PRIV])
 896
 897 AC_SUBST([HAVE_XF86VIDMODE])
 898
 899 dnl
 900 dnl More GLX setup
 901 dnl
 902 case "x$enable_glx$enable_xlib_glx" in
 903 xyesyes)
 904     DEFINES="$DEFINES -DUSE_XSHM"
 905     ;;
 906 xyesno)
 907     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 908     if test "x$driglx_direct" = xyes; then
 909         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 910     fi
 911     ;;
 912 esac
 913
 914 dnl
 915 dnl TLS detection
 916 dnl
 917
 918 AC_ARG_ENABLE([glx-tls],
 919     [AS_HELP_STRING([--enable-glx-tls],
 920         [enable TLS support in GLX @<:@default=disabled@:>@])],
 921     [GLX_USE_TLS="$enableval"],
 922     [GLX_USE_TLS=no])
 923 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 924
 925 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 926       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 927
 928 dnl
 929 dnl More DRI setup
 930 dnl
 931 dnl Directory for DRI drivers
 932 AC_ARG_WITH([dri-driverdir],
 933     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 934         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 935     [DRI_DRIVER_INSTALL_DIR="$withval"],
 936     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 937 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 938 dnl Extra search path for DRI drivers
 939 AC_ARG_WITH([dri-searchpath],
 940     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 941         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 942     [DRI_DRIVER_SEARCH_DIR="$withval"],
 943     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 944 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 945 dnl Which drivers to build - default is chosen by platform
 946 AC_ARG_WITH([dri-drivers],
 947     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 948         [comma delimited DRI drivers list, e.g.
 949         "swrast,i965,radeon" @<:@default=auto@:>@])],
 950     [with_dri_drivers="$withval"],
 951     [with_dri_drivers=yes])
 952 if test "x$with_dri_drivers" = x; then
 953     with_dri_drivers=no
 954 fi
 955
 956 dnl If $with_dri_drivers is yes, directories will be added through
 957 dnl platform checks
 958 DRI_DIRS=""
 959 case "$with_dri_drivers" in
 960 no) ;;
 961 yes)
 962     # classic DRI drivers
 963     if test "x$enable_opengl" = xyes; then
 964         DRI_DIRS="yes"
 965     fi
 966     ;;
 967 *)
 968     # verify the requested driver directories exist
 969     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 970     for driver in $dri_drivers; do
 971         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 972             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 973     done
 974     DRI_DIRS="$dri_drivers"
 975     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 976         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 977     fi
 978     ;;
 979 esac
 980
 981 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 982 if test "x$enable_dri" = xyes; then
 983     # Platform specific settings and drivers to build
 984     case "$host_os" in
 985     linux*)
 986         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 987         DEFINES="$DEFINES -DHAVE_ALIAS"
 988         if test "x$enable_dri3" = xyes; then
 989             DEFINES="$DEFINES -DHAVE_DRI3"
 990         fi
 991
 992         case "$host_cpu" in
 993         x86_64|amd64)
 994             if test "x$DRI_DIRS" = "xyes"; then
 995                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 996             fi
 997             ;;
 998         powerpc*)
 999             # Build only the drivers for cards that exist on PowerPC.
1000             if test "x$DRI_DIRS" = "xyes"; then
1001                 DRI_DIRS="r200 radeon swrast"
1002             fi
1003             ;;
1004         sparc*)
1005             # Build only the drivers for cards that exist on sparc
1006             if test "x$DRI_DIRS" = "xyes"; then
1007                 DRI_DIRS="r200 radeon swrast"
1008             fi
1009             ;;
1010         esac
1011         ;;
1012     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1013         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1014         DEFINES="$DEFINES -DHAVE_ALIAS"
1015
1016         if test "x$DRI_DIRS" = "xyes"; then
1017             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1018         fi
1019         ;;
1020     gnu*)
1021         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1022         DEFINES="$DEFINES -DHAVE_ALIAS"
1023         ;;
1024     solaris*)
1025         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1026         ;;
1027     cygwin*)
1028         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1029         if test "x$DRI_DIRS" = "xyes"; then
1030             DRI_DIRS="swrast"
1031         fi
1032         ;;
1033     esac
1034
1035     # default drivers
1036     if test "x$DRI_DIRS" = "xyes"; then
1037         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1038     fi
1039
1040     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1041
1042     # Check for expat
1043     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1044     if test "x$have_expat" = "xyes"; then
1045        PKG_CHECK_MODULES([EXPAT], [expat], [],
1046                          AC_MSG_ERROR([Expat required for DRI.]))
1047     else
1048        # expat version 2.0 and earlier do not provide expat.pc
1049        EXPAT_LIBS=-lexpat
1050     fi
1051
1052     # If we are building any DRI driver other than swrast.
1053     if test -n "$DRI_DIRS"; then
1054         if test x"$DRI_DIRS" != xswrast; then
1055             # ... libdrm is required
1056             if test "x$have_libdrm" != xyes; then
1057                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1058             fi
1059             DRICOMMON_NEED_LIBDRM=yes
1060         else
1061             DRICOMMON_NEED_LIBDRM=no
1062         fi
1063     fi
1064
1065     # put all the necessary libs together
1066     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1067     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1068
1069 fi
1070
1071 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1072 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1073                                   "x$enable_osmesa" = xyes -o \
1074                                   -n "$DRI_DIRS")
1075 AC_SUBST([DRI_LIB_DEPS])
1076 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1077
1078 case $DRI_DIRS in
1079 *i915*)
1080     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1081     HAVE_I915_DRI=yes;
1082     ;;
1083 *i965*)
1084     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1085     HAVE_I965_DRI=yes;
1086     ;;
1087 *nouveau*)
1088     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1089     HAVE_NOUVEAU_DRI=yes;
1090     ;;
1091 *radeon*)
1092     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1093     HAVE_RADEON_DRI=yes;
1094     ;;
1095 *r200*)
1096     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1097     HAVE_R200_DRI=yes;
1098     ;;
1099 *swrast*)
1100     HAVE_SWRAST_DRI=yes;
1101     ;;
1102 esac
1103
1104 dnl
1105 dnl OSMesa configuration
1106 dnl
1107
1108 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1109 AC_ARG_WITH([osmesa-bits],
1110     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1111         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1112     [osmesa_bits="$withval"],
1113     [osmesa_bits=8])
1114 if test "x$osmesa_bits" != x8; then
1115     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1116         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1117         osmesa_bits=8
1118     fi
1119 fi
1120 case "x$osmesa_bits" in
1121 x8)
1122     OSMESA_LIB="${OSMESA_LIB}"
1123     ;;
1124 x16|x32)
1125     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1126     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1127     ;;
1128 *)
1129     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1130     ;;
1131 esac
1132
1133 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1134     # only link libraries with osmesa if shared
1135     if test "$enable_static" = no; then
1136         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1137     else
1138         OSMESA_LIB_DEPS=""
1139     fi
1140     OSMESA_MESA_DEPS=""
1141     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1142 fi
1143
1144 AC_SUBST([OSMESA_LIB_DEPS])
1145 AC_SUBST([OSMESA_MESA_DEPS])
1146 AC_SUBST([OSMESA_PC_REQ])
1147 AC_SUBST([OSMESA_PC_LIB_PRIV])
1148
1149 dnl
1150 dnl gbm configuration
1151 dnl
1152 if test "x$enable_gbm" = xauto; then
1153     case "$with_egl_platforms" in
1154         *drm*)
1155             enable_gbm=yes ;;
1156          *)
1157             enable_gbm=no ;;
1158     esac
1159 fi
1160 if test "x$enable_gbm" = xyes; then
1161     if test x"$have_libudev" != xyes; then
1162         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1163     fi
1164
1165     if test "x$enable_dri" = xyes; then
1166         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1167         if test "x$enable_shared_glapi" = xno; then
1168             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1169         fi
1170     fi
1171 fi
1172 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1173 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1174 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1175 AC_SUBST([GBM_PC_REQ_PRIV])
1176 AC_SUBST([GBM_PC_LIB_PRIV])
1177
1178 dnl
1179 dnl EGL configuration
1180 dnl
1181 EGL_CLIENT_APIS=""
1182
1183 if test "x$enable_egl" = xyes; then
1184     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1185
1186     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1187
1188     if test "$enable_static" != yes; then
1189         if test "x$enable_dri" = xyes; then
1190             HAVE_EGL_DRIVER_DRI2=1
1191         fi
1192
1193     fi
1194 fi
1195 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1196 AC_SUBST([EGL_LIB_DEPS])
1197
1198 dnl
1199 dnl EGL Gallium configuration
1200 dnl
1201 if test "x$enable_gallium_egl" = xyes; then
1202     if test "x$with_gallium_drivers" = x; then
1203         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1204     fi
1205     if test "x$enable_egl" = xno; then
1206         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1207     fi
1208     if test "x$have_libdrm" != xyes; then
1209         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1210     fi
1211
1212     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1213     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1214 fi
1215 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1216
1217 dnl
1218 dnl gbm Gallium configuration
1219 dnl
1220 if test "x$enable_gallium_gbm" = xauto; then
1221     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1222         yesyesyes*drm*)
1223             enable_gallium_gbm=yes ;;
1224          *)
1225             enable_gallium_gbm=no ;;
1226     esac
1227 fi
1228 if test "x$enable_gallium_gbm" = xyes; then
1229     if test "x$with_gallium_drivers" = x; then
1230         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1231     fi
1232     if test "x$enable_gbm" = xno; then
1233         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1234     fi
1235     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1236     if test "x$enable_dri" = xno; then
1237         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1238     fi
1239
1240     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1241     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1242     enable_gallium_loader=yes
1243 fi
1244 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1245
1246 dnl
1247 dnl XA configuration
1248 dnl
1249 if test "x$enable_xa" = xyes; then
1250     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1251     enable_gallium_loader=yes
1252 fi
1253 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1254
1255 dnl
1256 dnl OpenVG configuration
1257 dnl
1258 VG_LIB_DEPS=""
1259
1260 if test "x$enable_openvg" = xyes; then
1261     if test "x$enable_egl" = xno; then
1262         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1263     fi
1264     if test "x$with_gallium_drivers" = x; then
1265         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1266     fi
1267     if test "x$enable_gallium_egl" = xno; then
1268         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1269     fi
1270
1271     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1272     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1273     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1274     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1275     AC_SUBST([VG_PC_LIB_PRIV])
1276 fi
1277 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1278
1279 dnl
1280 dnl Gallium G3DVL configuration
1281 dnl
1282 if test -n "$with_gallium_drivers"; then
1283     if test "x$enable_xvmc" = xauto; then
1284         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1285     fi
1286
1287     if test "x$enable_vdpau" = xauto; then
1288         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1289     fi
1290
1291     if test "x$enable_omx" = xauto; then
1292         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1293     fi
1294 fi
1295
1296 if test "x$enable_xvmc" = xyes; then
1297     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1298     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1299 fi
1300 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1301
1302 if test "x$enable_vdpau" = xyes; then
1303     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8],
1304                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1305     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1306 fi
1307 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1308
1309 if test "x$enable_omx" = xyes; then
1310     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= 0.0 x11-xcb xcb-dri2 >= 1.8])
1311     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1312 fi
1313 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1314
1315 dnl
1316 dnl OpenCL configuration
1317 dnl
1318
1319 AC_ARG_WITH([libclc-path],
1320    [AS_HELP_STRING([--with-libclc-path],
1321          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1322    [LIBCLC_PATH="$withval"],
1323    [LIBCLC_PATH=""])
1324
1325 if test "x$LIBCLC_PATH" != x; then
1326    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1327                   Please review the updated build instructions for clover:
1328                   http://dri.freedesktop.org/wiki/GalliumCompute])
1329 fi
1330
1331
1332 AC_ARG_WITH([clang-libdir],
1333    [AS_HELP_STRING([--with-clang-libdir],
1334          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1335    [CLANG_LIBDIR="$withval"],
1336    [CLANG_LIBDIR=""])
1337
1338 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1339
1340 if test "x$enable_opencl" = xyes; then
1341     if test "x$with_gallium_drivers" = x; then
1342         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1343     fi
1344
1345     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1346         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1347     fi
1348
1349     if test "x$have_libclc" = xno; then
1350         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1351                     Make sure the directory containing libclc.pc is specified in your
1352                     PKG_CONFIG_PATH environment variable.
1353                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1354     else
1355         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1356         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1357         AC_SUBST([LIBCLC_INCLUDEDIR])
1358         AC_SUBST([LIBCLC_LIBEXECDIR])
1359     fi
1360
1361     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1362     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1363     enable_gallium_loader=yes
1364
1365     if test "x$enable_opencl_icd" = xyes; then
1366         OPENCL_LIBNAME="MesaOpenCL"
1367     else
1368         OPENCL_LIBNAME="OpenCL"
1369     fi
1370 fi
1371 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1372 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1373 AC_SUBST([OPENCL_LIBNAME])
1374
1375 dnl
1376 dnl Gallium configuration
1377 dnl
1378 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1379
1380 AC_SUBST([LLVM_BINDIR])
1381 AC_SUBST([LLVM_CFLAGS])
1382 AC_SUBST([LLVM_CPPFLAGS])
1383 AC_SUBST([LLVM_CXXFLAGS])
1384 AC_SUBST([LLVM_LIBDIR])
1385 AC_SUBST([LLVM_LIBS])
1386 AC_SUBST([LLVM_LDFLAGS])
1387 AC_SUBST([LLVM_INCLUDEDIR])
1388 AC_SUBST([LLVM_VERSION])
1389 AC_SUBST([CLANG_RESOURCE_DIR])
1390
1391 case "x$enable_opengl$enable_gles1$enable_gles2" in
1392 x*yes*)
1393     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1394     ;;
1395 esac
1396
1397 AC_SUBST([VG_LIB_DEPS])
1398 AC_SUBST([EGL_CLIENT_APIS])
1399
1400 dnl
1401 dnl EGL Platforms configuration
1402 dnl
1403 AC_ARG_WITH([egl-platforms],
1404     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1405         [comma delimited native platforms libEGL supports, e.g.
1406         "x11,drm" @<:@default=auto@:>@])],
1407     [with_egl_platforms="$withval"],
1408     [if test "x$enable_egl" = xyes; then
1409         with_egl_platforms="x11"
1410     else
1411         with_egl_platforms=""
1412     fi])
1413
1414 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1415     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1416 fi
1417
1418 # Do per-EGL platform setups and checks
1419 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1420 for plat in $egl_platforms; do
1421         case "$plat" in
1422         wayland)
1423                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1424                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1425
1426                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1427                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1428                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1429                 ;;
1430
1431         x11)
1432                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1433                 ;;
1434
1435         drm)
1436                 test "x$enable_gbm" = "xno" &&
1437                         AC_MSG_ERROR([EGL platform drm needs gbm])
1438                 test "x$have_libdrm" != xyes &&
1439                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1440                 ;;
1441
1442         android|fbdev|gdi|null)
1443                 ;;
1444
1445         *)
1446                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1447                 ;;
1448         esac
1449
1450         case "$plat$have_libudev" in
1451                 waylandno|drmno)
1452                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1453         esac
1454 done
1455
1456 # libEGL wants to default to the first platform specified in
1457 # ./configure.  parse that here.
1458 if test "x$egl_platforms" != "x"; then
1459     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1460     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1461 else
1462     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1463 fi
1464
1465 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1466     NEED_WINSYS_XLIB=yes
1467 fi
1468 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1469 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1470 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1471 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1472 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1473
1474 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1475
1476 AC_SUBST([EGL_NATIVE_PLATFORM])
1477 AC_SUBST([EGL_CFLAGS])
1478
1479 # If we don't have the X11 platform, set this define so we don't try to include
1480 # the X11 headers.
1481 if ! echo "$egl_platforms" | grep -q 'x11'; then
1482     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1483     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1484 fi
1485
1486 AC_ARG_WITH([egl-driver-dir],
1487     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1488                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1489     [EGL_DRIVER_INSTALL_DIR="$withval"],
1490     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1491 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1492
1493 AC_ARG_WITH([max-width],
1494     [AS_HELP_STRING([--with-max-width=N],
1495                     [Maximum framebuffer width (4096)])],
1496     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1497      AS_IF([test "${withval}" -gt "4096"],
1498            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1499 )
1500 AC_ARG_WITH([max-height],
1501     [AS_HELP_STRING([--with-max-height=N],
1502                     [Maximum framebuffer height (4096)])],
1503     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1504      AS_IF([test "${withval}" -gt "4096"],
1505            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1506 )
1507
1508 dnl
1509 dnl Gallium LLVM
1510 dnl
1511 AC_ARG_ENABLE([gallium-llvm],
1512     [AS_HELP_STRING([--enable-gallium-llvm],
1513         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1514     [enable_gallium_llvm="$enableval"],
1515     [enable_gallium_llvm=auto])
1516
1517 AC_ARG_WITH([llvm-shared-libs],
1518     [AS_HELP_STRING([--with-llvm-shared-libs],
1519         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1520     [],
1521     [with_llvm_shared_libs=no])
1522
1523 AC_ARG_WITH([llvm-prefix],
1524     [AS_HELP_STRING([--with-llvm-prefix],
1525         [Prefix for LLVM installations in non-standard locations])],
1526     [llvm_prefix="$withval"],
1527     [llvm_prefix=""])
1528
1529
1530 # Call this inside ` ` to get the return value.
1531 # $1 is the llvm-config command with arguments.
1532 strip_unwanted_llvm_flags() {
1533     # Use \> (marks the end of the word)
1534     echo `$1` | sed \
1535         -e 's/-DNDEBUG\>//g' \
1536         -e 's/-pedantic\>//g' \
1537         -e 's/-Wcovered-switch-default\>//g' \
1538         -e 's/-O.\>//g' \
1539         -e 's/-g\>//g' \
1540         -e 's/-Wall\>//g' \
1541         -e 's/-fcolor-diagnostics\>//g' \
1542         -e 's/-fomit-frame-pointer\>//g'
1543 }
1544
1545
1546 if test "x$with_gallium_drivers" = x; then
1547     enable_gallium_llvm=no
1548 fi
1549 if test "x$enable_gallium_llvm" = xauto; then
1550     case "$host_cpu" in
1551     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1552     esac
1553 fi
1554 if test "x$enable_gallium_llvm" = xyes; then
1555     if test "x$llvm_prefix" != x; then
1556         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1557     else
1558         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1559     fi
1560
1561     if test "x$LLVM_CONFIG" != xno; then
1562         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1563         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1564         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1565         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1566         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1567         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1568         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1569         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1570
1571         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1572             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1573         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1574             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1575
1576         if test "x${LLVM_VERSION_MAJOR}" != x; then
1577             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1578         else
1579             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1580         fi
1581
1582         LLVM_COMPONENTS="engine bitwriter"
1583         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1584             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1585         fi
1586
1587         if test "x$enable_opencl" = xyes; then
1588             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1589             # LLVM 3.3 >= 177971 requires IRReader
1590             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1591                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1592             fi
1593             # LLVM 3.4 requires Option
1594             if $LLVM_CONFIG --components | grep -qw 'option'; then
1595                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1596             fi
1597         fi
1598         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1599         MESA_LLVM=1
1600
1601         dnl Check for Clang internal headers
1602         if test "x$enable_opencl" = xyes; then
1603             if test "x$CLANG_LIBDIR" = x; then
1604                 CLANG_LIBDIR=${LLVM_LIBDIR}
1605             fi
1606             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1607             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1608                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1609         fi
1610     else
1611         MESA_LLVM=0
1612         LLVM_VERSION_INT=0
1613     fi
1614 else
1615     MESA_LLVM=0
1616     LLVM_VERSION_INT=0
1617 fi
1618
1619 dnl Directory for XVMC libs
1620 AC_ARG_WITH([xvmc-libdir],
1621     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1622         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1623     [XVMC_LIB_INSTALL_DIR="$withval"],
1624     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1625 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1626
1627 dnl
1628 dnl Gallium Tests
1629 dnl
1630 if test "x$enable_gallium_tests" = xyes; then
1631     enable_gallium_loader=yes
1632 fi
1633 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1634
1635 if test "x$enable_gallium_loader" = xyes; then
1636     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1637 fi
1638 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1639
1640 dnl Directory for VDPAU libs
1641 AC_ARG_WITH([vdpau-libdir],
1642     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1643         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1644     [VDPAU_LIB_INSTALL_DIR="$withval"],
1645     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1646 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1647
1648 AC_ARG_WITH([omx-libdir],
1649     [AS_HELP_STRING([--with-omx-libdir=DIR],
1650         [directory for the OMX libraries])],
1651     [OMX_LIB_INSTALL_DIR="$withval"],
1652     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1653 AC_SUBST([OMX_LIB_INSTALL_DIR])
1654
1655 dnl Directory for OpenCL libs
1656 AC_ARG_WITH([opencl-libdir],
1657     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1658         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1659     [OPENCL_LIB_INSTALL_DIR="$withval"],
1660     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1661 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1662
1663 dnl
1664 dnl Gallium helper functions
1665 dnl
1666 gallium_check_st() {
1667     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1668          if test "x$have_libdrm" != xyes; then
1669             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1670          fi
1671          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1672     fi
1673     if test "x$enable_dri" = xyes && test "x$2" != x; then
1674          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1675     fi
1676     if test "x$enable_xa" = xyes && test "x$3" != x; then
1677          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1678     fi
1679     if test "x$enable_xvmc" = xyes && test "x$4" != x; then
1680          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1681     fi
1682     if test "x$enable_vdpau" = xyes && test "x$5" != x; then
1683          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1684     fi
1685     if test "x$enable_omx" = xyes && test "x$6" != x; then
1686          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1687     fi
1688 }
1689
1690 gallium_require_llvm() {
1691     if test "x$MESA_LLVM" = x0; then
1692         case "$host_cpu" in
1693         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1694         esac
1695     fi
1696 }
1697
1698 gallium_require_drm_loader() {
1699     if test "x$enable_gallium_loader" = xyes; then
1700         if test "x$have_libudev" != xyes; then
1701             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1702         fi
1703         if test "x$have_libdrm" != xyes; then
1704             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1705         fi
1706         enable_gallium_drm_loader=yes
1707     fi
1708 }
1709
1710 radeon_llvm_check() {
1711     if test "x$enable_gallium_llvm" != "xyes"; then
1712         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1713     fi
1714     LLVM_REQUIRED_VERSION_MAJOR="3"
1715     LLVM_REQUIRED_VERSION_MINOR="3"
1716     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1717         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1718     fi
1719     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1720         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1721                       sources with the --enable-experimental-targets=R600
1722                       configure flag])
1723     fi
1724     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1725     NEED_RADEON_LLVM=yes
1726     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1727                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1728 }
1729
1730 dnl Gallium drivers
1731 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1732         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1733     NEED_NONNULL_WINSYS=yes
1734 fi
1735 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1736
1737 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1738 if test "x$with_gallium_drivers" != x; then
1739     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1740     for driver in $gallium_drivers; do
1741         case "x$driver" in
1742         xsvga)
1743             HAVE_GALLIUM_SVGA=yes
1744             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1745             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1746             ;;
1747         xi915)
1748             HAVE_GALLIUM_I915=yes
1749             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1750             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1751             if test "x$MESA_LLVM" = x1; then
1752                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1753             fi
1754             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1755             gallium_check_st "i915/drm" "dri-i915"
1756             DRICOMMON_NEED_LIBDRM=yes
1757             ;;
1758         xilo)
1759             HAVE_GALLIUM_ILO=yes
1760             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1761             gallium_require_drm_loader
1762             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1763             gallium_check_st "intel/drm" "dri-ilo"
1764             DRICOMMON_NEED_LIBDRM=yes
1765             ;;
1766         xr300)
1767             HAVE_GALLIUM_R300=yes
1768             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1769             gallium_require_llvm "Gallium R300"
1770             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1771             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1772             DRICOMMON_NEED_LIBDRM=yes
1773             ;;
1774         xr600)
1775             HAVE_GALLIUM_R600=yes
1776             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1777             gallium_require_drm_loader
1778             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1779             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1780                 radeon_llvm_check "r600g"
1781                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1782             fi
1783             if test "x$enable_r600_llvm" = xyes; then
1784                 USE_R600_LLVM_COMPILER=yes;
1785             fi
1786             if test "x$enable_opencl" = xyes; then
1787                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1788             fi
1789             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1790             DRICOMMON_NEED_LIBDRM=yes
1791             ;;
1792         xradeonsi)
1793             HAVE_GALLIUM_RADEONSI=yes
1794             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1795             gallium_require_drm_loader
1796             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1797             radeon_llvm_check "radeonsi"
1798             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1799             DRICOMMON_NEED_LIBDRM=yes
1800             ;;
1801         xnouveau)
1802             HAVE_GALLIUM_NOUVEAU=yes
1803             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1804             gallium_require_drm_loader
1805             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1806             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1807             DRICOMMON_NEED_LIBDRM=yes
1808             ;;
1809         xfreedreno)
1810             HAVE_GALLIUM_FREEDRENO=yes
1811             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1812             gallium_require_drm_loader
1813             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1814             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1815             DRICOMMON_NEED_LIBDRM=yes
1816             ;;
1817         xswrast)
1818             HAVE_GALLIUM_SOFTPIPE=yes
1819             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1820             if test "x$MESA_LLVM" = x1; then
1821                 HAVE_GALLIUM_LLVMPIPE=yes
1822                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1823             fi
1824
1825             if test "x$enable_dri" = xyes; then
1826                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1827             fi
1828             ;;
1829         *)
1830             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1831             ;;
1832         esac
1833     done
1834 fi
1835
1836 dnl Set LLVM_LIBS - This is done after the driver configuration so
1837 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1838 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1839 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1840 dnl this was causing the same libraries to be appear multiple times
1841 dnl in LLVM_LIBS.
1842
1843 if test "x$MESA_LLVM" != x0; then
1844
1845     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1846
1847     if test "x$with_llvm_shared_libs" = xyes; then
1848         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1849         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1850         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1851
1852         if test "x$llvm_have_one_so" = xyes; then
1853             dnl LLVM was built using auto*, so there is only one shared object.
1854             LLVM_LIBS="-l$LLVM_SO_NAME"
1855         else
1856             dnl If LLVM was built with CMake, there will be one shared object per
1857             dnl component.
1858             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1859                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1860         Please make sure you have built llvm with the --enable-shared option
1861         and that your llvm libraries are installed in $LLVM_LIBDIR
1862         If you have installed your llvm libraries to a different directory you
1863         can use the --with-llvm-prefix= configure flag to specify this directory.
1864         NOTE: Mesa is attempting to use llvm shared libraries because you have
1865         passed one of the following options to configure:
1866                 --with-llvm-shared-libs
1867                 --enable-opencl
1868         If you do not want to build with llvm shared libraries and instead want to
1869         use llvm static libraries then remove these options from your configure
1870         invocation and reconfigure.])])
1871
1872            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1873            dnl install uses a shared object for each compoenent and we have
1874            dnl already added all of these objects to LLVM_LIBS.
1875         fi
1876     fi
1877 fi
1878
1879 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1880 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1881 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1882 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1883 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1884 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1885 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1886 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1887 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1888 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1889
1890 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1891                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1892                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1893 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1894                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1895                                                   && test "x$MESA_LLVM" = x1)
1896
1897 # NOTE: anything using xcb or other client side libs ends up in separate
1898 #       _CLIENT variables.  The pipe loader is built in two variants,
1899 #       one that is standalone and does not link any x client libs (for
1900 #       use by XA tracker in particular, but could be used in any case
1901 #       where communication with xserver is not desired).
1902 if test "x$enable_gallium_loader" = xyes; then
1903     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1904
1905     if test "x$enable_gallium_drm_loader" = xyes; then
1906         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1907         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1908                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1909         if test "x$pipe_loader_have_xcb" = xyes; then
1910             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1911             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1912         fi
1913     fi
1914
1915     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1916     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1917
1918     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1919     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1920     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1921     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1922 fi
1923
1924 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1925 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1926 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1927 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1928 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1929 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1930
1931 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1932                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1933                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1934                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1935 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1936                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1937 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1938 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1939 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1940 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1941 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1942 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1943 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1944
1945 AC_SUBST([ELF_LIB])
1946
1947 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1948 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1949 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1950 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1951 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1952
1953 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1954 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1955 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1956
1957 AC_SUBST([VDPAU_MAJOR], 1)
1958 AC_SUBST([VDPAU_MINOR], 0)
1959
1960 AC_SUBST([XVMC_MAJOR], 1)
1961 AC_SUBST([XVMC_MINOR], 0)
1962
1963 AC_SUBST([XA_MAJOR], 2)
1964 AC_SUBST([XA_MINOR], 2)
1965 AC_SUBST([XA_TINY], 0)
1966 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1967
1968 dnl Restore LDFLAGS and CPPFLAGS
1969 LDFLAGS="$_SAVE_LDFLAGS"
1970 CPPFLAGS="$_SAVE_CPPFLAGS"
1971
1972 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1973 if test "x$acv_mesa_CLANG" = xyes; then
1974     CFLAGS="$CFLAGS -Qunused-arguments"
1975     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1976 fi
1977
1978 dnl Add user CFLAGS and CXXFLAGS
1979 CFLAGS="$CFLAGS $USER_CFLAGS"
1980 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1981
1982 dnl Substitute the config
1983 AC_CONFIG_FILES([Makefile
1984                 src/Makefile
1985                 src/egl/Makefile
1986                 src/egl/drivers/Makefile
1987                 src/egl/drivers/dri2/Makefile
1988                 src/egl/main/Makefile
1989                 src/egl/main/egl.pc
1990                 src/egl/wayland/Makefile
1991                 src/egl/wayland/wayland-drm/Makefile
1992                 src/egl/wayland/wayland-egl/Makefile
1993                 src/egl/wayland/wayland-egl/wayland-egl.pc
1994                 src/gallium/auxiliary/Makefile
1995                 src/gallium/auxiliary/pipe-loader/Makefile
1996                 src/gallium/drivers/Makefile
1997                 src/gallium/drivers/freedreno/Makefile
1998                 src/gallium/drivers/galahad/Makefile
1999                 src/gallium/drivers/i915/Makefile
2000                 src/gallium/drivers/identity/Makefile
2001                 src/gallium/drivers/ilo/Makefile
2002                 src/gallium/drivers/llvmpipe/Makefile
2003                 src/gallium/drivers/noop/Makefile
2004                 src/gallium/drivers/nouveau/Makefile
2005                 src/gallium/drivers/r300/Makefile
2006                 src/gallium/drivers/r600/Makefile
2007                 src/gallium/drivers/radeon/Makefile
2008                 src/gallium/drivers/radeonsi/Makefile
2009                 src/gallium/drivers/rbug/Makefile
2010                 src/gallium/drivers/softpipe/Makefile
2011                 src/gallium/drivers/svga/Makefile
2012                 src/gallium/drivers/trace/Makefile
2013                 src/gallium/state_trackers/Makefile
2014                 src/gallium/state_trackers/clover/Makefile
2015                 src/gallium/state_trackers/dri/Makefile
2016                 src/gallium/state_trackers/dri/drm/Makefile
2017                 src/gallium/state_trackers/dri/sw/Makefile
2018                 src/gallium/state_trackers/egl/Makefile
2019                 src/gallium/state_trackers/gbm/Makefile
2020                 src/gallium/state_trackers/glx/xlib/Makefile
2021                 src/gallium/state_trackers/omx/Makefile
2022                 src/gallium/state_trackers/osmesa/Makefile
2023                 src/gallium/state_trackers/vdpau/Makefile
2024                 src/gallium/state_trackers/vega/Makefile
2025                 src/gallium/state_trackers/xa/Makefile
2026                 src/gallium/state_trackers/xvmc/Makefile
2027                 src/gallium/targets/Makefile
2028                 src/gallium/targets/dri-freedreno/Makefile
2029                 src/gallium/targets/dri-i915/Makefile
2030                 src/gallium/targets/dri-ilo/Makefile
2031                 src/gallium/targets/dri-nouveau/Makefile
2032                 src/gallium/targets/dri-swrast/Makefile
2033                 src/gallium/targets/dri-vmwgfx/Makefile
2034                 src/gallium/targets/egl-static/Makefile
2035                 src/gallium/targets/gbm/Makefile
2036                 src/gallium/targets/opencl/Makefile
2037                 src/gallium/targets/xa/Makefile
2038                 src/gallium/targets/xa/xatracker.pc
2039                 src/gallium/targets/osmesa/Makefile
2040                 src/gallium/targets/osmesa/osmesa.pc
2041                 src/gallium/targets/pipe-loader/Makefile
2042                 src/gallium/targets/radeonsi/dri/Makefile
2043                 src/gallium/targets/radeonsi/omx/Makefile
2044                 src/gallium/targets/radeonsi/vdpau/Makefile
2045                 src/gallium/targets/r300/dri/Makefile
2046                 src/gallium/targets/r600/dri/Makefile
2047                 src/gallium/targets/r600/omx/Makefile
2048                 src/gallium/targets/r600/vdpau/Makefile
2049                 src/gallium/targets/r600/xvmc/Makefile
2050                 src/gallium/targets/libgl-xlib/Makefile
2051                 src/gallium/targets/vdpau-nouveau/Makefile
2052                 src/gallium/targets/xvmc-nouveau/Makefile
2053                 src/gallium/tests/trivial/Makefile
2054                 src/gallium/tests/unit/Makefile
2055                 src/gallium/winsys/Makefile
2056                 src/gallium/winsys/freedreno/drm/Makefile
2057                 src/gallium/winsys/i915/drm/Makefile
2058                 src/gallium/winsys/i915/sw/Makefile
2059                 src/gallium/winsys/intel/drm/Makefile
2060                 src/gallium/winsys/nouveau/drm/Makefile
2061                 src/gallium/winsys/radeon/drm/Makefile
2062                 src/gallium/winsys/svga/drm/Makefile
2063                 src/gallium/winsys/sw/dri/Makefile
2064                 src/gallium/winsys/sw/fbdev/Makefile
2065                 src/gallium/winsys/sw/null/Makefile
2066                 src/gallium/winsys/sw/wayland/Makefile
2067                 src/gallium/winsys/sw/wrapper/Makefile
2068                 src/gallium/winsys/sw/xlib/Makefile
2069                 src/gbm/Makefile
2070                 src/gbm/main/gbm.pc
2071                 src/glsl/Makefile
2072                 src/glx/Makefile
2073                 src/glx/tests/Makefile
2074                 src/gtest/Makefile
2075                 src/loader/Makefile
2076                 src/mapi/Makefile
2077                 src/mapi/es1api/Makefile
2078                 src/mapi/es1api/glesv1_cm.pc
2079                 src/mapi/es2api/Makefile
2080                 src/mapi/es2api/glesv2.pc
2081                 src/mapi/glapi/Makefile
2082                 src/mapi/glapi/gen/Makefile
2083                 src/mapi/glapi/tests/Makefile
2084                 src/mapi/shared-glapi/Makefile
2085                 src/mapi/shared-glapi/tests/Makefile
2086                 src/mapi/vgapi/Makefile
2087                 src/mapi/vgapi/vg.pc
2088                 src/mesa/Makefile
2089                 src/mesa/gl.pc
2090                 src/mesa/drivers/dri/dri.pc
2091                 src/mesa/drivers/dri/common/Makefile
2092                 src/mesa/drivers/dri/common/xmlpool/Makefile
2093                 src/mesa/drivers/dri/i915/Makefile
2094                 src/mesa/drivers/dri/i965/Makefile
2095                 src/mesa/drivers/dri/Makefile
2096                 src/mesa/drivers/dri/nouveau/Makefile
2097                 src/mesa/drivers/dri/r200/Makefile
2098                 src/mesa/drivers/dri/radeon/Makefile
2099                 src/mesa/drivers/dri/swrast/Makefile
2100                 src/mesa/drivers/osmesa/Makefile
2101                 src/mesa/drivers/osmesa/osmesa.pc
2102                 src/mesa/drivers/x11/Makefile
2103                 src/mesa/main/tests/Makefile
2104                 src/mesa/main/tests/hash_table/Makefile])
2105
2106 dnl Sort the dirs alphabetically
2107 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2108 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2109 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2110 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2111
2112 AC_OUTPUT
2113
2114 dnl
2115 dnl Output some configuration info for the user
2116 dnl
2117 echo ""
2118 echo "        prefix:          $prefix"
2119 echo "        exec_prefix:     $exec_prefix"
2120 echo "        libdir:          $libdir"
2121 echo "        includedir:      $includedir"
2122
2123 dnl API info
2124 echo ""
2125 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2126 echo "        OpenVG:          $enable_openvg"
2127
2128 dnl Driver info
2129 echo ""
2130 case "x$enable_osmesa$enable_gallium_osmesa" in
2131 xnoyes)
2132         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2133         ;;
2134 xyesno)
2135         echo "        OSMesa:          lib$OSMESA_LIB"
2136         ;;
2137 xnono)
2138         echo "        OSMesa:          no"
2139         ;;
2140 esac
2141
2142 if test "x$enable_dri" != xno; then
2143         # cleanup the drivers var
2144         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2145         if test "x$DRI_DIRS" = x; then
2146             echo "        DRI drivers:     no"
2147         else
2148             echo "        DRI drivers:     $dri_dirs"
2149         fi
2150         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2151 fi
2152
2153 case "x$enable_glx$enable_xlib_glx" in
2154 xyesyes)
2155     echo "        GLX:             Xlib-based"
2156     ;;
2157 xyesno)
2158     echo "        GLX:             DRI-based"
2159     ;;
2160 *)
2161     echo "        GLX:             $enable_glx"
2162     ;;
2163 esac
2164
2165 dnl EGL
2166 echo ""
2167 echo "        EGL:             $enable_egl"
2168 if test "$enable_egl" = yes; then
2169     echo "        EGL platforms:   $egl_platforms"
2170
2171     egl_drivers=""
2172     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2173         egl_drivers="$egl_drivers builtin:egl_dri2"
2174     fi
2175
2176     if test "x$enable_gallium_egl" = xyes; then
2177         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2178         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2179     else
2180         echo "        EGL drivers:    $egl_drivers"
2181     fi
2182 fi
2183
2184 echo ""
2185 if test "x$MESA_LLVM" = x1; then
2186     echo "        llvm:            yes"
2187     echo "        llvm-config:     $LLVM_CONFIG"
2188     echo "        llvm-version:    $LLVM_VERSION"
2189 else
2190     echo "        llvm:            no"
2191 fi
2192
2193 echo ""
2194 if test -n "$with_gallium_drivers"; then
2195     echo "        Gallium:         yes"
2196     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2197     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2198     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2199     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2200 else
2201     echo "        Gallium:         no"
2202 fi
2203
2204
2205 dnl Libraries
2206 echo ""
2207 echo "        Shared libs:     $enable_shared"
2208 echo "        Static libs:     $enable_static"
2209 echo "        Shared-glapi:    $enable_shared_glapi"
2210
2211 dnl Compiler options
2212 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2213 cflags=`echo $CFLAGS | \
2214     $SED 's/^ *//;s/  */ /;s/ *$//'`
2215 cxxflags=`echo $CXXFLAGS | \
2216     $SED 's/^ *//;s/  */ /;s/ *$//'`
2217 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2218 echo ""
2219 echo "        CFLAGS:          $cflags"
2220 echo "        CXXFLAGS:        $cxxflags"
2221 echo "        Macros:          $defines"
2222 echo ""
2223 if test "x$MESA_LLVM" = x1; then
2224     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2225     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2226     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2227     echo ""
2228 fi
2229 echo "        PYTHON2:         $PYTHON2"
2230
2231 echo ""
2232 echo "        Run '${MAKE-make}' to build Mesa"
2233 echo ""