configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.65
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2 python])
 102 AC_PROG_SED
 103 AC_PROG_MKDIR_P
 104
 105 AC_SYS_LARGEFILE
 106
 107 LT_PREREQ([2.2])
 108 LT_INIT([disable-static])
 109
 110 AC_CHECK_PROG(RM, rm, [rm -f])
 111
 112 AX_PROG_BISON([],
 113               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 114                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 115 AX_PROG_FLEX([],
 116              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 117                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 118
 119 AC_CHECK_PROG(INDENT, indent, indent, cat)
 120 if test "x$INDENT" != "xcat"; then
 121     # Only GNU indent is supported
 122     INDENT_VERSION=`indent --version | grep GNU`
 123     if test $? -eq 0; then
 124        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 125     else
 126        INDENT="cat"
 127     fi
 128 fi
 129
 130 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 131
 132 if test -z "$PYTHON2"; then
 133     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 134         AC_MSG_ERROR([Python not found - unable to generate sources])
 135     fi
 136 else
 137     if test "x$acv_mako_found" = xno; then
 138         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 139             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 140         fi
 141     fi
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 dnl We need a POSIX shell for parts of the build. Assume we have one
 147 dnl in most cases.
 148 case "$host_os" in
 149 solaris*)
 150     # Solaris /bin/sh is too old/non-POSIX compliant
 151     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 152     SHELL="$POSIX_SHELL"
 153     ;;
 154 esac
 155
 156 dnl clang is mostly GCC-compatible, but its version is much lower,
 157 dnl so we have to check for it.
 158 AC_MSG_CHECKING([if compiling with clang])
 159
 160 AC_COMPILE_IFELSE(
 161 [AC_LANG_PROGRAM([], [[
 162 #ifndef __clang__
 163        not clang
 164 #endif
 165 ]])],
 166 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 167
 168 AC_MSG_RESULT([$acv_mesa_CLANG])
 169
 170 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 171 dnl versions are explictly not supported.
 172 GEN_ASM_OFFSETS=no
 173 USE_GNU99=no
 174 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 175     AC_MSG_CHECKING([whether gcc version is sufficient])
 176     major=0
 177     minor=0
 178
 179     GCC_VERSION=`$CC -dumpversion`
 180     if test $? -eq 0; then
 181         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 182         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 183     fi
 184
 185     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 186         AC_MSG_RESULT([no])
 187         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 188     else
 189         AC_MSG_RESULT([yes])
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 193         USE_GNU99=yes
 194     fi
 195     if test "x$cross_compiling" = xyes; then
 196         GEN_ASM_OFFSETS=yes
 197     fi
 198 fi
 199
 200 dnl We don't support building Mesa with Sun C compiler
 201 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 202 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 203 if test "x$SUNCC" = xyes; then
 204     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 205 fi
 206
 207 dnl Check for compiler builtins
 208 AX_GCC_BUILTIN([__builtin_bswap32])
 209 AX_GCC_BUILTIN([__builtin_bswap64])
 210 AX_GCC_BUILTIN([__builtin_clz])
 211 AX_GCC_BUILTIN([__builtin_clzll])
 212 AX_GCC_BUILTIN([__builtin_ctz])
 213 AX_GCC_BUILTIN([__builtin_expect])
 214 AX_GCC_BUILTIN([__builtin_ffs])
 215 AX_GCC_BUILTIN([__builtin_ffsll])
 216 AX_GCC_BUILTIN([__builtin_popcount])
 217 AX_GCC_BUILTIN([__builtin_popcountll])
 218 AX_GCC_BUILTIN([__builtin_unreachable])
 219
 220 AX_GCC_FUNC_ATTRIBUTE([const])
 221 AX_GCC_FUNC_ATTRIBUTE([flatten])
 222 AX_GCC_FUNC_ATTRIBUTE([format])
 223 AX_GCC_FUNC_ATTRIBUTE([malloc])
 224 AX_GCC_FUNC_ATTRIBUTE([packed])
 225 AX_GCC_FUNC_ATTRIBUTE([pure])
 226 AX_GCC_FUNC_ATTRIBUTE([unused])
 227 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 228
 229 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 230
 231 dnl Make sure the pkg-config macros are defined
 232 m4_ifndef([PKG_PROG_PKG_CONFIG],
 233     [m4_fatal([Could not locate the pkg-config autoconf macros.
 234   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 235   are in a different location, try setting the environment variable
 236   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 237 PKG_PROG_PKG_CONFIG()
 238
 239 dnl LIB_DIR - library basename
 240 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 241 AC_SUBST([LIB_DIR])
 242
 243 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 244 _SAVE_LDFLAGS="$LDFLAGS"
 245 _SAVE_CPPFLAGS="$CPPFLAGS"
 246
 247 dnl Compiler macros
 248 DEFINES="-D__STDC_LIMIT_MACROS"
 249 AC_SUBST([DEFINES])
 250 case "$host_os" in
 251 linux*|*-gnu*|gnu*)
 252     DEFINES="$DEFINES -D_GNU_SOURCE"
 253     ;;
 254 solaris*)
 255     DEFINES="$DEFINES -DSVR4"
 256     ;;
 257 cygwin*)
 258     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 259     ;;
 260 esac
 261
 262 dnl Add flags for gcc and g++
 263 if test "x$GCC" = xyes; then
 264     CFLAGS="$CFLAGS -Wall"
 265
 266     if test "x$USE_GNU99" = xyes; then
 267         CFLAGS="$CFLAGS -std=gnu99"
 268     else
 269         CFLAGS="$CFLAGS -std=c99"
 270     fi
 271
 272     # Enable -Werror=implicit-function-declaration and
 273     # -Werror=missing-prototypes, if available, or otherwise, just
 274     # -Wmissing-prototypes.  This is particularly useful to avoid
 275     # generating a loadable driver module that has undefined symbols.
 276     save_CFLAGS="$CFLAGS"
 277     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 278     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 279     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 280     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 281                    AC_MSG_RESULT([yes]),
 282                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 283                     AC_MSG_RESULT([no])]);
 284
 285     # Enable -fvisibility=hidden if using a gcc that supports it
 286     save_CFLAGS="$CFLAGS"
 287     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 288     VISIBILITY_CFLAGS="-fvisibility=hidden"
 289     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 290     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 291                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 292
 293     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 294     CFLAGS=$save_CFLAGS
 295
 296     # Work around aliasing bugs - developers should comment this out
 297     CFLAGS="$CFLAGS -fno-strict-aliasing"
 298
 299     # We don't want floating-point math functions to set errno or trap
 300     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 301
 302     # gcc's builtin memcmp is slower than glibc's
 303     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 304     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 305
 306     # Flags to help ensure that certain portions of the code -- and only those
 307     # portions -- can be built with MSVC:
 308     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 309     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326
 327     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 328     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 329 fi
 330 if test "x$GXX" = xyes; then
 331     CXXFLAGS="$CXXFLAGS -Wall"
 332
 333     # Enable -fvisibility=hidden if using a gcc that supports it
 334     save_CXXFLAGS="$CXXFLAGS"
 335     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 336     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 337     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 338     AC_LANG_PUSH([C++])
 339     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 340                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 341     AC_LANG_POP([C++])
 342
 343     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 344     CXXFLAGS=$save_CXXFLAGS
 345
 346     # Work around aliasing bugs - developers should comment this out
 347     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 348
 349     # gcc's builtin memcmp is slower than glibc's
 350     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 351     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 352 fi
 353
 354 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 355 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 356 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 357 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 358
 359 dnl even if the compiler appears to support it, using visibility attributes isn't
 360 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 361 case "$host_os" in
 362 cygwin*)
 363     VISIBILITY_CFLAGS=""
 364     VISIBILITY_CXXFLAGS=""
 365     ;;
 366 esac
 367
 368 AC_SUBST([VISIBILITY_CFLAGS])
 369 AC_SUBST([VISIBILITY_CXXFLAGS])
 370
 371 dnl
 372 dnl Optional flags, check for compiler support
 373 dnl
 374 SSE41_CFLAGS="-msse4.1"
 375 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 376 dnl stack, but on x86-32 such alignment is not guaranteed.
 377 case "$target_cpu" in
 378 i?86)
 379     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 380     ;;
 381 esac
 382 save_CFLAGS="$CFLAGS"
 383 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 384 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 385 #include <smmintrin.h>
 386 int main () {
 387     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 388     c = _mm_max_epu32(a, b);
 389     return 0;
 390 }]])], SSE41_SUPPORTED=1)
 391 CFLAGS="$save_CFLAGS"
 392 if test "x$SSE41_SUPPORTED" = x1; then
 393     DEFINES="$DEFINES -DUSE_SSE41"
 394 fi
 395 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 396 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 397
 398 dnl Can't have static and shared libraries, default to static if user
 399 dnl explicitly requested. If both disabled, set to static since shared
 400 dnl was explicitly requested.
 401 case "x$enable_static$enable_shared" in
 402 xyesyes)
 403     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 404     enable_shared=no
 405     ;;
 406 xnono)
 407     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 408     enable_shared=yes
 409     ;;
 410 esac
 411
 412 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 413
 414 dnl
 415 dnl other compiler options
 416 dnl
 417 AC_ARG_ENABLE([debug],
 418     [AS_HELP_STRING([--enable-debug],
 419         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 420     [enable_debug="$enableval"],
 421     [enable_debug=no]
 422 )
 423 if test "x$enable_debug" = xyes; then
 424     DEFINES="$DEFINES -DDEBUG"
 425     if test "x$GCC" = xyes; then
 426         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 427             CFLAGS="$CFLAGS -g"
 428         fi
 429         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 430             CFLAGS="$CFLAGS -O0"
 431         fi
 432     fi
 433     if test "x$GXX" = xyes; then
 434         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 435             CXXFLAGS="$CXXFLAGS -g"
 436         fi
 437         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 438             CXXFLAGS="$CXXFLAGS -O0"
 439         fi
 440     fi
 441 else
 442    DEFINES="$DEFINES -DNDEBUG"
 443 fi
 444
 445 dnl
 446 dnl Check if linker supports -Bsymbolic
 447 dnl
 448 save_LDFLAGS=$LDFLAGS
 449 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 450 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 451 AC_LINK_IFELSE(
 452     [AC_LANG_SOURCE([int main() { return 0;}])],
 453     [AC_MSG_RESULT([yes])
 454         BSYMBOLIC="-Wl,-Bsymbolic";],
 455     [AC_MSG_RESULT([no])
 456         BSYMBOLIC="";])
 457 LDFLAGS=$save_LDFLAGS
 458
 459 AC_SUBST([BSYMBOLIC])
 460
 461 dnl
 462 dnl Check if linker supports garbage collection
 463 dnl
 464 save_LDFLAGS=$LDFLAGS
 465 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 466 AC_MSG_CHECKING([whether ld supports --gc-sections])
 467 AC_LINK_IFELSE(
 468     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 469     [AC_MSG_RESULT([yes])
 470         GC_SECTIONS="-Wl,--gc-sections";],
 471     [AC_MSG_RESULT([no])
 472         GC_SECTIONS="";])
 473 LDFLAGS=$save_LDFLAGS
 474
 475 AC_SUBST([GC_SECTIONS])
 476
 477 dnl
 478 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 479 dnl so when these flags are passed to ld via libtool the checks will fail
 480 dnl
 481 case "$host_os" in
 482 openbsd* | darwin* )
 483     LD_NO_UNDEFINED="" ;;
 484 *)
 485     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 486 esac
 487
 488 AC_SUBST([LD_NO_UNDEFINED])
 489
 490 dnl
 491 dnl Check if linker supports version scripts
 492 dnl
 493 AC_MSG_CHECKING([if the linker supports version-scripts])
 494 save_LDFLAGS=$LDFLAGS
 495 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 496 cat > conftest.map <<EOF
 497 VERSION_1 {
 498      global:
 499          main;
 500
 501      local:
 502          *;
 503 };
 504 EOF
 505 AC_LINK_IFELSE(
 506     [AC_LANG_SOURCE([int main() { return 0;}])],
 507     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 508     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 509 LDFLAGS=$save_LDFLAGS
 510 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 511
 512 dnl
 513 dnl Check if linker supports dynamic list files
 514 dnl
 515 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 516 save_LDFLAGS=$LDFLAGS
 517 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 518 cat > conftest.dyn <<EOF
 519 {
 520         radeon_drm_winsys_create;
 521 };
 522 EOF
 523 AC_LINK_IFELSE(
 524     [AC_LANG_SOURCE([int main() { return 0;}])],
 525     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 526     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 527 LDFLAGS=$save_LDFLAGS
 528 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 529
 530 dnl
 531 dnl compatibility symlinks
 532 dnl
 533 case "$host_os" in
 534 linux* )
 535     HAVE_COMPAT_SYMLINKS=yes ;;
 536 * )
 537     HAVE_COMPAT_SYMLINKS=no ;;
 538 esac
 539
 540 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 541
 542 dnl
 543 dnl library names
 544 dnl
 545 dnl Unfortunately we need to do a few things that libtool can't help us with,
 546 dnl so we need some knowledge of shared library filenames:
 547 dnl
 548 dnl LIB_EXT is the extension used when creating symlinks for alternate
 549 dnl filenames for a shared library which will be dynamically loaded
 550 dnl
 551 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 552 dnl the file for a shared library we wish to link with
 553 dnl
 554 case "$host_os" in
 555 darwin* )
 556     LIB_EXT='dylib'
 557     IMP_LIB_EXT=$LIB_EXT
 558     ;;
 559 cygwin* )
 560     LIB_EXT='dll'
 561     IMP_LIB_EXT='dll.a'
 562     ;;
 563 aix* )
 564     LIB_EXT='a'
 565     IMP_LIB_EXT=$LIB_EXT
 566     ;;
 567 * )
 568     LIB_EXT='so'
 569     IMP_LIB_EXT=$LIB_EXT
 570     ;;
 571 esac
 572
 573 AC_SUBST([LIB_EXT])
 574
 575 AC_ARG_WITH([gl-lib-name],
 576   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 577     [specify GL library name @<:@default=GL@:>@])],
 578   [GL_LIB=$withval],
 579   [GL_LIB=GL])
 580 AC_ARG_WITH([osmesa-lib-name],
 581   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 582     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 583   [OSMESA_LIB=$withval],
 584   [OSMESA_LIB=OSMesa])
 585 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 586 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 587
 588 dnl
 589 dnl Mangled Mesa support
 590 dnl
 591 AC_ARG_ENABLE([mangling],
 592   [AS_HELP_STRING([--enable-mangling],
 593     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 594   [enable_mangling="${enableval}"],
 595   [enable_mangling=no]
 596 )
 597 if test "x${enable_mangling}" = "xyes" ; then
 598   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 599   GL_LIB="Mangled${GL_LIB}"
 600   OSMESA_LIB="Mangled${OSMESA_LIB}"
 601 fi
 602 AC_SUBST([GL_LIB])
 603 AC_SUBST([OSMESA_LIB])
 604
 605 dnl
 606 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 607 dnl
 608 AC_ARG_ENABLE([texture-float],
 609     [AS_HELP_STRING([--enable-texture-float],
 610         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 611     [enable_texture_float="$enableval"],
 612     [enable_texture_float=no]
 613 )
 614 if test "x$enable_texture_float" = xyes; then
 615     AC_MSG_WARN([Floating-point textures enabled.])
 616     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 617     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 618 fi
 619
 620 dnl
 621 dnl Arch/platform-specific settings
 622 dnl
 623 AC_ARG_ENABLE([asm],
 624     [AS_HELP_STRING([--disable-asm],
 625         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 626     [enable_asm="$enableval"],
 627     [enable_asm=yes]
 628 )
 629 asm_arch=""
 630 AC_MSG_CHECKING([whether to enable assembly])
 631 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 632 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 633 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 634     case "$host_cpu" in
 635     i?86 | x86_64 | amd64)
 636         enable_asm=no
 637         AC_MSG_RESULT([no, cross compiling])
 638         ;;
 639     esac
 640 fi
 641 # check for supported arches
 642 if test "x$enable_asm" = xyes; then
 643     case "$host_cpu" in
 644     i?86)
 645         case "$host_os" in
 646         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 647             asm_arch=x86
 648             ;;
 649         esac
 650         ;;
 651     x86_64|amd64)
 652         case "$host_os" in
 653         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 654             asm_arch=x86_64
 655             ;;
 656         esac
 657         ;;
 658     sparc*)
 659         case "$host_os" in
 660         linux*)
 661             asm_arch=sparc
 662             ;;
 663         esac
 664         ;;
 665     esac
 666
 667     case "$asm_arch" in
 668     x86)
 669         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 670         AC_MSG_RESULT([yes, x86])
 671         ;;
 672     x86_64|amd64)
 673         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 674         AC_MSG_RESULT([yes, x86_64])
 675         ;;
 676     sparc)
 677         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 678         AC_MSG_RESULT([yes, sparc])
 679         ;;
 680     *)
 681         AC_MSG_RESULT([no, platform not supported])
 682         ;;
 683     esac
 684 fi
 685
 686 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 687 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 688 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 689 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 690
 691 dnl Check to see if dlopen is in default libraries (like Solaris, which
 692 dnl has it in libc), or if libdl is needed to get it.
 693 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 694     [AC_CHECK_LIB([dl], [dlopen],
 695        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 696 AC_SUBST([DLOPEN_LIBS])
 697
 698 dnl Check if that library also has dladdr
 699 save_LIBS="$LIBS"
 700 LIBS="$LIBS $DLOPEN_LIBS"
 701 AC_CHECK_FUNCS([dladdr])
 702 LIBS="$save_LIBS"
 703
 704 case "$host_os" in
 705 darwin*)
 706     ;;
 707 *)
 708     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 709                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 710                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 711     AC_SUBST([CLOCK_LIB])
 712     ;;
 713 esac
 714
 715 dnl See if posix_memalign is available
 716 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 717
 718 dnl Check for pthreads
 719 AX_PTHREAD
 720 if test "x$ax_pthread_ok" = xno; then
 721     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 722 fi
 723 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 724 dnl to -pthread, which causes problems if we need -lpthread to appear in
 725 dnl pkgconfig files.
 726 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 727
 728 dnl SELinux awareness.
 729 AC_ARG_ENABLE([selinux],
 730     [AS_HELP_STRING([--enable-selinux],
 731         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 732     [MESA_SELINUX="$enableval"],
 733     [MESA_SELINUX=no])
 734 if test "x$enable_selinux" = "xyes"; then
 735     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 736         [AC_CHECK_HEADER([selinux/selinux.h],[],
 737                          [AC_MSG_ERROR([SELinux headers not found])])
 738          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 739                       [AC_MSG_ERROR([SELinux library not found])])
 740          SELINUX_LIBS="-lselinux"])
 741     DEFINES="$DEFINES -DMESA_SELINUX"
 742 fi
 743 AC_SUBST([SELINUX_CFLAGS])
 744 AC_SUBST([SELINUX_LIBS])
 745
 746 dnl Options for APIs
 747 AC_ARG_ENABLE([opengl],
 748     [AS_HELP_STRING([--disable-opengl],
 749         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 750     [enable_opengl="$enableval"],
 751     [enable_opengl=yes])
 752 AC_ARG_ENABLE([gles1],
 753     [AS_HELP_STRING([--disable-gles1],
 754         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 755     [enable_gles1="$enableval"],
 756     [enable_gles1=yes])
 757 AC_ARG_ENABLE([gles2],
 758     [AS_HELP_STRING([--disable-gles2],
 759         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 760     [enable_gles2="$enableval"],
 761     [enable_gles2=yes])
 762
 763 AC_ARG_ENABLE([dri],
 764     [AS_HELP_STRING([--enable-dri],
 765         [enable DRI modules @<:@default=enabled@:>@])],
 766     [enable_dri="$enableval"],
 767     [enable_dri=yes])
 768
 769 case "$host_os" in
 770 linux*)
 771     dri3_default=yes
 772     ;;
 773 *)
 774     dri3_default=no
 775     ;;
 776 esac
 777
 778 if test "x$enable_dri" = xno; then
 779     dri3_default=no
 780 fi
 781
 782 AC_ARG_ENABLE([dri3],
 783     [AS_HELP_STRING([--enable-dri3],
 784         [enable DRI3 @<:@default=auto@:>@])],
 785     [enable_dri3="$enableval"],
 786     [enable_dri3="$dri3_default"])
 787 AC_ARG_ENABLE([glx],
 788     [AS_HELP_STRING([--enable-glx],
 789         [enable GLX library @<:@default=enabled@:>@])],
 790     [enable_glx="$enableval"],
 791     [enable_glx=yes])
 792 AC_ARG_ENABLE([osmesa],
 793     [AS_HELP_STRING([--enable-osmesa],
 794         [enable OSMesa library @<:@default=disabled@:>@])],
 795     [enable_osmesa="$enableval"],
 796     [enable_osmesa=no])
 797 AC_ARG_ENABLE([gallium-osmesa],
 798     [AS_HELP_STRING([--enable-gallium-osmesa],
 799         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 800     [enable_gallium_osmesa="$enableval"],
 801     [enable_gallium_osmesa=no])
 802 AC_ARG_ENABLE([egl],
 803     [AS_HELP_STRING([--disable-egl],
 804         [disable EGL library @<:@default=enabled@:>@])],
 805     [enable_egl="$enableval"],
 806     [enable_egl=yes])
 807
 808 AC_ARG_ENABLE([xa],
 809     [AS_HELP_STRING([--enable-xa],
 810         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 811     [enable_xa="$enableval"],
 812     [enable_xa=no])
 813 AC_ARG_ENABLE([gbm],
 814    [AS_HELP_STRING([--enable-gbm],
 815          [enable gbm library @<:@default=auto@:>@])],
 816    [enable_gbm="$enableval"],
 817    [enable_gbm=auto])
 818 AC_ARG_ENABLE([nine],
 819     [AS_HELP_STRING([--enable-nine],
 820         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 821     [enable_nine="$enableval"],
 822     [enable_nine=no])
 823
 824 AC_ARG_ENABLE([xvmc],
 825    [AS_HELP_STRING([--enable-xvmc],
 826          [enable xvmc library @<:@default=auto@:>@])],
 827    [enable_xvmc="$enableval"],
 828    [enable_xvmc=auto])
 829 AC_ARG_ENABLE([vdpau],
 830    [AS_HELP_STRING([--enable-vdpau],
 831          [enable vdpau library @<:@default=auto@:>@])],
 832    [enable_vdpau="$enableval"],
 833    [enable_vdpau=auto])
 834 AC_ARG_ENABLE([omx],
 835    [AS_HELP_STRING([--enable-omx],
 836          [enable OpenMAX library @<:@default=disabled@:>@])],
 837    [enable_omx="$enableval"],
 838    [enable_omx=no])
 839 AC_ARG_ENABLE([va],
 840    [AS_HELP_STRING([--enable-va],
 841          [enable va library @<:@default=auto@:>@])],
 842    [enable_va="$enableval"],
 843    [enable_va=auto])
 844 AC_ARG_ENABLE([opencl],
 845    [AS_HELP_STRING([--enable-opencl],
 846          [enable OpenCL library @<:@default=disabled@:>@])],
 847    [enable_opencl="$enableval"],
 848    [enable_opencl=no])
 849 AC_ARG_ENABLE([opencl_icd],
 850    [AS_HELP_STRING([--enable-opencl-icd],
 851           [Build an OpenCL ICD library to be loaded by an ICD implementation
 852            @<:@default=disabled@:>@])],
 853     [enable_opencl_icd="$enableval"],
 854     [enable_opencl_icd=no])
 855 AC_ARG_ENABLE([xlib-glx],
 856     [AS_HELP_STRING([--enable-xlib-glx],
 857         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 858     [enable_xlib_glx="$enableval"],
 859     [enable_xlib_glx=no])
 860
 861 AC_ARG_ENABLE([r600-llvm-compiler],
 862     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 863         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 864     [enable_r600_llvm="$enableval"],
 865     [enable_r600_llvm=no])
 866
 867 AC_ARG_ENABLE([gallium-tests],
 868     [AS_HELP_STRING([--enable-gallium-tests],
 869         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 870     [enable_gallium_tests="$enableval"],
 871     [enable_gallium_tests=no])
 872
 873 # Option for Gallium drivers
 874
 875 # Keep this in sync with the --with-gallium-drivers help string default value
 876 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 877
 878 AC_ARG_WITH([gallium-drivers],
 879     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 880         [comma delimited Gallium drivers list, e.g.
 881         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 882         @<:@default=r300,r600,svga,swrast@:>@])],
 883     [with_gallium_drivers="$withval"],
 884     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 885
 886 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 887 # here so that the script doesn't choke on an unknown driver name later.
 888 case "$with_gallium_drivers" in
 889     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 890     no) with_gallium_drivers='' ;;
 891 esac
 892
 893 if test "x$enable_opengl" = xno -a \
 894         "x$enable_gles1" = xno -a \
 895         "x$enable_gles2" = xno -a \
 896         "x$enable_nine" = xno -a \
 897         "x$enable_xa" = xno -a \
 898         "x$enable_xvmc" = xno -a \
 899         "x$enable_vdpau" = xno -a \
 900         "x$enable_omx" = xno -a \
 901         "x$enable_va" = xno -a \
 902         "x$enable_opencl" = xno; then
 903     AC_MSG_ERROR([at least one API should be enabled])
 904 fi
 905
 906 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 907 if test "x$enable_opengl" = xno -a \
 908         "x$enable_gles1" = xyes; then
 909     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 910 fi
 911
 912 if test "x$enable_opengl" = xno -a \
 913         "x$enable_gles2" = xyes; then
 914     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 915 fi
 916
 917 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 918 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 919 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 920 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 921                                         "x$enable_gles1" = xyes -o \
 922                                         "x$enable_gles2" = xyes)
 923
 924 if test "x$enable_glx" = xno; then
 925     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 926     enable_xlib_glx=no
 927 fi
 928
 929 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 930     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 931 fi
 932
 933 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 934     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 935 fi
 936
 937 # Disable GLX if OpenGL is not enabled
 938 if test "x$enable_glx$enable_opengl" = xyesno; then
 939     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 940     enable_glx=no
 941 fi
 942
 943 # Disable GLX if DRI and Xlib-GLX are not enabled
 944 if test "x$enable_glx" = xyes -a \
 945         "x$enable_dri" = xno -a \
 946         "x$enable_xlib_glx" = xno; then
 947     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 948     enable_glx=no
 949 fi
 950
 951 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 952                                   "x$enable_dri" = xyes)
 953
 954 # Check for libdrm
 955 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 956                   [have_libdrm=yes], [have_libdrm=no])
 957 if test "x$have_libdrm" = xyes; then
 958         DEFINES="$DEFINES -DHAVE_LIBDRM"
 959 fi
 960
 961 # Select which platform-dependent DRI code gets built
 962 case "$host_os" in
 963 darwin*)
 964     dri_platform='apple' ;;
 965 gnu*|cygwin*)
 966     dri_platform='none' ;;
 967 *)
 968     dri_platform='drm' ;;
 969 esac
 970
 971 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
 972     have_drisw_kms='yes'
 973 fi
 974
 975 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 976 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 977 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
 978 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 979 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 980 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 981
 982 AC_ARG_ENABLE([shared-glapi],
 983     [AS_HELP_STRING([--enable-shared-glapi],
 984         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 985     [enable_shared_glapi="$enableval"],
 986     [enable_shared_glapi=yes])
 987
 988 case "x$enable_opengl$enable_gles1$enable_gles2" in
 989 x*yes*yes*)
 990     if test "x$enable_shared_glapi" = xno; then
 991         AC_MSG_ERROR([shared GLAPI required when building two or more of
 992                       the following APIs - opengl, gles1 gles2])
 993     fi
 994     ;;
 995 esac
 996
 997 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 998
 999 # Build the pipe-drivers as separate libraries/modules.
1000 # Do not touch this unless you know what you are doing.
1001 # XXX: Expose via configure option ?
1002 enable_shared_pipe_drivers=no
1003
1004 dnl
1005 dnl Driver specific build directories
1006 dnl
1007
1008 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
1009     NEED_WINSYS_XLIB="yes"
1010 fi
1011
1012 if test "x$enable_gallium_osmesa" = xyes; then
1013     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1014         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1015     fi
1016     if test "x$enable_osmesa" = xyes; then
1017         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1018     fi
1019 fi
1020
1021 AC_SUBST([MESA_LLVM])
1022
1023 # SHA1 hashing
1024 AC_ARG_WITH([sha1],
1025         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1026         [choose SHA1 implementation])])
1027 case "x$with_sha1" in
1028 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1029   ;;
1030 *)
1031         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1032 esac
1033
1034 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1035 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1036         with_sha1=libc
1037 fi
1038 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1039         AC_MSG_ERROR([sha1 in libc requested but not found])
1040 fi
1041 if test "x$with_sha1" = xlibc; then
1042         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1043                 [Use libc SHA1 functions])
1044         SHA1_LIBS=""
1045 fi
1046 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1047 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1048         with_sha1=CommonCrypto
1049 fi
1050 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1051         AC_MSG_ERROR([CommonCrypto requested but not found])
1052 fi
1053 if test "x$with_sha1" = xCommonCrypto; then
1054         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1055                 [Use CommonCrypto SHA1 functions])
1056         SHA1_LIBS=""
1057 fi
1058 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1059 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1060 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1061         with_sha1=CryptoAPI
1062 fi
1063 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1064         AC_MSG_ERROR([CryptoAPI requested but not found])
1065 fi
1066 if test "x$with_sha1" = xCryptoAPI; then
1067         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1068                 [Use CryptoAPI SHA1 functions])
1069         SHA1_LIBS=""
1070 fi
1071 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1072 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1073         with_sha1=libmd
1074 fi
1075 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1076         AC_MSG_ERROR([libmd requested but not found])
1077 fi
1078 if test "x$with_sha1" = xlibmd; then
1079         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1080                   [Use libmd SHA1 functions])
1081         SHA1_LIBS=-lmd
1082 fi
1083 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1084 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1085    with_sha1=libsha1
1086 fi
1087 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1088         AC_MSG_ERROR([libsha1 requested but not found])
1089 fi
1090 if test "x$with_sha1" = xlibsha1; then
1091         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1092                   [Use libsha1 for SHA1])
1093         SHA1_LIBS=-lsha1
1094 fi
1095 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1096 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1097         with_sha1=libnettle
1098 fi
1099 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1100         AC_MSG_ERROR([libnettle requested but not found])
1101 fi
1102 if test "x$with_sha1" = xlibnettle; then
1103         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1104                   [Use libnettle SHA1 functions])
1105         SHA1_LIBS=-lnettle
1106 fi
1107 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1108 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1109         with_sha1=libgcrypt
1110 fi
1111 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1112         AC_MSG_ERROR([libgcrypt requested but not found])
1113 fi
1114 if test "x$with_sha1" = xlibgcrypt; then
1115         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1116                   [Use libgcrypt SHA1 functions])
1117         SHA1_LIBS=-lgcrypt
1118 fi
1119 # We don't need all of the OpenSSL libraries, just libcrypto
1120 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1121 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1122                   [HAVE_OPENSSL_PKC=no])
1123 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1124         if test "x$with_sha1" = x; then
1125                 with_sha1=libcrypto
1126         fi
1127 else
1128         if test "x$with_sha1" = xlibcrypto; then
1129                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1130         fi
1131 fi
1132 if test "x$with_sha1" = xlibcrypto; then
1133         if test "x$HAVE_LIBCRYPTO" = xyes; then
1134                 SHA1_LIBS=-lcrypto
1135         else
1136                 SHA1_LIBS="$OPENSSL_LIBS"
1137                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1138         fi
1139 fi
1140 AC_MSG_CHECKING([for SHA1 implementation])
1141 AC_MSG_RESULT([$with_sha1])
1142 AC_SUBST(SHA1_LIBS)
1143 AC_SUBST(SHA1_CFLAGS)
1144
1145 # Enable a define for SHA1
1146 if test "x$with_sha1" != "x"; then
1147         DEFINES="$DEFINES -DHAVE_SHA1"
1148 fi
1149
1150 # Allow user to configure out the shader-cache feature
1151 AC_ARG_ENABLE([shader-cache],
1152     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1153     [enable_shader_cache="$enableval"],
1154     [if test "x$with_sha1" != "x"; then
1155         enable_shader_cache=yes
1156      else
1157         enable_shader_cache=no
1158      fi])
1159 if test "x$with_sha1" = "x"; then
1160     if test "x$enable_shader_cache" = "xyes"; then
1161         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1162     fi
1163 fi
1164 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1165
1166 case "$host_os" in
1167 linux*)
1168     need_pci_id=yes ;;
1169 *)
1170     need_pci_id=no ;;
1171 esac
1172
1173 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1174                   have_libudev=yes, have_libudev=no)
1175
1176 AC_ARG_ENABLE([sysfs],
1177     [AS_HELP_STRING([--enable-sysfs],
1178         [enable /sys PCI identification @<:@default=disabled@:>@])],
1179     [have_sysfs="$enableval"],
1180     [have_sysfs=no]
1181 )
1182
1183 if test "x$enable_dri" = xyes; then
1184     if test "$enable_static" = yes; then
1185         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1186     fi
1187
1188     # not a hard requirement as swrast does not depend on it
1189     if test "x$have_libdrm" = xyes; then
1190         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1191     fi
1192 fi
1193
1194 AC_ARG_ENABLE([driglx-direct],
1195     [AS_HELP_STRING([--disable-driglx-direct],
1196         [disable direct rendering in GLX and EGL for DRI \
1197             @<:@default=auto@:>@])],
1198     [driglx_direct="$enableval"],
1199     [driglx_direct="yes"])
1200
1201 dnl
1202 dnl libGL configuration per driver
1203 dnl
1204 case "x$enable_glx$enable_xlib_glx" in
1205 xyesyes)
1206     # Xlib-based GLX
1207     dri_modules="x11 xext xcb"
1208     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1209     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1210     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1211     GL_LIB_DEPS="$XLIBGL_LIBS"
1212     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1213     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1214     ;;
1215 xyesno)
1216     # DRI-based GLX
1217     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1218
1219     # find the DRI deps for libGL
1220     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1221
1222     if test x"$driglx_direct" = xyes; then
1223         if test x"$dri_platform" = xdrm ; then
1224             DEFINES="$DEFINES -DGLX_USE_DRM"
1225             if test "x$have_libdrm" != xyes; then
1226                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1227             fi
1228
1229             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1230             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1231             if test x"$enable_dri3" = xyes; then
1232                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1233                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1234             fi
1235
1236             if test x"$enable_dri" = xyes; then
1237                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1238             fi
1239
1240             if test x"$enable_dri3" = xyes; then
1241                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1242                dri3_modules="xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1243                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1244             fi
1245         fi
1246         if test x"$dri_platform" = xapple ; then
1247             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1248         fi
1249     fi
1250
1251     # add xf86vidmode if available
1252     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1253     if test "$HAVE_XF86VIDMODE" = yes ; then
1254         dri_modules="$dri_modules xxf86vm"
1255     fi
1256
1257     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1258     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1259     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1260     GL_LIB_DEPS="$DRIGL_LIBS"
1261
1262     # need DRM libs, $PTHREAD_LIBS, etc.
1263     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1264     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1265     ;;
1266 esac
1267
1268 have_pci_id=no
1269 if test "$have_libudev" = yes; then
1270     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1271     have_pci_id=yes
1272 fi
1273
1274 if test "$have_sysfs" = yes; then
1275     DEFINES="$DEFINES -DHAVE_SYSFS"
1276     have_pci_id=yes
1277 fi
1278
1279 # This is outside the case (above) so that it is invoked even for non-GLX
1280 # builds.
1281 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1282
1283 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1284 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1285 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1286 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1287
1288 AC_SUBST([X11_INCLUDES])
1289 AC_SUBST([GL_LIB_DEPS])
1290 AC_SUBST([GL_PC_REQ_PRIV])
1291 AC_SUBST([GL_PC_LIB_PRIV])
1292 AC_SUBST([GL_PC_CFLAGS])
1293 AC_SUBST([DRI_PC_REQ_PRIV])
1294 AC_SUBST([GLESv1_CM_LIB_DEPS])
1295 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1296 AC_SUBST([GLESv2_LIB_DEPS])
1297 AC_SUBST([GLESv2_PC_LIB_PRIV])
1298
1299 AC_SUBST([HAVE_XF86VIDMODE])
1300
1301 dnl
1302 dnl More GLX setup
1303 dnl
1304 case "x$enable_glx$enable_xlib_glx" in
1305 xyesyes)
1306     DEFINES="$DEFINES -DUSE_XSHM"
1307     ;;
1308 xyesno)
1309     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1310     if test "x$driglx_direct" = xyes; then
1311         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1312     fi
1313     ;;
1314 esac
1315
1316 dnl
1317 dnl TLS detection
1318 dnl
1319
1320 AC_ARG_ENABLE([glx-tls],
1321     [AS_HELP_STRING([--enable-glx-tls],
1322         [enable TLS support in GLX @<:@default=disabled@:>@])],
1323     [GLX_USE_TLS="$enableval"],
1324     [GLX_USE_TLS=no])
1325 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1326
1327 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1328       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1329
1330 dnl Read-only text section on x86 hardened platforms
1331 AC_ARG_ENABLE([glx-read-only-text],
1332     [AS_HELP_STRING([--enable-glx-read-only-text],
1333         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1334     [enable_glx_read_only_text="$enableval"],
1335     [enable_glx_read_only_text=no])
1336 if test "x$enable_glx_read_only_text" = xyes; then
1337     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1338 fi
1339
1340 dnl
1341 dnl More DRI setup
1342 dnl
1343 dnl Directory for DRI drivers
1344 AC_ARG_WITH([dri-driverdir],
1345     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1346         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1347     [DRI_DRIVER_INSTALL_DIR="$withval"],
1348     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1349 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1350 dnl Extra search path for DRI drivers
1351 AC_ARG_WITH([dri-searchpath],
1352     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1353         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1354     [DRI_DRIVER_SEARCH_DIR="$withval"],
1355     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1356 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1357 dnl Which drivers to build - default is chosen by platform
1358 AC_ARG_WITH([dri-drivers],
1359     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1360         [comma delimited classic DRI drivers list, e.g.
1361         "swrast,i965,radeon" @<:@default=auto@:>@])],
1362     [with_dri_drivers="$withval"],
1363     [with_dri_drivers=auto])
1364
1365 if test "x$with_dri_drivers" = xauto; then
1366     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1367         with_dri_drivers="yes"
1368     else
1369         with_dri_drivers="no"
1370     fi
1371 fi
1372 if test "x$with_dri_drivers" = xno; then
1373     with_dri_drivers=''
1374 fi
1375
1376 dnl If $with_dri_drivers is yes, drivers will be added through
1377 dnl platform checks. Set DEFINES and LIB_DEPS
1378 if test "x$enable_dri" = xyes; then
1379     # Platform specific settings and drivers to build
1380     case "$host_os" in
1381     linux*)
1382         DEFINES="$DEFINES -DHAVE_ALIAS"
1383         if test "x$enable_dri3" = xyes; then
1384             DEFINES="$DEFINES -DHAVE_DRI3"
1385         fi
1386
1387         if test "x$have_pci_id" != xyes; then
1388             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1389         fi
1390
1391         case "$host_cpu" in
1392         powerpc* | sparc*)
1393             # Build only the drivers for cards that exist on PowerPC/sparc
1394             if test "x$with_dri_drivers" = "xyes"; then
1395                 with_dri_drivers="r200 radeon swrast"
1396             fi
1397             ;;
1398         esac
1399         ;;
1400     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1401         DEFINES="$DEFINES -DHAVE_ALIAS"
1402         ;;
1403     gnu*)
1404         DEFINES="$DEFINES -DHAVE_ALIAS"
1405         ;;
1406     cygwin*)
1407         if test "x$with_dri_drivers" = "xyes"; then
1408             with_dri_drivers="swrast"
1409         fi
1410         ;;
1411     darwin*)
1412         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1413         if test "x$with_dri_drivers" = "xyes"; then
1414             with_dri_drivers="swrast"
1415         fi
1416         ;;
1417     esac
1418
1419     # default drivers
1420     if test "x$with_dri_drivers" = "xyes"; then
1421         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1422     fi
1423
1424     # Check for expat
1425     PKG_CHECK_MODULES([EXPAT], [expat], [],
1426         # expat version 2.0 and earlier do not provide expat.pc
1427         [AC_CHECK_HEADER([expat.h],[],
1428                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1429          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1430                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1431          EXPAT_LIBS="-lexpat"])
1432
1433     # put all the necessary libs together
1434     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1435 fi
1436
1437 AC_SUBST([DRI_LIB_DEPS])
1438
1439 DRI_DIRS=''
1440 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1441 if test -n "$with_dri_drivers"; then
1442     if test "x$enable_opengl" != xyes; then
1443         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1444     fi
1445
1446     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1447     for driver in $dri_drivers; do
1448         DRI_DIRS="$DRI_DIRS $driver"
1449         case "x$driver" in
1450         xi915)
1451             HAVE_I915_DRI=yes;
1452             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1453             ;;
1454         xi965)
1455             HAVE_I965_DRI=yes;
1456             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1457             ;;
1458         xnouveau)
1459             HAVE_NOUVEAU_DRI=yes;
1460             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1461             ;;
1462         xradeon)
1463             HAVE_RADEON_DRI=yes;
1464             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1465             ;;
1466         xr200)
1467             HAVE_R200_DRI=yes;
1468             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1469             ;;
1470         xswrast)
1471             HAVE_SWRAST_DRI=yes;
1472             ;;
1473         *)
1474             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1475             ;;
1476         esac
1477     done
1478     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1479 fi
1480
1481 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1482 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1483                                   "x$enable_osmesa" = xyes -o \
1484                                   -n "$DRI_DIRS")
1485
1486 dnl
1487 dnl OSMesa configuration
1488 dnl
1489
1490 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1491 AC_ARG_WITH([osmesa-bits],
1492     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1493         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1494     [osmesa_bits="$withval"],
1495     [osmesa_bits=8])
1496 if test "x$osmesa_bits" != x8; then
1497     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1498         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1499         osmesa_bits=8
1500     fi
1501 fi
1502 case "x$osmesa_bits" in
1503 x8)
1504     OSMESA_LIB="${OSMESA_LIB}"
1505     ;;
1506 x16|x32)
1507     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1508     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1509     ;;
1510 *)
1511     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1512     ;;
1513 esac
1514
1515 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1516     # only link libraries with osmesa if shared
1517     if test "$enable_static" = no; then
1518         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1519     else
1520         OSMESA_LIB_DEPS=""
1521     fi
1522     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1523 fi
1524
1525 AC_SUBST([OSMESA_LIB_DEPS])
1526 AC_SUBST([OSMESA_PC_REQ])
1527 AC_SUBST([OSMESA_PC_LIB_PRIV])
1528
1529 dnl
1530 dnl gbm configuration
1531 dnl
1532 if test "x$enable_gbm" = xauto; then
1533     case "$with_egl_platforms" in
1534         *drm*)
1535             enable_gbm=yes ;;
1536          *)
1537             enable_gbm=no ;;
1538     esac
1539 fi
1540 if test "x$enable_gbm" = xyes; then
1541     if test "x$need_pci_id$have_pci_id" = xyesno; then
1542         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1543     fi
1544
1545     if test "x$enable_dri" = xyes; then
1546         if test "x$enable_shared_glapi" = xno; then
1547             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1548         fi
1549     else
1550         # Strictly speaking libgbm does not require --enable-dri, although
1551         # both of its backends do. Thus one can build libgbm without any
1552         # backends if --disable-dri is set.
1553         # To avoid unnecessary complexity of checking if at least one backend
1554         # is available when building, just mandate --enable-dri.
1555         AC_MSG_ERROR([gbm requires --enable-dri])
1556     fi
1557 fi
1558 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1559 if test "x$need_pci_id$have_libudev" = xyesyes; then
1560     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1561 else
1562     GBM_PC_REQ_PRIV=""
1563 fi
1564 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1565 AC_SUBST([GBM_PC_REQ_PRIV])
1566 AC_SUBST([GBM_PC_LIB_PRIV])
1567
1568 dnl
1569 dnl EGL configuration
1570 dnl
1571 EGL_CLIENT_APIS=""
1572
1573 if test "x$enable_egl" = xyes; then
1574     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1575
1576     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1577
1578     if test "$enable_static" != yes; then
1579         if test "x$enable_dri" = xyes; then
1580             HAVE_EGL_DRIVER_DRI2=1
1581             if test "x$enable_shared_glapi" = xno; then
1582                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1583             fi
1584             if test "x$enable_dri3" = xyes; then
1585                 HAVE_EGL_DRIVER_DRI3=1
1586                 if test "x$enable_shared_glapi" = xno; then
1587                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1588                 fi
1589             fi
1590         else
1591             # Avoid building an "empty" libEGL. Drop/update this
1592             # when other backends (haiku?) come along.
1593             AC_MSG_ERROR([egl requires --enable-dri])
1594         fi
1595
1596     fi
1597 fi
1598 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1599 AC_SUBST([EGL_LIB_DEPS])
1600
1601 gallium_st="mesa"
1602
1603 dnl
1604 dnl XA configuration
1605 dnl
1606 if test "x$enable_xa" = xyes; then
1607     if test "x$with_gallium_drivers" = xswrast; then
1608        AC_MSG_ERROR([
1609           Building xa requires at least one non swrast gallium driver.
1610           If you are looking to use libxatracker.so with the VMware driver,
1611           make sure to include svga in the gallium drivers list, apart from
1612           enabling XA.
1613           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1614     fi
1615     gallium_st="$gallium_st xa"
1616 fi
1617 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1618
1619 dnl
1620 dnl Gallium G3DVL configuration
1621 dnl
1622 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1623     if test "x$enable_xvmc" = xauto; then
1624         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1625     fi
1626
1627     if test "x$enable_vdpau" = xauto; then
1628         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1629     fi
1630
1631     if test "x$enable_omx" = xauto; then
1632         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1633     fi
1634
1635     if test "x$enable_va" = xauto; then
1636         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1637     fi
1638 fi
1639
1640 if test "x$enable_dri" = xyes -o \
1641         "x$enable_xvmc" = xyes -o \
1642         "x$enable_vdpau" = xyes -o \
1643         "x$enable_omx" = xyes -o \
1644         "x$enable_va" = xyes; then
1645     need_gallium_vl=yes
1646 fi
1647 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1648
1649 if test "x$enable_xvmc" = xyes -o \
1650         "x$enable_vdpau" = xyes -o \
1651         "x$enable_omx" = xyes -o \
1652         "x$enable_va" = xyes; then
1653     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1654     need_gallium_vl_winsys=yes
1655 fi
1656 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1657
1658 if test "x$enable_xvmc" = xyes; then
1659     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1660     gallium_st="$gallium_st xvmc"
1661 fi
1662 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1663
1664 if test "x$enable_vdpau" = xyes; then
1665     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1666     gallium_st="$gallium_st vdpau"
1667 fi
1668 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1669
1670 if test "x$enable_omx" = xyes; then
1671     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1672     gallium_st="$gallium_st omx"
1673 fi
1674 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1675
1676 if test "x$enable_va" = xyes; then
1677     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1678     gallium_st="$gallium_st va"
1679 fi
1680 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1681
1682 dnl
1683 dnl Nine Direct3D9 configuration
1684 dnl
1685 if test "x$enable_nine" = xyes; then
1686     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1687         AC_MSG_ERROR([nine requires the gallium swrast driver])
1688     fi
1689     if test "x$with_gallium_drivers" = xswrast; then
1690         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1691     fi
1692     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1693         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1694     fi
1695
1696     if test "x$enable_dri3" = xno; then
1697         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1698     fi
1699
1700     gallium_st="$gallium_st nine"
1701 fi
1702 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1703
1704 dnl
1705 dnl OpenCL configuration
1706 dnl
1707
1708 AC_ARG_WITH([clang-libdir],
1709    [AS_HELP_STRING([--with-clang-libdir],
1710          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1711    [CLANG_LIBDIR="$withval"],
1712    [CLANG_LIBDIR=''])
1713
1714 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1715 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1716
1717 if test "x$enable_opencl" = xyes; then
1718     if test -z "$with_gallium_drivers"; then
1719         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1720     fi
1721
1722     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1723         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1724     fi
1725
1726     if test "x$have_libclc" = xno; then
1727         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1728                     Make sure the directory containing libclc.pc is specified in your
1729                     PKG_CONFIG_PATH environment variable.
1730                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1731     else
1732         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1733         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1734         AC_SUBST([LIBCLC_INCLUDEDIR])
1735         AC_SUBST([LIBCLC_LIBEXECDIR])
1736     fi
1737
1738     gallium_st="$gallium_st clover"
1739
1740     if test "x$enable_opencl_icd" = xyes; then
1741         OPENCL_LIBNAME="MesaOpenCL"
1742     else
1743         OPENCL_LIBNAME="OpenCL"
1744     fi
1745
1746     if test "x$have_libelf" != xyes; then
1747        AC_MSG_ERROR([Clover requires libelf])
1748     fi
1749 fi
1750 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1751 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1752 AC_SUBST([OPENCL_LIBNAME])
1753
1754 dnl
1755 dnl Gallium configuration
1756 dnl
1757 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1758
1759 AC_SUBST([LLVM_BINDIR])
1760 AC_SUBST([LLVM_CFLAGS])
1761 AC_SUBST([LLVM_CPPFLAGS])
1762 AC_SUBST([LLVM_CXXFLAGS])
1763 AC_SUBST([LLVM_LIBDIR])
1764 AC_SUBST([LLVM_LIBS])
1765 AC_SUBST([LLVM_LDFLAGS])
1766 AC_SUBST([LLVM_INCLUDEDIR])
1767 AC_SUBST([LLVM_VERSION])
1768 AC_SUBST([CLANG_RESOURCE_DIR])
1769
1770 case "x$enable_opengl$enable_gles1$enable_gles2" in
1771 x*yes*)
1772     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1773     ;;
1774 esac
1775
1776 AC_SUBST([VG_LIB_DEPS])
1777 AC_SUBST([EGL_CLIENT_APIS])
1778
1779 dnl
1780 dnl EGL Platforms configuration
1781 dnl
1782 AC_ARG_WITH([egl-platforms],
1783     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1784         [comma delimited native platforms libEGL supports, e.g.
1785         "x11,drm" @<:@default=auto@:>@])],
1786     [with_egl_platforms="$withval"],
1787     [if test "x$enable_egl" = xyes; then
1788         with_egl_platforms="x11"
1789     else
1790         with_egl_platforms=""
1791     fi])
1792
1793 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1794     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1795 fi
1796
1797 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1798         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1799         WAYLAND_SCANNER='')
1800 if test "x$WAYLAND_SCANNER" = x; then
1801     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1802 fi
1803
1804 # Do per-EGL platform setups and checks
1805 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1806 for plat in $egl_platforms; do
1807         case "$plat" in
1808         wayland)
1809                 test "x$have_libdrm" != xyes &&
1810                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1811
1812                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1813
1814                 if test "x$WAYLAND_SCANNER" = x; then
1815                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1816                 fi
1817                 ;;
1818
1819         x11)
1820                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1821                 ;;
1822
1823         drm)
1824                 test "x$enable_gbm" = "xno" &&
1825                         AC_MSG_ERROR([EGL platform drm needs gbm])
1826                 test "x$have_libdrm" != xyes &&
1827                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1828                 ;;
1829
1830         surfaceless)
1831                 test "x$have_libdrm" != xyes &&
1832                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1833                 ;;
1834
1835         *)
1836                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1837                 ;;
1838         esac
1839
1840         case "$plat$need_pci_id$have_pci_id" in
1841                 waylandyesno|drmyesno)
1842                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1843         esac
1844 done
1845
1846 # libEGL wants to default to the first platform specified in
1847 # ./configure.  parse that here.
1848 if test "x$egl_platforms" != "x"; then
1849     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1850     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1851 else
1852     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1853 fi
1854
1855 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1856 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1857 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1858 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1859 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1860
1861 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1862
1863 AC_SUBST([EGL_NATIVE_PLATFORM])
1864 AC_SUBST([EGL_CFLAGS])
1865
1866 # If we don't have the X11 platform, set this define so we don't try to include
1867 # the X11 headers.
1868 if ! echo "$egl_platforms" | grep -q 'x11'; then
1869     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1870     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1871 fi
1872
1873 dnl
1874 dnl Gallium LLVM
1875 dnl
1876 AC_ARG_ENABLE([gallium-llvm],
1877     [AS_HELP_STRING([--enable-gallium-llvm],
1878         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1879     [enable_gallium_llvm="$enableval"],
1880     [enable_gallium_llvm=auto])
1881
1882 AC_ARG_ENABLE([llvm-shared-libs],
1883     [AS_HELP_STRING([--enable-llvm-shared-libs],
1884         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1885     [enable_llvm_shared_libs="$enableval"],
1886     [enable_llvm_shared_libs=yes])
1887
1888 AC_ARG_WITH([llvm-prefix],
1889     [AS_HELP_STRING([--with-llvm-prefix],
1890         [Prefix for LLVM installations in non-standard locations])],
1891     [llvm_prefix="$withval"],
1892     [llvm_prefix=''])
1893
1894
1895 # Call this inside ` ` to get the return value.
1896 # $1 is the llvm-config command with arguments.
1897 strip_unwanted_llvm_flags() {
1898     # Use \> (marks the end of the word)
1899     echo `$1` | sed \
1900         -e 's/-DNDEBUG\>//g' \
1901         -e 's/-D_GNU_SOURCE\>//g' \
1902         -e 's/-pedantic\>//g' \
1903         -e 's/-Wcovered-switch-default\>//g' \
1904         -e 's/-O.\>//g' \
1905         -e 's/-g\>//g' \
1906         -e 's/-Wall\>//g' \
1907         -e 's/-Wcast-qual\>//g' \
1908         -e 's/-Woverloaded-virtual\>//g' \
1909         -e 's/-fcolor-diagnostics\>//g' \
1910         -e 's/-fdata-sections\>//g' \
1911         -e 's/-ffunction-sections\>//g' \
1912         -e 's/-fno-exceptions\>//g' \
1913         -e 's/-fomit-frame-pointer\>//g' \
1914         -e 's/-fvisibility-inlines-hidden\>//g' \
1915         -e 's/-fPIC\>//g' \
1916         -e 's/-fstack-protector-strong\>//g'
1917 }
1918
1919 llvm_check_version_for() {
1920     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1921         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1922     fi
1923 }
1924
1925
1926
1927 if test -z "$with_gallium_drivers"; then
1928     enable_gallium_llvm=no
1929 fi
1930 if test "x$enable_gallium_llvm" = xauto; then
1931     case "$host_cpu" in
1932     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1933     esac
1934 fi
1935 if test "x$enable_gallium_llvm" = xyes; then
1936     if test -n "$llvm_prefix"; then
1937         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1938     else
1939         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1940     fi
1941
1942     if test "x$LLVM_CONFIG" != xno; then
1943         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1944         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1945         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1946         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1947         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1948         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1949         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1950         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1951
1952         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1953             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1954         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1955             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1956
1957         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1958         if test -z "$LLVM_VERSION_PATCH"; then
1959             LLVM_VERSION_PATCH=0
1960         fi
1961
1962         if test -n "${LLVM_VERSION_MAJOR}"; then
1963             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1964         else
1965             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1966         fi
1967
1968         LLVM_REQUIRED_VERSION_MAJOR="3"
1969         LLVM_REQUIRED_VERSION_MINOR="3"
1970         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1971             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1972         fi
1973
1974         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1975
1976         if test "x$enable_opencl" = xyes; then
1977             llvm_check_version_for "3" "5" "0" "opencl"
1978
1979             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1980             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1981         fi
1982         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1983         MESA_LLVM=1
1984
1985         dnl Check for Clang internal headers
1986         if test "x$enable_opencl" = xyes; then
1987             if test -z "$CLANG_LIBDIR"; then
1988                 CLANG_LIBDIR=${LLVM_LIBDIR}
1989             fi
1990             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1991             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1992                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1993         fi
1994     else
1995         MESA_LLVM=0
1996         LLVM_VERSION_INT=0
1997     fi
1998 else
1999     MESA_LLVM=0
2000     LLVM_VERSION_INT=0
2001
2002     if test "x$enable_opencl" = xyes; then
2003         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2004     fi
2005 fi
2006
2007 dnl Directory for XVMC libs
2008 AC_ARG_WITH([xvmc-libdir],
2009     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2010         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2011     [XVMC_LIB_INSTALL_DIR="$withval"],
2012     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2013 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2014
2015 dnl
2016 dnl Gallium Tests
2017 dnl
2018 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2019
2020 dnl Directory for VDPAU libs
2021 AC_ARG_WITH([vdpau-libdir],
2022     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2023         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2024     [VDPAU_LIB_INSTALL_DIR="$withval"],
2025     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2026 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2027
2028 dnl Directory for OMX libs
2029
2030 AC_ARG_WITH([omx-libdir],
2031     [AS_HELP_STRING([--with-omx-libdir=DIR],
2032         [directory for the OMX libraries])],
2033     [OMX_LIB_INSTALL_DIR="$withval"],
2034     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2035 AC_SUBST([OMX_LIB_INSTALL_DIR])
2036
2037 dnl Directory for VA libs
2038
2039 AC_ARG_WITH([va-libdir],
2040     [AS_HELP_STRING([--with-va-libdir=DIR],
2041         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2042     [VA_LIB_INSTALL_DIR="$withval"],
2043     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2044 AC_SUBST([VA_LIB_INSTALL_DIR])
2045
2046 AC_ARG_WITH([d3d-libdir],
2047     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2048         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2049     [D3D_DRIVER_INSTALL_DIR="$withval"],
2050     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2051 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2052
2053 dnl
2054 dnl Gallium helper functions
2055 dnl
2056 gallium_require_drm() {
2057     if test "x$have_libdrm" != xyes; then
2058        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2059     fi
2060 }
2061
2062 gallium_require_llvm() {
2063     if test "x$MESA_LLVM" = x0; then
2064         case "$host" in *gnux32) return;; esac
2065         case "$host_cpu" in
2066         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2067         esac
2068     fi
2069 }
2070
2071 gallium_require_drm_loader() {
2072     if test "x$need_pci_id$have_pci_id" = xyesno; then
2073         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2074     fi
2075 }
2076
2077 require_egl_drm() {
2078     case "$with_egl_platforms" in
2079         *drm*)
2080             ;;
2081          *)
2082             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2083             ;;
2084     esac
2085     if test "x$enable_gbm" != xyes; then
2086             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2087     fi
2088 }
2089
2090 radeon_llvm_check() {
2091     if test ${LLVM_VERSION_INT} -lt 307; then
2092         amdgpu_llvm_target_name='r600'
2093     else
2094         amdgpu_llvm_target_name='amdgpu'
2095     fi
2096     if test "x$enable_gallium_llvm" != "xyes"; then
2097         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2098     fi
2099     llvm_check_version_for "3" "5" "0" $1
2100     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2101         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2102     fi
2103     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2104     NEED_RADEON_LLVM=yes
2105     if test "x$have_libelf" != xyes; then
2106        AC_MSG_ERROR([$1 requires libelf when using llvm])
2107     fi
2108 }
2109
2110 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2111 if test -n "$with_gallium_drivers"; then
2112     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2113     for driver in $gallium_drivers; do
2114         case "x$driver" in
2115         xsvga)
2116             HAVE_GALLIUM_SVGA=yes
2117             gallium_require_drm "svga"
2118             gallium_require_drm_loader
2119             ;;
2120         xi915)
2121             HAVE_GALLIUM_I915=yes
2122             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2123             gallium_require_drm "Gallium i915"
2124             gallium_require_drm_loader
2125             ;;
2126         xilo)
2127             HAVE_GALLIUM_ILO=yes
2128             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2129             gallium_require_drm "Gallium i965/ilo"
2130             gallium_require_drm_loader
2131             ;;
2132         xr300)
2133             HAVE_GALLIUM_R300=yes
2134             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2135             gallium_require_drm "Gallium R300"
2136             gallium_require_drm_loader
2137             gallium_require_llvm "Gallium R300"
2138             ;;
2139         xr600)
2140             HAVE_GALLIUM_R600=yes
2141             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2142             gallium_require_drm "Gallium R600"
2143             gallium_require_drm_loader
2144             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2145                 radeon_llvm_check "r600g"
2146                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2147             fi
2148             if test "x$enable_r600_llvm" = xyes; then
2149                 USE_R600_LLVM_COMPILER=yes;
2150             fi
2151             if test "x$enable_opencl" = xyes; then
2152                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2153             fi
2154             ;;
2155         xradeonsi)
2156             HAVE_GALLIUM_RADEONSI=yes
2157             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2158             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2159             gallium_require_drm "radeonsi"
2160             gallium_require_drm_loader
2161             radeon_llvm_check "radeonsi"
2162             require_egl_drm "radeonsi"
2163             ;;
2164         xnouveau)
2165             HAVE_GALLIUM_NOUVEAU=yes
2166             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2167             gallium_require_drm "nouveau"
2168             gallium_require_drm_loader
2169             ;;
2170         xfreedreno)
2171             HAVE_GALLIUM_FREEDRENO=yes
2172             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2173             gallium_require_drm "freedreno"
2174             gallium_require_drm_loader
2175             ;;
2176         xswrast)
2177             HAVE_GALLIUM_SOFTPIPE=yes
2178             if test "x$MESA_LLVM" = x1; then
2179                 HAVE_GALLIUM_LLVMPIPE=yes
2180             fi
2181             ;;
2182         xvc4)
2183             HAVE_GALLIUM_VC4=yes
2184             gallium_require_drm "vc4"
2185             gallium_require_drm_loader
2186
2187             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2188                               [USE_VC4_SIMULATOR=yes;
2189                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2190                               [USE_VC4_SIMULATOR=no])
2191             ;;
2192         xvirgl)
2193             HAVE_GALLIUM_VIRGL=yes
2194             gallium_require_drm "virgl"
2195             gallium_require_drm_loader
2196             require_egl_drm "virgl"
2197             ;;
2198         *)
2199             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2200             ;;
2201         esac
2202     done
2203 fi
2204
2205 dnl Set LLVM_LIBS - This is done after the driver configuration so
2206 dnl that drivers can add additional components to LLVM_COMPONENTS.
2207 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2208 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2209 dnl this was causing the same libraries to be appear multiple times
2210 dnl in LLVM_LIBS.
2211
2212 if test "x$MESA_LLVM" != x0; then
2213
2214     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2215
2216     dnl llvm-config may not give the right answer when llvm is a built as a
2217     dnl single shared library, so we must work the library name out for
2218     dnl ourselves.
2219     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2220     if test "x$enable_llvm_shared_libs" = xyes; then
2221         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2222         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2223         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2224
2225         if test "x$llvm_have_one_so" = xyes; then
2226             dnl LLVM was built using auto*, so there is only one shared object.
2227             LLVM_LIBS="-l$LLVM_SO_NAME"
2228         else
2229             dnl If LLVM was built with CMake, there will be one shared object per
2230             dnl component.
2231             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2232                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2233         Please make sure you have built llvm with the --enable-shared option
2234         and that your llvm libraries are installed in $LLVM_LIBDIR
2235         If you have installed your llvm libraries to a different directory you
2236         can use the --with-llvm-prefix= configure flag to specify this directory.
2237         NOTE: Mesa is attempting to use llvm shared libraries by default.
2238         If you do not want to build with llvm shared libraries and instead want to
2239         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2240         invocation and rebuild.])])
2241
2242            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2243            dnl install uses a shared object for each component and we have
2244            dnl already added all of these objects to LLVM_LIBS.
2245         fi
2246     else
2247         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2248         dnl We need to link to llvm system libs when using static libs
2249         dnl However, only llvm 3.5+ provides --system-libs
2250         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2251             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2252         fi
2253     fi
2254 fi
2255
2256 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2257 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2258 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2259 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2260 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2261 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2262 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2263                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2264 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2265 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2266 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2267 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2268 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2269 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2270
2271 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2272
2273 if test "x$enable_dri" = xyes; then
2274     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2275 fi
2276
2277 if test "x$have_drisw_kms" = xyes; then
2278     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2279 fi
2280 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2281
2282 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2283 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2284 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2285 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2286 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2287 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2288
2289 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2290                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2291                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2292 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2293 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2294 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2295 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2296 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2297 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2298 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2299     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2300 fi
2301
2302 AC_SUBST([ELF_LIB])
2303
2304 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2305 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2306 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2307 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2308
2309 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2310 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2311 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2312
2313 AC_SUBST([NINE_MAJOR], 1)
2314 AC_SUBST([NINE_MINOR], 0)
2315 AC_SUBST([NINE_TINY], 0)
2316 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2317
2318 AC_SUBST([VDPAU_MAJOR], 1)
2319 AC_SUBST([VDPAU_MINOR], 0)
2320
2321 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2322 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2323 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2324 AC_SUBST([VA_MINOR], $VA_MINOR)
2325
2326 AC_SUBST([XVMC_MAJOR], 1)
2327 AC_SUBST([XVMC_MINOR], 0)
2328
2329 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2330 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2331 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2332 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2333
2334 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2335 AC_SUBST([XA_MINOR], $XA_MINOR)
2336 AC_SUBST([XA_TINY], $XA_TINY)
2337 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2338
2339 dnl Restore LDFLAGS and CPPFLAGS
2340 LDFLAGS="$_SAVE_LDFLAGS"
2341 CPPFLAGS="$_SAVE_CPPFLAGS"
2342
2343 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2344 if test "x$acv_mesa_CLANG" = xyes; then
2345     CFLAGS="$CFLAGS -Qunused-arguments"
2346     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2347 fi
2348
2349 dnl Add user CFLAGS and CXXFLAGS
2350 CFLAGS="$CFLAGS $USER_CFLAGS"
2351 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2352
2353 dnl Substitute the config
2354 AC_CONFIG_FILES([Makefile
2355                 src/Makefile
2356                 src/egl/Makefile
2357                 src/egl/main/egl.pc
2358                 src/egl/wayland/wayland-drm/Makefile
2359                 src/egl/wayland/wayland-egl/Makefile
2360                 src/egl/wayland/wayland-egl/wayland-egl.pc
2361                 src/gallium/Makefile
2362                 src/gallium/auxiliary/Makefile
2363                 src/gallium/auxiliary/pipe-loader/Makefile
2364                 src/gallium/drivers/freedreno/Makefile
2365                 src/gallium/drivers/ddebug/Makefile
2366                 src/gallium/drivers/i915/Makefile
2367                 src/gallium/drivers/ilo/Makefile
2368                 src/gallium/drivers/llvmpipe/Makefile
2369                 src/gallium/drivers/noop/Makefile
2370                 src/gallium/drivers/nouveau/Makefile
2371                 src/gallium/drivers/r300/Makefile
2372                 src/gallium/drivers/r600/Makefile
2373                 src/gallium/drivers/radeon/Makefile
2374                 src/gallium/drivers/radeonsi/Makefile
2375                 src/gallium/drivers/rbug/Makefile
2376                 src/gallium/drivers/softpipe/Makefile
2377                 src/gallium/drivers/svga/Makefile
2378                 src/gallium/drivers/trace/Makefile
2379                 src/gallium/drivers/vc4/Makefile
2380                 src/gallium/drivers/virgl/Makefile
2381                 src/gallium/state_trackers/clover/Makefile
2382                 src/gallium/state_trackers/dri/Makefile
2383                 src/gallium/state_trackers/glx/xlib/Makefile
2384                 src/gallium/state_trackers/nine/Makefile
2385                 src/gallium/state_trackers/omx/Makefile
2386                 src/gallium/state_trackers/osmesa/Makefile
2387                 src/gallium/state_trackers/va/Makefile
2388                 src/gallium/state_trackers/vdpau/Makefile
2389                 src/gallium/state_trackers/xa/Makefile
2390                 src/gallium/state_trackers/xvmc/Makefile
2391                 src/gallium/targets/d3dadapter9/Makefile
2392                 src/gallium/targets/d3dadapter9/d3d.pc
2393                 src/gallium/targets/dri/Makefile
2394                 src/gallium/targets/libgl-xlib/Makefile
2395                 src/gallium/targets/omx/Makefile
2396                 src/gallium/targets/opencl/Makefile
2397                 src/gallium/targets/opencl/mesa.icd
2398                 src/gallium/targets/osmesa/Makefile
2399                 src/gallium/targets/osmesa/osmesa.pc
2400                 src/gallium/targets/pipe-loader/Makefile
2401                 src/gallium/targets/va/Makefile
2402                 src/gallium/targets/vdpau/Makefile
2403                 src/gallium/targets/xa/Makefile
2404                 src/gallium/targets/xa/xatracker.pc
2405                 src/gallium/targets/xvmc/Makefile
2406                 src/gallium/tests/trivial/Makefile
2407                 src/gallium/tests/unit/Makefile
2408                 src/gallium/winsys/freedreno/drm/Makefile
2409                 src/gallium/winsys/i915/drm/Makefile
2410                 src/gallium/winsys/intel/drm/Makefile
2411                 src/gallium/winsys/nouveau/drm/Makefile
2412                 src/gallium/winsys/radeon/drm/Makefile
2413                 src/gallium/winsys/amdgpu/drm/Makefile
2414                 src/gallium/winsys/svga/drm/Makefile
2415                 src/gallium/winsys/sw/dri/Makefile
2416                 src/gallium/winsys/sw/kms-dri/Makefile
2417                 src/gallium/winsys/sw/null/Makefile
2418                 src/gallium/winsys/sw/wrapper/Makefile
2419                 src/gallium/winsys/sw/xlib/Makefile
2420                 src/gallium/winsys/vc4/drm/Makefile
2421                 src/gallium/winsys/virgl/drm/Makefile
2422                 src/gallium/winsys/virgl/vtest/Makefile
2423                 src/gbm/Makefile
2424                 src/gbm/main/gbm.pc
2425                 src/glsl/Makefile
2426                 src/glx/Makefile
2427                 src/glx/apple/Makefile
2428                 src/glx/tests/Makefile
2429                 src/gtest/Makefile
2430                 src/loader/Makefile
2431                 src/mapi/Makefile
2432                 src/mapi/es1api/glesv1_cm.pc
2433                 src/mapi/es2api/glesv2.pc
2434                 src/mapi/glapi/gen/Makefile
2435                 src/mesa/Makefile
2436                 src/mesa/gl.pc
2437                 src/mesa/drivers/dri/dri.pc
2438                 src/mesa/drivers/dri/common/Makefile
2439                 src/mesa/drivers/dri/common/xmlpool/Makefile
2440                 src/mesa/drivers/dri/i915/Makefile
2441                 src/mesa/drivers/dri/i965/Makefile
2442                 src/mesa/drivers/dri/Makefile
2443                 src/mesa/drivers/dri/nouveau/Makefile
2444                 src/mesa/drivers/dri/r200/Makefile
2445                 src/mesa/drivers/dri/radeon/Makefile
2446                 src/mesa/drivers/dri/swrast/Makefile
2447                 src/mesa/drivers/osmesa/Makefile
2448                 src/mesa/drivers/osmesa/osmesa.pc
2449                 src/mesa/drivers/x11/Makefile
2450                 src/mesa/main/tests/Makefile
2451                 src/util/Makefile
2452                 src/util/tests/hash_table/Makefile])
2453
2454 AC_OUTPUT
2455
2456 dnl
2457 dnl Output some configuration info for the user
2458 dnl
2459 echo ""
2460 echo "        prefix:          $prefix"
2461 echo "        exec_prefix:     $exec_prefix"
2462 echo "        libdir:          $libdir"
2463 echo "        includedir:      $includedir"
2464
2465 dnl API info
2466 echo ""
2467 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2468
2469 dnl Driver info
2470 echo ""
2471 case "x$enable_osmesa$enable_gallium_osmesa" in
2472 xnoyes)
2473         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2474         ;;
2475 xyesno)
2476         echo "        OSMesa:          lib$OSMESA_LIB"
2477         ;;
2478 xnono)
2479         echo "        OSMesa:          no"
2480         ;;
2481 esac
2482
2483 echo ""
2484 if test "x$enable_dri" != xno; then
2485         echo "        DRI platform:    $dri_platform"
2486         if test -z "$DRI_DIRS"; then
2487             echo "        DRI drivers:     no"
2488         else
2489             echo "        DRI drivers:     $DRI_DIRS"
2490         fi
2491         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2492 fi
2493
2494 case "x$enable_glx$enable_xlib_glx" in
2495 xyesyes)
2496     echo "        GLX:             Xlib-based"
2497     ;;
2498 xyesno)
2499     echo "        GLX:             DRI-based"
2500     ;;
2501 *)
2502     echo "        GLX:             $enable_glx"
2503     ;;
2504 esac
2505
2506 dnl EGL
2507 echo ""
2508 echo "        EGL:             $enable_egl"
2509 if test "$enable_egl" = yes; then
2510     echo "        EGL platforms:   $egl_platforms"
2511
2512     egl_drivers=""
2513     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2514         egl_drivers="$egl_drivers builtin:egl_dri2"
2515     fi
2516     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2517         egl_drivers="$egl_drivers builtin:egl_dri3"
2518     fi
2519
2520     echo "        EGL drivers:    $egl_drivers"
2521 fi
2522
2523 echo ""
2524 if test "x$MESA_LLVM" = x1; then
2525     echo "        llvm:            yes"
2526     echo "        llvm-config:     $LLVM_CONFIG"
2527     echo "        llvm-version:    $LLVM_VERSION"
2528 else
2529     echo "        llvm:            no"
2530 fi
2531
2532 echo ""
2533 if test -n "$with_gallium_drivers"; then
2534     echo "        Gallium drivers: $gallium_drivers"
2535     echo "        Gallium st:      $gallium_st"
2536 else
2537     echo "        Gallium:         no"
2538 fi
2539
2540 dnl Shader cache
2541 echo ""
2542 echo "        Shader cache:    $enable_shader_cache"
2543 if test "x$enable_shader_cache" = "xyes"; then
2544     echo "        With SHA1 from:  $with_sha1"
2545 fi
2546
2547 dnl Libraries
2548 echo ""
2549 echo "        Shared libs:     $enable_shared"
2550 echo "        Static libs:     $enable_static"
2551 echo "        Shared-glapi:    $enable_shared_glapi"
2552
2553 dnl Compiler options
2554 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2555 cflags=`echo $CFLAGS | \
2556     $SED 's/^ *//;s/  */ /;s/ *$//'`
2557 cxxflags=`echo $CXXFLAGS | \
2558     $SED 's/^ *//;s/  */ /;s/ *$//'`
2559 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2560 echo ""
2561 echo "        CFLAGS:          $cflags"
2562 echo "        CXXFLAGS:        $cxxflags"
2563 echo "        Macros:          $defines"
2564 echo ""
2565 if test "x$MESA_LLVM" = x1; then
2566     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2567     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2568     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2569     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2570     echo ""
2571 fi
2572 echo "        PYTHON2:         $PYTHON2"
2573
2574 echo ""
2575 echo "        Run '${MAKE-make}' to build Mesa"
2576 echo ""