configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.52
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82 PYTHON_MAKO_REQUIRED=0.3.4
  83
  84 dnl Check for progs
  85 AC_PROG_CPP
  86 AC_PROG_CC
  87 AC_PROG_CXX
  88 AM_PROG_CC_C_O
  89 AM_PROG_AS
  90 AX_CHECK_GNU_MAKE
  91 AC_CHECK_PROGS([PYTHON2], [python2 python])
  92 AC_PROG_SED
  93 AC_PROG_MKDIR_P
  94
  95 AC_SYS_LARGEFILE
  96
  97 LT_PREREQ([2.2])
  98 LT_INIT([disable-static])
  99
 100 AX_PROG_BISON([],
 101               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 102                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 103 AX_PROG_FLEX([],
 104              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 105                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 106
 107 AC_CHECK_PROG(INDENT, indent, indent, cat)
 108 if test "x$INDENT" != "xcat"; then
 109     # Only GNU indent is supported
 110     INDENT_VERSION=`indent --version | grep GNU`
 111     if test $? -eq 0; then
 112        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 113     else
 114        INDENT="cat"
 115     fi
 116 fi
 117
 118 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 119 if test -n "$PYTHON2" -a "x$acv_mako_found" = "xyes"; then
 120     AC_MSG_RESULT(yes)
 121 else
 122     AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 123 fi
 124
 125 AC_PROG_INSTALL
 126
 127 dnl We need a POSIX shell for parts of the build. Assume we have one
 128 dnl in most cases.
 129 case "$host_os" in
 130 solaris*)
 131     # Solaris /bin/sh is too old/non-POSIX compliant
 132     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 133     SHELL="$POSIX_SHELL"
 134     ;;
 135 esac
 136
 137 dnl clang is mostly GCC-compatible, but its version is much lower,
 138 dnl so we have to check for it.
 139 AC_MSG_CHECKING([if compiling with clang])
 140
 141 AC_COMPILE_IFELSE(
 142 [AC_LANG_PROGRAM([], [[
 143 #ifndef __clang__
 144        not clang
 145 #endif
 146 ]])],
 147 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 148
 149 AC_MSG_RESULT([$acv_mesa_CLANG])
 150
 151 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 152 dnl versions are explictly not supported.
 153 GEN_ASM_OFFSETS=no
 154 USE_GNU99=no
 155 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 156     AC_MSG_CHECKING([whether gcc version is sufficient])
 157     major=0
 158     minor=0
 159
 160     GCC_VERSION=`$CC -dumpversion`
 161     if test $? -eq 0; then
 162         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 163         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 164     fi
 165
 166     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 167         AC_MSG_RESULT([no])
 168         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 169     else
 170         AC_MSG_RESULT([yes])
 171     fi
 172
 173     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 174         USE_GNU99=yes
 175     fi
 176     if test "x$cross_compiling" = xyes; then
 177         GEN_ASM_OFFSETS=yes
 178     fi
 179 fi
 180
 181 dnl Check for compiler builtins
 182 AX_GCC_BUILTIN([__builtin_bswap32])
 183 AX_GCC_BUILTIN([__builtin_bswap64])
 184 AX_GCC_BUILTIN([__builtin_clz])
 185 AX_GCC_BUILTIN([__builtin_clzll])
 186 AX_GCC_BUILTIN([__builtin_ctz])
 187 AX_GCC_BUILTIN([__builtin_expect])
 188 AX_GCC_BUILTIN([__builtin_ffs])
 189 AX_GCC_BUILTIN([__builtin_ffsll])
 190 AX_GCC_BUILTIN([__builtin_popcount])
 191 AX_GCC_BUILTIN([__builtin_popcountll])
 192 AX_GCC_BUILTIN([__builtin_unreachable])
 193
 194 AX_GCC_FUNC_ATTRIBUTE([flatten])
 195 AX_GCC_FUNC_ATTRIBUTE([format])
 196 AX_GCC_FUNC_ATTRIBUTE([malloc])
 197 AX_GCC_FUNC_ATTRIBUTE([packed])
 198 AX_GCC_FUNC_ATTRIBUTE([unused])
 199
 200 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 201
 202 dnl Make sure the pkg-config macros are defined
 203 m4_ifndef([PKG_PROG_PKG_CONFIG],
 204     [m4_fatal([Could not locate the pkg-config autoconf macros.
 205   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 206   are in a different location, try setting the environment variable
 207   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 208 PKG_PROG_PKG_CONFIG()
 209
 210 dnl LIB_DIR - library basename
 211 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 212 AC_SUBST([LIB_DIR])
 213
 214 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 215 _SAVE_LDFLAGS="$LDFLAGS"
 216 _SAVE_CPPFLAGS="$CPPFLAGS"
 217
 218 dnl Compiler macros
 219 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 220 AC_SUBST([DEFINES])
 221 case "$host_os" in
 222 linux*|*-gnu*|gnu*)
 223     DEFINES="$DEFINES -D_GNU_SOURCE"
 224     ;;
 225 solaris*)
 226     DEFINES="$DEFINES -DSVR4"
 227     ;;
 228 cygwin*)
 229     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 230     ;;
 231 esac
 232
 233 dnl Add flags for gcc and g++
 234 if test "x$GCC" = xyes; then
 235     CFLAGS="$CFLAGS -Wall"
 236
 237     if test "x$USE_GNU99" = xyes; then
 238         CFLAGS="$CFLAGS -std=gnu99"
 239     else
 240         CFLAGS="$CFLAGS -std=c99"
 241     fi
 242
 243     # Enable -Werror=implicit-function-declaration and
 244     # -Werror=missing-prototypes, if available, or otherwise, just
 245     # -Wmissing-prototypes.  This is particularly useful to avoid
 246     # generating a loadable driver module that has undefined symbols.
 247     save_CFLAGS="$CFLAGS"
 248     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 249     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 250     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 251     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 252                    AC_MSG_RESULT([yes]),
 253                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 254                     AC_MSG_RESULT([no])]);
 255
 256     # Enable -fvisibility=hidden if using a gcc that supports it
 257     save_CFLAGS="$CFLAGS"
 258     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 259     VISIBILITY_CFLAGS="-fvisibility=hidden"
 260     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 261     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 262                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 263
 264     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 265     CFLAGS=$save_CFLAGS
 266
 267     # Work around aliasing bugs - developers should comment this out
 268     CFLAGS="$CFLAGS -fno-strict-aliasing"
 269
 270     # gcc's builtin memcmp is slower than glibc's
 271     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 272     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 273
 274     # Flags to help ensure that certain portions of the code -- and only those
 275     # portions -- can be built with MSVC:
 276     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 277     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 278     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 279     #   supports most of C99)
 280     # - the rest has no compiler compiler restrictions
 281     MSVC2013_COMPAT_CFLAGS="-Werror=vla -Werror=pointer-arith"
 282     MSVC2013_COMPAT_CXXFLAGS="-Werror=vla -Werror=pointer-arith"
 283     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 284     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 285 fi
 286 if test "x$GXX" = xyes; then
 287     CXXFLAGS="$CXXFLAGS -Wall"
 288
 289     # Enable -fvisibility=hidden if using a gcc that supports it
 290     save_CXXFLAGS="$CXXFLAGS"
 291     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 292     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 293     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 294     AC_LANG_PUSH([C++])
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 296                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 297     AC_LANG_POP([C++])
 298
 299     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 300     CXXFLAGS=$save_CXXFLAGS
 301
 302     # Work around aliasing bugs - developers should comment this out
 303     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 304
 305     # gcc's builtin memcmp is slower than glibc's
 306     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 307     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 308 fi
 309
 310 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 311 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 312 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 313 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 314
 315 dnl even if the compiler appears to support it, using visibility attributes isn't
 316 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 317 case "$host_os" in
 318 cygwin*)
 319     VISIBILITY_CFLAGS=""
 320     VISIBILITY_CXXFLAGS=""
 321     ;;
 322 esac
 323
 324 AC_SUBST([VISIBILITY_CFLAGS])
 325 AC_SUBST([VISIBILITY_CXXFLAGS])
 326
 327 dnl
 328 dnl Optional flags, check for compiler support
 329 dnl
 330 SSE41_CFLAGS="-msse4.1"
 331 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 332 dnl stack, but on x86-32 such alignment is not guaranteed.
 333 case "$target_cpu" in
 334 i?86)
 335     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 336     ;;
 337 esac
 338 save_CFLAGS="$CFLAGS"
 339 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 340 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 341 #include <smmintrin.h>
 342 int main () {
 343     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 344     c = _mm_max_epu32(a, b);
 345     return 0;
 346 }]])], SSE41_SUPPORTED=1)
 347 CFLAGS="$save_CFLAGS"
 348 if test "x$SSE41_SUPPORTED" = x1; then
 349     DEFINES="$DEFINES -DUSE_SSE41"
 350 fi
 351 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 352 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 353
 354 dnl Can't have static and shared libraries, default to static if user
 355 dnl explicitly requested. If both disabled, set to static since shared
 356 dnl was explicitly requested.
 357 case "x$enable_static$enable_shared" in
 358 xyesyes)
 359     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 360     enable_shared=no
 361     ;;
 362 xnono)
 363     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 364     enable_shared=yes
 365     ;;
 366 esac
 367
 368 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 369
 370 dnl
 371 dnl other compiler options
 372 dnl
 373 AC_ARG_ENABLE([debug],
 374     [AS_HELP_STRING([--enable-debug],
 375         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 376     [enable_debug="$enableval"],
 377     [enable_debug=no]
 378 )
 379 if test "x$enable_debug" = xyes; then
 380     DEFINES="$DEFINES -DDEBUG"
 381     if test "x$GCC" = xyes; then
 382         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 383             CFLAGS="$CFLAGS -g"
 384         fi
 385         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 386             CFLAGS="$CFLAGS -O0"
 387         fi
 388     fi
 389     if test "x$GXX" = xyes; then
 390         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 391             CXXFLAGS="$CXXFLAGS -g"
 392         fi
 393         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 394             CXXFLAGS="$CXXFLAGS -O0"
 395         fi
 396     fi
 397 else
 398    DEFINES="$DEFINES -DNDEBUG"
 399 fi
 400
 401 dnl
 402 dnl Check if linker supports -Bsymbolic
 403 dnl
 404 save_LDFLAGS=$LDFLAGS
 405 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 406 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 407 AC_LINK_IFELSE(
 408     [AC_LANG_SOURCE([int main() { return 0;}])],
 409     [AC_MSG_RESULT([yes])
 410         BSYMBOLIC="-Wl,-Bsymbolic";],
 411     [AC_MSG_RESULT([no])
 412         BSYMBOLIC="";])
 413 LDFLAGS=$save_LDFLAGS
 414
 415 AC_SUBST([BSYMBOLIC])
 416
 417 dnl
 418 dnl Check if linker supports garbage collection
 419 dnl
 420 save_LDFLAGS=$LDFLAGS
 421 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 422 AC_MSG_CHECKING([whether ld supports --gc-sections])
 423 AC_LINK_IFELSE(
 424     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 425     [AC_MSG_RESULT([yes])
 426         GC_SECTIONS="-Wl,--gc-sections";],
 427     [AC_MSG_RESULT([no])
 428         GC_SECTIONS="";])
 429 LDFLAGS=$save_LDFLAGS
 430
 431 AC_SUBST([GC_SECTIONS])
 432
 433 dnl
 434 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 435 dnl so when these flags are passed to ld via libtool the checks will fail
 436 dnl
 437 case "$host_os" in
 438 openbsd* | darwin* )
 439     LD_NO_UNDEFINED="" ;;
 440 *)
 441     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 442 esac
 443
 444 AC_SUBST([LD_NO_UNDEFINED])
 445
 446 dnl
 447 dnl Check if linker supports version scripts
 448 dnl
 449 AC_MSG_CHECKING([if the linker supports version-scripts])
 450 save_LDFLAGS=$LDFLAGS
 451 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 452 cat > conftest.map <<EOF
 453 VERSION_1 {
 454      global:
 455          main;
 456
 457      local:
 458          *;
 459 };
 460 EOF
 461 AC_LINK_IFELSE(
 462     [AC_LANG_SOURCE([int main() { return 0;}])],
 463     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 464     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 465 LDFLAGS=$save_LDFLAGS
 466 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 467
 468 dnl
 469 dnl Check if linker supports dynamic list files
 470 dnl
 471 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 472 save_LDFLAGS=$LDFLAGS
 473 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 474 cat > conftest.dyn <<EOF
 475 {
 476         radeon_drm_winsys_create;
 477 };
 478 EOF
 479 AC_LINK_IFELSE(
 480     [AC_LANG_SOURCE([int main() { return 0;}])],
 481     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 482     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 483 LDFLAGS=$save_LDFLAGS
 484 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 485
 486 dnl
 487 dnl compatibility symlinks
 488 dnl
 489 case "$host_os" in
 490 linux* )
 491     HAVE_COMPAT_SYMLINKS=yes ;;
 492 * )
 493     HAVE_COMPAT_SYMLINKS=no ;;
 494 esac
 495
 496 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 497
 498 dnl
 499 dnl library names
 500 dnl
 501 case "$host_os" in
 502 darwin* )
 503     LIB_EXT='dylib' ;;
 504 cygwin* )
 505     LIB_EXT='dll' ;;
 506 aix* )
 507     LIB_EXT='a' ;;
 508 * )
 509     LIB_EXT='so' ;;
 510 esac
 511
 512 AC_SUBST([LIB_EXT])
 513
 514 AC_ARG_WITH([gl-lib-name],
 515   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 516     [specify GL library name @<:@default=GL@:>@])],
 517   [GL_LIB=$withval],
 518   [GL_LIB=GL])
 519 AC_ARG_WITH([osmesa-lib-name],
 520   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 521     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 522   [OSMESA_LIB=$withval],
 523   [OSMESA_LIB=OSMesa])
 524 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 525 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 526
 527 dnl
 528 dnl Mangled Mesa support
 529 dnl
 530 AC_ARG_ENABLE([mangling],
 531   [AS_HELP_STRING([--enable-mangling],
 532     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 533   [enable_mangling="${enableval}"],
 534   [enable_mangling=no]
 535 )
 536 if test "x${enable_mangling}" = "xyes" ; then
 537   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 538   GL_LIB="Mangled${GL_LIB}"
 539   OSMESA_LIB="Mangled${OSMESA_LIB}"
 540 fi
 541 AC_SUBST([GL_LIB])
 542 AC_SUBST([OSMESA_LIB])
 543
 544 dnl
 545 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 546 dnl
 547 AC_ARG_ENABLE([texture-float],
 548     [AS_HELP_STRING([--enable-texture-float],
 549         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 550     [enable_texture_float="$enableval"],
 551     [enable_texture_float=no]
 552 )
 553 if test "x$enable_texture_float" = xyes; then
 554     AC_MSG_WARN([Floating-point textures enabled.])
 555     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 556     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 557 fi
 558
 559 dnl
 560 dnl Arch/platform-specific settings
 561 dnl
 562 AC_ARG_ENABLE([asm],
 563     [AS_HELP_STRING([--disable-asm],
 564         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 565     [enable_asm="$enableval"],
 566     [enable_asm=yes]
 567 )
 568 asm_arch=""
 569 AC_MSG_CHECKING([whether to enable assembly])
 570 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 571 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 572 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 573     case "$host_cpu" in
 574     i?86 | x86_64 | amd64)
 575         enable_asm=no
 576         AC_MSG_RESULT([no, cross compiling])
 577         ;;
 578     esac
 579 fi
 580 # check for supported arches
 581 if test "x$enable_asm" = xyes; then
 582     case "$host_cpu" in
 583     i?86)
 584         case "$host_os" in
 585         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 586             asm_arch=x86
 587             ;;
 588         esac
 589         ;;
 590     x86_64|amd64)
 591         case "$host_os" in
 592         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 593             asm_arch=x86_64
 594             ;;
 595         esac
 596         ;;
 597     sparc*)
 598         case "$host_os" in
 599         linux*)
 600             asm_arch=sparc
 601             ;;
 602         esac
 603         ;;
 604     esac
 605
 606     case "$asm_arch" in
 607     x86)
 608         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 609         AC_MSG_RESULT([yes, x86])
 610         ;;
 611     x86_64|amd64)
 612         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 613         AC_MSG_RESULT([yes, x86_64])
 614         ;;
 615     sparc)
 616         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 617         AC_MSG_RESULT([yes, sparc])
 618         ;;
 619     *)
 620         AC_MSG_RESULT([no, platform not supported])
 621         ;;
 622     esac
 623 fi
 624
 625 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 626 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 627
 628 dnl Check to see if dlopen is in default libraries (like Solaris, which
 629 dnl has it in libc), or if libdl is needed to get it.
 630 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 631     [AC_CHECK_LIB([dl], [dlopen],
 632        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 633 AC_SUBST([DLOPEN_LIBS])
 634
 635 dnl Check if that library also has dladdr
 636 save_LIBS="$LIBS"
 637 LIBS="$LIBS $DLOPEN_LIBS"
 638 AC_CHECK_FUNCS([dladdr])
 639 LIBS="$save_LIBS"
 640
 641 case "$host_os" in
 642 darwin*|mingw*)
 643     ;;
 644 *)
 645     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 646                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 647                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 648     AC_SUBST([CLOCK_LIB])
 649     ;;
 650 esac
 651
 652 dnl See if posix_memalign is available
 653 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 654
 655 dnl Check for pthreads
 656 case "$host_os" in
 657 mingw*)
 658     ;;
 659 *)
 660     AX_PTHREAD
 661     ;;
 662 esac
 663 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 664 dnl to -pthread, which causes problems if we need -lpthread to appear in
 665 dnl pkgconfig files.
 666 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 667
 668 dnl SELinux awareness.
 669 AC_ARG_ENABLE([selinux],
 670     [AS_HELP_STRING([--enable-selinux],
 671         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 672     [MESA_SELINUX="$enableval"],
 673     [MESA_SELINUX=no])
 674 if test "x$enable_selinux" = "xyes"; then
 675     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 676         [AC_CHECK_HEADER([selinux/selinux.h],[],
 677                          [AC_MSG_ERROR([SELinux headers not found])])
 678          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 679                       [AC_MSG_ERROR([SELinux library not found])])
 680          SELINUX_LIBS="-lselinux"])
 681     DEFINES="$DEFINES -DMESA_SELINUX"
 682 fi
 683 AC_SUBST([SELINUX_CFLAGS])
 684 AC_SUBST([SELINUX_LIBS])
 685
 686 dnl Options for APIs
 687 AC_ARG_ENABLE([opengl],
 688     [AS_HELP_STRING([--disable-opengl],
 689         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 690     [enable_opengl="$enableval"],
 691     [enable_opengl=yes])
 692 AC_ARG_ENABLE([gles1],
 693     [AS_HELP_STRING([--enable-gles1],
 694         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 695     [enable_gles1="$enableval"],
 696     [enable_gles1=no])
 697 AC_ARG_ENABLE([gles2],
 698     [AS_HELP_STRING([--enable-gles2],
 699         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 700     [enable_gles2="$enableval"],
 701     [enable_gles2=no])
 702
 703 AC_ARG_ENABLE([dri],
 704     [AS_HELP_STRING([--enable-dri],
 705         [enable DRI modules @<:@default=enabled@:>@])],
 706     [enable_dri="$enableval"],
 707     [enable_dri=yes])
 708
 709 case "$host_os" in
 710 linux*)
 711     dri3_default=yes
 712     ;;
 713 *)
 714     dri3_default=no
 715     ;;
 716 esac
 717 AC_ARG_ENABLE([dri3],
 718     [AS_HELP_STRING([--enable-dri3],
 719         [enable DRI3 @<:@default=auto@:>@])],
 720     [enable_dri3="$enableval"],
 721     [enable_dri3="$dri3_default"])
 722 AC_ARG_ENABLE([glx],
 723     [AS_HELP_STRING([--enable-glx],
 724         [enable GLX library @<:@default=enabled@:>@])],
 725     [enable_glx="$enableval"],
 726     [enable_glx=yes])
 727 AC_ARG_ENABLE([osmesa],
 728     [AS_HELP_STRING([--enable-osmesa],
 729         [enable OSMesa library @<:@default=disabled@:>@])],
 730     [enable_osmesa="$enableval"],
 731     [enable_osmesa=no])
 732 AC_ARG_ENABLE([gallium-osmesa],
 733     [AS_HELP_STRING([--enable-gallium-osmesa],
 734         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 735     [enable_gallium_osmesa="$enableval"],
 736     [enable_gallium_osmesa=no])
 737 AC_ARG_ENABLE([egl],
 738     [AS_HELP_STRING([--disable-egl],
 739         [disable EGL library @<:@default=enabled@:>@])],
 740     [enable_egl="$enableval"],
 741     [enable_egl=yes])
 742
 743 AC_ARG_ENABLE([xa],
 744     [AS_HELP_STRING([--enable-xa],
 745         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 746     [enable_xa="$enableval"],
 747     [enable_xa=no])
 748 AC_ARG_ENABLE([gbm],
 749    [AS_HELP_STRING([--enable-gbm],
 750          [enable gbm library @<:@default=auto@:>@])],
 751    [enable_gbm="$enableval"],
 752    [enable_gbm=auto])
 753 AC_ARG_ENABLE([nine],
 754     [AS_HELP_STRING([--enable-nine],
 755         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 756     [enable_nine="$enableval"],
 757     [enable_nine=no])
 758
 759 AC_ARG_ENABLE([xvmc],
 760    [AS_HELP_STRING([--enable-xvmc],
 761          [enable xvmc library @<:@default=auto@:>@])],
 762    [enable_xvmc="$enableval"],
 763    [enable_xvmc=auto])
 764 AC_ARG_ENABLE([vdpau],
 765    [AS_HELP_STRING([--enable-vdpau],
 766          [enable vdpau library @<:@default=auto@:>@])],
 767    [enable_vdpau="$enableval"],
 768    [enable_vdpau=auto])
 769 AC_ARG_ENABLE([omx],
 770    [AS_HELP_STRING([--enable-omx],
 771          [enable OpenMAX library @<:@default=disabled@:>@])],
 772    [enable_omx="$enableval"],
 773    [enable_omx=no])
 774 AC_ARG_ENABLE([va],
 775    [AS_HELP_STRING([--enable-va],
 776          [enable va library @<:@default=auto@:>@])],
 777    [enable_va="$enableval"],
 778    [enable_va=auto])
 779 AC_ARG_ENABLE([opencl],
 780    [AS_HELP_STRING([--enable-opencl],
 781          [enable OpenCL library @<:@default=disabled@:>@])],
 782    [enable_opencl="$enableval"],
 783    [enable_opencl=no])
 784 AC_ARG_ENABLE([opencl_icd],
 785    [AS_HELP_STRING([--enable-opencl-icd],
 786           [Build an OpenCL ICD library to be loaded by an ICD implementation
 787            @<:@default=disabled@:>@])],
 788     [enable_opencl_icd="$enableval"],
 789     [enable_opencl_icd=no])
 790 AC_ARG_ENABLE([xlib-glx],
 791     [AS_HELP_STRING([--enable-xlib-glx],
 792         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 793     [enable_xlib_glx="$enableval"],
 794     [enable_xlib_glx=no])
 795
 796 AC_ARG_ENABLE([r600-llvm-compiler],
 797     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 798         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 799     [enable_r600_llvm="$enableval"],
 800     [enable_r600_llvm=no])
 801
 802 AC_ARG_ENABLE([gallium-tests],
 803     [AS_HELP_STRING([--enable-gallium-tests],
 804         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 805     [enable_gallium_tests="$enableval"],
 806     [enable_gallium_tests=no])
 807
 808 # Option for Gallium drivers
 809
 810 # Keep this in sync with the --with-gallium-drivers help string default value
 811 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 812
 813 AC_ARG_WITH([gallium-drivers],
 814     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 815         [comma delimited Gallium drivers list, e.g.
 816         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 817         @<:@default=r300,r600,svga,swrast@:>@])],
 818     [with_gallium_drivers="$withval"],
 819     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 820
 821 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 822 # here so that the script doesn't choke on an unknown driver name later.
 823 case "$with_gallium_drivers" in
 824     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 825     no) with_gallium_drivers='' ;;
 826 esac
 827
 828 if test "x$enable_opengl" = xno -a \
 829         "x$enable_gles1" = xno -a \
 830         "x$enable_gles2" = xno -a \
 831         "x$enable_nine" = xno -a \
 832         "x$enable_xa" = xno -a \
 833         "x$enable_xvmc" = xno -a \
 834         "x$enable_vdpau" = xno -a \
 835         "x$enable_omx" = xno -a \
 836         "x$enable_va" = xno -a \
 837         "x$enable_opencl" = xno; then
 838     AC_MSG_ERROR([at least one API should be enabled])
 839 fi
 840
 841 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 842 if test "x$enable_opengl" = xno -a \
 843         "x$enable_gles1" = xyes; then
 844     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 845 fi
 846
 847 if test "x$enable_opengl" = xno -a \
 848         "x$enable_gles2" = xyes; then
 849     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 850 fi
 851
 852 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 853 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 854 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 855 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 856                                         "x$enable_gles1" = xyes -o \
 857                                         "x$enable_gles2" = xyes)
 858
 859 if test "x$enable_glx" = xno; then
 860     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 861     enable_xlib_glx=no
 862 fi
 863
 864 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 865     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 866 fi
 867
 868 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 869     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 870 fi
 871
 872 # Disable GLX if OpenGL is not enabled
 873 if test "x$enable_glx$enable_opengl" = xyesno; then
 874     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 875     enable_glx=no
 876 fi
 877
 878 # Disable GLX if DRI and Xlib-GLX are not enabled
 879 if test "x$enable_glx" = xyes -a \
 880         "x$enable_dri" = xno -a \
 881         "x$enable_xlib_glx" = xno; then
 882     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 883     enable_glx=no
 884 fi
 885
 886 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 887                                   "x$enable_dri" = xyes)
 888
 889 # Select which platform-dependent DRI code gets built
 890 case "$host_os" in
 891 darwin*)
 892     dri_platform='apple' ;;
 893 gnu*|mingw*|cygwin*)
 894     dri_platform='none' ;;
 895 *)
 896     dri_platform='drm' ;;
 897 esac
 898
 899 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 900 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 901 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 902 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 903 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 904
 905 AC_ARG_ENABLE([shared-glapi],
 906     [AS_HELP_STRING([--enable-shared-glapi],
 907         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 908     [enable_shared_glapi="$enableval"],
 909     [enable_shared_glapi=yes])
 910
 911 case "x$enable_opengl$enable_gles1$enable_gles2" in
 912 x*yes*yes*)
 913     if test "x$enable_shared_glapi" = xno; then
 914         AC_MSG_ERROR([shared GLAPI required when building two or more of
 915                       the following APIs - opengl, gles1 gles2])
 916     fi
 917     ;;
 918 esac
 919
 920 # Building Xlib-GLX requires shared glapi to be disabled.
 921 if test "x$enable_xlib_glx" = xyes; then
 922     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 923     enable_shared_glapi=no
 924 fi
 925
 926 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 927
 928 # Build the pipe-drivers as separate libraries/modules.
 929 # Do not touch this unless you know what you are doing.
 930 # XXX: Expose via configure option ?
 931 enable_shared_pipe_drivers=no
 932
 933 dnl
 934 dnl Driver specific build directories
 935 dnl
 936
 937 case "x$enable_glx$enable_xlib_glx" in
 938 xyesyes)
 939     NEED_WINSYS_XLIB="yes"
 940     ;;
 941 esac
 942
 943 if test "x$enable_dri" = xyes; then
 944     enable_gallium_loader="$enable_shared_pipe_drivers"
 945 fi
 946
 947 if test "x$enable_gallium_osmesa" = xyes; then
 948     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 949         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 950     fi
 951     if test "x$enable_osmesa" = xyes; then
 952         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 953     fi
 954 fi
 955
 956 AC_SUBST([MESA_LLVM])
 957
 958 # SHA1 hashing
 959 AC_ARG_WITH([sha1],
 960         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 961         [choose SHA1 implementation])])
 962 case "x$with_sha1" in
 963 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 964   ;;
 965 *)
 966         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 967 esac
 968
 969 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 970 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 971         with_sha1=libc
 972 fi
 973 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 974         AC_MSG_ERROR([sha1 in libc requested but not found])
 975 fi
 976 if test "x$with_sha1" = xlibc; then
 977         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 978                 [Use libc SHA1 functions])
 979         SHA1_LIBS=""
 980 fi
 981 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 982 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 983         with_sha1=CommonCrypto
 984 fi
 985 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
 986         AC_MSG_ERROR([CommonCrypto requested but not found])
 987 fi
 988 if test "x$with_sha1" = xCommonCrypto; then
 989         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
 990                 [Use CommonCrypto SHA1 functions])
 991         SHA1_LIBS=""
 992 fi
 993 dnl stdcall functions cannot be tested with AC_CHECK_LIB
 994 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
 995 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
 996         with_sha1=CryptoAPI
 997 fi
 998 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
 999         AC_MSG_ERROR([CryptoAPI requested but not found])
1000 fi
1001 if test "x$with_sha1" = xCryptoAPI; then
1002         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1003                 [Use CryptoAPI SHA1 functions])
1004         SHA1_LIBS=""
1005 fi
1006 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1007 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1008         with_sha1=libmd
1009 fi
1010 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1011         AC_MSG_ERROR([libmd requested but not found])
1012 fi
1013 if test "x$with_sha1" = xlibmd; then
1014         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1015                   [Use libmd SHA1 functions])
1016         SHA1_LIBS=-lmd
1017 fi
1018 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1019 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1020    with_sha1=libsha1
1021 fi
1022 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1023         AC_MSG_ERROR([libsha1 requested but not found])
1024 fi
1025 if test "x$with_sha1" = xlibsha1; then
1026         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1027                   [Use libsha1 for SHA1])
1028         SHA1_LIBS=-lsha1
1029 fi
1030 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1031 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1032         with_sha1=libnettle
1033 fi
1034 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1035         AC_MSG_ERROR([libnettle requested but not found])
1036 fi
1037 if test "x$with_sha1" = xlibnettle; then
1038         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1039                   [Use libnettle SHA1 functions])
1040         SHA1_LIBS=-lnettle
1041 fi
1042 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1043 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1044         with_sha1=libgcrypt
1045 fi
1046 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1047         AC_MSG_ERROR([libgcrypt requested but not found])
1048 fi
1049 if test "x$with_sha1" = xlibgcrypt; then
1050         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1051                   [Use libgcrypt SHA1 functions])
1052         SHA1_LIBS=-lgcrypt
1053 fi
1054 # We don't need all of the OpenSSL libraries, just libcrypto
1055 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1056 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1057                   [HAVE_OPENSSL_PKC=no])
1058 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1059         if test "x$with_sha1" = x; then
1060                 with_sha1=libcrypto
1061         fi
1062 else
1063         if test "x$with_sha1" = xlibcrypto; then
1064                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1065         fi
1066 fi
1067 if test "x$with_sha1" = xlibcrypto; then
1068         if test "x$HAVE_LIBCRYPTO" = xyes; then
1069                 SHA1_LIBS=-lcrypto
1070         else
1071                 SHA1_LIBS="$OPENSSL_LIBS"
1072                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1073         fi
1074 fi
1075 AC_MSG_CHECKING([for SHA1 implementation])
1076 AC_MSG_RESULT([$with_sha1])
1077 AC_SUBST(SHA1_LIBS)
1078 AC_SUBST(SHA1_CFLAGS)
1079
1080 # Allow user to configure out the shader-cache feature
1081 AC_ARG_ENABLE([shader-cache],
1082     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1083     [enable_shader_cache="$enableval"],
1084     [if test "x$with_sha1" != "x"; then
1085         enable_shader_cache=yes
1086      else
1087         enable_shader_cache=no
1088      fi])
1089 if test "x$with_sha1" = "x"; then
1090     if test "x$enable_shader_cache" = "xyes"; then
1091         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1092     fi
1093 fi
1094 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1095
1096 # Check for libdrm
1097 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1098                   [have_libdrm=yes], [have_libdrm=no])
1099 if test "x$have_libdrm" = xyes; then
1100         DEFINES="$DEFINES -DHAVE_LIBDRM"
1101 fi
1102
1103 case "$host_os" in
1104 linux*)
1105     need_pci_id=yes ;;
1106 *)
1107     need_pci_id=no ;;
1108 esac
1109
1110 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1111                   have_libudev=yes, have_libudev=no)
1112
1113 AC_ARG_ENABLE([sysfs],
1114     [AS_HELP_STRING([--enable-sysfs],
1115         [enable /sys PCI identification @<:@default=disabled@:>@])],
1116     [have_sysfs="$enableval"],
1117     [have_sysfs=no]
1118 )
1119
1120 if test "x$enable_dri" = xyes; then
1121     if test "$enable_static" = yes; then
1122         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1123     fi
1124
1125     # not a hard requirement as swrast does not depend on it
1126     if test "x$have_libdrm" = xyes; then
1127         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1128     fi
1129 fi
1130
1131 AC_ARG_ENABLE([driglx-direct],
1132     [AS_HELP_STRING([--disable-driglx-direct],
1133         [disable direct rendering in GLX and EGL for DRI \
1134             @<:@default=auto@:>@])],
1135     [driglx_direct="$enableval"],
1136     [driglx_direct="yes"])
1137
1138 dnl
1139 dnl libGL configuration per driver
1140 dnl
1141 case "x$enable_glx$enable_xlib_glx" in
1142 xyesyes)
1143     # Xlib-based GLX
1144     dri_modules="x11 xext xcb"
1145     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1146     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1147     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1148     GL_LIB_DEPS="$XLIBGL_LIBS"
1149     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1150     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1151     ;;
1152 xyesno)
1153     # DRI-based GLX
1154     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1155
1156     # find the DRI deps for libGL
1157     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1158
1159     if test x"$driglx_direct" = xyes; then
1160         if test x"$dri_platform" = xdrm ; then
1161             DEFINES="$DEFINES -DGLX_USE_DRM"
1162             if test "x$have_libdrm" != xyes; then
1163                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1164             fi
1165
1166             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1167             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1168             if test x"$enable_dri3" = xyes; then
1169                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1170                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1171             fi
1172
1173             if test x"$enable_dri" = xyes; then
1174                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1175             fi
1176
1177             if test x"$enable_dri3" = xyes; then
1178                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1179                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1180             fi
1181         fi
1182         if test x"$dri_platform" = xapple ; then
1183             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1184         fi
1185     fi
1186
1187     # add xf86vidmode if available
1188     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1189     if test "$HAVE_XF86VIDMODE" = yes ; then
1190         dri_modules="$dri_modules xxf86vm"
1191     fi
1192
1193     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1194     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1195     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1196     GL_LIB_DEPS="$DRIGL_LIBS"
1197
1198     # need DRM libs, $PTHREAD_LIBS, etc.
1199     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1200     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1201     ;;
1202 esac
1203
1204 have_pci_id=no
1205 if test "$have_libudev" = yes; then
1206     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1207     have_pci_id=yes
1208 fi
1209
1210 if test "$have_sysfs" = yes; then
1211     DEFINES="$DEFINES -DHAVE_SYSFS"
1212     have_pci_id=yes
1213 fi
1214
1215 # This is outside the case (above) so that it is invoked even for non-GLX
1216 # builds.
1217 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1218
1219 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1220 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1221 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1222 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1223
1224 AC_SUBST([X11_INCLUDES])
1225 AC_SUBST([GL_LIB_DEPS])
1226 AC_SUBST([GL_PC_REQ_PRIV])
1227 AC_SUBST([GL_PC_LIB_PRIV])
1228 AC_SUBST([GL_PC_CFLAGS])
1229 AC_SUBST([DRI_PC_REQ_PRIV])
1230 AC_SUBST([GLESv1_CM_LIB_DEPS])
1231 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1232 AC_SUBST([GLESv2_LIB_DEPS])
1233 AC_SUBST([GLESv2_PC_LIB_PRIV])
1234
1235 AC_SUBST([HAVE_XF86VIDMODE])
1236
1237 dnl
1238 dnl More GLX setup
1239 dnl
1240 case "x$enable_glx$enable_xlib_glx" in
1241 xyesyes)
1242     DEFINES="$DEFINES -DUSE_XSHM"
1243     ;;
1244 xyesno)
1245     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1246     if test "x$driglx_direct" = xyes; then
1247         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1248     fi
1249     ;;
1250 esac
1251
1252 dnl
1253 dnl TLS detection
1254 dnl
1255
1256 AC_ARG_ENABLE([glx-tls],
1257     [AS_HELP_STRING([--enable-glx-tls],
1258         [enable TLS support in GLX @<:@default=disabled@:>@])],
1259     [GLX_USE_TLS="$enableval"],
1260     [GLX_USE_TLS=no])
1261 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1262
1263 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1264       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1265
1266 dnl
1267 dnl More DRI setup
1268 dnl
1269 dnl Directory for DRI drivers
1270 AC_ARG_WITH([dri-driverdir],
1271     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1272         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1273     [DRI_DRIVER_INSTALL_DIR="$withval"],
1274     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1275 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1276 dnl Extra search path for DRI drivers
1277 AC_ARG_WITH([dri-searchpath],
1278     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1279         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1280     [DRI_DRIVER_SEARCH_DIR="$withval"],
1281     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1282 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1283 dnl Which drivers to build - default is chosen by platform
1284 AC_ARG_WITH([dri-drivers],
1285     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1286         [comma delimited classic DRI drivers list, e.g.
1287         "swrast,i965,radeon" @<:@default=auto@:>@])],
1288     [with_dri_drivers="$withval"],
1289     [with_dri_drivers=auto])
1290
1291 if test "x$with_dri_drivers" = xauto; then
1292     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1293         with_dri_drivers="yes"
1294     else
1295         with_dri_drivers="no"
1296     fi
1297 fi
1298 if test "x$with_dri_drivers" = xno; then
1299     with_dri_drivers=''
1300 fi
1301
1302 dnl If $with_dri_drivers is yes, drivers will be added through
1303 dnl platform checks. Set DEFINES and LIB_DEPS
1304 if test "x$enable_dri" = xyes; then
1305     # Platform specific settings and drivers to build
1306     case "$host_os" in
1307     linux*)
1308         DEFINES="$DEFINES -DHAVE_ALIAS"
1309         if test "x$enable_dri3" = xyes; then
1310             DEFINES="$DEFINES -DHAVE_DRI3"
1311         fi
1312
1313         if test "x$have_pci_id" != xyes; then
1314             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1315         fi
1316
1317         case "$host_cpu" in
1318         powerpc* | sparc*)
1319             # Build only the drivers for cards that exist on PowerPC/sparc
1320             if test "x$with_dri_drivers" = "xyes"; then
1321                 with_dri_drivers="r200 radeon swrast"
1322             fi
1323             ;;
1324         esac
1325         ;;
1326     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1327         DEFINES="$DEFINES -DHAVE_ALIAS"
1328         ;;
1329     gnu*)
1330         DEFINES="$DEFINES -DHAVE_ALIAS"
1331         ;;
1332     cygwin*)
1333         if test "x$with_dri_drivers" = "xyes"; then
1334             with_dri_drivers="swrast"
1335         fi
1336         ;;
1337     darwin*)
1338         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1339         if test "x$with_dri_drivers" = "xyes"; then
1340             with_dri_drivers="swrast"
1341         fi
1342         ;;
1343     esac
1344
1345     # default drivers
1346     if test "x$with_dri_drivers" = "xyes"; then
1347         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1348     fi
1349
1350     # Check for expat
1351     PKG_CHECK_MODULES([EXPAT], [expat], [],
1352         # expat version 2.0 and earlier do not provide expat.pc
1353         [AC_CHECK_HEADER([expat.h],[],
1354                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1355          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1356                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1357          EXPAT_LIBS="-lexpat"])
1358
1359     DRICOMMON_NEED_LIBDRM=no
1360     # If we are building any DRI driver other than swrast.
1361     if test -n "$with_dri_drivers"; then
1362         if test "x$with_dri_drivers" != xswrast; then
1363             # ... libdrm is required
1364             if test "x$have_libdrm" != xyes; then
1365                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1366             fi
1367             DRICOMMON_NEED_LIBDRM=yes
1368         fi
1369     fi
1370
1371     # If we're building any gallium DRI driver other than swrast
1372     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1373         if test "x$with_gallium_drivers" != xswrast; then
1374             # ... build a libdrm aware dricommon
1375             DRICOMMON_NEED_LIBDRM=yes
1376         fi
1377     fi
1378
1379     # put all the necessary libs together
1380     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1381 fi
1382
1383 AC_SUBST([DRI_LIB_DEPS])
1384
1385 DRI_DIRS=''
1386 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1387 if test -n "$with_dri_drivers"; then
1388     if test "x$enable_opengl" != xyes; then
1389         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1390     fi
1391
1392     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1393     for driver in $dri_drivers; do
1394         DRI_DIRS="$DRI_DIRS $driver"
1395         case "x$driver" in
1396         xi915)
1397             HAVE_I915_DRI=yes;
1398             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1399             ;;
1400         xi965)
1401             HAVE_I965_DRI=yes;
1402             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1403             ;;
1404         xnouveau)
1405             HAVE_NOUVEAU_DRI=yes;
1406             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1407             ;;
1408         xradeon)
1409             HAVE_RADEON_DRI=yes;
1410             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1411             ;;
1412         xr200)
1413             HAVE_R200_DRI=yes;
1414             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1415             ;;
1416         xswrast)
1417             HAVE_SWRAST_DRI=yes;
1418             ;;
1419         *)
1420             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1421             ;;
1422         esac
1423     done
1424     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1425 fi
1426
1427 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1428 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1429                                   "x$enable_osmesa" = xyes -o \
1430                                   -n "$DRI_DIRS")
1431
1432 dnl
1433 dnl OSMesa configuration
1434 dnl
1435
1436 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1437 AC_ARG_WITH([osmesa-bits],
1438     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1439         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1440     [osmesa_bits="$withval"],
1441     [osmesa_bits=8])
1442 if test "x$osmesa_bits" != x8; then
1443     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1444         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1445         osmesa_bits=8
1446     fi
1447 fi
1448 case "x$osmesa_bits" in
1449 x8)
1450     OSMESA_LIB="${OSMESA_LIB}"
1451     ;;
1452 x16|x32)
1453     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1454     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1455     ;;
1456 *)
1457     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1458     ;;
1459 esac
1460
1461 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1462     # only link libraries with osmesa if shared
1463     if test "$enable_static" = no; then
1464         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1465     else
1466         OSMESA_LIB_DEPS=""
1467     fi
1468     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1469 fi
1470
1471 AC_SUBST([OSMESA_LIB_DEPS])
1472 AC_SUBST([OSMESA_PC_REQ])
1473 AC_SUBST([OSMESA_PC_LIB_PRIV])
1474
1475 dnl
1476 dnl gbm configuration
1477 dnl
1478 if test "x$enable_gbm" = xauto; then
1479     case "$with_egl_platforms" in
1480         *drm*)
1481             enable_gbm=yes ;;
1482          *)
1483             enable_gbm=no ;;
1484     esac
1485 fi
1486 if test "x$enable_gbm" = xyes; then
1487     if test "x$need_pci_id$have_pci_id" = xyesno; then
1488         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1489     fi
1490
1491     if test "x$enable_dri" = xyes; then
1492         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1493         if test "x$enable_shared_glapi" = xno; then
1494             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1495         fi
1496     else
1497         # Strictly speaking libgbm does not require --enable-dri, although
1498         # both of its backends do. Thus one can build libgbm without any
1499         # backends if --disable-dri is set.
1500         # To avoid unnecessary complexity of checking if at least one backend
1501         # is available when building, just mandate --enable-dri.
1502         AC_MSG_ERROR([gbm requires --enable-dri])
1503     fi
1504 fi
1505 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1506 if test "x$need_pci_id$have_libudev" = xyesyes; then
1507     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1508 else
1509     GBM_PC_REQ_PRIV=""
1510 fi
1511 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1512 AC_SUBST([GBM_PC_REQ_PRIV])
1513 AC_SUBST([GBM_PC_LIB_PRIV])
1514
1515 dnl
1516 dnl EGL configuration
1517 dnl
1518 EGL_CLIENT_APIS=""
1519
1520 if test "x$enable_egl" = xyes; then
1521     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1522
1523     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1524
1525     if test "$enable_static" != yes; then
1526         if test "x$enable_dri" = xyes; then
1527             HAVE_EGL_DRIVER_DRI2=1
1528         fi
1529
1530     fi
1531 fi
1532 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1533 AC_SUBST([EGL_LIB_DEPS])
1534
1535 dnl
1536 dnl XA configuration
1537 dnl
1538 if test "x$enable_xa" = xyes; then
1539     if test "x$with_gallium_drivers" = xswrast; then
1540        AC_MSG_ERROR([
1541           Building xa requires at least one non swrast gallium driver.
1542           If you are looking to use libxatracker.so with the VMware driver,
1543           make sure to include svga in the gallium drivers list, apart from
1544           enabling XA.
1545           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1546     fi
1547     enable_gallium_loader=$enable_shared_pipe_drivers
1548 fi
1549 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1550
1551 dnl
1552 dnl Gallium G3DVL configuration
1553 dnl
1554 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1555     if test "x$enable_xvmc" = xauto; then
1556         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1557     fi
1558
1559     if test "x$enable_vdpau" = xauto; then
1560         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1561     fi
1562
1563     if test "x$enable_omx" = xauto; then
1564         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1565     fi
1566
1567     if test "x$enable_va" = xauto; then
1568         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1569     fi
1570 fi
1571
1572 if test "x$enable_dri" = xyes -o \
1573         "x$enable_xvmc" = xyes -o \
1574         "x$enable_vdpau" = xyes -o \
1575         "x$enable_omx" = xyes -o \
1576         "x$enable_va" = xyes; then
1577     need_gallium_vl=yes
1578 fi
1579 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1580
1581 if test "x$enable_xvmc" = xyes -o \
1582         "x$enable_vdpau" = xyes -o \
1583         "x$enable_omx" = xyes -o \
1584         "x$enable_va" = xyes; then
1585     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1586     need_gallium_vl_winsys=yes
1587 fi
1588 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1589
1590 if test "x$enable_xvmc" = xyes; then
1591     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1592     enable_gallium_loader=$enable_shared_pipe_drivers
1593 fi
1594 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1595
1596 if test "x$enable_vdpau" = xyes; then
1597     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1598     enable_gallium_loader=$enable_shared_pipe_drivers
1599 fi
1600 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1601
1602 if test "x$enable_omx" = xyes; then
1603     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1604     enable_gallium_loader=$enable_shared_pipe_drivers
1605 fi
1606 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1607
1608 if test "x$enable_va" = xyes; then
1609     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1610     enable_gallium_loader=$enable_shared_pipe_drivers
1611 fi
1612 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1613
1614 dnl
1615 dnl Nine Direct3D9 configuration
1616 dnl
1617 if test "x$enable_nine" = xyes; then
1618     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1619         AC_MSG_ERROR([nine requires the gallium swrast driver])
1620     fi
1621     if test "x$with_gallium_drivers" == xswrast; then
1622         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1623     fi
1624     if test "x$enable_dri3" = xno; then
1625         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1626     fi
1627
1628     enable_gallium_loader=$enable_shared_pipe_drivers
1629 fi
1630 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1631
1632 dnl
1633 dnl OpenCL configuration
1634 dnl
1635
1636 AC_ARG_WITH([libclc-path],
1637    [AS_HELP_STRING([--with-libclc-path],
1638          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1639    [LIBCLC_PATH="$withval"],
1640    [LIBCLC_PATH=''])
1641
1642 if test -n "$LIBCLC_PATH"; then
1643    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1644                   Please review the updated build instructions for clover:
1645                   http://dri.freedesktop.org/wiki/GalliumCompute])
1646 fi
1647
1648
1649 AC_ARG_WITH([clang-libdir],
1650    [AS_HELP_STRING([--with-clang-libdir],
1651          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1652    [CLANG_LIBDIR="$withval"],
1653    [CLANG_LIBDIR=''])
1654
1655 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1656 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1657
1658 if test "x$enable_opencl" = xyes; then
1659     if test -z "$with_gallium_drivers"; then
1660         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1661     fi
1662
1663     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1664         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1665     fi
1666
1667     if test "x$have_libclc" = xno; then
1668         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1669                     Make sure the directory containing libclc.pc is specified in your
1670                     PKG_CONFIG_PATH environment variable.
1671                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1672     else
1673         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1674         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1675         AC_SUBST([LIBCLC_INCLUDEDIR])
1676         AC_SUBST([LIBCLC_LIBEXECDIR])
1677     fi
1678
1679     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1680     enable_gallium_loader=yes
1681
1682     if test "x$enable_opencl_icd" = xyes; then
1683         OPENCL_LIBNAME="MesaOpenCL"
1684     else
1685         OPENCL_LIBNAME="OpenCL"
1686     fi
1687
1688     if test "x$have_libelf" != xyes; then
1689        AC_MSG_ERROR([Clover requires libelf])
1690     fi
1691 fi
1692 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1693 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1694 AC_SUBST([OPENCL_LIBNAME])
1695
1696 dnl
1697 dnl Gallium configuration
1698 dnl
1699 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1700
1701 AC_SUBST([LLVM_BINDIR])
1702 AC_SUBST([LLVM_CFLAGS])
1703 AC_SUBST([LLVM_CPPFLAGS])
1704 AC_SUBST([LLVM_CXXFLAGS])
1705 AC_SUBST([LLVM_LIBDIR])
1706 AC_SUBST([LLVM_LIBS])
1707 AC_SUBST([LLVM_LDFLAGS])
1708 AC_SUBST([LLVM_INCLUDEDIR])
1709 AC_SUBST([LLVM_VERSION])
1710 AC_SUBST([CLANG_RESOURCE_DIR])
1711
1712 case "x$enable_opengl$enable_gles1$enable_gles2" in
1713 x*yes*)
1714     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1715     ;;
1716 esac
1717
1718 AC_SUBST([VG_LIB_DEPS])
1719 AC_SUBST([EGL_CLIENT_APIS])
1720
1721 dnl
1722 dnl EGL Platforms configuration
1723 dnl
1724 AC_ARG_WITH([egl-platforms],
1725     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1726         [comma delimited native platforms libEGL supports, e.g.
1727         "x11,drm" @<:@default=auto@:>@])],
1728     [with_egl_platforms="$withval"],
1729     [if test "x$enable_egl" = xyes; then
1730         with_egl_platforms="x11"
1731     else
1732         with_egl_platforms=""
1733     fi])
1734
1735 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1736     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1737 fi
1738
1739 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1740         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1741         WAYLAND_SCANNER='')
1742 if test "x$WAYLAND_SCANNER" = x; then
1743     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1744 fi
1745
1746 # Do per-EGL platform setups and checks
1747 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1748 for plat in $egl_platforms; do
1749         case "$plat" in
1750         wayland)
1751                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1752
1753                 if test "x$WAYLAND_SCANNER" = x; then
1754                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1755                 fi
1756                 ;;
1757
1758         x11)
1759                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1760                 ;;
1761
1762         drm)
1763                 test "x$enable_gbm" = "xno" &&
1764                         AC_MSG_ERROR([EGL platform drm needs gbm])
1765                 test "x$have_libdrm" != xyes &&
1766                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1767                 ;;
1768
1769         android|fbdev|gdi|null)
1770                 ;;
1771
1772         *)
1773                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1774                 ;;
1775         esac
1776
1777         case "$plat$need_pci_id$have_pci_id" in
1778                 waylandyesno|drmyesno)
1779                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1780         esac
1781 done
1782
1783 # libEGL wants to default to the first platform specified in
1784 # ./configure.  parse that here.
1785 if test "x$egl_platforms" != "x"; then
1786     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1787     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1788 else
1789     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1790 fi
1791
1792 if echo "$egl_platforms" | grep -q 'x11'; then
1793     NEED_WINSYS_XLIB=yes
1794 fi
1795 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1796 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1797 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1798 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1799 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1800
1801 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1802
1803 AC_SUBST([EGL_NATIVE_PLATFORM])
1804 AC_SUBST([EGL_CFLAGS])
1805
1806 # If we don't have the X11 platform, set this define so we don't try to include
1807 # the X11 headers.
1808 if ! echo "$egl_platforms" | grep -q 'x11'; then
1809     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1810     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1811 fi
1812
1813 AC_ARG_WITH([max-width],
1814     [AS_HELP_STRING([--with-max-width=N],
1815                     [Maximum framebuffer width (4096)])],
1816     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1817      AS_IF([test "${withval}" -gt "4096"],
1818            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1819 )
1820 AC_ARG_WITH([max-height],
1821     [AS_HELP_STRING([--with-max-height=N],
1822                     [Maximum framebuffer height (4096)])],
1823     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1824      AS_IF([test "${withval}" -gt "4096"],
1825            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1826 )
1827
1828 dnl
1829 dnl Gallium LLVM
1830 dnl
1831 AC_ARG_ENABLE([gallium-llvm],
1832     [AS_HELP_STRING([--enable-gallium-llvm],
1833         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1834     [enable_gallium_llvm="$enableval"],
1835     [enable_gallium_llvm=auto])
1836
1837 AC_ARG_ENABLE([llvm-shared-libs],
1838     [AS_HELP_STRING([--enable-llvm-shared-libs],
1839         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1840     [enable_llvm_shared_libs="$enableval"],
1841     [enable_llvm_shared_libs=yes])
1842
1843 AC_ARG_WITH([llvm-prefix],
1844     [AS_HELP_STRING([--with-llvm-prefix],
1845         [Prefix for LLVM installations in non-standard locations])],
1846     [llvm_prefix="$withval"],
1847     [llvm_prefix=''])
1848
1849
1850 # Call this inside ` ` to get the return value.
1851 # $1 is the llvm-config command with arguments.
1852 strip_unwanted_llvm_flags() {
1853     # Use \> (marks the end of the word)
1854     echo `$1` | sed \
1855         -e 's/-DNDEBUG\>//g' \
1856         -e 's/-D_GNU_SOURCE\>//g' \
1857         -e 's/-pedantic\>//g' \
1858         -e 's/-Wcovered-switch-default\>//g' \
1859         -e 's/-O.\>//g' \
1860         -e 's/-g\>//g' \
1861         -e 's/-Wall\>//g' \
1862         -e 's/-Wcast-qual\>//g' \
1863         -e 's/-Woverloaded-virtual\>//g' \
1864         -e 's/-fcolor-diagnostics\>//g' \
1865         -e 's/-fdata-sections\>//g' \
1866         -e 's/-ffunction-sections\>//g' \
1867         -e 's/-fno-exceptions\>//g' \
1868         -e 's/-fomit-frame-pointer\>//g' \
1869         -e 's/-fvisibility-inlines-hidden\>//g' \
1870         -e 's/-fPIC\>//g' \
1871         -e 's/-fstack-protector-strong\>//g'
1872 }
1873
1874
1875 if test -z "$with_gallium_drivers"; then
1876     enable_gallium_llvm=no
1877 fi
1878 if test "x$enable_gallium_llvm" = xauto; then
1879     case "$host_cpu" in
1880     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1881     esac
1882 fi
1883 if test "x$enable_gallium_llvm" = xyes; then
1884     if test -n "$llvm_prefix"; then
1885         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1886     else
1887         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1888     fi
1889
1890     if test "x$LLVM_CONFIG" != xno; then
1891         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1892         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1893         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1894         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1895         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1896         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1897         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1898         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1899
1900         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1901             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1902         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1903             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1904
1905         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1906         if test -z "$LLVM_VERSION_PATCH"; then
1907             LLVM_VERSION_PATCH=0
1908         fi
1909
1910         if test -n "${LLVM_VERSION_MAJOR}"; then
1911             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1912         else
1913             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1914         fi
1915
1916         LLVM_REQUIRED_VERSION_MAJOR="3"
1917         LLVM_REQUIRED_VERSION_MINOR="3"
1918         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1919             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1920         fi
1921
1922         LLVM_COMPONENTS="engine bitwriter"
1923         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1924             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1925         fi
1926
1927         if test "x$enable_opencl" = xyes; then
1928             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1929             # LLVM 3.3 >= 177971 requires IRReader
1930             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1931                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1932             fi
1933             # LLVM 3.4 requires Option
1934             if $LLVM_CONFIG --components | grep -qw 'option'; then
1935                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1936             fi
1937             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1938             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1939                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1940             fi
1941             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1942                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1943             fi
1944         fi
1945         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1946         MESA_LLVM=1
1947
1948         dnl Check for Clang internal headers
1949         if test "x$enable_opencl" = xyes; then
1950             if test -z "$CLANG_LIBDIR"; then
1951                 CLANG_LIBDIR=${LLVM_LIBDIR}
1952             fi
1953             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1954             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1955                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1956         fi
1957     else
1958         MESA_LLVM=0
1959         LLVM_VERSION_INT=0
1960     fi
1961 else
1962     MESA_LLVM=0
1963     LLVM_VERSION_INT=0
1964
1965     if test "x$enable_opencl" = xyes; then
1966         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1967     fi
1968 fi
1969
1970 dnl Directory for XVMC libs
1971 AC_ARG_WITH([xvmc-libdir],
1972     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1973         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1974     [XVMC_LIB_INSTALL_DIR="$withval"],
1975     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1976 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1977
1978 dnl
1979 dnl Gallium Tests
1980 dnl
1981 if test "x$enable_gallium_tests" = xyes; then
1982     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1983     enable_gallium_loader=yes
1984 fi
1985 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1986
1987 dnl Directory for VDPAU libs
1988 AC_ARG_WITH([vdpau-libdir],
1989     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1990         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1991     [VDPAU_LIB_INSTALL_DIR="$withval"],
1992     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1993 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1994
1995 dnl Directory for OMX libs
1996
1997 AC_ARG_WITH([omx-libdir],
1998     [AS_HELP_STRING([--with-omx-libdir=DIR],
1999         [directory for the OMX libraries])],
2000     [OMX_LIB_INSTALL_DIR="$withval"],
2001     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2002 AC_SUBST([OMX_LIB_INSTALL_DIR])
2003
2004 dnl Directory for VA libs
2005
2006 AC_ARG_WITH([va-libdir],
2007     [AS_HELP_STRING([--with-va-libdir=DIR],
2008         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2009     [VA_LIB_INSTALL_DIR="$withval"],
2010     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2011 AC_SUBST([VA_LIB_INSTALL_DIR])
2012
2013 AC_ARG_WITH([d3d-libdir],
2014     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2015         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2016     [D3D_DRIVER_INSTALL_DIR="$withval"],
2017     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2018 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2019
2020 dnl
2021 dnl Gallium helper functions
2022 dnl
2023 gallium_require_drm() {
2024     if test "x$have_libdrm" != xyes; then
2025        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2026     fi
2027 }
2028
2029 gallium_require_llvm() {
2030     if test "x$MESA_LLVM" = x0; then
2031         case "$host" in *gnux32) return;; esac
2032         case "$host_cpu" in
2033         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2034         esac
2035     fi
2036 }
2037
2038 gallium_require_drm_loader() {
2039     if test "x$enable_gallium_loader" = xyes; then
2040         if test "x$need_pci_id$have_pci_id" = xyesno; then
2041             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2042         fi
2043         enable_gallium_drm_loader=yes
2044     fi
2045     if test "x$enable_va" = xyes && test "x$7" != x; then
2046          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2047     fi
2048 }
2049
2050 require_egl_drm() {
2051     case "$with_egl_platforms" in
2052         *drm*)
2053             ;;
2054          *)
2055             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2056             ;;
2057     esac
2058     if test "x$enable_gbm" != xyes; then
2059             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2060     fi
2061 }
2062
2063 radeon_llvm_check() {
2064     if test "x$enable_gallium_llvm" != "xyes"; then
2065         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2066     fi
2067     LLVM_REQUIRED_VERSION_MAJOR="3"
2068     LLVM_REQUIRED_VERSION_MINOR="4"
2069     LLVM_REQUIRED_VERSION_PATCH="2"
2070     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2071         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2072     fi
2073     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2074         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2075                       sources with the --enable-experimental-targets=R600
2076                       configure flag])
2077     fi
2078     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2079     NEED_RADEON_LLVM=yes
2080     if test "x$have_libelf" != xyes; then
2081        AC_MSG_ERROR([$1 requires libelf when using llvm])
2082     fi
2083 }
2084
2085 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2086 if test -n "$with_gallium_drivers"; then
2087     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2088     for driver in $gallium_drivers; do
2089         case "x$driver" in
2090         xsvga)
2091             HAVE_GALLIUM_SVGA=yes
2092             gallium_require_drm "svga"
2093             gallium_require_drm_loader
2094             ;;
2095         xi915)
2096             HAVE_GALLIUM_I915=yes
2097             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2098             gallium_require_drm "Gallium i915"
2099             gallium_require_drm_loader
2100             ;;
2101         xilo)
2102             HAVE_GALLIUM_ILO=yes
2103             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2104             gallium_require_drm "Gallium i965/ilo"
2105             gallium_require_drm_loader
2106             ;;
2107         xr300)
2108             HAVE_GALLIUM_R300=yes
2109             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2110             gallium_require_drm "Gallium R300"
2111             gallium_require_drm_loader
2112             gallium_require_llvm "Gallium R300"
2113             ;;
2114         xr600)
2115             HAVE_GALLIUM_R600=yes
2116             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2117             gallium_require_drm "Gallium R600"
2118             gallium_require_drm_loader
2119             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2120                 radeon_llvm_check "r600g"
2121                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2122             fi
2123             if test "x$enable_r600_llvm" = xyes; then
2124                 USE_R600_LLVM_COMPILER=yes;
2125             fi
2126             if test "x$enable_opencl" = xyes; then
2127                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2128             fi
2129             ;;
2130         xradeonsi)
2131             HAVE_GALLIUM_RADEONSI=yes
2132             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2133             gallium_require_drm "radeonsi"
2134             gallium_require_drm_loader
2135             radeon_llvm_check "radeonsi"
2136             require_egl_drm "radeonsi"
2137             ;;
2138         xnouveau)
2139             HAVE_GALLIUM_NOUVEAU=yes
2140             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2141             gallium_require_drm "nouveau"
2142             gallium_require_drm_loader
2143             ;;
2144         xfreedreno)
2145             HAVE_GALLIUM_FREEDRENO=yes
2146             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2147             gallium_require_drm "freedreno"
2148             gallium_require_drm_loader
2149             ;;
2150         xswrast)
2151             HAVE_GALLIUM_SOFTPIPE=yes
2152             if test "x$MESA_LLVM" = x1; then
2153                 HAVE_GALLIUM_LLVMPIPE=yes
2154             fi
2155             ;;
2156         xvc4)
2157             HAVE_GALLIUM_VC4=yes
2158             gallium_require_drm "vc4"
2159             gallium_require_drm_loader
2160
2161             case "$host_cpu" in
2162                 i?86 | x86_64 | amd64)
2163                 USE_VC4_SIMULATOR=yes
2164                 ;;
2165             esac
2166             ;;
2167         *)
2168             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2169             ;;
2170         esac
2171     done
2172 fi
2173
2174 dnl Set LLVM_LIBS - This is done after the driver configuration so
2175 dnl that drivers can add additional components to LLVM_COMPONENTS.
2176 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2177 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2178 dnl this was causing the same libraries to be appear multiple times
2179 dnl in LLVM_LIBS.
2180
2181 if test "x$MESA_LLVM" != x0; then
2182
2183     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2184
2185     if test "x$enable_llvm_shared_libs" = xyes; then
2186         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2187         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2188         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2189
2190         if test "x$llvm_have_one_so" = xyes; then
2191             dnl LLVM was built using auto*, so there is only one shared object.
2192             LLVM_LIBS="-l$LLVM_SO_NAME"
2193         else
2194             dnl If LLVM was built with CMake, there will be one shared object per
2195             dnl component.
2196             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2197                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2198         Please make sure you have built llvm with the --enable-shared option
2199         and that your llvm libraries are installed in $LLVM_LIBDIR
2200         If you have installed your llvm libraries to a different directory you
2201         can use the --with-llvm-prefix= configure flag to specify this directory.
2202         NOTE: Mesa is attempting to use llvm shared libraries by default.
2203         If you do not want to build with llvm shared libraries and instead want to
2204         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2205         invocation and rebuild.])])
2206
2207            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2208            dnl install uses a shared object for each component and we have
2209            dnl already added all of these objects to LLVM_LIBS.
2210         fi
2211     else
2212         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2213         dnl We need to link to llvm system libs when using static libs
2214         dnl However, only llvm 3.5+ provides --system-libs
2215         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2216             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2217         fi
2218     fi
2219 fi
2220
2221 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2222 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2223 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2224 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2225 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2226 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2227 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2228                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2229 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2230 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2231 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2232 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2233 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2234
2235 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2236
2237 # NOTE: anything using xcb or other client side libs ends up in separate
2238 #       _CLIENT variables.  The pipe loader is built in two variants,
2239 #       one that is standalone and does not link any x client libs (for
2240 #       use by XA tracker in particular, but could be used in any case
2241 #       where communication with xserver is not desired).
2242 if test "x$enable_gallium_loader" = xyes; then
2243     if test "x$NEED_WINSYS_XLIB" = xyes; then
2244         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2245     fi
2246
2247     if test "x$enable_dri" = xyes; then
2248         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2249     fi
2250
2251     if test "x$enable_gallium_drm_loader" = xyes; then
2252         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2253         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2254                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2255         if test "x$pipe_loader_have_xcb" = xyes; then
2256             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2257             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2258         fi
2259     fi
2260
2261     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2262     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2263
2264     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2265     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2266     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2267     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2268 fi
2269
2270 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2271 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2272 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2273 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2274 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2275 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2276
2277 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2278                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2279                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2280 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2281 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2282 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2283 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2284 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2285 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2286 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2287 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2288 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2289     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2290 fi
2291
2292 AC_SUBST([ELF_LIB])
2293
2294 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2295 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2296 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2297 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2298 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2299
2300 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2301 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2302 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2303
2304 AC_SUBST([NINE_MAJOR], 1)
2305 AC_SUBST([NINE_MINOR], 0)
2306 AC_SUBST([NINE_TINY], 0)
2307 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2308
2309 AC_SUBST([VDPAU_MAJOR], 1)
2310 AC_SUBST([VDPAU_MINOR], 0)
2311
2312 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2313 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2314 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2315 AC_SUBST([VA_MINOR], $VA_MINOR)
2316
2317 AC_SUBST([XVMC_MAJOR], 1)
2318 AC_SUBST([XVMC_MINOR], 0)
2319
2320 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2321 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2322 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2323 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2324
2325 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2326 AC_SUBST([XA_MINOR], $XA_MINOR)
2327 AC_SUBST([XA_TINY], $XA_TINY)
2328 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2329
2330 dnl Restore LDFLAGS and CPPFLAGS
2331 LDFLAGS="$_SAVE_LDFLAGS"
2332 CPPFLAGS="$_SAVE_CPPFLAGS"
2333
2334 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2335 if test "x$acv_mesa_CLANG" = xyes; then
2336     CFLAGS="$CFLAGS -Qunused-arguments"
2337     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2338 fi
2339
2340 dnl Add user CFLAGS and CXXFLAGS
2341 CFLAGS="$CFLAGS $USER_CFLAGS"
2342 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2343
2344 dnl Substitute the config
2345 AC_CONFIG_FILES([Makefile
2346                 src/Makefile
2347                 src/egl/drivers/dri2/Makefile
2348                 src/egl/main/Makefile
2349                 src/egl/main/egl.pc
2350                 src/egl/wayland/wayland-drm/Makefile
2351                 src/egl/wayland/wayland-egl/Makefile
2352                 src/egl/wayland/wayland-egl/wayland-egl.pc
2353                 src/gallium/Makefile
2354                 src/gallium/auxiliary/Makefile
2355                 src/gallium/auxiliary/pipe-loader/Makefile
2356                 src/gallium/drivers/freedreno/Makefile
2357                 src/gallium/drivers/galahad/Makefile
2358                 src/gallium/drivers/i915/Makefile
2359                 src/gallium/drivers/ilo/Makefile
2360                 src/gallium/drivers/llvmpipe/Makefile
2361                 src/gallium/drivers/noop/Makefile
2362                 src/gallium/drivers/nouveau/Makefile
2363                 src/gallium/drivers/r300/Makefile
2364                 src/gallium/drivers/r600/Makefile
2365                 src/gallium/drivers/radeon/Makefile
2366                 src/gallium/drivers/radeonsi/Makefile
2367                 src/gallium/drivers/rbug/Makefile
2368                 src/gallium/drivers/softpipe/Makefile
2369                 src/gallium/drivers/svga/Makefile
2370                 src/gallium/drivers/trace/Makefile
2371                 src/gallium/drivers/vc4/Makefile
2372                 src/gallium/drivers/vc4/kernel/Makefile
2373                 src/gallium/state_trackers/clover/Makefile
2374                 src/gallium/state_trackers/dri/Makefile
2375                 src/gallium/state_trackers/glx/xlib/Makefile
2376                 src/gallium/state_trackers/nine/Makefile
2377                 src/gallium/state_trackers/omx/Makefile
2378                 src/gallium/state_trackers/osmesa/Makefile
2379                 src/gallium/state_trackers/va/Makefile
2380                 src/gallium/state_trackers/vdpau/Makefile
2381                 src/gallium/state_trackers/xa/Makefile
2382                 src/gallium/state_trackers/xvmc/Makefile
2383                 src/gallium/targets/d3dadapter9/Makefile
2384                 src/gallium/targets/d3dadapter9/d3d.pc
2385                 src/gallium/targets/dri/Makefile
2386                 src/gallium/targets/libgl-xlib/Makefile
2387                 src/gallium/targets/omx/Makefile
2388                 src/gallium/targets/opencl/Makefile
2389                 src/gallium/targets/osmesa/Makefile
2390                 src/gallium/targets/osmesa/osmesa.pc
2391                 src/gallium/targets/pipe-loader/Makefile
2392                 src/gallium/targets/va/Makefile
2393                 src/gallium/targets/vdpau/Makefile
2394                 src/gallium/targets/xa/Makefile
2395                 src/gallium/targets/xa/xatracker.pc
2396                 src/gallium/targets/xvmc/Makefile
2397                 src/gallium/tests/trivial/Makefile
2398                 src/gallium/tests/unit/Makefile
2399                 src/gallium/winsys/freedreno/drm/Makefile
2400                 src/gallium/winsys/i915/drm/Makefile
2401                 src/gallium/winsys/intel/drm/Makefile
2402                 src/gallium/winsys/nouveau/drm/Makefile
2403                 src/gallium/winsys/radeon/drm/Makefile
2404                 src/gallium/winsys/svga/drm/Makefile
2405                 src/gallium/winsys/sw/dri/Makefile
2406                 src/gallium/winsys/sw/fbdev/Makefile
2407                 src/gallium/winsys/sw/kms-dri/Makefile
2408                 src/gallium/winsys/sw/null/Makefile
2409                 src/gallium/winsys/sw/wayland/Makefile
2410                 src/gallium/winsys/sw/wrapper/Makefile
2411                 src/gallium/winsys/sw/xlib/Makefile
2412                 src/gallium/winsys/vc4/drm/Makefile
2413                 src/gbm/Makefile
2414                 src/gbm/main/gbm.pc
2415                 src/glsl/Makefile
2416                 src/glx/Makefile
2417                 src/glx/apple/Makefile
2418                 src/glx/tests/Makefile
2419                 src/gtest/Makefile
2420                 src/loader/Makefile
2421                 src/mapi/Makefile
2422                 src/mapi/es1api/glesv1_cm.pc
2423                 src/mapi/es2api/glesv2.pc
2424                 src/mapi/glapi/gen/Makefile
2425                 src/mesa/Makefile
2426                 src/mesa/gl.pc
2427                 src/mesa/drivers/dri/dri.pc
2428                 src/mesa/drivers/dri/common/Makefile
2429                 src/mesa/drivers/dri/common/xmlpool/Makefile
2430                 src/mesa/drivers/dri/i915/Makefile
2431                 src/mesa/drivers/dri/i965/Makefile
2432                 src/mesa/drivers/dri/Makefile
2433                 src/mesa/drivers/dri/nouveau/Makefile
2434                 src/mesa/drivers/dri/r200/Makefile
2435                 src/mesa/drivers/dri/radeon/Makefile
2436                 src/mesa/drivers/dri/swrast/Makefile
2437                 src/mesa/drivers/osmesa/Makefile
2438                 src/mesa/drivers/osmesa/osmesa.pc
2439                 src/mesa/drivers/x11/Makefile
2440                 src/mesa/main/tests/Makefile
2441                 src/util/Makefile
2442                 src/util/tests/hash_table/Makefile])
2443
2444 AC_OUTPUT
2445
2446 dnl
2447 dnl Output some configuration info for the user
2448 dnl
2449 echo ""
2450 echo "        prefix:          $prefix"
2451 echo "        exec_prefix:     $exec_prefix"
2452 echo "        libdir:          $libdir"
2453 echo "        includedir:      $includedir"
2454
2455 dnl API info
2456 echo ""
2457 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2458
2459 dnl Driver info
2460 echo ""
2461 case "x$enable_osmesa$enable_gallium_osmesa" in
2462 xnoyes)
2463         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2464         ;;
2465 xyesno)
2466         echo "        OSMesa:          lib$OSMESA_LIB"
2467         ;;
2468 xnono)
2469         echo "        OSMesa:          no"
2470         ;;
2471 esac
2472
2473 echo ""
2474 if test "x$enable_dri" != xno; then
2475         echo "        DRI platform:    $dri_platform"
2476         if test -z "$DRI_DIRS"; then
2477             echo "        DRI drivers:     no"
2478         else
2479             echo "        DRI drivers:     $DRI_DIRS"
2480         fi
2481         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2482 fi
2483
2484 case "x$enable_glx$enable_xlib_glx" in
2485 xyesyes)
2486     echo "        GLX:             Xlib-based"
2487     ;;
2488 xyesno)
2489     echo "        GLX:             DRI-based"
2490     ;;
2491 *)
2492     echo "        GLX:             $enable_glx"
2493     ;;
2494 esac
2495
2496 dnl EGL
2497 echo ""
2498 echo "        EGL:             $enable_egl"
2499 if test "$enable_egl" = yes; then
2500     echo "        EGL platforms:   $egl_platforms"
2501
2502     egl_drivers=""
2503     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2504         egl_drivers="$egl_drivers builtin:egl_dri2"
2505     fi
2506
2507     echo "        EGL drivers:    $egl_drivers"
2508 fi
2509
2510 echo ""
2511 if test "x$MESA_LLVM" = x1; then
2512     echo "        llvm:            yes"
2513     echo "        llvm-config:     $LLVM_CONFIG"
2514     echo "        llvm-version:    $LLVM_VERSION"
2515 else
2516     echo "        llvm:            no"
2517 fi
2518
2519 echo ""
2520 if test -n "$with_gallium_drivers"; then
2521     echo "        Gallium:         yes"
2522 else
2523     echo "        Gallium:         no"
2524 fi
2525
2526 dnl Shader cache
2527 echo ""
2528 echo "        Shader cache:    $enable_shader_cache"
2529 if test "x$enable_shader_cache" = "xyes"; then
2530     echo "        With SHA1 from:  $with_sha1"
2531 fi
2532
2533 dnl Libraries
2534 echo ""
2535 echo "        Shared libs:     $enable_shared"
2536 echo "        Static libs:     $enable_static"
2537 echo "        Shared-glapi:    $enable_shared_glapi"
2538
2539 dnl Compiler options
2540 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2541 cflags=`echo $CFLAGS | \
2542     $SED 's/^ *//;s/  */ /;s/ *$//'`
2543 cxxflags=`echo $CXXFLAGS | \
2544     $SED 's/^ *//;s/  */ /;s/ *$//'`
2545 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2546 echo ""
2547 echo "        CFLAGS:          $cflags"
2548 echo "        CXXFLAGS:        $cxxflags"
2549 echo "        Macros:          $defines"
2550 echo ""
2551 if test "x$MESA_LLVM" = x1; then
2552     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2553     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2554     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2555     echo ""
2556 fi
2557 echo "        PYTHON2:         $PYTHON2"
2558
2559 echo ""
2560 echo "        Run '${MAKE-make}' to build Mesa"
2561 echo ""