configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 123
 124 dnl Make sure the pkg-config macros are defined
 125 m4_ifndef([PKG_PROG_PKG_CONFIG],
 126     [m4_fatal([Could not locate the pkg-config autoconf macros.
 127   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 128   are in a different location, try setting the environment variable
 129   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 130 PKG_PROG_PKG_CONFIG()
 131
 132 dnl LIB_DIR - library basename
 133 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 134 AC_SUBST([LIB_DIR])
 135
 136 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 137 _SAVE_LDFLAGS="$LDFLAGS"
 138 _SAVE_CPPFLAGS="$CPPFLAGS"
 139
 140 dnl Compiler macros
 141 DEFINES=""
 142 AC_SUBST([DEFINES])
 143 case "$host_os" in
 144 linux*|*-gnu*|gnu*)
 145     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 146     ;;
 147 solaris*)
 148     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 149     ;;
 150 cygwin*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD"
 152     ;;
 153 esac
 154
 155 dnl Add flags for gcc and g++
 156 if test "x$GCC" = xyes; then
 157     case "$host_os" in
 158     cygwin*)
 159         CFLAGS="$CFLAGS -Wall -std=gnu99"
 160         ;;
 161     *)
 162         CFLAGS="$CFLAGS -Wall -std=c99"
 163         ;;
 164     esac
 165
 166     # Enable -Werror=implicit-function-declaration and
 167     # -Werror=missing-prototypes, if available, or otherwise, just
 168     # -Wmissing-prototypes.  This is particularly useful to avoid
 169     # generating a loadable driver module that has undefined symbols.
 170     save_CFLAGS="$CFLAGS"
 171     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 172     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 173     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 174     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 175                    AC_MSG_RESULT([yes]),
 176                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 177                     AC_MSG_RESULT([no])]);
 178
 179     # Enable -fvisibility=hidden if using a gcc that supports it
 180     save_CFLAGS="$CFLAGS"
 181     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 182     VISIBILITY_CFLAGS="-fvisibility=hidden"
 183     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 185                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 186
 187     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 188     CFLAGS=$save_CFLAGS
 189
 190     # Work around aliasing bugs - developers should comment this out
 191     CFLAGS="$CFLAGS -fno-strict-aliasing"
 192
 193     # gcc's builtin memcmp is slower than glibc's
 194     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 195     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 196 fi
 197 if test "x$GXX" = xyes; then
 198     CXXFLAGS="$CXXFLAGS -Wall"
 199
 200     # Enable -fvisibility=hidden if using a gcc that supports it
 201     save_CXXFLAGS="$CXXFLAGS"
 202     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 203     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 204     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 205     AC_LANG_PUSH([C++])
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 208     AC_LANG_POP([C++])
 209
 210     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 211     CXXFLAGS=$save_CXXFLAGS
 212
 213     # Work around aliasing bugs - developers should comment this out
 214     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 215
 216     # gcc's builtin memcmp is slower than glibc's
 217     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 218     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 219 fi
 220
 221 dnl even if the compiler appears to support it, using visibility attributes isn't
 222 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 223 case "$host_os" in
 224 cygwin*)
 225     VISIBILITY_CFLAGS=""
 226     VISIBILITY_CXXFLAGS=""
 227     ;;
 228 esac
 229
 230 AC_SUBST([VISIBILITY_CFLAGS])
 231 AC_SUBST([VISIBILITY_CXXFLAGS])
 232
 233 dnl
 234 dnl Optional flags, check for compiler support
 235 dnl
 236 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 237 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 287
 288 dnl
 289 dnl other compiler options
 290 dnl
 291 AC_ARG_ENABLE([debug],
 292     [AS_HELP_STRING([--enable-debug],
 293         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 294     [enable_debug="$enableval"],
 295     [enable_debug=no]
 296 )
 297 if test "x$enable_debug" = xyes; then
 298     DEFINES="$DEFINES -DDEBUG"
 299     if test "x$GCC" = xyes; then
 300         CFLAGS="$CFLAGS -g -O0"
 301     fi
 302     if test "x$GXX" = xyes; then
 303         CXXFLAGS="$CXXFLAGS -g -O0"
 304     fi
 305 fi
 306
 307 dnl
 308 dnl library names
 309 dnl
 310 LIB_PREFIX_GLOB='lib'
 311 LIB_VERSION_SEPARATOR='.'
 312 if test "$enable_static" = yes; then
 313     LIB_EXTENSION='a'
 314 else
 315     case "$host_os" in
 316     darwin* )
 317         LIB_EXTENSION='dylib' ;;
 318     cygwin* )
 319         dnl prefix can be 'cyg' or 'lib'
 320         LIB_PREFIX_GLOB='???'
 321         LIB_VERSION_SEPARATOR='-'
 322         LIB_EXTENSION='dll' ;;
 323     aix* )
 324         LIB_EXTENSION='a' ;;
 325     * )
 326         LIB_EXTENSION='so' ;;
 327     esac
 328 fi
 329 AC_ARG_WITH([gl-lib-name],
 330   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 331     [specify GL library name @<:@default=GL@:>@])],
 332   [GL_LIB=$withval],
 333   [GL_LIB=GL])
 334 AC_ARG_WITH([osmesa-lib-name],
 335   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 336     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 337   [OSMESA_LIB=$withval],
 338   [OSMESA_LIB=OSMesa])
 339 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 340 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 341
 342 dnl
 343 dnl Mangled Mesa support
 344 dnl
 345 AC_ARG_ENABLE([mangling],
 346   [AS_HELP_STRING([--enable-mangling],
 347     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 348   [enable_mangling="${enableval}"],
 349   [enable_mangling=no]
 350 )
 351 if test "x${enable_mangling}" = "xyes" ; then
 352   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 353   GL_LIB="Mangled${GL_LIB}"
 354   OSMESA_LIB="Mangled${OSMESA_LIB}"
 355 fi
 356 AC_SUBST([GL_LIB])
 357 AC_SUBST([OSMESA_LIB])
 358
 359 dnl
 360 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 361 dnl
 362 AC_ARG_ENABLE([texture-float],
 363     [AS_HELP_STRING([--enable-texture-float],
 364         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 365     [enable_texture_float="$enableval"],
 366     [enable_texture_float=no]
 367 )
 368 if test "x$enable_texture_float" = xyes; then
 369     AC_MSG_WARN([Floating-point textures enabled.])
 370     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 371     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 372 fi
 373
 374 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 375 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 376 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 377 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 378 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 379 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 380 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 381
 382 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 387 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 388 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 389
 390 AC_SUBST([GL_LIB_NAME])
 391 AC_SUBST([OSMESA_LIB_NAME])
 392 AC_SUBST([EGL_LIB_NAME])
 393 AC_SUBST([GLESv1_CM_LIB_NAME])
 394 AC_SUBST([GLESv2_LIB_NAME])
 395 AC_SUBST([VG_LIB_NAME])
 396 AC_SUBST([GLAPI_LIB_NAME])
 397
 398 AC_SUBST([GL_LIB_GLOB])
 399 AC_SUBST([EGL_LIB_GLOB])
 400 AC_SUBST([GLESv1_CM_LIB_GLOB])
 401 AC_SUBST([GLESv2_LIB_GLOB])
 402 AC_SUBST([VG_LIB_GLOB])
 403 AC_SUBST([GLAPI_LIB_GLOB])
 404
 405 dnl
 406 dnl Arch/platform-specific settings
 407 dnl
 408 AC_ARG_ENABLE([asm],
 409     [AS_HELP_STRING([--disable-asm],
 410         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 411     [enable_asm="$enableval"],
 412     [enable_asm=yes]
 413 )
 414 asm_arch=""
 415 AC_MSG_CHECKING([whether to enable assembly])
 416 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 417 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 418 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 419     case "$host_cpu" in
 420     i?86 | x86_64 | amd64)
 421         enable_asm=no
 422         AC_MSG_RESULT([no, cross compiling])
 423         ;;
 424     esac
 425 fi
 426 # check for supported arches
 427 if test "x$enable_asm" = xyes; then
 428     case "$host_cpu" in
 429     i?86)
 430         case "$host_os" in
 431         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 432             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 433             ;;
 434         gnu*)
 435             asm_arch=x86
 436             ;;
 437         esac
 438         ;;
 439     x86_64|amd64)
 440         case "$host_os" in
 441         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 442             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 443             ;;
 444         esac
 445         ;;
 446     sparc*)
 447         case "$host_os" in
 448         linux*)
 449             asm_arch=sparc
 450             ;;
 451         esac
 452         ;;
 453     esac
 454
 455     case "$asm_arch" in
 456     x86)
 457         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 458         AC_MSG_RESULT([yes, x86])
 459         ;;
 460     x86_64|amd64)
 461         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 462         AC_MSG_RESULT([yes, x86_64])
 463         ;;
 464     sparc)
 465         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 466         AC_MSG_RESULT([yes, sparc])
 467         ;;
 468     *)
 469         AC_MSG_RESULT([no, platform not supported])
 470         ;;
 471     esac
 472 fi
 473
 474 dnl Check to see if dlopen is in default libraries (like Solaris, which
 475 dnl has it in libc), or if libdl is needed to get it.
 476 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 477     [AC_CHECK_LIB([dl], [dlopen],
 478        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 479 AC_SUBST([DLOPEN_LIBS])
 480
 481 case "$host_os" in
 482 darwin*|mingw*)
 483     ;;
 484 *)
 485     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 486                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 487                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 488     AC_SUBST([CLOCK_LIB])
 489     ;;
 490 esac
 491
 492 dnl See if posix_memalign is available
 493 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 494
 495 dnl Check for pthreads
 496 AX_PTHREAD
 497 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 498 dnl to -pthread, which causes problems if we need -lpthread to appear in
 499 dnl pkgconfig files.
 500 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 501
 502 dnl SELinux awareness.
 503 AC_ARG_ENABLE([selinux],
 504     [AS_HELP_STRING([--enable-selinux],
 505         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 506     [MESA_SELINUX="$enableval"],
 507     [MESA_SELINUX=no])
 508 if test "x$enable_selinux" = "xyes"; then
 509     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 510         [AC_CHECK_HEADER([selinux/selinux.h],[],
 511                          [AC_MSG_ERROR([SELinux headers not found])])
 512          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 513                       [AC_MSG_ERROR([SELinux library not found])])
 514          SELINUX_LIBS="-lselinux"])
 515     DEFINES="$DEFINES -DMESA_SELINUX"
 516 fi
 517 AC_SUBST([SELINUX_CFLAGS])
 518 AC_SUBST([SELINUX_LIBS])
 519
 520 dnl Options for APIs
 521 AC_ARG_ENABLE([opengl],
 522     [AS_HELP_STRING([--disable-opengl],
 523         [disable support for standard OpenGL API @<:@default=no@:>@])],
 524     [enable_opengl="$enableval"],
 525     [enable_opengl=yes])
 526 AC_ARG_ENABLE([gles1],
 527     [AS_HELP_STRING([--enable-gles1],
 528         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 529     [enable_gles1="$enableval"],
 530     [enable_gles1=no])
 531 AC_ARG_ENABLE([gles2],
 532     [AS_HELP_STRING([--enable-gles2],
 533         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 534     [enable_gles2="$enableval"],
 535     [enable_gles2=no])
 536 AC_ARG_ENABLE([openvg],
 537     [AS_HELP_STRING([--enable-openvg],
 538         [enable support for OpenVG API @<:@default=no@:>@])],
 539     [enable_openvg="$enableval"],
 540     [enable_openvg=no])
 541
 542 AC_ARG_ENABLE([dri],
 543     [AS_HELP_STRING([--enable-dri],
 544         [enable DRI modules @<:@default=enabled@:>@])],
 545     [enable_dri="$enableval"],
 546     [enable_dri=yes])
 547 AC_ARG_ENABLE([dri3],
 548     [AS_HELP_STRING([--enable-dri3],
 549         [enable DRI3 @<:@default=enabled@:>@])],
 550     [enable_dri3="$enableval"],
 551     [enable_dri3=yes])
 552 AC_ARG_ENABLE([glx],
 553     [AS_HELP_STRING([--enable-glx],
 554         [enable GLX library @<:@default=enabled@:>@])],
 555     [enable_glx="$enableval"],
 556     [enable_glx=yes])
 557 AC_ARG_ENABLE([osmesa],
 558     [AS_HELP_STRING([--enable-osmesa],
 559         [enable OSMesa library @<:@default=disabled@:>@])],
 560     [enable_osmesa="$enableval"],
 561     [enable_osmesa=no])
 562 AC_ARG_ENABLE([gallium-osmesa],
 563     [AS_HELP_STRING([--enable-gallium-osmesa],
 564         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 565     [enable_gallium_osmesa="$enableval"],
 566     [enable_gallium_osmesa=no])
 567 AC_ARG_ENABLE([egl],
 568     [AS_HELP_STRING([--disable-egl],
 569         [disable EGL library @<:@default=enabled@:>@])],
 570     [enable_egl="$enableval"],
 571     [enable_egl=yes])
 572
 573 AC_ARG_ENABLE([xa],
 574     [AS_HELP_STRING([--enable-xa],
 575         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 576     [enable_xa="$enableval"],
 577     [enable_xa=no])
 578 AC_ARG_ENABLE([gbm],
 579    [AS_HELP_STRING([--enable-gbm],
 580          [enable gbm library @<:@default=auto@:>@])],
 581    [enable_gbm="$enableval"],
 582    [enable_gbm=auto])
 583
 584 AC_ARG_ENABLE([xvmc],
 585    [AS_HELP_STRING([--enable-xvmc],
 586          [enable xvmc library @<:@default=auto@:>@])],
 587    [enable_xvmc="$enableval"],
 588    [enable_xvmc=no])
 589 AC_ARG_ENABLE([vdpau],
 590    [AS_HELP_STRING([--enable-vdpau],
 591          [enable vdpau library @<:@default=auto@:>@])],
 592    [enable_vdpau="$enableval"],
 593    [enable_vdpau=auto])
 594 AC_ARG_ENABLE([omx],
 595    [AS_HELP_STRING([--enable-omx],
 596          [enable OpenMAX library @<:@default=no@:>@])],
 597    [enable_omx="$enableval"],
 598    [enable_omx=no])
 599 AC_ARG_ENABLE([opencl],
 600    [AS_HELP_STRING([--enable-opencl],
 601          [enable OpenCL library NOTE: Enabling this option will also enable
 602           --with-llvm-shared-libs
 603           @<:@default=no@:>@])],
 604    [],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([opencl_icd],
 607    [AS_HELP_STRING([--enable-opencl-icd],
 608           [Build an OpenCL ICD library to be loaded by an ICD implementation
 609            @<:@default=no@:>@])],
 610     [enable_opencl_icd="$enableval"],
 611     [enable_opencl_icd=no])
 612 AC_ARG_ENABLE([xlib-glx],
 613     [AS_HELP_STRING([--enable-xlib-glx],
 614         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 615     [enable_xlib_glx="$enableval"],
 616     [enable_xlib_glx=no])
 617 AC_ARG_ENABLE([gallium-egl],
 618     [AS_HELP_STRING([--enable-gallium-egl],
 619         [enable optional EGL state tracker (not required
 620          for EGL support in Gallium with OpenGL and OpenGL ES)
 621          @<:@default=disable@:>@])],
 622     [enable_gallium_egl="$enableval"],
 623     [enable_gallium_egl=no])
 624 AC_ARG_ENABLE([gallium-gbm],
 625     [AS_HELP_STRING([--enable-gallium-gbm],
 626         [enable optional gbm state tracker (not required for
 627          gbm support in Gallium)
 628          @<:@default=auto@:>@])],
 629     [enable_gallium_gbm="$enableval"],
 630     [enable_gallium_gbm=auto])
 631
 632 AC_ARG_ENABLE([r600-llvm-compiler],
 633     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 634         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 635     [enable_r600_llvm="$enableval"],
 636     [enable_r600_llvm=no])
 637
 638 AC_ARG_ENABLE([gallium-tests],
 639     [AS_HELP_STRING([--enable-gallium-tests],
 640         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 641     [enable_gallium_tests="$enableval"],
 642     [enable_gallium_tests=no])
 643
 644 # Option for Gallium drivers
 645
 646 # Keep this in sync with the --with-gallium-drivers help string default value
 647 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 648
 649 AC_ARG_WITH([gallium-drivers],
 650     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 651         [comma delimited Gallium drivers list, e.g.
 652         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 653         @<:@default=r300,r600,svga,swrast@:>@])],
 654     [with_gallium_drivers="$withval"],
 655     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 656
 657 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 658 # here so that the script doesn't choke on an unknown driver name later.
 659 case "$with_gallium_drivers" in
 660     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 661     no) with_gallium_drivers='' ;;
 662 esac
 663
 664 if test "x$enable_opengl" = xno -a \
 665         "x$enable_gles1" = xno -a \
 666         "x$enable_gles2" = xno -a \
 667         "x$enable_openvg" = xno -a \
 668         "x$enable_xa" = xno -a \
 669         "x$enable_xvmc" = xno -a \
 670         "x$enable_vdpau" = xno -a \
 671         "x$enable_omx" = xno -a \
 672         "x$enable_opencl" = xno; then
 673     AC_MSG_ERROR([at least one API should be enabled])
 674 fi
 675
 676 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 677 if test "x$enable_opengl" = xno -a \
 678         "x$enable_gles1" = xyes; then
 679     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 680 fi
 681
 682 if test "x$enable_opengl" = xno -a \
 683         "x$enable_gles2" = xyes; then
 684     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 685 fi
 686
 687 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 688 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 689 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 690 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 691                                         "x$enable_gles1" = xyes -o \
 692                                         "x$enable_gles2" = xyes)
 693
 694 if test "x$enable_glx" = xno; then
 695     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 696     enable_xlib_glx=no
 697 fi
 698
 699 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 700     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 701 fi
 702
 703 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 704     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 705 fi
 706
 707 # Disable GLX if OpenGL is not enabled
 708 if test "x$enable_glx$enable_opengl" = xyesno; then
 709     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 710     enable_glx=no
 711 fi
 712
 713 # Disable GLX if DRI and Xlib-GLX are not enabled
 714 if test "x$enable_glx" = xyes -a \
 715         "x$enable_dri" = xno -a \
 716         "x$enable_xlib_glx" = xno; then
 717     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 718     enable_glx=no
 719 fi
 720
 721 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 722                                   "x$enable_dri" = xyes)
 723 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 724 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 725
 726 AC_ARG_ENABLE([shared-glapi],
 727     [AS_HELP_STRING([--enable-shared-glapi],
 728         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 729     [enable_shared_glapi="$enableval"],
 730     [enable_shared_glapi=yes])
 731
 732 case "x$enable_opengl$enable_gles1$enable_gles2" in
 733 x*yes*yes*)
 734     if test "x$enable_shared_glapi" = xno; then
 735         AC_MSG_ERROR([shared GLAPI required when building two or more of
 736                       the following APIs - opengl, gles1 gles2])
 737     fi
 738     ;;
 739 esac
 740
 741 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 742
 743 dnl
 744 dnl Driver specific build directories
 745 dnl
 746 GALLIUM_TARGET_DIRS=""
 747 GALLIUM_WINSYS_DIRS="sw"
 748 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 749 GALLIUM_STATE_TRACKERS_DIRS=""
 750
 751 case "x$enable_glx$enable_xlib_glx" in
 752 xyesyes)
 753     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 754     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 755     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 756     NEED_WINSYS_XLIB="yes"
 757     ;;
 758 esac
 759
 760 if test "x$enable_dri" = xyes; then
 761     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 762     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 763 fi
 764
 765 if test "x$enable_gallium_osmesa" = xyes; then
 766     if test -z "$with_gallium_drivers"; then
 767         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 768     fi
 769     if test "x$enable_osmesa" = xyes; then
 770         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 771     fi
 772     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 773     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 774 fi
 775
 776 AC_SUBST([MESA_LLVM])
 777
 778 # Check for libdrm
 779 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 780                   [have_libdrm=yes], [have_libdrm=no])
 781 if test "x$have_libdrm" = xyes; then
 782         DEFINES="$DEFINES -DHAVE_LIBDRM"
 783 fi
 784
 785 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 786                   have_libudev=yes, have_libudev=no)
 787
 788 if test "x$enable_dri" = xyes; then
 789     # DRI must be shared, I think
 790     if test "$enable_static" = yes; then
 791         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 792     fi
 793
 794     # not a hard requirement as swrast does not depend on it
 795     if test "x$have_libdrm" = xyes; then
 796         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 797     fi
 798 fi
 799
 800 dnl Direct rendering or just indirect rendering
 801 case "$host_os" in
 802 gnu*)
 803     dnl Disable by default on GNU/Hurd
 804     driglx_direct_default="no"
 805     ;;
 806 cygwin*)
 807     dnl Disable by default on cygwin
 808     driglx_direct_default="no"
 809     ;;
 810 *)
 811     driglx_direct_default="yes"
 812     ;;
 813 esac
 814 AC_ARG_ENABLE([driglx-direct],
 815     [AS_HELP_STRING([--disable-driglx-direct],
 816         [disable direct rendering in GLX and EGL for DRI \
 817             @<:@default=auto@:>@])],
 818     [driglx_direct="$enableval"],
 819     [driglx_direct="$driglx_direct_default"])
 820
 821 dnl
 822 dnl libGL configuration per driver
 823 dnl
 824 case "x$enable_glx$enable_xlib_glx" in
 825 xyesyes)
 826     # Xlib-based GLX
 827     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 828     GL_PC_REQ_PRIV="x11 xext"
 829     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 830     GL_LIB_DEPS="$XLIBGL_LIBS"
 831     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 832     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 833     ;;
 834 xyesno)
 835     # DRI-based GLX
 836     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 837     if test x"$driglx_direct" = xyes; then
 838         if test "x$have_libdrm" != xyes; then
 839             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 840         fi
 841         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 842         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 843         if test x"$enable_dri3" = xyes; then
 844             if test x"$have_libudev" != xyes; then
 845               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 846             fi
 847             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 848             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 849         fi
 850     fi
 851
 852     # find the DRI deps for libGL
 853     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 854
 855     if test x"$enable_dri3" = xyes; then
 856         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= 1.1"
 857     fi
 858
 859     # add xf86vidmode if available
 860     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 861     if test "$HAVE_XF86VIDMODE" = yes ; then
 862         dri_modules="$dri_modules xxf86vm"
 863     fi
 864
 865     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 866     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 867     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 868     GL_LIB_DEPS="$DRIGL_LIBS"
 869
 870     # need DRM libs, $PTHREAD_LIBS, etc.
 871     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 872     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 873     ;;
 874 esac
 875
 876 if test "$have_libudev" = yes; then
 877     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 878 fi
 879
 880 # This is outside the case (above) so that it is invoked even for non-GLX
 881 # builds.
 882 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 883
 884 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 885 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 886 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 887 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 888
 889 AC_SUBST([X11_INCLUDES])
 890 AC_SUBST([GL_LIB_DEPS])
 891 AC_SUBST([GL_PC_REQ_PRIV])
 892 AC_SUBST([GL_PC_LIB_PRIV])
 893 AC_SUBST([GL_PC_CFLAGS])
 894 AC_SUBST([DRI_PC_REQ_PRIV])
 895 AC_SUBST([GLESv1_CM_LIB_DEPS])
 896 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 897 AC_SUBST([GLESv2_LIB_DEPS])
 898 AC_SUBST([GLESv2_PC_LIB_PRIV])
 899
 900 AC_SUBST([HAVE_XF86VIDMODE])
 901
 902 dnl
 903 dnl More GLX setup
 904 dnl
 905 case "x$enable_glx$enable_xlib_glx" in
 906 xyesyes)
 907     DEFINES="$DEFINES -DUSE_XSHM"
 908     ;;
 909 xyesno)
 910     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 911     if test "x$driglx_direct" = xyes; then
 912         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 913     fi
 914     ;;
 915 esac
 916
 917 dnl
 918 dnl TLS detection
 919 dnl
 920
 921 AC_ARG_ENABLE([glx-tls],
 922     [AS_HELP_STRING([--enable-glx-tls],
 923         [enable TLS support in GLX @<:@default=disabled@:>@])],
 924     [GLX_USE_TLS="$enableval"],
 925     [GLX_USE_TLS=no])
 926 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 927
 928 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 929       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 930
 931 dnl
 932 dnl More DRI setup
 933 dnl
 934 dnl Directory for DRI drivers
 935 AC_ARG_WITH([dri-driverdir],
 936     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 937         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 938     [DRI_DRIVER_INSTALL_DIR="$withval"],
 939     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 940 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 941 dnl Extra search path for DRI drivers
 942 AC_ARG_WITH([dri-searchpath],
 943     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 944         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 945     [DRI_DRIVER_SEARCH_DIR="$withval"],
 946     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 947 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 948 dnl Which drivers to build - default is chosen by platform
 949 AC_ARG_WITH([dri-drivers],
 950     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 951         [comma delimited classic DRI drivers list, e.g.
 952         "swrast,i965,radeon" @<:@default=auto@:>@])],
 953     [with_dri_drivers="$withval"],
 954     [with_dri_drivers=auto])
 955
 956 if test "x$with_dri_drivers" = xauto; then
 957     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 958         with_dri_drivers="yes"
 959     else
 960         with_dri_drivers="no"
 961     fi
 962 fi
 963
 964 dnl If $with_dri_drivers is yes, drivers will be added through
 965 dnl platform checks. Set DEFINES and LIB_DEPS
 966 if test "x$enable_dri" = xyes; then
 967     # Platform specific settings and drivers to build
 968     case "$host_os" in
 969     linux*)
 970         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 971         DEFINES="$DEFINES -DHAVE_ALIAS"
 972         if test "x$enable_dri3" = xyes; then
 973             DEFINES="$DEFINES -DHAVE_DRI3"
 974         fi
 975
 976         case "$host_cpu" in
 977         powerpc* | sparc*)
 978             # Build only the drivers for cards that exist on PowerPC/sparc
 979             if test "x$with_dri_drivers" = "xyes"; then
 980                 with_dri_drivers="r200 radeon swrast"
 981             fi
 982             ;;
 983         esac
 984         ;;
 985     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 986         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 987         DEFINES="$DEFINES -DHAVE_ALIAS"
 988         ;;
 989     gnu*)
 990         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 991         DEFINES="$DEFINES -DHAVE_ALIAS"
 992         ;;
 993     solaris*)
 994         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 995         ;;
 996     cygwin*)
 997         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 998         if test "x$with_dri_drivers" = "xyes"; then
 999             with_dri_drivers="swrast"
1000         fi
1001         ;;
1002     esac
1003
1004     # default drivers
1005     if test "x$with_dri_drivers" = "xyes"; then
1006         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1007     fi
1008
1009     # Check for expat
1010     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1011     if test "x$have_expat" = "xyes"; then
1012        PKG_CHECK_MODULES([EXPAT], [expat], [],
1013                          AC_MSG_ERROR([Expat required for DRI.]))
1014     else
1015        # expat version 2.0 and earlier do not provide expat.pc
1016        EXPAT_LIBS=-lexpat
1017     fi
1018
1019     # If we are building any DRI driver other than swrast.
1020     if test -n "$with_dri_drivers"; then
1021         if test "x$with_dri_drivers" != xswrast; then
1022             # ... libdrm is required
1023             if test "x$have_libdrm" != xyes; then
1024                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1025             fi
1026             DRICOMMON_NEED_LIBDRM=yes
1027         else
1028             DRICOMMON_NEED_LIBDRM=no
1029         fi
1030     fi
1031
1032     # put all the necessary libs together
1033     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1034     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1035
1036 fi
1037
1038 AC_SUBST([DRI_LIB_DEPS])
1039 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1040
1041 DRI_DIRS=""
1042 dnl Duplicates in DRI_DIRS are removed by sorting it after this block
1043 if test "x$with_dri_drivers" != xno; then
1044     if test "x$enable_opengl" != xyes; then
1045         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1046     fi
1047
1048     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1049     for driver in $dri_drivers; do
1050         DRI_DIRS+="$driver "
1051         case "x$driver" in
1052         xi915)
1053             HAVE_I915_DRI=yes;
1054             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1055             ;;
1056         xi965)
1057             HAVE_I965_DRI=yes;
1058             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1059             ;;
1060         xnouveau)
1061             HAVE_NOUVEAU_DRI=yes;
1062             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1063             ;;
1064         xradeon)
1065             HAVE_RADEON_DRI=yes;
1066             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1067             ;;
1068         xr200)
1069             HAVE_R200_DRI=yes;
1070             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1071             ;;
1072         xswrast)
1073             HAVE_SWRAST_DRI=yes;
1074             ;;
1075         *)
1076             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1077             ;;
1078         esac
1079     done
1080 fi
1081 DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1082
1083 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1084 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1085                                   "x$enable_osmesa" = xyes -o \
1086                                   -n "$DRI_DIRS")
1087
1088 dnl
1089 dnl OSMesa configuration
1090 dnl
1091
1092 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1093 AC_ARG_WITH([osmesa-bits],
1094     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1095         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1096     [osmesa_bits="$withval"],
1097     [osmesa_bits=8])
1098 if test "x$osmesa_bits" != x8; then
1099     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1100         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1101         osmesa_bits=8
1102     fi
1103 fi
1104 case "x$osmesa_bits" in
1105 x8)
1106     OSMESA_LIB="${OSMESA_LIB}"
1107     ;;
1108 x16|x32)
1109     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1110     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1111     ;;
1112 *)
1113     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1114     ;;
1115 esac
1116
1117 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1118     # only link libraries with osmesa if shared
1119     if test "$enable_static" = no; then
1120         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1121     else
1122         OSMESA_LIB_DEPS=""
1123     fi
1124     OSMESA_MESA_DEPS=""
1125     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1126 fi
1127
1128 AC_SUBST([OSMESA_LIB_DEPS])
1129 AC_SUBST([OSMESA_MESA_DEPS])
1130 AC_SUBST([OSMESA_PC_REQ])
1131 AC_SUBST([OSMESA_PC_LIB_PRIV])
1132
1133 dnl
1134 dnl gbm configuration
1135 dnl
1136 if test "x$enable_gbm" = xauto; then
1137     case "$with_egl_platforms" in
1138         *drm*)
1139             enable_gbm=yes ;;
1140          *)
1141             enable_gbm=no ;;
1142     esac
1143 fi
1144 if test "x$enable_gbm" = xyes; then
1145     if test x"$have_libudev" != xyes; then
1146         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1147     fi
1148
1149     if test "x$enable_dri" = xyes; then
1150         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1151         if test "x$enable_shared_glapi" = xno; then
1152             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1153         fi
1154     fi
1155 fi
1156 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1157 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1158 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1159 AC_SUBST([GBM_PC_REQ_PRIV])
1160 AC_SUBST([GBM_PC_LIB_PRIV])
1161
1162 dnl
1163 dnl EGL configuration
1164 dnl
1165 EGL_CLIENT_APIS=""
1166
1167 if test "x$enable_egl" = xyes; then
1168     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1169
1170     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1171
1172     if test "$enable_static" != yes; then
1173         if test "x$enable_dri" = xyes; then
1174             HAVE_EGL_DRIVER_DRI2=1
1175         fi
1176
1177     fi
1178 fi
1179 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1180 AC_SUBST([EGL_LIB_DEPS])
1181
1182 dnl
1183 dnl EGL Gallium configuration
1184 dnl
1185 if test "x$enable_gallium_egl" = xyes; then
1186     if test -z "$with_gallium_drivers"; then
1187         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1188     fi
1189     if test "x$enable_egl" = xno; then
1190         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1191     fi
1192     if test "x$have_libdrm" != xyes; then
1193         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1194     fi
1195
1196     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1197     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1198 fi
1199 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1200
1201 dnl
1202 dnl gbm Gallium configuration
1203 dnl
1204 if test "x$enable_gallium_gbm" = xauto; then
1205     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1206         yesyesyes*drm*)
1207             enable_gallium_gbm=yes ;;
1208          *)
1209             enable_gallium_gbm=no ;;
1210     esac
1211 fi
1212 if test "x$enable_gallium_gbm" = xyes; then
1213     if test -z "$with_gallium_drivers"; then
1214         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1215     fi
1216     if test "x$enable_gbm" = xno; then
1217         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1218     fi
1219     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1220     if test "x$enable_dri" = xno; then
1221         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1222     fi
1223
1224     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1225     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1226     enable_gallium_loader=yes
1227 fi
1228 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1229
1230 dnl
1231 dnl XA configuration
1232 dnl
1233 if test "x$enable_xa" = xyes; then
1234     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1235     enable_gallium_loader=yes
1236     enable_gallium_drm_loader=yes
1237 fi
1238 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1239
1240 dnl
1241 dnl OpenVG configuration
1242 dnl
1243 VG_LIB_DEPS=""
1244
1245 if test "x$enable_openvg" = xyes; then
1246     if test "x$enable_egl" = xno; then
1247         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1248     fi
1249     if test -z "$with_gallium_drivers"; then
1250         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1251     fi
1252     if test "x$enable_gallium_egl" = xno; then
1253         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1254     fi
1255
1256     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1257     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1258     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1259     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1260     AC_SUBST([VG_PC_LIB_PRIV])
1261 fi
1262 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1263
1264 dnl
1265 dnl Gallium G3DVL configuration
1266 dnl
1267 if test -n "$with_gallium_drivers"; then
1268     if test "x$enable_xvmc" = xauto; then
1269         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1270     fi
1271
1272     if test "x$enable_vdpau" = xauto; then
1273         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1274     fi
1275
1276     if test "x$enable_omx" = xauto; then
1277         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1278     fi
1279 fi
1280
1281 if test "x$enable_xvmc" = xyes; then
1282     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1283     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1284 fi
1285 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1286
1287 if test "x$enable_vdpau" = xyes; then
1288     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8],
1289                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1290     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1291 fi
1292 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1293
1294 if test "x$enable_omx" = xyes; then
1295     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= 0.0 x11-xcb xcb-dri2 >= 1.8])
1296     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1297 fi
1298 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1299
1300 dnl
1301 dnl OpenCL configuration
1302 dnl
1303
1304 AC_ARG_WITH([libclc-path],
1305    [AS_HELP_STRING([--with-libclc-path],
1306          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1307    [LIBCLC_PATH="$withval"],
1308    [LIBCLC_PATH=""])
1309
1310 if test -n "$LIBCLC_PATH"; then
1311    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1312                   Please review the updated build instructions for clover:
1313                   http://dri.freedesktop.org/wiki/GalliumCompute])
1314 fi
1315
1316
1317 AC_ARG_WITH([clang-libdir],
1318    [AS_HELP_STRING([--with-clang-libdir],
1319          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1320    [CLANG_LIBDIR="$withval"],
1321    [CLANG_LIBDIR=""])
1322
1323 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1324
1325 if test "x$enable_opencl" = xyes; then
1326     if test -z "$with_gallium_drivers"; then
1327         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1328     fi
1329
1330     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1331         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1332     fi
1333
1334     if test "x$have_libclc" = xno; then
1335         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1336                     Make sure the directory containing libclc.pc is specified in your
1337                     PKG_CONFIG_PATH environment variable.
1338                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1339     else
1340         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1341         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1342         AC_SUBST([LIBCLC_INCLUDEDIR])
1343         AC_SUBST([LIBCLC_LIBEXECDIR])
1344     fi
1345
1346     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1347     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1348     enable_gallium_loader=yes
1349
1350     if test "x$enable_opencl_icd" = xyes; then
1351         OPENCL_LIBNAME="MesaOpenCL"
1352     else
1353         OPENCL_LIBNAME="OpenCL"
1354     fi
1355 fi
1356 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1357 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1358 AC_SUBST([OPENCL_LIBNAME])
1359
1360 dnl
1361 dnl Gallium configuration
1362 dnl
1363 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1364
1365 AC_SUBST([LLVM_BINDIR])
1366 AC_SUBST([LLVM_CFLAGS])
1367 AC_SUBST([LLVM_CPPFLAGS])
1368 AC_SUBST([LLVM_CXXFLAGS])
1369 AC_SUBST([LLVM_LIBDIR])
1370 AC_SUBST([LLVM_LIBS])
1371 AC_SUBST([LLVM_LDFLAGS])
1372 AC_SUBST([LLVM_INCLUDEDIR])
1373 AC_SUBST([LLVM_VERSION])
1374 AC_SUBST([CLANG_RESOURCE_DIR])
1375
1376 case "x$enable_opengl$enable_gles1$enable_gles2" in
1377 x*yes*)
1378     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1379     ;;
1380 esac
1381
1382 AC_SUBST([VG_LIB_DEPS])
1383 AC_SUBST([EGL_CLIENT_APIS])
1384
1385 dnl
1386 dnl EGL Platforms configuration
1387 dnl
1388 AC_ARG_WITH([egl-platforms],
1389     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1390         [comma delimited native platforms libEGL supports, e.g.
1391         "x11,drm" @<:@default=auto@:>@])],
1392     [with_egl_platforms="$withval"],
1393     [if test "x$enable_egl" = xyes; then
1394         with_egl_platforms="x11"
1395     else
1396         with_egl_platforms=""
1397     fi])
1398
1399 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1400     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1401 fi
1402
1403 # Do per-EGL platform setups and checks
1404 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1405 for plat in $egl_platforms; do
1406         case "$plat" in
1407         wayland)
1408                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1409                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1410
1411                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1412                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1413                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1414                 ;;
1415
1416         x11)
1417                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1418                 ;;
1419
1420         drm)
1421                 test "x$enable_gbm" = "xno" &&
1422                         AC_MSG_ERROR([EGL platform drm needs gbm])
1423                 test "x$have_libdrm" != xyes &&
1424                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1425                 ;;
1426
1427         android|fbdev|gdi|null)
1428                 ;;
1429
1430         *)
1431                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1432                 ;;
1433         esac
1434
1435         case "$plat$have_libudev" in
1436                 waylandno|drmno)
1437                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1438         esac
1439 done
1440
1441 # libEGL wants to default to the first platform specified in
1442 # ./configure.  parse that here.
1443 if test "x$egl_platforms" != "x"; then
1444     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1445     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1446 else
1447     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1448 fi
1449
1450 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1451     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1452     NEED_WINSYS_XLIB=yes
1453 fi
1454 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1455 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1456 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1457 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1458 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1459
1460 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1461
1462 AC_SUBST([EGL_NATIVE_PLATFORM])
1463 AC_SUBST([EGL_CFLAGS])
1464
1465 # If we don't have the X11 platform, set this define so we don't try to include
1466 # the X11 headers.
1467 if ! echo "$egl_platforms" | grep -q 'x11'; then
1468     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1469     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1470 fi
1471
1472 AC_ARG_WITH([egl-driver-dir],
1473     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1474                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1475     [EGL_DRIVER_INSTALL_DIR="$withval"],
1476     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1477 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1478
1479 AC_ARG_WITH([max-width],
1480     [AS_HELP_STRING([--with-max-width=N],
1481                     [Maximum framebuffer width (4096)])],
1482     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1483      AS_IF([test "${withval}" -gt "4096"],
1484            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1485 )
1486 AC_ARG_WITH([max-height],
1487     [AS_HELP_STRING([--with-max-height=N],
1488                     [Maximum framebuffer height (4096)])],
1489     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1490      AS_IF([test "${withval}" -gt "4096"],
1491            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1492 )
1493
1494 dnl
1495 dnl Gallium LLVM
1496 dnl
1497 AC_ARG_ENABLE([gallium-llvm],
1498     [AS_HELP_STRING([--enable-gallium-llvm],
1499         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1500     [enable_gallium_llvm="$enableval"],
1501     [enable_gallium_llvm=auto])
1502
1503 AC_ARG_ENABLE([llvm-shared-libs],
1504     [AS_HELP_STRING([--enable-llvm-shared-libs],
1505         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1506     [],
1507     [with_llvm_shared_libs=yes])
1508
1509 AC_ARG_WITH([llvm-prefix],
1510     [AS_HELP_STRING([--with-llvm-prefix],
1511         [Prefix for LLVM installations in non-standard locations])],
1512     [llvm_prefix="$withval"],
1513     [llvm_prefix=""])
1514
1515
1516 # Call this inside ` ` to get the return value.
1517 # $1 is the llvm-config command with arguments.
1518 strip_unwanted_llvm_flags() {
1519     # Use \> (marks the end of the word)
1520     echo `$1` | sed \
1521         -e 's/-DNDEBUG\>//g' \
1522         -e 's/-pedantic\>//g' \
1523         -e 's/-Wcovered-switch-default\>//g' \
1524         -e 's/-O.\>//g' \
1525         -e 's/-g\>//g' \
1526         -e 's/-Wall\>//g' \
1527         -e 's/-fcolor-diagnostics\>//g' \
1528         -e 's/-fomit-frame-pointer\>//g'
1529 }
1530
1531
1532 if test -z "$with_gallium_drivers"; then
1533     enable_gallium_llvm=no
1534 fi
1535 if test "x$enable_gallium_llvm" = xauto; then
1536     case "$host_cpu" in
1537     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1538     esac
1539 fi
1540 if test "x$enable_gallium_llvm" = xyes; then
1541     if test -n "$llvm_prefix"; then
1542         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1543     else
1544         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1545     fi
1546
1547     if test "x$LLVM_CONFIG" != xno; then
1548         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1549         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1550         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1551         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1552         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1553         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1554         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1555         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1556
1557         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1558             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1559         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1560             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1561
1562         if test -n "${LLVM_VERSION_MAJOR}"; then
1563             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1564         else
1565             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1566         fi
1567
1568         LLVM_COMPONENTS="engine bitwriter"
1569         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1570             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1571         fi
1572
1573         if test "x$enable_opencl" = xyes; then
1574             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1575             # LLVM 3.3 >= 177971 requires IRReader
1576             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1577                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1578             fi
1579             # LLVM 3.4 requires Option
1580             if $LLVM_CONFIG --components | grep -qw 'option'; then
1581                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1582             fi
1583         fi
1584         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1585         MESA_LLVM=1
1586
1587         dnl Check for Clang internal headers
1588         if test "x$enable_opencl" = xyes; then
1589             if test -z "$CLANG_LIBDIR"; then
1590                 CLANG_LIBDIR=${LLVM_LIBDIR}
1591             fi
1592             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1593             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1594                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1595         fi
1596     else
1597         MESA_LLVM=0
1598         LLVM_VERSION_INT=0
1599     fi
1600 else
1601     MESA_LLVM=0
1602     LLVM_VERSION_INT=0
1603 fi
1604
1605 dnl Directory for XVMC libs
1606 AC_ARG_WITH([xvmc-libdir],
1607     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1608         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1609     [XVMC_LIB_INSTALL_DIR="$withval"],
1610     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1611 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1612
1613 dnl
1614 dnl Gallium Tests
1615 dnl
1616 if test "x$enable_gallium_tests" = xyes; then
1617     enable_gallium_loader=yes
1618 fi
1619 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1620
1621 if test "x$enable_gallium_loader" = xyes; then
1622     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1623 fi
1624 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1625
1626 dnl Directory for VDPAU libs
1627 AC_ARG_WITH([vdpau-libdir],
1628     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1629         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1630     [VDPAU_LIB_INSTALL_DIR="$withval"],
1631     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1632 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1633
1634 AC_ARG_WITH([omx-libdir],
1635     [AS_HELP_STRING([--with-omx-libdir=DIR],
1636         [directory for the OMX libraries])],
1637     [OMX_LIB_INSTALL_DIR="$withval"],
1638     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1639 AC_SUBST([OMX_LIB_INSTALL_DIR])
1640
1641 dnl Directory for OpenCL libs
1642 AC_ARG_WITH([opencl-libdir],
1643     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1644         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1645     [OPENCL_LIB_INSTALL_DIR="$withval"],
1646     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1647 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1648
1649 dnl
1650 dnl Gallium helper functions
1651 dnl
1652 gallium_check_st() {
1653     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1654          if test "x$have_libdrm" != xyes; then
1655             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1656          fi
1657          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1658     fi
1659     if test "x$enable_dri" = xyes && test -n "$2"; then
1660          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1661     fi
1662     if test "x$enable_xa" = xyes && test -n "$3"; then
1663          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1664     fi
1665     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1666          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1667     fi
1668     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1669          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1670     fi
1671     if test "x$enable_omx" = xyes && test "x$6" != x; then
1672          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1673     fi
1674 }
1675
1676 gallium_require_llvm() {
1677     if test "x$MESA_LLVM" = x0; then
1678         case "$host_cpu" in
1679         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1680         esac
1681     fi
1682 }
1683
1684 gallium_require_drm_loader() {
1685     if test "x$enable_gallium_loader" = xyes; then
1686         if test "x$have_libudev" != xyes; then
1687             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1688         fi
1689         if test "x$have_libdrm" != xyes; then
1690             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1691         fi
1692         enable_gallium_drm_loader=yes
1693     fi
1694 }
1695
1696 radeon_llvm_check() {
1697     if test "x$enable_gallium_llvm" != "xyes"; then
1698         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1699     fi
1700     LLVM_REQUIRED_VERSION_MAJOR="3"
1701     LLVM_REQUIRED_VERSION_MINOR="3"
1702     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1703         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1704     fi
1705     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1706         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1707                       sources with the --enable-experimental-targets=R600
1708                       configure flag])
1709     fi
1710     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1711     NEED_RADEON_LLVM=yes
1712     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1713                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1714 }
1715
1716 dnl Gallium drivers
1717 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1718         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1719     NEED_NONNULL_WINSYS=yes
1720 fi
1721 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1722
1723 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1724 if test -n "$with_gallium_drivers"; then
1725     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1726     for driver in $gallium_drivers; do
1727         case "x$driver" in
1728         xsvga)
1729             HAVE_GALLIUM_SVGA=yes
1730             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1731             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1732             ;;
1733         xi915)
1734             HAVE_GALLIUM_I915=yes
1735             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1736             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1737             if test "x$MESA_LLVM" = x1; then
1738                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1739             fi
1740             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1741             gallium_check_st "i915/drm" "dri-i915"
1742             DRICOMMON_NEED_LIBDRM=yes
1743             ;;
1744         xilo)
1745             HAVE_GALLIUM_ILO=yes
1746             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1747             gallium_require_drm_loader
1748             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1749             gallium_check_st "intel/drm" "dri-ilo"
1750             DRICOMMON_NEED_LIBDRM=yes
1751             ;;
1752         xr300)
1753             HAVE_GALLIUM_R300=yes
1754             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1755             gallium_require_llvm "Gallium R300"
1756             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1757             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1758             DRICOMMON_NEED_LIBDRM=yes
1759             ;;
1760         xr600)
1761             HAVE_GALLIUM_R600=yes
1762             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1763             gallium_require_drm_loader
1764             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1765             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1766                 radeon_llvm_check "r600g"
1767                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1768             fi
1769             if test "x$enable_r600_llvm" = xyes; then
1770                 USE_R600_LLVM_COMPILER=yes;
1771             fi
1772             if test "x$enable_opencl" = xyes; then
1773                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1774             fi
1775             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1776             DRICOMMON_NEED_LIBDRM=yes
1777             ;;
1778         xradeonsi)
1779             HAVE_GALLIUM_RADEONSI=yes
1780             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1781             gallium_require_drm_loader
1782             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1783             radeon_llvm_check "radeonsi"
1784             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1785             DRICOMMON_NEED_LIBDRM=yes
1786             ;;
1787         xnouveau)
1788             HAVE_GALLIUM_NOUVEAU=yes
1789             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1790             gallium_require_drm_loader
1791             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1792             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1793             DRICOMMON_NEED_LIBDRM=yes
1794             ;;
1795         xfreedreno)
1796             HAVE_GALLIUM_FREEDRENO=yes
1797             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1798             gallium_require_drm_loader
1799             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1800             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1801             DRICOMMON_NEED_LIBDRM=yes
1802             ;;
1803         xswrast)
1804             HAVE_GALLIUM_SOFTPIPE=yes
1805             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1806             if test "x$MESA_LLVM" = x1; then
1807                 HAVE_GALLIUM_LLVMPIPE=yes
1808                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1809             fi
1810
1811             if test "x$enable_dri" = xyes; then
1812                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1813             fi
1814             ;;
1815         *)
1816             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1817             ;;
1818         esac
1819     done
1820 fi
1821
1822 dnl Set LLVM_LIBS - This is done after the driver configuration so
1823 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1824 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1825 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1826 dnl this was causing the same libraries to be appear multiple times
1827 dnl in LLVM_LIBS.
1828
1829 if test "x$MESA_LLVM" != x0; then
1830
1831     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1832
1833     if test "x$with_llvm_shared_libs" = xyes; then
1834         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1835         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1836         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1837
1838         if test "x$llvm_have_one_so" = xyes; then
1839             dnl LLVM was built using auto*, so there is only one shared object.
1840             LLVM_LIBS="-l$LLVM_SO_NAME"
1841         else
1842             dnl If LLVM was built with CMake, there will be one shared object per
1843             dnl component.
1844             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1845                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1846         Please make sure you have built llvm with the --enable-shared option
1847         and that your llvm libraries are installed in $LLVM_LIBDIR
1848         If you have installed your llvm libraries to a different directory you
1849         can use the --with-llvm-prefix= configure flag to specify this directory.
1850         NOTE: Mesa is attempting to use llvm shared libraries because you have
1851         passed one of the following options to configure:
1852                 --with-llvm-shared-libs
1853                 --enable-opencl
1854         If you do not want to build with llvm shared libraries and instead want to
1855         use llvm static libraries then remove these options from your configure
1856         invocation and reconfigure.])])
1857
1858            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1859            dnl install uses a shared object for each compoenent and we have
1860            dnl already added all of these objects to LLVM_LIBS.
1861         fi
1862     fi
1863 fi
1864
1865 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1866 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1867 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1868 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1869 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1870 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1871 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1872 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1873 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1874 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1875
1876 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1877                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1878                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1879 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1880                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1881                                                   && test "x$MESA_LLVM" = x1)
1882
1883 # NOTE: anything using xcb or other client side libs ends up in separate
1884 #       _CLIENT variables.  The pipe loader is built in two variants,
1885 #       one that is standalone and does not link any x client libs (for
1886 #       use by XA tracker in particular, but could be used in any case
1887 #       where communication with xserver is not desired).
1888 if test "x$enable_gallium_loader" = xyes; then
1889     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1890
1891     if test "x$enable_gallium_xlib_loader" = xyes; then
1892         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1893         NEED_WINSYS_XLIB="yes"
1894         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1895     fi
1896
1897     if test "x$enable_gallium_drm_loader" = xyes; then
1898         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1899         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1900                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1901         if test "x$pipe_loader_have_xcb" = xyes; then
1902             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1903             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1904         fi
1905     fi
1906
1907     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1908     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1909
1910     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1911     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1912     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1913     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1914 fi
1915 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1916
1917 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1918 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1919 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1920 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1921 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1922 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1923
1924 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1925                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1926                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1927                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1928 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1929                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1930 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1931 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1932 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1933 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1934 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1935 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1936 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1937
1938 AC_SUBST([ELF_LIB])
1939
1940 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1941 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1942 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1943 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1944 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1945
1946 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1947 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1948 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1949
1950 AC_SUBST([VDPAU_MAJOR], 1)
1951 AC_SUBST([VDPAU_MINOR], 0)
1952
1953 AC_SUBST([XVMC_MAJOR], 1)
1954 AC_SUBST([XVMC_MINOR], 0)
1955
1956 AC_SUBST([XA_MAJOR], 2)
1957 AC_SUBST([XA_MINOR], 2)
1958 AC_SUBST([XA_TINY], 0)
1959 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1960
1961 dnl Restore LDFLAGS and CPPFLAGS
1962 LDFLAGS="$_SAVE_LDFLAGS"
1963 CPPFLAGS="$_SAVE_CPPFLAGS"
1964
1965 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1966 if test "x$acv_mesa_CLANG" = xyes; then
1967     CFLAGS="$CFLAGS -Qunused-arguments"
1968     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1969 fi
1970
1971 dnl Add user CFLAGS and CXXFLAGS
1972 CFLAGS="$CFLAGS $USER_CFLAGS"
1973 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1974
1975 dnl Substitute the config
1976 AC_CONFIG_FILES([Makefile
1977                 src/Makefile
1978                 src/egl/Makefile
1979                 src/egl/drivers/Makefile
1980                 src/egl/drivers/dri2/Makefile
1981                 src/egl/main/Makefile
1982                 src/egl/main/egl.pc
1983                 src/egl/wayland/Makefile
1984                 src/egl/wayland/wayland-drm/Makefile
1985                 src/egl/wayland/wayland-egl/Makefile
1986                 src/egl/wayland/wayland-egl/wayland-egl.pc
1987                 src/gallium/auxiliary/Makefile
1988                 src/gallium/auxiliary/pipe-loader/Makefile
1989                 src/gallium/drivers/Makefile
1990                 src/gallium/drivers/freedreno/Makefile
1991                 src/gallium/drivers/galahad/Makefile
1992                 src/gallium/drivers/i915/Makefile
1993                 src/gallium/drivers/identity/Makefile
1994                 src/gallium/drivers/ilo/Makefile
1995                 src/gallium/drivers/llvmpipe/Makefile
1996                 src/gallium/drivers/noop/Makefile
1997                 src/gallium/drivers/nouveau/Makefile
1998                 src/gallium/drivers/r300/Makefile
1999                 src/gallium/drivers/r600/Makefile
2000                 src/gallium/drivers/radeon/Makefile
2001                 src/gallium/drivers/radeonsi/Makefile
2002                 src/gallium/drivers/rbug/Makefile
2003                 src/gallium/drivers/softpipe/Makefile
2004                 src/gallium/drivers/svga/Makefile
2005                 src/gallium/drivers/trace/Makefile
2006                 src/gallium/state_trackers/Makefile
2007                 src/gallium/state_trackers/clover/Makefile
2008                 src/gallium/state_trackers/dri/Makefile
2009                 src/gallium/state_trackers/dri/drm/Makefile
2010                 src/gallium/state_trackers/dri/sw/Makefile
2011                 src/gallium/state_trackers/egl/Makefile
2012                 src/gallium/state_trackers/gbm/Makefile
2013                 src/gallium/state_trackers/glx/xlib/Makefile
2014                 src/gallium/state_trackers/omx/Makefile
2015                 src/gallium/state_trackers/osmesa/Makefile
2016                 src/gallium/state_trackers/vdpau/Makefile
2017                 src/gallium/state_trackers/vega/Makefile
2018                 src/gallium/state_trackers/xa/Makefile
2019                 src/gallium/state_trackers/xvmc/Makefile
2020                 src/gallium/targets/Makefile
2021                 src/gallium/targets/dri-freedreno/Makefile
2022                 src/gallium/targets/dri-i915/Makefile
2023                 src/gallium/targets/dri-ilo/Makefile
2024                 src/gallium/targets/dri-nouveau/Makefile
2025                 src/gallium/targets/dri-swrast/Makefile
2026                 src/gallium/targets/dri-vmwgfx/Makefile
2027                 src/gallium/targets/egl-static/Makefile
2028                 src/gallium/targets/gbm/Makefile
2029                 src/gallium/targets/opencl/Makefile
2030                 src/gallium/targets/xa/Makefile
2031                 src/gallium/targets/xa/xatracker.pc
2032                 src/gallium/targets/osmesa/Makefile
2033                 src/gallium/targets/osmesa/osmesa.pc
2034                 src/gallium/targets/pipe-loader/Makefile
2035                 src/gallium/targets/radeonsi/dri/Makefile
2036                 src/gallium/targets/radeonsi/omx/Makefile
2037                 src/gallium/targets/radeonsi/vdpau/Makefile
2038                 src/gallium/targets/r300/dri/Makefile
2039                 src/gallium/targets/r600/dri/Makefile
2040                 src/gallium/targets/r600/omx/Makefile
2041                 src/gallium/targets/r600/vdpau/Makefile
2042                 src/gallium/targets/r600/xvmc/Makefile
2043                 src/gallium/targets/libgl-xlib/Makefile
2044                 src/gallium/targets/vdpau-nouveau/Makefile
2045                 src/gallium/targets/xvmc-nouveau/Makefile
2046                 src/gallium/tests/trivial/Makefile
2047                 src/gallium/tests/unit/Makefile
2048                 src/gallium/winsys/Makefile
2049                 src/gallium/winsys/freedreno/drm/Makefile
2050                 src/gallium/winsys/i915/drm/Makefile
2051                 src/gallium/winsys/i915/sw/Makefile
2052                 src/gallium/winsys/intel/drm/Makefile
2053                 src/gallium/winsys/nouveau/drm/Makefile
2054                 src/gallium/winsys/radeon/drm/Makefile
2055                 src/gallium/winsys/svga/drm/Makefile
2056                 src/gallium/winsys/sw/dri/Makefile
2057                 src/gallium/winsys/sw/fbdev/Makefile
2058                 src/gallium/winsys/sw/null/Makefile
2059                 src/gallium/winsys/sw/wayland/Makefile
2060                 src/gallium/winsys/sw/wrapper/Makefile
2061                 src/gallium/winsys/sw/xlib/Makefile
2062                 src/gbm/Makefile
2063                 src/gbm/main/gbm.pc
2064                 src/glsl/Makefile
2065                 src/glx/Makefile
2066                 src/glx/tests/Makefile
2067                 src/gtest/Makefile
2068                 src/loader/Makefile
2069                 src/mapi/Makefile
2070                 src/mapi/es1api/Makefile
2071                 src/mapi/es1api/glesv1_cm.pc
2072                 src/mapi/es2api/Makefile
2073                 src/mapi/es2api/glesv2.pc
2074                 src/mapi/glapi/Makefile
2075                 src/mapi/glapi/gen/Makefile
2076                 src/mapi/glapi/tests/Makefile
2077                 src/mapi/shared-glapi/Makefile
2078                 src/mapi/shared-glapi/tests/Makefile
2079                 src/mapi/vgapi/Makefile
2080                 src/mapi/vgapi/vg.pc
2081                 src/mesa/Makefile
2082                 src/mesa/gl.pc
2083                 src/mesa/drivers/dri/dri.pc
2084                 src/mesa/drivers/dri/common/Makefile
2085                 src/mesa/drivers/dri/common/xmlpool/Makefile
2086                 src/mesa/drivers/dri/i915/Makefile
2087                 src/mesa/drivers/dri/i965/Makefile
2088                 src/mesa/drivers/dri/Makefile
2089                 src/mesa/drivers/dri/nouveau/Makefile
2090                 src/mesa/drivers/dri/r200/Makefile
2091                 src/mesa/drivers/dri/radeon/Makefile
2092                 src/mesa/drivers/dri/swrast/Makefile
2093                 src/mesa/drivers/osmesa/Makefile
2094                 src/mesa/drivers/osmesa/osmesa.pc
2095                 src/mesa/drivers/x11/Makefile
2096                 src/mesa/main/tests/Makefile
2097                 src/mesa/main/tests/hash_table/Makefile])
2098
2099 dnl Sort the dirs alphabetically
2100 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2101 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2102 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2103 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2104
2105 AC_OUTPUT
2106
2107 dnl
2108 dnl Output some configuration info for the user
2109 dnl
2110 echo ""
2111 echo "        prefix:          $prefix"
2112 echo "        exec_prefix:     $exec_prefix"
2113 echo "        libdir:          $libdir"
2114 echo "        includedir:      $includedir"
2115
2116 dnl API info
2117 echo ""
2118 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2119 echo "        OpenVG:          $enable_openvg"
2120
2121 dnl Driver info
2122 echo ""
2123 case "x$enable_osmesa$enable_gallium_osmesa" in
2124 xnoyes)
2125         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2126         ;;
2127 xyesno)
2128         echo "        OSMesa:          lib$OSMESA_LIB"
2129         ;;
2130 xnono)
2131         echo "        OSMesa:          no"
2132         ;;
2133 esac
2134
2135 if test "x$enable_dri" != xno; then
2136         if test -z "$DRI_DIRS"; then
2137             echo "        DRI drivers:     no"
2138         else
2139             echo "        DRI drivers:     $DRI_DIRS"
2140         fi
2141         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2142 fi
2143
2144 case "x$enable_glx$enable_xlib_glx" in
2145 xyesyes)
2146     echo "        GLX:             Xlib-based"
2147     ;;
2148 xyesno)
2149     echo "        GLX:             DRI-based"
2150     ;;
2151 *)
2152     echo "        GLX:             $enable_glx"
2153     ;;
2154 esac
2155
2156 dnl EGL
2157 echo ""
2158 echo "        EGL:             $enable_egl"
2159 if test "$enable_egl" = yes; then
2160     echo "        EGL platforms:   $egl_platforms"
2161
2162     egl_drivers=""
2163     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2164         egl_drivers="$egl_drivers builtin:egl_dri2"
2165     fi
2166
2167     if test "x$enable_gallium_egl" = xyes; then
2168         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2169         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2170     else
2171         echo "        EGL drivers:    $egl_drivers"
2172     fi
2173 fi
2174
2175 echo ""
2176 if test "x$MESA_LLVM" = x1; then
2177     echo "        llvm:            yes"
2178     echo "        llvm-config:     $LLVM_CONFIG"
2179     echo "        llvm-version:    $LLVM_VERSION"
2180 else
2181     echo "        llvm:            no"
2182 fi
2183
2184 echo ""
2185 if test -n "$with_gallium_drivers"; then
2186     echo "        Gallium:         yes"
2187     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2188     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2189     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2190     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2191 else
2192     echo "        Gallium:         no"
2193 fi
2194
2195
2196 dnl Libraries
2197 echo ""
2198 echo "        Shared libs:     $enable_shared"
2199 echo "        Static libs:     $enable_static"
2200 echo "        Shared-glapi:    $enable_shared_glapi"
2201
2202 dnl Compiler options
2203 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2204 cflags=`echo $CFLAGS | \
2205     $SED 's/^ *//;s/  */ /;s/ *$//'`
2206 cxxflags=`echo $CXXFLAGS | \
2207     $SED 's/^ *//;s/  */ /;s/ *$//'`
2208 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2209 echo ""
2210 echo "        CFLAGS:          $cflags"
2211 echo "        CXXFLAGS:        $cxxflags"
2212 echo "        Macros:          $defines"
2213 echo ""
2214 if test "x$MESA_LLVM" = x1; then
2215     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2216     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2217     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2218     echo ""
2219 fi
2220 echo "        PYTHON2:         $PYTHON2"
2221
2222 echo ""
2223 echo "        Run '${MAKE-make}' to build Mesa"
2224 echo ""