configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCB_REQUIRED=1.9.3
  45 XCBDRI2_REQUIRED=1.8
  46 XCBGLX_REQUIRED=1.8.1
  47 XSHMFENCE_REQUIRED=1.1
  48 XVMC_REQUIRED=1.0.6
  49
  50 dnl Check for progs
  51 AC_PROG_CPP
  52 AC_PROG_CC
  53 AC_PROG_CXX
  54 AM_PROG_CC_C_O
  55 AM_PROG_AS
  56 AX_CHECK_GNU_MAKE
  57 AC_CHECK_PROGS([PYTHON2], [python2 python])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 AC_SYS_LARGEFILE
  62
  63 LT_PREREQ([2.2])
  64 LT_INIT([disable-static])
  65
  66 AX_PROG_BISON([],
  67               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  68                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  69 AX_PROG_FLEX([],
  70              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  71                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133 AX_GCC_BUILTIN([__builtin_clz])
 134 AX_GCC_BUILTIN([__builtin_clzll])
 135 AX_GCC_BUILTIN([__builtin_ctz])
 136 AX_GCC_BUILTIN([__builtin_expect])
 137 AX_GCC_BUILTIN([__builtin_ffs])
 138 AX_GCC_BUILTIN([__builtin_ffsll])
 139 AX_GCC_BUILTIN([__builtin_popcount])
 140 AX_GCC_BUILTIN([__builtin_popcountll])
 141 AX_GCC_BUILTIN([__builtin_unreachable])
 142
 143 AX_GCC_FUNC_ATTRIBUTE([flatten])
 144 AX_GCC_FUNC_ATTRIBUTE([format])
 145 AX_GCC_FUNC_ATTRIBUTE([malloc])
 146 AX_GCC_FUNC_ATTRIBUTE([packed])
 147
 148 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 149
 150 dnl Make sure the pkg-config macros are defined
 151 m4_ifndef([PKG_PROG_PKG_CONFIG],
 152     [m4_fatal([Could not locate the pkg-config autoconf macros.
 153   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 154   are in a different location, try setting the environment variable
 155   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 156 PKG_PROG_PKG_CONFIG()
 157
 158 dnl LIB_DIR - library basename
 159 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 160 AC_SUBST([LIB_DIR])
 161
 162 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 163 _SAVE_LDFLAGS="$LDFLAGS"
 164 _SAVE_CPPFLAGS="$CPPFLAGS"
 165
 166 dnl Compiler macros
 167 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 168 AC_SUBST([DEFINES])
 169 case "$host_os" in
 170 linux*|*-gnu*|gnu*)
 171     DEFINES="$DEFINES -D_GNU_SOURCE"
 172     ;;
 173 solaris*)
 174     DEFINES="$DEFINES -DSVR4"
 175     ;;
 176 cygwin*)
 177     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 178     ;;
 179 esac
 180
 181 dnl Add flags for gcc and g++
 182 if test "x$GCC" = xyes; then
 183     CFLAGS="$CFLAGS -Wall -std=c99"
 184
 185     # Enable -Werror=implicit-function-declaration and
 186     # -Werror=missing-prototypes, if available, or otherwise, just
 187     # -Wmissing-prototypes.  This is particularly useful to avoid
 188     # generating a loadable driver module that has undefined symbols.
 189     save_CFLAGS="$CFLAGS"
 190     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 191     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 192     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 193     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 194                    AC_MSG_RESULT([yes]),
 195                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 196                     AC_MSG_RESULT([no])]);
 197
 198     # Enable -fvisibility=hidden if using a gcc that supports it
 199     save_CFLAGS="$CFLAGS"
 200     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 201     VISIBILITY_CFLAGS="-fvisibility=hidden"
 202     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 203     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 204                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 205
 206     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 207     CFLAGS=$save_CFLAGS
 208
 209     # Work around aliasing bugs - developers should comment this out
 210     CFLAGS="$CFLAGS -fno-strict-aliasing"
 211
 212     # gcc's builtin memcmp is slower than glibc's
 213     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 214     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 215 fi
 216 if test "x$GXX" = xyes; then
 217     CXXFLAGS="$CXXFLAGS -Wall"
 218
 219     # Enable -fvisibility=hidden if using a gcc that supports it
 220     save_CXXFLAGS="$CXXFLAGS"
 221     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 222     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 223     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 224     AC_LANG_PUSH([C++])
 225     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 226                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 227     AC_LANG_POP([C++])
 228
 229     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 230     CXXFLAGS=$save_CXXFLAGS
 231
 232     # Work around aliasing bugs - developers should comment this out
 233     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 234
 235     # gcc's builtin memcmp is slower than glibc's
 236     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 237     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 238 fi
 239
 240 dnl even if the compiler appears to support it, using visibility attributes isn't
 241 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 242 case "$host_os" in
 243 cygwin*)
 244     VISIBILITY_CFLAGS=""
 245     VISIBILITY_CXXFLAGS=""
 246     ;;
 247 esac
 248
 249 AC_SUBST([VISIBILITY_CFLAGS])
 250 AC_SUBST([VISIBILITY_CXXFLAGS])
 251
 252 dnl
 253 dnl Optional flags, check for compiler support
 254 dnl
 255 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 256 if test "x$SSE41_SUPPORTED" = x1; then
 257     DEFINES="$DEFINES -DUSE_SSE41"
 258 fi
 259 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 260
 261 dnl Can't have static and shared libraries, default to static if user
 262 dnl explicitly requested. If both disabled, set to static since shared
 263 dnl was explicitly requested.
 264 case "x$enable_static$enable_shared" in
 265 xyesyes)
 266     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 267     enable_shared=no
 268     ;;
 269 xnono)
 270     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 271     enable_shared=yes
 272     ;;
 273 esac
 274
 275 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 276
 277 dnl
 278 dnl other compiler options
 279 dnl
 280 AC_ARG_ENABLE([debug],
 281     [AS_HELP_STRING([--enable-debug],
 282         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 283     [enable_debug="$enableval"],
 284     [enable_debug=no]
 285 )
 286 if test "x$enable_debug" = xyes; then
 287     DEFINES="$DEFINES -DDEBUG"
 288     if test "x$GCC" = xyes; then
 289         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 290             CFLAGS="$CFLAGS -g"
 291         fi
 292         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 293             CFLAGS="$CFLAGS -O0"
 294         fi
 295     fi
 296     if test "x$GXX" = xyes; then
 297         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 298             CXXFLAGS="$CXXFLAGS -g"
 299         fi
 300         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 301             CXXFLAGS="$CXXFLAGS -O0"
 302         fi
 303     fi
 304 fi
 305
 306 dnl
 307 dnl Check if linker supports -Bsymbolic
 308 dnl
 309 save_LDFLAGS=$LDFLAGS
 310 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 311 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 312 AC_LINK_IFELSE(
 313     [AC_LANG_SOURCE([int main() { return 0;}])],
 314     [AC_MSG_RESULT([yes])
 315         BSYMBOLIC="-Wl,-Bsymbolic";],
 316     [AC_MSG_RESULT([no])
 317         BSYMBOLIC="";])
 318 LDFLAGS=$save_LDFLAGS
 319
 320 AC_SUBST([BSYMBOLIC])
 321
 322 dnl
 323 dnl Check if linker supports garbage collection
 324 dnl
 325 save_LDFLAGS=$LDFLAGS
 326 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 327 AC_MSG_CHECKING([whether ld supports --gc-sections])
 328 AC_LINK_IFELSE(
 329     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 330     [AC_MSG_RESULT([yes])
 331         GC_SECTIONS="-Wl,--gc-sections";],
 332     [AC_MSG_RESULT([no])
 333         GC_SECTIONS="";])
 334 LDFLAGS=$save_LDFLAGS
 335
 336 AC_SUBST([GC_SECTIONS])
 337
 338 dnl
 339 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 340 dnl so when these flags are passed to ld via libtool the checks will fail
 341 dnl
 342 case "$host_os" in
 343 openbsd* | darwin* )
 344     LD_NO_UNDEFINED="" ;;
 345 *)
 346     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 347 esac
 348
 349 AC_SUBST([LD_NO_UNDEFINED])
 350
 351 dnl
 352 dnl Check if linker supports version scripts
 353 dnl
 354 AC_MSG_CHECKING([if the linker supports version-scripts])
 355 save_LDFLAGS=$LDFLAGS
 356 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 357 cat > conftest.map <<EOF
 358 VERSION_1 {
 359      global:
 360          main;
 361
 362      local:
 363          *;
 364 };
 365 EOF
 366 AC_LINK_IFELSE(
 367     [AC_LANG_SOURCE([int main() { return 0;}])],
 368     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 369     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 370 LDFLAGS=$save_LDFLAGS
 371 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 372
 373 dnl
 374 dnl Check if linker supports dynamic list files
 375 dnl
 376 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 377 save_LDFLAGS=$LDFLAGS
 378 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 379 cat > conftest.dyn <<EOF
 380 {
 381         radeon_drm_winsys_create;
 382 };
 383 EOF
 384 AC_LINK_IFELSE(
 385     [AC_LANG_SOURCE([int main() { return 0;}])],
 386     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 387     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 388 LDFLAGS=$save_LDFLAGS
 389 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 390
 391 dnl
 392 dnl compatibility symlinks
 393 dnl
 394 case "$host_os" in
 395 linux* )
 396     HAVE_COMPAT_SYMLINKS=yes ;;
 397 * )
 398     HAVE_COMPAT_SYMLINKS=no ;;
 399 esac
 400
 401 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 402
 403 dnl
 404 dnl library names
 405 dnl
 406 case "$host_os" in
 407 darwin* )
 408     LIB_EXT='dylib' ;;
 409 cygwin* )
 410     LIB_EXT='dll' ;;
 411 aix* )
 412     LIB_EXT='a' ;;
 413 * )
 414     LIB_EXT='so' ;;
 415 esac
 416
 417 AC_SUBST([LIB_EXT])
 418
 419 AC_ARG_WITH([gl-lib-name],
 420   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 421     [specify GL library name @<:@default=GL@:>@])],
 422   [GL_LIB=$withval],
 423   [GL_LIB=GL])
 424 AC_ARG_WITH([osmesa-lib-name],
 425   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 426     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 427   [OSMESA_LIB=$withval],
 428   [OSMESA_LIB=OSMesa])
 429 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 430 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 431
 432 dnl
 433 dnl Mangled Mesa support
 434 dnl
 435 AC_ARG_ENABLE([mangling],
 436   [AS_HELP_STRING([--enable-mangling],
 437     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 438   [enable_mangling="${enableval}"],
 439   [enable_mangling=no]
 440 )
 441 if test "x${enable_mangling}" = "xyes" ; then
 442   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 443   GL_LIB="Mangled${GL_LIB}"
 444   OSMESA_LIB="Mangled${OSMESA_LIB}"
 445 fi
 446 AC_SUBST([GL_LIB])
 447 AC_SUBST([OSMESA_LIB])
 448
 449 dnl
 450 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 451 dnl
 452 AC_ARG_ENABLE([texture-float],
 453     [AS_HELP_STRING([--enable-texture-float],
 454         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 455     [enable_texture_float="$enableval"],
 456     [enable_texture_float=no]
 457 )
 458 if test "x$enable_texture_float" = xyes; then
 459     AC_MSG_WARN([Floating-point textures enabled.])
 460     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 461     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 462 fi
 463
 464 dnl
 465 dnl Arch/platform-specific settings
 466 dnl
 467 AC_ARG_ENABLE([asm],
 468     [AS_HELP_STRING([--disable-asm],
 469         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 470     [enable_asm="$enableval"],
 471     [enable_asm=yes]
 472 )
 473 asm_arch=""
 474 AC_MSG_CHECKING([whether to enable assembly])
 475 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 476 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 477 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 478     case "$host_cpu" in
 479     i?86 | x86_64 | amd64)
 480         enable_asm=no
 481         AC_MSG_RESULT([no, cross compiling])
 482         ;;
 483     esac
 484 fi
 485 # check for supported arches
 486 if test "x$enable_asm" = xyes; then
 487     case "$host_cpu" in
 488     i?86)
 489         case "$host_os" in
 490         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 491             asm_arch=x86
 492             ;;
 493         esac
 494         ;;
 495     x86_64|amd64)
 496         case "$host_os" in
 497         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 498             asm_arch=x86_64
 499             ;;
 500         esac
 501         ;;
 502     sparc*)
 503         case "$host_os" in
 504         linux*)
 505             asm_arch=sparc
 506             ;;
 507         esac
 508         ;;
 509     esac
 510
 511     case "$asm_arch" in
 512     x86)
 513         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 514         AC_MSG_RESULT([yes, x86])
 515         ;;
 516     x86_64|amd64)
 517         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 518         AC_MSG_RESULT([yes, x86_64])
 519         ;;
 520     sparc)
 521         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 522         AC_MSG_RESULT([yes, sparc])
 523         ;;
 524     *)
 525         AC_MSG_RESULT([no, platform not supported])
 526         ;;
 527     esac
 528 fi
 529
 530 dnl Check to see if dlopen is in default libraries (like Solaris, which
 531 dnl has it in libc), or if libdl is needed to get it.
 532 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 533     [AC_CHECK_LIB([dl], [dlopen],
 534        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 535 AC_SUBST([DLOPEN_LIBS])
 536
 537 dnl Check if that library also has dladdr
 538 save_LIBS="$LIBS"
 539 LIBS="$LIBS $DLOPEN_LIBS"
 540 AC_CHECK_FUNCS([dladdr])
 541 LIBS="$save_LIBS"
 542
 543 case "$host_os" in
 544 darwin*|mingw*)
 545     ;;
 546 *)
 547     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 548                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 549                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 550     AC_SUBST([CLOCK_LIB])
 551     ;;
 552 esac
 553
 554 dnl See if posix_memalign is available
 555 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 556
 557 dnl Check for pthreads
 558 case "$host_os" in
 559 mingw*)
 560     ;;
 561 *)
 562     AX_PTHREAD
 563     ;;
 564 esac
 565 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 566 dnl to -pthread, which causes problems if we need -lpthread to appear in
 567 dnl pkgconfig files.
 568 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 569
 570 dnl SELinux awareness.
 571 AC_ARG_ENABLE([selinux],
 572     [AS_HELP_STRING([--enable-selinux],
 573         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 574     [MESA_SELINUX="$enableval"],
 575     [MESA_SELINUX=no])
 576 if test "x$enable_selinux" = "xyes"; then
 577     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 578         [AC_CHECK_HEADER([selinux/selinux.h],[],
 579                          [AC_MSG_ERROR([SELinux headers not found])])
 580          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 581                       [AC_MSG_ERROR([SELinux library not found])])
 582          SELINUX_LIBS="-lselinux"])
 583     DEFINES="$DEFINES -DMESA_SELINUX"
 584 fi
 585 AC_SUBST([SELINUX_CFLAGS])
 586 AC_SUBST([SELINUX_LIBS])
 587
 588 dnl Options for APIs
 589 AC_ARG_ENABLE([opengl],
 590     [AS_HELP_STRING([--disable-opengl],
 591         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 592     [enable_opengl="$enableval"],
 593     [enable_opengl=yes])
 594 AC_ARG_ENABLE([gles1],
 595     [AS_HELP_STRING([--enable-gles1],
 596         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 597     [enable_gles1="$enableval"],
 598     [enable_gles1=no])
 599 AC_ARG_ENABLE([gles2],
 600     [AS_HELP_STRING([--enable-gles2],
 601         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 602     [enable_gles2="$enableval"],
 603     [enable_gles2=no])
 604 AC_ARG_ENABLE([openvg],
 605     [AS_HELP_STRING([--enable-openvg],
 606         [enable support for OpenVG API @<:@default=disabled@:>@])],
 607     [enable_openvg="$enableval"],
 608     [enable_openvg=no])
 609
 610 AC_ARG_ENABLE([dri],
 611     [AS_HELP_STRING([--enable-dri],
 612         [enable DRI modules @<:@default=enabled@:>@])],
 613     [enable_dri="$enableval"],
 614     [enable_dri=yes])
 615
 616 case "$host_os" in
 617 linux*)
 618     dri3_default=yes
 619     ;;
 620 *)
 621     dri3_default=no
 622     ;;
 623 esac
 624 AC_ARG_ENABLE([dri3],
 625     [AS_HELP_STRING([--enable-dri3],
 626         [enable DRI3 @<:@default=auto@:>@])],
 627     [enable_dri3="$enableval"],
 628     [enable_dri3="$dri3_default"])
 629 AC_ARG_ENABLE([glx],
 630     [AS_HELP_STRING([--enable-glx],
 631         [enable GLX library @<:@default=enabled@:>@])],
 632     [enable_glx="$enableval"],
 633     [enable_glx=yes])
 634 AC_ARG_ENABLE([osmesa],
 635     [AS_HELP_STRING([--enable-osmesa],
 636         [enable OSMesa library @<:@default=disabled@:>@])],
 637     [enable_osmesa="$enableval"],
 638     [enable_osmesa=no])
 639 AC_ARG_ENABLE([gallium-osmesa],
 640     [AS_HELP_STRING([--enable-gallium-osmesa],
 641         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 642     [enable_gallium_osmesa="$enableval"],
 643     [enable_gallium_osmesa=no])
 644 AC_ARG_ENABLE([egl],
 645     [AS_HELP_STRING([--disable-egl],
 646         [disable EGL library @<:@default=enabled@:>@])],
 647     [enable_egl="$enableval"],
 648     [enable_egl=yes])
 649
 650 AC_ARG_ENABLE([xa],
 651     [AS_HELP_STRING([--enable-xa],
 652         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 653     [enable_xa="$enableval"],
 654     [enable_xa=no])
 655 AC_ARG_ENABLE([gbm],
 656    [AS_HELP_STRING([--enable-gbm],
 657          [enable gbm library @<:@default=auto@:>@])],
 658    [enable_gbm="$enableval"],
 659    [enable_gbm=auto])
 660
 661 AC_ARG_ENABLE([xvmc],
 662    [AS_HELP_STRING([--enable-xvmc],
 663          [enable xvmc library @<:@default=auto@:>@])],
 664    [enable_xvmc="$enableval"],
 665    [enable_xvmc=auto])
 666 AC_ARG_ENABLE([vdpau],
 667    [AS_HELP_STRING([--enable-vdpau],
 668          [enable vdpau library @<:@default=auto@:>@])],
 669    [enable_vdpau="$enableval"],
 670    [enable_vdpau=auto])
 671 AC_ARG_ENABLE([omx],
 672    [AS_HELP_STRING([--enable-omx],
 673          [enable OpenMAX library @<:@default=disabled@:>@])],
 674    [enable_omx="$enableval"],
 675    [enable_omx=no])
 676 AC_ARG_ENABLE([va],
 677    [AS_HELP_STRING([--enable-va],
 678          [enable va library @<:@default=auto@:>@])],
 679    [enable_va="$enableval"],
 680    [enable_va=auto])
 681 AC_ARG_ENABLE([opencl],
 682    [AS_HELP_STRING([--enable-opencl],
 683          [enable OpenCL library @<:@default=disabled@:>@])],
 684    [enable_opencl="$enableval"],
 685    [enable_opencl=no])
 686 AC_ARG_ENABLE([opencl_icd],
 687    [AS_HELP_STRING([--enable-opencl-icd],
 688           [Build an OpenCL ICD library to be loaded by an ICD implementation
 689            @<:@default=disabled@:>@])],
 690     [enable_opencl_icd="$enableval"],
 691     [enable_opencl_icd=no])
 692 AC_ARG_ENABLE([xlib-glx],
 693     [AS_HELP_STRING([--enable-xlib-glx],
 694         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 695     [enable_xlib_glx="$enableval"],
 696     [enable_xlib_glx=no])
 697 AC_ARG_ENABLE([gallium-egl],
 698     [AS_HELP_STRING([--enable-gallium-egl],
 699         [enable optional EGL state tracker (not required
 700          for EGL support in Gallium with OpenGL and OpenGL ES)
 701          @<:@default=disabled@:>@])],
 702     [enable_gallium_egl="$enableval"],
 703     [enable_gallium_egl=no])
 704 AC_ARG_ENABLE([gallium-gbm],
 705     [AS_HELP_STRING([--enable-gallium-gbm],
 706         [enable optional gbm state tracker (not required for
 707          gbm support in Gallium)
 708          @<:@default=auto@:>@])],
 709     [enable_gallium_gbm="$enableval"],
 710     [enable_gallium_gbm=auto])
 711
 712 AC_ARG_ENABLE([r600-llvm-compiler],
 713     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 714         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 715     [enable_r600_llvm="$enableval"],
 716     [enable_r600_llvm=no])
 717
 718 AC_ARG_ENABLE([gallium-tests],
 719     [AS_HELP_STRING([--enable-gallium-tests],
 720         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 721     [enable_gallium_tests="$enableval"],
 722     [enable_gallium_tests=no])
 723
 724 # Option for Gallium drivers
 725
 726 # Keep this in sync with the --with-gallium-drivers help string default value
 727 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 728
 729 AC_ARG_WITH([gallium-drivers],
 730     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 731         [comma delimited Gallium drivers list, e.g.
 732         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 733         @<:@default=r300,r600,svga,swrast@:>@])],
 734     [with_gallium_drivers="$withval"],
 735     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 736
 737 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 738 # here so that the script doesn't choke on an unknown driver name later.
 739 case "$with_gallium_drivers" in
 740     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 741     no) with_gallium_drivers='' ;;
 742 esac
 743
 744 if test "x$enable_opengl" = xno -a \
 745         "x$enable_gles1" = xno -a \
 746         "x$enable_gles2" = xno -a \
 747         "x$enable_openvg" = xno -a \
 748         "x$enable_xa" = xno -a \
 749         "x$enable_xvmc" = xno -a \
 750         "x$enable_vdpau" = xno -a \
 751         "x$enable_omx" = xno -a \
 752         "x$enable_va" = xno -a \
 753         "x$enable_opencl" = xno; then
 754     AC_MSG_ERROR([at least one API should be enabled])
 755 fi
 756
 757 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 758 if test "x$enable_opengl" = xno -a \
 759         "x$enable_gles1" = xyes; then
 760     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 761 fi
 762
 763 if test "x$enable_opengl" = xno -a \
 764         "x$enable_gles2" = xyes; then
 765     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 766 fi
 767
 768 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 769 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 770 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 771 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 772                                         "x$enable_gles1" = xyes -o \
 773                                         "x$enable_gles2" = xyes)
 774
 775 if test "x$enable_glx" = xno; then
 776     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 777     enable_xlib_glx=no
 778 fi
 779
 780 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 781     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 782 fi
 783
 784 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 785     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 786 fi
 787
 788 # Disable GLX if OpenGL is not enabled
 789 if test "x$enable_glx$enable_opengl" = xyesno; then
 790     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 791     enable_glx=no
 792 fi
 793
 794 # Disable GLX if DRI and Xlib-GLX are not enabled
 795 if test "x$enable_glx" = xyes -a \
 796         "x$enable_dri" = xno -a \
 797         "x$enable_xlib_glx" = xno; then
 798     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 799     enable_glx=no
 800 fi
 801
 802 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 803                                   "x$enable_dri" = xyes)
 804
 805 # Select which platform-dependent DRI code gets built
 806 case "$host_os" in
 807 darwin*)
 808     dri_platform='apple' ;;
 809 gnu*|mingw*|cygwin*)
 810     dri_platform='none' ;;
 811 *)
 812     dri_platform='drm' ;;
 813 esac
 814
 815 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 816 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 817 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 818 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 819 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 820
 821 AC_ARG_ENABLE([shared-glapi],
 822     [AS_HELP_STRING([--enable-shared-glapi],
 823         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 824     [enable_shared_glapi="$enableval"],
 825     [enable_shared_glapi=yes])
 826
 827 case "x$enable_opengl$enable_gles1$enable_gles2" in
 828 x*yes*yes*)
 829     if test "x$enable_shared_glapi" = xno; then
 830         AC_MSG_ERROR([shared GLAPI required when building two or more of
 831                       the following APIs - opengl, gles1 gles2])
 832     fi
 833     ;;
 834 esac
 835
 836 # Building Xlib-GLX requires shared glapi to be disabled.
 837 if test "x$enable_xlib_glx" = xyes; then
 838     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 839     enable_shared_glapi=no
 840 fi
 841
 842 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 843
 844 # Build the pipe-drivers as separate libraries/modules.
 845 # Do not touch this unless you know what you are doing.
 846 # XXX: Expose via configure option ?
 847 enable_shared_pipe_drivers=no
 848
 849 dnl
 850 dnl Driver specific build directories
 851 dnl
 852
 853 case "x$enable_glx$enable_xlib_glx" in
 854 xyesyes)
 855     NEED_WINSYS_XLIB="yes"
 856     ;;
 857 esac
 858
 859 if test "x$enable_dri" = xyes; then
 860     enable_gallium_loader="$enable_shared_pipe_drivers"
 861 fi
 862
 863 if test "x$enable_gallium_osmesa" = xyes; then
 864     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 865         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 866     fi
 867     if test "x$enable_osmesa" = xyes; then
 868         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 869     fi
 870 fi
 871
 872 AC_SUBST([MESA_LLVM])
 873
 874 # Check for libdrm
 875 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 876                   [have_libdrm=yes], [have_libdrm=no])
 877 if test "x$have_libdrm" = xyes; then
 878         DEFINES="$DEFINES -DHAVE_LIBDRM"
 879 fi
 880
 881 case "$host_os" in
 882 linux*)
 883     need_pci_id=yes ;;
 884 *)
 885     need_pci_id=no ;;
 886 esac
 887
 888 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 889                   have_libudev=yes, have_libudev=no)
 890
 891 AC_ARG_ENABLE([sysfs],
 892     [AS_HELP_STRING([--enable-sysfs],
 893         [enable /sys PCI identification @<:@default=disabled@:>@])],
 894     [have_sysfs="$enableval"],
 895     [have_sysfs=no]
 896 )
 897
 898 if test "x$enable_dri" = xyes; then
 899     if test "$enable_static" = yes; then
 900         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 901     fi
 902
 903     # not a hard requirement as swrast does not depend on it
 904     if test "x$have_libdrm" = xyes; then
 905         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 906     fi
 907 fi
 908
 909 AC_ARG_ENABLE([driglx-direct],
 910     [AS_HELP_STRING([--disable-driglx-direct],
 911         [disable direct rendering in GLX and EGL for DRI \
 912             @<:@default=auto@:>@])],
 913     [driglx_direct="$enableval"],
 914     [driglx_direct="yes"])
 915
 916 dnl
 917 dnl libGL configuration per driver
 918 dnl
 919 case "x$enable_glx$enable_xlib_glx" in
 920 xyesyes)
 921     # Xlib-based GLX
 922     dri_modules="x11 xext xcb"
 923     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 924     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 925     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 926     GL_LIB_DEPS="$XLIBGL_LIBS"
 927     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 928     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 929     ;;
 930 xyesno)
 931     # DRI-based GLX
 932     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 933
 934     # find the DRI deps for libGL
 935     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 936
 937     if test x"$driglx_direct" = xyes; then
 938         if test x"$dri_platform" = xdrm ; then
 939             DEFINES="$DEFINES -DGLX_USE_DRM"
 940             if test "x$have_libdrm" != xyes; then
 941                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 942             fi
 943
 944             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 945             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 946             if test x"$enable_dri3" = xyes; then
 947                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 948                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 949             fi
 950
 951             if test x"$enable_dri" = xyes; then
 952                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 953             fi
 954
 955             if test x"$enable_dri3" = xyes; then
 956                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 957                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 958             fi
 959         fi
 960         if test x"$dri_platform" = xapple ; then
 961             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 962         fi
 963     fi
 964
 965     # add xf86vidmode if available
 966     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 967     if test "$HAVE_XF86VIDMODE" = yes ; then
 968         dri_modules="$dri_modules xxf86vm"
 969     fi
 970
 971     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 972     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 973     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 974     GL_LIB_DEPS="$DRIGL_LIBS"
 975
 976     # need DRM libs, $PTHREAD_LIBS, etc.
 977     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 978     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 979     ;;
 980 esac
 981
 982 have_pci_id=no
 983 if test "$have_libudev" = yes; then
 984     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 985     have_pci_id=yes
 986 fi
 987
 988 if test "$have_sysfs" = yes; then
 989     DEFINES="$DEFINES -DHAVE_SYSFS"
 990     have_pci_id=yes
 991 fi
 992
 993 # This is outside the case (above) so that it is invoked even for non-GLX
 994 # builds.
 995 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 996
 997 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 998 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 999 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1000 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1001
1002 AC_SUBST([X11_INCLUDES])
1003 AC_SUBST([GL_LIB_DEPS])
1004 AC_SUBST([GL_PC_REQ_PRIV])
1005 AC_SUBST([GL_PC_LIB_PRIV])
1006 AC_SUBST([GL_PC_CFLAGS])
1007 AC_SUBST([DRI_PC_REQ_PRIV])
1008 AC_SUBST([GLESv1_CM_LIB_DEPS])
1009 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1010 AC_SUBST([GLESv2_LIB_DEPS])
1011 AC_SUBST([GLESv2_PC_LIB_PRIV])
1012
1013 AC_SUBST([HAVE_XF86VIDMODE])
1014
1015 dnl
1016 dnl More GLX setup
1017 dnl
1018 case "x$enable_glx$enable_xlib_glx" in
1019 xyesyes)
1020     DEFINES="$DEFINES -DUSE_XSHM"
1021     ;;
1022 xyesno)
1023     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1024     if test "x$driglx_direct" = xyes; then
1025         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1026     fi
1027     ;;
1028 esac
1029
1030 dnl
1031 dnl TLS detection
1032 dnl
1033
1034 AC_ARG_ENABLE([glx-tls],
1035     [AS_HELP_STRING([--enable-glx-tls],
1036         [enable TLS support in GLX @<:@default=disabled@:>@])],
1037     [GLX_USE_TLS="$enableval"],
1038     [GLX_USE_TLS=no])
1039 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1040
1041 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1042       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1043
1044 dnl
1045 dnl More DRI setup
1046 dnl
1047 dnl Directory for DRI drivers
1048 AC_ARG_WITH([dri-driverdir],
1049     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1050         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1051     [DRI_DRIVER_INSTALL_DIR="$withval"],
1052     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1053 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1054 dnl Extra search path for DRI drivers
1055 AC_ARG_WITH([dri-searchpath],
1056     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1057         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1058     [DRI_DRIVER_SEARCH_DIR="$withval"],
1059     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1060 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1061 dnl Which drivers to build - default is chosen by platform
1062 AC_ARG_WITH([dri-drivers],
1063     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1064         [comma delimited classic DRI drivers list, e.g.
1065         "swrast,i965,radeon" @<:@default=auto@:>@])],
1066     [with_dri_drivers="$withval"],
1067     [with_dri_drivers=auto])
1068
1069 if test "x$with_dri_drivers" = xauto; then
1070     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1071         with_dri_drivers="yes"
1072     else
1073         with_dri_drivers="no"
1074     fi
1075 fi
1076 if test "x$with_dri_drivers" = xno; then
1077     with_dri_drivers=''
1078 fi
1079
1080 dnl If $with_dri_drivers is yes, drivers will be added through
1081 dnl platform checks. Set DEFINES and LIB_DEPS
1082 if test "x$enable_dri" = xyes; then
1083     # Platform specific settings and drivers to build
1084     case "$host_os" in
1085     linux*)
1086         DEFINES="$DEFINES -DHAVE_ALIAS"
1087         if test "x$enable_dri3" = xyes; then
1088             DEFINES="$DEFINES -DHAVE_DRI3"
1089         fi
1090
1091         if test "x$have_pci_id" != xyes; then
1092             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1093         fi
1094
1095         case "$host_cpu" in
1096         powerpc* | sparc*)
1097             # Build only the drivers for cards that exist on PowerPC/sparc
1098             if test "x$with_dri_drivers" = "xyes"; then
1099                 with_dri_drivers="r200 radeon swrast"
1100             fi
1101             ;;
1102         esac
1103         ;;
1104     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1105         DEFINES="$DEFINES -DHAVE_ALIAS"
1106         ;;
1107     gnu*)
1108         DEFINES="$DEFINES -DHAVE_ALIAS"
1109         ;;
1110     cygwin*)
1111         if test "x$with_dri_drivers" = "xyes"; then
1112             with_dri_drivers="swrast"
1113         fi
1114         ;;
1115     darwin*)
1116         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1117         if test "x$with_dri_drivers" = "xyes"; then
1118             with_dri_drivers="swrast"
1119         fi
1120         ;;
1121     esac
1122
1123     # default drivers
1124     if test "x$with_dri_drivers" = "xyes"; then
1125         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1126     fi
1127
1128     # Check for expat
1129     PKG_CHECK_MODULES([EXPAT], [expat], [],
1130         # expat version 2.0 and earlier do not provide expat.pc
1131         [AC_CHECK_HEADER([expat.h],[],
1132                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1133          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1134                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1135          EXPAT_LIBS="-lexpat"])
1136
1137     DRICOMMON_NEED_LIBDRM=no
1138     # If we are building any DRI driver other than swrast.
1139     if test -n "$with_dri_drivers"; then
1140         if test "x$with_dri_drivers" != xswrast; then
1141             # ... libdrm is required
1142             if test "x$have_libdrm" != xyes; then
1143                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1144             fi
1145             DRICOMMON_NEED_LIBDRM=yes
1146         fi
1147     fi
1148
1149     # If we're building any gallium DRI driver other than swrast
1150     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1151         if test "x$with_gallium_drivers" != xswrast; then
1152             # ... build a libdrm aware dricommon
1153             DRICOMMON_NEED_LIBDRM=yes
1154         fi
1155     fi
1156
1157     # put all the necessary libs together
1158     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1159 fi
1160
1161 AC_SUBST([DRI_LIB_DEPS])
1162
1163 DRI_DIRS=''
1164 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1165 if test -n "$with_dri_drivers"; then
1166     if test "x$enable_opengl" != xyes; then
1167         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1168     fi
1169
1170     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1171     for driver in $dri_drivers; do
1172         DRI_DIRS="$DRI_DIRS $driver"
1173         case "x$driver" in
1174         xi915)
1175             HAVE_I915_DRI=yes;
1176             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1177             ;;
1178         xi965)
1179             HAVE_I965_DRI=yes;
1180             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1181             ;;
1182         xnouveau)
1183             HAVE_NOUVEAU_DRI=yes;
1184             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1185             ;;
1186         xradeon)
1187             HAVE_RADEON_DRI=yes;
1188             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1189             ;;
1190         xr200)
1191             HAVE_R200_DRI=yes;
1192             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1193             ;;
1194         xswrast)
1195             HAVE_SWRAST_DRI=yes;
1196             ;;
1197         *)
1198             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1199             ;;
1200         esac
1201     done
1202     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1203 fi
1204
1205 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1206 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1207                                   "x$enable_osmesa" = xyes -o \
1208                                   -n "$DRI_DIRS")
1209
1210 dnl
1211 dnl OSMesa configuration
1212 dnl
1213
1214 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1215 AC_ARG_WITH([osmesa-bits],
1216     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1217         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1218     [osmesa_bits="$withval"],
1219     [osmesa_bits=8])
1220 if test "x$osmesa_bits" != x8; then
1221     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1222         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1223         osmesa_bits=8
1224     fi
1225 fi
1226 case "x$osmesa_bits" in
1227 x8)
1228     OSMESA_LIB="${OSMESA_LIB}"
1229     ;;
1230 x16|x32)
1231     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1232     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1233     ;;
1234 *)
1235     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1236     ;;
1237 esac
1238
1239 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1240     # only link libraries with osmesa if shared
1241     if test "$enable_static" = no; then
1242         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1243     else
1244         OSMESA_LIB_DEPS=""
1245     fi
1246     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1247 fi
1248
1249 AC_SUBST([OSMESA_LIB_DEPS])
1250 AC_SUBST([OSMESA_PC_REQ])
1251 AC_SUBST([OSMESA_PC_LIB_PRIV])
1252
1253 dnl
1254 dnl gbm configuration
1255 dnl
1256 if test "x$enable_gbm" = xauto; then
1257     case "$with_egl_platforms" in
1258         *drm*)
1259             enable_gbm=yes ;;
1260          *)
1261             enable_gbm=no ;;
1262     esac
1263 fi
1264 if test "x$enable_gbm" = xyes; then
1265     if test "x$need_pci_id$have_pci_id" = xyesno; then
1266         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1267     fi
1268
1269     if test "x$enable_dri" = xyes; then
1270         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1271         if test "x$enable_shared_glapi" = xno; then
1272             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1273         fi
1274     else
1275         # Strictly speaking libgbm does not require --enable-dri, although
1276         # both of its backends do. Thus one can build libgbm without any
1277         # backends if --disable-dri is set.
1278         # To avoid unnecessary complexity of checking if at least one backend
1279         # is available when building, just mandate --enable-dri.
1280         AC_MSG_ERROR([gbm requires --enable-dri])
1281     fi
1282 fi
1283 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1284 if test "x$need_pci_id$have_libudev" = xyesyes; then
1285     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1286 else
1287     GBM_PC_REQ_PRIV=""
1288 fi
1289 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1290 AC_SUBST([GBM_PC_REQ_PRIV])
1291 AC_SUBST([GBM_PC_LIB_PRIV])
1292
1293 dnl
1294 dnl EGL configuration
1295 dnl
1296 EGL_CLIENT_APIS=""
1297
1298 if test "x$enable_egl" = xyes; then
1299     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1300
1301     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1302
1303     if test "$enable_static" != yes; then
1304         if test "x$enable_dri" = xyes; then
1305             HAVE_EGL_DRIVER_DRI2=1
1306         fi
1307
1308     fi
1309 fi
1310 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1311 AC_SUBST([EGL_LIB_DEPS])
1312
1313 dnl
1314 dnl EGL Gallium configuration
1315 dnl
1316 if test "x$enable_gallium_egl" = xyes; then
1317     if test -z "$with_gallium_drivers"; then
1318         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1319     fi
1320     if test "x$enable_egl" = xno; then
1321         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1322     fi
1323     if test "x$have_libdrm" != xyes; then
1324         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1325     fi
1326 # XXX: Uncomment once converted to use static/shared pipe-drivers
1327 #    enable_gallium_loader=$enable_shared_pipe_drivers
1328 fi
1329 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1330
1331 dnl
1332 dnl gbm Gallium configuration
1333 dnl
1334 if test "x$enable_gallium_gbm" = xauto; then
1335     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1336         yesyesyes*drm*)
1337             enable_gallium_gbm=yes ;;
1338          *)
1339             enable_gallium_gbm=no ;;
1340     esac
1341 fi
1342 if test "x$enable_gallium_gbm" = xyes; then
1343     if test -z "$with_gallium_drivers"; then
1344         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1345     fi
1346     if test "x$enable_gbm" = xno; then
1347         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1348     fi
1349
1350     if test "x$enable_gallium_egl" != xyes; then
1351         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1352     fi
1353
1354     enable_gallium_loader=$enable_shared_pipe_drivers
1355 fi
1356 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1357
1358 dnl
1359 dnl XA configuration
1360 dnl
1361 if test "x$enable_xa" = xyes; then
1362     if test "x$with_gallium_drivers" = xswrast; then
1363        AC_MSG_ERROR([
1364           Building xa requires at least one non swrast gallium driver.
1365           If you are looking to use libxatracker.so with the VMware driver,
1366           make sure to include svga in the gallium drivers list, apart from
1367           enabling XA.
1368           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1369     fi
1370     enable_gallium_loader=$enable_shared_pipe_drivers
1371 fi
1372 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1373
1374 dnl
1375 dnl OpenVG configuration
1376 dnl
1377 VG_LIB_DEPS=""
1378
1379 if test "x$enable_openvg" = xyes; then
1380     if test "x$enable_egl" = xno; then
1381         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1382     fi
1383     if test -z "$with_gallium_drivers"; then
1384         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1385     fi
1386     if test "x$enable_gallium_egl" = xno; then
1387         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1388     fi
1389
1390     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1391     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1392     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1393     AC_SUBST([VG_PC_LIB_PRIV])
1394 fi
1395 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1396
1397 dnl
1398 dnl Gallium G3DVL configuration
1399 dnl
1400 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1401     if test "x$enable_xvmc" = xauto; then
1402         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1403     fi
1404
1405     if test "x$enable_vdpau" = xauto; then
1406         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1407     fi
1408
1409     if test "x$enable_omx" = xauto; then
1410         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1411     fi
1412
1413     if test "x$enable_va" = xauto; then
1414         PKG_CHECK_EXISTS([libva], [enable_va=yes], [enable_va=no])
1415     fi
1416 fi
1417
1418 if test "x$enable_xvmc" = xyes; then
1419     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1420     enable_gallium_loader=$enable_shared_pipe_drivers
1421 fi
1422 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1423
1424 if test "x$enable_vdpau" = xyes; then
1425     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1426                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb xcb-dri2`"])
1427     enable_gallium_loader=$enable_shared_pipe_drivers
1428 fi
1429 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1430
1431 if test "x$enable_omx" = xyes; then
1432     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1433     enable_gallium_loader=$enable_shared_pipe_drivers
1434 fi
1435 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1436
1437 if test "x$enable_va" = xyes; then
1438     PKG_CHECK_MODULES([VA], [libva >= 0.35.0 x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1439                       [VA_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1440     enable_gallium_loader=$enable_shared_pipe_drivers
1441 fi
1442 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1443
1444 dnl
1445 dnl OpenCL configuration
1446 dnl
1447
1448 AC_ARG_WITH([libclc-path],
1449    [AS_HELP_STRING([--with-libclc-path],
1450          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1451    [LIBCLC_PATH="$withval"],
1452    [LIBCLC_PATH=''])
1453
1454 if test -n "$LIBCLC_PATH"; then
1455    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1456                   Please review the updated build instructions for clover:
1457                   http://dri.freedesktop.org/wiki/GalliumCompute])
1458 fi
1459
1460
1461 AC_ARG_WITH([clang-libdir],
1462    [AS_HELP_STRING([--with-clang-libdir],
1463          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1464    [CLANG_LIBDIR="$withval"],
1465    [CLANG_LIBDIR=''])
1466
1467 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1468
1469 if test "x$enable_opencl" = xyes; then
1470     if test -z "$with_gallium_drivers"; then
1471         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1472     fi
1473
1474     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1475         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1476     fi
1477
1478     if test "x$have_libclc" = xno; then
1479         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1480                     Make sure the directory containing libclc.pc is specified in your
1481                     PKG_CONFIG_PATH environment variable.
1482                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1483     else
1484         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1485         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1486         AC_SUBST([LIBCLC_INCLUDEDIR])
1487         AC_SUBST([LIBCLC_LIBEXECDIR])
1488     fi
1489
1490     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1491     enable_gallium_loader=yes
1492
1493     if test "x$enable_opencl_icd" = xyes; then
1494         OPENCL_LIBNAME="MesaOpenCL"
1495     else
1496         OPENCL_LIBNAME="OpenCL"
1497     fi
1498 fi
1499 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1500 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1501 AC_SUBST([OPENCL_LIBNAME])
1502
1503 dnl
1504 dnl Gallium configuration
1505 dnl
1506 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1507
1508 AC_SUBST([LLVM_BINDIR])
1509 AC_SUBST([LLVM_CFLAGS])
1510 AC_SUBST([LLVM_CPPFLAGS])
1511 AC_SUBST([LLVM_CXXFLAGS])
1512 AC_SUBST([LLVM_LIBDIR])
1513 AC_SUBST([LLVM_LIBS])
1514 AC_SUBST([LLVM_LDFLAGS])
1515 AC_SUBST([LLVM_INCLUDEDIR])
1516 AC_SUBST([LLVM_VERSION])
1517 AC_SUBST([CLANG_RESOURCE_DIR])
1518
1519 case "x$enable_opengl$enable_gles1$enable_gles2" in
1520 x*yes*)
1521     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1522     ;;
1523 esac
1524
1525 AC_SUBST([VG_LIB_DEPS])
1526 AC_SUBST([EGL_CLIENT_APIS])
1527
1528 dnl
1529 dnl EGL Platforms configuration
1530 dnl
1531 AC_ARG_WITH([egl-platforms],
1532     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1533         [comma delimited native platforms libEGL supports, e.g.
1534         "x11,drm" @<:@default=auto@:>@])],
1535     [with_egl_platforms="$withval"],
1536     [if test "x$enable_egl" = xyes; then
1537         with_egl_platforms="x11"
1538     else
1539         with_egl_platforms=""
1540     fi])
1541
1542 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1543     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1544 fi
1545
1546 # Do per-EGL platform setups and checks
1547 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1548 for plat in $egl_platforms; do
1549         case "$plat" in
1550         wayland)
1551                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1552
1553                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1554                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1555                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1556                 ;;
1557
1558         x11)
1559                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1560                 ;;
1561
1562         drm)
1563                 test "x$enable_gbm" = "xno" &&
1564                         AC_MSG_ERROR([EGL platform drm needs gbm])
1565                 test "x$have_libdrm" != xyes &&
1566                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1567                 ;;
1568
1569         android|fbdev|gdi|null)
1570                 ;;
1571
1572         *)
1573                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1574                 ;;
1575         esac
1576
1577         case "$plat$need_pci_id$have_pci_id" in
1578                 waylandyesno|drmyesno)
1579                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1580         esac
1581 done
1582
1583 # libEGL wants to default to the first platform specified in
1584 # ./configure.  parse that here.
1585 if test "x$egl_platforms" != "x"; then
1586     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1587     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1588 else
1589     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1590 fi
1591
1592 if echo "$egl_platforms" | grep -q 'x11'; then
1593     NEED_WINSYS_XLIB=yes
1594 fi
1595 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1596 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1597 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1598 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1599 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1600
1601 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1602
1603 AC_SUBST([EGL_NATIVE_PLATFORM])
1604 AC_SUBST([EGL_CFLAGS])
1605
1606 # If we don't have the X11 platform, set this define so we don't try to include
1607 # the X11 headers.
1608 if ! echo "$egl_platforms" | grep -q 'x11'; then
1609     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1610     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1611 fi
1612
1613 AC_ARG_WITH([max-width],
1614     [AS_HELP_STRING([--with-max-width=N],
1615                     [Maximum framebuffer width (4096)])],
1616     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1617      AS_IF([test "${withval}" -gt "4096"],
1618            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1619 )
1620 AC_ARG_WITH([max-height],
1621     [AS_HELP_STRING([--with-max-height=N],
1622                     [Maximum framebuffer height (4096)])],
1623     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1624      AS_IF([test "${withval}" -gt "4096"],
1625            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1626 )
1627
1628 dnl
1629 dnl Gallium LLVM
1630 dnl
1631 AC_ARG_ENABLE([gallium-llvm],
1632     [AS_HELP_STRING([--enable-gallium-llvm],
1633         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1634     [enable_gallium_llvm="$enableval"],
1635     [enable_gallium_llvm=auto])
1636
1637 AC_ARG_ENABLE([llvm-shared-libs],
1638     [AS_HELP_STRING([--enable-llvm-shared-libs],
1639         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1640     [enable_llvm_shared_libs="$enableval"],
1641     [enable_llvm_shared_libs=yes])
1642
1643 AC_ARG_WITH([llvm-prefix],
1644     [AS_HELP_STRING([--with-llvm-prefix],
1645         [Prefix for LLVM installations in non-standard locations])],
1646     [llvm_prefix="$withval"],
1647     [llvm_prefix=''])
1648
1649
1650 # Call this inside ` ` to get the return value.
1651 # $1 is the llvm-config command with arguments.
1652 strip_unwanted_llvm_flags() {
1653     # Use \> (marks the end of the word)
1654     echo `$1` | sed \
1655         -e 's/-DNDEBUG\>//g' \
1656         -e 's/-D_GNU_SOURCE\>//g' \
1657         -e 's/-pedantic\>//g' \
1658         -e 's/-Wcovered-switch-default\>//g' \
1659         -e 's/-O.\>//g' \
1660         -e 's/-g\>//g' \
1661         -e 's/-Wall\>//g' \
1662         -e 's/-Wcast-qual\>//g' \
1663         -e 's/-Woverloaded-virtual\>//g' \
1664         -e 's/-fcolor-diagnostics\>//g' \
1665         -e 's/-fdata-sections\>//g' \
1666         -e 's/-ffunction-sections\>//g' \
1667         -e 's/-fno-exceptions\>//g' \
1668         -e 's/-fomit-frame-pointer\>//g' \
1669         -e 's/-fvisibility-inlines-hidden\>//g' \
1670         -e 's/-fPIC\>//g' \
1671         -e 's/-fstack-protector-strong\>//g'
1672 }
1673
1674
1675 if test -z "$with_gallium_drivers"; then
1676     enable_gallium_llvm=no
1677 fi
1678 if test "x$enable_gallium_llvm" = xauto; then
1679     case "$host_cpu" in
1680     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1681     esac
1682 fi
1683 if test "x$enable_gallium_llvm" = xyes; then
1684     if test -n "$llvm_prefix"; then
1685         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1686     else
1687         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1688     fi
1689
1690     if test "x$LLVM_CONFIG" != xno; then
1691         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1692         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1693         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1694         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1695         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1696         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1697         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1698         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1699
1700         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1701             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1702         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1703             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1704
1705         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1706         if test -z "$LLVM_VERSION_PATCH"; then
1707             LLVM_VERSION_PATCH=0
1708         fi
1709
1710         if test -n "${LLVM_VERSION_MAJOR}"; then
1711             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1712         else
1713             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1714         fi
1715
1716         LLVM_REQUIRED_VERSION_MAJOR="3"
1717         LLVM_REQUIRED_VERSION_MINOR="1"
1718         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1719             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1720         fi
1721
1722         LLVM_COMPONENTS="engine bitwriter"
1723         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1724             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1725         fi
1726
1727         if test "x$enable_opencl" = xyes; then
1728             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1729             # LLVM 3.3 >= 177971 requires IRReader
1730             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1731                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1732             fi
1733             # LLVM 3.4 requires Option
1734             if $LLVM_CONFIG --components | grep -qw 'option'; then
1735                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1736             fi
1737             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1738             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1739                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1740             fi
1741             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1742                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1743             fi
1744         fi
1745         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1746         MESA_LLVM=1
1747
1748         dnl Check for Clang internal headers
1749         if test "x$enable_opencl" = xyes; then
1750             if test -z "$CLANG_LIBDIR"; then
1751                 CLANG_LIBDIR=${LLVM_LIBDIR}
1752             fi
1753             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1754             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1755                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1756         fi
1757     else
1758         MESA_LLVM=0
1759         LLVM_VERSION_INT=0
1760     fi
1761 else
1762     MESA_LLVM=0
1763     LLVM_VERSION_INT=0
1764
1765     if test "x$enable_opencl" = xyes; then
1766         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1767     fi
1768 fi
1769
1770 dnl Directory for XVMC libs
1771 AC_ARG_WITH([xvmc-libdir],
1772     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1773         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1774     [XVMC_LIB_INSTALL_DIR="$withval"],
1775     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1776 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1777
1778 dnl
1779 dnl Gallium Tests
1780 dnl
1781 if test "x$enable_gallium_tests" = xyes; then
1782     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1783     enable_gallium_loader=yes
1784 fi
1785 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1786
1787 dnl Directory for VDPAU libs
1788 AC_ARG_WITH([vdpau-libdir],
1789     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1790         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1791     [VDPAU_LIB_INSTALL_DIR="$withval"],
1792     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1793 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1794
1795 dnl Directory for OMX libs
1796
1797 AC_ARG_WITH([omx-libdir],
1798     [AS_HELP_STRING([--with-omx-libdir=DIR],
1799         [directory for the OMX libraries])],
1800     [OMX_LIB_INSTALL_DIR="$withval"],
1801     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1802 AC_SUBST([OMX_LIB_INSTALL_DIR])
1803
1804 dnl Directory for VA libs
1805
1806 AC_ARG_WITH([va-libdir],
1807     [AS_HELP_STRING([--with-va-libdir=DIR],
1808         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1809     [VA_LIB_INSTALL_DIR="$withval"],
1810     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1811 AC_SUBST([VA_LIB_INSTALL_DIR])
1812
1813 dnl
1814 dnl Gallium helper functions
1815 dnl
1816 gallium_require_drm() {
1817     if test "x$have_libdrm" != xyes; then
1818        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1819     fi
1820 }
1821
1822 gallium_require_llvm() {
1823     if test "x$MESA_LLVM" = x0; then
1824         case "$host" in *gnux32) return;; esac
1825         case "$host_cpu" in
1826         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1827         esac
1828     fi
1829 }
1830
1831 gallium_require_drm_loader() {
1832     if test "x$enable_gallium_loader" = xyes; then
1833         if test "x$need_pci_id$have_pci_id" = xyesno; then
1834             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1835         fi
1836         enable_gallium_drm_loader=yes
1837     fi
1838     if test "x$enable_va" = xyes && test "x$7" != x; then
1839          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1840     fi
1841 }
1842
1843 require_egl_drm() {
1844     case "$with_egl_platforms" in
1845         *drm*)
1846             ;;
1847          *)
1848             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1849             ;;
1850     esac
1851     if test "x$enable_gbm" != xyes; then
1852             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1853     fi
1854 }
1855
1856 radeon_llvm_check() {
1857     if test "x$enable_gallium_llvm" != "xyes"; then
1858         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1859     fi
1860     LLVM_REQUIRED_VERSION_MAJOR="3"
1861     LLVM_REQUIRED_VERSION_MINOR="4"
1862     LLVM_REQUIRED_VERSION_PATCH="2"
1863     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1864         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1865     fi
1866     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1867         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1868                       sources with the --enable-experimental-targets=R600
1869                       configure flag])
1870     fi
1871     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1872     NEED_RADEON_LLVM=yes
1873     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1874                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1875 }
1876
1877 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1878 if test -n "$with_gallium_drivers"; then
1879     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1880     for driver in $gallium_drivers; do
1881         case "x$driver" in
1882         xsvga)
1883             HAVE_GALLIUM_SVGA=yes
1884             gallium_require_drm "svga"
1885             gallium_require_drm_loader
1886             ;;
1887         xi915)
1888             HAVE_GALLIUM_I915=yes
1889             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1890             gallium_require_drm "Gallium i915"
1891             gallium_require_drm_loader
1892             ;;
1893         xilo)
1894             HAVE_GALLIUM_ILO=yes
1895             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1896             gallium_require_drm "Gallium i965/ilo"
1897             gallium_require_drm_loader
1898             ;;
1899         xr300)
1900             HAVE_GALLIUM_R300=yes
1901             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1902             gallium_require_drm "Gallium R300"
1903             gallium_require_drm_loader
1904             gallium_require_llvm "Gallium R300"
1905             ;;
1906         xr600)
1907             HAVE_GALLIUM_R600=yes
1908             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1909             gallium_require_drm "Gallium R600"
1910             gallium_require_drm_loader
1911             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1912                 radeon_llvm_check "r600g"
1913                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1914             fi
1915             if test "x$enable_r600_llvm" = xyes; then
1916                 USE_R600_LLVM_COMPILER=yes;
1917             fi
1918             if test "x$enable_opencl" = xyes; then
1919                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1920             fi
1921             ;;
1922         xradeonsi)
1923             HAVE_GALLIUM_RADEONSI=yes
1924             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1925             gallium_require_drm "radeonsi"
1926             gallium_require_drm_loader
1927             radeon_llvm_check "radeonsi"
1928             require_egl_drm "radeonsi"
1929             ;;
1930         xnouveau)
1931             HAVE_GALLIUM_NOUVEAU=yes
1932             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1933             gallium_require_drm "nouveau"
1934             gallium_require_drm_loader
1935             ;;
1936         xfreedreno)
1937             HAVE_GALLIUM_FREEDRENO=yes
1938             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1939             gallium_require_drm "freedreno"
1940             gallium_require_drm_loader
1941             ;;
1942         xswrast)
1943             HAVE_GALLIUM_SOFTPIPE=yes
1944             if test "x$MESA_LLVM" = x1; then
1945                 HAVE_GALLIUM_LLVMPIPE=yes
1946             fi
1947             ;;
1948         xvc4)
1949             HAVE_GALLIUM_VC4=yes
1950             gallium_require_drm "vc4"
1951             gallium_require_drm_loader
1952
1953             case "$host_cpu" in
1954                 i?86 | x86_64 | amd64)
1955                 USE_VC4_SIMULATOR=yes
1956                 ;;
1957             esac
1958             ;;
1959         *)
1960             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1961             ;;
1962         esac
1963     done
1964 fi
1965
1966 dnl Set LLVM_LIBS - This is done after the driver configuration so
1967 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1968 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1969 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1970 dnl this was causing the same libraries to be appear multiple times
1971 dnl in LLVM_LIBS.
1972
1973 if test "x$MESA_LLVM" != x0; then
1974
1975     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1976
1977     if test "x$enable_llvm_shared_libs" = xyes; then
1978         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1979         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1980         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1981
1982         if test "x$llvm_have_one_so" = xyes; then
1983             dnl LLVM was built using auto*, so there is only one shared object.
1984             LLVM_LIBS="-l$LLVM_SO_NAME"
1985         else
1986             dnl If LLVM was built with CMake, there will be one shared object per
1987             dnl component.
1988             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1989                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1990         Please make sure you have built llvm with the --enable-shared option
1991         and that your llvm libraries are installed in $LLVM_LIBDIR
1992         If you have installed your llvm libraries to a different directory you
1993         can use the --with-llvm-prefix= configure flag to specify this directory.
1994         NOTE: Mesa is attempting to use llvm shared libraries by default.
1995         If you do not want to build with llvm shared libraries and instead want to
1996         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1997         invocation and rebuild.])])
1998
1999            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2000            dnl install uses a shared object for each compoenent and we have
2001            dnl already added all of these objects to LLVM_LIBS.
2002         fi
2003     else
2004         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2005     fi
2006 fi
2007
2008 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2009 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2010 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2011 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2012 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2013 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2014 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2015                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2016 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2017 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2018 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2019 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2020 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2021
2022 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2023
2024 # NOTE: anything using xcb or other client side libs ends up in separate
2025 #       _CLIENT variables.  The pipe loader is built in two variants,
2026 #       one that is standalone and does not link any x client libs (for
2027 #       use by XA tracker in particular, but could be used in any case
2028 #       where communication with xserver is not desired).
2029 if test "x$enable_gallium_loader" = xyes; then
2030     if test "x$NEED_WINSYS_XLIB" = xyes; then
2031         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2032     fi
2033
2034     if test "x$enable_dri" = xyes; then
2035         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2036     fi
2037
2038     if test "x$enable_gallium_drm_loader" = xyes; then
2039         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2040         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2041                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2042         if test "x$pipe_loader_have_xcb" = xyes; then
2043             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2044             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2045         fi
2046     fi
2047
2048     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2049     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2050
2051     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2052     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2053     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2054     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2055 fi
2056
2057 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2058 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2059 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2060 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2061 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2062 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2063
2064 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2065                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2066                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2067 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2068 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2069 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2070 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2071 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2072 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2073 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2074 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2075 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2076     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2077 fi
2078
2079 AC_SUBST([ELF_LIB])
2080
2081 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2082 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2083 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2084 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2085 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2086
2087 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2088 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2089 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2090
2091 AC_SUBST([VDPAU_MAJOR], 1)
2092 AC_SUBST([VDPAU_MINOR], 0)
2093
2094 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2095 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2096 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2097 AC_SUBST([VA_MINOR], $VA_MINOR)
2098
2099 AC_SUBST([XVMC_MAJOR], 1)
2100 AC_SUBST([XVMC_MINOR], 0)
2101
2102 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2103 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2104 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2105 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2106
2107 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2108 AC_SUBST([XA_MINOR], $XA_MINOR)
2109 AC_SUBST([XA_TINY], $XA_TINY)
2110 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2111
2112 dnl Restore LDFLAGS and CPPFLAGS
2113 LDFLAGS="$_SAVE_LDFLAGS"
2114 CPPFLAGS="$_SAVE_CPPFLAGS"
2115
2116 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2117 if test "x$acv_mesa_CLANG" = xyes; then
2118     CFLAGS="$CFLAGS -Qunused-arguments"
2119     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2120 fi
2121
2122 dnl Add user CFLAGS and CXXFLAGS
2123 CFLAGS="$CFLAGS $USER_CFLAGS"
2124 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2125
2126 dnl Substitute the config
2127 AC_CONFIG_FILES([Makefile
2128                 src/Makefile
2129                 src/egl/drivers/dri2/Makefile
2130                 src/egl/main/Makefile
2131                 src/egl/main/egl.pc
2132                 src/egl/wayland/Makefile
2133                 src/egl/wayland/wayland-drm/Makefile
2134                 src/egl/wayland/wayland-egl/Makefile
2135                 src/egl/wayland/wayland-egl/wayland-egl.pc
2136                 src/gallium/Makefile
2137                 src/gallium/auxiliary/Makefile
2138                 src/gallium/auxiliary/pipe-loader/Makefile
2139                 src/gallium/drivers/freedreno/Makefile
2140                 src/gallium/drivers/galahad/Makefile
2141                 src/gallium/drivers/i915/Makefile
2142                 src/gallium/drivers/identity/Makefile
2143                 src/gallium/drivers/ilo/Makefile
2144                 src/gallium/drivers/llvmpipe/Makefile
2145                 src/gallium/drivers/noop/Makefile
2146                 src/gallium/drivers/nouveau/Makefile
2147                 src/gallium/drivers/r300/Makefile
2148                 src/gallium/drivers/r600/Makefile
2149                 src/gallium/drivers/radeon/Makefile
2150                 src/gallium/drivers/radeonsi/Makefile
2151                 src/gallium/drivers/rbug/Makefile
2152                 src/gallium/drivers/softpipe/Makefile
2153                 src/gallium/drivers/svga/Makefile
2154                 src/gallium/drivers/trace/Makefile
2155                 src/gallium/drivers/vc4/Makefile
2156                 src/gallium/drivers/vc4/kernel/Makefile
2157                 src/gallium/state_trackers/clover/Makefile
2158                 src/gallium/state_trackers/dri/Makefile
2159                 src/gallium/state_trackers/egl/Makefile
2160                 src/gallium/state_trackers/gbm/Makefile
2161                 src/gallium/state_trackers/glx/xlib/Makefile
2162                 src/gallium/state_trackers/omx/Makefile
2163                 src/gallium/state_trackers/osmesa/Makefile
2164                 src/gallium/state_trackers/va/Makefile
2165                 src/gallium/state_trackers/vdpau/Makefile
2166                 src/gallium/state_trackers/vega/Makefile
2167                 src/gallium/state_trackers/xa/Makefile
2168                 src/gallium/state_trackers/xvmc/Makefile
2169                 src/gallium/targets/dri/Makefile
2170                 src/gallium/targets/egl-static/Makefile
2171                 src/gallium/targets/gbm/Makefile
2172                 src/gallium/targets/libgl-xlib/Makefile
2173                 src/gallium/targets/omx/Makefile
2174                 src/gallium/targets/opencl/Makefile
2175                 src/gallium/targets/osmesa/Makefile
2176                 src/gallium/targets/osmesa/osmesa.pc
2177                 src/gallium/targets/pipe-loader/Makefile
2178                 src/gallium/targets/va/Makefile
2179                 src/gallium/targets/vdpau/Makefile
2180                 src/gallium/targets/xa/Makefile
2181                 src/gallium/targets/xa/xatracker.pc
2182                 src/gallium/targets/xvmc/Makefile
2183                 src/gallium/tests/trivial/Makefile
2184                 src/gallium/tests/unit/Makefile
2185                 src/gallium/winsys/freedreno/drm/Makefile
2186                 src/gallium/winsys/i915/drm/Makefile
2187                 src/gallium/winsys/intel/drm/Makefile
2188                 src/gallium/winsys/nouveau/drm/Makefile
2189                 src/gallium/winsys/radeon/drm/Makefile
2190                 src/gallium/winsys/svga/drm/Makefile
2191                 src/gallium/winsys/sw/dri/Makefile
2192                 src/gallium/winsys/sw/fbdev/Makefile
2193                 src/gallium/winsys/sw/kms-dri/Makefile
2194                 src/gallium/winsys/sw/null/Makefile
2195                 src/gallium/winsys/sw/wayland/Makefile
2196                 src/gallium/winsys/sw/wrapper/Makefile
2197                 src/gallium/winsys/sw/xlib/Makefile
2198                 src/gallium/winsys/vc4/drm/Makefile
2199                 src/gbm/Makefile
2200                 src/gbm/main/gbm.pc
2201                 src/glsl/Makefile
2202                 src/glx/Makefile
2203                 src/glx/apple/Makefile
2204                 src/glx/tests/Makefile
2205                 src/gtest/Makefile
2206                 src/loader/Makefile
2207                 src/mapi/Makefile
2208                 src/mapi/es1api/glesv1_cm.pc
2209                 src/mapi/es2api/glesv2.pc
2210                 src/mapi/glapi/gen/Makefile
2211                 src/mapi/vgapi/Makefile
2212                 src/mapi/vgapi/vg.pc
2213                 src/mesa/Makefile
2214                 src/mesa/gl.pc
2215                 src/mesa/drivers/dri/dri.pc
2216                 src/mesa/drivers/dri/common/Makefile
2217                 src/mesa/drivers/dri/common/xmlpool/Makefile
2218                 src/mesa/drivers/dri/i915/Makefile
2219                 src/mesa/drivers/dri/i965/Makefile
2220                 src/mesa/drivers/dri/Makefile
2221                 src/mesa/drivers/dri/nouveau/Makefile
2222                 src/mesa/drivers/dri/r200/Makefile
2223                 src/mesa/drivers/dri/radeon/Makefile
2224                 src/mesa/drivers/dri/swrast/Makefile
2225                 src/mesa/drivers/osmesa/Makefile
2226                 src/mesa/drivers/osmesa/osmesa.pc
2227                 src/mesa/drivers/x11/Makefile
2228                 src/mesa/main/tests/Makefile
2229                 src/util/Makefile
2230                 src/util/tests/hash_table/Makefile])
2231
2232 AC_OUTPUT
2233
2234 dnl
2235 dnl Output some configuration info for the user
2236 dnl
2237 echo ""
2238 echo "        prefix:          $prefix"
2239 echo "        exec_prefix:     $exec_prefix"
2240 echo "        libdir:          $libdir"
2241 echo "        includedir:      $includedir"
2242
2243 dnl API info
2244 echo ""
2245 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2246 echo "        OpenVG:          $enable_openvg"
2247
2248 dnl Driver info
2249 echo ""
2250 case "x$enable_osmesa$enable_gallium_osmesa" in
2251 xnoyes)
2252         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2253         ;;
2254 xyesno)
2255         echo "        OSMesa:          lib$OSMESA_LIB"
2256         ;;
2257 xnono)
2258         echo "        OSMesa:          no"
2259         ;;
2260 esac
2261
2262 echo ""
2263 if test "x$enable_dri" != xno; then
2264         echo "        DRI platform:    $dri_platform"
2265         if test -z "$DRI_DIRS"; then
2266             echo "        DRI drivers:     no"
2267         else
2268             echo "        DRI drivers:     $DRI_DIRS"
2269         fi
2270         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2271 fi
2272
2273 case "x$enable_glx$enable_xlib_glx" in
2274 xyesyes)
2275     echo "        GLX:             Xlib-based"
2276     ;;
2277 xyesno)
2278     echo "        GLX:             DRI-based"
2279     ;;
2280 *)
2281     echo "        GLX:             $enable_glx"
2282     ;;
2283 esac
2284
2285 dnl EGL
2286 echo ""
2287 echo "        EGL:             $enable_egl"
2288 if test "$enable_egl" = yes; then
2289     echo "        EGL platforms:   $egl_platforms"
2290
2291     egl_drivers=""
2292     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2293         egl_drivers="$egl_drivers builtin:egl_dri2"
2294     fi
2295
2296     if test "x$enable_gallium_egl" = xyes; then
2297         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2298         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2299     else
2300         echo "        EGL drivers:    $egl_drivers"
2301     fi
2302 fi
2303
2304 echo ""
2305 if test "x$MESA_LLVM" = x1; then
2306     echo "        llvm:            yes"
2307     echo "        llvm-config:     $LLVM_CONFIG"
2308     echo "        llvm-version:    $LLVM_VERSION"
2309 else
2310     echo "        llvm:            no"
2311 fi
2312
2313 echo ""
2314 if test -n "$with_gallium_drivers"; then
2315     echo "        Gallium:         yes"
2316 else
2317     echo "        Gallium:         no"
2318 fi
2319
2320
2321 dnl Libraries
2322 echo ""
2323 echo "        Shared libs:     $enable_shared"
2324 echo "        Static libs:     $enable_static"
2325 echo "        Shared-glapi:    $enable_shared_glapi"
2326
2327 dnl Compiler options
2328 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2329 cflags=`echo $CFLAGS | \
2330     $SED 's/^ *//;s/  */ /;s/ *$//'`
2331 cxxflags=`echo $CXXFLAGS | \
2332     $SED 's/^ *//;s/  */ /;s/ *$//'`
2333 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2334 echo ""
2335 echo "        CFLAGS:          $cflags"
2336 echo "        CXXFLAGS:        $cxxflags"
2337 echo "        Macros:          $defines"
2338 echo ""
2339 if test "x$MESA_LLVM" = x1; then
2340     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2341     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2342     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2343     echo ""
2344 fi
2345 echo "        PYTHON2:         $PYTHON2"
2346
2347 echo ""
2348 echo "        Run '${MAKE-make}' to build Mesa"
2349 echo ""