configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 123
 124 dnl Make sure the pkg-config macros are defined
 125 m4_ifndef([PKG_PROG_PKG_CONFIG],
 126     [m4_fatal([Could not locate the pkg-config autoconf macros.
 127   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 128   are in a different location, try setting the environment variable
 129   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 130 PKG_PROG_PKG_CONFIG()
 131
 132 dnl LIB_DIR - library basename
 133 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 134 AC_SUBST([LIB_DIR])
 135
 136 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 137 _SAVE_LDFLAGS="$LDFLAGS"
 138 _SAVE_CPPFLAGS="$CPPFLAGS"
 139
 140 dnl Compiler macros
 141 DEFINES=""
 142 AC_SUBST([DEFINES])
 143 case "$host_os" in
 144 linux*|*-gnu*|gnu*)
 145     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 146     ;;
 147 solaris*)
 148     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 149     ;;
 150 cygwin*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD"
 152     ;;
 153 esac
 154
 155 dnl Add flags for gcc and g++
 156 if test "x$GCC" = xyes; then
 157     case "$host_os" in
 158     cygwin*)
 159         CFLAGS="$CFLAGS -Wall -std=gnu99"
 160         ;;
 161     *)
 162         CFLAGS="$CFLAGS -Wall -std=c99"
 163         ;;
 164     esac
 165
 166     # Enable -Werror=implicit-function-declaration and
 167     # -Werror=missing-prototypes, if available, or otherwise, just
 168     # -Wmissing-prototypes.  This is particularly useful to avoid
 169     # generating a loadable driver module that has undefined symbols.
 170     save_CFLAGS="$CFLAGS"
 171     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 172     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 173     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 174     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 175                    AC_MSG_RESULT([yes]),
 176                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 177                     AC_MSG_RESULT([no])]);
 178
 179     # Enable -fvisibility=hidden if using a gcc that supports it
 180     save_CFLAGS="$CFLAGS"
 181     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 182     VISIBILITY_CFLAGS="-fvisibility=hidden"
 183     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 185                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 186
 187     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 188     CFLAGS=$save_CFLAGS
 189
 190     # Work around aliasing bugs - developers should comment this out
 191     CFLAGS="$CFLAGS -fno-strict-aliasing"
 192
 193     # gcc's builtin memcmp is slower than glibc's
 194     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 195     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 196 fi
 197 if test "x$GXX" = xyes; then
 198     CXXFLAGS="$CXXFLAGS -Wall"
 199
 200     # Enable -fvisibility=hidden if using a gcc that supports it
 201     save_CXXFLAGS="$CXXFLAGS"
 202     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 203     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 204     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 205     AC_LANG_PUSH([C++])
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 208     AC_LANG_POP([C++])
 209
 210     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 211     CXXFLAGS=$save_CXXFLAGS
 212
 213     # Work around aliasing bugs - developers should comment this out
 214     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 215
 216     # gcc's builtin memcmp is slower than glibc's
 217     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 218     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 219 fi
 220
 221 dnl even if the compiler appears to support it, using visibility attributes isn't
 222 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 223 case "$host_os" in
 224 cygwin*)
 225     VISIBILITY_CFLAGS=""
 226     VISIBILITY_CXXFLAGS=""
 227     ;;
 228 esac
 229
 230 AC_SUBST([VISIBILITY_CFLAGS])
 231 AC_SUBST([VISIBILITY_CXXFLAGS])
 232
 233 dnl
 234 dnl Optional flags, check for compiler support
 235 dnl
 236 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 237 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 287
 288 dnl
 289 dnl other compiler options
 290 dnl
 291 AC_ARG_ENABLE([debug],
 292     [AS_HELP_STRING([--enable-debug],
 293         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 294     [enable_debug="$enableval"],
 295     [enable_debug=no]
 296 )
 297 if test "x$enable_debug" = xyes; then
 298     DEFINES="$DEFINES -DDEBUG"
 299     if test "x$GCC" = xyes; then
 300         CFLAGS="$CFLAGS -g -O0"
 301     fi
 302     if test "x$GXX" = xyes; then
 303         CXXFLAGS="$CXXFLAGS -g -O0"
 304     fi
 305 fi
 306
 307 dnl
 308 dnl library names
 309 dnl
 310 LIB_PREFIX_GLOB='lib'
 311 LIB_VERSION_SEPARATOR='.'
 312 if test "$enable_static" = yes; then
 313     LIB_EXTENSION='a'
 314 else
 315     case "$host_os" in
 316     darwin* )
 317         LIB_EXTENSION='dylib' ;;
 318     cygwin* )
 319         dnl prefix can be 'cyg' or 'lib'
 320         LIB_PREFIX_GLOB='???'
 321         LIB_VERSION_SEPARATOR='-'
 322         LIB_EXTENSION='dll' ;;
 323     aix* )
 324         LIB_EXTENSION='a' ;;
 325     * )
 326         LIB_EXTENSION='so' ;;
 327     esac
 328 fi
 329 AC_ARG_WITH([gl-lib-name],
 330   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 331     [specify GL library name @<:@default=GL@:>@])],
 332   [GL_LIB=$withval],
 333   [GL_LIB=GL])
 334 AC_ARG_WITH([osmesa-lib-name],
 335   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 336     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 337   [OSMESA_LIB=$withval],
 338   [OSMESA_LIB=OSMesa])
 339 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 340 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 341
 342 dnl
 343 dnl Mangled Mesa support
 344 dnl
 345 AC_ARG_ENABLE([mangling],
 346   [AS_HELP_STRING([--enable-mangling],
 347     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 348   [enable_mangling="${enableval}"],
 349   [enable_mangling=no]
 350 )
 351 if test "x${enable_mangling}" = "xyes" ; then
 352   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 353   GL_LIB="Mangled${GL_LIB}"
 354   OSMESA_LIB="Mangled${OSMESA_LIB}"
 355 fi
 356 AC_SUBST([GL_LIB])
 357 AC_SUBST([OSMESA_LIB])
 358
 359 dnl
 360 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 361 dnl
 362 AC_ARG_ENABLE([texture-float],
 363     [AS_HELP_STRING([--enable-texture-float],
 364         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 365     [enable_texture_float="$enableval"],
 366     [enable_texture_float=no]
 367 )
 368 if test "x$enable_texture_float" = xyes; then
 369     AC_MSG_WARN([Floating-point textures enabled.])
 370     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 371     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 372 fi
 373
 374 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 375 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 376 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 377 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 378 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 379 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 380 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 381
 382 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 387 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 388 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 389
 390 AC_SUBST([GL_LIB_NAME])
 391 AC_SUBST([OSMESA_LIB_NAME])
 392 AC_SUBST([EGL_LIB_NAME])
 393 AC_SUBST([GLESv1_CM_LIB_NAME])
 394 AC_SUBST([GLESv2_LIB_NAME])
 395 AC_SUBST([VG_LIB_NAME])
 396 AC_SUBST([GLAPI_LIB_NAME])
 397
 398 AC_SUBST([GL_LIB_GLOB])
 399 AC_SUBST([EGL_LIB_GLOB])
 400 AC_SUBST([GLESv1_CM_LIB_GLOB])
 401 AC_SUBST([GLESv2_LIB_GLOB])
 402 AC_SUBST([VG_LIB_GLOB])
 403 AC_SUBST([GLAPI_LIB_GLOB])
 404
 405 dnl
 406 dnl Arch/platform-specific settings
 407 dnl
 408 AC_ARG_ENABLE([asm],
 409     [AS_HELP_STRING([--disable-asm],
 410         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 411     [enable_asm="$enableval"],
 412     [enable_asm=yes]
 413 )
 414 asm_arch=""
 415 AC_MSG_CHECKING([whether to enable assembly])
 416 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 417 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 418 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 419     case "$host_cpu" in
 420     i?86 | x86_64 | amd64)
 421         enable_asm=no
 422         AC_MSG_RESULT([no, cross compiling])
 423         ;;
 424     esac
 425 fi
 426 # check for supported arches
 427 if test "x$enable_asm" = xyes; then
 428     case "$host_cpu" in
 429     i?86)
 430         case "$host_os" in
 431         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 432             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 433             ;;
 434         gnu*)
 435             asm_arch=x86
 436             ;;
 437         esac
 438         ;;
 439     x86_64|amd64)
 440         case "$host_os" in
 441         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 442             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 443             ;;
 444         esac
 445         ;;
 446     sparc*)
 447         case "$host_os" in
 448         linux*)
 449             asm_arch=sparc
 450             ;;
 451         esac
 452         ;;
 453     esac
 454
 455     case "$asm_arch" in
 456     x86)
 457         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 458         AC_MSG_RESULT([yes, x86])
 459         ;;
 460     x86_64|amd64)
 461         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 462         AC_MSG_RESULT([yes, x86_64])
 463         ;;
 464     sparc)
 465         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 466         AC_MSG_RESULT([yes, sparc])
 467         ;;
 468     *)
 469         AC_MSG_RESULT([no, platform not supported])
 470         ;;
 471     esac
 472 fi
 473
 474 dnl Check to see if dlopen is in default libraries (like Solaris, which
 475 dnl has it in libc), or if libdl is needed to get it.
 476 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 477     [AC_CHECK_LIB([dl], [dlopen],
 478        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 479 AC_SUBST([DLOPEN_LIBS])
 480
 481 case "$host_os" in
 482 darwin*|mingw*)
 483     ;;
 484 *)
 485     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 486                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 487                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 488     AC_SUBST([CLOCK_LIB])
 489     ;;
 490 esac
 491
 492 dnl See if posix_memalign is available
 493 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 494
 495 dnl Check for pthreads
 496 AX_PTHREAD
 497 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 498 dnl to -pthread, which causes problems if we need -lpthread to appear in
 499 dnl pkgconfig files.
 500 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 501
 502 dnl SELinux awareness.
 503 AC_ARG_ENABLE([selinux],
 504     [AS_HELP_STRING([--enable-selinux],
 505         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 506     [MESA_SELINUX="$enableval"],
 507     [MESA_SELINUX=no])
 508 if test "x$enable_selinux" = "xyes"; then
 509     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 510         [AC_CHECK_HEADER([selinux/selinux.h],[],
 511                          [AC_MSG_ERROR([SELinux headers not found])])
 512          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 513                       [AC_MSG_ERROR([SELinux library not found])])
 514          SELINUX_LIBS="-lselinux"])
 515     DEFINES="$DEFINES -DMESA_SELINUX"
 516 fi
 517 AC_SUBST([SELINUX_CFLAGS])
 518 AC_SUBST([SELINUX_LIBS])
 519
 520 dnl Options for APIs
 521 AC_ARG_ENABLE([opengl],
 522     [AS_HELP_STRING([--disable-opengl],
 523         [disable support for standard OpenGL API @<:@default=no@:>@])],
 524     [enable_opengl="$enableval"],
 525     [enable_opengl=yes])
 526 AC_ARG_ENABLE([gles1],
 527     [AS_HELP_STRING([--enable-gles1],
 528         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 529     [enable_gles1="$enableval"],
 530     [enable_gles1=no])
 531 AC_ARG_ENABLE([gles2],
 532     [AS_HELP_STRING([--enable-gles2],
 533         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 534     [enable_gles2="$enableval"],
 535     [enable_gles2=no])
 536 AC_ARG_ENABLE([openvg],
 537     [AS_HELP_STRING([--enable-openvg],
 538         [enable support for OpenVG API @<:@default=no@:>@])],
 539     [enable_openvg="$enableval"],
 540     [enable_openvg=no])
 541
 542 AC_ARG_ENABLE([dri],
 543     [AS_HELP_STRING([--enable-dri],
 544         [enable DRI modules @<:@default=enabled@:>@])],
 545     [enable_dri="$enableval"],
 546     [enable_dri=yes])
 547 AC_ARG_ENABLE([dri3],
 548     [AS_HELP_STRING([--enable-dri3],
 549         [enable DRI3 @<:@default=enabled@:>@])],
 550     [enable_dri3="$enableval"],
 551     [enable_dri3=yes])
 552 AC_ARG_ENABLE([glx],
 553     [AS_HELP_STRING([--enable-glx],
 554         [enable GLX library @<:@default=enabled@:>@])],
 555     [enable_glx="$enableval"],
 556     [enable_glx=yes])
 557 AC_ARG_ENABLE([osmesa],
 558     [AS_HELP_STRING([--enable-osmesa],
 559         [enable OSMesa library @<:@default=disabled@:>@])],
 560     [enable_osmesa="$enableval"],
 561     [enable_osmesa=no])
 562 AC_ARG_ENABLE([gallium-osmesa],
 563     [AS_HELP_STRING([--enable-gallium-osmesa],
 564         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 565     [enable_gallium_osmesa="$enableval"],
 566     [enable_gallium_osmesa=no])
 567 AC_ARG_ENABLE([egl],
 568     [AS_HELP_STRING([--disable-egl],
 569         [disable EGL library @<:@default=enabled@:>@])],
 570     [enable_egl="$enableval"],
 571     [enable_egl=yes])
 572
 573 AC_ARG_ENABLE([xa],
 574     [AS_HELP_STRING([--enable-xa],
 575         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 576     [enable_xa="$enableval"],
 577     [enable_xa=no])
 578 AC_ARG_ENABLE([gbm],
 579    [AS_HELP_STRING([--enable-gbm],
 580          [enable gbm library @<:@default=auto@:>@])],
 581    [enable_gbm="$enableval"],
 582    [enable_gbm=auto])
 583
 584 AC_ARG_ENABLE([xvmc],
 585    [AS_HELP_STRING([--enable-xvmc],
 586          [enable xvmc library @<:@default=auto@:>@])],
 587    [enable_xvmc="$enableval"],
 588    [enable_xvmc=no])
 589 AC_ARG_ENABLE([vdpau],
 590    [AS_HELP_STRING([--enable-vdpau],
 591          [enable vdpau library @<:@default=auto@:>@])],
 592    [enable_vdpau="$enableval"],
 593    [enable_vdpau=auto])
 594 AC_ARG_ENABLE([omx],
 595    [AS_HELP_STRING([--enable-omx],
 596          [enable OpenMAX library @<:@default=no@:>@])],
 597    [enable_omx="$enableval"],
 598    [enable_omx=no])
 599 AC_ARG_ENABLE([opencl],
 600    [AS_HELP_STRING([--enable-opencl],
 601          [enable OpenCL library NOTE: Enabling this option will also enable
 602           --with-llvm-shared-libs
 603           @<:@default=no@:>@])],
 604    [],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([opencl_icd],
 607    [AS_HELP_STRING([--enable-opencl-icd],
 608           [Build an OpenCL ICD library to be loaded by an ICD implementation
 609            @<:@default=no@:>@])],
 610     [enable_opencl_icd="$enableval"],
 611     [enable_opencl_icd=no])
 612 AC_ARG_ENABLE([xlib-glx],
 613     [AS_HELP_STRING([--enable-xlib-glx],
 614         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 615     [enable_xlib_glx="$enableval"],
 616     [enable_xlib_glx=no])
 617 AC_ARG_ENABLE([gallium-egl],
 618     [AS_HELP_STRING([--enable-gallium-egl],
 619         [enable optional EGL state tracker (not required
 620          for EGL support in Gallium with OpenGL and OpenGL ES)
 621          @<:@default=disable@:>@])],
 622     [enable_gallium_egl="$enableval"],
 623     [enable_gallium_egl=no])
 624 AC_ARG_ENABLE([gallium-gbm],
 625     [AS_HELP_STRING([--enable-gallium-gbm],
 626         [enable optional gbm state tracker (not required for
 627          gbm support in Gallium)
 628          @<:@default=auto@:>@])],
 629     [enable_gallium_gbm="$enableval"],
 630     [enable_gallium_gbm=auto])
 631
 632 AC_ARG_ENABLE([r600-llvm-compiler],
 633     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 634         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 635     [enable_r600_llvm="$enableval"],
 636     [enable_r600_llvm=no])
 637
 638 AC_ARG_ENABLE([gallium-tests],
 639     [AS_HELP_STRING([--enable-gallium-tests],
 640         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 641     [enable_gallium_tests="$enableval"],
 642     [enable_gallium_tests=no])
 643
 644 # Option for Gallium drivers
 645
 646 # Keep this in sync with the --with-gallium-drivers help string default value
 647 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 648
 649 AC_ARG_WITH([gallium-drivers],
 650     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 651         [comma delimited Gallium drivers list, e.g.
 652         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 653         @<:@default=r300,r600,svga,swrast@:>@])],
 654     [with_gallium_drivers="$withval"],
 655     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 656
 657 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 658 # here so that the script doesn't choke on an unknown driver name later.
 659 case "$with_gallium_drivers" in
 660     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 661     no) with_gallium_drivers='' ;;
 662 esac
 663
 664 if test "x$enable_opengl" = xno -a \
 665         "x$enable_gles1" = xno -a \
 666         "x$enable_gles2" = xno -a \
 667         "x$enable_openvg" = xno -a \
 668         "x$enable_xa" = xno -a \
 669         "x$enable_xvmc" = xno -a \
 670         "x$enable_vdpau" = xno -a \
 671         "x$enable_omx" = xno -a \
 672         "x$enable_opencl" = xno; then
 673     AC_MSG_ERROR([at least one API should be enabled])
 674 fi
 675
 676 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 677 if test "x$enable_opengl" = xno -a \
 678         "x$enable_gles1" = xyes; then
 679     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 680 fi
 681
 682 if test "x$enable_opengl" = xno -a \
 683         "x$enable_gles2" = xyes; then
 684     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 685 fi
 686
 687 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 688 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 689 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 690 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 691                                         "x$enable_gles1" = xyes -o \
 692                                         "x$enable_gles2" = xyes)
 693
 694 if test "x$enable_glx" = xno; then
 695     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 696     enable_xlib_glx=no
 697 fi
 698
 699 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 700     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 701 fi
 702
 703 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 704     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 705 fi
 706
 707 # Disable GLX if OpenGL is not enabled
 708 if test "x$enable_glx$enable_opengl" = xyesno; then
 709     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 710     enable_glx=no
 711 fi
 712
 713 # Disable GLX if DRI and Xlib-GLX are not enabled
 714 if test "x$enable_glx" = xyes -a \
 715         "x$enable_dri" = xno -a \
 716         "x$enable_xlib_glx" = xno; then
 717     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 718     enable_glx=no
 719 fi
 720
 721 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 722                                   "x$enable_dri" = xyes)
 723 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 724 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 725
 726 AC_ARG_ENABLE([shared-glapi],
 727     [AS_HELP_STRING([--enable-shared-glapi],
 728         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 729     [enable_shared_glapi="$enableval"],
 730     [enable_shared_glapi="$enable_dri"])
 731
 732 # Shared GLAPI is only useful for DRI
 733 if test "x$enable_dri" = xno; then
 734     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 735     enable_shared_glapi=no
 736 fi
 737
 738 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 739
 740 dnl
 741 dnl Driver specific build directories
 742 dnl
 743 GALLIUM_TARGET_DIRS=""
 744 GALLIUM_WINSYS_DIRS="sw"
 745 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 746 GALLIUM_STATE_TRACKERS_DIRS=""
 747
 748 case "x$enable_glx$enable_xlib_glx" in
 749 xyesyes)
 750     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 751     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 752     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 753     NEED_WINSYS_XLIB="yes"
 754     ;;
 755 esac
 756
 757 if test "x$enable_dri" = xyes; then
 758     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 759     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 760 fi
 761
 762 if test "x$enable_gallium_osmesa" = xyes; then
 763     if test -z "$with_gallium_drivers"; then
 764         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 765     fi
 766     if test "x$enable_osmesa" = xyes; then
 767         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 768     fi
 769     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 770     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 771 fi
 772
 773 AC_SUBST([MESA_LLVM])
 774
 775 # Check for libdrm
 776 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 777                   [have_libdrm=yes], [have_libdrm=no])
 778 if test "x$have_libdrm" = xyes; then
 779         DEFINES="$DEFINES -DHAVE_LIBDRM"
 780 fi
 781
 782 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 783                   have_libudev=yes, have_libudev=no)
 784
 785 if test "x$enable_dri" = xyes; then
 786     # DRI must be shared, I think
 787     if test "$enable_static" = yes; then
 788         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 789     fi
 790
 791     # not a hard requirement as swrast does not depend on it
 792     if test "x$have_libdrm" = xyes; then
 793         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 794     fi
 795 fi
 796
 797 dnl Direct rendering or just indirect rendering
 798 case "$host_os" in
 799 gnu*)
 800     dnl Disable by default on GNU/Hurd
 801     driglx_direct_default="no"
 802     ;;
 803 cygwin*)
 804     dnl Disable by default on cygwin
 805     driglx_direct_default="no"
 806     ;;
 807 *)
 808     driglx_direct_default="yes"
 809     ;;
 810 esac
 811 AC_ARG_ENABLE([driglx-direct],
 812     [AS_HELP_STRING([--disable-driglx-direct],
 813         [disable direct rendering in GLX and EGL for DRI \
 814             @<:@default=auto@:>@])],
 815     [driglx_direct="$enableval"],
 816     [driglx_direct="$driglx_direct_default"])
 817
 818 dnl
 819 dnl libGL configuration per driver
 820 dnl
 821 case "x$enable_glx$enable_xlib_glx" in
 822 xyesyes)
 823     # Xlib-based GLX
 824     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 825     GL_PC_REQ_PRIV="x11 xext"
 826     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 827     GL_LIB_DEPS="$XLIBGL_LIBS"
 828     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 829     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 830     ;;
 831 xyesno)
 832     # DRI-based GLX
 833     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 834     if test x"$driglx_direct" = xyes; then
 835         if test "x$have_libdrm" != xyes; then
 836             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 837         fi
 838         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 839         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 840         if test x"$enable_dri3" = xyes; then
 841             if test x"$have_libudev" != xyes; then
 842               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 843             fi
 844             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 845             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 846         fi
 847     fi
 848
 849     # find the DRI deps for libGL
 850     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 851
 852     if test x"$enable_dri3" = xyes; then
 853         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= 1.1"
 854     fi
 855
 856     # add xf86vidmode if available
 857     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 858     if test "$HAVE_XF86VIDMODE" = yes ; then
 859         dri_modules="$dri_modules xxf86vm"
 860     fi
 861
 862     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 863     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 864     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 865     GL_LIB_DEPS="$DRIGL_LIBS"
 866
 867     # need DRM libs, $PTHREAD_LIBS, etc.
 868     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 869     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 870     ;;
 871 esac
 872
 873 if test "$have_libudev" = yes; then
 874     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 875 fi
 876
 877 # This is outside the case (above) so that it is invoked even for non-GLX
 878 # builds.
 879 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 880
 881 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 882 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 883 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 884 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 885
 886 AC_SUBST([X11_INCLUDES])
 887 AC_SUBST([GL_LIB_DEPS])
 888 AC_SUBST([GL_PC_REQ_PRIV])
 889 AC_SUBST([GL_PC_LIB_PRIV])
 890 AC_SUBST([GL_PC_CFLAGS])
 891 AC_SUBST([DRI_PC_REQ_PRIV])
 892 AC_SUBST([GLESv1_CM_LIB_DEPS])
 893 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 894 AC_SUBST([GLESv2_LIB_DEPS])
 895 AC_SUBST([GLESv2_PC_LIB_PRIV])
 896
 897 AC_SUBST([HAVE_XF86VIDMODE])
 898
 899 dnl
 900 dnl More GLX setup
 901 dnl
 902 case "x$enable_glx$enable_xlib_glx" in
 903 xyesyes)
 904     DEFINES="$DEFINES -DUSE_XSHM"
 905     ;;
 906 xyesno)
 907     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 908     if test "x$driglx_direct" = xyes; then
 909         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 910     fi
 911     ;;
 912 esac
 913
 914 dnl
 915 dnl TLS detection
 916 dnl
 917
 918 AC_ARG_ENABLE([glx-tls],
 919     [AS_HELP_STRING([--enable-glx-tls],
 920         [enable TLS support in GLX @<:@default=disabled@:>@])],
 921     [GLX_USE_TLS="$enableval"],
 922     [GLX_USE_TLS=no])
 923 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 924
 925 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 926       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 927
 928 dnl
 929 dnl More DRI setup
 930 dnl
 931 dnl Directory for DRI drivers
 932 AC_ARG_WITH([dri-driverdir],
 933     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 934         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 935     [DRI_DRIVER_INSTALL_DIR="$withval"],
 936     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 937 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 938 dnl Extra search path for DRI drivers
 939 AC_ARG_WITH([dri-searchpath],
 940     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 941         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 942     [DRI_DRIVER_SEARCH_DIR="$withval"],
 943     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 944 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 945 dnl Which drivers to build - default is chosen by platform
 946 AC_ARG_WITH([dri-drivers],
 947     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 948         [comma delimited classic DRI drivers list, e.g.
 949         "swrast,i965,radeon" @<:@default=auto@:>@])],
 950     [with_dri_drivers="$withval"],
 951     [with_dri_drivers=yes])
 952 if test "x$with_dri_drivers" = x; then
 953     with_dri_drivers=no
 954 fi
 955
 956 dnl If $with_dri_drivers is yes, directories will be added through
 957 dnl platform checks
 958 DRI_DIRS=""
 959 case "$with_dri_drivers" in
 960 no) ;;
 961 yes)
 962     # classic DRI drivers
 963     if test "x$enable_opengl" = xyes; then
 964         DRI_DIRS="yes"
 965     fi
 966     ;;
 967 *)
 968     # verify the requested driver directories exist
 969     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 970     for driver in $dri_drivers; do
 971         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 972             AC_MSG_ERROR([classic DRI driver directory '$driver' does not exist])
 973     done
 974     DRI_DIRS="$dri_drivers"
 975     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 976         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 977     fi
 978     ;;
 979 esac
 980
 981 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 982 if test "x$enable_dri" = xyes; then
 983     # Platform specific settings and drivers to build
 984     case "$host_os" in
 985     linux*)
 986         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 987         DEFINES="$DEFINES -DHAVE_ALIAS"
 988         if test "x$enable_dri3" = xyes; then
 989             DEFINES="$DEFINES -DHAVE_DRI3"
 990         fi
 991
 992         case "$host_cpu" in
 993         powerpc*)
 994             # Build only the drivers for cards that exist on PowerPC.
 995             if test "x$DRI_DIRS" = "xyes"; then
 996                 DRI_DIRS="r200 radeon swrast"
 997             fi
 998             ;;
 999         sparc*)
1000             # Build only the drivers for cards that exist on sparc
1001             if test "x$DRI_DIRS" = "xyes"; then
1002                 DRI_DIRS="r200 radeon swrast"
1003             fi
1004             ;;
1005         esac
1006         ;;
1007     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1008         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1009         DEFINES="$DEFINES -DHAVE_ALIAS"
1010         ;;
1011     gnu*)
1012         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1013         DEFINES="$DEFINES -DHAVE_ALIAS"
1014         ;;
1015     solaris*)
1016         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1017         ;;
1018     cygwin*)
1019         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1020         if test "x$DRI_DIRS" = "xyes"; then
1021             DRI_DIRS="swrast"
1022         fi
1023         ;;
1024     esac
1025
1026     # default drivers
1027     if test "x$DRI_DIRS" = "xyes"; then
1028         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1029     fi
1030
1031     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1032
1033     # Check for expat
1034     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1035     if test "x$have_expat" = "xyes"; then
1036        PKG_CHECK_MODULES([EXPAT], [expat], [],
1037                          AC_MSG_ERROR([Expat required for DRI.]))
1038     else
1039        # expat version 2.0 and earlier do not provide expat.pc
1040        EXPAT_LIBS=-lexpat
1041     fi
1042
1043     # If we are building any DRI driver other than swrast.
1044     if test -n "$DRI_DIRS"; then
1045         if test x"$DRI_DIRS" != xswrast; then
1046             # ... libdrm is required
1047             if test "x$have_libdrm" != xyes; then
1048                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1049             fi
1050             DRICOMMON_NEED_LIBDRM=yes
1051         else
1052             DRICOMMON_NEED_LIBDRM=no
1053         fi
1054     fi
1055
1056     # put all the necessary libs together
1057     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1058     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1059
1060 fi
1061
1062 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1063 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1064                                   "x$enable_osmesa" = xyes -o \
1065                                   -n "$DRI_DIRS")
1066 AC_SUBST([DRI_LIB_DEPS])
1067 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1068
1069 case $DRI_DIRS in
1070 *i915*)
1071     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1072     HAVE_I915_DRI=yes;
1073     ;;
1074 *i965*)
1075     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1076     HAVE_I965_DRI=yes;
1077     ;;
1078 *nouveau*)
1079     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1080     HAVE_NOUVEAU_DRI=yes;
1081     ;;
1082 *radeon*)
1083     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1084     HAVE_RADEON_DRI=yes;
1085     ;;
1086 *r200*)
1087     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1088     HAVE_R200_DRI=yes;
1089     ;;
1090 *swrast*)
1091     HAVE_SWRAST_DRI=yes;
1092     ;;
1093 esac
1094
1095 dnl
1096 dnl OSMesa configuration
1097 dnl
1098
1099 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1100 AC_ARG_WITH([osmesa-bits],
1101     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1102         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1103     [osmesa_bits="$withval"],
1104     [osmesa_bits=8])
1105 if test "x$osmesa_bits" != x8; then
1106     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1107         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1108         osmesa_bits=8
1109     fi
1110 fi
1111 case "x$osmesa_bits" in
1112 x8)
1113     OSMESA_LIB="${OSMESA_LIB}"
1114     ;;
1115 x16|x32)
1116     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1117     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1118     ;;
1119 *)
1120     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1121     ;;
1122 esac
1123
1124 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1125     # only link libraries with osmesa if shared
1126     if test "$enable_static" = no; then
1127         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1128     else
1129         OSMESA_LIB_DEPS=""
1130     fi
1131     OSMESA_MESA_DEPS=""
1132     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1133 fi
1134
1135 AC_SUBST([OSMESA_LIB_DEPS])
1136 AC_SUBST([OSMESA_MESA_DEPS])
1137 AC_SUBST([OSMESA_PC_REQ])
1138 AC_SUBST([OSMESA_PC_LIB_PRIV])
1139
1140 dnl
1141 dnl gbm configuration
1142 dnl
1143 if test "x$enable_gbm" = xauto; then
1144     case "$with_egl_platforms" in
1145         *drm*)
1146             enable_gbm=yes ;;
1147          *)
1148             enable_gbm=no ;;
1149     esac
1150 fi
1151 if test "x$enable_gbm" = xyes; then
1152     if test x"$have_libudev" != xyes; then
1153         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1154     fi
1155
1156     if test "x$enable_dri" = xyes; then
1157         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1158         if test "x$enable_shared_glapi" = xno; then
1159             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1160         fi
1161     fi
1162 fi
1163 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1164 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1165 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1166 AC_SUBST([GBM_PC_REQ_PRIV])
1167 AC_SUBST([GBM_PC_LIB_PRIV])
1168
1169 dnl
1170 dnl EGL configuration
1171 dnl
1172 EGL_CLIENT_APIS=""
1173
1174 if test "x$enable_egl" = xyes; then
1175     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1176
1177     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1178
1179     if test "$enable_static" != yes; then
1180         if test "x$enable_dri" = xyes; then
1181             HAVE_EGL_DRIVER_DRI2=1
1182         fi
1183
1184     fi
1185 fi
1186 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1187 AC_SUBST([EGL_LIB_DEPS])
1188
1189 dnl
1190 dnl EGL Gallium configuration
1191 dnl
1192 if test "x$enable_gallium_egl" = xyes; then
1193     if test "x$with_gallium_drivers" = x; then
1194         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1195     fi
1196     if test "x$enable_egl" = xno; then
1197         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1198     fi
1199     if test "x$have_libdrm" != xyes; then
1200         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1201     fi
1202
1203     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1204     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1205 fi
1206 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1207
1208 dnl
1209 dnl gbm Gallium configuration
1210 dnl
1211 if test "x$enable_gallium_gbm" = xauto; then
1212     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1213         yesyesyes*drm*)
1214             enable_gallium_gbm=yes ;;
1215          *)
1216             enable_gallium_gbm=no ;;
1217     esac
1218 fi
1219 if test "x$enable_gallium_gbm" = xyes; then
1220     if test "x$with_gallium_drivers" = x; then
1221         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1222     fi
1223     if test "x$enable_gbm" = xno; then
1224         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1225     fi
1226     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1227     if test "x$enable_dri" = xno; then
1228         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1229     fi
1230
1231     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1232     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1233     enable_gallium_loader=yes
1234 fi
1235 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1236
1237 dnl
1238 dnl XA configuration
1239 dnl
1240 if test "x$enable_xa" = xyes; then
1241     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1242     enable_gallium_loader=yes
1243 fi
1244 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1245
1246 dnl
1247 dnl OpenVG configuration
1248 dnl
1249 VG_LIB_DEPS=""
1250
1251 if test "x$enable_openvg" = xyes; then
1252     if test "x$enable_egl" = xno; then
1253         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1254     fi
1255     if test "x$with_gallium_drivers" = x; then
1256         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1257     fi
1258     if test "x$enable_gallium_egl" = xno; then
1259         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1260     fi
1261
1262     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1263     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1264     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1265     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1266     AC_SUBST([VG_PC_LIB_PRIV])
1267 fi
1268 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1269
1270 dnl
1271 dnl Gallium G3DVL configuration
1272 dnl
1273 if test -n "$with_gallium_drivers"; then
1274     if test "x$enable_xvmc" = xauto; then
1275         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1276     fi
1277
1278     if test "x$enable_vdpau" = xauto; then
1279         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1280     fi
1281
1282     if test "x$enable_omx" = xauto; then
1283         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1284     fi
1285 fi
1286
1287 if test "x$enable_xvmc" = xyes; then
1288     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1289     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1290 fi
1291 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1292
1293 if test "x$enable_vdpau" = xyes; then
1294     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8],
1295                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1296     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1297 fi
1298 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1299
1300 if test "x$enable_omx" = xyes; then
1301     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= 0.0 x11-xcb xcb-dri2 >= 1.8])
1302     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1303 fi
1304 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1305
1306 dnl
1307 dnl OpenCL configuration
1308 dnl
1309
1310 AC_ARG_WITH([libclc-path],
1311    [AS_HELP_STRING([--with-libclc-path],
1312          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1313    [LIBCLC_PATH="$withval"],
1314    [LIBCLC_PATH=""])
1315
1316 if test "x$LIBCLC_PATH" != x; then
1317    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1318                   Please review the updated build instructions for clover:
1319                   http://dri.freedesktop.org/wiki/GalliumCompute])
1320 fi
1321
1322
1323 AC_ARG_WITH([clang-libdir],
1324    [AS_HELP_STRING([--with-clang-libdir],
1325          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1326    [CLANG_LIBDIR="$withval"],
1327    [CLANG_LIBDIR=""])
1328
1329 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1330
1331 if test "x$enable_opencl" = xyes; then
1332     if test "x$with_gallium_drivers" = x; then
1333         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1334     fi
1335
1336     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1337         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1338     fi
1339
1340     if test "x$have_libclc" = xno; then
1341         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1342                     Make sure the directory containing libclc.pc is specified in your
1343                     PKG_CONFIG_PATH environment variable.
1344                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1345     else
1346         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1347         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1348         AC_SUBST([LIBCLC_INCLUDEDIR])
1349         AC_SUBST([LIBCLC_LIBEXECDIR])
1350     fi
1351
1352     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1353     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1354     enable_gallium_loader=yes
1355
1356     if test "x$enable_opencl_icd" = xyes; then
1357         OPENCL_LIBNAME="MesaOpenCL"
1358     else
1359         OPENCL_LIBNAME="OpenCL"
1360     fi
1361 fi
1362 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1363 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1364 AC_SUBST([OPENCL_LIBNAME])
1365
1366 dnl
1367 dnl Gallium configuration
1368 dnl
1369 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1370
1371 AC_SUBST([LLVM_BINDIR])
1372 AC_SUBST([LLVM_CFLAGS])
1373 AC_SUBST([LLVM_CPPFLAGS])
1374 AC_SUBST([LLVM_CXXFLAGS])
1375 AC_SUBST([LLVM_LIBDIR])
1376 AC_SUBST([LLVM_LIBS])
1377 AC_SUBST([LLVM_LDFLAGS])
1378 AC_SUBST([LLVM_INCLUDEDIR])
1379 AC_SUBST([LLVM_VERSION])
1380 AC_SUBST([CLANG_RESOURCE_DIR])
1381
1382 case "x$enable_opengl$enable_gles1$enable_gles2" in
1383 x*yes*)
1384     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1385     ;;
1386 esac
1387
1388 AC_SUBST([VG_LIB_DEPS])
1389 AC_SUBST([EGL_CLIENT_APIS])
1390
1391 dnl
1392 dnl EGL Platforms configuration
1393 dnl
1394 AC_ARG_WITH([egl-platforms],
1395     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1396         [comma delimited native platforms libEGL supports, e.g.
1397         "x11,drm" @<:@default=auto@:>@])],
1398     [with_egl_platforms="$withval"],
1399     [if test "x$enable_egl" = xyes; then
1400         with_egl_platforms="x11"
1401     else
1402         with_egl_platforms=""
1403     fi])
1404
1405 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1406     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1407 fi
1408
1409 # Do per-EGL platform setups and checks
1410 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1411 for plat in $egl_platforms; do
1412         case "$plat" in
1413         wayland)
1414                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1415                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1416
1417                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1418                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1419                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1420                 ;;
1421
1422         x11)
1423                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1424                 ;;
1425
1426         drm)
1427                 test "x$enable_gbm" = "xno" &&
1428                         AC_MSG_ERROR([EGL platform drm needs gbm])
1429                 test "x$have_libdrm" != xyes &&
1430                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1431                 ;;
1432
1433         android|fbdev|gdi|null)
1434                 ;;
1435
1436         *)
1437                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1438                 ;;
1439         esac
1440
1441         case "$plat$have_libudev" in
1442                 waylandno|drmno)
1443                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1444         esac
1445 done
1446
1447 # libEGL wants to default to the first platform specified in
1448 # ./configure.  parse that here.
1449 if test "x$egl_platforms" != "x"; then
1450     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1451     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1452 else
1453     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1454 fi
1455
1456 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1457     NEED_WINSYS_XLIB=yes
1458 fi
1459 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1460 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1461 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1462 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1463 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1464
1465 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1466
1467 AC_SUBST([EGL_NATIVE_PLATFORM])
1468 AC_SUBST([EGL_CFLAGS])
1469
1470 # If we don't have the X11 platform, set this define so we don't try to include
1471 # the X11 headers.
1472 if ! echo "$egl_platforms" | grep -q 'x11'; then
1473     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1474     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1475 fi
1476
1477 AC_ARG_WITH([egl-driver-dir],
1478     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1479                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1480     [EGL_DRIVER_INSTALL_DIR="$withval"],
1481     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1482 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1483
1484 AC_ARG_WITH([max-width],
1485     [AS_HELP_STRING([--with-max-width=N],
1486                     [Maximum framebuffer width (4096)])],
1487     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1488      AS_IF([test "${withval}" -gt "4096"],
1489            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1490 )
1491 AC_ARG_WITH([max-height],
1492     [AS_HELP_STRING([--with-max-height=N],
1493                     [Maximum framebuffer height (4096)])],
1494     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1495      AS_IF([test "${withval}" -gt "4096"],
1496            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1497 )
1498
1499 dnl
1500 dnl Gallium LLVM
1501 dnl
1502 AC_ARG_ENABLE([gallium-llvm],
1503     [AS_HELP_STRING([--enable-gallium-llvm],
1504         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1505     [enable_gallium_llvm="$enableval"],
1506     [enable_gallium_llvm=auto])
1507
1508 AC_ARG_WITH([llvm-shared-libs],
1509     [AS_HELP_STRING([--with-llvm-shared-libs],
1510         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1511     [],
1512     [with_llvm_shared_libs=no])
1513
1514 AC_ARG_WITH([llvm-prefix],
1515     [AS_HELP_STRING([--with-llvm-prefix],
1516         [Prefix for LLVM installations in non-standard locations])],
1517     [llvm_prefix="$withval"],
1518     [llvm_prefix=""])
1519
1520
1521 # Call this inside ` ` to get the return value.
1522 # $1 is the llvm-config command with arguments.
1523 strip_unwanted_llvm_flags() {
1524     # Use \> (marks the end of the word)
1525     echo `$1` | sed \
1526         -e 's/-DNDEBUG\>//g' \
1527         -e 's/-pedantic\>//g' \
1528         -e 's/-Wcovered-switch-default\>//g' \
1529         -e 's/-O.\>//g' \
1530         -e 's/-g\>//g' \
1531         -e 's/-Wall\>//g' \
1532         -e 's/-fcolor-diagnostics\>//g' \
1533         -e 's/-fomit-frame-pointer\>//g'
1534 }
1535
1536
1537 if test "x$with_gallium_drivers" = x; then
1538     enable_gallium_llvm=no
1539 fi
1540 if test "x$enable_gallium_llvm" = xauto; then
1541     case "$host_cpu" in
1542     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1543     esac
1544 fi
1545 if test "x$enable_gallium_llvm" = xyes; then
1546     if test "x$llvm_prefix" != x; then
1547         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1548     else
1549         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1550     fi
1551
1552     if test "x$LLVM_CONFIG" != xno; then
1553         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1554         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1555         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1556         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1557         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1558         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1559         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1560         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1561
1562         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1563             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1564         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1565             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1566
1567         if test "x${LLVM_VERSION_MAJOR}" != x; then
1568             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1569         else
1570             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1571         fi
1572
1573         LLVM_COMPONENTS="engine bitwriter"
1574         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1575             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1576         fi
1577
1578         if test "x$enable_opencl" = xyes; then
1579             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1580             # LLVM 3.3 >= 177971 requires IRReader
1581             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1582                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1583             fi
1584             # LLVM 3.4 requires Option
1585             if $LLVM_CONFIG --components | grep -qw 'option'; then
1586                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1587             fi
1588         fi
1589         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1590         MESA_LLVM=1
1591
1592         dnl Check for Clang internal headers
1593         if test "x$enable_opencl" = xyes; then
1594             if test "x$CLANG_LIBDIR" = x; then
1595                 CLANG_LIBDIR=${LLVM_LIBDIR}
1596             fi
1597             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1598             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1599                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1600         fi
1601     else
1602         MESA_LLVM=0
1603         LLVM_VERSION_INT=0
1604     fi
1605 else
1606     MESA_LLVM=0
1607     LLVM_VERSION_INT=0
1608 fi
1609
1610 dnl Directory for XVMC libs
1611 AC_ARG_WITH([xvmc-libdir],
1612     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1613         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1614     [XVMC_LIB_INSTALL_DIR="$withval"],
1615     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1616 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1617
1618 dnl
1619 dnl Gallium Tests
1620 dnl
1621 if test "x$enable_gallium_tests" = xyes; then
1622     enable_gallium_loader=yes
1623 fi
1624 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1625
1626 if test "x$enable_gallium_loader" = xyes; then
1627     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1628 fi
1629 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1630
1631 dnl Directory for VDPAU libs
1632 AC_ARG_WITH([vdpau-libdir],
1633     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1634         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1635     [VDPAU_LIB_INSTALL_DIR="$withval"],
1636     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1637 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1638
1639 AC_ARG_WITH([omx-libdir],
1640     [AS_HELP_STRING([--with-omx-libdir=DIR],
1641         [directory for the OMX libraries])],
1642     [OMX_LIB_INSTALL_DIR="$withval"],
1643     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1644 AC_SUBST([OMX_LIB_INSTALL_DIR])
1645
1646 dnl Directory for OpenCL libs
1647 AC_ARG_WITH([opencl-libdir],
1648     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1649         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1650     [OPENCL_LIB_INSTALL_DIR="$withval"],
1651     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1652 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1653
1654 dnl
1655 dnl Gallium helper functions
1656 dnl
1657 gallium_check_st() {
1658     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1659          if test "x$have_libdrm" != xyes; then
1660             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1661          fi
1662          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1663     fi
1664     if test "x$enable_dri" = xyes && test "x$2" != x; then
1665          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1666     fi
1667     if test "x$enable_xa" = xyes && test "x$3" != x; then
1668          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1669     fi
1670     if test "x$enable_xvmc" = xyes && test "x$4" != x; then
1671          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1672     fi
1673     if test "x$enable_vdpau" = xyes && test "x$5" != x; then
1674          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1675     fi
1676     if test "x$enable_omx" = xyes && test "x$6" != x; then
1677          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1678     fi
1679 }
1680
1681 gallium_require_llvm() {
1682     if test "x$MESA_LLVM" = x0; then
1683         case "$host_cpu" in
1684         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1685         esac
1686     fi
1687 }
1688
1689 gallium_require_drm_loader() {
1690     if test "x$enable_gallium_loader" = xyes; then
1691         if test "x$have_libudev" != xyes; then
1692             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1693         fi
1694         if test "x$have_libdrm" != xyes; then
1695             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1696         fi
1697         enable_gallium_drm_loader=yes
1698     fi
1699 }
1700
1701 radeon_llvm_check() {
1702     if test "x$enable_gallium_llvm" != "xyes"; then
1703         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1704     fi
1705     LLVM_REQUIRED_VERSION_MAJOR="3"
1706     LLVM_REQUIRED_VERSION_MINOR="3"
1707     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1708         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1709     fi
1710     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1711         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1712                       sources with the --enable-experimental-targets=R600
1713                       configure flag])
1714     fi
1715     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1716     NEED_RADEON_LLVM=yes
1717     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1718                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1719 }
1720
1721 dnl Gallium drivers
1722 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1723         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1724     NEED_NONNULL_WINSYS=yes
1725 fi
1726 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1727
1728 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1729 if test "x$with_gallium_drivers" != x; then
1730     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1731     for driver in $gallium_drivers; do
1732         case "x$driver" in
1733         xsvga)
1734             HAVE_GALLIUM_SVGA=yes
1735             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1736             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1737             ;;
1738         xi915)
1739             HAVE_GALLIUM_I915=yes
1740             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1741             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1742             if test "x$MESA_LLVM" = x1; then
1743                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1744             fi
1745             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1746             gallium_check_st "i915/drm" "dri-i915"
1747             DRICOMMON_NEED_LIBDRM=yes
1748             ;;
1749         xilo)
1750             HAVE_GALLIUM_ILO=yes
1751             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1752             gallium_require_drm_loader
1753             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1754             gallium_check_st "intel/drm" "dri-ilo"
1755             DRICOMMON_NEED_LIBDRM=yes
1756             ;;
1757         xr300)
1758             HAVE_GALLIUM_R300=yes
1759             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1760             gallium_require_llvm "Gallium R300"
1761             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1762             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1763             DRICOMMON_NEED_LIBDRM=yes
1764             ;;
1765         xr600)
1766             HAVE_GALLIUM_R600=yes
1767             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1768             gallium_require_drm_loader
1769             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1770             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1771                 radeon_llvm_check "r600g"
1772                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1773             fi
1774             if test "x$enable_r600_llvm" = xyes; then
1775                 USE_R600_LLVM_COMPILER=yes;
1776             fi
1777             if test "x$enable_opencl" = xyes; then
1778                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1779             fi
1780             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1781             DRICOMMON_NEED_LIBDRM=yes
1782             ;;
1783         xradeonsi)
1784             HAVE_GALLIUM_RADEONSI=yes
1785             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1786             gallium_require_drm_loader
1787             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1788             radeon_llvm_check "radeonsi"
1789             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1790             DRICOMMON_NEED_LIBDRM=yes
1791             ;;
1792         xnouveau)
1793             HAVE_GALLIUM_NOUVEAU=yes
1794             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1795             gallium_require_drm_loader
1796             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1797             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1798             DRICOMMON_NEED_LIBDRM=yes
1799             ;;
1800         xfreedreno)
1801             HAVE_GALLIUM_FREEDRENO=yes
1802             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1803             gallium_require_drm_loader
1804             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1805             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1806             DRICOMMON_NEED_LIBDRM=yes
1807             ;;
1808         xswrast)
1809             HAVE_GALLIUM_SOFTPIPE=yes
1810             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1811             if test "x$MESA_LLVM" = x1; then
1812                 HAVE_GALLIUM_LLVMPIPE=yes
1813                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1814             fi
1815
1816             if test "x$enable_dri" = xyes; then
1817                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1818             fi
1819             ;;
1820         *)
1821             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1822             ;;
1823         esac
1824     done
1825 fi
1826
1827 dnl Set LLVM_LIBS - This is done after the driver configuration so
1828 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1829 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1830 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1831 dnl this was causing the same libraries to be appear multiple times
1832 dnl in LLVM_LIBS.
1833
1834 if test "x$MESA_LLVM" != x0; then
1835
1836     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1837
1838     if test "x$with_llvm_shared_libs" = xyes; then
1839         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1840         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1841         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1842
1843         if test "x$llvm_have_one_so" = xyes; then
1844             dnl LLVM was built using auto*, so there is only one shared object.
1845             LLVM_LIBS="-l$LLVM_SO_NAME"
1846         else
1847             dnl If LLVM was built with CMake, there will be one shared object per
1848             dnl component.
1849             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1850                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1851         Please make sure you have built llvm with the --enable-shared option
1852         and that your llvm libraries are installed in $LLVM_LIBDIR
1853         If you have installed your llvm libraries to a different directory you
1854         can use the --with-llvm-prefix= configure flag to specify this directory.
1855         NOTE: Mesa is attempting to use llvm shared libraries because you have
1856         passed one of the following options to configure:
1857                 --with-llvm-shared-libs
1858                 --enable-opencl
1859         If you do not want to build with llvm shared libraries and instead want to
1860         use llvm static libraries then remove these options from your configure
1861         invocation and reconfigure.])])
1862
1863            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1864            dnl install uses a shared object for each compoenent and we have
1865            dnl already added all of these objects to LLVM_LIBS.
1866         fi
1867     fi
1868 fi
1869
1870 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1871 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1872 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1873 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1874 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1875 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1876 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1877 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1878 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1879 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1880
1881 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1882                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1883                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1884 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1885                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1886                                                   && test "x$MESA_LLVM" = x1)
1887
1888 # NOTE: anything using xcb or other client side libs ends up in separate
1889 #       _CLIENT variables.  The pipe loader is built in two variants,
1890 #       one that is standalone and does not link any x client libs (for
1891 #       use by XA tracker in particular, but could be used in any case
1892 #       where communication with xserver is not desired).
1893 if test "x$enable_gallium_loader" = xyes; then
1894     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1895
1896     if test "x$enable_gallium_drm_loader" = xyes; then
1897         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1898         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1899                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1900         if test "x$pipe_loader_have_xcb" = xyes; then
1901             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1902             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1903         fi
1904     fi
1905
1906     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1907     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1908
1909     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1910     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1911     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1912     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1913 fi
1914
1915 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1916 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1917 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1918 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1919 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1920 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1921
1922 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1923                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1924                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1925                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1926 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1927                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1928 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1929 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1930 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1931 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1932 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1933 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1934 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1935
1936 AC_SUBST([ELF_LIB])
1937
1938 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1939 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1940 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1941 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1942 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1943
1944 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1945 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1946 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1947
1948 AC_SUBST([VDPAU_MAJOR], 1)
1949 AC_SUBST([VDPAU_MINOR], 0)
1950
1951 AC_SUBST([XVMC_MAJOR], 1)
1952 AC_SUBST([XVMC_MINOR], 0)
1953
1954 AC_SUBST([XA_MAJOR], 2)
1955 AC_SUBST([XA_MINOR], 2)
1956 AC_SUBST([XA_TINY], 0)
1957 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1958
1959 dnl Restore LDFLAGS and CPPFLAGS
1960 LDFLAGS="$_SAVE_LDFLAGS"
1961 CPPFLAGS="$_SAVE_CPPFLAGS"
1962
1963 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1964 if test "x$acv_mesa_CLANG" = xyes; then
1965     CFLAGS="$CFLAGS -Qunused-arguments"
1966     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1967 fi
1968
1969 dnl Add user CFLAGS and CXXFLAGS
1970 CFLAGS="$CFLAGS $USER_CFLAGS"
1971 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1972
1973 dnl Substitute the config
1974 AC_CONFIG_FILES([Makefile
1975                 src/Makefile
1976                 src/egl/Makefile
1977                 src/egl/drivers/Makefile
1978                 src/egl/drivers/dri2/Makefile
1979                 src/egl/main/Makefile
1980                 src/egl/main/egl.pc
1981                 src/egl/wayland/Makefile
1982                 src/egl/wayland/wayland-drm/Makefile
1983                 src/egl/wayland/wayland-egl/Makefile
1984                 src/egl/wayland/wayland-egl/wayland-egl.pc
1985                 src/gallium/auxiliary/Makefile
1986                 src/gallium/auxiliary/pipe-loader/Makefile
1987                 src/gallium/drivers/Makefile
1988                 src/gallium/drivers/freedreno/Makefile
1989                 src/gallium/drivers/galahad/Makefile
1990                 src/gallium/drivers/i915/Makefile
1991                 src/gallium/drivers/identity/Makefile
1992                 src/gallium/drivers/ilo/Makefile
1993                 src/gallium/drivers/llvmpipe/Makefile
1994                 src/gallium/drivers/noop/Makefile
1995                 src/gallium/drivers/nouveau/Makefile
1996                 src/gallium/drivers/r300/Makefile
1997                 src/gallium/drivers/r600/Makefile
1998                 src/gallium/drivers/radeon/Makefile
1999                 src/gallium/drivers/radeonsi/Makefile
2000                 src/gallium/drivers/rbug/Makefile
2001                 src/gallium/drivers/softpipe/Makefile
2002                 src/gallium/drivers/svga/Makefile
2003                 src/gallium/drivers/trace/Makefile
2004                 src/gallium/state_trackers/Makefile
2005                 src/gallium/state_trackers/clover/Makefile
2006                 src/gallium/state_trackers/dri/Makefile
2007                 src/gallium/state_trackers/dri/drm/Makefile
2008                 src/gallium/state_trackers/dri/sw/Makefile
2009                 src/gallium/state_trackers/egl/Makefile
2010                 src/gallium/state_trackers/gbm/Makefile
2011                 src/gallium/state_trackers/glx/xlib/Makefile
2012                 src/gallium/state_trackers/omx/Makefile
2013                 src/gallium/state_trackers/osmesa/Makefile
2014                 src/gallium/state_trackers/vdpau/Makefile
2015                 src/gallium/state_trackers/vega/Makefile
2016                 src/gallium/state_trackers/xa/Makefile
2017                 src/gallium/state_trackers/xvmc/Makefile
2018                 src/gallium/targets/Makefile
2019                 src/gallium/targets/dri-freedreno/Makefile
2020                 src/gallium/targets/dri-i915/Makefile
2021                 src/gallium/targets/dri-ilo/Makefile
2022                 src/gallium/targets/dri-nouveau/Makefile
2023                 src/gallium/targets/dri-swrast/Makefile
2024                 src/gallium/targets/dri-vmwgfx/Makefile
2025                 src/gallium/targets/egl-static/Makefile
2026                 src/gallium/targets/gbm/Makefile
2027                 src/gallium/targets/opencl/Makefile
2028                 src/gallium/targets/xa/Makefile
2029                 src/gallium/targets/xa/xatracker.pc
2030                 src/gallium/targets/osmesa/Makefile
2031                 src/gallium/targets/osmesa/osmesa.pc
2032                 src/gallium/targets/pipe-loader/Makefile
2033                 src/gallium/targets/radeonsi/dri/Makefile
2034                 src/gallium/targets/radeonsi/omx/Makefile
2035                 src/gallium/targets/radeonsi/vdpau/Makefile
2036                 src/gallium/targets/r300/dri/Makefile
2037                 src/gallium/targets/r600/dri/Makefile
2038                 src/gallium/targets/r600/omx/Makefile
2039                 src/gallium/targets/r600/vdpau/Makefile
2040                 src/gallium/targets/r600/xvmc/Makefile
2041                 src/gallium/targets/libgl-xlib/Makefile
2042                 src/gallium/targets/vdpau-nouveau/Makefile
2043                 src/gallium/targets/xvmc-nouveau/Makefile
2044                 src/gallium/tests/trivial/Makefile
2045                 src/gallium/tests/unit/Makefile
2046                 src/gallium/winsys/Makefile
2047                 src/gallium/winsys/freedreno/drm/Makefile
2048                 src/gallium/winsys/i915/drm/Makefile
2049                 src/gallium/winsys/i915/sw/Makefile
2050                 src/gallium/winsys/intel/drm/Makefile
2051                 src/gallium/winsys/nouveau/drm/Makefile
2052                 src/gallium/winsys/radeon/drm/Makefile
2053                 src/gallium/winsys/svga/drm/Makefile
2054                 src/gallium/winsys/sw/dri/Makefile
2055                 src/gallium/winsys/sw/fbdev/Makefile
2056                 src/gallium/winsys/sw/null/Makefile
2057                 src/gallium/winsys/sw/wayland/Makefile
2058                 src/gallium/winsys/sw/wrapper/Makefile
2059                 src/gallium/winsys/sw/xlib/Makefile
2060                 src/gbm/Makefile
2061                 src/gbm/main/gbm.pc
2062                 src/glsl/Makefile
2063                 src/glx/Makefile
2064                 src/glx/tests/Makefile
2065                 src/gtest/Makefile
2066                 src/loader/Makefile
2067                 src/mapi/Makefile
2068                 src/mapi/es1api/Makefile
2069                 src/mapi/es1api/glesv1_cm.pc
2070                 src/mapi/es2api/Makefile
2071                 src/mapi/es2api/glesv2.pc
2072                 src/mapi/glapi/Makefile
2073                 src/mapi/glapi/gen/Makefile
2074                 src/mapi/glapi/tests/Makefile
2075                 src/mapi/shared-glapi/Makefile
2076                 src/mapi/shared-glapi/tests/Makefile
2077                 src/mapi/vgapi/Makefile
2078                 src/mapi/vgapi/vg.pc
2079                 src/mesa/Makefile
2080                 src/mesa/gl.pc
2081                 src/mesa/drivers/dri/dri.pc
2082                 src/mesa/drivers/dri/common/Makefile
2083                 src/mesa/drivers/dri/common/xmlpool/Makefile
2084                 src/mesa/drivers/dri/i915/Makefile
2085                 src/mesa/drivers/dri/i965/Makefile
2086                 src/mesa/drivers/dri/Makefile
2087                 src/mesa/drivers/dri/nouveau/Makefile
2088                 src/mesa/drivers/dri/r200/Makefile
2089                 src/mesa/drivers/dri/radeon/Makefile
2090                 src/mesa/drivers/dri/swrast/Makefile
2091                 src/mesa/drivers/osmesa/Makefile
2092                 src/mesa/drivers/osmesa/osmesa.pc
2093                 src/mesa/drivers/x11/Makefile
2094                 src/mesa/main/tests/Makefile
2095                 src/mesa/main/tests/hash_table/Makefile])
2096
2097 dnl Sort the dirs alphabetically
2098 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2099 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2100 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2101 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2102
2103 AC_OUTPUT
2104
2105 dnl
2106 dnl Output some configuration info for the user
2107 dnl
2108 echo ""
2109 echo "        prefix:          $prefix"
2110 echo "        exec_prefix:     $exec_prefix"
2111 echo "        libdir:          $libdir"
2112 echo "        includedir:      $includedir"
2113
2114 dnl API info
2115 echo ""
2116 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2117 echo "        OpenVG:          $enable_openvg"
2118
2119 dnl Driver info
2120 echo ""
2121 case "x$enable_osmesa$enable_gallium_osmesa" in
2122 xnoyes)
2123         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2124         ;;
2125 xyesno)
2126         echo "        OSMesa:          lib$OSMESA_LIB"
2127         ;;
2128 xnono)
2129         echo "        OSMesa:          no"
2130         ;;
2131 esac
2132
2133 if test "x$enable_dri" != xno; then
2134         # cleanup the drivers var
2135         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2136         if test "x$DRI_DIRS" = x; then
2137             echo "        DRI drivers:     no"
2138         else
2139             echo "        DRI drivers:     $dri_dirs"
2140         fi
2141         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2142 fi
2143
2144 case "x$enable_glx$enable_xlib_glx" in
2145 xyesyes)
2146     echo "        GLX:             Xlib-based"
2147     ;;
2148 xyesno)
2149     echo "        GLX:             DRI-based"
2150     ;;
2151 *)
2152     echo "        GLX:             $enable_glx"
2153     ;;
2154 esac
2155
2156 dnl EGL
2157 echo ""
2158 echo "        EGL:             $enable_egl"
2159 if test "$enable_egl" = yes; then
2160     echo "        EGL platforms:   $egl_platforms"
2161
2162     egl_drivers=""
2163     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2164         egl_drivers="$egl_drivers builtin:egl_dri2"
2165     fi
2166
2167     if test "x$enable_gallium_egl" = xyes; then
2168         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2169         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2170     else
2171         echo "        EGL drivers:    $egl_drivers"
2172     fi
2173 fi
2174
2175 echo ""
2176 if test "x$MESA_LLVM" = x1; then
2177     echo "        llvm:            yes"
2178     echo "        llvm-config:     $LLVM_CONFIG"
2179     echo "        llvm-version:    $LLVM_VERSION"
2180 else
2181     echo "        llvm:            no"
2182 fi
2183
2184 echo ""
2185 if test -n "$with_gallium_drivers"; then
2186     echo "        Gallium:         yes"
2187     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2188     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2189     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2190     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2191 else
2192     echo "        Gallium:         no"
2193 fi
2194
2195
2196 dnl Libraries
2197 echo ""
2198 echo "        Shared libs:     $enable_shared"
2199 echo "        Static libs:     $enable_static"
2200 echo "        Shared-glapi:    $enable_shared_glapi"
2201
2202 dnl Compiler options
2203 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2204 cflags=`echo $CFLAGS | \
2205     $SED 's/^ *//;s/  */ /;s/ *$//'`
2206 cxxflags=`echo $CXXFLAGS | \
2207     $SED 's/^ *//;s/  */ /;s/ *$//'`
2208 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2209 echo ""
2210 echo "        CFLAGS:          $cflags"
2211 echo "        CXXFLAGS:        $cxxflags"
2212 echo "        Macros:          $defines"
2213 echo ""
2214 if test "x$MESA_LLVM" = x1; then
2215     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2216     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2217     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2218     echo ""
2219 fi
2220 echo "        PYTHON2:         $PYTHON2"
2221
2222 echo ""
2223 echo "        Run '${MAKE-make}' to build Mesa"
2224 echo ""