configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.2.0-devel],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  24     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  25
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27
  28 dnl Set internal versions
  29 OSMESA_VERSION=8
  30 AC_SUBST([OSMESA_VERSION])
  31
  32 dnl Versions for external dependencies
  33 LIBDRM_REQUIRED=2.4.24
  34 LIBDRM_RADEON_REQUIRED=2.4.46
  35 LIBDRM_INTEL_REQUIRED=2.4.38
  36 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  37 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  38 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AX_PROG_CC_FOR_BUILD
  48 AC_PROG_CXX
  49 AX_PROG_CXX_FOR_BUILD
  50 AM_PROG_CC_C_O
  51 AM_PROG_AS
  52 AC_CHECK_PROGS([MAKE], [gmake make])
  53 AC_CHECK_PROGS([PYTHON2], [python2 python])
  54 AX_PYTHON_MODULE([libxml2], [needed])
  55 AC_PROG_SED
  56 AC_PROG_MKDIR_P
  57
  58 LT_PREREQ([2.2])
  59 LT_INIT([disable-static])
  60
  61 AX_PROG_BISON([],
  62               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  63                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  64 AX_PROG_FLEX([],
  65              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  66                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  67
  68 AC_PATH_PROG([PERL], [perl])
  69
  70 AC_CHECK_PROG(INDENT, indent, indent, cat)
  71 if test "x$INDENT" != "xcat"; then
  72     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  73 fi
  74
  75 AC_PROG_INSTALL
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 GEN_ASM_OFFSETS=no
 104 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 105     AC_MSG_CHECKING([whether gcc version is sufficient])
 106     major=0
 107     minor=0
 108
 109     GCC_VERSION=`$CC -dumpversion`
 110     if test $? -eq 0; then
 111         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 112         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 113     fi
 114
 115     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 116         AC_MSG_RESULT([no])
 117         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 118     else
 119         AC_MSG_RESULT([yes])
 120     fi
 121
 122     if test "x$cross_compiling" = xyes; then
 123         GEN_ASM_OFFSETS=yes
 124     fi
 125 fi
 126 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 127
 128 dnl Make sure the pkg-config macros are defined
 129 m4_ifndef([PKG_PROG_PKG_CONFIG],
 130     [m4_fatal([Could not locate the pkg-config autoconf macros.
 131   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 132   are in a different location, try setting the environment variable
 133   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 134 PKG_PROG_PKG_CONFIG()
 135
 136 dnl LIB_DIR - library basename
 137 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 138 AC_SUBST([LIB_DIR])
 139
 140 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 141 _SAVE_LDFLAGS="$LDFLAGS"
 142 _SAVE_CPPFLAGS="$CPPFLAGS"
 143
 144 dnl build host compiler macros
 145 DEFINES_FOR_BUILD=""
 146 AC_SUBST([DEFINES_FOR_BUILD])
 147 case "$build_os" in
 148 linux*|*-gnu*|gnu*)
 149     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 150     ;;
 151 solaris*)
 152     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 153     ;;
 154 cygwin*)
 155     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 156     ;;
 157 esac
 158
 159 dnl Compiler macros
 160 DEFINES=""
 161 AC_SUBST([DEFINES])
 162 case "$host_os" in
 163 linux*|*-gnu*|gnu*)
 164     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 165     ;;
 166 solaris*)
 167     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 168     ;;
 169 cygwin*)
 170     DEFINES="$DEFINES -DHAVE_PTHREAD"
 171     ;;
 172 esac
 173
 174 dnl Add flags for gcc and g++
 175 if test "x$GCC" = xyes; then
 176     case "$host_os" in
 177     cygwin*)
 178         CFLAGS="$CFLAGS -Wall -std=gnu99"
 179         ;;
 180     *)
 181         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 182         CFLAGS="$CFLAGS -Wall -std=c99"
 183         ;;
 184     esac
 185
 186     # Enable -Werror=implicit-function-declaration and
 187     # -Werror=missing-prototypes, if available, or otherwise, just
 188     # -Wmissing-prototypes.  This is particularly useful to avoid
 189     # generating a loadable driver module that has undefined symbols.
 190     save_CFLAGS="$CFLAGS"
 191     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 192     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 193     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 194     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 195                    AC_MSG_RESULT([yes]),
 196                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 197                     AC_MSG_RESULT([no])]);
 198
 199     # Enable -fvisibility=hidden if using a gcc that supports it
 200     save_CFLAGS="$CFLAGS"
 201     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 202     VISIBILITY_CFLAGS="-fvisibility=hidden"
 203     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 204     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 205                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 206
 207     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 208     CFLAGS=$save_CFLAGS
 209
 210     # Work around aliasing bugs - developers should comment this out
 211     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 212     CFLAGS="$CFLAGS -fno-strict-aliasing"
 213
 214     # gcc's builtin memcmp is slower than glibc's
 215     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 216     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 217     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 218 fi
 219 if test "x$GXX" = xyes; then
 220     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 221     CXXFLAGS="$CXXFLAGS -Wall"
 222
 223     # Enable -fvisibility=hidden if using a gcc that supports it
 224     save_CXXFLAGS="$CXXFLAGS"
 225     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 226     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 227     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 228     AC_LANG_PUSH([C++])
 229     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 230                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 231     AC_LANG_POP([C++])
 232
 233     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 234     CXXFLAGS=$save_CXXFLAGS
 235
 236     # Work around aliasing bugs - developers should comment this out
 237     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 238     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 239
 240     # gcc's builtin memcmp is slower than glibc's
 241     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 242     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 243     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 244 fi
 245
 246 dnl even if the compiler appears to support it, using visibility attributes isn't
 247 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 248 case "$host_os" in
 249 cygwin*)
 250     VISIBILITY_CFLAGS=""
 251     VISIBILITY_CXXFLAGS=""
 252     ;;
 253 esac
 254
 255 AC_SUBST([VISIBILITY_CFLAGS])
 256 AC_SUBST([VISIBILITY_CXXFLAGS])
 257
 258 dnl
 259 dnl Hacks to enable 32 or 64 bit build
 260 dnl
 261 AC_ARG_ENABLE([32-bit],
 262     [AS_HELP_STRING([--enable-32-bit],
 263         [build 32-bit libraries @<:@default=auto@:>@])],
 264     [enable_32bit="$enableval"],
 265     [enable_32bit=auto]
 266 )
 267 if test "x$enable_32bit" = xyes; then
 268     if test "x$GCC" = xyes; then
 269         CFLAGS="$CFLAGS -m32"
 270         CCASFLAGS="$CCASFLAGS -m32"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m32"
 274     fi
 275 fi
 276 AC_ARG_ENABLE([64-bit],
 277     [AS_HELP_STRING([--enable-64-bit],
 278         [build 64-bit libraries @<:@default=auto@:>@])],
 279     [enable_64bit="$enableval"],
 280     [enable_64bit=auto]
 281 )
 282 if test "x$enable_64bit" = xyes; then
 283     if test "x$GCC" = xyes; then
 284         CFLAGS="$CFLAGS -m64"
 285     fi
 286     if test "x$GXX" = xyes; then
 287         CXXFLAGS="$CXXFLAGS -m64"
 288     fi
 289 fi
 290
 291 dnl Can't have static and shared libraries, default to static if user
 292 dnl explicitly requested. If both disabled, set to static since shared
 293 dnl was explicitly requested.
 294 case "x$enable_static$enable_shared" in
 295 xyesyes )
 296     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 297     enable_shared=no
 298     ;;
 299 xnono )
 300     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 301     enable_static=yes
 302     ;;
 303 esac
 304
 305 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 306
 307 dnl
 308 dnl other compiler options
 309 dnl
 310 AC_ARG_ENABLE([debug],
 311     [AS_HELP_STRING([--enable-debug],
 312         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 313     [enable_debug="$enableval"],
 314     [enable_debug=no]
 315 )
 316 if test "x$enable_debug" = xyes; then
 317     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 318     if test "x$GCC_FOR_BUILD" = xyes; then
 319         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 320     fi
 321     if test "x$GXX_FOR_BUILD" = xyes; then
 322         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 323     fi
 324
 325     DEFINES="$DEFINES -DDEBUG"
 326     if test "x$GCC" = xyes; then
 327         CFLAGS="$CFLAGS -g -O0"
 328     fi
 329     if test "x$GXX" = xyes; then
 330         CXXFLAGS="$CXXFLAGS -g -O0"
 331     fi
 332 fi
 333
 334 dnl
 335 dnl library names
 336 dnl
 337 LIB_PREFIX_GLOB='lib'
 338 LIB_VERSION_SEPARATOR='.'
 339 if test "$enable_static" = yes; then
 340     LIB_EXTENSION='a'
 341 else
 342     case "$host_os" in
 343     darwin* )
 344         LIB_EXTENSION='dylib' ;;
 345     cygwin* )
 346         dnl prefix can be 'cyg' or 'lib'
 347         LIB_PREFIX_GLOB='???'
 348         LIB_VERSION_SEPARATOR='-'
 349         LIB_EXTENSION='dll' ;;
 350     aix* )
 351         LIB_EXTENSION='a' ;;
 352     * )
 353         LIB_EXTENSION='so' ;;
 354     esac
 355 fi
 356 AC_ARG_WITH([gl-lib-name],
 357   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 358     [specify GL library name @<:@default=GL@:>@])],
 359   [GL_LIB=$withval],
 360   [GL_LIB=GL])
 361 AC_ARG_WITH([osmesa-lib-name],
 362   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 363     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 364   [OSMESA_LIB=$withval],
 365   [OSMESA_LIB=OSMesa])
 366 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 367 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 368
 369 dnl
 370 dnl Mangled Mesa support
 371 dnl
 372 AC_ARG_ENABLE([mangling],
 373   [AS_HELP_STRING([--enable-mangling],
 374     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 375   [enable_mangling="${enableval}"],
 376   [enable_mangling=no]
 377 )
 378 if test "x${enable_mangling}" = "xyes" ; then
 379   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 380   GL_LIB="Mangled${GL_LIB}"
 381   OSMESA_LIB="Mangled${OSMESA_LIB}"
 382 fi
 383 AC_SUBST([GL_LIB])
 384 AC_SUBST([OSMESA_LIB])
 385
 386 dnl
 387 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 388 dnl
 389 AC_ARG_ENABLE([texture-float],
 390     [AS_HELP_STRING([--enable-texture-float],
 391         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 392     [enable_texture_float="$enableval"],
 393     [enable_texture_float=no]
 394 )
 395 if test "x$enable_texture_float" = xyes; then
 396     AC_MSG_WARN([Floating-point textures enabled.])
 397     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 398     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 399 fi
 400
 401 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 402 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 403 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 404 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 405 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 406 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 407 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 408
 409 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 411 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 412 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 413 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 414 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 415 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 416
 417 AC_SUBST([GL_LIB_NAME])
 418 AC_SUBST([OSMESA_LIB_NAME])
 419 AC_SUBST([EGL_LIB_NAME])
 420 AC_SUBST([GLESv1_CM_LIB_NAME])
 421 AC_SUBST([GLESv2_LIB_NAME])
 422 AC_SUBST([VG_LIB_NAME])
 423 AC_SUBST([GLAPI_LIB_NAME])
 424
 425 AC_SUBST([GL_LIB_GLOB])
 426 AC_SUBST([EGL_LIB_GLOB])
 427 AC_SUBST([GLESv1_CM_LIB_GLOB])
 428 AC_SUBST([GLESv2_LIB_GLOB])
 429 AC_SUBST([VG_LIB_GLOB])
 430 AC_SUBST([GLAPI_LIB_GLOB])
 431
 432 dnl
 433 dnl Arch/platform-specific settings
 434 dnl
 435 AC_ARG_ENABLE([asm],
 436     [AS_HELP_STRING([--disable-asm],
 437         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 438     [enable_asm="$enableval"],
 439     [enable_asm=yes]
 440 )
 441 asm_arch=""
 442 AC_MSG_CHECKING([whether to enable assembly])
 443 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 444 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 445 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 446     case "$host_cpu" in
 447     i?86 | x86_64 | amd64)
 448         enable_asm=no
 449         AC_MSG_RESULT([no, cross compiling])
 450         ;;
 451     esac
 452 fi
 453 # check for supported arches
 454 if test "x$enable_asm" = xyes; then
 455     case "$host_cpu" in
 456     i?86)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 459             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 460             ;;
 461         gnu*)
 462             asm_arch=x86
 463             ;;
 464         esac
 465         ;;
 466     x86_64|amd64)
 467         case "$host_os" in
 468         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 469             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 470             ;;
 471         esac
 472         ;;
 473     sparc*)
 474         case "$host_os" in
 475         linux*)
 476             asm_arch=sparc
 477             ;;
 478         esac
 479         ;;
 480     esac
 481
 482     case "$asm_arch" in
 483     x86)
 484         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 485         AC_MSG_RESULT([yes, x86])
 486         ;;
 487     x86_64|amd64)
 488         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 489         AC_MSG_RESULT([yes, x86_64])
 490         ;;
 491     sparc)
 492         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 493         AC_MSG_RESULT([yes, sparc])
 494         ;;
 495     *)
 496         AC_MSG_RESULT([no, platform not supported])
 497         ;;
 498     esac
 499 fi
 500
 501 dnl Check to see if dlopen is in default libraries (like Solaris, which
 502 dnl has it in libc), or if libdl is needed to get it.
 503 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 504     [AC_CHECK_LIB([dl], [dlopen],
 505        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 506 AC_SUBST([DLOPEN_LIBS])
 507
 508 case "$host_os" in
 509 darwin*|mingw*)
 510     ;;
 511 *)
 512     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 513                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 514                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 515     AC_SUBST([CLOCK_LIB])
 516     ;;
 517 esac
 518
 519 dnl See if posix_memalign is available
 520 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 521
 522 dnl Check for pthreads
 523 AX_PTHREAD
 524 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 525 dnl to -pthread, which causes problems if we need -lpthread to appear in
 526 dnl pkgconfig files.
 527 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 528
 529 dnl SELinux awareness.
 530 AC_ARG_ENABLE([selinux],
 531     [AS_HELP_STRING([--enable-selinux],
 532         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 533     [MESA_SELINUX="$enableval"],
 534     [MESA_SELINUX=no])
 535 if test "x$enable_selinux" = "xyes"; then
 536     AC_CHECK_HEADER([selinux/selinux.h],[],
 537                     [AC_MSG_ERROR([SELinux headers not found])])
 538     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 539                  [AC_MSG_ERROR([SELinux library not found])])
 540     SELINUX_LIBS="-lselinux"
 541     DEFINES="$DEFINES -DMESA_SELINUX"
 542 fi
 543 AC_SUBST([SELINUX_LIBS])
 544
 545 dnl Options for APIs
 546 AC_ARG_ENABLE([opengl],
 547     [AS_HELP_STRING([--disable-opengl],
 548         [disable support for standard OpenGL API @<:@default=no@:>@])],
 549     [enable_opengl="$enableval"],
 550     [enable_opengl=yes])
 551 AC_ARG_ENABLE([gles1],
 552     [AS_HELP_STRING([--enable-gles1],
 553         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 554     [enable_gles1="$enableval"],
 555     [enable_gles1=no])
 556 AC_ARG_ENABLE([gles2],
 557     [AS_HELP_STRING([--enable-gles2],
 558         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 559     [enable_gles2="$enableval"],
 560     [enable_gles2=no])
 561 AC_ARG_ENABLE([openvg],
 562     [AS_HELP_STRING([--enable-openvg],
 563         [enable support for OpenVG API @<:@default=no@:>@])],
 564     [enable_openvg="$enableval"],
 565     [enable_openvg=no])
 566
 567 AC_ARG_ENABLE([dri],
 568     [AS_HELP_STRING([--enable-dri],
 569         [enable DRI modules @<:@default=enabled@:>@])],
 570     [enable_dri="$enableval"],
 571     [enable_dri=yes])
 572 AC_ARG_ENABLE([glx],
 573     [AS_HELP_STRING([--enable-glx],
 574         [enable GLX library @<:@default=enabled@:>@])],
 575     [enable_glx="$enableval"],
 576     [enable_glx=yes])
 577 AC_ARG_ENABLE([osmesa],
 578     [AS_HELP_STRING([--enable-osmesa],
 579         [enable OSMesa library @<:@default=disabled@:>@])],
 580     [enable_osmesa="$enableval"],
 581     [enable_osmesa=no])
 582 AC_ARG_ENABLE([egl],
 583     [AS_HELP_STRING([--disable-egl],
 584         [disable EGL library @<:@default=enabled@:>@])],
 585     [enable_egl="$enableval"],
 586     [enable_egl=yes])
 587
 588 AC_ARG_ENABLE([xorg],
 589     [AS_HELP_STRING([--enable-xorg],
 590         [enable support for X.Org DDX API @<:@default=no@:>@])],
 591     [enable_xorg="$enableval"],
 592     [enable_xorg=no])
 593 AC_ARG_ENABLE([xa],
 594     [AS_HELP_STRING([--enable-xa],
 595         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 596     [enable_xa="$enableval"],
 597     [enable_xa=no])
 598 AC_ARG_ENABLE([gbm],
 599    [AS_HELP_STRING([--enable-gbm],
 600          [enable gbm library @<:@default=auto@:>@])],
 601    [enable_gbm="$enableval"],
 602    [enable_gbm=auto])
 603
 604 AC_ARG_ENABLE([xvmc],
 605    [AS_HELP_STRING([--enable-xvmc],
 606          [enable xvmc library @<:@default=auto@:>@])],
 607    [enable_xvmc="$enableval"],
 608    [enable_xvmc=auto])
 609 AC_ARG_ENABLE([vdpau],
 610    [AS_HELP_STRING([--enable-vdpau],
 611          [enable vdpau library @<:@default=auto@:>@])],
 612    [enable_vdpau="$enableval"],
 613    [enable_vdpau=auto])
 614 AC_ARG_ENABLE([opencl],
 615    [AS_HELP_STRING([--enable-opencl],
 616          [enable OpenCL library NOTE: Enabling this option will also enable
 617           --with-llvm-shared-libs
 618           @<:@default=no@:>@])],
 619    [],
 620    [enable_opencl=no])
 621 AC_ARG_ENABLE([xlib_glx],
 622     [AS_HELP_STRING([--enable-xlib-glx],
 623         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 624     [enable_xlib_glx="$enableval"],
 625     [enable_xlib_glx=no])
 626 AC_ARG_ENABLE([gallium_egl],
 627     [AS_HELP_STRING([--enable-gallium-egl],
 628         [enable optional EGL state tracker (not required
 629          for EGL support in Gallium with OpenGL and OpenGL ES)
 630          @<:@default=disable@:>@])],
 631     [enable_gallium_egl="$enableval"],
 632     [enable_gallium_egl=no])
 633 AC_ARG_ENABLE([gallium_gbm],
 634     [AS_HELP_STRING([--enable-gallium-gbm],
 635         [enable optional gbm state tracker (not required for
 636          gbm support in Gallium)
 637          @<:@default=auto@:>@])],
 638     [enable_gallium_gbm="$enableval"],
 639     [enable_gallium_gbm=auto])
 640
 641 AC_ARG_ENABLE([r600-llvm-compiler],
 642     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 643         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 644     [enable_r600_llvm="$enableval"],
 645     [enable_r600_llvm=no])
 646
 647 AC_ARG_ENABLE([gallium_tests],
 648     [AS_HELP_STRING([--enable-gallium-tests],
 649         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 650     [enable_gallium_tests="$enableval"],
 651     [enable_gallium_tests=no])
 652
 653 # Option for Gallium drivers
 654
 655 # Keep this in sync with the --with-gallium-drivers help string default value
 656 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 657
 658 AC_ARG_WITH([gallium-drivers],
 659     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 660         [comma delimited Gallium drivers list, e.g.
 661         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 662         @<:@default=r300,r600,svga,swrast@:>@])],
 663     [with_gallium_drivers="$withval"],
 664     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 665
 666 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 667 # here so that the script doesn't choke on an unknown driver name later.
 668 case "$with_gallium_drivers" in
 669     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 670     no) with_gallium_drivers='' ;;
 671 esac
 672
 673 if test "x$enable_opengl" = xno -a \
 674         "x$enable_gles1" = xno -a \
 675         "x$enable_gles2" = xno -a \
 676         "x$enable_openvg" = xno -a \
 677         "x$enable_xorg" = xno -a \
 678         "x$enable_xa" = xno -a \
 679         "x$enable_xvmc" = xno -a \
 680         "x$enable_vdpau" = xno -a \
 681         "x$enable_opencl" = xno; then
 682     AC_MSG_ERROR([at least one API should be enabled])
 683 fi
 684
 685 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 686 if test "x$enable_opengl" = xno -a \
 687         "x$enable_gles1" = xyes; then
 688     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 689 fi
 690
 691 if test "x$enable_opengl" = xno -a \
 692         "x$enable_gles2" = xyes; then
 693     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 694 fi
 695
 696 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 697 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 698 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 699 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 700                                         "x$enable_gles1" = xyes -o \
 701                                         "x$enable_gles2" = xyes)
 702
 703 if test "x$enable_glx" = xno; then
 704     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 705     enable_xlib_glx=no
 706 fi
 707
 708 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 709     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 710 fi
 711
 712 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 713     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 714 fi
 715
 716 # Disable GLX if OpenGL is not enabled
 717 if test "x$enable_glx$enable_opengl" = xyesno; then
 718     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 719     enable_glx=no
 720 fi
 721
 722 # Disable GLX if DRI and Xlib-GLX are not enabled
 723 if test "x$enable_glx" = xyes -a \
 724         "x$enable_dri" = xno -a \
 725         "x$enable_xlib_glx" = xno; then
 726     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 727     enable_glx=no
 728 fi
 729
 730 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 731                                   "x$enable_dri" = xyes)
 732 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 733 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 734                                   "x$enable_osmesa" = xyes)
 735
 736 AC_ARG_ENABLE([shared-glapi],
 737     [AS_HELP_STRING([--enable-shared-glapi],
 738         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 739     [enable_shared_glapi="$enableval"],
 740     [enable_shared_glapi="$enable_dri"])
 741
 742 # Shared GLAPI is only useful for DRI
 743 if test "x$enable_dri" = xno; then
 744     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 745     enable_shared_glapi=no
 746 fi
 747
 748 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 749
 750 dnl
 751 dnl Driver specific build directories
 752 dnl
 753 GALLIUM_TARGET_DIRS=""
 754 GALLIUM_WINSYS_DIRS="sw"
 755 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 756 GALLIUM_STATE_TRACKERS_DIRS=""
 757
 758 case "x$enable_glx$enable_xlib_glx" in
 759 xyesyes)
 760     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 761     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 762     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 763     NEED_WINSYS_XLIB="yes"
 764     ;;
 765 esac
 766
 767 if test "x$enable_dri" = xyes; then
 768     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 769     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 770 fi
 771
 772 if test "x$enable_osmesa" = xyes; then
 773     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 774     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 775 fi
 776
 777 AC_SUBST([MESA_LLVM])
 778
 779 # Check for libdrm
 780 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 781                   [have_libdrm=yes], [have_libdrm=no])
 782
 783 if test "x$enable_dri" = xyes; then
 784     # DRI must be shared, I think
 785     if test "$enable_static" = yes; then
 786         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 787     fi
 788
 789     # not a hard requirement as swrast does not depend on it
 790     if test "x$have_libdrm" = xyes; then
 791         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 792     fi
 793 fi
 794
 795 dnl Direct rendering or just indirect rendering
 796 case "$host_os" in
 797 gnu*)
 798     dnl Disable by default on GNU/Hurd
 799     driglx_direct_default="no"
 800     ;;
 801 cygwin*)
 802     dnl Disable by default on cygwin
 803     driglx_direct_default="no"
 804     ;;
 805 *)
 806     driglx_direct_default="yes"
 807     ;;
 808 esac
 809 AC_ARG_ENABLE([driglx-direct],
 810     [AS_HELP_STRING([--disable-driglx-direct],
 811         [disable direct rendering in GLX and EGL for DRI \
 812             @<:@default=auto@:>@])],
 813     [driglx_direct="$enableval"],
 814     [driglx_direct="$driglx_direct_default"])
 815
 816 dnl
 817 dnl libGL configuration per driver
 818 dnl
 819 case "x$enable_glx$enable_xlib_glx" in
 820 xyesyes)
 821     # Xlib-based GLX
 822     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 823     GL_PC_REQ_PRIV="x11 xext"
 824     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 825     GL_LIB_DEPS="$XLIBGL_LIBS"
 826     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 827     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 828     ;;
 829 xyesno)
 830     # DRI-based GLX
 831     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 832     if test x"$driglx_direct" = xyes; then
 833         if test "x$have_libdrm" != xyes; then
 834             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 835         fi
 836         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 837         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 838     fi
 839
 840     # find the DRI deps for libGL
 841     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 842
 843     # add xf86vidmode if available
 844     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 845     if test "$HAVE_XF86VIDMODE" = yes ; then
 846         dri_modules="$dri_modules xxf86vm"
 847     fi
 848
 849     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 850     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 851     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 852     GL_LIB_DEPS="$DRIGL_LIBS"
 853
 854     # need DRM libs, $PTHREAD_LIBS, etc.
 855     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 856     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 857     ;;
 858 esac
 859
 860 # This is outside the case (above) so that it is invoked even for non-GLX
 861 # builds.
 862 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 863
 864 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 865 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 866 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 868
 869 AC_SUBST([X11_INCLUDES])
 870 AC_SUBST([GL_LIB_DEPS])
 871 AC_SUBST([GL_PC_REQ_PRIV])
 872 AC_SUBST([GL_PC_LIB_PRIV])
 873 AC_SUBST([GL_PC_CFLAGS])
 874 AC_SUBST([DRI_PC_REQ_PRIV])
 875 AC_SUBST([GLESv1_CM_LIB_DEPS])
 876 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 877 AC_SUBST([GLESv2_LIB_DEPS])
 878 AC_SUBST([GLESv2_PC_LIB_PRIV])
 879
 880 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 881
 882 AC_SUBST([HAVE_XF86VIDMODE])
 883
 884 dnl
 885 dnl More GLX setup
 886 dnl
 887 case "x$enable_glx$enable_xlib_glx" in
 888 xyesyes)
 889     DEFINES="$DEFINES -DUSE_XSHM"
 890     ;;
 891 xyesno)
 892     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 893     if test "x$driglx_direct" = xyes; then
 894         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 895     fi
 896     ;;
 897 esac
 898
 899 dnl
 900 dnl TLS detection
 901 dnl
 902
 903 AC_ARG_ENABLE([glx-tls],
 904     [AS_HELP_STRING([--enable-glx-tls],
 905         [enable TLS support in GLX @<:@default=disabled@:>@])],
 906     [GLX_USE_TLS="$enableval"],
 907     [GLX_USE_TLS=no])
 908 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 909
 910 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 911       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 912
 913 dnl
 914 dnl More DRI setup
 915 dnl
 916 dnl Directory for DRI drivers
 917 AC_ARG_WITH([dri-driverdir],
 918     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 919         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 920     [DRI_DRIVER_INSTALL_DIR="$withval"],
 921     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 922 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 923 dnl Extra search path for DRI drivers
 924 AC_ARG_WITH([dri-searchpath],
 925     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 926         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 927     [DRI_DRIVER_SEARCH_DIR="$withval"],
 928     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 929 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 930 dnl Which drivers to build - default is chosen by platform
 931 AC_ARG_WITH([dri-drivers],
 932     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 933         [comma delimited DRI drivers list, e.g.
 934         "swrast,i965,radeon" @<:@default=auto@:>@])],
 935     [with_dri_drivers="$withval"],
 936     [with_dri_drivers=yes])
 937 if test "x$with_dri_drivers" = x; then
 938     with_dri_drivers=no
 939 fi
 940
 941 dnl If $with_dri_drivers is yes, directories will be added through
 942 dnl platform checks
 943 DRI_DIRS=""
 944 case "$with_dri_drivers" in
 945 no) ;;
 946 yes)
 947     # classic DRI drivers
 948     if test "x$enable_opengl" = xyes; then
 949         DRI_DIRS="yes"
 950     fi
 951     ;;
 952 *)
 953     # verify the requested driver directories exist
 954     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 955     for driver in $dri_drivers; do
 956         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 957             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 958     done
 959     DRI_DIRS="$dri_drivers"
 960     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 961         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 962     fi
 963     ;;
 964 esac
 965
 966 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 967 if test "x$enable_dri" = xyes; then
 968     # Platform specific settings and drivers to build
 969     case "$host_os" in
 970     linux*)
 971         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 972         DEFINES="$DEFINES -DHAVE_ALIAS"
 973
 974         case "$host_cpu" in
 975         x86_64|amd64)
 976             if test "x$DRI_DIRS" = "xyes"; then
 977                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 978             fi
 979             ;;
 980         powerpc*)
 981             # Build only the drivers for cards that exist on PowerPC.
 982             if test "x$DRI_DIRS" = "xyes"; then
 983                 DRI_DIRS="r200 radeon swrast"
 984             fi
 985             ;;
 986         sparc*)
 987             # Build only the drivers for cards that exist on sparc
 988             if test "x$DRI_DIRS" = "xyes"; then
 989                 DRI_DIRS="r200 radeon swrast"
 990             fi
 991             ;;
 992         esac
 993         ;;
 994     freebsd* | dragonfly* | *netbsd* | openbsd*)
 995         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 996         DEFINES="$DEFINES -DHAVE_ALIAS"
 997
 998         if test "x$DRI_DIRS" = "xyes"; then
 999             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1000         fi
1001         ;;
1002     gnu*)
1003         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1004         DEFINES="$DEFINES -DHAVE_ALIAS"
1005         ;;
1006     solaris*)
1007         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1008         ;;
1009     cygwin*)
1010         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1011         if test "x$DRI_DIRS" = "xyes"; then
1012             DRI_DIRS="swrast"
1013         fi
1014         ;;
1015     esac
1016
1017     # default drivers
1018     if test "x$DRI_DIRS" = "xyes"; then
1019         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1020     fi
1021
1022     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1023
1024     # Check for expat
1025     EXPAT_INCLUDES=""
1026     EXPAT_LIB=-lexpat
1027     AC_ARG_WITH([expat],
1028         [AS_HELP_STRING([--with-expat=DIR],
1029             [expat install directory])],[
1030         EXPAT_INCLUDES="-I$withval/include"
1031         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1032         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1033         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1034         ])
1035     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1036     save_LIBS="$LIBS"
1037     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1038         [AC_MSG_ERROR([Expat required for DRI.])])
1039     LIBS="$save_LIBS"
1040
1041     # If we are building any DRI driver other than swrast.
1042     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1043         # ... libdrm is required
1044         if test "x$have_libdrm" != xyes; then
1045             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1046         fi
1047         # ... and build dricommon
1048         HAVE_COMMON_DRI=yes
1049     fi
1050
1051     # put all the necessary libs together
1052     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1053     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1054 fi
1055 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1056 AC_SUBST([EXPAT_INCLUDES])
1057 AC_SUBST([DRI_LIB_DEPS])
1058 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1059
1060 case $DRI_DIRS in
1061 *i915*|*i965*)
1062     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1063
1064     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1065         case $d in
1066         i915)
1067             HAVE_I915_DRI=yes;
1068             ;;
1069         i965)
1070             HAVE_I965_DRI=yes;
1071             ;;
1072         esac
1073     done
1074
1075     ;;
1076 esac
1077
1078 case $DRI_DIRS in
1079 *nouveau*)
1080     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1081     HAVE_NOUVEAU_DRI=yes;
1082     ;;
1083 esac
1084
1085 case $DRI_DIRS in
1086 *radeon*|*r200*)
1087     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1088
1089     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1090         case $d in
1091         radeon)
1092             HAVE_RADEON_DRI=yes;
1093             ;;
1094         r200)
1095             HAVE_R200_DRI=yes;
1096             ;;
1097         esac
1098     done
1099
1100     ;;
1101 esac
1102
1103 case $DRI_DIRS in
1104 *swrast*)
1105     HAVE_SWRAST_DRI=yes;
1106     ;;
1107 esac
1108
1109 dnl
1110 dnl OSMesa configuration
1111 dnl
1112
1113 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1114 AC_ARG_WITH([osmesa-bits],
1115     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1116         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1117     [osmesa_bits="$withval"],
1118     [osmesa_bits=8])
1119 if test "x$osmesa_bits" != x8; then
1120     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1121         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1122         osmesa_bits=8
1123     fi
1124 fi
1125 case "x$osmesa_bits" in
1126 x8)
1127     OSMESA_LIB="${OSMESA_LIB}"
1128     ;;
1129 x16|x32)
1130     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1131     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1132     ;;
1133 *)
1134     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1135     ;;
1136 esac
1137
1138 if test "x$enable_osmesa" = xyes; then
1139     # only link libraries with osmesa if shared
1140     if test "$enable_static" = no; then
1141         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1142     else
1143         OSMESA_LIB_DEPS=""
1144     fi
1145     OSMESA_MESA_DEPS=""
1146     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1147 fi
1148
1149 AC_SUBST([OSMESA_LIB_DEPS])
1150 AC_SUBST([OSMESA_MESA_DEPS])
1151 AC_SUBST([OSMESA_PC_REQ])
1152 AC_SUBST([OSMESA_PC_LIB_PRIV])
1153
1154 dnl
1155 dnl gbm configuration
1156 dnl
1157 if test "x$enable_gbm" = xauto; then
1158     case "$with_egl_platforms" in
1159         *drm*)
1160             enable_gbm=yes ;;
1161          *)
1162             enable_gbm=no ;;
1163     esac
1164 fi
1165 if test "x$enable_gbm" = xyes; then
1166     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1167                       AC_MSG_ERROR([gbm needs udev]))
1168
1169     if test "x$enable_dri" = xyes; then
1170         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1171         if test "x$enable_shared_glapi" = xno; then
1172             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1173         fi
1174     fi
1175 fi
1176 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1177 GBM_PC_REQ_PRIV="libudev"
1178 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1179 AC_SUBST([GBM_PC_REQ_PRIV])
1180 AC_SUBST([GBM_PC_LIB_PRIV])
1181
1182 dnl
1183 dnl EGL configuration
1184 dnl
1185 EGL_CLIENT_APIS=""
1186
1187 if test "x$enable_egl" = xyes; then
1188     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1189
1190     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1191
1192     if test "$enable_static" != yes; then
1193         # build egl_glx when libGL is built
1194         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1195                           [have_libudev=yes],[have_libudev=no])
1196         if test "$have_libudev" = yes; then
1197             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1198         fi
1199
1200         if test "x$enable_dri" = xyes; then
1201             HAVE_EGL_DRIVER_DRI2=1
1202         fi
1203
1204     fi
1205 fi
1206 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1207 AC_SUBST([EGL_LIB_DEPS])
1208
1209 dnl
1210 dnl EGL Gallium configuration
1211 dnl
1212 if test "x$enable_gallium_egl" = xyes; then
1213     if test "x$with_gallium_drivers" = x; then
1214         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1215     fi
1216     if test "x$enable_egl" = xno; then
1217         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1218     fi
1219     if test "x$have_libdrm" != xyes; then
1220         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1221     fi
1222
1223     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1224     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1225 fi
1226 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1227
1228 dnl
1229 dnl gbm Gallium configuration
1230 dnl
1231 if test "x$enable_gallium_gbm" = xauto; then
1232     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1233         yesyesyes*drm*)
1234             enable_gallium_gbm=yes ;;
1235          *)
1236             enable_gallium_gbm=no ;;
1237     esac
1238 fi
1239 if test "x$enable_gallium_gbm" = xyes; then
1240     if test "x$with_gallium_drivers" = x; then
1241         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1242     fi
1243     if test "x$enable_gbm" = xno; then
1244         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1245     fi
1246     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1247     if test "x$enable_dri" = xno; then
1248         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1249     fi
1250
1251     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1252     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1253     enable_gallium_loader=yes
1254 fi
1255 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1256
1257 dnl
1258 dnl X.Org DDX configuration
1259 dnl
1260 if test "x$enable_xorg" = xyes; then
1261     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1262     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1263     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1264     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1265         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1266         HAVE_XEXTPROTO_71="no")
1267     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1268 fi
1269 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1270
1271 dnl
1272 dnl XA configuration
1273 dnl
1274 if test "x$enable_xa" = xyes; then
1275 AC_PROG_AWK
1276 AC_PROG_GREP
1277 AC_CHECK_PROG(NM, nm, "nm")
1278 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1279 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1280 enable_xa=no
1281 fi
1282 fi
1283 if test "x$enable_xa" = xyes; then
1284     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1285     AC_SUBST(AWK)
1286     AC_SUBST(GREP)
1287     AC_SUBST(NM)
1288 fi
1289 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1290
1291 dnl
1292 dnl OpenVG configuration
1293 dnl
1294 VG_LIB_DEPS=""
1295
1296 if test "x$enable_openvg" = xyes; then
1297     if test "x$enable_egl" = xno; then
1298         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1299     fi
1300     if test "x$with_gallium_drivers" = x; then
1301         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1302     fi
1303     if test "x$enable_gallium_egl" = xno; then
1304         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1305     fi
1306
1307     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1308     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1309     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1310     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1311     AC_SUBST([VG_PC_LIB_PRIV])
1312 fi
1313 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1314
1315 dnl
1316 dnl Gallium G3DVL configuration
1317 dnl
1318 if test -n "$with_gallium_drivers"; then
1319     if test "x$enable_xvmc" = xauto; then
1320         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1321     fi
1322
1323     if test "x$enable_vdpau" = xauto; then
1324         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1325     fi
1326 fi
1327
1328 if test "x$enable_xvmc" = xyes; then
1329     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1330     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1331 fi
1332 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1333
1334 if test "x$enable_vdpau" = xyes; then
1335     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1336     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1337 fi
1338 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1339
1340 dnl
1341 dnl OpenCL configuration
1342 dnl
1343
1344 AC_ARG_WITH([libclc-path],
1345    [AS_HELP_STRING([--with-libclc-path],
1346          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1347    [LIBCLC_PATH="$withval"],
1348    [LIBCLC_PATH=""])
1349
1350 if test "x$LIBCLC_PATH" != x; then
1351    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1352                   Please review the updated build instructions for clover:
1353                   http://dri.freedesktop.org/wiki/GalliumCompute])
1354 fi
1355
1356
1357 AC_ARG_WITH([clang-libdir],
1358    [AS_HELP_STRING([--with-clang-libdir],
1359          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1360    [CLANG_LIBDIR="$withval"],
1361    [CLANG_LIBDIR=""])
1362
1363 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1364 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1365 AC_SUBST([LIBCLC_INCLUDEDIR])
1366 AC_SUBST([LIBCLC_LIBEXECDIR])
1367
1368 if test "x$enable_opencl" = xyes; then
1369     if test "x$with_gallium_drivers" = x; then
1370         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1371     fi
1372
1373     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1374         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1375     fi
1376
1377     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1378         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1379     fi
1380
1381     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1382     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1383     enable_gallium_loader=yes
1384 fi
1385 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1386
1387 dnl
1388 dnl Gallium configuration
1389 dnl
1390 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1391
1392 AC_SUBST([LLVM_BINDIR])
1393 AC_SUBST([LLVM_CFLAGS])
1394 AC_SUBST([LLVM_CPPFLAGS])
1395 AC_SUBST([LLVM_CXXFLAGS])
1396 AC_SUBST([LLVM_LIBDIR])
1397 AC_SUBST([LLVM_LIBS])
1398 AC_SUBST([LLVM_LDFLAGS])
1399 AC_SUBST([LLVM_INCLUDEDIR])
1400 AC_SUBST([LLVM_VERSION])
1401 AC_SUBST([CLANG_RESOURCE_DIR])
1402
1403 case "x$enable_opengl$enable_gles1$enable_gles2" in
1404 x*yes*)
1405     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1406     ;;
1407 esac
1408
1409 AC_SUBST([VG_LIB_DEPS])
1410 AC_SUBST([EGL_CLIENT_APIS])
1411
1412 dnl
1413 dnl EGL Platforms configuration
1414 dnl
1415 AC_ARG_WITH([egl-platforms],
1416     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1417         [comma delimited native platforms libEGL supports, e.g.
1418         "x11,drm" @<:@default=auto@:>@])],
1419     [with_egl_platforms="$withval"],
1420     [if test "x$enable_egl" = xyes; then
1421         with_egl_platforms="x11"
1422     else
1423         with_egl_platforms=""
1424     fi])
1425
1426 EGL_PLATFORMS=""
1427
1428 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1429     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1430 fi
1431
1432 # Do per-EGL platform setups and checks
1433 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1434 for plat in $egl_platforms; do
1435         case "$plat" in
1436         wayland)
1437                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1438                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1439
1440                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1441                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1442                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1443                 ;;
1444
1445         x11)
1446                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1447
1448                 if test "x$enable_glx" = xyes; then
1449                         HAVE_EGL_DRIVER_GLX=1
1450                 fi
1451                 ;;
1452
1453         drm)
1454                 test "x$enable_gbm" = "xno" &&
1455                         AC_MSG_ERROR([EGL platform drm needs gbm])
1456                 ;;
1457
1458         android|fbdev|gdi|null)
1459                 ;;
1460
1461         *)
1462                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1463                 ;;
1464         esac
1465
1466         case "$plat$have_libudev" in
1467                 waylandno|drmno)
1468                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1469         esac
1470 done
1471
1472 # libEGL wants to default to the first platform specified in
1473 # ./configure.  parse that here.
1474 if test "x$egl_platforms" != "x"; then
1475     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1476     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1477 else
1478     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1479 fi
1480
1481 EGL_PLATFORMS="$egl_platforms"
1482
1483 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1484     NEED_WINSYS_XLIB=yes
1485 fi
1486 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1487 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1488 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1489 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1490 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1491
1492 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1493 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1494
1495 AC_SUBST([EGL_NATIVE_PLATFORM])
1496 AC_SUBST([EGL_PLATFORMS])
1497 AC_SUBST([EGL_CFLAGS])
1498
1499 # If we don't have the X11 platform, set this define so we don't try to include
1500 # the X11 headers.
1501 if ! echo "$egl_platforms" | grep -q 'x11'; then
1502     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1503     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1504 fi
1505
1506 AC_ARG_WITH([egl-driver-dir],
1507     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1508                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1509     [EGL_DRIVER_INSTALL_DIR="$withval"],
1510     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1511 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1512
1513 AC_ARG_WITH([xorg-driver-dir],
1514     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1515                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1516     [XORG_DRIVER_INSTALL_DIR="$withval"],
1517     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1518 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1519
1520 AC_ARG_WITH([max-width],
1521     [AS_HELP_STRING([--with-max-width=N],
1522                     [Maximum framebuffer width (4096)])],
1523     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1524      AS_IF([test "${withval}" -gt "4096"],
1525            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1526 )
1527 AC_ARG_WITH([max-height],
1528     [AS_HELP_STRING([--with-max-height=N],
1529                     [Maximum framebuffer height (4096)])],
1530     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1531      AS_IF([test "${withval}" -gt "4096"],
1532            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1533 )
1534
1535 dnl
1536 dnl Gallium LLVM
1537 dnl
1538 AC_ARG_ENABLE([gallium-llvm],
1539     [AS_HELP_STRING([--enable-gallium-llvm],
1540         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1541     [enable_gallium_llvm="$enableval"],
1542     [enable_gallium_llvm=auto])
1543
1544 AC_ARG_WITH([llvm-shared-libs],
1545     [AS_HELP_STRING([--with-llvm-shared-libs],
1546         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1547     [],
1548     [with_llvm_shared_libs=no])
1549 AS_IF([test x$enable_opencl = xyes],
1550     [
1551         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1552         with_llvm_shared_libs=yes
1553     ])
1554
1555 AC_ARG_WITH([llvm-prefix],
1556     [AS_HELP_STRING([--with-llvm-prefix],
1557         [Prefix for LLVM installations in non-standard locations])],
1558     [llvm_prefix="$withval"],
1559     [llvm_prefix=""])
1560
1561
1562 # Call this inside ` ` to get the return value.
1563 # $1 is the llvm-config command with arguments.
1564 strip_unwanted_llvm_flags() {
1565     # Use \> (marks the end of the word)
1566     echo `$1` | sed \
1567         -e 's/-DNDEBUG\>//g' \
1568         -e 's/-pedantic\>//g' \
1569         -e 's/-Wcovered-switch-default\>//g' \
1570         -e 's/-O.\>//g' \
1571         -e 's/-g\>//g' \
1572         -e 's/-Wall\>//g' \
1573         -e 's/-fomit-frame-pointer\>//g'
1574 }
1575
1576
1577 if test "x$with_gallium_drivers" = x; then
1578     enable_gallium_llvm=no
1579 fi
1580 if test "x$enable_gallium_llvm" = xauto; then
1581     case "$host_cpu" in
1582     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1583     esac
1584 fi
1585 if test "x$enable_gallium_llvm" = xyes; then
1586     if test "x$llvm_prefix" != x; then
1587         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1588     else
1589         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1590     fi
1591
1592     if test "x$LLVM_CONFIG" != xno; then
1593         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1594         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1595         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1596         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1597         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1598         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1599         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1600         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1601
1602         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1603             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1604         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1605             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1606
1607         if test "x${LLVM_VERSION_MAJOR}" != x; then
1608             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1609         else
1610             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1611         fi
1612
1613         LLVM_COMPONENTS="engine bitwriter"
1614         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1615             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1616         fi
1617
1618         if test "x$enable_opencl" = xyes; then
1619             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1620             # LLVM 3.3 >= 177971 requires IRReader
1621             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1622                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1623             fi
1624         fi
1625         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1626         MESA_LLVM=1
1627
1628         dnl Check for Clang internal headers
1629         if test "x$enable_opencl" = xyes; then
1630             if test "x$CLANG_LIBDIR" = x; then
1631                 CLANG_LIBDIR=${LLVM_LIBDIR}
1632             fi
1633             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1634             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1635                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1636         fi
1637     else
1638         MESA_LLVM=0
1639         LLVM_VERSION_INT=0
1640     fi
1641 else
1642     MESA_LLVM=0
1643     LLVM_VERSION_INT=0
1644 fi
1645
1646 dnl Directory for XVMC libs
1647 AC_ARG_WITH([xvmc-libdir],
1648     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1649         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1650     [XVMC_LIB_INSTALL_DIR="$withval"],
1651     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1652 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1653
1654 dnl
1655 dnl Gallium Tests
1656 dnl
1657 if test "x$enable_gallium_tests" = xyes; then
1658     enable_gallium_loader=yes
1659 fi
1660 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1661
1662 if test "x$enable_gallium_loader" = xyes; then
1663     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1664 fi
1665 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1666
1667 dnl Directory for VDPAU libs
1668 AC_ARG_WITH([vdpau-libdir],
1669     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1670         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1671     [VDPAU_LIB_INSTALL_DIR="$withval"],
1672     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1673 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1674
1675 dnl Directory for OpenCL libs
1676 AC_ARG_WITH([opencl-libdir],
1677     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1678         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1679     [OPENCL_LIB_INSTALL_DIR="$withval"],
1680     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1681 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1682
1683 dnl
1684 dnl Gallium helper functions
1685 dnl
1686 gallium_check_st() {
1687     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1688          if test "x$have_libdrm" != xyes; then
1689             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1690          fi
1691          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1692     fi
1693     if test "x$enable_dri" = xyes && test "x$2" != x; then
1694          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1695          HAVE_COMMON_DRI=yes
1696     fi
1697     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1698          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1699     fi
1700     if test "x$enable_xa" = xyes && test "x$4" != x; then
1701          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1702     fi
1703     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1704          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1705     fi
1706     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1707          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1708     fi
1709 }
1710
1711 gallium_require_llvm() {
1712     if test "x$MESA_LLVM" = x0; then
1713         case "$host_cpu" in
1714         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1715         esac
1716     fi
1717 }
1718
1719 gallium_require_drm_loader() {
1720     if test "x$enable_gallium_loader" = xyes; then
1721         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1722                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1723         if test "x$have_libdrm" != xyes; then
1724             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1725         fi
1726         enable_gallium_drm_loader=yes
1727     fi
1728 }
1729
1730 radeon_llvm_check() {
1731     LLVM_REQUIRED_VERSION_MAJOR="3"
1732     LLVM_REQUIRED_VERSION_MINOR="3"
1733     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1734         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1735     fi
1736     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1737         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1738                       sources with the --enable-experimental-targets=R600
1739                       configure flag])
1740     fi
1741     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1742     NEED_RADEON_LLVM=yes
1743     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1744                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1745 }
1746
1747 dnl Gallium drivers
1748 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1749         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1750         "x$enable_vdpau" = xyes; then
1751     NEED_NONNULL_WINSYS=yes
1752 fi
1753 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1754
1755 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1756 if test "x$with_gallium_drivers" != x; then
1757     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1758     for driver in $gallium_drivers; do
1759         case "x$driver" in
1760         xsvga)
1761             HAVE_GALLIUM_SVGA=yes
1762             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1763             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1764             ;;
1765         xi915)
1766             HAVE_GALLIUM_I915=yes
1767             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1768             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1769             if test "x$MESA_LLVM" = x1; then
1770                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1771             fi
1772             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1773             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1774             ;;
1775         xilo)
1776             HAVE_GALLIUM_ILO=yes
1777             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1778             gallium_require_drm_loader
1779             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1780             gallium_check_st "intel/drm" "dri-ilo"
1781             ;;
1782         xr300)
1783             HAVE_GALLIUM_R300=yes
1784             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1785             gallium_require_llvm "Gallium R300"
1786             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1787             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1788             ;;
1789         xr600)
1790             HAVE_GALLIUM_R600=yes
1791             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1792             gallium_require_drm_loader
1793             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1794             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1795                 radeon_llvm_check
1796                 R600_NEED_RADEON_GALLIUM=yes;
1797                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1798             fi
1799             if test "x$enable_r600_llvm" = xyes; then
1800                 USE_R600_LLVM_COMPILER=yes;
1801             fi
1802             if test "x$enable_opencl" = xyes; then
1803                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1804             fi
1805             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1806             ;;
1807         xradeonsi)
1808             HAVE_GALLIUM_RADEONSI=yes
1809             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1810             gallium_require_drm_loader
1811             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1812             radeon_llvm_check
1813             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1814             ;;
1815         xnouveau)
1816             HAVE_GALLIUM_NOUVEAU=yes
1817             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1818             gallium_require_drm_loader
1819             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1820             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1821             ;;
1822         xfreedreno)
1823             HAVE_GALLIUM_FREEDRENO=yes
1824             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1825             gallium_require_drm_loader
1826             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1827             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1828             ;;
1829         xswrast)
1830             HAVE_GALLIUM_SOFTPIPE=yes
1831             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1832             if test "x$MESA_LLVM" = x1; then
1833                 HAVE_GALLIUM_LLVMPIPE=yes
1834                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1835             fi
1836
1837             if test "x$enable_dri" = xyes; then
1838                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1839                 HAVE_COMMON_DRI=yes
1840             fi
1841             if test "x$enable_vdpau" = xyes; then
1842                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1843             fi
1844             if test "x$enable_xvmc" = xyes; then
1845                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1846             fi
1847             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1848                 NEED_WINSYS_XLIB=yes
1849                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1850             fi
1851             ;;
1852         *)
1853             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1854             ;;
1855         esac
1856     done
1857 fi
1858
1859 dnl Set LLVM_LIBS - This is done after the driver configuration so
1860 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1861 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1862 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1863 dnl this was causing the same libraries to be appear multiple times
1864 dnl in LLVM_LIBS.
1865
1866 if test "x$MESA_LLVM" != x0; then
1867
1868     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1869
1870     if test "x$with_llvm_shared_libs" = xyes; then
1871         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1872         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1873         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1874
1875         if test "x$llvm_have_one_so" = xyes; then
1876             dnl LLVM was built using auto*, so there is only one shared object.
1877             LLVM_LIBS="-l$LLVM_SO_NAME"
1878         else
1879             dnl If LLVM was built with CMake, there will be one shared object per
1880             dnl component.
1881             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1882                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1883         Please make sure you have built llvm with the --enable-shared option
1884         and that your llvm libraries are installed in $LLVM_LIBDIR
1885         If you have installed your llvm libraries to a different directory you
1886         can use the --with-llvm-prefix= configure flag to specify this directory.
1887         NOTE: Mesa is attempting to use llvm shared libraries because you have
1888         passed one of the following options to configure:
1889                 --with-llvm-shared-libs
1890                 --enable-opencl
1891         If you do not want to build with llvm shared libraries and instead want to
1892         use llvm static libraries then remove these options from your configure
1893         invocation and reconfigure.])])
1894
1895            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1896            dnl install uses a shared object for each compoenent and we have
1897            dnl already added all of these objects to LLVM_LIBS.
1898         fi
1899     fi
1900 fi
1901
1902 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1903 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1904 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1905 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1906 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1907 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1908 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1909 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1910 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1911 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1912
1913 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1914                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1915                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1916 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1917                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes -a \
1918                                                   "x$MESA_LLVM" = x1)
1919
1920 if test "x$enable_gallium_loader" = xyes; then
1921     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1922
1923     if test "x$enable_gallium_drm_loader" = xyes; then
1924         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1925         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1926                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1927         if test "x$pipe_loader_have_xcb" = xyes; then
1928             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1929             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1930         fi
1931     fi
1932
1933     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1934     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1935 fi
1936
1937 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1938 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1939 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1940 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1941 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1942 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1943 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1944
1945 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1946                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1947                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1948                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1949 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1950                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1951 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1952 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1953 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
1954 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1955 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1956 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1957 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1958 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1959 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1960
1961 AC_SUBST([ELF_LIB])
1962
1963 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1964                                      "x$enable_xlib_glx" = xyes -o \
1965                                      "x$enable_osmesa" = xyes)
1966 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1967 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1968
1969 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1970 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1971 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1972
1973 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
1974
1975 AC_SUBST([VDPAU_MAJOR], 1)
1976 AC_SUBST([VDPAU_MINOR], 0)
1977
1978 AC_SUBST([XVMC_MAJOR], 1)
1979 AC_SUBST([XVMC_MINOR], 0)
1980
1981 AC_SUBST([XA_MAJOR], 1)
1982 AC_SUBST([XA_MINOR], 0)
1983 AC_SUBST([XA_TINY], 0)
1984 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1985
1986 dnl Restore LDFLAGS and CPPFLAGS
1987 LDFLAGS="$_SAVE_LDFLAGS"
1988 CPPFLAGS="$_SAVE_CPPFLAGS"
1989
1990 dnl Add user CFLAGS and CXXFLAGS
1991 CFLAGS="$CFLAGS $USER_CFLAGS"
1992 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1993
1994 dnl Substitute the config
1995 AC_CONFIG_FILES([Makefile
1996                 src/Makefile
1997                 src/egl/Makefile
1998                 src/egl/drivers/Makefile
1999                 src/egl/drivers/dri2/Makefile
2000                 src/egl/drivers/glx/Makefile
2001                 src/egl/main/Makefile
2002                 src/egl/main/egl.pc
2003                 src/egl/wayland/Makefile
2004                 src/egl/wayland/wayland-drm/Makefile
2005                 src/egl/wayland/wayland-egl/Makefile
2006                 src/egl/wayland/wayland-egl/wayland-egl.pc
2007                 src/gallium/auxiliary/Makefile
2008                 src/gallium/auxiliary/pipe-loader/Makefile
2009                 src/gallium/drivers/Makefile
2010                 src/gallium/drivers/freedreno/Makefile
2011                 src/gallium/drivers/freedreno/a2xx/Makefile
2012                 src/gallium/drivers/freedreno/a3xx/Makefile
2013                 src/gallium/drivers/i915/Makefile
2014                 src/gallium/drivers/ilo/Makefile
2015                 src/gallium/drivers/llvmpipe/Makefile
2016                 src/gallium/drivers/nouveau/Makefile
2017                 src/gallium/drivers/nv30/Makefile
2018                 src/gallium/drivers/nv50/Makefile
2019                 src/gallium/drivers/nvc0/Makefile
2020                 src/gallium/drivers/r300/Makefile
2021                 src/gallium/drivers/r600/Makefile
2022                 src/gallium/drivers/radeon/Makefile
2023                 src/gallium/drivers/radeonsi/Makefile
2024                 src/gallium/drivers/rbug/Makefile
2025                 src/gallium/drivers/softpipe/Makefile
2026                 src/gallium/drivers/svga/Makefile
2027                 src/gallium/drivers/trace/Makefile
2028                 src/gallium/state_trackers/Makefile
2029                 src/gallium/state_trackers/clover/Makefile
2030                 src/gallium/state_trackers/dri/Makefile
2031                 src/gallium/state_trackers/dri/drm/Makefile
2032                 src/gallium/state_trackers/dri/sw/Makefile
2033                 src/gallium/state_trackers/egl/Makefile
2034                 src/gallium/state_trackers/gbm/Makefile
2035                 src/gallium/state_trackers/glx/Makefile
2036                 src/gallium/state_trackers/osmesa/Makefile
2037                 src/gallium/state_trackers/vdpau/Makefile
2038                 src/gallium/state_trackers/vega/Makefile
2039                 src/gallium/state_trackers/xa/Makefile
2040                 src/gallium/state_trackers/xorg/Makefile
2041                 src/gallium/state_trackers/xvmc/Makefile
2042                 src/gallium/targets/Makefile
2043                 src/gallium/targets/dri-freedreno/Makefile
2044                 src/gallium/targets/dri-i915/Makefile
2045                 src/gallium/targets/dri-ilo/Makefile
2046                 src/gallium/targets/dri-nouveau/Makefile
2047                 src/gallium/targets/dri-r300/Makefile
2048                 src/gallium/targets/dri-r600/Makefile
2049                 src/gallium/targets/dri-radeonsi/Makefile
2050                 src/gallium/targets/dri-swrast/Makefile
2051                 src/gallium/targets/dri-vmwgfx/Makefile
2052                 src/gallium/targets/egl-static/Makefile
2053                 src/gallium/targets/gbm/Makefile
2054                 src/gallium/targets/opencl/Makefile
2055                 src/gallium/targets/osmesa/Makefile
2056                 src/gallium/targets/pipe-loader/Makefile
2057                 src/gallium/targets/libgl-xlib/Makefile
2058                 src/gallium/targets/vdpau-nouveau/Makefile
2059                 src/gallium/targets/vdpau-r300/Makefile
2060                 src/gallium/targets/vdpau-r600/Makefile
2061                 src/gallium/targets/vdpau-radeonsi/Makefile
2062                 src/gallium/targets/vdpau-softpipe/Makefile
2063                 src/gallium/targets/xa-vmwgfx/Makefile
2064                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2065                 src/gallium/targets/xorg-i915/Makefile
2066                 src/gallium/targets/xorg-nouveau/Makefile
2067                 src/gallium/targets/xorg-r600/Makefile
2068                 src/gallium/targets/xorg-radeonsi/Makefile
2069                 src/gallium/targets/xvmc-nouveau/Makefile
2070                 src/gallium/targets/xvmc-r300/Makefile
2071                 src/gallium/targets/xvmc-r600/Makefile
2072                 src/gallium/targets/xvmc-softpipe/Makefile
2073                 src/gallium/tests/trivial/Makefile
2074                 src/gallium/tests/unit/Makefile
2075                 src/gallium/winsys/Makefile
2076                 src/gallium/winsys/freedreno/drm/Makefile
2077                 src/gallium/winsys/i915/drm/Makefile
2078                 src/gallium/winsys/i915/sw/Makefile
2079                 src/gallium/winsys/intel/drm/Makefile
2080                 src/gallium/winsys/nouveau/drm/Makefile
2081                 src/gallium/winsys/radeon/drm/Makefile
2082                 src/gallium/winsys/svga/drm/Makefile
2083                 src/gallium/winsys/sw/dri/Makefile
2084                 src/gallium/winsys/sw/fbdev/Makefile
2085                 src/gallium/winsys/sw/null/Makefile
2086                 src/gallium/winsys/sw/wayland/Makefile
2087                 src/gallium/winsys/sw/wrapper/Makefile
2088                 src/gallium/winsys/sw/xlib/Makefile
2089                 src/gbm/Makefile
2090                 src/gbm/main/gbm.pc
2091                 src/glsl/Makefile
2092                 src/glsl/builtin_compiler/Makefile
2093                 src/glx/Makefile
2094                 src/glx/tests/Makefile
2095                 src/gtest/Makefile
2096                 src/mapi/Makefile
2097                 src/mapi/es1api/Makefile
2098                 src/mapi/es1api/glesv1_cm.pc
2099                 src/mapi/es2api/Makefile
2100                 src/mapi/es2api/glesv2.pc
2101                 src/mapi/glapi/Makefile
2102                 src/mapi/glapi/gen/Makefile
2103                 src/mapi/glapi/tests/Makefile
2104                 src/mapi/shared-glapi/Makefile
2105                 src/mapi/shared-glapi/tests/Makefile
2106                 src/mapi/vgapi/Makefile
2107                 src/mapi/vgapi/vg.pc
2108                 src/mesa/Makefile
2109                 src/mesa/gl.pc
2110                 src/mesa/drivers/dri/dri.pc
2111                 src/mesa/drivers/dri/common/Makefile
2112                 src/mesa/drivers/dri/common/xmlpool/Makefile
2113                 src/mesa/drivers/dri/i915/Makefile
2114                 src/mesa/drivers/dri/i965/Makefile
2115                 src/mesa/drivers/dri/Makefile
2116                 src/mesa/drivers/dri/nouveau/Makefile
2117                 src/mesa/drivers/dri/r200/Makefile
2118                 src/mesa/drivers/dri/radeon/Makefile
2119                 src/mesa/drivers/dri/swrast/Makefile
2120                 src/mesa/drivers/osmesa/Makefile
2121                 src/mesa/drivers/osmesa/osmesa.pc
2122                 src/mesa/drivers/x11/Makefile
2123                 src/mesa/libdricore/Makefile
2124                 src/mesa/main/tests/Makefile
2125                 src/mesa/main/tests/hash_table/Makefile
2126                 src/mesa/program/Makefile
2127                 src/mesa/x86-64/Makefile
2128                 src/mesa/x86/Makefile])
2129
2130 dnl Sort the dirs alphabetically
2131 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2132 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2133 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2134 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2135
2136 AC_OUTPUT
2137
2138 dnl
2139 dnl Output some configuration info for the user
2140 dnl
2141 echo ""
2142 echo "        prefix:          $prefix"
2143 echo "        exec_prefix:     $exec_prefix"
2144 echo "        libdir:          $libdir"
2145 echo "        includedir:      $includedir"
2146
2147 dnl API info
2148 echo ""
2149 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2150 echo "        OpenVG:          $enable_openvg"
2151
2152 dnl Driver info
2153 echo ""
2154 if test "x$enable_osmesa" != xno; then
2155         echo "        OSMesa:          lib$OSMESA_LIB"
2156 else
2157         echo "        OSMesa:          no"
2158 fi
2159
2160 if test "x$enable_dri" != xno; then
2161         # cleanup the drivers var
2162         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2163         if test "x$DRI_DIRS" = x; then
2164             echo "        DRI drivers:     no"
2165         else
2166             echo "        DRI drivers:     $dri_dirs"
2167         fi
2168         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2169 fi
2170
2171 case "x$enable_glx$enable_xlib_glx" in
2172 xyesyes)
2173     echo "        GLX:             Xlib-based"
2174     ;;
2175 xyesno)
2176     echo "        GLX:             DRI-based"
2177     ;;
2178 *)
2179     echo "        GLX:             $enable_glx"
2180     ;;
2181 esac
2182
2183 dnl EGL
2184 echo ""
2185 echo "        EGL:             $enable_egl"
2186 if test "$enable_egl" = yes; then
2187     echo "        EGL platforms:   $EGL_PLATFORMS"
2188
2189     egl_drivers=""
2190     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2191         egl_drivers="$egl_drivers builtin:egl_glx"
2192     fi
2193     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2194         egl_drivers="$egl_drivers builtin:egl_dri2"
2195     fi
2196
2197     if test "x$enable_gallium_egl" = xyes; then
2198         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2199         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2200     else
2201         echo "        EGL drivers:    $egl_drivers"
2202     fi
2203 fi
2204
2205 echo ""
2206 if test "x$MESA_LLVM" = x1; then
2207     echo "        llvm:            yes"
2208     echo "        llvm-config:     $LLVM_CONFIG"
2209     echo "        llvm-version:    $LLVM_VERSION"
2210 else
2211     echo "        llvm:            no"
2212 fi
2213
2214 echo ""
2215 if test -n "$with_gallium_drivers"; then
2216     echo "        Gallium:         yes"
2217     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2218     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2219     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2220     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2221 else
2222     echo "        Gallium:         no"
2223 fi
2224
2225
2226 dnl Libraries
2227 echo ""
2228 echo "        Shared libs:     $enable_shared"
2229 echo "        Static libs:     $enable_static"
2230 echo "        Shared-glapi:    $enable_shared_glapi"
2231
2232 dnl Compiler options
2233 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2234 cflags=`echo $CFLAGS | \
2235     $SED 's/^ *//;s/  */ /;s/ *$//'`
2236 cxxflags=`echo $CXXFLAGS | \
2237     $SED 's/^ *//;s/  */ /;s/ *$//'`
2238 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2239 echo ""
2240 echo "        CFLAGS:          $cflags"
2241 echo "        CXXFLAGS:        $cxxflags"
2242 echo "        Macros:          $defines"
2243 echo ""
2244 if test "x$MESA_LLVM" = x1; then
2245     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2246     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2247     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2248     echo ""
2249 fi
2250 echo "        PYTHON2:         $PYTHON2"
2251
2252 echo ""
2253 echo "        Run '${MAKE-make}' to build Mesa"
2254 echo ""