configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AX_PYTHON_MODULE([libxml2], [needed])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 LT_PREREQ([2.2])
  62 LT_INIT([disable-static])
  63
  64 AX_PROG_BISON([],
  65               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  66                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  67 AX_PROG_FLEX([],
  68              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  69                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  70
  71 AC_PATH_PROG([PERL], [perl])
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133
 134 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 135
 136 dnl Make sure the pkg-config macros are defined
 137 m4_ifndef([PKG_PROG_PKG_CONFIG],
 138     [m4_fatal([Could not locate the pkg-config autoconf macros.
 139   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 140   are in a different location, try setting the environment variable
 141   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 142 PKG_PROG_PKG_CONFIG()
 143
 144 dnl LIB_DIR - library basename
 145 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 146 AC_SUBST([LIB_DIR])
 147
 148 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 149 _SAVE_LDFLAGS="$LDFLAGS"
 150 _SAVE_CPPFLAGS="$CPPFLAGS"
 151
 152 dnl Compiler macros
 153 DEFINES=""
 154 AC_SUBST([DEFINES])
 155 case "$host_os" in
 156 linux*|*-gnu*|gnu*)
 157     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 158     ;;
 159 solaris*)
 160     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 161     ;;
 162 cygwin*)
 163     DEFINES="$DEFINES -DHAVE_PTHREAD"
 164     ;;
 165 esac
 166
 167 dnl Add flags for gcc and g++
 168 if test "x$GCC" = xyes; then
 169     case "$host_os" in
 170     cygwin*)
 171         CFLAGS="$CFLAGS -Wall -std=gnu99"
 172         ;;
 173     *)
 174         CFLAGS="$CFLAGS -Wall -std=c99"
 175         ;;
 176     esac
 177
 178     # Enable -Werror=implicit-function-declaration and
 179     # -Werror=missing-prototypes, if available, or otherwise, just
 180     # -Wmissing-prototypes.  This is particularly useful to avoid
 181     # generating a loadable driver module that has undefined symbols.
 182     save_CFLAGS="$CFLAGS"
 183     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 184     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 185     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 187                    AC_MSG_RESULT([yes]),
 188                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 189                     AC_MSG_RESULT([no])]);
 190
 191     # Enable -fvisibility=hidden if using a gcc that supports it
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 194     VISIBILITY_CFLAGS="-fvisibility=hidden"
 195     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 197                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 198
 199     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 200     CFLAGS=$save_CFLAGS
 201
 202     # Work around aliasing bugs - developers should comment this out
 203     CFLAGS="$CFLAGS -fno-strict-aliasing"
 204
 205     # gcc's builtin memcmp is slower than glibc's
 206     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 207     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 208 fi
 209 if test "x$GXX" = xyes; then
 210     CXXFLAGS="$CXXFLAGS -Wall"
 211
 212     # Enable -fvisibility=hidden if using a gcc that supports it
 213     save_CXXFLAGS="$CXXFLAGS"
 214     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 215     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 216     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 217     AC_LANG_PUSH([C++])
 218     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 219                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 220     AC_LANG_POP([C++])
 221
 222     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 223     CXXFLAGS=$save_CXXFLAGS
 224
 225     # Work around aliasing bugs - developers should comment this out
 226     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 227
 228     # gcc's builtin memcmp is slower than glibc's
 229     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 230     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 231 fi
 232
 233 dnl even if the compiler appears to support it, using visibility attributes isn't
 234 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 235 case "$host_os" in
 236 cygwin*)
 237     VISIBILITY_CFLAGS=""
 238     VISIBILITY_CXXFLAGS=""
 239     ;;
 240 esac
 241
 242 AC_SUBST([VISIBILITY_CFLAGS])
 243 AC_SUBST([VISIBILITY_CXXFLAGS])
 244
 245 dnl
 246 dnl Optional flags, check for compiler support
 247 dnl
 248 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 249 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 250
 251 dnl
 252 dnl Hacks to enable 32 or 64 bit build
 253 dnl
 254 AC_ARG_ENABLE([32-bit],
 255     [AS_HELP_STRING([--enable-32-bit],
 256         [build 32-bit libraries @<:@default=auto@:>@])],
 257     [enable_32bit="$enableval"],
 258     [enable_32bit=auto]
 259 )
 260 if test "x$enable_32bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m32"
 263         CCASFLAGS="$CCASFLAGS -m32"
 264     fi
 265     if test "x$GXX" = xyes; then
 266         CXXFLAGS="$CXXFLAGS -m32"
 267     fi
 268 fi
 269 AC_ARG_ENABLE([64-bit],
 270     [AS_HELP_STRING([--enable-64-bit],
 271         [build 64-bit libraries @<:@default=auto@:>@])],
 272     [enable_64bit="$enableval"],
 273     [enable_64bit=auto]
 274 )
 275 if test "x$enable_64bit" = xyes; then
 276     if test "x$GCC" = xyes; then
 277         CFLAGS="$CFLAGS -m64"
 278     fi
 279     if test "x$GXX" = xyes; then
 280         CXXFLAGS="$CXXFLAGS -m64"
 281     fi
 282 fi
 283
 284 dnl Can't have static and shared libraries, default to static if user
 285 dnl explicitly requested. If both disabled, set to static since shared
 286 dnl was explicitly requested.
 287 case "x$enable_static$enable_shared" in
 288 xyesyes )
 289     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 290     enable_shared=no
 291     ;;
 292 xnono )
 293     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 294     enable_static=yes
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 299
 300 dnl
 301 dnl other compiler options
 302 dnl
 303 AC_ARG_ENABLE([debug],
 304     [AS_HELP_STRING([--enable-debug],
 305         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 306     [enable_debug="$enableval"],
 307     [enable_debug=no]
 308 )
 309 if test "x$enable_debug" = xyes; then
 310     DEFINES="$DEFINES -DDEBUG"
 311     if test "x$GCC" = xyes; then
 312         CFLAGS="$CFLAGS -g -O0"
 313     fi
 314     if test "x$GXX" = xyes; then
 315         CXXFLAGS="$CXXFLAGS -g -O0"
 316     fi
 317 fi
 318
 319 dnl
 320 dnl library names
 321 dnl
 322 LIB_PREFIX_GLOB='lib'
 323 LIB_VERSION_SEPARATOR='.'
 324 if test "$enable_static" = yes; then
 325     LIB_EXTENSION='a'
 326 else
 327     case "$host_os" in
 328     darwin* )
 329         LIB_EXTENSION='dylib' ;;
 330     cygwin* )
 331         dnl prefix can be 'cyg' or 'lib'
 332         LIB_PREFIX_GLOB='???'
 333         LIB_VERSION_SEPARATOR='-'
 334         LIB_EXTENSION='dll' ;;
 335     aix* )
 336         LIB_EXTENSION='a' ;;
 337     * )
 338         LIB_EXTENSION='so' ;;
 339     esac
 340 fi
 341 AC_ARG_WITH([gl-lib-name],
 342   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 343     [specify GL library name @<:@default=GL@:>@])],
 344   [GL_LIB=$withval],
 345   [GL_LIB=GL])
 346 AC_ARG_WITH([osmesa-lib-name],
 347   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 348     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 349   [OSMESA_LIB=$withval],
 350   [OSMESA_LIB=OSMesa])
 351 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 352 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 353
 354 dnl
 355 dnl Mangled Mesa support
 356 dnl
 357 AC_ARG_ENABLE([mangling],
 358   [AS_HELP_STRING([--enable-mangling],
 359     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 360   [enable_mangling="${enableval}"],
 361   [enable_mangling=no]
 362 )
 363 if test "x${enable_mangling}" = "xyes" ; then
 364   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 365   GL_LIB="Mangled${GL_LIB}"
 366   OSMESA_LIB="Mangled${OSMESA_LIB}"
 367 fi
 368 AC_SUBST([GL_LIB])
 369 AC_SUBST([OSMESA_LIB])
 370
 371 dnl
 372 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 373 dnl
 374 AC_ARG_ENABLE([texture-float],
 375     [AS_HELP_STRING([--enable-texture-float],
 376         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 377     [enable_texture_float="$enableval"],
 378     [enable_texture_float=no]
 379 )
 380 if test "x$enable_texture_float" = xyes; then
 381     AC_MSG_WARN([Floating-point textures enabled.])
 382     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 383     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 384 fi
 385
 386 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 387 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 388 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 389 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 390 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 391 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 392 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 393
 394 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 395 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 396 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 397 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 398 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401
 402 AC_SUBST([GL_LIB_NAME])
 403 AC_SUBST([OSMESA_LIB_NAME])
 404 AC_SUBST([EGL_LIB_NAME])
 405 AC_SUBST([GLESv1_CM_LIB_NAME])
 406 AC_SUBST([GLESv2_LIB_NAME])
 407 AC_SUBST([VG_LIB_NAME])
 408 AC_SUBST([GLAPI_LIB_NAME])
 409
 410 AC_SUBST([GL_LIB_GLOB])
 411 AC_SUBST([EGL_LIB_GLOB])
 412 AC_SUBST([GLESv1_CM_LIB_GLOB])
 413 AC_SUBST([GLESv2_LIB_GLOB])
 414 AC_SUBST([VG_LIB_GLOB])
 415 AC_SUBST([GLAPI_LIB_GLOB])
 416
 417 dnl
 418 dnl Arch/platform-specific settings
 419 dnl
 420 AC_ARG_ENABLE([asm],
 421     [AS_HELP_STRING([--disable-asm],
 422         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 423     [enable_asm="$enableval"],
 424     [enable_asm=yes]
 425 )
 426 asm_arch=""
 427 AC_MSG_CHECKING([whether to enable assembly])
 428 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 429 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 430 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 431     case "$host_cpu" in
 432     i?86 | x86_64 | amd64)
 433         enable_asm=no
 434         AC_MSG_RESULT([no, cross compiling])
 435         ;;
 436     esac
 437 fi
 438 # check for supported arches
 439 if test "x$enable_asm" = xyes; then
 440     case "$host_cpu" in
 441     i?86)
 442         case "$host_os" in
 443         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 444             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 445             ;;
 446         gnu*)
 447             asm_arch=x86
 448             ;;
 449         esac
 450         ;;
 451     x86_64|amd64)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 454             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 455             ;;
 456         esac
 457         ;;
 458     sparc*)
 459         case "$host_os" in
 460         linux*)
 461             asm_arch=sparc
 462             ;;
 463         esac
 464         ;;
 465     esac
 466
 467     case "$asm_arch" in
 468     x86)
 469         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 470         AC_MSG_RESULT([yes, x86])
 471         ;;
 472     x86_64|amd64)
 473         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 474         AC_MSG_RESULT([yes, x86_64])
 475         ;;
 476     sparc)
 477         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 478         AC_MSG_RESULT([yes, sparc])
 479         ;;
 480     *)
 481         AC_MSG_RESULT([no, platform not supported])
 482         ;;
 483     esac
 484 fi
 485
 486 dnl Check to see if dlopen is in default libraries (like Solaris, which
 487 dnl has it in libc), or if libdl is needed to get it.
 488 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 489     [AC_CHECK_LIB([dl], [dlopen],
 490        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 491 AC_SUBST([DLOPEN_LIBS])
 492
 493 case "$host_os" in
 494 darwin*|mingw*)
 495     ;;
 496 *)
 497     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 498                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 499                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 500     AC_SUBST([CLOCK_LIB])
 501     ;;
 502 esac
 503
 504 dnl See if posix_memalign is available
 505 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 506
 507 dnl Check for pthreads
 508 AX_PTHREAD
 509 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 510 dnl to -pthread, which causes problems if we need -lpthread to appear in
 511 dnl pkgconfig files.
 512 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 513
 514 dnl SELinux awareness.
 515 AC_ARG_ENABLE([selinux],
 516     [AS_HELP_STRING([--enable-selinux],
 517         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 518     [MESA_SELINUX="$enableval"],
 519     [MESA_SELINUX=no])
 520 if test "x$enable_selinux" = "xyes"; then
 521     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 522         [AC_CHECK_HEADER([selinux/selinux.h],[],
 523                          [AC_MSG_ERROR([SELinux headers not found])])
 524          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 525                       [AC_MSG_ERROR([SELinux library not found])])
 526          SELINUX_LIBS="-lselinux"])
 527     DEFINES="$DEFINES -DMESA_SELINUX"
 528 fi
 529 AC_SUBST([SELINUX_CFLAGS])
 530 AC_SUBST([SELINUX_LIBS])
 531
 532 dnl Options for APIs
 533 AC_ARG_ENABLE([opengl],
 534     [AS_HELP_STRING([--disable-opengl],
 535         [disable support for standard OpenGL API @<:@default=no@:>@])],
 536     [enable_opengl="$enableval"],
 537     [enable_opengl=yes])
 538 AC_ARG_ENABLE([gles1],
 539     [AS_HELP_STRING([--enable-gles1],
 540         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 541     [enable_gles1="$enableval"],
 542     [enable_gles1=no])
 543 AC_ARG_ENABLE([gles2],
 544     [AS_HELP_STRING([--enable-gles2],
 545         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 546     [enable_gles2="$enableval"],
 547     [enable_gles2=no])
 548 AC_ARG_ENABLE([openvg],
 549     [AS_HELP_STRING([--enable-openvg],
 550         [enable support for OpenVG API @<:@default=no@:>@])],
 551     [enable_openvg="$enableval"],
 552     [enable_openvg=no])
 553
 554 AC_ARG_ENABLE([dri],
 555     [AS_HELP_STRING([--enable-dri],
 556         [enable DRI modules @<:@default=enabled@:>@])],
 557     [enable_dri="$enableval"],
 558     [enable_dri=yes])
 559 AC_ARG_ENABLE([dri3],
 560     [AS_HELP_STRING([--enable-dri3],
 561         [enable DRI3 @<:@default=enabled@:>@])],
 562     [enable_dri3="$enableval"],
 563     [enable_dri3=yes])
 564 AC_ARG_ENABLE([glx],
 565     [AS_HELP_STRING([--enable-glx],
 566         [enable GLX library @<:@default=enabled@:>@])],
 567     [enable_glx="$enableval"],
 568     [enable_glx=yes])
 569 AC_ARG_ENABLE([osmesa],
 570     [AS_HELP_STRING([--enable-osmesa],
 571         [enable OSMesa library @<:@default=disabled@:>@])],
 572     [enable_osmesa="$enableval"],
 573     [enable_osmesa=no])
 574 AC_ARG_ENABLE([gallium-osmesa],
 575     [AS_HELP_STRING([--enable-gallium-osmesa],
 576         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 577     [enable_gallium_osmesa="$enableval"],
 578     [enable_gallium_osmesa=no])
 579 AC_ARG_ENABLE([egl],
 580     [AS_HELP_STRING([--disable-egl],
 581         [disable EGL library @<:@default=enabled@:>@])],
 582     [enable_egl="$enableval"],
 583     [enable_egl=yes])
 584
 585 AC_ARG_ENABLE([xa],
 586     [AS_HELP_STRING([--enable-xa],
 587         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 588     [enable_xa="$enableval"],
 589     [enable_xa=no])
 590 AC_ARG_ENABLE([gbm],
 591    [AS_HELP_STRING([--enable-gbm],
 592          [enable gbm library @<:@default=auto@:>@])],
 593    [enable_gbm="$enableval"],
 594    [enable_gbm=auto])
 595
 596 AC_ARG_ENABLE([xvmc],
 597    [AS_HELP_STRING([--enable-xvmc],
 598          [enable xvmc library @<:@default=auto@:>@])],
 599    [enable_xvmc="$enableval"],
 600    [enable_xvmc=no])
 601 AC_ARG_ENABLE([vdpau],
 602    [AS_HELP_STRING([--enable-vdpau],
 603          [enable vdpau library @<:@default=auto@:>@])],
 604    [enable_vdpau="$enableval"],
 605    [enable_vdpau=auto])
 606 AC_ARG_ENABLE([omx],
 607    [AS_HELP_STRING([--enable-omx],
 608          [enable OpenMAX library @<:@default=no@:>@])],
 609    [enable_omx="$enableval"],
 610    [enable_omx=no])
 611 AC_ARG_ENABLE([opencl],
 612    [AS_HELP_STRING([--enable-opencl],
 613          [enable OpenCL library NOTE: Enabling this option will also enable
 614           --with-llvm-shared-libs
 615           @<:@default=no@:>@])],
 616    [],
 617    [enable_opencl=no])
 618 AC_ARG_ENABLE([opencl_icd],
 619    [AS_HELP_STRING([--enable-opencl-icd],
 620           [Build an OpenCL ICD library to be loaded by an ICD implementation
 621            @<:@default=no@:>@])],
 622     [enable_opencl_icd="$enableval"],
 623     [enable_opencl_icd=no])
 624 AC_ARG_ENABLE([xlib-glx],
 625     [AS_HELP_STRING([--enable-xlib-glx],
 626         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 627     [enable_xlib_glx="$enableval"],
 628     [enable_xlib_glx=no])
 629 AC_ARG_ENABLE([gallium-egl],
 630     [AS_HELP_STRING([--enable-gallium-egl],
 631         [enable optional EGL state tracker (not required
 632          for EGL support in Gallium with OpenGL and OpenGL ES)
 633          @<:@default=disable@:>@])],
 634     [enable_gallium_egl="$enableval"],
 635     [enable_gallium_egl=no])
 636 AC_ARG_ENABLE([gallium-gbm],
 637     [AS_HELP_STRING([--enable-gallium-gbm],
 638         [enable optional gbm state tracker (not required for
 639          gbm support in Gallium)
 640          @<:@default=auto@:>@])],
 641     [enable_gallium_gbm="$enableval"],
 642     [enable_gallium_gbm=auto])
 643
 644 AC_ARG_ENABLE([r600-llvm-compiler],
 645     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 646         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 647     [enable_r600_llvm="$enableval"],
 648     [enable_r600_llvm=no])
 649
 650 AC_ARG_ENABLE([gallium-tests],
 651     [AS_HELP_STRING([--enable-gallium-tests],
 652         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 653     [enable_gallium_tests="$enableval"],
 654     [enable_gallium_tests=no])
 655
 656 # Option for Gallium drivers
 657
 658 # Keep this in sync with the --with-gallium-drivers help string default value
 659 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 660
 661 AC_ARG_WITH([gallium-drivers],
 662     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 663         [comma delimited Gallium drivers list, e.g.
 664         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 665         @<:@default=r300,r600,svga,swrast@:>@])],
 666     [with_gallium_drivers="$withval"],
 667     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 668
 669 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 670 # here so that the script doesn't choke on an unknown driver name later.
 671 case "$with_gallium_drivers" in
 672     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 673     no) with_gallium_drivers='' ;;
 674 esac
 675
 676 if test "x$enable_opengl" = xno -a \
 677         "x$enable_gles1" = xno -a \
 678         "x$enable_gles2" = xno -a \
 679         "x$enable_openvg" = xno -a \
 680         "x$enable_xa" = xno -a \
 681         "x$enable_xvmc" = xno -a \
 682         "x$enable_vdpau" = xno -a \
 683         "x$enable_omx" = xno -a \
 684         "x$enable_opencl" = xno; then
 685     AC_MSG_ERROR([at least one API should be enabled])
 686 fi
 687
 688 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 689 if test "x$enable_opengl" = xno -a \
 690         "x$enable_gles1" = xyes; then
 691     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 692 fi
 693
 694 if test "x$enable_opengl" = xno -a \
 695         "x$enable_gles2" = xyes; then
 696     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 697 fi
 698
 699 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 700 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 701 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 702 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 703                                         "x$enable_gles1" = xyes -o \
 704                                         "x$enable_gles2" = xyes)
 705
 706 enable_dri_glx=$enable_dri
 707
 708 if test "x$enable_glx" = xno; then
 709     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 710     enable_xlib_glx=no
 711     enable_dri_glx=no
 712 fi
 713
 714 if test "x$enable_dri_glx$enable_xlib_glx" = xyesyes; then
 715     AC_MSG_ERROR([DRI-GLX and Xlib-GLX cannot be built together])
 716 fi
 717
 718 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 719     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 720 fi
 721
 722 # Disable GLX if OpenGL is not enabled
 723 if test "x$enable_glx$enable_opengl" = xyesno; then
 724     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 725     enable_glx=no
 726 fi
 727
 728 # Disable GLX if DRI-GLX and Xlib-GLX are not enabled
 729 if test "x$enable_glx" = xyes -a \
 730         "x$enable_dri_glx" = xno -a \
 731         "x$enable_xlib_glx" = xno; then
 732     AC_MSG_WARN([Neither DRI-GLX nor Xlib-GLX enabled, disabling GLX])
 733     enable_glx=no
 734 fi
 735
 736 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 737                                   "x$enable_dri_glx" = xyes)
 738 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 739 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 740
 741 AC_ARG_ENABLE([shared-glapi],
 742     [AS_HELP_STRING([--enable-shared-glapi],
 743         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 744     [enable_shared_glapi="$enableval"],
 745     [enable_shared_glapi=yes])
 746
 747 case "x$enable_opengl$enable_gles1$enable_gles2" in
 748 x*yes*yes*)
 749     if test "x$enable_shared_glapi" = xno; then
 750         AC_MSG_ERROR([shared GLAPI required when building two or more of
 751                       the following APIs - opengl, gles1 gles2])
 752     fi
 753     ;;
 754 esac
 755
 756 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 757
 758 dnl
 759 dnl Driver specific build directories
 760 dnl
 761 GALLIUM_TARGET_DIRS=""
 762 GALLIUM_WINSYS_DIRS="sw"
 763 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 764 GALLIUM_STATE_TRACKERS_DIRS=""
 765
 766 case "x$enable_glx$enable_xlib_glx" in
 767 xyesyes)
 768     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 769     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 770     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 771     NEED_WINSYS_XLIB="yes"
 772     ;;
 773 esac
 774
 775 if test "x$enable_dri" = xyes; then
 776     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 777     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 778 fi
 779
 780 if test "x$enable_gallium_osmesa" = xyes; then
 781     if test -z "$with_gallium_drivers"; then
 782         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 783     fi
 784     if test "x$enable_osmesa" = xyes; then
 785         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 786     fi
 787     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 788     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 789 fi
 790
 791 AC_SUBST([MESA_LLVM])
 792
 793 # Check for libdrm
 794 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 795                   [have_libdrm=yes], [have_libdrm=no])
 796 if test "x$have_libdrm" = xyes; then
 797         DEFINES="$DEFINES -DHAVE_LIBDRM"
 798 fi
 799
 800 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 801                   have_libudev=yes, have_libudev=no)
 802
 803 if test "x$enable_dri" = xyes; then
 804     # DRI must be shared, I think
 805     if test "$enable_static" = yes; then
 806         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 807     fi
 808
 809     # not a hard requirement as swrast does not depend on it
 810     if test "x$have_libdrm" = xyes; then
 811         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 812     fi
 813 fi
 814
 815 dnl Direct rendering or just indirect rendering
 816 case "$host_os" in
 817 gnu*)
 818     dnl Disable by default on GNU/Hurd
 819     driglx_direct_default="no"
 820     ;;
 821 cygwin*)
 822     dnl Disable by default on cygwin
 823     driglx_direct_default="no"
 824     ;;
 825 *)
 826     driglx_direct_default="yes"
 827     ;;
 828 esac
 829 AC_ARG_ENABLE([driglx-direct],
 830     [AS_HELP_STRING([--disable-driglx-direct],
 831         [disable direct rendering in GLX and EGL for DRI \
 832             @<:@default=auto@:>@])],
 833     [driglx_direct="$enableval"],
 834     [driglx_direct="$driglx_direct_default"])
 835
 836 dnl
 837 dnl libGL configuration per driver
 838 dnl
 839 case "x$enable_glx$enable_xlib_glx" in
 840 xyesyes)
 841     # Xlib-based GLX
 842     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 843     GL_PC_REQ_PRIV="x11 xext"
 844     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 845     GL_LIB_DEPS="$XLIBGL_LIBS"
 846     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 847     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 848     ;;
 849 xyesno)
 850     # DRI-based GLX
 851     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 852     if test x"$driglx_direct" = xyes; then
 853         if test "x$have_libdrm" != xyes; then
 854             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 855         fi
 856         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 857         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 858         if test x"$enable_dri3" = xyes; then
 859             if test x"$have_libudev" != xyes; then
 860               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 861             fi
 862             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 863             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 864         fi
 865     fi
 866
 867     # find the DRI deps for libGL
 868     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 869
 870     if test x"$enable_dri3" = xyes; then
 871         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 872     fi
 873
 874     # add xf86vidmode if available
 875     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 876     if test "$HAVE_XF86VIDMODE" = yes ; then
 877         dri_modules="$dri_modules xxf86vm"
 878     fi
 879
 880     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 881     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 882     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 883     GL_LIB_DEPS="$DRIGL_LIBS"
 884
 885     # need DRM libs, $PTHREAD_LIBS, etc.
 886     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 887     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 888     ;;
 889 esac
 890
 891 if test "$have_libudev" = yes; then
 892     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 893 fi
 894
 895 # This is outside the case (above) so that it is invoked even for non-GLX
 896 # builds.
 897 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 898
 899 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 900 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 901 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 902 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 903
 904 AC_SUBST([X11_INCLUDES])
 905 AC_SUBST([GL_LIB_DEPS])
 906 AC_SUBST([GL_PC_REQ_PRIV])
 907 AC_SUBST([GL_PC_LIB_PRIV])
 908 AC_SUBST([GL_PC_CFLAGS])
 909 AC_SUBST([DRI_PC_REQ_PRIV])
 910 AC_SUBST([GLESv1_CM_LIB_DEPS])
 911 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 912 AC_SUBST([GLESv2_LIB_DEPS])
 913 AC_SUBST([GLESv2_PC_LIB_PRIV])
 914
 915 AC_SUBST([HAVE_XF86VIDMODE])
 916
 917 dnl
 918 dnl More GLX setup
 919 dnl
 920 case "x$enable_glx$enable_xlib_glx" in
 921 xyesyes)
 922     DEFINES="$DEFINES -DUSE_XSHM"
 923     ;;
 924 xyesno)
 925     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 926     if test "x$driglx_direct" = xyes; then
 927         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 928     fi
 929     ;;
 930 esac
 931
 932 dnl
 933 dnl TLS detection
 934 dnl
 935
 936 AC_ARG_ENABLE([glx-tls],
 937     [AS_HELP_STRING([--enable-glx-tls],
 938         [enable TLS support in GLX @<:@default=disabled@:>@])],
 939     [GLX_USE_TLS="$enableval"],
 940     [GLX_USE_TLS=no])
 941 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 942
 943 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 944       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 945
 946 dnl
 947 dnl More DRI setup
 948 dnl
 949 dnl Directory for DRI drivers
 950 AC_ARG_WITH([dri-driverdir],
 951     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 952         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 953     [DRI_DRIVER_INSTALL_DIR="$withval"],
 954     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 955 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 956 dnl Extra search path for DRI drivers
 957 AC_ARG_WITH([dri-searchpath],
 958     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 959         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 960     [DRI_DRIVER_SEARCH_DIR="$withval"],
 961     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 962 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 963 dnl Which drivers to build - default is chosen by platform
 964 AC_ARG_WITH([dri-drivers],
 965     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 966         [comma delimited classic DRI drivers list, e.g.
 967         "swrast,i965,radeon" @<:@default=auto@:>@])],
 968     [with_dri_drivers="$withval"],
 969     [with_dri_drivers=auto])
 970
 971 if test "x$with_dri_drivers" = xauto; then
 972     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 973         with_dri_drivers="yes"
 974     else
 975         with_dri_drivers="no"
 976     fi
 977 fi
 978 if test "x$with_dri_drivers" = xno; then
 979     with_dri_drivers=''
 980 fi
 981
 982 dnl If $with_dri_drivers is yes, drivers will be added through
 983 dnl platform checks. Set DEFINES and LIB_DEPS
 984 if test "x$enable_dri" = xyes; then
 985     # Platform specific settings and drivers to build
 986     case "$host_os" in
 987     linux*)
 988         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 989         DEFINES="$DEFINES -DHAVE_ALIAS"
 990         if test "x$enable_dri3" = xyes; then
 991             DEFINES="$DEFINES -DHAVE_DRI3"
 992         fi
 993
 994         case "$host_cpu" in
 995         powerpc* | sparc*)
 996             # Build only the drivers for cards that exist on PowerPC/sparc
 997             if test "x$with_dri_drivers" = "xyes"; then
 998                 with_dri_drivers="r200 radeon swrast"
 999             fi
1000             ;;
1001         esac
1002         ;;
1003     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1004         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1005         DEFINES="$DEFINES -DHAVE_ALIAS"
1006         ;;
1007     gnu*)
1008         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1009         DEFINES="$DEFINES -DHAVE_ALIAS"
1010         ;;
1011     solaris*)
1012         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1013         ;;
1014     cygwin*)
1015         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1016         if test "x$with_dri_drivers" = "xyes"; then
1017             with_dri_drivers="swrast"
1018         fi
1019         ;;
1020     esac
1021
1022     # default drivers
1023     if test "x$with_dri_drivers" = "xyes"; then
1024         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1025     fi
1026
1027     # Check for expat
1028     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1029     if test "x$have_expat" = "xyes"; then
1030        PKG_CHECK_MODULES([EXPAT], [expat], [],
1031                          AC_MSG_ERROR([Expat required for DRI.]))
1032     else
1033        # expat version 2.0 and earlier do not provide expat.pc
1034        EXPAT_LIBS=-lexpat
1035     fi
1036
1037     # If we are building any DRI driver other than swrast.
1038     if test -n "$with_dri_drivers"; then
1039         if test "x$with_dri_drivers" != xswrast; then
1040             # ... libdrm is required
1041             if test "x$have_libdrm" != xyes; then
1042                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1043             fi
1044             DRICOMMON_NEED_LIBDRM=yes
1045         else
1046             DRICOMMON_NEED_LIBDRM=no
1047         fi
1048     fi
1049
1050     # put all the necessary libs together
1051     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1052     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1053
1054 fi
1055
1056 AC_SUBST([DRI_LIB_DEPS])
1057 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1058
1059 DRI_DIRS=''
1060 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1061 if test -n "$with_dri_drivers"; then
1062     if test "x$enable_opengl" != xyes; then
1063         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1064     fi
1065
1066     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1067     for driver in $dri_drivers; do
1068         DRI_DIRS+="$driver "
1069         case "x$driver" in
1070         xi915)
1071             HAVE_I915_DRI=yes;
1072             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1073             ;;
1074         xi965)
1075             HAVE_I965_DRI=yes;
1076             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1077             ;;
1078         xnouveau)
1079             HAVE_NOUVEAU_DRI=yes;
1080             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1081             ;;
1082         xradeon)
1083             HAVE_RADEON_DRI=yes;
1084             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1085             ;;
1086         xr200)
1087             HAVE_R200_DRI=yes;
1088             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1089             ;;
1090         xswrast)
1091             HAVE_SWRAST_DRI=yes;
1092             ;;
1093         *)
1094             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1095             ;;
1096         esac
1097     done
1098     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1099 fi
1100
1101 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1102 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1103                                   "x$enable_osmesa" = xyes -o \
1104                                   -n "$DRI_DIRS")
1105
1106 dnl
1107 dnl OSMesa configuration
1108 dnl
1109
1110 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1111 AC_ARG_WITH([osmesa-bits],
1112     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1113         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1114     [osmesa_bits="$withval"],
1115     [osmesa_bits=8])
1116 if test "x$osmesa_bits" != x8; then
1117     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1118         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1119         osmesa_bits=8
1120     fi
1121 fi
1122 case "x$osmesa_bits" in
1123 x8)
1124     OSMESA_LIB="${OSMESA_LIB}"
1125     ;;
1126 x16|x32)
1127     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1128     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1129     ;;
1130 *)
1131     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1132     ;;
1133 esac
1134
1135 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1136     # only link libraries with osmesa if shared
1137     if test "$enable_static" = no; then
1138         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1139     else
1140         OSMESA_LIB_DEPS=""
1141     fi
1142     OSMESA_MESA_DEPS=""
1143     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1144 fi
1145
1146 AC_SUBST([OSMESA_LIB_DEPS])
1147 AC_SUBST([OSMESA_MESA_DEPS])
1148 AC_SUBST([OSMESA_PC_REQ])
1149 AC_SUBST([OSMESA_PC_LIB_PRIV])
1150
1151 dnl
1152 dnl gbm configuration
1153 dnl
1154 if test "x$enable_gbm" = xauto; then
1155     case "$with_egl_platforms" in
1156         *drm*)
1157             enable_gbm=yes ;;
1158          *)
1159             enable_gbm=no ;;
1160     esac
1161 fi
1162 if test "x$enable_gbm" = xyes; then
1163     if test x"$have_libudev" != xyes; then
1164         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1165     fi
1166
1167     if test "x$enable_dri" = xyes; then
1168         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1169         if test "x$enable_shared_glapi" = xno; then
1170             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1171         fi
1172     fi
1173 fi
1174 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1175 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1176 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1177 AC_SUBST([GBM_PC_REQ_PRIV])
1178 AC_SUBST([GBM_PC_LIB_PRIV])
1179
1180 dnl
1181 dnl EGL configuration
1182 dnl
1183 EGL_CLIENT_APIS=""
1184
1185 if test "x$enable_egl" = xyes; then
1186     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1187
1188     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1189
1190     if test "$enable_static" != yes; then
1191         if test "x$enable_dri" = xyes; then
1192             HAVE_EGL_DRIVER_DRI2=1
1193         fi
1194
1195     fi
1196 fi
1197 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1198 AC_SUBST([EGL_LIB_DEPS])
1199
1200 dnl
1201 dnl EGL Gallium configuration
1202 dnl
1203 if test "x$enable_gallium_egl" = xyes; then
1204     if test -z "$with_gallium_drivers"; then
1205         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1206     fi
1207     if test "x$enable_egl" = xno; then
1208         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1209     fi
1210     if test "x$have_libdrm" != xyes; then
1211         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1212     fi
1213
1214     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1215     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1216 fi
1217 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1218
1219 dnl
1220 dnl gbm Gallium configuration
1221 dnl
1222 if test "x$enable_gallium_gbm" = xauto; then
1223     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1224         yesyesyes*drm*)
1225             enable_gallium_gbm=yes ;;
1226          *)
1227             enable_gallium_gbm=no ;;
1228     esac
1229 fi
1230 if test "x$enable_gallium_gbm" = xyes; then
1231     if test -z "$with_gallium_drivers"; then
1232         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1233     fi
1234     if test "x$enable_gbm" = xno; then
1235         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1236     fi
1237     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1238     if test "x$enable_dri" = xno; then
1239         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1240     fi
1241
1242     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1243     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1244     enable_gallium_loader=yes
1245 fi
1246 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1247
1248 dnl
1249 dnl XA configuration
1250 dnl
1251 if test "x$enable_xa" = xyes; then
1252     if test "x$with_gallium_drivers" = xswrast; then
1253        AC_MSG_ERROR([
1254           Building xa requires at least one non swrast gallium driver.
1255           If you are looking to use libxatracker.so with vmware's virtual gpu,
1256           make sure to include svga in the gallium drivers list, apart from
1257           enabling XA.
1258           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1259     fi
1260     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1261     enable_gallium_loader=yes
1262 fi
1263 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1264
1265 dnl
1266 dnl OpenVG configuration
1267 dnl
1268 VG_LIB_DEPS=""
1269
1270 if test "x$enable_openvg" = xyes; then
1271     if test "x$enable_egl" = xno; then
1272         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1273     fi
1274     if test -z "$with_gallium_drivers"; then
1275         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1276     fi
1277     if test "x$enable_gallium_egl" = xno; then
1278         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1279     fi
1280
1281     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1282     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1283     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1284     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1285     AC_SUBST([VG_PC_LIB_PRIV])
1286 fi
1287 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1288
1289 dnl
1290 dnl Gallium G3DVL configuration
1291 dnl
1292 if test -n "$with_gallium_drivers"; then
1293     if test "x$enable_xvmc" = xauto; then
1294         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1295     fi
1296
1297     if test "x$enable_vdpau" = xauto; then
1298         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1299     fi
1300
1301     if test "x$enable_omx" = xauto; then
1302         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1303     fi
1304 fi
1305
1306 if test "x$enable_xvmc" = xyes; then
1307     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1308     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1309 fi
1310 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1311
1312 if test "x$enable_vdpau" = xyes; then
1313     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1314                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1315     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1316 fi
1317 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1318
1319 if test "x$enable_omx" = xyes; then
1320     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1321     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1322 fi
1323 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1324
1325 dnl
1326 dnl OpenCL configuration
1327 dnl
1328
1329 AC_ARG_WITH([libclc-path],
1330    [AS_HELP_STRING([--with-libclc-path],
1331          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1332    [LIBCLC_PATH="$withval"],
1333    [LIBCLC_PATH=''])
1334
1335 if test -n "$LIBCLC_PATH"; then
1336    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1337                   Please review the updated build instructions for clover:
1338                   http://dri.freedesktop.org/wiki/GalliumCompute])
1339 fi
1340
1341
1342 AC_ARG_WITH([clang-libdir],
1343    [AS_HELP_STRING([--with-clang-libdir],
1344          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1345    [CLANG_LIBDIR="$withval"],
1346    [CLANG_LIBDIR=''])
1347
1348 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1349
1350 if test "x$enable_opencl" = xyes; then
1351     if test -z "$with_gallium_drivers"; then
1352         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1353     fi
1354
1355     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1356         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1357     fi
1358
1359     if test "x$have_libclc" = xno; then
1360         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1361                     Make sure the directory containing libclc.pc is specified in your
1362                     PKG_CONFIG_PATH environment variable.
1363                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1364     else
1365         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1366         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1367         AC_SUBST([LIBCLC_INCLUDEDIR])
1368         AC_SUBST([LIBCLC_LIBEXECDIR])
1369     fi
1370
1371     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1372     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1373     enable_gallium_loader=yes
1374
1375     if test "x$enable_opencl_icd" = xyes; then
1376         OPENCL_LIBNAME="MesaOpenCL"
1377     else
1378         OPENCL_LIBNAME="OpenCL"
1379     fi
1380 fi
1381 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1382 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1383 AC_SUBST([OPENCL_LIBNAME])
1384
1385 dnl
1386 dnl Gallium configuration
1387 dnl
1388 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1389
1390 AC_SUBST([LLVM_BINDIR])
1391 AC_SUBST([LLVM_CFLAGS])
1392 AC_SUBST([LLVM_CPPFLAGS])
1393 AC_SUBST([LLVM_CXXFLAGS])
1394 AC_SUBST([LLVM_LIBDIR])
1395 AC_SUBST([LLVM_LIBS])
1396 AC_SUBST([LLVM_LDFLAGS])
1397 AC_SUBST([LLVM_INCLUDEDIR])
1398 AC_SUBST([LLVM_VERSION])
1399 AC_SUBST([CLANG_RESOURCE_DIR])
1400
1401 case "x$enable_opengl$enable_gles1$enable_gles2" in
1402 x*yes*)
1403     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1404     ;;
1405 esac
1406
1407 AC_SUBST([VG_LIB_DEPS])
1408 AC_SUBST([EGL_CLIENT_APIS])
1409
1410 dnl
1411 dnl EGL Platforms configuration
1412 dnl
1413 AC_ARG_WITH([egl-platforms],
1414     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1415         [comma delimited native platforms libEGL supports, e.g.
1416         "x11,drm" @<:@default=auto@:>@])],
1417     [with_egl_platforms="$withval"],
1418     [if test "x$enable_egl" = xyes; then
1419         with_egl_platforms="x11"
1420     else
1421         with_egl_platforms=""
1422     fi])
1423
1424 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1425     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1426 fi
1427
1428 # Do per-EGL platform setups and checks
1429 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1430 for plat in $egl_platforms; do
1431         case "$plat" in
1432         wayland)
1433                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1434                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1435
1436                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1437                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1438                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1439                 ;;
1440
1441         x11)
1442                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1443                 ;;
1444
1445         drm)
1446                 test "x$enable_gbm" = "xno" &&
1447                         AC_MSG_ERROR([EGL platform drm needs gbm])
1448                 test "x$have_libdrm" != xyes &&
1449                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1450                 ;;
1451
1452         android|fbdev|gdi|null)
1453                 ;;
1454
1455         *)
1456                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1457                 ;;
1458         esac
1459
1460         case "$plat$have_libudev" in
1461                 waylandno|drmno)
1462                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1463         esac
1464 done
1465
1466 # libEGL wants to default to the first platform specified in
1467 # ./configure.  parse that here.
1468 if test "x$egl_platforms" != "x"; then
1469     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1470     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1471 else
1472     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1473 fi
1474
1475 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1476     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1477     NEED_WINSYS_XLIB=yes
1478 fi
1479 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1480 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1481 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1482 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1483 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1484
1485 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1486
1487 AC_SUBST([EGL_NATIVE_PLATFORM])
1488 AC_SUBST([EGL_CFLAGS])
1489
1490 # If we don't have the X11 platform, set this define so we don't try to include
1491 # the X11 headers.
1492 if ! echo "$egl_platforms" | grep -q 'x11'; then
1493     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1494     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1495 fi
1496
1497 AC_ARG_WITH([egl-driver-dir],
1498     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1499                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1500     [EGL_DRIVER_INSTALL_DIR="$withval"],
1501     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1502 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1503
1504 AC_ARG_WITH([max-width],
1505     [AS_HELP_STRING([--with-max-width=N],
1506                     [Maximum framebuffer width (4096)])],
1507     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1508      AS_IF([test "${withval}" -gt "4096"],
1509            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1510 )
1511 AC_ARG_WITH([max-height],
1512     [AS_HELP_STRING([--with-max-height=N],
1513                     [Maximum framebuffer height (4096)])],
1514     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1515      AS_IF([test "${withval}" -gt "4096"],
1516            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1517 )
1518
1519 dnl
1520 dnl Gallium LLVM
1521 dnl
1522 AC_ARG_ENABLE([gallium-llvm],
1523     [AS_HELP_STRING([--enable-gallium-llvm],
1524         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1525     [enable_gallium_llvm="$enableval"],
1526     [enable_gallium_llvm=auto])
1527
1528 AC_ARG_ENABLE([llvm-shared-libs],
1529     [AS_HELP_STRING([--enable-llvm-shared-libs],
1530         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1531     [],
1532     [with_llvm_shared_libs=yes])
1533
1534 AC_ARG_WITH([llvm-prefix],
1535     [AS_HELP_STRING([--with-llvm-prefix],
1536         [Prefix for LLVM installations in non-standard locations])],
1537     [llvm_prefix="$withval"],
1538     [llvm_prefix=''])
1539
1540
1541 # Call this inside ` ` to get the return value.
1542 # $1 is the llvm-config command with arguments.
1543 strip_unwanted_llvm_flags() {
1544     # Use \> (marks the end of the word)
1545     echo `$1` | sed \
1546         -e 's/-DNDEBUG\>//g' \
1547         -e 's/-pedantic\>//g' \
1548         -e 's/-Wcovered-switch-default\>//g' \
1549         -e 's/-O.\>//g' \
1550         -e 's/-g\>//g' \
1551         -e 's/-Wall\>//g' \
1552         -e 's/-fcolor-diagnostics\>//g' \
1553         -e 's/-fomit-frame-pointer\>//g'
1554 }
1555
1556
1557 if test -z "$with_gallium_drivers"; then
1558     enable_gallium_llvm=no
1559 fi
1560 if test "x$enable_gallium_llvm" = xauto; then
1561     case "$host_cpu" in
1562     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1563     esac
1564 fi
1565 if test "x$enable_gallium_llvm" = xyes; then
1566     if test -n "$llvm_prefix"; then
1567         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1568     else
1569         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1570     fi
1571
1572     if test "x$LLVM_CONFIG" != xno; then
1573         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1574         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1575         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1576         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1577         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1578         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1579         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1580         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1581         LLVM_LDFLAGS="-Wl,-rpath,$LLVM_LIBDIR $LLVM_LDFLAGS"
1582
1583         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1584             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1585         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1586             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1587
1588         if test -n "${LLVM_VERSION_MAJOR}"; then
1589             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1590         else
1591             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1592         fi
1593
1594         LLVM_COMPONENTS="engine bitwriter"
1595         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1596             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1597         fi
1598
1599         if test "x$enable_opencl" = xyes; then
1600             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1601             # LLVM 3.3 >= 177971 requires IRReader
1602             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1603                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1604             fi
1605             # LLVM 3.4 requires Option
1606             if $LLVM_CONFIG --components | grep -qw 'option'; then
1607                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1608             fi
1609         fi
1610         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1611         MESA_LLVM=1
1612
1613         dnl Check for Clang internal headers
1614         if test "x$enable_opencl" = xyes; then
1615             if test -z "$CLANG_LIBDIR"; then
1616                 CLANG_LIBDIR=${LLVM_LIBDIR}
1617             fi
1618             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1619             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1620                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1621         fi
1622     else
1623         MESA_LLVM=0
1624         LLVM_VERSION_INT=0
1625     fi
1626 else
1627     MESA_LLVM=0
1628     LLVM_VERSION_INT=0
1629 fi
1630
1631 dnl Directory for XVMC libs
1632 AC_ARG_WITH([xvmc-libdir],
1633     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1634         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1635     [XVMC_LIB_INSTALL_DIR="$withval"],
1636     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1637 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1638
1639 dnl
1640 dnl Gallium Tests
1641 dnl
1642 if test "x$enable_gallium_tests" = xyes; then
1643     enable_gallium_loader=yes
1644 fi
1645 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1646
1647 if test "x$enable_gallium_loader" = xyes; then
1648     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1649 fi
1650 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1651
1652 dnl Directory for VDPAU libs
1653 AC_ARG_WITH([vdpau-libdir],
1654     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1655         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1656     [VDPAU_LIB_INSTALL_DIR="$withval"],
1657     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1658 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1659
1660 AC_ARG_WITH([omx-libdir],
1661     [AS_HELP_STRING([--with-omx-libdir=DIR],
1662         [directory for the OMX libraries])],
1663     [OMX_LIB_INSTALL_DIR="$withval"],
1664     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1665 AC_SUBST([OMX_LIB_INSTALL_DIR])
1666
1667 dnl Directory for OpenCL libs
1668 AC_ARG_WITH([opencl-libdir],
1669     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1670         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1671     [OPENCL_LIB_INSTALL_DIR="$withval"],
1672     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1673 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1674
1675 dnl
1676 dnl Gallium helper functions
1677 dnl
1678 gallium_check_st() {
1679     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1680          if test "x$have_libdrm" != xyes; then
1681             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1682          fi
1683          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1684     fi
1685     if test "x$enable_dri" = xyes && test -n "$2"; then
1686          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1687     fi
1688     if test "x$enable_xa" = xyes && test -n "$3"; then
1689          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1690     fi
1691     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1692          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1693     fi
1694     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1695          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1696     fi
1697     if test "x$enable_omx" = xyes && test "x$6" != x; then
1698          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1699     fi
1700 }
1701
1702 gallium_require_llvm() {
1703     if test "x$MESA_LLVM" = x0; then
1704         case "$host_cpu" in
1705         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1706         esac
1707     fi
1708 }
1709
1710 gallium_require_drm_loader() {
1711     if test "x$enable_gallium_loader" = xyes; then
1712         if test "x$have_libudev" != xyes; then
1713             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1714         fi
1715         if test "x$have_libdrm" != xyes; then
1716             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1717         fi
1718         enable_gallium_drm_loader=yes
1719     fi
1720 }
1721
1722 radeon_llvm_check() {
1723     if test "x$enable_gallium_llvm" != "xyes"; then
1724         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1725     fi
1726     LLVM_REQUIRED_VERSION_MAJOR="3"
1727     LLVM_REQUIRED_VERSION_MINOR="3"
1728     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1729         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1730     fi
1731     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1732         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1733                       sources with the --enable-experimental-targets=R600
1734                       configure flag])
1735     fi
1736     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1737     NEED_RADEON_LLVM=yes
1738     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1739                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1740 }
1741
1742 dnl Gallium drivers
1743 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1744         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1745     NEED_NONNULL_WINSYS=yes
1746 fi
1747 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1748
1749 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1750 if test -n "$with_gallium_drivers"; then
1751     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1752     for driver in $gallium_drivers; do
1753         case "x$driver" in
1754         xsvga)
1755             HAVE_GALLIUM_SVGA=yes
1756             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1757             gallium_require_drm_loader
1758             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1759             ;;
1760         xi915)
1761             HAVE_GALLIUM_I915=yes
1762             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1763             gallium_require_drm_loader
1764             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1765             if test "x$MESA_LLVM" = x1; then
1766                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1767             fi
1768             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1769             gallium_check_st "i915/drm" "dri-i915"
1770             DRICOMMON_NEED_LIBDRM=yes
1771             ;;
1772         xilo)
1773             HAVE_GALLIUM_ILO=yes
1774             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1775             gallium_require_drm_loader
1776             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1777             gallium_check_st "intel/drm" "dri-ilo"
1778             DRICOMMON_NEED_LIBDRM=yes
1779             ;;
1780         xr300)
1781             HAVE_GALLIUM_R300=yes
1782             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1783             gallium_require_drm_loader
1784             gallium_require_llvm "Gallium R300"
1785             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1786             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1787             DRICOMMON_NEED_LIBDRM=yes
1788             ;;
1789         xr600)
1790             HAVE_GALLIUM_R600=yes
1791             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1792             gallium_require_drm_loader
1793             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1794             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1795                 radeon_llvm_check "r600g"
1796                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1797             fi
1798             if test "x$enable_r600_llvm" = xyes; then
1799                 USE_R600_LLVM_COMPILER=yes;
1800             fi
1801             if test "x$enable_opencl" = xyes; then
1802                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1803             fi
1804             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1805             DRICOMMON_NEED_LIBDRM=yes
1806             ;;
1807         xradeonsi)
1808             HAVE_GALLIUM_RADEONSI=yes
1809             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1810             gallium_require_drm_loader
1811             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1812             radeon_llvm_check "radeonsi"
1813             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1814             DRICOMMON_NEED_LIBDRM=yes
1815             ;;
1816         xnouveau)
1817             HAVE_GALLIUM_NOUVEAU=yes
1818             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1819             gallium_require_drm_loader
1820             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1821             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1822             DRICOMMON_NEED_LIBDRM=yes
1823             ;;
1824         xfreedreno)
1825             HAVE_GALLIUM_FREEDRENO=yes
1826             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1827             gallium_require_drm_loader
1828             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1829             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1830             DRICOMMON_NEED_LIBDRM=yes
1831             ;;
1832         xswrast)
1833             HAVE_GALLIUM_SOFTPIPE=yes
1834             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1835             if test "x$MESA_LLVM" = x1; then
1836                 HAVE_GALLIUM_LLVMPIPE=yes
1837                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1838             fi
1839
1840             if test "x$enable_dri" = xyes; then
1841                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1842             fi
1843             ;;
1844         *)
1845             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1846             ;;
1847         esac
1848     done
1849 fi
1850
1851 dnl Set LLVM_LIBS - This is done after the driver configuration so
1852 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1853 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1854 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1855 dnl this was causing the same libraries to be appear multiple times
1856 dnl in LLVM_LIBS.
1857
1858 if test "x$MESA_LLVM" != x0; then
1859
1860     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1861
1862     if test "x$with_llvm_shared_libs" = xyes; then
1863         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1864         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1865         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1866
1867         if test "x$llvm_have_one_so" = xyes; then
1868             dnl LLVM was built using auto*, so there is only one shared object.
1869             LLVM_LIBS="-l$LLVM_SO_NAME"
1870         else
1871             dnl If LLVM was built with CMake, there will be one shared object per
1872             dnl component.
1873             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1874                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1875         Please make sure you have built llvm with the --enable-shared option
1876         and that your llvm libraries are installed in $LLVM_LIBDIR
1877         If you have installed your llvm libraries to a different directory you
1878         can use the --with-llvm-prefix= configure flag to specify this directory.
1879         NOTE: Mesa is attempting to use llvm shared libraries because you have
1880         passed one of the following options to configure:
1881                 --with-llvm-shared-libs
1882                 --enable-opencl
1883         If you do not want to build with llvm shared libraries and instead want to
1884         use llvm static libraries then remove these options from your configure
1885         invocation and reconfigure.])])
1886
1887            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1888            dnl install uses a shared object for each compoenent and we have
1889            dnl already added all of these objects to LLVM_LIBS.
1890         fi
1891     fi
1892 fi
1893
1894 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1897 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1898 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1899 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1900 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1901 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1902 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1903 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1904
1905 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1906                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1907                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1908 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1909                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1910                                                   && test "x$MESA_LLVM" = x1)
1911
1912 # NOTE: anything using xcb or other client side libs ends up in separate
1913 #       _CLIENT variables.  The pipe loader is built in two variants,
1914 #       one that is standalone and does not link any x client libs (for
1915 #       use by XA tracker in particular, but could be used in any case
1916 #       where communication with xserver is not desired).
1917 if test "x$enable_gallium_loader" = xyes; then
1918     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1919
1920     if test "x$enable_gallium_xlib_loader" = xyes; then
1921         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1922         NEED_WINSYS_XLIB="yes"
1923         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1924     fi
1925
1926     if test "x$enable_gallium_drm_loader" = xyes; then
1927         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1928         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1929                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1930         if test "x$pipe_loader_have_xcb" = xyes; then
1931             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1932             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1933         fi
1934     fi
1935
1936     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1937     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1938
1939     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1940     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1941     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1942     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1943 fi
1944 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1945
1946 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1947 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1948 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1949 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1950 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1951 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1952
1953 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1954                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1955                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1956                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1957 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1958                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1959 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1960 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1961 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1962 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1963 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1964 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1965 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1966
1967 AC_SUBST([ELF_LIB])
1968
1969 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1970 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1971 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1972 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1973 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1974
1975 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1976 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1977 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1978
1979 AC_SUBST([VDPAU_MAJOR], 1)
1980 AC_SUBST([VDPAU_MINOR], 0)
1981
1982 AC_SUBST([XVMC_MAJOR], 1)
1983 AC_SUBST([XVMC_MINOR], 0)
1984
1985 AC_SUBST([XA_MAJOR], 2)
1986 AC_SUBST([XA_MINOR], 2)
1987 AC_SUBST([XA_TINY], 0)
1988 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1989
1990 dnl Restore LDFLAGS and CPPFLAGS
1991 LDFLAGS="$_SAVE_LDFLAGS"
1992 CPPFLAGS="$_SAVE_CPPFLAGS"
1993
1994 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1995 if test "x$acv_mesa_CLANG" = xyes; then
1996     CFLAGS="$CFLAGS -Qunused-arguments"
1997     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1998 fi
1999
2000 dnl Add user CFLAGS and CXXFLAGS
2001 CFLAGS="$CFLAGS $USER_CFLAGS"
2002 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2003
2004 dnl Substitute the config
2005 AC_CONFIG_FILES([Makefile
2006                 src/Makefile
2007                 src/egl/Makefile
2008                 src/egl/drivers/Makefile
2009                 src/egl/drivers/dri2/Makefile
2010                 src/egl/main/Makefile
2011                 src/egl/main/egl.pc
2012                 src/egl/wayland/Makefile
2013                 src/egl/wayland/wayland-drm/Makefile
2014                 src/egl/wayland/wayland-egl/Makefile
2015                 src/egl/wayland/wayland-egl/wayland-egl.pc
2016                 src/gallium/auxiliary/Makefile
2017                 src/gallium/auxiliary/pipe-loader/Makefile
2018                 src/gallium/drivers/Makefile
2019                 src/gallium/drivers/freedreno/Makefile
2020                 src/gallium/drivers/galahad/Makefile
2021                 src/gallium/drivers/i915/Makefile
2022                 src/gallium/drivers/identity/Makefile
2023                 src/gallium/drivers/ilo/Makefile
2024                 src/gallium/drivers/llvmpipe/Makefile
2025                 src/gallium/drivers/noop/Makefile
2026                 src/gallium/drivers/nouveau/Makefile
2027                 src/gallium/drivers/r300/Makefile
2028                 src/gallium/drivers/r600/Makefile
2029                 src/gallium/drivers/radeon/Makefile
2030                 src/gallium/drivers/radeonsi/Makefile
2031                 src/gallium/drivers/rbug/Makefile
2032                 src/gallium/drivers/softpipe/Makefile
2033                 src/gallium/drivers/svga/Makefile
2034                 src/gallium/drivers/trace/Makefile
2035                 src/gallium/state_trackers/Makefile
2036                 src/gallium/state_trackers/clover/Makefile
2037                 src/gallium/state_trackers/dri/Makefile
2038                 src/gallium/state_trackers/dri/drm/Makefile
2039                 src/gallium/state_trackers/dri/sw/Makefile
2040                 src/gallium/state_trackers/egl/Makefile
2041                 src/gallium/state_trackers/gbm/Makefile
2042                 src/gallium/state_trackers/glx/xlib/Makefile
2043                 src/gallium/state_trackers/omx/Makefile
2044                 src/gallium/state_trackers/osmesa/Makefile
2045                 src/gallium/state_trackers/vdpau/Makefile
2046                 src/gallium/state_trackers/vega/Makefile
2047                 src/gallium/state_trackers/xa/Makefile
2048                 src/gallium/state_trackers/xvmc/Makefile
2049                 src/gallium/targets/Makefile
2050                 src/gallium/targets/dri-freedreno/Makefile
2051                 src/gallium/targets/dri-i915/Makefile
2052                 src/gallium/targets/dri-ilo/Makefile
2053                 src/gallium/targets/dri-nouveau/Makefile
2054                 src/gallium/targets/dri-swrast/Makefile
2055                 src/gallium/targets/dri-vmwgfx/Makefile
2056                 src/gallium/targets/egl-static/Makefile
2057                 src/gallium/targets/gbm/Makefile
2058                 src/gallium/targets/opencl/Makefile
2059                 src/gallium/targets/xa/Makefile
2060                 src/gallium/targets/xa/xatracker.pc
2061                 src/gallium/targets/osmesa/Makefile
2062                 src/gallium/targets/osmesa/osmesa.pc
2063                 src/gallium/targets/pipe-loader/Makefile
2064                 src/gallium/targets/radeonsi/dri/Makefile
2065                 src/gallium/targets/radeonsi/omx/Makefile
2066                 src/gallium/targets/radeonsi/vdpau/Makefile
2067                 src/gallium/targets/r300/dri/Makefile
2068                 src/gallium/targets/r600/dri/Makefile
2069                 src/gallium/targets/r600/omx/Makefile
2070                 src/gallium/targets/r600/vdpau/Makefile
2071                 src/gallium/targets/r600/xvmc/Makefile
2072                 src/gallium/targets/libgl-xlib/Makefile
2073                 src/gallium/targets/vdpau-nouveau/Makefile
2074                 src/gallium/targets/xvmc-nouveau/Makefile
2075                 src/gallium/tests/trivial/Makefile
2076                 src/gallium/tests/unit/Makefile
2077                 src/gallium/winsys/Makefile
2078                 src/gallium/winsys/freedreno/drm/Makefile
2079                 src/gallium/winsys/i915/drm/Makefile
2080                 src/gallium/winsys/i915/sw/Makefile
2081                 src/gallium/winsys/intel/drm/Makefile
2082                 src/gallium/winsys/nouveau/drm/Makefile
2083                 src/gallium/winsys/radeon/drm/Makefile
2084                 src/gallium/winsys/svga/drm/Makefile
2085                 src/gallium/winsys/sw/dri/Makefile
2086                 src/gallium/winsys/sw/fbdev/Makefile
2087                 src/gallium/winsys/sw/null/Makefile
2088                 src/gallium/winsys/sw/wayland/Makefile
2089                 src/gallium/winsys/sw/wrapper/Makefile
2090                 src/gallium/winsys/sw/xlib/Makefile
2091                 src/gbm/Makefile
2092                 src/gbm/main/gbm.pc
2093                 src/glsl/Makefile
2094                 src/glx/Makefile
2095                 src/glx/tests/Makefile
2096                 src/gtest/Makefile
2097                 src/loader/Makefile
2098                 src/mapi/Makefile
2099                 src/mapi/es1api/Makefile
2100                 src/mapi/es1api/glesv1_cm.pc
2101                 src/mapi/es2api/Makefile
2102                 src/mapi/es2api/glesv2.pc
2103                 src/mapi/glapi/Makefile
2104                 src/mapi/glapi/gen/Makefile
2105                 src/mapi/glapi/tests/Makefile
2106                 src/mapi/shared-glapi/Makefile
2107                 src/mapi/shared-glapi/tests/Makefile
2108                 src/mapi/vgapi/Makefile
2109                 src/mapi/vgapi/vg.pc
2110                 src/mesa/Makefile
2111                 src/mesa/gl.pc
2112                 src/mesa/drivers/dri/dri.pc
2113                 src/mesa/drivers/dri/common/Makefile
2114                 src/mesa/drivers/dri/common/xmlpool/Makefile
2115                 src/mesa/drivers/dri/i915/Makefile
2116                 src/mesa/drivers/dri/i965/Makefile
2117                 src/mesa/drivers/dri/Makefile
2118                 src/mesa/drivers/dri/nouveau/Makefile
2119                 src/mesa/drivers/dri/r200/Makefile
2120                 src/mesa/drivers/dri/radeon/Makefile
2121                 src/mesa/drivers/dri/swrast/Makefile
2122                 src/mesa/drivers/osmesa/Makefile
2123                 src/mesa/drivers/osmesa/osmesa.pc
2124                 src/mesa/drivers/x11/Makefile
2125                 src/mesa/main/tests/Makefile
2126                 src/mesa/main/tests/hash_table/Makefile])
2127
2128 dnl Sort the dirs alphabetically
2129 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2130 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2131 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2132 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2133
2134 AC_OUTPUT
2135
2136 dnl
2137 dnl Output some configuration info for the user
2138 dnl
2139 echo ""
2140 echo "        prefix:          $prefix"
2141 echo "        exec_prefix:     $exec_prefix"
2142 echo "        libdir:          $libdir"
2143 echo "        includedir:      $includedir"
2144
2145 dnl API info
2146 echo ""
2147 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2148 echo "        OpenVG:          $enable_openvg"
2149
2150 dnl Driver info
2151 echo ""
2152 case "x$enable_osmesa$enable_gallium_osmesa" in
2153 xnoyes)
2154         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2155         ;;
2156 xyesno)
2157         echo "        OSMesa:          lib$OSMESA_LIB"
2158         ;;
2159 xnono)
2160         echo "        OSMesa:          no"
2161         ;;
2162 esac
2163
2164 if test "x$enable_dri" != xno; then
2165         if test -z "$DRI_DIRS"; then
2166             echo "        DRI drivers:     no"
2167         else
2168             echo "        DRI drivers:     $DRI_DIRS"
2169         fi
2170         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2171 fi
2172
2173 case "x$enable_glx$enable_xlib_glx" in
2174 xyesyes)
2175     echo "        GLX:             Xlib-based"
2176     ;;
2177 xyesno)
2178     echo "        GLX:             DRI-based"
2179     ;;
2180 *)
2181     echo "        GLX:             $enable_glx"
2182     ;;
2183 esac
2184
2185 dnl EGL
2186 echo ""
2187 echo "        EGL:             $enable_egl"
2188 if test "$enable_egl" = yes; then
2189     echo "        EGL platforms:   $egl_platforms"
2190
2191     egl_drivers=""
2192     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2193         egl_drivers="$egl_drivers builtin:egl_dri2"
2194     fi
2195
2196     if test "x$enable_gallium_egl" = xyes; then
2197         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2198         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2199     else
2200         echo "        EGL drivers:    $egl_drivers"
2201     fi
2202 fi
2203
2204 echo ""
2205 if test "x$MESA_LLVM" = x1; then
2206     echo "        llvm:            yes"
2207     echo "        llvm-config:     $LLVM_CONFIG"
2208     echo "        llvm-version:    $LLVM_VERSION"
2209 else
2210     echo "        llvm:            no"
2211 fi
2212
2213 echo ""
2214 if test -n "$with_gallium_drivers"; then
2215     echo "        Gallium:         yes"
2216     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2217     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2218     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2219     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2220 else
2221     echo "        Gallium:         no"
2222 fi
2223
2224
2225 dnl Libraries
2226 echo ""
2227 echo "        Shared libs:     $enable_shared"
2228 echo "        Static libs:     $enable_static"
2229 echo "        Shared-glapi:    $enable_shared_glapi"
2230
2231 dnl Compiler options
2232 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2233 cflags=`echo $CFLAGS | \
2234     $SED 's/^ *//;s/  */ /;s/ *$//'`
2235 cxxflags=`echo $CXXFLAGS | \
2236     $SED 's/^ *//;s/  */ /;s/ *$//'`
2237 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2238 echo ""
2239 echo "        CFLAGS:          $cflags"
2240 echo "        CXXFLAGS:        $cxxflags"
2241 echo "        Macros:          $defines"
2242 echo ""
2243 if test "x$MESA_LLVM" = x1; then
2244     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2245     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2246     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2247     echo ""
2248 fi
2249 echo "        PYTHON2:         $PYTHON2"
2250
2251 echo ""
2252 echo "        Run '${MAKE-make}' to build Mesa"
2253 echo ""