configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.60
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126 if test -n "$PYTHON2" -a "x$acv_mako_found" = "xyes"; then
 127     AC_MSG_RESULT(yes)
 128 else
 129     AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 130 fi
 131
 132 AC_PROG_INSTALL
 133
 134 dnl We need a POSIX shell for parts of the build. Assume we have one
 135 dnl in most cases.
 136 case "$host_os" in
 137 solaris*)
 138     # Solaris /bin/sh is too old/non-POSIX compliant
 139     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 140     SHELL="$POSIX_SHELL"
 141     ;;
 142 esac
 143
 144 dnl clang is mostly GCC-compatible, but its version is much lower,
 145 dnl so we have to check for it.
 146 AC_MSG_CHECKING([if compiling with clang])
 147
 148 AC_COMPILE_IFELSE(
 149 [AC_LANG_PROGRAM([], [[
 150 #ifndef __clang__
 151        not clang
 152 #endif
 153 ]])],
 154 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 155
 156 AC_MSG_RESULT([$acv_mesa_CLANG])
 157
 158 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 159 dnl versions are explictly not supported.
 160 GEN_ASM_OFFSETS=no
 161 USE_GNU99=no
 162 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 163     AC_MSG_CHECKING([whether gcc version is sufficient])
 164     major=0
 165     minor=0
 166
 167     GCC_VERSION=`$CC -dumpversion`
 168     if test $? -eq 0; then
 169         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 170         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 171     fi
 172
 173     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 174         AC_MSG_RESULT([no])
 175         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 176     else
 177         AC_MSG_RESULT([yes])
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 181         USE_GNU99=yes
 182     fi
 183     if test "x$cross_compiling" = xyes; then
 184         GEN_ASM_OFFSETS=yes
 185     fi
 186 fi
 187
 188 dnl Check for compiler builtins
 189 AX_GCC_BUILTIN([__builtin_bswap32])
 190 AX_GCC_BUILTIN([__builtin_bswap64])
 191 AX_GCC_BUILTIN([__builtin_clz])
 192 AX_GCC_BUILTIN([__builtin_clzll])
 193 AX_GCC_BUILTIN([__builtin_ctz])
 194 AX_GCC_BUILTIN([__builtin_expect])
 195 AX_GCC_BUILTIN([__builtin_ffs])
 196 AX_GCC_BUILTIN([__builtin_ffsll])
 197 AX_GCC_BUILTIN([__builtin_popcount])
 198 AX_GCC_BUILTIN([__builtin_popcountll])
 199 AX_GCC_BUILTIN([__builtin_unreachable])
 200
 201 AX_GCC_FUNC_ATTRIBUTE([flatten])
 202 AX_GCC_FUNC_ATTRIBUTE([format])
 203 AX_GCC_FUNC_ATTRIBUTE([malloc])
 204 AX_GCC_FUNC_ATTRIBUTE([packed])
 205 AX_GCC_FUNC_ATTRIBUTE([unused])
 206
 207 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 208
 209 dnl Make sure the pkg-config macros are defined
 210 m4_ifndef([PKG_PROG_PKG_CONFIG],
 211     [m4_fatal([Could not locate the pkg-config autoconf macros.
 212   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 213   are in a different location, try setting the environment variable
 214   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 215 PKG_PROG_PKG_CONFIG()
 216
 217 dnl LIB_DIR - library basename
 218 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 219 AC_SUBST([LIB_DIR])
 220
 221 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 222 _SAVE_LDFLAGS="$LDFLAGS"
 223 _SAVE_CPPFLAGS="$CPPFLAGS"
 224
 225 dnl Compiler macros
 226 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 227 AC_SUBST([DEFINES])
 228 case "$host_os" in
 229 linux*|*-gnu*|gnu*)
 230     DEFINES="$DEFINES -D_GNU_SOURCE"
 231     ;;
 232 solaris*)
 233     DEFINES="$DEFINES -DSVR4"
 234     ;;
 235 cygwin*)
 236     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 237     ;;
 238 esac
 239
 240 dnl Add flags for gcc and g++
 241 if test "x$GCC" = xyes; then
 242     CFLAGS="$CFLAGS -Wall"
 243
 244     if test "x$USE_GNU99" = xyes; then
 245         CFLAGS="$CFLAGS -std=gnu99"
 246     else
 247         CFLAGS="$CFLAGS -std=c99"
 248     fi
 249
 250     # Enable -Werror=implicit-function-declaration and
 251     # -Werror=missing-prototypes, if available, or otherwise, just
 252     # -Wmissing-prototypes.  This is particularly useful to avoid
 253     # generating a loadable driver module that has undefined symbols.
 254     save_CFLAGS="$CFLAGS"
 255     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 256     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 257     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 258     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 259                    AC_MSG_RESULT([yes]),
 260                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 261                     AC_MSG_RESULT([no])]);
 262
 263     # Enable -fvisibility=hidden if using a gcc that supports it
 264     save_CFLAGS="$CFLAGS"
 265     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 266     VISIBILITY_CFLAGS="-fvisibility=hidden"
 267     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 268     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 269                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 270
 271     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 272     CFLAGS=$save_CFLAGS
 273
 274     # Work around aliasing bugs - developers should comment this out
 275     CFLAGS="$CFLAGS -fno-strict-aliasing"
 276
 277     # gcc's builtin memcmp is slower than glibc's
 278     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 279     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 280
 281     # Flags to help ensure that certain portions of the code -- and only those
 282     # portions -- can be built with MSVC:
 283     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 284     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 285     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 286     #   supports most of C99)
 287     # - the rest has no compiler compiler restrictions
 288     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 289     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 290
 291     # Enable -Werror=vla if compiler supports it
 292     save_CFLAGS="$CFLAGS"
 293     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 294     CFLAGS="$CFLAGS -Werror=vla"
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 296                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 297                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 298                     AC_MSG_RESULT([yes])],
 299                     AC_MSG_RESULT([no]));
 300     CFLAGS="$save_CFLAGS"
 301
 302     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 303     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 304 fi
 305 if test "x$GXX" = xyes; then
 306     CXXFLAGS="$CXXFLAGS -Wall"
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CXXFLAGS="$CXXFLAGS"
 310     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 311     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 312     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 313     AC_LANG_PUSH([C++])
 314     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 315                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 316     AC_LANG_POP([C++])
 317
 318     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 319     CXXFLAGS=$save_CXXFLAGS
 320
 321     # Work around aliasing bugs - developers should comment this out
 322     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 323
 324     # gcc's builtin memcmp is slower than glibc's
 325     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 326     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 327 fi
 328
 329 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 330 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 331 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 332 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 333
 334 dnl even if the compiler appears to support it, using visibility attributes isn't
 335 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 336 case "$host_os" in
 337 cygwin*)
 338     VISIBILITY_CFLAGS=""
 339     VISIBILITY_CXXFLAGS=""
 340     ;;
 341 esac
 342
 343 AC_SUBST([VISIBILITY_CFLAGS])
 344 AC_SUBST([VISIBILITY_CXXFLAGS])
 345
 346 dnl
 347 dnl Optional flags, check for compiler support
 348 dnl
 349 SSE41_CFLAGS="-msse4.1"
 350 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 351 dnl stack, but on x86-32 such alignment is not guaranteed.
 352 case "$target_cpu" in
 353 i?86)
 354     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 355     ;;
 356 esac
 357 save_CFLAGS="$CFLAGS"
 358 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 359 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 360 #include <smmintrin.h>
 361 int main () {
 362     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 363     c = _mm_max_epu32(a, b);
 364     return 0;
 365 }]])], SSE41_SUPPORTED=1)
 366 CFLAGS="$save_CFLAGS"
 367 if test "x$SSE41_SUPPORTED" = x1; then
 368     DEFINES="$DEFINES -DUSE_SSE41"
 369 fi
 370 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 371 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 372
 373 dnl Can't have static and shared libraries, default to static if user
 374 dnl explicitly requested. If both disabled, set to static since shared
 375 dnl was explicitly requested.
 376 case "x$enable_static$enable_shared" in
 377 xyesyes)
 378     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 379     enable_shared=no
 380     ;;
 381 xnono)
 382     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 383     enable_shared=yes
 384     ;;
 385 esac
 386
 387 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 388
 389 dnl
 390 dnl other compiler options
 391 dnl
 392 AC_ARG_ENABLE([debug],
 393     [AS_HELP_STRING([--enable-debug],
 394         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 395     [enable_debug="$enableval"],
 396     [enable_debug=no]
 397 )
 398 if test "x$enable_debug" = xyes; then
 399     DEFINES="$DEFINES -DDEBUG"
 400     if test "x$GCC" = xyes; then
 401         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 402             CFLAGS="$CFLAGS -g"
 403         fi
 404         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 405             CFLAGS="$CFLAGS -O0"
 406         fi
 407     fi
 408     if test "x$GXX" = xyes; then
 409         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 410             CXXFLAGS="$CXXFLAGS -g"
 411         fi
 412         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 413             CXXFLAGS="$CXXFLAGS -O0"
 414         fi
 415     fi
 416 else
 417    DEFINES="$DEFINES -DNDEBUG"
 418 fi
 419
 420 dnl
 421 dnl Check if linker supports -Bsymbolic
 422 dnl
 423 save_LDFLAGS=$LDFLAGS
 424 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 425 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 426 AC_LINK_IFELSE(
 427     [AC_LANG_SOURCE([int main() { return 0;}])],
 428     [AC_MSG_RESULT([yes])
 429         BSYMBOLIC="-Wl,-Bsymbolic";],
 430     [AC_MSG_RESULT([no])
 431         BSYMBOLIC="";])
 432 LDFLAGS=$save_LDFLAGS
 433
 434 AC_SUBST([BSYMBOLIC])
 435
 436 dnl
 437 dnl Check if linker supports garbage collection
 438 dnl
 439 save_LDFLAGS=$LDFLAGS
 440 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 441 AC_MSG_CHECKING([whether ld supports --gc-sections])
 442 AC_LINK_IFELSE(
 443     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 444     [AC_MSG_RESULT([yes])
 445         GC_SECTIONS="-Wl,--gc-sections";],
 446     [AC_MSG_RESULT([no])
 447         GC_SECTIONS="";])
 448 LDFLAGS=$save_LDFLAGS
 449
 450 AC_SUBST([GC_SECTIONS])
 451
 452 dnl
 453 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 454 dnl so when these flags are passed to ld via libtool the checks will fail
 455 dnl
 456 case "$host_os" in
 457 openbsd* | darwin* )
 458     LD_NO_UNDEFINED="" ;;
 459 *)
 460     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 461 esac
 462
 463 AC_SUBST([LD_NO_UNDEFINED])
 464
 465 dnl
 466 dnl Check if linker supports version scripts
 467 dnl
 468 AC_MSG_CHECKING([if the linker supports version-scripts])
 469 save_LDFLAGS=$LDFLAGS
 470 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 471 cat > conftest.map <<EOF
 472 VERSION_1 {
 473      global:
 474          main;
 475
 476      local:
 477          *;
 478 };
 479 EOF
 480 AC_LINK_IFELSE(
 481     [AC_LANG_SOURCE([int main() { return 0;}])],
 482     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 483     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 484 LDFLAGS=$save_LDFLAGS
 485 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 486
 487 dnl
 488 dnl Check if linker supports dynamic list files
 489 dnl
 490 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 491 save_LDFLAGS=$LDFLAGS
 492 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 493 cat > conftest.dyn <<EOF
 494 {
 495         radeon_drm_winsys_create;
 496 };
 497 EOF
 498 AC_LINK_IFELSE(
 499     [AC_LANG_SOURCE([int main() { return 0;}])],
 500     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 501     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 502 LDFLAGS=$save_LDFLAGS
 503 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 504
 505 dnl
 506 dnl compatibility symlinks
 507 dnl
 508 case "$host_os" in
 509 linux* )
 510     HAVE_COMPAT_SYMLINKS=yes ;;
 511 * )
 512     HAVE_COMPAT_SYMLINKS=no ;;
 513 esac
 514
 515 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 516
 517 dnl
 518 dnl library names
 519 dnl
 520 case "$host_os" in
 521 darwin* )
 522     LIB_EXT='dylib' ;;
 523 cygwin* )
 524     LIB_EXT='dll' ;;
 525 aix* )
 526     LIB_EXT='a' ;;
 527 * )
 528     LIB_EXT='so' ;;
 529 esac
 530
 531 AC_SUBST([LIB_EXT])
 532
 533 AC_ARG_WITH([gl-lib-name],
 534   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 535     [specify GL library name @<:@default=GL@:>@])],
 536   [GL_LIB=$withval],
 537   [GL_LIB=GL])
 538 AC_ARG_WITH([osmesa-lib-name],
 539   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 540     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 541   [OSMESA_LIB=$withval],
 542   [OSMESA_LIB=OSMesa])
 543 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 544 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 545
 546 dnl
 547 dnl Mangled Mesa support
 548 dnl
 549 AC_ARG_ENABLE([mangling],
 550   [AS_HELP_STRING([--enable-mangling],
 551     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 552   [enable_mangling="${enableval}"],
 553   [enable_mangling=no]
 554 )
 555 if test "x${enable_mangling}" = "xyes" ; then
 556   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 557   GL_LIB="Mangled${GL_LIB}"
 558   OSMESA_LIB="Mangled${OSMESA_LIB}"
 559 fi
 560 AC_SUBST([GL_LIB])
 561 AC_SUBST([OSMESA_LIB])
 562
 563 dnl
 564 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 565 dnl
 566 AC_ARG_ENABLE([texture-float],
 567     [AS_HELP_STRING([--enable-texture-float],
 568         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 569     [enable_texture_float="$enableval"],
 570     [enable_texture_float=no]
 571 )
 572 if test "x$enable_texture_float" = xyes; then
 573     AC_MSG_WARN([Floating-point textures enabled.])
 574     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 575     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 576 fi
 577
 578 dnl
 579 dnl Arch/platform-specific settings
 580 dnl
 581 AC_ARG_ENABLE([asm],
 582     [AS_HELP_STRING([--disable-asm],
 583         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 584     [enable_asm="$enableval"],
 585     [enable_asm=yes]
 586 )
 587 asm_arch=""
 588 AC_MSG_CHECKING([whether to enable assembly])
 589 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 590 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 591 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 592     case "$host_cpu" in
 593     i?86 | x86_64 | amd64)
 594         enable_asm=no
 595         AC_MSG_RESULT([no, cross compiling])
 596         ;;
 597     esac
 598 fi
 599 # check for supported arches
 600 if test "x$enable_asm" = xyes; then
 601     case "$host_cpu" in
 602     i?86)
 603         case "$host_os" in
 604         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 605             asm_arch=x86
 606             ;;
 607         esac
 608         ;;
 609     x86_64|amd64)
 610         case "$host_os" in
 611         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 612             asm_arch=x86_64
 613             ;;
 614         esac
 615         ;;
 616     sparc*)
 617         case "$host_os" in
 618         linux*)
 619             asm_arch=sparc
 620             ;;
 621         esac
 622         ;;
 623     esac
 624
 625     case "$asm_arch" in
 626     x86)
 627         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 628         AC_MSG_RESULT([yes, x86])
 629         ;;
 630     x86_64|amd64)
 631         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 632         AC_MSG_RESULT([yes, x86_64])
 633         ;;
 634     sparc)
 635         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 636         AC_MSG_RESULT([yes, sparc])
 637         ;;
 638     *)
 639         AC_MSG_RESULT([no, platform not supported])
 640         ;;
 641     esac
 642 fi
 643
 644 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 645 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 646
 647 dnl Check to see if dlopen is in default libraries (like Solaris, which
 648 dnl has it in libc), or if libdl is needed to get it.
 649 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 650     [AC_CHECK_LIB([dl], [dlopen],
 651        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 652 AC_SUBST([DLOPEN_LIBS])
 653
 654 dnl Check if that library also has dladdr
 655 save_LIBS="$LIBS"
 656 LIBS="$LIBS $DLOPEN_LIBS"
 657 AC_CHECK_FUNCS([dladdr])
 658 LIBS="$save_LIBS"
 659
 660 case "$host_os" in
 661 darwin*)
 662     ;;
 663 *)
 664     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 665                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 666                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 667     AC_SUBST([CLOCK_LIB])
 668     ;;
 669 esac
 670
 671 dnl See if posix_memalign is available
 672 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 673
 674 dnl Check for pthreads
 675 AX_PTHREAD
 676 if test "x$ax_pthread_ok" = xno; then
 677     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 678 fi
 679 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 680 dnl to -pthread, which causes problems if we need -lpthread to appear in
 681 dnl pkgconfig files.
 682 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 683
 684 dnl SELinux awareness.
 685 AC_ARG_ENABLE([selinux],
 686     [AS_HELP_STRING([--enable-selinux],
 687         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 688     [MESA_SELINUX="$enableval"],
 689     [MESA_SELINUX=no])
 690 if test "x$enable_selinux" = "xyes"; then
 691     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 692         [AC_CHECK_HEADER([selinux/selinux.h],[],
 693                          [AC_MSG_ERROR([SELinux headers not found])])
 694          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 695                       [AC_MSG_ERROR([SELinux library not found])])
 696          SELINUX_LIBS="-lselinux"])
 697     DEFINES="$DEFINES -DMESA_SELINUX"
 698 fi
 699 AC_SUBST([SELINUX_CFLAGS])
 700 AC_SUBST([SELINUX_LIBS])
 701
 702 dnl Options for APIs
 703 AC_ARG_ENABLE([opengl],
 704     [AS_HELP_STRING([--disable-opengl],
 705         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 706     [enable_opengl="$enableval"],
 707     [enable_opengl=yes])
 708 AC_ARG_ENABLE([gles1],
 709     [AS_HELP_STRING([--enable-gles1],
 710         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 711     [enable_gles1="$enableval"],
 712     [enable_gles1=no])
 713 AC_ARG_ENABLE([gles2],
 714     [AS_HELP_STRING([--enable-gles2],
 715         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 716     [enable_gles2="$enableval"],
 717     [enable_gles2=no])
 718
 719 AC_ARG_ENABLE([dri],
 720     [AS_HELP_STRING([--enable-dri],
 721         [enable DRI modules @<:@default=enabled@:>@])],
 722     [enable_dri="$enableval"],
 723     [enable_dri=yes])
 724
 725 case "$host_os" in
 726 linux*)
 727     dri3_default=yes
 728     ;;
 729 *)
 730     dri3_default=no
 731     ;;
 732 esac
 733 AC_ARG_ENABLE([dri3],
 734     [AS_HELP_STRING([--enable-dri3],
 735         [enable DRI3 @<:@default=auto@:>@])],
 736     [enable_dri3="$enableval"],
 737     [enable_dri3="$dri3_default"])
 738 AC_ARG_ENABLE([glx],
 739     [AS_HELP_STRING([--enable-glx],
 740         [enable GLX library @<:@default=enabled@:>@])],
 741     [enable_glx="$enableval"],
 742     [enable_glx=yes])
 743 AC_ARG_ENABLE([osmesa],
 744     [AS_HELP_STRING([--enable-osmesa],
 745         [enable OSMesa library @<:@default=disabled@:>@])],
 746     [enable_osmesa="$enableval"],
 747     [enable_osmesa=no])
 748 AC_ARG_ENABLE([gallium-osmesa],
 749     [AS_HELP_STRING([--enable-gallium-osmesa],
 750         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 751     [enable_gallium_osmesa="$enableval"],
 752     [enable_gallium_osmesa=no])
 753 AC_ARG_ENABLE([egl],
 754     [AS_HELP_STRING([--disable-egl],
 755         [disable EGL library @<:@default=enabled@:>@])],
 756     [enable_egl="$enableval"],
 757     [enable_egl=yes])
 758
 759 AC_ARG_ENABLE([xa],
 760     [AS_HELP_STRING([--enable-xa],
 761         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 762     [enable_xa="$enableval"],
 763     [enable_xa=no])
 764 AC_ARG_ENABLE([gbm],
 765    [AS_HELP_STRING([--enable-gbm],
 766          [enable gbm library @<:@default=auto@:>@])],
 767    [enable_gbm="$enableval"],
 768    [enable_gbm=auto])
 769 AC_ARG_ENABLE([nine],
 770     [AS_HELP_STRING([--enable-nine],
 771         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 772     [enable_nine="$enableval"],
 773     [enable_nine=no])
 774
 775 AC_ARG_ENABLE([xvmc],
 776    [AS_HELP_STRING([--enable-xvmc],
 777          [enable xvmc library @<:@default=auto@:>@])],
 778    [enable_xvmc="$enableval"],
 779    [enable_xvmc=auto])
 780 AC_ARG_ENABLE([vdpau],
 781    [AS_HELP_STRING([--enable-vdpau],
 782          [enable vdpau library @<:@default=auto@:>@])],
 783    [enable_vdpau="$enableval"],
 784    [enable_vdpau=auto])
 785 AC_ARG_ENABLE([omx],
 786    [AS_HELP_STRING([--enable-omx],
 787          [enable OpenMAX library @<:@default=disabled@:>@])],
 788    [enable_omx="$enableval"],
 789    [enable_omx=no])
 790 AC_ARG_ENABLE([va],
 791    [AS_HELP_STRING([--enable-va],
 792          [enable va library @<:@default=auto@:>@])],
 793    [enable_va="$enableval"],
 794    [enable_va=auto])
 795 AC_ARG_ENABLE([opencl],
 796    [AS_HELP_STRING([--enable-opencl],
 797          [enable OpenCL library @<:@default=disabled@:>@])],
 798    [enable_opencl="$enableval"],
 799    [enable_opencl=no])
 800 AC_ARG_ENABLE([opencl_icd],
 801    [AS_HELP_STRING([--enable-opencl-icd],
 802           [Build an OpenCL ICD library to be loaded by an ICD implementation
 803            @<:@default=disabled@:>@])],
 804     [enable_opencl_icd="$enableval"],
 805     [enable_opencl_icd=no])
 806 AC_ARG_ENABLE([xlib-glx],
 807     [AS_HELP_STRING([--enable-xlib-glx],
 808         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 809     [enable_xlib_glx="$enableval"],
 810     [enable_xlib_glx=no])
 811
 812 AC_ARG_ENABLE([r600-llvm-compiler],
 813     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 814         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 815     [enable_r600_llvm="$enableval"],
 816     [enable_r600_llvm=no])
 817
 818 AC_ARG_ENABLE([gallium-tests],
 819     [AS_HELP_STRING([--enable-gallium-tests],
 820         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 821     [enable_gallium_tests="$enableval"],
 822     [enable_gallium_tests=no])
 823
 824 # Option for Gallium drivers
 825
 826 # Keep this in sync with the --with-gallium-drivers help string default value
 827 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 828
 829 AC_ARG_WITH([gallium-drivers],
 830     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 831         [comma delimited Gallium drivers list, e.g.
 832         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 833         @<:@default=r300,r600,svga,swrast@:>@])],
 834     [with_gallium_drivers="$withval"],
 835     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 836
 837 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 838 # here so that the script doesn't choke on an unknown driver name later.
 839 case "$with_gallium_drivers" in
 840     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 841     no) with_gallium_drivers='' ;;
 842 esac
 843
 844 if test "x$enable_opengl" = xno -a \
 845         "x$enable_gles1" = xno -a \
 846         "x$enable_gles2" = xno -a \
 847         "x$enable_nine" = xno -a \
 848         "x$enable_xa" = xno -a \
 849         "x$enable_xvmc" = xno -a \
 850         "x$enable_vdpau" = xno -a \
 851         "x$enable_omx" = xno -a \
 852         "x$enable_va" = xno -a \
 853         "x$enable_opencl" = xno; then
 854     AC_MSG_ERROR([at least one API should be enabled])
 855 fi
 856
 857 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 858 if test "x$enable_opengl" = xno -a \
 859         "x$enable_gles1" = xyes; then
 860     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 861 fi
 862
 863 if test "x$enable_opengl" = xno -a \
 864         "x$enable_gles2" = xyes; then
 865     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 866 fi
 867
 868 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 869 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 870 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 871 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 872                                         "x$enable_gles1" = xyes -o \
 873                                         "x$enable_gles2" = xyes)
 874
 875 if test "x$enable_glx" = xno; then
 876     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 877     enable_xlib_glx=no
 878 fi
 879
 880 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 881     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 882 fi
 883
 884 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 885     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 886 fi
 887
 888 # Disable GLX if OpenGL is not enabled
 889 if test "x$enable_glx$enable_opengl" = xyesno; then
 890     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 891     enable_glx=no
 892 fi
 893
 894 # Disable GLX if DRI and Xlib-GLX are not enabled
 895 if test "x$enable_glx" = xyes -a \
 896         "x$enable_dri" = xno -a \
 897         "x$enable_xlib_glx" = xno; then
 898     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 899     enable_glx=no
 900 fi
 901
 902 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 903                                   "x$enable_dri" = xyes)
 904
 905 # Select which platform-dependent DRI code gets built
 906 case "$host_os" in
 907 darwin*)
 908     dri_platform='apple' ;;
 909 gnu*|cygwin*)
 910     dri_platform='none' ;;
 911 *)
 912     dri_platform='drm' ;;
 913 esac
 914
 915 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 916 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 917 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 918 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 919 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 920
 921 AC_ARG_ENABLE([shared-glapi],
 922     [AS_HELP_STRING([--enable-shared-glapi],
 923         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 924     [enable_shared_glapi="$enableval"],
 925     [enable_shared_glapi=yes])
 926
 927 case "x$enable_opengl$enable_gles1$enable_gles2" in
 928 x*yes*yes*)
 929     if test "x$enable_shared_glapi" = xno; then
 930         AC_MSG_ERROR([shared GLAPI required when building two or more of
 931                       the following APIs - opengl, gles1 gles2])
 932     fi
 933     ;;
 934 esac
 935
 936 # Building Xlib-GLX requires shared glapi to be disabled.
 937 if test "x$enable_xlib_glx" = xyes; then
 938     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 939     enable_shared_glapi=no
 940 fi
 941
 942 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 943
 944 # Build the pipe-drivers as separate libraries/modules.
 945 # Do not touch this unless you know what you are doing.
 946 # XXX: Expose via configure option ?
 947 enable_shared_pipe_drivers=no
 948
 949 dnl
 950 dnl Driver specific build directories
 951 dnl
 952
 953 case "x$enable_glx$enable_xlib_glx" in
 954 xyesyes)
 955     NEED_WINSYS_XLIB="yes"
 956     ;;
 957 esac
 958
 959 if test "x$enable_dri" = xyes; then
 960     enable_gallium_loader="$enable_shared_pipe_drivers"
 961 fi
 962
 963 if test "x$enable_gallium_osmesa" = xyes; then
 964     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 965         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 966     fi
 967     if test "x$enable_osmesa" = xyes; then
 968         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 969     fi
 970 fi
 971
 972 AC_SUBST([MESA_LLVM])
 973
 974 # SHA1 hashing
 975 AC_ARG_WITH([sha1],
 976         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 977         [choose SHA1 implementation])])
 978 case "x$with_sha1" in
 979 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 980   ;;
 981 *)
 982         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 983 esac
 984
 985 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 986 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 987         with_sha1=libc
 988 fi
 989 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 990         AC_MSG_ERROR([sha1 in libc requested but not found])
 991 fi
 992 if test "x$with_sha1" = xlibc; then
 993         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 994                 [Use libc SHA1 functions])
 995         SHA1_LIBS=""
 996 fi
 997 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 998 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 999         with_sha1=CommonCrypto
1000 fi
1001 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1002         AC_MSG_ERROR([CommonCrypto requested but not found])
1003 fi
1004 if test "x$with_sha1" = xCommonCrypto; then
1005         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1006                 [Use CommonCrypto SHA1 functions])
1007         SHA1_LIBS=""
1008 fi
1009 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1010 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1011 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1012         with_sha1=CryptoAPI
1013 fi
1014 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1015         AC_MSG_ERROR([CryptoAPI requested but not found])
1016 fi
1017 if test "x$with_sha1" = xCryptoAPI; then
1018         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1019                 [Use CryptoAPI SHA1 functions])
1020         SHA1_LIBS=""
1021 fi
1022 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1023 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1024         with_sha1=libmd
1025 fi
1026 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1027         AC_MSG_ERROR([libmd requested but not found])
1028 fi
1029 if test "x$with_sha1" = xlibmd; then
1030         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1031                   [Use libmd SHA1 functions])
1032         SHA1_LIBS=-lmd
1033 fi
1034 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1035 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1036    with_sha1=libsha1
1037 fi
1038 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1039         AC_MSG_ERROR([libsha1 requested but not found])
1040 fi
1041 if test "x$with_sha1" = xlibsha1; then
1042         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1043                   [Use libsha1 for SHA1])
1044         SHA1_LIBS=-lsha1
1045 fi
1046 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1047 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1048         with_sha1=libnettle
1049 fi
1050 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1051         AC_MSG_ERROR([libnettle requested but not found])
1052 fi
1053 if test "x$with_sha1" = xlibnettle; then
1054         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1055                   [Use libnettle SHA1 functions])
1056         SHA1_LIBS=-lnettle
1057 fi
1058 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1059 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1060         with_sha1=libgcrypt
1061 fi
1062 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1063         AC_MSG_ERROR([libgcrypt requested but not found])
1064 fi
1065 if test "x$with_sha1" = xlibgcrypt; then
1066         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1067                   [Use libgcrypt SHA1 functions])
1068         SHA1_LIBS=-lgcrypt
1069 fi
1070 # We don't need all of the OpenSSL libraries, just libcrypto
1071 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1072 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1073                   [HAVE_OPENSSL_PKC=no])
1074 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1075         if test "x$with_sha1" = x; then
1076                 with_sha1=libcrypto
1077         fi
1078 else
1079         if test "x$with_sha1" = xlibcrypto; then
1080                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1081         fi
1082 fi
1083 if test "x$with_sha1" = xlibcrypto; then
1084         if test "x$HAVE_LIBCRYPTO" = xyes; then
1085                 SHA1_LIBS=-lcrypto
1086         else
1087                 SHA1_LIBS="$OPENSSL_LIBS"
1088                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1089         fi
1090 fi
1091 AC_MSG_CHECKING([for SHA1 implementation])
1092 AC_MSG_RESULT([$with_sha1])
1093 AC_SUBST(SHA1_LIBS)
1094 AC_SUBST(SHA1_CFLAGS)
1095
1096 # Allow user to configure out the shader-cache feature
1097 AC_ARG_ENABLE([shader-cache],
1098     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1099     [enable_shader_cache="$enableval"],
1100     [if test "x$with_sha1" != "x"; then
1101         enable_shader_cache=yes
1102      else
1103         enable_shader_cache=no
1104      fi])
1105 if test "x$with_sha1" = "x"; then
1106     if test "x$enable_shader_cache" = "xyes"; then
1107         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1108     fi
1109 fi
1110 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1111
1112 # Check for libdrm
1113 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1114                   [have_libdrm=yes], [have_libdrm=no])
1115 if test "x$have_libdrm" = xyes; then
1116         DEFINES="$DEFINES -DHAVE_LIBDRM"
1117 fi
1118
1119 case "$host_os" in
1120 linux*)
1121     need_pci_id=yes ;;
1122 *)
1123     need_pci_id=no ;;
1124 esac
1125
1126 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1127                   have_libudev=yes, have_libudev=no)
1128
1129 AC_ARG_ENABLE([sysfs],
1130     [AS_HELP_STRING([--enable-sysfs],
1131         [enable /sys PCI identification @<:@default=disabled@:>@])],
1132     [have_sysfs="$enableval"],
1133     [have_sysfs=no]
1134 )
1135
1136 if test "x$enable_dri" = xyes; then
1137     if test "$enable_static" = yes; then
1138         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1139     fi
1140
1141     # not a hard requirement as swrast does not depend on it
1142     if test "x$have_libdrm" = xyes; then
1143         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1144     fi
1145 fi
1146
1147 AC_ARG_ENABLE([driglx-direct],
1148     [AS_HELP_STRING([--disable-driglx-direct],
1149         [disable direct rendering in GLX and EGL for DRI \
1150             @<:@default=auto@:>@])],
1151     [driglx_direct="$enableval"],
1152     [driglx_direct="yes"])
1153
1154 dnl
1155 dnl libGL configuration per driver
1156 dnl
1157 case "x$enable_glx$enable_xlib_glx" in
1158 xyesyes)
1159     # Xlib-based GLX
1160     dri_modules="x11 xext xcb"
1161     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1162     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1163     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1164     GL_LIB_DEPS="$XLIBGL_LIBS"
1165     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1166     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1167     ;;
1168 xyesno)
1169     # DRI-based GLX
1170     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1171
1172     # find the DRI deps for libGL
1173     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1174
1175     if test x"$driglx_direct" = xyes; then
1176         if test x"$dri_platform" = xdrm ; then
1177             DEFINES="$DEFINES -DGLX_USE_DRM"
1178             if test "x$have_libdrm" != xyes; then
1179                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1180             fi
1181
1182             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1183             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1184             if test x"$enable_dri3" = xyes; then
1185                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1186                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1187             fi
1188
1189             if test x"$enable_dri" = xyes; then
1190                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1191             fi
1192
1193             if test x"$enable_dri3" = xyes; then
1194                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1195                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1196             fi
1197         fi
1198         if test x"$dri_platform" = xapple ; then
1199             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1200         fi
1201     fi
1202
1203     # add xf86vidmode if available
1204     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1205     if test "$HAVE_XF86VIDMODE" = yes ; then
1206         dri_modules="$dri_modules xxf86vm"
1207     fi
1208
1209     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1210     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1211     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1212     GL_LIB_DEPS="$DRIGL_LIBS"
1213
1214     # need DRM libs, $PTHREAD_LIBS, etc.
1215     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1216     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1217     ;;
1218 esac
1219
1220 have_pci_id=no
1221 if test "$have_libudev" = yes; then
1222     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1223     have_pci_id=yes
1224 fi
1225
1226 if test "$have_sysfs" = yes; then
1227     DEFINES="$DEFINES -DHAVE_SYSFS"
1228     have_pci_id=yes
1229 fi
1230
1231 # This is outside the case (above) so that it is invoked even for non-GLX
1232 # builds.
1233 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1234
1235 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1236 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1237 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1238 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1239
1240 AC_SUBST([X11_INCLUDES])
1241 AC_SUBST([GL_LIB_DEPS])
1242 AC_SUBST([GL_PC_REQ_PRIV])
1243 AC_SUBST([GL_PC_LIB_PRIV])
1244 AC_SUBST([GL_PC_CFLAGS])
1245 AC_SUBST([DRI_PC_REQ_PRIV])
1246 AC_SUBST([GLESv1_CM_LIB_DEPS])
1247 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1248 AC_SUBST([GLESv2_LIB_DEPS])
1249 AC_SUBST([GLESv2_PC_LIB_PRIV])
1250
1251 AC_SUBST([HAVE_XF86VIDMODE])
1252
1253 dnl
1254 dnl More GLX setup
1255 dnl
1256 case "x$enable_glx$enable_xlib_glx" in
1257 xyesyes)
1258     DEFINES="$DEFINES -DUSE_XSHM"
1259     ;;
1260 xyesno)
1261     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1262     if test "x$driglx_direct" = xyes; then
1263         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1264     fi
1265     ;;
1266 esac
1267
1268 dnl
1269 dnl TLS detection
1270 dnl
1271
1272 AC_ARG_ENABLE([glx-tls],
1273     [AS_HELP_STRING([--enable-glx-tls],
1274         [enable TLS support in GLX @<:@default=disabled@:>@])],
1275     [GLX_USE_TLS="$enableval"],
1276     [GLX_USE_TLS=no])
1277 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1278
1279 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1280       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1281
1282 dnl
1283 dnl More DRI setup
1284 dnl
1285 dnl Directory for DRI drivers
1286 AC_ARG_WITH([dri-driverdir],
1287     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1288         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1289     [DRI_DRIVER_INSTALL_DIR="$withval"],
1290     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1291 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1292 dnl Extra search path for DRI drivers
1293 AC_ARG_WITH([dri-searchpath],
1294     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1295         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1296     [DRI_DRIVER_SEARCH_DIR="$withval"],
1297     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1298 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1299 dnl Which drivers to build - default is chosen by platform
1300 AC_ARG_WITH([dri-drivers],
1301     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1302         [comma delimited classic DRI drivers list, e.g.
1303         "swrast,i965,radeon" @<:@default=auto@:>@])],
1304     [with_dri_drivers="$withval"],
1305     [with_dri_drivers=auto])
1306
1307 if test "x$with_dri_drivers" = xauto; then
1308     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1309         with_dri_drivers="yes"
1310     else
1311         with_dri_drivers="no"
1312     fi
1313 fi
1314 if test "x$with_dri_drivers" = xno; then
1315     with_dri_drivers=''
1316 fi
1317
1318 dnl If $with_dri_drivers is yes, drivers will be added through
1319 dnl platform checks. Set DEFINES and LIB_DEPS
1320 if test "x$enable_dri" = xyes; then
1321     # Platform specific settings and drivers to build
1322     case "$host_os" in
1323     linux*)
1324         DEFINES="$DEFINES -DHAVE_ALIAS"
1325         if test "x$enable_dri3" = xyes; then
1326             DEFINES="$DEFINES -DHAVE_DRI3"
1327         fi
1328
1329         if test "x$have_pci_id" != xyes; then
1330             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1331         fi
1332
1333         case "$host_cpu" in
1334         powerpc* | sparc*)
1335             # Build only the drivers for cards that exist on PowerPC/sparc
1336             if test "x$with_dri_drivers" = "xyes"; then
1337                 with_dri_drivers="r200 radeon swrast"
1338             fi
1339             ;;
1340         esac
1341         ;;
1342     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1343         DEFINES="$DEFINES -DHAVE_ALIAS"
1344         ;;
1345     gnu*)
1346         DEFINES="$DEFINES -DHAVE_ALIAS"
1347         ;;
1348     cygwin*)
1349         if test "x$with_dri_drivers" = "xyes"; then
1350             with_dri_drivers="swrast"
1351         fi
1352         ;;
1353     darwin*)
1354         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1355         if test "x$with_dri_drivers" = "xyes"; then
1356             with_dri_drivers="swrast"
1357         fi
1358         ;;
1359     esac
1360
1361     # default drivers
1362     if test "x$with_dri_drivers" = "xyes"; then
1363         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1364     fi
1365
1366     # Check for expat
1367     PKG_CHECK_MODULES([EXPAT], [expat], [],
1368         # expat version 2.0 and earlier do not provide expat.pc
1369         [AC_CHECK_HEADER([expat.h],[],
1370                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1371          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1372                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1373          EXPAT_LIBS="-lexpat"])
1374
1375     DRICOMMON_NEED_LIBDRM=no
1376     # If we are building any DRI driver other than swrast.
1377     if test -n "$with_dri_drivers"; then
1378         if test "x$with_dri_drivers" != xswrast; then
1379             # ... libdrm is required
1380             if test "x$have_libdrm" != xyes; then
1381                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1382             fi
1383             DRICOMMON_NEED_LIBDRM=yes
1384         fi
1385     fi
1386
1387     # If we're building any gallium DRI driver other than swrast
1388     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1389         if test "x$with_gallium_drivers" != xswrast; then
1390             # ... build a libdrm aware dricommon
1391             DRICOMMON_NEED_LIBDRM=yes
1392         fi
1393     fi
1394
1395     # put all the necessary libs together
1396     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1397 fi
1398
1399 AC_SUBST([DRI_LIB_DEPS])
1400
1401 DRI_DIRS=''
1402 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1403 if test -n "$with_dri_drivers"; then
1404     if test "x$enable_opengl" != xyes; then
1405         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1406     fi
1407
1408     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1409     for driver in $dri_drivers; do
1410         DRI_DIRS="$DRI_DIRS $driver"
1411         case "x$driver" in
1412         xi915)
1413             HAVE_I915_DRI=yes;
1414             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1415             ;;
1416         xi965)
1417             HAVE_I965_DRI=yes;
1418             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1419             ;;
1420         xnouveau)
1421             HAVE_NOUVEAU_DRI=yes;
1422             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1423             ;;
1424         xradeon)
1425             HAVE_RADEON_DRI=yes;
1426             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1427             ;;
1428         xr200)
1429             HAVE_R200_DRI=yes;
1430             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1431             ;;
1432         xswrast)
1433             HAVE_SWRAST_DRI=yes;
1434             ;;
1435         *)
1436             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1437             ;;
1438         esac
1439     done
1440     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1441 fi
1442
1443 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1444 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1445                                   "x$enable_osmesa" = xyes -o \
1446                                   -n "$DRI_DIRS")
1447
1448 dnl
1449 dnl OSMesa configuration
1450 dnl
1451
1452 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1453 AC_ARG_WITH([osmesa-bits],
1454     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1455         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1456     [osmesa_bits="$withval"],
1457     [osmesa_bits=8])
1458 if test "x$osmesa_bits" != x8; then
1459     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1460         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1461         osmesa_bits=8
1462     fi
1463 fi
1464 case "x$osmesa_bits" in
1465 x8)
1466     OSMESA_LIB="${OSMESA_LIB}"
1467     ;;
1468 x16|x32)
1469     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1470     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1471     ;;
1472 *)
1473     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1474     ;;
1475 esac
1476
1477 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1478     # only link libraries with osmesa if shared
1479     if test "$enable_static" = no; then
1480         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1481     else
1482         OSMESA_LIB_DEPS=""
1483     fi
1484     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1485 fi
1486
1487 AC_SUBST([OSMESA_LIB_DEPS])
1488 AC_SUBST([OSMESA_PC_REQ])
1489 AC_SUBST([OSMESA_PC_LIB_PRIV])
1490
1491 dnl
1492 dnl gbm configuration
1493 dnl
1494 if test "x$enable_gbm" = xauto; then
1495     case "$with_egl_platforms" in
1496         *drm*)
1497             enable_gbm=yes ;;
1498          *)
1499             enable_gbm=no ;;
1500     esac
1501 fi
1502 if test "x$enable_gbm" = xyes; then
1503     if test "x$need_pci_id$have_pci_id" = xyesno; then
1504         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1505     fi
1506
1507     if test "x$enable_dri" = xyes; then
1508         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1509         if test "x$enable_shared_glapi" = xno; then
1510             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1511         fi
1512     else
1513         # Strictly speaking libgbm does not require --enable-dri, although
1514         # both of its backends do. Thus one can build libgbm without any
1515         # backends if --disable-dri is set.
1516         # To avoid unnecessary complexity of checking if at least one backend
1517         # is available when building, just mandate --enable-dri.
1518         AC_MSG_ERROR([gbm requires --enable-dri])
1519     fi
1520 fi
1521 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1522 if test "x$need_pci_id$have_libudev" = xyesyes; then
1523     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1524 else
1525     GBM_PC_REQ_PRIV=""
1526 fi
1527 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1528 AC_SUBST([GBM_PC_REQ_PRIV])
1529 AC_SUBST([GBM_PC_LIB_PRIV])
1530
1531 dnl
1532 dnl EGL configuration
1533 dnl
1534 EGL_CLIENT_APIS=""
1535
1536 if test "x$enable_egl" = xyes; then
1537     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1538
1539     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1540
1541     if test "$enable_static" != yes; then
1542         if test "x$enable_dri" = xyes; then
1543             HAVE_EGL_DRIVER_DRI2=1
1544         fi
1545
1546     fi
1547 fi
1548 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1549 AC_SUBST([EGL_LIB_DEPS])
1550
1551 dnl
1552 dnl XA configuration
1553 dnl
1554 if test "x$enable_xa" = xyes; then
1555     if test "x$with_gallium_drivers" = xswrast; then
1556        AC_MSG_ERROR([
1557           Building xa requires at least one non swrast gallium driver.
1558           If you are looking to use libxatracker.so with the VMware driver,
1559           make sure to include svga in the gallium drivers list, apart from
1560           enabling XA.
1561           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1562     fi
1563     enable_gallium_loader=$enable_shared_pipe_drivers
1564 fi
1565 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1566
1567 dnl
1568 dnl Gallium G3DVL configuration
1569 dnl
1570 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1571     if test "x$enable_xvmc" = xauto; then
1572         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1573     fi
1574
1575     if test "x$enable_vdpau" = xauto; then
1576         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1577     fi
1578
1579     if test "x$enable_omx" = xauto; then
1580         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1581     fi
1582
1583     if test "x$enable_va" = xauto; then
1584         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1585     fi
1586 fi
1587
1588 if test "x$enable_dri" = xyes -o \
1589         "x$enable_xvmc" = xyes -o \
1590         "x$enable_vdpau" = xyes -o \
1591         "x$enable_omx" = xyes -o \
1592         "x$enable_va" = xyes; then
1593     need_gallium_vl=yes
1594 fi
1595 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1596
1597 if test "x$enable_xvmc" = xyes -o \
1598         "x$enable_vdpau" = xyes -o \
1599         "x$enable_omx" = xyes -o \
1600         "x$enable_va" = xyes; then
1601     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1602     need_gallium_vl_winsys=yes
1603 fi
1604 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1605
1606 if test "x$enable_xvmc" = xyes; then
1607     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1608     enable_gallium_loader=$enable_shared_pipe_drivers
1609 fi
1610 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1611
1612 if test "x$enable_vdpau" = xyes; then
1613     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1614     enable_gallium_loader=$enable_shared_pipe_drivers
1615 fi
1616 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1617
1618 if test "x$enable_omx" = xyes; then
1619     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1620     enable_gallium_loader=$enable_shared_pipe_drivers
1621 fi
1622 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1623
1624 if test "x$enable_va" = xyes; then
1625     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1626     enable_gallium_loader=$enable_shared_pipe_drivers
1627 fi
1628 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1629
1630 dnl
1631 dnl Nine Direct3D9 configuration
1632 dnl
1633 if test "x$enable_nine" = xyes; then
1634     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1635         AC_MSG_ERROR([nine requires the gallium swrast driver])
1636     fi
1637     if test "x$with_gallium_drivers" == xswrast; then
1638         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1639     fi
1640     if test "x$enable_dri3" = xno; then
1641         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1642     fi
1643
1644     enable_gallium_loader=$enable_shared_pipe_drivers
1645 fi
1646 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1647
1648 dnl
1649 dnl OpenCL configuration
1650 dnl
1651
1652 AC_ARG_WITH([libclc-path],
1653    [AS_HELP_STRING([--with-libclc-path],
1654          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1655    [LIBCLC_PATH="$withval"],
1656    [LIBCLC_PATH=''])
1657
1658 if test -n "$LIBCLC_PATH"; then
1659    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1660                   Please review the updated build instructions for clover:
1661                   http://dri.freedesktop.org/wiki/GalliumCompute])
1662 fi
1663
1664
1665 AC_ARG_WITH([clang-libdir],
1666    [AS_HELP_STRING([--with-clang-libdir],
1667          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1668    [CLANG_LIBDIR="$withval"],
1669    [CLANG_LIBDIR=''])
1670
1671 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1672 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1673
1674 if test "x$enable_opencl" = xyes; then
1675     if test -z "$with_gallium_drivers"; then
1676         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1677     fi
1678
1679     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1680         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1681     fi
1682
1683     if test "x$have_libclc" = xno; then
1684         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1685                     Make sure the directory containing libclc.pc is specified in your
1686                     PKG_CONFIG_PATH environment variable.
1687                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1688     else
1689         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1690         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1691         AC_SUBST([LIBCLC_INCLUDEDIR])
1692         AC_SUBST([LIBCLC_LIBEXECDIR])
1693     fi
1694
1695     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1696     enable_gallium_loader=yes
1697
1698     if test "x$enable_opencl_icd" = xyes; then
1699         OPENCL_LIBNAME="MesaOpenCL"
1700     else
1701         OPENCL_LIBNAME="OpenCL"
1702     fi
1703
1704     if test "x$have_libelf" != xyes; then
1705        AC_MSG_ERROR([Clover requires libelf])
1706     fi
1707 fi
1708 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1709 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1710 AC_SUBST([OPENCL_LIBNAME])
1711
1712 dnl
1713 dnl Gallium configuration
1714 dnl
1715 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1716
1717 AC_SUBST([LLVM_BINDIR])
1718 AC_SUBST([LLVM_CFLAGS])
1719 AC_SUBST([LLVM_CPPFLAGS])
1720 AC_SUBST([LLVM_CXXFLAGS])
1721 AC_SUBST([LLVM_LIBDIR])
1722 AC_SUBST([LLVM_LIBS])
1723 AC_SUBST([LLVM_LDFLAGS])
1724 AC_SUBST([LLVM_INCLUDEDIR])
1725 AC_SUBST([LLVM_VERSION])
1726 AC_SUBST([CLANG_RESOURCE_DIR])
1727
1728 case "x$enable_opengl$enable_gles1$enable_gles2" in
1729 x*yes*)
1730     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1731     ;;
1732 esac
1733
1734 AC_SUBST([VG_LIB_DEPS])
1735 AC_SUBST([EGL_CLIENT_APIS])
1736
1737 dnl
1738 dnl EGL Platforms configuration
1739 dnl
1740 AC_ARG_WITH([egl-platforms],
1741     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1742         [comma delimited native platforms libEGL supports, e.g.
1743         "x11,drm" @<:@default=auto@:>@])],
1744     [with_egl_platforms="$withval"],
1745     [if test "x$enable_egl" = xyes; then
1746         with_egl_platforms="x11"
1747     else
1748         with_egl_platforms=""
1749     fi])
1750
1751 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1752     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1753 fi
1754
1755 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1756         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1757         WAYLAND_SCANNER='')
1758 if test "x$WAYLAND_SCANNER" = x; then
1759     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1760 fi
1761
1762 # Do per-EGL platform setups and checks
1763 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1764 for plat in $egl_platforms; do
1765         case "$plat" in
1766         wayland)
1767                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1768
1769                 if test "x$WAYLAND_SCANNER" = x; then
1770                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1771                 fi
1772                 ;;
1773
1774         x11)
1775                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1776                 ;;
1777
1778         drm)
1779                 test "x$enable_gbm" = "xno" &&
1780                         AC_MSG_ERROR([EGL platform drm needs gbm])
1781                 test "x$have_libdrm" != xyes &&
1782                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1783                 ;;
1784
1785         android|gdi|null)
1786                 ;;
1787
1788         *)
1789                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1790                 ;;
1791         esac
1792
1793         case "$plat$need_pci_id$have_pci_id" in
1794                 waylandyesno|drmyesno)
1795                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1796         esac
1797 done
1798
1799 # libEGL wants to default to the first platform specified in
1800 # ./configure.  parse that here.
1801 if test "x$egl_platforms" != "x"; then
1802     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1803     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1804 else
1805     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1806 fi
1807
1808 if echo "$egl_platforms" | grep -q 'x11'; then
1809     NEED_WINSYS_XLIB=yes
1810 fi
1811 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1812 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1813 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1814 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1815
1816 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1817
1818 AC_SUBST([EGL_NATIVE_PLATFORM])
1819 AC_SUBST([EGL_CFLAGS])
1820
1821 # If we don't have the X11 platform, set this define so we don't try to include
1822 # the X11 headers.
1823 if ! echo "$egl_platforms" | grep -q 'x11'; then
1824     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1825     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1826 fi
1827
1828 AC_ARG_WITH([max-width],
1829     [AS_HELP_STRING([--with-max-width=N],
1830                     [Maximum framebuffer width (4096)])],
1831     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1832      AS_IF([test "${withval}" -gt "4096"],
1833            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1834 )
1835 AC_ARG_WITH([max-height],
1836     [AS_HELP_STRING([--with-max-height=N],
1837                     [Maximum framebuffer height (4096)])],
1838     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1839      AS_IF([test "${withval}" -gt "4096"],
1840            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1841 )
1842
1843 dnl
1844 dnl Gallium LLVM
1845 dnl
1846 AC_ARG_ENABLE([gallium-llvm],
1847     [AS_HELP_STRING([--enable-gallium-llvm],
1848         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1849     [enable_gallium_llvm="$enableval"],
1850     [enable_gallium_llvm=auto])
1851
1852 AC_ARG_ENABLE([llvm-shared-libs],
1853     [AS_HELP_STRING([--enable-llvm-shared-libs],
1854         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1855     [enable_llvm_shared_libs="$enableval"],
1856     [enable_llvm_shared_libs=yes])
1857
1858 AC_ARG_WITH([llvm-prefix],
1859     [AS_HELP_STRING([--with-llvm-prefix],
1860         [Prefix for LLVM installations in non-standard locations])],
1861     [llvm_prefix="$withval"],
1862     [llvm_prefix=''])
1863
1864
1865 # Call this inside ` ` to get the return value.
1866 # $1 is the llvm-config command with arguments.
1867 strip_unwanted_llvm_flags() {
1868     # Use \> (marks the end of the word)
1869     echo `$1` | sed \
1870         -e 's/-DNDEBUG\>//g' \
1871         -e 's/-D_GNU_SOURCE\>//g' \
1872         -e 's/-pedantic\>//g' \
1873         -e 's/-Wcovered-switch-default\>//g' \
1874         -e 's/-O.\>//g' \
1875         -e 's/-g\>//g' \
1876         -e 's/-Wall\>//g' \
1877         -e 's/-Wcast-qual\>//g' \
1878         -e 's/-Woverloaded-virtual\>//g' \
1879         -e 's/-fcolor-diagnostics\>//g' \
1880         -e 's/-fdata-sections\>//g' \
1881         -e 's/-ffunction-sections\>//g' \
1882         -e 's/-fno-exceptions\>//g' \
1883         -e 's/-fomit-frame-pointer\>//g' \
1884         -e 's/-fvisibility-inlines-hidden\>//g' \
1885         -e 's/-fPIC\>//g' \
1886         -e 's/-fstack-protector-strong\>//g'
1887 }
1888
1889
1890 if test -z "$with_gallium_drivers"; then
1891     enable_gallium_llvm=no
1892 fi
1893 if test "x$enable_gallium_llvm" = xauto; then
1894     case "$host_cpu" in
1895     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1896     esac
1897 fi
1898 if test "x$enable_gallium_llvm" = xyes; then
1899     if test -n "$llvm_prefix"; then
1900         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1901     else
1902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1903     fi
1904
1905     if test "x$LLVM_CONFIG" != xno; then
1906         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1907         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1908         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1909         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1910         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1911         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1912         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1913         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1914
1915         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1916             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1917         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1918             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1919
1920         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1921         if test -z "$LLVM_VERSION_PATCH"; then
1922             LLVM_VERSION_PATCH=0
1923         fi
1924
1925         if test -n "${LLVM_VERSION_MAJOR}"; then
1926             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1927         else
1928             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1929         fi
1930
1931         LLVM_REQUIRED_VERSION_MAJOR="3"
1932         LLVM_REQUIRED_VERSION_MINOR="3"
1933         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1934             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1935         fi
1936
1937         LLVM_COMPONENTS="engine bitwriter"
1938         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1939             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1940         fi
1941
1942         if test "x$enable_opencl" = xyes; then
1943             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1944             # LLVM 3.3 >= 177971 requires IRReader
1945             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1946                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1947             fi
1948             # LLVM 3.4 requires Option
1949             if $LLVM_CONFIG --components | grep -qw 'option'; then
1950                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1951             fi
1952             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1953             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1954                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1955             fi
1956             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1957                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1958             fi
1959         fi
1960         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1961         MESA_LLVM=1
1962
1963         dnl Check for Clang internal headers
1964         if test "x$enable_opencl" = xyes; then
1965             if test -z "$CLANG_LIBDIR"; then
1966                 CLANG_LIBDIR=${LLVM_LIBDIR}
1967             fi
1968             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1969             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1970                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1971         fi
1972     else
1973         MESA_LLVM=0
1974         LLVM_VERSION_INT=0
1975     fi
1976 else
1977     MESA_LLVM=0
1978     LLVM_VERSION_INT=0
1979
1980     if test "x$enable_opencl" = xyes; then
1981         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1982     fi
1983 fi
1984
1985 dnl Directory for XVMC libs
1986 AC_ARG_WITH([xvmc-libdir],
1987     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1988         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1989     [XVMC_LIB_INSTALL_DIR="$withval"],
1990     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1991 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1992
1993 dnl
1994 dnl Gallium Tests
1995 dnl
1996 if test "x$enable_gallium_tests" = xyes; then
1997     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1998     enable_gallium_loader=yes
1999 fi
2000 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2001
2002 dnl Directory for VDPAU libs
2003 AC_ARG_WITH([vdpau-libdir],
2004     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2005         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2006     [VDPAU_LIB_INSTALL_DIR="$withval"],
2007     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2008 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2009
2010 dnl Directory for OMX libs
2011
2012 AC_ARG_WITH([omx-libdir],
2013     [AS_HELP_STRING([--with-omx-libdir=DIR],
2014         [directory for the OMX libraries])],
2015     [OMX_LIB_INSTALL_DIR="$withval"],
2016     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2017 AC_SUBST([OMX_LIB_INSTALL_DIR])
2018
2019 dnl Directory for VA libs
2020
2021 AC_ARG_WITH([va-libdir],
2022     [AS_HELP_STRING([--with-va-libdir=DIR],
2023         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2024     [VA_LIB_INSTALL_DIR="$withval"],
2025     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2026 AC_SUBST([VA_LIB_INSTALL_DIR])
2027
2028 AC_ARG_WITH([d3d-libdir],
2029     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2030         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2031     [D3D_DRIVER_INSTALL_DIR="$withval"],
2032     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2033 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2034
2035 dnl
2036 dnl Gallium helper functions
2037 dnl
2038 gallium_require_drm() {
2039     if test "x$have_libdrm" != xyes; then
2040        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2041     fi
2042 }
2043
2044 gallium_require_llvm() {
2045     if test "x$MESA_LLVM" = x0; then
2046         case "$host" in *gnux32) return;; esac
2047         case "$host_cpu" in
2048         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2049         esac
2050     fi
2051 }
2052
2053 gallium_require_drm_loader() {
2054     if test "x$enable_gallium_loader" = xyes; then
2055         if test "x$need_pci_id$have_pci_id" = xyesno; then
2056             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2057         fi
2058         enable_gallium_drm_loader=yes
2059     fi
2060     if test "x$enable_va" = xyes && test "x$7" != x; then
2061          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2062     fi
2063 }
2064
2065 require_egl_drm() {
2066     case "$with_egl_platforms" in
2067         *drm*)
2068             ;;
2069          *)
2070             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2071             ;;
2072     esac
2073     if test "x$enable_gbm" != xyes; then
2074             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2075     fi
2076 }
2077
2078 radeon_llvm_check() {
2079     if test "x$enable_gallium_llvm" != "xyes"; then
2080         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2081     fi
2082     LLVM_REQUIRED_VERSION_MAJOR="3"
2083     LLVM_REQUIRED_VERSION_MINOR="4"
2084     LLVM_REQUIRED_VERSION_PATCH="2"
2085     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2086         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2087     fi
2088     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2089         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2090                       sources with the --enable-experimental-targets=R600
2091                       configure flag])
2092     fi
2093     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2094     NEED_RADEON_LLVM=yes
2095     if test "x$have_libelf" != xyes; then
2096        AC_MSG_ERROR([$1 requires libelf when using llvm])
2097     fi
2098 }
2099
2100 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2101 if test -n "$with_gallium_drivers"; then
2102     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2103     for driver in $gallium_drivers; do
2104         case "x$driver" in
2105         xsvga)
2106             HAVE_GALLIUM_SVGA=yes
2107             gallium_require_drm "svga"
2108             gallium_require_drm_loader
2109             ;;
2110         xi915)
2111             HAVE_GALLIUM_I915=yes
2112             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2113             gallium_require_drm "Gallium i915"
2114             gallium_require_drm_loader
2115             ;;
2116         xilo)
2117             HAVE_GALLIUM_ILO=yes
2118             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2119             gallium_require_drm "Gallium i965/ilo"
2120             gallium_require_drm_loader
2121             ;;
2122         xr300)
2123             HAVE_GALLIUM_R300=yes
2124             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2125             gallium_require_drm "Gallium R300"
2126             gallium_require_drm_loader
2127             gallium_require_llvm "Gallium R300"
2128             ;;
2129         xr600)
2130             HAVE_GALLIUM_R600=yes
2131             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2132             gallium_require_drm "Gallium R600"
2133             gallium_require_drm_loader
2134             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2135                 radeon_llvm_check "r600g"
2136                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2137             fi
2138             if test "x$enable_r600_llvm" = xyes; then
2139                 USE_R600_LLVM_COMPILER=yes;
2140             fi
2141             if test "x$enable_opencl" = xyes; then
2142                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2143             fi
2144             ;;
2145         xradeonsi)
2146             HAVE_GALLIUM_RADEONSI=yes
2147             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2148             gallium_require_drm "radeonsi"
2149             gallium_require_drm_loader
2150             radeon_llvm_check "radeonsi"
2151             require_egl_drm "radeonsi"
2152             ;;
2153         xnouveau)
2154             HAVE_GALLIUM_NOUVEAU=yes
2155             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2156             gallium_require_drm "nouveau"
2157             gallium_require_drm_loader
2158             ;;
2159         xfreedreno)
2160             HAVE_GALLIUM_FREEDRENO=yes
2161             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2162             gallium_require_drm "freedreno"
2163             gallium_require_drm_loader
2164             ;;
2165         xswrast)
2166             HAVE_GALLIUM_SOFTPIPE=yes
2167             if test "x$MESA_LLVM" = x1; then
2168                 HAVE_GALLIUM_LLVMPIPE=yes
2169             fi
2170             ;;
2171         xvc4)
2172             HAVE_GALLIUM_VC4=yes
2173             gallium_require_drm "vc4"
2174             gallium_require_drm_loader
2175
2176             case "$host_cpu" in
2177                 i?86 | x86_64 | amd64)
2178                 USE_VC4_SIMULATOR=yes
2179                 ;;
2180             esac
2181             ;;
2182         *)
2183             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2184             ;;
2185         esac
2186     done
2187 fi
2188
2189 dnl Set LLVM_LIBS - This is done after the driver configuration so
2190 dnl that drivers can add additional components to LLVM_COMPONENTS.
2191 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2192 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2193 dnl this was causing the same libraries to be appear multiple times
2194 dnl in LLVM_LIBS.
2195
2196 if test "x$MESA_LLVM" != x0; then
2197
2198     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2199
2200     if test "x$enable_llvm_shared_libs" = xyes; then
2201         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2202         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2203         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2204
2205         if test "x$llvm_have_one_so" = xyes; then
2206             dnl LLVM was built using auto*, so there is only one shared object.
2207             LLVM_LIBS="-l$LLVM_SO_NAME"
2208         else
2209             dnl If LLVM was built with CMake, there will be one shared object per
2210             dnl component.
2211             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2212                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2213         Please make sure you have built llvm with the --enable-shared option
2214         and that your llvm libraries are installed in $LLVM_LIBDIR
2215         If you have installed your llvm libraries to a different directory you
2216         can use the --with-llvm-prefix= configure flag to specify this directory.
2217         NOTE: Mesa is attempting to use llvm shared libraries by default.
2218         If you do not want to build with llvm shared libraries and instead want to
2219         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2220         invocation and rebuild.])])
2221
2222            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2223            dnl install uses a shared object for each component and we have
2224            dnl already added all of these objects to LLVM_LIBS.
2225         fi
2226     else
2227         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2228         dnl We need to link to llvm system libs when using static libs
2229         dnl However, only llvm 3.5+ provides --system-libs
2230         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2231             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2232         fi
2233     fi
2234 fi
2235
2236 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2237 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2238 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2239 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2240 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2241 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2242 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2243                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2244 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2245 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2246 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2247 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2248 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2249
2250 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2251
2252 # NOTE: anything using xcb or other client side libs ends up in separate
2253 #       _CLIENT variables.  The pipe loader is built in two variants,
2254 #       one that is standalone and does not link any x client libs (for
2255 #       use by XA tracker in particular, but could be used in any case
2256 #       where communication with xserver is not desired).
2257 if test "x$enable_gallium_loader" = xyes; then
2258     if test "x$NEED_WINSYS_XLIB" = xyes; then
2259         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2260     fi
2261
2262     if test "x$enable_dri" = xyes; then
2263         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2264     fi
2265
2266     if test "x$enable_gallium_drm_loader" = xyes; then
2267         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2268         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2269                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2270         if test "x$pipe_loader_have_xcb" = xyes; then
2271             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2272             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2273         fi
2274     fi
2275
2276     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2277     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2278
2279     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2280     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2281     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2282     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2283 fi
2284
2285 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2286 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2287 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2288 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2289 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2290 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2291
2292 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2293                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2294                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2295 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2296 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2297 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2298 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2299 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2300 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2301 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2302 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2303 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2304     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2305 fi
2306
2307 AC_SUBST([ELF_LIB])
2308
2309 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2310 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2311 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2312 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2313 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2314
2315 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2316 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2317 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2318
2319 AC_SUBST([NINE_MAJOR], 1)
2320 AC_SUBST([NINE_MINOR], 0)
2321 AC_SUBST([NINE_TINY], 0)
2322 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2323
2324 AC_SUBST([VDPAU_MAJOR], 1)
2325 AC_SUBST([VDPAU_MINOR], 0)
2326
2327 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2328 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2329 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2330 AC_SUBST([VA_MINOR], $VA_MINOR)
2331
2332 AC_SUBST([XVMC_MAJOR], 1)
2333 AC_SUBST([XVMC_MINOR], 0)
2334
2335 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2336 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2337 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2338 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2339
2340 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2341 AC_SUBST([XA_MINOR], $XA_MINOR)
2342 AC_SUBST([XA_TINY], $XA_TINY)
2343 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2344
2345 dnl Restore LDFLAGS and CPPFLAGS
2346 LDFLAGS="$_SAVE_LDFLAGS"
2347 CPPFLAGS="$_SAVE_CPPFLAGS"
2348
2349 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2350 if test "x$acv_mesa_CLANG" = xyes; then
2351     CFLAGS="$CFLAGS -Qunused-arguments"
2352     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2353 fi
2354
2355 dnl Add user CFLAGS and CXXFLAGS
2356 CFLAGS="$CFLAGS $USER_CFLAGS"
2357 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2358
2359 dnl Substitute the config
2360 AC_CONFIG_FILES([Makefile
2361                 src/Makefile
2362                 src/egl/drivers/dri2/Makefile
2363                 src/egl/main/Makefile
2364                 src/egl/main/egl.pc
2365                 src/egl/wayland/wayland-drm/Makefile
2366                 src/egl/wayland/wayland-egl/Makefile
2367                 src/egl/wayland/wayland-egl/wayland-egl.pc
2368                 src/gallium/Makefile
2369                 src/gallium/auxiliary/Makefile
2370                 src/gallium/auxiliary/pipe-loader/Makefile
2371                 src/gallium/drivers/freedreno/Makefile
2372                 src/gallium/drivers/i915/Makefile
2373                 src/gallium/drivers/ilo/Makefile
2374                 src/gallium/drivers/llvmpipe/Makefile
2375                 src/gallium/drivers/noop/Makefile
2376                 src/gallium/drivers/nouveau/Makefile
2377                 src/gallium/drivers/r300/Makefile
2378                 src/gallium/drivers/r600/Makefile
2379                 src/gallium/drivers/radeon/Makefile
2380                 src/gallium/drivers/radeonsi/Makefile
2381                 src/gallium/drivers/rbug/Makefile
2382                 src/gallium/drivers/softpipe/Makefile
2383                 src/gallium/drivers/svga/Makefile
2384                 src/gallium/drivers/trace/Makefile
2385                 src/gallium/drivers/vc4/Makefile
2386                 src/gallium/drivers/vc4/kernel/Makefile
2387                 src/gallium/state_trackers/clover/Makefile
2388                 src/gallium/state_trackers/dri/Makefile
2389                 src/gallium/state_trackers/glx/xlib/Makefile
2390                 src/gallium/state_trackers/nine/Makefile
2391                 src/gallium/state_trackers/omx/Makefile
2392                 src/gallium/state_trackers/osmesa/Makefile
2393                 src/gallium/state_trackers/va/Makefile
2394                 src/gallium/state_trackers/vdpau/Makefile
2395                 src/gallium/state_trackers/xa/Makefile
2396                 src/gallium/state_trackers/xvmc/Makefile
2397                 src/gallium/targets/d3dadapter9/Makefile
2398                 src/gallium/targets/d3dadapter9/d3d.pc
2399                 src/gallium/targets/dri/Makefile
2400                 src/gallium/targets/libgl-xlib/Makefile
2401                 src/gallium/targets/omx/Makefile
2402                 src/gallium/targets/opencl/Makefile
2403                 src/gallium/targets/osmesa/Makefile
2404                 src/gallium/targets/osmesa/osmesa.pc
2405                 src/gallium/targets/pipe-loader/Makefile
2406                 src/gallium/targets/va/Makefile
2407                 src/gallium/targets/vdpau/Makefile
2408                 src/gallium/targets/xa/Makefile
2409                 src/gallium/targets/xa/xatracker.pc
2410                 src/gallium/targets/xvmc/Makefile
2411                 src/gallium/tests/trivial/Makefile
2412                 src/gallium/tests/unit/Makefile
2413                 src/gallium/winsys/freedreno/drm/Makefile
2414                 src/gallium/winsys/i915/drm/Makefile
2415                 src/gallium/winsys/intel/drm/Makefile
2416                 src/gallium/winsys/nouveau/drm/Makefile
2417                 src/gallium/winsys/radeon/drm/Makefile
2418                 src/gallium/winsys/svga/drm/Makefile
2419                 src/gallium/winsys/sw/dri/Makefile
2420                 src/gallium/winsys/sw/kms-dri/Makefile
2421                 src/gallium/winsys/sw/null/Makefile
2422                 src/gallium/winsys/sw/wrapper/Makefile
2423                 src/gallium/winsys/sw/xlib/Makefile
2424                 src/gallium/winsys/vc4/drm/Makefile
2425                 src/gbm/Makefile
2426                 src/gbm/main/gbm.pc
2427                 src/glsl/Makefile
2428                 src/glx/Makefile
2429                 src/glx/apple/Makefile
2430                 src/glx/tests/Makefile
2431                 src/gtest/Makefile
2432                 src/loader/Makefile
2433                 src/mapi/Makefile
2434                 src/mapi/es1api/glesv1_cm.pc
2435                 src/mapi/es2api/glesv2.pc
2436                 src/mapi/glapi/gen/Makefile
2437                 src/mesa/Makefile
2438                 src/mesa/gl.pc
2439                 src/mesa/drivers/dri/dri.pc
2440                 src/mesa/drivers/dri/common/Makefile
2441                 src/mesa/drivers/dri/common/xmlpool/Makefile
2442                 src/mesa/drivers/dri/i915/Makefile
2443                 src/mesa/drivers/dri/i965/Makefile
2444                 src/mesa/drivers/dri/Makefile
2445                 src/mesa/drivers/dri/nouveau/Makefile
2446                 src/mesa/drivers/dri/r200/Makefile
2447                 src/mesa/drivers/dri/radeon/Makefile
2448                 src/mesa/drivers/dri/swrast/Makefile
2449                 src/mesa/drivers/osmesa/Makefile
2450                 src/mesa/drivers/osmesa/osmesa.pc
2451                 src/mesa/drivers/x11/Makefile
2452                 src/mesa/main/tests/Makefile
2453                 src/util/Makefile
2454                 src/util/tests/hash_table/Makefile])
2455
2456 AC_OUTPUT
2457
2458 dnl
2459 dnl Output some configuration info for the user
2460 dnl
2461 echo ""
2462 echo "        prefix:          $prefix"
2463 echo "        exec_prefix:     $exec_prefix"
2464 echo "        libdir:          $libdir"
2465 echo "        includedir:      $includedir"
2466
2467 dnl API info
2468 echo ""
2469 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2470
2471 dnl Driver info
2472 echo ""
2473 case "x$enable_osmesa$enable_gallium_osmesa" in
2474 xnoyes)
2475         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2476         ;;
2477 xyesno)
2478         echo "        OSMesa:          lib$OSMESA_LIB"
2479         ;;
2480 xnono)
2481         echo "        OSMesa:          no"
2482         ;;
2483 esac
2484
2485 echo ""
2486 if test "x$enable_dri" != xno; then
2487         echo "        DRI platform:    $dri_platform"
2488         if test -z "$DRI_DIRS"; then
2489             echo "        DRI drivers:     no"
2490         else
2491             echo "        DRI drivers:     $DRI_DIRS"
2492         fi
2493         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2494 fi
2495
2496 case "x$enable_glx$enable_xlib_glx" in
2497 xyesyes)
2498     echo "        GLX:             Xlib-based"
2499     ;;
2500 xyesno)
2501     echo "        GLX:             DRI-based"
2502     ;;
2503 *)
2504     echo "        GLX:             $enable_glx"
2505     ;;
2506 esac
2507
2508 dnl EGL
2509 echo ""
2510 echo "        EGL:             $enable_egl"
2511 if test "$enable_egl" = yes; then
2512     echo "        EGL platforms:   $egl_platforms"
2513
2514     egl_drivers=""
2515     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2516         egl_drivers="$egl_drivers builtin:egl_dri2"
2517     fi
2518
2519     echo "        EGL drivers:    $egl_drivers"
2520 fi
2521
2522 echo ""
2523 if test "x$MESA_LLVM" = x1; then
2524     echo "        llvm:            yes"
2525     echo "        llvm-config:     $LLVM_CONFIG"
2526     echo "        llvm-version:    $LLVM_VERSION"
2527 else
2528     echo "        llvm:            no"
2529 fi
2530
2531 echo ""
2532 if test -n "$with_gallium_drivers"; then
2533     echo "        Gallium:         yes"
2534 else
2535     echo "        Gallium:         no"
2536 fi
2537
2538 dnl Shader cache
2539 echo ""
2540 echo "        Shader cache:    $enable_shader_cache"
2541 if test "x$enable_shader_cache" = "xyes"; then
2542     echo "        With SHA1 from:  $with_sha1"
2543 fi
2544
2545 dnl Libraries
2546 echo ""
2547 echo "        Shared libs:     $enable_shared"
2548 echo "        Static libs:     $enable_static"
2549 echo "        Shared-glapi:    $enable_shared_glapi"
2550
2551 dnl Compiler options
2552 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2553 cflags=`echo $CFLAGS | \
2554     $SED 's/^ *//;s/  */ /;s/ *$//'`
2555 cxxflags=`echo $CXXFLAGS | \
2556     $SED 's/^ *//;s/  */ /;s/ *$//'`
2557 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2558 echo ""
2559 echo "        CFLAGS:          $cflags"
2560 echo "        CXXFLAGS:        $cxxflags"
2561 echo "        Macros:          $defines"
2562 echo ""
2563 if test "x$MESA_LLVM" = x1; then
2564     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2565     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2566     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2567     echo ""
2568 fi
2569 echo "        PYTHON2:         $PYTHON2"
2570
2571 echo ""
2572 echo "        Run '${MAKE-make}' to build Mesa"
2573 echo ""