configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LDFLAGS="$LDFLAGS"
 536 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LDFLAGS="$save_LDFLAGS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 case "$host_os" in
 556 mingw*)
 557     ;;
 558 *)
 559     AX_PTHREAD
 560     ;;
 561 esac
 562 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 563 dnl to -pthread, which causes problems if we need -lpthread to appear in
 564 dnl pkgconfig files.
 565 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 566
 567 dnl SELinux awareness.
 568 AC_ARG_ENABLE([selinux],
 569     [AS_HELP_STRING([--enable-selinux],
 570         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 571     [MESA_SELINUX="$enableval"],
 572     [MESA_SELINUX=no])
 573 if test "x$enable_selinux" = "xyes"; then
 574     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 575         [AC_CHECK_HEADER([selinux/selinux.h],[],
 576                          [AC_MSG_ERROR([SELinux headers not found])])
 577          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 578                       [AC_MSG_ERROR([SELinux library not found])])
 579          SELINUX_LIBS="-lselinux"])
 580     DEFINES="$DEFINES -DMESA_SELINUX"
 581 fi
 582 AC_SUBST([SELINUX_CFLAGS])
 583 AC_SUBST([SELINUX_LIBS])
 584
 585 dnl Options for APIs
 586 AC_ARG_ENABLE([opengl],
 587     [AS_HELP_STRING([--disable-opengl],
 588         [disable support for standard OpenGL API @<:@default=no@:>@])],
 589     [enable_opengl="$enableval"],
 590     [enable_opengl=yes])
 591 AC_ARG_ENABLE([gles1],
 592     [AS_HELP_STRING([--enable-gles1],
 593         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 594     [enable_gles1="$enableval"],
 595     [enable_gles1=no])
 596 AC_ARG_ENABLE([gles2],
 597     [AS_HELP_STRING([--enable-gles2],
 598         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 599     [enable_gles2="$enableval"],
 600     [enable_gles2=no])
 601 AC_ARG_ENABLE([openvg],
 602     [AS_HELP_STRING([--enable-openvg],
 603         [enable support for OpenVG API @<:@default=no@:>@])],
 604     [enable_openvg="$enableval"],
 605     [enable_openvg=no])
 606
 607 AC_ARG_ENABLE([dri],
 608     [AS_HELP_STRING([--enable-dri],
 609         [enable DRI modules @<:@default=enabled@:>@])],
 610     [enable_dri="$enableval"],
 611     [enable_dri=yes])
 612
 613 case "$host_os" in
 614 linux*)
 615     dri3_default=yes
 616     ;;
 617 *)
 618     dri3_default=no
 619     ;;
 620 esac
 621 AC_ARG_ENABLE([dri3],
 622     [AS_HELP_STRING([--enable-dri3],
 623         [enable DRI3 @<:@default=auto@:>@])],
 624     [enable_dri3="$enableval"],
 625     [enable_dri3="$dri3_default"])
 626 AC_ARG_ENABLE([glx],
 627     [AS_HELP_STRING([--enable-glx],
 628         [enable GLX library @<:@default=enabled@:>@])],
 629     [enable_glx="$enableval"],
 630     [enable_glx=yes])
 631 AC_ARG_ENABLE([osmesa],
 632     [AS_HELP_STRING([--enable-osmesa],
 633         [enable OSMesa library @<:@default=disabled@:>@])],
 634     [enable_osmesa="$enableval"],
 635     [enable_osmesa=no])
 636 AC_ARG_ENABLE([gallium-osmesa],
 637     [AS_HELP_STRING([--enable-gallium-osmesa],
 638         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 639     [enable_gallium_osmesa="$enableval"],
 640     [enable_gallium_osmesa=no])
 641 AC_ARG_ENABLE([egl],
 642     [AS_HELP_STRING([--disable-egl],
 643         [disable EGL library @<:@default=enabled@:>@])],
 644     [enable_egl="$enableval"],
 645     [enable_egl=yes])
 646
 647 AC_ARG_ENABLE([xa],
 648     [AS_HELP_STRING([--enable-xa],
 649         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 650     [enable_xa="$enableval"],
 651     [enable_xa=no])
 652 AC_ARG_ENABLE([gbm],
 653    [AS_HELP_STRING([--enable-gbm],
 654          [enable gbm library @<:@default=auto@:>@])],
 655    [enable_gbm="$enableval"],
 656    [enable_gbm=auto])
 657
 658 AC_ARG_ENABLE([xvmc],
 659    [AS_HELP_STRING([--enable-xvmc],
 660          [enable xvmc library @<:@default=auto@:>@])],
 661    [enable_xvmc="$enableval"],
 662    [enable_xvmc=no])
 663 AC_ARG_ENABLE([vdpau],
 664    [AS_HELP_STRING([--enable-vdpau],
 665          [enable vdpau library @<:@default=auto@:>@])],
 666    [enable_vdpau="$enableval"],
 667    [enable_vdpau=auto])
 668 AC_ARG_ENABLE([omx],
 669    [AS_HELP_STRING([--enable-omx],
 670          [enable OpenMAX library @<:@default=no@:>@])],
 671    [enable_omx="$enableval"],
 672    [enable_omx=no])
 673 AC_ARG_ENABLE([opencl],
 674    [AS_HELP_STRING([--enable-opencl],
 675          [enable OpenCL library @<:@default=no@:>@])],
 676    [enable_opencl="$enableval"],
 677    [enable_opencl=no])
 678 AC_ARG_ENABLE([opencl_icd],
 679    [AS_HELP_STRING([--enable-opencl-icd],
 680           [Build an OpenCL ICD library to be loaded by an ICD implementation
 681            @<:@default=no@:>@])],
 682     [enable_opencl_icd="$enableval"],
 683     [enable_opencl_icd=no])
 684 AC_ARG_ENABLE([xlib-glx],
 685     [AS_HELP_STRING([--enable-xlib-glx],
 686         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 687     [enable_xlib_glx="$enableval"],
 688     [enable_xlib_glx=no])
 689 AC_ARG_ENABLE([gallium-egl],
 690     [AS_HELP_STRING([--enable-gallium-egl],
 691         [enable optional EGL state tracker (not required
 692          for EGL support in Gallium with OpenGL and OpenGL ES)
 693          @<:@default=disable@:>@])],
 694     [enable_gallium_egl="$enableval"],
 695     [enable_gallium_egl=no])
 696 AC_ARG_ENABLE([gallium-gbm],
 697     [AS_HELP_STRING([--enable-gallium-gbm],
 698         [enable optional gbm state tracker (not required for
 699          gbm support in Gallium)
 700          @<:@default=auto@:>@])],
 701     [enable_gallium_gbm="$enableval"],
 702     [enable_gallium_gbm=auto])
 703
 704 AC_ARG_ENABLE([r600-llvm-compiler],
 705     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 706         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 707     [enable_r600_llvm="$enableval"],
 708     [enable_r600_llvm=no])
 709
 710 AC_ARG_ENABLE([gallium-tests],
 711     [AS_HELP_STRING([--enable-gallium-tests],
 712         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 713     [enable_gallium_tests="$enableval"],
 714     [enable_gallium_tests=no])
 715
 716 # Option for Gallium drivers
 717
 718 # Keep this in sync with the --with-gallium-drivers help string default value
 719 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 720
 721 AC_ARG_WITH([gallium-drivers],
 722     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 723         [comma delimited Gallium drivers list, e.g.
 724         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 725         @<:@default=r300,r600,svga,swrast@:>@])],
 726     [with_gallium_drivers="$withval"],
 727     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 728
 729 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 730 # here so that the script doesn't choke on an unknown driver name later.
 731 case "$with_gallium_drivers" in
 732     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 733     no) with_gallium_drivers='' ;;
 734 esac
 735
 736 if test "x$enable_opengl" = xno -a \
 737         "x$enable_gles1" = xno -a \
 738         "x$enable_gles2" = xno -a \
 739         "x$enable_openvg" = xno -a \
 740         "x$enable_xa" = xno -a \
 741         "x$enable_xvmc" = xno -a \
 742         "x$enable_vdpau" = xno -a \
 743         "x$enable_omx" = xno -a \
 744         "x$enable_opencl" = xno; then
 745     AC_MSG_ERROR([at least one API should be enabled])
 746 fi
 747
 748 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 749 if test "x$enable_opengl" = xno -a \
 750         "x$enable_gles1" = xyes; then
 751     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 752 fi
 753
 754 if test "x$enable_opengl" = xno -a \
 755         "x$enable_gles2" = xyes; then
 756     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 757 fi
 758
 759 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 760 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 761 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 762 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 763                                         "x$enable_gles1" = xyes -o \
 764                                         "x$enable_gles2" = xyes)
 765
 766 if test "x$enable_glx" = xno; then
 767     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 768     enable_xlib_glx=no
 769 fi
 770
 771 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 772     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 773 fi
 774
 775 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 776     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 777 fi
 778
 779 # Disable GLX if OpenGL is not enabled
 780 if test "x$enable_glx$enable_opengl" = xyesno; then
 781     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 782     enable_glx=no
 783 fi
 784
 785 # Disable GLX if DRI and Xlib-GLX are not enabled
 786 if test "x$enable_glx" = xyes -a \
 787         "x$enable_dri" = xno -a \
 788         "x$enable_xlib_glx" = xno; then
 789     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 790     enable_glx=no
 791 fi
 792
 793 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 794                                   "x$enable_dri" = xyes)
 795
 796 # Select which platform-dependent DRI code gets built
 797 case "$host_os" in
 798 darwin*)
 799     dri_platform='apple' ;;
 800 gnu*|mingw*|cygwin*)
 801     dri_platform='none' ;;
 802 *)
 803     dri_platform='drm' ;;
 804 esac
 805
 806 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 807 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 808 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 809 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 810 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 811
 812 AC_ARG_ENABLE([shared-glapi],
 813     [AS_HELP_STRING([--enable-shared-glapi],
 814         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 815     [enable_shared_glapi="$enableval"],
 816     [enable_shared_glapi=yes])
 817
 818 case "x$enable_opengl$enable_gles1$enable_gles2" in
 819 x*yes*yes*)
 820     if test "x$enable_shared_glapi" = xno; then
 821         AC_MSG_ERROR([shared GLAPI required when building two or more of
 822                       the following APIs - opengl, gles1 gles2])
 823     fi
 824     ;;
 825 esac
 826
 827 # Building Xlib-GLX requires shared glapi to be disabled.
 828 if test "x$enable_xlib_glx" = xyes; then
 829     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 830     enable_shared_glapi=no
 831 fi
 832
 833 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 834
 835 dnl
 836 dnl Driver specific build directories
 837 dnl
 838 GALLIUM_TARGET_DIRS=""
 839 GALLIUM_WINSYS_DIRS="sw"
 840 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 841 GALLIUM_STATE_TRACKERS_DIRS=""
 842
 843 case "x$enable_glx$enable_xlib_glx" in
 844 xyesyes)
 845     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 846     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 847     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 848     NEED_WINSYS_XLIB="yes"
 849     ;;
 850 esac
 851
 852 if test "x$enable_dri" = xyes; then
 853     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 854     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 855 fi
 856
 857 if test "x$enable_gallium_osmesa" = xyes; then
 858     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 859         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 860     fi
 861     if test "x$enable_osmesa" = xyes; then
 862         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 863     fi
 864     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 865     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 866 fi
 867
 868 AC_SUBST([MESA_LLVM])
 869
 870 # Check for libdrm
 871 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 872                   [have_libdrm=yes], [have_libdrm=no])
 873 if test "x$have_libdrm" = xyes; then
 874         DEFINES="$DEFINES -DHAVE_LIBDRM"
 875 fi
 876
 877 case "$host_os" in
 878 linux*)
 879     need_pci_id=yes ;;
 880 *)
 881     need_pci_id=no ;;
 882 esac
 883
 884 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 885                   have_libudev=yes, have_libudev=no)
 886
 887 AC_ARG_ENABLE([sysfs],
 888     [AS_HELP_STRING([--enable-sysfs],
 889         [enable /sys PCI identification @<:@default=disabled@:>@])],
 890     [have_sysfs="$enableval"],
 891     [have_sysfs=no]
 892 )
 893
 894 if test "x$enable_dri" = xyes; then
 895     if test "$enable_static" = yes; then
 896         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 897     fi
 898
 899     # not a hard requirement as swrast does not depend on it
 900     if test "x$have_libdrm" = xyes; then
 901         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 902     fi
 903 fi
 904
 905 dnl Direct rendering or just indirect rendering
 906 case "$host_os" in
 907 gnu*)
 908     dnl Disable by default on GNU/Hurd
 909     driglx_direct_default="no"
 910     ;;
 911 cygwin*)
 912     dnl Disable by default on cygwin
 913     driglx_direct_default="no"
 914     ;;
 915 *)
 916     driglx_direct_default="yes"
 917     ;;
 918 esac
 919 AC_ARG_ENABLE([driglx-direct],
 920     [AS_HELP_STRING([--disable-driglx-direct],
 921         [disable direct rendering in GLX and EGL for DRI \
 922             @<:@default=auto@:>@])],
 923     [driglx_direct="$enableval"],
 924     [driglx_direct="$driglx_direct_default"])
 925
 926 dnl
 927 dnl libGL configuration per driver
 928 dnl
 929 case "x$enable_glx$enable_xlib_glx" in
 930 xyesyes)
 931     # Xlib-based GLX
 932     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 933     GL_PC_REQ_PRIV="x11 xext"
 934     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 935     GL_LIB_DEPS="$XLIBGL_LIBS"
 936     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 937     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 938     ;;
 939 xyesno)
 940     # DRI-based GLX
 941     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 942
 943     # find the DRI deps for libGL
 944     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 945
 946     if test x"$driglx_direct" = xyes; then
 947         if test x"$dri_platform" = xdrm ; then
 948             if test "x$have_libdrm" != xyes; then
 949                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 950             fi
 951
 952             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 953             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 954             if test x"$enable_dri3" = xyes; then
 955                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 956                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 957             fi
 958
 959             if test x"$enable_dri" = xyes; then
 960                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 961             fi
 962
 963             if test x"$enable_dri3" = xyes; then
 964                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 965             fi
 966         fi
 967         if test x"$dri_platform" = xapple ; then
 968             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 969         fi
 970     fi
 971
 972     # add xf86vidmode if available
 973     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 974     if test "$HAVE_XF86VIDMODE" = yes ; then
 975         dri_modules="$dri_modules xxf86vm"
 976     fi
 977
 978     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 979     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 980     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 981     GL_LIB_DEPS="$DRIGL_LIBS"
 982
 983     # need DRM libs, $PTHREAD_LIBS, etc.
 984     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 985     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 986     ;;
 987 esac
 988
 989 have_pci_id=no
 990 if test "$have_libudev" = yes; then
 991     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 992     have_pci_id=yes
 993 fi
 994
 995 if test "$have_sysfs" = yes; then
 996     DEFINES="$DEFINES -DHAVE_SYSFS"
 997     have_pci_id=yes
 998 fi
 999
1000 # This is outside the case (above) so that it is invoked even for non-GLX
1001 # builds.
1002 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1003
1004 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1005 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1006 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1007 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1008
1009 AC_SUBST([X11_INCLUDES])
1010 AC_SUBST([GL_LIB_DEPS])
1011 AC_SUBST([GL_PC_REQ_PRIV])
1012 AC_SUBST([GL_PC_LIB_PRIV])
1013 AC_SUBST([GL_PC_CFLAGS])
1014 AC_SUBST([DRI_PC_REQ_PRIV])
1015 AC_SUBST([GLESv1_CM_LIB_DEPS])
1016 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1017 AC_SUBST([GLESv2_LIB_DEPS])
1018 AC_SUBST([GLESv2_PC_LIB_PRIV])
1019
1020 AC_SUBST([HAVE_XF86VIDMODE])
1021
1022 dnl
1023 dnl More GLX setup
1024 dnl
1025 case "x$enable_glx$enable_xlib_glx" in
1026 xyesyes)
1027     DEFINES="$DEFINES -DUSE_XSHM"
1028     ;;
1029 xyesno)
1030     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1031     if test "x$driglx_direct" = xyes; then
1032         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1033     fi
1034     ;;
1035 esac
1036
1037 dnl
1038 dnl TLS detection
1039 dnl
1040
1041 AC_ARG_ENABLE([glx-tls],
1042     [AS_HELP_STRING([--enable-glx-tls],
1043         [enable TLS support in GLX @<:@default=disabled@:>@])],
1044     [GLX_USE_TLS="$enableval"],
1045     [GLX_USE_TLS=no])
1046 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1047
1048 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1049       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1050
1051 dnl
1052 dnl More DRI setup
1053 dnl
1054 dnl Directory for DRI drivers
1055 AC_ARG_WITH([dri-driverdir],
1056     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1057         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1058     [DRI_DRIVER_INSTALL_DIR="$withval"],
1059     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1060 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1061 dnl Extra search path for DRI drivers
1062 AC_ARG_WITH([dri-searchpath],
1063     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1064         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1065     [DRI_DRIVER_SEARCH_DIR="$withval"],
1066     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1067 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1068 dnl Which drivers to build - default is chosen by platform
1069 AC_ARG_WITH([dri-drivers],
1070     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1071         [comma delimited classic DRI drivers list, e.g.
1072         "swrast,i965,radeon" @<:@default=auto@:>@])],
1073     [with_dri_drivers="$withval"],
1074     [with_dri_drivers=auto])
1075
1076 if test "x$with_dri_drivers" = xauto; then
1077     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1078         with_dri_drivers="yes"
1079     else
1080         with_dri_drivers="no"
1081     fi
1082 fi
1083 if test "x$with_dri_drivers" = xno; then
1084     with_dri_drivers=''
1085 fi
1086
1087 dnl If $with_dri_drivers is yes, drivers will be added through
1088 dnl platform checks. Set DEFINES and LIB_DEPS
1089 if test "x$enable_dri" = xyes; then
1090     # Platform specific settings and drivers to build
1091     case "$host_os" in
1092     linux*)
1093         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1094         DEFINES="$DEFINES -DHAVE_ALIAS"
1095         if test "x$enable_dri3" = xyes; then
1096             DEFINES="$DEFINES -DHAVE_DRI3"
1097         fi
1098
1099         if test "x$have_pci_id" != xyes; then
1100             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1101         fi
1102
1103         case "$host_cpu" in
1104         powerpc* | sparc*)
1105             # Build only the drivers for cards that exist on PowerPC/sparc
1106             if test "x$with_dri_drivers" = "xyes"; then
1107                 with_dri_drivers="r200 radeon swrast"
1108             fi
1109             ;;
1110         esac
1111         ;;
1112     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1113         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1114         DEFINES="$DEFINES -DHAVE_ALIAS"
1115         ;;
1116     gnu*)
1117         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1118         DEFINES="$DEFINES -DHAVE_ALIAS"
1119         ;;
1120     solaris*)
1121         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1122         ;;
1123     cygwin*)
1124         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1125         if test "x$with_dri_drivers" = "xyes"; then
1126             with_dri_drivers="swrast"
1127         fi
1128         ;;
1129     darwin*)
1130         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DGLX_ALIAS_UNSUPPORTED"
1131         if test "x$with_dri_drivers" = "xyes"; then
1132             with_dri_drivers="swrast"
1133         fi
1134         ;;
1135     esac
1136
1137     # default drivers
1138     if test "x$with_dri_drivers" = "xyes"; then
1139         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1140     fi
1141
1142     # Check for expat
1143     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1144     if test "x$have_expat" = "xyes"; then
1145        PKG_CHECK_MODULES([EXPAT], [expat], [],
1146                          AC_MSG_ERROR([Expat required for DRI.]))
1147     else
1148        # expat version 2.0 and earlier do not provide expat.pc
1149        EXPAT_LIBS=-lexpat
1150     fi
1151
1152     # If we are building any DRI driver other than swrast.
1153     if test -n "$with_dri_drivers"; then
1154         if test "x$with_dri_drivers" != xswrast; then
1155             # ... libdrm is required
1156             if test "x$have_libdrm" != xyes; then
1157                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1158             fi
1159             DRICOMMON_NEED_LIBDRM=yes
1160         else
1161             DRICOMMON_NEED_LIBDRM=no
1162         fi
1163     fi
1164
1165     # put all the necessary libs together
1166     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1167 fi
1168
1169 AC_SUBST([DRI_LIB_DEPS])
1170
1171 DRI_DIRS=''
1172 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1173 if test -n "$with_dri_drivers"; then
1174     if test "x$enable_opengl" != xyes; then
1175         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1176     fi
1177
1178     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1179     for driver in $dri_drivers; do
1180         DRI_DIRS="$DRI_DIRS $driver"
1181         case "x$driver" in
1182         xi915)
1183             HAVE_I915_DRI=yes;
1184             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1185             ;;
1186         xi965)
1187             HAVE_I965_DRI=yes;
1188             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1189             ;;
1190         xnouveau)
1191             HAVE_NOUVEAU_DRI=yes;
1192             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1193             ;;
1194         xradeon)
1195             HAVE_RADEON_DRI=yes;
1196             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1197             ;;
1198         xr200)
1199             HAVE_R200_DRI=yes;
1200             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1201             ;;
1202         xswrast)
1203             HAVE_SWRAST_DRI=yes;
1204             ;;
1205         *)
1206             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1207             ;;
1208         esac
1209     done
1210     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1211 fi
1212
1213 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1214 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1215                                   "x$enable_osmesa" = xyes -o \
1216                                   -n "$DRI_DIRS")
1217
1218 dnl
1219 dnl OSMesa configuration
1220 dnl
1221
1222 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1223 AC_ARG_WITH([osmesa-bits],
1224     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1225         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1226     [osmesa_bits="$withval"],
1227     [osmesa_bits=8])
1228 if test "x$osmesa_bits" != x8; then
1229     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1230         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1231         osmesa_bits=8
1232     fi
1233 fi
1234 case "x$osmesa_bits" in
1235 x8)
1236     OSMESA_LIB="${OSMESA_LIB}"
1237     ;;
1238 x16|x32)
1239     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1240     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1241     ;;
1242 *)
1243     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1244     ;;
1245 esac
1246
1247 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1248     # only link libraries with osmesa if shared
1249     if test "$enable_static" = no; then
1250         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1251     else
1252         OSMESA_LIB_DEPS=""
1253     fi
1254     OSMESA_MESA_DEPS=""
1255     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1256 fi
1257
1258 AC_SUBST([OSMESA_LIB_DEPS])
1259 AC_SUBST([OSMESA_MESA_DEPS])
1260 AC_SUBST([OSMESA_PC_REQ])
1261 AC_SUBST([OSMESA_PC_LIB_PRIV])
1262
1263 dnl
1264 dnl gbm configuration
1265 dnl
1266 if test "x$enable_gbm" = xauto; then
1267     case "$with_egl_platforms" in
1268         *drm*)
1269             enable_gbm=yes ;;
1270          *)
1271             enable_gbm=no ;;
1272     esac
1273 fi
1274 if test "x$enable_gbm" = xyes; then
1275     if test "x$need_pci_id$have_pci_id" = xyesno; then
1276         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1277     fi
1278
1279     if test "x$enable_dri" = xyes; then
1280         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1281         if test "x$enable_shared_glapi" = xno; then
1282             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1283         fi
1284     else
1285         # Strictly speaking libgbm does not require --enable-dri, although
1286         # both of its backends do. Thus one can build libgbm without any
1287         # backends if --disable-dri is set.
1288         # To avoid unnecessary complexity of checking if at least one backend
1289         # is available when building, just mandate --enable-dri.
1290         AC_MSG_ERROR([gbm requires --enable-dri])
1291     fi
1292 fi
1293 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1294 if test "x$need_pci_id$have_libudev" = xyesyes; then
1295     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1296 else
1297     GBM_PC_REQ_PRIV=""
1298 fi
1299 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1300 AC_SUBST([GBM_PC_REQ_PRIV])
1301 AC_SUBST([GBM_PC_LIB_PRIV])
1302
1303 dnl
1304 dnl EGL configuration
1305 dnl
1306 EGL_CLIENT_APIS=""
1307
1308 if test "x$enable_egl" = xyes; then
1309     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1310
1311     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1312
1313     if test "$enable_static" != yes; then
1314         if test "x$enable_dri" = xyes; then
1315             HAVE_EGL_DRIVER_DRI2=1
1316         fi
1317
1318     fi
1319 fi
1320 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1321 AC_SUBST([EGL_LIB_DEPS])
1322
1323 dnl
1324 dnl EGL Gallium configuration
1325 dnl
1326 if test "x$enable_gallium_egl" = xyes; then
1327     if test -z "$with_gallium_drivers"; then
1328         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1329     fi
1330     if test "x$enable_egl" = xno; then
1331         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1332     fi
1333     if test "x$have_libdrm" != xyes; then
1334         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1335     fi
1336
1337     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1338     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1339 fi
1340 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1341
1342 dnl
1343 dnl gbm Gallium configuration
1344 dnl
1345 if test "x$enable_gallium_gbm" = xauto; then
1346     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1347         yesyesyes*drm*)
1348             enable_gallium_gbm=yes ;;
1349          *)
1350             enable_gallium_gbm=no ;;
1351     esac
1352 fi
1353 if test "x$enable_gallium_gbm" = xyes; then
1354     if test -z "$with_gallium_drivers"; then
1355         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1356     fi
1357     if test "x$enable_gbm" = xno; then
1358         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1359     fi
1360     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1361     if test "x$enable_dri" = xno; then
1362         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1363     fi
1364
1365     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1366     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1367     enable_gallium_loader=yes
1368 fi
1369 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1370
1371 dnl
1372 dnl XA configuration
1373 dnl
1374 if test "x$enable_xa" = xyes; then
1375     if test "x$with_gallium_drivers" = xswrast; then
1376        AC_MSG_ERROR([
1377           Building xa requires at least one non swrast gallium driver.
1378           If you are looking to use libxatracker.so with vmware's virtual gpu,
1379           make sure to include svga in the gallium drivers list, apart from
1380           enabling XA.
1381           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1382     fi
1383     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1384     enable_gallium_loader=yes
1385 fi
1386 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1387
1388 dnl
1389 dnl OpenVG configuration
1390 dnl
1391 VG_LIB_DEPS=""
1392
1393 if test "x$enable_openvg" = xyes; then
1394     if test "x$enable_egl" = xno; then
1395         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1396     fi
1397     if test -z "$with_gallium_drivers"; then
1398         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1399     fi
1400     if test "x$enable_gallium_egl" = xno; then
1401         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1402     fi
1403
1404     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1405     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1406     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1407     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1408     AC_SUBST([VG_PC_LIB_PRIV])
1409 fi
1410 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1411
1412 dnl
1413 dnl Gallium G3DVL configuration
1414 dnl
1415 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1416     if test "x$enable_xvmc" = xauto; then
1417         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1418     fi
1419
1420     if test "x$enable_vdpau" = xauto; then
1421         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1422     fi
1423
1424     if test "x$enable_omx" = xauto; then
1425         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1426     fi
1427 fi
1428
1429 if test "x$enable_xvmc" = xyes; then
1430     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1431     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1432 fi
1433 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1434
1435 if test "x$enable_vdpau" = xyes; then
1436     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1437                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1438     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1439 fi
1440 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1441
1442 if test "x$enable_omx" = xyes; then
1443     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1444     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1445 fi
1446 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1447
1448 dnl
1449 dnl OpenCL configuration
1450 dnl
1451
1452 AC_ARG_WITH([libclc-path],
1453    [AS_HELP_STRING([--with-libclc-path],
1454          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1455    [LIBCLC_PATH="$withval"],
1456    [LIBCLC_PATH=''])
1457
1458 if test -n "$LIBCLC_PATH"; then
1459    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1460                   Please review the updated build instructions for clover:
1461                   http://dri.freedesktop.org/wiki/GalliumCompute])
1462 fi
1463
1464
1465 AC_ARG_WITH([clang-libdir],
1466    [AS_HELP_STRING([--with-clang-libdir],
1467          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1468    [CLANG_LIBDIR="$withval"],
1469    [CLANG_LIBDIR=''])
1470
1471 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1472
1473 if test "x$enable_opencl" = xyes; then
1474     if test -z "$with_gallium_drivers"; then
1475         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1476     fi
1477
1478     if test "x$enable_gallium_llvm" != xyes; then
1479         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1480     fi
1481
1482     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1483         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1484     fi
1485
1486     if test "x$have_libclc" = xno; then
1487         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1488                     Make sure the directory containing libclc.pc is specified in your
1489                     PKG_CONFIG_PATH environment variable.
1490                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1491     else
1492         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1493         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1494         AC_SUBST([LIBCLC_INCLUDEDIR])
1495         AC_SUBST([LIBCLC_LIBEXECDIR])
1496     fi
1497
1498     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1499     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1500     enable_gallium_loader=yes
1501
1502     if test "x$enable_opencl_icd" = xyes; then
1503         OPENCL_LIBNAME="MesaOpenCL"
1504     else
1505         OPENCL_LIBNAME="OpenCL"
1506     fi
1507 fi
1508 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1509 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1510 AC_SUBST([OPENCL_LIBNAME])
1511
1512 dnl
1513 dnl Gallium configuration
1514 dnl
1515 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1516
1517 AC_SUBST([LLVM_BINDIR])
1518 AC_SUBST([LLVM_CFLAGS])
1519 AC_SUBST([LLVM_CPPFLAGS])
1520 AC_SUBST([LLVM_CXXFLAGS])
1521 AC_SUBST([LLVM_LIBDIR])
1522 AC_SUBST([LLVM_LIBS])
1523 AC_SUBST([LLVM_LDFLAGS])
1524 AC_SUBST([LLVM_INCLUDEDIR])
1525 AC_SUBST([LLVM_VERSION])
1526 AC_SUBST([CLANG_RESOURCE_DIR])
1527
1528 case "x$enable_opengl$enable_gles1$enable_gles2" in
1529 x*yes*)
1530     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1531     ;;
1532 esac
1533
1534 AC_SUBST([VG_LIB_DEPS])
1535 AC_SUBST([EGL_CLIENT_APIS])
1536
1537 dnl
1538 dnl EGL Platforms configuration
1539 dnl
1540 AC_ARG_WITH([egl-platforms],
1541     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1542         [comma delimited native platforms libEGL supports, e.g.
1543         "x11,drm" @<:@default=auto@:>@])],
1544     [with_egl_platforms="$withval"],
1545     [if test "x$enable_egl" = xyes; then
1546         with_egl_platforms="x11"
1547     else
1548         with_egl_platforms=""
1549     fi])
1550
1551 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1552     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1553 fi
1554
1555 # Do per-EGL platform setups and checks
1556 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1557 for plat in $egl_platforms; do
1558         case "$plat" in
1559         wayland)
1560                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1561                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1562
1563                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1564                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1565                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1566                 ;;
1567
1568         x11)
1569                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1570                 ;;
1571
1572         drm)
1573                 test "x$enable_gbm" = "xno" &&
1574                         AC_MSG_ERROR([EGL platform drm needs gbm])
1575                 test "x$have_libdrm" != xyes &&
1576                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1577                 ;;
1578
1579         android|fbdev|gdi|null)
1580                 ;;
1581
1582         *)
1583                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1584                 ;;
1585         esac
1586
1587         case "$plat$need_pci_id$have_pci_id" in
1588                 waylandyesno|drmyesno)
1589                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1590         esac
1591 done
1592
1593 # libEGL wants to default to the first platform specified in
1594 # ./configure.  parse that here.
1595 if test "x$egl_platforms" != "x"; then
1596     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1597     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1598 else
1599     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1600 fi
1601
1602 if echo "$egl_platforms" | grep -q 'x11'; then
1603     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1604     NEED_WINSYS_XLIB=yes
1605 fi
1606 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1607 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1608 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1609 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1610 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1611
1612 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1613
1614 AC_SUBST([EGL_NATIVE_PLATFORM])
1615 AC_SUBST([EGL_CFLAGS])
1616
1617 # If we don't have the X11 platform, set this define so we don't try to include
1618 # the X11 headers.
1619 if ! echo "$egl_platforms" | grep -q 'x11'; then
1620     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1621     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1622 fi
1623
1624 AC_ARG_WITH([egl-driver-dir],
1625     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1626                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1627     [EGL_DRIVER_INSTALL_DIR="$withval"],
1628     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1629 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1630
1631 AC_ARG_WITH([max-width],
1632     [AS_HELP_STRING([--with-max-width=N],
1633                     [Maximum framebuffer width (4096)])],
1634     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1635      AS_IF([test "${withval}" -gt "4096"],
1636            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1637 )
1638 AC_ARG_WITH([max-height],
1639     [AS_HELP_STRING([--with-max-height=N],
1640                     [Maximum framebuffer height (4096)])],
1641     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1642      AS_IF([test "${withval}" -gt "4096"],
1643            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1644 )
1645
1646 dnl
1647 dnl Gallium LLVM
1648 dnl
1649 AC_ARG_ENABLE([gallium-llvm],
1650     [AS_HELP_STRING([--enable-gallium-llvm],
1651         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1652     [enable_gallium_llvm="$enableval"],
1653     [enable_gallium_llvm=auto])
1654
1655 AC_ARG_ENABLE([llvm-shared-libs],
1656     [AS_HELP_STRING([--enable-llvm-shared-libs],
1657         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1658     [enable_llvm_shared_libs="$enableval"],
1659     [enable_llvm_shared_libs=yes])
1660
1661 AC_ARG_WITH([llvm-prefix],
1662     [AS_HELP_STRING([--with-llvm-prefix],
1663         [Prefix for LLVM installations in non-standard locations])],
1664     [llvm_prefix="$withval"],
1665     [llvm_prefix=''])
1666
1667
1668 # Call this inside ` ` to get the return value.
1669 # $1 is the llvm-config command with arguments.
1670 strip_unwanted_llvm_flags() {
1671     # Use \> (marks the end of the word)
1672     echo `$1` | sed \
1673         -e 's/-DNDEBUG\>//g' \
1674         -e 's/-pedantic\>//g' \
1675         -e 's/-Wcovered-switch-default\>//g' \
1676         -e 's/-O.\>//g' \
1677         -e 's/-g\>//g' \
1678         -e 's/-Wall\>//g' \
1679         -e 's/-Wcast-qual\>//g' \
1680         -e 's/-Woverloaded-virtual\>//g' \
1681         -e 's/-fcolor-diagnostics\>//g' \
1682         -e 's/-fdata-sections\>//g' \
1683         -e 's/-ffunction-sections\>//g' \
1684         -e 's/-fno-exceptions\>//g' \
1685         -e 's/-fomit-frame-pointer\>//g' \
1686         -e 's/-fvisibility-inlines-hidden\>//g' \
1687         -e 's/-fPIC\>//g' \
1688         -e 's/-fstack-protector-strong\>//g'
1689 }
1690
1691
1692 if test -z "$with_gallium_drivers"; then
1693     enable_gallium_llvm=no
1694 fi
1695 if test "x$enable_gallium_llvm" = xauto; then
1696     case "$host_cpu" in
1697     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1698     esac
1699 fi
1700 if test "x$enable_gallium_llvm" = xyes; then
1701     if test -n "$llvm_prefix"; then
1702         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1703     else
1704         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1705     fi
1706
1707     if test "x$LLVM_CONFIG" != xno; then
1708         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1709         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1710         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1711         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1712         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1713         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1714         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1715         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1716
1717         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1718             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1719         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1720             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1721
1722         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1723         dnl llvm-config.h
1724         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1725             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1726             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1727
1728         if test -n "${LLVM_VERSION_MAJOR}"; then
1729             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1730         else
1731             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1732         fi
1733
1734         LLVM_REQUIRED_VERSION_MAJOR="3"
1735         LLVM_REQUIRED_VERSION_MINOR="1"
1736         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1737             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1738         fi
1739
1740         LLVM_COMPONENTS="engine bitwriter"
1741         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1742             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1743         fi
1744
1745         if test "x$enable_opencl" = xyes; then
1746             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1747             # LLVM 3.3 >= 177971 requires IRReader
1748             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1749                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1750             fi
1751             # LLVM 3.4 requires Option
1752             if $LLVM_CONFIG --components | grep -qw 'option'; then
1753                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1754             fi
1755             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1756             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1757                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1758             fi
1759             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1760                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1761             fi
1762         fi
1763         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1764         MESA_LLVM=1
1765
1766         dnl Check for Clang internal headers
1767         if test "x$enable_opencl" = xyes; then
1768             if test -z "$CLANG_LIBDIR"; then
1769                 CLANG_LIBDIR=${LLVM_LIBDIR}
1770             fi
1771             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1772             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1773                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1774         fi
1775     else
1776         MESA_LLVM=0
1777         LLVM_VERSION_INT=0
1778     fi
1779 else
1780     MESA_LLVM=0
1781     LLVM_VERSION_INT=0
1782 fi
1783
1784 dnl Directory for XVMC libs
1785 AC_ARG_WITH([xvmc-libdir],
1786     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1787         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1788     [XVMC_LIB_INSTALL_DIR="$withval"],
1789     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1790 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1791
1792 dnl
1793 dnl Gallium Tests
1794 dnl
1795 if test "x$enable_gallium_tests" = xyes; then
1796     enable_gallium_loader=yes
1797 fi
1798 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1799
1800 if test "x$enable_gallium_loader" = xyes; then
1801     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1802 fi
1803 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1804
1805 dnl Directory for VDPAU libs
1806 AC_ARG_WITH([vdpau-libdir],
1807     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1808         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1809     [VDPAU_LIB_INSTALL_DIR="$withval"],
1810     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1811 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1812
1813 OMX_LIB_INSTALL_DIR_DEFAULT=''
1814 if test "x$enable_omx" = xyes; then
1815     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1816 fi
1817
1818 AC_ARG_WITH([omx-libdir],
1819     [AS_HELP_STRING([--with-omx-libdir=DIR],
1820         [directory for the OMX libraries])],
1821     [OMX_LIB_INSTALL_DIR="$withval"],
1822     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1823 AC_SUBST([OMX_LIB_INSTALL_DIR])
1824
1825 dnl Directory for OpenCL libs
1826 AC_ARG_WITH([opencl-libdir],
1827     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1828         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1829     [OPENCL_LIB_INSTALL_DIR="$withval"],
1830     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1831 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1832
1833 dnl
1834 dnl Gallium helper functions
1835 dnl
1836 gallium_check_st() {
1837     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1838          if test "x$have_libdrm" != xyes; then
1839             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1840          fi
1841          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1842     fi
1843     if test "x$enable_dri" = xyes && test -n "$2"; then
1844          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1845     fi
1846     if test "x$enable_xa" = xyes && test -n "$3"; then
1847          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1848     fi
1849     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1850          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1851     fi
1852     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1853          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1854     fi
1855     if test "x$enable_omx" = xyes && test "x$6" != x; then
1856          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1857     fi
1858 }
1859
1860 gallium_require_llvm() {
1861     if test "x$MESA_LLVM" = x0; then
1862         case "$host_cpu" in
1863         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1864         esac
1865     fi
1866 }
1867
1868 gallium_require_drm_loader() {
1869     if test "x$enable_gallium_loader" = xyes; then
1870         if test "x$need_pci_id$have_pci_id" = xyesno; then
1871             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1872         fi
1873         if test "x$have_libdrm" != xyes; then
1874             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1875         fi
1876         enable_gallium_drm_loader=yes
1877     fi
1878 }
1879
1880 require_egl_drm() {
1881     case "$with_egl_platforms" in
1882         *drm*)
1883             ;;
1884          *)
1885             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1886             ;;
1887     esac
1888     if test "x$enable_gbm" != xyes; then
1889             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1890     fi
1891 }
1892
1893 radeon_llvm_check() {
1894     if test "x$enable_gallium_llvm" != "xyes"; then
1895         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1896     fi
1897     LLVM_REQUIRED_VERSION_MAJOR="3"
1898     LLVM_REQUIRED_VERSION_MINOR="3"
1899     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1900         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1901     fi
1902     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1903         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1904                       sources with the --enable-experimental-targets=R600
1905                       configure flag])
1906     fi
1907     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1908     NEED_RADEON_LLVM=yes
1909     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1910                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1911 }
1912
1913 dnl Gallium drivers
1914 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1915         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1916     NEED_NONNULL_WINSYS=yes
1917 fi
1918 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1919
1920 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1921 if test -n "$with_gallium_drivers"; then
1922     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1923     for driver in $gallium_drivers; do
1924         case "x$driver" in
1925         xsvga)
1926             HAVE_GALLIUM_SVGA=yes
1927             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1928             gallium_require_drm_loader
1929             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1930             ;;
1931         xi915)
1932             HAVE_GALLIUM_I915=yes
1933             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1934             gallium_require_drm_loader
1935             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1936             if test "x$MESA_LLVM" = x1; then
1937                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1938             fi
1939             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1940             gallium_check_st "i915/drm" "dri-i915"
1941             DRICOMMON_NEED_LIBDRM=yes
1942             ;;
1943         xilo)
1944             HAVE_GALLIUM_ILO=yes
1945             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1946             gallium_require_drm_loader
1947             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1948             gallium_check_st "intel/drm" "dri-ilo"
1949             DRICOMMON_NEED_LIBDRM=yes
1950             ;;
1951         xr300)
1952             HAVE_GALLIUM_R300=yes
1953             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1954             gallium_require_drm_loader
1955             gallium_require_llvm "Gallium R300"
1956             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1957             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1958             DRICOMMON_NEED_LIBDRM=yes
1959             ;;
1960         xr600)
1961             HAVE_GALLIUM_R600=yes
1962             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1963             gallium_require_drm_loader
1964             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1965             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1966                 radeon_llvm_check "r600g"
1967                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1968             fi
1969             if test "x$enable_r600_llvm" = xyes; then
1970                 USE_R600_LLVM_COMPILER=yes;
1971             fi
1972             if test "x$enable_opencl" = xyes; then
1973                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1974             fi
1975             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1976             DRICOMMON_NEED_LIBDRM=yes
1977             ;;
1978         xradeonsi)
1979             HAVE_GALLIUM_RADEONSI=yes
1980             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1981             gallium_require_drm_loader
1982             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1983             radeon_llvm_check "radeonsi"
1984             require_egl_drm "radeonsi"
1985             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1986             DRICOMMON_NEED_LIBDRM=yes
1987             ;;
1988         xnouveau)
1989             HAVE_GALLIUM_NOUVEAU=yes
1990             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1991             gallium_require_drm_loader
1992             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1993             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1994             DRICOMMON_NEED_LIBDRM=yes
1995             ;;
1996         xfreedreno)
1997             HAVE_GALLIUM_FREEDRENO=yes
1998             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1999             gallium_require_drm_loader
2000             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
2001             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
2002             DRICOMMON_NEED_LIBDRM=yes
2003             ;;
2004         xswrast)
2005             HAVE_GALLIUM_SOFTPIPE=yes
2006             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2007             if test "x$MESA_LLVM" = x1; then
2008                 HAVE_GALLIUM_LLVMPIPE=yes
2009                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2010             fi
2011
2012             if test "x$enable_dri" = xyes; then
2013                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2014             fi
2015             ;;
2016         *)
2017             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2018             ;;
2019         esac
2020     done
2021 fi
2022
2023 dnl Set LLVM_LIBS - This is done after the driver configuration so
2024 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2025 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2026 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2027 dnl this was causing the same libraries to be appear multiple times
2028 dnl in LLVM_LIBS.
2029
2030 if test "x$MESA_LLVM" != x0; then
2031
2032     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2033
2034     if test "x$enable_llvm_shared_libs" = xyes; then
2035         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2036         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2037         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2038
2039         if test "x$llvm_have_one_so" = xyes; then
2040             dnl LLVM was built using auto*, so there is only one shared object.
2041             LLVM_LIBS="-l$LLVM_SO_NAME"
2042         else
2043             dnl If LLVM was built with CMake, there will be one shared object per
2044             dnl component.
2045             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2046                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2047         Please make sure you have built llvm with the --enable-shared option
2048         and that your llvm libraries are installed in $LLVM_LIBDIR
2049         If you have installed your llvm libraries to a different directory you
2050         can use the --with-llvm-prefix= configure flag to specify this directory.
2051         NOTE: Mesa is attempting to use llvm shared libraries by default.
2052         If you do not want to build with llvm shared libraries and instead want to
2053         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2054         invocation and rebuild.])])
2055
2056            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2057            dnl install uses a shared object for each compoenent and we have
2058            dnl already added all of these objects to LLVM_LIBS.
2059         fi
2060     else
2061         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2062     fi
2063 fi
2064
2065 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2066 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2067 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2068 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2069 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2070 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2071 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2072                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2073 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2074 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2075 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2076 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2077
2078 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2079                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
2080                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2081 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2082                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2083                                                   && test "x$MESA_LLVM" = x1)
2084
2085 # NOTE: anything using xcb or other client side libs ends up in separate
2086 #       _CLIENT variables.  The pipe loader is built in two variants,
2087 #       one that is standalone and does not link any x client libs (for
2088 #       use by XA tracker in particular, but could be used in any case
2089 #       where communication with xserver is not desired).
2090 if test "x$enable_gallium_loader" = xyes; then
2091     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2092
2093     if test "x$NEED_WINSYS_XLIB" = xyes; then
2094         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2095     fi
2096
2097     if test "x$enable_dri" = xyes; then
2098         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2099     fi
2100
2101     if test "x$enable_gallium_drm_loader" = xyes; then
2102         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2103         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2104                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2105         if test "x$pipe_loader_have_xcb" = xyes; then
2106             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2107             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2108         fi
2109     fi
2110
2111     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2112     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2113
2114     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2115     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2116     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2117     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2118 fi
2119
2120 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2121 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2122 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2123 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2124 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2125 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2126
2127 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2128                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2129                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2130                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2131 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2132                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2133 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2134 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2135 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2136 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2137 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2138 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2139 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2140
2141 AC_SUBST([ELF_LIB])
2142
2143 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2144 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2145 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2146 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2147 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2148
2149 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2150 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2151 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2152
2153 AC_SUBST([VDPAU_MAJOR], 1)
2154 AC_SUBST([VDPAU_MINOR], 0)
2155
2156 AC_SUBST([XVMC_MAJOR], 1)
2157 AC_SUBST([XVMC_MINOR], 0)
2158
2159 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2160 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2161 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2162 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2163
2164 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2165 AC_SUBST([XA_MINOR], $XA_MINOR)
2166 AC_SUBST([XA_TINY], $XA_TINY)
2167 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2168
2169 dnl Restore LDFLAGS and CPPFLAGS
2170 LDFLAGS="$_SAVE_LDFLAGS"
2171 CPPFLAGS="$_SAVE_CPPFLAGS"
2172
2173 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2174 if test "x$acv_mesa_CLANG" = xyes; then
2175     CFLAGS="$CFLAGS -Qunused-arguments"
2176     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2177 fi
2178
2179 dnl Add user CFLAGS and CXXFLAGS
2180 CFLAGS="$CFLAGS $USER_CFLAGS"
2181 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2182
2183 dnl Substitute the config
2184 AC_CONFIG_FILES([Makefile
2185                 src/Makefile
2186                 src/egl/drivers/dri2/Makefile
2187                 src/egl/main/Makefile
2188                 src/egl/main/egl.pc
2189                 src/egl/wayland/Makefile
2190                 src/egl/wayland/wayland-drm/Makefile
2191                 src/egl/wayland/wayland-egl/Makefile
2192                 src/egl/wayland/wayland-egl/wayland-egl.pc
2193                 src/gallium/auxiliary/Makefile
2194                 src/gallium/auxiliary/pipe-loader/Makefile
2195                 src/gallium/drivers/Makefile
2196                 src/gallium/drivers/freedreno/Makefile
2197                 src/gallium/drivers/galahad/Makefile
2198                 src/gallium/drivers/i915/Makefile
2199                 src/gallium/drivers/identity/Makefile
2200                 src/gallium/drivers/ilo/Makefile
2201                 src/gallium/drivers/llvmpipe/Makefile
2202                 src/gallium/drivers/noop/Makefile
2203                 src/gallium/drivers/nouveau/Makefile
2204                 src/gallium/drivers/r300/Makefile
2205                 src/gallium/drivers/r600/Makefile
2206                 src/gallium/drivers/radeon/Makefile
2207                 src/gallium/drivers/radeonsi/Makefile
2208                 src/gallium/drivers/rbug/Makefile
2209                 src/gallium/drivers/softpipe/Makefile
2210                 src/gallium/drivers/svga/Makefile
2211                 src/gallium/drivers/trace/Makefile
2212                 src/gallium/state_trackers/Makefile
2213                 src/gallium/state_trackers/clover/Makefile
2214                 src/gallium/state_trackers/dri/Makefile
2215                 src/gallium/state_trackers/dri/drm/Makefile
2216                 src/gallium/state_trackers/dri/sw/Makefile
2217                 src/gallium/state_trackers/egl/Makefile
2218                 src/gallium/state_trackers/gbm/Makefile
2219                 src/gallium/state_trackers/glx/xlib/Makefile
2220                 src/gallium/state_trackers/omx/Makefile
2221                 src/gallium/state_trackers/osmesa/Makefile
2222                 src/gallium/state_trackers/vdpau/Makefile
2223                 src/gallium/state_trackers/vega/Makefile
2224                 src/gallium/state_trackers/xa/Makefile
2225                 src/gallium/state_trackers/xvmc/Makefile
2226                 src/gallium/targets/Makefile
2227                 src/gallium/targets/dri-freedreno/Makefile
2228                 src/gallium/targets/dri-i915/Makefile
2229                 src/gallium/targets/dri-ilo/Makefile
2230                 src/gallium/targets/dri-nouveau/Makefile
2231                 src/gallium/targets/dri-swrast/Makefile
2232                 src/gallium/targets/dri-vmwgfx/Makefile
2233                 src/gallium/targets/egl-static/Makefile
2234                 src/gallium/targets/gbm/Makefile
2235                 src/gallium/targets/opencl/Makefile
2236                 src/gallium/targets/xa/Makefile
2237                 src/gallium/targets/xa/xatracker.pc
2238                 src/gallium/targets/omx-nouveau/Makefile
2239                 src/gallium/targets/osmesa/Makefile
2240                 src/gallium/targets/osmesa/osmesa.pc
2241                 src/gallium/targets/pipe-loader/Makefile
2242                 src/gallium/targets/radeonsi/dri/Makefile
2243                 src/gallium/targets/radeonsi/omx/Makefile
2244                 src/gallium/targets/radeonsi/vdpau/Makefile
2245                 src/gallium/targets/r300/dri/Makefile
2246                 src/gallium/targets/r600/dri/Makefile
2247                 src/gallium/targets/r600/omx/Makefile
2248                 src/gallium/targets/r600/vdpau/Makefile
2249                 src/gallium/targets/r600/xvmc/Makefile
2250                 src/gallium/targets/libgl-xlib/Makefile
2251                 src/gallium/targets/vdpau-nouveau/Makefile
2252                 src/gallium/targets/xvmc-nouveau/Makefile
2253                 src/gallium/tests/trivial/Makefile
2254                 src/gallium/tests/unit/Makefile
2255                 src/gallium/winsys/Makefile
2256                 src/gallium/winsys/freedreno/drm/Makefile
2257                 src/gallium/winsys/i915/drm/Makefile
2258                 src/gallium/winsys/i915/sw/Makefile
2259                 src/gallium/winsys/intel/drm/Makefile
2260                 src/gallium/winsys/nouveau/drm/Makefile
2261                 src/gallium/winsys/radeon/drm/Makefile
2262                 src/gallium/winsys/svga/drm/Makefile
2263                 src/gallium/winsys/sw/dri/Makefile
2264                 src/gallium/winsys/sw/fbdev/Makefile
2265                 src/gallium/winsys/sw/null/Makefile
2266                 src/gallium/winsys/sw/wayland/Makefile
2267                 src/gallium/winsys/sw/wrapper/Makefile
2268                 src/gallium/winsys/sw/xlib/Makefile
2269                 src/gbm/Makefile
2270                 src/gbm/main/gbm.pc
2271                 src/glsl/Makefile
2272                 src/glx/Makefile
2273                 src/glx/apple/Makefile
2274                 src/glx/tests/Makefile
2275                 src/gtest/Makefile
2276                 src/loader/Makefile
2277                 src/mapi/Makefile
2278                 src/mapi/es1api/Makefile
2279                 src/mapi/es1api/glesv1_cm.pc
2280                 src/mapi/es2api/Makefile
2281                 src/mapi/es2api/glesv2.pc
2282                 src/mapi/glapi/Makefile
2283                 src/mapi/glapi/gen/Makefile
2284                 src/mapi/glapi/tests/Makefile
2285                 src/mapi/shared-glapi/Makefile
2286                 src/mapi/shared-glapi/tests/Makefile
2287                 src/mapi/vgapi/Makefile
2288                 src/mapi/vgapi/vg.pc
2289                 src/mesa/Makefile
2290                 src/mesa/gl.pc
2291                 src/mesa/drivers/dri/dri.pc
2292                 src/mesa/drivers/dri/common/Makefile
2293                 src/mesa/drivers/dri/common/xmlpool/Makefile
2294                 src/mesa/drivers/dri/i915/Makefile
2295                 src/mesa/drivers/dri/i965/Makefile
2296                 src/mesa/drivers/dri/Makefile
2297                 src/mesa/drivers/dri/nouveau/Makefile
2298                 src/mesa/drivers/dri/r200/Makefile
2299                 src/mesa/drivers/dri/radeon/Makefile
2300                 src/mesa/drivers/dri/swrast/Makefile
2301                 src/mesa/drivers/osmesa/Makefile
2302                 src/mesa/drivers/osmesa/osmesa.pc
2303                 src/mesa/drivers/x11/Makefile
2304                 src/mesa/main/tests/Makefile
2305                 src/mesa/main/tests/hash_table/Makefile])
2306
2307 dnl Sort the dirs alphabetically
2308 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2309 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2310 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2311 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2312
2313 AC_OUTPUT
2314
2315 dnl
2316 dnl Output some configuration info for the user
2317 dnl
2318 echo ""
2319 echo "        prefix:          $prefix"
2320 echo "        exec_prefix:     $exec_prefix"
2321 echo "        libdir:          $libdir"
2322 echo "        includedir:      $includedir"
2323
2324 dnl API info
2325 echo ""
2326 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2327 echo "        OpenVG:          $enable_openvg"
2328
2329 dnl Driver info
2330 echo ""
2331 case "x$enable_osmesa$enable_gallium_osmesa" in
2332 xnoyes)
2333         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2334         ;;
2335 xyesno)
2336         echo "        OSMesa:          lib$OSMESA_LIB"
2337         ;;
2338 xnono)
2339         echo "        OSMesa:          no"
2340         ;;
2341 esac
2342
2343 echo ""
2344 if test "x$enable_dri" != xno; then
2345         echo "        DRI platform:    $dri_platform"
2346         if test -z "$DRI_DIRS"; then
2347             echo "        DRI drivers:     no"
2348         else
2349             echo "        DRI drivers:     $DRI_DIRS"
2350         fi
2351         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2352 fi
2353
2354 case "x$enable_glx$enable_xlib_glx" in
2355 xyesyes)
2356     echo "        GLX:             Xlib-based"
2357     ;;
2358 xyesno)
2359     echo "        GLX:             DRI-based"
2360     ;;
2361 *)
2362     echo "        GLX:             $enable_glx"
2363     ;;
2364 esac
2365
2366 dnl EGL
2367 echo ""
2368 echo "        EGL:             $enable_egl"
2369 if test "$enable_egl" = yes; then
2370     echo "        EGL platforms:   $egl_platforms"
2371
2372     egl_drivers=""
2373     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2374         egl_drivers="$egl_drivers builtin:egl_dri2"
2375     fi
2376
2377     if test "x$enable_gallium_egl" = xyes; then
2378         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2379         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2380     else
2381         echo "        EGL drivers:    $egl_drivers"
2382     fi
2383 fi
2384
2385 echo ""
2386 if test "x$MESA_LLVM" = x1; then
2387     echo "        llvm:            yes"
2388     echo "        llvm-config:     $LLVM_CONFIG"
2389     echo "        llvm-version:    $LLVM_VERSION"
2390 else
2391     echo "        llvm:            no"
2392 fi
2393
2394 echo ""
2395 if test -n "$with_gallium_drivers"; then
2396     echo "        Gallium:         yes"
2397     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2398     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2399     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2400     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2401 else
2402     echo "        Gallium:         no"
2403 fi
2404
2405
2406 dnl Libraries
2407 echo ""
2408 echo "        Shared libs:     $enable_shared"
2409 echo "        Static libs:     $enable_static"
2410 echo "        Shared-glapi:    $enable_shared_glapi"
2411
2412 dnl Compiler options
2413 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2414 cflags=`echo $CFLAGS | \
2415     $SED 's/^ *//;s/  */ /;s/ *$//'`
2416 cxxflags=`echo $CXXFLAGS | \
2417     $SED 's/^ *//;s/  */ /;s/ *$//'`
2418 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2419 echo ""
2420 echo "        CFLAGS:          $cflags"
2421 echo "        CXXFLAGS:        $cxxflags"
2422 echo "        Macros:          $defines"
2423 echo ""
2424 if test "x$MESA_LLVM" = x1; then
2425     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2426     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2427     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2428     echo ""
2429 fi
2430 echo "        PYTHON2:         $PYTHON2"
2431
2432 echo ""
2433 echo "        Run '${MAKE-make}' to build Mesa"
2434 echo ""