configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.55
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCB_REQUIRED=1.9.3
  45 XCBDRI2_REQUIRED=1.8
  46 XCBGLX_REQUIRED=1.8.1
  47 XSHMFENCE_REQUIRED=1.1
  48 XVMC_REQUIRED=1.0.6
  49
  50 dnl Check for progs
  51 AC_PROG_CPP
  52 AC_PROG_CC
  53 AC_PROG_CXX
  54 AM_PROG_CC_C_O
  55 AM_PROG_AS
  56 AC_CHECK_PROGS([MAKE], [gmake make])
  57 AC_CHECK_PROGS([PYTHON2], [python2 python])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 AC_SYS_LARGEFILE
  62
  63 LT_PREREQ([2.2])
  64 LT_INIT([disable-static])
  65
  66 AX_PROG_BISON([],
  67               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  68                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  69 AX_PROG_FLEX([],
  70              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  71                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133 AX_GCC_BUILTIN([__builtin_clz])
 134 AX_GCC_BUILTIN([__builtin_clzll])
 135 AX_GCC_BUILTIN([__builtin_ctz])
 136 AX_GCC_BUILTIN([__builtin_expect])
 137 AX_GCC_BUILTIN([__builtin_ffs])
 138 AX_GCC_BUILTIN([__builtin_ffsll])
 139 AX_GCC_BUILTIN([__builtin_popcount])
 140 AX_GCC_BUILTIN([__builtin_popcountll])
 141 AX_GCC_BUILTIN([__builtin_unreachable])
 142
 143 AX_GCC_FUNC_ATTRIBUTE([flatten])
 144 AX_GCC_FUNC_ATTRIBUTE([format])
 145 AX_GCC_FUNC_ATTRIBUTE([packed])
 146
 147 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 148
 149 dnl Make sure the pkg-config macros are defined
 150 m4_ifndef([PKG_PROG_PKG_CONFIG],
 151     [m4_fatal([Could not locate the pkg-config autoconf macros.
 152   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 153   are in a different location, try setting the environment variable
 154   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 155 PKG_PROG_PKG_CONFIG()
 156
 157 dnl LIB_DIR - library basename
 158 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 159 AC_SUBST([LIB_DIR])
 160
 161 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 162 _SAVE_LDFLAGS="$LDFLAGS"
 163 _SAVE_CPPFLAGS="$CPPFLAGS"
 164
 165 dnl Compiler macros
 166 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 167 AC_SUBST([DEFINES])
 168 case "$host_os" in
 169 linux*|*-gnu*|gnu*)
 170     DEFINES="$DEFINES -D_GNU_SOURCE"
 171     ;;
 172 solaris*)
 173     DEFINES="$DEFINES -DSVR4"
 174     ;;
 175 cygwin*)
 176     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 177     ;;
 178 esac
 179
 180 dnl Add flags for gcc and g++
 181 if test "x$GCC" = xyes; then
 182     CFLAGS="$CFLAGS -Wall -std=c99"
 183
 184     # Enable -Werror=implicit-function-declaration and
 185     # -Werror=missing-prototypes, if available, or otherwise, just
 186     # -Wmissing-prototypes.  This is particularly useful to avoid
 187     # generating a loadable driver module that has undefined symbols.
 188     save_CFLAGS="$CFLAGS"
 189     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 190     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 191     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 193                    AC_MSG_RESULT([yes]),
 194                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 195                     AC_MSG_RESULT([no])]);
 196
 197     # Enable -fvisibility=hidden if using a gcc that supports it
 198     save_CFLAGS="$CFLAGS"
 199     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 200     VISIBILITY_CFLAGS="-fvisibility=hidden"
 201     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 202     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 203                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 204
 205     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 206     CFLAGS=$save_CFLAGS
 207
 208     # Work around aliasing bugs - developers should comment this out
 209     CFLAGS="$CFLAGS -fno-strict-aliasing"
 210
 211     # gcc's builtin memcmp is slower than glibc's
 212     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 213     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 214 fi
 215 if test "x$GXX" = xyes; then
 216     CXXFLAGS="$CXXFLAGS -Wall"
 217
 218     # Enable -fvisibility=hidden if using a gcc that supports it
 219     save_CXXFLAGS="$CXXFLAGS"
 220     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 221     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 222     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 223     AC_LANG_PUSH([C++])
 224     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 225                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 226     AC_LANG_POP([C++])
 227
 228     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 229     CXXFLAGS=$save_CXXFLAGS
 230
 231     # Work around aliasing bugs - developers should comment this out
 232     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 233
 234     # gcc's builtin memcmp is slower than glibc's
 235     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 236     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 237 fi
 238
 239 dnl even if the compiler appears to support it, using visibility attributes isn't
 240 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 241 case "$host_os" in
 242 cygwin*)
 243     VISIBILITY_CFLAGS=""
 244     VISIBILITY_CXXFLAGS=""
 245     ;;
 246 esac
 247
 248 AC_SUBST([VISIBILITY_CFLAGS])
 249 AC_SUBST([VISIBILITY_CXXFLAGS])
 250
 251 dnl
 252 dnl Optional flags, check for compiler support
 253 dnl
 254 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 255 if test "x$SSE41_SUPPORTED" = x1; then
 256     DEFINES="$DEFINES -DUSE_SSE41"
 257 fi
 258 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 259
 260 dnl Can't have static and shared libraries, default to static if user
 261 dnl explicitly requested. If both disabled, set to static since shared
 262 dnl was explicitly requested.
 263 case "x$enable_static$enable_shared" in
 264 xyesyes)
 265     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 266     enable_shared=no
 267     ;;
 268 xnono)
 269     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 270     enable_shared=yes
 271     ;;
 272 esac
 273
 274 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 275
 276 dnl
 277 dnl other compiler options
 278 dnl
 279 AC_ARG_ENABLE([debug],
 280     [AS_HELP_STRING([--enable-debug],
 281         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 282     [enable_debug="$enableval"],
 283     [enable_debug=no]
 284 )
 285 if test "x$enable_debug" = xyes; then
 286     DEFINES="$DEFINES -DDEBUG"
 287     if test "x$GCC" = xyes; then
 288         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 289             CFLAGS="$CFLAGS -g"
 290         fi
 291         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 292             CFLAGS="$CFLAGS -O0"
 293         fi
 294     fi
 295     if test "x$GXX" = xyes; then
 296         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 297             CXXFLAGS="$CXXFLAGS -g"
 298         fi
 299         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 300             CXXFLAGS="$CXXFLAGS -O0"
 301         fi
 302     fi
 303 fi
 304
 305 dnl
 306 dnl Check if linker supports -Bsymbolic
 307 dnl
 308 save_LDFLAGS=$LDFLAGS
 309 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 310 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 311 AC_LINK_IFELSE(
 312     [AC_LANG_SOURCE([int main() { return 0;}])],
 313     [AC_MSG_RESULT([yes])
 314         BSYMBOLIC="-Wl,-Bsymbolic";],
 315     [AC_MSG_RESULT([no])
 316         BSYMBOLIC="";])
 317 LDFLAGS=$save_LDFLAGS
 318
 319 AC_SUBST([BSYMBOLIC])
 320
 321 dnl
 322 dnl Check if linker supports garbage collection
 323 dnl
 324 save_LDFLAGS=$LDFLAGS
 325 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 326 AC_MSG_CHECKING([whether ld supports --gc-sections])
 327 AC_LINK_IFELSE(
 328     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 329     [AC_MSG_RESULT([yes])
 330         GC_SECTIONS="-Wl,--gc-sections";],
 331     [AC_MSG_RESULT([no])
 332         GC_SECTIONS="";])
 333 LDFLAGS=$save_LDFLAGS
 334
 335 AC_SUBST([GC_SECTIONS])
 336
 337 dnl
 338 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 339 dnl so when these flags are passed to ld via libtool the checks will fail
 340 dnl
 341 case "$host_os" in
 342 openbsd* | darwin* )
 343     LD_NO_UNDEFINED="" ;;
 344 *)
 345     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 346 esac
 347
 348 AC_SUBST([LD_NO_UNDEFINED])
 349
 350 dnl
 351 dnl Check if linker supports version scripts
 352 dnl
 353 AC_MSG_CHECKING([if the linker supports version-scripts])
 354 save_LDFLAGS=$LDFLAGS
 355 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 356 cat > conftest.map <<EOF
 357 VERSION_1 {
 358      global:
 359          main;
 360
 361      local:
 362          *;
 363 };
 364 EOF
 365 AC_LINK_IFELSE(
 366     [AC_LANG_SOURCE([int main() { return 0;}])],
 367     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 368     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 369 LDFLAGS=$save_LDFLAGS
 370 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 371
 372 dnl
 373 dnl Check if linker supports dynamic list files
 374 dnl
 375 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 376 save_LDFLAGS=$LDFLAGS
 377 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 378 cat > conftest.dyn <<EOF
 379 {
 380         radeon_drm_winsys_create;
 381 };
 382 EOF
 383 AC_LINK_IFELSE(
 384     [AC_LANG_SOURCE([int main() { return 0;}])],
 385     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 386     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 387 LDFLAGS=$save_LDFLAGS
 388 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 389
 390 dnl
 391 dnl compatibility symlinks
 392 dnl
 393 case "$host_os" in
 394 linux* )
 395     HAVE_COMPAT_SYMLINKS=yes ;;
 396 * )
 397     HAVE_COMPAT_SYMLINKS=no ;;
 398 esac
 399
 400 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 401
 402 dnl
 403 dnl library names
 404 dnl
 405 case "$host_os" in
 406 darwin* )
 407     LIB_EXT='dylib' ;;
 408 cygwin* )
 409     LIB_EXT='dll' ;;
 410 aix* )
 411     LIB_EXT='a' ;;
 412 * )
 413     LIB_EXT='so' ;;
 414 esac
 415
 416 AC_SUBST([LIB_EXT])
 417
 418 AC_ARG_WITH([gl-lib-name],
 419   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 420     [specify GL library name @<:@default=GL@:>@])],
 421   [GL_LIB=$withval],
 422   [GL_LIB=GL])
 423 AC_ARG_WITH([osmesa-lib-name],
 424   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 425     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 426   [OSMESA_LIB=$withval],
 427   [OSMESA_LIB=OSMesa])
 428 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 429 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 430
 431 dnl
 432 dnl Mangled Mesa support
 433 dnl
 434 AC_ARG_ENABLE([mangling],
 435   [AS_HELP_STRING([--enable-mangling],
 436     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 437   [enable_mangling="${enableval}"],
 438   [enable_mangling=no]
 439 )
 440 if test "x${enable_mangling}" = "xyes" ; then
 441   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 442   GL_LIB="Mangled${GL_LIB}"
 443   OSMESA_LIB="Mangled${OSMESA_LIB}"
 444 fi
 445 AC_SUBST([GL_LIB])
 446 AC_SUBST([OSMESA_LIB])
 447
 448 dnl
 449 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 450 dnl
 451 AC_ARG_ENABLE([texture-float],
 452     [AS_HELP_STRING([--enable-texture-float],
 453         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 454     [enable_texture_float="$enableval"],
 455     [enable_texture_float=no]
 456 )
 457 if test "x$enable_texture_float" = xyes; then
 458     AC_MSG_WARN([Floating-point textures enabled.])
 459     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 460     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 461 fi
 462
 463 dnl
 464 dnl Arch/platform-specific settings
 465 dnl
 466 AC_ARG_ENABLE([asm],
 467     [AS_HELP_STRING([--disable-asm],
 468         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 469     [enable_asm="$enableval"],
 470     [enable_asm=yes]
 471 )
 472 asm_arch=""
 473 AC_MSG_CHECKING([whether to enable assembly])
 474 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 475 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 476 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 477     case "$host_cpu" in
 478     i?86 | x86_64 | amd64)
 479         enable_asm=no
 480         AC_MSG_RESULT([no, cross compiling])
 481         ;;
 482     esac
 483 fi
 484 # check for supported arches
 485 if test "x$enable_asm" = xyes; then
 486     case "$host_cpu" in
 487     i?86)
 488         case "$host_os" in
 489         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 490             asm_arch=x86
 491             ;;
 492         esac
 493         ;;
 494     x86_64|amd64)
 495         case "$host_os" in
 496         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 497             asm_arch=x86_64
 498             ;;
 499         esac
 500         ;;
 501     sparc*)
 502         case "$host_os" in
 503         linux*)
 504             asm_arch=sparc
 505             ;;
 506         esac
 507         ;;
 508     esac
 509
 510     case "$asm_arch" in
 511     x86)
 512         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 513         AC_MSG_RESULT([yes, x86])
 514         ;;
 515     x86_64|amd64)
 516         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 517         AC_MSG_RESULT([yes, x86_64])
 518         ;;
 519     sparc)
 520         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 521         AC_MSG_RESULT([yes, sparc])
 522         ;;
 523     *)
 524         AC_MSG_RESULT([no, platform not supported])
 525         ;;
 526     esac
 527 fi
 528
 529 dnl Check to see if dlopen is in default libraries (like Solaris, which
 530 dnl has it in libc), or if libdl is needed to get it.
 531 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 532     [AC_CHECK_LIB([dl], [dlopen],
 533        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 534 AC_SUBST([DLOPEN_LIBS])
 535
 536 dnl Check if that library also has dladdr
 537 save_LIBS="$LIBS"
 538 LIBS="$LIBS $DLOPEN_LIBS"
 539 AC_CHECK_FUNCS([dladdr])
 540 LIBS="$save_LIBS"
 541
 542 case "$host_os" in
 543 darwin*|mingw*)
 544     ;;
 545 *)
 546     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 547                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 548                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 549     AC_SUBST([CLOCK_LIB])
 550     ;;
 551 esac
 552
 553 dnl See if posix_memalign is available
 554 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 555
 556 dnl Check for pthreads
 557 case "$host_os" in
 558 mingw*)
 559     ;;
 560 *)
 561     AX_PTHREAD
 562     ;;
 563 esac
 564 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 565 dnl to -pthread, which causes problems if we need -lpthread to appear in
 566 dnl pkgconfig files.
 567 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 568
 569 dnl SELinux awareness.
 570 AC_ARG_ENABLE([selinux],
 571     [AS_HELP_STRING([--enable-selinux],
 572         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 573     [MESA_SELINUX="$enableval"],
 574     [MESA_SELINUX=no])
 575 if test "x$enable_selinux" = "xyes"; then
 576     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 577         [AC_CHECK_HEADER([selinux/selinux.h],[],
 578                          [AC_MSG_ERROR([SELinux headers not found])])
 579          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 580                       [AC_MSG_ERROR([SELinux library not found])])
 581          SELINUX_LIBS="-lselinux"])
 582     DEFINES="$DEFINES -DMESA_SELINUX"
 583 fi
 584 AC_SUBST([SELINUX_CFLAGS])
 585 AC_SUBST([SELINUX_LIBS])
 586
 587 dnl Options for APIs
 588 AC_ARG_ENABLE([opengl],
 589     [AS_HELP_STRING([--disable-opengl],
 590         [disable support for standard OpenGL API @<:@default=no@:>@])],
 591     [enable_opengl="$enableval"],
 592     [enable_opengl=yes])
 593 AC_ARG_ENABLE([gles1],
 594     [AS_HELP_STRING([--enable-gles1],
 595         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 596     [enable_gles1="$enableval"],
 597     [enable_gles1=no])
 598 AC_ARG_ENABLE([gles2],
 599     [AS_HELP_STRING([--enable-gles2],
 600         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 601     [enable_gles2="$enableval"],
 602     [enable_gles2=no])
 603 AC_ARG_ENABLE([openvg],
 604     [AS_HELP_STRING([--enable-openvg],
 605         [enable support for OpenVG API @<:@default=no@:>@])],
 606     [enable_openvg="$enableval"],
 607     [enable_openvg=no])
 608
 609 AC_ARG_ENABLE([dri],
 610     [AS_HELP_STRING([--enable-dri],
 611         [enable DRI modules @<:@default=enabled@:>@])],
 612     [enable_dri="$enableval"],
 613     [enable_dri=yes])
 614
 615 case "$host_os" in
 616 linux*)
 617     dri3_default=yes
 618     ;;
 619 *)
 620     dri3_default=no
 621     ;;
 622 esac
 623 AC_ARG_ENABLE([dri3],
 624     [AS_HELP_STRING([--enable-dri3],
 625         [enable DRI3 @<:@default=auto@:>@])],
 626     [enable_dri3="$enableval"],
 627     [enable_dri3="$dri3_default"])
 628 AC_ARG_ENABLE([glx],
 629     [AS_HELP_STRING([--enable-glx],
 630         [enable GLX library @<:@default=enabled@:>@])],
 631     [enable_glx="$enableval"],
 632     [enable_glx=yes])
 633 AC_ARG_ENABLE([osmesa],
 634     [AS_HELP_STRING([--enable-osmesa],
 635         [enable OSMesa library @<:@default=disabled@:>@])],
 636     [enable_osmesa="$enableval"],
 637     [enable_osmesa=no])
 638 AC_ARG_ENABLE([gallium-osmesa],
 639     [AS_HELP_STRING([--enable-gallium-osmesa],
 640         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 641     [enable_gallium_osmesa="$enableval"],
 642     [enable_gallium_osmesa=no])
 643 AC_ARG_ENABLE([egl],
 644     [AS_HELP_STRING([--disable-egl],
 645         [disable EGL library @<:@default=enabled@:>@])],
 646     [enable_egl="$enableval"],
 647     [enable_egl=yes])
 648
 649 AC_ARG_ENABLE([xa],
 650     [AS_HELP_STRING([--enable-xa],
 651         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 652     [enable_xa="$enableval"],
 653     [enable_xa=no])
 654 AC_ARG_ENABLE([gbm],
 655    [AS_HELP_STRING([--enable-gbm],
 656          [enable gbm library @<:@default=auto@:>@])],
 657    [enable_gbm="$enableval"],
 658    [enable_gbm=auto])
 659
 660 AC_ARG_ENABLE([xvmc],
 661    [AS_HELP_STRING([--enable-xvmc],
 662          [enable xvmc library @<:@default=auto@:>@])],
 663    [enable_xvmc="$enableval"],
 664    [enable_xvmc=auto])
 665 AC_ARG_ENABLE([vdpau],
 666    [AS_HELP_STRING([--enable-vdpau],
 667          [enable vdpau library @<:@default=auto@:>@])],
 668    [enable_vdpau="$enableval"],
 669    [enable_vdpau=auto])
 670 AC_ARG_ENABLE([omx],
 671    [AS_HELP_STRING([--enable-omx],
 672          [enable OpenMAX library @<:@default=no@:>@])],
 673    [enable_omx="$enableval"],
 674    [enable_omx=no])
 675 AC_ARG_ENABLE([opencl],
 676    [AS_HELP_STRING([--enable-opencl],
 677          [enable OpenCL library @<:@default=no@:>@])],
 678    [enable_opencl="$enableval"],
 679    [enable_opencl=no])
 680 AC_ARG_ENABLE([opencl_icd],
 681    [AS_HELP_STRING([--enable-opencl-icd],
 682           [Build an OpenCL ICD library to be loaded by an ICD implementation
 683            @<:@default=no@:>@])],
 684     [enable_opencl_icd="$enableval"],
 685     [enable_opencl_icd=no])
 686 AC_ARG_ENABLE([xlib-glx],
 687     [AS_HELP_STRING([--enable-xlib-glx],
 688         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 689     [enable_xlib_glx="$enableval"],
 690     [enable_xlib_glx=no])
 691 AC_ARG_ENABLE([gallium-egl],
 692     [AS_HELP_STRING([--enable-gallium-egl],
 693         [enable optional EGL state tracker (not required
 694          for EGL support in Gallium with OpenGL and OpenGL ES)
 695          @<:@default=disable@:>@])],
 696     [enable_gallium_egl="$enableval"],
 697     [enable_gallium_egl=no])
 698 AC_ARG_ENABLE([gallium-gbm],
 699     [AS_HELP_STRING([--enable-gallium-gbm],
 700         [enable optional gbm state tracker (not required for
 701          gbm support in Gallium)
 702          @<:@default=auto@:>@])],
 703     [enable_gallium_gbm="$enableval"],
 704     [enable_gallium_gbm=auto])
 705
 706 AC_ARG_ENABLE([r600-llvm-compiler],
 707     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 708         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 709     [enable_r600_llvm="$enableval"],
 710     [enable_r600_llvm=no])
 711
 712 AC_ARG_ENABLE([gallium-tests],
 713     [AS_HELP_STRING([--enable-gallium-tests],
 714         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 715     [enable_gallium_tests="$enableval"],
 716     [enable_gallium_tests=no])
 717
 718 # Option for Gallium drivers
 719
 720 # Keep this in sync with the --with-gallium-drivers help string default value
 721 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 722
 723 AC_ARG_WITH([gallium-drivers],
 724     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 725         [comma delimited Gallium drivers list, e.g.
 726         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 727         @<:@default=r300,r600,svga,swrast@:>@])],
 728     [with_gallium_drivers="$withval"],
 729     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 730
 731 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 732 # here so that the script doesn't choke on an unknown driver name later.
 733 case "$with_gallium_drivers" in
 734     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 735     no) with_gallium_drivers='' ;;
 736 esac
 737
 738 if test "x$enable_opengl" = xno -a \
 739         "x$enable_gles1" = xno -a \
 740         "x$enable_gles2" = xno -a \
 741         "x$enable_openvg" = xno -a \
 742         "x$enable_xa" = xno -a \
 743         "x$enable_xvmc" = xno -a \
 744         "x$enable_vdpau" = xno -a \
 745         "x$enable_omx" = xno -a \
 746         "x$enable_opencl" = xno; then
 747     AC_MSG_ERROR([at least one API should be enabled])
 748 fi
 749
 750 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 751 if test "x$enable_opengl" = xno -a \
 752         "x$enable_gles1" = xyes; then
 753     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 754 fi
 755
 756 if test "x$enable_opengl" = xno -a \
 757         "x$enable_gles2" = xyes; then
 758     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 759 fi
 760
 761 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 762 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 763 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 764 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 765                                         "x$enable_gles1" = xyes -o \
 766                                         "x$enable_gles2" = xyes)
 767
 768 if test "x$enable_glx" = xno; then
 769     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 770     enable_xlib_glx=no
 771 fi
 772
 773 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 774     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 775 fi
 776
 777 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 778     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 779 fi
 780
 781 # Disable GLX if OpenGL is not enabled
 782 if test "x$enable_glx$enable_opengl" = xyesno; then
 783     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 784     enable_glx=no
 785 fi
 786
 787 # Disable GLX if DRI and Xlib-GLX are not enabled
 788 if test "x$enable_glx" = xyes -a \
 789         "x$enable_dri" = xno -a \
 790         "x$enable_xlib_glx" = xno; then
 791     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 792     enable_glx=no
 793 fi
 794
 795 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 796                                   "x$enable_dri" = xyes)
 797
 798 # Select which platform-dependent DRI code gets built
 799 case "$host_os" in
 800 darwin*)
 801     dri_platform='apple' ;;
 802 gnu*|mingw*|cygwin*)
 803     dri_platform='none' ;;
 804 *)
 805     dri_platform='drm' ;;
 806 esac
 807
 808 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 809 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 810 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 811 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 812 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 813
 814 AC_ARG_ENABLE([shared-glapi],
 815     [AS_HELP_STRING([--enable-shared-glapi],
 816         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 817     [enable_shared_glapi="$enableval"],
 818     [enable_shared_glapi=yes])
 819
 820 case "x$enable_opengl$enable_gles1$enable_gles2" in
 821 x*yes*yes*)
 822     if test "x$enable_shared_glapi" = xno; then
 823         AC_MSG_ERROR([shared GLAPI required when building two or more of
 824                       the following APIs - opengl, gles1 gles2])
 825     fi
 826     ;;
 827 esac
 828
 829 # Building Xlib-GLX requires shared glapi to be disabled.
 830 if test "x$enable_xlib_glx" = xyes; then
 831     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 832     enable_shared_glapi=no
 833 fi
 834
 835 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 836
 837 # Build the pipe-drivers as separate libraries/modules.
 838 # Do not touch this unless you know what you are doing.
 839 # XXX: Expose via configure option ?
 840 enable_shared_pipe_drivers=no
 841
 842 dnl
 843 dnl Driver specific build directories
 844 dnl
 845 GALLIUM_TARGET_DIRS=""
 846 GALLIUM_WINSYS_DIRS="sw"
 847 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 848 GALLIUM_STATE_TRACKERS_DIRS=""
 849
 850 case "x$enable_glx$enable_xlib_glx" in
 851 xyesyes)
 852     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 853     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 854     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 855     NEED_WINSYS_XLIB="yes"
 856     ;;
 857 esac
 858
 859 if test "x$enable_dri" = xyes; then
 860     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 861     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 862     enable_gallium_loader="$enable_shared_pipe_drivers"
 863 fi
 864
 865 if test "x$enable_gallium_osmesa" = xyes; then
 866     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 867         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 868     fi
 869     if test "x$enable_osmesa" = xyes; then
 870         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 871     fi
 872     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 873     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 874 fi
 875
 876 AC_SUBST([MESA_LLVM])
 877
 878 # Check for libdrm
 879 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 880                   [have_libdrm=yes], [have_libdrm=no])
 881 if test "x$have_libdrm" = xyes; then
 882         DEFINES="$DEFINES -DHAVE_LIBDRM"
 883 fi
 884
 885 case "$host_os" in
 886 linux*)
 887     need_pci_id=yes ;;
 888 *)
 889     need_pci_id=no ;;
 890 esac
 891
 892 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 893                   have_libudev=yes, have_libudev=no)
 894
 895 AC_ARG_ENABLE([sysfs],
 896     [AS_HELP_STRING([--enable-sysfs],
 897         [enable /sys PCI identification @<:@default=disabled@:>@])],
 898     [have_sysfs="$enableval"],
 899     [have_sysfs=no]
 900 )
 901
 902 if test "x$enable_dri" = xyes; then
 903     if test "$enable_static" = yes; then
 904         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 905     fi
 906
 907     # not a hard requirement as swrast does not depend on it
 908     if test "x$have_libdrm" = xyes; then
 909         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 910     fi
 911 fi
 912
 913 AC_ARG_ENABLE([driglx-direct],
 914     [AS_HELP_STRING([--disable-driglx-direct],
 915         [disable direct rendering in GLX and EGL for DRI \
 916             @<:@default=auto@:>@])],
 917     [driglx_direct="$enableval"],
 918     [driglx_direct="yes"])
 919
 920 dnl
 921 dnl libGL configuration per driver
 922 dnl
 923 case "x$enable_glx$enable_xlib_glx" in
 924 xyesyes)
 925     # Xlib-based GLX
 926     dri_modules="x11 xext xcb"
 927     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 928     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 929     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 930     GL_LIB_DEPS="$XLIBGL_LIBS"
 931     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 932     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 933     ;;
 934 xyesno)
 935     # DRI-based GLX
 936     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 937
 938     # find the DRI deps for libGL
 939     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 940
 941     if test x"$driglx_direct" = xyes; then
 942         if test x"$dri_platform" = xdrm ; then
 943             DEFINES="$DEFINES -DGLX_USE_DRM"
 944             if test "x$have_libdrm" != xyes; then
 945                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 946             fi
 947
 948             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 949             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 950             if test x"$enable_dri3" = xyes; then
 951                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 952                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 953             fi
 954
 955             if test x"$enable_dri" = xyes; then
 956                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 957             fi
 958
 959             if test x"$enable_dri3" = xyes; then
 960                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 961                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 962             fi
 963         fi
 964         if test x"$dri_platform" = xapple ; then
 965             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 966         fi
 967     fi
 968
 969     # add xf86vidmode if available
 970     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 971     if test "$HAVE_XF86VIDMODE" = yes ; then
 972         dri_modules="$dri_modules xxf86vm"
 973     fi
 974
 975     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 976     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 977     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 978     GL_LIB_DEPS="$DRIGL_LIBS"
 979
 980     # need DRM libs, $PTHREAD_LIBS, etc.
 981     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 982     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 983     ;;
 984 esac
 985
 986 have_pci_id=no
 987 if test "$have_libudev" = yes; then
 988     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 989     have_pci_id=yes
 990 fi
 991
 992 if test "$have_sysfs" = yes; then
 993     DEFINES="$DEFINES -DHAVE_SYSFS"
 994     have_pci_id=yes
 995 fi
 996
 997 # This is outside the case (above) so that it is invoked even for non-GLX
 998 # builds.
 999 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1000
1001 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1002 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1003 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1004 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1005
1006 AC_SUBST([X11_INCLUDES])
1007 AC_SUBST([GL_LIB_DEPS])
1008 AC_SUBST([GL_PC_REQ_PRIV])
1009 AC_SUBST([GL_PC_LIB_PRIV])
1010 AC_SUBST([GL_PC_CFLAGS])
1011 AC_SUBST([DRI_PC_REQ_PRIV])
1012 AC_SUBST([GLESv1_CM_LIB_DEPS])
1013 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1014 AC_SUBST([GLESv2_LIB_DEPS])
1015 AC_SUBST([GLESv2_PC_LIB_PRIV])
1016
1017 AC_SUBST([HAVE_XF86VIDMODE])
1018
1019 dnl
1020 dnl More GLX setup
1021 dnl
1022 case "x$enable_glx$enable_xlib_glx" in
1023 xyesyes)
1024     DEFINES="$DEFINES -DUSE_XSHM"
1025     ;;
1026 xyesno)
1027     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1028     if test "x$driglx_direct" = xyes; then
1029         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1030     fi
1031     ;;
1032 esac
1033
1034 dnl
1035 dnl TLS detection
1036 dnl
1037
1038 AC_ARG_ENABLE([glx-tls],
1039     [AS_HELP_STRING([--enable-glx-tls],
1040         [enable TLS support in GLX @<:@default=disabled@:>@])],
1041     [GLX_USE_TLS="$enableval"],
1042     [GLX_USE_TLS=no])
1043 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1044
1045 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1046       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1047
1048 dnl
1049 dnl More DRI setup
1050 dnl
1051 dnl Directory for DRI drivers
1052 AC_ARG_WITH([dri-driverdir],
1053     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1054         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1055     [DRI_DRIVER_INSTALL_DIR="$withval"],
1056     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1057 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1058 dnl Extra search path for DRI drivers
1059 AC_ARG_WITH([dri-searchpath],
1060     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1061         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1062     [DRI_DRIVER_SEARCH_DIR="$withval"],
1063     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1064 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1065 dnl Which drivers to build - default is chosen by platform
1066 AC_ARG_WITH([dri-drivers],
1067     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1068         [comma delimited classic DRI drivers list, e.g.
1069         "swrast,i965,radeon" @<:@default=auto@:>@])],
1070     [with_dri_drivers="$withval"],
1071     [with_dri_drivers=auto])
1072
1073 if test "x$with_dri_drivers" = xauto; then
1074     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1075         with_dri_drivers="yes"
1076     else
1077         with_dri_drivers="no"
1078     fi
1079 fi
1080 if test "x$with_dri_drivers" = xno; then
1081     with_dri_drivers=''
1082 fi
1083
1084 dnl If $with_dri_drivers is yes, drivers will be added through
1085 dnl platform checks. Set DEFINES and LIB_DEPS
1086 if test "x$enable_dri" = xyes; then
1087     # Platform specific settings and drivers to build
1088     case "$host_os" in
1089     linux*)
1090         DEFINES="$DEFINES -DHAVE_ALIAS"
1091         if test "x$enable_dri3" = xyes; then
1092             DEFINES="$DEFINES -DHAVE_DRI3"
1093         fi
1094
1095         if test "x$have_pci_id" != xyes; then
1096             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1097         fi
1098
1099         case "$host_cpu" in
1100         powerpc* | sparc*)
1101             # Build only the drivers for cards that exist on PowerPC/sparc
1102             if test "x$with_dri_drivers" = "xyes"; then
1103                 with_dri_drivers="r200 radeon swrast"
1104             fi
1105             ;;
1106         esac
1107         ;;
1108     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1109         DEFINES="$DEFINES -DHAVE_ALIAS"
1110         ;;
1111     gnu*)
1112         DEFINES="$DEFINES -DHAVE_ALIAS"
1113         ;;
1114     cygwin*)
1115         if test "x$with_dri_drivers" = "xyes"; then
1116             with_dri_drivers="swrast"
1117         fi
1118         ;;
1119     darwin*)
1120         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1121         if test "x$with_dri_drivers" = "xyes"; then
1122             with_dri_drivers="swrast"
1123         fi
1124         ;;
1125     esac
1126
1127     # default drivers
1128     if test "x$with_dri_drivers" = "xyes"; then
1129         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1130     fi
1131
1132     # Check for expat
1133     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1134     if test "x$have_expat" = "xyes"; then
1135        PKG_CHECK_MODULES([EXPAT], [expat], [],
1136                          AC_MSG_ERROR([Expat required for DRI.]))
1137     else
1138        # expat version 2.0 and earlier do not provide expat.pc
1139        EXPAT_LIBS=-lexpat
1140     fi
1141
1142     DRICOMMON_NEED_LIBDRM=no
1143     # If we are building any DRI driver other than swrast.
1144     if test -n "$with_dri_drivers"; then
1145         if test "x$with_dri_drivers" != xswrast; then
1146             # ... libdrm is required
1147             if test "x$have_libdrm" != xyes; then
1148                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1149             fi
1150             DRICOMMON_NEED_LIBDRM=yes
1151         fi
1152     fi
1153
1154     # If we're building any gallium DRI driver other than swrast
1155     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1156         if test "x$with_gallium_drivers" != xswrast; then
1157             # ... build a libdrm aware dricommon
1158             DRICOMMON_NEED_LIBDRM=yes
1159         fi
1160     fi
1161
1162     # put all the necessary libs together
1163     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1164 fi
1165
1166 AC_SUBST([DRI_LIB_DEPS])
1167
1168 DRI_DIRS=''
1169 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1170 if test -n "$with_dri_drivers"; then
1171     if test "x$enable_opengl" != xyes; then
1172         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1173     fi
1174
1175     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1176     for driver in $dri_drivers; do
1177         DRI_DIRS="$DRI_DIRS $driver"
1178         case "x$driver" in
1179         xi915)
1180             HAVE_I915_DRI=yes;
1181             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1182             ;;
1183         xi965)
1184             HAVE_I965_DRI=yes;
1185             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1186             ;;
1187         xnouveau)
1188             HAVE_NOUVEAU_DRI=yes;
1189             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1190             ;;
1191         xradeon)
1192             HAVE_RADEON_DRI=yes;
1193             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1194             ;;
1195         xr200)
1196             HAVE_R200_DRI=yes;
1197             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1198             ;;
1199         xswrast)
1200             HAVE_SWRAST_DRI=yes;
1201             ;;
1202         *)
1203             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1204             ;;
1205         esac
1206     done
1207     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1208 fi
1209
1210 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1211 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1212                                   "x$enable_osmesa" = xyes -o \
1213                                   -n "$DRI_DIRS")
1214
1215 dnl
1216 dnl OSMesa configuration
1217 dnl
1218
1219 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1220 AC_ARG_WITH([osmesa-bits],
1221     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1222         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1223     [osmesa_bits="$withval"],
1224     [osmesa_bits=8])
1225 if test "x$osmesa_bits" != x8; then
1226     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1227         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1228         osmesa_bits=8
1229     fi
1230 fi
1231 case "x$osmesa_bits" in
1232 x8)
1233     OSMESA_LIB="${OSMESA_LIB}"
1234     ;;
1235 x16|x32)
1236     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1237     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1238     ;;
1239 *)
1240     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1241     ;;
1242 esac
1243
1244 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1245     # only link libraries with osmesa if shared
1246     if test "$enable_static" = no; then
1247         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1248     else
1249         OSMESA_LIB_DEPS=""
1250     fi
1251     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1252 fi
1253
1254 AC_SUBST([OSMESA_LIB_DEPS])
1255 AC_SUBST([OSMESA_PC_REQ])
1256 AC_SUBST([OSMESA_PC_LIB_PRIV])
1257
1258 dnl
1259 dnl gbm configuration
1260 dnl
1261 if test "x$enable_gbm" = xauto; then
1262     case "$with_egl_platforms" in
1263         *drm*)
1264             enable_gbm=yes ;;
1265          *)
1266             enable_gbm=no ;;
1267     esac
1268 fi
1269 if test "x$enable_gbm" = xyes; then
1270     if test "x$need_pci_id$have_pci_id" = xyesno; then
1271         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1272     fi
1273
1274     if test "x$enable_dri" = xyes; then
1275         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1276         if test "x$enable_shared_glapi" = xno; then
1277             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1278         fi
1279     else
1280         # Strictly speaking libgbm does not require --enable-dri, although
1281         # both of its backends do. Thus one can build libgbm without any
1282         # backends if --disable-dri is set.
1283         # To avoid unnecessary complexity of checking if at least one backend
1284         # is available when building, just mandate --enable-dri.
1285         AC_MSG_ERROR([gbm requires --enable-dri])
1286     fi
1287 fi
1288 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1289 if test "x$need_pci_id$have_libudev" = xyesyes; then
1290     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1291 else
1292     GBM_PC_REQ_PRIV=""
1293 fi
1294 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1295 AC_SUBST([GBM_PC_REQ_PRIV])
1296 AC_SUBST([GBM_PC_LIB_PRIV])
1297
1298 dnl
1299 dnl EGL configuration
1300 dnl
1301 EGL_CLIENT_APIS=""
1302
1303 if test "x$enable_egl" = xyes; then
1304     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1305
1306     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1307
1308     if test "$enable_static" != yes; then
1309         if test "x$enable_dri" = xyes; then
1310             HAVE_EGL_DRIVER_DRI2=1
1311         fi
1312
1313     fi
1314 fi
1315 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1316 AC_SUBST([EGL_LIB_DEPS])
1317
1318 dnl
1319 dnl EGL Gallium configuration
1320 dnl
1321 if test "x$enable_gallium_egl" = xyes; then
1322     if test -z "$with_gallium_drivers"; then
1323         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1324     fi
1325     if test "x$enable_egl" = xno; then
1326         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1327     fi
1328     if test "x$have_libdrm" != xyes; then
1329         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1330     fi
1331
1332     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1333     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1334 # XXX: Uncomment once converted to use static/shared pipe-drivers
1335 #    enable_gallium_loader=$enable_shared_pipe_drivers
1336 fi
1337 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1338
1339 dnl
1340 dnl gbm Gallium configuration
1341 dnl
1342 if test "x$enable_gallium_gbm" = xauto; then
1343     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1344         yesyesyes*drm*)
1345             enable_gallium_gbm=yes ;;
1346          *)
1347             enable_gallium_gbm=no ;;
1348     esac
1349 fi
1350 if test "x$enable_gallium_gbm" = xyes; then
1351     if test -z "$with_gallium_drivers"; then
1352         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1353     fi
1354     if test "x$enable_gbm" = xno; then
1355         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1356     fi
1357
1358     if test "x$enable_gallium_egl" != xyes; then
1359         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1360     fi
1361
1362     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1363     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1364     enable_gallium_loader=$enable_shared_pipe_drivers
1365 fi
1366 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1367
1368 dnl
1369 dnl XA configuration
1370 dnl
1371 if test "x$enable_xa" = xyes; then
1372     if test "x$with_gallium_drivers" = xswrast; then
1373        AC_MSG_ERROR([
1374           Building xa requires at least one non swrast gallium driver.
1375           If you are looking to use libxatracker.so with the VMware driver,
1376           make sure to include svga in the gallium drivers list, apart from
1377           enabling XA.
1378           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1379     fi
1380     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1381     enable_gallium_loader=$enable_shared_pipe_drivers
1382 fi
1383 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1384
1385 dnl
1386 dnl OpenVG configuration
1387 dnl
1388 VG_LIB_DEPS=""
1389
1390 if test "x$enable_openvg" = xyes; then
1391     if test "x$enable_egl" = xno; then
1392         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1393     fi
1394     if test -z "$with_gallium_drivers"; then
1395         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1396     fi
1397     if test "x$enable_gallium_egl" = xno; then
1398         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1399     fi
1400
1401     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1402     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1403     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1404     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1405     AC_SUBST([VG_PC_LIB_PRIV])
1406 fi
1407 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1408
1409 dnl
1410 dnl Gallium G3DVL configuration
1411 dnl
1412 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1413     if test "x$enable_xvmc" = xauto; then
1414         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1415     fi
1416
1417     if test "x$enable_vdpau" = xauto; then
1418         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1419     fi
1420
1421     if test "x$enable_omx" = xauto; then
1422         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1423     fi
1424 fi
1425
1426 if test "x$enable_xvmc" = xyes; then
1427     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1428     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1429     enable_gallium_loader=$enable_shared_pipe_drivers
1430 fi
1431 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1432
1433 if test "x$enable_vdpau" = xyes; then
1434     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1435                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb xcb-dri2`"])
1436     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1437     enable_gallium_loader=$enable_shared_pipe_drivers
1438 fi
1439 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1440
1441 if test "x$enable_omx" = xyes; then
1442     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1443     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1444     enable_gallium_loader=$enable_shared_pipe_drivers
1445 fi
1446 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1447
1448 dnl
1449 dnl OpenCL configuration
1450 dnl
1451
1452 AC_ARG_WITH([libclc-path],
1453    [AS_HELP_STRING([--with-libclc-path],
1454          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1455    [LIBCLC_PATH="$withval"],
1456    [LIBCLC_PATH=''])
1457
1458 if test -n "$LIBCLC_PATH"; then
1459    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1460                   Please review the updated build instructions for clover:
1461                   http://dri.freedesktop.org/wiki/GalliumCompute])
1462 fi
1463
1464
1465 AC_ARG_WITH([clang-libdir],
1466    [AS_HELP_STRING([--with-clang-libdir],
1467          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1468    [CLANG_LIBDIR="$withval"],
1469    [CLANG_LIBDIR=''])
1470
1471 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1472
1473 if test "x$enable_opencl" = xyes; then
1474     if test -z "$with_gallium_drivers"; then
1475         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1476     fi
1477
1478     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1479         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1480     fi
1481
1482     if test "x$have_libclc" = xno; then
1483         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1484                     Make sure the directory containing libclc.pc is specified in your
1485                     PKG_CONFIG_PATH environment variable.
1486                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1487     else
1488         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1489         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1490         AC_SUBST([LIBCLC_INCLUDEDIR])
1491         AC_SUBST([LIBCLC_LIBEXECDIR])
1492     fi
1493
1494     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1495     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1496     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1497     enable_gallium_loader=yes
1498
1499     if test "x$enable_opencl_icd" = xyes; then
1500         OPENCL_LIBNAME="MesaOpenCL"
1501     else
1502         OPENCL_LIBNAME="OpenCL"
1503     fi
1504 fi
1505 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1506 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1507 AC_SUBST([OPENCL_LIBNAME])
1508
1509 dnl
1510 dnl Gallium configuration
1511 dnl
1512 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1513
1514 AC_SUBST([LLVM_BINDIR])
1515 AC_SUBST([LLVM_CFLAGS])
1516 AC_SUBST([LLVM_CPPFLAGS])
1517 AC_SUBST([LLVM_CXXFLAGS])
1518 AC_SUBST([LLVM_LIBDIR])
1519 AC_SUBST([LLVM_LIBS])
1520 AC_SUBST([LLVM_LDFLAGS])
1521 AC_SUBST([LLVM_INCLUDEDIR])
1522 AC_SUBST([LLVM_VERSION])
1523 AC_SUBST([CLANG_RESOURCE_DIR])
1524
1525 case "x$enable_opengl$enable_gles1$enable_gles2" in
1526 x*yes*)
1527     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1528     ;;
1529 esac
1530
1531 AC_SUBST([VG_LIB_DEPS])
1532 AC_SUBST([EGL_CLIENT_APIS])
1533
1534 dnl
1535 dnl EGL Platforms configuration
1536 dnl
1537 AC_ARG_WITH([egl-platforms],
1538     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1539         [comma delimited native platforms libEGL supports, e.g.
1540         "x11,drm" @<:@default=auto@:>@])],
1541     [with_egl_platforms="$withval"],
1542     [if test "x$enable_egl" = xyes; then
1543         with_egl_platforms="x11"
1544     else
1545         with_egl_platforms=""
1546     fi])
1547
1548 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1549     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1550 fi
1551
1552 # Do per-EGL platform setups and checks
1553 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1554 for plat in $egl_platforms; do
1555         case "$plat" in
1556         wayland)
1557                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1558                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1559
1560                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1561                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1562                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1563                 ;;
1564
1565         x11)
1566                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1567                 ;;
1568
1569         drm)
1570                 test "x$enable_gbm" = "xno" &&
1571                         AC_MSG_ERROR([EGL platform drm needs gbm])
1572                 test "x$have_libdrm" != xyes &&
1573                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1574                 ;;
1575
1576         android|fbdev|gdi|null)
1577                 ;;
1578
1579         *)
1580                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1581                 ;;
1582         esac
1583
1584         case "$plat$need_pci_id$have_pci_id" in
1585                 waylandyesno|drmyesno)
1586                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1587         esac
1588 done
1589
1590 # libEGL wants to default to the first platform specified in
1591 # ./configure.  parse that here.
1592 if test "x$egl_platforms" != "x"; then
1593     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1594     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1595 else
1596     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1597 fi
1598
1599 if echo "$egl_platforms" | grep -q 'x11'; then
1600     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1601     NEED_WINSYS_XLIB=yes
1602 fi
1603 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1604 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1605 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1606 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1607 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1608
1609 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1610
1611 AC_SUBST([EGL_NATIVE_PLATFORM])
1612 AC_SUBST([EGL_CFLAGS])
1613
1614 # If we don't have the X11 platform, set this define so we don't try to include
1615 # the X11 headers.
1616 if ! echo "$egl_platforms" | grep -q 'x11'; then
1617     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1618     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1619 fi
1620
1621 AC_ARG_WITH([egl-driver-dir],
1622     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1623                     [directory for EGL drivers @<:@default=${libdir}/egl@:>@])],
1624     [EGL_DRIVER_INSTALL_DIR="$withval"],
1625     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1626 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1627
1628 AC_ARG_WITH([max-width],
1629     [AS_HELP_STRING([--with-max-width=N],
1630                     [Maximum framebuffer width (4096)])],
1631     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1632      AS_IF([test "${withval}" -gt "4096"],
1633            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1634 )
1635 AC_ARG_WITH([max-height],
1636     [AS_HELP_STRING([--with-max-height=N],
1637                     [Maximum framebuffer height (4096)])],
1638     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1639      AS_IF([test "${withval}" -gt "4096"],
1640            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1641 )
1642
1643 dnl
1644 dnl Gallium LLVM
1645 dnl
1646 AC_ARG_ENABLE([gallium-llvm],
1647     [AS_HELP_STRING([--enable-gallium-llvm],
1648         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1649     [enable_gallium_llvm="$enableval"],
1650     [enable_gallium_llvm=auto])
1651
1652 AC_ARG_ENABLE([llvm-shared-libs],
1653     [AS_HELP_STRING([--enable-llvm-shared-libs],
1654         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1655     [enable_llvm_shared_libs="$enableval"],
1656     [enable_llvm_shared_libs=yes])
1657
1658 AC_ARG_WITH([llvm-prefix],
1659     [AS_HELP_STRING([--with-llvm-prefix],
1660         [Prefix for LLVM installations in non-standard locations])],
1661     [llvm_prefix="$withval"],
1662     [llvm_prefix=''])
1663
1664
1665 # Call this inside ` ` to get the return value.
1666 # $1 is the llvm-config command with arguments.
1667 strip_unwanted_llvm_flags() {
1668     # Use \> (marks the end of the word)
1669     echo `$1` | sed \
1670         -e 's/-DNDEBUG\>//g' \
1671         -e 's/-D_GNU_SOURCE\>//g' \
1672         -e 's/-pedantic\>//g' \
1673         -e 's/-Wcovered-switch-default\>//g' \
1674         -e 's/-O.\>//g' \
1675         -e 's/-g\>//g' \
1676         -e 's/-Wall\>//g' \
1677         -e 's/-Wcast-qual\>//g' \
1678         -e 's/-Woverloaded-virtual\>//g' \
1679         -e 's/-fcolor-diagnostics\>//g' \
1680         -e 's/-fdata-sections\>//g' \
1681         -e 's/-ffunction-sections\>//g' \
1682         -e 's/-fno-exceptions\>//g' \
1683         -e 's/-fomit-frame-pointer\>//g' \
1684         -e 's/-fvisibility-inlines-hidden\>//g' \
1685         -e 's/-fPIC\>//g' \
1686         -e 's/-fstack-protector-strong\>//g'
1687 }
1688
1689
1690 if test -z "$with_gallium_drivers"; then
1691     enable_gallium_llvm=no
1692 fi
1693 if test "x$enable_gallium_llvm" = xauto; then
1694     case "$host_cpu" in
1695     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1696     esac
1697 fi
1698 if test "x$enable_gallium_llvm" = xyes; then
1699     if test -n "$llvm_prefix"; then
1700         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1701     else
1702         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1703     fi
1704
1705     if test "x$LLVM_CONFIG" != xno; then
1706         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1707         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1708         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1709         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1710         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1711         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1712         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1713         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1714
1715         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1716             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1717         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1718             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1719
1720         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1721         dnl llvm-config.h
1722         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1723             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1724             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1725
1726         if test -n "${LLVM_VERSION_MAJOR}"; then
1727             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1728         else
1729             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1730         fi
1731
1732         LLVM_REQUIRED_VERSION_MAJOR="3"
1733         LLVM_REQUIRED_VERSION_MINOR="1"
1734         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1735             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1736         fi
1737
1738         LLVM_COMPONENTS="engine bitwriter"
1739         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1740             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1741         fi
1742
1743         if test "x$enable_opencl" = xyes; then
1744             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1745             # LLVM 3.3 >= 177971 requires IRReader
1746             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1747                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1748             fi
1749             # LLVM 3.4 requires Option
1750             if $LLVM_CONFIG --components | grep -qw 'option'; then
1751                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1752             fi
1753             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1754             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1755                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1756             fi
1757             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1758                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1759             fi
1760         fi
1761         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1762         MESA_LLVM=1
1763
1764         dnl Check for Clang internal headers
1765         if test "x$enable_opencl" = xyes; then
1766             if test -z "$CLANG_LIBDIR"; then
1767                 CLANG_LIBDIR=${LLVM_LIBDIR}
1768             fi
1769             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1770             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1771                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1772         fi
1773     else
1774         MESA_LLVM=0
1775         LLVM_VERSION_INT=0
1776     fi
1777 else
1778     MESA_LLVM=0
1779     LLVM_VERSION_INT=0
1780
1781     if test "x$enable_opencl" = xyes; then
1782         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1783     fi
1784 fi
1785
1786 dnl Directory for XVMC libs
1787 AC_ARG_WITH([xvmc-libdir],
1788     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1789         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1790     [XVMC_LIB_INSTALL_DIR="$withval"],
1791     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1792 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1793
1794 dnl
1795 dnl Gallium Tests
1796 dnl
1797 if test "x$enable_gallium_tests" = xyes; then
1798     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1799     enable_gallium_loader=yes
1800 fi
1801 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1802
1803 if test "x$enable_gallium_loader" = xyes; then
1804     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1805 fi
1806
1807 dnl Directory for VDPAU libs
1808 AC_ARG_WITH([vdpau-libdir],
1809     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1810         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1811     [VDPAU_LIB_INSTALL_DIR="$withval"],
1812     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1813 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1814
1815 OMX_LIB_INSTALL_DIR_DEFAULT=''
1816 if test "x$enable_omx" = xyes; then
1817     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1818 fi
1819
1820 AC_ARG_WITH([omx-libdir],
1821     [AS_HELP_STRING([--with-omx-libdir=DIR],
1822         [directory for the OMX libraries])],
1823     [OMX_LIB_INSTALL_DIR="$withval"],
1824     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1825 AC_SUBST([OMX_LIB_INSTALL_DIR])
1826
1827 dnl Directory for OpenCL libs
1828 AC_ARG_WITH([opencl-libdir],
1829     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1830         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1831     [OPENCL_LIB_INSTALL_DIR="$withval"],
1832     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1833 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1834
1835 dnl
1836 dnl Gallium helper functions
1837 dnl
1838 gallium_check_st() {
1839     if test "x$have_libdrm" != xyes; then
1840        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1841     fi
1842     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $2"
1843
1844     if test "x$enable_dri" = xyes -a -n "$3"; then
1845          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1846     fi
1847     if test "x$enable_xa" = xyes -a -n "$4"; then
1848          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1849     fi
1850     if test "x$enable_xvmc" = xyes -a -n "$5"; then
1851          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1852     fi
1853     if test "x$enable_vdpau" = xyes -a -n "$6"; then
1854          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1855     fi
1856     if test "x$enable_omx" = xyes -a "x$7" != x; then
1857          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1858     fi
1859 }
1860
1861 gallium_require_llvm() {
1862     if test "x$MESA_LLVM" = x0; then
1863         case "$host" in *gnux32) return;; esac
1864         case "$host_cpu" in
1865         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1866         esac
1867     fi
1868 }
1869
1870 gallium_require_drm_loader() {
1871     if test "x$enable_gallium_loader" = xyes; then
1872         if test "x$need_pci_id$have_pci_id" = xyesno; then
1873             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1874         fi
1875         if test "x$have_libdrm" != xyes; then
1876             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1877         fi
1878         enable_gallium_drm_loader=yes
1879     fi
1880 }
1881
1882 require_egl_drm() {
1883     case "$with_egl_platforms" in
1884         *drm*)
1885             ;;
1886          *)
1887             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1888             ;;
1889     esac
1890     if test "x$enable_gbm" != xyes; then
1891             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1892     fi
1893 }
1894
1895 radeon_llvm_check() {
1896     if test "x$enable_gallium_llvm" != "xyes"; then
1897         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1898     fi
1899     LLVM_REQUIRED_VERSION_MAJOR="3"
1900     LLVM_REQUIRED_VERSION_MINOR="4"
1901     LLVM_REQUIRED_VERSION_PATCH="2"
1902     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1903         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1904     fi
1905     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1906         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1907                       sources with the --enable-experimental-targets=R600
1908                       configure flag])
1909     fi
1910     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1911     NEED_RADEON_LLVM=yes
1912     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1913                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1914 }
1915
1916 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1917 if test -n "$with_gallium_drivers"; then
1918     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1919     for driver in $gallium_drivers; do
1920         case "x$driver" in
1921         xsvga)
1922             HAVE_GALLIUM_SVGA=yes
1923             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1924             gallium_require_drm_loader
1925             gallium_check_st "svga" "svga/drm" "dri/vmwgfx" "xa/vmwgfx"
1926             ;;
1927         xi915)
1928             HAVE_GALLIUM_I915=yes
1929             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1930             gallium_require_drm_loader
1931             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1932             gallium_check_st "Gallium i915" "i915/drm" "dri/i915" "xa/i915"
1933             ;;
1934         xilo)
1935             HAVE_GALLIUM_ILO=yes
1936             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1937             gallium_require_drm_loader
1938             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1939             gallium_check_st "Gallium i965/ilo" "intel/drm" "dri/ilo" "xa/ilo"
1940             ;;
1941         xr300)
1942             HAVE_GALLIUM_R300=yes
1943             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1944             gallium_require_drm_loader
1945             gallium_require_llvm "Gallium R300"
1946             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1947             gallium_check_st "Gallium R300" "radeon/drm" "dri/r300"
1948             ;;
1949         xr600)
1950             HAVE_GALLIUM_R600=yes
1951             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1952             gallium_require_drm_loader
1953             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1954             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1955                 radeon_llvm_check "r600g"
1956                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1957             fi
1958             if test "x$enable_r600_llvm" = xyes; then
1959                 USE_R600_LLVM_COMPILER=yes;
1960             fi
1961             if test "x$enable_opencl" = xyes; then
1962                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1963             fi
1964             gallium_check_st "Gallium R600" "radeon/drm" "dri/r600" "" "xvmc/r600" "vdpau/r600" "omx/r600"
1965             ;;
1966         xradeonsi)
1967             HAVE_GALLIUM_RADEONSI=yes
1968             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1969             gallium_require_drm_loader
1970             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1971             radeon_llvm_check "radeonsi"
1972             require_egl_drm "radeonsi"
1973             gallium_check_st "radeonsi" "radeon/drm" "dri/radeonsi" "" "" "vdpau/radeonsi" "omx/radeonsi"
1974             ;;
1975         xnouveau)
1976             HAVE_GALLIUM_NOUVEAU=yes
1977             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1978             gallium_require_drm_loader
1979             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1980             gallium_check_st "nouveau" "nouveau/drm" "dri/nouveau" "xa/nouveau" "xvmc/nouveau" "vdpau/nouveau" "omx/nouveau"
1981             ;;
1982         xfreedreno)
1983             HAVE_GALLIUM_FREEDRENO=yes
1984             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1985             gallium_require_drm_loader
1986             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1987             gallium_check_st "freedreno" "freedreno/drm" "dri/freedreno" "xa/freedreno" "" ""
1988             ;;
1989         xswrast)
1990             HAVE_GALLIUM_SOFTPIPE=yes
1991             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1992             if test "x$MESA_LLVM" = x1; then
1993                 HAVE_GALLIUM_LLVMPIPE=yes
1994                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1995             fi
1996
1997             if test "x$enable_dri" = xyes; then
1998                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/swrast"
1999             fi
2000
2001             if test "x$have_libdrm" = xyes; then
2002                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/kms-dri"
2003                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/kms-swrast"
2004             fi
2005             ;;
2006         xvc4)
2007             HAVE_GALLIUM_VC4=yes
2008             gallium_require_drm_loader
2009             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS vc4"
2010             gallium_check_st "vc4" "vc4/drm" "dri-vc4" "" "" ""
2011
2012             case "$host_cpu" in
2013                 i?86 | x86_64 | amd64)
2014                 USE_VC4_SIMULATOR=yes
2015                 ;;
2016             esac
2017             ;;
2018         *)
2019             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2020             ;;
2021         esac
2022     done
2023 fi
2024
2025 dnl Set LLVM_LIBS - This is done after the driver configuration so
2026 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2027 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2028 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2029 dnl this was causing the same libraries to be appear multiple times
2030 dnl in LLVM_LIBS.
2031
2032 if test "x$MESA_LLVM" != x0; then
2033
2034     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2035
2036     if test "x$enable_llvm_shared_libs" = xyes; then
2037         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2038         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2039         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2040
2041         if test "x$llvm_have_one_so" = xyes; then
2042             dnl LLVM was built using auto*, so there is only one shared object.
2043             LLVM_LIBS="-l$LLVM_SO_NAME"
2044         else
2045             dnl If LLVM was built with CMake, there will be one shared object per
2046             dnl component.
2047             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2048                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2049         Please make sure you have built llvm with the --enable-shared option
2050         and that your llvm libraries are installed in $LLVM_LIBDIR
2051         If you have installed your llvm libraries to a different directory you
2052         can use the --with-llvm-prefix= configure flag to specify this directory.
2053         NOTE: Mesa is attempting to use llvm shared libraries by default.
2054         If you do not want to build with llvm shared libraries and instead want to
2055         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2056         invocation and rebuild.])])
2057
2058            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2059            dnl install uses a shared object for each compoenent and we have
2060            dnl already added all of these objects to LLVM_LIBS.
2061         fi
2062     else
2063         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2064     fi
2065 fi
2066
2067 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2068 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2069 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2070 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2071 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2072 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2073 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2074                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2075 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2076 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2077 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2078 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2079 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2080
2081 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2082
2083 # NOTE: anything using xcb or other client side libs ends up in separate
2084 #       _CLIENT variables.  The pipe loader is built in two variants,
2085 #       one that is standalone and does not link any x client libs (for
2086 #       use by XA tracker in particular, but could be used in any case
2087 #       where communication with xserver is not desired).
2088 if test "x$enable_gallium_loader" = xyes; then
2089     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2090
2091     if test "x$NEED_WINSYS_XLIB" = xyes; then
2092         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2093     fi
2094
2095     if test "x$enable_dri" = xyes; then
2096         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2097     fi
2098
2099     if test "x$enable_gallium_drm_loader" = xyes; then
2100         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2101         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2102                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2103         if test "x$pipe_loader_have_xcb" = xyes; then
2104             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2105             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2106         fi
2107     fi
2108
2109     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2110     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2111
2112     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2113     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2114     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2115     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2116 fi
2117
2118 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2119 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2120 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2121 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2122 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2123 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2124
2125 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2126                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2127                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2128 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2129 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2130 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2131 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2132 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2133 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2134 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2135 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2136 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2137     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2138 fi
2139
2140 AC_SUBST([ELF_LIB])
2141
2142 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2143 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2144 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2145 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2146 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2147
2148 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2149 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2150 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2151
2152 AC_SUBST([VDPAU_MAJOR], 1)
2153 AC_SUBST([VDPAU_MINOR], 0)
2154
2155 AC_SUBST([XVMC_MAJOR], 1)
2156 AC_SUBST([XVMC_MINOR], 0)
2157
2158 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2159 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2160 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2161 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2162
2163 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2164 AC_SUBST([XA_MINOR], $XA_MINOR)
2165 AC_SUBST([XA_TINY], $XA_TINY)
2166 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2167
2168 dnl Restore LDFLAGS and CPPFLAGS
2169 LDFLAGS="$_SAVE_LDFLAGS"
2170 CPPFLAGS="$_SAVE_CPPFLAGS"
2171
2172 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2173 if test "x$acv_mesa_CLANG" = xyes; then
2174     CFLAGS="$CFLAGS -Qunused-arguments"
2175     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2176 fi
2177
2178 dnl Add user CFLAGS and CXXFLAGS
2179 CFLAGS="$CFLAGS $USER_CFLAGS"
2180 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2181
2182 dnl Substitute the config
2183 AC_CONFIG_FILES([Makefile
2184                 src/Makefile
2185                 src/egl/drivers/dri2/Makefile
2186                 src/egl/main/Makefile
2187                 src/egl/main/egl.pc
2188                 src/egl/wayland/Makefile
2189                 src/egl/wayland/wayland-drm/Makefile
2190                 src/egl/wayland/wayland-egl/Makefile
2191                 src/egl/wayland/wayland-egl/wayland-egl.pc
2192                 src/gallium/Makefile
2193                 src/gallium/auxiliary/Makefile
2194                 src/gallium/auxiliary/pipe-loader/Makefile
2195                 src/gallium/drivers/freedreno/Makefile
2196                 src/gallium/drivers/galahad/Makefile
2197                 src/gallium/drivers/i915/Makefile
2198                 src/gallium/drivers/identity/Makefile
2199                 src/gallium/drivers/ilo/Makefile
2200                 src/gallium/drivers/llvmpipe/Makefile
2201                 src/gallium/drivers/noop/Makefile
2202                 src/gallium/drivers/nouveau/Makefile
2203                 src/gallium/drivers/r300/Makefile
2204                 src/gallium/drivers/r600/Makefile
2205                 src/gallium/drivers/radeon/Makefile
2206                 src/gallium/drivers/radeonsi/Makefile
2207                 src/gallium/drivers/rbug/Makefile
2208                 src/gallium/drivers/softpipe/Makefile
2209                 src/gallium/drivers/svga/Makefile
2210                 src/gallium/drivers/trace/Makefile
2211                 src/gallium/drivers/vc4/Makefile
2212                 src/gallium/state_trackers/clover/Makefile
2213                 src/gallium/state_trackers/dri/Makefile
2214                 src/gallium/state_trackers/egl/Makefile
2215                 src/gallium/state_trackers/gbm/Makefile
2216                 src/gallium/state_trackers/glx/xlib/Makefile
2217                 src/gallium/state_trackers/omx/Makefile
2218                 src/gallium/state_trackers/osmesa/Makefile
2219                 src/gallium/state_trackers/vdpau/Makefile
2220                 src/gallium/state_trackers/vega/Makefile
2221                 src/gallium/state_trackers/xa/Makefile
2222                 src/gallium/state_trackers/xvmc/Makefile
2223                 src/gallium/targets/dri/Makefile
2224                 src/gallium/targets/egl-static/Makefile
2225                 src/gallium/targets/gbm/Makefile
2226                 src/gallium/targets/libgl-xlib/Makefile
2227                 src/gallium/targets/omx/Makefile
2228                 src/gallium/targets/opencl/Makefile
2229                 src/gallium/targets/osmesa/Makefile
2230                 src/gallium/targets/osmesa/osmesa.pc
2231                 src/gallium/targets/pipe-loader/Makefile
2232                 src/gallium/targets/vdpau/Makefile
2233                 src/gallium/targets/xa/Makefile
2234                 src/gallium/targets/xa/xatracker.pc
2235                 src/gallium/targets/xvmc/Makefile
2236                 src/gallium/tests/trivial/Makefile
2237                 src/gallium/tests/unit/Makefile
2238                 src/gallium/winsys/freedreno/drm/Makefile
2239                 src/gallium/winsys/i915/drm/Makefile
2240                 src/gallium/winsys/intel/drm/Makefile
2241                 src/gallium/winsys/nouveau/drm/Makefile
2242                 src/gallium/winsys/radeon/drm/Makefile
2243                 src/gallium/winsys/svga/drm/Makefile
2244                 src/gallium/winsys/sw/dri/Makefile
2245                 src/gallium/winsys/sw/fbdev/Makefile
2246                 src/gallium/winsys/sw/kms-dri/Makefile
2247                 src/gallium/winsys/sw/null/Makefile
2248                 src/gallium/winsys/sw/wayland/Makefile
2249                 src/gallium/winsys/sw/wrapper/Makefile
2250                 src/gallium/winsys/sw/xlib/Makefile
2251                 src/gallium/winsys/vc4/drm/Makefile
2252                 src/gbm/Makefile
2253                 src/gbm/main/gbm.pc
2254                 src/glsl/Makefile
2255                 src/glx/Makefile
2256                 src/glx/apple/Makefile
2257                 src/glx/tests/Makefile
2258                 src/gtest/Makefile
2259                 src/loader/Makefile
2260                 src/mapi/Makefile
2261                 src/mapi/es1api/glesv1_cm.pc
2262                 src/mapi/es2api/glesv2.pc
2263                 src/mapi/glapi/gen/Makefile
2264                 src/mapi/vgapi/Makefile
2265                 src/mapi/vgapi/vg.pc
2266                 src/mesa/Makefile
2267                 src/mesa/gl.pc
2268                 src/mesa/drivers/dri/dri.pc
2269                 src/mesa/drivers/dri/common/Makefile
2270                 src/mesa/drivers/dri/common/xmlpool/Makefile
2271                 src/mesa/drivers/dri/i915/Makefile
2272                 src/mesa/drivers/dri/i965/Makefile
2273                 src/mesa/drivers/dri/Makefile
2274                 src/mesa/drivers/dri/nouveau/Makefile
2275                 src/mesa/drivers/dri/r200/Makefile
2276                 src/mesa/drivers/dri/radeon/Makefile
2277                 src/mesa/drivers/dri/swrast/Makefile
2278                 src/mesa/drivers/osmesa/Makefile
2279                 src/mesa/drivers/osmesa/osmesa.pc
2280                 src/mesa/drivers/x11/Makefile
2281                 src/mesa/main/tests/Makefile
2282                 src/util/Makefile
2283                 src/util/tests/hash_table/Makefile])
2284
2285 dnl Sort the dirs alphabetically
2286 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2287 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2288 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2289 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2290
2291 AC_OUTPUT
2292
2293 dnl
2294 dnl Output some configuration info for the user
2295 dnl
2296 echo ""
2297 echo "        prefix:          $prefix"
2298 echo "        exec_prefix:     $exec_prefix"
2299 echo "        libdir:          $libdir"
2300 echo "        includedir:      $includedir"
2301
2302 dnl API info
2303 echo ""
2304 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2305 echo "        OpenVG:          $enable_openvg"
2306
2307 dnl Driver info
2308 echo ""
2309 case "x$enable_osmesa$enable_gallium_osmesa" in
2310 xnoyes)
2311         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2312         ;;
2313 xyesno)
2314         echo "        OSMesa:          lib$OSMESA_LIB"
2315         ;;
2316 xnono)
2317         echo "        OSMesa:          no"
2318         ;;
2319 esac
2320
2321 echo ""
2322 if test "x$enable_dri" != xno; then
2323         echo "        DRI platform:    $dri_platform"
2324         if test -z "$DRI_DIRS"; then
2325             echo "        DRI drivers:     no"
2326         else
2327             echo "        DRI drivers:     $DRI_DIRS"
2328         fi
2329         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2330 fi
2331
2332 case "x$enable_glx$enable_xlib_glx" in
2333 xyesyes)
2334     echo "        GLX:             Xlib-based"
2335     ;;
2336 xyesno)
2337     echo "        GLX:             DRI-based"
2338     ;;
2339 *)
2340     echo "        GLX:             $enable_glx"
2341     ;;
2342 esac
2343
2344 dnl EGL
2345 echo ""
2346 echo "        EGL:             $enable_egl"
2347 if test "$enable_egl" = yes; then
2348     echo "        EGL platforms:   $egl_platforms"
2349
2350     egl_drivers=""
2351     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2352         egl_drivers="$egl_drivers builtin:egl_dri2"
2353     fi
2354
2355     if test "x$enable_gallium_egl" = xyes; then
2356         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2357         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2358     else
2359         echo "        EGL drivers:    $egl_drivers"
2360     fi
2361 fi
2362
2363 echo ""
2364 if test "x$MESA_LLVM" = x1; then
2365     echo "        llvm:            yes"
2366     echo "        llvm-config:     $LLVM_CONFIG"
2367     echo "        llvm-version:    $LLVM_VERSION"
2368 else
2369     echo "        llvm:            no"
2370 fi
2371
2372 echo ""
2373 if test -n "$with_gallium_drivers"; then
2374     echo "        Gallium:         yes"
2375     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2376     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2377     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2378     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2379 else
2380     echo "        Gallium:         no"
2381 fi
2382
2383
2384 dnl Libraries
2385 echo ""
2386 echo "        Shared libs:     $enable_shared"
2387 echo "        Static libs:     $enable_static"
2388 echo "        Shared-glapi:    $enable_shared_glapi"
2389
2390 dnl Compiler options
2391 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2392 cflags=`echo $CFLAGS | \
2393     $SED 's/^ *//;s/  */ /;s/ *$//'`
2394 cxxflags=`echo $CXXFLAGS | \
2395     $SED 's/^ *//;s/  */ /;s/ *$//'`
2396 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2397 echo ""
2398 echo "        CFLAGS:          $cflags"
2399 echo "        CXXFLAGS:        $cxxflags"
2400 echo "        Macros:          $defines"
2401 echo ""
2402 if test "x$MESA_LLVM" = x1; then
2403     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2404     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2405     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2406     echo ""
2407 fi
2408 echo "        PYTHON2:         $PYTHON2"
2409
2410 echo ""
2411 echo "        Run '${MAKE-make}' to build Mesa"
2412 echo ""