configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LDFLAGS="$LDFLAGS"
 536 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LDFLAGS="$save_LDFLAGS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 AX_PTHREAD
 556 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 557 dnl to -pthread, which causes problems if we need -lpthread to appear in
 558 dnl pkgconfig files.
 559 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 560
 561 dnl SELinux awareness.
 562 AC_ARG_ENABLE([selinux],
 563     [AS_HELP_STRING([--enable-selinux],
 564         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 565     [MESA_SELINUX="$enableval"],
 566     [MESA_SELINUX=no])
 567 if test "x$enable_selinux" = "xyes"; then
 568     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 569         [AC_CHECK_HEADER([selinux/selinux.h],[],
 570                          [AC_MSG_ERROR([SELinux headers not found])])
 571          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 572                       [AC_MSG_ERROR([SELinux library not found])])
 573          SELINUX_LIBS="-lselinux"])
 574     DEFINES="$DEFINES -DMESA_SELINUX"
 575 fi
 576 AC_SUBST([SELINUX_CFLAGS])
 577 AC_SUBST([SELINUX_LIBS])
 578
 579 dnl Options for APIs
 580 AC_ARG_ENABLE([opengl],
 581     [AS_HELP_STRING([--disable-opengl],
 582         [disable support for standard OpenGL API @<:@default=no@:>@])],
 583     [enable_opengl="$enableval"],
 584     [enable_opengl=yes])
 585 AC_ARG_ENABLE([gles1],
 586     [AS_HELP_STRING([--enable-gles1],
 587         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 588     [enable_gles1="$enableval"],
 589     [enable_gles1=no])
 590 AC_ARG_ENABLE([gles2],
 591     [AS_HELP_STRING([--enable-gles2],
 592         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 593     [enable_gles2="$enableval"],
 594     [enable_gles2=no])
 595 AC_ARG_ENABLE([openvg],
 596     [AS_HELP_STRING([--enable-openvg],
 597         [enable support for OpenVG API @<:@default=no@:>@])],
 598     [enable_openvg="$enableval"],
 599     [enable_openvg=no])
 600
 601 AC_ARG_ENABLE([dri],
 602     [AS_HELP_STRING([--enable-dri],
 603         [enable DRI modules @<:@default=enabled@:>@])],
 604     [enable_dri="$enableval"],
 605     [enable_dri=yes])
 606
 607 case "$host_os" in
 608 linux*)
 609     dri3_default=yes
 610     ;;
 611 *)
 612     dri3_default=no
 613     ;;
 614 esac
 615 AC_ARG_ENABLE([dri3],
 616     [AS_HELP_STRING([--enable-dri3],
 617         [enable DRI3 @<:@default=auto@:>@])],
 618     [enable_dri3="$enableval"],
 619     [enable_dri3="$dri3_default"])
 620 AC_ARG_ENABLE([glx],
 621     [AS_HELP_STRING([--enable-glx],
 622         [enable GLX library @<:@default=enabled@:>@])],
 623     [enable_glx="$enableval"],
 624     [enable_glx=yes])
 625 AC_ARG_ENABLE([osmesa],
 626     [AS_HELP_STRING([--enable-osmesa],
 627         [enable OSMesa library @<:@default=disabled@:>@])],
 628     [enable_osmesa="$enableval"],
 629     [enable_osmesa=no])
 630 AC_ARG_ENABLE([gallium-osmesa],
 631     [AS_HELP_STRING([--enable-gallium-osmesa],
 632         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 633     [enable_gallium_osmesa="$enableval"],
 634     [enable_gallium_osmesa=no])
 635 AC_ARG_ENABLE([egl],
 636     [AS_HELP_STRING([--disable-egl],
 637         [disable EGL library @<:@default=enabled@:>@])],
 638     [enable_egl="$enableval"],
 639     [enable_egl=yes])
 640
 641 AC_ARG_ENABLE([xa],
 642     [AS_HELP_STRING([--enable-xa],
 643         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 644     [enable_xa="$enableval"],
 645     [enable_xa=no])
 646 AC_ARG_ENABLE([gbm],
 647    [AS_HELP_STRING([--enable-gbm],
 648          [enable gbm library @<:@default=auto@:>@])],
 649    [enable_gbm="$enableval"],
 650    [enable_gbm=auto])
 651
 652 AC_ARG_ENABLE([xvmc],
 653    [AS_HELP_STRING([--enable-xvmc],
 654          [enable xvmc library @<:@default=auto@:>@])],
 655    [enable_xvmc="$enableval"],
 656    [enable_xvmc=no])
 657 AC_ARG_ENABLE([vdpau],
 658    [AS_HELP_STRING([--enable-vdpau],
 659          [enable vdpau library @<:@default=auto@:>@])],
 660    [enable_vdpau="$enableval"],
 661    [enable_vdpau=auto])
 662 AC_ARG_ENABLE([omx],
 663    [AS_HELP_STRING([--enable-omx],
 664          [enable OpenMAX library @<:@default=no@:>@])],
 665    [enable_omx="$enableval"],
 666    [enable_omx=no])
 667 AC_ARG_ENABLE([opencl],
 668    [AS_HELP_STRING([--enable-opencl],
 669          [enable OpenCL library @<:@default=no@:>@])],
 670    [enable_opencl="$enableval"],
 671    [enable_opencl=no])
 672 AC_ARG_ENABLE([opencl_icd],
 673    [AS_HELP_STRING([--enable-opencl-icd],
 674           [Build an OpenCL ICD library to be loaded by an ICD implementation
 675            @<:@default=no@:>@])],
 676     [enable_opencl_icd="$enableval"],
 677     [enable_opencl_icd=no])
 678 AC_ARG_ENABLE([xlib-glx],
 679     [AS_HELP_STRING([--enable-xlib-glx],
 680         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 681     [enable_xlib_glx="$enableval"],
 682     [enable_xlib_glx=no])
 683 AC_ARG_ENABLE([gallium-egl],
 684     [AS_HELP_STRING([--enable-gallium-egl],
 685         [enable optional EGL state tracker (not required
 686          for EGL support in Gallium with OpenGL and OpenGL ES)
 687          @<:@default=disable@:>@])],
 688     [enable_gallium_egl="$enableval"],
 689     [enable_gallium_egl=no])
 690 AC_ARG_ENABLE([gallium-gbm],
 691     [AS_HELP_STRING([--enable-gallium-gbm],
 692         [enable optional gbm state tracker (not required for
 693          gbm support in Gallium)
 694          @<:@default=auto@:>@])],
 695     [enable_gallium_gbm="$enableval"],
 696     [enable_gallium_gbm=auto])
 697
 698 AC_ARG_ENABLE([r600-llvm-compiler],
 699     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 700         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 701     [enable_r600_llvm="$enableval"],
 702     [enable_r600_llvm=no])
 703
 704 AC_ARG_ENABLE([gallium-tests],
 705     [AS_HELP_STRING([--enable-gallium-tests],
 706         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 707     [enable_gallium_tests="$enableval"],
 708     [enable_gallium_tests=no])
 709
 710 # Option for Gallium drivers
 711
 712 # Keep this in sync with the --with-gallium-drivers help string default value
 713 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 714
 715 AC_ARG_WITH([gallium-drivers],
 716     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 717         [comma delimited Gallium drivers list, e.g.
 718         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 719         @<:@default=r300,r600,svga,swrast@:>@])],
 720     [with_gallium_drivers="$withval"],
 721     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 722
 723 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 724 # here so that the script doesn't choke on an unknown driver name later.
 725 case "$with_gallium_drivers" in
 726     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 727     no) with_gallium_drivers='' ;;
 728 esac
 729
 730 if test "x$enable_opengl" = xno -a \
 731         "x$enable_gles1" = xno -a \
 732         "x$enable_gles2" = xno -a \
 733         "x$enable_openvg" = xno -a \
 734         "x$enable_xa" = xno -a \
 735         "x$enable_xvmc" = xno -a \
 736         "x$enable_vdpau" = xno -a \
 737         "x$enable_omx" = xno -a \
 738         "x$enable_opencl" = xno; then
 739     AC_MSG_ERROR([at least one API should be enabled])
 740 fi
 741
 742 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 743 if test "x$enable_opengl" = xno -a \
 744         "x$enable_gles1" = xyes; then
 745     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 746 fi
 747
 748 if test "x$enable_opengl" = xno -a \
 749         "x$enable_gles2" = xyes; then
 750     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 751 fi
 752
 753 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 754 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 755 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 756 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 757                                         "x$enable_gles1" = xyes -o \
 758                                         "x$enable_gles2" = xyes)
 759
 760 if test "x$enable_glx" = xno; then
 761     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 762     enable_xlib_glx=no
 763 fi
 764
 765 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 766     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 767 fi
 768
 769 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 770     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 771 fi
 772
 773 # Disable GLX if OpenGL is not enabled
 774 if test "x$enable_glx$enable_opengl" = xyesno; then
 775     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 776     enable_glx=no
 777 fi
 778
 779 # Disable GLX if DRI and Xlib-GLX are not enabled
 780 if test "x$enable_glx" = xyes -a \
 781         "x$enable_dri" = xno -a \
 782         "x$enable_xlib_glx" = xno; then
 783     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 784     enable_glx=no
 785 fi
 786
 787 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 788                                   "x$enable_dri" = xyes)
 789
 790 # Select which platform-dependent DRI code gets built
 791 case "$host_os" in
 792 darwin*)
 793     dri_platform='apple' ;;
 794 gnu*|mingw*|cygwin*)
 795     dri_platform='none' ;;
 796 *)
 797     dri_platform='drm' ;;
 798 esac
 799
 800 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 801 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 802 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 803 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 804 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 805
 806 AC_ARG_ENABLE([shared-glapi],
 807     [AS_HELP_STRING([--enable-shared-glapi],
 808         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 809     [enable_shared_glapi="$enableval"],
 810     [enable_shared_glapi=yes])
 811
 812 case "x$enable_opengl$enable_gles1$enable_gles2" in
 813 x*yes*yes*)
 814     if test "x$enable_shared_glapi" = xno; then
 815         AC_MSG_ERROR([shared GLAPI required when building two or more of
 816                       the following APIs - opengl, gles1 gles2])
 817     fi
 818     ;;
 819 esac
 820
 821 # Building Xlib-GLX requires shared glapi to be disabled.
 822 if test "x$enable_xlib_glx" = xyes; then
 823     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 824     enable_shared_glapi=no
 825 fi
 826
 827 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 828
 829 dnl
 830 dnl Driver specific build directories
 831 dnl
 832 GALLIUM_TARGET_DIRS=""
 833 GALLIUM_WINSYS_DIRS="sw"
 834 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 835 GALLIUM_STATE_TRACKERS_DIRS=""
 836
 837 case "x$enable_glx$enable_xlib_glx" in
 838 xyesyes)
 839     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 840     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 841     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 842     NEED_WINSYS_XLIB="yes"
 843     ;;
 844 esac
 845
 846 if test "x$enable_dri" = xyes; then
 847     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 848     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 849 fi
 850
 851 if test "x$enable_gallium_osmesa" = xyes; then
 852     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 853         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 854     fi
 855     if test "x$enable_osmesa" = xyes; then
 856         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 857     fi
 858     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 859     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 860 fi
 861
 862 AC_SUBST([MESA_LLVM])
 863
 864 # Check for libdrm
 865 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 866                   [have_libdrm=yes], [have_libdrm=no])
 867 if test "x$have_libdrm" = xyes; then
 868         DEFINES="$DEFINES -DHAVE_LIBDRM"
 869 fi
 870
 871 case "$host_os" in
 872 linux*)
 873     need_libudev=yes ;;
 874 *)
 875     need_libudev=no ;;
 876 esac
 877
 878 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 879                   have_libudev=yes, have_libudev=no)
 880
 881 if test "x$enable_dri" = xyes; then
 882     if test "$enable_static" = yes; then
 883         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 884     fi
 885
 886     # not a hard requirement as swrast does not depend on it
 887     if test "x$have_libdrm" = xyes; then
 888         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 889     fi
 890 fi
 891
 892 dnl Direct rendering or just indirect rendering
 893 case "$host_os" in
 894 gnu*)
 895     dnl Disable by default on GNU/Hurd
 896     driglx_direct_default="no"
 897     ;;
 898 cygwin*)
 899     dnl Disable by default on cygwin
 900     driglx_direct_default="no"
 901     ;;
 902 *)
 903     driglx_direct_default="yes"
 904     ;;
 905 esac
 906 AC_ARG_ENABLE([driglx-direct],
 907     [AS_HELP_STRING([--disable-driglx-direct],
 908         [disable direct rendering in GLX and EGL for DRI \
 909             @<:@default=auto@:>@])],
 910     [driglx_direct="$enableval"],
 911     [driglx_direct="$driglx_direct_default"])
 912
 913 dnl
 914 dnl libGL configuration per driver
 915 dnl
 916 case "x$enable_glx$enable_xlib_glx" in
 917 xyesyes)
 918     # Xlib-based GLX
 919     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 920     GL_PC_REQ_PRIV="x11 xext"
 921     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 922     GL_LIB_DEPS="$XLIBGL_LIBS"
 923     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 924     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 925     ;;
 926 xyesno)
 927     # DRI-based GLX
 928     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 929
 930     # find the DRI deps for libGL
 931     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 932
 933     if test x"$driglx_direct" = xyes; then
 934         if test x"$dri_platform" = xdrm ; then
 935             if test "x$have_libdrm" != xyes; then
 936                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 937             fi
 938
 939             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 940             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 941             if test x"$enable_dri3" = xyes; then
 942                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 943                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 944             fi
 945
 946             if test x"$enable_dri" = xyes; then
 947                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 948             fi
 949
 950             if test x"$enable_dri3" = xyes; then
 951                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 952             fi
 953         fi
 954         if test x"$dri_platform" = xapple ; then
 955             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 956         fi
 957     fi
 958
 959     # add xf86vidmode if available
 960     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 961     if test "$HAVE_XF86VIDMODE" = yes ; then
 962         dri_modules="$dri_modules xxf86vm"
 963     fi
 964
 965     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 966     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 967     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 968     GL_LIB_DEPS="$DRIGL_LIBS"
 969
 970     # need DRM libs, $PTHREAD_LIBS, etc.
 971     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 972     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 973     ;;
 974 esac
 975
 976 if test "$have_libudev" = yes; then
 977     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 978 fi
 979
 980 # This is outside the case (above) so that it is invoked even for non-GLX
 981 # builds.
 982 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 983
 984 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 985 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 986 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 987 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 988
 989 AC_SUBST([X11_INCLUDES])
 990 AC_SUBST([GL_LIB_DEPS])
 991 AC_SUBST([GL_PC_REQ_PRIV])
 992 AC_SUBST([GL_PC_LIB_PRIV])
 993 AC_SUBST([GL_PC_CFLAGS])
 994 AC_SUBST([DRI_PC_REQ_PRIV])
 995 AC_SUBST([GLESv1_CM_LIB_DEPS])
 996 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 997 AC_SUBST([GLESv2_LIB_DEPS])
 998 AC_SUBST([GLESv2_PC_LIB_PRIV])
 999
1000 AC_SUBST([HAVE_XF86VIDMODE])
1001
1002 dnl
1003 dnl More GLX setup
1004 dnl
1005 case "x$enable_glx$enable_xlib_glx" in
1006 xyesyes)
1007     DEFINES="$DEFINES -DUSE_XSHM"
1008     ;;
1009 xyesno)
1010     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1011     if test "x$driglx_direct" = xyes; then
1012         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1013     fi
1014     ;;
1015 esac
1016
1017 dnl
1018 dnl TLS detection
1019 dnl
1020
1021 AC_ARG_ENABLE([glx-tls],
1022     [AS_HELP_STRING([--enable-glx-tls],
1023         [enable TLS support in GLX @<:@default=disabled@:>@])],
1024     [GLX_USE_TLS="$enableval"],
1025     [GLX_USE_TLS=no])
1026 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1027
1028 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1029       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1030
1031 dnl
1032 dnl More DRI setup
1033 dnl
1034 dnl Directory for DRI drivers
1035 AC_ARG_WITH([dri-driverdir],
1036     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1037         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1038     [DRI_DRIVER_INSTALL_DIR="$withval"],
1039     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1040 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1041 dnl Extra search path for DRI drivers
1042 AC_ARG_WITH([dri-searchpath],
1043     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1044         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1045     [DRI_DRIVER_SEARCH_DIR="$withval"],
1046     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1047 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1048 dnl Which drivers to build - default is chosen by platform
1049 AC_ARG_WITH([dri-drivers],
1050     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1051         [comma delimited classic DRI drivers list, e.g.
1052         "swrast,i965,radeon" @<:@default=auto@:>@])],
1053     [with_dri_drivers="$withval"],
1054     [with_dri_drivers=auto])
1055
1056 if test "x$with_dri_drivers" = xauto; then
1057     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1058         with_dri_drivers="yes"
1059     else
1060         with_dri_drivers="no"
1061     fi
1062 fi
1063 if test "x$with_dri_drivers" = xno; then
1064     with_dri_drivers=''
1065 fi
1066
1067 dnl If $with_dri_drivers is yes, drivers will be added through
1068 dnl platform checks. Set DEFINES and LIB_DEPS
1069 if test "x$enable_dri" = xyes; then
1070     # Platform specific settings and drivers to build
1071     case "$host_os" in
1072     linux*)
1073         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1074         DEFINES="$DEFINES -DHAVE_ALIAS"
1075         if test "x$enable_dri3" = xyes; then
1076             DEFINES="$DEFINES -DHAVE_DRI3"
1077         fi
1078
1079         if test "x$have_libudev" != xyes; then
1080             AC_MSG_ERROR([libudev-dev required for building DRI])
1081         fi
1082
1083         case "$host_cpu" in
1084         powerpc* | sparc*)
1085             # Build only the drivers for cards that exist on PowerPC/sparc
1086             if test "x$with_dri_drivers" = "xyes"; then
1087                 with_dri_drivers="r200 radeon swrast"
1088             fi
1089             ;;
1090         esac
1091         ;;
1092     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1093         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1094         DEFINES="$DEFINES -DHAVE_ALIAS"
1095         ;;
1096     gnu*)
1097         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1098         DEFINES="$DEFINES -DHAVE_ALIAS"
1099         ;;
1100     solaris*)
1101         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1102         ;;
1103     cygwin*)
1104         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1105         if test "x$with_dri_drivers" = "xyes"; then
1106             with_dri_drivers="swrast"
1107         fi
1108         ;;
1109     darwin*)
1110         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DGLX_ALIAS_UNSUPPORTED"
1111         if test "x$with_dri_drivers" = "xyes"; then
1112             with_dri_drivers="swrast"
1113         fi
1114         ;;
1115     esac
1116
1117     # default drivers
1118     if test "x$with_dri_drivers" = "xyes"; then
1119         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1120     fi
1121
1122     # Check for expat
1123     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1124     if test "x$have_expat" = "xyes"; then
1125        PKG_CHECK_MODULES([EXPAT], [expat], [],
1126                          AC_MSG_ERROR([Expat required for DRI.]))
1127     else
1128        # expat version 2.0 and earlier do not provide expat.pc
1129        EXPAT_LIBS=-lexpat
1130     fi
1131
1132     # If we are building any DRI driver other than swrast.
1133     if test -n "$with_dri_drivers"; then
1134         if test "x$with_dri_drivers" != xswrast; then
1135             # ... libdrm is required
1136             if test "x$have_libdrm" != xyes; then
1137                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1138             fi
1139             DRICOMMON_NEED_LIBDRM=yes
1140         else
1141             DRICOMMON_NEED_LIBDRM=no
1142         fi
1143     fi
1144
1145     # put all the necessary libs together
1146     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1147 fi
1148
1149 AC_SUBST([DRI_LIB_DEPS])
1150
1151 DRI_DIRS=''
1152 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1153 if test -n "$with_dri_drivers"; then
1154     if test "x$enable_opengl" != xyes; then
1155         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1156     fi
1157
1158     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1159     for driver in $dri_drivers; do
1160         DRI_DIRS="$DRI_DIRS $driver"
1161         case "x$driver" in
1162         xi915)
1163             HAVE_I915_DRI=yes;
1164             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1165             ;;
1166         xi965)
1167             HAVE_I965_DRI=yes;
1168             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1169             ;;
1170         xnouveau)
1171             HAVE_NOUVEAU_DRI=yes;
1172             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1173             ;;
1174         xradeon)
1175             HAVE_RADEON_DRI=yes;
1176             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1177             ;;
1178         xr200)
1179             HAVE_R200_DRI=yes;
1180             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1181             ;;
1182         xswrast)
1183             HAVE_SWRAST_DRI=yes;
1184             ;;
1185         *)
1186             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1187             ;;
1188         esac
1189     done
1190     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1191 fi
1192
1193 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1194 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1195                                   "x$enable_osmesa" = xyes -o \
1196                                   -n "$DRI_DIRS")
1197
1198 dnl
1199 dnl OSMesa configuration
1200 dnl
1201
1202 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1203 AC_ARG_WITH([osmesa-bits],
1204     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1205         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1206     [osmesa_bits="$withval"],
1207     [osmesa_bits=8])
1208 if test "x$osmesa_bits" != x8; then
1209     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1210         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1211         osmesa_bits=8
1212     fi
1213 fi
1214 case "x$osmesa_bits" in
1215 x8)
1216     OSMESA_LIB="${OSMESA_LIB}"
1217     ;;
1218 x16|x32)
1219     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1220     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1221     ;;
1222 *)
1223     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1224     ;;
1225 esac
1226
1227 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1228     # only link libraries with osmesa if shared
1229     if test "$enable_static" = no; then
1230         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1231     else
1232         OSMESA_LIB_DEPS=""
1233     fi
1234     OSMESA_MESA_DEPS=""
1235     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1236 fi
1237
1238 AC_SUBST([OSMESA_LIB_DEPS])
1239 AC_SUBST([OSMESA_MESA_DEPS])
1240 AC_SUBST([OSMESA_PC_REQ])
1241 AC_SUBST([OSMESA_PC_LIB_PRIV])
1242
1243 dnl
1244 dnl gbm configuration
1245 dnl
1246 if test "x$enable_gbm" = xauto; then
1247     case "$with_egl_platforms" in
1248         *drm*)
1249             enable_gbm=yes ;;
1250          *)
1251             enable_gbm=no ;;
1252     esac
1253 fi
1254 if test "x$enable_gbm" = xyes; then
1255     if test "x$need_libudev$have_libudev" = xyesno; then
1256         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1257     fi
1258
1259     if test "x$enable_dri" = xyes; then
1260         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1261         if test "x$enable_shared_glapi" = xno; then
1262             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1263         fi
1264     else
1265         # Strictly speaking libgbm does not require --enable-dri, although
1266         # both of its backends do. Thus one can build libgbm without any
1267         # backends if --disable-dri is set.
1268         # To avoid unnecessary complexity of checking if at least one backend
1269         # is available when building, just mandate --enable-dri.
1270         AC_MSG_ERROR([gbm requires --enable-dri])
1271     fi
1272 fi
1273 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1274 if test "x$need_libudev" = xyes; then
1275     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1276 else
1277     GBM_PC_REQ_PRIV=""
1278 fi
1279 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1280 AC_SUBST([GBM_PC_REQ_PRIV])
1281 AC_SUBST([GBM_PC_LIB_PRIV])
1282
1283 dnl
1284 dnl EGL configuration
1285 dnl
1286 EGL_CLIENT_APIS=""
1287
1288 if test "x$enable_egl" = xyes; then
1289     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1290
1291     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1292
1293     if test "$enable_static" != yes; then
1294         if test "x$enable_dri" = xyes; then
1295             HAVE_EGL_DRIVER_DRI2=1
1296         fi
1297
1298     fi
1299 fi
1300 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1301 AC_SUBST([EGL_LIB_DEPS])
1302
1303 dnl
1304 dnl EGL Gallium configuration
1305 dnl
1306 if test "x$enable_gallium_egl" = xyes; then
1307     if test -z "$with_gallium_drivers"; then
1308         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1309     fi
1310     if test "x$enable_egl" = xno; then
1311         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1312     fi
1313     if test "x$have_libdrm" != xyes; then
1314         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1315     fi
1316
1317     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1318     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1319 fi
1320 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1321
1322 dnl
1323 dnl gbm Gallium configuration
1324 dnl
1325 if test "x$enable_gallium_gbm" = xauto; then
1326     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1327         yesyesyes*drm*)
1328             enable_gallium_gbm=yes ;;
1329          *)
1330             enable_gallium_gbm=no ;;
1331     esac
1332 fi
1333 if test "x$enable_gallium_gbm" = xyes; then
1334     if test -z "$with_gallium_drivers"; then
1335         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1336     fi
1337     if test "x$enable_gbm" = xno; then
1338         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1339     fi
1340     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1341     if test "x$enable_dri" = xno; then
1342         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1343     fi
1344
1345     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1346     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1347     enable_gallium_loader=yes
1348 fi
1349 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1350
1351 dnl
1352 dnl XA configuration
1353 dnl
1354 if test "x$enable_xa" = xyes; then
1355     if test "x$with_gallium_drivers" = xswrast; then
1356        AC_MSG_ERROR([
1357           Building xa requires at least one non swrast gallium driver.
1358           If you are looking to use libxatracker.so with vmware's virtual gpu,
1359           make sure to include svga in the gallium drivers list, apart from
1360           enabling XA.
1361           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1362     fi
1363     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1364     enable_gallium_loader=yes
1365 fi
1366 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1367
1368 dnl
1369 dnl OpenVG configuration
1370 dnl
1371 VG_LIB_DEPS=""
1372
1373 if test "x$enable_openvg" = xyes; then
1374     if test "x$enable_egl" = xno; then
1375         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1376     fi
1377     if test -z "$with_gallium_drivers"; then
1378         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1379     fi
1380     if test "x$enable_gallium_egl" = xno; then
1381         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1382     fi
1383
1384     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1385     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1386     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1387     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1388     AC_SUBST([VG_PC_LIB_PRIV])
1389 fi
1390 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1391
1392 dnl
1393 dnl Gallium G3DVL configuration
1394 dnl
1395 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1396     if test "x$enable_xvmc" = xauto; then
1397         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1398     fi
1399
1400     if test "x$enable_vdpau" = xauto; then
1401         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1402     fi
1403
1404     if test "x$enable_omx" = xauto; then
1405         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1406     fi
1407 fi
1408
1409 if test "x$enable_xvmc" = xyes; then
1410     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1411     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1412 fi
1413 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1414
1415 if test "x$enable_vdpau" = xyes; then
1416     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1417                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1418     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1419 fi
1420 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1421
1422 if test "x$enable_omx" = xyes; then
1423     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1424     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1425 fi
1426 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1427
1428 dnl
1429 dnl OpenCL configuration
1430 dnl
1431
1432 AC_ARG_WITH([libclc-path],
1433    [AS_HELP_STRING([--with-libclc-path],
1434          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1435    [LIBCLC_PATH="$withval"],
1436    [LIBCLC_PATH=''])
1437
1438 if test -n "$LIBCLC_PATH"; then
1439    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1440                   Please review the updated build instructions for clover:
1441                   http://dri.freedesktop.org/wiki/GalliumCompute])
1442 fi
1443
1444
1445 AC_ARG_WITH([clang-libdir],
1446    [AS_HELP_STRING([--with-clang-libdir],
1447          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1448    [CLANG_LIBDIR="$withval"],
1449    [CLANG_LIBDIR=''])
1450
1451 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1452
1453 if test "x$enable_opencl" = xyes; then
1454     if test -z "$with_gallium_drivers"; then
1455         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1456     fi
1457
1458     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1459         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1460     fi
1461
1462     if test "x$have_libclc" = xno; then
1463         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1464                     Make sure the directory containing libclc.pc is specified in your
1465                     PKG_CONFIG_PATH environment variable.
1466                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1467     else
1468         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1469         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1470         AC_SUBST([LIBCLC_INCLUDEDIR])
1471         AC_SUBST([LIBCLC_LIBEXECDIR])
1472     fi
1473
1474     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1475     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1476     enable_gallium_loader=yes
1477
1478     if test "x$enable_opencl_icd" = xyes; then
1479         OPENCL_LIBNAME="MesaOpenCL"
1480     else
1481         OPENCL_LIBNAME="OpenCL"
1482     fi
1483 fi
1484 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1485 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1486 AC_SUBST([OPENCL_LIBNAME])
1487
1488 dnl
1489 dnl Gallium configuration
1490 dnl
1491 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1492
1493 AC_SUBST([LLVM_BINDIR])
1494 AC_SUBST([LLVM_CFLAGS])
1495 AC_SUBST([LLVM_CPPFLAGS])
1496 AC_SUBST([LLVM_CXXFLAGS])
1497 AC_SUBST([LLVM_LIBDIR])
1498 AC_SUBST([LLVM_LIBS])
1499 AC_SUBST([LLVM_LDFLAGS])
1500 AC_SUBST([LLVM_INCLUDEDIR])
1501 AC_SUBST([LLVM_VERSION])
1502 AC_SUBST([CLANG_RESOURCE_DIR])
1503
1504 case "x$enable_opengl$enable_gles1$enable_gles2" in
1505 x*yes*)
1506     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1507     ;;
1508 esac
1509
1510 AC_SUBST([VG_LIB_DEPS])
1511 AC_SUBST([EGL_CLIENT_APIS])
1512
1513 dnl
1514 dnl EGL Platforms configuration
1515 dnl
1516 AC_ARG_WITH([egl-platforms],
1517     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1518         [comma delimited native platforms libEGL supports, e.g.
1519         "x11,drm" @<:@default=auto@:>@])],
1520     [with_egl_platforms="$withval"],
1521     [if test "x$enable_egl" = xyes; then
1522         with_egl_platforms="x11"
1523     else
1524         with_egl_platforms=""
1525     fi])
1526
1527 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1528     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1529 fi
1530
1531 # Do per-EGL platform setups and checks
1532 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1533 for plat in $egl_platforms; do
1534         case "$plat" in
1535         wayland)
1536                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1537                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1538
1539                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1540                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1541                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1542                 ;;
1543
1544         x11)
1545                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1546                 ;;
1547
1548         drm)
1549                 test "x$enable_gbm" = "xno" &&
1550                         AC_MSG_ERROR([EGL platform drm needs gbm])
1551                 test "x$have_libdrm" != xyes &&
1552                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1553                 ;;
1554
1555         android|fbdev|gdi|null)
1556                 ;;
1557
1558         *)
1559                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1560                 ;;
1561         esac
1562
1563         case "$plat$need_libudev$have_libudev" in
1564                 waylandyesno|drmyesno)
1565                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1566         esac
1567 done
1568
1569 # libEGL wants to default to the first platform specified in
1570 # ./configure.  parse that here.
1571 if test "x$egl_platforms" != "x"; then
1572     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1573     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1574 else
1575     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1576 fi
1577
1578 if echo "$egl_platforms" | grep -q 'x11'; then
1579     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1580     NEED_WINSYS_XLIB=yes
1581 fi
1582 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1583 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1584 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1585 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1586 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1587
1588 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1589
1590 AC_SUBST([EGL_NATIVE_PLATFORM])
1591 AC_SUBST([EGL_CFLAGS])
1592
1593 # If we don't have the X11 platform, set this define so we don't try to include
1594 # the X11 headers.
1595 if ! echo "$egl_platforms" | grep -q 'x11'; then
1596     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1597     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1598 fi
1599
1600 AC_ARG_WITH([egl-driver-dir],
1601     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1602                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1603     [EGL_DRIVER_INSTALL_DIR="$withval"],
1604     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1605 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1606
1607 AC_ARG_WITH([max-width],
1608     [AS_HELP_STRING([--with-max-width=N],
1609                     [Maximum framebuffer width (4096)])],
1610     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1611      AS_IF([test "${withval}" -gt "4096"],
1612            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1613 )
1614 AC_ARG_WITH([max-height],
1615     [AS_HELP_STRING([--with-max-height=N],
1616                     [Maximum framebuffer height (4096)])],
1617     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1618      AS_IF([test "${withval}" -gt "4096"],
1619            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1620 )
1621
1622 dnl
1623 dnl Gallium LLVM
1624 dnl
1625 AC_ARG_ENABLE([gallium-llvm],
1626     [AS_HELP_STRING([--enable-gallium-llvm],
1627         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1628     [enable_gallium_llvm="$enableval"],
1629     [enable_gallium_llvm=auto])
1630
1631 AC_ARG_ENABLE([llvm-shared-libs],
1632     [AS_HELP_STRING([--enable-llvm-shared-libs],
1633         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1634     [enable_llvm_shared_libs="$enableval"],
1635     [enable_llvm_shared_libs=yes])
1636
1637 AC_ARG_WITH([llvm-prefix],
1638     [AS_HELP_STRING([--with-llvm-prefix],
1639         [Prefix for LLVM installations in non-standard locations])],
1640     [llvm_prefix="$withval"],
1641     [llvm_prefix=''])
1642
1643
1644 # Call this inside ` ` to get the return value.
1645 # $1 is the llvm-config command with arguments.
1646 strip_unwanted_llvm_flags() {
1647     # Use \> (marks the end of the word)
1648     echo `$1` | sed \
1649         -e 's/-DNDEBUG\>//g' \
1650         -e 's/-pedantic\>//g' \
1651         -e 's/-Wcovered-switch-default\>//g' \
1652         -e 's/-O.\>//g' \
1653         -e 's/-g\>//g' \
1654         -e 's/-Wall\>//g' \
1655         -e 's/-Wcast-qual\>//g' \
1656         -e 's/-Woverloaded-virtual\>//g' \
1657         -e 's/-fcolor-diagnostics\>//g' \
1658         -e 's/-fdata-sections\>//g' \
1659         -e 's/-ffunction-sections\>//g' \
1660         -e 's/-fno-exceptions\>//g' \
1661         -e 's/-fomit-frame-pointer\>//g' \
1662         -e 's/-fvisibility-inlines-hidden\>//g' \
1663         -e 's/-fPIC\>//g' \
1664         -e 's/-fstack-protector-strong\>//g'
1665 }
1666
1667
1668 if test -z "$with_gallium_drivers"; then
1669     enable_gallium_llvm=no
1670 fi
1671 if test "x$enable_gallium_llvm" = xauto; then
1672     case "$host_cpu" in
1673     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1674     esac
1675 fi
1676 if test "x$enable_gallium_llvm" = xyes; then
1677     if test -n "$llvm_prefix"; then
1678         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1679     else
1680         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1681     fi
1682
1683     if test "x$LLVM_CONFIG" != xno; then
1684         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1685         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1686         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1687         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1688         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1689         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1690         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1691         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1692
1693         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1694             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1695         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1696             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1697
1698         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1699         dnl llvm-config.h
1700         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1701             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1702             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1703
1704         if test -n "${LLVM_VERSION_MAJOR}"; then
1705             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1706         else
1707             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1708         fi
1709
1710         LLVM_REQUIRED_VERSION_MAJOR="3"
1711         LLVM_REQUIRED_VERSION_MINOR="1"
1712         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1713             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1714         fi
1715
1716         LLVM_COMPONENTS="engine bitwriter"
1717         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1718             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1719         fi
1720
1721         if test "x$enable_opencl" = xyes; then
1722             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1723             # LLVM 3.3 >= 177971 requires IRReader
1724             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1725                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1726             fi
1727             # LLVM 3.4 requires Option
1728             if $LLVM_CONFIG --components | grep -qw 'option'; then
1729                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1730             fi
1731             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1732             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1733                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1734             fi
1735             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1736                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1737             fi
1738         fi
1739         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1740         MESA_LLVM=1
1741
1742         dnl Check for Clang internal headers
1743         if test "x$enable_opencl" = xyes; then
1744             if test -z "$CLANG_LIBDIR"; then
1745                 CLANG_LIBDIR=${LLVM_LIBDIR}
1746             fi
1747             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1748             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1749                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1750         fi
1751     else
1752         MESA_LLVM=0
1753         LLVM_VERSION_INT=0
1754     fi
1755 else
1756     MESA_LLVM=0
1757     LLVM_VERSION_INT=0
1758 fi
1759
1760 dnl Directory for XVMC libs
1761 AC_ARG_WITH([xvmc-libdir],
1762     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1763         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1764     [XVMC_LIB_INSTALL_DIR="$withval"],
1765     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1766 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1767
1768 dnl
1769 dnl Gallium Tests
1770 dnl
1771 if test "x$enable_gallium_tests" = xyes; then
1772     enable_gallium_loader=yes
1773 fi
1774 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1775
1776 if test "x$enable_gallium_loader" = xyes; then
1777     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1778 fi
1779 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1780
1781 dnl Directory for VDPAU libs
1782 AC_ARG_WITH([vdpau-libdir],
1783     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1784         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1785     [VDPAU_LIB_INSTALL_DIR="$withval"],
1786     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1787 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1788
1789 OMX_LIB_INSTALL_DIR_DEFAULT=''
1790 if test "x$enable_omx" = xyes; then
1791     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1792 fi
1793
1794 AC_ARG_WITH([omx-libdir],
1795     [AS_HELP_STRING([--with-omx-libdir=DIR],
1796         [directory for the OMX libraries])],
1797     [OMX_LIB_INSTALL_DIR="$withval"],
1798     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1799 AC_SUBST([OMX_LIB_INSTALL_DIR])
1800
1801 dnl Directory for OpenCL libs
1802 AC_ARG_WITH([opencl-libdir],
1803     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1804         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1805     [OPENCL_LIB_INSTALL_DIR="$withval"],
1806     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1807 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1808
1809 dnl
1810 dnl Gallium helper functions
1811 dnl
1812 gallium_check_st() {
1813     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1814          if test "x$have_libdrm" != xyes; then
1815             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1816          fi
1817          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1818     fi
1819     if test "x$enable_dri" = xyes && test -n "$2"; then
1820          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1821     fi
1822     if test "x$enable_xa" = xyes && test -n "$3"; then
1823          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1824     fi
1825     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1826          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1827     fi
1828     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1829          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1830     fi
1831     if test "x$enable_omx" = xyes && test "x$6" != x; then
1832          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1833     fi
1834 }
1835
1836 gallium_require_llvm() {
1837     if test "x$MESA_LLVM" = x0; then
1838         case "$host_cpu" in
1839         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1840         esac
1841     fi
1842 }
1843
1844 gallium_require_drm_loader() {
1845     if test "x$enable_gallium_loader" = xyes; then
1846         if test "x$need_libudev$have_libudev" = xyesno; then
1847             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1848         fi
1849         if test "x$have_libdrm" != xyes; then
1850             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1851         fi
1852         enable_gallium_drm_loader=yes
1853     fi
1854 }
1855
1856 require_egl_drm() {
1857     case "$with_egl_platforms" in
1858         *drm*)
1859             ;;
1860          *)
1861             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1862             ;;
1863     esac
1864     if test "x$enable_gbm" != xyes; then
1865             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1866     fi
1867 }
1868
1869 radeon_llvm_check() {
1870     if test "x$enable_gallium_llvm" != "xyes"; then
1871         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1872     fi
1873     LLVM_REQUIRED_VERSION_MAJOR="3"
1874     LLVM_REQUIRED_VERSION_MINOR="3"
1875     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1876         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1877     fi
1878     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1879         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1880                       sources with the --enable-experimental-targets=R600
1881                       configure flag])
1882     fi
1883     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1884     NEED_RADEON_LLVM=yes
1885     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1886                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1887 }
1888
1889 dnl Gallium drivers
1890 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1891         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1892     NEED_NONNULL_WINSYS=yes
1893 fi
1894 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1895
1896 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1897 if test -n "$with_gallium_drivers"; then
1898     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1899     for driver in $gallium_drivers; do
1900         case "x$driver" in
1901         xsvga)
1902             HAVE_GALLIUM_SVGA=yes
1903             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1904             gallium_require_drm_loader
1905             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1906             ;;
1907         xi915)
1908             HAVE_GALLIUM_I915=yes
1909             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1910             gallium_require_drm_loader
1911             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1912             if test "x$MESA_LLVM" = x1; then
1913                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1914             fi
1915             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1916             gallium_check_st "i915/drm" "dri-i915"
1917             DRICOMMON_NEED_LIBDRM=yes
1918             ;;
1919         xilo)
1920             HAVE_GALLIUM_ILO=yes
1921             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1922             gallium_require_drm_loader
1923             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1924             gallium_check_st "intel/drm" "dri-ilo"
1925             DRICOMMON_NEED_LIBDRM=yes
1926             ;;
1927         xr300)
1928             HAVE_GALLIUM_R300=yes
1929             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1930             gallium_require_drm_loader
1931             gallium_require_llvm "Gallium R300"
1932             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1933             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1934             DRICOMMON_NEED_LIBDRM=yes
1935             ;;
1936         xr600)
1937             HAVE_GALLIUM_R600=yes
1938             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1939             gallium_require_drm_loader
1940             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1941             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1942                 radeon_llvm_check "r600g"
1943                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1944             fi
1945             if test "x$enable_r600_llvm" = xyes; then
1946                 USE_R600_LLVM_COMPILER=yes;
1947             fi
1948             if test "x$enable_opencl" = xyes; then
1949                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1950             fi
1951             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1952             DRICOMMON_NEED_LIBDRM=yes
1953             ;;
1954         xradeonsi)
1955             HAVE_GALLIUM_RADEONSI=yes
1956             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1957             gallium_require_drm_loader
1958             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1959             radeon_llvm_check "radeonsi"
1960             require_egl_drm "radeonsi"
1961             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1962             DRICOMMON_NEED_LIBDRM=yes
1963             ;;
1964         xnouveau)
1965             HAVE_GALLIUM_NOUVEAU=yes
1966             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1967             gallium_require_drm_loader
1968             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1969             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1970             DRICOMMON_NEED_LIBDRM=yes
1971             ;;
1972         xfreedreno)
1973             HAVE_GALLIUM_FREEDRENO=yes
1974             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1975             gallium_require_drm_loader
1976             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1977             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1978             DRICOMMON_NEED_LIBDRM=yes
1979             ;;
1980         xswrast)
1981             HAVE_GALLIUM_SOFTPIPE=yes
1982             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1983             if test "x$MESA_LLVM" = x1; then
1984                 HAVE_GALLIUM_LLVMPIPE=yes
1985                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1986             fi
1987
1988             if test "x$enable_dri" = xyes; then
1989                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1990             fi
1991             ;;
1992         *)
1993             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1994             ;;
1995         esac
1996     done
1997 fi
1998
1999 dnl Set LLVM_LIBS - This is done after the driver configuration so
2000 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2001 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2002 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2003 dnl this was causing the same libraries to be appear multiple times
2004 dnl in LLVM_LIBS.
2005
2006 if test "x$MESA_LLVM" != x0; then
2007
2008     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2009
2010     if test "x$enable_llvm_shared_libs" = xyes; then
2011         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2012         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2013         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2014
2015         if test "x$llvm_have_one_so" = xyes; then
2016             dnl LLVM was built using auto*, so there is only one shared object.
2017             LLVM_LIBS="-l$LLVM_SO_NAME"
2018         else
2019             dnl If LLVM was built with CMake, there will be one shared object per
2020             dnl component.
2021             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2022                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2023         Please make sure you have built llvm with the --enable-shared option
2024         and that your llvm libraries are installed in $LLVM_LIBDIR
2025         If you have installed your llvm libraries to a different directory you
2026         can use the --with-llvm-prefix= configure flag to specify this directory.
2027         NOTE: Mesa is attempting to use llvm shared libraries by default.
2028         If you do not want to build with llvm shared libraries and instead want to
2029         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2030         invocation and rebuild.])])
2031
2032            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2033            dnl install uses a shared object for each compoenent and we have
2034            dnl already added all of these objects to LLVM_LIBS.
2035         fi
2036     else
2037         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2038     fi
2039 fi
2040
2041 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2042 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2043 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2044 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2045 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2046 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2047 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2048                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2049 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2050 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2051 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2052 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2053
2054 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2055                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
2056                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2057 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2058                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2059                                                   && test "x$MESA_LLVM" = x1)
2060
2061 # NOTE: anything using xcb or other client side libs ends up in separate
2062 #       _CLIENT variables.  The pipe loader is built in two variants,
2063 #       one that is standalone and does not link any x client libs (for
2064 #       use by XA tracker in particular, but could be used in any case
2065 #       where communication with xserver is not desired).
2066 if test "x$enable_gallium_loader" = xyes; then
2067     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2068
2069     if test "x$NEED_WINSYS_XLIB" = xyes; then
2070         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2071     fi
2072
2073     if test "x$enable_dri" = xyes; then
2074         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2075     fi
2076
2077     if test "x$enable_gallium_drm_loader" = xyes; then
2078         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2079         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2080                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2081         if test "x$pipe_loader_have_xcb" = xyes; then
2082             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2083             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2084         fi
2085     fi
2086
2087     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2088     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2089
2090     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2091     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2092     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2093     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2094 fi
2095
2096 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2097 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2098 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2099 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2100 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2101 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2102
2103 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2104                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2105                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2106                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2107 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2108                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2109 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2110 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2111 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2112 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2113 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2114 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2115 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2116
2117 AC_SUBST([ELF_LIB])
2118
2119 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2120 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2121 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2122 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2123 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2124
2125 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2126 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2127 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2128
2129 AC_SUBST([VDPAU_MAJOR], 1)
2130 AC_SUBST([VDPAU_MINOR], 0)
2131
2132 AC_SUBST([XVMC_MAJOR], 1)
2133 AC_SUBST([XVMC_MINOR], 0)
2134
2135 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2136 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2137 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2138 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2139
2140 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2141 AC_SUBST([XA_MINOR], $XA_MINOR)
2142 AC_SUBST([XA_TINY], $XA_TINY)
2143 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2144
2145 dnl Restore LDFLAGS and CPPFLAGS
2146 LDFLAGS="$_SAVE_LDFLAGS"
2147 CPPFLAGS="$_SAVE_CPPFLAGS"
2148
2149 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2150 if test "x$acv_mesa_CLANG" = xyes; then
2151     CFLAGS="$CFLAGS -Qunused-arguments"
2152     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2153 fi
2154
2155 dnl Add user CFLAGS and CXXFLAGS
2156 CFLAGS="$CFLAGS $USER_CFLAGS"
2157 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2158
2159 dnl Substitute the config
2160 AC_CONFIG_FILES([Makefile
2161                 src/Makefile
2162                 src/egl/drivers/dri2/Makefile
2163                 src/egl/main/Makefile
2164                 src/egl/main/egl.pc
2165                 src/egl/wayland/Makefile
2166                 src/egl/wayland/wayland-drm/Makefile
2167                 src/egl/wayland/wayland-egl/Makefile
2168                 src/egl/wayland/wayland-egl/wayland-egl.pc
2169                 src/gallium/auxiliary/Makefile
2170                 src/gallium/auxiliary/pipe-loader/Makefile
2171                 src/gallium/drivers/Makefile
2172                 src/gallium/drivers/freedreno/Makefile
2173                 src/gallium/drivers/galahad/Makefile
2174                 src/gallium/drivers/i915/Makefile
2175                 src/gallium/drivers/identity/Makefile
2176                 src/gallium/drivers/ilo/Makefile
2177                 src/gallium/drivers/llvmpipe/Makefile
2178                 src/gallium/drivers/noop/Makefile
2179                 src/gallium/drivers/nouveau/Makefile
2180                 src/gallium/drivers/r300/Makefile
2181                 src/gallium/drivers/r600/Makefile
2182                 src/gallium/drivers/radeon/Makefile
2183                 src/gallium/drivers/radeonsi/Makefile
2184                 src/gallium/drivers/rbug/Makefile
2185                 src/gallium/drivers/softpipe/Makefile
2186                 src/gallium/drivers/svga/Makefile
2187                 src/gallium/drivers/trace/Makefile
2188                 src/gallium/state_trackers/Makefile
2189                 src/gallium/state_trackers/clover/Makefile
2190                 src/gallium/state_trackers/dri/Makefile
2191                 src/gallium/state_trackers/dri/drm/Makefile
2192                 src/gallium/state_trackers/dri/sw/Makefile
2193                 src/gallium/state_trackers/egl/Makefile
2194                 src/gallium/state_trackers/gbm/Makefile
2195                 src/gallium/state_trackers/glx/xlib/Makefile
2196                 src/gallium/state_trackers/omx/Makefile
2197                 src/gallium/state_trackers/osmesa/Makefile
2198                 src/gallium/state_trackers/vdpau/Makefile
2199                 src/gallium/state_trackers/vega/Makefile
2200                 src/gallium/state_trackers/xa/Makefile
2201                 src/gallium/state_trackers/xvmc/Makefile
2202                 src/gallium/targets/Makefile
2203                 src/gallium/targets/dri-freedreno/Makefile
2204                 src/gallium/targets/dri-i915/Makefile
2205                 src/gallium/targets/dri-ilo/Makefile
2206                 src/gallium/targets/dri-nouveau/Makefile
2207                 src/gallium/targets/dri-swrast/Makefile
2208                 src/gallium/targets/dri-vmwgfx/Makefile
2209                 src/gallium/targets/egl-static/Makefile
2210                 src/gallium/targets/gbm/Makefile
2211                 src/gallium/targets/opencl/Makefile
2212                 src/gallium/targets/xa/Makefile
2213                 src/gallium/targets/xa/xatracker.pc
2214                 src/gallium/targets/omx-nouveau/Makefile
2215                 src/gallium/targets/osmesa/Makefile
2216                 src/gallium/targets/osmesa/osmesa.pc
2217                 src/gallium/targets/pipe-loader/Makefile
2218                 src/gallium/targets/radeonsi/dri/Makefile
2219                 src/gallium/targets/radeonsi/omx/Makefile
2220                 src/gallium/targets/radeonsi/vdpau/Makefile
2221                 src/gallium/targets/r300/dri/Makefile
2222                 src/gallium/targets/r600/dri/Makefile
2223                 src/gallium/targets/r600/omx/Makefile
2224                 src/gallium/targets/r600/vdpau/Makefile
2225                 src/gallium/targets/r600/xvmc/Makefile
2226                 src/gallium/targets/libgl-xlib/Makefile
2227                 src/gallium/targets/vdpau-nouveau/Makefile
2228                 src/gallium/targets/xvmc-nouveau/Makefile
2229                 src/gallium/tests/trivial/Makefile
2230                 src/gallium/tests/unit/Makefile
2231                 src/gallium/winsys/Makefile
2232                 src/gallium/winsys/freedreno/drm/Makefile
2233                 src/gallium/winsys/i915/drm/Makefile
2234                 src/gallium/winsys/i915/sw/Makefile
2235                 src/gallium/winsys/intel/drm/Makefile
2236                 src/gallium/winsys/nouveau/drm/Makefile
2237                 src/gallium/winsys/radeon/drm/Makefile
2238                 src/gallium/winsys/svga/drm/Makefile
2239                 src/gallium/winsys/sw/dri/Makefile
2240                 src/gallium/winsys/sw/fbdev/Makefile
2241                 src/gallium/winsys/sw/null/Makefile
2242                 src/gallium/winsys/sw/wayland/Makefile
2243                 src/gallium/winsys/sw/wrapper/Makefile
2244                 src/gallium/winsys/sw/xlib/Makefile
2245                 src/gbm/Makefile
2246                 src/gbm/main/gbm.pc
2247                 src/glsl/Makefile
2248                 src/glx/Makefile
2249                 src/glx/apple/Makefile
2250                 src/glx/tests/Makefile
2251                 src/gtest/Makefile
2252                 src/loader/Makefile
2253                 src/mapi/Makefile
2254                 src/mapi/es1api/Makefile
2255                 src/mapi/es1api/glesv1_cm.pc
2256                 src/mapi/es2api/Makefile
2257                 src/mapi/es2api/glesv2.pc
2258                 src/mapi/glapi/Makefile
2259                 src/mapi/glapi/gen/Makefile
2260                 src/mapi/glapi/tests/Makefile
2261                 src/mapi/shared-glapi/Makefile
2262                 src/mapi/shared-glapi/tests/Makefile
2263                 src/mapi/vgapi/Makefile
2264                 src/mapi/vgapi/vg.pc
2265                 src/mesa/Makefile
2266                 src/mesa/gl.pc
2267                 src/mesa/drivers/dri/dri.pc
2268                 src/mesa/drivers/dri/common/Makefile
2269                 src/mesa/drivers/dri/common/xmlpool/Makefile
2270                 src/mesa/drivers/dri/i915/Makefile
2271                 src/mesa/drivers/dri/i965/Makefile
2272                 src/mesa/drivers/dri/Makefile
2273                 src/mesa/drivers/dri/nouveau/Makefile
2274                 src/mesa/drivers/dri/r200/Makefile
2275                 src/mesa/drivers/dri/radeon/Makefile
2276                 src/mesa/drivers/dri/swrast/Makefile
2277                 src/mesa/drivers/osmesa/Makefile
2278                 src/mesa/drivers/osmesa/osmesa.pc
2279                 src/mesa/drivers/x11/Makefile
2280                 src/mesa/main/tests/Makefile
2281                 src/mesa/main/tests/hash_table/Makefile])
2282
2283 dnl Sort the dirs alphabetically
2284 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2285 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2286 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2287 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2288
2289 AC_OUTPUT
2290
2291 dnl
2292 dnl Output some configuration info for the user
2293 dnl
2294 echo ""
2295 echo "        prefix:          $prefix"
2296 echo "        exec_prefix:     $exec_prefix"
2297 echo "        libdir:          $libdir"
2298 echo "        includedir:      $includedir"
2299
2300 dnl API info
2301 echo ""
2302 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2303 echo "        OpenVG:          $enable_openvg"
2304
2305 dnl Driver info
2306 echo ""
2307 case "x$enable_osmesa$enable_gallium_osmesa" in
2308 xnoyes)
2309         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2310         ;;
2311 xyesno)
2312         echo "        OSMesa:          lib$OSMESA_LIB"
2313         ;;
2314 xnono)
2315         echo "        OSMesa:          no"
2316         ;;
2317 esac
2318
2319 echo ""
2320 if test "x$enable_dri" != xno; then
2321         echo "        DRI platform:    $dri_platform"
2322         if test -z "$DRI_DIRS"; then
2323             echo "        DRI drivers:     no"
2324         else
2325             echo "        DRI drivers:     $DRI_DIRS"
2326         fi
2327         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2328 fi
2329
2330 case "x$enable_glx$enable_xlib_glx" in
2331 xyesyes)
2332     echo "        GLX:             Xlib-based"
2333     ;;
2334 xyesno)
2335     echo "        GLX:             DRI-based"
2336     ;;
2337 *)
2338     echo "        GLX:             $enable_glx"
2339     ;;
2340 esac
2341
2342 dnl EGL
2343 echo ""
2344 echo "        EGL:             $enable_egl"
2345 if test "$enable_egl" = yes; then
2346     echo "        EGL platforms:   $egl_platforms"
2347
2348     egl_drivers=""
2349     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2350         egl_drivers="$egl_drivers builtin:egl_dri2"
2351     fi
2352
2353     if test "x$enable_gallium_egl" = xyes; then
2354         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2355         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2356     else
2357         echo "        EGL drivers:    $egl_drivers"
2358     fi
2359 fi
2360
2361 echo ""
2362 if test "x$MESA_LLVM" = x1; then
2363     echo "        llvm:            yes"
2364     echo "        llvm-config:     $LLVM_CONFIG"
2365     echo "        llvm-version:    $LLVM_VERSION"
2366 else
2367     echo "        llvm:            no"
2368 fi
2369
2370 echo ""
2371 if test -n "$with_gallium_drivers"; then
2372     echo "        Gallium:         yes"
2373     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2374     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2375     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2376     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2377 else
2378     echo "        Gallium:         no"
2379 fi
2380
2381
2382 dnl Libraries
2383 echo ""
2384 echo "        Shared libs:     $enable_shared"
2385 echo "        Static libs:     $enable_static"
2386 echo "        Shared-glapi:    $enable_shared_glapi"
2387
2388 dnl Compiler options
2389 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2390 cflags=`echo $CFLAGS | \
2391     $SED 's/^ *//;s/  */ /;s/ *$//'`
2392 cxxflags=`echo $CXXFLAGS | \
2393     $SED 's/^ *//;s/  */ /;s/ *$//'`
2394 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2395 echo ""
2396 echo "        CFLAGS:          $cflags"
2397 echo "        CXXFLAGS:        $cxxflags"
2398 echo "        Macros:          $defines"
2399 echo ""
2400 if test "x$MESA_LLVM" = x1; then
2401     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2402     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2403     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2404     echo ""
2405 fi
2406 echo "        PYTHON2:         $PYTHON2"
2407
2408 echo ""
2409 echo "        Run '${MAKE-make}' to build Mesa"
2410 echo ""