configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.52
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82
  83 dnl Check for progs
  84 AC_PROG_CPP
  85 AC_PROG_CC
  86 AC_PROG_CXX
  87 AM_PROG_CC_C_O
  88 AM_PROG_AS
  89 AX_CHECK_GNU_MAKE
  90 AC_CHECK_PROGS([PYTHON2], [python2 python])
  91 AC_PROG_SED
  92 AC_PROG_MKDIR_P
  93
  94 AC_SYS_LARGEFILE
  95
  96 LT_PREREQ([2.2])
  97 LT_INIT([disable-static])
  98
  99 AX_PROG_BISON([],
 100               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 101                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 102 AX_PROG_FLEX([],
 103              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 104                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 105
 106 AC_CHECK_PROG(INDENT, indent, indent, cat)
 107 if test "x$INDENT" != "xcat"; then
 108     # Only GNU indent is supported
 109     INDENT_VERSION=`indent --version | grep GNU`
 110     if test $? -eq 0; then
 111        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 112     else
 113        INDENT="cat"
 114     fi
 115 fi
 116
 117 AX_CHECK_PYTHON_MAKO_MODULE(0.3.4)
 118
 119 AC_PROG_INSTALL
 120
 121 dnl We need a POSIX shell for parts of the build. Assume we have one
 122 dnl in most cases.
 123 case "$host_os" in
 124 solaris*)
 125     # Solaris /bin/sh is too old/non-POSIX compliant
 126     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 127     SHELL="$POSIX_SHELL"
 128     ;;
 129 esac
 130
 131 dnl clang is mostly GCC-compatible, but its version is much lower,
 132 dnl so we have to check for it.
 133 AC_MSG_CHECKING([if compiling with clang])
 134
 135 AC_COMPILE_IFELSE(
 136 [AC_LANG_PROGRAM([], [[
 137 #ifndef __clang__
 138        not clang
 139 #endif
 140 ]])],
 141 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 142
 143 AC_MSG_RESULT([$acv_mesa_CLANG])
 144
 145 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 146 dnl versions are explictly not supported.
 147 GEN_ASM_OFFSETS=no
 148 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 149     AC_MSG_CHECKING([whether gcc version is sufficient])
 150     major=0
 151     minor=0
 152
 153     GCC_VERSION=`$CC -dumpversion`
 154     if test $? -eq 0; then
 155         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 156         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 157     fi
 158
 159     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 160         AC_MSG_RESULT([no])
 161         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 162     else
 163         AC_MSG_RESULT([yes])
 164     fi
 165
 166     if test "x$cross_compiling" = xyes; then
 167         GEN_ASM_OFFSETS=yes
 168     fi
 169 fi
 170
 171 dnl Check for compiler builtins
 172 AX_GCC_BUILTIN([__builtin_bswap32])
 173 AX_GCC_BUILTIN([__builtin_bswap64])
 174 AX_GCC_BUILTIN([__builtin_clz])
 175 AX_GCC_BUILTIN([__builtin_clzll])
 176 AX_GCC_BUILTIN([__builtin_ctz])
 177 AX_GCC_BUILTIN([__builtin_expect])
 178 AX_GCC_BUILTIN([__builtin_ffs])
 179 AX_GCC_BUILTIN([__builtin_ffsll])
 180 AX_GCC_BUILTIN([__builtin_popcount])
 181 AX_GCC_BUILTIN([__builtin_popcountll])
 182 AX_GCC_BUILTIN([__builtin_unreachable])
 183
 184 AX_GCC_FUNC_ATTRIBUTE([flatten])
 185 AX_GCC_FUNC_ATTRIBUTE([format])
 186 AX_GCC_FUNC_ATTRIBUTE([malloc])
 187 AX_GCC_FUNC_ATTRIBUTE([packed])
 188
 189 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 190
 191 dnl Make sure the pkg-config macros are defined
 192 m4_ifndef([PKG_PROG_PKG_CONFIG],
 193     [m4_fatal([Could not locate the pkg-config autoconf macros.
 194   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 195   are in a different location, try setting the environment variable
 196   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 197 PKG_PROG_PKG_CONFIG()
 198
 199 dnl LIB_DIR - library basename
 200 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 201 AC_SUBST([LIB_DIR])
 202
 203 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 204 _SAVE_LDFLAGS="$LDFLAGS"
 205 _SAVE_CPPFLAGS="$CPPFLAGS"
 206
 207 dnl Compiler macros
 208 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 209 AC_SUBST([DEFINES])
 210 case "$host_os" in
 211 linux*|*-gnu*|gnu*)
 212     DEFINES="$DEFINES -D_GNU_SOURCE"
 213     ;;
 214 solaris*)
 215     DEFINES="$DEFINES -DSVR4"
 216     ;;
 217 cygwin*)
 218     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 219     ;;
 220 esac
 221
 222 dnl Add flags for gcc and g++
 223 if test "x$GCC" = xyes; then
 224     CFLAGS="$CFLAGS -Wall -std=c99"
 225
 226     # Enable -Werror=implicit-function-declaration and
 227     # -Werror=missing-prototypes, if available, or otherwise, just
 228     # -Wmissing-prototypes.  This is particularly useful to avoid
 229     # generating a loadable driver module that has undefined symbols.
 230     save_CFLAGS="$CFLAGS"
 231     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 232     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 233     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 234     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 235                    AC_MSG_RESULT([yes]),
 236                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 237                     AC_MSG_RESULT([no])]);
 238
 239     # Enable -fvisibility=hidden if using a gcc that supports it
 240     save_CFLAGS="$CFLAGS"
 241     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 242     VISIBILITY_CFLAGS="-fvisibility=hidden"
 243     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 244     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 245                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 246
 247     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 248     CFLAGS=$save_CFLAGS
 249
 250     # Work around aliasing bugs - developers should comment this out
 251     CFLAGS="$CFLAGS -fno-strict-aliasing"
 252
 253     # gcc's builtin memcmp is slower than glibc's
 254     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 255     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 256 fi
 257 if test "x$GXX" = xyes; then
 258     CXXFLAGS="$CXXFLAGS -Wall"
 259
 260     # Enable -fvisibility=hidden if using a gcc that supports it
 261     save_CXXFLAGS="$CXXFLAGS"
 262     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 263     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 264     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 265     AC_LANG_PUSH([C++])
 266     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 267                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 268     AC_LANG_POP([C++])
 269
 270     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 271     CXXFLAGS=$save_CXXFLAGS
 272
 273     # Work around aliasing bugs - developers should comment this out
 274     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 275
 276     # gcc's builtin memcmp is slower than glibc's
 277     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 278     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 279 fi
 280
 281 dnl even if the compiler appears to support it, using visibility attributes isn't
 282 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 283 case "$host_os" in
 284 cygwin*)
 285     VISIBILITY_CFLAGS=""
 286     VISIBILITY_CXXFLAGS=""
 287     ;;
 288 esac
 289
 290 AC_SUBST([VISIBILITY_CFLAGS])
 291 AC_SUBST([VISIBILITY_CXXFLAGS])
 292
 293 dnl
 294 dnl Optional flags, check for compiler support
 295 dnl
 296 SSE41_CFLAGS="-msse4.1"
 297 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 298 dnl stack, but on x86-32 such alignment is not guaranteed.
 299 case "$target_cpu" in
 300 i?86)
 301     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 302     ;;
 303 esac
 304 save_CFLAGS="$CFLAGS"
 305 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 306 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 307 #include <smmintrin.h>
 308 int main () {
 309     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 310     c = _mm_max_epu32(a, b);
 311     return 0;
 312 }]])], SSE41_SUPPORTED=1)
 313 CFLAGS="$save_CFLAGS"
 314 if test "x$SSE41_SUPPORTED" = x1; then
 315     DEFINES="$DEFINES -DUSE_SSE41"
 316 fi
 317 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 318 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 319
 320 dnl Can't have static and shared libraries, default to static if user
 321 dnl explicitly requested. If both disabled, set to static since shared
 322 dnl was explicitly requested.
 323 case "x$enable_static$enable_shared" in
 324 xyesyes)
 325     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 326     enable_shared=no
 327     ;;
 328 xnono)
 329     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 330     enable_shared=yes
 331     ;;
 332 esac
 333
 334 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 335
 336 dnl
 337 dnl other compiler options
 338 dnl
 339 AC_ARG_ENABLE([debug],
 340     [AS_HELP_STRING([--enable-debug],
 341         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 342     [enable_debug="$enableval"],
 343     [enable_debug=no]
 344 )
 345 if test "x$enable_debug" = xyes; then
 346     DEFINES="$DEFINES -DDEBUG"
 347     if test "x$GCC" = xyes; then
 348         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 349             CFLAGS="$CFLAGS -g"
 350         fi
 351         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 352             CFLAGS="$CFLAGS -O0"
 353         fi
 354     fi
 355     if test "x$GXX" = xyes; then
 356         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 357             CXXFLAGS="$CXXFLAGS -g"
 358         fi
 359         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 360             CXXFLAGS="$CXXFLAGS -O0"
 361         fi
 362     fi
 363 fi
 364
 365 dnl
 366 dnl Check if linker supports -Bsymbolic
 367 dnl
 368 save_LDFLAGS=$LDFLAGS
 369 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 370 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 371 AC_LINK_IFELSE(
 372     [AC_LANG_SOURCE([int main() { return 0;}])],
 373     [AC_MSG_RESULT([yes])
 374         BSYMBOLIC="-Wl,-Bsymbolic";],
 375     [AC_MSG_RESULT([no])
 376         BSYMBOLIC="";])
 377 LDFLAGS=$save_LDFLAGS
 378
 379 AC_SUBST([BSYMBOLIC])
 380
 381 dnl
 382 dnl Check if linker supports garbage collection
 383 dnl
 384 save_LDFLAGS=$LDFLAGS
 385 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 386 AC_MSG_CHECKING([whether ld supports --gc-sections])
 387 AC_LINK_IFELSE(
 388     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 389     [AC_MSG_RESULT([yes])
 390         GC_SECTIONS="-Wl,--gc-sections";],
 391     [AC_MSG_RESULT([no])
 392         GC_SECTIONS="";])
 393 LDFLAGS=$save_LDFLAGS
 394
 395 AC_SUBST([GC_SECTIONS])
 396
 397 dnl
 398 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 399 dnl so when these flags are passed to ld via libtool the checks will fail
 400 dnl
 401 case "$host_os" in
 402 openbsd* | darwin* )
 403     LD_NO_UNDEFINED="" ;;
 404 *)
 405     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 406 esac
 407
 408 AC_SUBST([LD_NO_UNDEFINED])
 409
 410 dnl
 411 dnl Check if linker supports version scripts
 412 dnl
 413 AC_MSG_CHECKING([if the linker supports version-scripts])
 414 save_LDFLAGS=$LDFLAGS
 415 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 416 cat > conftest.map <<EOF
 417 VERSION_1 {
 418      global:
 419          main;
 420
 421      local:
 422          *;
 423 };
 424 EOF
 425 AC_LINK_IFELSE(
 426     [AC_LANG_SOURCE([int main() { return 0;}])],
 427     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 428     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 429 LDFLAGS=$save_LDFLAGS
 430 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 431
 432 dnl
 433 dnl Check if linker supports dynamic list files
 434 dnl
 435 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 436 save_LDFLAGS=$LDFLAGS
 437 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 438 cat > conftest.dyn <<EOF
 439 {
 440         radeon_drm_winsys_create;
 441 };
 442 EOF
 443 AC_LINK_IFELSE(
 444     [AC_LANG_SOURCE([int main() { return 0;}])],
 445     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 446     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 447 LDFLAGS=$save_LDFLAGS
 448 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 449
 450 dnl
 451 dnl compatibility symlinks
 452 dnl
 453 case "$host_os" in
 454 linux* )
 455     HAVE_COMPAT_SYMLINKS=yes ;;
 456 * )
 457     HAVE_COMPAT_SYMLINKS=no ;;
 458 esac
 459
 460 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 461
 462 dnl
 463 dnl library names
 464 dnl
 465 case "$host_os" in
 466 darwin* )
 467     LIB_EXT='dylib' ;;
 468 cygwin* )
 469     LIB_EXT='dll' ;;
 470 aix* )
 471     LIB_EXT='a' ;;
 472 * )
 473     LIB_EXT='so' ;;
 474 esac
 475
 476 AC_SUBST([LIB_EXT])
 477
 478 AC_ARG_WITH([gl-lib-name],
 479   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 480     [specify GL library name @<:@default=GL@:>@])],
 481   [GL_LIB=$withval],
 482   [GL_LIB=GL])
 483 AC_ARG_WITH([osmesa-lib-name],
 484   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 485     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 486   [OSMESA_LIB=$withval],
 487   [OSMESA_LIB=OSMesa])
 488 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 489 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 490
 491 dnl
 492 dnl Mangled Mesa support
 493 dnl
 494 AC_ARG_ENABLE([mangling],
 495   [AS_HELP_STRING([--enable-mangling],
 496     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 497   [enable_mangling="${enableval}"],
 498   [enable_mangling=no]
 499 )
 500 if test "x${enable_mangling}" = "xyes" ; then
 501   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 502   GL_LIB="Mangled${GL_LIB}"
 503   OSMESA_LIB="Mangled${OSMESA_LIB}"
 504 fi
 505 AC_SUBST([GL_LIB])
 506 AC_SUBST([OSMESA_LIB])
 507
 508 dnl
 509 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 510 dnl
 511 AC_ARG_ENABLE([texture-float],
 512     [AS_HELP_STRING([--enable-texture-float],
 513         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 514     [enable_texture_float="$enableval"],
 515     [enable_texture_float=no]
 516 )
 517 if test "x$enable_texture_float" = xyes; then
 518     AC_MSG_WARN([Floating-point textures enabled.])
 519     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 520     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 521 fi
 522
 523 dnl
 524 dnl Arch/platform-specific settings
 525 dnl
 526 AC_ARG_ENABLE([asm],
 527     [AS_HELP_STRING([--disable-asm],
 528         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 529     [enable_asm="$enableval"],
 530     [enable_asm=yes]
 531 )
 532 asm_arch=""
 533 AC_MSG_CHECKING([whether to enable assembly])
 534 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 535 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 536 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 537     case "$host_cpu" in
 538     i?86 | x86_64 | amd64)
 539         enable_asm=no
 540         AC_MSG_RESULT([no, cross compiling])
 541         ;;
 542     esac
 543 fi
 544 # check for supported arches
 545 if test "x$enable_asm" = xyes; then
 546     case "$host_cpu" in
 547     i?86)
 548         case "$host_os" in
 549         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 550             asm_arch=x86
 551             ;;
 552         esac
 553         ;;
 554     x86_64|amd64)
 555         case "$host_os" in
 556         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 557             asm_arch=x86_64
 558             ;;
 559         esac
 560         ;;
 561     sparc*)
 562         case "$host_os" in
 563         linux*)
 564             asm_arch=sparc
 565             ;;
 566         esac
 567         ;;
 568     esac
 569
 570     case "$asm_arch" in
 571     x86)
 572         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 573         AC_MSG_RESULT([yes, x86])
 574         ;;
 575     x86_64|amd64)
 576         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 577         AC_MSG_RESULT([yes, x86_64])
 578         ;;
 579     sparc)
 580         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 581         AC_MSG_RESULT([yes, sparc])
 582         ;;
 583     *)
 584         AC_MSG_RESULT([no, platform not supported])
 585         ;;
 586     esac
 587 fi
 588
 589 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 590 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 591
 592 dnl Check to see if dlopen is in default libraries (like Solaris, which
 593 dnl has it in libc), or if libdl is needed to get it.
 594 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 595     [AC_CHECK_LIB([dl], [dlopen],
 596        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 597 AC_SUBST([DLOPEN_LIBS])
 598
 599 dnl Check if that library also has dladdr
 600 save_LIBS="$LIBS"
 601 LIBS="$LIBS $DLOPEN_LIBS"
 602 AC_CHECK_FUNCS([dladdr])
 603 LIBS="$save_LIBS"
 604
 605 case "$host_os" in
 606 darwin*|mingw*)
 607     ;;
 608 *)
 609     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 610                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 611                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 612     AC_SUBST([CLOCK_LIB])
 613     ;;
 614 esac
 615
 616 dnl See if posix_memalign is available
 617 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 618
 619 dnl Check for pthreads
 620 case "$host_os" in
 621 mingw*)
 622     ;;
 623 *)
 624     AX_PTHREAD
 625     ;;
 626 esac
 627 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 628 dnl to -pthread, which causes problems if we need -lpthread to appear in
 629 dnl pkgconfig files.
 630 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 631
 632 dnl SELinux awareness.
 633 AC_ARG_ENABLE([selinux],
 634     [AS_HELP_STRING([--enable-selinux],
 635         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 636     [MESA_SELINUX="$enableval"],
 637     [MESA_SELINUX=no])
 638 if test "x$enable_selinux" = "xyes"; then
 639     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 640         [AC_CHECK_HEADER([selinux/selinux.h],[],
 641                          [AC_MSG_ERROR([SELinux headers not found])])
 642          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 643                       [AC_MSG_ERROR([SELinux library not found])])
 644          SELINUX_LIBS="-lselinux"])
 645     DEFINES="$DEFINES -DMESA_SELINUX"
 646 fi
 647 AC_SUBST([SELINUX_CFLAGS])
 648 AC_SUBST([SELINUX_LIBS])
 649
 650 dnl Options for APIs
 651 AC_ARG_ENABLE([opengl],
 652     [AS_HELP_STRING([--disable-opengl],
 653         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 654     [enable_opengl="$enableval"],
 655     [enable_opengl=yes])
 656 AC_ARG_ENABLE([gles1],
 657     [AS_HELP_STRING([--enable-gles1],
 658         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 659     [enable_gles1="$enableval"],
 660     [enable_gles1=no])
 661 AC_ARG_ENABLE([gles2],
 662     [AS_HELP_STRING([--enable-gles2],
 663         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 664     [enable_gles2="$enableval"],
 665     [enable_gles2=no])
 666 AC_ARG_ENABLE([openvg],
 667     [AS_HELP_STRING([--enable-openvg],
 668         [enable support for OpenVG API @<:@default=disabled@:>@])],
 669     [enable_openvg="$enableval"],
 670     [enable_openvg=no])
 671
 672 AC_ARG_ENABLE([dri],
 673     [AS_HELP_STRING([--enable-dri],
 674         [enable DRI modules @<:@default=enabled@:>@])],
 675     [enable_dri="$enableval"],
 676     [enable_dri=yes])
 677
 678 case "$host_os" in
 679 linux*)
 680     dri3_default=yes
 681     ;;
 682 *)
 683     dri3_default=no
 684     ;;
 685 esac
 686 AC_ARG_ENABLE([dri3],
 687     [AS_HELP_STRING([--enable-dri3],
 688         [enable DRI3 @<:@default=auto@:>@])],
 689     [enable_dri3="$enableval"],
 690     [enable_dri3="$dri3_default"])
 691 AC_ARG_ENABLE([glx],
 692     [AS_HELP_STRING([--enable-glx],
 693         [enable GLX library @<:@default=enabled@:>@])],
 694     [enable_glx="$enableval"],
 695     [enable_glx=yes])
 696 AC_ARG_ENABLE([osmesa],
 697     [AS_HELP_STRING([--enable-osmesa],
 698         [enable OSMesa library @<:@default=disabled@:>@])],
 699     [enable_osmesa="$enableval"],
 700     [enable_osmesa=no])
 701 AC_ARG_ENABLE([gallium-osmesa],
 702     [AS_HELP_STRING([--enable-gallium-osmesa],
 703         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 704     [enable_gallium_osmesa="$enableval"],
 705     [enable_gallium_osmesa=no])
 706 AC_ARG_ENABLE([egl],
 707     [AS_HELP_STRING([--disable-egl],
 708         [disable EGL library @<:@default=enabled@:>@])],
 709     [enable_egl="$enableval"],
 710     [enable_egl=yes])
 711
 712 AC_ARG_ENABLE([xa],
 713     [AS_HELP_STRING([--enable-xa],
 714         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 715     [enable_xa="$enableval"],
 716     [enable_xa=no])
 717 AC_ARG_ENABLE([gbm],
 718    [AS_HELP_STRING([--enable-gbm],
 719          [enable gbm library @<:@default=auto@:>@])],
 720    [enable_gbm="$enableval"],
 721    [enable_gbm=auto])
 722 AC_ARG_ENABLE([nine],
 723     [AS_HELP_STRING([--enable-nine],
 724         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 725     [enable_nine="$enableval"],
 726     [enable_nine=no])
 727
 728 AC_ARG_ENABLE([xvmc],
 729    [AS_HELP_STRING([--enable-xvmc],
 730          [enable xvmc library @<:@default=auto@:>@])],
 731    [enable_xvmc="$enableval"],
 732    [enable_xvmc=auto])
 733 AC_ARG_ENABLE([vdpau],
 734    [AS_HELP_STRING([--enable-vdpau],
 735          [enable vdpau library @<:@default=auto@:>@])],
 736    [enable_vdpau="$enableval"],
 737    [enable_vdpau=auto])
 738 AC_ARG_ENABLE([omx],
 739    [AS_HELP_STRING([--enable-omx],
 740          [enable OpenMAX library @<:@default=disabled@:>@])],
 741    [enable_omx="$enableval"],
 742    [enable_omx=no])
 743 AC_ARG_ENABLE([va],
 744    [AS_HELP_STRING([--enable-va],
 745          [enable va library @<:@default=auto@:>@])],
 746    [enable_va="$enableval"],
 747    [enable_va=auto])
 748 AC_ARG_ENABLE([opencl],
 749    [AS_HELP_STRING([--enable-opencl],
 750          [enable OpenCL library @<:@default=disabled@:>@])],
 751    [enable_opencl="$enableval"],
 752    [enable_opencl=no])
 753 AC_ARG_ENABLE([opencl_icd],
 754    [AS_HELP_STRING([--enable-opencl-icd],
 755           [Build an OpenCL ICD library to be loaded by an ICD implementation
 756            @<:@default=disabled@:>@])],
 757     [enable_opencl_icd="$enableval"],
 758     [enable_opencl_icd=no])
 759 AC_ARG_ENABLE([xlib-glx],
 760     [AS_HELP_STRING([--enable-xlib-glx],
 761         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 762     [enable_xlib_glx="$enableval"],
 763     [enable_xlib_glx=no])
 764
 765 AC_ARG_ENABLE([r600-llvm-compiler],
 766     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 767         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 768     [enable_r600_llvm="$enableval"],
 769     [enable_r600_llvm=no])
 770
 771 AC_ARG_ENABLE([gallium-tests],
 772     [AS_HELP_STRING([--enable-gallium-tests],
 773         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 774     [enable_gallium_tests="$enableval"],
 775     [enable_gallium_tests=no])
 776
 777 # Option for Gallium drivers
 778
 779 # Keep this in sync with the --with-gallium-drivers help string default value
 780 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 781
 782 AC_ARG_WITH([gallium-drivers],
 783     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 784         [comma delimited Gallium drivers list, e.g.
 785         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 786         @<:@default=r300,r600,svga,swrast@:>@])],
 787     [with_gallium_drivers="$withval"],
 788     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 789
 790 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 791 # here so that the script doesn't choke on an unknown driver name later.
 792 case "$with_gallium_drivers" in
 793     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 794     no) with_gallium_drivers='' ;;
 795 esac
 796
 797 if test "x$enable_opengl" = xno -a \
 798         "x$enable_gles1" = xno -a \
 799         "x$enable_gles2" = xno -a \
 800         "x$enable_nine" = xno -a \
 801         "x$enable_openvg" = xno -a \
 802         "x$enable_xa" = xno -a \
 803         "x$enable_xvmc" = xno -a \
 804         "x$enable_vdpau" = xno -a \
 805         "x$enable_omx" = xno -a \
 806         "x$enable_va" = xno -a \
 807         "x$enable_opencl" = xno; then
 808     AC_MSG_ERROR([at least one API should be enabled])
 809 fi
 810
 811 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 812 if test "x$enable_opengl" = xno -a \
 813         "x$enable_gles1" = xyes; then
 814     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 815 fi
 816
 817 if test "x$enable_opengl" = xno -a \
 818         "x$enable_gles2" = xyes; then
 819     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 820 fi
 821
 822 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 823 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 824 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 825 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 826                                         "x$enable_gles1" = xyes -o \
 827                                         "x$enable_gles2" = xyes)
 828
 829 if test "x$enable_glx" = xno; then
 830     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 831     enable_xlib_glx=no
 832 fi
 833
 834 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 835     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 836 fi
 837
 838 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 839     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 840 fi
 841
 842 # Disable GLX if OpenGL is not enabled
 843 if test "x$enable_glx$enable_opengl" = xyesno; then
 844     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 845     enable_glx=no
 846 fi
 847
 848 # Disable GLX if DRI and Xlib-GLX are not enabled
 849 if test "x$enable_glx" = xyes -a \
 850         "x$enable_dri" = xno -a \
 851         "x$enable_xlib_glx" = xno; then
 852     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 853     enable_glx=no
 854 fi
 855
 856 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 857                                   "x$enable_dri" = xyes)
 858
 859 # Select which platform-dependent DRI code gets built
 860 case "$host_os" in
 861 darwin*)
 862     dri_platform='apple' ;;
 863 gnu*|mingw*|cygwin*)
 864     dri_platform='none' ;;
 865 *)
 866     dri_platform='drm' ;;
 867 esac
 868
 869 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 870 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 871 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 872 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 873 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 874
 875 AC_ARG_ENABLE([shared-glapi],
 876     [AS_HELP_STRING([--enable-shared-glapi],
 877         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 878     [enable_shared_glapi="$enableval"],
 879     [enable_shared_glapi=yes])
 880
 881 case "x$enable_opengl$enable_gles1$enable_gles2" in
 882 x*yes*yes*)
 883     if test "x$enable_shared_glapi" = xno; then
 884         AC_MSG_ERROR([shared GLAPI required when building two or more of
 885                       the following APIs - opengl, gles1 gles2])
 886     fi
 887     ;;
 888 esac
 889
 890 # Building Xlib-GLX requires shared glapi to be disabled.
 891 if test "x$enable_xlib_glx" = xyes; then
 892     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 893     enable_shared_glapi=no
 894 fi
 895
 896 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 897
 898 # Build the pipe-drivers as separate libraries/modules.
 899 # Do not touch this unless you know what you are doing.
 900 # XXX: Expose via configure option ?
 901 enable_shared_pipe_drivers=no
 902
 903 dnl
 904 dnl Driver specific build directories
 905 dnl
 906
 907 case "x$enable_glx$enable_xlib_glx" in
 908 xyesyes)
 909     NEED_WINSYS_XLIB="yes"
 910     ;;
 911 esac
 912
 913 if test "x$enable_dri" = xyes; then
 914     enable_gallium_loader="$enable_shared_pipe_drivers"
 915 fi
 916
 917 if test "x$enable_gallium_osmesa" = xyes; then
 918     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 919         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 920     fi
 921     if test "x$enable_osmesa" = xyes; then
 922         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 923     fi
 924 fi
 925
 926 AC_SUBST([MESA_LLVM])
 927
 928 # SHA1 hashing
 929 AC_ARG_WITH([sha1],
 930         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 931         [choose SHA1 implementation])])
 932 case "x$with_sha1" in
 933 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 934   ;;
 935 *)
 936         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 937 esac
 938
 939 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 940 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 941         with_sha1=libc
 942 fi
 943 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 944         AC_MSG_ERROR([sha1 in libc requested but not found])
 945 fi
 946 if test "x$with_sha1" = xlibc; then
 947         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 948                 [Use libc SHA1 functions])
 949         SHA1_LIBS=""
 950 fi
 951 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 952 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 953         with_sha1=CommonCrypto
 954 fi
 955 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
 956         AC_MSG_ERROR([CommonCrypto requested but not found])
 957 fi
 958 if test "x$with_sha1" = xCommonCrypto; then
 959         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
 960                 [Use CommonCrypto SHA1 functions])
 961         SHA1_LIBS=""
 962 fi
 963 dnl stdcall functions cannot be tested with AC_CHECK_LIB
 964 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
 965 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
 966         with_sha1=CryptoAPI
 967 fi
 968 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
 969         AC_MSG_ERROR([CryptoAPI requested but not found])
 970 fi
 971 if test "x$with_sha1" = xCryptoAPI; then
 972         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
 973                 [Use CryptoAPI SHA1 functions])
 974         SHA1_LIBS=""
 975 fi
 976 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
 977 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
 978         with_sha1=libmd
 979 fi
 980 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
 981         AC_MSG_ERROR([libmd requested but not found])
 982 fi
 983 if test "x$with_sha1" = xlibmd; then
 984         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
 985                   [Use libmd SHA1 functions])
 986         SHA1_LIBS=-lmd
 987 fi
 988 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
 989 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
 990    with_sha1=libsha1
 991 fi
 992 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
 993         AC_MSG_ERROR([libsha1 requested but not found])
 994 fi
 995 if test "x$with_sha1" = xlibsha1; then
 996         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
 997                   [Use libsha1 for SHA1])
 998         SHA1_LIBS=-lsha1
 999 fi
1000 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1001 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1002         with_sha1=libnettle
1003 fi
1004 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1005         AC_MSG_ERROR([libnettle requested but not found])
1006 fi
1007 if test "x$with_sha1" = xlibnettle; then
1008         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1009                   [Use libnettle SHA1 functions])
1010         SHA1_LIBS=-lnettle
1011 fi
1012 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1013 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1014         with_sha1=libgcrypt
1015 fi
1016 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1017         AC_MSG_ERROR([libgcrypt requested but not found])
1018 fi
1019 if test "x$with_sha1" = xlibgcrypt; then
1020         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1021                   [Use libgcrypt SHA1 functions])
1022         SHA1_LIBS=-lgcrypt
1023 fi
1024 # We don't need all of the OpenSSL libraries, just libcrypto
1025 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1026 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1027                   [HAVE_OPENSSL_PKC=no])
1028 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1029         if test "x$with_sha1" = x; then
1030                 with_sha1=libcrypto
1031         fi
1032 else
1033         if test "x$with_sha1" = xlibcrypto; then
1034                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1035         fi
1036 fi
1037 if test "x$with_sha1" = xlibcrypto; then
1038         if test "x$HAVE_LIBCRYPTO" = xyes; then
1039                 SHA1_LIBS=-lcrypto
1040         else
1041                 SHA1_LIBS="$OPENSSL_LIBS"
1042                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1043         fi
1044 fi
1045 AC_MSG_CHECKING([for SHA1 implementation])
1046 AM_CONDITIONAL([HAVE_SHA1], [test x$with_sha1 != x])
1047 AC_MSG_RESULT([$with_sha1])
1048 AC_SUBST(SHA1_LIBS)
1049 AC_SUBST(SHA1_CFLAGS)
1050
1051 # Check for libdrm
1052 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1053                   [have_libdrm=yes], [have_libdrm=no])
1054 if test "x$have_libdrm" = xyes; then
1055         DEFINES="$DEFINES -DHAVE_LIBDRM"
1056 fi
1057
1058 case "$host_os" in
1059 linux*)
1060     need_pci_id=yes ;;
1061 *)
1062     need_pci_id=no ;;
1063 esac
1064
1065 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1066                   have_libudev=yes, have_libudev=no)
1067
1068 AC_ARG_ENABLE([sysfs],
1069     [AS_HELP_STRING([--enable-sysfs],
1070         [enable /sys PCI identification @<:@default=disabled@:>@])],
1071     [have_sysfs="$enableval"],
1072     [have_sysfs=no]
1073 )
1074
1075 if test "x$enable_dri" = xyes; then
1076     if test "$enable_static" = yes; then
1077         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1078     fi
1079
1080     # not a hard requirement as swrast does not depend on it
1081     if test "x$have_libdrm" = xyes; then
1082         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1083     fi
1084 fi
1085
1086 AC_ARG_ENABLE([driglx-direct],
1087     [AS_HELP_STRING([--disable-driglx-direct],
1088         [disable direct rendering in GLX and EGL for DRI \
1089             @<:@default=auto@:>@])],
1090     [driglx_direct="$enableval"],
1091     [driglx_direct="yes"])
1092
1093 dnl
1094 dnl libGL configuration per driver
1095 dnl
1096 case "x$enable_glx$enable_xlib_glx" in
1097 xyesyes)
1098     # Xlib-based GLX
1099     dri_modules="x11 xext xcb"
1100     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1101     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1102     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1103     GL_LIB_DEPS="$XLIBGL_LIBS"
1104     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1105     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1106     ;;
1107 xyesno)
1108     # DRI-based GLX
1109     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1110
1111     # find the DRI deps for libGL
1112     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1113
1114     if test x"$driglx_direct" = xyes; then
1115         if test x"$dri_platform" = xdrm ; then
1116             DEFINES="$DEFINES -DGLX_USE_DRM"
1117             if test "x$have_libdrm" != xyes; then
1118                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1119             fi
1120
1121             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1122             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1123             if test x"$enable_dri3" = xyes; then
1124                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1125                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1126             fi
1127
1128             if test x"$enable_dri" = xyes; then
1129                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1130             fi
1131
1132             if test x"$enable_dri3" = xyes; then
1133                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1134                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1135             fi
1136         fi
1137         if test x"$dri_platform" = xapple ; then
1138             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1139         fi
1140     fi
1141
1142     # add xf86vidmode if available
1143     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1144     if test "$HAVE_XF86VIDMODE" = yes ; then
1145         dri_modules="$dri_modules xxf86vm"
1146     fi
1147
1148     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1149     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1150     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1151     GL_LIB_DEPS="$DRIGL_LIBS"
1152
1153     # need DRM libs, $PTHREAD_LIBS, etc.
1154     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1155     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1156     ;;
1157 esac
1158
1159 have_pci_id=no
1160 if test "$have_libudev" = yes; then
1161     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1162     have_pci_id=yes
1163 fi
1164
1165 if test "$have_sysfs" = yes; then
1166     DEFINES="$DEFINES -DHAVE_SYSFS"
1167     have_pci_id=yes
1168 fi
1169
1170 # This is outside the case (above) so that it is invoked even for non-GLX
1171 # builds.
1172 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1173
1174 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1175 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1176 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1177 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1178
1179 AC_SUBST([X11_INCLUDES])
1180 AC_SUBST([GL_LIB_DEPS])
1181 AC_SUBST([GL_PC_REQ_PRIV])
1182 AC_SUBST([GL_PC_LIB_PRIV])
1183 AC_SUBST([GL_PC_CFLAGS])
1184 AC_SUBST([DRI_PC_REQ_PRIV])
1185 AC_SUBST([GLESv1_CM_LIB_DEPS])
1186 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1187 AC_SUBST([GLESv2_LIB_DEPS])
1188 AC_SUBST([GLESv2_PC_LIB_PRIV])
1189
1190 AC_SUBST([HAVE_XF86VIDMODE])
1191
1192 dnl
1193 dnl More GLX setup
1194 dnl
1195 case "x$enable_glx$enable_xlib_glx" in
1196 xyesyes)
1197     DEFINES="$DEFINES -DUSE_XSHM"
1198     ;;
1199 xyesno)
1200     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1201     if test "x$driglx_direct" = xyes; then
1202         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1203     fi
1204     ;;
1205 esac
1206
1207 dnl
1208 dnl TLS detection
1209 dnl
1210
1211 AC_ARG_ENABLE([glx-tls],
1212     [AS_HELP_STRING([--enable-glx-tls],
1213         [enable TLS support in GLX @<:@default=disabled@:>@])],
1214     [GLX_USE_TLS="$enableval"],
1215     [GLX_USE_TLS=no])
1216 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1217
1218 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1219       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1220
1221 dnl
1222 dnl More DRI setup
1223 dnl
1224 dnl Directory for DRI drivers
1225 AC_ARG_WITH([dri-driverdir],
1226     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1227         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1228     [DRI_DRIVER_INSTALL_DIR="$withval"],
1229     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1230 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1231 dnl Extra search path for DRI drivers
1232 AC_ARG_WITH([dri-searchpath],
1233     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1234         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1235     [DRI_DRIVER_SEARCH_DIR="$withval"],
1236     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1237 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1238 dnl Which drivers to build - default is chosen by platform
1239 AC_ARG_WITH([dri-drivers],
1240     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1241         [comma delimited classic DRI drivers list, e.g.
1242         "swrast,i965,radeon" @<:@default=auto@:>@])],
1243     [with_dri_drivers="$withval"],
1244     [with_dri_drivers=auto])
1245
1246 if test "x$with_dri_drivers" = xauto; then
1247     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1248         with_dri_drivers="yes"
1249     else
1250         with_dri_drivers="no"
1251     fi
1252 fi
1253 if test "x$with_dri_drivers" = xno; then
1254     with_dri_drivers=''
1255 fi
1256
1257 dnl If $with_dri_drivers is yes, drivers will be added through
1258 dnl platform checks. Set DEFINES and LIB_DEPS
1259 if test "x$enable_dri" = xyes; then
1260     # Platform specific settings and drivers to build
1261     case "$host_os" in
1262     linux*)
1263         DEFINES="$DEFINES -DHAVE_ALIAS"
1264         if test "x$enable_dri3" = xyes; then
1265             DEFINES="$DEFINES -DHAVE_DRI3"
1266         fi
1267
1268         if test "x$have_pci_id" != xyes; then
1269             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1270         fi
1271
1272         case "$host_cpu" in
1273         powerpc* | sparc*)
1274             # Build only the drivers for cards that exist on PowerPC/sparc
1275             if test "x$with_dri_drivers" = "xyes"; then
1276                 with_dri_drivers="r200 radeon swrast"
1277             fi
1278             ;;
1279         esac
1280         ;;
1281     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1282         DEFINES="$DEFINES -DHAVE_ALIAS"
1283         ;;
1284     gnu*)
1285         DEFINES="$DEFINES -DHAVE_ALIAS"
1286         ;;
1287     cygwin*)
1288         if test "x$with_dri_drivers" = "xyes"; then
1289             with_dri_drivers="swrast"
1290         fi
1291         ;;
1292     darwin*)
1293         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1294         if test "x$with_dri_drivers" = "xyes"; then
1295             with_dri_drivers="swrast"
1296         fi
1297         ;;
1298     esac
1299
1300     # default drivers
1301     if test "x$with_dri_drivers" = "xyes"; then
1302         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1303     fi
1304
1305     # Check for expat
1306     PKG_CHECK_MODULES([EXPAT], [expat], [],
1307         # expat version 2.0 and earlier do not provide expat.pc
1308         [AC_CHECK_HEADER([expat.h],[],
1309                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1310          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1311                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1312          EXPAT_LIBS="-lexpat"])
1313
1314     DRICOMMON_NEED_LIBDRM=no
1315     # If we are building any DRI driver other than swrast.
1316     if test -n "$with_dri_drivers"; then
1317         if test "x$with_dri_drivers" != xswrast; then
1318             # ... libdrm is required
1319             if test "x$have_libdrm" != xyes; then
1320                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1321             fi
1322             DRICOMMON_NEED_LIBDRM=yes
1323         fi
1324     fi
1325
1326     # If we're building any gallium DRI driver other than swrast
1327     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1328         if test "x$with_gallium_drivers" != xswrast; then
1329             # ... build a libdrm aware dricommon
1330             DRICOMMON_NEED_LIBDRM=yes
1331         fi
1332     fi
1333
1334     # put all the necessary libs together
1335     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1336 fi
1337
1338 AC_SUBST([DRI_LIB_DEPS])
1339
1340 DRI_DIRS=''
1341 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1342 if test -n "$with_dri_drivers"; then
1343     if test "x$enable_opengl" != xyes; then
1344         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1345     fi
1346
1347     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1348     for driver in $dri_drivers; do
1349         DRI_DIRS="$DRI_DIRS $driver"
1350         case "x$driver" in
1351         xi915)
1352             HAVE_I915_DRI=yes;
1353             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1354             ;;
1355         xi965)
1356             HAVE_I965_DRI=yes;
1357             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1358             ;;
1359         xnouveau)
1360             HAVE_NOUVEAU_DRI=yes;
1361             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1362             ;;
1363         xradeon)
1364             HAVE_RADEON_DRI=yes;
1365             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1366             ;;
1367         xr200)
1368             HAVE_R200_DRI=yes;
1369             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1370             ;;
1371         xswrast)
1372             HAVE_SWRAST_DRI=yes;
1373             ;;
1374         *)
1375             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1376             ;;
1377         esac
1378     done
1379     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1380 fi
1381
1382 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1383 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1384                                   "x$enable_osmesa" = xyes -o \
1385                                   -n "$DRI_DIRS")
1386
1387 dnl
1388 dnl OSMesa configuration
1389 dnl
1390
1391 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1392 AC_ARG_WITH([osmesa-bits],
1393     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1394         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1395     [osmesa_bits="$withval"],
1396     [osmesa_bits=8])
1397 if test "x$osmesa_bits" != x8; then
1398     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1399         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1400         osmesa_bits=8
1401     fi
1402 fi
1403 case "x$osmesa_bits" in
1404 x8)
1405     OSMESA_LIB="${OSMESA_LIB}"
1406     ;;
1407 x16|x32)
1408     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1409     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1410     ;;
1411 *)
1412     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1413     ;;
1414 esac
1415
1416 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1417     # only link libraries with osmesa if shared
1418     if test "$enable_static" = no; then
1419         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1420     else
1421         OSMESA_LIB_DEPS=""
1422     fi
1423     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1424 fi
1425
1426 AC_SUBST([OSMESA_LIB_DEPS])
1427 AC_SUBST([OSMESA_PC_REQ])
1428 AC_SUBST([OSMESA_PC_LIB_PRIV])
1429
1430 dnl
1431 dnl gbm configuration
1432 dnl
1433 if test "x$enable_gbm" = xauto; then
1434     case "$with_egl_platforms" in
1435         *drm*)
1436             enable_gbm=yes ;;
1437          *)
1438             enable_gbm=no ;;
1439     esac
1440 fi
1441 if test "x$enable_gbm" = xyes; then
1442     if test "x$need_pci_id$have_pci_id" = xyesno; then
1443         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1444     fi
1445
1446     if test "x$enable_dri" = xyes; then
1447         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1448         if test "x$enable_shared_glapi" = xno; then
1449             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1450         fi
1451     else
1452         # Strictly speaking libgbm does not require --enable-dri, although
1453         # both of its backends do. Thus one can build libgbm without any
1454         # backends if --disable-dri is set.
1455         # To avoid unnecessary complexity of checking if at least one backend
1456         # is available when building, just mandate --enable-dri.
1457         AC_MSG_ERROR([gbm requires --enable-dri])
1458     fi
1459 fi
1460 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1461 if test "x$need_pci_id$have_libudev" = xyesyes; then
1462     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1463 else
1464     GBM_PC_REQ_PRIV=""
1465 fi
1466 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1467 AC_SUBST([GBM_PC_REQ_PRIV])
1468 AC_SUBST([GBM_PC_LIB_PRIV])
1469
1470 dnl
1471 dnl EGL configuration
1472 dnl
1473 EGL_CLIENT_APIS=""
1474
1475 if test "x$enable_egl" = xyes; then
1476     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1477
1478     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1479
1480     if test "$enable_static" != yes; then
1481         if test "x$enable_dri" = xyes; then
1482             HAVE_EGL_DRIVER_DRI2=1
1483         fi
1484
1485     fi
1486 fi
1487 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1488 AC_SUBST([EGL_LIB_DEPS])
1489
1490 dnl
1491 dnl XA configuration
1492 dnl
1493 if test "x$enable_xa" = xyes; then
1494     if test "x$with_gallium_drivers" = xswrast; then
1495        AC_MSG_ERROR([
1496           Building xa requires at least one non swrast gallium driver.
1497           If you are looking to use libxatracker.so with the VMware driver,
1498           make sure to include svga in the gallium drivers list, apart from
1499           enabling XA.
1500           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1501     fi
1502     enable_gallium_loader=$enable_shared_pipe_drivers
1503 fi
1504 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1505
1506 dnl
1507 dnl OpenVG configuration
1508 dnl
1509 VG_LIB_DEPS=""
1510
1511 if test "x$enable_openvg" = xyes; then
1512     if test "x$enable_egl" = xno; then
1513         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1514     fi
1515     if test -z "$with_gallium_drivers"; then
1516         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1517     fi
1518
1519     AC_MSG_ERROR([Cannot enable OpenVG, because egl_gallium has been removed and
1520                   OpenVG has not been integrated into standard libEGL yet])
1521
1522     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1523     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1524     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1525     AC_SUBST([VG_PC_LIB_PRIV])
1526 fi
1527 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1528
1529 dnl
1530 dnl Gallium G3DVL configuration
1531 dnl
1532 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1533     if test "x$enable_xvmc" = xauto; then
1534         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1535     fi
1536
1537     if test "x$enable_vdpau" = xauto; then
1538         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1539     fi
1540
1541     if test "x$enable_omx" = xauto; then
1542         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1543     fi
1544
1545     if test "x$enable_va" = xauto; then
1546         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1547     fi
1548 fi
1549
1550 if test "x$enable_xvmc" = xyes -o \
1551         "x$enable_vdpau" = xyes -o \
1552         "x$enable_omx" = xyes -o \
1553         "x$enable_va" = xyes; then
1554     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1555     need_gallium_vl=yes
1556 fi
1557 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1558
1559 if test "x$enable_xvmc" = xyes; then
1560     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1561     enable_gallium_loader=$enable_shared_pipe_drivers
1562 fi
1563 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1564
1565 if test "x$enable_vdpau" = xyes; then
1566     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1567     enable_gallium_loader=$enable_shared_pipe_drivers
1568 fi
1569 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1570
1571 if test "x$enable_omx" = xyes; then
1572     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1573     enable_gallium_loader=$enable_shared_pipe_drivers
1574 fi
1575 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1576
1577 if test "x$enable_va" = xyes; then
1578     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1579     enable_gallium_loader=$enable_shared_pipe_drivers
1580 fi
1581 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1582
1583 dnl
1584 dnl Nine Direct3D9 configuration
1585 dnl
1586 if test "x$enable_nine" = xyes; then
1587     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1588         AC_MSG_ERROR([nine requires the gallium swrast driver])
1589     fi
1590     if test "x$with_gallium_drivers" == xswrast; then
1591         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1592     fi
1593     if test "x$enable_dri3" = xno; then
1594         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1595     fi
1596
1597     enable_gallium_loader=$enable_shared_pipe_drivers
1598 fi
1599 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1600
1601 dnl
1602 dnl OpenCL configuration
1603 dnl
1604
1605 AC_ARG_WITH([libclc-path],
1606    [AS_HELP_STRING([--with-libclc-path],
1607          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1608    [LIBCLC_PATH="$withval"],
1609    [LIBCLC_PATH=''])
1610
1611 if test -n "$LIBCLC_PATH"; then
1612    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1613                   Please review the updated build instructions for clover:
1614                   http://dri.freedesktop.org/wiki/GalliumCompute])
1615 fi
1616
1617
1618 AC_ARG_WITH([clang-libdir],
1619    [AS_HELP_STRING([--with-clang-libdir],
1620          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1621    [CLANG_LIBDIR="$withval"],
1622    [CLANG_LIBDIR=''])
1623
1624 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1625 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1626
1627 if test "x$enable_opencl" = xyes; then
1628     if test -z "$with_gallium_drivers"; then
1629         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1630     fi
1631
1632     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1633         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1634     fi
1635
1636     if test "x$have_libclc" = xno; then
1637         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1638                     Make sure the directory containing libclc.pc is specified in your
1639                     PKG_CONFIG_PATH environment variable.
1640                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1641     else
1642         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1643         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1644         AC_SUBST([LIBCLC_INCLUDEDIR])
1645         AC_SUBST([LIBCLC_LIBEXECDIR])
1646     fi
1647
1648     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1649     enable_gallium_loader=yes
1650
1651     if test "x$enable_opencl_icd" = xyes; then
1652         OPENCL_LIBNAME="MesaOpenCL"
1653     else
1654         OPENCL_LIBNAME="OpenCL"
1655     fi
1656
1657     if test "x$have_libelf" != xyes; then
1658        AC_MSG_ERROR([Clover requires libelf])
1659     fi
1660 fi
1661 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1662 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1663 AC_SUBST([OPENCL_LIBNAME])
1664
1665 dnl
1666 dnl Gallium configuration
1667 dnl
1668 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1669
1670 AC_SUBST([LLVM_BINDIR])
1671 AC_SUBST([LLVM_CFLAGS])
1672 AC_SUBST([LLVM_CPPFLAGS])
1673 AC_SUBST([LLVM_CXXFLAGS])
1674 AC_SUBST([LLVM_LIBDIR])
1675 AC_SUBST([LLVM_LIBS])
1676 AC_SUBST([LLVM_LDFLAGS])
1677 AC_SUBST([LLVM_INCLUDEDIR])
1678 AC_SUBST([LLVM_VERSION])
1679 AC_SUBST([CLANG_RESOURCE_DIR])
1680
1681 case "x$enable_opengl$enable_gles1$enable_gles2" in
1682 x*yes*)
1683     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1684     ;;
1685 esac
1686
1687 AC_SUBST([VG_LIB_DEPS])
1688 AC_SUBST([EGL_CLIENT_APIS])
1689
1690 dnl
1691 dnl EGL Platforms configuration
1692 dnl
1693 AC_ARG_WITH([egl-platforms],
1694     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1695         [comma delimited native platforms libEGL supports, e.g.
1696         "x11,drm" @<:@default=auto@:>@])],
1697     [with_egl_platforms="$withval"],
1698     [if test "x$enable_egl" = xyes; then
1699         with_egl_platforms="x11"
1700     else
1701         with_egl_platforms=""
1702     fi])
1703
1704 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1705     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1706 fi
1707
1708 # Do per-EGL platform setups and checks
1709 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1710 for plat in $egl_platforms; do
1711         case "$plat" in
1712         wayland)
1713                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1714
1715                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1716                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1717                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1718                 ;;
1719
1720         x11)
1721                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1722                 ;;
1723
1724         drm)
1725                 test "x$enable_gbm" = "xno" &&
1726                         AC_MSG_ERROR([EGL platform drm needs gbm])
1727                 test "x$have_libdrm" != xyes &&
1728                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1729                 ;;
1730
1731         android|fbdev|gdi|null)
1732                 ;;
1733
1734         *)
1735                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1736                 ;;
1737         esac
1738
1739         case "$plat$need_pci_id$have_pci_id" in
1740                 waylandyesno|drmyesno)
1741                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1742         esac
1743 done
1744
1745 # libEGL wants to default to the first platform specified in
1746 # ./configure.  parse that here.
1747 if test "x$egl_platforms" != "x"; then
1748     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1749     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1750 else
1751     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1752 fi
1753
1754 if echo "$egl_platforms" | grep -q 'x11'; then
1755     NEED_WINSYS_XLIB=yes
1756 fi
1757 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1758 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1759 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1760 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1761 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1762
1763 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1764
1765 AC_SUBST([EGL_NATIVE_PLATFORM])
1766 AC_SUBST([EGL_CFLAGS])
1767
1768 # If we don't have the X11 platform, set this define so we don't try to include
1769 # the X11 headers.
1770 if ! echo "$egl_platforms" | grep -q 'x11'; then
1771     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1772     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1773 fi
1774
1775 AC_ARG_WITH([max-width],
1776     [AS_HELP_STRING([--with-max-width=N],
1777                     [Maximum framebuffer width (4096)])],
1778     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1779      AS_IF([test "${withval}" -gt "4096"],
1780            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1781 )
1782 AC_ARG_WITH([max-height],
1783     [AS_HELP_STRING([--with-max-height=N],
1784                     [Maximum framebuffer height (4096)])],
1785     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1786      AS_IF([test "${withval}" -gt "4096"],
1787            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1788 )
1789
1790 dnl
1791 dnl Gallium LLVM
1792 dnl
1793 AC_ARG_ENABLE([gallium-llvm],
1794     [AS_HELP_STRING([--enable-gallium-llvm],
1795         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1796     [enable_gallium_llvm="$enableval"],
1797     [enable_gallium_llvm=auto])
1798
1799 AC_ARG_ENABLE([llvm-shared-libs],
1800     [AS_HELP_STRING([--enable-llvm-shared-libs],
1801         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1802     [enable_llvm_shared_libs="$enableval"],
1803     [enable_llvm_shared_libs=yes])
1804
1805 AC_ARG_WITH([llvm-prefix],
1806     [AS_HELP_STRING([--with-llvm-prefix],
1807         [Prefix for LLVM installations in non-standard locations])],
1808     [llvm_prefix="$withval"],
1809     [llvm_prefix=''])
1810
1811
1812 # Call this inside ` ` to get the return value.
1813 # $1 is the llvm-config command with arguments.
1814 strip_unwanted_llvm_flags() {
1815     # Use \> (marks the end of the word)
1816     echo `$1` | sed \
1817         -e 's/-DNDEBUG\>//g' \
1818         -e 's/-D_GNU_SOURCE\>//g' \
1819         -e 's/-pedantic\>//g' \
1820         -e 's/-Wcovered-switch-default\>//g' \
1821         -e 's/-O.\>//g' \
1822         -e 's/-g\>//g' \
1823         -e 's/-Wall\>//g' \
1824         -e 's/-Wcast-qual\>//g' \
1825         -e 's/-Woverloaded-virtual\>//g' \
1826         -e 's/-fcolor-diagnostics\>//g' \
1827         -e 's/-fdata-sections\>//g' \
1828         -e 's/-ffunction-sections\>//g' \
1829         -e 's/-fno-exceptions\>//g' \
1830         -e 's/-fomit-frame-pointer\>//g' \
1831         -e 's/-fvisibility-inlines-hidden\>//g' \
1832         -e 's/-fPIC\>//g' \
1833         -e 's/-fstack-protector-strong\>//g'
1834 }
1835
1836
1837 if test -z "$with_gallium_drivers"; then
1838     enable_gallium_llvm=no
1839 fi
1840 if test "x$enable_gallium_llvm" = xauto; then
1841     case "$host_cpu" in
1842     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1843     esac
1844 fi
1845 if test "x$enable_gallium_llvm" = xyes; then
1846     if test -n "$llvm_prefix"; then
1847         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1848     else
1849         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1850     fi
1851
1852     if test "x$LLVM_CONFIG" != xno; then
1853         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1854         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1855         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1856         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1857         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1858         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1859         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1860         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1861
1862         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1863             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1864         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1865             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1866
1867         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1868         if test -z "$LLVM_VERSION_PATCH"; then
1869             LLVM_VERSION_PATCH=0
1870         fi
1871
1872         if test -n "${LLVM_VERSION_MAJOR}"; then
1873             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1874         else
1875             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1876         fi
1877
1878         LLVM_REQUIRED_VERSION_MAJOR="3"
1879         LLVM_REQUIRED_VERSION_MINOR="3"
1880         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1881             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1882         fi
1883
1884         LLVM_COMPONENTS="engine bitwriter"
1885         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1886             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1887         fi
1888
1889         if test "x$enable_opencl" = xyes; then
1890             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1891             # LLVM 3.3 >= 177971 requires IRReader
1892             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1893                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1894             fi
1895             # LLVM 3.4 requires Option
1896             if $LLVM_CONFIG --components | grep -qw 'option'; then
1897                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1898             fi
1899             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1900             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1901                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1902             fi
1903             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1904                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1905             fi
1906         fi
1907         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1908         MESA_LLVM=1
1909
1910         dnl Check for Clang internal headers
1911         if test "x$enable_opencl" = xyes; then
1912             if test -z "$CLANG_LIBDIR"; then
1913                 CLANG_LIBDIR=${LLVM_LIBDIR}
1914             fi
1915             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1916             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1917                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1918         fi
1919     else
1920         MESA_LLVM=0
1921         LLVM_VERSION_INT=0
1922     fi
1923 else
1924     MESA_LLVM=0
1925     LLVM_VERSION_INT=0
1926
1927     if test "x$enable_opencl" = xyes; then
1928         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1929     fi
1930 fi
1931
1932 dnl Directory for XVMC libs
1933 AC_ARG_WITH([xvmc-libdir],
1934     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1935         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1936     [XVMC_LIB_INSTALL_DIR="$withval"],
1937     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1938 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1939
1940 dnl
1941 dnl Gallium Tests
1942 dnl
1943 if test "x$enable_gallium_tests" = xyes; then
1944     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1945     enable_gallium_loader=yes
1946 fi
1947 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1948
1949 dnl Directory for VDPAU libs
1950 AC_ARG_WITH([vdpau-libdir],
1951     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1952         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1953     [VDPAU_LIB_INSTALL_DIR="$withval"],
1954     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1955 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1956
1957 dnl Directory for OMX libs
1958
1959 AC_ARG_WITH([omx-libdir],
1960     [AS_HELP_STRING([--with-omx-libdir=DIR],
1961         [directory for the OMX libraries])],
1962     [OMX_LIB_INSTALL_DIR="$withval"],
1963     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1964 AC_SUBST([OMX_LIB_INSTALL_DIR])
1965
1966 dnl Directory for VA libs
1967
1968 AC_ARG_WITH([va-libdir],
1969     [AS_HELP_STRING([--with-va-libdir=DIR],
1970         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1971     [VA_LIB_INSTALL_DIR="$withval"],
1972     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1973 AC_SUBST([VA_LIB_INSTALL_DIR])
1974
1975 AC_ARG_WITH([d3d-libdir],
1976     [AS_HELP_STRING([--with-d3d-libdir=DIR],
1977         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
1978     [D3D_DRIVER_INSTALL_DIR="$withval"],
1979     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
1980 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
1981
1982 dnl
1983 dnl Gallium helper functions
1984 dnl
1985 gallium_require_drm() {
1986     if test "x$have_libdrm" != xyes; then
1987        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1988     fi
1989 }
1990
1991 gallium_require_llvm() {
1992     if test "x$MESA_LLVM" = x0; then
1993         case "$host" in *gnux32) return;; esac
1994         case "$host_cpu" in
1995         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1996         esac
1997     fi
1998 }
1999
2000 gallium_require_drm_loader() {
2001     if test "x$enable_gallium_loader" = xyes; then
2002         if test "x$need_pci_id$have_pci_id" = xyesno; then
2003             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2004         fi
2005         enable_gallium_drm_loader=yes
2006     fi
2007     if test "x$enable_va" = xyes && test "x$7" != x; then
2008          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2009     fi
2010 }
2011
2012 require_egl_drm() {
2013     case "$with_egl_platforms" in
2014         *drm*)
2015             ;;
2016          *)
2017             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2018             ;;
2019     esac
2020     if test "x$enable_gbm" != xyes; then
2021             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2022     fi
2023 }
2024
2025 radeon_llvm_check() {
2026     if test "x$enable_gallium_llvm" != "xyes"; then
2027         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2028     fi
2029     LLVM_REQUIRED_VERSION_MAJOR="3"
2030     LLVM_REQUIRED_VERSION_MINOR="4"
2031     LLVM_REQUIRED_VERSION_PATCH="2"
2032     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2033         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2034     fi
2035     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2036         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2037                       sources with the --enable-experimental-targets=R600
2038                       configure flag])
2039     fi
2040     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2041     NEED_RADEON_LLVM=yes
2042     if test "x$have_libelf" != xyes; then
2043        AC_MSG_ERROR([$1 requires libelf when using llvm])
2044     fi
2045 }
2046
2047 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2048 if test -n "$with_gallium_drivers"; then
2049     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2050     for driver in $gallium_drivers; do
2051         case "x$driver" in
2052         xsvga)
2053             HAVE_GALLIUM_SVGA=yes
2054             gallium_require_drm "svga"
2055             gallium_require_drm_loader
2056             ;;
2057         xi915)
2058             HAVE_GALLIUM_I915=yes
2059             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2060             gallium_require_drm "Gallium i915"
2061             gallium_require_drm_loader
2062             ;;
2063         xilo)
2064             HAVE_GALLIUM_ILO=yes
2065             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2066             gallium_require_drm "Gallium i965/ilo"
2067             gallium_require_drm_loader
2068             ;;
2069         xr300)
2070             HAVE_GALLIUM_R300=yes
2071             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2072             gallium_require_drm "Gallium R300"
2073             gallium_require_drm_loader
2074             gallium_require_llvm "Gallium R300"
2075             ;;
2076         xr600)
2077             HAVE_GALLIUM_R600=yes
2078             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2079             gallium_require_drm "Gallium R600"
2080             gallium_require_drm_loader
2081             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2082                 radeon_llvm_check "r600g"
2083                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2084             fi
2085             if test "x$enable_r600_llvm" = xyes; then
2086                 USE_R600_LLVM_COMPILER=yes;
2087             fi
2088             if test "x$enable_opencl" = xyes; then
2089                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2090             fi
2091             ;;
2092         xradeonsi)
2093             HAVE_GALLIUM_RADEONSI=yes
2094             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2095             gallium_require_drm "radeonsi"
2096             gallium_require_drm_loader
2097             radeon_llvm_check "radeonsi"
2098             require_egl_drm "radeonsi"
2099             ;;
2100         xnouveau)
2101             HAVE_GALLIUM_NOUVEAU=yes
2102             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2103             gallium_require_drm "nouveau"
2104             gallium_require_drm_loader
2105             ;;
2106         xfreedreno)
2107             HAVE_GALLIUM_FREEDRENO=yes
2108             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2109             gallium_require_drm "freedreno"
2110             gallium_require_drm_loader
2111             ;;
2112         xswrast)
2113             HAVE_GALLIUM_SOFTPIPE=yes
2114             if test "x$MESA_LLVM" = x1; then
2115                 HAVE_GALLIUM_LLVMPIPE=yes
2116             fi
2117             ;;
2118         xvc4)
2119             HAVE_GALLIUM_VC4=yes
2120             gallium_require_drm "vc4"
2121             gallium_require_drm_loader
2122
2123             case "$host_cpu" in
2124                 i?86 | x86_64 | amd64)
2125                 USE_VC4_SIMULATOR=yes
2126                 ;;
2127             esac
2128             ;;
2129         *)
2130             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2131             ;;
2132         esac
2133     done
2134 fi
2135
2136 dnl Set LLVM_LIBS - This is done after the driver configuration so
2137 dnl that drivers can add additional components to LLVM_COMPONENTS.
2138 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2139 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2140 dnl this was causing the same libraries to be appear multiple times
2141 dnl in LLVM_LIBS.
2142
2143 if test "x$MESA_LLVM" != x0; then
2144
2145     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2146
2147     if test "x$enable_llvm_shared_libs" = xyes; then
2148         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2149         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2150         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2151
2152         if test "x$llvm_have_one_so" = xyes; then
2153             dnl LLVM was built using auto*, so there is only one shared object.
2154             LLVM_LIBS="-l$LLVM_SO_NAME"
2155         else
2156             dnl If LLVM was built with CMake, there will be one shared object per
2157             dnl component.
2158             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2159                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2160         Please make sure you have built llvm with the --enable-shared option
2161         and that your llvm libraries are installed in $LLVM_LIBDIR
2162         If you have installed your llvm libraries to a different directory you
2163         can use the --with-llvm-prefix= configure flag to specify this directory.
2164         NOTE: Mesa is attempting to use llvm shared libraries by default.
2165         If you do not want to build with llvm shared libraries and instead want to
2166         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2167         invocation and rebuild.])])
2168
2169            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2170            dnl install uses a shared object for each component and we have
2171            dnl already added all of these objects to LLVM_LIBS.
2172         fi
2173     else
2174         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2175         dnl We need to link to llvm system libs when using static libs
2176         dnl However, only llvm 3.5+ provides --system-libs
2177         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2178             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2179         fi
2180     fi
2181 fi
2182
2183 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2184 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2185 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2186 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2187 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2188 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2189 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2190                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2191 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2192 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2193 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2194 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2195 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2196
2197 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2198
2199 # NOTE: anything using xcb or other client side libs ends up in separate
2200 #       _CLIENT variables.  The pipe loader is built in two variants,
2201 #       one that is standalone and does not link any x client libs (for
2202 #       use by XA tracker in particular, but could be used in any case
2203 #       where communication with xserver is not desired).
2204 if test "x$enable_gallium_loader" = xyes; then
2205     if test "x$NEED_WINSYS_XLIB" = xyes; then
2206         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2207     fi
2208
2209     if test "x$enable_dri" = xyes; then
2210         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2211     fi
2212
2213     if test "x$enable_gallium_drm_loader" = xyes; then
2214         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2215         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2216                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2217         if test "x$pipe_loader_have_xcb" = xyes; then
2218             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2219             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2220         fi
2221     fi
2222
2223     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2224     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2225
2226     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2227     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2228     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2229     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2230 fi
2231
2232 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2233 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2234 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2235 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2236 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2237 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2238
2239 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2240                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2241                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2242 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2243 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2244 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2245 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2246 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2247 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2248 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2249 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2250 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2251     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2252 fi
2253
2254 AC_SUBST([ELF_LIB])
2255
2256 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2257 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2258 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2259 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2260 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2261
2262 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2263 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2264 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2265
2266 AC_SUBST([NINE_MAJOR], 1)
2267 AC_SUBST([NINE_MINOR], 0)
2268 AC_SUBST([NINE_TINY], 0)
2269 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2270
2271 AC_SUBST([VDPAU_MAJOR], 1)
2272 AC_SUBST([VDPAU_MINOR], 0)
2273
2274 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2275 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2276 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2277 AC_SUBST([VA_MINOR], $VA_MINOR)
2278
2279 AC_SUBST([XVMC_MAJOR], 1)
2280 AC_SUBST([XVMC_MINOR], 0)
2281
2282 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2283 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2284 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2285 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2286
2287 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2288 AC_SUBST([XA_MINOR], $XA_MINOR)
2289 AC_SUBST([XA_TINY], $XA_TINY)
2290 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2291
2292 dnl Restore LDFLAGS and CPPFLAGS
2293 LDFLAGS="$_SAVE_LDFLAGS"
2294 CPPFLAGS="$_SAVE_CPPFLAGS"
2295
2296 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2297 if test "x$acv_mesa_CLANG" = xyes; then
2298     CFLAGS="$CFLAGS -Qunused-arguments"
2299     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2300 fi
2301
2302 dnl Add user CFLAGS and CXXFLAGS
2303 CFLAGS="$CFLAGS $USER_CFLAGS"
2304 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2305
2306 dnl Substitute the config
2307 AC_CONFIG_FILES([Makefile
2308                 src/Makefile
2309                 src/egl/drivers/dri2/Makefile
2310                 src/egl/main/Makefile
2311                 src/egl/main/egl.pc
2312                 src/egl/wayland/wayland-drm/Makefile
2313                 src/egl/wayland/wayland-egl/Makefile
2314                 src/egl/wayland/wayland-egl/wayland-egl.pc
2315                 src/gallium/Makefile
2316                 src/gallium/auxiliary/Makefile
2317                 src/gallium/auxiliary/pipe-loader/Makefile
2318                 src/gallium/drivers/freedreno/Makefile
2319                 src/gallium/drivers/galahad/Makefile
2320                 src/gallium/drivers/i915/Makefile
2321                 src/gallium/drivers/identity/Makefile
2322                 src/gallium/drivers/ilo/Makefile
2323                 src/gallium/drivers/llvmpipe/Makefile
2324                 src/gallium/drivers/noop/Makefile
2325                 src/gallium/drivers/nouveau/Makefile
2326                 src/gallium/drivers/r300/Makefile
2327                 src/gallium/drivers/r600/Makefile
2328                 src/gallium/drivers/radeon/Makefile
2329                 src/gallium/drivers/radeonsi/Makefile
2330                 src/gallium/drivers/rbug/Makefile
2331                 src/gallium/drivers/softpipe/Makefile
2332                 src/gallium/drivers/svga/Makefile
2333                 src/gallium/drivers/trace/Makefile
2334                 src/gallium/drivers/vc4/Makefile
2335                 src/gallium/drivers/vc4/kernel/Makefile
2336                 src/gallium/state_trackers/clover/Makefile
2337                 src/gallium/state_trackers/dri/Makefile
2338                 src/gallium/state_trackers/glx/xlib/Makefile
2339                 src/gallium/state_trackers/nine/Makefile
2340                 src/gallium/state_trackers/omx/Makefile
2341                 src/gallium/state_trackers/osmesa/Makefile
2342                 src/gallium/state_trackers/va/Makefile
2343                 src/gallium/state_trackers/vdpau/Makefile
2344                 src/gallium/state_trackers/vega/Makefile
2345                 src/gallium/state_trackers/xa/Makefile
2346                 src/gallium/state_trackers/xvmc/Makefile
2347                 src/gallium/targets/d3dadapter9/Makefile
2348                 src/gallium/targets/d3dadapter9/d3d.pc
2349                 src/gallium/targets/dri/Makefile
2350                 src/gallium/targets/libgl-xlib/Makefile
2351                 src/gallium/targets/omx/Makefile
2352                 src/gallium/targets/opencl/Makefile
2353                 src/gallium/targets/osmesa/Makefile
2354                 src/gallium/targets/osmesa/osmesa.pc
2355                 src/gallium/targets/pipe-loader/Makefile
2356                 src/gallium/targets/va/Makefile
2357                 src/gallium/targets/vdpau/Makefile
2358                 src/gallium/targets/xa/Makefile
2359                 src/gallium/targets/xa/xatracker.pc
2360                 src/gallium/targets/xvmc/Makefile
2361                 src/gallium/tests/trivial/Makefile
2362                 src/gallium/tests/unit/Makefile
2363                 src/gallium/winsys/freedreno/drm/Makefile
2364                 src/gallium/winsys/i915/drm/Makefile
2365                 src/gallium/winsys/intel/drm/Makefile
2366                 src/gallium/winsys/nouveau/drm/Makefile
2367                 src/gallium/winsys/radeon/drm/Makefile
2368                 src/gallium/winsys/svga/drm/Makefile
2369                 src/gallium/winsys/sw/dri/Makefile
2370                 src/gallium/winsys/sw/fbdev/Makefile
2371                 src/gallium/winsys/sw/kms-dri/Makefile
2372                 src/gallium/winsys/sw/null/Makefile
2373                 src/gallium/winsys/sw/wayland/Makefile
2374                 src/gallium/winsys/sw/wrapper/Makefile
2375                 src/gallium/winsys/sw/xlib/Makefile
2376                 src/gallium/winsys/vc4/drm/Makefile
2377                 src/gbm/Makefile
2378                 src/gbm/main/gbm.pc
2379                 src/glsl/Makefile
2380                 src/glx/Makefile
2381                 src/glx/apple/Makefile
2382                 src/glx/tests/Makefile
2383                 src/gtest/Makefile
2384                 src/loader/Makefile
2385                 src/mapi/Makefile
2386                 src/mapi/es1api/glesv1_cm.pc
2387                 src/mapi/es2api/glesv2.pc
2388                 src/mapi/glapi/gen/Makefile
2389                 src/mapi/vgapi/Makefile
2390                 src/mapi/vgapi/vg.pc
2391                 src/mesa/Makefile
2392                 src/mesa/gl.pc
2393                 src/mesa/drivers/dri/dri.pc
2394                 src/mesa/drivers/dri/common/Makefile
2395                 src/mesa/drivers/dri/common/xmlpool/Makefile
2396                 src/mesa/drivers/dri/i915/Makefile
2397                 src/mesa/drivers/dri/i965/Makefile
2398                 src/mesa/drivers/dri/Makefile
2399                 src/mesa/drivers/dri/nouveau/Makefile
2400                 src/mesa/drivers/dri/r200/Makefile
2401                 src/mesa/drivers/dri/radeon/Makefile
2402                 src/mesa/drivers/dri/swrast/Makefile
2403                 src/mesa/drivers/osmesa/Makefile
2404                 src/mesa/drivers/osmesa/osmesa.pc
2405                 src/mesa/drivers/x11/Makefile
2406                 src/mesa/main/tests/Makefile
2407                 src/util/Makefile
2408                 src/util/tests/hash_table/Makefile])
2409
2410 AC_OUTPUT
2411
2412 dnl
2413 dnl Output some configuration info for the user
2414 dnl
2415 echo ""
2416 echo "        prefix:          $prefix"
2417 echo "        exec_prefix:     $exec_prefix"
2418 echo "        libdir:          $libdir"
2419 echo "        includedir:      $includedir"
2420
2421 dnl API info
2422 echo ""
2423 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2424 echo "        OpenVG:          $enable_openvg"
2425
2426 dnl Driver info
2427 echo ""
2428 case "x$enable_osmesa$enable_gallium_osmesa" in
2429 xnoyes)
2430         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2431         ;;
2432 xyesno)
2433         echo "        OSMesa:          lib$OSMESA_LIB"
2434         ;;
2435 xnono)
2436         echo "        OSMesa:          no"
2437         ;;
2438 esac
2439
2440 echo ""
2441 if test "x$enable_dri" != xno; then
2442         echo "        DRI platform:    $dri_platform"
2443         if test -z "$DRI_DIRS"; then
2444             echo "        DRI drivers:     no"
2445         else
2446             echo "        DRI drivers:     $DRI_DIRS"
2447         fi
2448         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2449 fi
2450
2451 case "x$enable_glx$enable_xlib_glx" in
2452 xyesyes)
2453     echo "        GLX:             Xlib-based"
2454     ;;
2455 xyesno)
2456     echo "        GLX:             DRI-based"
2457     ;;
2458 *)
2459     echo "        GLX:             $enable_glx"
2460     ;;
2461 esac
2462
2463 dnl EGL
2464 echo ""
2465 echo "        EGL:             $enable_egl"
2466 if test "$enable_egl" = yes; then
2467     echo "        EGL platforms:   $egl_platforms"
2468
2469     egl_drivers=""
2470     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2471         egl_drivers="$egl_drivers builtin:egl_dri2"
2472     fi
2473
2474     echo "        EGL drivers:    $egl_drivers"
2475 fi
2476
2477 echo ""
2478 if test "x$MESA_LLVM" = x1; then
2479     echo "        llvm:            yes"
2480     echo "        llvm-config:     $LLVM_CONFIG"
2481     echo "        llvm-version:    $LLVM_VERSION"
2482 else
2483     echo "        llvm:            no"
2484 fi
2485
2486 echo ""
2487 if test -n "$with_gallium_drivers"; then
2488     echo "        Gallium:         yes"
2489 else
2490     echo "        Gallium:         no"
2491 fi
2492
2493
2494 dnl Libraries
2495 echo ""
2496 echo "        Shared libs:     $enable_shared"
2497 echo "        Static libs:     $enable_static"
2498 echo "        Shared-glapi:    $enable_shared_glapi"
2499
2500 dnl Compiler options
2501 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2502 cflags=`echo $CFLAGS | \
2503     $SED 's/^ *//;s/  */ /;s/ *$//'`
2504 cxxflags=`echo $CXXFLAGS | \
2505     $SED 's/^ *//;s/  */ /;s/ *$//'`
2506 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2507 echo ""
2508 echo "        CFLAGS:          $cflags"
2509 echo "        CXXFLAGS:        $cxxflags"
2510 echo "        Macros:          $defines"
2511 echo ""
2512 if test "x$MESA_LLVM" = x1; then
2513     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2514     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2515     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2516     echo ""
2517 fi
2518 echo "        PYTHON2:         $PYTHON2"
2519
2520 echo ""
2521 echo "        Run '${MAKE-make}' to build Mesa"
2522 echo ""