configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.3
  22 DRI2PROTO_REQUIRED=1.99.3
  23
  24 dnl Check for progs
  25 AC_PROG_CPP
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_CHECK_PROGS([MAKE], [gmake make])
  29 AC_PATH_PROG([MKDEP], [makedepend])
  30 AC_PATH_PROG([SED], [sed])
  31
  32 dnl We need a POSIX shell for parts of the build. Assume we have one
  33 dnl in most cases.
  34 case "$host_os" in
  35 solaris*)
  36     # Solaris /bin/sh is too old/non-POSIX compliant
  37     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  38     SHELL="$POSIX_SHELL"
  39     ;;
  40 esac
  41
  42 MKDEP_OPTIONS=-fdepend
  43 dnl Ask gcc where it's keeping its secret headers
  44 if test "x$GCC" = xyes; then
  45     for dir in include include-fixed; do
  46         GCC_INCLUDES=`$CC -print-file-name=$dir`
  47         if test "x$GCC_INCLUDES" != x && \
  48            test "$GCC_INCLUDES" != "$dir" && \
  49            test -d "$GCC_INCLUDES"; then
  50             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  51         fi
  52     done
  53 fi
  54 AC_SUBST([MKDEP_OPTIONS])
  55
  56 dnl Make sure the pkg-config macros are defined
  57 m4_ifndef([PKG_PROG_PKG_CONFIG],
  58     [m4_fatal([Could not locate the pkg-config autoconf macros.
  59   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  60   are in a different location, try setting the environment variable
  61   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  62 PKG_PROG_PKG_CONFIG()
  63
  64 dnl LIB_DIR - library basename
  65 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  66 AC_SUBST([LIB_DIR])
  67
  68 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  69 _SAVE_LDFLAGS="$LDFLAGS"
  70 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  71 AC_SUBST([EXTRA_LIB_PATH])
  72
  73 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  74 _SAVE_CPPFLAGS="$CPPFLAGS"
  75 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  76 AC_SUBST([X11_INCLUDES])
  77
  78 dnl Compiler macros
  79 DEFINES=""
  80 AC_SUBST([DEFINES])
  81 case "$host_os" in
  82 linux*|*-gnu*|gnu*)
  83     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  84     ;;
  85 solaris*)
  86     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  87     ;;
  88 esac
  89
  90 dnl Add flags for gcc and g++
  91 if test "x$GCC" = xyes; then
  92     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
  93
  94     # Work around aliasing bugs - developers should comment this out
  95     CFLAGS="$CFLAGS -fno-strict-aliasing"
  96 fi
  97 if test "x$GXX" = xyes; then
  98     CXXFLAGS="$CXXFLAGS -Wall"
  99
 100     # Work around aliasing bugs - developers should comment this out
 101     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 102 fi
 103
 104 dnl These should be unnecessary, but let the user set them if they want
 105 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 106     Default is to use CFLAGS.])
 107 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 108     compiler. Default is to use CFLAGS.])
 109 AC_SUBST([OPT_FLAGS])
 110 AC_SUBST([ARCH_FLAGS])
 111
 112 dnl
 113 dnl Hacks to enable 32 or 64 bit build
 114 dnl
 115 AC_ARG_ENABLE([32-bit],
 116     [AS_HELP_STRING([--enable-32-bit],
 117         [build 32-bit libraries @<:@default=auto@:>@])],
 118     [enable_32bit="$enableval"],
 119     [enable_32bit=auto]
 120 )
 121 if test "x$enable_32bit" = xyes; then
 122     if test "x$GCC" = xyes; then
 123         CFLAGS="$CFLAGS -m32"
 124         ARCH_FLAGS="$ARCH_FLAGS -m32"
 125     fi
 126     if test "x$GXX" = xyes; then
 127         CXXFLAGS="$CXXFLAGS -m32"
 128     fi
 129 fi
 130 AC_ARG_ENABLE([64-bit],
 131     [AS_HELP_STRING([--enable-64-bit],
 132         [build 64-bit libraries @<:@default=auto@:>@])],
 133     [enable_64bit="$enableval"],
 134     [enable_64bit=auto]
 135 )
 136 if test "x$enable_64bit" = xyes; then
 137     if test "x$GCC" = xyes; then
 138         CFLAGS="$CFLAGS -m64"
 139     fi
 140     if test "x$GXX" = xyes; then
 141         CXXFLAGS="$CXXFLAGS -m64"
 142     fi
 143 fi
 144
 145 dnl
 146 dnl shared/static libraries, mimic libtool options
 147 dnl
 148 AC_ARG_ENABLE([static],
 149     [AS_HELP_STRING([--enable-static],
 150         [build static libraries @<:@default=disabled@:>@])],
 151     [enable_static="$enableval"],
 152     [enable_static=no]
 153 )
 154 case "x$enable_static" in
 155 xyes|xno ) ;;
 156 x ) enable_static=no ;;
 157 * )
 158     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 159     ;;
 160 esac
 161 AC_ARG_ENABLE([shared],
 162     [AS_HELP_STRING([--disable-shared],
 163         [build shared libraries @<:@default=enabled@:>@])],
 164     [enable_shared="$enableval"],
 165     [enable_shared=yes]
 166 )
 167 case "x$enable_shared" in
 168 xyes|xno ) ;;
 169 x ) enable_shared=yes ;;
 170 * )
 171     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 172     ;;
 173 esac
 174
 175 dnl Can't have static and shared libraries, default to static if user
 176 dnl explicitly requested. If both disabled, set to static since shared
 177 dnl was explicitly requirested.
 178 case "x$enable_static$enable_shared" in
 179 xyesyes )
 180     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 181     enable_shared=no
 182     ;;
 183 xnono )
 184     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 185     enable_static=yes
 186     ;;
 187 esac
 188
 189 dnl
 190 dnl mklib options
 191 dnl
 192 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 193 if test "$enable_static" = yes; then
 194     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 195 fi
 196 AC_SUBST([MKLIB_OPTIONS])
 197
 198 dnl
 199 dnl other compiler options
 200 dnl
 201 AC_ARG_ENABLE([debug],
 202     [AS_HELP_STRING([--enable-debug],
 203         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 204     [enable_debug="$enableval"],
 205     [enable_debug=no]
 206 )
 207 if test "x$enable_debug" = xyes; then
 208     DEFINES="$DEFINES -DDEBUG"
 209     if test "x$GCC" = xyes; then
 210         CFLAGS="$CFLAGS -g"
 211     fi
 212     if test "x$GXX" = xyes; then
 213         CXXFLAGS="$CXXFLAGS -g"
 214     fi
 215 fi
 216
 217 dnl
 218 dnl library names
 219 dnl
 220 if test "$enable_static" = yes; then
 221     LIB_EXTENSION='a'
 222 else
 223     case "$host_os" in
 224     darwin* )
 225         LIB_EXTENSION='dylib' ;;
 226     cygwin* )
 227         LIB_EXTENSION='dll' ;;
 228     * )
 229         LIB_EXTENSION='so' ;;
 230     esac
 231 fi
 232
 233 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 234 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 235 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 236 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 237 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 238
 239 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 240 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 241 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 242 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 243 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 244
 245 AC_SUBST([GL_LIB_NAME])
 246 AC_SUBST([GLU_LIB_NAME])
 247 AC_SUBST([GLUT_LIB_NAME])
 248 AC_SUBST([GLW_LIB_NAME])
 249 AC_SUBST([OSMESA_LIB_NAME])
 250
 251 AC_SUBST([GL_LIB_GLOB])
 252 AC_SUBST([GLU_LIB_GLOB])
 253 AC_SUBST([GLUT_LIB_GLOB])
 254 AC_SUBST([GLW_LIB_GLOB])
 255 AC_SUBST([OSMESA_LIB_GLOB])
 256
 257 dnl
 258 dnl Arch/platform-specific settings
 259 dnl
 260 AC_ARG_ENABLE([asm],
 261     [AS_HELP_STRING([--disable-asm],
 262         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 263     [enable_asm="$enableval"],
 264     [enable_asm=yes]
 265 )
 266 asm_arch=""
 267 ASM_FLAGS=""
 268 MESA_ASM_SOURCES=""
 269 GLAPI_ASM_SOURCES=""
 270 AC_MSG_CHECKING([whether to enable assembly])
 271 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 272 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 273 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 274     case "$host_cpu" in
 275     i?86 | x86_64)
 276         enable_asm=no
 277         AC_MSG_RESULT([no, cross compiling])
 278         ;;
 279     esac
 280 fi
 281 # check for supported arches
 282 if test "x$enable_asm" = xyes; then
 283     case "$host_cpu" in
 284     i?86)
 285         case "$host_os" in
 286         linux* | *freebsd* | dragonfly*)
 287             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 288             ;;
 289         esac
 290         ;;
 291     x86_64)
 292         case "$host_os" in
 293         linux* | *freebsd* | dragonfly*)
 294             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 295             ;;
 296         esac
 297         ;;
 298     powerpc)
 299         case "$host_os" in
 300         linux*)
 301             asm_arch=ppc
 302             ;;
 303         esac
 304         ;;
 305     sparc*)
 306         case "$host_os" in
 307         linux*)
 308             asm_arch=sparc
 309             ;;
 310         esac
 311         ;;
 312     esac
 313
 314     case "$asm_arch" in
 315     x86)
 316         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 317         MESA_ASM_SOURCES='$(X86_SOURCES)'
 318         GLAPI_ASM_SOURCES='$(X86_API)'
 319         AC_MSG_RESULT([yes, x86])
 320         ;;
 321     x86_64)
 322         ASM_FLAGS="-DUSE_X86_64_ASM"
 323         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 324         GLAPI_ASM_SOURCES='$(X86-64_API)'
 325         AC_MSG_RESULT([yes, x86_64])
 326         ;;
 327     ppc)
 328         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 329         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 330         AC_MSG_RESULT([yes, ppc])
 331         ;;
 332     sparc)
 333         ASM_FLAGS="-DUSE_SPARC_ASM"
 334         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 335         GLAPI_ASM_SOURCES='$(SPARC_API)'
 336         AC_MSG_RESULT([yes, sparc])
 337         ;;
 338     *)
 339         AC_MSG_RESULT([no, platform not supported])
 340         ;;
 341     esac
 342 fi
 343 AC_SUBST([ASM_FLAGS])
 344 AC_SUBST([MESA_ASM_SOURCES])
 345 AC_SUBST([GLAPI_ASM_SOURCES])
 346
 347 dnl PIC code macro
 348 MESA_PIC_FLAGS
 349
 350 dnl Check to see if dlopen is in default libraries (like Solaris, which
 351 dnl has it in libc), or if libdl is needed to get it.
 352 AC_CHECK_FUNC([dlopen], [],
 353     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 354
 355 dnl See if posix_memalign is available
 356 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 357
 358 dnl SELinux awareness.
 359 AC_ARG_ENABLE([selinux],
 360     [AS_HELP_STRING([--enable-selinux],
 361         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 362     [MESA_SELINUX="$enableval"],
 363     [MESA_SELINUX=no])
 364 if test "x$enable_selinux" = "xyes"; then
 365     AC_CHECK_HEADER([selinux/selinux.h],[],
 366                     [AC_MSG_ERROR([SELinux headers not found])])
 367     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 368                  [AC_MSG_ERROR([SELinux library not found])])
 369     SELINUX_LIBS="-lselinux"
 370     DEFINES="$DEFINES -DMESA_SELINUX"
 371 fi
 372
 373 dnl
 374 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 375 dnl More later: directfb, fbdev, ...
 376 dnl
 377 default_driver="xlib"
 378
 379 case "$host_os" in
 380 linux*)
 381     case "$host_cpu" in
 382     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 383     esac
 384     ;;
 385 *freebsd* | dragonfly*)
 386     case "$host_cpu" in
 387     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 388     esac
 389     ;;
 390 esac
 391
 392 AC_ARG_WITH([driver],
 393     [AS_HELP_STRING([--with-driver=DRIVER],
 394         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 395     [mesa_driver="$withval"],
 396     [mesa_driver="$default_driver"])
 397 dnl Check for valid option
 398 case "x$mesa_driver" in
 399 xxlib|xdri|xosmesa)
 400     ;;
 401 *)
 402     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 403     ;;
 404 esac
 405
 406 dnl
 407 dnl Driver specific build directories
 408 dnl
 409 SRC_DIRS="mesa glew"
 410 GLU_DIRS="sgi"
 411 WINDOW_SYSTEM=""
 412 GALLIUM_DIRS="auxiliary drivers state_trackers"
 413 GALLIUM_WINSYS_DIRS=""
 414 GALLIUM_WINSYS_DRM_DIRS=""
 415 GALLIUM_AUXILIARY_DIRS="draw translate cso_cache pipebuffer tgsi sct rtasm util indices"
 416 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 417 GALLIUM_STATE_TRACKERS_DIRS=""
 418
 419 case "$mesa_driver" in
 420 xlib)
 421     DRIVER_DIRS="x11"
 422     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 423     ;;
 424 dri)
 425     SRC_DIRS="glx/x11 $SRC_DIRS"
 426     DRIVER_DIRS="dri"
 427     WINDOW_SYSTEM="dri"
 428     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 429     ;;
 430 osmesa)
 431     DRIVER_DIRS="osmesa"
 432     ;;
 433 esac
 434 AC_SUBST([SRC_DIRS])
 435 AC_SUBST([GLU_DIRS])
 436 AC_SUBST([DRIVER_DIRS])
 437 AC_SUBST([WINDOW_SYSTEM])
 438 AC_SUBST([GALLIUM_DIRS])
 439 AC_SUBST([GALLIUM_WINSYS_DIRS])
 440 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 441 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 442 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 443 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 444
 445 dnl
 446 dnl User supplied program configuration
 447 dnl
 448 if test -d "$srcdir/progs/demos"; then
 449     default_demos=yes
 450 else
 451     default_demos=no
 452 fi
 453 AC_ARG_WITH([demos],
 454     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 455         [optional comma delimited demo directories to build
 456         @<:@default=auto if source available@:>@])],
 457     [with_demos="$withval"],
 458     [with_demos="$default_demos"])
 459 if test "x$with_demos" = x; then
 460     with_demos=no
 461 fi
 462
 463 dnl If $with_demos is yes, directories will be added as libs available
 464 PROGRAM_DIRS=""
 465 case "$with_demos" in
 466 no) ;;
 467 yes)
 468     # If the driver isn't osmesa, we have libGL and can build xdemos
 469     if test "$mesa_driver" != osmesa; then
 470         PROGRAM_DIRS="xdemos"
 471     fi
 472     ;;
 473 *)
 474     # verify the requested demos directories exist
 475     demos=`IFS=,; echo $with_demos`
 476     for demo in $demos; do
 477         test -d "$srcdir/progs/$demo" || \
 478             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 479     done
 480     PROGRAM_DIRS="$demos"
 481     ;;
 482 esac
 483
 484 dnl
 485 dnl Find out if X is available. The variable have_x is set if libX11 is
 486 dnl found to mimic AC_PATH_XTRA.
 487 dnl
 488 if test -n "$PKG_CONFIG"; then
 489     AC_MSG_CHECKING([pkg-config files for X11 are available])
 490     PKG_CHECK_EXISTS([x11],[
 491         x11_pkgconfig=yes
 492         have_x=yes
 493         ],[
 494         x11_pkgconfig=no
 495     ])
 496     AC_MSG_RESULT([$x11_pkgconfig])
 497 else
 498     x11_pkgconfig=no
 499 fi
 500 dnl Use the autoconf macro if no pkg-config files
 501 if test "$x11_pkgconfig" = no; then
 502     AC_PATH_XTRA
 503 fi
 504
 505 dnl Try to tell the user that the --x-* options are only used when
 506 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 507 m4_divert_once([HELP_BEGIN],
 508 [These options are only used when the X libraries cannot be found by the
 509 pkg-config utility.])
 510
 511 dnl We need X for xlib and dri, so bomb now if it's not found
 512 case "$mesa_driver" in
 513 xlib|dri)
 514     if test "$no_x" = yes; then
 515         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 516     fi
 517     ;;
 518 esac
 519
 520 dnl XCB - this is only used for GLX right now
 521 AC_ARG_ENABLE([xcb],
 522     [AS_HELP_STRING([--enable-xcb],
 523         [use XCB for GLX @<:@default=disabled@:>@])],
 524     [enable_xcb="$enableval"],
 525     [enable_xcb=no])
 526 if test "x$enable_xcb" = xyes; then
 527     DEFINES="$DEFINES -DUSE_XCB"
 528 else
 529     enable_xcb=no
 530 fi
 531
 532 dnl
 533 dnl libGL configuration per driver
 534 dnl
 535 case "$mesa_driver" in
 536 xlib)
 537     if test "$x11_pkgconfig" = yes; then
 538         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 539         GL_PC_REQ_PRIV="x11 xext"
 540         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 541         GL_LIB_DEPS="$XLIBGL_LIBS"
 542     else
 543         # should check these...
 544         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 545         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 546         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 547         GL_PC_CFLAGS="$X11_INCLUDES"
 548     fi
 549     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 550     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 551
 552     # if static, move the external libraries to the programs
 553     # and empty the libraries for libGL
 554     if test "$enable_static" = yes; then
 555         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 556         GL_LIB_DEPS=""
 557     fi
 558     ;;
 559 dri)
 560     # DRI must be shared, I think
 561     if test "$enable_static" = yes; then
 562         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 563     fi
 564
 565     # Check for libdrm
 566     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 567     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 568     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 569     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 570
 571     # find the DRI deps for libGL
 572     if test "$x11_pkgconfig" = yes; then
 573         # add xcb modules if necessary
 574         dri_modules="x11 xext xxf86vm xdamage xfixes"
 575         if test "$enable_xcb" = yes; then
 576             dri_modules="$dri_modules x11-xcb xcb-glx"
 577         fi
 578
 579         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 580         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 581         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 582         GL_LIB_DEPS="$DRIGL_LIBS"
 583     else
 584         # should check these...
 585         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 586         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 587         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 588         GL_PC_CFLAGS="$X11_INCLUDES"
 589
 590         # XCB can only be used from pkg-config
 591         if test "$enable_xcb" = yes; then
 592             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 593             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 594             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 595             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 596         fi
 597     fi
 598
 599     # need DRM libs, -lpthread, etc.
 600     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 601     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 602     ;;
 603 osmesa)
 604     # No libGL for osmesa
 605     GL_LIB_DEPS=""
 606     ;;
 607 esac
 608 AC_SUBST([GL_LIB_DEPS])
 609 AC_SUBST([GL_PC_REQ_PRIV])
 610 AC_SUBST([GL_PC_LIB_PRIV])
 611 AC_SUBST([GL_PC_CFLAGS])
 612 AC_SUBST([DRI_PC_REQ_PRIV])
 613
 614 dnl
 615 dnl More X11 setup
 616 dnl
 617 if test "$mesa_driver" = xlib; then
 618     DEFINES="$DEFINES -DUSE_XSHM"
 619 fi
 620
 621 dnl
 622 dnl More DRI setup
 623 dnl
 624 AC_ARG_ENABLE([glx-tls],
 625     [AS_HELP_STRING([--enable-glx-tls],
 626         [enable TLS support in GLX @<:@default=disabled@:>@])],
 627     [GLX_USE_TLS="$enableval"],
 628     [GLX_USE_TLS=no])
 629 dnl Directory for DRI drivers
 630 AC_ARG_WITH([dri-driverdir],
 631     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 632         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 633     [DRI_DRIVER_INSTALL_DIR="$withval"],
 634     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 635 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 636 dnl Direct rendering or just indirect rendering
 637 AC_ARG_ENABLE([driglx-direct],
 638     [AS_HELP_STRING([--disable-driglx-direct],
 639         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 640     [driglx_direct="$enableval"],
 641     [driglx_direct="yes"])
 642 dnl Which drivers to build - default is chosen by platform
 643 AC_ARG_WITH([dri-drivers],
 644     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 645         [comma delimited DRI drivers list, e.g.
 646         "swrast,i965,radeon" @<:@default=auto@:>@])],
 647     [with_dri_drivers="$withval"],
 648     [with_dri_drivers=yes])
 649 if test "x$with_dri_drivers" = x; then
 650     with_dri_drivers=no
 651 fi
 652
 653 dnl If $with_dri_drivers is yes, directories will be added through
 654 dnl platform checks
 655 DRI_DIRS=""
 656 case "$with_dri_drivers" in
 657 no) ;;
 658 yes)
 659     DRI_DIRS="yes"
 660     ;;
 661 *)
 662     # verify the requested driver directories exist
 663     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 664     for driver in $dri_drivers; do
 665         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 666             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 667     done
 668     DRI_DIRS="$dri_drivers"
 669     ;;
 670 esac
 671
 672 dnl Just default to no EGL for now
 673 USING_EGL=0
 674 AC_SUBST([USING_EGL])
 675
 676 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 677 if test "$mesa_driver" = dri; then
 678     # Use TLS in GLX?
 679     if test "x$GLX_USE_TLS" = xyes; then
 680         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 681     fi
 682
 683     if test "x$USING_EGL" = x1; then
 684         PROGRAM_DIRS="egl"
 685     fi
 686
 687     # Platform specific settings and drivers to build
 688     case "$host_os" in
 689     linux*)
 690         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 691         if test "x$driglx_direct" = xyes; then
 692             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 693         fi
 694         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 695
 696         case "$host_cpu" in
 697         x86_64)
 698             # ffb, gamma, and sis are missing because they have not be
 699             # converted to use the new interface.  i810 are missing
 700             # because there is no x86-64 system where they could *ever*
 701             # be used.
 702             if test "x$DRI_DIRS" = "xyes"; then
 703                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 704                     savage tdfx unichrome swrast"
 705             fi
 706             ;;
 707         powerpc*)
 708             # Build only the drivers for cards that exist on PowerPC.
 709             # At some point MGA will be added, but not yet.
 710             if test "x$DRI_DIRS" = "xyes"; then
 711                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 712             fi
 713             ;;
 714         sparc*)
 715             # Build only the drivers for cards that exist on sparc`
 716             if test "x$DRI_DIRS" = "xyes"; then
 717                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 718             fi
 719             ;;
 720         esac
 721         ;;
 722     freebsd* | dragonfly*)
 723         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 724         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 725         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 726         if test "x$driglx_direct" = xyes; then
 727             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 728         fi
 729         if test "x$GXX" = xyes; then
 730             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 731         fi
 732
 733         # ffb and gamma are missing because they have not been converted
 734         # to use the new interface.
 735         if test "x$DRI_DIRS" = "xyes"; then
 736             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 737                 unichrome savage sis swrast"
 738         fi
 739         ;;
 740     gnu*)
 741         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 742         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 743         ;;
 744     solaris*)
 745         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 746         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 747         if test "x$driglx_direct" = xyes; then
 748             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 749         fi
 750         ;;
 751     esac
 752
 753     # default drivers
 754     if test "x$DRI_DIRS" = "xyes"; then
 755         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 756             savage sis tdfx trident unichrome ffb swrast"
 757     fi
 758
 759     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 760
 761     # Check for expat
 762     EXPAT_INCLUDES=""
 763     EXPAT_LIB=-lexpat
 764     AC_ARG_WITH([expat],
 765         [AS_HELP_STRING([--with-expat=DIR],
 766             [expat install directory])],[
 767         EXPAT_INCLUDES="-I$withval/include"
 768         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 769         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 770         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 771         ])
 772     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 773     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 774         [AC_MSG_ERROR([Expat required for DRI.])])
 775
 776     # put all the necessary libs together
 777     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 778 fi
 779 AC_SUBST([DRI_DIRS])
 780 AC_SUBST([EXPAT_INCLUDES])
 781 AC_SUBST([DRI_LIB_DEPS])
 782
 783 dnl
 784 dnl OSMesa configuration
 785 dnl
 786 if test "$mesa_driver" = xlib; then
 787     default_gl_osmesa=yes
 788 else
 789     default_gl_osmesa=no
 790 fi
 791 AC_ARG_ENABLE([gl-osmesa],
 792     [AS_HELP_STRING([--enable-gl-osmesa],
 793         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 794     [gl_osmesa="$enableval"],
 795     [gl_osmesa="$default_gl_osmesa"])
 796 if test "x$gl_osmesa" = xyes; then
 797     if test "$mesa_driver" = osmesa; then
 798         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 799     else
 800         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 801     fi
 802 fi
 803
 804 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 805 AC_ARG_WITH([osmesa-bits],
 806     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 807         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 808     [osmesa_bits="$withval"],
 809     [osmesa_bits=8])
 810 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 811     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 812     osmesa_bits=8
 813 fi
 814 case "x$osmesa_bits" in
 815 x8)
 816     OSMESA_LIB=OSMesa
 817     ;;
 818 x16|x32)
 819     OSMESA_LIB="OSMesa$osmesa_bits"
 820     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 821     ;;
 822 *)
 823     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 824     ;;
 825 esac
 826 AC_SUBST([OSMESA_LIB])
 827
 828 case "$mesa_driver" in
 829 osmesa)
 830     # only link libraries with osmesa if shared
 831     if test "$enable_static" = no; then
 832         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 833     else
 834         OSMESA_LIB_DEPS=""
 835     fi
 836     OSMESA_MESA_DEPS=""
 837     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 838     ;;
 839 *)
 840     # Link OSMesa to libGL otherwise
 841     OSMESA_LIB_DEPS=""
 842     # only link libraries with osmesa if shared
 843     if test "$enable_static" = no; then
 844         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 845     else
 846         OSMESA_MESA_DEPS=""
 847     fi
 848     OSMESA_PC_REQ="gl"
 849     ;;
 850 esac
 851 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 852 AC_SUBST([OSMESA_LIB_DEPS])
 853 AC_SUBST([OSMESA_MESA_DEPS])
 854 AC_SUBST([OSMESA_PC_REQ])
 855 AC_SUBST([OSMESA_PC_LIB_PRIV])
 856
 857 dnl
 858 dnl EGL configuration
 859 dnl
 860 AC_ARG_ENABLE([egl],
 861     [AS_HELP_STRING([--disable-egl],
 862         [disable EGL library @<:@default=enabled@:>@])],
 863     [enable_egl="$enableval"],
 864     [enable_egl=yes])
 865 if test "x$enable_egl" = xyes; then
 866     SRC_DIRS="$SRC_DIRS egl"
 867
 868     if test "$x11_pkgconfig" = yes; then
 869         PKG_CHECK_MODULES([EGL], [x11])
 870         EGL_LIB_DEPS="$EGL_LIBS"
 871     else
 872         # should check these...
 873         EGL_LIB_DEPS="$X_LIBS -lX11"
 874     fi
 875     EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS"
 876 fi
 877 AC_SUBST([EGL_LIB_DEPS])
 878
 879 dnl
 880 dnl GLU configuration
 881 dnl
 882 AC_ARG_ENABLE([glu],
 883     [AS_HELP_STRING([--disable-glu],
 884         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 885     [enable_glu="$enableval"],
 886     [enable_glu=yes])
 887 if test "x$enable_glu" = xyes; then
 888     SRC_DIRS="$SRC_DIRS glu"
 889
 890     case "$mesa_driver" in
 891     osmesa)
 892         # If GLU is available and we have libOSMesa (not 16 or 32),
 893         # we can build the osdemos
 894         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 895             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 896         fi
 897
 898         # Link libGLU to libOSMesa instead of libGL
 899         GLU_LIB_DEPS=""
 900         GLU_PC_REQ="osmesa"
 901         if test "$enable_static" = no; then
 902             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 903         else
 904             GLU_MESA_DEPS=""
 905         fi
 906         ;;
 907     *)
 908         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 909         GLU_PC_REQ="gl"
 910         GLU_PC_LIB_PRIV="-lm"
 911         if test "$enable_static" = no; then
 912             GLU_LIB_DEPS="-lm"
 913             GLU_MESA_DEPS='-l$(GL_LIB)'
 914         else
 915             GLU_LIB_DEPS=""
 916             GLU_MESA_DEPS=""
 917             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 918         fi
 919         ;;
 920     esac
 921 fi
 922 if test "$enable_static" = no; then
 923     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 924 fi
 925 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 926 AC_SUBST([GLU_LIB_DEPS])
 927 AC_SUBST([GLU_MESA_DEPS])
 928 AC_SUBST([GLU_PC_REQ])
 929 AC_SUBST([GLU_PC_REQ_PRIV])
 930 AC_SUBST([GLU_PC_LIB_PRIV])
 931 AC_SUBST([GLU_PC_CFLAGS])
 932
 933 dnl
 934 dnl GLw configuration
 935 dnl
 936 AC_ARG_ENABLE([glw],
 937     [AS_HELP_STRING([--disable-glw],
 938         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 939     [enable_glw="$enableval"],
 940     [enable_glw=yes])
 941 dnl Don't build GLw on osmesa
 942 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 943     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 944     enable_glw=no
 945 fi
 946 AC_ARG_ENABLE([motif],
 947     [AS_HELP_STRING([--enable-motif],
 948         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 949     [enable_motif="$enableval"],
 950     [enable_motif=no])
 951
 952 if test "x$enable_glw" = xyes; then
 953     SRC_DIRS="$SRC_DIRS glw"
 954     if test "$x11_pkgconfig" = yes; then
 955         PKG_CHECK_MODULES([GLW],[x11 xt])
 956         GLW_PC_REQ_PRIV="x11 xt"
 957         GLW_LIB_DEPS="$GLW_LIBS"
 958     else
 959         # should check these...
 960         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 961         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 962         GLW_PC_CFLAGS="$X11_INCLUDES"
 963     fi
 964
 965     GLW_SOURCES="GLwDrawA.c"
 966     MOTIF_CFLAGS=
 967     if test "x$enable_motif" = xyes; then
 968         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 969         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 970         if test "x$MOTIF_CONFIG" != xno; then
 971             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 972             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 973         else
 974             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 975                 [AC_MSG_ERROR([Can't locate Motif headers])])
 976             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 977                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 978         fi
 979         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 980         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 981         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 982         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 983     fi
 984
 985     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 986     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
 987     if test "$enable_static" = no; then
 988         GLW_MESA_DEPS='-l$(GL_LIB)'
 989         GLW_LIB_DEPS="$GLW_LIB_DEPS"
 990     else
 991         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 992         GLW_LIB_DEPS=""
 993         GLW_MESA_DEPS=""
 994     fi
 995 fi
 996 AC_SUBST([GLW_LIB_DEPS])
 997 AC_SUBST([GLW_MESA_DEPS])
 998 AC_SUBST([GLW_SOURCES])
 999 AC_SUBST([MOTIF_CFLAGS])
1000 AC_SUBST([GLW_PC_REQ_PRIV])
1001 AC_SUBST([GLW_PC_LIB_PRIV])
1002 AC_SUBST([GLW_PC_CFLAGS])
1003
1004 dnl
1005 dnl GLUT configuration
1006 dnl
1007 if test -f "$srcdir/include/GL/glut.h"; then
1008     default_glut=yes
1009 else
1010     default_glut=no
1011 fi
1012 AC_ARG_ENABLE([glut],
1013     [AS_HELP_STRING([--disable-glut],
1014         [enable GLUT library @<:@default=enabled if source available@:>@])],
1015     [enable_glut="$enableval"],
1016     [enable_glut="$default_glut"])
1017
1018 dnl Can't build glut if GLU not available
1019 if test "x$enable_glu$enable_glut" = xnoyes; then
1020     AC_MSG_WARN([Disabling glut since GLU is disabled])
1021     enable_glut=no
1022 fi
1023 dnl Don't build glut on osmesa
1024 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1025     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1026     enable_glut=no
1027 fi
1028
1029 if test "x$enable_glut" = xyes; then
1030     SRC_DIRS="$SRC_DIRS glut/glx"
1031     GLUT_CFLAGS=""
1032     if test "x$GCC" = xyes; then
1033         GLUT_CFLAGS="-fexceptions"
1034     fi
1035     if test "$x11_pkgconfig" = yes; then
1036         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1037         GLUT_PC_REQ_PRIV="x11 xmu xi"
1038         GLUT_LIB_DEPS="$GLUT_LIBS"
1039     else
1040         # should check these...
1041         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1042         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1043         GLUT_PC_CFLAGS="$X11_INCLUDES"
1044     fi
1045     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1046     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1047
1048     # If glut is available, we can build most programs
1049     if test "$with_demos" = yes; then
1050         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1051     fi
1052
1053     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1054     if test "$enable_static" = no; then
1055         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1056     else
1057         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1058         GLUT_LIB_DEPS=""
1059         GLUT_MESA_DEPS=""
1060     fi
1061 fi
1062 AC_SUBST([GLUT_LIB_DEPS])
1063 AC_SUBST([GLUT_MESA_DEPS])
1064 AC_SUBST([GLUT_CFLAGS])
1065 AC_SUBST([GLUT_PC_REQ_PRIV])
1066 AC_SUBST([GLUT_PC_LIB_PRIV])
1067 AC_SUBST([GLUT_PC_CFLAGS])
1068
1069 dnl
1070 dnl Program library dependencies
1071 dnl    Only libm is added here if necessary as the libraries should
1072 dnl    be pulled in by the linker
1073 dnl
1074 if test "x$APP_LIB_DEPS" = x; then
1075     case "$host_os" in
1076     solaris*)
1077         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1078         ;;
1079     cygwin*)
1080         APP_LIB_DEPS="-lX11"
1081         ;;
1082     *)
1083         APP_LIB_DEPS="-lm"
1084         ;;
1085     esac
1086 fi
1087 AC_SUBST([APP_LIB_DEPS])
1088 AC_SUBST([PROGRAM_DIRS])
1089
1090 dnl
1091 dnl Gallium configuration
1092 dnl
1093 AC_ARG_ENABLE([gallium],
1094     [AS_HELP_STRING([--disable-gallium],
1095         [build gallium @<:@default=enabled@:>@])],
1096     [enable_gallium="$enableval"],
1097     [enable_gallium=yes])
1098 if test "x$enable_gallium" = xyes; then
1099     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1100 fi
1101
1102 dnl
1103 dnl Gallium state trackers configuration
1104 dnl
1105 AC_ARG_WITH([state-trackers],
1106     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1107         [comma delimited state_trackers list, e.g.
1108         "egl,glx" @<:@default=auto@:>@])],
1109     [with_state_trackers="$withval"],
1110     [with_state_trackers=yes])
1111
1112 case "$with_state_trackers" in
1113 no)
1114     GALLIUM_STATE_TRACKERS_DIRS=""
1115     ;;
1116 yes)
1117     # look at what else is built
1118     case "$mesa_driver" in
1119     xlib)
1120         GALLIUM_STATE_TRACKERS_DIRS=glx
1121         ;;
1122     dri)
1123         test "x$enable_egl" = xyes && GALLIUM_STATE_TRACKERS_DIRS=egl
1124         ;;
1125     esac
1126     ;;
1127 *)
1128     # verify the requested state tracker exist
1129     state_trackers=`IFS=', '; echo $with_state_trackers`
1130     for tracker in $state_trackers; do
1131         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1132             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1133
1134         if test "$tracker" = egl && test "x$enable_egl" != xyes; then
1135             AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1136         fi
1137     done
1138     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1139     ;;
1140 esac
1141
1142 AC_ARG_WITH([xorg-driver-dir],
1143     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1144                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1145     [XORG_DRIVER_INSTALL_DIR="$withval"],
1146     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1147 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1148
1149 AC_ARG_WITH([max-width],
1150     [AS_HELP_STRING([--with-max-width=N],
1151                     [Maximum framebuffer width (4096)])],
1152     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1153      AS_IF([test "${withval}" -gt "4096"],
1154            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1155 )
1156 AC_ARG_WITH([max-height],
1157     [AS_HELP_STRING([--with-max-height=N],
1158                     [Maximum framebuffer height (4096)])],
1159     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1160      AS_IF([test "${withval}" -gt "4096"],
1161            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1162 )
1163
1164 dnl
1165 dnl Gallium Intel configuration
1166 dnl
1167 AC_ARG_ENABLE([gallium-intel],
1168     [AS_HELP_STRING([--disable-gallium-intel],
1169         [build gallium intel @<:@default=enabled@:>@])],
1170     [enable_gallium_intel="$enableval"],
1171     [enable_gallium_intel=yes])
1172 if test "x$enable_gallium_intel" = xyes; then
1173     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1174     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1175 fi
1176
1177 dnl
1178 dnl Gallium Radeon configuration
1179 dnl
1180 AC_ARG_ENABLE([gallium-radeon],
1181     [AS_HELP_STRING([--enable-gallium-radeon],
1182         [build gallium radeon @<:@default=disabled@:>@])],
1183     [enable_gallium_radeon="$enableval"],
1184     [enable_gallium_radeon=no])
1185 if test "x$enable_gallium_radeon" = xyes; then
1186     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1187     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1188 fi
1189
1190 dnl
1191 dnl Gallium Radeon configuration
1192 dnl
1193 AC_ARG_ENABLE([gallium-nouveau],
1194     [AS_HELP_STRING([--enable-gallium-nouveau],
1195         [build gallium nouveau @<:@default=disabled@:>@])],
1196     [enable_gallium_nouveau="$enableval"],
1197     [enable_gallium_nouveau=no])
1198 if test "x$enable_gallium_nouveau" = xyes; then
1199     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1200     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nv04 nv10 nv20 nv30 nv40 nv50"
1201 fi
1202
1203
1204 dnl Restore LDFLAGS and CPPFLAGS
1205 LDFLAGS="$_SAVE_LDFLAGS"
1206 CPPFLAGS="$_SAVE_CPPFLAGS"
1207
1208 dnl Substitute the config
1209 AC_CONFIG_FILES([configs/autoconf])
1210
1211 dnl Replace the configs/current symlink
1212 AC_CONFIG_COMMANDS([configs],[
1213 if test -f configs/current || test -L configs/current; then
1214     rm -f configs/current
1215 fi
1216 ln -s autoconf configs/current
1217 ])
1218
1219 AC_OUTPUT
1220
1221 dnl
1222 dnl Output some configuration info for the user
1223 dnl
1224 echo ""
1225 echo "        prefix:          $prefix"
1226 echo "        exec_prefix:     $exec_prefix"
1227 echo "        libdir:          $libdir"
1228 echo "        includedir:      $includedir"
1229
1230 dnl Driver info
1231 echo ""
1232 echo "        Driver:          $mesa_driver"
1233 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1234     echo "        OSMesa:          lib$OSMESA_LIB"
1235 else
1236     echo "        OSMesa:          no"
1237 fi
1238 if test "$mesa_driver" = dri; then
1239     # cleanup the drivers var
1240     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1241 if test "x$DRI_DIRS" = x; then
1242     echo "        DRI drivers:     no"
1243 else
1244     echo "        DRI drivers:     $dri_dirs"
1245 fi
1246     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1247 fi
1248 echo "        Use XCB:         $enable_xcb"
1249
1250 echo ""
1251 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1252     echo "        Gallium:         yes"
1253     echo "        Gallium dirs:    $GALLIUM_DIRS"
1254     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1255     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1256     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1257     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1258     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1259 else
1260     echo "        Gallium:         no"
1261 fi
1262
1263 dnl Libraries
1264 echo ""
1265 echo "        Shared libs:     $enable_shared"
1266 echo "        Static libs:     $enable_static"
1267 echo "        EGL:             $enable_egl"
1268 echo "        GLU:             $enable_glu"
1269 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1270 echo "        glut:            $enable_glut"
1271
1272 dnl Programs
1273 # cleanup the programs var for display
1274 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1275 if test "x$program_dirs" = x; then
1276     echo "        Demos:           no"
1277 else
1278     echo "        Demos:           $program_dirs"
1279 fi
1280
1281 dnl Compiler options
1282 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1283 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1284     $SED 's/^ *//;s/  */ /;s/ *$//'`
1285 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1286     $SED 's/^ *//;s/  */ /;s/ *$//'`
1287 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1288 echo ""
1289 echo "        CFLAGS:          $cflags"
1290 echo "        CXXFLAGS:        $cxxflags"
1291 echo "        Macros:          $defines"
1292
1293 echo ""
1294 echo "        Run '${MAKE-make}' to build Mesa"
1295 echo ""