configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.38
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 _SAVE_CPPFLAGS="$CPPFLAGS"
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DPTHREADS"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     CFLAGS="$CFLAGS -Wall -std=c99"
 171
 172     # Enable -Werror=implicit-function-declaration and
 173     # -Werror=missing-prototypes, if available, or otherwise, just
 174     # -Wmissing-prototypes.  This is particularly useful to avoid
 175     # generating a loadable driver module that has undefined symbols.
 176     save_CFLAGS="$CFLAGS"
 177     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 178     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 179     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 180     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 181                    AC_MSG_RESULT([yes]),
 182                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 183                     AC_MSG_RESULT([no])]);
 184
 185     # Enable -fvisibility=hidden if using a gcc that supports it
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 188     VISIBILITY_CFLAGS="-fvisibility=hidden"
 189     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 191                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 192
 193     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 194     CFLAGS=$save_CFLAGS
 195
 196     # Work around aliasing bugs - developers should comment this out
 197     CFLAGS="$CFLAGS -fno-strict-aliasing"
 198
 199     # gcc's builtin memcmp is slower than glibc's
 200     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 201     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 202 fi
 203 if test "x$GXX" = xyes; then
 204     CXXFLAGS="$CXXFLAGS -Wall"
 205
 206     # Enable -fvisibility=hidden if using a gcc that supports it
 207     save_CXXFLAGS="$CXXFLAGS"
 208     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 209     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 210     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 211     AC_LANG_PUSH([C++])
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 214     AC_LANG_POP([C++])
 215
 216     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 217     CXXFLAGS=$save_CXXFLAGS
 218
 219     # Work around aliasing bugs - developers should comment this out
 220     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 221
 222     # gcc's builtin memcmp is slower than glibc's
 223     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 224     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 225 fi
 226
 227 dnl even if the compiler appears to support it, using visibility attributes isn't
 228 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 229 case "$host_os" in
 230 cygwin*)
 231     VISIBILITY_CFLAGS=""
 232     VISIBILITY_CXXFLAGS=""
 233     ;;
 234 esac
 235
 236 AC_SUBST([VISIBILITY_CFLAGS])
 237 AC_SUBST([VISIBILITY_CXXFLAGS])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 dnl
 287 dnl mklib options
 288 dnl
 289 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 290 if test "$enable_static" = yes; then
 291     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 292 fi
 293 AC_SUBST([MKLIB_OPTIONS])
 294
 295 dnl
 296 dnl other compiler options
 297 dnl
 298 AC_ARG_ENABLE([debug],
 299     [AS_HELP_STRING([--enable-debug],
 300         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 301     [enable_debug="$enableval"],
 302     [enable_debug=no]
 303 )
 304 if test "x$enable_debug" = xyes; then
 305     DEFINES="$DEFINES -DDEBUG"
 306     if test "x$GCC" = xyes; then
 307         CFLAGS="$CFLAGS -g"
 308     fi
 309     if test "x$GXX" = xyes; then
 310         CXXFLAGS="$CXXFLAGS -g"
 311     fi
 312 fi
 313
 314 dnl
 315 dnl library names
 316 dnl
 317 LIB_PREFIX_GLOB='lib'
 318 LIB_VERSION_SEPARATOR='.'
 319 if test "$enable_static" = yes; then
 320     LIB_EXTENSION='a'
 321 else
 322     case "$host_os" in
 323     darwin* )
 324         LIB_EXTENSION='dylib' ;;
 325     cygwin* )
 326         dnl prefix can be 'cyg' or 'lib'
 327         LIB_PREFIX_GLOB='???'
 328         LIB_VERSION_SEPARATOR='-'
 329         LIB_EXTENSION='dll' ;;
 330     aix* )
 331         LIB_EXTENSION='a' ;;
 332     * )
 333         LIB_EXTENSION='so' ;;
 334     esac
 335 fi
 336 AC_ARG_WITH([gl-lib-name],
 337   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 338     [specify GL library name @<:@default=GL@:>@])],
 339   [GL_LIB=$withval],
 340   [GL_LIB=GL])
 341 AC_ARG_WITH([glu-lib-name],
 342   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 343     [specify GLU library name @<:@default=GLU@:>@])],
 344   [GLU_LIB=$withval],
 345   [GLU_LIB=GLU])
 346 AC_ARG_WITH([osmesa-lib-name],
 347   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 348     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 349   [OSMESA_LIB=$withval],
 350   [OSMESA_LIB=OSMesa])
 351 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 352 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 353 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 354
 355 dnl
 356 dnl Mangled Mesa support
 357 dnl
 358 AC_ARG_ENABLE([mangling],
 359   [AS_HELP_STRING([--enable-mangling],
 360     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 361   [enable_mangling="${enableval}"],
 362   [enable_mangling=no]
 363 )
 364 if test "x${enable_mangling}" = "xyes" ; then
 365   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 366   GL_LIB="Mangled${GL_LIB}"
 367   GLU_LIB="Mangled${GLU_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([GLU_LIB])
 372 AC_SUBST([OSMESA_LIB])
 373
 374 dnl
 375 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 376 dnl
 377 AC_ARG_ENABLE([texture-float],
 378     [AS_HELP_STRING([--enable-texture-float],
 379         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 380     [enable_texture_float="$enableval"],
 381     [enable_texture_float=no]
 382 )
 383 if test "x$enable_texture_float" = xyes; then
 384     AC_MSG_WARN([Floating-point textures enabled.])
 385     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 386     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 387 fi
 388
 389 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 390 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 391 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 392 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 393 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 394 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 395 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 396 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 397
 398 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406
 407 AC_SUBST([GL_LIB_NAME])
 408 AC_SUBST([GLU_LIB_NAME])
 409 AC_SUBST([OSMESA_LIB_NAME])
 410 AC_SUBST([EGL_LIB_NAME])
 411 AC_SUBST([GLESv1_CM_LIB_NAME])
 412 AC_SUBST([GLESv2_LIB_NAME])
 413 AC_SUBST([VG_LIB_NAME])
 414 AC_SUBST([GLAPI_LIB_NAME])
 415
 416 AC_SUBST([GL_LIB_GLOB])
 417 AC_SUBST([GLU_LIB_GLOB])
 418 AC_SUBST([EGL_LIB_GLOB])
 419 AC_SUBST([GLESv1_CM_LIB_GLOB])
 420 AC_SUBST([GLESv2_LIB_GLOB])
 421 AC_SUBST([VG_LIB_GLOB])
 422 AC_SUBST([GLAPI_LIB_GLOB])
 423
 424 dnl
 425 dnl Arch/platform-specific settings
 426 dnl
 427 AC_ARG_ENABLE([asm],
 428     [AS_HELP_STRING([--disable-asm],
 429         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 430     [enable_asm="$enableval"],
 431     [enable_asm=yes]
 432 )
 433 asm_arch=""
 434 MESA_ASM_FILES=""
 435 AC_MSG_CHECKING([whether to enable assembly])
 436 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 437 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 438 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 439     case "$host_cpu" in
 440     i?86 | x86_64)
 441         enable_asm=no
 442         AC_MSG_RESULT([no, cross compiling])
 443         ;;
 444     esac
 445 fi
 446 # check for supported arches
 447 if test "x$enable_asm" = xyes; then
 448     case "$host_cpu" in
 449     i?86)
 450         case "$host_os" in
 451         linux* | *freebsd* | dragonfly* | *netbsd*)
 452             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 453             ;;
 454         esac
 455         ;;
 456     x86_64)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 460             ;;
 461         esac
 462         ;;
 463     sparc*)
 464         case "$host_os" in
 465         linux*)
 466             asm_arch=sparc
 467             ;;
 468         esac
 469         ;;
 470     esac
 471
 472     case "$asm_arch" in
 473     x86)
 474         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 475         MESA_ASM_FILES='$(X86_FILES)'
 476         AC_MSG_RESULT([yes, x86])
 477         ;;
 478     x86_64)
 479         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 480         MESA_ASM_FILES='$(X86_64_FILES)'
 481         AC_MSG_RESULT([yes, x86_64])
 482         ;;
 483     sparc)
 484         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 485         MESA_ASM_FILES='$(SPARC_FILES)'
 486         AC_MSG_RESULT([yes, sparc])
 487         ;;
 488     *)
 489         AC_MSG_RESULT([no, platform not supported])
 490         ;;
 491     esac
 492 fi
 493 AC_SUBST([MESA_ASM_FILES])
 494
 495 dnl PIC code macro
 496 MESA_PIC_FLAGS
 497
 498 dnl Check to see if dlopen is in default libraries (like Solaris, which
 499 dnl has it in libc), or if libdl is needed to get it.
 500 AC_CHECK_FUNC([dlopen], [],
 501     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 502 AC_SUBST([DLOPEN_LIBS])
 503
 504 dnl See if posix_memalign is available
 505 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 506
 507 dnl SELinux awareness.
 508 AC_ARG_ENABLE([selinux],
 509     [AS_HELP_STRING([--enable-selinux],
 510         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 511     [MESA_SELINUX="$enableval"],
 512     [MESA_SELINUX=no])
 513 if test "x$enable_selinux" = "xyes"; then
 514     AC_CHECK_HEADER([selinux/selinux.h],[],
 515                     [AC_MSG_ERROR([SELinux headers not found])])
 516     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 517                  [AC_MSG_ERROR([SELinux library not found])])
 518     SELINUX_LIBS="-lselinux"
 519     DEFINES="$DEFINES -DMESA_SELINUX"
 520 fi
 521
 522 dnl Options for APIs
 523 AC_ARG_ENABLE([opengl],
 524     [AS_HELP_STRING([--disable-opengl],
 525         [disable support for standard OpenGL API @<:@default=no@:>@])],
 526     [enable_opengl="$enableval"],
 527     [enable_opengl=yes])
 528 AC_ARG_ENABLE([gles1],
 529     [AS_HELP_STRING([--enable-gles1],
 530         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 531     [enable_gles1="$enableval"],
 532     [enable_gles1=no])
 533 AC_ARG_ENABLE([gles2],
 534     [AS_HELP_STRING([--enable-gles2],
 535         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 536     [enable_gles2="$enableval"],
 537     [enable_gles2=no])
 538 AC_ARG_ENABLE([openvg],
 539     [AS_HELP_STRING([--enable-openvg],
 540         [enable support for OpenVG API @<:@default=no@:>@])],
 541     [enable_openvg="$enableval"],
 542     [enable_openvg=no])
 543
 544 AC_ARG_ENABLE([dri],
 545     [AS_HELP_STRING([--enable-dri],
 546         [enable DRI modules @<:@default=enabled@:>@])],
 547     [enable_dri="$enableval"],
 548     [enable_dri=yes])
 549 AC_ARG_ENABLE([glx],
 550     [AS_HELP_STRING([--enable-glx],
 551         [enable GLX library @<:@default=enabled@:>@])],
 552     [enable_glx="$enableval"],
 553     [enable_glx=yes])
 554 AC_ARG_ENABLE([osmesa],
 555     [AS_HELP_STRING([--enable-osmesa],
 556         [enable OSMesa library @<:@default=disabled@:>@])],
 557     [enable_osmesa="$enableval"],
 558     [enable_osmesa=no])
 559 AC_ARG_ENABLE([egl],
 560     [AS_HELP_STRING([--disable-egl],
 561         [disable EGL library @<:@default=enabled@:>@])],
 562     [enable_egl="$enableval"],
 563     [enable_egl=yes])
 564
 565 AC_ARG_ENABLE([xorg],
 566     [AS_HELP_STRING([--enable-xorg],
 567         [enable support for X.Org DDX API @<:@default=no@:>@])],
 568     [enable_xorg="$enableval"],
 569     [enable_xorg=no])
 570 AC_ARG_ENABLE([xa],
 571     [AS_HELP_STRING([--enable-xa],
 572         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 573     [enable_xa="$enableval"],
 574     [enable_xa=no])
 575 AC_ARG_ENABLE([d3d1x],
 576     [AS_HELP_STRING([--enable-d3d1x],
 577         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 578     [enable_d3d1x="$enableval"],
 579     [enable_d3d1x=no])
 580 AC_ARG_ENABLE([gbm],
 581    [AS_HELP_STRING([--enable-gbm],
 582          [enable gbm library @<:@default=auto@:>@])],
 583    [enable_gbm="$enableval"],
 584    [enable_gbm=auto])
 585
 586 AC_ARG_ENABLE([xvmc],
 587    [AS_HELP_STRING([--enable-xvmc],
 588          [enable xvmc library @<:@default=auto@:>@])],
 589    [enable_xvmc="$enableval"],
 590    [enable_xvmc=auto])
 591 AC_ARG_ENABLE([vdpau],
 592    [AS_HELP_STRING([--enable-vdpau],
 593          [enable vdpau library @<:@default=auto@:>@])],
 594    [enable_vdpau="$enableval"],
 595    [enable_vdpau=auto])
 596 AC_ARG_ENABLE([va],
 597    [AS_HELP_STRING([--enable-va],
 598          [enable va library @<:@default=auto@:>@])],
 599    [enable_va="$enableval"],
 600    [enable_va=auto])
 601 AC_ARG_ENABLE([opencl],
 602    [AS_HELP_STRING([--enable-opencl],
 603          [enable OpenCL library @<:@default=no@:>@])],
 604    [enable_opencl="$enableval"],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([xlib_glx],
 607     [AS_HELP_STRING([--enable-xlib-glx],
 608         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 609     [enable_xlib_glx="$enableval"],
 610     [enable_xlib_glx=no])
 611 AC_ARG_ENABLE([gallium_egl],
 612     [AS_HELP_STRING([--enable-gallium-egl],
 613         [enable optional EGL state tracker (not required
 614          for EGL support in Gallium with OpenGL and OpenGL ES)
 615          @<:@default=disable@:>@])],
 616     [enable_gallium_egl="$enableval"],
 617     [enable_gallium_egl=no])
 618 AC_ARG_ENABLE([gallium_gbm],
 619     [AS_HELP_STRING([--enable-gallium-gbm],
 620         [enable optional gbm state tracker (not required for
 621          gbm support in Gallium)
 622          @<:@default=auto@:>@])],
 623     [enable_gallium_gbm="$enableval"],
 624     [enable_gallium_gbm=auto])
 625
 626 AC_ARG_ENABLE([r600-llvm-compiler],
 627     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 628         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 629     [enable_r600_llvm="$enableval"],
 630     [enable_r600_llvm=no])
 631
 632 AC_ARG_ENABLE([gallium_tests],
 633     [AS_HELP_STRING([--enable-gallium-tests],
 634         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 635     [enable_gallium_tests="$enableval"],
 636     [enable_gallium_tests=no])
 637
 638 # Option for Gallium drivers
 639 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 640
 641 AC_ARG_WITH([gallium-drivers],
 642     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 643         [comma delimited Gallium drivers list, e.g.
 644         "i915,nouveau,r300,r600,svga,swrast"
 645         @<:@default=r300,r600,swrast@:>@])],
 646     [with_gallium_drivers="$withval"],
 647     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 648
 649 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 650 # here so that the script doesn't choke on an unknown driver name later.
 651 case "$with_gallium_drivers" in
 652     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 653     no) with_gallium_drivers='' ;;
 654 esac
 655
 656 if test "x$enable_opengl" = xno -a \
 657         "x$enable_gles1" = xno -a \
 658         "x$enable_gles2" = xno -a \
 659         "x$enable_openvg" = xno -a \
 660         "x$enable_xorg" = xno -a \
 661         "x$enable_xa" = xno -a \
 662         "x$enable_d3d1x" = xno -a \
 663         "x$enable_xvmc" = xno -a \
 664         "x$enable_vdpau" = xno -a \
 665         "x$enable_va" = xno -a \
 666         "x$enable_opencl" = xno; then
 667     AC_MSG_ERROR([at least one API should be enabled])
 668 fi
 669
 670 API_DEFINES=""
 671 if test "x$enable_opengl" = xno; then
 672     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 673 else
 674     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 675 fi
 676 if test "x$enable_gles1" = xyes; then
 677     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 678 fi
 679 if test "x$enable_gles2" = xyes; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 681 fi
 682 AC_SUBST([API_DEFINES])
 683
 684 if test "x$enable_glx" = xno; then
 685     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 686     enable_xlib_glx=no
 687 fi
 688
 689 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 690     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 691 fi
 692
 693 # Disable GLX if DRI and Xlib-GLX are not enabled
 694 if test "x$enable_glx" = xyes -a \
 695         "x$enable_dri" = xno -a \
 696         "x$enable_xlib_glx" = xno; then
 697     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 698     enable_glx=no
 699 fi
 700
 701 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 702
 703 AC_ARG_ENABLE([shared-glapi],
 704     [AS_HELP_STRING([--enable-shared-glapi],
 705         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 706     [enable_shared_glapi="$enableval"],
 707     [enable_shared_glapi="$enable_dri"])
 708
 709 # Shared GLAPI is only useful for DRI
 710 if test "x$enable_dri" = xno; then
 711     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 712     enable_shared_glapi=no
 713 fi
 714
 715 # TODO: Get rid of SHARED_GLAPI variable
 716 SHARED_GLAPI="0"
 717 if test "x$enable_shared_glapi" = xyes; then
 718     SHARED_GLAPI="1"
 719     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 720     # the remap table)
 721     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 722     CORE_DIRS="mapi/shared-glapi"
 723 fi
 724 AC_SUBST([SHARED_GLAPI])
 725 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 726
 727 dnl
 728 dnl Driver specific build directories
 729 dnl
 730 SRC_DIRS="gtest"
 731 GLU_DIRS="sgi"
 732 GALLIUM_DIRS="auxiliary drivers state_trackers"
 733 GALLIUM_TARGET_DIRS=""
 734 GALLIUM_WINSYS_DIRS="sw"
 735 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 736 GALLIUM_STATE_TRACKERS_DIRS=""
 737
 738 # build glapi if OpenGL is enabled
 739 if test "x$enable_opengl" = xyes; then
 740     CORE_DIRS="$CORE_DIRS mapi/glapi"
 741 fi
 742
 743 # build es1api if OpenGL ES 1.x is enabled
 744 if test "x$enable_gles1" = xyes; then
 745     CORE_DIRS="$CORE_DIRS mapi/es1api"
 746 fi
 747
 748 # build es2api if OpenGL ES 2.x is enabled
 749 if test "x$enable_gles2" = xyes; then
 750     CORE_DIRS="$CORE_DIRS mapi/es2api"
 751 fi
 752
 753 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 754 case "x$enable_opengl$enable_gles1$enable_gles2" in
 755 x*yes*)
 756     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 757     ;;
 758 esac
 759
 760 case "x$enable_glx$enable_xlib_glx" in
 761 xyesyes)
 762     DRIVER_DIRS="$DRIVER_DIRS x11"
 763     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 764     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 765     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 766     HAVE_WINSYS_XLIB="yes"
 767     ;;
 768 xyesno)
 769     # DRI-based GLX
 770     SRC_DIRS="$SRC_DIRS glx"
 771     ;;
 772 esac
 773
 774 if test "x$enable_dri" = xyes; then
 775     DRIVER_DIRS="$DRIVER_DIRS dri"
 776
 777     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 778     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 779     HAVE_ST_DRI="yes"
 780 fi
 781
 782 if test "x$enable_osmesa" = xyes; then
 783     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 784 fi
 785
 786 AC_SUBST([SRC_DIRS])
 787 AC_SUBST([GLU_DIRS])
 788 AC_SUBST([DRIVER_DIRS])
 789 AC_SUBST([GALLIUM_DIRS])
 790 AC_SUBST([GALLIUM_TARGET_DIRS])
 791 AC_SUBST([GALLIUM_WINSYS_DIRS])
 792 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 793 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 794 AC_SUBST([MESA_LLVM])
 795
 796 # Check for libdrm
 797 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 798                   [have_libdrm=yes], [have_libdrm=no])
 799
 800 if test "x$enable_dri" = xyes; then
 801     # DRI must be shared, I think
 802     if test "$enable_static" = yes; then
 803         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 804     fi
 805
 806     # not a hard requirement as swrast does not depend on it
 807     if test "x$have_libdrm" = xyes; then
 808         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 809     fi
 810 fi
 811
 812 dnl Find out if X is available.
 813 PKG_CHECK_MODULES([X11], [x11])
 814
 815 dnl Try to tell the user that the --x-* options are only used when
 816 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 817 m4_divert_once([HELP_BEGIN],
 818 [These options are only used when the X libraries cannot be found by the
 819 pkg-config utility.])
 820
 821 dnl We need X for xlib and dri, so bomb now if it's not found
 822 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 823     AC_MSG_ERROR([X11 development libraries needed for GLX])
 824 fi
 825
 826 if test "x$enable_glx" = xyes; then
 827     DEFINES="$DEFINES -DUSE_XCB"
 828 fi
 829
 830 dnl Direct rendering or just indirect rendering
 831 case "$host_os" in
 832 gnu*)
 833     dnl Disable by default on GNU/Hurd
 834     driglx_direct_default="no"
 835     ;;
 836 cygwin*)
 837     dnl Disable by default on cygwin
 838     driglx_direct_default="no"
 839     ;;
 840 *)
 841     driglx_direct_default="yes"
 842     ;;
 843 esac
 844 AC_ARG_ENABLE([driglx-direct],
 845     [AS_HELP_STRING([--disable-driglx-direct],
 846         [enable direct rendering in GLX and EGL for DRI \
 847             @<:@default=auto@:>@])],
 848     [driglx_direct="$enableval"],
 849     [driglx_direct="$driglx_direct_default"])
 850
 851 dnl
 852 dnl libGL configuration per driver
 853 dnl
 854 case "x$enable_glx$enable_xlib_glx" in
 855 xyesyes)
 856     # Xlib-based GLX
 857     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 858     GL_PC_REQ_PRIV="x11 xext"
 859     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 860     GL_LIB_DEPS="$XLIBGL_LIBS"
 861     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 862     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 863     ;;
 864 xyesno)
 865     # DRI-based GLX
 866     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 867     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 868     if test x"$driglx_direct" = xyes; then
 869         if test "x$have_libdrm" != xyes; then
 870             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 871         fi
 872         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 873         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 874     fi
 875
 876     # find the DRI deps for libGL
 877     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 878
 879     # add xf86vidmode if available
 880     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 881     if test "$HAVE_XF86VIDMODE" = yes ; then
 882         dri_modules="$dri_modules xxf86vm"
 883     fi
 884
 885     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 886     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 887     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 888     GL_LIB_DEPS="$DRIGL_LIBS"
 889
 890     # need DRM libs, -lpthread, etc.
 891     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 892     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 893     ;;
 894 esac
 895
 896 # This is outside the case (above) so that it is invoked even for non-GLX
 897 # builds.
 898 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 899
 900 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 901 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 902 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 903 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 904
 905 AC_SUBST([GL_LIB_DEPS])
 906 AC_SUBST([GL_PC_REQ_PRIV])
 907 AC_SUBST([GL_PC_LIB_PRIV])
 908 AC_SUBST([GL_PC_CFLAGS])
 909 AC_SUBST([DRI_PC_REQ_PRIV])
 910 AC_SUBST([GLESv1_CM_LIB_DEPS])
 911 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 912 AC_SUBST([GLESv2_LIB_DEPS])
 913 AC_SUBST([GLESv2_PC_LIB_PRIV])
 914
 915 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
 916 AC_SUBST([GLAPI_LIB_DEPS])
 917
 918
 919 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 920 GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 921
 922 AM_CONDITIONAL(HAVE_DRICORE, test "x$enable_dri" = xyes)
 923
 924 AC_SUBST([HAVE_XF86VIDMODE])
 925
 926 dnl
 927 dnl More GLX setup
 928 dnl
 929 case "x$enable_glx$enable_xlib_glx" in
 930 xyesyes)
 931     DEFINES="$DEFINES -DUSE_XSHM"
 932     ;;
 933 xyesno)
 934     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 935     if test "x$driglx_direct" = xyes; then
 936         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 937     fi
 938     ;;
 939 esac
 940
 941 dnl
 942 dnl TLS detection
 943 dnl
 944
 945 AC_ARG_ENABLE([glx-tls],
 946     [AS_HELP_STRING([--enable-glx-tls],
 947         [enable TLS support in GLX @<:@default=disabled@:>@])],
 948     [GLX_USE_TLS="$enableval"],
 949     [GLX_USE_TLS=no])
 950 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 951
 952 AS_IF([test "x$GLX_USE_TLS" = xyes],
 953       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 954
 955 dnl
 956 dnl More DRI setup
 957 dnl
 958 dnl Directory for DRI drivers
 959 AC_ARG_WITH([dri-driverdir],
 960     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 961         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 962     [DRI_DRIVER_INSTALL_DIR="$withval"],
 963     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 964 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 965 dnl Extra search path for DRI drivers
 966 AC_ARG_WITH([dri-searchpath],
 967     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 968         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 969     [DRI_DRIVER_SEARCH_DIR="$withval"],
 970     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 971 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 972 dnl Which drivers to build - default is chosen by platform
 973 AC_ARG_WITH([dri-drivers],
 974     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 975         [comma delimited DRI drivers list, e.g.
 976         "swrast,i965,radeon" @<:@default=auto@:>@])],
 977     [with_dri_drivers="$withval"],
 978     [with_dri_drivers=yes])
 979 if test "x$with_dri_drivers" = x; then
 980     with_dri_drivers=no
 981 fi
 982
 983 dnl If $with_dri_drivers is yes, directories will be added through
 984 dnl platform checks
 985 DRI_DIRS=""
 986 case "$with_dri_drivers" in
 987 no) ;;
 988 yes)
 989     # classic DRI drivers require FEATURE_GL to build
 990     if test "x$enable_opengl" = xyes; then
 991         DRI_DIRS="yes"
 992     fi
 993     ;;
 994 *)
 995     # verify the requested driver directories exist
 996     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 997     for driver in $dri_drivers; do
 998         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 999             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1000     done
1001     DRI_DIRS="$dri_drivers"
1002     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1003         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1004     fi
1005     ;;
1006 esac
1007
1008 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1009 if test "x$enable_dri" = xyes; then
1010     # Platform specific settings and drivers to build
1011     case "$host_os" in
1012     linux*)
1013         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1014         DEFINES="$DEFINES -DHAVE_ALIAS"
1015
1016         case "$host_cpu" in
1017         x86_64)
1018             if test "x$DRI_DIRS" = "xyes"; then
1019                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1020             fi
1021             ;;
1022         powerpc*)
1023             # Build only the drivers for cards that exist on PowerPC.
1024             if test "x$DRI_DIRS" = "xyes"; then
1025                 DRI_DIRS="r200 radeon swrast"
1026             fi
1027             ;;
1028         sparc*)
1029             # Build only the drivers for cards that exist on sparc
1030             if test "x$DRI_DIRS" = "xyes"; then
1031                 DRI_DIRS="r200 radeon swrast"
1032             fi
1033             ;;
1034         esac
1035         ;;
1036     freebsd* | dragonfly* | *netbsd*)
1037         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1038         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1039
1040         if test "x$DRI_DIRS" = "xyes"; then
1041             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1042         fi
1043         ;;
1044     gnu*)
1045         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1046         DEFINES="$DEFINES -DHAVE_ALIAS"
1047         ;;
1048     solaris*)
1049         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1050         ;;
1051     cygwin*)
1052         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1053         if test "x$DRI_DIRS" = "xyes"; then
1054             DRI_DIRS="swrast"
1055         fi
1056         ;;
1057     esac
1058
1059     # default drivers
1060     if test "x$DRI_DIRS" = "xyes"; then
1061         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1062     fi
1063
1064     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1065
1066     # Check for expat
1067     if test "x$enable_dri" = xyes; then
1068         EXPAT_INCLUDES=""
1069         EXPAT_LIB=-lexpat
1070         AC_ARG_WITH([expat],
1071             [AS_HELP_STRING([--with-expat=DIR],
1072                 [expat install directory])],[
1073             EXPAT_INCLUDES="-I$withval/include"
1074             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1075             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1076             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1077             ])
1078         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1079         save_LIBS="$LIBS"
1080         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1081             [AC_MSG_ERROR([Expat required for DRI.])])
1082         LIBS="$save_LIBS"
1083     fi
1084
1085     # if we are building any dri driver other than swrast ...
1086     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1087         # ... libdrm is required
1088         if test "x$have_libdrm" != xyes; then
1089             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1090         fi
1091         # ... and build dricommon
1092         HAVE_COMMON_DRI=yes
1093     fi
1094
1095     # put all the necessary libs together
1096     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1097     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1098 fi
1099 AC_SUBST([DRI_DIRS])
1100 AC_SUBST([EXPAT_INCLUDES])
1101 AC_SUBST([DRI_LIB_DEPS])
1102 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1103
1104 case $DRI_DIRS in
1105 *i915*|*i965*)
1106     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1107
1108     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1109         case $d in
1110         i915)
1111             HAVE_I915_DRI=yes;
1112             ;;
1113         i965)
1114             HAVE_I965_DRI=yes;
1115             ;;
1116         esac
1117     done
1118
1119     ;;
1120 esac
1121
1122 case $DRI_DIRS in
1123 *nouveau*)
1124     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1125     HAVE_NOUVEAU_DRI=yes;
1126     ;;
1127 esac
1128
1129 case $DRI_DIRS in
1130 *radeon*|*r200*)
1131     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1132
1133     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1134         case $d in
1135         radeon)
1136             HAVE_RADEON_DRI=yes;
1137             ;;
1138         r200)
1139             HAVE_R200_DRI=yes;
1140             ;;
1141         esac
1142     done
1143
1144     ;;
1145 esac
1146
1147 case $DRI_DIRS in
1148 *swrast*)
1149     HAVE_SWRAST_DRI=yes;
1150     ;;
1151 esac
1152
1153 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1154 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1156 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1157 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1158 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1159 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1160
1161 dnl
1162 dnl OSMesa configuration
1163 dnl
1164
1165 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1166 AC_ARG_WITH([osmesa-bits],
1167     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1168         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1169     [osmesa_bits="$withval"],
1170     [osmesa_bits=8])
1171 if test "x$osmesa_bits" != x8; then
1172     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1173         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1174         osmesa_bits=8
1175     fi
1176 fi
1177 case "x$osmesa_bits" in
1178 x8)
1179     OSMESA_LIB="${OSMESA_LIB}"
1180     ;;
1181 x16|x32)
1182     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1183     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1184     ;;
1185 *)
1186     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1187     ;;
1188 esac
1189
1190 if test "x$enable_osmesa" = xyes; then
1191     # only link libraries with osmesa if shared
1192     if test "$enable_static" = no; then
1193         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1194     else
1195         OSMESA_LIB_DEPS=""
1196     fi
1197     OSMESA_MESA_DEPS=""
1198     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1199 fi
1200
1201 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1202
1203 AC_SUBST([OSMESA_LIB_DEPS])
1204 AC_SUBST([OSMESA_MESA_DEPS])
1205 AC_SUBST([OSMESA_PC_REQ])
1206 AC_SUBST([OSMESA_PC_LIB_PRIV])
1207 AC_SUBST([OSMESA_VERSION])
1208
1209 dnl
1210 dnl gbm configuration
1211 dnl
1212 if test "x$enable_gbm" = xauto; then
1213     case "$with_egl_platforms" in
1214         *drm*)
1215             enable_gbm=yes ;;
1216          *)
1217             enable_gbm=no ;;
1218     esac
1219 fi
1220 if test "x$enable_gbm" = xyes; then
1221     SRC_DIRS="$SRC_DIRS gbm"
1222
1223     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1224                       AC_MSG_ERROR([gbm needs udev]))
1225
1226     if test "x$enable_dri" = xyes; then
1227         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1228         if test "x$enable_shared_glapi" = xno; then
1229             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1230         fi
1231     fi
1232 fi
1233 GBM_PC_REQ_PRIV="libudev"
1234 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1235 AC_SUBST([GBM_PC_REQ_PRIV])
1236 AC_SUBST([GBM_PC_LIB_PRIV])
1237
1238 dnl
1239 dnl EGL configuration
1240 dnl
1241 EGL_CLIENT_APIS=""
1242
1243 if test "x$enable_egl" = xyes; then
1244     SRC_DIRS="$SRC_DIRS egl"
1245     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1246
1247     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1248
1249     if test "$enable_static" != yes; then
1250         # build egl_glx when libGL is built
1251         if test "x$enable_glx" = xyes; then
1252             HAVE_EGL_DRIVER_GLX=1
1253         fi
1254
1255         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1256                           [have_libudev=yes],[have_libudev=no])
1257         if test "$have_libudev" = yes; then
1258             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1259         fi
1260
1261         if test "x$enable_dri" = xyes; then
1262             HAVE_EGL_DRIVER_DRI2=1
1263         fi
1264
1265     fi
1266 fi
1267 AC_SUBST([EGL_LIB_DEPS])
1268
1269 dnl
1270 dnl EGL Gallium configuration
1271 dnl
1272 if test "x$enable_gallium_egl" = xyes; then
1273     if test "x$with_gallium_drivers" = x; then
1274         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1275     fi
1276     if test "x$enable_egl" = xno; then
1277         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1278     fi
1279     if test "x$have_libdrm" != xyes; then
1280         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1281     fi
1282
1283     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1284     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1285     HAVE_ST_EGL="yes"
1286 fi
1287
1288 dnl
1289 dnl gbm Gallium configuration
1290 dnl
1291 if test "x$enable_gallium_gbm" = xauto; then
1292     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1293         yesyesyes*drm*)
1294             enable_gallium_gbm=yes ;;
1295          *)
1296             enable_gallium_gbm=no ;;
1297     esac
1298 fi
1299 if test "x$enable_gallium_gbm" = xyes; then
1300     if test "x$with_gallium_drivers" = x; then
1301         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1302     fi
1303     if test "x$enable_gbm" = xno; then
1304         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1305     fi
1306     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1307     if test "x$enable_dri" = xno; then
1308         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1309     fi
1310
1311     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1312     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1313     HAVE_ST_GBM="yes"
1314     enable_gallium_loader=yes
1315 fi
1316
1317 dnl
1318 dnl X.Org DDX configuration
1319 dnl
1320 if test "x$enable_xorg" = xyes; then
1321     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1322     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1323     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1324     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1325         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1326         HAVE_XEXTPROTO_71="no")
1327     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1328     HAVE_ST_XORG=yes
1329 fi
1330
1331 dnl
1332 dnl XA configuration
1333 dnl
1334 if test "x$enable_xa" = xyes; then
1335 AC_PROG_AWK
1336 AC_PROG_GREP
1337 AC_CHECK_PROG(NM, nm, "nm")
1338 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1339 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1340 enable_xa=no
1341 fi
1342 fi
1343 if test "x$enable_xa" = xyes; then
1344     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1345     HAVE_ST_XA=yes
1346     AC_SUBST(AWK)
1347     AC_SUBST(GREP)
1348     AC_SUBST(NM)
1349 fi
1350
1351 dnl
1352 dnl OpenVG configuration
1353 dnl
1354 VG_LIB_DEPS=""
1355
1356 if test "x$enable_openvg" = xyes; then
1357     if test "x$enable_egl" = xno; then
1358         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1359     fi
1360     if test "x$with_gallium_drivers" = x; then
1361         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1362     fi
1363     if test "x$enable_gallium_egl" = xno; then
1364         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1365     fi
1366
1367     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1368     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1369     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1370     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1371     HAVE_ST_VEGA=yes
1372 fi
1373
1374 dnl
1375 dnl D3D1X configuration
1376 dnl
1377
1378 if test "x$enable_d3d1x" = xyes; then
1379     if test "x$with_gallium_drivers" = x; then
1380         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1381     fi
1382
1383     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1384     HAVE_ST_D3D1X=yes
1385 fi
1386
1387 dnl
1388 dnl Gallium G3DVL configuration
1389 dnl
1390 AC_ARG_ENABLE([gallium-g3dvl],
1391     [AS_HELP_STRING([--enable-gallium-g3dvl],
1392         [build gallium g3dvl @<:@default=disabled@:>@])],
1393     [enable_gallium_g3dvl="$enableval"],
1394     [enable_gallium_g3dvl=no])
1395 if test "x$enable_gallium_g3dvl" = xyes; then
1396     if test "x$with_gallium_drivers" = x; then
1397         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1398     fi
1399
1400     if test "x$enable_xvmc" = xauto; then
1401         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1402     fi
1403
1404     if test "x$enable_vdpau" = xauto; then
1405         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1406     fi
1407
1408     if test "x$enable_va" = xauto; then
1409         #don't enable vaapi state tracker even if package exists
1410         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1411         enable_va=no
1412     fi
1413 fi
1414
1415 if test "x$enable_xvmc" = xyes; then
1416     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1417     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1418     HAVE_ST_XVMC="yes"
1419 fi
1420
1421 if test "x$enable_vdpau" = xyes; then
1422     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1423     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1424     HAVE_ST_VDPAU="yes"
1425 fi
1426
1427 if test "x$enable_va" = xyes; then
1428     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1429     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1430     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1431     HAVE_ST_VA="yes"
1432 fi
1433
1434 dnl
1435 dnl OpenCL configuration
1436 dnl
1437
1438 AC_ARG_WITH([libclc-path],
1439    [AS_HELP_STRING([--with-libclc-path],
1440          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1441    [LIBCLC_PATH="$withval"],
1442    [LIBCLC_PATH=""])
1443
1444 AC_ARG_WITH([clang-libdir],
1445    [AS_HELP_STRING([--with-clang-libdir],
1446          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1447    [CLANG_LIBDIR="$withval"],
1448    [CLANG_LIBDIR=""])
1449
1450 AC_SUBST([LIBCLC_PATH])
1451
1452 if test "x$enable_opencl" = xyes; then
1453     if test "x$with_gallium_drivers" = x; then
1454         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1455     fi
1456
1457     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1458         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1459     fi
1460
1461     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1462     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1463     enable_gallium_loader=yes
1464 fi
1465
1466 dnl
1467 dnl GLU configuration
1468 dnl
1469 AC_ARG_ENABLE([glu],
1470     [AS_HELP_STRING([--disable-glu],
1471         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1472     [enable_glu="$enableval"],
1473     [enable_glu=yes])
1474
1475 if test "x$enable_glu" = xyes; then
1476     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1477         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1478         enable_glu=no
1479     fi
1480 fi
1481
1482 if test "x$enable_glu" = xyes; then
1483     SRC_DIRS="$SRC_DIRS glu"
1484
1485     if test "x$enable_glx" = xno; then
1486         # Link libGLU to libOSMesa instead of libGL
1487         GLU_LIB_DEPS=""
1488         GLU_PC_REQ="osmesa"
1489         if test "$enable_static" = no; then
1490             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1491         else
1492             GLU_MESA_DEPS=""
1493         fi
1494     else
1495         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1496         GLU_PC_REQ="gl"
1497         GLU_PC_LIB_PRIV="-lm"
1498         if test "$enable_static" = no; then
1499             GLU_LIB_DEPS="-lm"
1500             GLU_MESA_DEPS='-l$(GL_LIB)'
1501         else
1502             GLU_LIB_DEPS=""
1503             GLU_MESA_DEPS=""
1504         fi
1505     fi
1506 fi
1507 if test "$enable_static" = no; then
1508     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1509 fi
1510 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1511 AC_SUBST([GLU_LIB_DEPS])
1512 AC_SUBST([GLU_MESA_DEPS])
1513 AC_SUBST([GLU_PC_REQ])
1514 AC_SUBST([GLU_PC_REQ_PRIV])
1515 AC_SUBST([GLU_PC_LIB_PRIV])
1516 AC_SUBST([GLU_PC_CFLAGS])
1517
1518 AC_SUBST([PROGRAM_DIRS])
1519
1520 dnl
1521 dnl Gallium configuration
1522 dnl
1523 if test "x$with_gallium_drivers" != x; then
1524     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1525 fi
1526 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1527
1528 AC_SUBST([LLVM_BINDIR])
1529 AC_SUBST([LLVM_CFLAGS])
1530 AC_SUBST([LLVM_CPPFLAGS])
1531 AC_SUBST([LLVM_CXXFLAGS])
1532 AC_SUBST([LLVM_LIBDIR])
1533 AC_SUBST([LLVM_LIBS])
1534 AC_SUBST([LLVM_LDFLAGS])
1535 AC_SUBST([LLVM_INCLUDEDIR])
1536 AC_SUBST([LLVM_VERSION])
1537 AC_SUBST([CLANG_RESOURCE_DIR])
1538
1539 case "x$enable_opengl$enable_gles1$enable_gles2" in
1540 x*yes*)
1541     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1542     ;;
1543 esac
1544
1545 AC_SUBST([VG_LIB_DEPS])
1546 AC_SUBST([EGL_CLIENT_APIS])
1547
1548 dnl
1549 dnl EGL Platforms configuration
1550 dnl
1551 AC_ARG_WITH([egl-platforms],
1552     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1553         [comma delimited native platforms libEGL supports, e.g.
1554         "x11,drm" @<:@default=auto@:>@])],
1555     [with_egl_platforms="$withval"],
1556     [if test "x$enable_egl" = xyes; then
1557         with_egl_platforms="x11"
1558     else
1559         with_egl_platforms=""
1560     fi])
1561
1562 EGL_PLATFORMS=""
1563
1564 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1565     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1566 fi
1567
1568 # Do per-EGL platform setups and checks
1569 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1570 for plat in $egl_platforms; do
1571         case "$plat" in
1572         fbdev|null)
1573                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1574                 ;;
1575
1576         wayland)
1577                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1578                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1579                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1580
1581                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1582                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1583                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1584                 ;;
1585
1586         x11)
1587                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1588                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1589                 save_LIBS="$LIBS"
1590                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1591                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1592                 LIBS="$save_LIBS"
1593                 ;;
1594
1595         drm)
1596                 test "x$enable_gbm" = "xno" &&
1597                         AC_MSG_ERROR([EGL platform drm needs gbm])
1598                 ;;
1599
1600         android|gdi)
1601                 ;;
1602
1603         *)
1604                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1605                 ;;
1606         esac
1607
1608         case "$plat$have_libudev" in
1609                 waylandno|drmno)
1610                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1611         esac
1612 done
1613
1614 # libEGL wants to default to the first platform specified in
1615 # ./configure.  parse that here.
1616 if test "x$egl_platforms" != "x"; then
1617     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1618     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1619 else
1620     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1621 fi
1622
1623 EGL_PLATFORMS="$egl_platforms"
1624
1625 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1626 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1627 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1628 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1629 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1630
1631 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1632 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1633
1634 AC_SUBST([EGL_NATIVE_PLATFORM])
1635 AC_SUBST([EGL_PLATFORMS])
1636 AC_SUBST([EGL_CFLAGS])
1637
1638 AC_ARG_WITH([egl-driver-dir],
1639     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1640                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1641     [EGL_DRIVER_INSTALL_DIR="$withval"],
1642     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1643 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1644
1645 AC_ARG_WITH([xorg-driver-dir],
1646     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1647                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1648     [XORG_DRIVER_INSTALL_DIR="$withval"],
1649     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1650 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1651
1652 AC_ARG_WITH([max-width],
1653     [AS_HELP_STRING([--with-max-width=N],
1654                     [Maximum framebuffer width (4096)])],
1655     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1656      AS_IF([test "${withval}" -gt "4096"],
1657            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1658 )
1659 AC_ARG_WITH([max-height],
1660     [AS_HELP_STRING([--with-max-height=N],
1661                     [Maximum framebuffer height (4096)])],
1662     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1663      AS_IF([test "${withval}" -gt "4096"],
1664            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1665 )
1666
1667 dnl
1668 dnl Gallium LLVM
1669 dnl
1670 AC_ARG_ENABLE([gallium-llvm],
1671     [AS_HELP_STRING([--enable-gallium-llvm],
1672         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1673     [enable_gallium_llvm="$enableval"],
1674     [enable_gallium_llvm=auto])
1675
1676 AC_ARG_WITH([llvm-shared-libs],
1677     [AS_HELP_STRING([--with-llvm-shared-libs],
1678         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1679     [with_llvm_shared_libs=yes],
1680     [with_llvm_shared_libs=no])
1681
1682 AC_ARG_WITH([llvm-prefix],
1683     [AS_HELP_STRING([--with-llvm-prefix],
1684         [Prefix for LLVM installations in non-standard locations])],
1685     [llvm_prefix="$withval"],
1686     [llvm_prefix=""])
1687
1688
1689 if test "x$with_gallium_drivers" = x; then
1690     enable_gallium_llvm=no
1691 fi
1692 if test "x$enable_gallium_llvm" = xauto; then
1693     case "$host_cpu" in
1694     i*86|x86_64) enable_gallium_llvm=yes;;
1695     esac
1696 fi
1697 if test "x$enable_gallium_llvm" = xyes; then
1698     if test "x$llvm_prefix" != x; then
1699         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1700     else
1701         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1702     fi
1703
1704     if test "x$LLVM_CONFIG" != xno; then
1705         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1706         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1707         if test "x$with_llvm_shared_libs" = xyes; then
1708             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1709             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1710         else
1711             LLVM_COMPONENTS="engine bitwriter"
1712             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1713                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1714             fi
1715             if test "x$enable_opencl" = xyes; then
1716                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1717             fi
1718             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1719         fi
1720         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1721         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1722         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1723         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1724         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1725         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1726         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1727         MESA_LLVM=1
1728
1729         dnl Check for Clang interanl headers
1730         if test "x$enable_opencl" = xyes; then
1731             if test "x$CLANG_LIBDIR" = x; then
1732                 CLANG_LIBDIR=${LLVM_LIBDIR}
1733             fi
1734             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1735             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1736                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1737         fi
1738     else
1739         MESA_LLVM=0
1740     fi
1741 else
1742     MESA_LLVM=0
1743 fi
1744
1745 dnl Directory for XVMC libs
1746 AC_ARG_WITH([xvmc-libdir],
1747     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1748         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1749     [XVMC_LIB_INSTALL_DIR="$withval"],
1750     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1751 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1752
1753 dnl
1754 dnl Gallium Tests
1755 dnl
1756 if test "x$enable_gallium_tests" = xyes; then
1757     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1758     enable_gallium_loader=yes
1759 fi
1760
1761 dnl Directory for VDPAU libs
1762 AC_ARG_WITH([vdpau-libdir],
1763     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1764         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1765     [VDPAU_LIB_INSTALL_DIR="$withval"],
1766     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1767 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1768
1769 dnl Directory for VA libs
1770 AC_ARG_WITH([va-libdir],
1771     [AS_HELP_STRING([--with-va-libdir=DIR],
1772         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1773     [VA_LIB_INSTALL_DIR="$withval"],
1774     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1775 AC_SUBST([VA_LIB_INSTALL_DIR])
1776
1777 dnl Directory for OpenCL libs
1778 AC_ARG_WITH([opencl-libdir],
1779     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1780         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1781     [OPENCL_LIB_INSTALL_DIR="$withval"],
1782     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1783 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1784
1785 dnl
1786 dnl Gallium helper functions
1787 dnl
1788 gallium_check_st() {
1789     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1790          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1791          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1792          if test "x$have_libdrm" != xyes; then
1793             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1794          fi
1795          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1796     fi
1797     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1798          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1799     fi
1800     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1801          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1802     fi
1803     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1804          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1805     fi
1806     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1807          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1808     fi
1809     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1810          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1811     fi
1812     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1813          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1814     fi
1815 }
1816
1817 gallium_require_llvm() {
1818     if test "x$MESA_LLVM" = x0; then
1819         case "$host_cpu" in
1820         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1821         esac
1822     fi
1823 }
1824
1825 gallium_require_drm_loader() {
1826     if test "x$enable_gallium_loader" = xyes; then
1827         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1828                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1829         if test "x$have_libdrm" != xyes; then
1830             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1831         fi
1832         enable_gallium_drm_loader=yes
1833     fi
1834 }
1835
1836 dnl Gallium drivers
1837 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1838 if test "x$with_gallium_drivers" != x; then
1839     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1840     for driver in $gallium_drivers; do
1841         case "x$driver" in
1842         xsvga)
1843             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1844             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1845             ;;
1846         xi915)
1847             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1848             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1849             if test "x$MESA_LLVM" = x1; then
1850                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1851             fi
1852             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1853             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1854             ;;
1855         xr300)
1856             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1857             gallium_require_llvm "Gallium R300"
1858             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1859             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1860             ;;
1861         xr600)
1862             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1863             gallium_require_drm_loader
1864             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1865             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1866                 if test "x$LLVM_VERSION" != "x3.1"; then
1867                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1868                 fi
1869                 NEED_RADEON_GALLIUM=yes;
1870             fi
1871             if test "x$enable_r600_llvm" = xyes; then
1872                 USE_R600_LLVM_COMPILER=yes;
1873             fi
1874             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1875                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1876             fi
1877             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1878             ;;
1879         xradeonsi)
1880             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1881             gallium_require_drm_loader
1882             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1883             if test "x$LLVM_VERSION" != "x3.1"; then
1884                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1885             fi
1886             NEED_RADEON_GALLIUM=yes;
1887             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1888             ;;
1889         xnouveau)
1890             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1891             gallium_require_drm_loader
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1893             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1894             ;;
1895         xswrast)
1896             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1897             if test "x$MESA_LLVM" = x1; then
1898                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1899             fi
1900
1901             if test "x$HAVE_ST_DRI" = xyes; then
1902                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1903             fi
1904             if test "x$HAVE_ST_VDPAU" = xyes; then
1905                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1906             fi
1907             if test "x$HAVE_ST_XVMC" = xyes; then
1908                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1909             fi
1910             if test "x$HAVE_ST_VA" = xyes; then
1911                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1912             fi
1913             if test "x$HAVE_ST_VDPAU" = xyes ||
1914                test "x$HAVE_ST_XVMC" = xyes ||
1915                test "x$HAVE_ST_VA" = xyes; then
1916                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1917                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1918                fi
1919             fi
1920             ;;
1921         *)
1922             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1923             ;;
1924         esac
1925     done
1926 fi
1927
1928 if test "x$enable_gallium_loader" = xyes; then
1929     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1930     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1931     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1932     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1933
1934     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1935         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1936         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1937     fi
1938
1939     if test "x$enable_gallium_drm_loader" = xyes; then
1940         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1941         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1942                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1943         if test "x$pipe_loader_have_xcb" = xyes; then
1944             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1945             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1946         fi
1947     fi
1948
1949     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1950     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1951 fi
1952
1953 dnl Tell Automake which drivers to build
1954 for driver in $GALLIUM_DRIVERS_DIRS; do
1955     case "x$driver" in
1956         xgalahad)
1957             HAVE_GALAHAD_GALLIUM=yes;
1958             ;;
1959         xidentity)
1960             HAVE_IDENTITY_GALLIUM=yes;
1961             ;;
1962         xnoop)
1963             HAVE_NOOP_GALLIUM=yes;
1964             ;;
1965         *)
1966             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1967             ;;
1968     esac
1969 done
1970
1971 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1972 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1973 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1974 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1975 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1976 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1977 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1978 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1979 AC_SUBST([GALLIUM_MAKE_DIRS])
1980
1981 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1982 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
1983
1984 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1985 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1986 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1987
1988 dnl prepend CORE_DIRS to SRC_DIRS
1989 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1990
1991 dnl Restore LDFLAGS and CPPFLAGS
1992 LDFLAGS="$_SAVE_LDFLAGS"
1993 CPPFLAGS="$_SAVE_CPPFLAGS"
1994
1995 dnl Add user CFLAGS and CXXFLAGS
1996 CFLAGS="$CFLAGS $USER_CFLAGS"
1997 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1998
1999 dnl Substitute the config
2000 AC_CONFIG_FILES([configs/current
2001                 Makefile
2002                 src/Makefile
2003                 src/gallium/Makefile
2004                 src/gallium/auxiliary/pipe-loader/Makefile
2005                 src/gallium/state_trackers/clover/Makefile
2006                 src/gallium/drivers/Makefile
2007                 src/gallium/drivers/r300/Makefile
2008                 src/gallium/drivers/r600/Makefile
2009                 src/gallium/targets/opencl/Makefile
2010                 src/gbm/Makefile
2011                 src/gbm/main/gbm.pc
2012                 src/egl/drivers/Makefile
2013                 src/egl/drivers/dri2/Makefile
2014                 src/egl/drivers/glx/Makefile
2015                 src/egl/Makefile
2016                 src/egl/main/Makefile
2017                 src/egl/main/egl.pc
2018                 src/egl/wayland/Makefile
2019                 src/egl/wayland/wayland-egl/Makefile
2020                 src/egl/wayland/wayland-egl/wayland-egl.pc
2021                 src/egl/wayland/wayland-drm/Makefile
2022                 src/glsl/Makefile
2023                 src/glsl/glcpp/Makefile
2024                 src/glsl/tests/Makefile
2025                 src/glx/Makefile
2026                 src/glx/tests/Makefile
2027                 src/mapi/es1api/Makefile
2028                 src/mapi/es1api/glesv1_cm.pc
2029                 src/mapi/es2api/Makefile
2030                 src/mapi/es2api/glesv2.pc
2031                 src/mapi/glapi/Makefile
2032                 src/mapi/glapi/gen/Makefile
2033                 src/mapi/shared-glapi/Makefile
2034                 src/mapi/glapi/tests/Makefile
2035                 src/mapi/shared-glapi/tests/Makefile
2036                 src/gtest/Makefile
2037                 src/mesa/Makefile
2038                 src/mesa/libdricore/Makefile
2039                 src/mesa/main/tests/Makefile
2040                 src/mesa/x86/Makefile
2041                 src/mesa/x86-64/Makefile
2042                 src/mesa/drivers/Makefile
2043                 src/mesa/drivers/dri/dri.pc
2044                 src/mesa/drivers/dri/Makefile
2045                 src/mesa/drivers/dri/common/Makefile
2046                 src/mesa/drivers/dri/i915/Makefile
2047                 src/mesa/drivers/dri/i965/Makefile
2048                 src/mesa/drivers/dri/nouveau/Makefile
2049                 src/mesa/drivers/dri/r200/Makefile
2050                 src/mesa/drivers/dri/radeon/Makefile
2051                 src/mesa/drivers/dri/swrast/Makefile
2052                 src/mesa/drivers/osmesa/Makefile
2053                 src/mesa/drivers/x11/Makefile
2054                 src/mesa/gl.pc
2055                 src/mesa/drivers/osmesa/osmesa.pc])
2056
2057 dnl Sort the dirs alphabetically
2058 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2059 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2060 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2061 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2062 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2063
2064 AC_OUTPUT
2065
2066 dnl
2067 dnl Output some configuration info for the user
2068 dnl
2069 echo ""
2070 echo "        prefix:          $prefix"
2071 echo "        exec_prefix:     $exec_prefix"
2072 echo "        libdir:          $libdir"
2073 echo "        includedir:      $includedir"
2074
2075 dnl API info
2076 echo ""
2077 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2078 echo "        OpenVG:          $enable_openvg"
2079
2080 dnl Driver info
2081 echo ""
2082 if test "x$enable_osmesa" != xno; then
2083         echo "        OSMesa:          lib$OSMESA_LIB"
2084 else
2085         echo "        OSMesa:          no"
2086 fi
2087
2088 if test "x$enable_dri" != xno; then
2089         # cleanup the drivers var
2090         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2091         if test "x$DRI_DIRS" = x; then
2092             echo "        DRI drivers:     no"
2093         else
2094             echo "        DRI drivers:     $dri_dirs"
2095         fi
2096         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2097 fi
2098
2099 case "x$enable_glx$enable_xlib_glx" in
2100 xyesyes)
2101     echo "        GLX:             Xlib-based"
2102     ;;
2103 xyesno)
2104     echo "        GLX:             DRI-based"
2105     ;;
2106 *)
2107     echo "        GLX:             $enable_glx"
2108     ;;
2109 esac
2110
2111 echo ""
2112 echo "        GLU:             $enable_glu"
2113
2114 dnl EGL
2115 echo ""
2116 echo "        EGL:             $enable_egl"
2117 if test "$enable_egl" = yes; then
2118     echo "        EGL platforms:   $EGL_PLATFORMS"
2119
2120     egl_drivers=""
2121     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2122         egl_drivers="$egl_drivers builtin:egl_glx"
2123     fi
2124     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2125         egl_drivers="$egl_drivers builtin:egl_dri2"
2126     fi
2127
2128     if test "x$HAVE_ST_EGL" = xyes; then
2129         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2130         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2131     else
2132         echo "        EGL drivers:    $egl_drivers"
2133     fi
2134 fi
2135
2136 echo ""
2137 if test "x$MESA_LLVM" = x1; then
2138     echo "        llvm:            yes"
2139     echo "        llvm-config:     $LLVM_CONFIG"
2140     echo "        llvm-version:    $LLVM_VERSION"
2141 else
2142     echo "        llvm:            no"
2143 fi
2144
2145 echo ""
2146 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2147     echo "        Gallium:         yes"
2148     echo "        Gallium dirs:    $GALLIUM_DIRS"
2149     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2150     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2151     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2152     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2153 else
2154     echo "        Gallium:         no"
2155 fi
2156
2157
2158 dnl Libraries
2159 echo ""
2160 echo "        Shared libs:     $enable_shared"
2161 echo "        Static libs:     $enable_static"
2162 echo "        Shared-glapi:    $enable_shared_glapi"
2163
2164 dnl Compiler options
2165 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2166 cflags=`echo $CFLAGS $PIC_FLAGS | \
2167     $SED 's/^ *//;s/  */ /;s/ *$//'`
2168 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2169     $SED 's/^ *//;s/  */ /;s/ *$//'`
2170 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2171 echo ""
2172 echo "        CFLAGS:          $cflags"
2173 echo "        CXXFLAGS:        $cxxflags"
2174 echo "        Macros:          $defines"
2175 echo ""
2176 echo "        PYTHON2:         $PYTHON2"
2177
2178 echo ""
2179 echo "        Run '${MAKE-make}' to build Mesa"
2180 echo ""