configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122
 123 dnl Check for compiler builtins
 124 AX_GCC_BUILTIN([__builtin_bswap32])
 125 AX_GCC_BUILTIN([__builtin_bswap64])
 126
 127 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 128
 129 dnl Make sure the pkg-config macros are defined
 130 m4_ifndef([PKG_PROG_PKG_CONFIG],
 131     [m4_fatal([Could not locate the pkg-config autoconf macros.
 132   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 133   are in a different location, try setting the environment variable
 134   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 135 PKG_PROG_PKG_CONFIG()
 136
 137 dnl LIB_DIR - library basename
 138 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 139 AC_SUBST([LIB_DIR])
 140
 141 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 142 _SAVE_LDFLAGS="$LDFLAGS"
 143 _SAVE_CPPFLAGS="$CPPFLAGS"
 144
 145 dnl Compiler macros
 146 DEFINES=""
 147 AC_SUBST([DEFINES])
 148 case "$host_os" in
 149 linux*|*-gnu*|gnu*)
 150     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 151     ;;
 152 solaris*)
 153     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 154     ;;
 155 cygwin*)
 156     DEFINES="$DEFINES -DHAVE_PTHREAD"
 157     ;;
 158 esac
 159
 160 dnl Add flags for gcc and g++
 161 if test "x$GCC" = xyes; then
 162     case "$host_os" in
 163     cygwin*)
 164         CFLAGS="$CFLAGS -Wall -std=gnu99"
 165         ;;
 166     *)
 167         CFLAGS="$CFLAGS -Wall -std=c99"
 168         ;;
 169     esac
 170
 171     # Enable -Werror=implicit-function-declaration and
 172     # -Werror=missing-prototypes, if available, or otherwise, just
 173     # -Wmissing-prototypes.  This is particularly useful to avoid
 174     # generating a loadable driver module that has undefined symbols.
 175     save_CFLAGS="$CFLAGS"
 176     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 177     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 178     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 179     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 180                    AC_MSG_RESULT([yes]),
 181                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 182                     AC_MSG_RESULT([no])]);
 183
 184     # Enable -fvisibility=hidden if using a gcc that supports it
 185     save_CFLAGS="$CFLAGS"
 186     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 187     VISIBILITY_CFLAGS="-fvisibility=hidden"
 188     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 190                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 191
 192     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 193     CFLAGS=$save_CFLAGS
 194
 195     # Work around aliasing bugs - developers should comment this out
 196     CFLAGS="$CFLAGS -fno-strict-aliasing"
 197
 198     # gcc's builtin memcmp is slower than glibc's
 199     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 200     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 201 fi
 202 if test "x$GXX" = xyes; then
 203     CXXFLAGS="$CXXFLAGS -Wall"
 204
 205     # Enable -fvisibility=hidden if using a gcc that supports it
 206     save_CXXFLAGS="$CXXFLAGS"
 207     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 208     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 209     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 210     AC_LANG_PUSH([C++])
 211     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 212                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 213     AC_LANG_POP([C++])
 214
 215     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 216     CXXFLAGS=$save_CXXFLAGS
 217
 218     # Work around aliasing bugs - developers should comment this out
 219     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 220
 221     # gcc's builtin memcmp is slower than glibc's
 222     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 223     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 224 fi
 225
 226 dnl even if the compiler appears to support it, using visibility attributes isn't
 227 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 228 case "$host_os" in
 229 cygwin*)
 230     VISIBILITY_CFLAGS=""
 231     VISIBILITY_CXXFLAGS=""
 232     ;;
 233 esac
 234
 235 AC_SUBST([VISIBILITY_CFLAGS])
 236 AC_SUBST([VISIBILITY_CXXFLAGS])
 237
 238 dnl
 239 dnl Optional flags, check for compiler support
 240 dnl
 241 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 242 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 243
 244 dnl
 245 dnl Hacks to enable 32 or 64 bit build
 246 dnl
 247 AC_ARG_ENABLE([32-bit],
 248     [AS_HELP_STRING([--enable-32-bit],
 249         [build 32-bit libraries @<:@default=auto@:>@])],
 250     [enable_32bit="$enableval"],
 251     [enable_32bit=auto]
 252 )
 253 if test "x$enable_32bit" = xyes; then
 254     if test "x$GCC" = xyes; then
 255         CFLAGS="$CFLAGS -m32"
 256         CCASFLAGS="$CCASFLAGS -m32"
 257     fi
 258     if test "x$GXX" = xyes; then
 259         CXXFLAGS="$CXXFLAGS -m32"
 260     fi
 261 fi
 262 AC_ARG_ENABLE([64-bit],
 263     [AS_HELP_STRING([--enable-64-bit],
 264         [build 64-bit libraries @<:@default=auto@:>@])],
 265     [enable_64bit="$enableval"],
 266     [enable_64bit=auto]
 267 )
 268 if test "x$enable_64bit" = xyes; then
 269     if test "x$GCC" = xyes; then
 270         CFLAGS="$CFLAGS -m64"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m64"
 274     fi
 275 fi
 276
 277 dnl Can't have static and shared libraries, default to static if user
 278 dnl explicitly requested. If both disabled, set to static since shared
 279 dnl was explicitly requested.
 280 case "x$enable_static$enable_shared" in
 281 xyesyes )
 282     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 283     enable_shared=no
 284     ;;
 285 xnono )
 286     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 287     enable_static=yes
 288     ;;
 289 esac
 290
 291 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 292
 293 dnl
 294 dnl other compiler options
 295 dnl
 296 AC_ARG_ENABLE([debug],
 297     [AS_HELP_STRING([--enable-debug],
 298         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 299     [enable_debug="$enableval"],
 300     [enable_debug=no]
 301 )
 302 if test "x$enable_debug" = xyes; then
 303     DEFINES="$DEFINES -DDEBUG"
 304     if test "x$GCC" = xyes; then
 305         CFLAGS="$CFLAGS -g -O0"
 306     fi
 307     if test "x$GXX" = xyes; then
 308         CXXFLAGS="$CXXFLAGS -g -O0"
 309     fi
 310 fi
 311
 312 dnl
 313 dnl library names
 314 dnl
 315 LIB_PREFIX_GLOB='lib'
 316 LIB_VERSION_SEPARATOR='.'
 317 if test "$enable_static" = yes; then
 318     LIB_EXTENSION='a'
 319 else
 320     case "$host_os" in
 321     darwin* )
 322         LIB_EXTENSION='dylib' ;;
 323     cygwin* )
 324         dnl prefix can be 'cyg' or 'lib'
 325         LIB_PREFIX_GLOB='???'
 326         LIB_VERSION_SEPARATOR='-'
 327         LIB_EXTENSION='dll' ;;
 328     aix* )
 329         LIB_EXTENSION='a' ;;
 330     * )
 331         LIB_EXTENSION='so' ;;
 332     esac
 333 fi
 334 AC_ARG_WITH([gl-lib-name],
 335   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 336     [specify GL library name @<:@default=GL@:>@])],
 337   [GL_LIB=$withval],
 338   [GL_LIB=GL])
 339 AC_ARG_WITH([osmesa-lib-name],
 340   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 341     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 342   [OSMESA_LIB=$withval],
 343   [OSMESA_LIB=OSMesa])
 344 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 345 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 346
 347 dnl
 348 dnl Mangled Mesa support
 349 dnl
 350 AC_ARG_ENABLE([mangling],
 351   [AS_HELP_STRING([--enable-mangling],
 352     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 353   [enable_mangling="${enableval}"],
 354   [enable_mangling=no]
 355 )
 356 if test "x${enable_mangling}" = "xyes" ; then
 357   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 358   GL_LIB="Mangled${GL_LIB}"
 359   OSMESA_LIB="Mangled${OSMESA_LIB}"
 360 fi
 361 AC_SUBST([GL_LIB])
 362 AC_SUBST([OSMESA_LIB])
 363
 364 dnl
 365 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 366 dnl
 367 AC_ARG_ENABLE([texture-float],
 368     [AS_HELP_STRING([--enable-texture-float],
 369         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 370     [enable_texture_float="$enableval"],
 371     [enable_texture_float=no]
 372 )
 373 if test "x$enable_texture_float" = xyes; then
 374     AC_MSG_WARN([Floating-point textures enabled.])
 375     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 376     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 377 fi
 378
 379 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 380 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 381 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 382 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 383 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 384 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 385 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 386
 387 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 388 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 389 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 390 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 391 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 392 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 393 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 394
 395 AC_SUBST([GL_LIB_NAME])
 396 AC_SUBST([OSMESA_LIB_NAME])
 397 AC_SUBST([EGL_LIB_NAME])
 398 AC_SUBST([GLESv1_CM_LIB_NAME])
 399 AC_SUBST([GLESv2_LIB_NAME])
 400 AC_SUBST([VG_LIB_NAME])
 401 AC_SUBST([GLAPI_LIB_NAME])
 402
 403 AC_SUBST([GL_LIB_GLOB])
 404 AC_SUBST([EGL_LIB_GLOB])
 405 AC_SUBST([GLESv1_CM_LIB_GLOB])
 406 AC_SUBST([GLESv2_LIB_GLOB])
 407 AC_SUBST([VG_LIB_GLOB])
 408 AC_SUBST([GLAPI_LIB_GLOB])
 409
 410 dnl
 411 dnl Arch/platform-specific settings
 412 dnl
 413 AC_ARG_ENABLE([asm],
 414     [AS_HELP_STRING([--disable-asm],
 415         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 416     [enable_asm="$enableval"],
 417     [enable_asm=yes]
 418 )
 419 asm_arch=""
 420 AC_MSG_CHECKING([whether to enable assembly])
 421 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 422 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 423 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 424     case "$host_cpu" in
 425     i?86 | x86_64 | amd64)
 426         enable_asm=no
 427         AC_MSG_RESULT([no, cross compiling])
 428         ;;
 429     esac
 430 fi
 431 # check for supported arches
 432 if test "x$enable_asm" = xyes; then
 433     case "$host_cpu" in
 434     i?86)
 435         case "$host_os" in
 436         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 437             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 438             ;;
 439         gnu*)
 440             asm_arch=x86
 441             ;;
 442         esac
 443         ;;
 444     x86_64|amd64)
 445         case "$host_os" in
 446         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 447             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 448             ;;
 449         esac
 450         ;;
 451     sparc*)
 452         case "$host_os" in
 453         linux*)
 454             asm_arch=sparc
 455             ;;
 456         esac
 457         ;;
 458     esac
 459
 460     case "$asm_arch" in
 461     x86)
 462         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 463         AC_MSG_RESULT([yes, x86])
 464         ;;
 465     x86_64|amd64)
 466         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 467         AC_MSG_RESULT([yes, x86_64])
 468         ;;
 469     sparc)
 470         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 471         AC_MSG_RESULT([yes, sparc])
 472         ;;
 473     *)
 474         AC_MSG_RESULT([no, platform not supported])
 475         ;;
 476     esac
 477 fi
 478
 479 dnl Check to see if dlopen is in default libraries (like Solaris, which
 480 dnl has it in libc), or if libdl is needed to get it.
 481 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 482     [AC_CHECK_LIB([dl], [dlopen],
 483        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 484 AC_SUBST([DLOPEN_LIBS])
 485
 486 case "$host_os" in
 487 darwin*|mingw*)
 488     ;;
 489 *)
 490     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 491                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 492                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 493     AC_SUBST([CLOCK_LIB])
 494     ;;
 495 esac
 496
 497 dnl See if posix_memalign is available
 498 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 499
 500 dnl Check for pthreads
 501 AX_PTHREAD
 502 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 503 dnl to -pthread, which causes problems if we need -lpthread to appear in
 504 dnl pkgconfig files.
 505 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 506
 507 dnl SELinux awareness.
 508 AC_ARG_ENABLE([selinux],
 509     [AS_HELP_STRING([--enable-selinux],
 510         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 511     [MESA_SELINUX="$enableval"],
 512     [MESA_SELINUX=no])
 513 if test "x$enable_selinux" = "xyes"; then
 514     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 515         [AC_CHECK_HEADER([selinux/selinux.h],[],
 516                          [AC_MSG_ERROR([SELinux headers not found])])
 517          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 518                       [AC_MSG_ERROR([SELinux library not found])])
 519          SELINUX_LIBS="-lselinux"])
 520     DEFINES="$DEFINES -DMESA_SELINUX"
 521 fi
 522 AC_SUBST([SELINUX_CFLAGS])
 523 AC_SUBST([SELINUX_LIBS])
 524
 525 dnl Options for APIs
 526 AC_ARG_ENABLE([opengl],
 527     [AS_HELP_STRING([--disable-opengl],
 528         [disable support for standard OpenGL API @<:@default=no@:>@])],
 529     [enable_opengl="$enableval"],
 530     [enable_opengl=yes])
 531 AC_ARG_ENABLE([gles1],
 532     [AS_HELP_STRING([--enable-gles1],
 533         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 534     [enable_gles1="$enableval"],
 535     [enable_gles1=no])
 536 AC_ARG_ENABLE([gles2],
 537     [AS_HELP_STRING([--enable-gles2],
 538         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 539     [enable_gles2="$enableval"],
 540     [enable_gles2=no])
 541 AC_ARG_ENABLE([openvg],
 542     [AS_HELP_STRING([--enable-openvg],
 543         [enable support for OpenVG API @<:@default=no@:>@])],
 544     [enable_openvg="$enableval"],
 545     [enable_openvg=no])
 546
 547 AC_ARG_ENABLE([dri],
 548     [AS_HELP_STRING([--enable-dri],
 549         [enable DRI modules @<:@default=enabled@:>@])],
 550     [enable_dri="$enableval"],
 551     [enable_dri=yes])
 552 AC_ARG_ENABLE([dri3],
 553     [AS_HELP_STRING([--enable-dri3],
 554         [enable DRI3 @<:@default=enabled@:>@])],
 555     [enable_dri3="$enableval"],
 556     [enable_dri3=yes])
 557 AC_ARG_ENABLE([glx],
 558     [AS_HELP_STRING([--enable-glx],
 559         [enable GLX library @<:@default=enabled@:>@])],
 560     [enable_glx="$enableval"],
 561     [enable_glx=yes])
 562 AC_ARG_ENABLE([osmesa],
 563     [AS_HELP_STRING([--enable-osmesa],
 564         [enable OSMesa library @<:@default=disabled@:>@])],
 565     [enable_osmesa="$enableval"],
 566     [enable_osmesa=no])
 567 AC_ARG_ENABLE([gallium-osmesa],
 568     [AS_HELP_STRING([--enable-gallium-osmesa],
 569         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 570     [enable_gallium_osmesa="$enableval"],
 571     [enable_gallium_osmesa=no])
 572 AC_ARG_ENABLE([egl],
 573     [AS_HELP_STRING([--disable-egl],
 574         [disable EGL library @<:@default=enabled@:>@])],
 575     [enable_egl="$enableval"],
 576     [enable_egl=yes])
 577
 578 AC_ARG_ENABLE([xa],
 579     [AS_HELP_STRING([--enable-xa],
 580         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 581     [enable_xa="$enableval"],
 582     [enable_xa=no])
 583 AC_ARG_ENABLE([gbm],
 584    [AS_HELP_STRING([--enable-gbm],
 585          [enable gbm library @<:@default=auto@:>@])],
 586    [enable_gbm="$enableval"],
 587    [enable_gbm=auto])
 588
 589 AC_ARG_ENABLE([xvmc],
 590    [AS_HELP_STRING([--enable-xvmc],
 591          [enable xvmc library @<:@default=auto@:>@])],
 592    [enable_xvmc="$enableval"],
 593    [enable_xvmc=no])
 594 AC_ARG_ENABLE([vdpau],
 595    [AS_HELP_STRING([--enable-vdpau],
 596          [enable vdpau library @<:@default=auto@:>@])],
 597    [enable_vdpau="$enableval"],
 598    [enable_vdpau=auto])
 599 AC_ARG_ENABLE([omx],
 600    [AS_HELP_STRING([--enable-omx],
 601          [enable OpenMAX library @<:@default=no@:>@])],
 602    [enable_omx="$enableval"],
 603    [enable_omx=no])
 604 AC_ARG_ENABLE([opencl],
 605    [AS_HELP_STRING([--enable-opencl],
 606          [enable OpenCL library NOTE: Enabling this option will also enable
 607           --with-llvm-shared-libs
 608           @<:@default=no@:>@])],
 609    [],
 610    [enable_opencl=no])
 611 AC_ARG_ENABLE([opencl_icd],
 612    [AS_HELP_STRING([--enable-opencl-icd],
 613           [Build an OpenCL ICD library to be loaded by an ICD implementation
 614            @<:@default=no@:>@])],
 615     [enable_opencl_icd="$enableval"],
 616     [enable_opencl_icd=no])
 617 AC_ARG_ENABLE([xlib-glx],
 618     [AS_HELP_STRING([--enable-xlib-glx],
 619         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 620     [enable_xlib_glx="$enableval"],
 621     [enable_xlib_glx=no])
 622 AC_ARG_ENABLE([gallium-egl],
 623     [AS_HELP_STRING([--enable-gallium-egl],
 624         [enable optional EGL state tracker (not required
 625          for EGL support in Gallium with OpenGL and OpenGL ES)
 626          @<:@default=disable@:>@])],
 627     [enable_gallium_egl="$enableval"],
 628     [enable_gallium_egl=no])
 629 AC_ARG_ENABLE([gallium-gbm],
 630     [AS_HELP_STRING([--enable-gallium-gbm],
 631         [enable optional gbm state tracker (not required for
 632          gbm support in Gallium)
 633          @<:@default=auto@:>@])],
 634     [enable_gallium_gbm="$enableval"],
 635     [enable_gallium_gbm=auto])
 636
 637 AC_ARG_ENABLE([r600-llvm-compiler],
 638     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 639         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 640     [enable_r600_llvm="$enableval"],
 641     [enable_r600_llvm=no])
 642
 643 AC_ARG_ENABLE([gallium-tests],
 644     [AS_HELP_STRING([--enable-gallium-tests],
 645         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 646     [enable_gallium_tests="$enableval"],
 647     [enable_gallium_tests=no])
 648
 649 # Option for Gallium drivers
 650
 651 # Keep this in sync with the --with-gallium-drivers help string default value
 652 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 653
 654 AC_ARG_WITH([gallium-drivers],
 655     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 656         [comma delimited Gallium drivers list, e.g.
 657         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 658         @<:@default=r300,r600,svga,swrast@:>@])],
 659     [with_gallium_drivers="$withval"],
 660     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 661
 662 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 663 # here so that the script doesn't choke on an unknown driver name later.
 664 case "$with_gallium_drivers" in
 665     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 666     no) with_gallium_drivers='' ;;
 667 esac
 668
 669 if test "x$enable_opengl" = xno -a \
 670         "x$enable_gles1" = xno -a \
 671         "x$enable_gles2" = xno -a \
 672         "x$enable_openvg" = xno -a \
 673         "x$enable_xa" = xno -a \
 674         "x$enable_xvmc" = xno -a \
 675         "x$enable_vdpau" = xno -a \
 676         "x$enable_omx" = xno -a \
 677         "x$enable_opencl" = xno; then
 678     AC_MSG_ERROR([at least one API should be enabled])
 679 fi
 680
 681 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 682 if test "x$enable_opengl" = xno -a \
 683         "x$enable_gles1" = xyes; then
 684     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 685 fi
 686
 687 if test "x$enable_opengl" = xno -a \
 688         "x$enable_gles2" = xyes; then
 689     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 690 fi
 691
 692 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 693 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 694 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 695 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 696                                         "x$enable_gles1" = xyes -o \
 697                                         "x$enable_gles2" = xyes)
 698
 699 if test "x$enable_glx" = xno; then
 700     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 701     enable_xlib_glx=no
 702 fi
 703
 704 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 705     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 706 fi
 707
 708 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 709     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 710 fi
 711
 712 # Disable GLX if OpenGL is not enabled
 713 if test "x$enable_glx$enable_opengl" = xyesno; then
 714     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 715     enable_glx=no
 716 fi
 717
 718 # Disable GLX if DRI and Xlib-GLX are not enabled
 719 if test "x$enable_glx" = xyes -a \
 720         "x$enable_dri" = xno -a \
 721         "x$enable_xlib_glx" = xno; then
 722     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 723     enable_glx=no
 724 fi
 725
 726 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 727                                   "x$enable_dri" = xyes)
 728 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 729 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 730
 731 AC_ARG_ENABLE([shared-glapi],
 732     [AS_HELP_STRING([--enable-shared-glapi],
 733         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 734     [enable_shared_glapi="$enableval"],
 735     [enable_shared_glapi=yes])
 736
 737 case "x$enable_opengl$enable_gles1$enable_gles2" in
 738 x*yes*yes*)
 739     if test "x$enable_shared_glapi" = xno; then
 740         AC_MSG_ERROR([shared GLAPI required when building two or more of
 741                       the following APIs - opengl, gles1 gles2])
 742     fi
 743     ;;
 744 esac
 745
 746 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 747
 748 dnl
 749 dnl Driver specific build directories
 750 dnl
 751 GALLIUM_TARGET_DIRS=""
 752 GALLIUM_WINSYS_DIRS="sw"
 753 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 754 GALLIUM_STATE_TRACKERS_DIRS=""
 755
 756 case "x$enable_glx$enable_xlib_glx" in
 757 xyesyes)
 758     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 759     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 760     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 761     NEED_WINSYS_XLIB="yes"
 762     ;;
 763 esac
 764
 765 if test "x$enable_dri" = xyes; then
 766     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 767     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 768 fi
 769
 770 if test "x$enable_gallium_osmesa" = xyes; then
 771     if test -z "$with_gallium_drivers"; then
 772         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 773     fi
 774     if test "x$enable_osmesa" = xyes; then
 775         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 776     fi
 777     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 778     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 779 fi
 780
 781 AC_SUBST([MESA_LLVM])
 782
 783 # Check for libdrm
 784 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 785                   [have_libdrm=yes], [have_libdrm=no])
 786 if test "x$have_libdrm" = xyes; then
 787         DEFINES="$DEFINES -DHAVE_LIBDRM"
 788 fi
 789
 790 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 791                   have_libudev=yes, have_libudev=no)
 792
 793 if test "x$enable_dri" = xyes; then
 794     # DRI must be shared, I think
 795     if test "$enable_static" = yes; then
 796         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 797     fi
 798
 799     # not a hard requirement as swrast does not depend on it
 800     if test "x$have_libdrm" = xyes; then
 801         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 802     fi
 803 fi
 804
 805 dnl Direct rendering or just indirect rendering
 806 case "$host_os" in
 807 gnu*)
 808     dnl Disable by default on GNU/Hurd
 809     driglx_direct_default="no"
 810     ;;
 811 cygwin*)
 812     dnl Disable by default on cygwin
 813     driglx_direct_default="no"
 814     ;;
 815 *)
 816     driglx_direct_default="yes"
 817     ;;
 818 esac
 819 AC_ARG_ENABLE([driglx-direct],
 820     [AS_HELP_STRING([--disable-driglx-direct],
 821         [disable direct rendering in GLX and EGL for DRI \
 822             @<:@default=auto@:>@])],
 823     [driglx_direct="$enableval"],
 824     [driglx_direct="$driglx_direct_default"])
 825
 826 dnl
 827 dnl libGL configuration per driver
 828 dnl
 829 case "x$enable_glx$enable_xlib_glx" in
 830 xyesyes)
 831     # Xlib-based GLX
 832     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 833     GL_PC_REQ_PRIV="x11 xext"
 834     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 835     GL_LIB_DEPS="$XLIBGL_LIBS"
 836     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 837     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 838     ;;
 839 xyesno)
 840     # DRI-based GLX
 841     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 842     if test x"$driglx_direct" = xyes; then
 843         if test "x$have_libdrm" != xyes; then
 844             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 845         fi
 846         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 847         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 848         if test x"$enable_dri3" = xyes; then
 849             if test x"$have_libudev" != xyes; then
 850               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 851             fi
 852             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 853             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 854         fi
 855     fi
 856
 857     # find the DRI deps for libGL
 858     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 859
 860     if test x"$enable_dri3" = xyes; then
 861         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= 1.1"
 862     fi
 863
 864     # add xf86vidmode if available
 865     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 866     if test "$HAVE_XF86VIDMODE" = yes ; then
 867         dri_modules="$dri_modules xxf86vm"
 868     fi
 869
 870     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 871     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 872     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 873     GL_LIB_DEPS="$DRIGL_LIBS"
 874
 875     # need DRM libs, $PTHREAD_LIBS, etc.
 876     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 877     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 878     ;;
 879 esac
 880
 881 if test "$have_libudev" = yes; then
 882     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 883 fi
 884
 885 # This is outside the case (above) so that it is invoked even for non-GLX
 886 # builds.
 887 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 888
 889 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 890 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 891 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 892 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 893
 894 AC_SUBST([X11_INCLUDES])
 895 AC_SUBST([GL_LIB_DEPS])
 896 AC_SUBST([GL_PC_REQ_PRIV])
 897 AC_SUBST([GL_PC_LIB_PRIV])
 898 AC_SUBST([GL_PC_CFLAGS])
 899 AC_SUBST([DRI_PC_REQ_PRIV])
 900 AC_SUBST([GLESv1_CM_LIB_DEPS])
 901 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 902 AC_SUBST([GLESv2_LIB_DEPS])
 903 AC_SUBST([GLESv2_PC_LIB_PRIV])
 904
 905 AC_SUBST([HAVE_XF86VIDMODE])
 906
 907 dnl
 908 dnl More GLX setup
 909 dnl
 910 case "x$enable_glx$enable_xlib_glx" in
 911 xyesyes)
 912     DEFINES="$DEFINES -DUSE_XSHM"
 913     ;;
 914 xyesno)
 915     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 916     if test "x$driglx_direct" = xyes; then
 917         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 918     fi
 919     ;;
 920 esac
 921
 922 dnl
 923 dnl TLS detection
 924 dnl
 925
 926 AC_ARG_ENABLE([glx-tls],
 927     [AS_HELP_STRING([--enable-glx-tls],
 928         [enable TLS support in GLX @<:@default=disabled@:>@])],
 929     [GLX_USE_TLS="$enableval"],
 930     [GLX_USE_TLS=no])
 931 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 932
 933 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 934       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 935
 936 dnl
 937 dnl More DRI setup
 938 dnl
 939 dnl Directory for DRI drivers
 940 AC_ARG_WITH([dri-driverdir],
 941     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 942         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 943     [DRI_DRIVER_INSTALL_DIR="$withval"],
 944     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 945 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 946 dnl Extra search path for DRI drivers
 947 AC_ARG_WITH([dri-searchpath],
 948     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 949         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 950     [DRI_DRIVER_SEARCH_DIR="$withval"],
 951     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 952 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 953 dnl Which drivers to build - default is chosen by platform
 954 AC_ARG_WITH([dri-drivers],
 955     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 956         [comma delimited classic DRI drivers list, e.g.
 957         "swrast,i965,radeon" @<:@default=auto@:>@])],
 958     [with_dri_drivers="$withval"],
 959     [with_dri_drivers=auto])
 960
 961 if test "x$with_dri_drivers" = xauto; then
 962     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 963         with_dri_drivers="yes"
 964     else
 965         with_dri_drivers="no"
 966     fi
 967 fi
 968
 969 dnl If $with_dri_drivers is yes, drivers will be added through
 970 dnl platform checks. Set DEFINES and LIB_DEPS
 971 if test "x$enable_dri" = xyes; then
 972     # Platform specific settings and drivers to build
 973     case "$host_os" in
 974     linux*)
 975         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 976         DEFINES="$DEFINES -DHAVE_ALIAS"
 977         if test "x$enable_dri3" = xyes; then
 978             DEFINES="$DEFINES -DHAVE_DRI3"
 979         fi
 980
 981         case "$host_cpu" in
 982         powerpc* | sparc*)
 983             # Build only the drivers for cards that exist on PowerPC/sparc
 984             if test "x$with_dri_drivers" = "xyes"; then
 985                 with_dri_drivers="r200 radeon swrast"
 986             fi
 987             ;;
 988         esac
 989         ;;
 990     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 991         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 992         DEFINES="$DEFINES -DHAVE_ALIAS"
 993         ;;
 994     gnu*)
 995         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 996         DEFINES="$DEFINES -DHAVE_ALIAS"
 997         ;;
 998     solaris*)
 999         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1000         ;;
1001     cygwin*)
1002         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1003         if test "x$with_dri_drivers" = "xyes"; then
1004             with_dri_drivers="swrast"
1005         fi
1006         ;;
1007     esac
1008
1009     # default drivers
1010     if test "x$with_dri_drivers" = "xyes"; then
1011         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1012     fi
1013
1014     # Check for expat
1015     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1016     if test "x$have_expat" = "xyes"; then
1017        PKG_CHECK_MODULES([EXPAT], [expat], [],
1018                          AC_MSG_ERROR([Expat required for DRI.]))
1019     else
1020        # expat version 2.0 and earlier do not provide expat.pc
1021        EXPAT_LIBS=-lexpat
1022     fi
1023
1024     # If we are building any DRI driver other than swrast.
1025     if test -n "$with_dri_drivers"; then
1026         if test "x$with_dri_drivers" != xswrast; then
1027             # ... libdrm is required
1028             if test "x$have_libdrm" != xyes; then
1029                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1030             fi
1031             DRICOMMON_NEED_LIBDRM=yes
1032         else
1033             DRICOMMON_NEED_LIBDRM=no
1034         fi
1035     fi
1036
1037     # put all the necessary libs together
1038     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1039     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1040
1041 fi
1042
1043 AC_SUBST([DRI_LIB_DEPS])
1044 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1045
1046 DRI_DIRS=""
1047 dnl Duplicates in DRI_DIRS are removed by sorting it after this block
1048 if test "x$with_dri_drivers" != xno; then
1049     if test "x$enable_opengl" != xyes; then
1050         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1051     fi
1052
1053     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1054     for driver in $dri_drivers; do
1055         DRI_DIRS+="$driver "
1056         case "x$driver" in
1057         xi915)
1058             HAVE_I915_DRI=yes;
1059             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1060             ;;
1061         xi965)
1062             HAVE_I965_DRI=yes;
1063             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1064             ;;
1065         xnouveau)
1066             HAVE_NOUVEAU_DRI=yes;
1067             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1068             ;;
1069         xradeon)
1070             HAVE_RADEON_DRI=yes;
1071             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1072             ;;
1073         xr200)
1074             HAVE_R200_DRI=yes;
1075             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1076             ;;
1077         xswrast)
1078             HAVE_SWRAST_DRI=yes;
1079             ;;
1080         *)
1081             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1082             ;;
1083         esac
1084     done
1085 fi
1086 DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1087
1088 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1089 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1090                                   "x$enable_osmesa" = xyes -o \
1091                                   -n "$DRI_DIRS")
1092
1093 dnl
1094 dnl OSMesa configuration
1095 dnl
1096
1097 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1098 AC_ARG_WITH([osmesa-bits],
1099     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1100         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1101     [osmesa_bits="$withval"],
1102     [osmesa_bits=8])
1103 if test "x$osmesa_bits" != x8; then
1104     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1105         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1106         osmesa_bits=8
1107     fi
1108 fi
1109 case "x$osmesa_bits" in
1110 x8)
1111     OSMESA_LIB="${OSMESA_LIB}"
1112     ;;
1113 x16|x32)
1114     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1115     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1116     ;;
1117 *)
1118     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1119     ;;
1120 esac
1121
1122 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1123     # only link libraries with osmesa if shared
1124     if test "$enable_static" = no; then
1125         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1126     else
1127         OSMESA_LIB_DEPS=""
1128     fi
1129     OSMESA_MESA_DEPS=""
1130     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1131 fi
1132
1133 AC_SUBST([OSMESA_LIB_DEPS])
1134 AC_SUBST([OSMESA_MESA_DEPS])
1135 AC_SUBST([OSMESA_PC_REQ])
1136 AC_SUBST([OSMESA_PC_LIB_PRIV])
1137
1138 dnl
1139 dnl gbm configuration
1140 dnl
1141 if test "x$enable_gbm" = xauto; then
1142     case "$with_egl_platforms" in
1143         *drm*)
1144             enable_gbm=yes ;;
1145          *)
1146             enable_gbm=no ;;
1147     esac
1148 fi
1149 if test "x$enable_gbm" = xyes; then
1150     if test x"$have_libudev" != xyes; then
1151         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1152     fi
1153
1154     if test "x$enable_dri" = xyes; then
1155         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1156         if test "x$enable_shared_glapi" = xno; then
1157             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1158         fi
1159     fi
1160 fi
1161 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1162 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1163 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1164 AC_SUBST([GBM_PC_REQ_PRIV])
1165 AC_SUBST([GBM_PC_LIB_PRIV])
1166
1167 dnl
1168 dnl EGL configuration
1169 dnl
1170 EGL_CLIENT_APIS=""
1171
1172 if test "x$enable_egl" = xyes; then
1173     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1174
1175     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1176
1177     if test "$enable_static" != yes; then
1178         if test "x$enable_dri" = xyes; then
1179             HAVE_EGL_DRIVER_DRI2=1
1180         fi
1181
1182     fi
1183 fi
1184 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1185 AC_SUBST([EGL_LIB_DEPS])
1186
1187 dnl
1188 dnl EGL Gallium configuration
1189 dnl
1190 if test "x$enable_gallium_egl" = xyes; then
1191     if test -z "$with_gallium_drivers"; then
1192         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1193     fi
1194     if test "x$enable_egl" = xno; then
1195         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1196     fi
1197     if test "x$have_libdrm" != xyes; then
1198         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1199     fi
1200
1201     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1202     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1203 fi
1204 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1205
1206 dnl
1207 dnl gbm Gallium configuration
1208 dnl
1209 if test "x$enable_gallium_gbm" = xauto; then
1210     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1211         yesyesyes*drm*)
1212             enable_gallium_gbm=yes ;;
1213          *)
1214             enable_gallium_gbm=no ;;
1215     esac
1216 fi
1217 if test "x$enable_gallium_gbm" = xyes; then
1218     if test -z "$with_gallium_drivers"; then
1219         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1220     fi
1221     if test "x$enable_gbm" = xno; then
1222         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1223     fi
1224     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1225     if test "x$enable_dri" = xno; then
1226         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1227     fi
1228
1229     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1230     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1231     enable_gallium_loader=yes
1232 fi
1233 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1234
1235 dnl
1236 dnl XA configuration
1237 dnl
1238 if test "x$enable_xa" = xyes; then
1239     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1240     enable_gallium_loader=yes
1241     enable_gallium_drm_loader=yes
1242 fi
1243 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1244
1245 dnl
1246 dnl OpenVG configuration
1247 dnl
1248 VG_LIB_DEPS=""
1249
1250 if test "x$enable_openvg" = xyes; then
1251     if test "x$enable_egl" = xno; then
1252         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1253     fi
1254     if test -z "$with_gallium_drivers"; then
1255         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1256     fi
1257     if test "x$enable_gallium_egl" = xno; then
1258         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1259     fi
1260
1261     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1262     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1263     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1264     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1265     AC_SUBST([VG_PC_LIB_PRIV])
1266 fi
1267 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1268
1269 dnl
1270 dnl Gallium G3DVL configuration
1271 dnl
1272 if test -n "$with_gallium_drivers"; then
1273     if test "x$enable_xvmc" = xauto; then
1274         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1275     fi
1276
1277     if test "x$enable_vdpau" = xauto; then
1278         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1279     fi
1280
1281     if test "x$enable_omx" = xauto; then
1282         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1283     fi
1284 fi
1285
1286 if test "x$enable_xvmc" = xyes; then
1287     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1288     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1289 fi
1290 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1291
1292 if test "x$enable_vdpau" = xyes; then
1293     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8],
1294                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1295     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1296 fi
1297 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1298
1299 if test "x$enable_omx" = xyes; then
1300     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= 0.0 x11-xcb xcb-dri2 >= 1.8])
1301     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1302 fi
1303 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1304
1305 dnl
1306 dnl OpenCL configuration
1307 dnl
1308
1309 AC_ARG_WITH([libclc-path],
1310    [AS_HELP_STRING([--with-libclc-path],
1311          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1312    [LIBCLC_PATH="$withval"],
1313    [LIBCLC_PATH=""])
1314
1315 if test -n "$LIBCLC_PATH"; then
1316    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1317                   Please review the updated build instructions for clover:
1318                   http://dri.freedesktop.org/wiki/GalliumCompute])
1319 fi
1320
1321
1322 AC_ARG_WITH([clang-libdir],
1323    [AS_HELP_STRING([--with-clang-libdir],
1324          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1325    [CLANG_LIBDIR="$withval"],
1326    [CLANG_LIBDIR=""])
1327
1328 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1329
1330 if test "x$enable_opencl" = xyes; then
1331     if test -z "$with_gallium_drivers"; then
1332         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1333     fi
1334
1335     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1336         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1337     fi
1338
1339     if test "x$have_libclc" = xno; then
1340         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1341                     Make sure the directory containing libclc.pc is specified in your
1342                     PKG_CONFIG_PATH environment variable.
1343                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1344     else
1345         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1346         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1347         AC_SUBST([LIBCLC_INCLUDEDIR])
1348         AC_SUBST([LIBCLC_LIBEXECDIR])
1349     fi
1350
1351     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1352     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1353     enable_gallium_loader=yes
1354
1355     if test "x$enable_opencl_icd" = xyes; then
1356         OPENCL_LIBNAME="MesaOpenCL"
1357     else
1358         OPENCL_LIBNAME="OpenCL"
1359     fi
1360 fi
1361 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1362 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1363 AC_SUBST([OPENCL_LIBNAME])
1364
1365 dnl
1366 dnl Gallium configuration
1367 dnl
1368 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1369
1370 AC_SUBST([LLVM_BINDIR])
1371 AC_SUBST([LLVM_CFLAGS])
1372 AC_SUBST([LLVM_CPPFLAGS])
1373 AC_SUBST([LLVM_CXXFLAGS])
1374 AC_SUBST([LLVM_LIBDIR])
1375 AC_SUBST([LLVM_LIBS])
1376 AC_SUBST([LLVM_LDFLAGS])
1377 AC_SUBST([LLVM_INCLUDEDIR])
1378 AC_SUBST([LLVM_VERSION])
1379 AC_SUBST([CLANG_RESOURCE_DIR])
1380
1381 case "x$enable_opengl$enable_gles1$enable_gles2" in
1382 x*yes*)
1383     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1384     ;;
1385 esac
1386
1387 AC_SUBST([VG_LIB_DEPS])
1388 AC_SUBST([EGL_CLIENT_APIS])
1389
1390 dnl
1391 dnl EGL Platforms configuration
1392 dnl
1393 AC_ARG_WITH([egl-platforms],
1394     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1395         [comma delimited native platforms libEGL supports, e.g.
1396         "x11,drm" @<:@default=auto@:>@])],
1397     [with_egl_platforms="$withval"],
1398     [if test "x$enable_egl" = xyes; then
1399         with_egl_platforms="x11"
1400     else
1401         with_egl_platforms=""
1402     fi])
1403
1404 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1405     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1406 fi
1407
1408 # Do per-EGL platform setups and checks
1409 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1410 for plat in $egl_platforms; do
1411         case "$plat" in
1412         wayland)
1413                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1414                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1415
1416                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1417                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1418                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1419                 ;;
1420
1421         x11)
1422                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1423                 ;;
1424
1425         drm)
1426                 test "x$enable_gbm" = "xno" &&
1427                         AC_MSG_ERROR([EGL platform drm needs gbm])
1428                 test "x$have_libdrm" != xyes &&
1429                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1430                 ;;
1431
1432         android|fbdev|gdi|null)
1433                 ;;
1434
1435         *)
1436                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1437                 ;;
1438         esac
1439
1440         case "$plat$have_libudev" in
1441                 waylandno|drmno)
1442                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1443         esac
1444 done
1445
1446 # libEGL wants to default to the first platform specified in
1447 # ./configure.  parse that here.
1448 if test "x$egl_platforms" != "x"; then
1449     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1450     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1451 else
1452     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1453 fi
1454
1455 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1456     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1457     NEED_WINSYS_XLIB=yes
1458 fi
1459 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1460 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1461 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1462 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1463 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1464
1465 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1466
1467 AC_SUBST([EGL_NATIVE_PLATFORM])
1468 AC_SUBST([EGL_CFLAGS])
1469
1470 # If we don't have the X11 platform, set this define so we don't try to include
1471 # the X11 headers.
1472 if ! echo "$egl_platforms" | grep -q 'x11'; then
1473     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1474     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1475 fi
1476
1477 AC_ARG_WITH([egl-driver-dir],
1478     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1479                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1480     [EGL_DRIVER_INSTALL_DIR="$withval"],
1481     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1482 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1483
1484 AC_ARG_WITH([max-width],
1485     [AS_HELP_STRING([--with-max-width=N],
1486                     [Maximum framebuffer width (4096)])],
1487     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1488      AS_IF([test "${withval}" -gt "4096"],
1489            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1490 )
1491 AC_ARG_WITH([max-height],
1492     [AS_HELP_STRING([--with-max-height=N],
1493                     [Maximum framebuffer height (4096)])],
1494     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1495      AS_IF([test "${withval}" -gt "4096"],
1496            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1497 )
1498
1499 dnl
1500 dnl Gallium LLVM
1501 dnl
1502 AC_ARG_ENABLE([gallium-llvm],
1503     [AS_HELP_STRING([--enable-gallium-llvm],
1504         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1505     [enable_gallium_llvm="$enableval"],
1506     [enable_gallium_llvm=auto])
1507
1508 AC_ARG_ENABLE([llvm-shared-libs],
1509     [AS_HELP_STRING([--enable-llvm-shared-libs],
1510         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1511     [],
1512     [with_llvm_shared_libs=yes])
1513
1514 AC_ARG_WITH([llvm-prefix],
1515     [AS_HELP_STRING([--with-llvm-prefix],
1516         [Prefix for LLVM installations in non-standard locations])],
1517     [llvm_prefix="$withval"],
1518     [llvm_prefix=""])
1519
1520
1521 # Call this inside ` ` to get the return value.
1522 # $1 is the llvm-config command with arguments.
1523 strip_unwanted_llvm_flags() {
1524     # Use \> (marks the end of the word)
1525     echo `$1` | sed \
1526         -e 's/-DNDEBUG\>//g' \
1527         -e 's/-pedantic\>//g' \
1528         -e 's/-Wcovered-switch-default\>//g' \
1529         -e 's/-O.\>//g' \
1530         -e 's/-g\>//g' \
1531         -e 's/-Wall\>//g' \
1532         -e 's/-fcolor-diagnostics\>//g' \
1533         -e 's/-fomit-frame-pointer\>//g'
1534 }
1535
1536
1537 if test -z "$with_gallium_drivers"; then
1538     enable_gallium_llvm=no
1539 fi
1540 if test "x$enable_gallium_llvm" = xauto; then
1541     case "$host_cpu" in
1542     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1543     esac
1544 fi
1545 if test "x$enable_gallium_llvm" = xyes; then
1546     if test -n "$llvm_prefix"; then
1547         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1548     else
1549         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1550     fi
1551
1552     if test "x$LLVM_CONFIG" != xno; then
1553         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1554         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1555         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1556         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1557         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1558         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1559         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1560         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1561
1562         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1563             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1564         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1565             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1566
1567         if test -n "${LLVM_VERSION_MAJOR}"; then
1568             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1569         else
1570             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1571         fi
1572
1573         LLVM_COMPONENTS="engine bitwriter"
1574         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1575             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1576         fi
1577
1578         if test "x$enable_opencl" = xyes; then
1579             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1580             # LLVM 3.3 >= 177971 requires IRReader
1581             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1582                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1583             fi
1584             # LLVM 3.4 requires Option
1585             if $LLVM_CONFIG --components | grep -qw 'option'; then
1586                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1587             fi
1588         fi
1589         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1590         MESA_LLVM=1
1591
1592         dnl Check for Clang internal headers
1593         if test "x$enable_opencl" = xyes; then
1594             if test -z "$CLANG_LIBDIR"; then
1595                 CLANG_LIBDIR=${LLVM_LIBDIR}
1596             fi
1597             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1598             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1599                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1600         fi
1601     else
1602         MESA_LLVM=0
1603         LLVM_VERSION_INT=0
1604     fi
1605 else
1606     MESA_LLVM=0
1607     LLVM_VERSION_INT=0
1608 fi
1609
1610 dnl Directory for XVMC libs
1611 AC_ARG_WITH([xvmc-libdir],
1612     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1613         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1614     [XVMC_LIB_INSTALL_DIR="$withval"],
1615     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1616 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1617
1618 dnl
1619 dnl Gallium Tests
1620 dnl
1621 if test "x$enable_gallium_tests" = xyes; then
1622     enable_gallium_loader=yes
1623 fi
1624 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1625
1626 if test "x$enable_gallium_loader" = xyes; then
1627     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1628 fi
1629 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1630
1631 dnl Directory for VDPAU libs
1632 AC_ARG_WITH([vdpau-libdir],
1633     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1634         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1635     [VDPAU_LIB_INSTALL_DIR="$withval"],
1636     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1637 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1638
1639 AC_ARG_WITH([omx-libdir],
1640     [AS_HELP_STRING([--with-omx-libdir=DIR],
1641         [directory for the OMX libraries])],
1642     [OMX_LIB_INSTALL_DIR="$withval"],
1643     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`])
1644 AC_SUBST([OMX_LIB_INSTALL_DIR])
1645
1646 dnl Directory for OpenCL libs
1647 AC_ARG_WITH([opencl-libdir],
1648     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1649         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1650     [OPENCL_LIB_INSTALL_DIR="$withval"],
1651     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1652 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1653
1654 dnl
1655 dnl Gallium helper functions
1656 dnl
1657 gallium_check_st() {
1658     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1659          if test "x$have_libdrm" != xyes; then
1660             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1661          fi
1662          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1663     fi
1664     if test "x$enable_dri" = xyes && test -n "$2"; then
1665          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1666     fi
1667     if test "x$enable_xa" = xyes && test -n "$3"; then
1668          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1669     fi
1670     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1671          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1672     fi
1673     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1674          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1675     fi
1676     if test "x$enable_omx" = xyes && test "x$6" != x; then
1677          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1678     fi
1679 }
1680
1681 gallium_require_llvm() {
1682     if test "x$MESA_LLVM" = x0; then
1683         case "$host_cpu" in
1684         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1685         esac
1686     fi
1687 }
1688
1689 gallium_require_drm_loader() {
1690     if test "x$enable_gallium_loader" = xyes; then
1691         if test "x$have_libudev" != xyes; then
1692             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1693         fi
1694         if test "x$have_libdrm" != xyes; then
1695             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1696         fi
1697         enable_gallium_drm_loader=yes
1698     fi
1699 }
1700
1701 radeon_llvm_check() {
1702     if test "x$enable_gallium_llvm" != "xyes"; then
1703         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1704     fi
1705     LLVM_REQUIRED_VERSION_MAJOR="3"
1706     LLVM_REQUIRED_VERSION_MINOR="3"
1707     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1708         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1709     fi
1710     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1711         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1712                       sources with the --enable-experimental-targets=R600
1713                       configure flag])
1714     fi
1715     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1716     NEED_RADEON_LLVM=yes
1717     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1718                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1719 }
1720
1721 dnl Gallium drivers
1722 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1723         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1724     NEED_NONNULL_WINSYS=yes
1725 fi
1726 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1727
1728 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1729 if test -n "$with_gallium_drivers"; then
1730     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1731     for driver in $gallium_drivers; do
1732         case "x$driver" in
1733         xsvga)
1734             HAVE_GALLIUM_SVGA=yes
1735             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1736             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1737             ;;
1738         xi915)
1739             HAVE_GALLIUM_I915=yes
1740             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1741             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1742             if test "x$MESA_LLVM" = x1; then
1743                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1744             fi
1745             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1746             gallium_check_st "i915/drm" "dri-i915"
1747             DRICOMMON_NEED_LIBDRM=yes
1748             ;;
1749         xilo)
1750             HAVE_GALLIUM_ILO=yes
1751             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1752             gallium_require_drm_loader
1753             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1754             gallium_check_st "intel/drm" "dri-ilo"
1755             DRICOMMON_NEED_LIBDRM=yes
1756             ;;
1757         xr300)
1758             HAVE_GALLIUM_R300=yes
1759             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1760             gallium_require_llvm "Gallium R300"
1761             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1762             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1763             DRICOMMON_NEED_LIBDRM=yes
1764             ;;
1765         xr600)
1766             HAVE_GALLIUM_R600=yes
1767             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1768             gallium_require_drm_loader
1769             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1770             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1771                 radeon_llvm_check "r600g"
1772                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1773             fi
1774             if test "x$enable_r600_llvm" = xyes; then
1775                 USE_R600_LLVM_COMPILER=yes;
1776             fi
1777             if test "x$enable_opencl" = xyes; then
1778                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1779             fi
1780             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1781             DRICOMMON_NEED_LIBDRM=yes
1782             ;;
1783         xradeonsi)
1784             HAVE_GALLIUM_RADEONSI=yes
1785             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1786             gallium_require_drm_loader
1787             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1788             radeon_llvm_check "radeonsi"
1789             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1790             DRICOMMON_NEED_LIBDRM=yes
1791             ;;
1792         xnouveau)
1793             HAVE_GALLIUM_NOUVEAU=yes
1794             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1795             gallium_require_drm_loader
1796             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1797             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1798             DRICOMMON_NEED_LIBDRM=yes
1799             ;;
1800         xfreedreno)
1801             HAVE_GALLIUM_FREEDRENO=yes
1802             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1803             gallium_require_drm_loader
1804             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1805             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1806             DRICOMMON_NEED_LIBDRM=yes
1807             ;;
1808         xswrast)
1809             HAVE_GALLIUM_SOFTPIPE=yes
1810             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1811             if test "x$MESA_LLVM" = x1; then
1812                 HAVE_GALLIUM_LLVMPIPE=yes
1813                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1814             fi
1815
1816             if test "x$enable_dri" = xyes; then
1817                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1818             fi
1819             ;;
1820         *)
1821             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1822             ;;
1823         esac
1824     done
1825 fi
1826
1827 dnl Set LLVM_LIBS - This is done after the driver configuration so
1828 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1829 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1830 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1831 dnl this was causing the same libraries to be appear multiple times
1832 dnl in LLVM_LIBS.
1833
1834 if test "x$MESA_LLVM" != x0; then
1835
1836     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1837
1838     if test "x$with_llvm_shared_libs" = xyes; then
1839         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1840         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1841         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1842
1843         if test "x$llvm_have_one_so" = xyes; then
1844             dnl LLVM was built using auto*, so there is only one shared object.
1845             LLVM_LIBS="-l$LLVM_SO_NAME"
1846         else
1847             dnl If LLVM was built with CMake, there will be one shared object per
1848             dnl component.
1849             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1850                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1851         Please make sure you have built llvm with the --enable-shared option
1852         and that your llvm libraries are installed in $LLVM_LIBDIR
1853         If you have installed your llvm libraries to a different directory you
1854         can use the --with-llvm-prefix= configure flag to specify this directory.
1855         NOTE: Mesa is attempting to use llvm shared libraries because you have
1856         passed one of the following options to configure:
1857                 --with-llvm-shared-libs
1858                 --enable-opencl
1859         If you do not want to build with llvm shared libraries and instead want to
1860         use llvm static libraries then remove these options from your configure
1861         invocation and reconfigure.])])
1862
1863            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1864            dnl install uses a shared object for each compoenent and we have
1865            dnl already added all of these objects to LLVM_LIBS.
1866         fi
1867     fi
1868 fi
1869
1870 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1871 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1872 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1873 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1874 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1875 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1876 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1877 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1878 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1879 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1880
1881 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1882                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1883                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1884 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1885                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1886                                                   && test "x$MESA_LLVM" = x1)
1887
1888 # NOTE: anything using xcb or other client side libs ends up in separate
1889 #       _CLIENT variables.  The pipe loader is built in two variants,
1890 #       one that is standalone and does not link any x client libs (for
1891 #       use by XA tracker in particular, but could be used in any case
1892 #       where communication with xserver is not desired).
1893 if test "x$enable_gallium_loader" = xyes; then
1894     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1895
1896     if test "x$enable_gallium_xlib_loader" = xyes; then
1897         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1898         NEED_WINSYS_XLIB="yes"
1899         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1900     fi
1901
1902     if test "x$enable_gallium_drm_loader" = xyes; then
1903         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1904         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1905                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1906         if test "x$pipe_loader_have_xcb" = xyes; then
1907             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1908             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1909         fi
1910     fi
1911
1912     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1913     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1914
1915     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1916     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1917     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1918     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1919 fi
1920 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1921
1922 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1923 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1924 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1925 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1926 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1927 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1928
1929 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1930                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1931                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1932                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1933 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1934                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1935 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1936 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1937 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1938 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1939 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1940 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1941 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1942
1943 AC_SUBST([ELF_LIB])
1944
1945 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1946 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1947 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1948 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1949 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1950
1951 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1952 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1953 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1954
1955 AC_SUBST([VDPAU_MAJOR], 1)
1956 AC_SUBST([VDPAU_MINOR], 0)
1957
1958 AC_SUBST([XVMC_MAJOR], 1)
1959 AC_SUBST([XVMC_MINOR], 0)
1960
1961 AC_SUBST([XA_MAJOR], 2)
1962 AC_SUBST([XA_MINOR], 2)
1963 AC_SUBST([XA_TINY], 0)
1964 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1965
1966 dnl Restore LDFLAGS and CPPFLAGS
1967 LDFLAGS="$_SAVE_LDFLAGS"
1968 CPPFLAGS="$_SAVE_CPPFLAGS"
1969
1970 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1971 if test "x$acv_mesa_CLANG" = xyes; then
1972     CFLAGS="$CFLAGS -Qunused-arguments"
1973     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1974 fi
1975
1976 dnl Add user CFLAGS and CXXFLAGS
1977 CFLAGS="$CFLAGS $USER_CFLAGS"
1978 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1979
1980 dnl Substitute the config
1981 AC_CONFIG_FILES([Makefile
1982                 src/Makefile
1983                 src/egl/Makefile
1984                 src/egl/drivers/Makefile
1985                 src/egl/drivers/dri2/Makefile
1986                 src/egl/main/Makefile
1987                 src/egl/main/egl.pc
1988                 src/egl/wayland/Makefile
1989                 src/egl/wayland/wayland-drm/Makefile
1990                 src/egl/wayland/wayland-egl/Makefile
1991                 src/egl/wayland/wayland-egl/wayland-egl.pc
1992                 src/gallium/auxiliary/Makefile
1993                 src/gallium/auxiliary/pipe-loader/Makefile
1994                 src/gallium/drivers/Makefile
1995                 src/gallium/drivers/freedreno/Makefile
1996                 src/gallium/drivers/galahad/Makefile
1997                 src/gallium/drivers/i915/Makefile
1998                 src/gallium/drivers/identity/Makefile
1999                 src/gallium/drivers/ilo/Makefile
2000                 src/gallium/drivers/llvmpipe/Makefile
2001                 src/gallium/drivers/noop/Makefile
2002                 src/gallium/drivers/nouveau/Makefile
2003                 src/gallium/drivers/r300/Makefile
2004                 src/gallium/drivers/r600/Makefile
2005                 src/gallium/drivers/radeon/Makefile
2006                 src/gallium/drivers/radeonsi/Makefile
2007                 src/gallium/drivers/rbug/Makefile
2008                 src/gallium/drivers/softpipe/Makefile
2009                 src/gallium/drivers/svga/Makefile
2010                 src/gallium/drivers/trace/Makefile
2011                 src/gallium/state_trackers/Makefile
2012                 src/gallium/state_trackers/clover/Makefile
2013                 src/gallium/state_trackers/dri/Makefile
2014                 src/gallium/state_trackers/dri/drm/Makefile
2015                 src/gallium/state_trackers/dri/sw/Makefile
2016                 src/gallium/state_trackers/egl/Makefile
2017                 src/gallium/state_trackers/gbm/Makefile
2018                 src/gallium/state_trackers/glx/xlib/Makefile
2019                 src/gallium/state_trackers/omx/Makefile
2020                 src/gallium/state_trackers/osmesa/Makefile
2021                 src/gallium/state_trackers/vdpau/Makefile
2022                 src/gallium/state_trackers/vega/Makefile
2023                 src/gallium/state_trackers/xa/Makefile
2024                 src/gallium/state_trackers/xvmc/Makefile
2025                 src/gallium/targets/Makefile
2026                 src/gallium/targets/dri-freedreno/Makefile
2027                 src/gallium/targets/dri-i915/Makefile
2028                 src/gallium/targets/dri-ilo/Makefile
2029                 src/gallium/targets/dri-nouveau/Makefile
2030                 src/gallium/targets/dri-swrast/Makefile
2031                 src/gallium/targets/dri-vmwgfx/Makefile
2032                 src/gallium/targets/egl-static/Makefile
2033                 src/gallium/targets/gbm/Makefile
2034                 src/gallium/targets/opencl/Makefile
2035                 src/gallium/targets/xa/Makefile
2036                 src/gallium/targets/xa/xatracker.pc
2037                 src/gallium/targets/osmesa/Makefile
2038                 src/gallium/targets/osmesa/osmesa.pc
2039                 src/gallium/targets/pipe-loader/Makefile
2040                 src/gallium/targets/radeonsi/dri/Makefile
2041                 src/gallium/targets/radeonsi/omx/Makefile
2042                 src/gallium/targets/radeonsi/vdpau/Makefile
2043                 src/gallium/targets/r300/dri/Makefile
2044                 src/gallium/targets/r600/dri/Makefile
2045                 src/gallium/targets/r600/omx/Makefile
2046                 src/gallium/targets/r600/vdpau/Makefile
2047                 src/gallium/targets/r600/xvmc/Makefile
2048                 src/gallium/targets/libgl-xlib/Makefile
2049                 src/gallium/targets/vdpau-nouveau/Makefile
2050                 src/gallium/targets/xvmc-nouveau/Makefile
2051                 src/gallium/tests/trivial/Makefile
2052                 src/gallium/tests/unit/Makefile
2053                 src/gallium/winsys/Makefile
2054                 src/gallium/winsys/freedreno/drm/Makefile
2055                 src/gallium/winsys/i915/drm/Makefile
2056                 src/gallium/winsys/i915/sw/Makefile
2057                 src/gallium/winsys/intel/drm/Makefile
2058                 src/gallium/winsys/nouveau/drm/Makefile
2059                 src/gallium/winsys/radeon/drm/Makefile
2060                 src/gallium/winsys/svga/drm/Makefile
2061                 src/gallium/winsys/sw/dri/Makefile
2062                 src/gallium/winsys/sw/fbdev/Makefile
2063                 src/gallium/winsys/sw/null/Makefile
2064                 src/gallium/winsys/sw/wayland/Makefile
2065                 src/gallium/winsys/sw/wrapper/Makefile
2066                 src/gallium/winsys/sw/xlib/Makefile
2067                 src/gbm/Makefile
2068                 src/gbm/main/gbm.pc
2069                 src/glsl/Makefile
2070                 src/glx/Makefile
2071                 src/glx/tests/Makefile
2072                 src/gtest/Makefile
2073                 src/loader/Makefile
2074                 src/mapi/Makefile
2075                 src/mapi/es1api/Makefile
2076                 src/mapi/es1api/glesv1_cm.pc
2077                 src/mapi/es2api/Makefile
2078                 src/mapi/es2api/glesv2.pc
2079                 src/mapi/glapi/Makefile
2080                 src/mapi/glapi/gen/Makefile
2081                 src/mapi/glapi/tests/Makefile
2082                 src/mapi/shared-glapi/Makefile
2083                 src/mapi/shared-glapi/tests/Makefile
2084                 src/mapi/vgapi/Makefile
2085                 src/mapi/vgapi/vg.pc
2086                 src/mesa/Makefile
2087                 src/mesa/gl.pc
2088                 src/mesa/drivers/dri/dri.pc
2089                 src/mesa/drivers/dri/common/Makefile
2090                 src/mesa/drivers/dri/common/xmlpool/Makefile
2091                 src/mesa/drivers/dri/i915/Makefile
2092                 src/mesa/drivers/dri/i965/Makefile
2093                 src/mesa/drivers/dri/Makefile
2094                 src/mesa/drivers/dri/nouveau/Makefile
2095                 src/mesa/drivers/dri/r200/Makefile
2096                 src/mesa/drivers/dri/radeon/Makefile
2097                 src/mesa/drivers/dri/swrast/Makefile
2098                 src/mesa/drivers/osmesa/Makefile
2099                 src/mesa/drivers/osmesa/osmesa.pc
2100                 src/mesa/drivers/x11/Makefile
2101                 src/mesa/main/tests/Makefile
2102                 src/mesa/main/tests/hash_table/Makefile])
2103
2104 dnl Sort the dirs alphabetically
2105 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2106 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2107 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2108 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2109
2110 AC_OUTPUT
2111
2112 dnl
2113 dnl Output some configuration info for the user
2114 dnl
2115 echo ""
2116 echo "        prefix:          $prefix"
2117 echo "        exec_prefix:     $exec_prefix"
2118 echo "        libdir:          $libdir"
2119 echo "        includedir:      $includedir"
2120
2121 dnl API info
2122 echo ""
2123 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2124 echo "        OpenVG:          $enable_openvg"
2125
2126 dnl Driver info
2127 echo ""
2128 case "x$enable_osmesa$enable_gallium_osmesa" in
2129 xnoyes)
2130         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2131         ;;
2132 xyesno)
2133         echo "        OSMesa:          lib$OSMESA_LIB"
2134         ;;
2135 xnono)
2136         echo "        OSMesa:          no"
2137         ;;
2138 esac
2139
2140 if test "x$enable_dri" != xno; then
2141         if test -z "$DRI_DIRS"; then
2142             echo "        DRI drivers:     no"
2143         else
2144             echo "        DRI drivers:     $DRI_DIRS"
2145         fi
2146         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2147 fi
2148
2149 case "x$enable_glx$enable_xlib_glx" in
2150 xyesyes)
2151     echo "        GLX:             Xlib-based"
2152     ;;
2153 xyesno)
2154     echo "        GLX:             DRI-based"
2155     ;;
2156 *)
2157     echo "        GLX:             $enable_glx"
2158     ;;
2159 esac
2160
2161 dnl EGL
2162 echo ""
2163 echo "        EGL:             $enable_egl"
2164 if test "$enable_egl" = yes; then
2165     echo "        EGL platforms:   $egl_platforms"
2166
2167     egl_drivers=""
2168     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2169         egl_drivers="$egl_drivers builtin:egl_dri2"
2170     fi
2171
2172     if test "x$enable_gallium_egl" = xyes; then
2173         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2174         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2175     else
2176         echo "        EGL drivers:    $egl_drivers"
2177     fi
2178 fi
2179
2180 echo ""
2181 if test "x$MESA_LLVM" = x1; then
2182     echo "        llvm:            yes"
2183     echo "        llvm-config:     $LLVM_CONFIG"
2184     echo "        llvm-version:    $LLVM_VERSION"
2185 else
2186     echo "        llvm:            no"
2187 fi
2188
2189 echo ""
2190 if test -n "$with_gallium_drivers"; then
2191     echo "        Gallium:         yes"
2192     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2193     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2194     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2195     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2196 else
2197     echo "        Gallium:         no"
2198 fi
2199
2200
2201 dnl Libraries
2202 echo ""
2203 echo "        Shared libs:     $enable_shared"
2204 echo "        Static libs:     $enable_static"
2205 echo "        Shared-glapi:    $enable_shared_glapi"
2206
2207 dnl Compiler options
2208 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2209 cflags=`echo $CFLAGS | \
2210     $SED 's/^ *//;s/  */ /;s/ *$//'`
2211 cxxflags=`echo $CXXFLAGS | \
2212     $SED 's/^ *//;s/  */ /;s/ *$//'`
2213 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2214 echo ""
2215 echo "        CFLAGS:          $cflags"
2216 echo "        CXXFLAGS:        $cxxflags"
2217 echo "        Macros:          $defines"
2218 echo ""
2219 if test "x$MESA_LLVM" = x1; then
2220     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2221     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2222     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2223     echo ""
2224 fi
2225 echo "        PYTHON2:         $PYTHON2"
2226
2227 echo ""
2228 echo "        Run '${MAKE-make}' to build Mesa"
2229 echo ""