projects / mesa.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
configure.ac: Check gallium LLVM version in gallium_require_llvm
[mesa.git] / configure.ac
1 dnl Copyright © 2011-2014 Intel Corporation
2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
3 dnl Copyright © 2007-2010 Dan Nicholson
4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
5 dnl Copyright © 2010-2014 Christian König
6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
7 dnl Copyright © 2009-2012 Jakob Bornecrantz
8 dnl Copyright © 2009-2014 Jon TURNEY
9 dnl Copyright © 2011-2012 Benjamin Franzke
10 dnl Copyright © 2008-2014 David Airlie
11 dnl Copyright © 2009-2013 Brian Paul
12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
13 dnl
14 dnl Permission is hereby granted, free of charge, to any person obtaining a
15 dnl copy of this software and associated documentation files (the "Software"),
16 dnl to deal in the Software without restriction, including without limitation
17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
18 dnl and/or sell copies of the Software, and to permit persons to whom the
19 dnl Software is furnished to do so, subject to the following conditions:
20 dnl
21 dnl The above copyright notice and this permission notice (including the next
22 dnl paragraph) shall be included in all copies or substantial portions of the
23 dnl Software.
24 dnl
25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
31 dnl DEALINGS IN THE SOFTWARE.
32 dnl
33 dnl Process this file with autoconf to create configure.
34
35 AC_PREREQ([2.60])
36
37 dnl Tell the user about autoconf.html in the --help output
38 m4_divert_once([HELP_END], [
39 See docs/autoconf.html for more details on the options for Mesa.])
40
41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
42 AC_INIT([Mesa], [MESA_VERSION],
43 [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
44 AC_CONFIG_AUX_DIR([bin])
45 AC_CONFIG_MACRO_DIR([m4])
46 AC_CANONICAL_SYSTEM
47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
48
49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
50 case "$host_os" in
51 mingw*)
52 AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
53 ;;
54 esac
55
56 # Support silent build rules, requires at least automake-1.11. Disable
57 # by either passing --disable-silent-rules to configure or passing V=1
58 # to make
59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
60 [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
61
62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
63
64 dnl Set internal versions
65 OSMESA_VERSION=8
66 AC_SUBST([OSMESA_VERSION])
67 OPENCL_VERSION=1
68 AC_SUBST([OPENCL_VERSION])
69
70 dnl Versions for external dependencies
71 LIBDRM_REQUIRED=2.4.66
72 LIBDRM_RADEON_REQUIRED=2.4.56
73 LIBDRM_AMDGPU_REQUIRED=2.4.63
74 LIBDRM_INTEL_REQUIRED=2.4.61
75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
78 LIBDRM_VC4_REQUIRED=2.4.69
79 DRI2PROTO_REQUIRED=2.6
80 DRI3PROTO_REQUIRED=1.0
81 PRESENTPROTO_REQUIRED=1.0
82 GLPROTO_REQUIRED=1.4.14
83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
84 LIBVA_REQUIRED=0.38.0
85 VDPAU_REQUIRED=1.1
86 WAYLAND_REQUIRED=1.2.0
87 XCB_REQUIRED=1.9.3
88 XCBDRI2_REQUIRED=1.8
89 XCBGLX_REQUIRED=1.8.1
90 XSHMFENCE_REQUIRED=1.1
91 XVMC_REQUIRED=1.0.6
92 PYTHON_MAKO_REQUIRED=0.8.0
93 LIBSENSORS_REQUIRED=4.0.0
94
95 dnl Check for progs
96 AC_PROG_CPP
97 AC_PROG_CC
98 AC_PROG_CXX
99 AM_PROG_CC_C_O
100 AM_PROG_AS
101 AX_CHECK_GNU_MAKE
102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
103 AC_PROG_SED
104 AC_PROG_MKDIR_P
105
106 AC_SYS_LARGEFILE
107
108 LT_PREREQ([2.2])
109 LT_INIT([disable-static])
110
111 AC_CHECK_PROG(RM, rm, [rm -f])
112 AC_CHECK_PROG(XXD, xxd, [xxd])
113
114 AX_PROG_BISON([],
115 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
116 [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
117 AX_PROG_FLEX([],
118 AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
119 [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
120
121 AC_CHECK_PROG(INDENT, indent, indent, cat)
122 if test "x$INDENT" != "xcat"; then
123 # Only GNU indent is supported
124 INDENT_VERSION=`indent --version | grep GNU`
125 if test $? -eq 0; then
126 AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
127 else
128 INDENT="cat"
129 fi
130 fi
131
132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
133
134 if test -z "$PYTHON2"; then
135 if test ! -f "$srcdir/src/util/format_srgb.c"; then
136 AC_MSG_ERROR([Python not found - unable to generate sources])
137 fi
138 else
139 if test "x$acv_mako_found" = xno; then
140 if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
141 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
142 fi
143 fi
144 fi
145
146 AC_PROG_INSTALL
147
148 dnl We need a POSIX shell for parts of the build. Assume we have one
149 dnl in most cases.
150 case "$host_os" in
151 solaris*)
152 # Solaris /bin/sh is too old/non-POSIX compliant
153 AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
154 SHELL="$POSIX_SHELL"
155 ;;
156 esac
157
158 dnl clang is mostly GCC-compatible, but its version is much lower,
159 dnl so we have to check for it.
160 AC_MSG_CHECKING([if compiling with clang])
161
162 AC_COMPILE_IFELSE(
163 [AC_LANG_PROGRAM([], [[
164 #ifndef __clang__
165 not clang
166 #endif
167 ]])],
168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
169
170 AC_MSG_RESULT([$acv_mesa_CLANG])
171
172 dnl If we're using GCC, make sure that it is at least version 4.2.0. Older
173 dnl versions are explictly not supported.
174 GEN_ASM_OFFSETS=no
175 USE_GNU99=no
176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
177 AC_MSG_CHECKING([whether gcc version is sufficient])
178 major=0
179 minor=0
180
181 GCC_VERSION=`$CC -dumpversion`
182 if test $? -eq 0; then
183 GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
184 GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
185 fi
186
187 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
188 AC_MSG_RESULT([no])
189 AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
190 else
191 AC_MSG_RESULT([yes])
192 fi
193
194 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
195 USE_GNU99=yes
196 fi
197 if test "x$cross_compiling" = xyes; then
198 GEN_ASM_OFFSETS=yes
199 fi
200 fi
201
202 dnl We don't support building Mesa with Sun C compiler
203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
205 if test "x$SUNCC" = xyes; then
206 AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
207 fi
208
209 dnl Check for compiler builtins
210 AX_GCC_BUILTIN([__builtin_bswap32])
211 AX_GCC_BUILTIN([__builtin_bswap64])
212 AX_GCC_BUILTIN([__builtin_clz])
213 AX_GCC_BUILTIN([__builtin_clzll])
214 AX_GCC_BUILTIN([__builtin_ctz])
215 AX_GCC_BUILTIN([__builtin_expect])
216 AX_GCC_BUILTIN([__builtin_ffs])
217 AX_GCC_BUILTIN([__builtin_ffsll])
218 AX_GCC_BUILTIN([__builtin_popcount])
219 AX_GCC_BUILTIN([__builtin_popcountll])
220 AX_GCC_BUILTIN([__builtin_unreachable])
221
222 AX_GCC_FUNC_ATTRIBUTE([const])
223 AX_GCC_FUNC_ATTRIBUTE([flatten])
224 AX_GCC_FUNC_ATTRIBUTE([format])
225 AX_GCC_FUNC_ATTRIBUTE([malloc])
226 AX_GCC_FUNC_ATTRIBUTE([packed])
227 AX_GCC_FUNC_ATTRIBUTE([pure])
228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
229 AX_GCC_FUNC_ATTRIBUTE([unused])
230 AX_GCC_FUNC_ATTRIBUTE([visibility])
231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
232 AX_GCC_FUNC_ATTRIBUTE([weak])
233
234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
235
236 dnl Make sure the pkg-config macros are defined
237 m4_ifndef([PKG_PROG_PKG_CONFIG],
238 [m4_fatal([Could not locate the pkg-config autoconf macros.
239 These are usually located in /usr/share/aclocal/pkg.m4. If your macros
240 are in a different location, try setting the environment variable
241 ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
242 PKG_PROG_PKG_CONFIG()
243
244 dnl LIB_DIR - library basename
245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
246 AC_SUBST([LIB_DIR])
247
248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
249 _SAVE_LDFLAGS="$LDFLAGS"
250 _SAVE_CPPFLAGS="$CPPFLAGS"
251
252 dnl Compiler macros
253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
254 AC_SUBST([DEFINES])
255 android=no
256 case "$host_os" in
257 *-android)
258 android=yes
259 ;;
260 linux*|*-gnu*|gnu*|cygwin*)
261 DEFINES="$DEFINES -D_GNU_SOURCE"
262 ;;
263 solaris*)
264 DEFINES="$DEFINES -DSVR4"
265 ;;
266 esac
267
268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
269
270 dnl Add flags for gcc and g++
271 if test "x$GCC" = xyes; then
272 CFLAGS="$CFLAGS -Wall"
273
274 if test "x$USE_GNU99" = xyes; then
275 CFLAGS="$CFLAGS -std=gnu99"
276 else
277 CFLAGS="$CFLAGS -std=c99"
278 fi
279
280 # Enable -Werror=implicit-function-declaration and
281 # -Werror=missing-prototypes, if available, or otherwise, just
282 # -Wmissing-prototypes. This is particularly useful to avoid
283 # generating a loadable driver module that has undefined symbols.
284 save_CFLAGS="$CFLAGS"
285 AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
286 CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
287 CFLAGS="$CFLAGS -Werror=missing-prototypes"
288 AC_LINK_IFELSE([AC_LANG_PROGRAM()],
289 AC_MSG_RESULT([yes]),
290 [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
291 AC_MSG_RESULT([no])]);
292
293 # Enable -fvisibility=hidden if using a gcc that supports it
294 save_CFLAGS="$CFLAGS"
295 AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
296 VISIBILITY_CFLAGS="-fvisibility=hidden"
297 CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
298 AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
299 [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
300
301 # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
302 CFLAGS=$save_CFLAGS
303
304 # We don't want floating-point math functions to set errno or trap
305 CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
306
307 # Flags to help ensure that certain portions of the code -- and only those
308 # portions -- can be built with MSVC:
309 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
310 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
311 # supports most of C99)
312 # - the rest has no compiler compiler restrictions
313 MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
314 MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
315
316 # Enable -Werror=vla if compiler supports it
317 save_CFLAGS="$CFLAGS"
318 AC_MSG_CHECKING([whether $CC supports -Werror=vla])
319 CFLAGS="$CFLAGS -Werror=vla"
320 AC_LINK_IFELSE([AC_LANG_PROGRAM()],
321 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
322 MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
323 AC_MSG_RESULT([yes])],
324 AC_MSG_RESULT([no]));
325 CFLAGS="$save_CFLAGS"
326 fi
327 if test "x$GXX" = xyes; then
328 CXXFLAGS="$CXXFLAGS -Wall"
329
330 # Enable -fvisibility=hidden if using a gcc that supports it
331 save_CXXFLAGS="$CXXFLAGS"
332 AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
333 VISIBILITY_CXXFLAGS="-fvisibility=hidden"
334 CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
335 AC_LANG_PUSH([C++])
336 AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
337 [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
338 AC_LANG_POP([C++])
339
340 # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
341 CXXFLAGS=$save_CXXFLAGS
342
343 # We don't want floating-point math functions to set errno or trap
344 CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
345 fi
346
347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
349
350 dnl even if the compiler appears to support it, using visibility attributes isn't
351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
352 case "$host_os" in
353 cygwin*)
354 VISIBILITY_CFLAGS=""
355 VISIBILITY_CXXFLAGS=""
356 ;;
357 esac
358
359 AC_SUBST([VISIBILITY_CFLAGS])
360 AC_SUBST([VISIBILITY_CXXFLAGS])
361
362 dnl
363 dnl Optional flags, check for compiler support
364 dnl
365 SSE41_CFLAGS="-msse4.1"
366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
367 dnl stack, but on x86-32 such alignment is not guaranteed.
368 case "$target_cpu" in
369 i?86)
370 SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
371 ;;
372 esac
373 save_CFLAGS="$CFLAGS"
374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
376 #include <smmintrin.h>
377 int param;
378 int main () {
379 __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
380 c = _mm_max_epu32(a, b);
381 return _mm_cvtsi128_si32(c);
382 }]])], SSE41_SUPPORTED=1)
383 CFLAGS="$save_CFLAGS"
384 if test "x$SSE41_SUPPORTED" = x1; then
385 DEFINES="$DEFINES -DUSE_SSE41"
386 fi
387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
389
390 dnl Check for new-style atomic builtins
391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
392 int main() {
393 int n;
394 return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
397 DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
398 fi
399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
400
401 dnl Check for Endianness
402 AC_C_BIGENDIAN(
403 little_endian=no,
404 little_endian=yes,
405 little_endian=no,
406 little_endian=no
407 )
408
409 dnl Check for POWER8 Architecture
410 PWR8_CFLAGS="-mpower8-vector"
411 have_pwr8_intrinsics=no
412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
413 save_CFLAGS=$CFLAGS
414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
417 #error "Need GCC >= 4.8 for sane POWER8 support"
418 #endif
419 #include <altivec.h>
420 int main () {
421 vector unsigned char r;
422 vector unsigned int v = vec_splat_u32 (1);
423 r = __builtin_vec_vgbbd ((vector unsigned char) v);
424 return 0;
425 }]])], have_pwr8_intrinsics=yes)
426 CFLAGS=$save_CFLAGS
427
428 AC_ARG_ENABLE(pwr8,
429 [AC_HELP_STRING([--disable-pwr8-inst],
430 [disable POWER8-specific instructions])],
431 [enable_pwr8=$enableval], [enable_pwr8=auto])
432
433 if test "x$enable_pwr8" = xno ; then
434 have_pwr8_intrinsics=disabled
435 fi
436
437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
438 DEFINES="$DEFINES -D_ARCH_PWR8"
439 CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
440 CFLAGS="$CFLAGS $PWR8_CFLAGS"
441 else
442 PWR8_CFLAGS=
443 fi
444
445 AC_MSG_RESULT($have_pwr8_intrinsics)
446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
447 AC_MSG_ERROR([POWER8 compiler support not detected])
448 fi
449
450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
451 AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
452 fi
453
454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
455
456 dnl Can't have static and shared libraries, default to static if user
457 dnl explicitly requested. If both disabled, set to static since shared
458 dnl was explicitly requested.
459 case "x$enable_static$enable_shared" in
460 xyesyes)
461 AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
462 enable_shared=no
463 ;;
464 xnono)
465 AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
466 enable_shared=yes
467 ;;
468 esac
469
470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
471
472 dnl
473 dnl other compiler options
474 dnl
475 AC_ARG_ENABLE([debug],
476 [AS_HELP_STRING([--enable-debug],
477 [use debug compiler flags and macros @<:@default=disabled@:>@])],
478 [enable_debug="$enableval"],
479 [enable_debug=no]
480 )
481
482 AC_ARG_ENABLE([profile],
483 [AS_HELP_STRING([--enable-profile],
484 [enable profiling of code @<:@default=disabled@:>@])],
485 [enable_profile="$enableval"],
486 [enable_profile=no]
487 )
488
489 if test "x$enable_profile" = xyes; then
490 DEFINES="$DEFINES -DPROFILE"
491 if test "x$GCC" = xyes; then
492 CFLAGS="$CFLAGS -fno-omit-frame-pointer"
493 fi
494 if test "x$GXX" = xyes; then
495 CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
496 fi
497 fi
498
499 if test "x$enable_debug" = xyes; then
500 DEFINES="$DEFINES -DDEBUG"
501 if test "x$enable_profile" = xyes; then
502 AC_MSG_WARN([Debug and Profile are enabled at the same time])
503 fi
504 if test "x$GCC" = xyes; then
505 if ! echo "$CFLAGS" | grep -q -e '-g'; then
506 CFLAGS="$CFLAGS -g"
507 fi
508 if ! echo "$CFLAGS" | grep -q -e '-O'; then
509 CFLAGS="$CFLAGS -O0"
510 fi
511 fi
512 if test "x$GXX" = xyes; then
513 if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
514 CXXFLAGS="$CXXFLAGS -g"
515 fi
516 if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
517 CXXFLAGS="$CXXFLAGS -O0"
518 fi
519 fi
520 else
521 DEFINES="$DEFINES -DNDEBUG"
522 fi
523
524 DEFAULT_GL_LIB_NAME=GL
525
526 dnl
527 dnl Check if linker supports -Bsymbolic
528 dnl
529 save_LDFLAGS=$LDFLAGS
530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
532 AC_LINK_IFELSE(
533 [AC_LANG_SOURCE([int main() { return 0;}])],
534 [AC_MSG_RESULT([yes])
535 BSYMBOLIC="-Wl,-Bsymbolic";],
536 [AC_MSG_RESULT([no])
537 BSYMBOLIC="";])
538 LDFLAGS=$save_LDFLAGS
539
540 AC_SUBST([BSYMBOLIC])
541
542 dnl
543 dnl Check if linker supports garbage collection
544 dnl
545 save_LDFLAGS=$LDFLAGS
546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
547 AC_MSG_CHECKING([whether ld supports --gc-sections])
548 AC_LINK_IFELSE(
549 [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
550 [AC_MSG_RESULT([yes])
551 GC_SECTIONS="-Wl,--gc-sections";],
552 [AC_MSG_RESULT([no])
553 GC_SECTIONS="";])
554 LDFLAGS=$save_LDFLAGS
555
556 AC_SUBST([GC_SECTIONS])
557
558 dnl
559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
560 dnl so when these flags are passed to ld via libtool the checks will fail
561 dnl
562 case "$host_os" in
563 openbsd* | darwin* )
564 LD_NO_UNDEFINED="" ;;
565 *)
566 LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
567 esac
568
569 AC_SUBST([LD_NO_UNDEFINED])
570
571 dnl
572 dnl Check if linker supports version scripts
573 dnl
574 AC_MSG_CHECKING([if the linker supports version-scripts])
575 save_LDFLAGS=$LDFLAGS
576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
577 cat > conftest.map <<EOF
578 VERSION_1 {
579 global:
580 main;
581
582 local:
583 *;
584 };
585 EOF
586 AC_LINK_IFELSE(
587 [AC_LANG_SOURCE([int main() { return 0;}])],
588 [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
589 [have_ld_version_script=no; AC_MSG_RESULT(no)])
590 LDFLAGS=$save_LDFLAGS
591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
592
593 dnl
594 dnl Check if linker supports dynamic list files
595 dnl
596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
597 save_LDFLAGS=$LDFLAGS
598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
599 cat > conftest.dyn <<EOF
600 {
601 radeon_drm_winsys_create;
602 };
603 EOF
604 AC_LINK_IFELSE(
605 [AC_LANG_SOURCE([int main() { return 0;}])],
606 [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
607 [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
608 LDFLAGS=$save_LDFLAGS
609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
610
611 dnl
612 dnl compatibility symlinks
613 dnl
614 case "$host_os" in
615 linux* )
616 HAVE_COMPAT_SYMLINKS=yes ;;
617 * )
618 HAVE_COMPAT_SYMLINKS=no ;;
619 esac
620
621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
622
623 DEFAULT_GL_LIB_NAME=GL
624
625 dnl
626 dnl Libglvnd configuration
627 dnl
628 AC_ARG_ENABLE([libglvnd],
629 [AS_HELP_STRING([--enable-libglvnd],
630 [Build for libglvnd @<:@default=disabled@:>@])],
631 [enable_libglvnd="$enableval"],
632 [enable_libglvnd=no])
633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
635 if test "x$enable_libglvnd" = xyes ; then
636 DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
637 DEFAULT_GL_LIB_NAME=GLX_mesa
638 fi
639
640 dnl
641 dnl library names
642 dnl
643 dnl Unfortunately we need to do a few things that libtool can't help us with,
644 dnl so we need some knowledge of shared library filenames:
645 dnl
646 dnl LIB_EXT is the extension used when creating symlinks for alternate
647 dnl filenames for a shared library which will be dynamically loaded
648 dnl
649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
650 dnl the file for a shared library we wish to link with
651 dnl
652 case "$host_os" in
653 darwin* )
654 LIB_EXT='dylib'
655 IMP_LIB_EXT=$LIB_EXT
656 ;;
657 cygwin* )
658 LIB_EXT='dll'
659 IMP_LIB_EXT='dll.a'
660 ;;
661 aix* )
662 LIB_EXT='a'
663 IMP_LIB_EXT=$LIB_EXT
664 ;;
665 * )
666 LIB_EXT='so'
667 IMP_LIB_EXT=$LIB_EXT
668 ;;
669 esac
670
671 AC_SUBST([LIB_EXT])
672
673 AC_ARG_WITH([gl-lib-name],
674 [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
675 [specify GL library name @<:@default=GL@:>@])],
676 [GL_LIB=$withval],
677 [GL_LIB="$DEFAULT_GL_LIB_NAME"])
678 AC_ARG_WITH([osmesa-lib-name],
679 [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
680 [specify OSMesa library name @<:@default=OSMesa@:>@])],
681 [OSMESA_LIB=$withval],
682 [OSMESA_LIB=OSMesa])
683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
685
686 dnl
687 dnl Mangled Mesa support
688 dnl
689 AC_ARG_ENABLE([mangling],
690 [AS_HELP_STRING([--enable-mangling],
691 [enable mangled symbols and library name @<:@default=disabled@:>@])],
692 [enable_mangling="${enableval}"],
693 [enable_mangling=no]
694 )
695 if test "x${enable_mangling}" = "xyes" ; then
696 DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
697 GL_LIB="Mangled${GL_LIB}"
698 OSMESA_LIB="Mangled${OSMESA_LIB}"
699 fi
700 AC_SUBST([GL_LIB])
701 AC_SUBST([OSMESA_LIB])
702
703 dnl
704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
705 dnl
706 AC_ARG_ENABLE([texture-float],
707 [AS_HELP_STRING([--enable-texture-float],
708 [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
709 [enable_texture_float="$enableval"],
710 [enable_texture_float=no]
711 )
712 if test "x$enable_texture_float" = xyes; then
713 AC_MSG_WARN([Floating-point textures enabled.])
714 AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
715 DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
716 fi
717
718 dnl
719 dnl Arch/platform-specific settings
720 dnl
721 AC_ARG_ENABLE([asm],
722 [AS_HELP_STRING([--disable-asm],
723 [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
724 [enable_asm="$enableval"],
725 [enable_asm=yes]
726 )
727 asm_arch=""
728 AC_MSG_CHECKING([whether to enable assembly])
729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
732 case "$host_cpu" in
733 i?86 | x86_64 | amd64)
734 if test "x$host_cpu" != "x$target_cpu"; then
735 enable_asm=no
736 AC_MSG_RESULT([no, cross compiling])
737 fi
738 ;;
739 esac
740 fi
741 # check for supported arches
742 if test "x$enable_asm" = xyes; then
743 case "$host_cpu" in
744 i?86)
745 case "$host_os" in
746 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
747 asm_arch=x86
748 ;;
749 esac
750 ;;
751 x86_64|amd64)
752 case "$host_os" in
753 linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
754 asm_arch=x86_64
755 ;;
756 esac
757 ;;
758 sparc*)
759 case "$host_os" in
760 linux*)
761 asm_arch=sparc
762 ;;
763 esac
764 ;;
765 esac
766
767 case "$asm_arch" in
768 x86)
769 DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
770 AC_MSG_RESULT([yes, x86])
771 ;;
772 x86_64|amd64)
773 DEFINES="$DEFINES -DUSE_X86_64_ASM"
774 AC_MSG_RESULT([yes, x86_64])
775 ;;
776 sparc)
777 DEFINES="$DEFINES -DUSE_SPARC_ASM"
778 AC_MSG_RESULT([yes, sparc])
779 ;;
780 *)
781 AC_MSG_RESULT([no, platform not supported])
782 ;;
783 esac
784 fi
785
786 AC_HEADER_MAJOR
787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
791
792 dnl Check to see if dlopen is in default libraries (like Solaris, which
793 dnl has it in libc), or if libdl is needed to get it.
794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
795 [AC_CHECK_LIB([dl], [dlopen],
796 [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
797 AC_SUBST([DLOPEN_LIBS])
798
799 dnl Check if that library also has dladdr
800 save_LIBS="$LIBS"
801 LIBS="$LIBS $DLOPEN_LIBS"
802 AC_CHECK_FUNCS([dladdr])
803 LIBS="$save_LIBS"
804
805 case "$host_os" in
806 darwin*)
807 ;;
808 *)
809 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
810 [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
811 [AC_MSG_ERROR([Could not find clock_gettime])])])
812 AC_SUBST([CLOCK_LIB])
813 ;;
814 esac
815
816 dnl See if posix_memalign is available
817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
818
819 dnl Check for pthreads
820 AX_PTHREAD
821 if test "x$ax_pthread_ok" = xno; then
822 AC_MSG_ERROR([Building mesa on this platform requires pthreads])
823 fi
824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
825 dnl to -pthread, which causes problems if we need -lpthread to appear in
826 dnl pkgconfig files. Since Android doesn't have a pthread lib, this check
827 dnl is not valid for that platform.
828 if test "x$android" = xno; then
829 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
830 fi
831
832 dnl pthread-stubs is mandatory on targets where it exists
833 case "$host_os" in
834 cygwin* )
835 pthread_stubs_possible="no"
836 ;;
837 * )
838 pthread_stubs_possible="yes"
839 ;;
840 esac
841
842 if test "x$pthread_stubs_possible" = xyes; then
843 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
844 AC_SUBST(PTHREADSTUBS_CFLAGS)
845 AC_SUBST(PTHREADSTUBS_LIBS)
846 fi
847
848 dnl SELinux awareness.
849 AC_ARG_ENABLE([selinux],
850 [AS_HELP_STRING([--enable-selinux],
851 [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
852 [MESA_SELINUX="$enableval"],
853 [MESA_SELINUX=no])
854 if test "x$enable_selinux" = "xyes"; then
855 PKG_CHECK_MODULES([SELINUX], [libselinux], [],
856 [AC_CHECK_HEADER([selinux/selinux.h],[],
857 [AC_MSG_ERROR([SELinux headers not found])])
858 AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
859 [AC_MSG_ERROR([SELinux library not found])])
860 SELINUX_LIBS="-lselinux"])
861 DEFINES="$DEFINES -DMESA_SELINUX"
862 fi
863 AC_SUBST([SELINUX_CFLAGS])
864 AC_SUBST([SELINUX_LIBS])
865
866 dnl
867 dnl LLVM
868 dnl
869 AC_ARG_ENABLE([llvm-shared-libs],
870 [AS_HELP_STRING([--enable-llvm-shared-libs],
871 [link with LLVM shared libraries @<:@default=enabled@:>@])],
872 [enable_llvm_shared_libs="$enableval"],
873 [enable_llvm_shared_libs=yes])
874
875 AC_ARG_WITH([llvm-prefix],
876 [AS_HELP_STRING([--with-llvm-prefix],
877 [Prefix for LLVM installations in non-standard locations])],
878 [llvm_prefix="$withval"],
879 [llvm_prefix=''])
880
881 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
882 if test "x$have_libelf" = xno; then
883 LIBELF_LIBS=''
884 LIBELF_CFLAGS=''
885 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
886 AC_SUBST([LIBELF_LIBS])
887 AC_SUBST([LIBELF_CFLAGS])
888 fi
889
890 if test -z "$LLVM_CONFIG"; then
891 if test -n "$llvm_prefix"; then
892 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
893 else
894 AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
895 fi
896 fi
897
898 llvm_add_component() {
899 new_llvm_component=$1
900 driver_name=$2
901
902 LLVM_COMPONENTS="$LLVM_COMPONENTS $new_llvm_component"
903 }
904
905 llvm_add_default_components() {
906 driver_name=$1
907
908 # Required default components
909 llvm_add_component "bitwriter" $driver_name
910 llvm_add_component "engine" $driver_name
911 llvm_add_component "mcdisassembler" $driver_name
912 llvm_add_component "mcjit" $driver_name
913
914 # Optional default components
915 if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
916 LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
917 fi
918 }
919
920 llvm_add_target() {
921 new_llvm_target=$1
922 driver_name=$2
923
924 if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
925 llvm_add_component $new_llvm_target $driver_name
926 else
927 AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
928 fi
929 }
930
931 # Call this inside ` ` to get the return value.
932 # $1 is the llvm-config command with arguments.
933 strip_unwanted_llvm_flags() {
934 # Use \> (marks the end of the word)
935 echo `$1` | sed \
936 -e 's/-march=\S*//g' \
937 -e 's/-mtune=\S*//g' \
938 -e 's/-mcpu=\S*//g' \
939 -e 's/-DNDEBUG\>//g' \
940 -e 's/-D_GNU_SOURCE\>//g' \
941 -e 's/-pedantic\>//g' \
942 -e 's/-Wcovered-switch-default\>//g' \
943 -e 's/-O.\>//g' \
944 -e 's/-g\>//g' \
945 -e 's/-Wall\>//g' \
946 -e 's/-Wcast-qual\>//g' \
947 -e 's/-Woverloaded-virtual\>//g' \
948 -e 's/-fcolor-diagnostics\>//g' \
949 -e 's/-fdata-sections\>//g' \
950 -e 's/-ffunction-sections\>//g' \
951 -e 's/-fno-exceptions\>//g' \
952 -e 's/-fomit-frame-pointer\>//g' \
953 -e 's/-fvisibility-inlines-hidden\>//g' \
954 -e 's/-fPIC\>//g' \
955 -e 's/-fstack-protector-strong\>//g'
956 }
957
958 llvm_set_environment_variables() {
959 if test "x$LLVM_CONFIG" != xno; then
960 LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
961 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
962 LLVM_BINDIR=`$LLVM_CONFIG --bindir`
963 LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
964 LLVM_CFLAGS=$LLVM_CPPFLAGS # CPPFLAGS seem to be sufficient
965 LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
966 LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
967 LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
968
969 AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
970 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
971 AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
972 [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
973
974 LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
975 if test -z "$LLVM_VERSION_PATCH"; then
976 LLVM_VERSION_PATCH=0
977 fi
978
979 if test -n "${LLVM_VERSION_MAJOR}"; then
980 LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
981 else
982 LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
983 fi
984
985 llvm_add_default_components "gallium"
986
987 if test "x$enable_opencl" = xyes; then
988 llvm_check_version_for "3" "6" "0" "opencl"
989
990 llvm_add_component "all-targets" "opencl"
991 llvm_add_component "ipo" "opencl"
992 llvm_add_component "linker" "opencl"
993 llvm_add_component "instrumentation" "opencl"
994 llvm_add_component "irreader" "opencl"
995 llvm_add_component "option" "opencl"
996 llvm_add_component "objcarcopts" "opencl"
997 llvm_add_component "profiledata" "opencl"
998 fi
999 DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1000 MESA_LLVM=1
1001
1002 dnl Check for Clang internal headers
1003 if test "x$enable_opencl" = xyes; then
1004 if test -z "$CLANG_LIBDIR"; then
1005 CLANG_LIBDIR=${LLVM_LIBDIR}
1006 fi
1007 CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1008 AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1009 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1010 fi
1011 else
1012 MESA_LLVM=0
1013 LLVM_VERSION_INT=0
1014 fi
1015 }
1016
1017 llvm_check_version_for() {
1018 if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1019 AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1020 fi
1021 }
1022
1023 radeon_llvm_check() {
1024 if test ${LLVM_VERSION_INT} -lt 307; then
1025 amdgpu_llvm_target_name='r600'
1026 else
1027 amdgpu_llvm_target_name='amdgpu'
1028 fi
1029
1030 llvm_check_version_for $2 $3 $4 $1
1031
1032 llvm_add_target $amdgpu_llvm_target_name $1
1033
1034 llvm_add_component "bitreader" $1
1035 llvm_add_component "ipo" $1
1036
1037 NEED_RADEON_LLVM=yes
1038 if test "x$have_libelf" != xyes; then
1039 AC_MSG_ERROR([$1 requires libelf when using llvm])
1040 fi
1041 }
1042
1043 dnl Options for APIs
1044 AC_ARG_ENABLE([opengl],
1045 [AS_HELP_STRING([--disable-opengl],
1046 [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1047 [enable_opengl="$enableval"],
1048 [enable_opengl=yes])
1049 AC_ARG_ENABLE([gles1],
1050 [AS_HELP_STRING([--disable-gles1],
1051 [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1052 [enable_gles1="$enableval"],
1053 [enable_gles1=yes])
1054 AC_ARG_ENABLE([gles2],
1055 [AS_HELP_STRING([--disable-gles2],
1056 [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1057 [enable_gles2="$enableval"],
1058 [enable_gles2=yes])
1059
1060 AC_ARG_ENABLE([dri],
1061 [AS_HELP_STRING([--enable-dri],
1062 [enable DRI modules @<:@default=enabled@:>@])],
1063 [enable_dri="$enableval"],
1064 [enable_dri=yes])
1065
1066 AC_ARG_ENABLE([gallium-extra-hud],
1067 [AS_HELP_STRING([--enable-gallium-extra-hud],
1068 [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1069 [enable_gallium_extra_hud="$enableval"],
1070 [enable_gallium_extra_hud=no])
1071 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1072 if test "x$enable_gallium_extra_hud" = xyes ; then
1073 DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1074 fi
1075
1076 #TODO: no pkgconfig .pc available for libsensors.
1077 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1078 AC_ARG_ENABLE([lmsensors],
1079 [AS_HELP_STRING([--enable-lmsensors],
1080 [enable HUD lmsensor support @<:@default=disabled@:>@])],
1081 [enable_lmsensors="$enableval"],
1082 [enable_lmsensors=no])
1083 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1084 if test "x$enable_lmsensors" = xyes ; then
1085 DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1086 LIBSENSORS_LDFLAGS="-lsensors"
1087 else
1088 LIBSENSORS_LDFLAGS=""
1089 fi
1090 AC_SUBST(LIBSENSORS_LDFLAGS)
1091
1092 case "$host_os" in
1093 linux*)
1094 dri3_default=yes
1095 ;;
1096 *)
1097 dri3_default=no
1098 ;;
1099 esac
1100
1101 if test "x$enable_dri" = xno; then
1102 dri3_default=no
1103 fi
1104
1105 AC_ARG_ENABLE([dri3],
1106 [AS_HELP_STRING([--enable-dri3],
1107 [enable DRI3 @<:@default=auto@:>@])],
1108 [enable_dri3="$enableval"],
1109 [enable_dri3="$dri3_default"])
1110 AC_ARG_ENABLE([glx],
1111 [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1112 [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1113 [enable_glx="$enableval"],
1114 [enable_glx=yes])
1115 AC_ARG_ENABLE([osmesa],
1116 [AS_HELP_STRING([--enable-osmesa],
1117 [enable OSMesa library @<:@default=disabled@:>@])],
1118 [enable_osmesa="$enableval"],
1119 [enable_osmesa=no])
1120 AC_ARG_ENABLE([gallium-osmesa],
1121 [AS_HELP_STRING([--enable-gallium-osmesa],
1122 [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1123 [enable_gallium_osmesa="$enableval"],
1124 [enable_gallium_osmesa=no])
1125 AC_ARG_ENABLE([egl],
1126 [AS_HELP_STRING([--disable-egl],
1127 [disable EGL library @<:@default=enabled@:>@])],
1128 [enable_egl="$enableval"],
1129 [enable_egl=yes])
1130
1131 AC_ARG_ENABLE([xa],
1132 [AS_HELP_STRING([--enable-xa],
1133 [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1134 [enable_xa="$enableval"],
1135 [enable_xa=no])
1136 AC_ARG_ENABLE([gbm],
1137 [AS_HELP_STRING([--enable-gbm],
1138 [enable gbm library @<:@default=yes except cygwin@:>@])],
1139 [enable_gbm="$enableval"],
1140 [case "$host_os" in
1141 cygwin*)
1142 enable_gbm=no
1143 ;;
1144 *)
1145 enable_gbm=yes
1146 ;;
1147 esac])
1148 AC_ARG_ENABLE([nine],
1149 [AS_HELP_STRING([--enable-nine],
1150 [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1151 [enable_nine="$enableval"],
1152 [enable_nine=no])
1153
1154 AC_ARG_ENABLE([xvmc],
1155 [AS_HELP_STRING([--enable-xvmc],
1156 [enable xvmc library @<:@default=auto@:>@])],
1157 [enable_xvmc="$enableval"],
1158 [enable_xvmc=auto])
1159 AC_ARG_ENABLE([vdpau],
1160 [AS_HELP_STRING([--enable-vdpau],
1161 [enable vdpau library @<:@default=auto@:>@])],
1162 [enable_vdpau="$enableval"],
1163 [enable_vdpau=auto])
1164 AC_ARG_ENABLE([omx],
1165 [AS_HELP_STRING([--enable-omx],
1166 [enable OpenMAX library @<:@default=disabled@:>@])],
1167 [enable_omx="$enableval"],
1168 [enable_omx=no])
1169 AC_ARG_ENABLE([va],
1170 [AS_HELP_STRING([--enable-va],
1171 [enable va library @<:@default=auto@:>@])],
1172 [enable_va="$enableval"],
1173 [enable_va=auto])
1174 AC_ARG_ENABLE([opencl],
1175 [AS_HELP_STRING([--enable-opencl],
1176 [enable OpenCL library @<:@default=disabled@:>@])],
1177 [enable_opencl="$enableval"],
1178 [enable_opencl=no])
1179 AC_ARG_ENABLE([opencl_icd],
1180 [AS_HELP_STRING([--enable-opencl-icd],
1181 [Build an OpenCL ICD library to be loaded by an ICD implementation
1182 @<:@default=disabled@:>@])],
1183 [enable_opencl_icd="$enableval"],
1184 [enable_opencl_icd=no])
1185
1186 AC_ARG_ENABLE([gallium-tests],
1187 [AS_HELP_STRING([--enable-gallium-tests],
1188 [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1189 [enable_gallium_tests="$enableval"],
1190 [enable_gallium_tests=no])
1191
1192 # Option for Gallium drivers
1193
1194 # Keep this in sync with the --with-gallium-drivers help string default value
1195 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1196
1197 AC_ARG_WITH([gallium-drivers],
1198 [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1199 [comma delimited Gallium drivers list, e.g.
1200 "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1201 @<:@default=r300,r600,svga,swrast@:>@])],
1202 [with_gallium_drivers="$withval"],
1203 [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1204
1205 # Doing '--without-gallium-drivers' will set this variable to 'no'. Clear it
1206 # here so that the script doesn't choke on an unknown driver name later.
1207 case "$with_gallium_drivers" in
1208 yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1209 no) with_gallium_drivers='' ;;
1210 esac
1211
1212 if test "x$enable_opengl" = xno -a \
1213 "x$enable_gles1" = xno -a \
1214 "x$enable_gles2" = xno -a \
1215 "x$enable_nine" = xno -a \
1216 "x$enable_xa" = xno -a \
1217 "x$enable_xvmc" = xno -a \
1218 "x$enable_vdpau" = xno -a \
1219 "x$enable_omx" = xno -a \
1220 "x$enable_va" = xno -a \
1221 "x$enable_opencl" = xno; then
1222 AC_MSG_ERROR([at least one API should be enabled])
1223 fi
1224
1225 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1226 if test "x$enable_opengl" = xno -a \
1227 "x$enable_gles1" = xyes; then
1228 AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1229 fi
1230
1231 if test "x$enable_opengl" = xno -a \
1232 "x$enable_gles2" = xyes; then
1233 AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1234 fi
1235
1236 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1237 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1238 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1239 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1240 "x$enable_gles1" = xyes -o \
1241 "x$enable_gles2" = xyes)
1242
1243 # Validate GLX options
1244 if test "x$enable_glx" = xyes; then
1245 if test "x$enable_dri" = xyes; then
1246 enable_glx=dri
1247 elif test -n "$with_gallium_drivers"; then
1248 enable_glx=gallium-xlib
1249 else
1250 enable_glx=xlib
1251 fi
1252 fi
1253 case "x$enable_glx" in
1254 xdri | xxlib | xgallium-xlib)
1255 # GLX requires OpenGL
1256 if test "x$enable_opengl" = xno; then
1257 AC_MSG_ERROR([GLX cannot be built without OpenGL])
1258 fi
1259
1260 # Check individual dependencies
1261 case "x$enable_glx" in
1262 xdri)
1263 if test "x$enable_dri" = xno; then
1264 AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1265 fi
1266 ;;
1267 xxlib)
1268 if test "x$enable_dri" = xyes; then
1269 AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1270 fi
1271 ;;
1272 xgallium-xlib )
1273 if test "x$enable_dri" = xyes; then
1274 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1275 fi
1276 if test -z "$with_gallium_drivers"; then
1277 AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1278 fi
1279 ;;
1280 esac
1281 ;;
1282 xno)
1283 ;;
1284 *)
1285 AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1286 ;;
1287 esac
1288
1289 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1290 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1291 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1292 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1293
1294 dnl
1295 dnl Libglvnd configuration
1296 dnl
1297 AC_ARG_ENABLE([libglvnd],
1298 [AS_HELP_STRING([--enable-libglvnd],
1299 [Build for libglvnd @<:@default=disabled@:>@])],
1300 [enable_libglvnd="$enableval"],
1301 [enable_libglvnd=no])
1302 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1303 if test "x$enable_libglvnd" = xyes ; then
1304 dnl XXX: update once we can handle more than libGL/glx.
1305 dnl Namely: we should error out if neither of the glvnd enabled libraries
1306 dnl are built
1307 case "x$enable_glx" in
1308 xno)
1309 AC_MSG_ERROR([cannot build libglvnd without GLX])
1310 ;;
1311 xxlib | xgallium-xlib )
1312 AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1313 ;;
1314 xdri)
1315 ;;
1316 esac
1317
1318 PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1319 DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1320 DEFAULT_GL_LIB_NAME=GLX_mesa
1321 fi
1322
1323 # Check for libdrm
1324 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1325 [have_libdrm=yes], [have_libdrm=no])
1326 if test "x$have_libdrm" = xyes; then
1327 DEFINES="$DEFINES -DHAVE_LIBDRM"
1328 fi
1329
1330 require_libdrm() {
1331 if test "x$have_libdrm" != xyes; then
1332 AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1333 fi
1334 }
1335
1336
1337 # Select which platform-dependent DRI code gets built
1338 case "$host_os" in
1339 darwin*)
1340 dri_platform='apple' ;;
1341 cygwin*)
1342 dri_platform='windows' ;;
1343 gnu*)
1344 dri_platform='none' ;;
1345 *)
1346 dri_platform='drm' ;;
1347 esac
1348
1349 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1350 have_drisw_kms='yes'
1351 fi
1352
1353 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1354 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1355 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1356 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1357 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1358 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1359 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1360 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1361 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1362
1363 AC_ARG_ENABLE([shared-glapi],
1364 [AS_HELP_STRING([--enable-shared-glapi],
1365 [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1366 [enable_shared_glapi="$enableval"],
1367 [enable_shared_glapi=yes])
1368
1369 case "x$enable_opengl$enable_gles1$enable_gles2" in
1370 x*yes*yes*)
1371 if test "x$enable_shared_glapi" = xno; then
1372 AC_MSG_ERROR([shared GLAPI required when building two or more of
1373 the following APIs - opengl, gles1 gles2])
1374 fi
1375 ;;
1376 esac
1377
1378 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1379
1380 # Build the pipe-drivers as separate libraries/modules.
1381 # Do not touch this unless you know what you are doing.
1382 # XXX: Expose via configure option ?
1383 enable_shared_pipe_drivers=no
1384
1385 dnl
1386 dnl Driver specific build directories
1387 dnl
1388
1389 if test "x$enable_gallium_osmesa" = xyes; then
1390 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1391 AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1392 fi
1393 if test "x$enable_osmesa" = xyes; then
1394 AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1395 fi
1396 fi
1397
1398 AC_SUBST([MESA_LLVM])
1399
1400 # SHA1 hashing
1401 AC_ARG_WITH([sha1],
1402 [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1403 [choose SHA1 implementation])])
1404 case "x$with_sha1" in
1405 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1406 ;;
1407 *)
1408 AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1409 esac
1410
1411 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1412 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1413 with_sha1=libc
1414 fi
1415 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1416 AC_MSG_ERROR([sha1 in libc requested but not found])
1417 fi
1418 if test "x$with_sha1" = xlibc; then
1419 AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1420 [Use libc SHA1 functions])
1421 SHA1_LIBS=""
1422 fi
1423 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1424 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1425 with_sha1=CommonCrypto
1426 fi
1427 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1428 AC_MSG_ERROR([CommonCrypto requested but not found])
1429 fi
1430 if test "x$with_sha1" = xCommonCrypto; then
1431 AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1432 [Use CommonCrypto SHA1 functions])
1433 SHA1_LIBS=""
1434 fi
1435 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1436 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1437 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1438 with_sha1=CryptoAPI
1439 fi
1440 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1441 AC_MSG_ERROR([CryptoAPI requested but not found])
1442 fi
1443 if test "x$with_sha1" = xCryptoAPI; then
1444 AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1445 [Use CryptoAPI SHA1 functions])
1446 SHA1_LIBS=""
1447 fi
1448 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1449 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1450 with_sha1=libmd
1451 fi
1452 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1453 AC_MSG_ERROR([libmd requested but not found])
1454 fi
1455 if test "x$with_sha1" = xlibmd; then
1456 AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1457 [Use libmd SHA1 functions])
1458 SHA1_LIBS=-lmd
1459 fi
1460 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1461 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1462 with_sha1=libsha1
1463 fi
1464 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1465 AC_MSG_ERROR([libsha1 requested but not found])
1466 fi
1467 if test "x$with_sha1" = xlibsha1; then
1468 AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1469 [Use libsha1 for SHA1])
1470 SHA1_LIBS=-lsha1
1471 fi
1472 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1473 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1474 with_sha1=libnettle
1475 fi
1476 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1477 AC_MSG_ERROR([libnettle requested but not found])
1478 fi
1479 if test "x$with_sha1" = xlibnettle; then
1480 AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1481 [Use libnettle SHA1 functions])
1482 SHA1_LIBS=-lnettle
1483 fi
1484 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1485 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1486 with_sha1=libgcrypt
1487 fi
1488 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1489 AC_MSG_ERROR([libgcrypt requested but not found])
1490 fi
1491 if test "x$with_sha1" = xlibgcrypt; then
1492 AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1493 [Use libgcrypt SHA1 functions])
1494 SHA1_LIBS=-lgcrypt
1495 fi
1496 # We don't need all of the OpenSSL libraries, just libcrypto
1497 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1498 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1499 [HAVE_OPENSSL_PKC=no])
1500 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1501 if test "x$with_sha1" = x; then
1502 with_sha1=libcrypto
1503 fi
1504 else
1505 if test "x$with_sha1" = xlibcrypto; then
1506 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1507 fi
1508 fi
1509 if test "x$with_sha1" = xlibcrypto; then
1510 if test "x$HAVE_LIBCRYPTO" = xyes; then
1511 SHA1_LIBS=-lcrypto
1512 else
1513 SHA1_LIBS="$OPENSSL_LIBS"
1514 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1515 fi
1516 fi
1517 AC_MSG_CHECKING([for SHA1 implementation])
1518 AC_MSG_RESULT([$with_sha1])
1519 AC_SUBST(SHA1_LIBS)
1520 AC_SUBST(SHA1_CFLAGS)
1521
1522 # Enable a define for SHA1
1523 if test "x$with_sha1" != "x"; then
1524 DEFINES="$DEFINES -DHAVE_SHA1"
1525 fi
1526
1527 # Allow user to configure out the shader-cache feature
1528 AC_ARG_ENABLE([shader-cache],
1529 AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1530 [enable_shader_cache="$enableval"],
1531 [if test "x$with_sha1" != "x"; then
1532 enable_shader_cache=yes
1533 else
1534 enable_shader_cache=no
1535 fi])
1536 if test "x$with_sha1" = "x"; then
1537 if test "x$enable_shader_cache" = "xyes"; then
1538 AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1539 fi
1540 fi
1541 if test "x$enable_shader_cache" = "xyes"; then
1542 AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1543 fi
1544
1545 if test "x$enable_dri" = xyes; then
1546 if test "$enable_static" = yes; then
1547 AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1548 fi
1549
1550 # not a hard requirement as swrast does not depend on it
1551 if test "x$have_libdrm" = xyes; then
1552 DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1553 fi
1554 fi
1555
1556 AC_ARG_ENABLE([driglx-direct],
1557 [AS_HELP_STRING([--disable-driglx-direct],
1558 [disable direct rendering in GLX and EGL for DRI \
1559 @<:@default=auto@:>@])],
1560 [driglx_direct="$enableval"],
1561 [driglx_direct="yes"])
1562
1563 dnl
1564 dnl libGL configuration per driver
1565 dnl
1566 case "x$enable_glx" in
1567 xxlib | xgallium-xlib)
1568 # Xlib-based GLX
1569 dri_modules="x11 xext xcb"
1570 PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1571 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1572 X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1573 GL_LIB_DEPS="$XLIBGL_LIBS"
1574 GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1575 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1576 ;;
1577 xdri)
1578 # DRI-based GLX
1579 PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1580
1581 # find the DRI deps for libGL
1582 dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1583
1584 if test x"$driglx_direct" = xyes; then
1585 if test x"$dri_platform" = xdrm ; then
1586 DEFINES="$DEFINES -DGLX_USE_DRM"
1587 require_libdrm "Direct rendering"
1588
1589 PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1590 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1591 if test x"$enable_dri3" = xyes; then
1592 PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1593 PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1594 fi
1595
1596 if test x"$enable_dri" = xyes; then
1597 dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1598 fi
1599
1600 if test x"$enable_dri3" = xyes; then
1601 PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1602 dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1603 PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1604 fi
1605 fi
1606 if test x"$dri_platform" = xapple ; then
1607 DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1608 fi
1609 if test x"$dri_platform" = xwindows ; then
1610 DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1611 fi
1612 fi
1613
1614 # add xf86vidmode if available
1615 PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1616 if test "$HAVE_XF86VIDMODE" = yes ; then
1617 dri_modules="$dri_modules xxf86vm"
1618 fi
1619
1620 PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1621 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1622 X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1623 GL_LIB_DEPS="$DRIGL_LIBS"
1624
1625 # need DRM libs, $PTHREAD_LIBS, etc.
1626 GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1627 GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1628 ;;
1629 esac
1630
1631 # This is outside the case (above) so that it is invoked even for non-GLX
1632 # builds.
1633 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1634
1635 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1636 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1637 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1638 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1639
1640 AC_SUBST([X11_INCLUDES])
1641 AC_SUBST([GL_LIB_DEPS])
1642 AC_SUBST([GL_PC_REQ_PRIV])
1643 AC_SUBST([GL_PC_LIB_PRIV])
1644 AC_SUBST([GL_PC_CFLAGS])
1645 AC_SUBST([DRI_PC_REQ_PRIV])
1646 AC_SUBST([GLESv1_CM_LIB_DEPS])
1647 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1648 AC_SUBST([GLESv2_LIB_DEPS])
1649 AC_SUBST([GLESv2_PC_LIB_PRIV])
1650
1651 AC_SUBST([HAVE_XF86VIDMODE])
1652
1653 dnl
1654 dnl More GLX setup
1655 dnl
1656 case "x$enable_glx" in
1657 xxlib | xgallium-xlib)
1658 DEFINES="$DEFINES -DUSE_XSHM"
1659 ;;
1660 xdri)
1661 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1662 if test "x$driglx_direct" = xyes; then
1663 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1664 fi
1665 ;;
1666 esac
1667
1668 dnl
1669 dnl TLS detection
1670 dnl
1671
1672 AC_ARG_ENABLE([glx-tls],
1673 [AS_HELP_STRING([--enable-glx-tls],
1674 [enable TLS support in GLX @<:@default=disabled@:>@])],
1675 [GLX_USE_TLS="$enableval"],
1676 [GLX_USE_TLS=no])
1677 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1678
1679 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1680 [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1681
1682 dnl Read-only text section on x86 hardened platforms
1683 AC_ARG_ENABLE([glx-read-only-text],
1684 [AS_HELP_STRING([--enable-glx-read-only-text],
1685 [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1686 [enable_glx_read_only_text="$enableval"],
1687 [enable_glx_read_only_text=no])
1688 if test "x$enable_glx_read_only_text" = xyes; then
1689 DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1690 fi
1691
1692 dnl
1693 dnl More DRI setup
1694 dnl
1695 dnl Directory for DRI drivers
1696 AC_ARG_WITH([dri-driverdir],
1697 [AS_HELP_STRING([--with-dri-driverdir=DIR],
1698 [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1699 [DRI_DRIVER_INSTALL_DIR="$withval"],
1700 [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1701 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1702 dnl Extra search path for DRI drivers
1703 AC_ARG_WITH([dri-searchpath],
1704 [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1705 [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1706 [DRI_DRIVER_SEARCH_DIR="$withval"],
1707 [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1708 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1709 dnl Which drivers to build - default is chosen by platform
1710 AC_ARG_WITH([dri-drivers],
1711 [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1712 [comma delimited classic DRI drivers list, e.g.
1713 "swrast,i965,radeon" @<:@default=auto@:>@])],
1714 [with_dri_drivers="$withval"],
1715 [with_dri_drivers=auto])
1716
1717 if test "x$with_dri_drivers" = xauto; then
1718 if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1719 with_dri_drivers="yes"
1720 else
1721 with_dri_drivers="no"
1722 fi
1723 fi
1724 if test "x$with_dri_drivers" = xno; then
1725 with_dri_drivers=''
1726 fi
1727
1728 dnl If $with_dri_drivers is yes, drivers will be added through
1729 dnl platform checks. Set DEFINES and LIB_DEPS
1730 if test "x$enable_dri" = xyes; then
1731 # Platform specific settings and drivers to build
1732 case "$host_os" in
1733 linux*)
1734 DEFINES="$DEFINES -DHAVE_ALIAS"
1735 if test "x$enable_dri3" = xyes; then
1736 DEFINES="$DEFINES -DHAVE_DRI3"
1737 fi
1738
1739 case "$host_cpu" in
1740 powerpc* | sparc*)
1741 # Build only the drivers for cards that exist on PowerPC/sparc
1742 if test "x$with_dri_drivers" = "xyes"; then
1743 with_dri_drivers="r200 radeon swrast"
1744 fi
1745 ;;
1746 esac
1747 ;;
1748 *freebsd* | dragonfly* | *netbsd* | openbsd*)
1749 DEFINES="$DEFINES -DHAVE_ALIAS"
1750 ;;
1751 gnu*)
1752 DEFINES="$DEFINES -DHAVE_ALIAS"
1753 ;;
1754 cygwin*)
1755 if test "x$with_dri_drivers" = "xyes"; then
1756 with_dri_drivers="swrast"
1757 fi
1758 ;;
1759 darwin*)
1760 DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1761 if test "x$with_dri_drivers" = "xyes"; then
1762 with_dri_drivers="swrast"
1763 fi
1764 ;;
1765 esac
1766
1767 # default drivers
1768 if test "x$with_dri_drivers" = "xyes"; then
1769 with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1770 fi
1771
1772 # Check for expat
1773 PKG_CHECK_MODULES([EXPAT], [expat], [],
1774 # expat version 2.0 and earlier do not provide expat.pc
1775 [AC_CHECK_HEADER([expat.h],[],
1776 [AC_MSG_ERROR([Expat headers required for DRI not found])])
1777 AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1778 [AC_MSG_ERROR([Expat library required for DRI not found])])
1779 EXPAT_LIBS="-lexpat"])
1780
1781 # put all the necessary libs together
1782 DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1783 fi
1784
1785 AC_SUBST([DRI_LIB_DEPS])
1786
1787 DRI_DIRS=''
1788 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1789 if test -n "$with_dri_drivers"; then
1790 if test "x$enable_opengl" != xyes; then
1791 AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1792 fi
1793
1794 dri_drivers=`IFS=', '; echo $with_dri_drivers`
1795 for driver in $dri_drivers; do
1796 DRI_DIRS="$DRI_DIRS $driver"
1797 case "x$driver" in
1798 xi915)
1799 HAVE_I915_DRI=yes;
1800 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1801 ;;
1802 xi965)
1803 HAVE_I965_DRI=yes;
1804 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1805 ;;
1806 xnouveau)
1807 HAVE_NOUVEAU_DRI=yes;
1808 PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1809 ;;
1810 xradeon)
1811 HAVE_RADEON_DRI=yes;
1812 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1813 ;;
1814 xr200)
1815 HAVE_R200_DRI=yes;
1816 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1817 ;;
1818 xswrast)
1819 HAVE_SWRAST_DRI=yes;
1820 ;;
1821 *)
1822 AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1823 ;;
1824 esac
1825 done
1826 DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1827 fi
1828
1829
1830 #
1831 # Vulkan driver configuration
1832 #
1833
1834 AC_ARG_WITH([vulkan-drivers],
1835 [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1836 [comma delimited Vulkan drivers list, e.g.
1837 "intel"
1838 @<:@default=no@:>@])],
1839 [with_vulkan_drivers="$withval"],
1840 [with_vulkan_drivers="no"])
1841
1842 # Doing '--without-vulkan-drivers' will set this variable to 'no'. Clear it
1843 # here so that the script doesn't choke on an unknown driver name later.
1844 case "x$with_vulkan_drivers" in
1845 xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1846 xno) with_vulkan_drivers='' ;;
1847 esac
1848
1849 AC_ARG_WITH([vulkan-icddir],
1850 [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1851 [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1852 [VULKAN_ICD_INSTALL_DIR="$withval"],
1853 [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1854 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1855
1856 if test -n "$with_vulkan_drivers"; then
1857 VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1858 for driver in $VULKAN_DRIVERS; do
1859 case "x$driver" in
1860 xintel)
1861 if test "x$HAVE_I965_DRI" != xyes; then
1862 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1863 fi
1864 if test "x$with_sha1" == "x"; then
1865 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1866 fi
1867 HAVE_INTEL_VULKAN=yes;
1868
1869 ;;
1870 xradeon)
1871 PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1872 HAVE_RADEON_VULKAN=yes;
1873 if test "x$with_sha1" == "x"; then
1874 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1875 fi
1876 ;;
1877 *)
1878 AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1879 ;;
1880 esac
1881 done
1882 VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1883 fi
1884
1885
1886 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1887 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1888 "x$enable_osmesa" = xyes -o \
1889 -n "$DRI_DIRS")
1890
1891 dnl
1892 dnl OSMesa configuration
1893 dnl
1894
1895 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1896 AC_ARG_WITH([osmesa-bits],
1897 [AS_HELP_STRING([--with-osmesa-bits=BITS],
1898 [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1899 [osmesa_bits="$withval"],
1900 [osmesa_bits=8])
1901 if test "x$osmesa_bits" != x8; then
1902 if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1903 AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1904 osmesa_bits=8
1905 fi
1906 fi
1907 case "x$osmesa_bits" in
1908 x8)
1909 OSMESA_LIB="${OSMESA_LIB}"
1910 ;;
1911 x16|x32)
1912 OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1913 DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1914 ;;
1915 *)
1916 AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1917 ;;
1918 esac
1919
1920 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1921 # only link libraries with osmesa if shared
1922 if test "$enable_static" = no; then
1923 OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1924 else
1925 OSMESA_LIB_DEPS=""
1926 fi
1927 OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1928 fi
1929
1930 AC_SUBST([OSMESA_LIB_DEPS])
1931 AC_SUBST([OSMESA_PC_REQ])
1932 AC_SUBST([OSMESA_PC_LIB_PRIV])
1933
1934 dnl
1935 dnl gbm configuration
1936 dnl
1937 if test "x$enable_gbm" = xyes; then
1938 if test "x$enable_dri" = xyes; then
1939 if test "x$enable_shared_glapi" = xno; then
1940 AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1941 fi
1942 else
1943 # Strictly speaking libgbm does not require --enable-dri, although
1944 # both of its backends do. Thus one can build libgbm without any
1945 # backends if --disable-dri is set.
1946 # To avoid unnecessary complexity of checking if at least one backend
1947 # is available when building, just mandate --enable-dri.
1948 AC_MSG_ERROR([gbm requires --enable-dri])
1949 fi
1950 fi
1951 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1952 # FINISHME: GBM has a number of dependencies which we should add below
1953 GBM_PC_REQ_PRIV=""
1954 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1955 AC_SUBST([GBM_PC_REQ_PRIV])
1956 AC_SUBST([GBM_PC_LIB_PRIV])
1957
1958 dnl
1959 dnl EGL configuration
1960 dnl
1961 EGL_CLIENT_APIS=""
1962
1963 if test "x$enable_egl" = xyes; then
1964 EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1965
1966 AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1967
1968 if test "$enable_static" != yes; then
1969 if test "x$enable_dri" = xyes; then
1970 HAVE_EGL_DRIVER_DRI2=1
1971 if test "x$enable_shared_glapi" = xno; then
1972 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1973 fi
1974 if test "x$enable_dri3" = xyes; then
1975 HAVE_EGL_DRIVER_DRI3=1
1976 if test "x$enable_shared_glapi" = xno; then
1977 AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1978 fi
1979 fi
1980 else
1981 # Avoid building an "empty" libEGL. Drop/update this
1982 # when other backends (haiku?) come along.
1983 AC_MSG_ERROR([egl requires --enable-dri])
1984 fi
1985
1986 fi
1987 fi
1988 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1989 AC_SUBST([EGL_LIB_DEPS])
1990
1991 gallium_st="mesa"
1992
1993 dnl
1994 dnl XA configuration
1995 dnl
1996 if test "x$enable_xa" = xyes; then
1997 if test "x$with_gallium_drivers" = xswrast; then
1998 AC_MSG_ERROR([
1999 Building xa requires at least one non swrast gallium driver.
2000 If you are looking to use libxatracker.so with the VMware driver,
2001 make sure to include svga in the gallium drivers list, apart from
2002 enabling XA.
2003 Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2004 fi
2005 gallium_st="$gallium_st xa"
2006 fi
2007 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2008
2009 dnl
2010 dnl Gallium G3DVL configuration
2011 dnl
2012 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2013 if test "x$enable_xvmc" = xauto; then
2014 PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2015 fi
2016
2017 if test "x$enable_vdpau" = xauto; then
2018 PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2019 fi
2020
2021 if test "x$enable_omx" = xauto; then
2022 PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2023 fi
2024
2025 if test "x$enable_va" = xauto; then
2026 PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2027 fi
2028 fi
2029
2030 if test "x$enable_dri" = xyes -o \
2031 "x$enable_xvmc" = xyes -o \
2032 "x$enable_vdpau" = xyes -o \
2033 "x$enable_omx" = xyes -o \
2034 "x$enable_va" = xyes; then
2035 need_gallium_vl=yes
2036 fi
2037 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2038
2039 if test "x$enable_xvmc" = xyes -o \
2040 "x$enable_vdpau" = xyes -o \
2041 "x$enable_omx" = xyes -o \
2042 "x$enable_va" = xyes; then
2043 if test x"$enable_dri3" = xyes; then
2044 PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2045 x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2046 else
2047 PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2048 fi
2049 need_gallium_vl_winsys=yes
2050 fi
2051 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2052
2053 if test "x$enable_xvmc" = xyes; then
2054 PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2055 gallium_st="$gallium_st xvmc"
2056 fi
2057 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2058
2059 if test "x$enable_vdpau" = xyes; then
2060 PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2061 gallium_st="$gallium_st vdpau"
2062 DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2063 fi
2064 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2065
2066 if test "x$enable_omx" = xyes; then
2067 PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2068 gallium_st="$gallium_st omx"
2069 fi
2070 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2071
2072 if test "x$enable_va" = xyes; then
2073 PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2074 gallium_st="$gallium_st va"
2075 fi
2076 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2077
2078 dnl
2079 dnl Nine Direct3D9 configuration
2080 dnl
2081 if test "x$enable_nine" = xyes; then
2082 if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2083 AC_MSG_ERROR([nine requires the gallium swrast driver])
2084 fi
2085 if test "x$with_gallium_drivers" = xswrast; then
2086 AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2087 fi
2088 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2089 AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2090 fi
2091
2092 if test "x$enable_dri3" = xno; then
2093 AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2094 fi
2095
2096 gallium_st="$gallium_st nine"
2097 fi
2098 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2099
2100 dnl
2101 dnl OpenCL configuration
2102 dnl
2103
2104 AC_ARG_WITH([clang-libdir],
2105 [AS_HELP_STRING([--with-clang-libdir],
2106 [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2107 [CLANG_LIBDIR="$withval"],
2108 [CLANG_LIBDIR=''])
2109
2110 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2111
2112 if test "x$enable_opencl" = xyes; then
2113 if test -z "$with_gallium_drivers"; then
2114 AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2115 fi
2116
2117 if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2118 AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2119 fi
2120
2121 if test "x$have_libclc" = xno; then
2122 AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2123 Make sure the directory containing libclc.pc is specified in your
2124 PKG_CONFIG_PATH environment variable.
2125 By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2126 else
2127 LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2128 LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2129 AC_SUBST([LIBCLC_INCLUDEDIR])
2130 AC_SUBST([LIBCLC_LIBEXECDIR])
2131 fi
2132
2133 gallium_st="$gallium_st clover"
2134
2135 if test "x$enable_opencl_icd" = xyes; then
2136 OPENCL_LIBNAME="MesaOpenCL"
2137 else
2138 OPENCL_LIBNAME="OpenCL"
2139 fi
2140
2141 if test "x$have_libelf" != xyes; then
2142 AC_MSG_ERROR([Clover requires libelf])
2143 fi
2144 fi
2145 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2146 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2147 AC_SUBST([OPENCL_LIBNAME])
2148
2149 dnl
2150 dnl Gallium configuration
2151 dnl
2152 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2153
2154 AC_SUBST([LLVM_BINDIR])
2155 AC_SUBST([LLVM_CFLAGS])
2156 AC_SUBST([LLVM_CPPFLAGS])
2157 AC_SUBST([LLVM_CXXFLAGS])
2158 AC_SUBST([LLVM_LIBDIR])
2159 AC_SUBST([LLVM_LIBS])
2160 AC_SUBST([LLVM_LDFLAGS])
2161 AC_SUBST([LLVM_INCLUDEDIR])
2162 AC_SUBST([LLVM_VERSION])
2163 AC_SUBST([CLANG_RESOURCE_DIR])
2164
2165 case "x$enable_opengl$enable_gles1$enable_gles2" in
2166 x*yes*)
2167 EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2168 ;;
2169 esac
2170
2171 AC_SUBST([VG_LIB_DEPS])
2172 AC_SUBST([EGL_CLIENT_APIS])
2173
2174 dnl
2175 dnl EGL Platforms configuration
2176 dnl
2177 AC_ARG_WITH([egl-platforms],
2178 [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2179 [comma delimited native platforms libEGL supports, e.g.
2180 "x11,drm" @<:@default=auto@:>@])],
2181 [with_egl_platforms="$withval"],
2182 [if test "x$enable_egl" = xyes; then
2183 if test "x$enable_gbm" = xyes; then
2184 with_egl_platforms="x11,drm"
2185 else
2186 with_egl_platforms="x11"
2187 fi
2188 else
2189 with_egl_platforms=""
2190 fi])
2191
2192 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2193 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2194 fi
2195
2196 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2197 WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2198 WAYLAND_SCANNER='')
2199 if test "x$WAYLAND_SCANNER" = x; then
2200 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2201 fi
2202
2203 # Do per-EGL platform setups and checks
2204 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2205 for plat in $egl_platforms; do
2206 case "$plat" in
2207 wayland)
2208
2209 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2210
2211 if test "x$WAYLAND_SCANNER" = x; then
2212 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2213 fi
2214 ;;
2215
2216 x11)
2217 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2218 ;;
2219
2220 drm)
2221 test "x$enable_gbm" = "xno" &&
2222 AC_MSG_ERROR([EGL platform drm needs gbm])
2223 ;;
2224
2225 surfaceless)
2226 ;;
2227
2228 android)
2229 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2230 ;;
2231
2232 *)
2233 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2234 ;;
2235 esac
2236
2237 case "$plat" in
2238 wayland|drm|surfaceless)
2239 require_libdrm "Platform $plat"
2240 ;;
2241 esac
2242 done
2243
2244 # libEGL wants to default to the first platform specified in
2245 # ./configure. parse that here.
2246 if test "x$egl_platforms" != "x"; then
2247 FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2248 EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2249 else
2250 EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2251 fi
2252
2253 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2254 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2255 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2256 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2257 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2258
2259 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2260
2261 AC_SUBST([EGL_NATIVE_PLATFORM])
2262 AC_SUBST([EGL_CFLAGS])
2263
2264 # If we don't have the X11 platform, set this define so we don't try to include
2265 # the X11 headers.
2266 if ! echo "$egl_platforms" | grep -q 'x11'; then
2267 DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2268 GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2269 fi
2270
2271 dnl
2272 dnl Gallium LLVM
2273 dnl
2274 AC_ARG_ENABLE([gallium-llvm],
2275 [AS_HELP_STRING([--enable-gallium-llvm],
2276 [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2277 [enable_gallium_llvm="$enableval"],
2278 [enable_gallium_llvm=auto])
2279
2280 if test -z "$with_gallium_drivers"; then
2281 enable_gallium_llvm=no
2282 fi
2283 if test "x$enable_gallium_llvm" = xauto; then
2284 case "$host_cpu" in
2285 i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2286 esac
2287 fi
2288 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2289 llvm_set_environment_variables
2290 else
2291 MESA_LLVM=0
2292 LLVM_VERSION_INT=0
2293 fi
2294
2295 dnl Directory for XVMC libs
2296 AC_ARG_WITH([xvmc-libdir],
2297 [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2298 [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2299 [XVMC_LIB_INSTALL_DIR="$withval"],
2300 [XVMC_LIB_INSTALL_DIR='${libdir}'])
2301 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2302
2303 dnl
2304 dnl Gallium Tests
2305 dnl
2306 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2307
2308 dnl Directory for VDPAU libs
2309 AC_ARG_WITH([vdpau-libdir],
2310 [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2311 [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2312 [VDPAU_LIB_INSTALL_DIR="$withval"],
2313 [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2314 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2315
2316 dnl Directory for OMX libs
2317
2318 AC_ARG_WITH([omx-libdir],
2319 [AS_HELP_STRING([--with-omx-libdir=DIR],
2320 [directory for the OMX libraries])],
2321 [OMX_LIB_INSTALL_DIR="$withval"],
2322 [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2323 AC_SUBST([OMX_LIB_INSTALL_DIR])
2324
2325 dnl Directory for VA libs
2326
2327 AC_ARG_WITH([va-libdir],
2328 [AS_HELP_STRING([--with-va-libdir=DIR],
2329 [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2330 [VA_LIB_INSTALL_DIR="$withval"],
2331 [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2332 AC_SUBST([VA_LIB_INSTALL_DIR])
2333
2334 AC_ARG_WITH([d3d-libdir],
2335 [AS_HELP_STRING([--with-d3d-libdir=DIR],
2336 [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2337 [D3D_DRIVER_INSTALL_DIR="$withval"],
2338 [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2339 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2340
2341 dnl
2342 dnl Gallium helper functions
2343 dnl
2344 gallium_require_llvm() {
2345 if test "x$enable_gallium_llvm" == "xyes"; then
2346 llvm_check_version_for "3" "3" "0" "gallium"
2347 else
2348 AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2349 fi
2350 }
2351
2352 dnl
2353 dnl DRM is needed by X, Wayland, and offscreen rendering.
2354 dnl Surfaceless is an alternative for the last one.
2355 dnl
2356 require_basic_egl() {
2357 case "$with_egl_platforms" in
2358 *drm*|*surfaceless*)
2359 ;;
2360 *)
2361 AC_MSG_ERROR([$1 requires one of these:
2362 1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2363 2) --with-egl-platforms=surfaceless (offscreen only)
2364 Recommended options: drm,x11])
2365 ;;
2366 esac
2367 }
2368
2369 radeon_gallium_llvm_check() {
2370 if test "x$enable_gallium_llvm" != "xyes"; then
2371 AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2372 fi
2373 radeon_llvm_check $*
2374 }
2375
2376 swr_llvm_check() {
2377 gallium_require_llvm $1
2378 if test ${LLVM_VERSION_INT} -lt 306; then
2379 AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2380 fi
2381 if test "x$enable_gallium_llvm" != "xyes"; then
2382 AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2383 fi
2384 }
2385
2386 swr_require_cxx_feature_flags() {
2387 feature_name="$1"
2388 preprocessor_test="$2"
2389 option_list="$3"
2390 output_var="$4"
2391
2392 AC_MSG_CHECKING([whether $CXX supports $feature_name])
2393 AC_LANG_PUSH([C++])
2394 save_CXXFLAGS="$CXXFLAGS"
2395 save_IFS="$IFS"
2396 IFS=","
2397 found=0
2398 for opts in $option_list
2399 do
2400 unset IFS
2401 CXXFLAGS="$opts $save_CXXFLAGS"
2402 AC_COMPILE_IFELSE(
2403 [AC_LANG_PROGRAM(
2404 [ #if !($preprocessor_test)
2405 #error
2406 #endif
2407 ])],
2408 [found=1; break],
2409 [])
2410 IFS=","
2411 done
2412 IFS="$save_IFS"
2413 CXXFLAGS="$save_CXXFLAGS"
2414 AC_LANG_POP([C++])
2415 if test $found -eq 1; then
2416 AC_MSG_RESULT([$opts])
2417 eval "$output_var=\$opts"
2418 return 0
2419 fi
2420 AC_MSG_RESULT([no])
2421 AC_MSG_ERROR([swr requires $feature_name support])
2422 return 1
2423 }
2424
2425 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2426 if test -n "$with_gallium_drivers"; then
2427 gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2428 for driver in $gallium_drivers; do
2429 case "x$driver" in
2430 xsvga)
2431 HAVE_GALLIUM_SVGA=yes
2432 require_libdrm "svga"
2433 ;;
2434 xi915)
2435 HAVE_GALLIUM_I915=yes
2436 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2437 require_libdrm "Gallium i915"
2438 ;;
2439 xilo)
2440 HAVE_GALLIUM_ILO=yes
2441 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2442 require_libdrm "Gallium i965/ilo"
2443 ;;
2444 xr300)
2445 HAVE_GALLIUM_R300=yes
2446 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2447 require_libdrm "r300"
2448 gallium_require_llvm "r300"
2449 ;;
2450 xr600)
2451 HAVE_GALLIUM_R600=yes
2452 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2453 require_libdrm "r600"
2454 if test "x$enable_opencl" = xyes; then
2455 radeon_gallium_llvm_check "r600" "3" "6" "0"
2456
2457 llvm_add_component "asmparser" "r600"
2458 llvm_add_component "bitreader" "r600"
2459 fi
2460 ;;
2461 xradeonsi)
2462 HAVE_GALLIUM_RADEONSI=yes
2463 PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2464 PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2465 require_libdrm "radeonsi"
2466 radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2467 require_basic_egl "radeonsi"
2468 ;;
2469 xnouveau)
2470 HAVE_GALLIUM_NOUVEAU=yes
2471 PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2472 require_libdrm "nouveau"
2473 ;;
2474 xfreedreno)
2475 HAVE_GALLIUM_FREEDRENO=yes
2476 PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2477 require_libdrm "freedreno"
2478 ;;
2479 xswrast)
2480 HAVE_GALLIUM_SOFTPIPE=yes
2481 if test "x$MESA_LLVM" = x1 && test "x$enable_gallium_llvm" == "xyes"; then
2482 HAVE_GALLIUM_LLVMPIPE=yes
2483 fi
2484 ;;
2485 xswr)
2486 swr_llvm_check "swr"
2487
2488 swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2489 ",-std=c++11" \
2490 SWR_CXX11_CXXFLAGS
2491 AC_SUBST([SWR_CXX11_CXXFLAGS])
2492
2493 swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2494 ",-mavx,-march=core-avx" \
2495 SWR_AVX_CXXFLAGS
2496 AC_SUBST([SWR_AVX_CXXFLAGS])
2497
2498 swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2499 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2500 SWR_AVX2_CXXFLAGS
2501 AC_SUBST([SWR_AVX2_CXXFLAGS])
2502
2503 HAVE_GALLIUM_SWR=yes
2504 ;;
2505 xvc4)
2506 HAVE_GALLIUM_VC4=yes
2507 PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2508 require_libdrm "vc4"
2509
2510 PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2511 [USE_VC4_SIMULATOR=yes;
2512 DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2513 [USE_VC4_SIMULATOR=no])
2514 ;;
2515 xvirgl)
2516 HAVE_GALLIUM_VIRGL=yes
2517 require_libdrm "virgl"
2518 require_basic_egl "virgl"
2519 ;;
2520 *)
2521 AC_MSG_ERROR([Unknown Gallium driver: $driver])
2522 ;;
2523 esac
2524 done
2525 fi
2526
2527 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2528 radeon_llvm_check "radv" "3" "9" "0"
2529 fi
2530
2531 dnl Set LLVM_LIBS - This is done after the driver configuration so
2532 dnl that drivers can add additional components to LLVM_COMPONENTS.
2533 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2534 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2535 dnl this was causing the same libraries to be appear multiple times
2536 dnl in LLVM_LIBS.
2537
2538 if test "x$MESA_LLVM" != x0; then
2539
2540 if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2541 AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2542 fi
2543 LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2544
2545 dnl llvm-config may not give the right answer when llvm is a built as a
2546 dnl single shared library, so we must work the library name out for
2547 dnl ourselves.
2548 dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2549 if test "x$enable_llvm_shared_libs" = xyes; then
2550 dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2551 LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2552 AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2553
2554 if test "x$llvm_have_one_so" = xyes; then
2555 dnl LLVM was built using auto*, so there is only one shared object.
2556 LLVM_LIBS="-l$LLVM_SO_NAME"
2557 else
2558 dnl If LLVM was built with CMake, there will be one shared object per
2559 dnl component.
2560 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2561 [AC_MSG_ERROR([Could not find llvm shared libraries:
2562 Please make sure you have built llvm with the --enable-shared option
2563 and that your llvm libraries are installed in $LLVM_LIBDIR
2564 If you have installed your llvm libraries to a different directory you
2565 can use the --with-llvm-prefix= configure flag to specify this directory.
2566 NOTE: Mesa is attempting to use llvm shared libraries by default.
2567 If you do not want to build with llvm shared libraries and instead want to
2568 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2569 invocation and rebuild.])])
2570
2571 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2572 dnl install uses a shared object for each component and we have
2573 dnl already added all of these objects to LLVM_LIBS.
2574 fi
2575 else
2576 AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2577 dnl We need to link to llvm system libs when using static libs
2578 dnl However, only llvm 3.5+ provides --system-libs
2579 if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2580 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2581 fi
2582 fi
2583 fi
2584
2585 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2586 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2587 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2588 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2589 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2590 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2591 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2592 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2593 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2594 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2595 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2596 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2597 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2598 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2599 "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2600 "x$HAVE_GALLIUM_SWR" = xyes)
2601 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2602 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2603
2604 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2605
2606 if test "x$enable_dri" = xyes; then
2607 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2608 fi
2609
2610 if test "x$have_drisw_kms" = xyes; then
2611 GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2612 fi
2613 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2614
2615 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2616 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2617 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2618 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2619 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2620 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2621
2622 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2623 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2624
2625 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2626 "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2627 "x$HAVE_RADEON_VULKAN" = xyes)
2628
2629 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2630 "x$HAVE_I965_DRI" = xyes)
2631
2632 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2633 "x$HAVE_GALLIUM_R600" = xyes -o \
2634 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2635 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2636 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2637 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2638 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2639 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2640 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2641 AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2642 fi
2643
2644 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2645 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2646 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2647 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2648 "x$enable_gallium_osmesa" = xyes)
2649
2650 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2651 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2652 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2653
2654 AC_SUBST([NINE_MAJOR], 1)
2655 AC_SUBST([NINE_MINOR], 0)
2656 AC_SUBST([NINE_TINY], 0)
2657 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2658
2659 AC_SUBST([VDPAU_MAJOR], 1)
2660 AC_SUBST([VDPAU_MINOR], 0)
2661
2662 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2663 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2664 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2665 AC_SUBST([VA_MINOR], $VA_MINOR)
2666
2667 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2668
2669 AC_SUBST([XVMC_MAJOR], 1)
2670 AC_SUBST([XVMC_MINOR], 0)
2671
2672 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2673 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2674 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2675 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2676
2677 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2678 AC_SUBST([XA_MINOR], $XA_MINOR)
2679 AC_SUBST([XA_TINY], $XA_TINY)
2680 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2681
2682 AC_ARG_ENABLE(valgrind,
2683 [AS_HELP_STRING([--enable-valgrind],
2684 [Build mesa with valgrind support (default: auto)])],
2685 [VALGRIND=$enableval], [VALGRIND=auto])
2686 if test "x$VALGRIND" != xno; then
2687 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2688 fi
2689 AC_MSG_CHECKING([whether to enable Valgrind support])
2690 if test "x$VALGRIND" = xauto; then
2691 VALGRIND="$have_valgrind"
2692 fi
2693
2694 if test "x$VALGRIND" = "xyes"; then
2695 if ! test "x$have_valgrind" = xyes; then
2696 AC_MSG_ERROR([Valgrind support required but not present])
2697 fi
2698 AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2699 fi
2700
2701 AC_MSG_RESULT([$VALGRIND])
2702
2703 dnl Restore LDFLAGS and CPPFLAGS
2704 LDFLAGS="$_SAVE_LDFLAGS"
2705 CPPFLAGS="$_SAVE_CPPFLAGS"
2706
2707 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2708 if test "x$acv_mesa_CLANG" = xyes; then
2709 CFLAGS="$CFLAGS -Qunused-arguments"
2710 CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2711 fi
2712
2713 dnl Add user CFLAGS and CXXFLAGS
2714 CFLAGS="$CFLAGS $USER_CFLAGS"
2715 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2716
2717 dnl Substitute the config
2718 AC_CONFIG_FILES([Makefile
2719 src/Makefile
2720 src/amd/Makefile
2721 src/amd/vulkan/Makefile
2722 src/compiler/Makefile
2723 src/egl/Makefile
2724 src/egl/main/egl.pc
2725 src/egl/wayland/wayland-drm/Makefile
2726 src/egl/wayland/wayland-egl/Makefile
2727 src/egl/wayland/wayland-egl/wayland-egl.pc
2728 src/gallium/Makefile
2729 src/gallium/auxiliary/Makefile
2730 src/gallium/auxiliary/pipe-loader/Makefile
2731 src/gallium/drivers/freedreno/Makefile
2732 src/gallium/drivers/ddebug/Makefile
2733 src/gallium/drivers/i915/Makefile
2734 src/gallium/drivers/ilo/Makefile
2735 src/gallium/drivers/llvmpipe/Makefile
2736 src/gallium/drivers/noop/Makefile
2737 src/gallium/drivers/nouveau/Makefile
2738 src/gallium/drivers/r300/Makefile
2739 src/gallium/drivers/r600/Makefile
2740 src/gallium/drivers/radeon/Makefile
2741 src/gallium/drivers/radeonsi/Makefile
2742 src/gallium/drivers/rbug/Makefile
2743 src/gallium/drivers/softpipe/Makefile
2744 src/gallium/drivers/svga/Makefile
2745 src/gallium/drivers/swr/Makefile
2746 src/gallium/drivers/trace/Makefile
2747 src/gallium/drivers/vc4/Makefile
2748 src/gallium/drivers/virgl/Makefile
2749 src/gallium/state_trackers/clover/Makefile
2750 src/gallium/state_trackers/dri/Makefile
2751 src/gallium/state_trackers/glx/xlib/Makefile
2752 src/gallium/state_trackers/nine/Makefile
2753 src/gallium/state_trackers/omx/Makefile
2754 src/gallium/state_trackers/osmesa/Makefile
2755 src/gallium/state_trackers/va/Makefile
2756 src/gallium/state_trackers/vdpau/Makefile
2757 src/gallium/state_trackers/xa/Makefile
2758 src/gallium/state_trackers/xvmc/Makefile
2759 src/gallium/targets/d3dadapter9/Makefile
2760 src/gallium/targets/d3dadapter9/d3d.pc
2761 src/gallium/targets/dri/Makefile
2762 src/gallium/targets/libgl-xlib/Makefile
2763 src/gallium/targets/omx/Makefile
2764 src/gallium/targets/opencl/Makefile
2765 src/gallium/targets/opencl/mesa.icd
2766 src/gallium/targets/osmesa/Makefile
2767 src/gallium/targets/osmesa/osmesa.pc
2768 src/gallium/targets/pipe-loader/Makefile
2769 src/gallium/targets/va/Makefile
2770 src/gallium/targets/vdpau/Makefile
2771 src/gallium/targets/xa/Makefile
2772 src/gallium/targets/xa/xatracker.pc
2773 src/gallium/targets/xvmc/Makefile
2774 src/gallium/tests/trivial/Makefile
2775 src/gallium/tests/unit/Makefile
2776 src/gallium/winsys/freedreno/drm/Makefile
2777 src/gallium/winsys/i915/drm/Makefile
2778 src/gallium/winsys/intel/drm/Makefile
2779 src/gallium/winsys/nouveau/drm/Makefile
2780 src/gallium/winsys/radeon/drm/Makefile
2781 src/gallium/winsys/amdgpu/drm/Makefile
2782 src/gallium/winsys/svga/drm/Makefile
2783 src/gallium/winsys/sw/dri/Makefile
2784 src/gallium/winsys/sw/kms-dri/Makefile
2785 src/gallium/winsys/sw/null/Makefile
2786 src/gallium/winsys/sw/wrapper/Makefile
2787 src/gallium/winsys/sw/xlib/Makefile
2788 src/gallium/winsys/vc4/drm/Makefile
2789 src/gallium/winsys/virgl/drm/Makefile
2790 src/gallium/winsys/virgl/vtest/Makefile
2791 src/gbm/Makefile
2792 src/gbm/main/gbm.pc
2793 src/glx/Makefile
2794 src/glx/apple/Makefile
2795 src/glx/tests/Makefile
2796 src/glx/windows/Makefile
2797 src/glx/windows/windowsdriproto.pc
2798 src/gtest/Makefile
2799 src/intel/Makefile
2800 src/intel/tools/Makefile
2801 src/intel/vulkan/Makefile
2802 src/loader/Makefile
2803 src/mapi/Makefile
2804 src/mapi/es1api/glesv1_cm.pc
2805 src/mapi/es2api/glesv2.pc
2806 src/mapi/glapi/gen/Makefile
2807 src/mesa/Makefile
2808 src/mesa/gl.pc
2809 src/mesa/drivers/dri/dri.pc
2810 src/mesa/drivers/dri/common/Makefile
2811 src/mesa/drivers/dri/common/xmlpool/Makefile
2812 src/mesa/drivers/dri/i915/Makefile
2813 src/mesa/drivers/dri/i965/Makefile
2814 src/mesa/drivers/dri/Makefile
2815 src/mesa/drivers/dri/nouveau/Makefile
2816 src/mesa/drivers/dri/r200/Makefile
2817 src/mesa/drivers/dri/radeon/Makefile
2818 src/mesa/drivers/dri/swrast/Makefile
2819 src/mesa/drivers/osmesa/Makefile
2820 src/mesa/drivers/osmesa/osmesa.pc
2821 src/mesa/drivers/x11/Makefile
2822 src/mesa/main/tests/Makefile
2823 src/util/Makefile
2824 src/util/tests/hash_table/Makefile
2825 src/vulkan/wsi/Makefile])
2826
2827 AC_OUTPUT
2828
2829 # Fix up dependencies in *.Plo files, where we changed the extension of a
2830 # source file
2831 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2832
2833
2834 dnl
2835 dnl Output some configuration info for the user
2836 dnl
2837 echo ""
2838 echo " prefix: $prefix"
2839 echo " exec_prefix: $exec_prefix"
2840 echo " libdir: $libdir"
2841 echo " includedir: $includedir"
2842
2843 dnl API info
2844 echo ""
2845 echo " OpenGL: $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2846
2847 dnl Driver info
2848 echo ""
2849 case "x$enable_osmesa$enable_gallium_osmesa" in
2850 xnoyes)
2851 echo " OSMesa: lib$OSMESA_LIB (Gallium)"
2852 ;;
2853 xyesno)
2854 echo " OSMesa: lib$OSMESA_LIB"
2855 ;;
2856 xnono)
2857 echo " OSMesa: no"
2858 ;;
2859 esac
2860
2861 echo ""
2862 if test "x$enable_dri" != xno; then
2863 echo " DRI platform: $dri_platform"
2864 if test -z "$DRI_DIRS"; then
2865 echo " DRI drivers: no"
2866 else
2867 echo " DRI drivers: $DRI_DIRS"
2868 fi
2869 echo " DRI driver dir: $DRI_DRIVER_INSTALL_DIR"
2870 fi
2871
2872 case "x$enable_glx" in
2873 xdri)
2874 echo " GLX: DRI-based"
2875 ;;
2876 xxlib)
2877 echo " GLX: Xlib-based"
2878 ;;
2879 xgallium-xlib)
2880 echo " GLX: Xlib-based (Gallium)"
2881 ;;
2882 *)
2883 echo " GLX: $enable_glx"
2884 ;;
2885 esac
2886
2887 dnl EGL
2888 echo ""
2889 echo " EGL: $enable_egl"
2890 if test "$enable_egl" = yes; then
2891 echo " EGL platforms: $egl_platforms"
2892
2893 egl_drivers=""
2894 if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2895 egl_drivers="$egl_drivers builtin:egl_dri2"
2896 fi
2897 if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2898 egl_drivers="$egl_drivers builtin:egl_dri3"
2899 fi
2900
2901 echo " EGL drivers: $egl_drivers"
2902 fi
2903 if test "x$enable_gbm" = xyes; then
2904 echo " GBM: yes"
2905 else
2906 echo " GBM: no"
2907 fi
2908
2909 # Vulkan
2910 echo ""
2911 if test "x$VULKAN_DRIVERS" != x; then
2912 echo " Vulkan drivers: $VULKAN_DRIVERS"
2913 echo " Vulkan ICD dir: $VULKAN_ICD_INSTALL_DIR"
2914 else
2915 echo " Vulkan drivers: no"
2916 fi
2917
2918 echo ""
2919 if test "x$MESA_LLVM" = x1; then
2920 echo " llvm: yes"
2921 echo " llvm-config: $LLVM_CONFIG"
2922 echo " llvm-version: $LLVM_VERSION"
2923 else
2924 echo " llvm: no"
2925 fi
2926
2927 echo ""
2928 if test -n "$with_gallium_drivers"; then
2929 echo " Gallium drivers: $gallium_drivers"
2930 echo " Gallium st: $gallium_st"
2931 else
2932 echo " Gallium: no"
2933 fi
2934
2935 echo ""
2936 if test "x$enable_gallium_extra_hud" != xyes; then
2937 echo " HUD extra stats: no"
2938 else
2939 echo " HUD extra stats: yes"
2940 fi
2941
2942 if test "x$enable_lmsensors" != xyes; then
2943 echo " HUD lmsensors: no"
2944 else
2945 echo " HUD lmsensors: yes"
2946 fi
2947
2948 dnl Shader cache
2949 echo ""
2950 echo " Shader cache: $enable_shader_cache"
2951 if test "x$enable_shader_cache" = "xyes"; then
2952 echo " With SHA1 from: $with_sha1"
2953 fi
2954
2955 dnl Libraries
2956 echo ""
2957 echo " Shared libs: $enable_shared"
2958 echo " Static libs: $enable_static"
2959 echo " Shared-glapi: $enable_shared_glapi"
2960
2961 dnl Compiler options
2962 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2963 cflags=`echo $CFLAGS | \
2964 $SED 's/^ *//;s/ */ /;s/ *$//'`
2965 cxxflags=`echo $CXXFLAGS | \
2966 $SED 's/^ *//;s/ */ /;s/ *$//'`
2967 defines=`echo $DEFINES | $SED 's/^ *//;s/ */ /;s/ *$//'`
2968 echo ""
2969 echo " CFLAGS: $cflags"
2970 echo " CXXFLAGS: $cxxflags"
2971 echo " Macros: $defines"
2972 echo ""
2973 if test "x$MESA_LLVM" = x1; then
2974 echo " LLVM_CFLAGS: $LLVM_CFLAGS"
2975 echo " LLVM_CXXFLAGS: $LLVM_CXXFLAGS"
2976 echo " LLVM_CPPFLAGS: $LLVM_CPPFLAGS"
2977 echo " LLVM_LDFLAGS: $LLVM_LDFLAGS"
2978 echo ""
2979 fi
2980 echo " PYTHON2: $PYTHON2"
2981
2982 echo ""
2983 echo " Run '${MAKE-make}' to build Mesa"
2984 echo ""