configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19 AM_INIT_AUTOMAKE([foreign])
  20
  21 # Support silent build rules, requires at least automake-1.11. Disable
  22 # by either passing --disable-silent-rules to configure or passing V=1
  23 # to make
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  30 USER_CFLAGS="$CFLAGS"
  31 USER_CXXFLAGS="$CXXFLAGS"
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.24
  36 LIBDRM_INTEL_REQUIRED=2.4.30
  37 LIBDRM_NOUVEAU_REQUIRED=0.6
  38 DRI2PROTO_REQUIRED=2.6
  39 GLPROTO_REQUIRED=1.4.14
  40 LIBDRM_XORG_REQUIRED=2.4.24
  41 LIBKMS_XORG_REQUIRED=1.0.0
  42
  43 dnl Check for progs
  44 AC_PROG_CPP
  45 AC_PROG_CC
  46 AC_PROG_CXX
  47 AC_CHECK_PROGS([MAKE], [gmake make])
  48 AC_CHECK_PROGS([PYTHON2], [python2 python])
  49 AC_PROG_SED
  50 AC_PROG_MKDIR_P
  51 AC_PATH_PROG([MKDEP], [makedepend])
  52
  53 if test "x$MKDEP" = "x"; then
  54     AC_MSG_ERROR([makedepend is required to build Mesa])
  55 fi
  56
  57 AC_PATH_PROG([FLEX], [flex])
  58 test "x$FLEX" = "x" && AC_MSG_ERROR([flex is needed to build Mesa])
  59
  60 AC_PATH_PROG([BISON], [bison])
  61 test "x$BISON" = "x" && AC_MSG_ERROR([bison is needed to build Mesa])
  62
  63 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  64 dnl configuration in that case.
  65 AC_PROG_INSTALL
  66 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  67
  68 dnl We need a POSIX shell for parts of the build. Assume we have one
  69 dnl in most cases.
  70 case "$host_os" in
  71 solaris*)
  72     # Solaris /bin/sh is too old/non-POSIX compliant
  73     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  74     SHELL="$POSIX_SHELL"
  75     ;;
  76 esac
  77
  78 AC_PATH_PROG([GTESTCONFIG], [gtest-config])
  79 if test "x$GTESTCONFIG" != "x"; then
  80     GTEST_CFLAGS=`gtest-config --cppflags --cxxflags`
  81     GTEST_LIBS=`gtest-config --ldflags --libs`
  82     AC_SUBST([GTEST_CFLAGS])
  83     AC_SUBST([GTEST_LIBS])
  84     HAVE_GTEST=yes
  85 else
  86     HAVE_GTEST=no
  87 fi
  88 AM_CONDITIONAL(HAVE_GTEST, test x$HAVE_GTEST = xyes)
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         major=`echo $GCC_VERSION | cut -d. -f1`
 114         minor=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123 fi
 124
 125
 126 MKDEP_OPTIONS=-fdepend
 127 dnl Ask gcc where it's keeping its secret headers
 128 if test "x$GCC" = xyes; then
 129     for dir in include include-fixed; do
 130         GCC_INCLUDES=`$CC -print-file-name=$dir`
 131         if test "x$GCC_INCLUDES" != x && \
 132            test "$GCC_INCLUDES" != "$dir" && \
 133            test -d "$GCC_INCLUDES"; then
 134             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 135         fi
 136     done
 137 fi
 138 AC_SUBST([MKDEP_OPTIONS])
 139
 140 dnl Make sure the pkg-config macros are defined
 141 m4_ifndef([PKG_PROG_PKG_CONFIG],
 142     [m4_fatal([Could not locate the pkg-config autoconf macros.
 143   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 144   are in a different location, try setting the environment variable
 145   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 146 PKG_PROG_PKG_CONFIG()
 147
 148 dnl LIB_DIR - library basename
 149 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 150 AC_SUBST([LIB_DIR])
 151
 152 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 153 _SAVE_LDFLAGS="$LDFLAGS"
 154 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 155 AC_SUBST([EXTRA_LIB_PATH])
 156
 157 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 158 _SAVE_CPPFLAGS="$CPPFLAGS"
 159 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 160 AC_SUBST([X11_INCLUDES])
 161
 162 dnl Compiler macros
 163 DEFINES=""
 164 AC_SUBST([DEFINES])
 165 case "$host_os" in
 166 linux*|*-gnu*|gnu*)
 167     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 168     ;;
 169 solaris*)
 170     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 171     ;;
 172 cygwin*)
 173     DEFINES="$DEFINES -DPTHREADS"
 174     ;;
 175 esac
 176
 177 dnl Add flags for gcc and g++
 178 if test "x$GCC" = xyes; then
 179     CFLAGS="$CFLAGS -Wall -std=c99"
 180
 181     # Enable -Werror=implicit-function-declaration and
 182     # -Werror=missing-prototypes, if available, or otherwise, just
 183     # -Wmissing-prototypes.  This is particularly useful to avoid
 184     # generating a loadable driver module that has undefined symbols.
 185     save_CFLAGS="$CFLAGS"
 186     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 187     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 188     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 190                    AC_MSG_RESULT([yes]),
 191                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 192                     AC_MSG_RESULT([no])]);
 193
 194     # Enable -fvisibility=hidden if using a gcc that supports it
 195     save_CFLAGS="$CFLAGS"
 196     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 197     VISIBILITY_CFLAGS="-fvisibility=hidden"
 198     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 199     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 200                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 201
 202     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 203     CFLAGS=$save_CFLAGS
 204
 205     # Work around aliasing bugs - developers should comment this out
 206     CFLAGS="$CFLAGS -fno-strict-aliasing"
 207
 208     # gcc's builtin memcmp is slower than glibc's
 209     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 210     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 211 fi
 212 if test "x$GXX" = xyes; then
 213     CXXFLAGS="$CXXFLAGS -Wall"
 214
 215     # Enable -fvisibility=hidden if using a gcc that supports it
 216     save_CXXFLAGS="$CXXFLAGS"
 217     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 218     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 219     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 220     AC_LANG_PUSH([C++])
 221     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 222                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 223     AC_LANG_POP([C++])
 224
 225     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 226     CXXFLAGS=$save_CXXFLAGS
 227
 228     # Work around aliasing bugs - developers should comment this out
 229     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 230
 231     # gcc's builtin memcmp is slower than glibc's
 232     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 233     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 234 fi
 235
 236 dnl even if the compiler appears to support it, using visibility attributes isn't
 237 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 238 case "$host_os" in
 239 cygwin*)
 240     VISIBILITY_CFLAGS=""
 241     VISIBILITY_CXXFLAGS=""
 242     ;;
 243 esac
 244
 245 AC_SUBST([VISIBILITY_CFLAGS])
 246 AC_SUBST([VISIBILITY_CXXFLAGS])
 247
 248 dnl These should be unnecessary, but let the user set them if they want
 249 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 250     Default is to use CFLAGS.])
 251 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 252     compiler. Default is to use CFLAGS.])
 253 AC_SUBST([OPT_FLAGS])
 254 AC_SUBST([ARCH_FLAGS])
 255
 256 dnl
 257 dnl Hacks to enable 32 or 64 bit build
 258 dnl
 259 AC_ARG_ENABLE([32-bit],
 260     [AS_HELP_STRING([--enable-32-bit],
 261         [build 32-bit libraries @<:@default=auto@:>@])],
 262     [enable_32bit="$enableval"],
 263     [enable_32bit=auto]
 264 )
 265 if test "x$enable_32bit" = xyes; then
 266     if test "x$GCC" = xyes; then
 267         CFLAGS="$CFLAGS -m32"
 268         ARCH_FLAGS="$ARCH_FLAGS -m32"
 269     fi
 270     if test "x$GXX" = xyes; then
 271         CXXFLAGS="$CXXFLAGS -m32"
 272     fi
 273 fi
 274 AC_ARG_ENABLE([64-bit],
 275     [AS_HELP_STRING([--enable-64-bit],
 276         [build 64-bit libraries @<:@default=auto@:>@])],
 277     [enable_64bit="$enableval"],
 278     [enable_64bit=auto]
 279 )
 280 if test "x$enable_64bit" = xyes; then
 281     if test "x$GCC" = xyes; then
 282         CFLAGS="$CFLAGS -m64"
 283     fi
 284     if test "x$GXX" = xyes; then
 285         CXXFLAGS="$CXXFLAGS -m64"
 286     fi
 287 fi
 288
 289 dnl Can't have static and shared libraries, default to static if user
 290 dnl explicitly requested. If both disabled, set to static since shared
 291 dnl was explicitly requested.
 292 case "x$enable_static$enable_shared" in
 293 xyesyes )
 294     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 295     enable_shared=no
 296     ;;
 297 xnono )
 298     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 299     enable_static=yes
 300     ;;
 301 esac
 302
 303 dnl
 304 dnl mklib options
 305 dnl
 306 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 307 if test "$enable_static" = yes; then
 308     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 309 fi
 310 AC_SUBST([MKLIB_OPTIONS])
 311
 312 dnl
 313 dnl other compiler options
 314 dnl
 315 AC_ARG_ENABLE([debug],
 316     [AS_HELP_STRING([--enable-debug],
 317         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 318     [enable_debug="$enableval"],
 319     [enable_debug=no]
 320 )
 321 if test "x$enable_debug" = xyes; then
 322     DEFINES="$DEFINES -DDEBUG"
 323     if test "x$GCC" = xyes; then
 324         CFLAGS="$CFLAGS -g"
 325     fi
 326     if test "x$GXX" = xyes; then
 327         CXXFLAGS="$CXXFLAGS -g"
 328     fi
 329 fi
 330
 331 dnl
 332 dnl library names
 333 dnl
 334 LIB_PREFIX_GLOB='lib'
 335 LIB_VERSION_SEPARATOR='.'
 336 if test "$enable_static" = yes; then
 337     LIB_EXTENSION='a'
 338 else
 339     case "$host_os" in
 340     darwin* )
 341         LIB_EXTENSION='dylib' ;;
 342     cygwin* )
 343         dnl prefix can be 'cyg' or 'lib'
 344         LIB_PREFIX_GLOB='???'
 345         LIB_VERSION_SEPARATOR='-'
 346         LIB_EXTENSION='dll' ;;
 347     aix* )
 348         LIB_EXTENSION='a' ;;
 349     * )
 350         LIB_EXTENSION='so' ;;
 351     esac
 352 fi
 353
 354 dnl
 355 dnl Mangled Mesa support
 356 dnl
 357 AC_ARG_ENABLE([mangling],
 358   [AS_HELP_STRING([--enable-mangling],
 359     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 360   [enable_mangling="${enableval}"],
 361   [enable_mangling=no]
 362 )
 363 GL_LIB="GL"
 364 GLU_LIB="GLU"
 365 OSMESA_LIB="OSMesa"
 366 if test "x${enable_mangling}" = "xyes" ; then
 367   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 368   GL_LIB="MangledGL"
 369   GLU_LIB="MangledGLU"
 370   OSMESA_LIB="MangledOSMesa"
 371 fi
 372 AC_SUBST([GL_LIB])
 373 AC_SUBST([GLU_LIB])
 374 AC_SUBST([OSMESA_LIB])
 375
 376 dnl
 377 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 378 dnl
 379 AC_ARG_ENABLE([texture-float],
 380     [AS_HELP_STRING([--enable-texture-float],
 381         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 382     [enable_texture_float="$enableval"],
 383     [enable_texture_float=no]
 384 )
 385 if test "x$enable_texture_float" = xyes; then
 386     AC_MSG_WARN([Floating-point textures enabled.])
 387     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 388     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 389 fi
 390
 391 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 392 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 393 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 394 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 395 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 396 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 397 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 398 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 399
 400 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409
 410 AC_SUBST([GL_LIB_NAME])
 411 AC_SUBST([GLU_LIB_NAME])
 412 AC_SUBST([OSMESA_LIB_NAME])
 413 AC_SUBST([EGL_LIB_NAME])
 414 AC_SUBST([GLESv1_CM_LIB_NAME])
 415 AC_SUBST([GLESv2_LIB_NAME])
 416 AC_SUBST([VG_LIB_NAME])
 417 AC_SUBST([GLAPI_LIB_NAME])
 418
 419 AC_SUBST([GL_LIB_GLOB])
 420 AC_SUBST([GLU_LIB_GLOB])
 421 AC_SUBST([OSMESA_LIB_GLOB])
 422 AC_SUBST([EGL_LIB_GLOB])
 423 AC_SUBST([GLESv1_CM_LIB_GLOB])
 424 AC_SUBST([GLESv2_LIB_GLOB])
 425 AC_SUBST([VG_LIB_GLOB])
 426 AC_SUBST([GLAPI_LIB_GLOB])
 427
 428 dnl
 429 dnl Arch/platform-specific settings
 430 dnl
 431 AC_ARG_ENABLE([asm],
 432     [AS_HELP_STRING([--disable-asm],
 433         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 434     [enable_asm="$enableval"],
 435     [enable_asm=yes]
 436 )
 437 asm_arch=""
 438 ASM_FLAGS=""
 439 MESA_ASM_SOURCES=""
 440 GLAPI_ASM_SOURCES=""
 441 AC_MSG_CHECKING([whether to enable assembly])
 442 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 443 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 444 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 445     case "$host_cpu" in
 446     i?86 | x86_64)
 447         enable_asm=no
 448         AC_MSG_RESULT([no, cross compiling])
 449         ;;
 450     esac
 451 fi
 452 # check for supported arches
 453 if test "x$enable_asm" = xyes; then
 454     case "$host_cpu" in
 455     i?86)
 456         case "$host_os" in
 457         linux* | *freebsd* | dragonfly* | *netbsd*)
 458             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 459             ;;
 460         esac
 461         ;;
 462     x86_64)
 463         case "$host_os" in
 464         linux* | *freebsd* | dragonfly* | *netbsd*)
 465             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 466             ;;
 467         esac
 468         ;;
 469     powerpc)
 470         case "$host_os" in
 471         linux*)
 472             asm_arch=ppc
 473             ;;
 474         esac
 475         ;;
 476     sparc*)
 477         case "$host_os" in
 478         linux*)
 479             asm_arch=sparc
 480             ;;
 481         esac
 482         ;;
 483     esac
 484
 485     case "$asm_arch" in
 486     x86)
 487         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 488         MESA_ASM_SOURCES='$(X86_SOURCES)'
 489         GLAPI_ASM_SOURCES='$(X86_API)'
 490         AC_MSG_RESULT([yes, x86])
 491         ;;
 492     x86_64)
 493         ASM_FLAGS="-DUSE_X86_64_ASM"
 494         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 495         GLAPI_ASM_SOURCES='$(X86-64_API)'
 496         AC_MSG_RESULT([yes, x86_64])
 497         ;;
 498     sparc)
 499         ASM_FLAGS="-DUSE_SPARC_ASM"
 500         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 501         GLAPI_ASM_SOURCES='$(SPARC_API)'
 502         AC_MSG_RESULT([yes, sparc])
 503         ;;
 504     *)
 505         AC_MSG_RESULT([no, platform not supported])
 506         ;;
 507     esac
 508 fi
 509 AC_SUBST([ASM_FLAGS])
 510 AC_SUBST([MESA_ASM_SOURCES])
 511 AC_SUBST([GLAPI_ASM_SOURCES])
 512
 513 dnl PIC code macro
 514 MESA_PIC_FLAGS
 515
 516 dnl Check to see if dlopen is in default libraries (like Solaris, which
 517 dnl has it in libc), or if libdl is needed to get it.
 518 AC_CHECK_FUNC([dlopen], [],
 519     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 520 AC_SUBST([DLOPEN_LIBS])
 521
 522 dnl See if posix_memalign is available
 523 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 524
 525 dnl SELinux awareness.
 526 AC_ARG_ENABLE([selinux],
 527     [AS_HELP_STRING([--enable-selinux],
 528         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 529     [MESA_SELINUX="$enableval"],
 530     [MESA_SELINUX=no])
 531 if test "x$enable_selinux" = "xyes"; then
 532     AC_CHECK_HEADER([selinux/selinux.h],[],
 533                     [AC_MSG_ERROR([SELinux headers not found])])
 534     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 535                  [AC_MSG_ERROR([SELinux library not found])])
 536     SELINUX_LIBS="-lselinux"
 537     DEFINES="$DEFINES -DMESA_SELINUX"
 538 fi
 539
 540 dnl Options for APIs
 541 AC_ARG_ENABLE([opengl],
 542     [AS_HELP_STRING([--disable-opengl],
 543         [disable support for standard OpenGL API @<:@default=no@:>@])],
 544     [enable_opengl="$enableval"],
 545     [enable_opengl=yes])
 546 AC_ARG_ENABLE([gles1],
 547     [AS_HELP_STRING([--enable-gles1],
 548         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 549     [enable_gles1="$enableval"],
 550     [enable_gles1=no])
 551 AC_ARG_ENABLE([gles2],
 552     [AS_HELP_STRING([--enable-gles2],
 553         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 554     [enable_gles2="$enableval"],
 555     [enable_gles2=no])
 556 AC_ARG_ENABLE([openvg],
 557     [AS_HELP_STRING([--enable-openvg],
 558         [enable support for OpenVG API @<:@default=no@:>@])],
 559     [enable_openvg="$enableval"],
 560     [enable_openvg=no])
 561
 562 AC_ARG_ENABLE([dri],
 563     [AS_HELP_STRING([--enable-dri],
 564         [enable DRI modules @<:@default=auto@:>@])],
 565     [enable_dri="$enableval"],
 566     [enable_dri=auto])
 567 AC_ARG_ENABLE([glx],
 568     [AS_HELP_STRING([--enable-glx],
 569         [enable GLX library @<:@default=auto@:>@])],
 570     [enable_glx="$enableval"],
 571     [enable_glx=auto])
 572 AC_ARG_ENABLE([osmesa],
 573     [AS_HELP_STRING([--enable-osmesa],
 574         [enable OSMesa library @<:@default=auto@:>@])],
 575     [enable_osmesa="$enableval"],
 576     [enable_osmesa=auto])
 577 AC_ARG_ENABLE([egl],
 578     [AS_HELP_STRING([--disable-egl],
 579         [disable EGL library @<:@default=enabled@:>@])],
 580     [enable_egl="$enableval"],
 581     [enable_egl=yes])
 582
 583 AC_ARG_ENABLE([xorg],
 584     [AS_HELP_STRING([--enable-xorg],
 585         [enable support for X.Org DDX API @<:@default=no@:>@])],
 586     [enable_xorg="$enableval"],
 587     [enable_xorg=no])
 588 AC_ARG_ENABLE([xa],
 589     [AS_HELP_STRING([--enable-xa],
 590         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 591     [enable_xa="$enableval"],
 592     [enable_xa=no])
 593 AC_ARG_ENABLE([d3d1x],
 594     [AS_HELP_STRING([--enable-d3d1x],
 595         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 596     [enable_d3d1x="$enableval"],
 597     [enable_d3d1x=no])
 598 AC_ARG_ENABLE([gbm],
 599    [AS_HELP_STRING([--enable-gbm],
 600          [enable gbm library @<:@default=auto@:>@])],
 601    [enable_gbm="$enableval"],
 602    [enable_gbm=auto])
 603
 604 AC_ARG_ENABLE([xvmc],
 605    [AS_HELP_STRING([--enable-xvmc],
 606          [enable xvmc library @<:@default=auto@:>@])],
 607    [enable_xvmc="$enableval"],
 608    [enable_xvmc=auto])
 609 AC_ARG_ENABLE([vdpau],
 610    [AS_HELP_STRING([--enable-vdpau],
 611          [enable vdpau library @<:@default=auto@:>@])],
 612    [enable_vdpau="$enableval"],
 613    [enable_vdpau=auto])
 614 AC_ARG_ENABLE([va],
 615    [AS_HELP_STRING([--enable-va],
 616          [enable va library @<:@default=auto@:>@])],
 617    [enable_va="$enableval"],
 618    [enable_va=auto])
 619
 620 AC_ARG_ENABLE([xlib_glx],
 621     [AS_HELP_STRING([--enable-xlib-glx],
 622         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 623     [enable_xlib_glx="$enableval"],
 624     [enable_xlib_glx=auto])
 625 AC_ARG_ENABLE([gallium_egl],
 626     [AS_HELP_STRING([--enable-gallium-egl],
 627         [enable optional EGL state tracker (not required
 628          for EGL support in Gallium with OpenGL and OpenGL ES)
 629          @<:@default=disable@:>@])],
 630     [enable_gallium_egl="$enableval"],
 631     [enable_gallium_egl=no])
 632 AC_ARG_ENABLE([gallium_gbm],
 633     [AS_HELP_STRING([--enable-gallium-gbm],
 634         [enable optional gbm state tracker (not required for
 635          gbm support in Gallium)
 636          @<:@default=auto@:>@])],
 637     [enable_gallium_gbm="$enableval"],
 638     [enable_gallium_gbm=auto])
 639
 640 # Option for Gallium drivers
 641 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 642
 643 AC_ARG_WITH([gallium-drivers],
 644     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 645         [comma delimited Gallium drivers list, e.g.
 646         "i915,nouveau,r300,r600,svga,swrast"
 647         @<:@default=r300,r600,swrast@:>@])],
 648     [with_gallium_drivers="$withval"],
 649     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 650
 651 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 652 # here so that the script doesn't choke on an unknown driver name later.
 653 case "$with_gallium_drivers" in
 654     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 655     no) with_gallium_drivers='' ;;
 656 esac
 657
 658 if test "x$enable_opengl" = xno -a \
 659         "x$enable_gles1" = xno -a \
 660         "x$enable_gles2" = xno -a \
 661         "x$enable_openvg" = xno -a \
 662         "x$enable_xorg" = xno -a \
 663         "x$enable_xa" = xno -a \
 664         "x$enable_d3d1x" = xno -a \
 665         "x$enable_xvmc" = xno -a \
 666         "x$enable_vdpau" = xno -a \
 667         "x$enable_va" = xno; then
 668     AC_MSG_ERROR([at least one API should be enabled])
 669 fi
 670
 671 API_DEFINES=""
 672 if test "x$enable_opengl" = xno; then
 673     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 674 else
 675     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 676 fi
 677 if test "x$enable_gles1" = xyes; then
 678     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 679 fi
 680 if test "x$enable_gles2" = xyes; then
 681     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 682 fi
 683 AC_SUBST([API_DEFINES])
 684
 685 AC_ARG_ENABLE([shared-glapi],
 686     [AS_HELP_STRING([--enable-shared-glapi],
 687         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 688     [enable_shared_glapi="$enableval"],
 689     [enable_shared_glapi=no])
 690
 691 SHARED_GLAPI="0"
 692 if test "x$enable_shared_glapi" = xyes; then
 693     SHARED_GLAPI="1"
 694 fi
 695 AC_SUBST([SHARED_GLAPI])
 696
 697 dnl
 698 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 699 dnl More later: fbdev, ...
 700 dnl
 701 default_driver="xlib"
 702
 703 case "$host_os" in
 704 linux*)
 705     case "$host_cpu" in
 706     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 707     esac
 708     ;;
 709 *freebsd* | dragonfly* | *netbsd*)
 710     case "$host_cpu" in
 711     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 712     esac
 713     ;;
 714 esac
 715
 716 if test "x$enable_opengl" = xno; then
 717     default_driver="no"
 718 fi
 719
 720 AC_ARG_WITH([driver],
 721     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 722     [mesa_driver="$withval"],
 723     [mesa_driver=auto])
 724 dnl Check for valid option
 725 case "x$mesa_driver" in
 726 xxlib|xdri|xosmesa|xno)
 727     if test "x$enable_dri" != xauto -o \
 728             "x$enable_glx" != xauto -o \
 729             "x$enable_osmesa" != xauto -o \
 730             "x$enable_xlib_glx" != xauto; then
 731         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 732     fi
 733     ;;
 734 xauto)
 735     mesa_driver="$default_driver"
 736     ;;
 737 *)
 738     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 739     ;;
 740 esac
 741
 742 # map $mesa_driver to APIs
 743 if test "x$enable_dri" = xauto; then
 744     case "x$mesa_driver" in
 745     xdri) enable_dri=yes ;;
 746     *)    enable_dri=no ;;
 747     esac
 748 fi
 749
 750 if test "x$enable_glx" = xauto; then
 751     case "x$mesa_driver" in
 752     xdri|xxlib) enable_glx=yes ;;
 753     *)          enable_glx=no ;;
 754     esac
 755 fi
 756
 757 if test "x$enable_osmesa" = xauto; then
 758     case "x$mesa_driver" in
 759     xxlib|xosmesa) enable_osmesa=yes ;;
 760     *)             enable_osmesa=no ;;
 761     esac
 762 fi
 763
 764 if test "x$enable_xlib_glx" = xauto; then
 765     case "x$mesa_driver" in
 766     xxlib) enable_xlib_glx=yes ;;
 767     *)     enable_xlib_glx=no ;;
 768     esac
 769 fi
 770
 771 if test "x$enable_glx" = xno; then
 772     enable_xlib_glx=no
 773 fi
 774
 775 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 776
 777 dnl
 778 dnl Driver specific build directories
 779 dnl
 780
 781 dnl this variable will be prepended to SRC_DIRS and is not exported
 782 CORE_DIRS=""
 783
 784 SRC_DIRS=""
 785 GLU_DIRS="sgi"
 786 GALLIUM_DIRS="auxiliary drivers state_trackers"
 787 GALLIUM_TARGET_DIRS=""
 788 GALLIUM_WINSYS_DIRS="sw"
 789 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 790 GALLIUM_STATE_TRACKERS_DIRS=""
 791
 792 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 793 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 794 x*yes*)
 795     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 796     ;;
 797 esac
 798
 799 # build glapi if OpenGL is enabled
 800 if test "x$enable_opengl" = xyes; then
 801     CORE_DIRS="$CORE_DIRS mapi/glapi"
 802 fi
 803
 804 # build es1api if OpenGL ES 1.x is enabled
 805 if test "x$enable_gles1" = xyes; then
 806     CORE_DIRS="$CORE_DIRS mapi/es1api"
 807 fi
 808
 809 # build es2api if OpenGL ES 2.x is enabled
 810 if test "x$enable_gles2" = xyes; then
 811     CORE_DIRS="$CORE_DIRS mapi/es2api"
 812 fi
 813
 814 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 815 case "x$enable_opengl$enable_gles1$enable_gles2" in
 816 x*yes*)
 817     CORE_DIRS="$CORE_DIRS glsl mesa"
 818     ;;
 819 esac
 820
 821 case "x$enable_glx$enable_xlib_glx" in
 822 xyesyes)
 823     DRIVER_DIRS="$DRIVER_DIRS x11"
 824     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 825     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 826     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 827     HAVE_WINSYS_XLIB="yes"
 828     ;;
 829 xyesno)
 830     # DRI-based GLX
 831     SRC_DIRS="$SRC_DIRS glx"
 832     ;;
 833 esac
 834
 835 if test "x$enable_dri" = xyes; then
 836     DRIVER_DIRS="$DRIVER_DIRS dri"
 837
 838     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 839     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 840     HAVE_ST_DRI="yes"
 841 fi
 842
 843 if test "x$enable_osmesa" = xyes; then
 844     # the empty space matters for osmesa... (see src/mesa/Makefile)
 845     if test -n "$DRIVER_DIRS"; then
 846         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 847     else
 848         DRIVER_DIRS="osmesa"
 849     fi
 850 fi
 851
 852 AC_SUBST([SRC_DIRS])
 853 AC_SUBST([GLU_DIRS])
 854 AC_SUBST([DRIVER_DIRS])
 855 AC_SUBST([GALLIUM_DIRS])
 856 AC_SUBST([GALLIUM_TARGET_DIRS])
 857 AC_SUBST([GALLIUM_WINSYS_DIRS])
 858 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 859 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 860 AC_SUBST([MESA_LLVM])
 861
 862 # Check for libdrm
 863 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 864                   [have_libdrm=yes], [have_libdrm=no])
 865
 866 if test "x$enable_dri" = xyes; then
 867     # DRI must be shared, I think
 868     if test "$enable_static" = yes; then
 869         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 870     fi
 871
 872     # not a hard requirement as swrast does not depend on it
 873     if test "x$have_libdrm" = xyes; then
 874         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 875     fi
 876 fi
 877
 878 dnl
 879 dnl Find out if X is available. The variable have_x is set if libX11 is
 880 dnl found to mimic AC_PATH_XTRA.
 881 dnl
 882 if test -n "$PKG_CONFIG"; then
 883     AC_MSG_CHECKING([pkg-config files for X11 are available])
 884     PKG_CHECK_EXISTS([x11],[
 885         x11_pkgconfig=yes
 886         have_x=yes
 887         ],[
 888         x11_pkgconfig=no
 889     ])
 890     AC_MSG_RESULT([$x11_pkgconfig])
 891 else
 892     x11_pkgconfig=no
 893 fi
 894 dnl Use the autoconf macro if no pkg-config files
 895 if test "$x11_pkgconfig" = yes; then
 896     PKG_CHECK_MODULES([X11], [x11])
 897 else
 898     AC_PATH_XTRA
 899     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 900     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 901     AC_SUBST([X11_CFLAGS])
 902     AC_SUBST([X11_LIBS])
 903 fi
 904
 905 dnl Try to tell the user that the --x-* options are only used when
 906 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 907 m4_divert_once([HELP_BEGIN],
 908 [These options are only used when the X libraries cannot be found by the
 909 pkg-config utility.])
 910
 911 dnl We need X for xlib and dri, so bomb now if it's not found
 912 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 913     AC_MSG_ERROR([X11 development libraries needed for GLX])
 914 fi
 915
 916 if test "x$enable_glx" = xyes; then
 917     DEFINES="$DEFINES -DUSE_XCB"
 918 fi
 919
 920 dnl Direct rendering or just indirect rendering
 921 case "$host_os" in
 922 gnu*)
 923     dnl Disable by default on GNU/Hurd
 924     driglx_direct_default="no"
 925     ;;
 926 cygwin*)
 927     dnl Disable by default on cygwin
 928     driglx_direct_default="no"
 929     ;;
 930 *)
 931     driglx_direct_default="yes"
 932     ;;
 933 esac
 934 AC_ARG_ENABLE([driglx-direct],
 935     [AS_HELP_STRING([--disable-driglx-direct],
 936         [enable direct rendering in GLX and EGL for DRI \
 937             @<:@default=auto@:>@])],
 938     [driglx_direct="$enableval"],
 939     [driglx_direct="$driglx_direct_default"])
 940
 941 dnl
 942 dnl libGL configuration per driver
 943 dnl
 944 case "x$enable_glx$enable_xlib_glx" in
 945 xyesyes)
 946     # Xlib-based GLX
 947     if test "$x11_pkgconfig" = yes; then
 948         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 949         GL_PC_REQ_PRIV="x11 xext"
 950         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 951         GL_LIB_DEPS="$XLIBGL_LIBS"
 952     else
 953         # should check these...
 954         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 955         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 956         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 957         GL_PC_CFLAGS="$X11_INCLUDES"
 958     fi
 959     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 960     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 961     ;;
 962 xyesno)
 963     # DRI-based GLX
 964     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 965     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 966     if test x"$driglx_direct" = xyes; then
 967         if test "x$have_libdrm" != xyes; then
 968             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 969         fi
 970         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 971         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 972     fi
 973
 974     # find the DRI deps for libGL
 975     if test "$x11_pkgconfig" = yes; then
 976         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 977
 978         # add xf86vidmode if available
 979         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 980         if test "$HAVE_XF86VIDMODE" = yes ; then
 981             dri_modules="$dri_modules xxf86vm"
 982         fi
 983
 984         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 985         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 986         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 987         GL_LIB_DEPS="$DRIGL_LIBS"
 988     else
 989         # should check these...
 990         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 991         if test "x$HAVE_XF86VIDMODE" == xyes; then
 992            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 993         else
 994            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
 995         fi
 996         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 997         GL_PC_CFLAGS="$X11_INCLUDES"
 998
 999         # XCB can only be used from pkg-config
1000         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1001         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1002         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1003         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1004     fi
1005
1006     # Check to see if the xcb-glx library is new enough to support
1007     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1008     # is released.
1009     save_CPPFLAGS="$CPPFLAGS"
1010     save_LDFLAGS="$LDFLAGS"
1011     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1012     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1013     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1014         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1015         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1016     CPPFLAGS="$save_CPPFLAGS"
1017     LDFLAGS="$save_LDFLAGS"
1018
1019     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1020         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1021     fi
1022
1023     # need DRM libs, -lpthread, etc.
1024     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1025     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1026     ;;
1027 esac
1028
1029 # This is outside the case (above) so that it is invoked even for non-GLX
1030 # builds.
1031 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1032     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1033
1034 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1035 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1036 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1037 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1038
1039 AC_SUBST([GL_LIB_DEPS])
1040 AC_SUBST([GL_PC_REQ_PRIV])
1041 AC_SUBST([GL_PC_LIB_PRIV])
1042 AC_SUBST([GL_PC_CFLAGS])
1043 AC_SUBST([DRI_PC_REQ_PRIV])
1044 AC_SUBST([GLESv1_CM_LIB_DEPS])
1045 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1046 AC_SUBST([GLESv2_LIB_DEPS])
1047 AC_SUBST([GLESv2_PC_LIB_PRIV])
1048
1049 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1050 AC_SUBST([GLAPI_LIB_DEPS])
1051
1052
1053 dnl Setup default DRI CFLAGS
1054 DRI_CFLAGS='$(CFLAGS)'
1055 DRI_CXXFLAGS='$(CXXFLAGS)'
1056 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1057 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1058
1059 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1060     DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
1061     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1062     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
1063     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
1064     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1065     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1066     MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
1067 fi
1068 AC_SUBST([DRICORE_LIBS])
1069 AC_SUBST([DRICORE_GLSL_LIBS])
1070 AC_SUBST([DRICORE_LIB_DEPS])
1071 AC_SUBST([DRI_CXXFLAGS])
1072 AC_SUBST([DRI_CFLAGS])
1073 AC_SUBST([MESA_MODULES])
1074
1075 AC_SUBST([HAVE_XF86VIDMODE])
1076
1077 dnl
1078 dnl More GLX setup
1079 dnl
1080 case "x$enable_glx$enable_xlib_glx" in
1081 xyesyes)
1082     DEFINES="$DEFINES -DUSE_XSHM"
1083     ;;
1084 xyesno)
1085     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1086     if test "x$driglx_direct" = xyes; then
1087         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1088     fi
1089     ;;
1090 esac
1091
1092 dnl
1093 dnl TLS detection
1094 dnl
1095
1096 AC_ARG_ENABLE([glx-tls],
1097     [AS_HELP_STRING([--enable-glx-tls],
1098         [enable TLS support in GLX @<:@default=disabled@:>@])],
1099     [GLX_USE_TLS="$enableval"],
1100     [GLX_USE_TLS=no])
1101 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1102
1103 AS_IF([test "x$GLX_USE_TLS" = xyes],
1104       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1105
1106 dnl
1107 dnl More DRI setup
1108 dnl
1109 dnl Directory for DRI drivers
1110 AC_ARG_WITH([dri-driverdir],
1111     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1112         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1113     [DRI_DRIVER_INSTALL_DIR="$withval"],
1114     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1115 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1116 dnl Extra search path for DRI drivers
1117 AC_ARG_WITH([dri-searchpath],
1118     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1119         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1120     [DRI_DRIVER_SEARCH_DIR="$withval"],
1121     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1122 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1123 dnl Which drivers to build - default is chosen by platform
1124 AC_ARG_WITH([dri-drivers],
1125     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1126         [comma delimited DRI drivers list, e.g.
1127         "swrast,i965,radeon" @<:@default=auto@:>@])],
1128     [with_dri_drivers="$withval"],
1129     [with_dri_drivers=yes])
1130 if test "x$with_dri_drivers" = x; then
1131     with_dri_drivers=no
1132 fi
1133
1134 dnl If $with_dri_drivers is yes, directories will be added through
1135 dnl platform checks
1136 DRI_DIRS=""
1137 case "$with_dri_drivers" in
1138 no) ;;
1139 yes)
1140     # classic DRI drivers require FEATURE_GL to build
1141     if test "x$enable_opengl" = xyes; then
1142         DRI_DIRS="yes"
1143     fi
1144     ;;
1145 *)
1146     # verify the requested driver directories exist
1147     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1148     for driver in $dri_drivers; do
1149         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1150             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1151     done
1152     DRI_DIRS="$dri_drivers"
1153     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1154         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1155     fi
1156     ;;
1157 esac
1158
1159 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1160 if test "x$enable_dri" = xyes; then
1161     # Platform specific settings and drivers to build
1162     case "$host_os" in
1163     linux*)
1164         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1165         DEFINES="$DEFINES -DHAVE_ALIAS"
1166
1167         case "$host_cpu" in
1168         x86_64)
1169             if test "x$DRI_DIRS" = "xyes"; then
1170                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1171             fi
1172             ;;
1173         powerpc*)
1174             # Build only the drivers for cards that exist on PowerPC.
1175             if test "x$DRI_DIRS" = "xyes"; then
1176                 DRI_DIRS="r200 radeon swrast"
1177             fi
1178             ;;
1179         sparc*)
1180             # Build only the drivers for cards that exist on sparc
1181             if test "x$DRI_DIRS" = "xyes"; then
1182                 DRI_DIRS="r200 radeon swrast"
1183             fi
1184             ;;
1185         esac
1186         ;;
1187     freebsd* | dragonfly* | *netbsd*)
1188         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1189         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1190
1191         if test "x$DRI_DIRS" = "xyes"; then
1192             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1193         fi
1194         ;;
1195     gnu*)
1196         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1197         DEFINES="$DEFINES -DHAVE_ALIAS"
1198         ;;
1199     solaris*)
1200         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1201         ;;
1202     cygwin*)
1203         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1204         if test "x$DRI_DIRS" = "xyes"; then
1205             DRI_DIRS="swrast"
1206         fi
1207         ;;
1208     esac
1209
1210     # default drivers
1211     if test "x$DRI_DIRS" = "xyes"; then
1212         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1213     fi
1214
1215     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1216
1217     # Check for expat
1218     if test "x$enable_dri" = xyes; then
1219         EXPAT_INCLUDES=""
1220         EXPAT_LIB=-lexpat
1221         AC_ARG_WITH([expat],
1222             [AS_HELP_STRING([--with-expat=DIR],
1223                 [expat install directory])],[
1224             EXPAT_INCLUDES="-I$withval/include"
1225             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1226             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1227             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1228             ])
1229         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1230         save_LIBS="$LIBS"
1231         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1232             [AC_MSG_ERROR([Expat required for DRI.])])
1233         LIBS="$save_LIBS"
1234     fi
1235
1236     # libdrm is required for all except swrast
1237     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1238         if test "x$have_libdrm" != xyes; then
1239             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1240         fi
1241     fi
1242
1243     # put all the necessary libs together
1244     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1245 fi
1246 AC_SUBST([DRI_DIRS])
1247 AC_SUBST([EXPAT_INCLUDES])
1248 AC_SUBST([DRI_LIB_DEPS])
1249
1250 case $DRI_DIRS in
1251 *i915*|*i965*)
1252     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1253
1254     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1255         case $d in
1256         i915)
1257             HAVE_I915_DRI=yes;
1258             ;;
1259         i965)
1260             HAVE_I965_DRI=yes;
1261             ;;
1262         esac
1263     done
1264
1265     ;;
1266 esac
1267
1268 case $DRI_DIRS in
1269 *nouveau*)
1270     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1271     HAVE_NOUVEAU_DRI=yes;
1272     ;;
1273 esac
1274
1275 case $DRI_DIRS in
1276 *radeon*|*r200*)
1277     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1278
1279     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1280         case $d in
1281         radeon)
1282             HAVE_RADEON_DRI=yes;
1283             ;;
1284         r200)
1285             HAVE_R200_DRI=yes;
1286             ;;
1287         esac
1288     done
1289
1290     ;;
1291 esac
1292
1293 case $DRI_DIRS in
1294 *swrast*)
1295     HAVE_SWRAST_DRI=yes;
1296     ;;
1297 esac
1298
1299 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1300 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1301 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1302 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1303 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1304 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1305
1306 dnl
1307 dnl OSMesa configuration
1308 dnl
1309
1310 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1311 AC_ARG_WITH([osmesa-bits],
1312     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1313         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1314     [osmesa_bits="$withval"],
1315     [osmesa_bits=8])
1316 if test "x$osmesa_bits" != x8; then
1317     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1318         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1319         osmesa_bits=8
1320     fi
1321 fi
1322 case "x$osmesa_bits" in
1323 x8)
1324     OSMESA_LIB="${OSMESA_LIB}"
1325     ;;
1326 x16|x32)
1327     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1328     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1329     ;;
1330 *)
1331     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1332     ;;
1333 esac
1334
1335 if test "x$enable_osmesa" = xyes; then
1336     # only link libraries with osmesa if shared
1337     if test "$enable_static" = no; then
1338         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1339     else
1340         OSMESA_LIB_DEPS=""
1341     fi
1342     OSMESA_MESA_DEPS=""
1343     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1344 fi
1345 AC_SUBST([OSMESA_LIB_DEPS])
1346 AC_SUBST([OSMESA_MESA_DEPS])
1347 AC_SUBST([OSMESA_PC_REQ])
1348 AC_SUBST([OSMESA_PC_LIB_PRIV])
1349
1350 dnl
1351 dnl gbm configuration
1352 dnl
1353 if test "x$enable_gbm" = xauto; then
1354     case "$with_egl_platforms" in
1355         *drm*)
1356             enable_gbm=yes ;;
1357          *)
1358             enable_gbm=no ;;
1359     esac
1360 fi
1361 if test "x$enable_gbm" = xyes; then
1362     SRC_DIRS="$SRC_DIRS gbm"
1363
1364     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1365                       AC_MSG_ERROR([gbm needs udev]))
1366
1367     if test "x$enable_dri" = xyes; then
1368         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1369         if test "$SHARED_GLAPI" -eq 0; then
1370             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1371         fi
1372     fi
1373 fi
1374 GBM_PC_REQ_PRIV="libudev"
1375 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1376 AC_SUBST([GBM_PC_REQ_PRIV])
1377 AC_SUBST([GBM_PC_LIB_PRIV])
1378
1379 dnl
1380 dnl EGL configuration
1381 dnl
1382 EGL_CLIENT_APIS=""
1383
1384 if test "x$enable_egl" = xyes; then
1385     SRC_DIRS="$SRC_DIRS egl"
1386     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1387     EGL_DRIVERS_DIRS=""
1388
1389     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1390
1391     if test "$enable_static" != yes; then
1392         # build egl_glx when libGL is built
1393         if test "x$enable_glx" = xyes; then
1394             EGL_DRIVERS_DIRS="glx"
1395         fi
1396
1397         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1398                           [have_libudev=yes],[have_libudev=no])
1399         if test "$have_libudev" = yes; then
1400             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1401         fi
1402         if test "x$enable_dri" = xyes; then
1403             # build egl_dri2 when xcb-dri2 is available
1404             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1405                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1406
1407             if test "$have_xcb_dri2" = yes; then
1408                 EGL_DRIVER_DRI2=dri2
1409                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1410                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1411                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1412                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1413             fi
1414         fi
1415
1416         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1417     fi
1418 fi
1419 AC_SUBST([EGL_LIB_DEPS])
1420 AC_SUBST([EGL_DRIVERS_DIRS])
1421
1422 dnl
1423 dnl EGL Gallium configuration
1424 dnl
1425 if test "x$enable_gallium_egl" = xyes; then
1426     if test "x$with_gallium_drivers" = x; then
1427         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1428     fi
1429     if test "x$enable_egl" = xno; then
1430         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1431     fi
1432     if test "x$have_libdrm" != xyes; then
1433         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1434     fi
1435
1436     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1437     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1438     HAVE_ST_EGL="yes"
1439 fi
1440
1441 dnl
1442 dnl gbm Gallium configuration
1443 dnl
1444 if test "x$enable_gallium_gbm" = xauto; then
1445     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1446         yesyesyes*drm*)
1447             enable_gallium_gbm=yes ;;
1448          *)
1449             enable_gallium_gbm=no ;;
1450     esac
1451 fi
1452 if test "x$enable_gallium_gbm" = xyes; then
1453     if test "x$with_gallium_drivers" = x; then
1454         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1455     fi
1456     if test "x$enable_gbm" = xno; then
1457         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1458     fi
1459     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1460     if test "x$enable_dri" = xno; then
1461         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1462     fi
1463
1464     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1465     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1466     HAVE_ST_GBM="yes"
1467 fi
1468
1469 dnl
1470 dnl X.Org DDX configuration
1471 dnl
1472 if test "x$enable_xorg" = xyes; then
1473     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1474     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1475     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1476     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1477         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1478         HAVE_XEXTPROTO_71="no")
1479     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1480     HAVE_ST_XORG=yes
1481 fi
1482
1483 dnl
1484 dnl XA configuration
1485 dnl
1486 if test "x$enable_xa" = xyes; then
1487 AC_PROG_AWK
1488 AC_PROG_GREP
1489 AC_CHECK_PROG(NM, nm, "nm")
1490 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1491 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1492 enable_xa=no
1493 fi
1494 fi
1495 if test "x$enable_xa" = xyes; then
1496     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1497     HAVE_ST_XA=yes
1498     AC_SUBST(AWK)
1499     AC_SUBST(GREP)
1500     AC_SUBST(NM)
1501 fi
1502
1503 dnl
1504 dnl OpenVG configuration
1505 dnl
1506 VG_LIB_DEPS=""
1507
1508 if test "x$enable_openvg" = xyes; then
1509     if test "x$enable_egl" = xno; then
1510         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1511     fi
1512     if test "x$with_gallium_drivers" = x; then
1513         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1514     fi
1515     if test "x$enable_gallium_egl" = xno; then
1516         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1517     fi
1518
1519     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1520     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1521     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1522     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1523     HAVE_ST_VEGA=yes
1524 fi
1525
1526 dnl
1527 dnl D3D1X configuration
1528 dnl
1529
1530 if test "x$enable_d3d1x" = xyes; then
1531     if test "x$with_gallium_drivers" = x; then
1532         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1533     fi
1534
1535     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1536     HAVE_ST_D3D1X=yes
1537 fi
1538
1539 dnl
1540 dnl Gallium G3DVL configuration
1541 dnl
1542 AC_ARG_ENABLE([gallium-g3dvl],
1543     [AS_HELP_STRING([--enable-gallium-g3dvl],
1544         [build gallium g3dvl @<:@default=disabled@:>@])],
1545     [enable_gallium_g3dvl="$enableval"],
1546     [enable_gallium_g3dvl=no])
1547 if test "x$enable_gallium_g3dvl" = xyes; then
1548     if test "x$with_gallium_drivers" = x; then
1549         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1550     fi
1551
1552     if test "x$enable_xvmc" = xauto; then
1553         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1554     fi
1555
1556     if test "x$enable_vdpau" = xauto; then
1557         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1558     fi
1559
1560     if test "x$enable_va" = xauto; then
1561         #don't enable vaapi state tracker even if package exists
1562         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1563         enable_va=no
1564     fi
1565 fi
1566
1567 if test "x$enable_xvmc" = xyes; then
1568     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6])
1569     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg/xvmc"
1570     HAVE_ST_XVMC="yes"
1571 fi
1572
1573 if test "x$enable_vdpau" = xyes; then
1574     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1])
1575     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1576     HAVE_ST_VDPAU="yes"
1577 fi
1578
1579 if test "x$enable_va" = xyes; then
1580     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1])
1581     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1582     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1583     HAVE_ST_VA="yes"
1584 fi
1585
1586 dnl
1587 dnl GLU configuration
1588 dnl
1589 AC_ARG_ENABLE([glu],
1590     [AS_HELP_STRING([--disable-glu],
1591         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1592     [enable_glu="$enableval"],
1593     [enable_glu=yes])
1594
1595 if test "x$enable_glu" = xyes; then
1596     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1597         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1598         enable_glu=no
1599     fi
1600 fi
1601
1602 if test "x$enable_glu" = xyes; then
1603     SRC_DIRS="$SRC_DIRS glu"
1604
1605     if test "x$enable_glx" = xno; then
1606         # Link libGLU to libOSMesa instead of libGL
1607         GLU_LIB_DEPS=""
1608         GLU_PC_REQ="osmesa"
1609         if test "$enable_static" = no; then
1610             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1611         else
1612             GLU_MESA_DEPS=""
1613         fi
1614     else
1615         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1616         GLU_PC_REQ="gl"
1617         GLU_PC_LIB_PRIV="-lm"
1618         if test "$enable_static" = no; then
1619             GLU_LIB_DEPS="-lm"
1620             GLU_MESA_DEPS='-l$(GL_LIB)'
1621         else
1622             GLU_LIB_DEPS=""
1623             GLU_MESA_DEPS=""
1624         fi
1625     fi
1626 fi
1627 if test "$enable_static" = no; then
1628     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1629 fi
1630 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1631 AC_SUBST([GLU_LIB_DEPS])
1632 AC_SUBST([GLU_MESA_DEPS])
1633 AC_SUBST([GLU_PC_REQ])
1634 AC_SUBST([GLU_PC_REQ_PRIV])
1635 AC_SUBST([GLU_PC_LIB_PRIV])
1636 AC_SUBST([GLU_PC_CFLAGS])
1637
1638 AC_SUBST([PROGRAM_DIRS])
1639
1640 dnl
1641 dnl Gallium configuration
1642 dnl
1643 if test "x$with_gallium_drivers" != x; then
1644     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1645 fi
1646
1647 AC_SUBST([LLVM_CFLAGS])
1648 AC_SUBST([LLVM_LIBS])
1649 AC_SUBST([LLVM_LDFLAGS])
1650 AC_SUBST([LLVM_VERSION])
1651
1652 case "x$enable_opengl$enable_gles1$enable_gles2" in
1653 x*yes*)
1654     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1655     ;;
1656 esac
1657
1658 AC_SUBST([VG_LIB_DEPS])
1659 AC_SUBST([EGL_CLIENT_APIS])
1660
1661 AC_ARG_WITH([egl-platforms],
1662     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1663         [comma delimited native platforms libEGL supports, e.g.
1664         "x11,drm" @<:@default=auto@:>@])],
1665     [with_egl_platforms="$withval"],
1666     [with_egl_platforms=yes])
1667
1668 EGL_PLATFORMS=""
1669
1670 case "$with_egl_platforms" in
1671 yes)
1672     if test "x$enable_egl" = xyes; then
1673         EGL_PLATFORMS="x11"
1674     fi
1675     ;;
1676 *)
1677     if test "x$enable_egl" != xyes; then
1678         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1679     fi
1680     # verify the requested driver directories exist
1681     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1682     for plat in $egl_platforms; do
1683         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1684             AC_MSG_ERROR([EGL platform '$plat' does not exist])
1685         if test "$plat" = "fbdev"; then
1686                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1687         fi
1688         if test "$plat" = "null"; then
1689                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1690         fi
1691         if test "$plat" = "wayland"; then
1692                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1693                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1694                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1695
1696                 m4_ifdef([WAYLAND_SCANNER_RULES],
1697                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1698         fi
1699         if test "$plat" = "drm" && test "x$enable_gbm" = "xno"; then
1700                 AC_MSG_ERROR([EGL platform drm needs gbm])
1701         fi
1702         case "$plat$have_libudev" in
1703                 waylandno|drmno)
1704                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1705         esac
1706     done
1707     EGL_PLATFORMS="$egl_platforms"
1708     ;;
1709 esac
1710 AC_SUBST([EGL_PLATFORMS])
1711
1712 AC_ARG_WITH([egl-driver-dir],
1713     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1714                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1715     [EGL_DRIVER_INSTALL_DIR="$withval"],
1716     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1717 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1718
1719 AC_ARG_WITH([xorg-driver-dir],
1720     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1721                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1722     [XORG_DRIVER_INSTALL_DIR="$withval"],
1723     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1724 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1725
1726 AC_ARG_WITH([max-width],
1727     [AS_HELP_STRING([--with-max-width=N],
1728                     [Maximum framebuffer width (4096)])],
1729     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1730      AS_IF([test "${withval}" -gt "4096"],
1731            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1732 )
1733 AC_ARG_WITH([max-height],
1734     [AS_HELP_STRING([--with-max-height=N],
1735                     [Maximum framebuffer height (4096)])],
1736     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1737      AS_IF([test "${withval}" -gt "4096"],
1738            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1739 )
1740
1741 dnl
1742 dnl Gallium LLVM
1743 dnl
1744 AC_ARG_ENABLE([gallium-llvm],
1745     [AS_HELP_STRING([--enable-gallium-llvm],
1746         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1747     [enable_gallium_llvm="$enableval"],
1748     [enable_gallium_llvm=auto])
1749 if test "x$with_gallium_drivers" = x; then
1750     enable_gallium_llvm=no
1751 fi
1752 if test "x$enable_gallium_llvm" = xauto; then
1753     case "$host_cpu" in
1754     i*86|x86_64) enable_gallium_llvm=yes;;
1755     esac
1756 fi
1757 if test "x$enable_gallium_llvm" = xyes; then
1758     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1759
1760     if test "x$LLVM_CONFIG" != xno; then
1761         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1762         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g'`
1763         LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1764
1765         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1766         DEFINES="$DEFINES -D__STDC_CONSTANT_MACROS"
1767         MESA_LLVM=1
1768     else
1769         MESA_LLVM=0
1770     fi
1771 else
1772     MESA_LLVM=0
1773 fi
1774
1775 dnl Directory for VDPAU libs
1776 AC_ARG_WITH([vdpau-libdir],
1777     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1778         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1779     [VDPAU_LIB_INSTALL_DIR="$withval"],
1780     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1781 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1782
1783 dnl Directory for VA libs
1784 AC_ARG_WITH([va-libdir],
1785     [AS_HELP_STRING([--with-va-libdir=DIR],
1786         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1787     [VA_LIB_INSTALL_DIR="$withval"],
1788     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1789 AC_SUBST([VA_LIB_INSTALL_DIR])
1790
1791 dnl
1792 dnl Gallium helper functions
1793 dnl
1794 gallium_check_st() {
1795     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1796          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1797          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1798          if test "x$have_libdrm" != xyes; then
1799             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1800          fi
1801          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1802     fi
1803     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1804          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1805     fi
1806     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1807          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1808     fi
1809     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1810          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1811     fi
1812     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1813          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1814          NEED_G3DVL_DRI="yes"
1815     fi
1816     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1817          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1818          NEED_G3DVL_DRI="yes"
1819     fi
1820     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1821          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1822          NEED_G3DVL_DRI="yes"
1823     fi
1824 }
1825
1826 gallium_require_llvm() {
1827     if test "x$MESA_LLVM" = x0; then
1828         case "$host_cpu" in
1829         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1830         esac
1831     fi
1832 }
1833
1834 dnl Gallium drivers
1835 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1836 if test "x$with_gallium_drivers" != x; then
1837     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1838     for driver in $gallium_drivers; do
1839         case "x$driver" in
1840         xsvga)
1841             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1842             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1843             ;;
1844         xi915)
1845             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1846             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1847             if test "x$MESA_LLVM" = x1; then
1848                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1849             fi
1850             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1851             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1852             ;;
1853         xr300)
1854             gallium_require_llvm "Gallium R300"
1855             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1856             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1857             ;;
1858         xr600)
1859             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1860             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1861             ;;
1862         xnouveau)
1863             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1864             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1865             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1866             ;;
1867         xswrast)
1868             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1869             if test "x$MESA_LLVM" = x1; then
1870                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1871             fi
1872
1873             if test "x$HAVE_ST_DRI" = xyes; then
1874                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1875             fi
1876             if test "x$HAVE_ST_VDPAU" = xyes; then
1877                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1878             fi
1879             if test "x$HAVE_ST_XVMC" = xyes; then
1880                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1881             fi
1882             if test "x$HAVE_ST_VA" = xyes; then
1883                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1884             fi
1885             if test "x$HAVE_ST_VDPAU" = xyes ||
1886                test "x$HAVE_ST_XVMC" = xyes ||
1887                test "x$HAVE_ST_VA" = xyes; then
1888                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1889                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1890                fi
1891             fi
1892             ;;
1893         *)
1894             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1895             ;;
1896         esac
1897     done
1898 fi
1899
1900 if test "x$NEED_G3DVL_DRI" = xyes; then
1901     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS g3dvl/dri"
1902 fi
1903
1904 dnl prepend CORE_DIRS to SRC_DIRS
1905 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1906
1907 dnl Restore LDFLAGS and CPPFLAGS
1908 LDFLAGS="$_SAVE_LDFLAGS"
1909 CPPFLAGS="$_SAVE_CPPFLAGS"
1910
1911 dnl Add user CFLAGS and CXXFLAGS
1912 CFLAGS="$CFLAGS $USER_CFLAGS"
1913 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1914
1915 dnl Substitute the config
1916 AC_CONFIG_FILES([configs/autoconf
1917                 src/gbm/Makefile
1918                 src/gbm/main/gbm.pc
1919                 src/egl/wayland/Makefile
1920                 src/egl/wayland/wayland-egl/Makefile
1921                 src/egl/wayland/wayland-egl/wayland-egl.pc
1922                 src/egl/wayland/wayland-drm/Makefile
1923                 src/mesa/drivers/dri/dri.pc
1924                 src/mesa/drivers/dri/Makefile
1925                 src/mesa/drivers/dri/common/Makefile
1926                 src/mesa/drivers/dri/i915/Makefile
1927                 src/mesa/drivers/dri/i965/Makefile
1928                 src/mesa/drivers/dri/nouveau/Makefile
1929                 src/mesa/drivers/dri/r200/Makefile
1930                 src/mesa/drivers/dri/radeon/Makefile
1931                 src/mesa/drivers/dri/swrast/Makefile
1932                 tests/Makefile
1933                 tests/glx/Makefile])
1934
1935 dnl Replace the configs/current symlink
1936 AC_CONFIG_COMMANDS([configs],[
1937 if test -f configs/current || test -L configs/current; then
1938     rm -f configs/current
1939 fi
1940 ln -s autoconf configs/current
1941 ])
1942
1943 dnl Sort the dirs alphabetically
1944 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1945 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1946 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1947 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1948
1949 AC_OUTPUT
1950
1951 dnl
1952 dnl Output some configuration info for the user
1953 dnl
1954 echo ""
1955 echo "        prefix:          $prefix"
1956 echo "        exec_prefix:     $exec_prefix"
1957 echo "        libdir:          $libdir"
1958 echo "        includedir:      $includedir"
1959
1960 dnl API info
1961 echo ""
1962 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1963 echo "        OpenVG:          $enable_openvg"
1964
1965 dnl Driver info
1966 echo ""
1967 if test "x$enable_osmesa" != xno; then
1968         echo "        OSMesa:          lib$OSMESA_LIB"
1969 else
1970         echo "        OSMesa:          no"
1971 fi
1972
1973 if test "x$enable_dri" != xno; then
1974         # cleanup the drivers var
1975         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1976         if test "x$DRI_DIRS" = x; then
1977             echo "        DRI drivers:     no"
1978         else
1979             echo "        DRI drivers:     $dri_dirs"
1980         fi
1981         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1982 fi
1983
1984 case "x$enable_glx$enable_xlib_glx" in
1985 xyesyes)
1986     echo "        GLX:             Xlib-based"
1987     ;;
1988 xyesno)
1989     echo "        GLX:             DRI-based"
1990     ;;
1991 *)
1992     echo "        GLX:             $enable_glx"
1993     ;;
1994 esac
1995
1996 echo ""
1997 echo "        GLU:             $enable_glu"
1998
1999 dnl EGL
2000 echo ""
2001 echo "        EGL:             $enable_egl"
2002 if test "$enable_egl" = yes; then
2003     echo "        EGL platforms:   $EGL_PLATFORMS"
2004
2005     egl_drivers=""
2006     for d in $EGL_DRIVERS_DIRS; do
2007         egl_drivers="$egl_drivers builtin:egl_$d"
2008     done
2009
2010     if test "x$HAVE_ST_EGL" = xyes; then
2011         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2012         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2013     else
2014         echo "        EGL drivers:    $egl_drivers"
2015     fi
2016 fi
2017
2018 echo ""
2019 if test "x$MESA_LLVM" = x1; then
2020     echo "        llvm:            yes"
2021     echo "        llvm-config:     $LLVM_CONFIG"
2022     echo "        llvm-version:    $LLVM_VERSION"
2023 else
2024     echo "        llvm:            no"
2025 fi
2026
2027 echo ""
2028 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2029     echo "        Gallium:         yes"
2030     echo "        Gallium dirs:    $GALLIUM_DIRS"
2031     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2032     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2033     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2034     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2035 else
2036     echo "        Gallium:         no"
2037 fi
2038
2039
2040 dnl Libraries
2041 echo ""
2042 echo "        Shared libs:     $enable_shared"
2043 echo "        Static libs:     $enable_static"
2044
2045 dnl Compiler options
2046 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2047 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2048     $SED 's/^ *//;s/  */ /;s/ *$//'`
2049 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2050     $SED 's/^ *//;s/  */ /;s/ *$//'`
2051 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2052 echo ""
2053 echo "        CFLAGS:          $cflags"
2054 echo "        CXXFLAGS:        $cxxflags"
2055 echo "        Macros:          $defines"
2056 echo ""
2057 echo "        PYTHON2:         $PYTHON2"
2058
2059 echo ""
2060 echo "        Run '${MAKE-make}' to build Mesa"
2061 echo ""