configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.8.0
  93 LIBSENSORS_REQUIRED=4.0.0
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112 AC_CHECK_PROG(XXD, xxd, [xxd])
 113
 114 AX_PROG_BISON([],
 115               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 116                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 117 AX_PROG_FLEX([],
 118              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 119                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 120
 121 AC_CHECK_PROG(INDENT, indent, indent, cat)
 122 if test "x$INDENT" != "xcat"; then
 123     # Only GNU indent is supported
 124     INDENT_VERSION=`indent --version | grep GNU`
 125     if test $? -eq 0; then
 126        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 127     else
 128        INDENT="cat"
 129     fi
 130 fi
 131
 132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 133
 134 if test -z "$PYTHON2"; then
 135     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 136         AC_MSG_ERROR([Python not found - unable to generate sources])
 137     fi
 138 else
 139     if test "x$acv_mako_found" = xno; then
 140         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 141             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 142         fi
 143     fi
 144 fi
 145
 146 AC_PROG_INSTALL
 147
 148 dnl We need a POSIX shell for parts of the build. Assume we have one
 149 dnl in most cases.
 150 case "$host_os" in
 151 solaris*)
 152     # Solaris /bin/sh is too old/non-POSIX compliant
 153     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 154     SHELL="$POSIX_SHELL"
 155     ;;
 156 esac
 157
 158 dnl clang is mostly GCC-compatible, but its version is much lower,
 159 dnl so we have to check for it.
 160 AC_MSG_CHECKING([if compiling with clang])
 161
 162 AC_COMPILE_IFELSE(
 163 [AC_LANG_PROGRAM([], [[
 164 #ifndef __clang__
 165        not clang
 166 #endif
 167 ]])],
 168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 169
 170 AC_MSG_RESULT([$acv_mesa_CLANG])
 171
 172 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 173 dnl versions are explictly not supported.
 174 GEN_ASM_OFFSETS=no
 175 USE_GNU99=no
 176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 177     AC_MSG_CHECKING([whether gcc version is sufficient])
 178     major=0
 179     minor=0
 180
 181     GCC_VERSION=`$CC -dumpversion`
 182     if test $? -eq 0; then
 183         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 184         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 188         AC_MSG_RESULT([no])
 189         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 190     else
 191         AC_MSG_RESULT([yes])
 192     fi
 193
 194     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 195         USE_GNU99=yes
 196     fi
 197     if test "x$cross_compiling" = xyes; then
 198         GEN_ASM_OFFSETS=yes
 199     fi
 200 fi
 201
 202 dnl We don't support building Mesa with Sun C compiler
 203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 205 if test "x$SUNCC" = xyes; then
 206     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 207 fi
 208
 209 dnl Check for compiler builtins
 210 AX_GCC_BUILTIN([__builtin_bswap32])
 211 AX_GCC_BUILTIN([__builtin_bswap64])
 212 AX_GCC_BUILTIN([__builtin_clz])
 213 AX_GCC_BUILTIN([__builtin_clzll])
 214 AX_GCC_BUILTIN([__builtin_ctz])
 215 AX_GCC_BUILTIN([__builtin_expect])
 216 AX_GCC_BUILTIN([__builtin_ffs])
 217 AX_GCC_BUILTIN([__builtin_ffsll])
 218 AX_GCC_BUILTIN([__builtin_popcount])
 219 AX_GCC_BUILTIN([__builtin_popcountll])
 220 AX_GCC_BUILTIN([__builtin_unreachable])
 221
 222 AX_GCC_FUNC_ATTRIBUTE([const])
 223 AX_GCC_FUNC_ATTRIBUTE([flatten])
 224 AX_GCC_FUNC_ATTRIBUTE([format])
 225 AX_GCC_FUNC_ATTRIBUTE([malloc])
 226 AX_GCC_FUNC_ATTRIBUTE([packed])
 227 AX_GCC_FUNC_ATTRIBUTE([pure])
 228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 229 AX_GCC_FUNC_ATTRIBUTE([unused])
 230 AX_GCC_FUNC_ATTRIBUTE([visibility])
 231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 232 AX_GCC_FUNC_ATTRIBUTE([weak])
 233
 234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 235
 236 dnl Make sure the pkg-config macros are defined
 237 m4_ifndef([PKG_PROG_PKG_CONFIG],
 238     [m4_fatal([Could not locate the pkg-config autoconf macros.
 239   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 240   are in a different location, try setting the environment variable
 241   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 242 PKG_PROG_PKG_CONFIG()
 243
 244 dnl LIB_DIR - library basename
 245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 246 AC_SUBST([LIB_DIR])
 247
 248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 249 _SAVE_LDFLAGS="$LDFLAGS"
 250 _SAVE_CPPFLAGS="$CPPFLAGS"
 251
 252 dnl Compiler macros
 253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 254 AC_SUBST([DEFINES])
 255 android=no
 256 case "$host_os" in
 257 *-android)
 258     android=yes
 259     ;;
 260 linux*|*-gnu*|gnu*|cygwin*)
 261     DEFINES="$DEFINES -D_GNU_SOURCE"
 262     ;;
 263 solaris*)
 264     DEFINES="$DEFINES -DSVR4"
 265     ;;
 266 esac
 267
 268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # We don't want floating-point math functions to set errno or trap
 305     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # We don't want floating-point math functions to set errno or trap
 344     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int param;
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 380     c = _mm_max_epu32(a, b);
 381     return _mm_cvtsi128_si32(c);
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Check for new-style atomic builtins
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 int main() {
 393     int n;
 394     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 397     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 398 fi
 399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 DEFAULT_GL_LIB_NAME=GL
 525
 526 dnl
 527 dnl Check if linker supports -Bsymbolic
 528 dnl
 529 save_LDFLAGS=$LDFLAGS
 530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 532 AC_LINK_IFELSE(
 533     [AC_LANG_SOURCE([int main() { return 0;}])],
 534     [AC_MSG_RESULT([yes])
 535         BSYMBOLIC="-Wl,-Bsymbolic";],
 536     [AC_MSG_RESULT([no])
 537         BSYMBOLIC="";])
 538 LDFLAGS=$save_LDFLAGS
 539
 540 AC_SUBST([BSYMBOLIC])
 541
 542 dnl
 543 dnl Check if linker supports garbage collection
 544 dnl
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";],
 552     [AC_MSG_RESULT([no])
 553         GC_SECTIONS="";])
 554 LDFLAGS=$save_LDFLAGS
 555
 556 AC_SUBST([GC_SECTIONS])
 557
 558 dnl
 559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 560 dnl so when these flags are passed to ld via libtool the checks will fail
 561 dnl
 562 case "$host_os" in
 563 openbsd* | darwin* )
 564     LD_NO_UNDEFINED="" ;;
 565 *)
 566     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 567 esac
 568
 569 AC_SUBST([LD_NO_UNDEFINED])
 570
 571 dnl
 572 dnl Check if linker supports version scripts
 573 dnl
 574 AC_MSG_CHECKING([if the linker supports version-scripts])
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 577 cat > conftest.map <<EOF
 578 VERSION_1 {
 579      global:
 580          main;
 581
 582      local:
 583          *;
 584 };
 585 EOF
 586 AC_LINK_IFELSE(
 587     [AC_LANG_SOURCE([int main() { return 0;}])],
 588     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 589     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 590 LDFLAGS=$save_LDFLAGS
 591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 592
 593 dnl
 594 dnl Check if linker supports dynamic list files
 595 dnl
 596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 597 save_LDFLAGS=$LDFLAGS
 598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 599 cat > conftest.dyn <<EOF
 600 {
 601         radeon_drm_winsys_create;
 602 };
 603 EOF
 604 AC_LINK_IFELSE(
 605     [AC_LANG_SOURCE([int main() { return 0;}])],
 606     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 607     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 608 LDFLAGS=$save_LDFLAGS
 609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 610
 611 dnl
 612 dnl compatibility symlinks
 613 dnl
 614 case "$host_os" in
 615 linux* )
 616     HAVE_COMPAT_SYMLINKS=yes ;;
 617 * )
 618     HAVE_COMPAT_SYMLINKS=no ;;
 619 esac
 620
 621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 622
 623 DEFAULT_GL_LIB_NAME=GL
 624
 625 dnl
 626 dnl Libglvnd configuration
 627 dnl
 628 AC_ARG_ENABLE([libglvnd],
 629     [AS_HELP_STRING([--enable-libglvnd],
 630         [Build for libglvnd @<:@default=disabled@:>@])],
 631     [enable_libglvnd="$enableval"],
 632     [enable_libglvnd=no])
 633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 635 if test "x$enable_libglvnd" = xyes ; then
 636     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 637     DEFAULT_GL_LIB_NAME=GLX_mesa
 638 fi
 639
 640 dnl
 641 dnl library names
 642 dnl
 643 dnl Unfortunately we need to do a few things that libtool can't help us with,
 644 dnl so we need some knowledge of shared library filenames:
 645 dnl
 646 dnl LIB_EXT is the extension used when creating symlinks for alternate
 647 dnl filenames for a shared library which will be dynamically loaded
 648 dnl
 649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 650 dnl the file for a shared library we wish to link with
 651 dnl
 652 case "$host_os" in
 653 darwin* )
 654     LIB_EXT='dylib'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 cygwin* )
 658     LIB_EXT='dll'
 659     IMP_LIB_EXT='dll.a'
 660     ;;
 661 aix* )
 662     LIB_EXT='a'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 * )
 666     LIB_EXT='so'
 667     IMP_LIB_EXT=$LIB_EXT
 668     ;;
 669 esac
 670
 671 AC_SUBST([LIB_EXT])
 672
 673 AC_ARG_WITH([gl-lib-name],
 674   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 675     [specify GL library name @<:@default=GL@:>@])],
 676   [GL_LIB=$withval],
 677   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AC_ARG_WITH([osmesa-lib-name],
 679   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 680     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 681   [OSMESA_LIB=$withval],
 682   [OSMESA_LIB=OSMesa])
 683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 685
 686 dnl
 687 dnl Mangled Mesa support
 688 dnl
 689 AC_ARG_ENABLE([mangling],
 690   [AS_HELP_STRING([--enable-mangling],
 691     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 692   [enable_mangling="${enableval}"],
 693   [enable_mangling=no]
 694 )
 695 if test "x${enable_mangling}" = "xyes" ; then
 696   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 697   GL_LIB="Mangled${GL_LIB}"
 698   OSMESA_LIB="Mangled${OSMESA_LIB}"
 699 fi
 700 AC_SUBST([GL_LIB])
 701 AC_SUBST([OSMESA_LIB])
 702
 703 dnl
 704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 705 dnl
 706 AC_ARG_ENABLE([texture-float],
 707     [AS_HELP_STRING([--enable-texture-float],
 708         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 709     [enable_texture_float="$enableval"],
 710     [enable_texture_float=no]
 711 )
 712 if test "x$enable_texture_float" = xyes; then
 713     AC_MSG_WARN([Floating-point textures enabled.])
 714     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 715     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 716 fi
 717
 718 dnl
 719 dnl Arch/platform-specific settings
 720 dnl
 721 AC_ARG_ENABLE([asm],
 722     [AS_HELP_STRING([--disable-asm],
 723         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 724     [enable_asm="$enableval"],
 725     [enable_asm=yes]
 726 )
 727 asm_arch=""
 728 AC_MSG_CHECKING([whether to enable assembly])
 729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 732     case "$host_cpu" in
 733     i?86 | x86_64 | amd64)
 734         if test "x$host_cpu" != "x$target_cpu"; then
 735             enable_asm=no
 736             AC_MSG_RESULT([no, cross compiling])
 737         fi
 738         ;;
 739     esac
 740 fi
 741 # check for supported arches
 742 if test "x$enable_asm" = xyes; then
 743     case "$host_cpu" in
 744     i?86)
 745         case "$host_os" in
 746         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 747             asm_arch=x86
 748             ;;
 749         esac
 750         ;;
 751     x86_64|amd64)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 754             asm_arch=x86_64
 755             ;;
 756         esac
 757         ;;
 758     sparc*)
 759         case "$host_os" in
 760         linux*)
 761             asm_arch=sparc
 762             ;;
 763         esac
 764         ;;
 765     esac
 766
 767     case "$asm_arch" in
 768     x86)
 769         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 770         AC_MSG_RESULT([yes, x86])
 771         ;;
 772     x86_64|amd64)
 773         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 774         AC_MSG_RESULT([yes, x86_64])
 775         ;;
 776     sparc)
 777         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 778         AC_MSG_RESULT([yes, sparc])
 779         ;;
 780     *)
 781         AC_MSG_RESULT([no, platform not supported])
 782         ;;
 783     esac
 784 fi
 785
 786 AC_HEADER_MAJOR
 787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 791
 792 dnl Check to see if dlopen is in default libraries (like Solaris, which
 793 dnl has it in libc), or if libdl is needed to get it.
 794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 795     [AC_CHECK_LIB([dl], [dlopen],
 796        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 797 AC_SUBST([DLOPEN_LIBS])
 798
 799 dnl Check if that library also has dladdr
 800 save_LIBS="$LIBS"
 801 LIBS="$LIBS $DLOPEN_LIBS"
 802 AC_CHECK_FUNCS([dladdr])
 803 LIBS="$save_LIBS"
 804
 805 case "$host_os" in
 806 darwin*)
 807     ;;
 808 *)
 809     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 810                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 811                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 812     AC_SUBST([CLOCK_LIB])
 813     ;;
 814 esac
 815
 816 dnl See if posix_memalign is available
 817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 818
 819 dnl Check for pthreads
 820 AX_PTHREAD
 821 if test "x$ax_pthread_ok" = xno; then
 822     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 823 fi
 824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 825 dnl to -pthread, which causes problems if we need -lpthread to appear in
 826 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 827 dnl is not valid for that platform.
 828 if test "x$android" = xno; then
 829     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 830 fi
 831
 832 dnl pthread-stubs is mandatory on targets where it exists
 833 case "$host_os" in
 834 cygwin* )
 835     pthread_stubs_possible="no"
 836     ;;
 837 * )
 838     pthread_stubs_possible="yes"
 839     ;;
 840 esac
 841
 842 if test "x$pthread_stubs_possible" = xyes; then
 843     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 844     AC_SUBST(PTHREADSTUBS_CFLAGS)
 845     AC_SUBST(PTHREADSTUBS_LIBS)
 846 fi
 847
 848 dnl SELinux awareness.
 849 AC_ARG_ENABLE([selinux],
 850     [AS_HELP_STRING([--enable-selinux],
 851         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 852     [MESA_SELINUX="$enableval"],
 853     [MESA_SELINUX=no])
 854 if test "x$enable_selinux" = "xyes"; then
 855     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 856         [AC_CHECK_HEADER([selinux/selinux.h],[],
 857                          [AC_MSG_ERROR([SELinux headers not found])])
 858          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 859                       [AC_MSG_ERROR([SELinux library not found])])
 860          SELINUX_LIBS="-lselinux"])
 861     DEFINES="$DEFINES -DMESA_SELINUX"
 862 fi
 863 AC_SUBST([SELINUX_CFLAGS])
 864 AC_SUBST([SELINUX_LIBS])
 865
 866 dnl
 867 dnl LLVM
 868 dnl
 869 llvm_add_component() {
 870     new_llvm_component=$1
 871     driver_name=$2
 872
 873     LLVM_COMPONENTS="$LLVM_COMPONENTS $new_llvm_component"
 874 }
 875
 876 llvm_add_default_components() {
 877     driver_name=$1
 878
 879     # Required default components
 880     llvm_add_component "bitwriter" $driver_name
 881     llvm_add_component "engine" $driver_name
 882     llvm_add_component "mcdisassembler" $driver_name
 883     llvm_add_component "mcjit" $driver_name
 884
 885     # Optional default components
 886     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 887         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 888     fi
 889 }
 890
 891 llvm_add_target() {
 892     new_llvm_target=$1
 893     driver_name=$2
 894
 895     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 896         llvm_add_component $new_llvm_target $driver_name
 897     else
 898         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 899     fi
 900 }
 901
 902 llvm_set_environment_variables() {
 903     if test -z "$LLVM_CONFIG"; then
 904         if test -n "$llvm_prefix"; then
 905             AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 906         else
 907             AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 908         fi
 909     fi
 910
 911     if test "x$LLVM_CONFIG" != xno; then
 912         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 913         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 914         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 915         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 916         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 917         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 918         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 919         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 920
 921         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 922             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 923         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 924             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 925
 926         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 927         if test -z "$LLVM_VERSION_PATCH"; then
 928             LLVM_VERSION_PATCH=0
 929         fi
 930
 931         if test -n "${LLVM_VERSION_MAJOR}"; then
 932             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 933         else
 934             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
 935         fi
 936
 937         LLVM_REQUIRED_VERSION_MAJOR="3"
 938         LLVM_REQUIRED_VERSION_MINOR="3"
 939         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
 940             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
 941         fi
 942
 943         llvm_add_default_components "gallium"
 944
 945         if test "x$enable_opencl" = xyes; then
 946             llvm_check_version_for "3" "6" "0" "opencl"
 947
 948             llvm_add_component "all-targets" "opencl"
 949             llvm_add_component "ipo" "opencl"
 950             llvm_add_component "linker" "opencl"
 951             llvm_add_component "instrumentation" "opencl"
 952             llvm_add_component "irreader" "opencl"
 953             llvm_add_component "option" "opencl"
 954             llvm_add_component "objcarcopts" "opencl"
 955             llvm_add_component "profiledata" "opencl"
 956         fi
 957         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
 958         MESA_LLVM=1
 959
 960         dnl Check for Clang internal headers
 961         if test "x$enable_opencl" = xyes; then
 962             if test -z "$CLANG_LIBDIR"; then
 963                 CLANG_LIBDIR=${LLVM_LIBDIR}
 964             fi
 965             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
 966             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
 967                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
 968         fi
 969     else
 970         MESA_LLVM=0
 971         LLVM_VERSION_INT=0
 972     fi
 973 }
 974
 975 dnl Options for APIs
 976 AC_ARG_ENABLE([opengl],
 977     [AS_HELP_STRING([--disable-opengl],
 978         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 979     [enable_opengl="$enableval"],
 980     [enable_opengl=yes])
 981 AC_ARG_ENABLE([gles1],
 982     [AS_HELP_STRING([--disable-gles1],
 983         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 984     [enable_gles1="$enableval"],
 985     [enable_gles1=yes])
 986 AC_ARG_ENABLE([gles2],
 987     [AS_HELP_STRING([--disable-gles2],
 988         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 989     [enable_gles2="$enableval"],
 990     [enable_gles2=yes])
 991
 992 AC_ARG_ENABLE([dri],
 993     [AS_HELP_STRING([--enable-dri],
 994         [enable DRI modules @<:@default=enabled@:>@])],
 995     [enable_dri="$enableval"],
 996     [enable_dri=yes])
 997
 998 AC_ARG_ENABLE([gallium-extra-hud],
 999     [AS_HELP_STRING([--enable-gallium-extra-hud],
1000         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1001     [enable_gallium_extra_hud="$enableval"],
1002     [enable_gallium_extra_hud=no])
1003 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1004 if test "x$enable_gallium_extra_hud" = xyes ; then
1005     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1006 fi
1007
1008 #TODO: no pkgconfig .pc available for libsensors.
1009 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1010 AC_ARG_ENABLE([lmsensors],
1011     [AS_HELP_STRING([--enable-lmsensors],
1012         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1013     [enable_lmsensors="$enableval"],
1014     [enable_lmsensors=no])
1015 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1016 if test "x$enable_lmsensors" = xyes ; then
1017     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1018     LIBSENSORS_LDFLAGS="-lsensors"
1019 else
1020     LIBSENSORS_LDFLAGS=""
1021 fi
1022 AC_SUBST(LIBSENSORS_LDFLAGS)
1023
1024 case "$host_os" in
1025 linux*)
1026     dri3_default=yes
1027     ;;
1028 *)
1029     dri3_default=no
1030     ;;
1031 esac
1032
1033 if test "x$enable_dri" = xno; then
1034     dri3_default=no
1035 fi
1036
1037 AC_ARG_ENABLE([dri3],
1038     [AS_HELP_STRING([--enable-dri3],
1039         [enable DRI3 @<:@default=auto@:>@])],
1040     [enable_dri3="$enableval"],
1041     [enable_dri3="$dri3_default"])
1042 AC_ARG_ENABLE([glx],
1043     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1044         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1045     [enable_glx="$enableval"],
1046     [enable_glx=yes])
1047 AC_ARG_ENABLE([osmesa],
1048     [AS_HELP_STRING([--enable-osmesa],
1049         [enable OSMesa library @<:@default=disabled@:>@])],
1050     [enable_osmesa="$enableval"],
1051     [enable_osmesa=no])
1052 AC_ARG_ENABLE([gallium-osmesa],
1053     [AS_HELP_STRING([--enable-gallium-osmesa],
1054         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1055     [enable_gallium_osmesa="$enableval"],
1056     [enable_gallium_osmesa=no])
1057 AC_ARG_ENABLE([egl],
1058     [AS_HELP_STRING([--disable-egl],
1059         [disable EGL library @<:@default=enabled@:>@])],
1060     [enable_egl="$enableval"],
1061     [enable_egl=yes])
1062
1063 AC_ARG_ENABLE([xa],
1064     [AS_HELP_STRING([--enable-xa],
1065         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1066     [enable_xa="$enableval"],
1067     [enable_xa=no])
1068 AC_ARG_ENABLE([gbm],
1069    [AS_HELP_STRING([--enable-gbm],
1070          [enable gbm library @<:@default=yes except cygwin@:>@])],
1071    [enable_gbm="$enableval"],
1072    [case "$host_os" in
1073        cygwin*)
1074           enable_gbm=no
1075           ;;
1076        *)
1077           enable_gbm=yes
1078           ;;
1079     esac])
1080 AC_ARG_ENABLE([nine],
1081     [AS_HELP_STRING([--enable-nine],
1082         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1083     [enable_nine="$enableval"],
1084     [enable_nine=no])
1085
1086 AC_ARG_ENABLE([xvmc],
1087    [AS_HELP_STRING([--enable-xvmc],
1088          [enable xvmc library @<:@default=auto@:>@])],
1089    [enable_xvmc="$enableval"],
1090    [enable_xvmc=auto])
1091 AC_ARG_ENABLE([vdpau],
1092    [AS_HELP_STRING([--enable-vdpau],
1093          [enable vdpau library @<:@default=auto@:>@])],
1094    [enable_vdpau="$enableval"],
1095    [enable_vdpau=auto])
1096 AC_ARG_ENABLE([omx],
1097    [AS_HELP_STRING([--enable-omx],
1098          [enable OpenMAX library @<:@default=disabled@:>@])],
1099    [enable_omx="$enableval"],
1100    [enable_omx=no])
1101 AC_ARG_ENABLE([va],
1102    [AS_HELP_STRING([--enable-va],
1103          [enable va library @<:@default=auto@:>@])],
1104    [enable_va="$enableval"],
1105    [enable_va=auto])
1106 AC_ARG_ENABLE([opencl],
1107    [AS_HELP_STRING([--enable-opencl],
1108          [enable OpenCL library @<:@default=disabled@:>@])],
1109    [enable_opencl="$enableval"],
1110    [enable_opencl=no])
1111 AC_ARG_ENABLE([opencl_icd],
1112    [AS_HELP_STRING([--enable-opencl-icd],
1113           [Build an OpenCL ICD library to be loaded by an ICD implementation
1114            @<:@default=disabled@:>@])],
1115     [enable_opencl_icd="$enableval"],
1116     [enable_opencl_icd=no])
1117
1118 AC_ARG_ENABLE([gallium-tests],
1119     [AS_HELP_STRING([--enable-gallium-tests],
1120         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1121     [enable_gallium_tests="$enableval"],
1122     [enable_gallium_tests=no])
1123
1124 # Option for Gallium drivers
1125
1126 # Keep this in sync with the --with-gallium-drivers help string default value
1127 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1128
1129 AC_ARG_WITH([gallium-drivers],
1130     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1131         [comma delimited Gallium drivers list, e.g.
1132         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1133         @<:@default=r300,r600,svga,swrast@:>@])],
1134     [with_gallium_drivers="$withval"],
1135     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1136
1137 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1138 # here so that the script doesn't choke on an unknown driver name later.
1139 case "$with_gallium_drivers" in
1140     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1141     no) with_gallium_drivers='' ;;
1142 esac
1143
1144 if test "x$enable_opengl" = xno -a \
1145         "x$enable_gles1" = xno -a \
1146         "x$enable_gles2" = xno -a \
1147         "x$enable_nine" = xno -a \
1148         "x$enable_xa" = xno -a \
1149         "x$enable_xvmc" = xno -a \
1150         "x$enable_vdpau" = xno -a \
1151         "x$enable_omx" = xno -a \
1152         "x$enable_va" = xno -a \
1153         "x$enable_opencl" = xno; then
1154     AC_MSG_ERROR([at least one API should be enabled])
1155 fi
1156
1157 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1158 if test "x$enable_opengl" = xno -a \
1159         "x$enable_gles1" = xyes; then
1160     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1161 fi
1162
1163 if test "x$enable_opengl" = xno -a \
1164         "x$enable_gles2" = xyes; then
1165     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1166 fi
1167
1168 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1169 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1170 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1171 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1172                                         "x$enable_gles1" = xyes -o \
1173                                         "x$enable_gles2" = xyes)
1174
1175 # Validate GLX options
1176 if test "x$enable_glx" = xyes; then
1177     if test "x$enable_dri" = xyes; then
1178         enable_glx=dri
1179     elif test -n "$with_gallium_drivers"; then
1180         enable_glx=gallium-xlib
1181     else
1182         enable_glx=xlib
1183     fi
1184 fi
1185 case "x$enable_glx" in
1186 xdri | xxlib | xgallium-xlib)
1187     # GLX requires OpenGL
1188     if test "x$enable_opengl" = xno; then
1189         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1190     fi
1191
1192     # Check individual dependencies
1193     case "x$enable_glx" in
1194     xdri)
1195         if test "x$enable_dri" = xno; then
1196             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1197         fi
1198         ;;
1199     xxlib)
1200         if test "x$enable_dri" = xyes; then
1201             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1202         fi
1203         ;;
1204     xgallium-xlib )
1205         if test "x$enable_dri" = xyes; then
1206             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1207         fi
1208         if test -z "$with_gallium_drivers"; then
1209             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1210         fi
1211         ;;
1212     esac
1213     ;;
1214 xno)
1215     ;;
1216 *)
1217     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1218     ;;
1219 esac
1220
1221 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1222 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1223 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1224 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1225
1226 dnl
1227 dnl Libglvnd configuration
1228 dnl
1229 AC_ARG_ENABLE([libglvnd],
1230     [AS_HELP_STRING([--enable-libglvnd],
1231         [Build for libglvnd @<:@default=disabled@:>@])],
1232     [enable_libglvnd="$enableval"],
1233     [enable_libglvnd=no])
1234 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1235 if test "x$enable_libglvnd" = xyes ; then
1236     dnl XXX: update once we can handle more than libGL/glx.
1237     dnl Namely: we should error out if neither of the glvnd enabled libraries
1238     dnl are built
1239     case "x$enable_glx" in
1240     xno)
1241         AC_MSG_ERROR([cannot build libglvnd without GLX])
1242         ;;
1243     xxlib | xgallium-xlib )
1244         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1245         ;;
1246     xdri)
1247         ;;
1248     esac
1249
1250     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1251     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1252     DEFAULT_GL_LIB_NAME=GLX_mesa
1253 fi
1254
1255 # Check for libdrm
1256 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1257                   [have_libdrm=yes], [have_libdrm=no])
1258 if test "x$have_libdrm" = xyes; then
1259         DEFINES="$DEFINES -DHAVE_LIBDRM"
1260 fi
1261
1262 require_libdrm() {
1263     if test "x$have_libdrm" != xyes; then
1264        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1265     fi
1266 }
1267
1268
1269 # Select which platform-dependent DRI code gets built
1270 case "$host_os" in
1271 darwin*)
1272     dri_platform='apple' ;;
1273 cygwin*)
1274     dri_platform='windows' ;;
1275 gnu*)
1276     dri_platform='none' ;;
1277 *)
1278     dri_platform='drm' ;;
1279 esac
1280
1281 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1282     have_drisw_kms='yes'
1283 fi
1284
1285 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1286 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1287 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1288 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1289 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1290 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1291 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1292 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1293 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1294
1295 AC_ARG_ENABLE([shared-glapi],
1296     [AS_HELP_STRING([--enable-shared-glapi],
1297         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1298     [enable_shared_glapi="$enableval"],
1299     [enable_shared_glapi=yes])
1300
1301 case "x$enable_opengl$enable_gles1$enable_gles2" in
1302 x*yes*yes*)
1303     if test "x$enable_shared_glapi" = xno; then
1304         AC_MSG_ERROR([shared GLAPI required when building two or more of
1305                       the following APIs - opengl, gles1 gles2])
1306     fi
1307     ;;
1308 esac
1309
1310 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1311
1312 # Build the pipe-drivers as separate libraries/modules.
1313 # Do not touch this unless you know what you are doing.
1314 # XXX: Expose via configure option ?
1315 enable_shared_pipe_drivers=no
1316
1317 dnl
1318 dnl Driver specific build directories
1319 dnl
1320
1321 if test "x$enable_gallium_osmesa" = xyes; then
1322     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1323         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1324     fi
1325     if test "x$enable_osmesa" = xyes; then
1326         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1327     fi
1328 fi
1329
1330 AC_SUBST([MESA_LLVM])
1331
1332 # SHA1 hashing
1333 AC_ARG_WITH([sha1],
1334         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1335         [choose SHA1 implementation])])
1336 case "x$with_sha1" in
1337 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1338   ;;
1339 *)
1340         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1341 esac
1342
1343 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1344 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1345         with_sha1=libc
1346 fi
1347 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1348         AC_MSG_ERROR([sha1 in libc requested but not found])
1349 fi
1350 if test "x$with_sha1" = xlibc; then
1351         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1352                 [Use libc SHA1 functions])
1353         SHA1_LIBS=""
1354 fi
1355 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1356 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1357         with_sha1=CommonCrypto
1358 fi
1359 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1360         AC_MSG_ERROR([CommonCrypto requested but not found])
1361 fi
1362 if test "x$with_sha1" = xCommonCrypto; then
1363         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1364                 [Use CommonCrypto SHA1 functions])
1365         SHA1_LIBS=""
1366 fi
1367 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1368 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1369 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1370         with_sha1=CryptoAPI
1371 fi
1372 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1373         AC_MSG_ERROR([CryptoAPI requested but not found])
1374 fi
1375 if test "x$with_sha1" = xCryptoAPI; then
1376         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1377                 [Use CryptoAPI SHA1 functions])
1378         SHA1_LIBS=""
1379 fi
1380 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1381 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1382         with_sha1=libmd
1383 fi
1384 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1385         AC_MSG_ERROR([libmd requested but not found])
1386 fi
1387 if test "x$with_sha1" = xlibmd; then
1388         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1389                   [Use libmd SHA1 functions])
1390         SHA1_LIBS=-lmd
1391 fi
1392 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1393 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1394    with_sha1=libsha1
1395 fi
1396 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1397         AC_MSG_ERROR([libsha1 requested but not found])
1398 fi
1399 if test "x$with_sha1" = xlibsha1; then
1400         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1401                   [Use libsha1 for SHA1])
1402         SHA1_LIBS=-lsha1
1403 fi
1404 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1405 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1406         with_sha1=libnettle
1407 fi
1408 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1409         AC_MSG_ERROR([libnettle requested but not found])
1410 fi
1411 if test "x$with_sha1" = xlibnettle; then
1412         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1413                   [Use libnettle SHA1 functions])
1414         SHA1_LIBS=-lnettle
1415 fi
1416 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1417 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1418         with_sha1=libgcrypt
1419 fi
1420 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1421         AC_MSG_ERROR([libgcrypt requested but not found])
1422 fi
1423 if test "x$with_sha1" = xlibgcrypt; then
1424         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1425                   [Use libgcrypt SHA1 functions])
1426         SHA1_LIBS=-lgcrypt
1427 fi
1428 # We don't need all of the OpenSSL libraries, just libcrypto
1429 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1430 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1431                   [HAVE_OPENSSL_PKC=no])
1432 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1433         if test "x$with_sha1" = x; then
1434                 with_sha1=libcrypto
1435         fi
1436 else
1437         if test "x$with_sha1" = xlibcrypto; then
1438                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1439         fi
1440 fi
1441 if test "x$with_sha1" = xlibcrypto; then
1442         if test "x$HAVE_LIBCRYPTO" = xyes; then
1443                 SHA1_LIBS=-lcrypto
1444         else
1445                 SHA1_LIBS="$OPENSSL_LIBS"
1446                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1447         fi
1448 fi
1449 AC_MSG_CHECKING([for SHA1 implementation])
1450 AC_MSG_RESULT([$with_sha1])
1451 AC_SUBST(SHA1_LIBS)
1452 AC_SUBST(SHA1_CFLAGS)
1453
1454 # Enable a define for SHA1
1455 if test "x$with_sha1" != "x"; then
1456         DEFINES="$DEFINES -DHAVE_SHA1"
1457 fi
1458
1459 # Allow user to configure out the shader-cache feature
1460 AC_ARG_ENABLE([shader-cache],
1461     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1462     [enable_shader_cache="$enableval"],
1463     [if test "x$with_sha1" != "x"; then
1464         enable_shader_cache=yes
1465      else
1466         enable_shader_cache=no
1467      fi])
1468 if test "x$with_sha1" = "x"; then
1469     if test "x$enable_shader_cache" = "xyes"; then
1470         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1471     fi
1472 fi
1473 if test "x$enable_shader_cache" = "xyes"; then
1474    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1475 fi
1476
1477 if test "x$enable_dri" = xyes; then
1478     if test "$enable_static" = yes; then
1479         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1480     fi
1481
1482     # not a hard requirement as swrast does not depend on it
1483     if test "x$have_libdrm" = xyes; then
1484         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1485     fi
1486 fi
1487
1488 AC_ARG_ENABLE([driglx-direct],
1489     [AS_HELP_STRING([--disable-driglx-direct],
1490         [disable direct rendering in GLX and EGL for DRI \
1491             @<:@default=auto@:>@])],
1492     [driglx_direct="$enableval"],
1493     [driglx_direct="yes"])
1494
1495 dnl
1496 dnl libGL configuration per driver
1497 dnl
1498 case "x$enable_glx" in
1499 xxlib | xgallium-xlib)
1500     # Xlib-based GLX
1501     dri_modules="x11 xext xcb"
1502     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1503     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1504     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1505     GL_LIB_DEPS="$XLIBGL_LIBS"
1506     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1507     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1508     ;;
1509 xdri)
1510     # DRI-based GLX
1511     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1512
1513     # find the DRI deps for libGL
1514     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1515
1516     if test x"$driglx_direct" = xyes; then
1517         if test x"$dri_platform" = xdrm ; then
1518             DEFINES="$DEFINES -DGLX_USE_DRM"
1519             require_libdrm "Direct rendering"
1520
1521             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1522             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1523             if test x"$enable_dri3" = xyes; then
1524                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1525                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1526             fi
1527
1528             if test x"$enable_dri" = xyes; then
1529                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1530             fi
1531
1532             if test x"$enable_dri3" = xyes; then
1533                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1534                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1535                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1536             fi
1537         fi
1538         if test x"$dri_platform" = xapple ; then
1539             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1540         fi
1541         if test x"$dri_platform" = xwindows ; then
1542             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1543         fi
1544     fi
1545
1546     # add xf86vidmode if available
1547     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1548     if test "$HAVE_XF86VIDMODE" = yes ; then
1549         dri_modules="$dri_modules xxf86vm"
1550     fi
1551
1552     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1553     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1554     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1555     GL_LIB_DEPS="$DRIGL_LIBS"
1556
1557     # need DRM libs, $PTHREAD_LIBS, etc.
1558     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1559     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1560     ;;
1561 esac
1562
1563 # This is outside the case (above) so that it is invoked even for non-GLX
1564 # builds.
1565 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1566
1567 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1568 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1569 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1570 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1571
1572 AC_SUBST([X11_INCLUDES])
1573 AC_SUBST([GL_LIB_DEPS])
1574 AC_SUBST([GL_PC_REQ_PRIV])
1575 AC_SUBST([GL_PC_LIB_PRIV])
1576 AC_SUBST([GL_PC_CFLAGS])
1577 AC_SUBST([DRI_PC_REQ_PRIV])
1578 AC_SUBST([GLESv1_CM_LIB_DEPS])
1579 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1580 AC_SUBST([GLESv2_LIB_DEPS])
1581 AC_SUBST([GLESv2_PC_LIB_PRIV])
1582
1583 AC_SUBST([HAVE_XF86VIDMODE])
1584
1585 dnl
1586 dnl More GLX setup
1587 dnl
1588 case "x$enable_glx" in
1589 xxlib | xgallium-xlib)
1590     DEFINES="$DEFINES -DUSE_XSHM"
1591     ;;
1592 xdri)
1593     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1594     if test "x$driglx_direct" = xyes; then
1595         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1596     fi
1597     ;;
1598 esac
1599
1600 dnl
1601 dnl TLS detection
1602 dnl
1603
1604 AC_ARG_ENABLE([glx-tls],
1605     [AS_HELP_STRING([--enable-glx-tls],
1606         [enable TLS support in GLX @<:@default=disabled@:>@])],
1607     [GLX_USE_TLS="$enableval"],
1608     [GLX_USE_TLS=no])
1609 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1610
1611 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1612       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1613
1614 dnl Read-only text section on x86 hardened platforms
1615 AC_ARG_ENABLE([glx-read-only-text],
1616     [AS_HELP_STRING([--enable-glx-read-only-text],
1617         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1618     [enable_glx_read_only_text="$enableval"],
1619     [enable_glx_read_only_text=no])
1620 if test "x$enable_glx_read_only_text" = xyes; then
1621     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1622 fi
1623
1624 dnl
1625 dnl More DRI setup
1626 dnl
1627 dnl Directory for DRI drivers
1628 AC_ARG_WITH([dri-driverdir],
1629     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1630         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1631     [DRI_DRIVER_INSTALL_DIR="$withval"],
1632     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1633 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1634 dnl Extra search path for DRI drivers
1635 AC_ARG_WITH([dri-searchpath],
1636     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1637         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1638     [DRI_DRIVER_SEARCH_DIR="$withval"],
1639     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1640 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1641 dnl Which drivers to build - default is chosen by platform
1642 AC_ARG_WITH([dri-drivers],
1643     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1644         [comma delimited classic DRI drivers list, e.g.
1645         "swrast,i965,radeon" @<:@default=auto@:>@])],
1646     [with_dri_drivers="$withval"],
1647     [with_dri_drivers=auto])
1648
1649 if test "x$with_dri_drivers" = xauto; then
1650     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1651         with_dri_drivers="yes"
1652     else
1653         with_dri_drivers="no"
1654     fi
1655 fi
1656 if test "x$with_dri_drivers" = xno; then
1657     with_dri_drivers=''
1658 fi
1659
1660 dnl If $with_dri_drivers is yes, drivers will be added through
1661 dnl platform checks. Set DEFINES and LIB_DEPS
1662 if test "x$enable_dri" = xyes; then
1663     # Platform specific settings and drivers to build
1664     case "$host_os" in
1665     linux*)
1666         DEFINES="$DEFINES -DHAVE_ALIAS"
1667         if test "x$enable_dri3" = xyes; then
1668             DEFINES="$DEFINES -DHAVE_DRI3"
1669         fi
1670
1671         case "$host_cpu" in
1672         powerpc* | sparc*)
1673             # Build only the drivers for cards that exist on PowerPC/sparc
1674             if test "x$with_dri_drivers" = "xyes"; then
1675                 with_dri_drivers="r200 radeon swrast"
1676             fi
1677             ;;
1678         esac
1679         ;;
1680     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1681         DEFINES="$DEFINES -DHAVE_ALIAS"
1682         ;;
1683     gnu*)
1684         DEFINES="$DEFINES -DHAVE_ALIAS"
1685         ;;
1686     cygwin*)
1687         if test "x$with_dri_drivers" = "xyes"; then
1688             with_dri_drivers="swrast"
1689         fi
1690         ;;
1691     darwin*)
1692         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1693         if test "x$with_dri_drivers" = "xyes"; then
1694             with_dri_drivers="swrast"
1695         fi
1696         ;;
1697     esac
1698
1699     # default drivers
1700     if test "x$with_dri_drivers" = "xyes"; then
1701         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1702     fi
1703
1704     # Check for expat
1705     PKG_CHECK_MODULES([EXPAT], [expat], [],
1706         # expat version 2.0 and earlier do not provide expat.pc
1707         [AC_CHECK_HEADER([expat.h],[],
1708                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1709          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1710                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1711          EXPAT_LIBS="-lexpat"])
1712
1713     # put all the necessary libs together
1714     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1715 fi
1716
1717 AC_SUBST([DRI_LIB_DEPS])
1718
1719 DRI_DIRS=''
1720 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1721 if test -n "$with_dri_drivers"; then
1722     if test "x$enable_opengl" != xyes; then
1723         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1724     fi
1725
1726     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1727     for driver in $dri_drivers; do
1728         DRI_DIRS="$DRI_DIRS $driver"
1729         case "x$driver" in
1730         xi915)
1731             HAVE_I915_DRI=yes;
1732             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1733             ;;
1734         xi965)
1735             HAVE_I965_DRI=yes;
1736             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1737             ;;
1738         xnouveau)
1739             HAVE_NOUVEAU_DRI=yes;
1740             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1741             ;;
1742         xradeon)
1743             HAVE_RADEON_DRI=yes;
1744             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1745             ;;
1746         xr200)
1747             HAVE_R200_DRI=yes;
1748             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1749             ;;
1750         xswrast)
1751             HAVE_SWRAST_DRI=yes;
1752             ;;
1753         *)
1754             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1755             ;;
1756         esac
1757     done
1758     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1759 fi
1760
1761
1762 #
1763 # Vulkan driver configuration
1764 #
1765
1766 AC_ARG_WITH([vulkan-drivers],
1767     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1768         [comma delimited Vulkan drivers list, e.g.
1769         "intel"
1770         @<:@default=no@:>@])],
1771     [with_vulkan_drivers="$withval"],
1772     [with_vulkan_drivers="no"])
1773
1774 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1775 # here so that the script doesn't choke on an unknown driver name later.
1776 case "x$with_vulkan_drivers" in
1777     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1778     xno) with_vulkan_drivers='' ;;
1779 esac
1780
1781 AC_ARG_WITH([vulkan-icddir],
1782     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1783         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1784     [VULKAN_ICD_INSTALL_DIR="$withval"],
1785     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1786 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1787
1788 if test -n "$with_vulkan_drivers"; then
1789     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1790     for driver in $VULKAN_DRIVERS; do
1791         case "x$driver" in
1792         xintel)
1793             if test "x$HAVE_I965_DRI" != xyes; then
1794                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1795             fi
1796             if test "x$with_sha1" == "x"; then
1797                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1798             fi
1799             HAVE_INTEL_VULKAN=yes;
1800
1801             ;;
1802         xradeon)
1803             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1804             HAVE_RADEON_VULKAN=yes;
1805             if test "x$with_sha1" == "x"; then
1806                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1807             fi
1808             ;;
1809         *)
1810             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1811             ;;
1812         esac
1813     done
1814     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1815 fi
1816
1817
1818 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1819 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1820                                   "x$enable_osmesa" = xyes -o \
1821                                   -n "$DRI_DIRS")
1822
1823 dnl
1824 dnl OSMesa configuration
1825 dnl
1826
1827 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1828 AC_ARG_WITH([osmesa-bits],
1829     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1830         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1831     [osmesa_bits="$withval"],
1832     [osmesa_bits=8])
1833 if test "x$osmesa_bits" != x8; then
1834     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1835         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1836         osmesa_bits=8
1837     fi
1838 fi
1839 case "x$osmesa_bits" in
1840 x8)
1841     OSMESA_LIB="${OSMESA_LIB}"
1842     ;;
1843 x16|x32)
1844     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1845     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1846     ;;
1847 *)
1848     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1849     ;;
1850 esac
1851
1852 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1853     # only link libraries with osmesa if shared
1854     if test "$enable_static" = no; then
1855         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1856     else
1857         OSMESA_LIB_DEPS=""
1858     fi
1859     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1860 fi
1861
1862 AC_SUBST([OSMESA_LIB_DEPS])
1863 AC_SUBST([OSMESA_PC_REQ])
1864 AC_SUBST([OSMESA_PC_LIB_PRIV])
1865
1866 dnl
1867 dnl gbm configuration
1868 dnl
1869 if test "x$enable_gbm" = xyes; then
1870     if test "x$enable_dri" = xyes; then
1871         if test "x$enable_shared_glapi" = xno; then
1872             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1873         fi
1874     else
1875         # Strictly speaking libgbm does not require --enable-dri, although
1876         # both of its backends do. Thus one can build libgbm without any
1877         # backends if --disable-dri is set.
1878         # To avoid unnecessary complexity of checking if at least one backend
1879         # is available when building, just mandate --enable-dri.
1880         AC_MSG_ERROR([gbm requires --enable-dri])
1881     fi
1882 fi
1883 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1884 # FINISHME: GBM has a number of dependencies which we should add below
1885 GBM_PC_REQ_PRIV=""
1886 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1887 AC_SUBST([GBM_PC_REQ_PRIV])
1888 AC_SUBST([GBM_PC_LIB_PRIV])
1889
1890 dnl
1891 dnl EGL configuration
1892 dnl
1893 EGL_CLIENT_APIS=""
1894
1895 if test "x$enable_egl" = xyes; then
1896     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1897
1898     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1899
1900     if test "$enable_static" != yes; then
1901         if test "x$enable_dri" = xyes; then
1902             HAVE_EGL_DRIVER_DRI2=1
1903             if test "x$enable_shared_glapi" = xno; then
1904                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1905             fi
1906             if test "x$enable_dri3" = xyes; then
1907                 HAVE_EGL_DRIVER_DRI3=1
1908                 if test "x$enable_shared_glapi" = xno; then
1909                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1910                 fi
1911             fi
1912         else
1913             # Avoid building an "empty" libEGL. Drop/update this
1914             # when other backends (haiku?) come along.
1915             AC_MSG_ERROR([egl requires --enable-dri])
1916         fi
1917
1918     fi
1919 fi
1920 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1921 AC_SUBST([EGL_LIB_DEPS])
1922
1923 gallium_st="mesa"
1924
1925 dnl
1926 dnl XA configuration
1927 dnl
1928 if test "x$enable_xa" = xyes; then
1929     if test "x$with_gallium_drivers" = xswrast; then
1930        AC_MSG_ERROR([
1931           Building xa requires at least one non swrast gallium driver.
1932           If you are looking to use libxatracker.so with the VMware driver,
1933           make sure to include svga in the gallium drivers list, apart from
1934           enabling XA.
1935           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1936     fi
1937     gallium_st="$gallium_st xa"
1938 fi
1939 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1940
1941 dnl
1942 dnl Gallium G3DVL configuration
1943 dnl
1944 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1945     if test "x$enable_xvmc" = xauto; then
1946         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1947     fi
1948
1949     if test "x$enable_vdpau" = xauto; then
1950         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1951     fi
1952
1953     if test "x$enable_omx" = xauto; then
1954         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1955     fi
1956
1957     if test "x$enable_va" = xauto; then
1958         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1959     fi
1960 fi
1961
1962 if test "x$enable_dri" = xyes -o \
1963         "x$enable_xvmc" = xyes -o \
1964         "x$enable_vdpau" = xyes -o \
1965         "x$enable_omx" = xyes -o \
1966         "x$enable_va" = xyes; then
1967     need_gallium_vl=yes
1968 fi
1969 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1970
1971 if test "x$enable_xvmc" = xyes -o \
1972         "x$enable_vdpau" = xyes -o \
1973         "x$enable_omx" = xyes -o \
1974         "x$enable_va" = xyes; then
1975     if test x"$enable_dri3" = xyes; then
1976         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1977                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1978     else
1979         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1980     fi
1981     need_gallium_vl_winsys=yes
1982 fi
1983 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1984
1985 if test "x$enable_xvmc" = xyes; then
1986     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1987     gallium_st="$gallium_st xvmc"
1988 fi
1989 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1990
1991 if test "x$enable_vdpau" = xyes; then
1992     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1993     gallium_st="$gallium_st vdpau"
1994     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1995 fi
1996 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1997
1998 if test "x$enable_omx" = xyes; then
1999     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2000     gallium_st="$gallium_st omx"
2001 fi
2002 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2003
2004 if test "x$enable_va" = xyes; then
2005     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2006     gallium_st="$gallium_st va"
2007 fi
2008 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2009
2010 dnl
2011 dnl Nine Direct3D9 configuration
2012 dnl
2013 if test "x$enable_nine" = xyes; then
2014     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2015         AC_MSG_ERROR([nine requires the gallium swrast driver])
2016     fi
2017     if test "x$with_gallium_drivers" = xswrast; then
2018         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2019     fi
2020     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2021         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2022     fi
2023
2024     if test "x$enable_dri3" = xno; then
2025         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2026     fi
2027
2028     gallium_st="$gallium_st nine"
2029 fi
2030 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2031
2032 dnl
2033 dnl OpenCL configuration
2034 dnl
2035
2036 AC_ARG_WITH([clang-libdir],
2037    [AS_HELP_STRING([--with-clang-libdir],
2038          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2039    [CLANG_LIBDIR="$withval"],
2040    [CLANG_LIBDIR=''])
2041
2042 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2043 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
2044
2045 if test "x$have_libelf" = xno; then
2046    LIBELF_LIBS=''
2047    LIBELF_CFLAGS=''
2048    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
2049    AC_SUBST([LIBELF_LIBS])
2050    AC_SUBST([LIBELF_CFLAGS])
2051 fi
2052
2053 if test "x$enable_opencl" = xyes; then
2054     if test -z "$with_gallium_drivers"; then
2055         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2056     fi
2057
2058     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2059         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2060     fi
2061
2062     if test "x$have_libclc" = xno; then
2063         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2064                     Make sure the directory containing libclc.pc is specified in your
2065                     PKG_CONFIG_PATH environment variable.
2066                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2067     else
2068         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2069         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2070         AC_SUBST([LIBCLC_INCLUDEDIR])
2071         AC_SUBST([LIBCLC_LIBEXECDIR])
2072     fi
2073
2074     gallium_st="$gallium_st clover"
2075
2076     if test "x$enable_opencl_icd" = xyes; then
2077         OPENCL_LIBNAME="MesaOpenCL"
2078     else
2079         OPENCL_LIBNAME="OpenCL"
2080     fi
2081
2082     if test "x$have_libelf" != xyes; then
2083        AC_MSG_ERROR([Clover requires libelf])
2084     fi
2085 fi
2086 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2087 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2088 AC_SUBST([OPENCL_LIBNAME])
2089
2090 dnl
2091 dnl Gallium configuration
2092 dnl
2093 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2094
2095 AC_SUBST([LLVM_BINDIR])
2096 AC_SUBST([LLVM_CFLAGS])
2097 AC_SUBST([LLVM_CPPFLAGS])
2098 AC_SUBST([LLVM_CXXFLAGS])
2099 AC_SUBST([LLVM_LIBDIR])
2100 AC_SUBST([LLVM_LIBS])
2101 AC_SUBST([LLVM_LDFLAGS])
2102 AC_SUBST([LLVM_INCLUDEDIR])
2103 AC_SUBST([LLVM_VERSION])
2104 AC_SUBST([CLANG_RESOURCE_DIR])
2105
2106 case "x$enable_opengl$enable_gles1$enable_gles2" in
2107 x*yes*)
2108     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2109     ;;
2110 esac
2111
2112 AC_SUBST([VG_LIB_DEPS])
2113 AC_SUBST([EGL_CLIENT_APIS])
2114
2115 dnl
2116 dnl EGL Platforms configuration
2117 dnl
2118 AC_ARG_WITH([egl-platforms],
2119     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2120         [comma delimited native platforms libEGL supports, e.g.
2121         "x11,drm" @<:@default=auto@:>@])],
2122     [with_egl_platforms="$withval"],
2123     [if test "x$enable_egl" = xyes; then
2124         if test "x$enable_gbm" = xyes; then
2125            with_egl_platforms="x11,drm"
2126         else
2127            with_egl_platforms="x11"
2128         fi
2129     else
2130         with_egl_platforms=""
2131     fi])
2132
2133 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2134     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2135 fi
2136
2137 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2138         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2139         WAYLAND_SCANNER='')
2140 if test "x$WAYLAND_SCANNER" = x; then
2141     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2142 fi
2143
2144 # Do per-EGL platform setups and checks
2145 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2146 for plat in $egl_platforms; do
2147         case "$plat" in
2148         wayland)
2149
2150                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2151
2152                 if test "x$WAYLAND_SCANNER" = x; then
2153                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2154                 fi
2155                 ;;
2156
2157         x11)
2158                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2159                 ;;
2160
2161         drm)
2162                 test "x$enable_gbm" = "xno" &&
2163                         AC_MSG_ERROR([EGL platform drm needs gbm])
2164                 ;;
2165
2166         surfaceless)
2167                 ;;
2168
2169         android)
2170                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2171                 ;;
2172
2173         *)
2174                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2175                 ;;
2176         esac
2177
2178         case "$plat" in
2179         wayland|drm|surfaceless)
2180                 require_libdrm "Platform $plat"
2181                 ;;
2182         esac
2183 done
2184
2185 # libEGL wants to default to the first platform specified in
2186 # ./configure.  parse that here.
2187 if test "x$egl_platforms" != "x"; then
2188     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2189     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2190 else
2191     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2192 fi
2193
2194 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2195 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2196 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2197 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2198 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2199
2200 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2201
2202 AC_SUBST([EGL_NATIVE_PLATFORM])
2203 AC_SUBST([EGL_CFLAGS])
2204
2205 # If we don't have the X11 platform, set this define so we don't try to include
2206 # the X11 headers.
2207 if ! echo "$egl_platforms" | grep -q 'x11'; then
2208     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2209     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2210 fi
2211
2212 dnl
2213 dnl Gallium LLVM
2214 dnl
2215 AC_ARG_ENABLE([gallium-llvm],
2216     [AS_HELP_STRING([--enable-gallium-llvm],
2217         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2218     [enable_gallium_llvm="$enableval"],
2219     [enable_gallium_llvm=auto])
2220
2221 AC_ARG_ENABLE([llvm-shared-libs],
2222     [AS_HELP_STRING([--enable-llvm-shared-libs],
2223         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2224     [enable_llvm_shared_libs="$enableval"],
2225     [enable_llvm_shared_libs=yes])
2226
2227 AC_ARG_WITH([llvm-prefix],
2228     [AS_HELP_STRING([--with-llvm-prefix],
2229         [Prefix for LLVM installations in non-standard locations])],
2230     [llvm_prefix="$withval"],
2231     [llvm_prefix=''])
2232
2233
2234 # Call this inside ` ` to get the return value.
2235 # $1 is the llvm-config command with arguments.
2236 strip_unwanted_llvm_flags() {
2237     # Use \> (marks the end of the word)
2238     echo `$1` | sed \
2239         -e 's/-march=\S*//g' \
2240         -e 's/-mtune=\S*//g' \
2241         -e 's/-mcpu=\S*//g' \
2242         -e 's/-DNDEBUG\>//g' \
2243         -e 's/-D_GNU_SOURCE\>//g' \
2244         -e 's/-pedantic\>//g' \
2245         -e 's/-Wcovered-switch-default\>//g' \
2246         -e 's/-O.\>//g' \
2247         -e 's/-g\>//g' \
2248         -e 's/-Wall\>//g' \
2249         -e 's/-Wcast-qual\>//g' \
2250         -e 's/-Woverloaded-virtual\>//g' \
2251         -e 's/-fcolor-diagnostics\>//g' \
2252         -e 's/-fdata-sections\>//g' \
2253         -e 's/-ffunction-sections\>//g' \
2254         -e 's/-fno-exceptions\>//g' \
2255         -e 's/-fomit-frame-pointer\>//g' \
2256         -e 's/-fvisibility-inlines-hidden\>//g' \
2257         -e 's/-fPIC\>//g' \
2258         -e 's/-fstack-protector-strong\>//g'
2259 }
2260
2261 llvm_check_version_for() {
2262     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2263         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2264     fi
2265 }
2266
2267
2268
2269 if test -z "$with_gallium_drivers"; then
2270     enable_gallium_llvm=no
2271 fi
2272 if test "x$enable_gallium_llvm" = xauto; then
2273     case "$host_cpu" in
2274     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2275     esac
2276 fi
2277 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2278     llvm_set_environment_variables
2279 else
2280     MESA_LLVM=0
2281     LLVM_VERSION_INT=0
2282
2283     if test "x$enable_opencl" = xyes; then
2284         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2285     fi
2286 fi
2287
2288 dnl Directory for XVMC libs
2289 AC_ARG_WITH([xvmc-libdir],
2290     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2291         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2292     [XVMC_LIB_INSTALL_DIR="$withval"],
2293     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2294 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2295
2296 dnl
2297 dnl Gallium Tests
2298 dnl
2299 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2300
2301 dnl Directory for VDPAU libs
2302 AC_ARG_WITH([vdpau-libdir],
2303     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2304         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2305     [VDPAU_LIB_INSTALL_DIR="$withval"],
2306     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2307 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2308
2309 dnl Directory for OMX libs
2310
2311 AC_ARG_WITH([omx-libdir],
2312     [AS_HELP_STRING([--with-omx-libdir=DIR],
2313         [directory for the OMX libraries])],
2314     [OMX_LIB_INSTALL_DIR="$withval"],
2315     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2316 AC_SUBST([OMX_LIB_INSTALL_DIR])
2317
2318 dnl Directory for VA libs
2319
2320 AC_ARG_WITH([va-libdir],
2321     [AS_HELP_STRING([--with-va-libdir=DIR],
2322         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2323     [VA_LIB_INSTALL_DIR="$withval"],
2324     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2325 AC_SUBST([VA_LIB_INSTALL_DIR])
2326
2327 AC_ARG_WITH([d3d-libdir],
2328     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2329         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2330     [D3D_DRIVER_INSTALL_DIR="$withval"],
2331     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2332 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2333
2334 dnl
2335 dnl Gallium helper functions
2336 dnl
2337 gallium_require_llvm() {
2338     if test "x$MESA_LLVM" = x0; then
2339         case "$host" in *gnux32) return;; esac
2340         case "$host_cpu" in
2341         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2342         esac
2343     fi
2344 }
2345
2346 dnl
2347 dnl DRM is needed by X, Wayland, and offscreen rendering.
2348 dnl Surfaceless is an alternative for the last one.
2349 dnl
2350 require_basic_egl() {
2351     case "$with_egl_platforms" in
2352         *drm*|*surfaceless*)
2353             ;;
2354         *)
2355             AC_MSG_ERROR([$1 requires one of these:
2356                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2357                   2) --with-egl-platforms=surfaceless (offscreen only)
2358                   Recommended options: drm,x11])
2359             ;;
2360     esac
2361 }
2362
2363 radeon_llvm_check() {
2364     if test ${LLVM_VERSION_INT} -lt 307; then
2365         amdgpu_llvm_target_name='r600'
2366     else
2367         amdgpu_llvm_target_name='amdgpu'
2368     fi
2369
2370     llvm_check_version_for $2 $3 $4 $1
2371
2372     llvm_add_target $amdgpu_llvm_target_name $1
2373
2374     llvm_add_component "bitreader" $1
2375     llvm_add_component "ipo" $1
2376
2377     NEED_RADEON_LLVM=yes
2378     if test "x$have_libelf" != xyes; then
2379        AC_MSG_ERROR([$1 requires libelf when using llvm])
2380     fi
2381 }
2382
2383 radeon_gallium_llvm_check() {
2384     if test "x$enable_gallium_llvm" != "xyes"; then
2385         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2386     fi
2387     radeon_llvm_check $*
2388 }
2389
2390 swr_llvm_check() {
2391     gallium_require_llvm $1
2392     if test ${LLVM_VERSION_INT} -lt 306; then
2393         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2394     fi
2395     if test "x$enable_gallium_llvm" != "xyes"; then
2396         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2397     fi
2398 }
2399
2400 swr_require_cxx_feature_flags() {
2401     feature_name="$1"
2402     preprocessor_test="$2"
2403     option_list="$3"
2404     output_var="$4"
2405
2406     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2407     AC_LANG_PUSH([C++])
2408     save_CXXFLAGS="$CXXFLAGS"
2409     save_IFS="$IFS"
2410     IFS=","
2411     found=0
2412     for opts in $option_list
2413     do
2414         unset IFS
2415         CXXFLAGS="$opts $save_CXXFLAGS"
2416         AC_COMPILE_IFELSE(
2417             [AC_LANG_PROGRAM(
2418                 [   #if !($preprocessor_test)
2419                     #error
2420                     #endif
2421                 ])],
2422             [found=1; break],
2423             [])
2424         IFS=","
2425     done
2426     IFS="$save_IFS"
2427     CXXFLAGS="$save_CXXFLAGS"
2428     AC_LANG_POP([C++])
2429     if test $found -eq 1; then
2430         AC_MSG_RESULT([$opts])
2431         eval "$output_var=\$opts"
2432         return 0
2433     fi
2434     AC_MSG_RESULT([no])
2435     AC_MSG_ERROR([swr requires $feature_name support])
2436     return 1
2437 }
2438
2439 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2440 if test -n "$with_gallium_drivers"; then
2441     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2442     for driver in $gallium_drivers; do
2443         case "x$driver" in
2444         xsvga)
2445             HAVE_GALLIUM_SVGA=yes
2446             require_libdrm "svga"
2447             ;;
2448         xi915)
2449             HAVE_GALLIUM_I915=yes
2450             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2451             require_libdrm "Gallium i915"
2452             ;;
2453         xilo)
2454             HAVE_GALLIUM_ILO=yes
2455             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2456             require_libdrm "Gallium i965/ilo"
2457             ;;
2458         xr300)
2459             HAVE_GALLIUM_R300=yes
2460             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2461             require_libdrm "Gallium R300"
2462             gallium_require_llvm "Gallium R300"
2463             ;;
2464         xr600)
2465             HAVE_GALLIUM_R600=yes
2466             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2467             require_libdrm "Gallium R600"
2468             if test "x$enable_opencl" = xyes; then
2469                 radeon_gallium_llvm_check "r600g" "3" "6" "0"
2470
2471                 llvm_add_component "asmparser" "r600"
2472                 llvm_add_component "bitreader" "r600"
2473             fi
2474             ;;
2475         xradeonsi)
2476             HAVE_GALLIUM_RADEONSI=yes
2477             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2478             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2479             require_libdrm "radeonsi"
2480             radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2481             require_basic_egl "radeonsi"
2482             ;;
2483         xnouveau)
2484             HAVE_GALLIUM_NOUVEAU=yes
2485             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2486             require_libdrm "nouveau"
2487             ;;
2488         xfreedreno)
2489             HAVE_GALLIUM_FREEDRENO=yes
2490             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2491             require_libdrm "freedreno"
2492             ;;
2493         xswrast)
2494             HAVE_GALLIUM_SOFTPIPE=yes
2495             if test "x$MESA_LLVM" = x1; then
2496                 HAVE_GALLIUM_LLVMPIPE=yes
2497             fi
2498             ;;
2499         xswr)
2500             swr_llvm_check "swr"
2501
2502             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2503                 ",-std=c++11" \
2504                 SWR_CXX11_CXXFLAGS
2505             AC_SUBST([SWR_CXX11_CXXFLAGS])
2506
2507             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2508                 ",-mavx,-march=core-avx" \
2509                 SWR_AVX_CXXFLAGS
2510             AC_SUBST([SWR_AVX_CXXFLAGS])
2511
2512             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2513                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2514                 SWR_AVX2_CXXFLAGS
2515             AC_SUBST([SWR_AVX2_CXXFLAGS])
2516
2517             HAVE_GALLIUM_SWR=yes
2518             ;;
2519         xvc4)
2520             HAVE_GALLIUM_VC4=yes
2521             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2522             require_libdrm "vc4"
2523
2524             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2525                               [USE_VC4_SIMULATOR=yes;
2526                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2527                               [USE_VC4_SIMULATOR=no])
2528             ;;
2529         xvirgl)
2530             HAVE_GALLIUM_VIRGL=yes
2531             require_libdrm "virgl"
2532             require_basic_egl "virgl"
2533             ;;
2534         *)
2535             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2536             ;;
2537         esac
2538     done
2539 fi
2540
2541 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2542     radeon_llvm_check "radv" "3" "9" "0"
2543 fi
2544
2545 dnl Set LLVM_LIBS - This is done after the driver configuration so
2546 dnl that drivers can add additional components to LLVM_COMPONENTS.
2547 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2548 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2549 dnl this was causing the same libraries to be appear multiple times
2550 dnl in LLVM_LIBS.
2551
2552 if test "x$MESA_LLVM" != x0; then
2553
2554     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2555        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2556     fi
2557     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2558
2559     dnl llvm-config may not give the right answer when llvm is a built as a
2560     dnl single shared library, so we must work the library name out for
2561     dnl ourselves.
2562     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2563     if test "x$enable_llvm_shared_libs" = xyes; then
2564         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2565         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2566         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2567
2568         if test "x$llvm_have_one_so" = xyes; then
2569             dnl LLVM was built using auto*, so there is only one shared object.
2570             LLVM_LIBS="-l$LLVM_SO_NAME"
2571         else
2572             dnl If LLVM was built with CMake, there will be one shared object per
2573             dnl component.
2574             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2575                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2576         Please make sure you have built llvm with the --enable-shared option
2577         and that your llvm libraries are installed in $LLVM_LIBDIR
2578         If you have installed your llvm libraries to a different directory you
2579         can use the --with-llvm-prefix= configure flag to specify this directory.
2580         NOTE: Mesa is attempting to use llvm shared libraries by default.
2581         If you do not want to build with llvm shared libraries and instead want to
2582         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2583         invocation and rebuild.])])
2584
2585            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2586            dnl install uses a shared object for each component and we have
2587            dnl already added all of these objects to LLVM_LIBS.
2588         fi
2589     else
2590         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2591         dnl We need to link to llvm system libs when using static libs
2592         dnl However, only llvm 3.5+ provides --system-libs
2593         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2594             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2595         fi
2596     fi
2597 fi
2598
2599 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2600 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2601 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2602 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2603 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2604 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2605 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2606                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2607 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2608 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2609 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2610 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2612 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2613                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2614                                          "x$HAVE_GALLIUM_SWR" = xyes)
2615 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2616 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2617
2618 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2619
2620 if test "x$enable_dri" = xyes; then
2621     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2622 fi
2623
2624 if test "x$have_drisw_kms" = xyes; then
2625     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2626 fi
2627 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2628
2629 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2630 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2631 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2632 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2633 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2634 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2635
2636 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2637 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2638
2639 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2640                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2641                                       "x$HAVE_RADEON_VULKAN" = xyes)
2642
2643 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2644                                         "x$HAVE_I965_DRI" = xyes)
2645
2646 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2647                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2648                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2649 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2650 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2651 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2652 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2653 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2654 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2655     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2656 fi
2657
2658 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2659 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2660 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2661 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2662                                         "x$enable_gallium_osmesa" = xyes)
2663
2664 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2665 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2666 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2667
2668 AC_SUBST([NINE_MAJOR], 1)
2669 AC_SUBST([NINE_MINOR], 0)
2670 AC_SUBST([NINE_TINY], 0)
2671 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2672
2673 AC_SUBST([VDPAU_MAJOR], 1)
2674 AC_SUBST([VDPAU_MINOR], 0)
2675
2676 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2677 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2678 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2679 AC_SUBST([VA_MINOR], $VA_MINOR)
2680
2681 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2682
2683 AC_SUBST([XVMC_MAJOR], 1)
2684 AC_SUBST([XVMC_MINOR], 0)
2685
2686 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2687 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2688 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2689 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2690
2691 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2692 AC_SUBST([XA_MINOR], $XA_MINOR)
2693 AC_SUBST([XA_TINY], $XA_TINY)
2694 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2695
2696 AC_ARG_ENABLE(valgrind,
2697               [AS_HELP_STRING([--enable-valgrind],
2698                              [Build mesa with valgrind support (default: auto)])],
2699                              [VALGRIND=$enableval], [VALGRIND=auto])
2700 if test "x$VALGRIND" != xno; then
2701         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2702 fi
2703 AC_MSG_CHECKING([whether to enable Valgrind support])
2704 if test "x$VALGRIND" = xauto; then
2705         VALGRIND="$have_valgrind"
2706 fi
2707
2708 if test "x$VALGRIND" = "xyes"; then
2709         if ! test "x$have_valgrind" = xyes; then
2710                 AC_MSG_ERROR([Valgrind support required but not present])
2711         fi
2712         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2713 fi
2714
2715 AC_MSG_RESULT([$VALGRIND])
2716
2717 dnl Restore LDFLAGS and CPPFLAGS
2718 LDFLAGS="$_SAVE_LDFLAGS"
2719 CPPFLAGS="$_SAVE_CPPFLAGS"
2720
2721 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2722 if test "x$acv_mesa_CLANG" = xyes; then
2723     CFLAGS="$CFLAGS -Qunused-arguments"
2724     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2725 fi
2726
2727 dnl Add user CFLAGS and CXXFLAGS
2728 CFLAGS="$CFLAGS $USER_CFLAGS"
2729 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2730
2731 dnl Substitute the config
2732 AC_CONFIG_FILES([Makefile
2733                 src/Makefile
2734                 src/amd/Makefile
2735                 src/amd/vulkan/Makefile
2736                 src/compiler/Makefile
2737                 src/egl/Makefile
2738                 src/egl/main/egl.pc
2739                 src/egl/wayland/wayland-drm/Makefile
2740                 src/egl/wayland/wayland-egl/Makefile
2741                 src/egl/wayland/wayland-egl/wayland-egl.pc
2742                 src/gallium/Makefile
2743                 src/gallium/auxiliary/Makefile
2744                 src/gallium/auxiliary/pipe-loader/Makefile
2745                 src/gallium/drivers/freedreno/Makefile
2746                 src/gallium/drivers/ddebug/Makefile
2747                 src/gallium/drivers/i915/Makefile
2748                 src/gallium/drivers/ilo/Makefile
2749                 src/gallium/drivers/llvmpipe/Makefile
2750                 src/gallium/drivers/noop/Makefile
2751                 src/gallium/drivers/nouveau/Makefile
2752                 src/gallium/drivers/r300/Makefile
2753                 src/gallium/drivers/r600/Makefile
2754                 src/gallium/drivers/radeon/Makefile
2755                 src/gallium/drivers/radeonsi/Makefile
2756                 src/gallium/drivers/rbug/Makefile
2757                 src/gallium/drivers/softpipe/Makefile
2758                 src/gallium/drivers/svga/Makefile
2759                 src/gallium/drivers/swr/Makefile
2760                 src/gallium/drivers/trace/Makefile
2761                 src/gallium/drivers/vc4/Makefile
2762                 src/gallium/drivers/virgl/Makefile
2763                 src/gallium/state_trackers/clover/Makefile
2764                 src/gallium/state_trackers/dri/Makefile
2765                 src/gallium/state_trackers/glx/xlib/Makefile
2766                 src/gallium/state_trackers/nine/Makefile
2767                 src/gallium/state_trackers/omx/Makefile
2768                 src/gallium/state_trackers/osmesa/Makefile
2769                 src/gallium/state_trackers/va/Makefile
2770                 src/gallium/state_trackers/vdpau/Makefile
2771                 src/gallium/state_trackers/xa/Makefile
2772                 src/gallium/state_trackers/xvmc/Makefile
2773                 src/gallium/targets/d3dadapter9/Makefile
2774                 src/gallium/targets/d3dadapter9/d3d.pc
2775                 src/gallium/targets/dri/Makefile
2776                 src/gallium/targets/libgl-xlib/Makefile
2777                 src/gallium/targets/omx/Makefile
2778                 src/gallium/targets/opencl/Makefile
2779                 src/gallium/targets/opencl/mesa.icd
2780                 src/gallium/targets/osmesa/Makefile
2781                 src/gallium/targets/osmesa/osmesa.pc
2782                 src/gallium/targets/pipe-loader/Makefile
2783                 src/gallium/targets/va/Makefile
2784                 src/gallium/targets/vdpau/Makefile
2785                 src/gallium/targets/xa/Makefile
2786                 src/gallium/targets/xa/xatracker.pc
2787                 src/gallium/targets/xvmc/Makefile
2788                 src/gallium/tests/trivial/Makefile
2789                 src/gallium/tests/unit/Makefile
2790                 src/gallium/winsys/freedreno/drm/Makefile
2791                 src/gallium/winsys/i915/drm/Makefile
2792                 src/gallium/winsys/intel/drm/Makefile
2793                 src/gallium/winsys/nouveau/drm/Makefile
2794                 src/gallium/winsys/radeon/drm/Makefile
2795                 src/gallium/winsys/amdgpu/drm/Makefile
2796                 src/gallium/winsys/svga/drm/Makefile
2797                 src/gallium/winsys/sw/dri/Makefile
2798                 src/gallium/winsys/sw/kms-dri/Makefile
2799                 src/gallium/winsys/sw/null/Makefile
2800                 src/gallium/winsys/sw/wrapper/Makefile
2801                 src/gallium/winsys/sw/xlib/Makefile
2802                 src/gallium/winsys/vc4/drm/Makefile
2803                 src/gallium/winsys/virgl/drm/Makefile
2804                 src/gallium/winsys/virgl/vtest/Makefile
2805                 src/gbm/Makefile
2806                 src/gbm/main/gbm.pc
2807                 src/glx/Makefile
2808                 src/glx/apple/Makefile
2809                 src/glx/tests/Makefile
2810                 src/glx/windows/Makefile
2811                 src/glx/windows/windowsdriproto.pc
2812                 src/gtest/Makefile
2813                 src/intel/Makefile
2814                 src/intel/tools/Makefile
2815                 src/intel/vulkan/Makefile
2816                 src/loader/Makefile
2817                 src/mapi/Makefile
2818                 src/mapi/es1api/glesv1_cm.pc
2819                 src/mapi/es2api/glesv2.pc
2820                 src/mapi/glapi/gen/Makefile
2821                 src/mesa/Makefile
2822                 src/mesa/gl.pc
2823                 src/mesa/drivers/dri/dri.pc
2824                 src/mesa/drivers/dri/common/Makefile
2825                 src/mesa/drivers/dri/common/xmlpool/Makefile
2826                 src/mesa/drivers/dri/i915/Makefile
2827                 src/mesa/drivers/dri/i965/Makefile
2828                 src/mesa/drivers/dri/Makefile
2829                 src/mesa/drivers/dri/nouveau/Makefile
2830                 src/mesa/drivers/dri/r200/Makefile
2831                 src/mesa/drivers/dri/radeon/Makefile
2832                 src/mesa/drivers/dri/swrast/Makefile
2833                 src/mesa/drivers/osmesa/Makefile
2834                 src/mesa/drivers/osmesa/osmesa.pc
2835                 src/mesa/drivers/x11/Makefile
2836                 src/mesa/main/tests/Makefile
2837                 src/util/Makefile
2838                 src/util/tests/hash_table/Makefile
2839                 src/vulkan/wsi/Makefile])
2840
2841 AC_OUTPUT
2842
2843 # Fix up dependencies in *.Plo files, where we changed the extension of a
2844 # source file
2845 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2846
2847
2848 dnl
2849 dnl Output some configuration info for the user
2850 dnl
2851 echo ""
2852 echo "        prefix:          $prefix"
2853 echo "        exec_prefix:     $exec_prefix"
2854 echo "        libdir:          $libdir"
2855 echo "        includedir:      $includedir"
2856
2857 dnl API info
2858 echo ""
2859 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2860
2861 dnl Driver info
2862 echo ""
2863 case "x$enable_osmesa$enable_gallium_osmesa" in
2864 xnoyes)
2865         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2866         ;;
2867 xyesno)
2868         echo "        OSMesa:          lib$OSMESA_LIB"
2869         ;;
2870 xnono)
2871         echo "        OSMesa:          no"
2872         ;;
2873 esac
2874
2875 echo ""
2876 if test "x$enable_dri" != xno; then
2877         echo "        DRI platform:    $dri_platform"
2878         if test -z "$DRI_DIRS"; then
2879             echo "        DRI drivers:     no"
2880         else
2881             echo "        DRI drivers:     $DRI_DIRS"
2882         fi
2883         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2884 fi
2885
2886 case "x$enable_glx" in
2887 xdri)
2888     echo "        GLX:             DRI-based"
2889     ;;
2890 xxlib)
2891     echo "        GLX:             Xlib-based"
2892     ;;
2893 xgallium-xlib)
2894     echo "        GLX:             Xlib-based (Gallium)"
2895     ;;
2896 *)
2897     echo "        GLX:             $enable_glx"
2898     ;;
2899 esac
2900
2901 dnl EGL
2902 echo ""
2903 echo "        EGL:             $enable_egl"
2904 if test "$enable_egl" = yes; then
2905     echo "        EGL platforms:   $egl_platforms"
2906
2907     egl_drivers=""
2908     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2909         egl_drivers="$egl_drivers builtin:egl_dri2"
2910     fi
2911     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2912         egl_drivers="$egl_drivers builtin:egl_dri3"
2913     fi
2914
2915     echo "        EGL drivers:    $egl_drivers"
2916 fi
2917 if test "x$enable_gbm" = xyes; then
2918     echo "        GBM:             yes"
2919 else
2920     echo "        GBM:             no"
2921 fi
2922
2923 # Vulkan
2924 echo ""
2925 if test "x$VULKAN_DRIVERS" != x; then
2926     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2927     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2928 else
2929     echo "        Vulkan drivers:  no"
2930 fi
2931
2932 echo ""
2933 if test "x$MESA_LLVM" = x1; then
2934     echo "        llvm:            yes"
2935     echo "        llvm-config:     $LLVM_CONFIG"
2936     echo "        llvm-version:    $LLVM_VERSION"
2937 else
2938     echo "        llvm:            no"
2939 fi
2940
2941 echo ""
2942 if test -n "$with_gallium_drivers"; then
2943     echo "        Gallium drivers: $gallium_drivers"
2944     echo "        Gallium st:      $gallium_st"
2945 else
2946     echo "        Gallium:         no"
2947 fi
2948
2949 echo ""
2950 if test "x$enable_gallium_extra_hud" != xyes; then
2951     echo "        HUD extra stats: no"
2952 else
2953     echo "        HUD extra stats: yes"
2954 fi
2955
2956 if test "x$enable_lmsensors" != xyes; then
2957     echo "        HUD lmsensors:   no"
2958 else
2959     echo "        HUD lmsensors:   yes"
2960 fi
2961
2962 dnl Shader cache
2963 echo ""
2964 echo "        Shader cache:    $enable_shader_cache"
2965 if test "x$enable_shader_cache" = "xyes"; then
2966     echo "        With SHA1 from:  $with_sha1"
2967 fi
2968
2969 dnl Libraries
2970 echo ""
2971 echo "        Shared libs:     $enable_shared"
2972 echo "        Static libs:     $enable_static"
2973 echo "        Shared-glapi:    $enable_shared_glapi"
2974
2975 dnl Compiler options
2976 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2977 cflags=`echo $CFLAGS | \
2978     $SED 's/^ *//;s/  */ /;s/ *$//'`
2979 cxxflags=`echo $CXXFLAGS | \
2980     $SED 's/^ *//;s/  */ /;s/ *$//'`
2981 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2982 echo ""
2983 echo "        CFLAGS:          $cflags"
2984 echo "        CXXFLAGS:        $cxxflags"
2985 echo "        Macros:          $defines"
2986 echo ""
2987 if test "x$MESA_LLVM" = x1; then
2988     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2989     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2990     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2991     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2992     echo ""
2993 fi
2994 echo "        PYTHON2:         $PYTHON2"
2995
2996 echo ""
2997 echo "        Run '${MAKE-make}' to build Mesa"
2998 echo ""