configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/gcc-plugin.m4)
  27 m4_include(config/ax_cxx_compile_stdcxx.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT(move-if-change)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty build-libcpp"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #f
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 145
 146 # these libraries are built for the target environment, and are built after
 147 # the host libraries and the host tools (which may be a cross compiler)
 148 # Note that libiberty is not a target library.
 149 target_libraries="target-libgcc \
 150                 target-libbacktrace \
 151                 target-libgloss \
 152                 target-newlib \
 153                 target-libgomp \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 251 # is provided.
 252 if test x$with_system_readline = xyes ; then
 253   noconfigdirs="$noconfigdirs readline"
 254 fi
 255
 256 AC_ARG_WITH(zstd,
 257 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 258
 259 # some tools are so dependent upon X11 that if we're not building with X,
 260 # it's not even worth trying to configure, much less build, that tool.
 261
 262 case ${with_x} in
 263   yes | "") ;; # the default value for this tree is that X11 is available
 264   no)
 265     skipdirs="${skipdirs} tk itcl libgui"
 266     # We won't be able to build gdbtk without X.
 267     enable_gdbtk=no
 268     ;;
 269   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 270 esac
 271
 272 # Some are only suitable for cross toolchains.
 273 # Remove these if host=target.
 274 cross_only="target-libgloss target-newlib target-opcodes"
 275
 276 case $is_cross_compiler in
 277   no) skipdirs="${skipdirs} ${cross_only}" ;;
 278 esac
 279
 280 # If both --with-headers and --with-libs are specified, default to
 281 # --without-newlib.
 282 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 283    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 284   if test x"${with_newlib}" = x ; then
 285     with_newlib=no
 286   fi
 287 fi
 288
 289 # Recognize --with-newlib/--without-newlib.
 290 case ${with_newlib} in
 291   no) skipdirs="${skipdirs} target-newlib" ;;
 292   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 293 esac
 294
 295 AC_ARG_ENABLE(as-accelerator-for,
 296 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 297                 [build as offload target compiler.
 298                 Specify offload host triple by ARG])])
 299
 300 AC_ARG_ENABLE(offload-targets,
 301 [AS_HELP_STRING([--enable-offload-targets=LIST],
 302                 [enable offloading to devices from comma-separated LIST of
 303                 TARGET[=DIR]. Use optional path to find offload target compiler
 304                 during the build])],
 305 [
 306   if test x"$enable_offload_targets" = x; then
 307     AC_MSG_ERROR([no offload targets specified])
 308   fi
 309 ], [enable_offload_targets=])
 310
 311 AC_ARG_ENABLE(offload-defaulted,
 312 [AS_HELP_STRING([--enable-offload-defaulted]
 313                 [If enabled, configured but not installed offload compilers and
 314                 libgomp plugins are silently ignored.  Useful for distribution
 315                 compilers where those are in separate optional packages.])],
 316 [enable_offload_defaulted=$enableval],
 317 [enable_offload_defaulted=])
 318
 319 # Handle --enable-gold, --enable-ld.
 320 # --disable-gold [--enable-ld]
 321 #     Build only ld.  Default option.
 322 # --enable-gold [--enable-ld]
 323 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 324 #     as "ld.bfd" and "ld".
 325 # --enable-gold=default [--enable-ld]
 326 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 327 #     install ld as "ld.bfd".
 328 # --enable-gold[=default] --disable-ld
 329 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 330 # --enable-gold --enable-ld=default
 331 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 332 #     and ld.bfd).
 333 #     In other words, ld is default
 334 # --enable-gold=default --enable-ld=default
 335 #     Error.
 336
 337 default_ld=
 338 AC_ARG_ENABLE(gold,
 339 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 340                 [build gold @<:@ARG={default,yes,no}@:>@])],
 341 ENABLE_GOLD=$enableval,
 342 ENABLE_GOLD=no)
 343 case "${ENABLE_GOLD}" in
 344   yes|default)
 345     # Check for ELF target.
 346     is_elf=no
 347     case "${target}" in
 348       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 349       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 350       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 351       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 352         case "${target}" in
 353           *-*-linux*aout* | *-*-linux*oldld*)
 354             ;;
 355           *)
 356             is_elf=yes
 357             ;;
 358         esac
 359     esac
 360
 361     if test "$is_elf" = "yes"; then
 362       # Check for target supported by gold.
 363       case "${target}" in
 364         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 365         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 366           configdirs="$configdirs gold"
 367           if test x${ENABLE_GOLD} = xdefault; then
 368             default_ld=gold
 369           fi
 370           ENABLE_GOLD=yes
 371           ;;
 372       esac
 373     fi
 374     ;;
 375   no)
 376     ;;
 377   *)
 378     AC_MSG_ERROR([invalid --enable-gold argument])
 379     ;;
 380 esac
 381
 382 AC_ARG_ENABLE(ld,
 383 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 384                 [build ld @<:@ARG={default,yes,no}@:>@])],
 385 ENABLE_LD=$enableval,
 386 ENABLE_LD=yes)
 387
 388 case "${ENABLE_LD}" in
 389   default)
 390     if test x${default_ld} != x; then
 391       AC_MSG_ERROR([either gold or ld can be the default ld])
 392     fi
 393     ;;
 394   yes)
 395     ;;
 396   no)
 397     if test x${ENABLE_GOLD} != xyes; then
 398       AC_MSG_WARN([neither ld nor gold are enabled])
 399     fi
 400     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 401     ;;
 402   *)
 403     AC_MSG_ERROR([invalid --enable-ld argument])
 404     ;;
 405 esac
 406
 407 AC_ARG_ENABLE(gprofng,
 408 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 409                 [build gprofng @<:@ARG={yes,no}@:>@])],
 410 enable_gprofng=$enableval,
 411 enable_gprofng=yes)
 412 if test "$enable_gprofng" = "yes"; then
 413   case "${target}" in
 414     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux*)
 415     configdirs="$configdirs gprofng"
 416     ;;
 417   esac
 418 fi
 419
 420
 421 # PR gas/19109
 422 # Decide the default method for compressing debug sections.
 423 # Provide a configure time option to override our default.
 424 AC_ARG_ENABLE(compressed_debug_sections,
 425 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 426                 [Enable compressed debug sections for gas, gold or ld by
 427                  default])],
 428 [
 429   if test x"$enable_compressed_debug_sections" = xyes; then
 430     AC_MSG_ERROR([no program with compressed debug sections specified])
 431   fi
 432 ], [enable_compressed_debug_sections=])
 433
 434 # Select default compression algorithm.
 435 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 436 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 437                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 438 [], [default_compressed_debug_sections_algorithm=])
 439
 440 # Configure extra directories which are host specific
 441
 442 case "${host}" in
 443   *-cygwin*)
 444     configdirs="$configdirs libtermcap" ;;
 445 esac
 446
 447 # A target can indicate whether a language isn't supported for some reason.
 448 # Only spaces may be used in this macro; not newlines or tabs.
 449 unsupported_languages=
 450
 451 # Remove more programs from consideration, based on the host or
 452 # target this usually means that a port of the program doesn't
 453 # exist yet.
 454
 455 case "${host}" in
 456   i[[3456789]]86-*-msdosdjgpp*)
 457     noconfigdirs="$noconfigdirs tcl tk itcl"
 458     ;;
 459 esac
 460
 461 # Default to --disable-year2038 until we can handle differences between
 462 # projects that use gnulib (which understands year 2038) and projects that
 463 # do not (like BFD).
 464 AC_ARG_ENABLE(year2038,
 465 AS_HELP_STRING([--enable-year2038],
 466   [enable support for timestamps past the year 2038]),
 467 ENABLE_YEAR2038=$enableval,
 468 ENABLE_YEAR2038=no)
 469 enable_year2038=
 470 if test "${ENABLE_YEAR2038}" = "no" ; then
 471   enable_year2038=no
 472 fi
 473
 474 AC_ARG_ENABLE(libquadmath,
 475 AS_HELP_STRING([--disable-libquadmath],
 476   [do not build libquadmath directory]),
 477 ENABLE_LIBQUADMATH=$enableval,
 478 ENABLE_LIBQUADMATH=yes)
 479 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 480   noconfigdirs="$noconfigdirs target-libquadmath"
 481 fi
 482
 483
 484 AC_ARG_ENABLE(libquadmath-support,
 485 AS_HELP_STRING([--disable-libquadmath-support],
 486   [disable libquadmath support for Fortran]),
 487 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 488 ENABLE_LIBQUADMATH_SUPPORT=yes)
 489 enable_libquadmath_support=
 490 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 491   enable_libquadmath_support=no
 492 fi
 493
 494
 495 AC_ARG_ENABLE(libada,
 496 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 497 ENABLE_LIBADA=$enableval,
 498 ENABLE_LIBADA=yes)
 499 if test "${ENABLE_LIBADA}" != "yes" ; then
 500   noconfigdirs="$noconfigdirs gnattools"
 501 fi
 502
 503 AC_ARG_ENABLE(libssp,
 504 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 505 ENABLE_LIBSSP=$enableval,
 506 ENABLE_LIBSSP=yes)
 507
 508 AC_ARG_ENABLE(libstdcxx,
 509 AS_HELP_STRING([--disable-libstdcxx],
 510   [do not build libstdc++-v3 directory]),
 511 ENABLE_LIBSTDCXX=$enableval,
 512 ENABLE_LIBSTDCXX=default)
 513 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 514   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 515 fi]
 516
 517 # Enable libgomp by default on hosted POSIX systems, and a few others.
 518 if test x$enable_libgomp = x ; then
 519     case "${target}" in
 520     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 521         ;;
 522     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 523         ;;
 524     *-*-solaris2* | *-*-hpux11*)
 525         ;;
 526     *-*-darwin* | *-*-aix*)
 527         ;;
 528     nvptx*-*-* | amdgcn*-*-*)
 529         ;;
 530     *)
 531         noconfigdirs="$noconfigdirs target-libgomp"
 532         ;;
 533     esac
 534 fi
 535
 536 # Disable libatomic on unsupported systems.
 537 if test -d ${srcdir}/libatomic; then
 538     if test x$enable_libatomic = x; then
 539         AC_MSG_CHECKING([for libatomic support])
 540         if (srcdir=${srcdir}/libatomic; \
 541                 . ${srcdir}/configure.tgt; \
 542                 test -n "$UNSUPPORTED")
 543         then
 544             AC_MSG_RESULT([no])
 545             noconfigdirs="$noconfigdirs target-libatomic"
 546         else
 547             AC_MSG_RESULT([yes])
 548         fi
 549     fi
 550 fi
 551
 552 # Disable libitm on unsupported systems.
 553 if test -d ${srcdir}/libitm; then
 554     if test x$enable_libitm = x; then
 555         AC_MSG_CHECKING([for libitm support])
 556         if (srcdir=${srcdir}/libitm; \
 557                 . ${srcdir}/configure.tgt; \
 558                 test -n "$UNSUPPORTED")
 559         then
 560             AC_MSG_RESULT([no])
 561             noconfigdirs="$noconfigdirs target-libitm"
 562         else
 563             AC_MSG_RESULT([yes])
 564         fi
 565     fi
 566 fi
 567
 568 # Disable libsanitizer on unsupported systems.
 569 if test -d ${srcdir}/libsanitizer; then
 570     if test x$enable_libsanitizer = x; then
 571         AC_MSG_CHECKING([for libsanitizer support])
 572         if (srcdir=${srcdir}/libsanitizer; \
 573                 . ${srcdir}/configure.tgt; \
 574                 test -n "$UNSUPPORTED")
 575         then
 576             AC_MSG_RESULT([no])
 577             noconfigdirs="$noconfigdirs target-libsanitizer"
 578         else
 579             AC_MSG_RESULT([yes])
 580         fi
 581     fi
 582 fi
 583
 584 # Disable libvtv on unsupported systems.
 585 if test -d ${srcdir}/libvtv; then
 586     if test x$enable_libvtv = x; then
 587         AC_MSG_CHECKING([for libvtv support])
 588         if (srcdir=${srcdir}/libvtv; \
 589                 . ${srcdir}/configure.tgt; \
 590                 test "$VTV_SUPPORTED" != "yes")
 591         then
 592             AC_MSG_RESULT([no])
 593             noconfigdirs="$noconfigdirs target-libvtv"
 594         else
 595             AC_MSG_RESULT([yes])
 596         fi
 597     fi
 598 fi
 599
 600 # Disable libquadmath for some systems.
 601 case "${target}" in
 602   avr-*-*)
 603     noconfigdirs="$noconfigdirs target-libquadmath"
 604     ;;
 605   # libquadmath is unused on AIX and libquadmath build process use of
 606   # LD_LIBRARY_PATH can break AIX bootstrap.
 607   powerpc-*-aix* | rs6000-*-aix*)
 608     noconfigdirs="$noconfigdirs target-libquadmath"
 609     ;;
 610 esac
 611
 612 # Disable libssp for some systems.
 613 case "${target}" in
 614   avr-*-*)
 615     # No hosted I/O support.
 616     noconfigdirs="$noconfigdirs target-libssp"
 617     ;;
 618   bpf-*-*)
 619     noconfigdirs="$noconfigdirs target-libssp"
 620     ;;
 621   powerpc-*-aix* | rs6000-*-aix*)
 622     noconfigdirs="$noconfigdirs target-libssp"
 623     ;;
 624   pru-*-*)
 625     # No hosted I/O support.
 626     noconfigdirs="$noconfigdirs target-libssp"
 627     ;;
 628   rl78-*-*)
 629     # libssp uses a misaligned load to trigger a fault, but the RL78
 630     # doesn't fault for those - instead, it gives a build-time error
 631     # for explicit misaligned loads.
 632     noconfigdirs="$noconfigdirs target-libssp"
 633     ;;
 634   visium-*-*)
 635     # No hosted I/O support.
 636     noconfigdirs="$noconfigdirs target-libssp"
 637     ;;
 638 esac
 639
 640 # Disable libstdc++-v3 for some systems.
 641 # Allow user to override this if they pass --enable-libstdcxx
 642 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 643   case "${target}" in
 644     *-*-vxworks*)
 645       # VxWorks uses the Dinkumware C++ library.
 646       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 647       ;;
 648     amdgcn*-*-*)
 649       # Not ported/fails to build when using newlib.
 650       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 651       ;;
 652     arm*-wince-pe*)
 653       # the C++ libraries don't build on top of CE's C libraries
 654       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 655       ;;
 656     avr-*-*)
 657       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 658       ;;
 659     bpf-*-*)
 660       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 661       ;;
 662     ft32-*-*)
 663       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 664       ;;
 665   esac
 666 fi
 667
 668 # Disable C++ on systems where it is known to not work.
 669 # For testing, you can override this with --enable-languages=c++.
 670 case ,${enable_languages}, in
 671   *,c++,*)
 672     ;;
 673   *)
 674       case "${target}" in
 675         bpf-*-*)
 676           unsupported_languages="$unsupported_languages c++"
 677           ;;
 678       esac
 679       ;;
 680 esac
 681
 682 # Disable Objc on systems where it is known to not work.
 683 # For testing, you can override this with --enable-languages=objc.
 684 case ,${enable_languages}, in
 685   *,objc,*)
 686     ;;
 687   *)
 688       case "${target}" in
 689         bpf-*-*)
 690           unsupported_languages="$unsupported_languages objc"
 691           ;;
 692       esac
 693       ;;
 694 esac
 695
 696 # Disable D on systems where it is known to not work.
 697 # For testing, you can override this with --enable-languages=d.
 698 case ,${enable_languages}, in
 699   *,d,*)
 700     ;;
 701   *)
 702     case "${target}" in
 703       bpf-*-*)
 704         unsupported_languages="$unsupported_languages d"
 705         ;;
 706     esac
 707     ;;
 708 esac
 709
 710 # Disable libphobos on unsupported systems.
 711 # For testing, you can override this with --enable-libphobos.
 712 if test -d ${srcdir}/libphobos; then
 713     if test x$enable_libphobos = x; then
 714         AC_MSG_CHECKING([for libphobos support])
 715         if (srcdir=${srcdir}/libphobos; \
 716                 . ${srcdir}/configure.tgt; \
 717                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 718         then
 719             AC_MSG_RESULT([no])
 720             noconfigdirs="$noconfigdirs target-libphobos"
 721         else
 722             AC_MSG_RESULT([yes])
 723         fi
 724     fi
 725 fi
 726
 727 # Disable Fortran for some systems.
 728 case "${target}" in
 729   mmix-*-*)
 730     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 731     unsupported_languages="$unsupported_languages fortran"
 732     ;;
 733   bpf-*-*)
 734     unsupported_languages="$unsupported_languages fortran"
 735     ;;
 736 esac
 737
 738 # Disable libffi for some systems.
 739 case "${target}" in
 740   powerpc-*-darwin*)
 741     ;;
 742   i[[3456789]]86-*-darwin*)
 743     ;;
 744   x86_64-*-darwin[[912]]*)
 745     ;;
 746   *-*-darwin*)
 747     noconfigdirs="$noconfigdirs target-libffi"
 748     ;;
 749   *-*-netware*)
 750     noconfigdirs="$noconfigdirs target-libffi"
 751     ;;
 752   *-*-phoenix*)
 753     noconfigdirs="$noconfigdirs target-libffi"
 754     ;;
 755   *-*-rtems*)
 756     noconfigdirs="$noconfigdirs target-libffi"
 757     ;;
 758   *-*-tpf*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   *-*-uclinux*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   *-*-vxworks*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   aarch64*-*-freebsd*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   alpha*-*-*vms*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   arm*-*-freebsd*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   arm-wince-pe)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   arm*-*-symbianelf*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   bpf-*-*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   cris-*-* | crisv32-*-*)
 786     case "${target}" in
 787       *-*-linux*)
 788         ;;
 789       *) # See PR46792 regarding target-libffi.
 790         noconfigdirs="$noconfigdirs target-libffi";;
 791     esac
 792     ;;
 793   hppa*64*-*-hpux*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   hppa*-hp-hpux11*)
 797     ;;
 798   hppa*-*-hpux*)
 799     noconfigdirs="$noconfigdirs target-libffi"
 800     ;;
 801   ia64*-*-*vms*)
 802     noconfigdirs="$noconfigdirs target-libffi"
 803     ;;
 804   i[[3456789]]86-w64-mingw*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   i[[3456789]]86-*-mingw*)
 808     noconfigdirs="$noconfigdirs target-libffi"
 809     ;;
 810   x86_64-*-mingw*)
 811     noconfigdirs="$noconfigdirs target-libffi"
 812     ;;
 813   mmix-*-*)
 814     noconfigdirs="$noconfigdirs target-libffi"
 815     ;;
 816   powerpc-*-aix*)
 817     ;;
 818   rs6000-*-aix*)
 819     ;;
 820   ft32-*-*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   *-*-lynxos*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826 esac
 827
 828 # Disable the go frontend on systems where it is known to not work. Please keep
 829 # this in sync with contrib/config-list.mk.
 830 case "${target}" in
 831 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 832     unsupported_languages="$unsupported_languages go"
 833     ;;
 834 esac
 835
 836 # Only allow gdbserver on some systems.
 837 if test -d ${srcdir}/gdbserver; then
 838     if test x$enable_gdbserver = x; then
 839         AC_MSG_CHECKING([for gdbserver support])
 840         if (srcdir=${srcdir}/gdbserver; \
 841                 . ${srcdir}/configure.srv; \
 842                 test -n "$UNSUPPORTED")
 843         then
 844             AC_MSG_RESULT([no])
 845             noconfigdirs="$noconfigdirs gdbserver"
 846         else
 847             AC_MSG_RESULT([yes])
 848         fi
 849     fi
 850 fi
 851
 852 # Disable libgo for some systems where it is known to not work.
 853 # For testing, you can easily override this with --enable-libgo.
 854 if test x$enable_libgo = x; then
 855     case "${target}" in
 856     *-*-darwin*)
 857         # PR 46986
 858         noconfigdirs="$noconfigdirs target-libgo"
 859         ;;
 860     *-*-cygwin* | *-*-mingw*)
 861         noconfigdirs="$noconfigdirs target-libgo"
 862         ;;
 863     bpf-*-*)
 864         noconfigdirs="$noconfigdirs target-libgo"
 865         ;;
 866     esac
 867 fi
 868
 869 # Default libgloss CPU subdirectory.
 870 libgloss_dir="$target_cpu"
 871
 872 case "${target}" in
 873   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 874     libgloss_dir=wince
 875     ;;
 876   aarch64*-*-* )
 877     libgloss_dir=aarch64
 878     ;;
 879   arm*-*-*)
 880     libgloss_dir=arm
 881     ;;
 882   cris-*-* | crisv32-*-*)
 883     libgloss_dir=cris
 884     ;;
 885   hppa*-*-*)
 886     libgloss_dir=pa
 887     ;;
 888   i[[3456789]]86-*-*)
 889     libgloss_dir=i386
 890     ;;
 891   loongarch*-*-*)
 892     libgloss_dir=loongarch
 893     ;;
 894   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 895     libgloss_dir=m68hc11
 896     ;;
 897   m68*-*-* | fido-*-*)
 898     libgloss_dir=m68k
 899     ;;
 900   mips*-*-*)
 901     libgloss_dir=mips
 902     ;;
 903   powerpc*-*-*)
 904     libgloss_dir=rs6000
 905     ;;
 906   pru-*-*)
 907     libgloss_dir=pru
 908     ;;
 909   sparc*-*-*)
 910     libgloss_dir=sparc
 911     ;;
 912 esac
 913
 914 # Disable newlib and libgloss for various target OSes.
 915 case "${target}" in
 916   alpha*-dec-osf*)
 917     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 918     ;;
 919   i[[3456789]]86-*-linux*)
 920     # This section makes it possible to build newlib natively on linux.
 921     # If we are using a cross compiler then don't configure newlib.
 922     if test x${is_cross_compiler} != xno ; then
 923       noconfigdirs="$noconfigdirs target-newlib"
 924     fi
 925     noconfigdirs="$noconfigdirs target-libgloss"
 926     # If we are not using a cross compiler, do configure newlib.
 927     # Note however, that newlib will only be configured in this situation
 928     # if the --with-newlib option has been given, because otherwise
 929     # 'target-newlib' will appear in skipdirs.
 930     ;;
 931   i[[3456789]]86-*-rdos*)
 932     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 933     ;;
 934   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 935     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 936     ;;
 937   sparc-*-sunos4*)
 938     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 939     ;;
 940   bpf-*-*)
 941     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 942     ;;
 943   *-*-aix*)
 944     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 945     ;;
 946   *-*-beos*)
 947     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 948     ;;
 949   *-*-chorusos)
 950     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 951     ;;
 952   *-*-dragonfly*)
 953     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     ;;
 955   *-*-freebsd*)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   *-*-lynxos*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   *-*-mingw*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-netbsd*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-netware*)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-tpf*)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-uclinux*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-vxworks*)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982 esac
 983
 984 case "${target}" in
 985   *-*-chorusos)
 986     ;;
 987   aarch64-*-darwin*)
 988     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 989     noconfigdirs="$noconfigdirs sim target-rda"
 990     ;;
 991   amdgcn*-*-*)
 992     ;;
 993   arm-*-darwin*)
 994     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 995     noconfigdirs="$noconfigdirs sim target-rda"
 996     ;;
 997   powerpc-*-darwin*)
 998     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 999     noconfigdirs="$noconfigdirs sim target-rda"
1000     ;;
1001   i[[3456789]]86-*-darwin*)
1002     noconfigdirs="$noconfigdirs ld gprof"
1003     noconfigdirs="$noconfigdirs sim target-rda"
1004     ;;
1005   x86_64-*-darwin[[912]]*)
1006     noconfigdirs="$noconfigdirs ld gas gprof"
1007     noconfigdirs="$noconfigdirs sim target-rda"
1008     ;;
1009   *-*-darwin*)
1010     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1011     noconfigdirs="$noconfigdirs sim target-rda"
1012     ;;
1013   *-*-dragonfly*)
1014     ;;
1015   *-*-freebsd*)
1016     if test "x$with_gmp" = x \
1017         && ! test -d ${srcdir}/gmp \
1018         && test -f /usr/local/include/gmp.h; then
1019       with_gmp=/usr/local
1020     fi
1021     ;;
1022   *-*-kaos*)
1023     # Remove unsupported stuff on all kaOS configurations.
1024     noconfigdirs="$noconfigdirs target-libgloss"
1025     ;;
1026   *-*-netbsd*)
1027     ;;
1028   *-*-netware*)
1029     ;;
1030   *-*-phoenix*)
1031     noconfigdirs="$noconfigdirs target-libgloss"
1032     ;;
1033   *-*-rtems*)
1034     noconfigdirs="$noconfigdirs target-libgloss"
1035     ;;
1036     # The tpf target doesn't support gdb yet.
1037   *-*-tpf*)
1038     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1039     ;;
1040   *-*-uclinux*)
1041     noconfigdirs="$noconfigdirs target-rda"
1042     ;;
1043   *-*-vxworks*)
1044     ;;
1045   alpha*-dec-osf*)
1046     # ld works, but does not support shared libraries.
1047     # gas doesn't generate exception information.
1048     noconfigdirs="$noconfigdirs gas ld"
1049     ;;
1050   alpha*-*-*vms*)
1051     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1052     ;;
1053   alpha*-*-*)
1054     # newlib is not 64 bit ready
1055     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1056     ;;
1057   bpf-*-*)
1058     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1059     ;;
1060   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1061     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1062     ;;
1063   arc*-*-*)
1064     noconfigdirs="$noconfigdirs sim"
1065     ;;
1066   arm-*-pe*)
1067     noconfigdirs="$noconfigdirs target-libgloss"
1068     ;;
1069   arm-*-riscix*)
1070     noconfigdirs="$noconfigdirs ld target-libgloss"
1071     ;;
1072   avr-*-*)
1073     if test x${with_avrlibc} != xno; then
1074       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1075     fi
1076     ;;
1077   c4x-*-* | tic4x-*-*)
1078     noconfigdirs="$noconfigdirs target-libgloss"
1079     ;;
1080   tic54x-*-*)
1081     noconfigdirs="$noconfigdirs target-libgloss gdb"
1082     ;;
1083   d10v-*-*)
1084     noconfigdirs="$noconfigdirs target-libgloss"
1085     ;;
1086   d30v-*-*)
1087     noconfigdirs="$noconfigdirs gdb"
1088     ;;
1089   fr30-*-elf*)
1090     noconfigdirs="$noconfigdirs gdb"
1091     ;;
1092   ft32-*-*)
1093     noconfigdirs="$noconfigdirs target-rda gprof"
1094     ;;
1095   moxie-*-*)
1096     noconfigdirs="$noconfigdirs"
1097     ;;
1098   h8300*-*-*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   h8500-*-*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1105     ;;
1106   hppa*64*-*-hpux*)
1107     noconfigdirs="$noconfigdirs gdb"
1108     ;;
1109   hppa*-*-hpux11*)
1110     noconfigdirs="$noconfigdirs gdb ld"
1111     ;;
1112   hppa*64*-*-linux*)
1113     ;;
1114   hppa*-*-linux*)
1115     ;;
1116   hppa*-*-*elf* | \
1117   hppa*-*-lites* | \
1118   hppa*-*-openbsd* | \
1119   hppa*64*-*-*)
1120     ;;
1121   hppa*-*-pro*)
1122     ;;
1123   hppa*-*-*)
1124     noconfigdirs="$noconfigdirs ld"
1125     ;;
1126   i960-*-*)
1127     noconfigdirs="$noconfigdirs gdb"
1128     ;;
1129   ia64*-*-elf*)
1130     # No gdb support yet.
1131     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1132     ;;
1133   ia64*-**-hpux*)
1134     # No ld support yet.
1135     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1136     ;;
1137   ia64*-*-*vms*)
1138     # No ld support yet.
1139     noconfigdirs="$noconfigdirs libgui itcl ld"
1140     ;;
1141   i[[3456789]]86-w64-mingw*)
1142     ;;
1143   i[[3456789]]86-*-mingw*)
1144     target_configdirs="$target_configdirs target-winsup"
1145     ;;
1146   *-*-cygwin*)
1147     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1148     noconfigdirs="$noconfigdirs target-libgloss"
1149     # always build newlib if winsup directory is present.
1150     if test -d "$srcdir/winsup/cygwin"; then
1151       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1152     elif test -d "$srcdir/newlib"; then
1153       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1154     fi
1155     ;;
1156   i[[3456789]]86-*-pe)
1157     noconfigdirs="$noconfigdirs target-libgloss"
1158     ;;
1159   i[[3456789]]86-*-sco3.2v5*)
1160     # The linker does not yet know about weak symbols in COFF,
1161     # and is not configured to handle mixed ELF and COFF.
1162     noconfigdirs="$noconfigdirs ld target-libgloss"
1163     ;;
1164   i[[3456789]]86-*-sco*)
1165     noconfigdirs="$noconfigdirs gprof target-libgloss"
1166     ;;
1167   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1168     noconfigdirs="$noconfigdirs target-libgloss"
1169     ;;
1170   i[[3456789]]86-*-sysv4*)
1171     noconfigdirs="$noconfigdirs target-libgloss"
1172     ;;
1173   i[[3456789]]86-*-beos*)
1174     noconfigdirs="$noconfigdirs gdb"
1175     ;;
1176   i[[3456789]]86-*-rdos*)
1177     noconfigdirs="$noconfigdirs gdb"
1178     ;;
1179   mmix-*-*)
1180     noconfigdirs="$noconfigdirs gdb"
1181     ;;
1182   mt-*-*)
1183     noconfigdirs="$noconfigdirs sim"
1184     ;;
1185   nfp-*-*)
1186     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1187     noconfigdirs="$noconfigdirs $target_libraries"
1188     ;;
1189   pdp11-*-*)
1190     noconfigdirs="$noconfigdirs gdb gprof"
1191     ;;
1192   powerpc-*-aix*)
1193     # copied from rs6000-*-* entry
1194     noconfigdirs="$noconfigdirs gprof"
1195     ;;
1196   powerpc*-*-winnt* | powerpc*-*-pe*)
1197     target_configdirs="$target_configdirs target-winsup"
1198     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1199     # always build newlib.
1200     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1201     ;;
1202     # This is temporary until we can link against shared libraries
1203   powerpcle-*-solaris*)
1204     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1205     ;;
1206   powerpc-*-beos*)
1207     noconfigdirs="$noconfigdirs gdb"
1208     ;;
1209   rs6000-*-lynxos*)
1210     noconfigdirs="$noconfigdirs gprof"
1211     ;;
1212   rs6000-*-aix*)
1213     noconfigdirs="$noconfigdirs gprof"
1214     ;;
1215   rs6000-*-*)
1216     noconfigdirs="$noconfigdirs gprof"
1217     ;;
1218   m68k-apollo-*)
1219     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1220     ;;
1221   microblaze*)
1222     noconfigdirs="$noconfigdirs gprof"
1223     ;;
1224   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1225     if test x$with_newlib = xyes; then
1226       noconfigdirs="$noconfigdirs gprof"
1227     fi
1228     ;;
1229   mips*-*-irix5*)
1230     noconfigdirs="$noconfigdirs gprof target-libgloss"
1231     ;;
1232   mips*-*-irix6*)
1233     noconfigdirs="$noconfigdirs gprof target-libgloss"
1234     ;;
1235   mips*-*-bsd*)
1236     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1237     ;;
1238   mips*-*-linux*)
1239     ;;
1240   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1241   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1242     noconfigdirs="$noconfigdirs ld gas gprof"
1243     ;;
1244   mips*-*-*)
1245     noconfigdirs="$noconfigdirs gprof"
1246     ;;
1247   nvptx*-*-*)
1248     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1249     ;;
1250   sh-*-*)
1251     case "${target}" in
1252       sh*-*-elf)
1253          ;;
1254       *)
1255          noconfigdirs="$noconfigdirs target-libgloss" ;;
1256     esac
1257     ;;
1258   sparc-*-sunos4*)
1259     if test x${is_cross_compiler} = xno ; then
1260            use_gnu_ld=no
1261     fi
1262     ;;
1263   tic6x-*-*)
1264     noconfigdirs="$noconfigdirs sim"
1265     ;;
1266   tilepro*-*-* | tilegx*-*-*)
1267     noconfigdirs="$noconfigdirs sim"
1268     ;;
1269   v810-*-*)
1270     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1271     ;;
1272   vax-*-*)
1273     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1274     ;;
1275   wasm32-*-*)
1276     noconfigdirs="$noconfigdirs ld"
1277     ;;
1278   loongarch*-*-linux*)
1279     ;;
1280   loongarch*-*-*)
1281     noconfigdirs="$noconfigdirs gprof"
1282     ;;
1283 esac
1284
1285 # If we aren't building newlib, then don't build libgloss, since libgloss
1286 # depends upon some newlib header files.
1287 case "${noconfigdirs}" in
1288   *target-libgloss*) ;;
1289   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1290 esac
1291
1292 # Work in distributions that contain no compiler tools, like Autoconf.
1293 host_makefile_frag=/dev/null
1294 if test -d ${srcdir}/config ; then
1295 case "${host}" in
1296   i[[3456789]]86-*-msdosdjgpp*)
1297     host_makefile_frag="config/mh-djgpp"
1298     ;;
1299   *-cygwin*)
1300     ACX_CHECK_CYGWIN_CAT_WORKS
1301     host_makefile_frag="config/mh-cygwin"
1302     ;;
1303   *-mingw*)
1304     host_makefile_frag="config/mh-mingw"
1305     ;;
1306   alpha*-linux*)
1307     host_makefile_frag="config/mh-alpha-linux"
1308     ;;
1309   hppa*-hp-hpux10*)
1310     host_makefile_frag="config/mh-pa-hpux10"
1311     ;;
1312   hppa*-hp-hpux*)
1313     host_makefile_frag="config/mh-pa"
1314     ;;
1315   hppa*-*)
1316     host_makefile_frag="config/mh-pa"
1317     ;;
1318   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1319     host_makefile_frag="config/mh-darwin"
1320     ;;
1321   powerpc-*-aix*)
1322     host_makefile_frag="config/mh-ppc-aix"
1323     ;;
1324   rs6000-*-aix*)
1325     host_makefile_frag="config/mh-ppc-aix"
1326     ;;
1327 esac
1328 fi
1329
1330 if test "${build}" != "${host}" ; then
1331   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1332   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1333   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1334   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1335   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1336   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1337   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1338   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1339   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1340   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1341   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1342   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1343   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1344   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1345   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1346 else
1347   AR_FOR_BUILD="\$(AR)"
1348   AS_FOR_BUILD="\$(AS)"
1349   CC_FOR_BUILD="\$(CC)"
1350   CXX_FOR_BUILD="\$(CXX)"
1351   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1352   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1353   GOC_FOR_BUILD="\$(GOC)"
1354   GDC_FOR_BUILD="\$(GDC)"
1355   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1356   LD_FOR_BUILD="\$(LD)"
1357   NM_FOR_BUILD="\$(NM)"
1358   RANLIB_FOR_BUILD="\$(RANLIB)"
1359   WINDRES_FOR_BUILD="\$(WINDRES)"
1360   WINDMC_FOR_BUILD="\$(WINDMC)"
1361 fi
1362
1363 AC_PROG_CC_C99
1364 AC_PROG_CXX
1365
1366 # We must set the default linker to the linker used by gcc for the correct
1367 # operation of libtool.  If LD is not defined and we are using gcc, try to
1368 # set the LD default to the ld used by gcc.
1369 if test -z "$LD"; then
1370   if test "$GCC" = yes; then
1371     case $build in
1372     *-*-mingw*)
1373       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1374     *)
1375       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1376     esac
1377     case $gcc_prog_ld in
1378     # Accept absolute paths.
1379     [[\\/]* | [A-Za-z]:[\\/]*)]
1380       LD="$gcc_prog_ld" ;;
1381     esac
1382   fi
1383 fi
1384
1385 # Check whether -static-libstdc++ -static-libgcc is supported.
1386 have_static_libs=no
1387 if test "$GCC" = yes; then
1388   saved_LDFLAGS="$LDFLAGS"
1389
1390   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1391   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1392   AC_LANG_PUSH(C++)
1393   AC_LINK_IFELSE([AC_LANG_SOURCE([
1394 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1395 #error -static-libstdc++ not implemented
1396 #endif
1397 int main() {}])],
1398     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1399     [AC_MSG_RESULT([no])])
1400   AC_LANG_POP(C++)
1401
1402   LDFLAGS="$saved_LDFLAGS"
1403 fi
1404
1405 ACX_PROG_GNAT
1406 ACX_PROG_GDC
1407 ACX_PROG_CMP_IGNORE_INITIAL
1408
1409 AC_ARG_ENABLE([bootstrap],
1410 [AS_HELP_STRING([--enable-bootstrap],
1411                 [enable bootstrapping @<:@yes if native build@:>@])],,
1412 enable_bootstrap=default)
1413
1414 # Issue errors and warnings for invalid/strange bootstrap combinations.
1415 if test -r $srcdir/gcc/configure; then
1416   have_compiler=yes
1417 else
1418   have_compiler=no
1419 fi
1420
1421 case "$have_compiler:$host:$target:$enable_bootstrap" in
1422   *:*:*:no) ;;
1423
1424   # Default behavior.  Enable bootstrap if we have a compiler
1425   # and we are in a native configuration.
1426   yes:$build:$build:default)
1427     enable_bootstrap=yes ;;
1428
1429   *:*:*:default)
1430     enable_bootstrap=no ;;
1431
1432   # We have a compiler and we are in a native configuration, bootstrap is ok
1433   yes:$build:$build:yes)
1434     ;;
1435
1436   # Other configurations, but we have a compiler.  Assume the user knows
1437   # what he's doing.
1438   yes:*:*:yes)
1439     AC_MSG_WARN([trying to bootstrap a cross compiler])
1440     ;;
1441
1442   # No compiler: if they passed --enable-bootstrap explicitly, fail
1443   no:*:*:yes)
1444     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1445
1446   # Fail if wrong command line
1447   *)
1448     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1449     ;;
1450 esac
1451
1452 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1453 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1454 # require C++11 (or higher).
1455 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1456   CXX="$CXX -std=c++11"
1457 elif test "$have_compiler" = yes; then
1458   AX_CXX_COMPILE_STDCXX(11)
1459
1460   if test "${build}" != "${host}"; then
1461     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1462   fi
1463 fi
1464
1465 AC_ARG_ENABLE([pgo-build],
1466 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1467                 [enable the PGO build])],
1468 [enable_pgo_build=$enableval],
1469 [enable_pgo_build=no])
1470
1471 # Issue errors and warnings for invalid/strange PGO build combinations.
1472 case "$have_compiler:$host:$target:$enable_pgo_build" in
1473   *:*:*:no) ;;
1474
1475   # Allow the PGO build only if we aren't building a compiler and
1476   # we are in a native configuration.
1477   no:$build:$build:yes | no:$build:$build:lto) ;;
1478
1479   # Disallow the PGO bootstrap if we are building a compiler.
1480   yes:*:*:yes | yes:*:*:lto)
1481     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1482
1483   *)
1484     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1485     ;;
1486 esac
1487
1488 if test "$enable_pgo_build" != "no"; then
1489   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1490   old_CFLAGS="$CFLAGS"
1491   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1492   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1493   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1494                     [PGO_BUILD_GEN_CFLAGS=])
1495   CFLAGS="$old_CFLAGS"
1496   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1497     AC_MSG_RESULT([yes])
1498     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1499   else
1500     AC_MSG_RESULT([no])
1501     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1502   fi
1503
1504   if test "$enable_pgo_build" = "lto"; then
1505     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1506     old_CFLAGS="$CFLAGS"
1507     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1508     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1509     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1510                       [PGO_BUILD_LTO_CFLAGS=])
1511     CFLAGS="$old_CFLAGS"
1512     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1513       AC_MSG_RESULT([yes])
1514     else
1515       AC_MSG_RESULT([no])
1516       AC_MSG_WARN([LTO is disabled for the PGO build])
1517     fi
1518   fi
1519 fi
1520 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1521 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1522 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1523
1524 # Used for setting $lt_cv_objdir
1525 _LT_CHECK_OBJDIR
1526
1527 # Check for GMP, MPFR and MPC
1528 require_gmp=no
1529 require_mpc=no
1530 if test -d ${srcdir}/gcc ; then
1531   require_gmp=yes
1532   require_mpc=yes
1533 fi
1534 if test -d ${srcdir}/gdb ; then
1535   if test "x$enable_gdb" != xno; then
1536    require_gmp=yes
1537   fi
1538 fi
1539
1540 gmplibs="-lmpfr -lgmp"
1541 if test x"$require_mpc" = "xyes" ; then
1542   gmplibs="-lmpc $gmplibs"
1543 fi
1544 gmpinc=
1545 have_gmp=no
1546
1547 # Specify a location for mpc
1548 # check for this first so it ends up on the link line before mpfr.
1549 AC_ARG_WITH(mpc,
1550 [AS_HELP_STRING([--with-mpc=PATH],
1551                 [specify prefix directory for installed MPC package.
1552                  Equivalent to --with-mpc-include=PATH/include
1553                  plus --with-mpc-lib=PATH/lib])])
1554 AC_ARG_WITH(mpc-include,
1555 [AS_HELP_STRING([--with-mpc-include=PATH],
1556                 [specify directory for installed MPC include files])])
1557 AC_ARG_WITH(mpc-lib,
1558 [AS_HELP_STRING([--with-mpc-lib=PATH],
1559                 [specify directory for the installed MPC library])])
1560
1561 if test "x$with_mpc" != x; then
1562   gmplibs="-L$with_mpc/lib $gmplibs"
1563   gmpinc="-I$with_mpc/include $gmpinc"
1564 fi
1565 if test "x$with_mpc_include" != x; then
1566   gmpinc="-I$with_mpc_include $gmpinc"
1567 fi
1568 if test "x$with_mpc_lib" != x; then
1569   gmplibs="-L$with_mpc_lib $gmplibs"
1570 fi
1571 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1572   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1573   gmpinc='-I$$s/mpc/src '"$gmpinc"
1574   # Do not test the mpc version.  Assume that it is sufficient, since
1575   # it is in the source tree, and the library has not been built yet
1576   # but it would be included on the link line in the version check below
1577   # hence making the test fail.
1578   have_gmp=yes
1579 fi
1580
1581 # Specify a location for mpfr
1582 # check for this first so it ends up on the link line before gmp.
1583 AC_ARG_WITH(mpfr,
1584 [AS_HELP_STRING([--with-mpfr=PATH],
1585                 [specify prefix directory for installed MPFR package.
1586                  Equivalent to --with-mpfr-include=PATH/include
1587                  plus --with-mpfr-lib=PATH/lib])])
1588 AC_ARG_WITH(mpfr-include,
1589 [AS_HELP_STRING([--with-mpfr-include=PATH],
1590                 [specify directory for installed MPFR include files])])
1591 AC_ARG_WITH(mpfr-lib,
1592 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1593                 [specify directory for the installed MPFR library])])
1594
1595 if test "x$with_mpfr" != x; then
1596   gmplibs="-L$with_mpfr/lib $gmplibs"
1597   gmpinc="-I$with_mpfr/include $gmpinc"
1598 fi
1599 if test "x$with_mpfr_include" != x; then
1600   gmpinc="-I$with_mpfr_include $gmpinc"
1601 fi
1602 if test "x$with_mpfr_lib" != x; then
1603   gmplibs="-L$with_mpfr_lib $gmplibs"
1604 fi
1605 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1606   # MPFR v3.1.0 moved the sources into a src sub-directory.
1607   if ! test -d ${srcdir}/mpfr/src; then
1608     AC_MSG_ERROR([dnl
1609 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1610   fi
1611   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1612   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1613   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1614   # Do not test the mpfr version.  Assume that it is sufficient, since
1615   # it is in the source tree, and the library has not been built yet
1616   # but it would be included on the link line in the version check below
1617   # hence making the test fail.
1618   have_gmp=yes
1619 fi
1620
1621 # Specify a location for gmp
1622 AC_ARG_WITH(gmp,
1623 [AS_HELP_STRING([--with-gmp=PATH],
1624                 [specify prefix directory for the installed GMP package.
1625                  Equivalent to --with-gmp-include=PATH/include
1626                  plus --with-gmp-lib=PATH/lib])])
1627 AC_ARG_WITH(gmp-include,
1628 [AS_HELP_STRING([--with-gmp-include=PATH],
1629                 [specify directory for installed GMP include files])])
1630 AC_ARG_WITH(gmp-lib,
1631 [AS_HELP_STRING([--with-gmp-lib=PATH],
1632                 [specify directory for the installed GMP library])])
1633
1634
1635 if test "x$with_gmp" != x; then
1636   gmplibs="-L$with_gmp/lib $gmplibs"
1637   gmpinc="-I$with_gmp/include $gmpinc"
1638 fi
1639 if test "x$with_gmp_include" != x; then
1640   gmpinc="-I$with_gmp_include $gmpinc"
1641 fi
1642 if test "x$with_gmp_lib" != x; then
1643   gmplibs="-L$with_gmp_lib $gmplibs"
1644 fi
1645 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1646   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1647   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1648   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1649   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1650   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1651   # Do not test the gmp version.  Assume that it is sufficient, since
1652   # it is in the source tree, and the library has not been built yet
1653   # but it would be included on the link line in the version check below
1654   # hence making the test fail.
1655   have_gmp=yes
1656 fi
1657
1658 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1659   have_gmp=yes
1660   saved_CFLAGS="$CFLAGS"
1661   CFLAGS="$CFLAGS $gmpinc"
1662   # Check for the recommended and required versions of GMP.
1663   AC_MSG_CHECKING([for the correct version of gmp.h])
1664   AC_TRY_COMPILE([#include "gmp.h"],[
1665   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1666   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1667   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1668   choke me
1669   #endif
1670   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1671   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1672   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1673   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1674   choke me
1675   #endif
1676   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1677    [AC_MSG_RESULT([no]); have_gmp=no])
1678
1679   # If we have GMP, check the MPFR version.
1680   if test x"$have_gmp" = xyes; then
1681     # Check for the recommended and required versions of MPFR.
1682     AC_MSG_CHECKING([for the correct version of mpfr.h])
1683     AC_TRY_COMPILE([#include <gmp.h>
1684     #include <mpfr.h>],[
1685     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1686     choke me
1687     #endif
1688     ], [AC_TRY_COMPILE([#include <gmp.h>
1689     #include <mpfr.h>],[
1690     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1691     choke me
1692     #endif
1693     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1694      [AC_MSG_RESULT([no]); have_gmp=no])
1695   fi
1696
1697   # Check for the MPC header version.
1698   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1699     # Check for the recommended and required versions of MPC.
1700     AC_MSG_CHECKING([for the correct version of mpc.h])
1701     AC_TRY_COMPILE([#include <mpc.h>],[
1702     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1703     choke me
1704     #endif
1705     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1706     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1707     choke me
1708     #endif
1709     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1710      [AC_MSG_RESULT([no]); have_gmp=no])
1711   fi
1712
1713   # Now check the MPFR library.
1714   if test x"$have_gmp" = xyes; then
1715     saved_LIBS="$LIBS"
1716     LIBS="$LIBS $gmplibs"
1717     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1718     AC_TRY_LINK([#include <mpfr.h>],[
1719     mpfr_t n;
1720     mpfr_t x;
1721     int t;
1722     mpfr_init (n);
1723     mpfr_init (x);
1724     mpfr_atan2 (n, n, x, MPFR_RNDN);
1725     mpfr_erfc (n, x, MPFR_RNDN);
1726     mpfr_subnormalize (x, t, MPFR_RNDN);
1727     mpfr_clear(n);
1728     mpfr_clear(x);
1729     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1730     LIBS="$saved_LIBS"
1731   fi
1732
1733   # Now check the MPC library
1734   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1735     saved_LIBS="$LIBS"
1736     LIBS="$LIBS $gmplibs"
1737     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1738     AC_TRY_LINK([#include <mpc.h>],[
1739     mpc_t c;
1740     mpc_init2 (c, 53);
1741     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1742     mpc_cosh (c, c, MPC_RNDNN);
1743     mpc_pow (c, c, c, MPC_RNDNN);
1744     mpc_acosh (c, c, MPC_RNDNN);
1745     mpc_clear (c);
1746     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1747     LIBS="$saved_LIBS"
1748   fi
1749
1750   CFLAGS="$saved_CFLAGS"
1751
1752 # The library versions listed in the error message below should match
1753 # the HARD-minimums enforced above.
1754   if test x$have_gmp != xyes; then
1755     if test -d ${srcdir}/gcc ; then
1756       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1757 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1758 their locations.  Source code for these libraries can be found at
1759 their respective hosting sites as well as at
1760 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1761 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1762 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1763 make sure that you have installed both the libraries and the header
1764 files.  They may be located in separate packages.])
1765     else
1766       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1767 Try the --with-gmp and/or --with-mpfr options to specify
1768 their locations.  If you obtained GMP and/or MPFR from a vendor
1769 distribution package, make sure that you have installed both the libraries
1770 and the header files.  They may be located in separate packages.])
1771     fi
1772   fi
1773 fi
1774
1775 # Flags needed for both GMP, MPFR and/or MPC.
1776 AC_SUBST(gmplibs)
1777 AC_SUBST(gmpinc)
1778 AC_SUBST(extra_mpfr_configure_flags)
1779 AC_SUBST(extra_mpc_gmp_configure_flags)
1780 AC_SUBST(extra_mpc_mpfr_configure_flags)
1781 AC_SUBST(extra_isl_gmp_configure_flags)
1782
1783 # Libraries to use for stage1 or when not bootstrapping.
1784 AC_ARG_WITH(stage1-libs,
1785 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1786 [if test "$withval" = "no" -o "$withval" = "yes"; then
1787    stage1_libs=
1788  else
1789    stage1_libs=$withval
1790  fi],
1791 [stage1_libs=])
1792 AC_SUBST(stage1_libs)
1793
1794 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1795 # default is yes if gcc is being built; no otherwise.  The reason for
1796 # this default is that gdb is sometimes linked against GNU Source
1797 # Highlight, which is a shared library that uses C++ exceptions.  In
1798 # this case, -static-libstdc++ will cause crashes.
1799 AC_ARG_WITH(static-standard-libraries,
1800 [AS_HELP_STRING([--with-static-standard-libraries],
1801                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1802 [], [with_static_standard_libraries=auto])
1803 if test "$with_static_standard_libraries" = auto; then
1804   with_static_standard_libraries=$have_compiler
1805 fi
1806
1807 # Linker flags to use for stage1 or when not bootstrapping.
1808 AC_ARG_WITH(stage1-ldflags,
1809 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1810 [if test "$withval" = "no" -o "$withval" = "yes"; then
1811    stage1_ldflags=
1812  else
1813    stage1_ldflags=$withval
1814  fi],
1815 [stage1_ldflags=
1816  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1817  # if supported.  But if the user explicitly specified the libraries to use,
1818  # trust that they are doing what they want.
1819  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1820      -a "$have_static_libs" = yes; then
1821    stage1_ldflags="-static-libstdc++ -static-libgcc"
1822  fi])
1823 AC_SUBST(stage1_ldflags)
1824
1825 # Libraries to use for stage2 and later builds.
1826 AC_ARG_WITH(boot-libs,
1827 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1828 [if test "$withval" = "no" -o "$withval" = "yes"; then
1829    poststage1_libs=
1830  else
1831    poststage1_libs=$withval
1832  fi],
1833 [poststage1_libs=])
1834 AC_SUBST(poststage1_libs)
1835
1836 # Linker flags to use for stage2 and later builds.
1837 AC_ARG_WITH(boot-ldflags,
1838 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1839                 [linker flags for stage2 and later])],
1840 [if test "$withval" = "no" -o "$withval" = "yes"; then
1841    poststage1_ldflags=
1842  else
1843    poststage1_ldflags=$withval
1844  fi],
1845 [poststage1_ldflags=
1846  # In stages 2 and 3, default to linking libstdc++ and libgcc
1847  # statically.  But if the user explicitly specified the libraries to
1848  # use, trust that they are doing what they want.
1849  if test "$poststage1_libs" = ""; then
1850    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1851  fi])
1852 AC_SUBST(poststage1_ldflags)
1853
1854 # GCC GRAPHITE dependency isl.
1855 # Basic setup is inlined here, actual checks are in config/isl.m4
1856
1857 AC_ARG_WITH(isl,
1858   [AS_HELP_STRING(
1859    [--with-isl=PATH],
1860    [Specify prefix directory for the installed isl package.
1861     Equivalent to --with-isl-include=PATH/include
1862     plus --with-isl-lib=PATH/lib])])
1863
1864 # Treat --without-isl as a request to disable
1865 # GRAPHITE support and skip all following checks.
1866 if test "x$with_isl" != "xno"; then
1867   # Check for isl
1868   dnl Provide configure switches and initialize islinc & isllibs
1869   dnl with user input.
1870   ISL_INIT_FLAGS
1871   dnl The versions of isl that work for Graphite
1872   ISL_CHECK_VERSION()
1873   dnl Only execute fail-action, if isl has been requested.
1874   ISL_IF_FAILED([
1875     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1876 fi
1877
1878 # If the isl check failed, disable builds of in-tree variant of isl
1879 if test "x$with_isl" = xno ||
1880    test "x$gcc_cv_isl" = xno; then
1881   noconfigdirs="$noconfigdirs isl"
1882   islinc=
1883 fi
1884
1885 AC_SUBST(isllibs)
1886 AC_SUBST(islinc)
1887
1888 # Check for LTO support.
1889 AC_ARG_ENABLE(lto,
1890 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1891 enable_lto=$enableval,
1892 enable_lto=yes; default_enable_lto=yes)
1893
1894 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1895   build_lto_plugin=yes
1896 ],[if test x"$default_enable_lto" = x"yes" ; then
1897     case $target in
1898       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1899       # On other non-ELF platforms, LTO has yet to be validated.
1900       *) enable_lto=no ;;
1901     esac
1902   else
1903   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1904   # It would also be nice to check the binutils support, but we don't
1905   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1906   # warn during gcc/ subconfigure; unless you're bootstrapping with
1907   # -flto it won't be needed until after installation anyway.
1908     case $target in
1909       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1910       *) if test x"$enable_lto" = x"yes"; then
1911         AC_MSG_ERROR([LTO support is not enabled for this target.])
1912         fi
1913       ;;
1914     esac
1915   fi
1916   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1917   # Build it unless LTO was explicitly disabled.
1918   case $target in
1919     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1920     *) ;;
1921   esac
1922 ])
1923
1924 AC_ARG_ENABLE(linker-plugin-configure-flags,
1925   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1926     [additional flags for configuring linker plugins @<:@none@:>@])],
1927   extra_linker_plugin_configure_flags=$enableval,
1928   extra_linker_plugin_configure_flags=)
1929 AC_SUBST(extra_linker_plugin_configure_flags)
1930 AC_ARG_ENABLE(linker-plugin-flags,
1931   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1932     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1933   extra_linker_plugin_flags=$enableval,
1934   extra_linker_plugin_flags=)
1935 AC_SUBST(extra_linker_plugin_flags)
1936
1937 # Handle --enable-host-pie
1938 # If host PIE executables are the default (or must be forced on) for some host,
1939 # we must pass that configuration to the gcc directory.
1940 gcc_host_pie=
1941 AC_ARG_ENABLE(host-pie,
1942 [AS_HELP_STRING([--enable-host-pie],
1943                 [build position independent host executables])],
1944 [host_pie=$enableval
1945  case $host in
1946    *-*-darwin2*)
1947      if test x$host_pie != xyes ; then
1948        # for Darwin20+ this is required.
1949        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
1950        host_pie=yes
1951        gcc_host_pie=--enable-host-pie
1952      fi ;;
1953   *) ;;
1954  esac],
1955 [case $host in
1956   *-*-darwin2*)
1957     # Default to PIE (mandatory for aarch64).
1958     host_pie=yes
1959     gcc_host_pie=--enable-host-pie
1960     ;;
1961   *) host_pie=no ;;
1962  esac])
1963
1964 AC_SUBST(host_pie)
1965 AC_SUBST(gcc_host_pie)
1966
1967 # Enable --enable-host-shared.
1968 # Checked early to determine whether jit is an 'all' language
1969 AC_ARG_ENABLE(host-shared,
1970 [AS_HELP_STRING([--enable-host-shared],
1971                 [build host code as shared libraries])],
1972 [host_shared=$enableval
1973  case $host in
1974    x86_64-*-darwin* | aarch64-*-darwin*)
1975      if test x$host_shared != xyes ; then
1976        # PIC is the default, and actually cannot be switched off.
1977        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
1978        host_shared=yes
1979      fi ;;
1980    *-*-darwin*)
1981      if test x$host_pie = xyes -a x$host_shared != xyes ; then
1982        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
1983        host_shared=yes
1984      fi ;;
1985   *) ;;
1986  esac],
1987 [case $host in
1988   # 64B x86_64 and Aarch64 Darwin default to PIC.
1989   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1990   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
1991   *-*-darwin*) host_shared=$host_pie ;;
1992   *) host_shared=no;;
1993  esac])
1994
1995 AC_SUBST(host_shared)
1996
1997 if test x$host_shared = xyes; then
1998   case $host in
1999     *-*-darwin*)
2000       # Since host shared is the default for 64b Darwin, and also enabled for
2001       # host_pie, ensure that we present the PIE flag when host_pie is active.
2002       if test x$host_pie = xyes; then
2003         PICFLAG=-fPIE
2004       fi
2005       ;;
2006     *)
2007       PICFLAG=-fPIC
2008       ;;
2009   esac
2010 elif test x$host_pie = xyes; then
2011   PICFLAG=-fPIE
2012 else
2013   PICFLAG=
2014 fi
2015
2016 AC_SUBST(PICFLAG)
2017
2018 # If we are building PIC/PIE host executables, and we are building dependent
2019 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2020 # code.
2021 host_libs_picflag=
2022 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2023 host_libs_picflag='--with-pic'
2024 fi
2025 AC_SUBST(host_libs_picflag)
2026
2027 # By default, C and C++ are the only stage 1 languages.
2028 stage1_languages=,c,
2029
2030 # Target libraries that we bootstrap.
2031 bootstrap_target_libs=,target-libgcc,
2032
2033 # Figure out what language subdirectories are present.
2034 # Look if the user specified --enable-languages="..."; if not, use
2035 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2036 # go away some day.
2037 # NB:  embedded tabs in this IF block -- do not untabify
2038 if test -d ${srcdir}/gcc; then
2039   if test x"${enable_languages+set}" != xset; then
2040     if test x"${LANGUAGES+set}" = xset; then
2041       enable_languages="${LANGUAGES}"
2042         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2043     else
2044       enable_languages=default
2045     fi
2046   else
2047     if test x"${enable_languages}" = x ||
2048        test x"${enable_languages}" = xyes;
2049        then
2050       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2051       exit 1
2052     fi
2053   fi
2054   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2055
2056   # 'f95' is the old name for the 'fortran' language. We issue a warning
2057   # and make the substitution.
2058   case ,${enable_languages}, in
2059     *,f95,*)
2060       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2061       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2062       ;;
2063   esac
2064
2065   # If bootstrapping, C++ must be enabled.
2066   case ",$enable_languages,:$enable_bootstrap" in
2067     *,c++,*:*) ;;
2068     *:yes)
2069       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2070         enable_languages="${enable_languages},c++"
2071       else
2072         AC_MSG_ERROR([bootstrapping requires c++ sources])
2073       fi
2074       ;;
2075   esac
2076
2077   # First scan to see if an enabled language requires some other language.
2078   # We assume that a given config-lang.in will list all the language
2079   # front ends it requires, even if some are required indirectly.
2080   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2081     case ${lang_frag} in
2082       ..) ;;
2083       # The odd quoting in the next line works around
2084       # an apparent bug in bash 1.12 on linux.
2085       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2086       *)
2087         # From the config-lang.in, get $language, $lang_requires, and
2088         # $lang_requires_boot_languages.
2089         language=
2090         lang_requires=
2091         lang_requires_boot_languages=
2092         # set srcdir during sourcing lang_frag to the gcc dir.
2093         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2094         # polutes this shell
2095         saved_srcdir=${srcdir}
2096         srcdir=${srcdir}/gcc . ${lang_frag}
2097         srcdir=${saved_srcdir}
2098         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2099           case ,${enable_languages}, in
2100             *,$other,*) ;;
2101             *,default,*) ;;
2102             *,all,*) ;;
2103             *,$language,*)
2104               echo " \`$other' language required by \`$language'; enabling" 1>&2
2105               enable_languages="${enable_languages},${other}"
2106               ;;
2107           esac
2108         done
2109         for other in ${lang_requires_boot_languages} ; do
2110           if test "$other" != "c"; then
2111             case ,${enable_stage1_languages}, in
2112               *,$other,*) ;;
2113               *,default,*) ;;
2114               *,all,*) ;;
2115               *)
2116                 case ,${enable_languages}, in
2117                   *,$language,*)
2118                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2119                     enable_stage1_languages="$enable_stage1_languages,${other}"
2120                     ;;
2121                 esac
2122                 ;;
2123             esac
2124           fi
2125         done
2126         ;;
2127     esac
2128   done
2129
2130   new_enable_languages=,c,
2131
2132   # If LTO is enabled, add the LTO front end.
2133   if test "$enable_lto" = "yes" ; then
2134     case ,${enable_languages}, in
2135       *,lto,*) ;;
2136       *) enable_languages="${enable_languages},lto" ;;
2137     esac
2138     if test "${build_lto_plugin}" = "yes" ; then
2139       configdirs="$configdirs lto-plugin"
2140     fi
2141   fi
2142
2143   # If we're building an offloading compiler, add the LTO front end.
2144   if test x"$enable_as_accelerator_for" != x ; then
2145     case ,${enable_languages}, in
2146       *,lto,*) ;;
2147       *) enable_languages="${enable_languages},lto" ;;
2148     esac
2149   fi
2150
2151   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2152   potential_languages=,c,
2153
2154   enabled_target_libs=
2155   disabled_target_libs=
2156
2157   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2158     case ${lang_frag} in
2159       ..) ;;
2160       # The odd quoting in the next line works around
2161       # an apparent bug in bash 1.12 on linux.
2162       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2163       *)
2164         # From the config-lang.in, get $language, $target_libs,
2165         # $lang_dirs, $boot_language, and $build_by_default
2166         language=
2167         target_libs=
2168         lang_dirs=
2169         subdir_requires=
2170         boot_language=no
2171         build_by_default=yes
2172         # set srcdir during sourcing.  See above about save & restore
2173         saved_srcdir=${srcdir}
2174         srcdir=${srcdir}/gcc . ${lang_frag}
2175         srcdir=${saved_srcdir}
2176         if test x${language} = x; then
2177           echo "${lang_frag} doesn't set \$language." 1>&2
2178           exit 1
2179         fi
2180
2181         if test "$language" = "c++"; then
2182           boot_language=yes
2183         fi
2184
2185         add_this_lang=no
2186         # C is always enabled, so no need to add it again
2187         if test "$language" != "c"; then
2188           case ,${enable_languages}, in
2189             *,${language},*)
2190               # Language was explicitly selected; include it
2191               add_this_lang=yes
2192               ;;
2193             *,all,*)
2194               # All languages are enabled
2195               add_this_lang=all
2196               ;;
2197             *,default,*)
2198               # 'default' was selected, select it if it is a default language
2199               add_this_lang=${build_by_default}
2200               ;;
2201           esac
2202         fi
2203
2204         # Disable languages that need other directories if these aren't available.
2205         for i in $subdir_requires; do
2206           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2207           case ${add_this_lang} in
2208             yes)
2209               # Specifically requested language; tell them.
2210               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2211               ;;
2212             all)
2213               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2214               add_this_lang=unsupported
2215               ;;
2216             *)
2217               # Silently disable.
2218               add_this_lang=unsupported
2219               ;;
2220           esac
2221         done
2222
2223         # Disable Ada if no preexisting GNAT is available.
2224         case ${add_this_lang}:${language}:${have_gnat} in
2225           yes:ada:no)
2226             # Specifically requested language; tell them.
2227             AC_MSG_ERROR([GNAT is required to build $language])
2228             ;;
2229           all:ada:no)
2230             AC_MSG_WARN([GNAT is required to build $language])
2231             add_this_lang=unsupported
2232             ;;
2233           *:ada:no)
2234             # Silently disable.
2235             add_this_lang=unsupported
2236             ;;
2237         esac
2238
2239         # Disable D if no preexisting GDC is available.
2240         case ${add_this_lang}:${language}:${have_gdc} in
2241           yes:d:no)
2242             # Specifically requested language; tell them.
2243             AC_MSG_ERROR([GDC is required to build $language])
2244            ;;
2245           all:d:no)
2246             AC_MSG_WARN([GDC is required to build $language])
2247             add_this_lang=unsupported
2248             ;;
2249           *:d:no)
2250             # Silently disable.
2251             add_this_lang=unsupported
2252             ;;
2253         esac
2254
2255         # Disable jit if -enable-host-shared not specified
2256         # but not if building for Mingw. All code in Windows
2257         # is position independent code (PIC).
2258         case $target in
2259           *mingw*) ;;
2260           *)
2261           case ${add_this_lang}:${language}:${host_shared} in
2262             yes:jit:no)
2263                    # PR jit/64780: explicitly specify --enable-host-shared
2264             AC_MSG_ERROR([
2265 Enabling language "jit" requires --enable-host-shared.
2266
2267 --enable-host-shared typically slows the rest of the compiler down by
2268 a few %, so you must explicitly enable it.
2269
2270 If you want to build both the jit and the regular compiler, it is often
2271 best to do this via two separate configure/builds, in separate
2272 directories, to avoid imposing the performance cost of
2273 --enable-host-shared on the regular compiler.])
2274                     ;;
2275             all:jit:no)
2276               AC_MSG_WARN([--enable-host-shared required to build $language])
2277               add_this_lang=unsupported
2278               ;;
2279             *:jit:no)
2280               # Silently disable.
2281               add_this_lang=unsupported
2282               ;;
2283                 esac
2284           ;;
2285         esac
2286
2287         # Disable a language that is unsupported by the target.
2288         case "${add_this_lang}: $unsupported_languages " in
2289           no:*) ;;
2290           unsupported:*) ;;
2291           *:*" $language "*)
2292             AC_MSG_WARN([${language} not supported for this target])
2293             add_this_lang=unsupported
2294             ;;
2295         esac
2296
2297         case $add_this_lang in
2298           unsupported)
2299             # Remove language-dependent dirs.
2300             disabled_target_libs="$disabled_target_libs $target_libs"
2301             noconfigdirs="$noconfigdirs $lang_dirs"
2302             ;;
2303           no)
2304             # Remove language-dependent dirs; still show language as supported.
2305             disabled_target_libs="$disabled_target_libs $target_libs"
2306             noconfigdirs="$noconfigdirs $lang_dirs"
2307             potential_languages="${potential_languages}${language},"
2308             ;;
2309           all|yes)
2310             new_enable_languages="${new_enable_languages}${language},"
2311             potential_languages="${potential_languages}${language},"
2312             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2313             enabled_target_libs="$enabled_target_libs $target_libs"
2314             case "${boot_language}:,$enable_stage1_languages," in
2315               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2316                 # Add to (comma-separated) list of stage 1 languages.
2317                 case ",$stage1_languages," in
2318                   *,$language,* | ,yes, | ,all,) ;;
2319                   *) stage1_languages="${stage1_languages}${language}," ;;
2320                 esac
2321                 # We need to bootstrap any supporting libraries.
2322                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2323                 ;;
2324             esac
2325             ;;
2326         esac
2327         ;;
2328     esac
2329   done
2330
2331   # Add target libraries which are only needed for disabled languages
2332   # to noconfigdirs.
2333   if test -n "$disabled_target_libs"; then
2334     for dir in $disabled_target_libs; do
2335       case " $enabled_target_libs " in
2336       *" ${dir} "*) ;;
2337       *) noconfigdirs="$noconfigdirs $dir" ;;
2338       esac
2339     done
2340   fi
2341
2342   AC_ARG_ENABLE(stage1-languages,
2343   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2344                   [choose additional languages to build during
2345                   stage1.  Mostly useful for compiler development])],
2346   [case ,${enable_stage1_languages}, in
2347     ,no,|,,)
2348       # Set it to something that will have no effect in the loop below
2349       enable_stage1_languages=c ;;
2350     ,yes,)
2351       enable_stage1_languages=`echo $new_enable_languages | \
2352         sed -e "s/^,//" -e "s/,$//" ` ;;
2353     *,all,*)
2354       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2355         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2356   esac
2357
2358   # Add "good" languages from enable_stage1_languages to stage1_languages,
2359   # while "bad" languages go in missing_languages.  Leave no duplicates.
2360   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2361     case $potential_languages in
2362       *,$i,*)
2363         case $stage1_languages in
2364           *,$i,*) ;;
2365           *) stage1_languages="$stage1_languages$i," ;;
2366         esac ;;
2367       *)
2368         case $missing_languages in
2369           *,$i,*) ;;
2370           *) missing_languages="$missing_languages$i," ;;
2371         esac ;;
2372      esac
2373   done])
2374
2375   # Remove leading/trailing commas that were added for simplicity
2376   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2377   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2378   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2379   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2380
2381   if test "x$missing_languages" != x; then
2382     AC_MSG_ERROR([
2383 The following requested languages could not be built: ${missing_languages}
2384 Supported languages are: ${potential_languages}])
2385   fi
2386   if test "x$new_enable_languages" != "x$enable_languages"; then
2387     echo The following languages will be built: ${new_enable_languages}
2388     enable_languages="$new_enable_languages"
2389   fi
2390
2391   AC_SUBST(stage1_languages)
2392   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2393 fi
2394
2395 # Handle --disable-<component> generically.
2396 for dir in $configdirs $build_configdirs $target_configdirs ; do
2397   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2398   varname=`echo $dirname | sed -e s/+/_/g`
2399   if eval test x\${enable_${varname}} "=" xno ; then
2400     noconfigdirs="$noconfigdirs $dir"
2401   fi
2402 done
2403
2404 # Check for Boehm's garbage collector
2405 AC_ARG_ENABLE(objc-gc,
2406 [AS_HELP_STRING([--enable-objc-gc],
2407                 [enable use of Boehm's garbage collector with the
2408                  GNU Objective-C runtime])])
2409 AC_ARG_WITH([target-bdw-gc],
2410 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2411                 [specify prefix directory for installed bdw-gc package.
2412                  Equivalent to --with-target-bdw-gc-include=PATH/include
2413                  plus --with-target-bdw-gc-lib=PATH/lib])])
2414 AC_ARG_WITH([target-bdw-gc-include],
2415 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2416                 [specify directories for installed bdw-gc include files])])
2417 AC_ARG_WITH([target-bdw-gc-lib],
2418 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2419                 [specify directories for installed bdw-gc library])])
2420
2421 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2422   AC_MSG_CHECKING([for bdw garbage collector])
2423   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2424     dnl no bdw-gw options, assume default locations
2425     AC_MSG_RESULT([using bdw-gc in default locations])
2426   else
2427     dnl bdw-gw options, first error checking, complete checking in libobjc
2428     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2429       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2430     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2431       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2432     else
2433       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2434     fi
2435   fi
2436 esac
2437
2438 # Disable libitm, libsanitizer, libvtv if we're not building C++
2439 case ,${enable_languages}, in
2440   *,c++,*)
2441     # Disable libitm, libsanitizer if we're not building libstdc++
2442     case "${noconfigdirs}" in
2443       *target-libstdc++-v3*)
2444         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2445         ;;
2446       *) ;;
2447     esac
2448     ;;
2449   *)
2450     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2451     ;;
2452 esac
2453
2454 # If gcc/ is not in the source tree then we'll not be building a
2455 # target compiler, assume in that case we don't want to build any
2456 # target libraries or tools.
2457 #
2458 # This was added primarily for the benefit for binutils-gdb who reuse
2459 # this configure script, but don't always have target tools available.
2460 if test ! -d ${srcdir}/gcc; then
2461    skipdirs="${skipdirs} ${target_configdirs}"
2462 fi
2463
2464 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2465 # $build_configdirs and $target_configdirs.
2466 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2467
2468 notsupp=""
2469 for dir in . $skipdirs $noconfigdirs ; do
2470   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2471   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2472     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2473     if test -r $srcdir/$dirname/configure ; then
2474       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2475         true
2476       else
2477         notsupp="$notsupp $dir"
2478       fi
2479     fi
2480   fi
2481   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2482     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2483     if test -r $srcdir/$dirname/configure ; then
2484       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2485         true
2486       else
2487         notsupp="$notsupp $dir"
2488       fi
2489     fi
2490   fi
2491   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2492     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2493     if test -r $srcdir/$dirname/configure ; then
2494       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2495         true
2496       else
2497         notsupp="$notsupp $dir"
2498       fi
2499     fi
2500   fi
2501 done
2502
2503 # Quietly strip out all directories which aren't configurable in this tree.
2504 # This relies on all configurable subdirectories being autoconfiscated, which
2505 # is now the case.
2506 build_configdirs_all="$build_configdirs"
2507 build_configdirs=
2508 for i in ${build_configdirs_all} ; do
2509   j=`echo $i | sed -e s/build-//g`
2510   if test -f ${srcdir}/$j/configure ; then
2511     build_configdirs="${build_configdirs} $i"
2512   fi
2513 done
2514
2515 configdirs_all="$configdirs"
2516 configdirs=
2517 for i in ${configdirs_all} ; do
2518   if test -f ${srcdir}/$i/configure ; then
2519     configdirs="${configdirs} $i"
2520   fi
2521 done
2522
2523 target_configdirs_all="$target_configdirs"
2524 target_configdirs=
2525 for i in ${target_configdirs_all} ; do
2526   j=`echo $i | sed -e s/target-//g`
2527   if test -f ${srcdir}/$j/configure ; then
2528     target_configdirs="${target_configdirs} $i"
2529   fi
2530 done
2531
2532 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2533 # so we have to add it after the preceding checks.
2534 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2535 then
2536   case " $configdirs " in
2537     *" libiberty "*)
2538       # If we can build libiberty, we can also build libiberty-linker-plugin.
2539       configdirs="$configdirs libiberty-linker-plugin"
2540       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2541         --with-libiberty=../libiberty-linker-plugin";;
2542     *)
2543       AC_MSG_ERROR([libiberty missing]);;
2544   esac
2545 fi
2546
2547 # Sometimes we have special requirements for the host libiberty.
2548 extra_host_libiberty_configure_flags=
2549 case " $configdirs " in
2550   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2551     # When these are to be built as shared libraries, the same applies to
2552     # libiberty.
2553     extra_host_libiberty_configure_flags=--enable-shared
2554     ;;
2555 esac
2556 AC_SUBST(extra_host_libiberty_configure_flags)
2557
2558 # Sometimes we have special requirements for the host zlib.
2559 extra_host_zlib_configure_flags=
2560 case " $configdirs " in
2561   *" bfd "*)
2562     # When bfd is to be built as a shared library, the same applies to
2563     # zlib.
2564     if test "$enable_shared" = "yes"; then
2565       extra_host_zlib_configure_flags=--enable-host-shared
2566     fi
2567     ;;
2568 esac
2569 AC_SUBST(extra_host_zlib_configure_flags)
2570
2571 # Produce a warning message for the subdirs we can't configure.
2572 # This isn't especially interesting in the Cygnus tree, but in the individual
2573 # FSF releases, it's important to let people know when their machine isn't
2574 # supported by the one or two programs in a package.
2575
2576 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2577   # If $appdirs is non-empty, at least one of those directories must still
2578   # be configured, or we error out.  (E.g., if the gas release supports a
2579   # specified target in some subdirs but not the gas subdir, we shouldn't
2580   # pretend that all is well.)
2581   if test -n "$appdirs" ; then
2582     for dir in $appdirs ; do
2583       if test -r $dir/Makefile.in ; then
2584         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2585           appdirs=""
2586           break
2587         fi
2588         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2589           appdirs=""
2590           break
2591         fi
2592       fi
2593     done
2594     if test -n "$appdirs" ; then
2595       echo "*** This configuration is not supported by this package." 1>&2
2596       exit 1
2597     fi
2598   fi
2599   # Okay, some application will build, or we don't care to check.  Still
2600   # notify of subdirs not getting built.
2601   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2602   echo "    ${notsupp}" 1>&2
2603   echo "    (Any other directories should still work fine.)" 1>&2
2604 fi
2605
2606 case "$host" in
2607   *msdosdjgpp*)
2608     enable_gdbtk=no ;;
2609 esac
2610
2611 # To find our prefix, in gcc_cv_tool_prefix.
2612 ACX_TOOL_DIRS
2613
2614 copy_dirs=
2615
2616 AC_ARG_WITH([build-sysroot],
2617   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2618                   [use sysroot as the system root during the build])],
2619   [if test x"$withval" != x ; then
2620      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2621    fi],
2622   [SYSROOT_CFLAGS_FOR_TARGET=])
2623 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2624
2625 AC_ARG_WITH([debug-prefix-map],
2626   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2627                   [map A to B, C to D ... in debug information])],
2628   [if test x"$withval" != x; then
2629      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2630      for debug_map in $withval; do
2631        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2632      done
2633    fi],
2634   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2635 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2636
2637 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2638 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2639 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2640 # We want to ensure that TARGET libraries (which we know are built with
2641 # gcc) are built with "-O2 -g", so include those options when setting
2642 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2643 if test "x$CFLAGS_FOR_TARGET" = x; then
2644   if test "x${is_cross_compiler}" = xyes; then
2645     CFLAGS_FOR_TARGET="-g -O2"
2646   else
2647     CFLAGS_FOR_TARGET=$CFLAGS
2648     case " $CFLAGS " in
2649       *" -O2 "*) ;;
2650       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2651     esac
2652     case " $CFLAGS " in
2653       *" -g "* | *" -g3 "*) ;;
2654       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2655     esac
2656   fi
2657 fi
2658 AC_SUBST(CFLAGS_FOR_TARGET)
2659
2660 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2661   if test "x${is_cross_compiler}" = xyes; then
2662     CXXFLAGS_FOR_TARGET="-g -O2"
2663   else
2664     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2665     case " $CXXFLAGS " in
2666       *" -O2 "*) ;;
2667       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2668     esac
2669     case " $CXXFLAGS " in
2670       *" -g "* | *" -g3 "*) ;;
2671       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2672     esac
2673   fi
2674 fi
2675 AC_SUBST(CXXFLAGS_FOR_TARGET)
2676
2677 AC_SUBST(LDFLAGS_FOR_TARGET)
2678
2679 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2680 # the named directory are copied to $(tooldir)/sys-include.
2681 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2682   if test x${is_cross_compiler} = xno ; then
2683     echo 1>&2 '***' --with-headers is only supported when cross compiling
2684     exit 1
2685   fi
2686   if test x"${with_headers}" != xyes ; then
2687     x=${gcc_cv_tool_prefix}
2688     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2689   fi
2690 fi
2691
2692 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2693 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2694 # are permitted.
2695 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2696   if test x${is_cross_compiler} = xno ; then
2697     echo 1>&2 '***' --with-libs is only supported when cross compiling
2698     exit 1
2699   fi
2700   if test x"${with_libs}" != xyes ; then
2701     # Copy the libraries in reverse order, so that files in the first named
2702     # library override files in subsequent libraries.
2703     x=${gcc_cv_tool_prefix}
2704     for l in ${with_libs}; do
2705       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2706     done
2707   fi
2708 fi
2709
2710 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2711 #
2712 # This is done by determining whether or not the appropriate directory
2713 # is available, and by checking whether or not specific configurations
2714 # have requested that this magic not happen.
2715 #
2716 # The command line options always override the explicit settings in
2717 # configure.ac, and the settings in configure.ac override this magic.
2718 #
2719 # If the default for a toolchain is to use GNU as and ld, and you don't
2720 # want to do that, then you should use the --without-gnu-as and
2721 # --without-gnu-ld options for the configure script.  Similarly, if
2722 # the default is to use the included zlib and you don't want to do that,
2723 # you should use the --with-system-zlib option for the configure script.
2724
2725 if test x${use_gnu_as} = x &&
2726    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2727   with_gnu_as=yes
2728   extra_host_args="$extra_host_args --with-gnu-as"
2729 fi
2730
2731 if test x${use_gnu_ld} = x &&
2732    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2733   with_gnu_ld=yes
2734   extra_host_args="$extra_host_args --with-gnu-ld"
2735 fi
2736
2737 if test x${use_included_zlib} = x &&
2738    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2739   :
2740 else
2741   with_system_zlib=yes
2742   extra_host_args="$extra_host_args --with-system-zlib"
2743 fi
2744
2745 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2746 # can detect this case.
2747
2748 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2749   with_newlib=yes
2750   extra_host_args="$extra_host_args --with-newlib"
2751 fi
2752
2753 # Handle ${copy_dirs}
2754 set fnord ${copy_dirs}
2755 shift
2756 while test $# != 0 ; do
2757   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2758     :
2759   else
2760     echo Copying $1 to $2
2761
2762     # Use the install script to create the directory and all required
2763     # parent directories.
2764     if test -d $2 ; then
2765       :
2766     else
2767       echo >config.temp
2768       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2769     fi
2770
2771     # Copy the directory, assuming we have tar.
2772     # FIXME: Should we use B in the second tar?  Not all systems support it.
2773     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2774
2775     # It is the responsibility of the user to correctly adjust all
2776     # symlinks.  If somebody can figure out how to handle them correctly
2777     # here, feel free to add the code.
2778
2779     echo $1 > $2/COPIED
2780   fi
2781   shift; shift
2782 done
2783
2784 # Determine a target-dependent exec_prefix that the installed
2785 # gcc will search in.  Keep this list sorted by triplet, with
2786 # the *-*-osname triplets last.
2787 md_exec_prefix=
2788 case "${target}" in
2789   i[[34567]]86-pc-msdosdjgpp*)
2790     md_exec_prefix=/dev/env/DJDIR/bin
2791     ;;
2792   *-*-hpux* | \
2793   *-*-nto-qnx* | \
2794   *-*-solaris2*)
2795     md_exec_prefix=/usr/ccs/bin
2796     ;;
2797 esac
2798
2799 extra_arflags_for_target=
2800 extra_nmflags_for_target=
2801 extra_ranlibflags_for_target=
2802 target_makefile_frag=/dev/null
2803 case "${target}" in
2804   spu-*-*)
2805     target_makefile_frag="config/mt-spu"
2806     ;;
2807   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2808     target_makefile_frag="config/mt-sde"
2809     ;;
2810   mipsisa*-*-elfoabi*)
2811     target_makefile_frag="config/mt-mips-elfoabi"
2812     ;;
2813   mips*-*-*linux* | mips*-*-gnu*)
2814     target_makefile_frag="config/mt-mips-gnu"
2815     ;;
2816   nios2-*-elf*)
2817     target_makefile_frag="config/mt-nios2-elf"
2818     ;;
2819   *-*-linux-android*)
2820     target_makefile_frag="config/mt-android"
2821     ;;
2822   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2823     target_makefile_frag="config/mt-gnu"
2824     ;;
2825   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2826     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2827     # commands to handle both 32-bit and 64-bit objects.  These flags are
2828     # harmless if we're using GNU nm or ar.
2829     extra_arflags_for_target=" -X32_64"
2830     extra_nmflags_for_target=" -B -X32_64"
2831     ;;
2832 esac
2833
2834 alphaieee_frag=/dev/null
2835 case $target in
2836   alpha*-*-*)
2837     # This just makes sure to use the -mieee option to build target libs.
2838     # This should probably be set individually by each library.
2839     alphaieee_frag="config/mt-alphaieee"
2840     ;;
2841 esac
2842
2843 # If --enable-target-optspace always use -Os instead of -O2 to build
2844 # the target libraries, similarly if it is not specified, use -Os
2845 # on selected platforms.
2846 ospace_frag=/dev/null
2847 case "${enable_target_optspace}:${target}" in
2848   yes:*)
2849     ospace_frag="config/mt-ospace"
2850     ;;
2851   :d30v-*)
2852     ospace_frag="config/mt-d30v"
2853     ;;
2854   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2855     ospace_frag="config/mt-ospace"
2856     ;;
2857   no:* | :*)
2858     ;;
2859   *)
2860     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2861     ;;
2862 esac
2863
2864 # Some systems (e.g., one of the i386-aix systems the gas testers are
2865 # using) don't handle "\$" correctly, so don't use it here.
2866 tooldir='${exec_prefix}'/${target_noncanonical}
2867 build_tooldir=${tooldir}
2868
2869 # Create a .gdbinit file which runs the one in srcdir
2870 # and tells GDB to look there for source files.
2871
2872 if test -r ${srcdir}/.gdbinit ; then
2873   case ${srcdir} in
2874     .) ;;
2875     *) cat > ./.gdbinit <<EOF
2876 # ${NO_EDIT}
2877 dir ${srcdir}
2878 dir .
2879 source ${srcdir}/.gdbinit
2880 EOF
2881     ;;
2882   esac
2883 fi
2884
2885 # Make sure that the compiler is able to generate an executable.  If it
2886 # can't, we are probably in trouble.  We don't care whether we can run the
2887 # executable--we might be using a cross compiler--we only care whether it
2888 # can be created.  At this point the main configure script has set CC.
2889 we_are_ok=no
2890 echo "int main () { return 0; }" > conftest.c
2891 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2892 if test $? = 0 ; then
2893   if test -s conftest || test -s conftest.exe ; then
2894     we_are_ok=yes
2895   fi
2896 fi
2897 case $we_are_ok in
2898   no)
2899     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2900     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2901     rm -f conftest*
2902     exit 1
2903     ;;
2904 esac
2905 rm -f conftest*
2906
2907 # Decide which environment variable is used to find dynamic libraries.
2908 case "${host}" in
2909   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2910   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2911   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2912   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2913 esac
2914
2915 # On systems where the dynamic library environment variable is PATH,
2916 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2917 # built executables to PATH.
2918 if test "$RPATH_ENVVAR" = PATH; then
2919   GCC_SHLIB_SUBDIR=/shlib
2920 else
2921   GCC_SHLIB_SUBDIR=
2922 fi
2923
2924 # Adjust the toplevel makefile according to whether bootstrap was selected.
2925 case $enable_bootstrap in
2926   yes)
2927     bootstrap_suffix=bootstrap
2928     BUILD_CONFIG=bootstrap-debug
2929     ;;
2930   no)
2931     bootstrap_suffix=no-bootstrap
2932     BUILD_CONFIG=
2933     ;;
2934 esac
2935
2936 AC_MSG_CHECKING(for default BUILD_CONFIG)
2937
2938 AC_ARG_WITH([build-config],
2939   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2940                   [use config/NAME.mk build configuration])],
2941   [case $with_build_config in
2942    yes) with_build_config= ;;
2943    no) with_build_config= BUILD_CONFIG= ;;
2944    esac])
2945
2946 if test "x${with_build_config}" != x; then
2947   BUILD_CONFIG=$with_build_config
2948 else
2949   case $BUILD_CONFIG in
2950   bootstrap-debug)
2951     if echo "int f (void) { return 0; }" > conftest.c &&
2952        ${CC} -c conftest.c &&
2953        mv conftest.o conftest.o.g0 &&
2954        ${CC} -c -g conftest.c &&
2955        mv conftest.o conftest.o.g &&
2956        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2957       :
2958     else
2959       BUILD_CONFIG=
2960     fi
2961     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2962     ;;
2963   esac
2964 fi
2965 AC_MSG_RESULT($BUILD_CONFIG)
2966 AC_SUBST(BUILD_CONFIG)
2967
2968 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2969 AC_MSG_CHECKING([for --enable-vtable-verify])
2970 AC_ARG_ENABLE(vtable-verify,
2971 [AS_HELP_STRING([--enable-vtable-verify],
2972                 [Enable vtable verification feature])],
2973 [case "$enableval" in
2974  yes) enable_vtable_verify=yes ;;
2975  no)  enable_vtable_verify=no ;;
2976  *)   enable_vtable_verify=no;;
2977  esac],
2978 [enable_vtable_verify=no])
2979 AC_MSG_RESULT($enable_vtable_verify)
2980
2981 # Record target_configdirs and the configure arguments for target and
2982 # build configuration in Makefile.
2983 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2984 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2985 bootstrap_fixincludes=no
2986
2987 # If we are building libgomp, bootstrap it.
2988 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2989   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2990 fi
2991
2992 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2993 # or bootstrap-ubsan, bootstrap it.
2994 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2995   case "$BUILD_CONFIG" in
2996     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2997       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2998       bootstrap_fixincludes=yes
2999       ;;
3000   esac
3001 fi
3002
3003 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3004 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3005    test "$enable_vtable_verify" != no; then
3006   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3007 fi
3008
3009 # If we are building libatomic and the list of enabled languages includes the
3010 # D frontend, bootstrap it.
3011 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3012   case ,${enable_languages}, in
3013     *,d,*)
3014       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3015       ;;
3016   esac
3017 fi
3018
3019 # Determine whether gdb needs tk/tcl or not.
3020 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3021 # and in that case we want gdb to be built without tk.  Ugh!
3022 # In fact I believe gdb is the *only* package directly dependent on tk,
3023 # so we should be able to put the 'maybe's in unconditionally and
3024 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3025 # 100% sure that that's safe though.
3026
3027 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3028 case "$enable_gdbtk" in
3029   no)
3030     GDB_TK="" ;;
3031   yes)
3032     GDB_TK="${gdb_tk}" ;;
3033   *)
3034     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3035     # distro.  Eventually someone will fix this and move Insight, nee
3036     # gdbtk to a separate directory.
3037     if test -d ${srcdir}/gdb/gdbtk ; then
3038       GDB_TK="${gdb_tk}"
3039     else
3040       GDB_TK=""
3041     fi
3042     ;;
3043 esac
3044 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3045 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3046
3047 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3048 # else does, only include them if one of these is built.  The Makefile
3049 # provides the ordering, so it's enough here to add to the list.
3050 case " ${configdirs} " in
3051   *\ gdb\ *)
3052     configdirs="${configdirs} gnulib gdbsupport"
3053     ;;
3054   *\ gdbserver\ *)
3055     configdirs="${configdirs} gnulib gdbsupport"
3056     ;;
3057   *\ sim\ *)
3058     configdirs="${configdirs} gnulib"
3059     ;;
3060 esac
3061
3062 # Strip out unwanted targets.
3063
3064 # While at that, we remove Makefiles if we were started for recursive
3065 # configuration, so that the top-level Makefile reconfigures them,
3066 # like we used to do when configure itself was recursive.
3067
3068 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3069 # but now we're fixing up the Makefile ourselves with the additional
3070 # commands passed to AC_CONFIG_FILES.  Use separate variables
3071 # extrasub-{build,host,target} not because there is any reason to split
3072 # the substitutions up that way, but only to remain below the limit of
3073 # 99 commands in a script, for HP-UX sed.
3074
3075 # Do not nest @if/@endif or @unless/@endunless pairs, because
3076 # configure will not warn you at all.
3077
3078 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3079   yes:yes:*\ gold\ *:*,c++,*) ;;
3080   yes:yes:*\ gold\ *:*)
3081     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3082     ;;
3083 esac
3084
3085 extrasub_build=
3086 for module in ${build_configdirs} ; do
3087   if test -z "${no_recursion}" \
3088      && test -f ${build_subdir}/${module}/Makefile; then
3089     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3090     rm -f ${build_subdir}/${module}/Makefile
3091   fi
3092   extrasub_build="$extrasub_build
3093 /^@if build-$module\$/d
3094 /^@endif build-$module\$/d
3095 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3096 /^@if build-$module-$bootstrap_suffix\$/d
3097 /^@endif build-$module-$bootstrap_suffix\$/d
3098 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3099 done
3100 extrasub_host=
3101 for module in ${configdirs} ; do
3102   if test -z "${no_recursion}"; then
3103     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3104       if test -f ${file}; then
3105         echo 1>&2 "*** removing ${file} to force reconfigure"
3106         rm -f ${file}
3107       fi
3108     done
3109   fi
3110   case ${module},${bootstrap_fixincludes} in
3111     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3112     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3113   esac
3114   extrasub_host="$extrasub_host
3115 /^@if $module\$/d
3116 /^@endif $module\$/d
3117 /^@unless $module\$/,/^@endunless $module\$/d
3118 /^@if $module-$host_bootstrap_suffix\$/d
3119 /^@endif $module-$host_bootstrap_suffix\$/d
3120 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3121 done
3122 extrasub_target=
3123 for module in ${target_configdirs} ; do
3124   if test -z "${no_recursion}" \
3125      && test -f ${target_subdir}/${module}/Makefile; then
3126     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3127     rm -f ${target_subdir}/${module}/Makefile
3128   fi
3129
3130   # We only bootstrap target libraries listed in bootstrap_target_libs.
3131   case $bootstrap_target_libs in
3132     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3133     *) target_bootstrap_suffix=no-bootstrap ;;
3134   esac
3135
3136   extrasub_target="$extrasub_target
3137 /^@if target-$module\$/d
3138 /^@endif target-$module\$/d
3139 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3140 /^@if target-$module-$target_bootstrap_suffix\$/d
3141 /^@endif target-$module-$target_bootstrap_suffix\$/d
3142 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3143 done
3144
3145 # Do the final fixup along with target modules.
3146 extrasub_target="$extrasub_target
3147 /^@if /,/^@endif /d
3148 /^@unless /d
3149 /^@endunless /d"
3150
3151 if test "$enable_pgo_build" != "no"; then
3152   extrasub_build="$extrasub_build
3153 /^@if pgo-build\$/d
3154 /^@endif pgo-build\$/d"
3155 fi
3156
3157 # Create the serialization dependencies.  This uses a temporary file.
3158
3159 AC_ARG_ENABLE([serial-configure],
3160 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3161                 [force sequential configuration of
3162                  sub-packages for the host, target or build
3163                  machine, or all sub-packages])])
3164
3165 case ${enable_serial_configure} in
3166   yes)
3167     enable_serial_build_configure=yes
3168     enable_serial_host_configure=yes
3169     enable_serial_target_configure=yes
3170     ;;
3171 esac
3172
3173 # These force 'configure's to be done one at a time, to avoid problems
3174 # with contention over a shared config.cache.
3175 rm -f serdep.tmp
3176 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3177 echo '# serdep.tmp' > serdep.tmp
3178 fi
3179 olditem=
3180 test "x${enable_serial_build_configure}" = xyes &&
3181 for item in ${build_configdirs} ; do
3182   case ${olditem} in
3183     "") ;;
3184     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3185   esac
3186   olditem=${item}
3187 done
3188 olditem=
3189 test "x${enable_serial_host_configure}" = xyes &&
3190 for item in ${configdirs} ; do
3191   case ${olditem} in
3192     "") ;;
3193     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3194   esac
3195   olditem=${item}
3196 done
3197 olditem=
3198 test "x${enable_serial_target_configure}" = xyes &&
3199 for item in ${target_configdirs} ; do
3200   case ${olditem} in
3201     "") ;;
3202     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3203   esac
3204   olditem=${item}
3205 done
3206 serialization_dependencies=serdep.tmp
3207 AC_SUBST_FILE(serialization_dependencies)
3208
3209 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3210 # target, nonopt, and variable assignments.  These are the ones we
3211 # might not want to pass down to subconfigures.  The exception being
3212 # --cache-file=/dev/null, which is used to turn off the use of cache
3213 # files altogether, and which should be passed on to subconfigures.
3214 # Also strip program-prefix, program-suffix, and program-transform-name,
3215 # so that we can pass down a consistent program-transform-name.
3216 baseargs=
3217 tbaseargs=
3218 keep_next=no
3219 skip_next=no
3220 eval "set -- $ac_configure_args"
3221 for ac_arg
3222 do
3223   if test X"$skip_next" = X"yes"; then
3224     skip_next=no
3225     continue
3226   fi
3227   if test X"$keep_next" = X"yes"; then
3228     case $ac_arg in
3229       *\'*)
3230         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3231     esac
3232     baseargs="$baseargs '$ac_arg'"
3233     tbaseargs="$tbaseargs '$ac_arg'"
3234     keep_next=no
3235     continue
3236   fi
3237
3238   # Handle separated arguments.  Based on the logic generated by
3239   # autoconf 2.59.
3240   case $ac_arg in
3241     *=* | --config-cache | -C | -disable-* | --disable-* \
3242       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3243       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3244       | -with-* | --with-* | -without-* | --without-* | --x)
3245       separate_arg=no
3246       ;;
3247     -*)
3248       separate_arg=yes
3249       ;;
3250     *)
3251       separate_arg=no
3252       ;;
3253   esac
3254
3255   skip_targ=no
3256   case $ac_arg in
3257 changequote(,)
3258   --with-* | --without-*)
3259     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3260
3261     case $libopt in
3262     *[-_]include)
3263       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3264       ;;
3265     *[-_]lib)
3266       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3267       ;;
3268     *)
3269       lib=$libopt
3270       ;;
3271     esac
3272 changequote([,])
3273
3274     case $lib in
3275     mpc | mpfr | gmp | isl)
3276       # If we're processing --with-$lib, --with-$lib-include or
3277       # --with-$lib-lib, for one of the libs above, and target is
3278       # different from host, don't pass the current argument to any
3279       # target library's configure.
3280       if test x$is_cross_compiler = xyes; then
3281         skip_targ=yes
3282       fi
3283       ;;
3284     esac
3285     ;;
3286   esac
3287
3288   case "$ac_arg" in
3289     --cache-file=/dev/null | \
3290     -cache-file=/dev/null )
3291       # Handled here to avoid the test to skip args below.
3292       baseargs="$baseargs '$ac_arg'"
3293       tbaseargs="$tbaseargs '$ac_arg'"
3294       # Assert: $separate_arg should always be no.
3295       keep_next=$separate_arg
3296       ;;
3297     --no*)
3298       continue
3299       ;;
3300     --c* | \
3301     --sr* | \
3302     --ho* | \
3303     --bu* | \
3304     --t* | \
3305     --program-* | \
3306     -cache_file* | \
3307     -srcdir* | \
3308     -host* | \
3309     -build* | \
3310     -target* | \
3311     -program-prefix* | \
3312     -program-suffix* | \
3313     -program-transform-name* )
3314       skip_next=$separate_arg
3315       continue
3316       ;;
3317     -*)
3318       # An option.  Add it.
3319       case $ac_arg in
3320         *\'*)
3321           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3322       esac
3323       baseargs="$baseargs '$ac_arg'"
3324       if test X"$skip_targ" = Xno; then
3325         tbaseargs="$tbaseargs '$ac_arg'"
3326       fi
3327       keep_next=$separate_arg
3328       ;;
3329     *)
3330       # Either a variable assignment, or a nonopt (triplet).  Don't
3331       # pass it down; let the Makefile handle this.
3332       continue
3333       ;;
3334   esac
3335 done
3336 # Remove the initial space we just introduced and, as these will be
3337 # expanded by make, quote '$'.
3338 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3339
3340 # Add in --program-transform-name, after --program-prefix and
3341 # --program-suffix have been applied to it.  Autoconf has already
3342 # doubled dollar signs and backslashes in program_transform_name; we want
3343 # the backslashes un-doubled, and then the entire thing wrapped in single
3344 # quotes, because this will be expanded first by make and then by the shell.
3345 # Also, because we want to override the logic in subdir configure scripts to
3346 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3347 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3348 ${program_transform_name}
3349 EOF_SED
3350 gcc_transform_name=`cat conftestsed.out`
3351 rm -f conftestsed.out
3352 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3353 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3354 if test "$silent" = yes; then
3355   baseargs="$baseargs --silent"
3356   tbaseargs="$tbaseargs --silent"
3357 fi
3358
3359 baseargs="$baseargs --disable-option-checking"
3360 tbaseargs="$tbaseargs --disable-option-checking"
3361
3362 if test "$enable_year2038" = no; then
3363   baseargs="$baseargs --disable-year2038"
3364   tbaseargs="$tbaseargs --disable-year2038"
3365 fi
3366
3367 # Record and document user additions to sub configure arguments.
3368 AC_ARG_VAR([build_configargs],
3369            [additional configure arguments for build directories])
3370 AC_ARG_VAR([host_configargs],
3371            [additional configure arguments for host directories])
3372 AC_ARG_VAR([target_configargs],
3373            [additional configure arguments for target directories])
3374
3375 # For the build-side libraries, we just need to pretend we're native,
3376 # and not use the same cache file.  Multilibs are neither needed nor
3377 # desired.  We can't even use the same cache file for all build-side
3378 # libraries, as they're compiled differently; some with C, some with
3379 # C++ or with different feature-enabling options.
3380 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3381
3382 # For host modules, accept cache file option, or specification as blank.
3383 case "${cache_file}" in
3384 "") # empty
3385   cache_file_option="" ;;
3386 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3387   cache_file_option="--cache-file=${cache_file}" ;;
3388 *) # relative path
3389   cache_file_option="--cache-file=../${cache_file}" ;;
3390 esac
3391
3392 # Host dirs don't like to share a cache file either, horribly enough.
3393 # This seems to be due to autoconf 2.5x stupidity.
3394 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3395
3396 target_configargs="$target_configargs ${tbaseargs}"
3397
3398 # Passing a --with-cross-host argument lets the target libraries know
3399 # whether they are being built with a cross-compiler or being built
3400 # native.  However, it would be better to use other mechanisms to make the
3401 # sorts of decisions they want to make on this basis.  Please consider
3402 # this option to be deprecated.  FIXME.
3403 if test x${is_cross_compiler} = xyes ; then
3404   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3405 fi
3406
3407 # Special user-friendly check for native x86_64-linux build, if
3408 # multilib is not explicitly enabled.
3409 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3410   x86_64-*linux*:yes:$build:$build:)
3411     # Make sure we have a development environment that handles 32-bit
3412     dev64=no
3413     echo "int main () { return 0; }" > conftest.c
3414     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3415     if test $? = 0 ; then
3416       if test -s conftest || test -s conftest.exe ; then
3417         dev64=yes
3418       fi
3419     fi
3420     rm -f conftest*
3421     if test x${dev64} != xyes ; then
3422       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3423     fi
3424     ;;
3425 esac
3426
3427 # Default to --enable-multilib.
3428 if test x${enable_multilib} = x ; then
3429   target_configargs="--enable-multilib ${target_configargs}"
3430 fi
3431
3432 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3433 # changed from the earlier setting of with_newlib.
3434 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3435   target_configargs="--with-newlib ${target_configargs}"
3436 fi
3437
3438 # Different target subdirs use different values of certain variables
3439 # (notably CXX).  Worse, multilibs use *lots* of different values.
3440 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3441 # it doesn't automatically accept command-line overrides of them.
3442 # This means it's not safe for target subdirs to share a cache file,
3443 # which is disgusting, but there you have it.  Hopefully this can be
3444 # fixed in future.  It's still worthwhile to use a cache file for each
3445 # directory.  I think.
3446
3447 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3448 # We need to pass --target, as newer autoconf's requires consistency
3449 # for target_alias and gcc doesn't manage it consistently.
3450 target_configargs="--cache-file=./config.cache ${target_configargs}"
3451
3452 FLAGS_FOR_TARGET=
3453 case " $target_configdirs " in
3454  *" newlib "*)
3455   case " $target_configargs " in
3456   *" --with-newlib "*)
3457    case "$target" in
3458     *-cygwin*)
3459       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3460       ;;
3461    esac
3462
3463    # If we're not building GCC, don't discard standard headers.
3464    if test -d ${srcdir}/gcc; then
3465      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3466
3467      if test "${build}" != "${host}"; then
3468        # On Canadian crosses, CC_FOR_TARGET will have already been set
3469        # by `configure', so we won't have an opportunity to add -Bgcc/
3470        # to it.  This is right: we don't want to search that directory
3471        # for binaries, but we want the header files in there, so add
3472        # them explicitly.
3473        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3474
3475        # Someone might think of using the pre-installed headers on
3476        # Canadian crosses, in case the installed compiler is not fully
3477        # compatible with the compiler being built.  In this case, it
3478        # would be better to flag an error than risking having
3479        # incompatible object files being constructed.  We can't
3480        # guarantee that an error will be flagged, but let's hope the
3481        # compiler will do it, when presented with incompatible header
3482        # files.
3483      fi
3484    fi
3485
3486    case "${target}-${is_cross_compiler}" in
3487    i[[3456789]]86-*-linux*-no)
3488       # Here host == target, so we don't need to build gcc,
3489       # so we don't want to discard standard headers.
3490       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3491       ;;
3492    *)
3493       # If we're building newlib, use its generic headers last, but search
3494       # for any libc-related directories first (so make it the last -B
3495       # switch).
3496       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3497
3498       # If we're building libgloss, find the startup file, simulator library
3499       # and linker script.
3500       case " $target_configdirs " in
3501         *" libgloss "*)
3502         # Look for startup file, simulator library and maybe linker script.
3503         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3504         # Look for libnosys.a in case the target needs it.
3505         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3506         # Most targets have the linker script in the source directory.
3507         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3508         ;;
3509       esac
3510       ;;
3511    esac
3512    ;;
3513   esac
3514   ;;
3515 esac
3516
3517 case "$target" in
3518   x86_64-*mingw* | *-w64-mingw*)
3519   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3520   # however, use a symlink named 'mingw' in ${prefix} .
3521     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3522     ;;
3523   *-mingw*)
3524   # MinGW can't be handled as Cygwin above since it does not use newlib.
3525     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3526     ;;
3527 esac
3528
3529 # Allow the user to override the flags for
3530 # our build compiler if desired.
3531 if test x"${build}" = x"${host}" ; then
3532   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3533   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3534   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3535   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3536 fi
3537
3538 # On Canadian crosses, we'll be searching the right directories for
3539 # the previously-installed cross compiler, so don't bother to add
3540 # flags for directories within the install tree of the compiler
3541 # being built; programs in there won't even run.
3542 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3543   # Search for pre-installed headers if nothing else fits.
3544   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3545 fi
3546
3547 if test "x${use_gnu_ld}" = x &&
3548    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3549   # Arrange for us to find uninstalled linker scripts.
3550   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3551 fi
3552
3553 # Search for other target-specific linker scripts and such.
3554 case "${target}" in
3555   mep*)
3556     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3557     ;;
3558   # The VxWorks support for shared libraries is getting in
3559   # incrementally.  Make sure it doesn't get activated implicitly:
3560   *vxworks*)
3561     if test "${enable_shared-unset}" = unset ; then
3562       enable_shared=no
3563       # So the build of libraries knows ...
3564       target_configargs="${target_configargs} --disable-shared"
3565       # So gcc knows ...
3566       host_configargs="${host_configargs} --disable-shared"
3567     fi
3568     ;;
3569 esac
3570
3571 # Makefile fragments.
3572 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3573 do
3574   eval fragval=\$$frag
3575   if test $fragval != /dev/null; then
3576     eval $frag=${srcdir}/$fragval
3577   fi
3578 done
3579 AC_SUBST_FILE(host_makefile_frag)
3580 AC_SUBST_FILE(target_makefile_frag)
3581 AC_SUBST_FILE(alphaieee_frag)
3582 AC_SUBST_FILE(ospace_frag)
3583
3584 # Miscellanea: directories, flags, etc.
3585 AC_SUBST(RPATH_ENVVAR)
3586 AC_SUBST(GCC_SHLIB_SUBDIR)
3587 AC_SUBST(tooldir)
3588 AC_SUBST(build_tooldir)
3589 AC_SUBST(CONFIGURE_GDB_TK)
3590 AC_SUBST(GDB_TK)
3591 AC_SUBST(INSTALL_GDB_TK)
3592
3593 # Build module lists & subconfigure args.
3594 AC_SUBST(build_configargs)
3595 AC_SUBST(build_configdirs)
3596
3597 # Host module lists & subconfigure args.
3598 AC_SUBST(host_configargs)
3599 AC_SUBST(configdirs)
3600 AC_SUBST(target_configdirs)
3601
3602 # Target module lists & subconfigure args.
3603 AC_SUBST(target_configargs)
3604
3605
3606 # Build tools.
3607 AC_SUBST(AR_FOR_BUILD)
3608 AC_SUBST(AS_FOR_BUILD)
3609 AC_SUBST(CC_FOR_BUILD)
3610 AC_SUBST(CFLAGS_FOR_BUILD)
3611 AC_SUBST(CPP_FOR_BUILD)
3612 AC_SUBST(CPPFLAGS_FOR_BUILD)
3613 AC_SUBST(CXXFLAGS_FOR_BUILD)
3614 AC_SUBST(CXX_FOR_BUILD)
3615 AC_SUBST(DLLTOOL_FOR_BUILD)
3616 AC_SUBST(DSYMUTIL_FOR_BUILD)
3617 AC_SUBST(GFORTRAN_FOR_BUILD)
3618 AC_SUBST(GOC_FOR_BUILD)
3619 AC_SUBST(GDC_FOR_BUILD)
3620 AC_SUBST(LDFLAGS_FOR_BUILD)
3621 AC_SUBST(LD_FOR_BUILD)
3622 AC_SUBST(NM_FOR_BUILD)
3623 AC_SUBST(RANLIB_FOR_BUILD)
3624 AC_SUBST(WINDMC_FOR_BUILD)
3625 AC_SUBST(WINDRES_FOR_BUILD)
3626
3627 # Generate default definitions for YACC, M4, LEX and other programs that run
3628 # on the build machine.  These are used if the Makefile can't locate these
3629 # programs in objdir.
3630 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3631
3632 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3633 case " $build_configdirs " in
3634   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3635 esac
3636
3637 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3638 case " $build_configdirs " in
3639   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3640 esac
3641
3642 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3643 case " $build_configdirs " in
3644   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3645 esac
3646
3647 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3648 case " $build_configdirs " in
3649   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3650   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3651 esac
3652
3653 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3654 case " $build_configdirs " in
3655   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3656 esac
3657
3658 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3659 case " $build_configdirs " in
3660   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3661   *)
3662 changequote(,)
3663     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3664     # higher, else we use the "missing" dummy.
3665     if ${MAKEINFO} --version \
3666        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3667       :
3668     else
3669       MAKEINFO="$MISSING makeinfo"
3670     fi
3671     ;;
3672 changequote([,])
3673 esac
3674
3675 # FIXME: expect and dejagnu may become build tools?
3676
3677 AC_CHECK_PROGS(EXPECT, expect, expect)
3678 case " $configdirs " in
3679   *" expect "*)
3680     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3681     ;;
3682 esac
3683
3684 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3685 case " $configdirs " in
3686   *" dejagnu "*)
3687     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3688     ;;
3689 esac
3690
3691
3692 # Host tools.
3693 NCN_STRICT_CHECK_TOOLS(AR, ar)
3694 NCN_STRICT_CHECK_TOOLS(AS, as)
3695 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3696 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3697 NCN_STRICT_CHECK_TOOLS(LD, ld)
3698 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3699 NCN_STRICT_CHECK_TOOLS(NM, nm)
3700 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3701 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3702 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3703 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3704 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3705 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3706 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3707 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3708 AC_SUBST(CC)
3709 AC_SUBST(CXX)
3710 AC_SUBST(CFLAGS)
3711 AC_SUBST(CXXFLAGS)
3712 AC_SUBST(GDC)
3713 AC_SUBST(GDCFLAGS)
3714 AC_SUBST(PKG_CONFIG_PATH)
3715
3716 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3717 AR_PLUGIN_OPTION=
3718 RANLIB_PLUGIN_OPTION=
3719 if test -n "$PLUGIN_OPTION"; then
3720   if $AR --help 2>&1 | grep -q "\--plugin"; then
3721     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3722   fi
3723   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3724     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3725   fi
3726 fi
3727 AC_SUBST(AR_PLUGIN_OPTION)
3728 AC_SUBST(RANLIB_PLUGIN_OPTION)
3729
3730 # Target tools.
3731 AC_ARG_WITH([build-time-tools],
3732   [AS_HELP_STRING([--with-build-time-tools=PATH],
3733                   [use given path to find target tools during the build])],
3734   [case x"$withval" in
3735      x/*) ;;
3736      *)
3737        with_build_time_tools=
3738        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3739        ;;
3740    esac],
3741   [with_build_time_tools=])
3742
3743 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3744 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3745 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3746 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3747 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3748 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3749
3750 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3751 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3752 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3753 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3754 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3755 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3756 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3757 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3758 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3759 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3760 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3761 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3762 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3763 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3764 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3765
3766 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3767
3768 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3769 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3770 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3771 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3772 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3773                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3774                 c++)
3775 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3776                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3777                 c++)
3778 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3779 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3780 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3781 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3782                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3783 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3784                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3785 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3786                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3787 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3788 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3789 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3790 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3791 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3792 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3793 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3794 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3795 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3796 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3797 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3798
3799 AC_SUBST(FLAGS_FOR_TARGET)
3800 AC_SUBST(RAW_CXX_FOR_TARGET)
3801
3802 # Certain tools may need extra flags.
3803 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3804 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3805 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3806
3807 # When building target libraries, except in a Canadian cross, we use
3808 # the same toolchain as the compiler we just built.
3809 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3810 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3811 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3812 if test $host = $build; then
3813   case " $configdirs " in
3814     *" gcc "*)
3815       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3816       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3817       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3818       ;;
3819   esac
3820 fi
3821
3822 AC_SUBST(COMPILER_AS_FOR_TARGET)
3823 AC_SUBST(COMPILER_LD_FOR_TARGET)
3824 AC_SUBST(COMPILER_NM_FOR_TARGET)
3825
3826 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3827 AC_ARG_ENABLE(maintainer-mode,
3828 [AS_HELP_STRING([--enable-maintainer-mode],
3829                 [enable make rules and dependencies not useful
3830                  (and sometimes confusing) to the casual installer])],
3831       USE_MAINTAINER_MODE=$enableval,
3832       USE_MAINTAINER_MODE=no)
3833 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3834 AC_SUBST(MAINTAINER_MODE_TRUE)
3835 AC_SUBST(MAINTAINER_MODE_FALSE)
3836 if test "$USE_MAINTAINER_MODE" = yes; then
3837   MAINTAINER_MODE_TRUE=
3838   MAINTAINER_MODE_FALSE='#'
3839 else
3840   MAINTAINER_MODE_TRUE='#'
3841   MAINTAINER_MODE_FALSE=
3842 fi
3843 MAINT=$MAINTAINER_MODE_TRUE
3844 AC_SUBST(MAINT)dnl
3845
3846 # ---------------------
3847 # GCC bootstrap support
3848 # ---------------------
3849
3850 # Stage specific cflags for build.
3851 stage1_cflags="-g"
3852 case $build in
3853   vax-*-*)
3854     case ${GCC} in
3855       yes) stage1_cflags="-g -Wa,-J" ;;
3856       *) stage1_cflags="-g -J" ;;
3857     esac ;;
3858 esac
3859
3860 AC_SUBST(stage1_cflags)
3861
3862 # Enable --enable-checking in stage1 of the compiler.
3863 AC_ARG_ENABLE(stage1-checking,
3864 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3865                 [choose additional checking for stage1 of the compiler])],
3866 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3867 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3868   # For --disable-checking or implicit --enable-checking=release, avoid
3869   # setting --enable-checking=gc in the default stage1 checking for LTO
3870   # bootstraps.  See PR62077.
3871   case $BUILD_CONFIG in
3872     *lto*)
3873       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3874     *)
3875       stage1_checking=--enable-checking=yes,types;;
3876   esac
3877   if test "x$enable_checking" = x && \
3878      test -d ${srcdir}/gcc && \
3879      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3880     stage1_checking=--enable-checking=yes,types,extra
3881   fi
3882 else
3883   stage1_checking=--enable-checking=$enable_checking,types
3884 fi])
3885 AC_SUBST(stage1_checking)
3886
3887 # Enable -Werror in bootstrap stage2 and later.
3888 AC_ARG_ENABLE(werror,
3889 [AS_HELP_STRING([--enable-werror],
3890                 [enable -Werror in bootstrap stage2 and later])],
3891 [
3892 case ${enable_werror} in
3893   yes) stage2_werror_flag="--enable-werror-always" ;;
3894   *) stage2_werror_flag="" ;;
3895 esac
3896 ],
3897 [
3898 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3899   case $BUILD_CONFIG in
3900   bootstrap-debug)
3901       stage2_werror_flag="--enable-werror-always" ;;
3902   "")
3903       stage2_werror_flag="--enable-werror-always" ;;
3904   esac
3905 fi
3906 ])
3907
3908 AC_SUBST(stage2_werror_flag)
3909
3910 # Specify what files to not compare during bootstrap.
3911
3912 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3913 case "$target" in
3914   hppa*64*-*-hpux*) ;;
3915   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3916   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3917 esac
3918 AC_SUBST(compare_exclusions)
3919
3920 AC_CONFIG_FILES([Makefile],
3921   [sed "$extrasub_build" Makefile |
3922    sed "$extrasub_host" |
3923    sed "$extrasub_target" > mf$$
3924    mv -f mf$$ Makefile],
3925   [extrasub_build="$extrasub_build"
3926    extrasub_host="$extrasub_host"
3927    extrasub_target="$extrasub_target"])
3928 AC_OUTPUT