configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.79
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBVA_REQUIRED=0.38.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.8
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.8.0
 106 LLVM_REQUIRED_RADEONSI=3.8.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl Add flags for gcc and g++
 286 if test "x$GCC" = xyes; then
 287     CFLAGS="$CFLAGS -Wall"
 288
 289     if test "x$USE_GNU99" = xyes; then
 290         CFLAGS="$CFLAGS -std=gnu99"
 291     else
 292         CFLAGS="$CFLAGS -std=c99"
 293     fi
 294
 295     # Enable -Werror=implicit-function-declaration and
 296     # -Werror=missing-prototypes, if available, or otherwise, just
 297     # -Wmissing-prototypes.  This is particularly useful to avoid
 298     # generating a loadable driver module that has undefined symbols.
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 301     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 302     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 303     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 304                    AC_MSG_RESULT([yes]),
 305                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 306                     AC_MSG_RESULT([no])])
 307
 308     # Enable -fvisibility=hidden if using a gcc that supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 311     VISIBILITY_CFLAGS="-fvisibility=hidden"
 312     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 314                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 315
 316     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 317     CFLAGS=$save_CFLAGS
 318
 319     # We don't want floating-point math functions to set errno or trap
 320     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 321
 322     # Flags to help ensure that certain portions of the code -- and only those
 323     # portions -- can be built with MSVC:
 324     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 325     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 326     #   supports most of C99)
 327     # - the rest has no compiler compiler restrictions
 328     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 329     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 330
 331     # Enable -Werror=vla if compiler supports it
 332     save_CFLAGS="$CFLAGS"
 333     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 334     CFLAGS="$CFLAGS -Werror=vla"
 335     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 336                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 337                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 338                     AC_MSG_RESULT([yes])],
 339                     AC_MSG_RESULT([no]))
 340     CFLAGS="$save_CFLAGS"
 341 fi
 342 if test "x$GXX" = xyes; then
 343     CXXFLAGS="$CXXFLAGS -Wall"
 344
 345     # Enable -fvisibility=hidden if using a gcc that supports it
 346     save_CXXFLAGS="$CXXFLAGS"
 347     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 348     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 349     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 350     AC_LANG_PUSH([C++])
 351     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 352                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 353     AC_LANG_POP([C++])
 354
 355     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 356     CXXFLAGS=$save_CXXFLAGS
 357
 358     # We don't want floating-point math functions to set errno or trap
 359     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 360 fi
 361
 362 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 363 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 364
 365 dnl even if the compiler appears to support it, using visibility attributes isn't
 366 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 367 case "$host_os" in
 368 cygwin*)
 369     VISIBILITY_CFLAGS=""
 370     VISIBILITY_CXXFLAGS=""
 371     ;;
 372 esac
 373
 374 AC_SUBST([VISIBILITY_CFLAGS])
 375 AC_SUBST([VISIBILITY_CXXFLAGS])
 376
 377 dnl
 378 dnl Optional flags, check for compiler support
 379 dnl
 380 SSE41_CFLAGS="-msse4.1"
 381 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 382 dnl stack, but on x86-32 such alignment is not guaranteed.
 383 case "$target_cpu" in
 384 i?86)
 385     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 386     ;;
 387 esac
 388 save_CFLAGS="$CFLAGS"
 389 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 390 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 391 #include <smmintrin.h>
 392 int param;
 393 int main () {
 394     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 395     c = _mm_max_epu32(a, b);
 396     return _mm_cvtsi128_si32(c);
 397 }]])], SSE41_SUPPORTED=1)
 398 CFLAGS="$save_CFLAGS"
 399 if test "x$SSE41_SUPPORTED" = x1; then
 400     DEFINES="$DEFINES -DUSE_SSE41"
 401 fi
 402 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 403 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 404
 405 dnl Check for new-style atomic builtins
 406 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407 int main() {
 408     int n;
 409     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 410 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 411 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 412     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 413 fi
 414 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 415
 416 dnl Check if host supports 64-bit atomics
 417 dnl note that lack of support usually results in link (not compile) error
 418 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 419 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 420 #include <stdint.h>
 421 uint64_t v;
 422 int main() {
 423     return __sync_add_and_fetch(&v, (uint64_t)1);
 424 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 425 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 426     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 427 fi
 428 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 429
 430 dnl Check for Endianness
 431 AC_C_BIGENDIAN(
 432    little_endian=no,
 433    little_endian=yes,
 434    little_endian=no,
 435    little_endian=no
 436 )
 437
 438 dnl Check for POWER8 Architecture
 439 PWR8_CFLAGS="-mpower8-vector"
 440 have_pwr8_intrinsics=no
 441 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 442 save_CFLAGS=$CFLAGS
 443 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 444 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 445 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 446 #error "Need GCC >= 4.8 for sane POWER8 support"
 447 #endif
 448 #include <altivec.h>
 449 int main () {
 450     vector unsigned char r;
 451     vector unsigned int v = vec_splat_u32 (1);
 452     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 453     return 0;
 454 }]])], have_pwr8_intrinsics=yes)
 455 CFLAGS=$save_CFLAGS
 456
 457 AC_ARG_ENABLE(pwr8,
 458    [AS_HELP_STRING([--disable-pwr8-inst],
 459                    [disable POWER8-specific instructions])],
 460    [enable_pwr8=$enableval], [enable_pwr8=auto])
 461
 462 if test "x$enable_pwr8" = xno ; then
 463    have_pwr8_intrinsics=disabled
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 467    DEFINES="$DEFINES -D_ARCH_PWR8"
 468    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 469    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 470 else
 471    PWR8_CFLAGS=
 472 fi
 473
 474 AC_MSG_RESULT($have_pwr8_intrinsics)
 475 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 476    AC_MSG_ERROR([POWER8 compiler support not detected])
 477 fi
 478
 479 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 480    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 481 fi
 482
 483 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 484
 485 dnl Can't have static and shared libraries, default to static if user
 486 dnl explicitly requested. If both disabled, set to static since shared
 487 dnl was explicitly requested.
 488 case "x$enable_static$enable_shared" in
 489 xyesyes)
 490     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 491     ;;
 492 xnono)
 493     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 494     ;;
 495 esac
 496
 497 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 498
 499 dnl
 500 dnl other compiler options
 501 dnl
 502 AC_ARG_ENABLE([debug],
 503     [AS_HELP_STRING([--enable-debug],
 504         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 505     [enable_debug="$enableval"],
 506     [enable_debug=no]
 507 )
 508
 509 AC_ARG_ENABLE([profile],
 510     [AS_HELP_STRING([--enable-profile],
 511         [enable profiling of code @<:@default=disabled@:>@])],
 512     [enable_profile="$enableval"],
 513     [enable_profile=no]
 514 )
 515
 516 AC_ARG_ENABLE([sanitize],
 517     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 518         [enable code sanitizer @<:@default=disabled@:>@])],
 519     [enable_sanitize="$enableval"],
 520     [enable_sanitize=no])
 521
 522 if test "x$enable_profile" = xyes; then
 523     DEFINES="$DEFINES -DPROFILE"
 524     if test "x$GCC" = xyes; then
 525         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 526     fi
 527     if test "x$GXX" = xyes; then
 528         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 529     fi
 530 fi
 531
 532 if test "x$enable_debug" = xyes; then
 533     DEFINES="$DEFINES -DDEBUG"
 534     if test "x$enable_profile" = xyes; then
 535         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 536     fi
 537     if test "x$GCC" = xyes; then
 538         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 539             CFLAGS="$CFLAGS -g"
 540         fi
 541         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 542             CFLAGS="$CFLAGS -O0"
 543         fi
 544     fi
 545     if test "x$GXX" = xyes; then
 546         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 547             CXXFLAGS="$CXXFLAGS -g"
 548         fi
 549         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 550             CXXFLAGS="$CXXFLAGS -O0"
 551         fi
 552     fi
 553 else
 554    DEFINES="$DEFINES -DNDEBUG"
 555 fi
 556
 557 if test "x$enable_sanitize" != xno; then
 558     if test "x$enable_profile" = xyes; then
 559         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 560     fi
 561
 562     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 563     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 564     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 565
 566     AC_LINK_IFELSE(
 567         [AC_LANG_SOURCE([int main(){return 0;}])],
 568         [],
 569         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 570 fi
 571
 572 dnl
 573 dnl Check if linker supports -Bsymbolic
 574 dnl
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 577 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 578 AC_LINK_IFELSE(
 579     [AC_LANG_SOURCE([int main() { return 0;}])],
 580     [AC_MSG_RESULT([yes])
 581         BSYMBOLIC="-Wl,-Bsymbolic";],
 582     [AC_MSG_RESULT([no])
 583         BSYMBOLIC="";])
 584 LDFLAGS=$save_LDFLAGS
 585
 586 AC_SUBST([BSYMBOLIC])
 587
 588 dnl
 589 dnl Check if linker supports garbage collection
 590 dnl
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 593 AC_MSG_CHECKING([whether ld supports --gc-sections])
 594 AC_LINK_IFELSE(
 595     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 596     [AC_MSG_RESULT([yes])
 597         GC_SECTIONS="-Wl,--gc-sections";],
 598     [AC_MSG_RESULT([no])
 599         GC_SECTIONS="";])
 600 LDFLAGS=$save_LDFLAGS
 601
 602 AC_SUBST([GC_SECTIONS])
 603
 604 dnl
 605 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 606 dnl so when these flags are passed to ld via libtool the checks will fail
 607 dnl
 608 case "$host_os" in
 609 openbsd* | darwin* )
 610     LD_NO_UNDEFINED="" ;;
 611 *)
 612     if test "x$enable_sanitize" = xno; then
 613         LD_NO_UNDEFINED="-Wl,--no-undefined"
 614     else
 615         LD_NO_UNDEFINED=""
 616     fi
 617     ;;
 618 esac
 619
 620 AC_SUBST([LD_NO_UNDEFINED])
 621
 622 dnl
 623 dnl Check if linker supports version scripts
 624 dnl
 625 AC_MSG_CHECKING([if the linker supports version-scripts])
 626 save_LDFLAGS=$LDFLAGS
 627 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 628 cat > conftest.map <<EOF
 629 VERSION_1 {
 630      global:
 631          main;
 632
 633      local:
 634          *;
 635 };
 636 EOF
 637 AC_LINK_IFELSE(
 638     [AC_LANG_SOURCE([int main() { return 0;}])],
 639     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 640     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 641 LDFLAGS=$save_LDFLAGS
 642 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 643
 644 dnl
 645 dnl Check if linker supports dynamic list files
 646 dnl
 647 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 648 save_LDFLAGS=$LDFLAGS
 649 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 650 cat > conftest.dyn <<EOF
 651 {
 652         radeon_drm_winsys_create;
 653 };
 654 EOF
 655 AC_LINK_IFELSE(
 656     [AC_LANG_SOURCE([int main() { return 0;}])],
 657     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 658     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 659 LDFLAGS=$save_LDFLAGS
 660 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 661
 662 dnl
 663 dnl compatibility symlinks
 664 dnl
 665 case "$host_os" in
 666 linux* )
 667     HAVE_COMPAT_SYMLINKS=yes ;;
 668 * )
 669     HAVE_COMPAT_SYMLINKS=no ;;
 670 esac
 671
 672 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 673
 674 dnl
 675 dnl library names
 676 dnl
 677 dnl Unfortunately we need to do a few things that libtool can't help us with,
 678 dnl so we need some knowledge of shared library filenames:
 679 dnl
 680 dnl LIB_EXT is the extension used when creating symlinks for alternate
 681 dnl filenames for a shared library which will be dynamically loaded
 682 dnl
 683 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 684 dnl the file for a shared library we wish to link with
 685 dnl
 686 case "$host_os" in
 687 darwin* )
 688     LIB_EXT='dylib'
 689     IMP_LIB_EXT=$LIB_EXT
 690     ;;
 691 cygwin* )
 692     LIB_EXT='dll'
 693     IMP_LIB_EXT='dll.a'
 694     ;;
 695 aix* )
 696     LIB_EXT='a'
 697     IMP_LIB_EXT=$LIB_EXT
 698     ;;
 699 * )
 700     LIB_EXT='so'
 701     IMP_LIB_EXT=$LIB_EXT
 702     ;;
 703 esac
 704
 705 AC_SUBST([LIB_EXT])
 706
 707 dnl
 708 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 709 dnl
 710 AC_ARG_ENABLE([texture-float],
 711     [AS_HELP_STRING([--enable-texture-float],
 712         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 713     [enable_texture_float="$enableval"],
 714     [enable_texture_float=no]
 715 )
 716 if test "x$enable_texture_float" = xyes; then
 717     AC_MSG_WARN([Floating-point textures enabled.])
 718     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 719     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 720 fi
 721
 722 dnl
 723 dnl Arch/platform-specific settings
 724 dnl
 725 AC_ARG_ENABLE([asm],
 726     [AS_HELP_STRING([--disable-asm],
 727         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 728     [enable_asm="$enableval"],
 729     [enable_asm=yes]
 730 )
 731 asm_arch=""
 732 AC_MSG_CHECKING([whether to enable assembly])
 733 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 734 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 735 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 736     case "$host_cpu" in
 737     i?86 | x86_64 | amd64)
 738         if test "x$host_cpu" != "x$target_cpu"; then
 739             enable_asm=no
 740             AC_MSG_RESULT([no, cross compiling])
 741         fi
 742         ;;
 743     esac
 744 fi
 745 # check for supported arches
 746 if test "x$enable_asm" = xyes; then
 747     case "$host_cpu" in
 748     i?86)
 749         case "$host_os" in
 750         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 751             asm_arch=x86
 752             ;;
 753         esac
 754         ;;
 755     x86_64|amd64)
 756         case "$host_os" in
 757         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 758             asm_arch=x86_64
 759             ;;
 760         esac
 761         ;;
 762     sparc*)
 763         case "$host_os" in
 764         linux*)
 765             asm_arch=sparc
 766             ;;
 767         esac
 768         ;;
 769     esac
 770
 771     case "$asm_arch" in
 772     x86)
 773         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 774         AC_MSG_RESULT([yes, x86])
 775         ;;
 776     x86_64|amd64)
 777         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 778         AC_MSG_RESULT([yes, x86_64])
 779         ;;
 780     sparc)
 781         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 782         AC_MSG_RESULT([yes, sparc])
 783         ;;
 784     *)
 785         AC_MSG_RESULT([no, platform not supported])
 786         ;;
 787     esac
 788 fi
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 792 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 793 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 794 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 795
 796 dnl Check to see if dlopen is in default libraries (like Solaris, which
 797 dnl has it in libc), or if libdl is needed to get it.
 798 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 799     [AC_CHECK_LIB([dl], [dlopen],
 800        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 801 AC_SUBST([DLOPEN_LIBS])
 802
 803 dnl Check if that library also has dladdr
 804 save_LIBS="$LIBS"
 805 LIBS="$LIBS $DLOPEN_LIBS"
 806 AC_CHECK_FUNCS([dladdr])
 807 LIBS="$save_LIBS"
 808
 809 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 810
 811 case "$host_os" in
 812 darwin*)
 813     ;;
 814 *)
 815     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 816                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 817                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 818     AC_SUBST([CLOCK_LIB])
 819     ;;
 820 esac
 821
 822 dnl See if posix_memalign is available
 823 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 824
 825 dnl Check for zlib
 826 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840
 841 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 842 dnl project. Even then there's a notable issue as described in the project README
 843 case "$host_os" in
 844 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 845     pthread_stubs_possible="no"
 846     ;;
 847 * )
 848     pthread_stubs_possible="yes"
 849     ;;
 850 esac
 851
 852 if test "x$pthread_stubs_possible" = xyes; then
 853     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 854     AC_SUBST(PTHREADSTUBS_CFLAGS)
 855     AC_SUBST(PTHREADSTUBS_LIBS)
 856 fi
 857
 858 dnl SELinux awareness.
 859 AC_ARG_ENABLE([selinux],
 860     [AS_HELP_STRING([--enable-selinux],
 861         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 862     [MESA_SELINUX="$enableval"],
 863     [MESA_SELINUX=no])
 864 if test "x$enable_selinux" = "xyes"; then
 865     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 866         [AC_CHECK_HEADER([selinux/selinux.h],[],
 867                          [AC_MSG_ERROR([SELinux headers not found])])
 868          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 869                       [AC_MSG_ERROR([SELinux library not found])])
 870          SELINUX_LIBS="-lselinux"])
 871     DEFINES="$DEFINES -DMESA_SELINUX"
 872 fi
 873 AC_SUBST([SELINUX_CFLAGS])
 874 AC_SUBST([SELINUX_LIBS])
 875
 876 dnl
 877 dnl LLVM
 878 dnl
 879 AC_ARG_ENABLE([llvm-shared-libs],
 880     [AS_HELP_STRING([--enable-llvm-shared-libs],
 881         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 882     [enable_llvm_shared_libs="$enableval"],
 883     [enable_llvm_shared_libs=yes])
 884
 885 AC_ARG_WITH([llvm-prefix],
 886     [AS_HELP_STRING([--with-llvm-prefix],
 887         [Prefix for LLVM installations in non-standard locations])],
 888     [llvm_prefix="$withval"],
 889     [llvm_prefix=''])
 890
 891 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 892 if test "x$have_libelf" = xno; then
 893    LIBELF_LIBS=''
 894    LIBELF_CFLAGS=''
 895    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 896    AC_SUBST([LIBELF_LIBS])
 897    AC_SUBST([LIBELF_CFLAGS])
 898 fi
 899
 900 if test -z "$LLVM_CONFIG"; then
 901     if test -n "$llvm_prefix"; then
 902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 903     else
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 905     fi
 906 fi
 907
 908 llvm_add_component() {
 909     new_llvm_component=$1
 910     driver_name=$2
 911
 912     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 913         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 914     else
 915         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 916     fi
 917 }
 918
 919 llvm_add_default_components() {
 920     driver_name=$1
 921
 922     # Required default components
 923     llvm_add_component "bitwriter" $driver_name
 924     llvm_add_component "engine" $driver_name
 925     llvm_add_component "mcdisassembler" $driver_name
 926     llvm_add_component "mcjit" $driver_name
 927
 928     # Optional default components
 929     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 930         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 931     fi
 932 }
 933
 934 llvm_add_target() {
 935     new_llvm_target=$1
 936     driver_name=$2
 937
 938     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 939         llvm_add_component $new_llvm_target $driver_name
 940     else
 941         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 942     fi
 943 }
 944
 945 # Call this inside ` ` to get the return value.
 946 # $1 is the llvm-config command with arguments.
 947 strip_unwanted_llvm_flags() {
 948     echo " `$1` " | sed -E \
 949         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 950         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 951         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 952         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 954         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 956         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 957         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 958         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 959         -e 's/^[[[:space:]]]//' \
 960         -e 's/[[[:space:]]]$//'
 961 }
 962
 963 llvm_set_environment_variables() {
 964     if test "x$LLVM_CONFIG" != xno; then
 965         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 966         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 967         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 968         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 969
 970         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 971         save_CFLAGS="$CFLAGS"
 972         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 973
 974         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 975             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 976         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 977             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 978         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 979             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 980
 981         CFLAGS="$save_CFLAGS"
 982
 983         # Only needed for LLVM < 3.6.0
 984         if test -z "$LLVM_VERSION_PATCH"; then
 985             LLVM_VERSION_PATCH=0
 986         fi
 987
 988         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 989
 990         FOUND_LLVM=yes
 991     else
 992         FOUND_LLVM=no
 993         LLVM_VERSION_INT=0
 994     fi
 995 }
 996
 997 require_llvm() {
 998     if test "x$enable_llvm" != "xyes"; then
 999         AC_MSG_ERROR([--enable-llvm is required when building $1])
1000     fi
1001 }
1002
1003 llvm_require_version() {
1004     require_llvm $2
1005
1006     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1007     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1008     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1009
1010     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1011         # major > required major
1012         #  --> OK
1013         return
1014     fi
1015
1016     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1017         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1018             # major = required major and
1019             # minor > required minor
1020             #  --> OK
1021             return
1022         else
1023             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1024                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1025                     # major = required major and
1026                     # minor = required minor and
1027                     # patch >= required patch
1028                     #  --> OK
1029                     return
1030                 fi
1031             fi
1032         fi
1033     fi
1034
1035     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1036 }
1037
1038 radeon_llvm_check() {
1039     if test ${LLVM_VERSION_INT} -lt 307; then
1040         amdgpu_llvm_target_name='r600'
1041     else
1042         amdgpu_llvm_target_name='amdgpu'
1043     fi
1044
1045     llvm_require_version $*
1046
1047     llvm_add_target $amdgpu_llvm_target_name $2
1048
1049     llvm_add_default_components $2
1050     llvm_add_component "bitreader" $2
1051     llvm_add_component "ipo" $2
1052
1053     if test "x$have_libelf" != xyes; then
1054        AC_MSG_ERROR([$2 requires libelf when using llvm])
1055     fi
1056 }
1057
1058 llvm_set_environment_variables
1059
1060 AC_SUBST([LLVM_CFLAGS])
1061 AC_SUBST([LLVM_CXXFLAGS])
1062 AC_SUBST([LLVM_LIBS])
1063 AC_SUBST([LLVM_LDFLAGS])
1064 AC_SUBST([LLVM_INCLUDEDIR])
1065
1066 dnl
1067 dnl libunwind
1068 dnl
1069 AC_ARG_ENABLE([libunwind],
1070     [AS_HELP_STRING([--enable-libunwind],
1071             [Use libunwind for backtracing (default: auto)])],
1072         [LIBUNWIND="$enableval"],
1073         [LIBUNWIND="auto"])
1074
1075 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1076 if test "x$LIBUNWIND" = "xauto"; then
1077     LIBUNWIND="$HAVE_LIBUNWIND"
1078 fi
1079
1080 if test "x$LIBUNWIND" = "xyes"; then
1081     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1082     if test "x$HAVE_LIBUNWIND" != "xyes"; then
1083         AC_MSG_ERROR([libunwind requested but not installed.])
1084     fi
1085     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1086 fi
1087
1088 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$LIBUNWIND" = xyes])
1089
1090
1091 dnl Options for APIs
1092 AC_ARG_ENABLE([opengl],
1093     [AS_HELP_STRING([--disable-opengl],
1094         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1095     [enable_opengl="$enableval"],
1096     [enable_opengl=yes])
1097 AC_ARG_ENABLE([gles1],
1098     [AS_HELP_STRING([--disable-gles1],
1099         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1100     [enable_gles1="$enableval"],
1101     [enable_gles1=yes])
1102 AC_ARG_ENABLE([gles2],
1103     [AS_HELP_STRING([--disable-gles2],
1104         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1105     [enable_gles2="$enableval"],
1106     [enable_gles2=yes])
1107
1108 AC_ARG_ENABLE([dri],
1109     [AS_HELP_STRING([--enable-dri],
1110         [enable DRI modules @<:@default=enabled@:>@])],
1111     [enable_dri="$enableval"],
1112     [enable_dri=yes])
1113
1114 AC_ARG_ENABLE([gallium-extra-hud],
1115     [AS_HELP_STRING([--enable-gallium-extra-hud],
1116         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1117     [enable_gallium_extra_hud="$enableval"],
1118     [enable_gallium_extra_hud=no])
1119 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1120 if test "x$enable_gallium_extra_hud" = xyes ; then
1121     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1122 fi
1123
1124 #TODO: no pkgconfig .pc available for libsensors.
1125 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1126 AC_ARG_ENABLE([lmsensors],
1127     [AS_HELP_STRING([--enable-lmsensors],
1128         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1129     [enable_lmsensors="$enableval"],
1130     [enable_lmsensors=no])
1131 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1132 if test "x$enable_lmsensors" = xyes ; then
1133     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1134     LIBSENSORS_LIBS="-lsensors"
1135 else
1136     LIBSENSORS_LIBS=""
1137 fi
1138 AC_SUBST(LIBSENSORS_LIBS)
1139
1140 case "$host_os" in
1141 linux*)
1142     dri3_default=yes
1143     ;;
1144 *)
1145     dri3_default=no
1146     ;;
1147 esac
1148
1149 if test "x$enable_dri" = xno; then
1150     dri3_default=no
1151 fi
1152
1153 AC_ARG_ENABLE([dri3],
1154     [AS_HELP_STRING([--enable-dri3],
1155         [enable DRI3 @<:@default=auto@:>@])],
1156     [enable_dri3="$enableval"],
1157     [enable_dri3="$dri3_default"])
1158 AC_ARG_ENABLE([glx],
1159     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1160         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1161     [enable_glx="$enableval"],
1162     [enable_glx=yes])
1163 AC_ARG_ENABLE([osmesa],
1164     [AS_HELP_STRING([--enable-osmesa],
1165         [enable OSMesa library @<:@default=disabled@:>@])],
1166     [enable_osmesa="$enableval"],
1167     [enable_osmesa=no])
1168 AC_ARG_ENABLE([gallium-osmesa],
1169     [AS_HELP_STRING([--enable-gallium-osmesa],
1170         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1171     [enable_gallium_osmesa="$enableval"],
1172     [enable_gallium_osmesa=no])
1173 AC_ARG_ENABLE([egl],
1174     [AS_HELP_STRING([--disable-egl],
1175         [disable EGL library @<:@default=enabled@:>@])],
1176     [enable_egl="$enableval"],
1177     [enable_egl=yes])
1178
1179 AC_ARG_ENABLE([xa],
1180     [AS_HELP_STRING([--enable-xa],
1181         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1182     [enable_xa="$enableval"],
1183     [enable_xa=no])
1184 AC_ARG_ENABLE([gbm],
1185    [AS_HELP_STRING([--enable-gbm],
1186          [enable gbm library @<:@default=yes except cygwin@:>@])],
1187    [enable_gbm="$enableval"],
1188    [case "$host_os" in
1189        cygwin*)
1190           enable_gbm=no
1191           ;;
1192        *)
1193           enable_gbm=yes
1194           ;;
1195     esac])
1196 AC_ARG_ENABLE([nine],
1197     [AS_HELP_STRING([--enable-nine],
1198         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1199     [enable_nine="$enableval"],
1200     [enable_nine=no])
1201
1202 AC_ARG_ENABLE([xvmc],
1203    [AS_HELP_STRING([--enable-xvmc],
1204          [enable xvmc library @<:@default=auto@:>@])],
1205    [enable_xvmc="$enableval"],
1206    [enable_xvmc=auto])
1207 AC_ARG_ENABLE([vdpau],
1208    [AS_HELP_STRING([--enable-vdpau],
1209          [enable vdpau library @<:@default=auto@:>@])],
1210    [enable_vdpau="$enableval"],
1211    [enable_vdpau=auto])
1212 AC_ARG_ENABLE([omx],
1213    [AS_HELP_STRING([--enable-omx],
1214          [enable OpenMAX library @<:@default=disabled@:>@])],
1215    [enable_omx="$enableval"],
1216    [enable_omx=no])
1217 AC_ARG_ENABLE([va],
1218    [AS_HELP_STRING([--enable-va],
1219          [enable va library @<:@default=auto@:>@])],
1220    [enable_va="$enableval"],
1221    [enable_va=auto])
1222 AC_ARG_ENABLE([opencl],
1223    [AS_HELP_STRING([--enable-opencl],
1224          [enable OpenCL library @<:@default=disabled@:>@])],
1225    [enable_opencl="$enableval"],
1226    [enable_opencl=no])
1227 AC_ARG_ENABLE([opencl_icd],
1228    [AS_HELP_STRING([--enable-opencl-icd],
1229           [Build an OpenCL ICD library to be loaded by an ICD implementation
1230            @<:@default=disabled@:>@])],
1231     [enable_opencl_icd="$enableval"],
1232     [enable_opencl_icd=no])
1233
1234 AC_ARG_ENABLE([gallium-tests],
1235     [AS_HELP_STRING([--enable-gallium-tests],
1236         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1237     [enable_gallium_tests="$enableval"],
1238     [enable_gallium_tests=no])
1239
1240 # Option for Gallium drivers
1241
1242 # Keep this in sync with the --with-gallium-drivers help string default value
1243 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1244
1245 AC_ARG_WITH([gallium-drivers],
1246     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1247         [comma delimited Gallium drivers list, e.g.
1248         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1249         @<:@default=r300,r600,svga,swrast@:>@])],
1250     [with_gallium_drivers="$withval"],
1251     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1252
1253 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1254 # here so that the script doesn't choke on an unknown driver name later.
1255 case "$with_gallium_drivers" in
1256     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1257     no) with_gallium_drivers='' ;;
1258 esac
1259
1260 if test "x$enable_opengl" = xno -a \
1261         "x$enable_gles1" = xno -a \
1262         "x$enable_gles2" = xno -a \
1263         "x$enable_nine" = xno -a \
1264         "x$enable_xa" = xno -a \
1265         "x$enable_xvmc" = xno -a \
1266         "x$enable_vdpau" = xno -a \
1267         "x$enable_omx" = xno -a \
1268         "x$enable_va" = xno -a \
1269         "x$enable_opencl" = xno; then
1270     AC_MSG_ERROR([at least one API should be enabled])
1271 fi
1272
1273 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1274 if test "x$enable_opengl" = xno -a \
1275         "x$enable_gles1" = xyes; then
1276     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1277 fi
1278
1279 if test "x$enable_opengl" = xno -a \
1280         "x$enable_gles2" = xyes; then
1281     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1282 fi
1283
1284 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1285 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1286 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1287 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1288                                         "x$enable_gles1" = xyes -o \
1289                                         "x$enable_gles2" = xyes)
1290
1291 # Validate GLX options
1292 if test "x$enable_glx" = xyes; then
1293     if test "x$enable_dri" = xyes; then
1294         enable_glx=dri
1295     elif test -n "$with_gallium_drivers"; then
1296         enable_glx=gallium-xlib
1297     else
1298         enable_glx=xlib
1299     fi
1300 fi
1301 case "x$enable_glx" in
1302 xdri | xxlib | xgallium-xlib)
1303     # GLX requires OpenGL
1304     if test "x$enable_opengl" = xno; then
1305         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1306     fi
1307
1308     # Check individual dependencies
1309     case "x$enable_glx" in
1310     xdri)
1311         if test "x$enable_dri" = xno; then
1312             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1313         fi
1314         ;;
1315     xxlib)
1316         if test "x$enable_dri" = xyes; then
1317             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1318         fi
1319         ;;
1320     xgallium-xlib )
1321         if test "x$enable_dri" = xyes; then
1322             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1323         fi
1324         if test -z "$with_gallium_drivers"; then
1325             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1326         fi
1327         ;;
1328     esac
1329     ;;
1330 xno)
1331     ;;
1332 *)
1333     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1334     ;;
1335 esac
1336
1337 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1338 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1339 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1340 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1341
1342 DEFAULT_GL_LIB_NAME=GL
1343
1344 dnl
1345 dnl Libglvnd configuration
1346 dnl
1347 AC_ARG_ENABLE([libglvnd],
1348     [AS_HELP_STRING([--enable-libglvnd],
1349         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1350     [enable_libglvnd="$enableval"],
1351     [enable_libglvnd=no])
1352 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1353
1354 if test "x$enable_libglvnd" = xyes ; then
1355     dnl XXX: update once we can handle more than libGL/glx.
1356     dnl Namely: we should error out if neither of the glvnd enabled libraries
1357     dnl are built
1358     case "x$enable_glx" in
1359     xno)
1360         AC_MSG_ERROR([cannot build libglvnd without GLX])
1361         ;;
1362     xxlib | xgallium-xlib )
1363         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1364         ;;
1365     xdri)
1366         ;;
1367     esac
1368
1369     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1370     PKG_CHECK_VAR(LIBGLVND_DATADIR, libglvnd, datadir)
1371     AC_SUBST([LIBGLVND_DATADIR])
1372
1373     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1374     DEFAULT_GL_LIB_NAME=GLX_mesa
1375 fi
1376
1377 AC_ARG_WITH([gl-lib-name],
1378   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1379     [specify GL library name @<:@default=GL@:>@])],
1380   [GL_LIB=$withval],
1381   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1382 AC_ARG_WITH([osmesa-lib-name],
1383   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1384     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1385   [OSMESA_LIB=$withval],
1386   [OSMESA_LIB=OSMesa])
1387 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1388 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1389
1390 dnl
1391 dnl Mangled Mesa support
1392 dnl
1393 AC_ARG_ENABLE([mangling],
1394   [AS_HELP_STRING([--enable-mangling],
1395     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1396   [enable_mangling="${enableval}"],
1397   [enable_mangling=no]
1398 )
1399 if test "x${enable_mangling}" = "xyes" ; then
1400   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1401   GL_LIB="Mangled${GL_LIB}"
1402   OSMESA_LIB="Mangled${OSMESA_LIB}"
1403 fi
1404 AC_SUBST([GL_LIB])
1405 AC_SUBST([OSMESA_LIB])
1406
1407 # Check for libdrm
1408 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1409                   [have_libdrm=yes], [have_libdrm=no])
1410 if test "x$have_libdrm" = xyes; then
1411         DEFINES="$DEFINES -DHAVE_LIBDRM"
1412 fi
1413
1414 require_libdrm() {
1415     if test "x$have_libdrm" != xyes; then
1416        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1417     fi
1418 }
1419
1420
1421 # Select which platform-dependent DRI code gets built
1422 case "$host_os" in
1423 darwin*)
1424     dri_platform='apple' ;;
1425 cygwin*)
1426     dri_platform='windows' ;;
1427 gnu*)
1428     dri_platform='none' ;;
1429 *)
1430     dri_platform='drm' ;;
1431 esac
1432
1433 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1434     have_drisw_kms='yes'
1435 fi
1436
1437 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1438 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1439 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1440 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1441 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1442 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1443 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1444 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1445 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1446
1447 AC_ARG_ENABLE([shared-glapi],
1448     [AS_HELP_STRING([--enable-shared-glapi],
1449         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1450     [enable_shared_glapi="$enableval"],
1451     [enable_shared_glapi=yes])
1452
1453 case "x$enable_opengl$enable_gles1$enable_gles2" in
1454 x*yes*yes*)
1455     if test "x$enable_shared_glapi" = xno; then
1456         AC_MSG_ERROR([shared GLAPI required when building two or more of
1457                       the following APIs - opengl, gles1 gles2])
1458     fi
1459     ;;
1460 esac
1461
1462 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1463
1464 # Build the pipe-drivers as separate libraries/modules.
1465 # Do not touch this unless you know what you are doing.
1466 # XXX: Expose via configure option ?
1467 enable_shared_pipe_drivers=no
1468
1469 dnl
1470 dnl Driver specific build directories
1471 dnl
1472
1473 if test "x$enable_gallium_osmesa" = xyes; then
1474     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1475         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1476     fi
1477     if test "x$enable_osmesa" = xyes; then
1478         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1479     fi
1480 fi
1481
1482 require_dri_shared_libs_and_glapi() {
1483     if test "x$enable_static" = xyes; then
1484         AC_MSG_ERROR([$1 cannot be build as static library])
1485     fi
1486
1487     if test "x$enable_dri" != xyes; then
1488         # There is only a single backend which won't be build/used otherwise.
1489         # XXX: Revisit this as the egl/haiku is a thing.
1490         AC_MSG_ERROR([$1 requires --enable-dri])
1491     fi
1492
1493     if test "x$enable_shared_glapi" != xyes; then
1494         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1495     fi
1496 }
1497
1498 if test "x$enable_dri" = xyes; then
1499     require_dri_shared_libs_and_glapi "DRI"
1500
1501     # not a hard requirement as swrast does not depend on it
1502     if test "x$have_libdrm" = xyes; then
1503         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1504     fi
1505 fi
1506
1507 AC_ARG_ENABLE([driglx-direct],
1508     [AS_HELP_STRING([--disable-driglx-direct],
1509         [disable direct rendering in GLX and EGL for DRI \
1510             @<:@default=auto@:>@])],
1511     [driglx_direct="$enableval"],
1512     [driglx_direct="yes"])
1513
1514 dnl
1515 dnl libGL configuration per driver
1516 dnl
1517 if test "x$enable_glx" != xno; then
1518     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1519 fi
1520 case "x$enable_glx" in
1521 xxlib | xgallium-xlib)
1522     # Xlib-based GLX
1523     dri_modules="x11 xext xcb"
1524     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1525     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1526     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1527     GL_LIB_DEPS="$XLIBGL_LIBS"
1528     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1529     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1530     ;;
1531 xdri)
1532     # DRI-based GLX
1533
1534     # find the DRI deps for libGL
1535     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1536
1537     if test x"$driglx_direct" = xyes; then
1538         if test x"$dri_platform" = xdrm ; then
1539             DEFINES="$DEFINES -DGLX_USE_DRM"
1540             require_libdrm "Direct rendering"
1541
1542             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1543             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1544             if test x"$enable_dri" = xyes; then
1545                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1546             fi
1547
1548             if test x"$enable_dri3" = xyes; then
1549                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1550                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1551                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1552             fi
1553         fi
1554         if test x"$dri_platform" = xapple ; then
1555             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1556         fi
1557         if test x"$dri_platform" = xwindows ; then
1558             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1559         fi
1560     fi
1561
1562     # add xf86vidmode if available
1563     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1564     if test "$HAVE_XF86VIDMODE" = yes ; then
1565         dri_modules="$dri_modules xxf86vm"
1566     fi
1567
1568     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1569     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1570     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1571     GL_LIB_DEPS="$DRIGL_LIBS"
1572
1573     # need DRM libs, $PTHREAD_LIBS, etc.
1574     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1575     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1576     ;;
1577 esac
1578
1579 # This is outside the case (above) so that it is invoked even for non-GLX
1580 # builds.
1581 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1582
1583 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1584 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1585 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1586 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1587
1588 AC_SUBST([X11_INCLUDES])
1589 AC_SUBST([GL_LIB_DEPS])
1590 AC_SUBST([GL_PC_REQ_PRIV])
1591 AC_SUBST([GL_PC_LIB_PRIV])
1592 AC_SUBST([GL_PC_CFLAGS])
1593 AC_SUBST([DRI_PC_REQ_PRIV])
1594 AC_SUBST([GLESv1_CM_LIB_DEPS])
1595 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1596 AC_SUBST([GLESv2_LIB_DEPS])
1597 AC_SUBST([GLESv2_PC_LIB_PRIV])
1598
1599 AC_SUBST([HAVE_XF86VIDMODE])
1600
1601 dnl
1602 dnl More GLX setup
1603 dnl
1604 case "x$enable_glx" in
1605 xxlib | xgallium-xlib)
1606     DEFINES="$DEFINES -DUSE_XSHM"
1607     ;;
1608 xdri)
1609     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1610     if test "x$driglx_direct" = xyes; then
1611         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1612     fi
1613     ;;
1614 esac
1615
1616 dnl
1617 dnl TLS detection
1618 dnl
1619
1620 AC_ARG_ENABLE([glx-tls],
1621     [AS_HELP_STRING([--enable-glx-tls],
1622         [enable TLS support in GLX @<:@default=enabled@:>@])],
1623     [GLX_USE_TLS="$enableval"],
1624     [GLX_USE_TLS=yes])
1625 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1626
1627 if test "x$GLX_USE_TLS" = xyes; then
1628     DEFINES="$DEFINES -DGLX_USE_TLS"
1629 fi
1630
1631 dnl Read-only text section on x86 hardened platforms
1632 AC_ARG_ENABLE([glx-read-only-text],
1633     [AS_HELP_STRING([--enable-glx-read-only-text],
1634         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1635     [enable_glx_read_only_text="$enableval"],
1636     [enable_glx_read_only_text=no])
1637 if test "x$enable_glx_read_only_text" = xyes; then
1638     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1639 fi
1640
1641 dnl
1642 dnl More DRI setup
1643 dnl
1644 dnl Directory for DRI drivers
1645 AC_ARG_WITH([dri-driverdir],
1646     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1647         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1648     [DRI_DRIVER_INSTALL_DIR="$withval"],
1649     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1650 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1651 dnl Extra search path for DRI drivers
1652 AC_ARG_WITH([dri-searchpath],
1653     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1654         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1655     [DRI_DRIVER_SEARCH_DIR="$withval"],
1656     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1657 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1658 dnl Which drivers to build - default is chosen by platform
1659 AC_ARG_WITH([dri-drivers],
1660     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1661         [comma delimited classic DRI drivers list, e.g.
1662         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1663     [with_dri_drivers="$withval"],
1664     [with_dri_drivers=auto])
1665
1666 if test "x$with_dri_drivers" = xauto; then
1667     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1668         with_dri_drivers="yes"
1669     else
1670         with_dri_drivers="no"
1671     fi
1672 fi
1673 if test "x$with_dri_drivers" = xno; then
1674     with_dri_drivers=''
1675 fi
1676
1677 dnl If $with_dri_drivers is yes, drivers will be added through
1678 dnl platform checks. Set DEFINES and LIB_DEPS
1679 if test "x$enable_dri" = xyes; then
1680     # Platform specific settings and drivers to build
1681     case "$host_os" in
1682     linux*)
1683         if test "x$enable_dri3" = xyes; then
1684             DEFINES="$DEFINES -DHAVE_DRI3"
1685         fi
1686
1687         case "$host_cpu" in
1688         powerpc* | sparc*)
1689             # Build only the drivers for cards that exist on PowerPC/sparc
1690             if test "x$with_dri_drivers" = "xyes"; then
1691                 with_dri_drivers="r200 radeon swrast"
1692             fi
1693             ;;
1694         esac
1695         ;;
1696     cygwin*)
1697         if test "x$with_dri_drivers" = "xyes"; then
1698             with_dri_drivers="swrast"
1699         fi
1700         ;;
1701     darwin*)
1702         DEFINES="$DEFINES -DBUILDING_MESA"
1703         if test "x$with_dri_drivers" = "xyes"; then
1704             with_dri_drivers="swrast"
1705         fi
1706         ;;
1707     esac
1708
1709     # default drivers
1710     if test "x$with_dri_drivers" = "xyes"; then
1711         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1712     fi
1713
1714     # Check for expat
1715     PKG_CHECK_MODULES([EXPAT], [expat], [],
1716         # expat version 2.0 and earlier do not provide expat.pc
1717         [AC_CHECK_HEADER([expat.h],[],
1718                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1719          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1720                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1721          EXPAT_LIBS="-lexpat"])
1722
1723     # put all the necessary libs together
1724     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1725 fi
1726
1727 AC_SUBST([DRI_LIB_DEPS])
1728
1729 DRI_DIRS=''
1730 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1731 if test -n "$with_dri_drivers"; then
1732     if test "x$enable_opengl" != xyes; then
1733         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1734     fi
1735
1736     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1737     for driver in $dri_drivers; do
1738         DRI_DIRS="$DRI_DIRS $driver"
1739         case "x$driver" in
1740         xi915)
1741             require_libdrm "i915"
1742             HAVE_I915_DRI=yes
1743             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1744             ;;
1745         xi965)
1746             require_libdrm "i965"
1747             HAVE_I965_DRI=yes
1748             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1749             ;;
1750         xnouveau)
1751             require_libdrm "nouveau"
1752             HAVE_NOUVEAU_DRI=yes
1753             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1754             ;;
1755         xradeon)
1756             require_libdrm "radeon"
1757             HAVE_RADEON_DRI=yes;
1758             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1759             ;;
1760         xr200)
1761             require_libdrm "r200"
1762             HAVE_R200_DRI=yes
1763             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1764             ;;
1765         xswrast)
1766             HAVE_SWRAST_DRI=yes
1767             ;;
1768         *)
1769             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1770             ;;
1771         esac
1772     done
1773     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1774 fi
1775
1776
1777 dnl
1778 dnl Gallium LLVM
1779 dnl Deprecated: kept for backwards compatibility
1780 dnl
1781 AC_ARG_ENABLE([gallium-llvm],
1782     [AS_HELP_STRING([--enable-gallium-llvm],
1783         [DEPRECATED: use --enable-llvm instead])],
1784     [enable_gallium_llvm="$enableval"],
1785     [enable_gallium_llvm=auto])
1786
1787 if test "x$enable_gallium_llvm" != xauto; then
1788    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1789    enable_llvm=$enable_gallium_llvm
1790 fi
1791
1792 dnl
1793 dnl LLVM
1794 dnl
1795 AC_ARG_ENABLE([llvm],
1796     [AS_HELP_STRING([--enable-llvm],
1797         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1798     [enable_llvm="$enableval"],
1799     [enable_llvm=auto])
1800
1801 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1802     if test "x$FOUND_LLVM" = xyes; then
1803         case "$host_cpu" in
1804         i*86|x86_64|amd64) enable_llvm=yes;;
1805         *) enable_llvm=no;;
1806         esac
1807     else
1808         enable_llvm=no
1809     fi
1810 fi
1811
1812 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1813     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1814 fi
1815
1816 #
1817 # Vulkan driver configuration
1818 #
1819
1820 AC_ARG_WITH([vulkan-drivers],
1821     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1822         [comma delimited Vulkan drivers list, e.g.
1823         "intel,radeon"
1824         @<:@default=no@:>@])],
1825     [with_vulkan_drivers="$withval"],
1826     [with_vulkan_drivers="no"])
1827
1828 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1829 # here so that the script doesn't choke on an unknown driver name later.
1830 case "x$with_vulkan_drivers" in
1831     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1832     xno) with_vulkan_drivers='' ;;
1833 esac
1834
1835 AC_ARG_WITH([vulkan-icddir],
1836     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1837         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1838     [VULKAN_ICD_INSTALL_DIR="$withval"],
1839     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1840 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1841
1842 if test -n "$with_vulkan_drivers"; then
1843     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1844         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1845     fi
1846
1847     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1848     for driver in $VULKAN_DRIVERS; do
1849         case "x$driver" in
1850         xintel)
1851             require_libdrm "ANV"
1852             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1853             HAVE_INTEL_VULKAN=yes
1854             ;;
1855         xradeon)
1856             require_libdrm "radv"
1857             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1858             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1859             HAVE_RADEON_VULKAN=yes
1860             ;;
1861         *)
1862             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1863             ;;
1864         esac
1865     done
1866     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1867 fi
1868
1869
1870 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1871 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1872 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1873                                   "x$enable_osmesa" = xyes -o \
1874                                   -n "$DRI_DIRS")
1875
1876 dnl
1877 dnl OSMesa configuration
1878 dnl
1879
1880 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1881 AC_ARG_WITH([osmesa-bits],
1882     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1883         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1884     [osmesa_bits="$withval"],
1885     [osmesa_bits=8])
1886 if test "x$osmesa_bits" != x8; then
1887     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1888         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1889         osmesa_bits=8
1890     fi
1891 fi
1892 case "x$osmesa_bits" in
1893 x8)
1894     OSMESA_LIB="${OSMESA_LIB}"
1895     ;;
1896 x16|x32)
1897     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1898     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1899     ;;
1900 *)
1901     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1902     ;;
1903 esac
1904
1905 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1906     # only link libraries with osmesa if shared
1907     if test "$enable_static" = no; then
1908         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1909     else
1910         OSMESA_LIB_DEPS=""
1911     fi
1912     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1913 fi
1914
1915 AC_SUBST([OSMESA_LIB_DEPS])
1916 AC_SUBST([OSMESA_PC_REQ])
1917 AC_SUBST([OSMESA_PC_LIB_PRIV])
1918
1919 dnl
1920 dnl gbm configuration
1921 dnl
1922 if test "x$enable_gbm" = xyes; then
1923     require_dri_shared_libs_and_glapi "gbm"
1924 fi
1925 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1926 # FINISHME: GBM has a number of dependencies which we should add below
1927 GBM_PC_REQ_PRIV=""
1928 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1929 AC_SUBST([GBM_PC_REQ_PRIV])
1930 AC_SUBST([GBM_PC_LIB_PRIV])
1931
1932 dnl
1933 dnl EGL configuration
1934 dnl
1935
1936 if test "x$enable_egl" = xyes; then
1937     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1938
1939     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1940
1941     require_dri_shared_libs_and_glapi "egl"
1942 fi
1943 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1944 AC_SUBST([EGL_LIB_DEPS])
1945
1946 gallium_st="mesa"
1947
1948 dnl
1949 dnl XA configuration
1950 dnl
1951 if test "x$enable_xa" = xyes; then
1952     if test "x$with_gallium_drivers" = xswrast; then
1953        AC_MSG_ERROR([
1954           Building xa requires at least one non swrast gallium driver.
1955           If you are looking to use libxatracker.so with the VMware driver,
1956           make sure to include svga in the gallium drivers list, apart from
1957           enabling XA.
1958           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1959     fi
1960     gallium_st="$gallium_st xa"
1961 fi
1962 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1963
1964 dnl
1965 dnl Gallium G3DVL configuration
1966 dnl
1967 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1968     if test "x$enable_xvmc" = xauto; then
1969         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1970     fi
1971
1972     if test "x$enable_vdpau" = xauto; then
1973         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1974     fi
1975
1976     if test "x$enable_omx" = xauto; then
1977         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1978     fi
1979
1980     if test "x$enable_va" = xauto; then
1981         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1982     fi
1983 fi
1984
1985 if test "x$enable_dri" = xyes -o \
1986         "x$enable_xvmc" = xyes -o \
1987         "x$enable_vdpau" = xyes -o \
1988         "x$enable_omx" = xyes -o \
1989         "x$enable_va" = xyes; then
1990     need_gallium_vl=yes
1991 fi
1992 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1993
1994 if test "x$enable_xvmc" = xyes -o \
1995         "x$enable_vdpau" = xyes -o \
1996         "x$enable_omx" = xyes -o \
1997         "x$enable_va" = xyes; then
1998     if test x"$enable_dri3" = xyes; then
1999         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2000                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2001     else
2002         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2003     fi
2004     need_gallium_vl_winsys=yes
2005 fi
2006 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2007
2008 if test "x$enable_xvmc" = xyes; then
2009     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2010     gallium_st="$gallium_st xvmc"
2011 fi
2012 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2013
2014 if test "x$enable_vdpau" = xyes; then
2015     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2016     gallium_st="$gallium_st vdpau"
2017     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2018 fi
2019 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2020
2021 if test "x$enable_omx" = xyes; then
2022     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2023     gallium_st="$gallium_st omx"
2024 fi
2025 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2026
2027 if test "x$enable_va" = xyes; then
2028     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2029     gallium_st="$gallium_st va"
2030 fi
2031 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2032
2033 dnl
2034 dnl Nine Direct3D9 configuration
2035 dnl
2036 if test "x$enable_nine" = xyes; then
2037     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2038         AC_MSG_ERROR([nine requires the gallium swrast driver])
2039     fi
2040     if test "x$with_gallium_drivers" = xswrast; then
2041         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2042     fi
2043     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2044         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2045     fi
2046
2047     if test "x$enable_dri3" = xno; then
2048         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2049     fi
2050
2051     gallium_st="$gallium_st nine"
2052 fi
2053 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2054
2055 dnl
2056 dnl OpenCL configuration
2057 dnl
2058
2059 AC_ARG_WITH([clang-libdir],
2060    [AS_HELP_STRING([--with-clang-libdir],
2061          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2062    [CLANG_LIBDIR="$withval"],
2063    [CLANG_LIBDIR=''])
2064
2065 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2066
2067 if test "x$enable_opencl" = xyes; then
2068     if test -z "$with_gallium_drivers"; then
2069         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2070     fi
2071
2072     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2073         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2074     fi
2075
2076     if test "x$have_libclc" = xno; then
2077         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2078                     Make sure the directory containing libclc.pc is specified in your
2079                     PKG_CONFIG_PATH environment variable.
2080                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2081     else
2082         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2083         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2084         AC_SUBST([LIBCLC_INCLUDEDIR])
2085         AC_SUBST([LIBCLC_LIBEXECDIR])
2086     fi
2087
2088     gallium_st="$gallium_st clover"
2089
2090     if test "x$enable_opencl_icd" = xyes; then
2091         OPENCL_LIBNAME="MesaOpenCL"
2092     else
2093         OPENCL_LIBNAME="OpenCL"
2094     fi
2095
2096     if test "x$have_libelf" != xyes; then
2097        AC_MSG_ERROR([Clover requires libelf])
2098     fi
2099
2100     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2101         altivec_enabled=no
2102         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2103         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2104         #error "AltiVec not enabled"
2105         #endif
2106         ])], altivec_enabled=yes)
2107
2108         if test "$altivec_enabled" = yes; then
2109             CLOVER_STD_OVERRIDE="-std=gnu++11"
2110         fi
2111         AC_SUBST([CLOVER_STD_OVERRIDE])
2112     fi
2113
2114     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2115
2116     llvm_add_default_components "opencl"
2117     llvm_add_component "all-targets" "opencl"
2118     llvm_add_component "linker" "opencl"
2119     llvm_add_component "instrumentation" "opencl"
2120     llvm_add_component "ipo" "opencl"
2121     llvm_add_component "irreader" "opencl"
2122     llvm_add_component "option" "opencl"
2123     llvm_add_component "objcarcopts" "opencl"
2124     llvm_add_component "profiledata" "opencl"
2125
2126     dnl Check for Clang internal headers
2127     if test -z "$CLANG_LIBDIR"; then
2128         CLANG_LIBDIR=${LLVM_LIBDIR}
2129     fi
2130     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2131     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2132         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2133 fi
2134 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2135 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2136 AC_SUBST([OPENCL_LIBNAME])
2137 AC_SUBST([CLANG_RESOURCE_DIR])
2138
2139 dnl
2140 dnl Gallium configuration
2141 dnl
2142 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2143
2144 dnl
2145 dnl EGL Platforms configuration
2146 dnl
2147 AC_ARG_WITH([egl-platforms],
2148     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2149         [comma delimited native platforms libEGL supports, e.g.
2150         "x11,drm" @<:@default=auto@:>@])],
2151     [with_egl_platforms="$withval"],
2152     [if test "x$enable_egl" = xyes; then
2153         if test "x$enable_gbm" = xyes; then
2154            with_egl_platforms="x11,drm"
2155         else
2156            with_egl_platforms="x11"
2157         fi
2158     else
2159         with_egl_platforms=""
2160     fi])
2161
2162 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2163         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2164         WAYLAND_SCANNER='')
2165 if test "x$WAYLAND_SCANNER" = x; then
2166     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
2167 fi
2168
2169 # Do per-EGL platform setups and checks
2170 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2171 for plat in $egl_platforms; do
2172         case "$plat" in
2173         wayland)
2174
2175                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2176
2177                 if test "x$WAYLAND_SCANNER" = "x:"; then
2178                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2179                 fi
2180                 ;;
2181
2182         x11)
2183                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2184                 ;;
2185
2186         drm)
2187                 test "x$enable_gbm" = "xno" &&
2188                         AC_MSG_ERROR([EGL platform drm needs gbm])
2189                 ;;
2190
2191         surfaceless)
2192                 ;;
2193
2194         android)
2195                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2196                 ;;
2197
2198         *)
2199                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2200                 ;;
2201         esac
2202
2203         case "$plat" in
2204         wayland|drm|surfaceless)
2205                 require_libdrm "Platform $plat"
2206                 ;;
2207         esac
2208 done
2209
2210 # libEGL wants to default to the first platform specified in
2211 # ./configure.  parse that here.
2212 if test "x$egl_platforms" != "x"; then
2213     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2214     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2215 else
2216     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2217 fi
2218
2219 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2220 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2221 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2222 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2223 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2224
2225 AC_SUBST([EGL_NATIVE_PLATFORM])
2226 AC_SUBST([EGL_CFLAGS])
2227
2228 # If we don't have the X11 platform, set this define so we don't try to include
2229 # the X11 headers.
2230 if ! echo "$egl_platforms" | grep -q 'x11'; then
2231     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2232     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2233 fi
2234
2235 dnl Directory for XVMC libs
2236 AC_ARG_WITH([xvmc-libdir],
2237     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2238         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2239     [XVMC_LIB_INSTALL_DIR="$withval"],
2240     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2241 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2242
2243 dnl
2244 dnl Gallium Tests
2245 dnl
2246 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2247
2248 dnl Directory for VDPAU libs
2249 AC_ARG_WITH([vdpau-libdir],
2250     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2251         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2252     [VDPAU_LIB_INSTALL_DIR="$withval"],
2253     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2254 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2255
2256 dnl Directory for OMX libs
2257
2258 AC_ARG_WITH([omx-libdir],
2259     [AS_HELP_STRING([--with-omx-libdir=DIR],
2260         [directory for the OMX libraries])],
2261     [OMX_LIB_INSTALL_DIR="$withval"],
2262     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2263                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2264 AC_SUBST([OMX_LIB_INSTALL_DIR])
2265
2266 dnl Directory for VA libs
2267
2268 AC_ARG_WITH([va-libdir],
2269     [AS_HELP_STRING([--with-va-libdir=DIR],
2270         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2271     [VA_LIB_INSTALL_DIR="$withval"],
2272     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2273 AC_SUBST([VA_LIB_INSTALL_DIR])
2274
2275 AC_ARG_WITH([d3d-libdir],
2276     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2277         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2278     [D3D_DRIVER_INSTALL_DIR="$withval"],
2279     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2280 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2281
2282 dnl
2283 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2284 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2285 dnl architectures.
2286 dnl
2287 r300_require_llvm() {
2288     case "$host" in *gnux32) return;; esac
2289     case "$host_cpu" in
2290     i*86|x86_64|amd64) require_llvm $1
2291         ;;
2292     esac
2293 }
2294
2295 dnl
2296 dnl DRM is needed by X, Wayland, and offscreen rendering.
2297 dnl Surfaceless is an alternative for the last one.
2298 dnl
2299 require_basic_egl() {
2300     case "$with_egl_platforms" in
2301         *drm*|*surfaceless*)
2302             ;;
2303         *)
2304             AC_MSG_ERROR([$1 requires one of these:
2305                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2306                   2) --with-egl-platforms=surfaceless (offscreen only)
2307                   Recommended options: drm,x11])
2308             ;;
2309     esac
2310 }
2311
2312 swr_require_cxx_feature_flags() {
2313     feature_name="$1"
2314     preprocessor_test="$2"
2315     option_list="$3"
2316     output_var="$4"
2317
2318     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2319     AC_LANG_PUSH([C++])
2320     save_CXXFLAGS="$CXXFLAGS"
2321     save_IFS="$IFS"
2322     IFS=","
2323     found=0
2324     for opts in $option_list
2325     do
2326         unset IFS
2327         CXXFLAGS="$opts $save_CXXFLAGS"
2328         AC_COMPILE_IFELSE(
2329             [AC_LANG_PROGRAM(
2330                 [   #if !($preprocessor_test)
2331                     #error
2332                     #endif
2333                 ])],
2334             [found=1; break],
2335             [])
2336         IFS=","
2337     done
2338     IFS="$save_IFS"
2339     CXXFLAGS="$save_CXXFLAGS"
2340     AC_LANG_POP([C++])
2341     if test $found -eq 1; then
2342         AC_MSG_RESULT([$opts])
2343         eval "$output_var=\$opts"
2344         return 0
2345     fi
2346     AC_MSG_RESULT([no])
2347     AC_MSG_ERROR([swr requires $feature_name support])
2348     return 1
2349 }
2350
2351 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2352 if test -n "$with_gallium_drivers"; then
2353     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2354     for driver in $gallium_drivers; do
2355         case "x$driver" in
2356         xsvga)
2357             HAVE_GALLIUM_SVGA=yes
2358             require_libdrm "svga"
2359             ;;
2360         xi915)
2361             HAVE_GALLIUM_I915=yes
2362             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2363             require_libdrm "Gallium i915"
2364             ;;
2365         xr300)
2366             HAVE_GALLIUM_R300=yes
2367             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2368             require_libdrm "r300"
2369             r300_require_llvm "r300"
2370             ;;
2371         xr600)
2372             HAVE_GALLIUM_R600=yes
2373             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2374             require_libdrm "r600"
2375             if test "x$enable_llvm" = xyes; then
2376                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2377
2378                 llvm_add_component "asmparser" "r600"
2379                 llvm_add_component "bitreader" "r600"
2380             fi
2381             ;;
2382         xradeonsi)
2383             HAVE_GALLIUM_RADEONSI=yes
2384             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2385             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2386             require_libdrm "radeonsi"
2387             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2388             if test "x$enable_egl" = xyes; then
2389                 require_basic_egl "radeonsi"
2390             fi
2391             ;;
2392         xnouveau)
2393             HAVE_GALLIUM_NOUVEAU=yes
2394             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2395             require_libdrm "nouveau"
2396             ;;
2397         xfreedreno)
2398             HAVE_GALLIUM_FREEDRENO=yes
2399             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2400             require_libdrm "freedreno"
2401             ;;
2402         xetnaviv)
2403             HAVE_GALLIUM_ETNAVIV=yes
2404             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2405             require_libdrm "etnaviv"
2406             ;;
2407        ximx)
2408             HAVE_GALLIUM_IMX=yes
2409             ;;
2410         xswrast)
2411             HAVE_GALLIUM_SOFTPIPE=yes
2412             if test "x$enable_llvm" = xyes; then
2413                 HAVE_GALLIUM_LLVMPIPE=yes
2414             fi
2415             ;;
2416         xswr)
2417             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2418
2419             swr_require_cxx_feature_flags "C++14" "__cplusplus >= 201402L" \
2420                 "-std=c++14" \
2421                 SWR_CXX14_CXXFLAGS
2422             AC_SUBST([SWR_CXX14_CXXFLAGS])
2423
2424             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2425                 ",-mavx,-march=core-avx" \
2426                 SWR_AVX_CXXFLAGS
2427             AC_SUBST([SWR_AVX_CXXFLAGS])
2428
2429             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2430                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2431                 SWR_AVX2_CXXFLAGS
2432             AC_SUBST([SWR_AVX2_CXXFLAGS])
2433
2434             HAVE_GALLIUM_SWR=yes
2435             ;;
2436         xvc4)
2437             HAVE_GALLIUM_VC4=yes
2438             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2439             require_libdrm "vc4"
2440
2441             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2442                               [USE_VC4_SIMULATOR=yes;
2443                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2444                               [USE_VC4_SIMULATOR=no])
2445             ;;
2446         xvirgl)
2447             HAVE_GALLIUM_VIRGL=yes
2448             require_libdrm "virgl"
2449             require_basic_egl "virgl"
2450             ;;
2451         *)
2452             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2453             ;;
2454         esac
2455     done
2456 fi
2457
2458 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2459     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2460     llvm_add_default_components "gallium"
2461 fi
2462
2463 dnl We need to validate some needed dependencies for renderonly drivers.
2464
2465 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2466     AC_MSG_ERROR([Building with imx requires etnaviv])
2467 fi
2468
2469 dnl
2470 dnl Set defines and buildtime variables only when using LLVM.
2471 dnl
2472 if test "x$enable_llvm" = xyes; then
2473     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2474
2475     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2476     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2477     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2478
2479     dnl Set LLVM_LIBS - This is done after the driver configuration so
2480     dnl that drivers can add additional components to LLVM_COMPONENTS.
2481     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2482     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2483     dnl this was causing the same libraries to be appear multiple times
2484     dnl in LLVM_LIBS.
2485
2486     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2487        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2488     fi
2489     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2490
2491     dnl llvm-config may not give the right answer when llvm is a built as a
2492     dnl single shared library, so we must work the library name out for
2493     dnl ourselves.
2494     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2495     if test "x$enable_llvm_shared_libs" = xyes; then
2496         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2497         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2498         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2499
2500         if test "x$llvm_have_one_so" = xyes; then
2501             dnl LLVM was built using auto*, so there is only one shared object.
2502             LLVM_LIBS="-l$LLVM_SO_NAME"
2503         else
2504             dnl If LLVM was built with CMake, there will be one shared object per
2505             dnl component.
2506             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2507                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2508         Please make sure you have built llvm with the --enable-shared option
2509         and that your llvm libraries are installed in $LLVM_LIBDIR
2510         If you have installed your llvm libraries to a different directory you
2511         can use the --with-llvm-prefix= configure flag to specify this directory.
2512         NOTE: Mesa is attempting to use llvm shared libraries by default.
2513         If you do not want to build with llvm shared libraries and instead want to
2514         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2515         invocation and rebuild.])])
2516
2517            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2518            dnl install uses a shared object for each component and we have
2519            dnl already added all of these objects to LLVM_LIBS.
2520         fi
2521     else
2522         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2523         dnl We need to link to llvm system libs when using static libs
2524         dnl However, only llvm 3.5+ provides --system-libs
2525         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2526             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2527         fi
2528     fi
2529 fi
2530
2531 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2532 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2533 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2534 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2535 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2536 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2537                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2538 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2539 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2540 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2541 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2542 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2543 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2544 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2545 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2546                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2547                                          "x$HAVE_GALLIUM_SWR" = xyes)
2548 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2549 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2550
2551 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2552
2553 if test "x$enable_dri" = xyes; then
2554     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2555 fi
2556
2557 if test "x$have_drisw_kms" = xyes; then
2558     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2559 fi
2560 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2561
2562 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2563 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2564 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2565 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2566 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2567 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2568
2569 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2570 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2571
2572 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2573                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2574                                       "x$HAVE_RADEON_VULKAN" = xyes)
2575
2576 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2577                                         "x$HAVE_I965_DRI" = xyes)
2578
2579 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2580                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2581                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2582 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2583 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2584 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2585 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2586
2587 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2588 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2589 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2590 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2591                                         "x$enable_gallium_osmesa" = xyes)
2592
2593 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2594 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2595 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2596
2597 AC_SUBST([NINE_MAJOR], 1)
2598 AC_SUBST([NINE_MINOR], 0)
2599 AC_SUBST([NINE_TINY], 0)
2600 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2601
2602 AC_SUBST([VDPAU_MAJOR], 1)
2603 AC_SUBST([VDPAU_MINOR], 0)
2604
2605 if test "x$enable_va" = xyes; then
2606     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2607     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2608 fi
2609 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2610 AC_SUBST([VA_MINOR], $VA_MINOR)
2611
2612 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2613
2614 AC_SUBST([XVMC_MAJOR], 1)
2615 AC_SUBST([XVMC_MINOR], 0)
2616
2617 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2618 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2619 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2620 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2621
2622 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2623 AC_SUBST([XA_MINOR], $XA_MINOR)
2624 AC_SUBST([XA_TINY], $XA_TINY)
2625 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2626
2627 AC_ARG_ENABLE(valgrind,
2628               [AS_HELP_STRING([--enable-valgrind],
2629                              [Build mesa with valgrind support (default: auto)])],
2630                              [VALGRIND=$enableval], [VALGRIND=auto])
2631 if test "x$VALGRIND" != xno; then
2632         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2633 fi
2634 AC_MSG_CHECKING([whether to enable Valgrind support])
2635 if test "x$VALGRIND" = xauto; then
2636         VALGRIND="$have_valgrind"
2637 fi
2638
2639 if test "x$VALGRIND" = "xyes"; then
2640         if ! test "x$have_valgrind" = xyes; then
2641                 AC_MSG_ERROR([Valgrind support required but not present])
2642         fi
2643         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2644 fi
2645
2646 AC_MSG_RESULT([$VALGRIND])
2647
2648 dnl Restore LDFLAGS and CPPFLAGS
2649 LDFLAGS="$_SAVE_LDFLAGS"
2650 CPPFLAGS="$_SAVE_CPPFLAGS"
2651
2652 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2653 if test "x$acv_mesa_CLANG" = xyes; then
2654     CFLAGS="$CFLAGS -Qunused-arguments"
2655     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2656 fi
2657
2658 dnl Add user CFLAGS and CXXFLAGS
2659 CFLAGS="$CFLAGS $USER_CFLAGS"
2660 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2661
2662 dnl Substitute the config
2663 AC_CONFIG_FILES([Makefile
2664                 src/Makefile
2665                 src/amd/Makefile
2666                 src/amd/vulkan/Makefile
2667                 src/compiler/Makefile
2668                 src/egl/Makefile
2669                 src/egl/main/egl.pc
2670                 src/egl/wayland/wayland-drm/Makefile
2671                 src/egl/wayland/wayland-egl/Makefile
2672                 src/egl/wayland/wayland-egl/wayland-egl.pc
2673                 src/gallium/Makefile
2674                 src/gallium/auxiliary/Makefile
2675                 src/gallium/auxiliary/pipe-loader/Makefile
2676                 src/gallium/drivers/freedreno/Makefile
2677                 src/gallium/drivers/ddebug/Makefile
2678                 src/gallium/drivers/i915/Makefile
2679                 src/gallium/drivers/llvmpipe/Makefile
2680                 src/gallium/drivers/noop/Makefile
2681                 src/gallium/drivers/nouveau/Makefile
2682                 src/gallium/drivers/r300/Makefile
2683                 src/gallium/drivers/r600/Makefile
2684                 src/gallium/drivers/radeon/Makefile
2685                 src/gallium/drivers/radeonsi/Makefile
2686                 src/gallium/drivers/rbug/Makefile
2687                 src/gallium/drivers/softpipe/Makefile
2688                 src/gallium/drivers/svga/Makefile
2689                 src/gallium/drivers/swr/Makefile
2690                 src/gallium/drivers/trace/Makefile
2691                 src/gallium/drivers/etnaviv/Makefile
2692                 src/gallium/drivers/imx/Makefile
2693                 src/gallium/drivers/vc4/Makefile
2694                 src/gallium/drivers/virgl/Makefile
2695                 src/gallium/state_trackers/clover/Makefile
2696                 src/gallium/state_trackers/dri/Makefile
2697                 src/gallium/state_trackers/glx/xlib/Makefile
2698                 src/gallium/state_trackers/nine/Makefile
2699                 src/gallium/state_trackers/omx/Makefile
2700                 src/gallium/state_trackers/osmesa/Makefile
2701                 src/gallium/state_trackers/va/Makefile
2702                 src/gallium/state_trackers/vdpau/Makefile
2703                 src/gallium/state_trackers/xa/Makefile
2704                 src/gallium/state_trackers/xvmc/Makefile
2705                 src/gallium/targets/d3dadapter9/Makefile
2706                 src/gallium/targets/d3dadapter9/d3d.pc
2707                 src/gallium/targets/dri/Makefile
2708                 src/gallium/targets/libgl-xlib/Makefile
2709                 src/gallium/targets/omx/Makefile
2710                 src/gallium/targets/opencl/Makefile
2711                 src/gallium/targets/opencl/mesa.icd
2712                 src/gallium/targets/osmesa/Makefile
2713                 src/gallium/targets/osmesa/osmesa.pc
2714                 src/gallium/targets/pipe-loader/Makefile
2715                 src/gallium/targets/va/Makefile
2716                 src/gallium/targets/vdpau/Makefile
2717                 src/gallium/targets/xa/Makefile
2718                 src/gallium/targets/xa/xatracker.pc
2719                 src/gallium/targets/xvmc/Makefile
2720                 src/gallium/tests/trivial/Makefile
2721                 src/gallium/tests/unit/Makefile
2722                 src/gallium/winsys/etnaviv/drm/Makefile
2723                 src/gallium/winsys/imx/drm/Makefile
2724                 src/gallium/winsys/freedreno/drm/Makefile
2725                 src/gallium/winsys/i915/drm/Makefile
2726                 src/gallium/winsys/nouveau/drm/Makefile
2727                 src/gallium/winsys/radeon/drm/Makefile
2728                 src/gallium/winsys/amdgpu/drm/Makefile
2729                 src/gallium/winsys/svga/drm/Makefile
2730                 src/gallium/winsys/sw/dri/Makefile
2731                 src/gallium/winsys/sw/kms-dri/Makefile
2732                 src/gallium/winsys/sw/null/Makefile
2733                 src/gallium/winsys/sw/wrapper/Makefile
2734                 src/gallium/winsys/sw/xlib/Makefile
2735                 src/gallium/winsys/vc4/drm/Makefile
2736                 src/gallium/winsys/virgl/drm/Makefile
2737                 src/gallium/winsys/virgl/vtest/Makefile
2738                 src/gbm/Makefile
2739                 src/gbm/main/gbm.pc
2740                 src/glx/Makefile
2741                 src/glx/apple/Makefile
2742                 src/glx/tests/Makefile
2743                 src/glx/windows/Makefile
2744                 src/glx/windows/windowsdriproto.pc
2745                 src/gtest/Makefile
2746                 src/intel/Makefile
2747                 src/loader/Makefile
2748                 src/mapi/Makefile
2749                 src/mapi/es1api/glesv1_cm.pc
2750                 src/mapi/es2api/glesv2.pc
2751                 src/mapi/glapi/gen/Makefile
2752                 src/mesa/Makefile
2753                 src/mesa/gl.pc
2754                 src/mesa/drivers/dri/dri.pc
2755                 src/mesa/drivers/dri/common/Makefile
2756                 src/mesa/drivers/dri/common/xmlpool/Makefile
2757                 src/mesa/drivers/dri/i915/Makefile
2758                 src/mesa/drivers/dri/i965/Makefile
2759                 src/mesa/drivers/dri/Makefile
2760                 src/mesa/drivers/dri/nouveau/Makefile
2761                 src/mesa/drivers/dri/r200/Makefile
2762                 src/mesa/drivers/dri/radeon/Makefile
2763                 src/mesa/drivers/dri/swrast/Makefile
2764                 src/mesa/drivers/osmesa/Makefile
2765                 src/mesa/drivers/osmesa/osmesa.pc
2766                 src/mesa/drivers/x11/Makefile
2767                 src/mesa/main/tests/Makefile
2768                 src/util/Makefile
2769                 src/util/tests/hash_table/Makefile
2770                 src/vulkan/Makefile])
2771
2772 AC_OUTPUT
2773
2774 # Fix up dependencies in *.Plo files, where we changed the extension of a
2775 # source file
2776 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2777
2778
2779 dnl
2780 dnl Output some configuration info for the user
2781 dnl
2782 echo ""
2783 echo "        prefix:          $prefix"
2784 echo "        exec_prefix:     $exec_prefix"
2785 echo "        libdir:          $libdir"
2786 echo "        includedir:      $includedir"
2787
2788 dnl API info
2789 echo ""
2790 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2791
2792 dnl Driver info
2793 echo ""
2794 case "x$enable_osmesa$enable_gallium_osmesa" in
2795 xnoyes)
2796         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2797         ;;
2798 xyesno)
2799         echo "        OSMesa:          lib$OSMESA_LIB"
2800         ;;
2801 xnono)
2802         echo "        OSMesa:          no"
2803         ;;
2804 esac
2805
2806 echo ""
2807 if test "x$enable_dri" != xno; then
2808         echo "        DRI platform:    $dri_platform"
2809         if test -z "$DRI_DIRS"; then
2810             echo "        DRI drivers:     no"
2811         else
2812             echo "        DRI drivers:     $DRI_DIRS"
2813         fi
2814         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2815 fi
2816
2817 case "x$enable_glx" in
2818 xdri)
2819     echo "        GLX:             DRI-based"
2820     ;;
2821 xxlib)
2822     echo "        GLX:             Xlib-based"
2823     ;;
2824 xgallium-xlib)
2825     echo "        GLX:             Xlib-based (Gallium)"
2826     ;;
2827 *)
2828     echo "        GLX:             $enable_glx"
2829     ;;
2830 esac
2831
2832 dnl EGL
2833 echo ""
2834 echo "        EGL:             $enable_egl"
2835 if test "$enable_egl" = yes; then
2836     echo "        EGL platforms:   $egl_platforms"
2837
2838     egl_drivers=""
2839     if test "x$enable_dri" != "xno"; then
2840         egl_drivers="$egl_drivers builtin:egl_dri2"
2841     fi
2842     if test "x$enable_dri3" != "xno"; then
2843         egl_drivers="$egl_drivers builtin:egl_dri3"
2844     fi
2845
2846     echo "        EGL drivers:    $egl_drivers"
2847 fi
2848 if test "x$enable_gbm" = xyes; then
2849     echo "        GBM:             yes"
2850 else
2851     echo "        GBM:             no"
2852 fi
2853
2854 # Vulkan
2855 echo ""
2856 if test "x$VULKAN_DRIVERS" != x; then
2857     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2858     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2859 else
2860     echo "        Vulkan drivers:  no"
2861 fi
2862
2863 echo ""
2864 if test "x$enable_llvm" = xyes; then
2865     echo "        llvm:            yes"
2866     echo "        llvm-config:     $LLVM_CONFIG"
2867     echo "        llvm-version:    $LLVM_VERSION"
2868 else
2869     echo "        llvm:            no"
2870 fi
2871
2872 echo ""
2873 if test -n "$with_gallium_drivers"; then
2874     echo "        Gallium drivers: $gallium_drivers"
2875     echo "        Gallium st:      $gallium_st"
2876 else
2877     echo "        Gallium:         no"
2878 fi
2879
2880 echo ""
2881 if test "x$enable_gallium_extra_hud" != xyes; then
2882     echo "        HUD extra stats: no"
2883 else
2884     echo "        HUD extra stats: yes"
2885 fi
2886
2887 if test "x$enable_lmsensors" != xyes; then
2888     echo "        HUD lmsensors:   no"
2889 else
2890     echo "        HUD lmsensors:   yes"
2891 fi
2892
2893 dnl Libraries
2894 echo ""
2895 echo "        Shared libs:     $enable_shared"
2896 echo "        Static libs:     $enable_static"
2897 echo "        Shared-glapi:    $enable_shared_glapi"
2898
2899 dnl Compiler options
2900 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2901 cflags=`echo $CFLAGS | \
2902     $SED 's/^ *//;s/  */ /;s/ *$//'`
2903 cxxflags=`echo $CXXFLAGS | \
2904     $SED 's/^ *//;s/  */ /;s/ *$//'`
2905 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2906 echo ""
2907 echo "        CFLAGS:          $cflags"
2908 echo "        CXXFLAGS:        $cxxflags"
2909 echo "        Macros:          $defines"
2910 echo ""
2911 if test "x$enable_llvm" = xyes; then
2912     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2913     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2914     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2915     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2916     echo ""
2917 fi
2918 echo "        PYTHON2:         $PYTHON2"
2919
2920 echo ""
2921 echo "        Run '${MAKE-make}' to build Mesa"
2922 echo ""