configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.68
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.8.0
  93 LIBSENSORS_REQUIRED=4.0.0
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112 AC_CHECK_PROG(XXD, xxd, [xxd])
 113
 114 AX_PROG_BISON([],
 115               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 116                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 117 AX_PROG_FLEX([],
 118              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 119                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 120
 121 AC_CHECK_PROG(INDENT, indent, indent, cat)
 122 if test "x$INDENT" != "xcat"; then
 123     # Only GNU indent is supported
 124     INDENT_VERSION=`indent --version | grep GNU`
 125     if test $? -eq 0; then
 126        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 127     else
 128        INDENT="cat"
 129     fi
 130 fi
 131
 132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 133
 134 if test -z "$PYTHON2"; then
 135     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 136         AC_MSG_ERROR([Python not found - unable to generate sources])
 137     fi
 138 else
 139     if test "x$acv_mako_found" = xno; then
 140         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 141             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 142         fi
 143     fi
 144 fi
 145
 146 AC_PROG_INSTALL
 147
 148 dnl We need a POSIX shell for parts of the build. Assume we have one
 149 dnl in most cases.
 150 case "$host_os" in
 151 solaris*)
 152     # Solaris /bin/sh is too old/non-POSIX compliant
 153     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 154     SHELL="$POSIX_SHELL"
 155     ;;
 156 esac
 157
 158 dnl clang is mostly GCC-compatible, but its version is much lower,
 159 dnl so we have to check for it.
 160 AC_MSG_CHECKING([if compiling with clang])
 161
 162 AC_COMPILE_IFELSE(
 163 [AC_LANG_PROGRAM([], [[
 164 #ifndef __clang__
 165        not clang
 166 #endif
 167 ]])],
 168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 169
 170 AC_MSG_RESULT([$acv_mesa_CLANG])
 171
 172 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 173 dnl versions are explictly not supported.
 174 GEN_ASM_OFFSETS=no
 175 USE_GNU99=no
 176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 177     AC_MSG_CHECKING([whether gcc version is sufficient])
 178     major=0
 179     minor=0
 180
 181     GCC_VERSION=`$CC -dumpversion`
 182     if test $? -eq 0; then
 183         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 184         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 188         AC_MSG_RESULT([no])
 189         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 190     else
 191         AC_MSG_RESULT([yes])
 192     fi
 193
 194     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 195         USE_GNU99=yes
 196     fi
 197     if test "x$cross_compiling" = xyes; then
 198         GEN_ASM_OFFSETS=yes
 199     fi
 200 fi
 201
 202 dnl We don't support building Mesa with Sun C compiler
 203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 205 if test "x$SUNCC" = xyes; then
 206     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 207 fi
 208
 209 dnl Check for compiler builtins
 210 AX_GCC_BUILTIN([__builtin_bswap32])
 211 AX_GCC_BUILTIN([__builtin_bswap64])
 212 AX_GCC_BUILTIN([__builtin_clz])
 213 AX_GCC_BUILTIN([__builtin_clzll])
 214 AX_GCC_BUILTIN([__builtin_ctz])
 215 AX_GCC_BUILTIN([__builtin_expect])
 216 AX_GCC_BUILTIN([__builtin_ffs])
 217 AX_GCC_BUILTIN([__builtin_ffsll])
 218 AX_GCC_BUILTIN([__builtin_popcount])
 219 AX_GCC_BUILTIN([__builtin_popcountll])
 220 AX_GCC_BUILTIN([__builtin_unreachable])
 221
 222 AX_GCC_FUNC_ATTRIBUTE([const])
 223 AX_GCC_FUNC_ATTRIBUTE([flatten])
 224 AX_GCC_FUNC_ATTRIBUTE([format])
 225 AX_GCC_FUNC_ATTRIBUTE([malloc])
 226 AX_GCC_FUNC_ATTRIBUTE([packed])
 227 AX_GCC_FUNC_ATTRIBUTE([pure])
 228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 229 AX_GCC_FUNC_ATTRIBUTE([unused])
 230 AX_GCC_FUNC_ATTRIBUTE([visibility])
 231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 232 AX_GCC_FUNC_ATTRIBUTE([weak])
 233
 234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 235
 236 dnl Make sure the pkg-config macros are defined
 237 m4_ifndef([PKG_PROG_PKG_CONFIG],
 238     [m4_fatal([Could not locate the pkg-config autoconf macros.
 239   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 240   are in a different location, try setting the environment variable
 241   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 242 PKG_PROG_PKG_CONFIG()
 243
 244 dnl LIB_DIR - library basename
 245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 246 AC_SUBST([LIB_DIR])
 247
 248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 249 _SAVE_LDFLAGS="$LDFLAGS"
 250 _SAVE_CPPFLAGS="$CPPFLAGS"
 251
 252 dnl Compiler macros
 253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 254 AC_SUBST([DEFINES])
 255 android=no
 256 case "$host_os" in
 257 *-android)
 258     android=yes
 259     ;;
 260 linux*|*-gnu*|gnu*|cygwin*)
 261     DEFINES="$DEFINES -D_GNU_SOURCE"
 262     ;;
 263 solaris*)
 264     DEFINES="$DEFINES -DSVR4"
 265     ;;
 266 esac
 267
 268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # We don't want floating-point math functions to set errno or trap
 305     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # We don't want floating-point math functions to set errno or trap
 344     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int param;
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 380     c = _mm_max_epu32(a, b);
 381     return _mm_cvtsi128_si32(c);
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Check for new-style atomic builtins
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 int main() {
 393     int n;
 394     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 397     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 398 fi
 399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 DEFAULT_GL_LIB_NAME=GL
 525
 526 dnl
 527 dnl Check if linker supports -Bsymbolic
 528 dnl
 529 save_LDFLAGS=$LDFLAGS
 530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 532 AC_LINK_IFELSE(
 533     [AC_LANG_SOURCE([int main() { return 0;}])],
 534     [AC_MSG_RESULT([yes])
 535         BSYMBOLIC="-Wl,-Bsymbolic";],
 536     [AC_MSG_RESULT([no])
 537         BSYMBOLIC="";])
 538 LDFLAGS=$save_LDFLAGS
 539
 540 AC_SUBST([BSYMBOLIC])
 541
 542 dnl
 543 dnl Check if linker supports garbage collection
 544 dnl
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";],
 552     [AC_MSG_RESULT([no])
 553         GC_SECTIONS="";])
 554 LDFLAGS=$save_LDFLAGS
 555
 556 AC_SUBST([GC_SECTIONS])
 557
 558 dnl
 559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 560 dnl so when these flags are passed to ld via libtool the checks will fail
 561 dnl
 562 case "$host_os" in
 563 openbsd* | darwin* )
 564     LD_NO_UNDEFINED="" ;;
 565 *)
 566     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 567 esac
 568
 569 AC_SUBST([LD_NO_UNDEFINED])
 570
 571 dnl
 572 dnl Check if linker supports version scripts
 573 dnl
 574 AC_MSG_CHECKING([if the linker supports version-scripts])
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 577 cat > conftest.map <<EOF
 578 VERSION_1 {
 579      global:
 580          main;
 581
 582      local:
 583          *;
 584 };
 585 EOF
 586 AC_LINK_IFELSE(
 587     [AC_LANG_SOURCE([int main() { return 0;}])],
 588     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 589     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 590 LDFLAGS=$save_LDFLAGS
 591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 592
 593 dnl
 594 dnl Check if linker supports dynamic list files
 595 dnl
 596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 597 save_LDFLAGS=$LDFLAGS
 598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 599 cat > conftest.dyn <<EOF
 600 {
 601         radeon_drm_winsys_create;
 602 };
 603 EOF
 604 AC_LINK_IFELSE(
 605     [AC_LANG_SOURCE([int main() { return 0;}])],
 606     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 607     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 608 LDFLAGS=$save_LDFLAGS
 609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 610
 611 dnl
 612 dnl compatibility symlinks
 613 dnl
 614 case "$host_os" in
 615 linux* )
 616     HAVE_COMPAT_SYMLINKS=yes ;;
 617 * )
 618     HAVE_COMPAT_SYMLINKS=no ;;
 619 esac
 620
 621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 622
 623 DEFAULT_GL_LIB_NAME=GL
 624
 625 dnl
 626 dnl Libglvnd configuration
 627 dnl
 628 AC_ARG_ENABLE([libglvnd],
 629     [AS_HELP_STRING([--enable-libglvnd],
 630         [Build for libglvnd @<:@default=disabled@:>@])],
 631     [enable_libglvnd="$enableval"],
 632     [enable_libglvnd=no])
 633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 635 if test "x$enable_libglvnd" = xyes ; then
 636     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 637     DEFAULT_GL_LIB_NAME=GLX_mesa
 638 fi
 639
 640 dnl
 641 dnl library names
 642 dnl
 643 dnl Unfortunately we need to do a few things that libtool can't help us with,
 644 dnl so we need some knowledge of shared library filenames:
 645 dnl
 646 dnl LIB_EXT is the extension used when creating symlinks for alternate
 647 dnl filenames for a shared library which will be dynamically loaded
 648 dnl
 649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 650 dnl the file for a shared library we wish to link with
 651 dnl
 652 case "$host_os" in
 653 darwin* )
 654     LIB_EXT='dylib'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 cygwin* )
 658     LIB_EXT='dll'
 659     IMP_LIB_EXT='dll.a'
 660     ;;
 661 aix* )
 662     LIB_EXT='a'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 * )
 666     LIB_EXT='so'
 667     IMP_LIB_EXT=$LIB_EXT
 668     ;;
 669 esac
 670
 671 AC_SUBST([LIB_EXT])
 672
 673 AC_ARG_WITH([gl-lib-name],
 674   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 675     [specify GL library name @<:@default=GL@:>@])],
 676   [GL_LIB=$withval],
 677   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AC_ARG_WITH([osmesa-lib-name],
 679   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 680     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 681   [OSMESA_LIB=$withval],
 682   [OSMESA_LIB=OSMesa])
 683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 685
 686 dnl
 687 dnl Mangled Mesa support
 688 dnl
 689 AC_ARG_ENABLE([mangling],
 690   [AS_HELP_STRING([--enable-mangling],
 691     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 692   [enable_mangling="${enableval}"],
 693   [enable_mangling=no]
 694 )
 695 if test "x${enable_mangling}" = "xyes" ; then
 696   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 697   GL_LIB="Mangled${GL_LIB}"
 698   OSMESA_LIB="Mangled${OSMESA_LIB}"
 699 fi
 700 AC_SUBST([GL_LIB])
 701 AC_SUBST([OSMESA_LIB])
 702
 703 dnl
 704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 705 dnl
 706 AC_ARG_ENABLE([texture-float],
 707     [AS_HELP_STRING([--enable-texture-float],
 708         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 709     [enable_texture_float="$enableval"],
 710     [enable_texture_float=no]
 711 )
 712 if test "x$enable_texture_float" = xyes; then
 713     AC_MSG_WARN([Floating-point textures enabled.])
 714     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 715     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 716 fi
 717
 718 dnl
 719 dnl Arch/platform-specific settings
 720 dnl
 721 AC_ARG_ENABLE([asm],
 722     [AS_HELP_STRING([--disable-asm],
 723         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 724     [enable_asm="$enableval"],
 725     [enable_asm=yes]
 726 )
 727 asm_arch=""
 728 AC_MSG_CHECKING([whether to enable assembly])
 729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 732     case "$host_cpu" in
 733     i?86 | x86_64 | amd64)
 734         if test "x$host_cpu" != "x$target_cpu"; then
 735             enable_asm=no
 736             AC_MSG_RESULT([no, cross compiling])
 737         fi
 738         ;;
 739     esac
 740 fi
 741 # check for supported arches
 742 if test "x$enable_asm" = xyes; then
 743     case "$host_cpu" in
 744     i?86)
 745         case "$host_os" in
 746         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 747             asm_arch=x86
 748             ;;
 749         esac
 750         ;;
 751     x86_64|amd64)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 754             asm_arch=x86_64
 755             ;;
 756         esac
 757         ;;
 758     sparc*)
 759         case "$host_os" in
 760         linux*)
 761             asm_arch=sparc
 762             ;;
 763         esac
 764         ;;
 765     esac
 766
 767     case "$asm_arch" in
 768     x86)
 769         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 770         AC_MSG_RESULT([yes, x86])
 771         ;;
 772     x86_64|amd64)
 773         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 774         AC_MSG_RESULT([yes, x86_64])
 775         ;;
 776     sparc)
 777         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 778         AC_MSG_RESULT([yes, sparc])
 779         ;;
 780     *)
 781         AC_MSG_RESULT([no, platform not supported])
 782         ;;
 783     esac
 784 fi
 785
 786 AC_HEADER_MAJOR
 787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 791
 792 dnl Check to see if dlopen is in default libraries (like Solaris, which
 793 dnl has it in libc), or if libdl is needed to get it.
 794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 795     [AC_CHECK_LIB([dl], [dlopen],
 796        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 797 AC_SUBST([DLOPEN_LIBS])
 798
 799 dnl Check if that library also has dladdr
 800 save_LIBS="$LIBS"
 801 LIBS="$LIBS $DLOPEN_LIBS"
 802 AC_CHECK_FUNCS([dladdr])
 803 LIBS="$save_LIBS"
 804
 805 case "$host_os" in
 806 darwin*)
 807     ;;
 808 *)
 809     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 810                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 811                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 812     AC_SUBST([CLOCK_LIB])
 813     ;;
 814 esac
 815
 816 dnl See if posix_memalign is available
 817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 818
 819 dnl Check for pthreads
 820 AX_PTHREAD
 821 if test "x$ax_pthread_ok" = xno; then
 822     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 823 fi
 824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 825 dnl to -pthread, which causes problems if we need -lpthread to appear in
 826 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 827 dnl is not valid for that platform.
 828 if test "x$android" = xno; then
 829     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 830 fi
 831
 832 dnl pthread-stubs is mandatory on targets where it exists
 833 case "$host_os" in
 834 cygwin* )
 835     pthread_stubs_possible="no"
 836     ;;
 837 * )
 838     pthread_stubs_possible="yes"
 839     ;;
 840 esac
 841
 842 if test "x$pthread_stubs_possible" = xyes; then
 843     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 844     AC_SUBST(PTHREADSTUBS_CFLAGS)
 845     AC_SUBST(PTHREADSTUBS_LIBS)
 846 fi
 847
 848 dnl SELinux awareness.
 849 AC_ARG_ENABLE([selinux],
 850     [AS_HELP_STRING([--enable-selinux],
 851         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 852     [MESA_SELINUX="$enableval"],
 853     [MESA_SELINUX=no])
 854 if test "x$enable_selinux" = "xyes"; then
 855     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 856         [AC_CHECK_HEADER([selinux/selinux.h],[],
 857                          [AC_MSG_ERROR([SELinux headers not found])])
 858          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 859                       [AC_MSG_ERROR([SELinux library not found])])
 860          SELINUX_LIBS="-lselinux"])
 861     DEFINES="$DEFINES -DMESA_SELINUX"
 862 fi
 863 AC_SUBST([SELINUX_CFLAGS])
 864 AC_SUBST([SELINUX_LIBS])
 865
 866 dnl Options for APIs
 867 AC_ARG_ENABLE([opengl],
 868     [AS_HELP_STRING([--disable-opengl],
 869         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 870     [enable_opengl="$enableval"],
 871     [enable_opengl=yes])
 872 AC_ARG_ENABLE([gles1],
 873     [AS_HELP_STRING([--disable-gles1],
 874         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 875     [enable_gles1="$enableval"],
 876     [enable_gles1=yes])
 877 AC_ARG_ENABLE([gles2],
 878     [AS_HELP_STRING([--disable-gles2],
 879         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 880     [enable_gles2="$enableval"],
 881     [enable_gles2=yes])
 882
 883 AC_ARG_ENABLE([dri],
 884     [AS_HELP_STRING([--enable-dri],
 885         [enable DRI modules @<:@default=enabled@:>@])],
 886     [enable_dri="$enableval"],
 887     [enable_dri=yes])
 888
 889 AC_ARG_ENABLE([gallium-extra-hud],
 890     [AS_HELP_STRING([--enable-gallium-extra-hud],
 891         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
 892     [enable_gallium_extra_hud="$enableval"],
 893     [enable_gallium_extra_hud=no])
 894 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
 895 if test "x$enable_gallium_extra_hud" = xyes ; then
 896     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
 897 fi
 898
 899 #TODO: no pkgconfig .pc available for libsensors.
 900 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
 901 AC_ARG_ENABLE([lmsensors],
 902     [AS_HELP_STRING([--enable-lmsensors],
 903         [enable HUD lmsensor support @<:@default=disabled@:>@])],
 904     [enable_lmsensors="$enableval"],
 905     [enable_lmsensors=no])
 906 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
 907 if test "x$enable_lmsensors" = xyes ; then
 908     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
 909     LIBSENSORS_LDFLAGS="-lsensors"
 910 else
 911     LIBSENSORS_LDFLAGS=""
 912 fi
 913 AC_SUBST(LIBSENSORS_LDFLAGS)
 914
 915 case "$host_os" in
 916 linux*)
 917     dri3_default=yes
 918     ;;
 919 *)
 920     dri3_default=no
 921     ;;
 922 esac
 923
 924 if test "x$enable_dri" = xno; then
 925     dri3_default=no
 926 fi
 927
 928 AC_ARG_ENABLE([dri3],
 929     [AS_HELP_STRING([--enable-dri3],
 930         [enable DRI3 @<:@default=auto@:>@])],
 931     [enable_dri3="$enableval"],
 932     [enable_dri3="$dri3_default"])
 933 AC_ARG_ENABLE([glx],
 934     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 935         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 936     [enable_glx="$enableval"],
 937     [enable_glx=yes])
 938 AC_ARG_ENABLE([osmesa],
 939     [AS_HELP_STRING([--enable-osmesa],
 940         [enable OSMesa library @<:@default=disabled@:>@])],
 941     [enable_osmesa="$enableval"],
 942     [enable_osmesa=no])
 943 AC_ARG_ENABLE([gallium-osmesa],
 944     [AS_HELP_STRING([--enable-gallium-osmesa],
 945         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 946     [enable_gallium_osmesa="$enableval"],
 947     [enable_gallium_osmesa=no])
 948 AC_ARG_ENABLE([egl],
 949     [AS_HELP_STRING([--disable-egl],
 950         [disable EGL library @<:@default=enabled@:>@])],
 951     [enable_egl="$enableval"],
 952     [enable_egl=yes])
 953
 954 AC_ARG_ENABLE([xa],
 955     [AS_HELP_STRING([--enable-xa],
 956         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 957     [enable_xa="$enableval"],
 958     [enable_xa=no])
 959 AC_ARG_ENABLE([gbm],
 960    [AS_HELP_STRING([--enable-gbm],
 961          [enable gbm library @<:@default=yes except cygwin@:>@])],
 962    [enable_gbm="$enableval"],
 963    [case "$host_os" in
 964        cygwin*)
 965           enable_gbm=no
 966           ;;
 967        *)
 968           enable_gbm=yes
 969           ;;
 970     esac])
 971 AC_ARG_ENABLE([nine],
 972     [AS_HELP_STRING([--enable-nine],
 973         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 974     [enable_nine="$enableval"],
 975     [enable_nine=no])
 976
 977 AC_ARG_ENABLE([xvmc],
 978    [AS_HELP_STRING([--enable-xvmc],
 979          [enable xvmc library @<:@default=auto@:>@])],
 980    [enable_xvmc="$enableval"],
 981    [enable_xvmc=auto])
 982 AC_ARG_ENABLE([vdpau],
 983    [AS_HELP_STRING([--enable-vdpau],
 984          [enable vdpau library @<:@default=auto@:>@])],
 985    [enable_vdpau="$enableval"],
 986    [enable_vdpau=auto])
 987 AC_ARG_ENABLE([omx],
 988    [AS_HELP_STRING([--enable-omx],
 989          [enable OpenMAX library @<:@default=disabled@:>@])],
 990    [enable_omx="$enableval"],
 991    [enable_omx=no])
 992 AC_ARG_ENABLE([va],
 993    [AS_HELP_STRING([--enable-va],
 994          [enable va library @<:@default=auto@:>@])],
 995    [enable_va="$enableval"],
 996    [enable_va=auto])
 997 AC_ARG_ENABLE([opencl],
 998    [AS_HELP_STRING([--enable-opencl],
 999          [enable OpenCL library @<:@default=disabled@:>@])],
1000    [enable_opencl="$enableval"],
1001    [enable_opencl=no])
1002 AC_ARG_ENABLE([opencl_icd],
1003    [AS_HELP_STRING([--enable-opencl-icd],
1004           [Build an OpenCL ICD library to be loaded by an ICD implementation
1005            @<:@default=disabled@:>@])],
1006     [enable_opencl_icd="$enableval"],
1007     [enable_opencl_icd=no])
1008
1009 AC_ARG_ENABLE([gallium-tests],
1010     [AS_HELP_STRING([--enable-gallium-tests],
1011         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1012     [enable_gallium_tests="$enableval"],
1013     [enable_gallium_tests=no])
1014
1015 # Option for Gallium drivers
1016
1017 # Keep this in sync with the --with-gallium-drivers help string default value
1018 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1019
1020 AC_ARG_WITH([gallium-drivers],
1021     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1022         [comma delimited Gallium drivers list, e.g.
1023         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1024         @<:@default=r300,r600,svga,swrast@:>@])],
1025     [with_gallium_drivers="$withval"],
1026     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1027
1028 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1029 # here so that the script doesn't choke on an unknown driver name later.
1030 case "$with_gallium_drivers" in
1031     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1032     no) with_gallium_drivers='' ;;
1033 esac
1034
1035 if test "x$enable_opengl" = xno -a \
1036         "x$enable_gles1" = xno -a \
1037         "x$enable_gles2" = xno -a \
1038         "x$enable_nine" = xno -a \
1039         "x$enable_xa" = xno -a \
1040         "x$enable_xvmc" = xno -a \
1041         "x$enable_vdpau" = xno -a \
1042         "x$enable_omx" = xno -a \
1043         "x$enable_va" = xno -a \
1044         "x$enable_opencl" = xno; then
1045     AC_MSG_ERROR([at least one API should be enabled])
1046 fi
1047
1048 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1049 if test "x$enable_opengl" = xno -a \
1050         "x$enable_gles1" = xyes; then
1051     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1052 fi
1053
1054 if test "x$enable_opengl" = xno -a \
1055         "x$enable_gles2" = xyes; then
1056     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1057 fi
1058
1059 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1060 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1061 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1062 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1063                                         "x$enable_gles1" = xyes -o \
1064                                         "x$enable_gles2" = xyes)
1065
1066 # Validate GLX options
1067 if test "x$enable_glx" = xyes; then
1068     if test "x$enable_dri" = xyes; then
1069         enable_glx=dri
1070     elif test -n "$with_gallium_drivers"; then
1071         enable_glx=gallium-xlib
1072     else
1073         enable_glx=xlib
1074     fi
1075 fi
1076 case "x$enable_glx" in
1077 xdri | xxlib | xgallium-xlib)
1078     # GLX requires OpenGL
1079     if test "x$enable_opengl" = xno; then
1080         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1081     fi
1082
1083     # Check individual dependencies
1084     case "x$enable_glx" in
1085     xdri)
1086         if test "x$enable_dri" = xno; then
1087             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1088         fi
1089         ;;
1090     xxlib)
1091         if test "x$enable_dri" = xyes; then
1092             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1093         fi
1094         ;;
1095     xgallium-xlib )
1096         if test "x$enable_dri" = xyes; then
1097             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1098         fi
1099         if test -z "$with_gallium_drivers"; then
1100             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1101         fi
1102         ;;
1103     esac
1104     ;;
1105 xno)
1106     ;;
1107 *)
1108     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1109     ;;
1110 esac
1111
1112 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1113 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1114 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1115 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1116
1117 dnl
1118 dnl Libglvnd configuration
1119 dnl
1120 AC_ARG_ENABLE([libglvnd],
1121     [AS_HELP_STRING([--enable-libglvnd],
1122         [Build for libglvnd @<:@default=disabled@:>@])],
1123     [enable_libglvnd="$enableval"],
1124     [enable_libglvnd=no])
1125 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1126 if test "x$enable_libglvnd" = xyes ; then
1127     dnl XXX: update once we can handle more than libGL/glx.
1128     dnl Namely: we should error out if neither of the glvnd enabled libraries
1129     dnl are built
1130     case "x$enable_glx" in
1131     xno)
1132         AC_MSG_ERROR([cannot build libglvnd without GLX])
1133         ;;
1134     xxlib | xgallium-xlib )
1135         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1136         ;;
1137     xdri)
1138         ;;
1139     esac
1140
1141     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1142     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1143     DEFAULT_GL_LIB_NAME=GLX_mesa
1144 fi
1145
1146 # Check for libdrm
1147 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1148                   [have_libdrm=yes], [have_libdrm=no])
1149 if test "x$have_libdrm" = xyes; then
1150         DEFINES="$DEFINES -DHAVE_LIBDRM"
1151 fi
1152
1153 require_libdrm() {
1154     if test "x$have_libdrm" != xyes; then
1155        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1156     fi
1157 }
1158
1159
1160 # Select which platform-dependent DRI code gets built
1161 case "$host_os" in
1162 darwin*)
1163     dri_platform='apple' ;;
1164 cygwin*)
1165     dri_platform='windows' ;;
1166 gnu*)
1167     dri_platform='none' ;;
1168 *)
1169     dri_platform='drm' ;;
1170 esac
1171
1172 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1173     have_drisw_kms='yes'
1174 fi
1175
1176 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1177 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1178 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1179 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1180 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1181 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1182 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1183 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1184 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1185
1186 AC_ARG_ENABLE([shared-glapi],
1187     [AS_HELP_STRING([--enable-shared-glapi],
1188         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1189     [enable_shared_glapi="$enableval"],
1190     [enable_shared_glapi=yes])
1191
1192 case "x$enable_opengl$enable_gles1$enable_gles2" in
1193 x*yes*yes*)
1194     if test "x$enable_shared_glapi" = xno; then
1195         AC_MSG_ERROR([shared GLAPI required when building two or more of
1196                       the following APIs - opengl, gles1 gles2])
1197     fi
1198     ;;
1199 esac
1200
1201 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1202
1203 # Build the pipe-drivers as separate libraries/modules.
1204 # Do not touch this unless you know what you are doing.
1205 # XXX: Expose via configure option ?
1206 enable_shared_pipe_drivers=no
1207
1208 dnl
1209 dnl Driver specific build directories
1210 dnl
1211
1212 if test "x$enable_gallium_osmesa" = xyes; then
1213     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1214         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1215     fi
1216     if test "x$enable_osmesa" = xyes; then
1217         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1218     fi
1219 fi
1220
1221 AC_SUBST([MESA_LLVM])
1222
1223 # SHA1 hashing
1224 AC_ARG_WITH([sha1],
1225         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1226         [choose SHA1 implementation])])
1227 case "x$with_sha1" in
1228 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1229   ;;
1230 *)
1231         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1232 esac
1233
1234 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1235 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1236         with_sha1=libc
1237 fi
1238 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1239         AC_MSG_ERROR([sha1 in libc requested but not found])
1240 fi
1241 if test "x$with_sha1" = xlibc; then
1242         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1243                 [Use libc SHA1 functions])
1244         SHA1_LIBS=""
1245 fi
1246 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1247 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1248         with_sha1=CommonCrypto
1249 fi
1250 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1251         AC_MSG_ERROR([CommonCrypto requested but not found])
1252 fi
1253 if test "x$with_sha1" = xCommonCrypto; then
1254         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1255                 [Use CommonCrypto SHA1 functions])
1256         SHA1_LIBS=""
1257 fi
1258 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1259 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1260 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1261         with_sha1=CryptoAPI
1262 fi
1263 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1264         AC_MSG_ERROR([CryptoAPI requested but not found])
1265 fi
1266 if test "x$with_sha1" = xCryptoAPI; then
1267         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1268                 [Use CryptoAPI SHA1 functions])
1269         SHA1_LIBS=""
1270 fi
1271 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1272 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1273         with_sha1=libmd
1274 fi
1275 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1276         AC_MSG_ERROR([libmd requested but not found])
1277 fi
1278 if test "x$with_sha1" = xlibmd; then
1279         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1280                   [Use libmd SHA1 functions])
1281         SHA1_LIBS=-lmd
1282 fi
1283 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1284 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1285    with_sha1=libsha1
1286 fi
1287 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1288         AC_MSG_ERROR([libsha1 requested but not found])
1289 fi
1290 if test "x$with_sha1" = xlibsha1; then
1291         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1292                   [Use libsha1 for SHA1])
1293         SHA1_LIBS=-lsha1
1294 fi
1295 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1296 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1297         with_sha1=libnettle
1298 fi
1299 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1300         AC_MSG_ERROR([libnettle requested but not found])
1301 fi
1302 if test "x$with_sha1" = xlibnettle; then
1303         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1304                   [Use libnettle SHA1 functions])
1305         SHA1_LIBS=-lnettle
1306 fi
1307 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1308 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1309         with_sha1=libgcrypt
1310 fi
1311 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1312         AC_MSG_ERROR([libgcrypt requested but not found])
1313 fi
1314 if test "x$with_sha1" = xlibgcrypt; then
1315         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1316                   [Use libgcrypt SHA1 functions])
1317         SHA1_LIBS=-lgcrypt
1318 fi
1319 # We don't need all of the OpenSSL libraries, just libcrypto
1320 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1321 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1322                   [HAVE_OPENSSL_PKC=no])
1323 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1324         if test "x$with_sha1" = x; then
1325                 with_sha1=libcrypto
1326         fi
1327 else
1328         if test "x$with_sha1" = xlibcrypto; then
1329                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1330         fi
1331 fi
1332 if test "x$with_sha1" = xlibcrypto; then
1333         if test "x$HAVE_LIBCRYPTO" = xyes; then
1334                 SHA1_LIBS=-lcrypto
1335         else
1336                 SHA1_LIBS="$OPENSSL_LIBS"
1337                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1338         fi
1339 fi
1340 AC_MSG_CHECKING([for SHA1 implementation])
1341 AC_MSG_RESULT([$with_sha1])
1342 AC_SUBST(SHA1_LIBS)
1343 AC_SUBST(SHA1_CFLAGS)
1344
1345 # Enable a define for SHA1
1346 if test "x$with_sha1" != "x"; then
1347         DEFINES="$DEFINES -DHAVE_SHA1"
1348 fi
1349
1350 # Allow user to configure out the shader-cache feature
1351 AC_ARG_ENABLE([shader-cache],
1352     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1353     [enable_shader_cache="$enableval"],
1354     [if test "x$with_sha1" != "x"; then
1355         enable_shader_cache=yes
1356      else
1357         enable_shader_cache=no
1358      fi])
1359 if test "x$with_sha1" = "x"; then
1360     if test "x$enable_shader_cache" = "xyes"; then
1361         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1362     fi
1363 fi
1364 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1365 if test "x$enable_shader_cache" = "xyes"; then
1366    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1367 fi
1368
1369 if test "x$enable_dri" = xyes; then
1370     if test "$enable_static" = yes; then
1371         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1372     fi
1373
1374     # not a hard requirement as swrast does not depend on it
1375     if test "x$have_libdrm" = xyes; then
1376         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1377     fi
1378 fi
1379
1380 AC_ARG_ENABLE([driglx-direct],
1381     [AS_HELP_STRING([--disable-driglx-direct],
1382         [disable direct rendering in GLX and EGL for DRI \
1383             @<:@default=auto@:>@])],
1384     [driglx_direct="$enableval"],
1385     [driglx_direct="yes"])
1386
1387 dnl
1388 dnl libGL configuration per driver
1389 dnl
1390 case "x$enable_glx" in
1391 xxlib | xgallium-xlib)
1392     # Xlib-based GLX
1393     dri_modules="x11 xext xcb"
1394     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1395     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1396     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1397     GL_LIB_DEPS="$XLIBGL_LIBS"
1398     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1399     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1400     ;;
1401 xdri)
1402     # DRI-based GLX
1403     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1404
1405     # find the DRI deps for libGL
1406     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1407
1408     if test x"$driglx_direct" = xyes; then
1409         if test x"$dri_platform" = xdrm ; then
1410             DEFINES="$DEFINES -DGLX_USE_DRM"
1411             require_libdrm "Direct rendering"
1412
1413             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1414             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1415             if test x"$enable_dri3" = xyes; then
1416                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1417                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1418             fi
1419
1420             if test x"$enable_dri" = xyes; then
1421                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1422             fi
1423
1424             if test x"$enable_dri3" = xyes; then
1425                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1426                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1427                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1428             fi
1429         fi
1430         if test x"$dri_platform" = xapple ; then
1431             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1432         fi
1433         if test x"$dri_platform" = xwindows ; then
1434             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1435         fi
1436     fi
1437
1438     # add xf86vidmode if available
1439     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1440     if test "$HAVE_XF86VIDMODE" = yes ; then
1441         dri_modules="$dri_modules xxf86vm"
1442     fi
1443
1444     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1445     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1446     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1447     GL_LIB_DEPS="$DRIGL_LIBS"
1448
1449     # need DRM libs, $PTHREAD_LIBS, etc.
1450     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1451     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1452     ;;
1453 esac
1454
1455 # This is outside the case (above) so that it is invoked even for non-GLX
1456 # builds.
1457 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1458
1459 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1460 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1461 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1462 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1463
1464 AC_SUBST([X11_INCLUDES])
1465 AC_SUBST([GL_LIB_DEPS])
1466 AC_SUBST([GL_PC_REQ_PRIV])
1467 AC_SUBST([GL_PC_LIB_PRIV])
1468 AC_SUBST([GL_PC_CFLAGS])
1469 AC_SUBST([DRI_PC_REQ_PRIV])
1470 AC_SUBST([GLESv1_CM_LIB_DEPS])
1471 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1472 AC_SUBST([GLESv2_LIB_DEPS])
1473 AC_SUBST([GLESv2_PC_LIB_PRIV])
1474
1475 AC_SUBST([HAVE_XF86VIDMODE])
1476
1477 dnl
1478 dnl More GLX setup
1479 dnl
1480 case "x$enable_glx" in
1481 xxlib | xgallium-xlib)
1482     DEFINES="$DEFINES -DUSE_XSHM"
1483     ;;
1484 xdri)
1485     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1486     if test "x$driglx_direct" = xyes; then
1487         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1488     fi
1489     ;;
1490 esac
1491
1492 dnl
1493 dnl TLS detection
1494 dnl
1495
1496 AC_ARG_ENABLE([glx-tls],
1497     [AS_HELP_STRING([--enable-glx-tls],
1498         [enable TLS support in GLX @<:@default=disabled@:>@])],
1499     [GLX_USE_TLS="$enableval"],
1500     [GLX_USE_TLS=no])
1501 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1502
1503 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1504       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1505
1506 dnl Read-only text section on x86 hardened platforms
1507 AC_ARG_ENABLE([glx-read-only-text],
1508     [AS_HELP_STRING([--enable-glx-read-only-text],
1509         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1510     [enable_glx_read_only_text="$enableval"],
1511     [enable_glx_read_only_text=no])
1512 if test "x$enable_glx_read_only_text" = xyes; then
1513     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1514 fi
1515
1516 dnl
1517 dnl More DRI setup
1518 dnl
1519 dnl Directory for DRI drivers
1520 AC_ARG_WITH([dri-driverdir],
1521     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1522         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1523     [DRI_DRIVER_INSTALL_DIR="$withval"],
1524     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1525 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1526 dnl Extra search path for DRI drivers
1527 AC_ARG_WITH([dri-searchpath],
1528     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1529         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1530     [DRI_DRIVER_SEARCH_DIR="$withval"],
1531     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1532 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1533 dnl Which drivers to build - default is chosen by platform
1534 AC_ARG_WITH([dri-drivers],
1535     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1536         [comma delimited classic DRI drivers list, e.g.
1537         "swrast,i965,radeon" @<:@default=auto@:>@])],
1538     [with_dri_drivers="$withval"],
1539     [with_dri_drivers=auto])
1540
1541 if test "x$with_dri_drivers" = xauto; then
1542     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1543         with_dri_drivers="yes"
1544     else
1545         with_dri_drivers="no"
1546     fi
1547 fi
1548 if test "x$with_dri_drivers" = xno; then
1549     with_dri_drivers=''
1550 fi
1551
1552 dnl If $with_dri_drivers is yes, drivers will be added through
1553 dnl platform checks. Set DEFINES and LIB_DEPS
1554 if test "x$enable_dri" = xyes; then
1555     # Platform specific settings and drivers to build
1556     case "$host_os" in
1557     linux*)
1558         DEFINES="$DEFINES -DHAVE_ALIAS"
1559         if test "x$enable_dri3" = xyes; then
1560             DEFINES="$DEFINES -DHAVE_DRI3"
1561         fi
1562
1563         case "$host_cpu" in
1564         powerpc* | sparc*)
1565             # Build only the drivers for cards that exist on PowerPC/sparc
1566             if test "x$with_dri_drivers" = "xyes"; then
1567                 with_dri_drivers="r200 radeon swrast"
1568             fi
1569             ;;
1570         esac
1571         ;;
1572     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1573         DEFINES="$DEFINES -DHAVE_ALIAS"
1574         ;;
1575     gnu*)
1576         DEFINES="$DEFINES -DHAVE_ALIAS"
1577         ;;
1578     cygwin*)
1579         if test "x$with_dri_drivers" = "xyes"; then
1580             with_dri_drivers="swrast"
1581         fi
1582         ;;
1583     darwin*)
1584         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1585         if test "x$with_dri_drivers" = "xyes"; then
1586             with_dri_drivers="swrast"
1587         fi
1588         ;;
1589     esac
1590
1591     # default drivers
1592     if test "x$with_dri_drivers" = "xyes"; then
1593         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1594     fi
1595
1596     # Check for expat
1597     PKG_CHECK_MODULES([EXPAT], [expat], [],
1598         # expat version 2.0 and earlier do not provide expat.pc
1599         [AC_CHECK_HEADER([expat.h],[],
1600                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1601          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1602                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1603          EXPAT_LIBS="-lexpat"])
1604
1605     # put all the necessary libs together
1606     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1607 fi
1608
1609 AC_SUBST([DRI_LIB_DEPS])
1610
1611 DRI_DIRS=''
1612 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1613 if test -n "$with_dri_drivers"; then
1614     if test "x$enable_opengl" != xyes; then
1615         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1616     fi
1617
1618     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1619     for driver in $dri_drivers; do
1620         DRI_DIRS="$DRI_DIRS $driver"
1621         case "x$driver" in
1622         xi915)
1623             HAVE_I915_DRI=yes;
1624             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1625             ;;
1626         xi965)
1627             HAVE_I965_DRI=yes;
1628             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1629             ;;
1630         xnouveau)
1631             HAVE_NOUVEAU_DRI=yes;
1632             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1633             ;;
1634         xradeon)
1635             HAVE_RADEON_DRI=yes;
1636             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1637             ;;
1638         xr200)
1639             HAVE_R200_DRI=yes;
1640             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1641             ;;
1642         xswrast)
1643             HAVE_SWRAST_DRI=yes;
1644             ;;
1645         *)
1646             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1647             ;;
1648         esac
1649     done
1650     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1651 fi
1652
1653
1654 #
1655 # Vulkan driver configuration
1656 #
1657
1658 AC_ARG_WITH([vulkan-drivers],
1659     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1660         [comma delimited Vulkan drivers list, e.g.
1661         "intel"
1662         @<:@default=no@:>@])],
1663     [with_vulkan_drivers="$withval"],
1664     [with_vulkan_drivers="no"])
1665
1666 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1667 # here so that the script doesn't choke on an unknown driver name later.
1668 case "x$with_vulkan_drivers" in
1669     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1670     xno) with_vulkan_drivers='' ;;
1671 esac
1672
1673 AC_ARG_WITH([vulkan-icddir],
1674     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1675         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1676     [VULKAN_ICD_INSTALL_DIR="$withval"],
1677     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1678 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1679
1680 if test -n "$with_vulkan_drivers"; then
1681     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1682     for driver in $VULKAN_DRIVERS; do
1683         case "x$driver" in
1684         xintel)
1685             if test "x$HAVE_I965_DRI" != xyes; then
1686                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1687             fi
1688             if test "x$with_sha1" == "x"; then
1689                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1690             fi
1691             HAVE_INTEL_VULKAN=yes;
1692
1693             ;;
1694         xradeon)
1695             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1696             HAVE_RADEON_VULKAN=yes;
1697             if test "x$with_sha1" == "x"; then
1698                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1699             fi
1700             ;;
1701         *)
1702             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1703             ;;
1704         esac
1705     done
1706     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1707 fi
1708
1709
1710 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1711 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1712                                   "x$enable_osmesa" = xyes -o \
1713                                   -n "$DRI_DIRS")
1714
1715 dnl
1716 dnl OSMesa configuration
1717 dnl
1718
1719 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1720 AC_ARG_WITH([osmesa-bits],
1721     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1722         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1723     [osmesa_bits="$withval"],
1724     [osmesa_bits=8])
1725 if test "x$osmesa_bits" != x8; then
1726     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1727         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1728         osmesa_bits=8
1729     fi
1730 fi
1731 case "x$osmesa_bits" in
1732 x8)
1733     OSMESA_LIB="${OSMESA_LIB}"
1734     ;;
1735 x16|x32)
1736     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1737     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1738     ;;
1739 *)
1740     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1741     ;;
1742 esac
1743
1744 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1745     # only link libraries with osmesa if shared
1746     if test "$enable_static" = no; then
1747         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1748     else
1749         OSMESA_LIB_DEPS=""
1750     fi
1751     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1752 fi
1753
1754 AC_SUBST([OSMESA_LIB_DEPS])
1755 AC_SUBST([OSMESA_PC_REQ])
1756 AC_SUBST([OSMESA_PC_LIB_PRIV])
1757
1758 dnl
1759 dnl gbm configuration
1760 dnl
1761 if test "x$enable_gbm" = xyes; then
1762     if test "x$enable_dri" = xyes; then
1763         if test "x$enable_shared_glapi" = xno; then
1764             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1765         fi
1766     else
1767         # Strictly speaking libgbm does not require --enable-dri, although
1768         # both of its backends do. Thus one can build libgbm without any
1769         # backends if --disable-dri is set.
1770         # To avoid unnecessary complexity of checking if at least one backend
1771         # is available when building, just mandate --enable-dri.
1772         AC_MSG_ERROR([gbm requires --enable-dri])
1773     fi
1774 fi
1775 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1776 # FINISHME: GBM has a number of dependencies which we should add below
1777 GBM_PC_REQ_PRIV=""
1778 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1779 AC_SUBST([GBM_PC_REQ_PRIV])
1780 AC_SUBST([GBM_PC_LIB_PRIV])
1781
1782 dnl
1783 dnl EGL configuration
1784 dnl
1785 EGL_CLIENT_APIS=""
1786
1787 if test "x$enable_egl" = xyes; then
1788     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1789
1790     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1791
1792     if test "$enable_static" != yes; then
1793         if test "x$enable_dri" = xyes; then
1794             HAVE_EGL_DRIVER_DRI2=1
1795             if test "x$enable_shared_glapi" = xno; then
1796                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1797             fi
1798             if test "x$enable_dri3" = xyes; then
1799                 HAVE_EGL_DRIVER_DRI3=1
1800                 if test "x$enable_shared_glapi" = xno; then
1801                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1802                 fi
1803             fi
1804         else
1805             # Avoid building an "empty" libEGL. Drop/update this
1806             # when other backends (haiku?) come along.
1807             AC_MSG_ERROR([egl requires --enable-dri])
1808         fi
1809
1810     fi
1811 fi
1812 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1813 AC_SUBST([EGL_LIB_DEPS])
1814
1815 gallium_st="mesa"
1816
1817 dnl
1818 dnl XA configuration
1819 dnl
1820 if test "x$enable_xa" = xyes; then
1821     if test "x$with_gallium_drivers" = xswrast; then
1822        AC_MSG_ERROR([
1823           Building xa requires at least one non swrast gallium driver.
1824           If you are looking to use libxatracker.so with the VMware driver,
1825           make sure to include svga in the gallium drivers list, apart from
1826           enabling XA.
1827           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1828     fi
1829     gallium_st="$gallium_st xa"
1830 fi
1831 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1832
1833 dnl
1834 dnl Gallium G3DVL configuration
1835 dnl
1836 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1837     if test "x$enable_xvmc" = xauto; then
1838         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1839     fi
1840
1841     if test "x$enable_vdpau" = xauto; then
1842         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1843     fi
1844
1845     if test "x$enable_omx" = xauto; then
1846         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1847     fi
1848
1849     if test "x$enable_va" = xauto; then
1850         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1851     fi
1852 fi
1853
1854 if test "x$enable_dri" = xyes -o \
1855         "x$enable_xvmc" = xyes -o \
1856         "x$enable_vdpau" = xyes -o \
1857         "x$enable_omx" = xyes -o \
1858         "x$enable_va" = xyes; then
1859     need_gallium_vl=yes
1860 fi
1861 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1862
1863 if test "x$enable_xvmc" = xyes -o \
1864         "x$enable_vdpau" = xyes -o \
1865         "x$enable_omx" = xyes -o \
1866         "x$enable_va" = xyes; then
1867     if test x"$enable_dri3" = xyes; then
1868         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1869                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1870     else
1871         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1872     fi
1873     need_gallium_vl_winsys=yes
1874 fi
1875 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1876
1877 if test "x$enable_xvmc" = xyes; then
1878     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1879     gallium_st="$gallium_st xvmc"
1880 fi
1881 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1882
1883 if test "x$enable_vdpau" = xyes; then
1884     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1885     gallium_st="$gallium_st vdpau"
1886     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1887 fi
1888 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1889
1890 if test "x$enable_omx" = xyes; then
1891     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1892     gallium_st="$gallium_st omx"
1893 fi
1894 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1895
1896 if test "x$enable_va" = xyes; then
1897     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1898     gallium_st="$gallium_st va"
1899 fi
1900 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1901
1902 dnl
1903 dnl Nine Direct3D9 configuration
1904 dnl
1905 if test "x$enable_nine" = xyes; then
1906     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1907         AC_MSG_ERROR([nine requires the gallium swrast driver])
1908     fi
1909     if test "x$with_gallium_drivers" = xswrast; then
1910         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1911     fi
1912     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1913         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1914     fi
1915
1916     if test "x$enable_dri3" = xno; then
1917         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1918     fi
1919
1920     gallium_st="$gallium_st nine"
1921 fi
1922 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1923
1924 dnl
1925 dnl OpenCL configuration
1926 dnl
1927
1928 AC_ARG_WITH([clang-libdir],
1929    [AS_HELP_STRING([--with-clang-libdir],
1930          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1931    [CLANG_LIBDIR="$withval"],
1932    [CLANG_LIBDIR=''])
1933
1934 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1935 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1936
1937 if test "x$have_libelf" = xno; then
1938    LIBELF_LIBS=''
1939    LIBELF_CFLAGS=''
1940    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1941    AC_SUBST([LIBELF_LIBS])
1942    AC_SUBST([LIBELF_CFLAGS])
1943 fi
1944
1945 if test "x$enable_opencl" = xyes; then
1946     if test -z "$with_gallium_drivers"; then
1947         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1948     fi
1949
1950     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1951         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1952     fi
1953
1954     if test "x$have_libclc" = xno; then
1955         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1956                     Make sure the directory containing libclc.pc is specified in your
1957                     PKG_CONFIG_PATH environment variable.
1958                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1959     else
1960         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1961         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1962         AC_SUBST([LIBCLC_INCLUDEDIR])
1963         AC_SUBST([LIBCLC_LIBEXECDIR])
1964     fi
1965
1966     gallium_st="$gallium_st clover"
1967
1968     if test "x$enable_opencl_icd" = xyes; then
1969         OPENCL_LIBNAME="MesaOpenCL"
1970     else
1971         OPENCL_LIBNAME="OpenCL"
1972     fi
1973
1974     if test "x$have_libelf" != xyes; then
1975        AC_MSG_ERROR([Clover requires libelf])
1976     fi
1977 fi
1978 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1979 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1980 AC_SUBST([OPENCL_LIBNAME])
1981
1982 dnl
1983 dnl Gallium configuration
1984 dnl
1985 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1986
1987 AC_SUBST([LLVM_BINDIR])
1988 AC_SUBST([LLVM_CFLAGS])
1989 AC_SUBST([LLVM_CPPFLAGS])
1990 AC_SUBST([LLVM_CXXFLAGS])
1991 AC_SUBST([LLVM_LIBDIR])
1992 AC_SUBST([LLVM_LIBS])
1993 AC_SUBST([LLVM_LDFLAGS])
1994 AC_SUBST([LLVM_INCLUDEDIR])
1995 AC_SUBST([LLVM_VERSION])
1996 AC_SUBST([CLANG_RESOURCE_DIR])
1997
1998 case "x$enable_opengl$enable_gles1$enable_gles2" in
1999 x*yes*)
2000     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2001     ;;
2002 esac
2003
2004 AC_SUBST([VG_LIB_DEPS])
2005 AC_SUBST([EGL_CLIENT_APIS])
2006
2007 dnl
2008 dnl EGL Platforms configuration
2009 dnl
2010 AC_ARG_WITH([egl-platforms],
2011     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2012         [comma delimited native platforms libEGL supports, e.g.
2013         "x11,drm" @<:@default=auto@:>@])],
2014     [with_egl_platforms="$withval"],
2015     [if test "x$enable_egl" = xyes; then
2016         if test "x$enable_gbm" = xyes; then
2017            with_egl_platforms="x11,drm"
2018         else
2019            with_egl_platforms="x11"
2020         fi
2021     else
2022         with_egl_platforms=""
2023     fi])
2024
2025 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2026     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2027 fi
2028
2029 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2030         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2031         WAYLAND_SCANNER='')
2032 if test "x$WAYLAND_SCANNER" = x; then
2033     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2034 fi
2035
2036 # Do per-EGL platform setups and checks
2037 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2038 for plat in $egl_platforms; do
2039         case "$plat" in
2040         wayland)
2041
2042                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2043
2044                 if test "x$WAYLAND_SCANNER" = x; then
2045                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2046                 fi
2047                 ;;
2048
2049         x11)
2050                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2051                 ;;
2052
2053         drm)
2054                 test "x$enable_gbm" = "xno" &&
2055                         AC_MSG_ERROR([EGL platform drm needs gbm])
2056                 ;;
2057
2058         surfaceless)
2059                 ;;
2060
2061         android)
2062                 ;;
2063
2064         *)
2065                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2066                 ;;
2067         esac
2068
2069         case "$plat" in
2070         wayland|drm|surfaceless)
2071                 require_libdrm "Platform $plat"
2072                 ;;
2073         esac
2074 done
2075
2076 # libEGL wants to default to the first platform specified in
2077 # ./configure.  parse that here.
2078 if test "x$egl_platforms" != "x"; then
2079     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2080     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2081 else
2082     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2083 fi
2084
2085 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2086 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2087 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2088 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2089 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2090
2091 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2092
2093 AC_SUBST([EGL_NATIVE_PLATFORM])
2094 AC_SUBST([EGL_CFLAGS])
2095
2096 # If we don't have the X11 platform, set this define so we don't try to include
2097 # the X11 headers.
2098 if ! echo "$egl_platforms" | grep -q 'x11'; then
2099     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2100     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2101 fi
2102
2103 dnl
2104 dnl Gallium LLVM
2105 dnl
2106 AC_ARG_ENABLE([gallium-llvm],
2107     [AS_HELP_STRING([--enable-gallium-llvm],
2108         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2109     [enable_gallium_llvm="$enableval"],
2110     [enable_gallium_llvm=auto])
2111
2112 AC_ARG_ENABLE([llvm-shared-libs],
2113     [AS_HELP_STRING([--enable-llvm-shared-libs],
2114         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2115     [enable_llvm_shared_libs="$enableval"],
2116     [enable_llvm_shared_libs=yes])
2117
2118 AC_ARG_WITH([llvm-prefix],
2119     [AS_HELP_STRING([--with-llvm-prefix],
2120         [Prefix for LLVM installations in non-standard locations])],
2121     [llvm_prefix="$withval"],
2122     [llvm_prefix=''])
2123
2124
2125 # Call this inside ` ` to get the return value.
2126 # $1 is the llvm-config command with arguments.
2127 strip_unwanted_llvm_flags() {
2128     # Use \> (marks the end of the word)
2129     echo `$1` | sed \
2130         -e 's/-march=\S*//g' \
2131         -e 's/-mtune=\S*//g' \
2132         -e 's/-mcpu=\S*//g' \
2133         -e 's/-DNDEBUG\>//g' \
2134         -e 's/-D_GNU_SOURCE\>//g' \
2135         -e 's/-pedantic\>//g' \
2136         -e 's/-Wcovered-switch-default\>//g' \
2137         -e 's/-O.\>//g' \
2138         -e 's/-g\>//g' \
2139         -e 's/-Wall\>//g' \
2140         -e 's/-Wcast-qual\>//g' \
2141         -e 's/-Woverloaded-virtual\>//g' \
2142         -e 's/-fcolor-diagnostics\>//g' \
2143         -e 's/-fdata-sections\>//g' \
2144         -e 's/-ffunction-sections\>//g' \
2145         -e 's/-fno-exceptions\>//g' \
2146         -e 's/-fomit-frame-pointer\>//g' \
2147         -e 's/-fvisibility-inlines-hidden\>//g' \
2148         -e 's/-fPIC\>//g' \
2149         -e 's/-fstack-protector-strong\>//g'
2150 }
2151
2152 llvm_check_version_for() {
2153     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2154         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2155     fi
2156 }
2157
2158
2159
2160 if test -z "$with_gallium_drivers"; then
2161     enable_gallium_llvm=no
2162 fi
2163 if test "x$enable_gallium_llvm" = xauto; then
2164     case "$host_cpu" in
2165     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2166     esac
2167 fi
2168 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2169     if test -n "$llvm_prefix"; then
2170         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2171     else
2172         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2173     fi
2174
2175     if test "x$LLVM_CONFIG" != xno; then
2176         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2177         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2178         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2179         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2180         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2181         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2182         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2183         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2184
2185         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2186             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2187         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2188             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2189
2190         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2191         if test -z "$LLVM_VERSION_PATCH"; then
2192             LLVM_VERSION_PATCH=0
2193         fi
2194
2195         if test -n "${LLVM_VERSION_MAJOR}"; then
2196             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2197         else
2198             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2199         fi
2200
2201         LLVM_REQUIRED_VERSION_MAJOR="3"
2202         LLVM_REQUIRED_VERSION_MINOR="3"
2203         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2204             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2205         fi
2206
2207         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2208
2209         if $LLVM_CONFIG --components | grep -q inteljitevents ; then
2210             LLVM_COMPONENTS="${LLVM_COMPONENTS} inteljitevents"
2211         fi
2212
2213         if test "x$enable_opencl" = xyes; then
2214             llvm_check_version_for "3" "6" "0" "opencl"
2215
2216             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2217             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2218         fi
2219         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2220         MESA_LLVM=1
2221
2222         dnl Check for Clang internal headers
2223         if test "x$enable_opencl" = xyes; then
2224             if test -z "$CLANG_LIBDIR"; then
2225                 CLANG_LIBDIR=${LLVM_LIBDIR}
2226             fi
2227             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2228             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2229                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2230         fi
2231     else
2232         MESA_LLVM=0
2233         LLVM_VERSION_INT=0
2234     fi
2235 else
2236     MESA_LLVM=0
2237     LLVM_VERSION_INT=0
2238
2239     if test "x$enable_opencl" = xyes; then
2240         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2241     fi
2242 fi
2243
2244 dnl Directory for XVMC libs
2245 AC_ARG_WITH([xvmc-libdir],
2246     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2247         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2248     [XVMC_LIB_INSTALL_DIR="$withval"],
2249     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2250 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2251
2252 dnl
2253 dnl Gallium Tests
2254 dnl
2255 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2256
2257 dnl Directory for VDPAU libs
2258 AC_ARG_WITH([vdpau-libdir],
2259     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2260         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2261     [VDPAU_LIB_INSTALL_DIR="$withval"],
2262     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2263 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2264
2265 dnl Directory for OMX libs
2266
2267 AC_ARG_WITH([omx-libdir],
2268     [AS_HELP_STRING([--with-omx-libdir=DIR],
2269         [directory for the OMX libraries])],
2270     [OMX_LIB_INSTALL_DIR="$withval"],
2271     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2272 AC_SUBST([OMX_LIB_INSTALL_DIR])
2273
2274 dnl Directory for VA libs
2275
2276 AC_ARG_WITH([va-libdir],
2277     [AS_HELP_STRING([--with-va-libdir=DIR],
2278         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2279     [VA_LIB_INSTALL_DIR="$withval"],
2280     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2281 AC_SUBST([VA_LIB_INSTALL_DIR])
2282
2283 AC_ARG_WITH([d3d-libdir],
2284     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2285         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2286     [D3D_DRIVER_INSTALL_DIR="$withval"],
2287     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2288 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2289
2290 dnl
2291 dnl Gallium helper functions
2292 dnl
2293 gallium_require_llvm() {
2294     if test "x$MESA_LLVM" = x0; then
2295         case "$host" in *gnux32) return;; esac
2296         case "$host_cpu" in
2297         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2298         esac
2299     fi
2300 }
2301
2302 dnl
2303 dnl DRM is needed by X, Wayland, and offscreen rendering.
2304 dnl Surfaceless is an alternative for the last one.
2305 dnl
2306 require_basic_egl() {
2307     case "$with_egl_platforms" in
2308         *drm*|*surfaceless*)
2309             ;;
2310         *)
2311             AC_MSG_ERROR([$1 requires one of these:
2312                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2313                   2) --with-egl-platforms=surfaceless (offscreen only)
2314                   Recommended options: drm,x11])
2315             ;;
2316     esac
2317 }
2318
2319 radeon_llvm_check() {
2320     if test ${LLVM_VERSION_INT} -lt 307; then
2321         amdgpu_llvm_target_name='r600'
2322     else
2323         amdgpu_llvm_target_name='amdgpu'
2324     fi
2325     llvm_check_version_for $2 $3 $4 $1
2326     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2327         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2328     fi
2329     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2330     NEED_RADEON_LLVM=yes
2331     if test "x$have_libelf" != xyes; then
2332        AC_MSG_ERROR([$1 requires libelf when using llvm])
2333     fi
2334 }
2335
2336 radeon_gallium_llvm_check() {
2337     if test "x$enable_gallium_llvm" != "xyes"; then
2338         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2339     fi
2340     radeon_llvm_check $*
2341 }
2342
2343 swr_llvm_check() {
2344     gallium_require_llvm $1
2345     if test ${LLVM_VERSION_INT} -lt 306; then
2346         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2347     fi
2348     if test "x$enable_gallium_llvm" != "xyes"; then
2349         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2350     fi
2351 }
2352
2353 swr_require_cxx_feature_flags() {
2354     feature_name="$1"
2355     preprocessor_test="$2"
2356     option_list="$3"
2357     output_var="$4"
2358
2359     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2360     AC_LANG_PUSH([C++])
2361     save_CXXFLAGS="$CXXFLAGS"
2362     save_IFS="$IFS"
2363     IFS=","
2364     found=0
2365     for opts in $option_list
2366     do
2367         unset IFS
2368         CXXFLAGS="$opts $save_CXXFLAGS"
2369         AC_COMPILE_IFELSE(
2370             [AC_LANG_PROGRAM(
2371                 [   #if !($preprocessor_test)
2372                     #error
2373                     #endif
2374                 ])],
2375             [found=1; break],
2376             [])
2377         IFS=","
2378     done
2379     IFS="$save_IFS"
2380     CXXFLAGS="$save_CXXFLAGS"
2381     AC_LANG_POP([C++])
2382     if test $found -eq 1; then
2383         AC_MSG_RESULT([$opts])
2384         eval "$output_var=\$opts"
2385         return 0
2386     fi
2387     AC_MSG_RESULT([no])
2388     AC_MSG_ERROR([swr requires $feature_name support])
2389     return 1
2390 }
2391
2392 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2393 if test -n "$with_gallium_drivers"; then
2394     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2395     for driver in $gallium_drivers; do
2396         case "x$driver" in
2397         xsvga)
2398             HAVE_GALLIUM_SVGA=yes
2399             require_libdrm "svga"
2400             ;;
2401         xi915)
2402             HAVE_GALLIUM_I915=yes
2403             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2404             require_libdrm "Gallium i915"
2405             ;;
2406         xilo)
2407             HAVE_GALLIUM_ILO=yes
2408             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2409             require_libdrm "Gallium i965/ilo"
2410             ;;
2411         xr300)
2412             HAVE_GALLIUM_R300=yes
2413             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2414             require_libdrm "Gallium R300"
2415             gallium_require_llvm "Gallium R300"
2416             ;;
2417         xr600)
2418             HAVE_GALLIUM_R600=yes
2419             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2420             require_libdrm "Gallium R600"
2421             if test "x$enable_opencl" = xyes; then
2422                 radeon_gallium_llvm_check "r600g" "3" "6" "0"
2423                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2424             fi
2425             ;;
2426         xradeonsi)
2427             HAVE_GALLIUM_RADEONSI=yes
2428             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2429             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2430             require_libdrm "radeonsi"
2431             radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2432             require_basic_egl "radeonsi"
2433             ;;
2434         xnouveau)
2435             HAVE_GALLIUM_NOUVEAU=yes
2436             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2437             require_libdrm "nouveau"
2438             ;;
2439         xfreedreno)
2440             HAVE_GALLIUM_FREEDRENO=yes
2441             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2442             require_libdrm "freedreno"
2443             ;;
2444         xswrast)
2445             HAVE_GALLIUM_SOFTPIPE=yes
2446             if test "x$MESA_LLVM" = x1; then
2447                 HAVE_GALLIUM_LLVMPIPE=yes
2448             fi
2449             ;;
2450         xswr)
2451             swr_llvm_check "swr"
2452
2453             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2454                 ",-std=c++11" \
2455                 SWR_CXX11_CXXFLAGS
2456             AC_SUBST([SWR_CXX11_CXXFLAGS])
2457
2458             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2459                 ",-mavx,-march=core-avx" \
2460                 SWR_AVX_CXXFLAGS
2461             AC_SUBST([SWR_AVX_CXXFLAGS])
2462
2463             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2464                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2465                 SWR_AVX2_CXXFLAGS
2466             AC_SUBST([SWR_AVX2_CXXFLAGS])
2467
2468             HAVE_GALLIUM_SWR=yes
2469             ;;
2470         xvc4)
2471             HAVE_GALLIUM_VC4=yes
2472             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2473             require_libdrm "vc4"
2474
2475             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2476                               [USE_VC4_SIMULATOR=yes;
2477                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2478                               [USE_VC4_SIMULATOR=no])
2479             ;;
2480         xvirgl)
2481             HAVE_GALLIUM_VIRGL=yes
2482             require_libdrm "virgl"
2483             require_basic_egl "virgl"
2484             ;;
2485         *)
2486             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2487             ;;
2488         esac
2489     done
2490 fi
2491
2492 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2493     radeon_llvm_check "radv" "3" "9" "0"
2494 fi
2495
2496 dnl Set LLVM_LIBS - This is done after the driver configuration so
2497 dnl that drivers can add additional components to LLVM_COMPONENTS.
2498 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2499 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2500 dnl this was causing the same libraries to be appear multiple times
2501 dnl in LLVM_LIBS.
2502
2503 if test "x$MESA_LLVM" != x0; then
2504
2505     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2506        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2507     fi
2508     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2509
2510     dnl llvm-config may not give the right answer when llvm is a built as a
2511     dnl single shared library, so we must work the library name out for
2512     dnl ourselves.
2513     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2514     if test "x$enable_llvm_shared_libs" = xyes; then
2515         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2516         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2517         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2518
2519         if test "x$llvm_have_one_so" = xyes; then
2520             dnl LLVM was built using auto*, so there is only one shared object.
2521             LLVM_LIBS="-l$LLVM_SO_NAME"
2522         else
2523             dnl If LLVM was built with CMake, there will be one shared object per
2524             dnl component.
2525             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2526                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2527         Please make sure you have built llvm with the --enable-shared option
2528         and that your llvm libraries are installed in $LLVM_LIBDIR
2529         If you have installed your llvm libraries to a different directory you
2530         can use the --with-llvm-prefix= configure flag to specify this directory.
2531         NOTE: Mesa is attempting to use llvm shared libraries by default.
2532         If you do not want to build with llvm shared libraries and instead want to
2533         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2534         invocation and rebuild.])])
2535
2536            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2537            dnl install uses a shared object for each component and we have
2538            dnl already added all of these objects to LLVM_LIBS.
2539         fi
2540     else
2541         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2542         dnl We need to link to llvm system libs when using static libs
2543         dnl However, only llvm 3.5+ provides --system-libs
2544         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2545             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2546         fi
2547     fi
2548 fi
2549
2550 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2551 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2552 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2557                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2558 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2559 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2560 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2561 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2562 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2563 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2564                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2565                                          "x$HAVE_GALLIUM_SWR" = xyes)
2566 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2567 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2568
2569 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2570
2571 if test "x$enable_dri" = xyes; then
2572     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2573 fi
2574
2575 if test "x$have_drisw_kms" = xyes; then
2576     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2577 fi
2578 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2579
2580 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2581 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2582 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2583 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2584 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2585 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2586
2587 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2588 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2589
2590 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2591                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2592                                       "x$HAVE_RADEON_VULKAN" = xyes)
2593
2594 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2595                                         "x$HAVE_I965_DRI" = xyes)
2596
2597 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2598                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2599                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2600 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2601 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2602 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2603 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2604 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2605 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2606     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2607 fi
2608
2609 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2610 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2612 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2613                                         "x$enable_gallium_osmesa" = xyes)
2614
2615 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2616 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2617 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2618
2619 AC_SUBST([NINE_MAJOR], 1)
2620 AC_SUBST([NINE_MINOR], 0)
2621 AC_SUBST([NINE_TINY], 0)
2622 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2623
2624 AC_SUBST([VDPAU_MAJOR], 1)
2625 AC_SUBST([VDPAU_MINOR], 0)
2626
2627 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2628 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2629 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2630 AC_SUBST([VA_MINOR], $VA_MINOR)
2631
2632 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2633
2634 AC_SUBST([XVMC_MAJOR], 1)
2635 AC_SUBST([XVMC_MINOR], 0)
2636
2637 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2638 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2639 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2640 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2641
2642 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2643 AC_SUBST([XA_MINOR], $XA_MINOR)
2644 AC_SUBST([XA_TINY], $XA_TINY)
2645 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2646
2647 AC_SUBST([TIMESTAMP_CMD], '`test $(SOURCE_DATE_EPOCH) && echo $(SOURCE_DATE_EPOCH) || date +%s`')
2648
2649 AC_ARG_ENABLE(valgrind,
2650               [AS_HELP_STRING([--enable-valgrind],
2651                              [Build mesa with valgrind support (default: auto)])],
2652                              [VALGRIND=$enableval], [VALGRIND=auto])
2653 if test "x$VALGRIND" != xno; then
2654         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2655 fi
2656 AC_MSG_CHECKING([whether to enable Valgrind support])
2657 if test "x$VALGRIND" = xauto; then
2658         VALGRIND="$have_valgrind"
2659 fi
2660
2661 if test "x$VALGRIND" = "xyes"; then
2662         if ! test "x$have_valgrind" = xyes; then
2663                 AC_MSG_ERROR([Valgrind support required but not present])
2664         fi
2665         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2666 fi
2667
2668 AC_MSG_RESULT([$VALGRIND])
2669
2670 dnl Restore LDFLAGS and CPPFLAGS
2671 LDFLAGS="$_SAVE_LDFLAGS"
2672 CPPFLAGS="$_SAVE_CPPFLAGS"
2673
2674 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2675 if test "x$acv_mesa_CLANG" = xyes; then
2676     CFLAGS="$CFLAGS -Qunused-arguments"
2677     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2678 fi
2679
2680 dnl Add user CFLAGS and CXXFLAGS
2681 CFLAGS="$CFLAGS $USER_CFLAGS"
2682 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2683
2684 dnl Substitute the config
2685 AC_CONFIG_FILES([Makefile
2686                 src/Makefile
2687                 src/amd/Makefile
2688                 src/amd/common/Makefile
2689                 src/amd/vulkan/Makefile
2690                 src/compiler/Makefile
2691                 src/egl/Makefile
2692                 src/egl/main/egl.pc
2693                 src/egl/wayland/wayland-drm/Makefile
2694                 src/egl/wayland/wayland-egl/Makefile
2695                 src/egl/wayland/wayland-egl/wayland-egl.pc
2696                 src/gallium/Makefile
2697                 src/gallium/auxiliary/Makefile
2698                 src/gallium/auxiliary/pipe-loader/Makefile
2699                 src/gallium/drivers/freedreno/Makefile
2700                 src/gallium/drivers/ddebug/Makefile
2701                 src/gallium/drivers/i915/Makefile
2702                 src/gallium/drivers/ilo/Makefile
2703                 src/gallium/drivers/llvmpipe/Makefile
2704                 src/gallium/drivers/noop/Makefile
2705                 src/gallium/drivers/nouveau/Makefile
2706                 src/gallium/drivers/r300/Makefile
2707                 src/gallium/drivers/r600/Makefile
2708                 src/gallium/drivers/radeon/Makefile
2709                 src/gallium/drivers/radeonsi/Makefile
2710                 src/gallium/drivers/rbug/Makefile
2711                 src/gallium/drivers/softpipe/Makefile
2712                 src/gallium/drivers/svga/Makefile
2713                 src/gallium/drivers/swr/Makefile
2714                 src/gallium/drivers/trace/Makefile
2715                 src/gallium/drivers/vc4/Makefile
2716                 src/gallium/drivers/virgl/Makefile
2717                 src/gallium/state_trackers/clover/Makefile
2718                 src/gallium/state_trackers/dri/Makefile
2719                 src/gallium/state_trackers/glx/xlib/Makefile
2720                 src/gallium/state_trackers/nine/Makefile
2721                 src/gallium/state_trackers/omx/Makefile
2722                 src/gallium/state_trackers/osmesa/Makefile
2723                 src/gallium/state_trackers/va/Makefile
2724                 src/gallium/state_trackers/vdpau/Makefile
2725                 src/gallium/state_trackers/xa/Makefile
2726                 src/gallium/state_trackers/xvmc/Makefile
2727                 src/gallium/targets/d3dadapter9/Makefile
2728                 src/gallium/targets/d3dadapter9/d3d.pc
2729                 src/gallium/targets/dri/Makefile
2730                 src/gallium/targets/libgl-xlib/Makefile
2731                 src/gallium/targets/omx/Makefile
2732                 src/gallium/targets/opencl/Makefile
2733                 src/gallium/targets/opencl/mesa.icd
2734                 src/gallium/targets/osmesa/Makefile
2735                 src/gallium/targets/osmesa/osmesa.pc
2736                 src/gallium/targets/pipe-loader/Makefile
2737                 src/gallium/targets/va/Makefile
2738                 src/gallium/targets/vdpau/Makefile
2739                 src/gallium/targets/xa/Makefile
2740                 src/gallium/targets/xa/xatracker.pc
2741                 src/gallium/targets/xvmc/Makefile
2742                 src/gallium/tests/trivial/Makefile
2743                 src/gallium/tests/unit/Makefile
2744                 src/gallium/winsys/freedreno/drm/Makefile
2745                 src/gallium/winsys/i915/drm/Makefile
2746                 src/gallium/winsys/intel/drm/Makefile
2747                 src/gallium/winsys/nouveau/drm/Makefile
2748                 src/gallium/winsys/radeon/drm/Makefile
2749                 src/gallium/winsys/amdgpu/drm/Makefile
2750                 src/gallium/winsys/svga/drm/Makefile
2751                 src/gallium/winsys/sw/dri/Makefile
2752                 src/gallium/winsys/sw/kms-dri/Makefile
2753                 src/gallium/winsys/sw/null/Makefile
2754                 src/gallium/winsys/sw/wrapper/Makefile
2755                 src/gallium/winsys/sw/xlib/Makefile
2756                 src/gallium/winsys/vc4/drm/Makefile
2757                 src/gallium/winsys/virgl/drm/Makefile
2758                 src/gallium/winsys/virgl/vtest/Makefile
2759                 src/gbm/Makefile
2760                 src/gbm/main/gbm.pc
2761                 src/glx/Makefile
2762                 src/glx/apple/Makefile
2763                 src/glx/tests/Makefile
2764                 src/glx/windows/Makefile
2765                 src/glx/windows/windowsdriproto.pc
2766                 src/gtest/Makefile
2767                 src/intel/Makefile
2768                 src/intel/tools/Makefile
2769                 src/intel/vulkan/Makefile
2770                 src/loader/Makefile
2771                 src/mapi/Makefile
2772                 src/mapi/es1api/glesv1_cm.pc
2773                 src/mapi/es2api/glesv2.pc
2774                 src/mapi/glapi/gen/Makefile
2775                 src/mesa/Makefile
2776                 src/mesa/gl.pc
2777                 src/mesa/drivers/dri/dri.pc
2778                 src/mesa/drivers/dri/common/Makefile
2779                 src/mesa/drivers/dri/common/xmlpool/Makefile
2780                 src/mesa/drivers/dri/i915/Makefile
2781                 src/mesa/drivers/dri/i965/Makefile
2782                 src/mesa/drivers/dri/Makefile
2783                 src/mesa/drivers/dri/nouveau/Makefile
2784                 src/mesa/drivers/dri/r200/Makefile
2785                 src/mesa/drivers/dri/radeon/Makefile
2786                 src/mesa/drivers/dri/swrast/Makefile
2787                 src/mesa/drivers/osmesa/Makefile
2788                 src/mesa/drivers/osmesa/osmesa.pc
2789                 src/mesa/drivers/x11/Makefile
2790                 src/mesa/main/tests/Makefile
2791                 src/util/Makefile
2792                 src/util/tests/hash_table/Makefile
2793                 src/vulkan/wsi/Makefile])
2794
2795 AC_OUTPUT
2796
2797 # Fix up dependencies in *.Plo files, where we changed the extension of a
2798 # source file
2799 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2800
2801
2802 dnl
2803 dnl Output some configuration info for the user
2804 dnl
2805 echo ""
2806 echo "        prefix:          $prefix"
2807 echo "        exec_prefix:     $exec_prefix"
2808 echo "        libdir:          $libdir"
2809 echo "        includedir:      $includedir"
2810
2811 dnl API info
2812 echo ""
2813 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2814
2815 dnl Driver info
2816 echo ""
2817 case "x$enable_osmesa$enable_gallium_osmesa" in
2818 xnoyes)
2819         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2820         ;;
2821 xyesno)
2822         echo "        OSMesa:          lib$OSMESA_LIB"
2823         ;;
2824 xnono)
2825         echo "        OSMesa:          no"
2826         ;;
2827 esac
2828
2829 echo ""
2830 if test "x$enable_dri" != xno; then
2831         echo "        DRI platform:    $dri_platform"
2832         if test -z "$DRI_DIRS"; then
2833             echo "        DRI drivers:     no"
2834         else
2835             echo "        DRI drivers:     $DRI_DIRS"
2836         fi
2837         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2838 fi
2839
2840 case "x$enable_glx" in
2841 xdri)
2842     echo "        GLX:             DRI-based"
2843     ;;
2844 xxlib)
2845     echo "        GLX:             Xlib-based"
2846     ;;
2847 xgallium-xlib)
2848     echo "        GLX:             Xlib-based (Gallium)"
2849     ;;
2850 *)
2851     echo "        GLX:             $enable_glx"
2852     ;;
2853 esac
2854
2855 dnl EGL
2856 echo ""
2857 echo "        EGL:             $enable_egl"
2858 if test "$enable_egl" = yes; then
2859     echo "        EGL platforms:   $egl_platforms"
2860
2861     egl_drivers=""
2862     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2863         egl_drivers="$egl_drivers builtin:egl_dri2"
2864     fi
2865     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2866         egl_drivers="$egl_drivers builtin:egl_dri3"
2867     fi
2868
2869     echo "        EGL drivers:    $egl_drivers"
2870 fi
2871 if test "x$enable_gbm" = xyes; then
2872     echo "        GBM:             yes"
2873 else
2874     echo "        GBM:             no"
2875 fi
2876
2877 # Vulkan
2878 echo ""
2879 if test "x$VULKAN_DRIVERS" != x; then
2880     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2881     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2882 else
2883     echo "        Vulkan drivers:  no"
2884 fi
2885
2886 echo ""
2887 if test "x$MESA_LLVM" = x1; then
2888     echo "        llvm:            yes"
2889     echo "        llvm-config:     $LLVM_CONFIG"
2890     echo "        llvm-version:    $LLVM_VERSION"
2891 else
2892     echo "        llvm:            no"
2893 fi
2894
2895 echo ""
2896 if test -n "$with_gallium_drivers"; then
2897     echo "        Gallium drivers: $gallium_drivers"
2898     echo "        Gallium st:      $gallium_st"
2899 else
2900     echo "        Gallium:         no"
2901 fi
2902
2903 echo ""
2904 if test "x$enable_gallium_extra_hud" != xyes; then
2905     echo "        HUD extra stats: no"
2906 else
2907     echo "        HUD extra stats: yes"
2908 fi
2909
2910 if test "x$enable_lmsensors" != xyes; then
2911     echo "        HUD lmsensors:   no"
2912 else
2913     echo "        HUD lmsensors:   yes"
2914 fi
2915
2916 dnl Shader cache
2917 echo ""
2918 echo "        Shader cache:    $enable_shader_cache"
2919 if test "x$enable_shader_cache" = "xyes"; then
2920     echo "        With SHA1 from:  $with_sha1"
2921 fi
2922
2923 dnl Libraries
2924 echo ""
2925 echo "        Shared libs:     $enable_shared"
2926 echo "        Static libs:     $enable_static"
2927 echo "        Shared-glapi:    $enable_shared_glapi"
2928
2929 dnl Compiler options
2930 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2931 cflags=`echo $CFLAGS | \
2932     $SED 's/^ *//;s/  */ /;s/ *$//'`
2933 cxxflags=`echo $CXXFLAGS | \
2934     $SED 's/^ *//;s/  */ /;s/ *$//'`
2935 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2936 echo ""
2937 echo "        CFLAGS:          $cflags"
2938 echo "        CXXFLAGS:        $cxxflags"
2939 echo "        Macros:          $defines"
2940 echo ""
2941 if test "x$MESA_LLVM" = x1; then
2942     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2943     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2944     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2945     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2946     echo ""
2947 fi
2948 echo "        PYTHON2:         $PYTHON2"
2949
2950 echo ""
2951 echo "        Run '${MAKE-make}' to build Mesa"
2952 echo ""