configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.82
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl
 286 dnl Check compiler flags
 287 dnl
 288 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 289 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 290 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 291 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 292 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 293 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 294 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 295
 296 dnl
 297 dnl Check C++ compiler flags
 298 dnl
 299 AC_LANG_PUSH([C++])
 300 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 301 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 302 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 303 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 304 AC_LANG_POP([C++])
 305
 306 # Flags to help ensure that certain portions of the code -- and only those
 307 # portions -- can be built with MSVC:
 308 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 309 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 310 #   supports most of C99)
 311 # - the rest has no compiler compiler restrictions
 312 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"])
 313 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="-Werror=vla"])
 314 AC_LANG_PUSH([C++])
 315 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"])
 316 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="-Werror=vla"])
 317 AC_LANG_POP([C++])
 318
 319 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 320 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 321
 322 if test "x$GCC" = xyes; then
 323     if test "x$USE_GNU99" = xyes; then
 324         CFLAGS="$CFLAGS -std=gnu99"
 325     else
 326         CFLAGS="$CFLAGS -std=c99"
 327     fi
 328 fi
 329
 330 dnl even if the compiler appears to support it, using visibility attributes isn't
 331 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 332 case "$host_os" in
 333 cygwin*)
 334     VISIBILITY_CFLAGS=""
 335     VISIBILITY_CXXFLAGS=""
 336     ;;
 337 esac
 338
 339 AC_SUBST([VISIBILITY_CFLAGS])
 340 AC_SUBST([VISIBILITY_CXXFLAGS])
 341
 342 dnl
 343 dnl Optional flags, check for compiler support
 344 dnl
 345 SSE41_CFLAGS="-msse4.1"
 346 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 347 dnl stack, but on x86-32 such alignment is not guaranteed.
 348 case "$target_cpu" in
 349 i?86)
 350     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 351     ;;
 352 esac
 353 save_CFLAGS="$CFLAGS"
 354 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 355 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 356 #include <smmintrin.h>
 357 int param;
 358 int main () {
 359     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 360     c = _mm_max_epu32(a, b);
 361     return _mm_cvtsi128_si32(c);
 362 }]])], SSE41_SUPPORTED=1)
 363 CFLAGS="$save_CFLAGS"
 364 if test "x$SSE41_SUPPORTED" = x1; then
 365     DEFINES="$DEFINES -DUSE_SSE41"
 366 fi
 367 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 368 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 369
 370 dnl Check for new-style atomic builtins
 371 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 372 int main() {
 373     int n;
 374     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 375 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 376 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 377     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 378 fi
 379 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 380
 381 dnl Check if host supports 64-bit atomics
 382 dnl note that lack of support usually results in link (not compile) error
 383 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 384 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 385 #include <stdint.h>
 386 uint64_t v;
 387 int main() {
 388     return __sync_add_and_fetch(&v, (uint64_t)1);
 389 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 390 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 391     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 392 fi
 393 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 394
 395 dnl Check for Endianness
 396 AC_C_BIGENDIAN(
 397    little_endian=no,
 398    little_endian=yes,
 399    little_endian=no,
 400    little_endian=no
 401 )
 402
 403 dnl Check for POWER8 Architecture
 404 PWR8_CFLAGS="-mpower8-vector"
 405 have_pwr8_intrinsics=no
 406 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 407 save_CFLAGS=$CFLAGS
 408 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 409 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 410 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 411 #error "Need GCC >= 4.8 for sane POWER8 support"
 412 #endif
 413 #include <altivec.h>
 414 int main () {
 415     vector unsigned char r;
 416     vector unsigned int v = vec_splat_u32 (1);
 417     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 418     return 0;
 419 }]])], have_pwr8_intrinsics=yes)
 420 CFLAGS=$save_CFLAGS
 421
 422 AC_ARG_ENABLE(pwr8,
 423    [AS_HELP_STRING([--disable-pwr8],
 424                    [disable POWER8-specific instructions])],
 425    [enable_pwr8=$enableval], [enable_pwr8=auto])
 426
 427 if test "x$enable_pwr8" = xno ; then
 428    have_pwr8_intrinsics=disabled
 429 fi
 430
 431 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 432    DEFINES="$DEFINES -D_ARCH_PWR8"
 433    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 434    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 435 else
 436    PWR8_CFLAGS=
 437 fi
 438
 439 AC_MSG_RESULT($have_pwr8_intrinsics)
 440 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 441    AC_MSG_ERROR([POWER8 compiler support not detected])
 442 fi
 443
 444 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 445    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 446 fi
 447
 448 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 449
 450 dnl Can't have static and shared libraries, default to static if user
 451 dnl explicitly requested. If both disabled, set to static since shared
 452 dnl was explicitly requested.
 453 case "x$enable_static$enable_shared" in
 454 xyesyes)
 455     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 456     ;;
 457 xnono)
 458     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 459     ;;
 460 esac
 461
 462 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 463
 464 dnl
 465 dnl other compiler options
 466 dnl
 467 AC_ARG_ENABLE([debug],
 468     [AS_HELP_STRING([--enable-debug],
 469         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 470     [enable_debug="$enableval"],
 471     [enable_debug=no]
 472 )
 473
 474 AC_ARG_ENABLE([profile],
 475     [AS_HELP_STRING([--enable-profile],
 476         [enable profiling of code @<:@default=disabled@:>@])],
 477     [enable_profile="$enableval"],
 478     [enable_profile=no]
 479 )
 480
 481 AC_ARG_ENABLE([sanitize],
 482     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 483         [enable code sanitizer @<:@default=disabled@:>@])],
 484     [enable_sanitize="$enableval"],
 485     [enable_sanitize=no])
 486
 487 if test "x$enable_profile" = xyes; then
 488     DEFINES="$DEFINES -DPROFILE"
 489     if test "x$GCC" = xyes; then
 490         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 491     fi
 492     if test "x$GXX" = xyes; then
 493         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 494     fi
 495 fi
 496
 497 if test "x$enable_debug" = xyes; then
 498     DEFINES="$DEFINES -DDEBUG"
 499     if test "x$enable_profile" = xyes; then
 500         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 501     fi
 502     if test "x$GCC" = xyes; then
 503         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 504             CFLAGS="$CFLAGS -g"
 505         fi
 506         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 507             CFLAGS="$CFLAGS -O0"
 508         fi
 509     fi
 510     if test "x$GXX" = xyes; then
 511         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 512             CXXFLAGS="$CXXFLAGS -g"
 513         fi
 514         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 515             CXXFLAGS="$CXXFLAGS -O0"
 516         fi
 517     fi
 518 else
 519    DEFINES="$DEFINES -DNDEBUG"
 520 fi
 521
 522 if test "x$enable_sanitize" != xno; then
 523     if test "x$enable_profile" = xyes; then
 524         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 525     fi
 526
 527     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 528     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 529     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 530
 531     AC_LINK_IFELSE(
 532         [AC_LANG_SOURCE([int main(){return 0;}])],
 533         [],
 534         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 535 fi
 536
 537 dnl
 538 dnl Check if linker supports -Bsymbolic
 539 dnl
 540 save_LDFLAGS=$LDFLAGS
 541 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 542 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 543 AC_LINK_IFELSE(
 544     [AC_LANG_SOURCE([int main() { return 0;}])],
 545     [AC_MSG_RESULT([yes])
 546         BSYMBOLIC="-Wl,-Bsymbolic";],
 547     [AC_MSG_RESULT([no])
 548         BSYMBOLIC="";])
 549 LDFLAGS=$save_LDFLAGS
 550
 551 AC_SUBST([BSYMBOLIC])
 552
 553 dnl
 554 dnl Check if linker supports garbage collection
 555 dnl
 556 save_LDFLAGS=$LDFLAGS
 557 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 558 AC_MSG_CHECKING([whether ld supports --gc-sections])
 559 AC_LINK_IFELSE(
 560     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 561     [AC_MSG_RESULT([yes])
 562         GC_SECTIONS="-Wl,--gc-sections";],
 563     [AC_MSG_RESULT([no])
 564         GC_SECTIONS="";])
 565 LDFLAGS=$save_LDFLAGS
 566
 567 AC_SUBST([GC_SECTIONS])
 568
 569 dnl
 570 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 571 dnl so when these flags are passed to ld via libtool the checks will fail
 572 dnl
 573 case "$host_os" in
 574 openbsd* | darwin* )
 575     LD_NO_UNDEFINED="" ;;
 576 *)
 577     if test "x$enable_sanitize" = xno; then
 578         LD_NO_UNDEFINED="-Wl,--no-undefined"
 579     else
 580         LD_NO_UNDEFINED=""
 581     fi
 582     ;;
 583 esac
 584
 585 AC_SUBST([LD_NO_UNDEFINED])
 586
 587 dnl
 588 dnl Check if linker supports version scripts
 589 dnl
 590 AC_MSG_CHECKING([if the linker supports version-scripts])
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 593 cat > conftest.map <<EOF
 594 VERSION_1 {
 595      global:
 596          main;
 597
 598      local:
 599          *;
 600 };
 601 EOF
 602 AC_LINK_IFELSE(
 603     [AC_LANG_SOURCE([int main() { return 0;}])],
 604     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 605     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 606 LDFLAGS=$save_LDFLAGS
 607 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 608
 609 dnl
 610 dnl Check if linker supports dynamic list files
 611 dnl
 612 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 613 save_LDFLAGS=$LDFLAGS
 614 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 615 cat > conftest.dyn <<EOF
 616 {
 617         radeon_drm_winsys_create;
 618 };
 619 EOF
 620 AC_LINK_IFELSE(
 621     [AC_LANG_SOURCE([int main() { return 0;}])],
 622     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 623     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 624 LDFLAGS=$save_LDFLAGS
 625 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 626
 627 dnl
 628 dnl compatibility symlinks
 629 dnl
 630 case "$host_os" in
 631 linux* )
 632     HAVE_COMPAT_SYMLINKS=yes ;;
 633 * )
 634     HAVE_COMPAT_SYMLINKS=no ;;
 635 esac
 636
 637 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 638
 639 dnl
 640 dnl library names
 641 dnl
 642 dnl Unfortunately we need to do a few things that libtool can't help us with,
 643 dnl so we need some knowledge of shared library filenames:
 644 dnl
 645 dnl LIB_EXT is the extension used when creating symlinks for alternate
 646 dnl filenames for a shared library which will be dynamically loaded
 647 dnl
 648 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 649 dnl the file for a shared library we wish to link with
 650 dnl
 651 case "$host_os" in
 652 darwin* )
 653     LIB_EXT='dylib'
 654     IMP_LIB_EXT=$LIB_EXT
 655     ;;
 656 cygwin* )
 657     LIB_EXT='dll'
 658     IMP_LIB_EXT='dll.a'
 659     ;;
 660 aix* )
 661     LIB_EXT='a'
 662     IMP_LIB_EXT=$LIB_EXT
 663     ;;
 664 * )
 665     LIB_EXT='so'
 666     IMP_LIB_EXT=$LIB_EXT
 667     ;;
 668 esac
 669
 670 AC_SUBST([LIB_EXT])
 671
 672 dnl
 673 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 674 dnl
 675 AC_ARG_ENABLE([texture-float],
 676     [AS_HELP_STRING([--enable-texture-float],
 677         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 678     [enable_texture_float="$enableval"],
 679     [enable_texture_float=no]
 680 )
 681 if test "x$enable_texture_float" = xyes; then
 682     AC_MSG_WARN([Floating-point textures enabled.])
 683     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 684     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 685 fi
 686
 687 dnl
 688 dnl Arch/platform-specific settings
 689 dnl
 690 AC_ARG_ENABLE([asm],
 691     [AS_HELP_STRING([--disable-asm],
 692         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 693     [enable_asm="$enableval"],
 694     [enable_asm=yes]
 695 )
 696 asm_arch=""
 697 AC_MSG_CHECKING([whether to enable assembly])
 698 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 699 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 700 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 701     case "$host_cpu" in
 702     i?86 | x86_64 | amd64)
 703         if test "x$host_cpu" != "x$target_cpu"; then
 704             enable_asm=no
 705             AC_MSG_RESULT([no, cross compiling])
 706         fi
 707         ;;
 708     esac
 709 fi
 710 # check for supported arches
 711 if test "x$enable_asm" = xyes; then
 712     case "$host_cpu" in
 713     i?86)
 714         case "$host_os" in
 715         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 716             asm_arch=x86
 717             ;;
 718         esac
 719         ;;
 720     x86_64|amd64)
 721         case "$host_os" in
 722         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 723             asm_arch=x86_64
 724             ;;
 725         esac
 726         ;;
 727     sparc*)
 728         case "$host_os" in
 729         linux*)
 730             asm_arch=sparc
 731             ;;
 732         esac
 733         ;;
 734     powerpc64le)
 735         case "$host_os" in
 736         linux*)
 737             asm_arch=ppc64le
 738             ;;
 739         esac
 740         ;;
 741     aarch64)
 742         case "$host_os" in
 743         linux*)
 744             asm_arch=aarch64
 745             ;;
 746         esac
 747         ;;
 748     arm)
 749         case "$host_os" in
 750         linux*)
 751             asm_arch=arm
 752             ;;
 753         esac
 754         ;;
 755     esac
 756
 757     case "$asm_arch" in
 758     x86)
 759         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 760         AC_MSG_RESULT([yes, x86])
 761         ;;
 762     x86_64|amd64)
 763         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 764         AC_MSG_RESULT([yes, x86_64])
 765         ;;
 766     sparc)
 767         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 768         AC_MSG_RESULT([yes, sparc])
 769         ;;
 770     ppc64le)
 771         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 772         AC_MSG_RESULT([yes, ppc64le])
 773         ;;
 774     aarch64)
 775         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 776         AC_MSG_RESULT([yes, aarch64])
 777         ;;
 778     arm)
 779         DEFINES="$DEFINES -DUSE_ARM_ASM"
 780         AC_MSG_RESULT([yes, arm])
 781         ;;
 782     *)
 783         AC_MSG_RESULT([no, platform not supported])
 784         ;;
 785     esac
 786 fi
 787
 788 AC_HEADER_MAJOR
 789 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 790 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 791 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 792 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 793
 794 dnl Check to see if dlopen is in default libraries (like Solaris, which
 795 dnl has it in libc), or if libdl is needed to get it.
 796 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 797     [AC_CHECK_LIB([dl], [dlopen],
 798        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 799 AC_SUBST([DLOPEN_LIBS])
 800
 801 dnl Check if that library also has dladdr
 802 save_LIBS="$LIBS"
 803 LIBS="$LIBS $DLOPEN_LIBS"
 804 AC_CHECK_FUNCS([dladdr])
 805 LIBS="$save_LIBS"
 806
 807 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 808
 809 case "$host_os" in
 810 darwin*)
 811     ;;
 812 *)
 813     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 814                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 815                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 816     AC_SUBST([CLOCK_LIB])
 817     ;;
 818 esac
 819
 820 dnl See if posix_memalign is available
 821 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 822
 823 dnl Check for zlib
 824 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 825
 826 dnl Check for pthreads
 827 AX_PTHREAD
 828 if test "x$ax_pthread_ok" = xno; then
 829     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 830 fi
 831 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 832 dnl to -pthread, which causes problems if we need -lpthread to appear in
 833 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 834 dnl is not valid for that platform.
 835 if test "x$android" = xno; then
 836     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 837 fi
 838 dnl According to the manual when using pthreads, one should add -pthread to
 839 dnl both compile and link-time arguments.
 840 dnl In practise that should be sufficient for all platforms, since any
 841 dnl platforms build with GCC and Clang support the flag.
 842 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 843
 844 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 845 dnl project. Even then there's a notable issue as described in the project README
 846 case "$host_os" in
 847 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 848     pthread_stubs_possible="no"
 849     ;;
 850 * )
 851     pthread_stubs_possible="yes"
 852     ;;
 853 esac
 854
 855 if test "x$pthread_stubs_possible" = xyes; then
 856     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 857 fi
 858
 859 dnl SELinux awareness.
 860 AC_ARG_ENABLE([selinux],
 861     [AS_HELP_STRING([--enable-selinux],
 862         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 863     [MESA_SELINUX="$enableval"],
 864     [MESA_SELINUX=no])
 865 if test "x$enable_selinux" = "xyes"; then
 866     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 867         [AC_CHECK_HEADER([selinux/selinux.h],[],
 868                          [AC_MSG_ERROR([SELinux headers not found])])
 869          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 870                       [AC_MSG_ERROR([SELinux library not found])])
 871          SELINUX_LIBS="-lselinux"])
 872     DEFINES="$DEFINES -DMESA_SELINUX"
 873 fi
 874 AC_SUBST([SELINUX_CFLAGS])
 875 AC_SUBST([SELINUX_LIBS])
 876
 877 dnl
 878 dnl LLVM
 879 dnl
 880 AC_ARG_ENABLE([llvm-shared-libs],
 881     [AS_HELP_STRING([--enable-llvm-shared-libs],
 882         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 883     [enable_llvm_shared_libs="$enableval"],
 884     [enable_llvm_shared_libs=yes])
 885
 886 AC_ARG_WITH([llvm-prefix],
 887     [AS_HELP_STRING([--with-llvm-prefix],
 888         [Prefix for LLVM installations in non-standard locations])],
 889     [llvm_prefix="$withval"],
 890     [llvm_prefix=''])
 891
 892 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 893 if test "x$have_libelf" = xno; then
 894    LIBELF_LIBS=''
 895    LIBELF_CFLAGS=''
 896    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 897    AC_SUBST([LIBELF_LIBS])
 898    AC_SUBST([LIBELF_CFLAGS])
 899 fi
 900
 901 if test -z "$LLVM_CONFIG"; then
 902     if test -n "$llvm_prefix"; then
 903         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 904     else
 905         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 906     fi
 907 fi
 908
 909 llvm_add_component() {
 910     new_llvm_component=$1
 911     driver_name=$2
 912
 913     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 914         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 915     else
 916         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 917     fi
 918 }
 919
 920 llvm_add_default_components() {
 921     driver_name=$1
 922
 923     # Required default components
 924     llvm_add_component "bitwriter" $driver_name
 925     llvm_add_component "engine" $driver_name
 926     llvm_add_component "mcdisassembler" $driver_name
 927     llvm_add_component "mcjit" $driver_name
 928
 929     # Optional default components
 930     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 931         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 932     fi
 933 }
 934
 935 llvm_add_target() {
 936     new_llvm_target=$1
 937     driver_name=$2
 938
 939     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 940         llvm_add_component $new_llvm_target $driver_name
 941     else
 942         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 943     fi
 944 }
 945
 946 # Call this inside ` ` to get the return value.
 947 # $1 is the llvm-config command with arguments.
 948 strip_unwanted_llvm_flags() {
 949     echo " `$1` " | sed -E \
 950         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 951         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 952         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 954         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 956         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 957         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 958         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 959         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 960         -e 's/^[[[:space:]]]//' \
 961         -e 's/[[[:space:]]]$//'
 962 }
 963
 964 llvm_set_environment_variables() {
 965     if test "x$LLVM_CONFIG" != xno; then
 966         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 967         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 968         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 969         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 970
 971         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 972         save_CFLAGS="$CFLAGS"
 973         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 974
 975         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 976             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 977         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 978             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 979         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 980             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 981
 982         CFLAGS="$save_CFLAGS"
 983
 984         # Only needed for LLVM < 3.6.0
 985         if test -z "$LLVM_VERSION_PATCH"; then
 986             LLVM_VERSION_PATCH=0
 987         fi
 988
 989         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 990
 991         FOUND_LLVM=yes
 992     else
 993         FOUND_LLVM=no
 994         LLVM_VERSION_INT=0
 995     fi
 996 }
 997
 998 require_llvm() {
 999     if test "x$enable_llvm" != "xyes"; then
1000         AC_MSG_ERROR([--enable-llvm is required when building $1])
1001     fi
1002 }
1003
1004 llvm_require_version() {
1005     require_llvm $2
1006
1007     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1008     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1009     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1010
1011     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1012         # major > required major
1013         #  --> OK
1014         return
1015     fi
1016
1017     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1018         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1019             # major = required major and
1020             # minor > required minor
1021             #  --> OK
1022             return
1023         else
1024             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1025                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1026                     # major = required major and
1027                     # minor = required minor and
1028                     # patch >= required patch
1029                     #  --> OK
1030                     return
1031                 fi
1032             fi
1033         fi
1034     fi
1035
1036     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1037 }
1038
1039 radeon_llvm_check() {
1040     if test ${LLVM_VERSION_INT} -lt 307; then
1041         amdgpu_llvm_target_name='r600'
1042     else
1043         amdgpu_llvm_target_name='amdgpu'
1044     fi
1045
1046     llvm_require_version $*
1047
1048     llvm_add_target $amdgpu_llvm_target_name $2
1049
1050     llvm_add_default_components $2
1051     llvm_add_component "bitreader" $2
1052     llvm_add_component "ipo" $2
1053
1054     if test "x$have_libelf" != xyes; then
1055        AC_MSG_ERROR([$2 requires libelf when using llvm])
1056     fi
1057 }
1058
1059 llvm_set_environment_variables
1060
1061 AC_SUBST([LLVM_CFLAGS])
1062 AC_SUBST([LLVM_CXXFLAGS])
1063 AC_SUBST([LLVM_LIBS])
1064 AC_SUBST([LLVM_LDFLAGS])
1065 AC_SUBST([LLVM_INCLUDEDIR])
1066
1067 dnl
1068 dnl libunwind
1069 dnl
1070 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1071 AC_ARG_ENABLE([libunwind],
1072     [AS_HELP_STRING([--enable-libunwind],
1073             [Use libunwind for backtracing (default: auto)])],
1074         [LIBUNWIND="$enableval"],
1075         [LIBUNWIND="$HAVE_LIBUNWIND"])
1076
1077 if test "x$LIBUNWIND" = "xyes"; then
1078     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1079     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1080 fi
1081
1082
1083 dnl Options for APIs
1084 AC_ARG_ENABLE([opengl],
1085     [AS_HELP_STRING([--disable-opengl],
1086         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1087     [enable_opengl="$enableval"],
1088     [enable_opengl=yes])
1089 AC_ARG_ENABLE([gles1],
1090     [AS_HELP_STRING([--disable-gles1],
1091         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1092     [enable_gles1="$enableval"],
1093     [enable_gles1=yes])
1094 AC_ARG_ENABLE([gles2],
1095     [AS_HELP_STRING([--disable-gles2],
1096         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1097     [enable_gles2="$enableval"],
1098     [enable_gles2=yes])
1099
1100 AC_ARG_ENABLE([dri],
1101     [AS_HELP_STRING([--enable-dri],
1102         [enable DRI modules @<:@default=enabled@:>@])],
1103     [enable_dri="$enableval"],
1104     [enable_dri=yes])
1105
1106 AC_ARG_ENABLE([gallium-extra-hud],
1107     [AS_HELP_STRING([--enable-gallium-extra-hud],
1108         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1109     [enable_gallium_extra_hud="$enableval"],
1110     [enable_gallium_extra_hud=no])
1111 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1112 if test "x$enable_gallium_extra_hud" = xyes ; then
1113     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1114 fi
1115
1116 #TODO: no pkgconfig .pc available for libsensors.
1117 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1118 AC_ARG_ENABLE([lmsensors],
1119     [AS_HELP_STRING([--enable-lmsensors],
1120         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1121     [enable_lmsensors="$enableval"],
1122     [enable_lmsensors=no])
1123 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1124 if test "x$enable_lmsensors" = xyes ; then
1125     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1126     LIBSENSORS_LIBS="-lsensors"
1127 else
1128     LIBSENSORS_LIBS=""
1129 fi
1130 AC_SUBST(LIBSENSORS_LIBS)
1131
1132 case "$host_os" in
1133 linux*)
1134     dri3_default=yes
1135     ;;
1136 *)
1137     dri3_default=no
1138     ;;
1139 esac
1140
1141 if test "x$enable_dri" = xno; then
1142     dri3_default=no
1143 fi
1144
1145 AC_ARG_ENABLE([dri3],
1146     [AS_HELP_STRING([--enable-dri3],
1147         [enable DRI3 @<:@default=auto@:>@])],
1148     [enable_dri3="$enableval"],
1149     [enable_dri3="$dri3_default"])
1150 AC_ARG_ENABLE([glx],
1151     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1152         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1153     [enable_glx="$enableval"],
1154     [enable_glx=yes])
1155 AC_ARG_ENABLE([osmesa],
1156     [AS_HELP_STRING([--enable-osmesa],
1157         [enable OSMesa library @<:@default=disabled@:>@])],
1158     [enable_osmesa="$enableval"],
1159     [enable_osmesa=no])
1160 AC_ARG_ENABLE([gallium-osmesa],
1161     [AS_HELP_STRING([--enable-gallium-osmesa],
1162         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1163     [enable_gallium_osmesa="$enableval"],
1164     [enable_gallium_osmesa=no])
1165 AC_ARG_ENABLE([egl],
1166     [AS_HELP_STRING([--disable-egl],
1167         [disable EGL library @<:@default=enabled@:>@])],
1168     [enable_egl="$enableval"],
1169     [enable_egl=yes])
1170
1171 AC_ARG_ENABLE([xa],
1172     [AS_HELP_STRING([--enable-xa],
1173         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1174     [enable_xa="$enableval"],
1175     [enable_xa=no])
1176 AC_ARG_ENABLE([gbm],
1177    [AS_HELP_STRING([--enable-gbm],
1178          [enable gbm library @<:@default=yes except cygwin@:>@])],
1179    [enable_gbm="$enableval"],
1180    [case "$host_os" in
1181        cygwin*)
1182           enable_gbm=no
1183           ;;
1184        *)
1185           enable_gbm=yes
1186           ;;
1187     esac])
1188 AC_ARG_ENABLE([nine],
1189     [AS_HELP_STRING([--enable-nine],
1190         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1191     [enable_nine="$enableval"],
1192     [enable_nine=no])
1193
1194 AC_ARG_ENABLE([xvmc],
1195    [AS_HELP_STRING([--enable-xvmc],
1196          [enable xvmc library @<:@default=auto@:>@])],
1197    [enable_xvmc="$enableval"],
1198    [enable_xvmc=auto])
1199 AC_ARG_ENABLE([vdpau],
1200    [AS_HELP_STRING([--enable-vdpau],
1201          [enable vdpau library @<:@default=auto@:>@])],
1202    [enable_vdpau="$enableval"],
1203    [enable_vdpau=auto])
1204 AC_ARG_ENABLE([omx],
1205    [AS_HELP_STRING([--enable-omx],
1206          [enable OpenMAX library @<:@default=disabled@:>@])],
1207    [enable_omx="$enableval"],
1208    [enable_omx=no])
1209 AC_ARG_ENABLE([va],
1210    [AS_HELP_STRING([--enable-va],
1211          [enable va library @<:@default=auto@:>@])],
1212    [enable_va="$enableval"],
1213    [enable_va=auto])
1214 AC_ARG_ENABLE([opencl],
1215    [AS_HELP_STRING([--enable-opencl],
1216          [enable OpenCL library @<:@default=disabled@:>@])],
1217    [enable_opencl="$enableval"],
1218    [enable_opencl=no])
1219 AC_ARG_ENABLE([opencl_icd],
1220    [AS_HELP_STRING([--enable-opencl-icd],
1221           [Build an OpenCL ICD library to be loaded by an ICD implementation
1222            @<:@default=disabled@:>@])],
1223     [enable_opencl_icd="$enableval"],
1224     [enable_opencl_icd=no])
1225
1226 AC_ARG_ENABLE([gallium-tests],
1227     [AS_HELP_STRING([--enable-gallium-tests],
1228         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1229     [enable_gallium_tests="$enableval"],
1230     [enable_gallium_tests=no])
1231
1232 # Option for Gallium drivers
1233
1234 # Keep this in sync with the --with-gallium-drivers help string default value
1235 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1236
1237 AC_ARG_WITH([gallium-drivers],
1238     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1239         [comma delimited Gallium drivers list, e.g.
1240         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1241         @<:@default=r300,r600,svga,swrast@:>@])],
1242     [with_gallium_drivers="$withval"],
1243     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1244
1245 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1246 # here so that the script doesn't choke on an unknown driver name later.
1247 case "$with_gallium_drivers" in
1248     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1249     no) with_gallium_drivers='' ;;
1250 esac
1251
1252 if test "x$enable_opengl" = xno -a \
1253         "x$enable_gles1" = xno -a \
1254         "x$enable_gles2" = xno -a \
1255         "x$enable_nine" = xno -a \
1256         "x$enable_xa" = xno -a \
1257         "x$enable_xvmc" = xno -a \
1258         "x$enable_vdpau" = xno -a \
1259         "x$enable_omx" = xno -a \
1260         "x$enable_va" = xno -a \
1261         "x$enable_opencl" = xno; then
1262     AC_MSG_ERROR([at least one API should be enabled])
1263 fi
1264
1265 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1266 if test "x$enable_opengl" = xno -a \
1267         "x$enable_gles1" = xyes; then
1268     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1269 fi
1270
1271 if test "x$enable_opengl" = xno -a \
1272         "x$enable_gles2" = xyes; then
1273     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1274 fi
1275
1276 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1277 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1278 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1279 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1280                                         "x$enable_gles1" = xyes -o \
1281                                         "x$enable_gles2" = xyes)
1282 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1283                                       "x$enable_gles1" = xyes -o \
1284                                       "x$enable_gles2" = xyes)
1285
1286 # Validate GLX options
1287 if test "x$enable_glx" = xyes; then
1288     if test "x$enable_dri" = xyes; then
1289         enable_glx=dri
1290     elif test -n "$with_gallium_drivers"; then
1291         enable_glx=gallium-xlib
1292     else
1293         enable_glx=xlib
1294     fi
1295 fi
1296 case "x$enable_glx" in
1297 xdri | xxlib | xgallium-xlib)
1298     # GLX requires OpenGL
1299     if test "x$enable_opengl" = xno; then
1300         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1301     fi
1302
1303     # Check individual dependencies
1304     case "x$enable_glx" in
1305     xdri)
1306         if test "x$enable_dri" = xno; then
1307             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1308         fi
1309         ;;
1310     xxlib)
1311         if test "x$enable_dri" = xyes; then
1312             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1313         fi
1314         ;;
1315     xgallium-xlib )
1316         if test "x$enable_dri" = xyes; then
1317             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1318         fi
1319         if test -z "$with_gallium_drivers"; then
1320             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1321         fi
1322         ;;
1323     esac
1324     ;;
1325 xno)
1326     ;;
1327 *)
1328     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1329     ;;
1330 esac
1331
1332 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1333 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1334 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1335 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1336
1337 DEFAULT_GL_LIB_NAME=GL
1338
1339 dnl
1340 dnl Libglvnd configuration
1341 dnl
1342 AC_ARG_ENABLE([libglvnd],
1343     [AS_HELP_STRING([--enable-libglvnd],
1344         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1345     [enable_libglvnd="$enableval"],
1346     [enable_libglvnd=no])
1347 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1348
1349 if test "x$enable_libglvnd" = xyes ; then
1350     dnl XXX: update once we can handle more than libGL/glx.
1351     dnl Namely: we should error out if neither of the glvnd enabled libraries
1352     dnl are built
1353     case "x$enable_glx" in
1354     xno)
1355         AC_MSG_ERROR([cannot build libglvnd without GLX])
1356         ;;
1357     xxlib | xgallium-xlib )
1358         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1359         ;;
1360     xdri)
1361         ;;
1362     esac
1363
1364     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1365     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1366     AC_SUBST([LIBGLVND_DATADIR])
1367
1368     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1369     DEFAULT_GL_LIB_NAME=GLX_mesa
1370 fi
1371
1372 AC_ARG_WITH([gl-lib-name],
1373   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1374     [specify GL library name @<:@default=GL@:>@])],
1375   [GL_LIB=$withval],
1376   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1377 AC_ARG_WITH([osmesa-lib-name],
1378   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1379     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1380   [OSMESA_LIB=$withval],
1381   [OSMESA_LIB=OSMesa])
1382 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1383 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1384
1385 dnl
1386 dnl Mangled Mesa support
1387 dnl
1388 AC_ARG_ENABLE([mangling],
1389   [AS_HELP_STRING([--enable-mangling],
1390     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1391   [enable_mangling="${enableval}"],
1392   [enable_mangling=no]
1393 )
1394 if test "x${enable_mangling}" = "xyes" ; then
1395   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1396   GL_LIB="Mangled${GL_LIB}"
1397   OSMESA_LIB="Mangled${OSMESA_LIB}"
1398 fi
1399 AC_SUBST([GL_LIB])
1400 AC_SUBST([OSMESA_LIB])
1401
1402 # Check for libdrm
1403 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1404                   [have_libdrm=yes], [have_libdrm=no])
1405 if test "x$have_libdrm" = xyes; then
1406     DEFINES="$DEFINES -DHAVE_LIBDRM"
1407 fi
1408
1409 require_libdrm() {
1410     if test "x$have_libdrm" != xyes; then
1411        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1412     fi
1413 }
1414
1415
1416 # Select which platform-dependent DRI code gets built
1417 case "$host_os" in
1418 darwin*)
1419     dri_platform='apple' ;;
1420 cygwin*)
1421     dri_platform='windows' ;;
1422 gnu*)
1423     dri_platform='none' ;;
1424 *)
1425     dri_platform='drm' ;;
1426 esac
1427
1428 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1429     have_drisw_kms='yes'
1430 fi
1431
1432 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1433 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1434 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1435 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1436 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1437 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1438 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1439 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1440 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1441
1442 AC_ARG_ENABLE([shared-glapi],
1443     [AS_HELP_STRING([--enable-shared-glapi],
1444         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1445     [enable_shared_glapi="$enableval"],
1446     [enable_shared_glapi=yes])
1447
1448 case "x$enable_opengl$enable_gles1$enable_gles2" in
1449 x*yes*yes*)
1450     if test "x$enable_shared_glapi" = xno; then
1451         AC_MSG_ERROR([shared GLAPI required when building two or more of
1452                       the following APIs - opengl, gles1 gles2])
1453     fi
1454     ;;
1455 esac
1456
1457 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1458
1459 # Build the pipe-drivers as separate libraries/modules.
1460 # Do not touch this unless you know what you are doing.
1461 # XXX: Expose via configure option ?
1462 enable_shared_pipe_drivers=no
1463
1464 dnl
1465 dnl Driver specific build directories
1466 dnl
1467
1468 if test "x$enable_gallium_osmesa" = xyes; then
1469     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1470         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1471     fi
1472     if test "x$enable_osmesa" = xyes; then
1473         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1474     fi
1475 fi
1476
1477 require_dri_shared_libs_and_glapi() {
1478     if test "x$enable_static" = xyes; then
1479         AC_MSG_ERROR([$1 cannot be build as static library])
1480     fi
1481
1482     if test "x$enable_dri" != xyes; then
1483         # There is only a single backend which won't be build/used otherwise.
1484         # XXX: Revisit this as the egl/haiku is a thing.
1485         AC_MSG_ERROR([$1 requires --enable-dri])
1486     fi
1487
1488     if test "x$enable_shared_glapi" != xyes; then
1489         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1490     fi
1491 }
1492
1493 if test "x$enable_dri" = xyes; then
1494     require_dri_shared_libs_and_glapi "DRI"
1495
1496     # not a hard requirement as swrast does not depend on it
1497     if test "x$have_libdrm" = xyes; then
1498         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1499     fi
1500 fi
1501
1502 AC_ARG_ENABLE([driglx-direct],
1503     [AS_HELP_STRING([--disable-driglx-direct],
1504         [disable direct rendering in GLX and EGL for DRI \
1505             @<:@default=auto@:>@])],
1506     [driglx_direct="$enableval"],
1507     [driglx_direct="yes"])
1508
1509 dnl
1510 dnl libGL configuration per driver
1511 dnl
1512 if test "x$enable_glx" != xno; then
1513     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1514 fi
1515 case "x$enable_glx" in
1516 xxlib | xgallium-xlib)
1517     # Xlib-based GLX
1518     dri_modules="x11 xext xcb"
1519     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1520     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1521     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1522     GL_LIB_DEPS="$XLIBGL_LIBS"
1523     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1524     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1525     ;;
1526 xdri)
1527     # DRI-based GLX
1528
1529     # find the DRI deps for libGL
1530     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1531
1532     if test x"$driglx_direct" = xyes; then
1533         if test x"$dri_platform" = xdrm ; then
1534             DEFINES="$DEFINES -DGLX_USE_DRM"
1535             require_libdrm "Direct rendering"
1536
1537             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1538             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1539
1540             if test x"$enable_dri" = xyes; then
1541                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1542             fi
1543         fi
1544         if test x"$dri_platform" = xapple ; then
1545             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1546         fi
1547         if test x"$dri_platform" = xwindows ; then
1548             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1549         fi
1550     fi
1551
1552     # add xf86vidmode if available
1553     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1554     if test "$HAVE_XF86VIDMODE" = yes ; then
1555         dri_modules="$dri_modules xxf86vm"
1556     fi
1557
1558     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1559     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1560     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1561     GL_LIB_DEPS="$DRIGL_LIBS"
1562
1563     # need DRM libs, $PTHREAD_LIBS, etc.
1564     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1565     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1566     ;;
1567 esac
1568
1569 # This is outside the case (above) so that it is invoked even for non-GLX
1570 # builds.
1571 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1572
1573 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1574 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1575 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1576 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1577
1578 AC_SUBST([X11_INCLUDES])
1579 AC_SUBST([GL_LIB_DEPS])
1580 AC_SUBST([GL_PC_REQ_PRIV])
1581 AC_SUBST([GL_PC_LIB_PRIV])
1582 AC_SUBST([GL_PC_CFLAGS])
1583 AC_SUBST([DRI_PC_REQ_PRIV])
1584 AC_SUBST([GLESv1_CM_LIB_DEPS])
1585 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1586 AC_SUBST([GLESv2_LIB_DEPS])
1587 AC_SUBST([GLESv2_PC_LIB_PRIV])
1588
1589 AC_SUBST([HAVE_XF86VIDMODE])
1590
1591 dnl
1592 dnl More GLX setup
1593 dnl
1594 case "x$enable_glx" in
1595 xxlib | xgallium-xlib)
1596     DEFINES="$DEFINES -DUSE_XSHM"
1597     ;;
1598 xdri)
1599     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1600     if test "x$driglx_direct" = xyes; then
1601         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1602     fi
1603     ;;
1604 esac
1605
1606 dnl
1607 dnl TLS detection
1608 dnl
1609
1610 AC_ARG_ENABLE([glx-tls],
1611     [AS_HELP_STRING([--enable-glx-tls],
1612         [enable TLS support in GLX @<:@default=enabled@:>@])],
1613     [GLX_USE_TLS="$enableval"],
1614     [GLX_USE_TLS=yes])
1615 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1616
1617 if test "x$GLX_USE_TLS" = xyes; then
1618     DEFINES="$DEFINES -DGLX_USE_TLS"
1619 fi
1620
1621 dnl Read-only text section on x86 hardened platforms
1622 AC_ARG_ENABLE([glx-read-only-text],
1623     [AS_HELP_STRING([--enable-glx-read-only-text],
1624         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1625     [enable_glx_read_only_text="$enableval"],
1626     [enable_glx_read_only_text=no])
1627 if test "x$enable_glx_read_only_text" = xyes; then
1628     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1629 fi
1630
1631 dnl
1632 dnl DEPRECATED: EGL Platforms configuration
1633 dnl
1634 AC_ARG_WITH([egl-platforms],
1635     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1636         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1637     [with_egl_platforms="$withval"],
1638     [with_egl_platforms=auto])
1639
1640 if test "x$with_egl_platforms" = xauto; then
1641     with_egl_platforms="x11,surfaceless"
1642     if test "x$enable_gbm" = xyes; then
1643         with_egl_platforms="$with_egl_platforms,drm"
1644     fi
1645 else
1646     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1647 fi
1648
1649 dnl
1650 dnl Platforms configuration
1651 dnl
1652 AC_ARG_WITH([platforms],
1653     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1654         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1655         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1656     [with_platforms="$withval"],
1657     [with_platforms=auto])
1658
1659 # Reuse the autodetection rather than duplicating it.
1660 if test "x$with_platforms" = xauto; then
1661     with_platforms=$with_egl_platforms
1662 fi
1663
1664 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1665         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1666         WAYLAND_SCANNER='')
1667 if test "x$WAYLAND_SCANNER" = x; then
1668     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1669 fi
1670
1671 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1672 if test "x$have_wayland_protocols" = xyes; then
1673     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1674 fi
1675 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1676
1677 # Do per platform setups and checks
1678 platforms=`IFS=', '; echo $with_platforms`
1679 for plat in $platforms; do
1680     case "$plat" in
1681     wayland)
1682
1683         PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1684
1685         if test "x$WAYLAND_SCANNER" = "x:"; then
1686                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1687         fi
1688         if test "x$have_wayland_protocols" = xno; then
1689                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1690         fi
1691         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1692         ;;
1693
1694     x11)
1695         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1696         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1697         ;;
1698
1699     drm)
1700         test "x$enable_gbm" = "xno" &&
1701                 AC_MSG_ERROR([EGL platform drm needs gbm])
1702         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1703         ;;
1704
1705     surfaceless)
1706         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1707         ;;
1708
1709     android)
1710         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1711         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1712         ;;
1713
1714     *)
1715         AC_MSG_ERROR([platform '$plat' does not exist])
1716         ;;
1717     esac
1718
1719     case "$plat" in
1720     wayland|drm|surfaceless)
1721         require_libdrm "Platform $plat"
1722         ;;
1723     esac
1724 done
1725
1726 if test "x$enable_glx" != xno; then
1727     if ! echo "$platforms" | grep -q 'x11'; then
1728         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1729     fi
1730 fi
1731
1732 if test x"$enable_dri3" = xyes; then
1733     DEFINES="$DEFINES -DHAVE_DRI3"
1734
1735     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1736     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1737 fi
1738
1739 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1740 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1741 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1742 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1743 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1744
1745 dnl
1746 dnl More DRI setup
1747 dnl
1748 dnl Directory for DRI drivers
1749 AC_ARG_WITH([dri-driverdir],
1750     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1751         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1752     [DRI_DRIVER_INSTALL_DIR="$withval"],
1753     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1754 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1755 dnl Extra search path for DRI drivers
1756 AC_ARG_WITH([dri-searchpath],
1757     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1758         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1759     [DRI_DRIVER_SEARCH_DIR="$withval"],
1760     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1761 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1762 dnl Which drivers to build - default is chosen by platform
1763 AC_ARG_WITH([dri-drivers],
1764     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1765         [comma delimited classic DRI drivers list, e.g.
1766         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1767     [with_dri_drivers="$withval"],
1768     [with_dri_drivers=auto])
1769
1770 if test "x$with_dri_drivers" = xauto; then
1771     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1772         with_dri_drivers="yes"
1773     else
1774         with_dri_drivers="no"
1775     fi
1776 fi
1777 if test "x$with_dri_drivers" = xno; then
1778     with_dri_drivers=''
1779 fi
1780
1781 # Check for expat
1782 PKG_CHECK_MODULES([EXPAT], [expat],,
1783     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1784 )
1785
1786 dnl If $with_dri_drivers is yes, drivers will be added through
1787 dnl platform checks. Set DEFINES and LIB_DEPS
1788 if test "x$enable_dri" = xyes; then
1789     # Platform specific settings and drivers to build
1790     case "$host_os" in
1791     linux*)
1792         case "$host_cpu" in
1793         powerpc* | sparc*)
1794             # Build only the drivers for cards that exist on PowerPC/sparc
1795             if test "x$with_dri_drivers" = "xyes"; then
1796                 with_dri_drivers="r200 radeon swrast"
1797             fi
1798             ;;
1799         esac
1800         ;;
1801     cygwin*)
1802         if test "x$with_dri_drivers" = "xyes"; then
1803             with_dri_drivers="swrast"
1804         fi
1805         ;;
1806     darwin*)
1807         DEFINES="$DEFINES -DBUILDING_MESA"
1808         if test "x$with_dri_drivers" = "xyes"; then
1809             with_dri_drivers="swrast"
1810         fi
1811         ;;
1812     esac
1813
1814     # default drivers
1815     if test "x$with_dri_drivers" = "xyes"; then
1816         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1817     fi
1818
1819     # put all the necessary libs together
1820     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1821 fi
1822
1823 AC_SUBST([DRI_LIB_DEPS])
1824
1825 DRI_DIRS=''
1826 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1827 if test -n "$with_dri_drivers"; then
1828     if test "x$enable_opengl" != xyes; then
1829         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1830     fi
1831
1832     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1833     for driver in $dri_drivers; do
1834         DRI_DIRS="$DRI_DIRS $driver"
1835         case "x$driver" in
1836         xi915)
1837             require_libdrm "i915"
1838             HAVE_I915_DRI=yes
1839             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1840             ;;
1841         xi965)
1842             require_libdrm "i965"
1843             HAVE_I965_DRI=yes
1844             ;;
1845         xnouveau)
1846             require_libdrm "nouveau"
1847             HAVE_NOUVEAU_DRI=yes
1848             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1849             ;;
1850         xradeon)
1851             require_libdrm "radeon"
1852             HAVE_RADEON_DRI=yes;
1853             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1854             ;;
1855         xr200)
1856             require_libdrm "r200"
1857             HAVE_R200_DRI=yes
1858             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1859             ;;
1860         xswrast)
1861             HAVE_SWRAST_DRI=yes
1862             ;;
1863         *)
1864             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1865             ;;
1866         esac
1867     done
1868     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1869 fi
1870
1871
1872 dnl
1873 dnl Gallium LLVM
1874 dnl Deprecated: kept for backwards compatibility
1875 dnl
1876 AC_ARG_ENABLE([gallium-llvm],
1877     [AS_HELP_STRING([--enable-gallium-llvm],
1878         [DEPRECATED: use --enable-llvm instead])],
1879     [enable_gallium_llvm="$enableval"],
1880     [enable_gallium_llvm=auto])
1881
1882 if test "x$enable_gallium_llvm" != xauto; then
1883    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1884    enable_llvm=$enable_gallium_llvm
1885 fi
1886
1887 dnl
1888 dnl LLVM
1889 dnl
1890 AC_ARG_ENABLE([llvm],
1891     [AS_HELP_STRING([--enable-llvm],
1892         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1893     [enable_llvm="$enableval"],
1894     [enable_llvm=auto])
1895
1896 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1897     if test "x$FOUND_LLVM" = xyes; then
1898         case "$host_cpu" in
1899         i*86|x86_64|amd64) enable_llvm=yes;;
1900         *) enable_llvm=no;;
1901         esac
1902     else
1903         enable_llvm=no
1904     fi
1905 fi
1906
1907 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1908     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1909 fi
1910
1911 #
1912 # Vulkan driver configuration
1913 #
1914
1915 AC_ARG_WITH([vulkan-drivers],
1916     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1917         [comma delimited Vulkan drivers list, e.g.
1918         "intel,radeon"
1919         @<:@default=no@:>@])],
1920     [with_vulkan_drivers="$withval"],
1921     [with_vulkan_drivers="no"])
1922
1923 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1924 # here so that the script doesn't choke on an unknown driver name later.
1925 case "x$with_vulkan_drivers" in
1926     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1927     xno) with_vulkan_drivers='' ;;
1928 esac
1929
1930 AC_ARG_WITH([vulkan-icddir],
1931     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1932         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1933     [VULKAN_ICD_INSTALL_DIR="$withval"],
1934     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1935 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1936
1937 require_x11_dri3() {
1938     if echo "$platforms" | grep -q 'x11'; then
1939         if test "x$enable_dri3" != xyes; then
1940             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1941         fi
1942     fi
1943 }
1944
1945 if test -n "$with_vulkan_drivers"; then
1946     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1947         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1948     fi
1949
1950     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1951     for driver in $VULKAN_DRIVERS; do
1952         case "x$driver" in
1953         xintel)
1954             require_libdrm "ANV"
1955             require_x11_dri3 "ANV"
1956             HAVE_INTEL_VULKAN=yes
1957             ;;
1958         xradeon)
1959             require_libdrm "radv"
1960             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1961             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1962             require_x11_dri3 "radv"
1963             HAVE_RADEON_VULKAN=yes
1964             ;;
1965         *)
1966             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1967             ;;
1968         esac
1969     done
1970     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1971 fi
1972
1973
1974 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1975 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1976 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1977                                   "x$enable_osmesa" = xyes -o \
1978                                   -n "$DRI_DIRS")
1979
1980 dnl
1981 dnl OSMesa configuration
1982 dnl
1983
1984 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1985 AC_ARG_WITH([osmesa-bits],
1986     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1987         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1988     [osmesa_bits="$withval"],
1989     [osmesa_bits=8])
1990 if test "x$osmesa_bits" != x8; then
1991     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1992         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1993         osmesa_bits=8
1994     fi
1995 fi
1996 case "x$osmesa_bits" in
1997 x8)
1998     OSMESA_LIB="${OSMESA_LIB}"
1999     ;;
2000 x16|x32)
2001     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2002     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2003     ;;
2004 *)
2005     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2006     ;;
2007 esac
2008
2009 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2010     # only link libraries with osmesa if shared
2011     if test "$enable_static" = no; then
2012         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2013     else
2014         OSMESA_LIB_DEPS=""
2015     fi
2016     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2017 fi
2018
2019 AC_SUBST([OSMESA_LIB_DEPS])
2020 AC_SUBST([OSMESA_PC_REQ])
2021 AC_SUBST([OSMESA_PC_LIB_PRIV])
2022
2023 dnl
2024 dnl gbm configuration
2025 dnl
2026 if test "x$enable_gbm" = xyes; then
2027     require_dri_shared_libs_and_glapi "gbm"
2028 fi
2029 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2030 # FINISHME: GBM has a number of dependencies which we should add below
2031 GBM_PC_REQ_PRIV=""
2032 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2033 AC_SUBST([GBM_PC_REQ_PRIV])
2034 AC_SUBST([GBM_PC_LIB_PRIV])
2035
2036 dnl
2037 dnl EGL configuration
2038 dnl
2039
2040 if test "x$enable_egl" = xyes; then
2041     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2042
2043     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2044
2045     require_dri_shared_libs_and_glapi "egl"
2046 fi
2047 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2048 AC_SUBST([EGL_LIB_DEPS])
2049
2050 gallium_st="mesa"
2051
2052 dnl
2053 dnl XA configuration
2054 dnl
2055 if test "x$enable_xa" = xyes; then
2056     if test "x$with_gallium_drivers" = xswrast; then
2057        AC_MSG_ERROR([
2058           Building xa requires at least one non swrast gallium driver.
2059           If you are looking to use libxatracker.so with the VMware driver,
2060           make sure to include svga in the gallium drivers list, apart from
2061           enabling XA.
2062           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2063     fi
2064     gallium_st="$gallium_st xa"
2065 fi
2066 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2067
2068 if echo $platforms | grep -q "x11"; then
2069     have_xvmc_platform=yes
2070 else
2071     have_xvmc_platform=no
2072 fi
2073
2074 if echo $platforms | grep -q "x11"; then
2075     have_vdpau_platform=yes
2076 else
2077     have_vdpau_platform=no
2078 fi
2079
2080 if echo $platforms | grep -q "x11\|drm"; then
2081     have_omx_platform=yes
2082 else
2083     have_omx_platform=no
2084 fi
2085
2086 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2087     have_va_platform=yes
2088 else
2089     have_va_platform=no
2090 fi
2091
2092 dnl
2093 dnl Gallium G3DVL configuration
2094 dnl
2095 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2096     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2097         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2098     fi
2099
2100     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2101         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2102     fi
2103
2104     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2105         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2106     fi
2107
2108     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2109         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2110     fi
2111 fi
2112
2113 if test "x$enable_dri" = xyes -o \
2114         "x$enable_xvmc" = xyes -o \
2115         "x$enable_vdpau" = xyes -o \
2116         "x$enable_omx" = xyes -o \
2117         "x$enable_va" = xyes; then
2118     need_gallium_vl=yes
2119 fi
2120 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2121
2122 if test "x$enable_xvmc" = xyes -o \
2123         "x$enable_vdpau" = xyes -o \
2124         "x$enable_omx" = xyes -o \
2125         "x$enable_va" = xyes; then
2126     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2127     need_gallium_vl_winsys=yes
2128 fi
2129 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2130
2131 if test "x$enable_xvmc" = xyes; then
2132     if test "x$have_xvmc_platform" != xyes; then
2133         AC_MSG_ERROR([XVMC requires the x11 platforms])
2134     fi
2135     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2136     gallium_st="$gallium_st xvmc"
2137 fi
2138 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2139
2140 if test "x$enable_vdpau" = xyes; then
2141     if test "x$have_vdpau_platform" != xyes; then
2142         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2143     fi
2144     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2145     gallium_st="$gallium_st vdpau"
2146     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2147 fi
2148 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2149
2150 if test "x$enable_omx" = xyes; then
2151     if test "x$have_omx_platform" != xyes; then
2152         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2153     fi
2154     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2155     gallium_st="$gallium_st omx"
2156 fi
2157 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2158
2159 if test "x$enable_va" = xyes; then
2160     if test "x$have_va_platform" != xyes; then
2161         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2162     fi
2163     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2164     gallium_st="$gallium_st va"
2165 fi
2166 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2167
2168 dnl
2169 dnl Nine Direct3D9 configuration
2170 dnl
2171 if test "x$enable_nine" = xyes; then
2172     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2173         AC_MSG_ERROR([nine requires the gallium swrast driver])
2174     fi
2175     if test "x$with_gallium_drivers" = xswrast; then
2176         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2177     fi
2178     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2179         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2180     fi
2181
2182     if test "x$enable_dri3" = xno; then
2183         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2184     fi
2185
2186     gallium_st="$gallium_st nine"
2187 fi
2188 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2189
2190 dnl
2191 dnl OpenCL configuration
2192 dnl
2193
2194 AC_ARG_WITH([clang-libdir],
2195    [AS_HELP_STRING([--with-clang-libdir],
2196          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2197    [CLANG_LIBDIR="$withval"],
2198    [CLANG_LIBDIR=''])
2199
2200 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2201
2202 if test "x$enable_opencl" = xyes; then
2203     if test -z "$with_gallium_drivers"; then
2204         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2205     fi
2206
2207     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2208         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2209     fi
2210
2211     if test "x$have_libclc" = xno; then
2212         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2213                     Make sure the directory containing libclc.pc is specified in your
2214                     PKG_CONFIG_PATH environment variable.
2215                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2216     else
2217         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2218         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2219         AC_SUBST([LIBCLC_INCLUDEDIR])
2220         AC_SUBST([LIBCLC_LIBEXECDIR])
2221     fi
2222
2223     gallium_st="$gallium_st clover"
2224
2225     if test "x$enable_opencl_icd" = xyes; then
2226         OPENCL_LIBNAME="MesaOpenCL"
2227     else
2228         OPENCL_LIBNAME="OpenCL"
2229     fi
2230
2231     if test "x$have_libelf" != xyes; then
2232        AC_MSG_ERROR([Clover requires libelf])
2233     fi
2234
2235     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2236         altivec_enabled=no
2237         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2238         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2239         #error "AltiVec not enabled"
2240         #endif
2241         ])], altivec_enabled=yes)
2242
2243         if test "$altivec_enabled" = yes; then
2244             CLOVER_STD_OVERRIDE="-std=gnu++11"
2245         fi
2246         AC_SUBST([CLOVER_STD_OVERRIDE])
2247     fi
2248
2249     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2250
2251     llvm_add_default_components "opencl"
2252     llvm_add_component "all-targets" "opencl"
2253     llvm_add_component "linker" "opencl"
2254     llvm_add_component "instrumentation" "opencl"
2255     llvm_add_component "ipo" "opencl"
2256     llvm_add_component "irreader" "opencl"
2257     llvm_add_component "option" "opencl"
2258     llvm_add_component "objcarcopts" "opencl"
2259     llvm_add_component "profiledata" "opencl"
2260
2261     dnl Check for Clang internal headers
2262     if test -z "$CLANG_LIBDIR"; then
2263         CLANG_LIBDIR=${LLVM_LIBDIR}
2264     fi
2265     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2266     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2267         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2268 fi
2269 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2270 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2271 AC_SUBST([OPENCL_LIBNAME])
2272 AC_SUBST([CLANG_RESOURCE_DIR])
2273
2274 dnl
2275 dnl Gallium configuration
2276 dnl
2277 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2278
2279 # libEGL wants to default to the first platform specified in
2280 # ./configure.  parse that here.
2281 if test "x$platforms" != "x"; then
2282     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2283     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2284 else
2285     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2286 fi
2287
2288 AC_SUBST([EGL_NATIVE_PLATFORM])
2289 AC_SUBST([EGL_CFLAGS])
2290
2291 # If we don't have the X11 platform, set this define so we don't try to include
2292 # the X11 headers.
2293 if ! echo "$platforms" | grep -q 'x11'; then
2294     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2295     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2296 fi
2297
2298 dnl Directory for XVMC libs
2299 AC_ARG_WITH([xvmc-libdir],
2300     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2301         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2302     [XVMC_LIB_INSTALL_DIR="$withval"],
2303     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2304 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2305
2306 dnl
2307 dnl Gallium Tests
2308 dnl
2309 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2310
2311 dnl Directory for VDPAU libs
2312 AC_ARG_WITH([vdpau-libdir],
2313     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2314         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2315     [VDPAU_LIB_INSTALL_DIR="$withval"],
2316     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2317 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2318
2319 dnl Directory for OMX libs
2320
2321 AC_ARG_WITH([omx-libdir],
2322     [AS_HELP_STRING([--with-omx-libdir=DIR],
2323         [directory for the OMX libraries])],
2324     [OMX_LIB_INSTALL_DIR="$withval"],
2325     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2326                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2327 AC_SUBST([OMX_LIB_INSTALL_DIR])
2328
2329 dnl Directory for VA libs
2330
2331 AC_ARG_WITH([va-libdir],
2332     [AS_HELP_STRING([--with-va-libdir=DIR],
2333         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2334     [VA_LIB_INSTALL_DIR="$withval"],
2335     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2336 AC_SUBST([VA_LIB_INSTALL_DIR])
2337
2338 AC_ARG_WITH([d3d-libdir],
2339     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2340         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2341     [D3D_DRIVER_INSTALL_DIR="$withval"],
2342     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2343 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2344
2345 dnl Architectures to build SWR library for
2346
2347 AC_ARG_WITH([swr-archs],
2348     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2349         [comma delimited swr architectures list, e.g.
2350         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2351     [with_swr_archs="$withval"],
2352     [with_swr_archs="avx,avx2"])
2353
2354 dnl
2355 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2356 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2357 dnl architectures.
2358 dnl
2359 r300_require_llvm() {
2360     case "$host" in *gnux32) return;; esac
2361     case "$host_cpu" in
2362     i*86|x86_64|amd64) require_llvm $1
2363         ;;
2364     esac
2365 }
2366
2367 dnl
2368 dnl DRM is needed by X, Wayland, and offscreen rendering.
2369 dnl Surfaceless is an alternative for the last one.
2370 dnl
2371 require_basic_egl() {
2372     case "$with_platforms" in
2373         *drm*|*surfaceless*)
2374             ;;
2375         *)
2376             AC_MSG_ERROR([$1 requires one of these:
2377                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2378                   2) --with-platforms=surfaceless (offscreen only)
2379                   Recommended options: drm,x11])
2380             ;;
2381     esac
2382 }
2383
2384 swr_require_cxx_feature_flags() {
2385     feature_name="$1"
2386     preprocessor_test="$2"
2387     option_list="$3"
2388     output_var="$4"
2389
2390     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2391     AC_LANG_PUSH([C++])
2392     save_CXXFLAGS="$CXXFLAGS"
2393     save_IFS="$IFS"
2394     IFS=","
2395     found=0
2396     for opts in $option_list
2397     do
2398         unset IFS
2399         CXXFLAGS="$opts $save_CXXFLAGS"
2400         AC_COMPILE_IFELSE(
2401             [AC_LANG_PROGRAM(
2402                 [   #if !($preprocessor_test)
2403                     #error
2404                     #endif
2405                 ])],
2406             [found=1; break],
2407             [])
2408         IFS=","
2409     done
2410     IFS="$save_IFS"
2411     CXXFLAGS="$save_CXXFLAGS"
2412     AC_LANG_POP([C++])
2413     if test $found -eq 1; then
2414         AC_MSG_RESULT([$opts])
2415         eval "$output_var=\$opts"
2416         return 0
2417     fi
2418     AC_MSG_RESULT([no])
2419     AC_MSG_ERROR([swr requires $feature_name support])
2420     return 1
2421 }
2422
2423 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2424 if test -n "$with_gallium_drivers"; then
2425     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2426     for driver in $gallium_drivers; do
2427         case "x$driver" in
2428         xsvga)
2429             HAVE_GALLIUM_SVGA=yes
2430             require_libdrm "svga"
2431             ;;
2432         xi915)
2433             HAVE_GALLIUM_I915=yes
2434             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2435             require_libdrm "Gallium i915"
2436             ;;
2437         xr300)
2438             HAVE_GALLIUM_R300=yes
2439             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2440             require_libdrm "r300"
2441             r300_require_llvm "r300"
2442             ;;
2443         xr600)
2444             HAVE_GALLIUM_R600=yes
2445             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2446             require_libdrm "r600"
2447             if test "x$enable_llvm" = xyes; then
2448                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2449
2450                 llvm_add_component "asmparser" "r600"
2451                 llvm_add_component "bitreader" "r600"
2452             fi
2453             ;;
2454         xradeonsi)
2455             HAVE_GALLIUM_RADEONSI=yes
2456             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2457             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2458             require_libdrm "radeonsi"
2459             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2460             if test "x$enable_egl" = xyes; then
2461                 require_basic_egl "radeonsi"
2462             fi
2463             ;;
2464         xnouveau)
2465             HAVE_GALLIUM_NOUVEAU=yes
2466             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2467             require_libdrm "nouveau"
2468             ;;
2469         xfreedreno)
2470             HAVE_GALLIUM_FREEDRENO=yes
2471             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2472             require_libdrm "freedreno"
2473             ;;
2474         xetnaviv)
2475             HAVE_GALLIUM_ETNAVIV=yes
2476             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2477             require_libdrm "etnaviv"
2478             ;;
2479        ximx)
2480             HAVE_GALLIUM_IMX=yes
2481             ;;
2482         xswrast)
2483             HAVE_GALLIUM_SOFTPIPE=yes
2484             if test "x$enable_llvm" = xyes; then
2485                 HAVE_GALLIUM_LLVMPIPE=yes
2486             fi
2487             ;;
2488         xswr)
2489             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2490
2491             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2492                 ",-std=c++11" \
2493                 SWR_CXX11_CXXFLAGS
2494             AC_SUBST([SWR_CXX11_CXXFLAGS])
2495
2496             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2497                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2498                 SWR_AVX_CXXFLAGS
2499             AC_SUBST([SWR_AVX_CXXFLAGS])
2500
2501             swr_archs=`IFS=', '; echo $with_swr_archs`
2502             for arch in $swr_archs; do
2503                 case "x$arch" in
2504                 xavx)
2505                     HAVE_SWR_AVX=yes
2506                     ;;
2507                 xavx2)
2508                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2509                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2510                         SWR_AVX2_CXXFLAGS
2511                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2512                     HAVE_SWR_AVX2=yes
2513                     ;;
2514                 xknl)
2515                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2516                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2517                         SWR_KNL_CXXFLAGS
2518                     AC_SUBST([SWR_KNL_CXXFLAGS])
2519                     HAVE_SWR_KNL=yes
2520                     ;;
2521                 xskx)
2522                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2523                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2524                         SWR_SKX_CXXFLAGS
2525                     AC_SUBST([SWR_SKX_CXXFLAGS])
2526                     HAVE_SWR_SKX=yes
2527                     ;;
2528                 *)
2529                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2530                     ;;
2531                 esac
2532             done
2533
2534             if test "x$HAVE_SWR_AVX" != xyes -a \
2535                     "x$HAVE_SWR_AVX2" != xyes -a \
2536                     "x$HAVE_SWR_KNL" != xyes -a \
2537                     "x$HAVE_SWR_SKX" != xyes; then
2538                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2539             fi
2540
2541             HAVE_GALLIUM_SWR=yes
2542             ;;
2543         xvc4)
2544             HAVE_GALLIUM_VC4=yes
2545             require_libdrm "vc4"
2546
2547             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2548                               [USE_VC4_SIMULATOR=yes;
2549                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2550                               [USE_VC4_SIMULATOR=no])
2551             ;;
2552         xpl111)
2553             HAVE_GALLIUM_PL111=yes
2554             ;;
2555         xvirgl)
2556             HAVE_GALLIUM_VIRGL=yes
2557             require_libdrm "virgl"
2558             if test "x$enable_egl" = xyes; then
2559                 require_basic_egl "virgl"
2560             fi
2561             ;;
2562         *)
2563             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2564             ;;
2565         esac
2566     done
2567 fi
2568
2569 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2570 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2571                                               "x$LLVM_VERSION" != x3.9.1)
2572
2573 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2574     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2575     llvm_add_default_components "gallium"
2576 fi
2577
2578 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2579 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2580 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2581 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2582
2583 dnl We need to validate some needed dependencies for renderonly drivers.
2584
2585 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2586     AC_MSG_ERROR([Building with imx requires etnaviv])
2587 fi
2588
2589 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2590     AC_MSG_ERROR([Building with pl111 requires vc4])
2591 fi
2592
2593 dnl
2594 dnl Set defines and buildtime variables only when using LLVM.
2595 dnl
2596 if test "x$enable_llvm" = xyes; then
2597     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2598
2599     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2600     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2601     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2602
2603     dnl Set LLVM_LIBS - This is done after the driver configuration so
2604     dnl that drivers can add additional components to LLVM_COMPONENTS.
2605     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2606     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2607     dnl this was causing the same libraries to be appear multiple times
2608     dnl in LLVM_LIBS.
2609
2610     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2611        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2612     fi
2613     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2614
2615     if test "x$enable_llvm_shared_libs" = xyes; then
2616         if test $LLVM_VERSION_MAJOR -lt 4 -o "`$LLVM_CONFIG --shared-mode ${LLVM_COMPONENTS}`" = static; then
2617             dnl llvm-config may not give the right answer when llvm is a built as a
2618             dnl single shared library, so we must work the library name out for
2619             dnl ourselves.
2620             dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2621             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2622             LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2623             AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2624
2625             if test "x$llvm_have_one_so" = xyes; then
2626                dnl LLVM was built using auto*, so there is only one shared object.
2627                LLVM_LIBS="-l$LLVM_SO_NAME"
2628             else
2629                 dnl If LLVM was built with CMake, there will be one shared object per
2630                 dnl component.
2631                 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2632                       [AC_MSG_ERROR([Could not find llvm shared libraries:
2633                        Please make sure you have built llvm with the --enable-shared option
2634                        and that your llvm libraries are installed in $LLVM_LIBDIR
2635                        If you have installed your llvm libraries to a different directory you
2636                        can use the --with-llvm-prefix= configure flag to specify this directory.
2637                        NOTE: Mesa is attempting to use llvm shared libraries by default.
2638                        If you do not want to build with llvm shared libraries and instead want to
2639                        use llvm static libraries then add --disable-llvm-shared-libs to your configure
2640                        invocation and rebuild.])])
2641
2642                 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2643                 dnl install uses a shared object for each component and we have
2644                 dnl already added all of these objects to LLVM_LIBS.
2645             fi
2646         fi
2647     else
2648         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2649         dnl We need to link to llvm system libs when using static libs
2650         dnl However, only llvm 3.5+ provides --system-libs
2651         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2652             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2653         fi
2654     fi
2655 fi
2656
2657 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2658 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2659 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2660 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2661 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2662 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2663 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2664                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2665 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2666 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2667 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2668 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2669 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2670 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2671 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2672 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2673                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2674                                          "x$HAVE_GALLIUM_SWR" = xyes)
2675 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2676 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2677
2678 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2679
2680 if test "x$enable_dri" = xyes; then
2681     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2682 fi
2683
2684 if test "x$have_drisw_kms" = xyes; then
2685     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2686 fi
2687 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2688
2689 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2690 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2691 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2692 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2693 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2694 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2695
2696 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2697 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2698
2699 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2700                                       "x$HAVE_RADEON_VULKAN" = xyes)
2701
2702 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2703                                         "x$HAVE_I965_DRI" = xyes)
2704
2705 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2706                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2707                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2708 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2709 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2710 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2711 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2712
2713 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2714 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2715 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2716 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2717                                         "x$enable_gallium_osmesa" = xyes)
2718
2719 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2720 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2721 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2722 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2723 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2724 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2725
2726 AC_SUBST([NINE_MAJOR], 1)
2727 AC_SUBST([NINE_MINOR], 0)
2728 AC_SUBST([NINE_TINY], 0)
2729 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2730
2731 AC_SUBST([VDPAU_MAJOR], 1)
2732 AC_SUBST([VDPAU_MINOR], 0)
2733
2734 if test "x$enable_va" = xyes; then
2735     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2736     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2737 fi
2738 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2739 AC_SUBST([VA_MINOR], $VA_MINOR)
2740
2741 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2742
2743 AC_SUBST([XVMC_MAJOR], 1)
2744 AC_SUBST([XVMC_MINOR], 0)
2745
2746 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2747 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2748 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2749 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2750
2751 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2752 AC_SUBST([XA_MINOR], $XA_MINOR)
2753 AC_SUBST([XA_TINY], $XA_TINY)
2754 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2755
2756 AC_ARG_ENABLE(valgrind,
2757               [AS_HELP_STRING([--enable-valgrind],
2758                              [Build mesa with valgrind support (default: auto)])],
2759                              [VALGRIND=$enableval], [VALGRIND=auto])
2760 if test "x$VALGRIND" != xno; then
2761     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2762 fi
2763 AC_MSG_CHECKING([whether to enable Valgrind support])
2764 if test "x$VALGRIND" = xauto; then
2765     VALGRIND="$have_valgrind"
2766 fi
2767
2768 if test "x$VALGRIND" = "xyes"; then
2769     if ! test "x$have_valgrind" = xyes; then
2770         AC_MSG_ERROR([Valgrind support required but not present])
2771     fi
2772     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2773 fi
2774
2775 AC_MSG_RESULT([$VALGRIND])
2776
2777 dnl Restore LDFLAGS and CPPFLAGS
2778 LDFLAGS="$_SAVE_LDFLAGS"
2779 CPPFLAGS="$_SAVE_CPPFLAGS"
2780
2781 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2782 if test "x$acv_mesa_CLANG" = xyes; then
2783     CFLAGS="$CFLAGS -Qunused-arguments"
2784     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2785 fi
2786
2787 dnl Add user CFLAGS and CXXFLAGS
2788 CFLAGS="$CFLAGS $USER_CFLAGS"
2789 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2790
2791 dnl Substitute the config
2792 AC_CONFIG_FILES([Makefile
2793                  src/Makefile
2794                  src/amd/Makefile
2795                  src/amd/vulkan/Makefile
2796                  src/broadcom/Makefile
2797                  src/compiler/Makefile
2798                  src/egl/Makefile
2799                  src/egl/main/egl.pc
2800                  src/egl/wayland/wayland-drm/Makefile
2801                  src/egl/wayland/wayland-egl/Makefile
2802                  src/egl/wayland/wayland-egl/wayland-egl.pc
2803                  src/gallium/Makefile
2804                  src/gallium/auxiliary/Makefile
2805                  src/gallium/auxiliary/pipe-loader/Makefile
2806                  src/gallium/drivers/freedreno/Makefile
2807                  src/gallium/drivers/ddebug/Makefile
2808                  src/gallium/drivers/i915/Makefile
2809                  src/gallium/drivers/llvmpipe/Makefile
2810                  src/gallium/drivers/noop/Makefile
2811                  src/gallium/drivers/nouveau/Makefile
2812                  src/gallium/drivers/pl111/Makefile
2813                  src/gallium/drivers/r300/Makefile
2814                  src/gallium/drivers/r600/Makefile
2815                  src/gallium/drivers/radeon/Makefile
2816                  src/gallium/drivers/radeonsi/Makefile
2817                  src/gallium/drivers/rbug/Makefile
2818                  src/gallium/drivers/softpipe/Makefile
2819                  src/gallium/drivers/svga/Makefile
2820                  src/gallium/drivers/swr/Makefile
2821                  src/gallium/drivers/trace/Makefile
2822                  src/gallium/drivers/etnaviv/Makefile
2823                  src/gallium/drivers/imx/Makefile
2824                  src/gallium/drivers/vc4/Makefile
2825                  src/gallium/drivers/virgl/Makefile
2826                  src/gallium/state_trackers/clover/Makefile
2827                  src/gallium/state_trackers/dri/Makefile
2828                  src/gallium/state_trackers/glx/xlib/Makefile
2829                  src/gallium/state_trackers/nine/Makefile
2830                  src/gallium/state_trackers/omx/Makefile
2831                  src/gallium/state_trackers/osmesa/Makefile
2832                  src/gallium/state_trackers/va/Makefile
2833                  src/gallium/state_trackers/vdpau/Makefile
2834                  src/gallium/state_trackers/xa/Makefile
2835                  src/gallium/state_trackers/xvmc/Makefile
2836                  src/gallium/targets/d3dadapter9/Makefile
2837                  src/gallium/targets/d3dadapter9/d3d.pc
2838                  src/gallium/targets/dri/Makefile
2839                  src/gallium/targets/libgl-xlib/Makefile
2840                  src/gallium/targets/omx/Makefile
2841                  src/gallium/targets/opencl/Makefile
2842                  src/gallium/targets/opencl/mesa.icd
2843                  src/gallium/targets/osmesa/Makefile
2844                  src/gallium/targets/osmesa/osmesa.pc
2845                  src/gallium/targets/pipe-loader/Makefile
2846                  src/gallium/targets/va/Makefile
2847                  src/gallium/targets/vdpau/Makefile
2848                  src/gallium/targets/xa/Makefile
2849                  src/gallium/targets/xa/xatracker.pc
2850                  src/gallium/targets/xvmc/Makefile
2851                  src/gallium/tests/trivial/Makefile
2852                  src/gallium/tests/unit/Makefile
2853                  src/gallium/winsys/etnaviv/drm/Makefile
2854                  src/gallium/winsys/imx/drm/Makefile
2855                  src/gallium/winsys/freedreno/drm/Makefile
2856                  src/gallium/winsys/i915/drm/Makefile
2857                  src/gallium/winsys/nouveau/drm/Makefile
2858                  src/gallium/winsys/pl111/drm/Makefile
2859                  src/gallium/winsys/radeon/drm/Makefile
2860                  src/gallium/winsys/amdgpu/drm/Makefile
2861                  src/gallium/winsys/svga/drm/Makefile
2862                  src/gallium/winsys/sw/dri/Makefile
2863                  src/gallium/winsys/sw/kms-dri/Makefile
2864                  src/gallium/winsys/sw/null/Makefile
2865                  src/gallium/winsys/sw/wrapper/Makefile
2866                  src/gallium/winsys/sw/xlib/Makefile
2867                  src/gallium/winsys/vc4/drm/Makefile
2868                  src/gallium/winsys/virgl/drm/Makefile
2869                  src/gallium/winsys/virgl/vtest/Makefile
2870                  src/gbm/Makefile
2871                  src/gbm/main/gbm.pc
2872                  src/glx/Makefile
2873                  src/glx/apple/Makefile
2874                  src/glx/tests/Makefile
2875                  src/glx/windows/Makefile
2876                  src/glx/windows/windowsdriproto.pc
2877                  src/gtest/Makefile
2878                  src/intel/Makefile
2879                  src/loader/Makefile
2880                  src/mapi/Makefile
2881                  src/mapi/es1api/glesv1_cm.pc
2882                  src/mapi/es2api/glesv2.pc
2883                  src/mapi/glapi/gen/Makefile
2884                  src/mesa/Makefile
2885                  src/mesa/gl.pc
2886                  src/mesa/drivers/dri/dri.pc
2887                  src/mesa/drivers/dri/common/Makefile
2888                  src/mesa/drivers/dri/i915/Makefile
2889                  src/mesa/drivers/dri/i965/Makefile
2890                  src/mesa/drivers/dri/Makefile
2891                  src/mesa/drivers/dri/nouveau/Makefile
2892                  src/mesa/drivers/dri/r200/Makefile
2893                  src/mesa/drivers/dri/radeon/Makefile
2894                  src/mesa/drivers/dri/swrast/Makefile
2895                  src/mesa/drivers/osmesa/Makefile
2896                  src/mesa/drivers/osmesa/osmesa.pc
2897                  src/mesa/drivers/x11/Makefile
2898                  src/mesa/main/tests/Makefile
2899                  src/util/Makefile
2900                  src/util/tests/hash_table/Makefile
2901                  src/util/xmlpool/Makefile
2902                  src/vulkan/Makefile])
2903
2904 AC_OUTPUT
2905
2906 # Fix up dependencies in *.Plo files, where we changed the extension of a
2907 # source file
2908 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2909
2910 rm -f src/compiler/spirv/spirv_info.lo
2911 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
2912
2913 dnl
2914 dnl Output some configuration info for the user
2915 dnl
2916 echo ""
2917 echo "        prefix:          $prefix"
2918 echo "        exec_prefix:     $exec_prefix"
2919 echo "        libdir:          $libdir"
2920 echo "        includedir:      $includedir"
2921
2922 dnl API info
2923 echo ""
2924 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2925
2926 dnl Driver info
2927 echo ""
2928 case "x$enable_osmesa$enable_gallium_osmesa" in
2929 xnoyes)
2930         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2931         ;;
2932 xyesno)
2933         echo "        OSMesa:          lib$OSMESA_LIB"
2934         ;;
2935 xnono)
2936         echo "        OSMesa:          no"
2937         ;;
2938 esac
2939
2940 echo ""
2941 if test "x$enable_dri" != xno; then
2942         echo "        DRI platform:    $dri_platform"
2943         if test -z "$DRI_DIRS"; then
2944             echo "        DRI drivers:     no"
2945         else
2946             echo "        DRI drivers:     $DRI_DIRS"
2947         fi
2948         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2949 fi
2950
2951 case "x$enable_glx" in
2952 xdri)
2953     echo "        GLX:             DRI-based"
2954     ;;
2955 xxlib)
2956     echo "        GLX:             Xlib-based"
2957     ;;
2958 xgallium-xlib)
2959     echo "        GLX:             Xlib-based (Gallium)"
2960     ;;
2961 *)
2962     echo "        GLX:             $enable_glx"
2963     ;;
2964 esac
2965
2966 dnl EGL
2967 echo ""
2968 echo "        EGL:             $enable_egl"
2969 if test "$enable_egl" = yes; then
2970
2971     egl_drivers=""
2972     if test "x$enable_dri" != "xno"; then
2973         egl_drivers="$egl_drivers builtin:egl_dri2"
2974     fi
2975     if test "x$enable_dri3" != "xno"; then
2976         egl_drivers="$egl_drivers builtin:egl_dri3"
2977     fi
2978
2979     echo "        EGL drivers:    $egl_drivers"
2980 fi
2981 if test "x$enable_gbm" = xyes; then
2982     echo "        GBM:             yes"
2983 else
2984     echo "        GBM:             no"
2985 fi
2986
2987     echo "        EGL/Vulkan/VL platforms:   $platforms"
2988
2989 # Vulkan
2990 echo ""
2991 if test "x$VULKAN_DRIVERS" != x; then
2992     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2993     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2994 else
2995     echo "        Vulkan drivers:  no"
2996 fi
2997
2998 echo ""
2999 if test "x$enable_llvm" = xyes; then
3000     echo "        llvm:            yes"
3001     echo "        llvm-config:     $LLVM_CONFIG"
3002     echo "        llvm-version:    $LLVM_VERSION"
3003 else
3004     echo "        llvm:            no"
3005 fi
3006
3007 echo ""
3008 if test -n "$with_gallium_drivers"; then
3009     echo "        Gallium drivers: $gallium_drivers"
3010     echo "        Gallium st:      $gallium_st"
3011 else
3012     echo "        Gallium:         no"
3013 fi
3014
3015 echo ""
3016 if test "x$enable_gallium_extra_hud" != xyes; then
3017     echo "        HUD extra stats: no"
3018 else
3019     echo "        HUD extra stats: yes"
3020 fi
3021
3022 if test "x$enable_lmsensors" != xyes; then
3023     echo "        HUD lmsensors:   no"
3024 else
3025     echo "        HUD lmsensors:   yes"
3026 fi
3027
3028 echo ""
3029 if test "x$HAVE_GALLIUM_SWR" != x; then
3030     echo "        SWR archs:       $swr_archs"
3031 fi
3032
3033 dnl Libraries
3034 echo ""
3035 echo "        Shared libs:     $enable_shared"
3036 echo "        Static libs:     $enable_static"
3037 echo "        Shared-glapi:    $enable_shared_glapi"
3038
3039 dnl Compiler options
3040 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3041 cflags=`echo $CFLAGS | \
3042     $SED 's/^ *//;s/  */ /;s/ *$//'`
3043 cxxflags=`echo $CXXFLAGS | \
3044     $SED 's/^ *//;s/  */ /;s/ *$//'`
3045 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3046 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3047 echo ""
3048 echo "        CFLAGS:          $cflags"
3049 echo "        CXXFLAGS:        $cxxflags"
3050 echo "        LDFLAGS:         $ldflags"
3051 echo "        Macros:          $defines"
3052 echo ""
3053 if test "x$enable_llvm" = xyes; then
3054     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3055     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3056     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3057     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3058     echo ""
3059 fi
3060 echo "        PYTHON2:         $PYTHON2"
3061
3062 echo ""
3063 echo "        Run '${MAKE-make}' to build Mesa"
3064 echo ""