configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  80 DRI2PROTO_REQUIRED=2.6
  81 DRI3PROTO_REQUIRED=1.0
  82 PRESENTPROTO_REQUIRED=1.0
  83 GLPROTO_REQUIRED=1.4.14
  84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  85 LIBVA_REQUIRED=0.38.0
  86 VDPAU_REQUIRED=1.1
  87 WAYLAND_REQUIRED=1.11
  88 XCB_REQUIRED=1.9.3
  89 XCBDRI2_REQUIRED=1.8
  90 XCBGLX_REQUIRED=1.8.1
  91 XSHMFENCE_REQUIRED=1.1
  92 XVMC_REQUIRED=1.0.6
  93 PYTHON_MAKO_REQUIRED=0.8.0
  94 LIBSENSORS_REQUIRED=4.0.0
  95
  96 dnl LLVM versions
  97 LLVM_REQUIRED_GALLIUM=3.3.0
  98 LLVM_REQUIRED_OPENCL=3.6.0
  99 LLVM_REQUIRED_R600=3.6.0
 100 LLVM_REQUIRED_RADEONSI=3.6.0
 101 LLVM_REQUIRED_RADV=3.9.0
 102 LLVM_REQUIRED_SWR=3.6.0
 103
 104 dnl Check for progs
 105 AC_PROG_CPP
 106 AC_PROG_CC
 107 AC_PROG_CXX
 108 AM_PROG_CC_C_O
 109 AM_PROG_AS
 110 AX_CHECK_GNU_MAKE
 111 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 112 AC_PROG_SED
 113 AC_PROG_MKDIR_P
 114
 115 AC_SYS_LARGEFILE
 116
 117 LT_PREREQ([2.2])
 118 LT_INIT([disable-static])
 119
 120 AC_CHECK_PROG(RM, rm, [rm -f])
 121 AC_CHECK_PROG(XXD, xxd, [xxd])
 122
 123 AX_PROG_BISON([],
 124               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 125                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 126 AX_PROG_FLEX([],
 127              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 128                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 129
 130 AC_CHECK_PROG(INDENT, indent, indent, cat)
 131 if test "x$INDENT" != "xcat"; then
 132     # Only GNU indent is supported
 133     INDENT_VERSION=`indent --version | grep GNU`
 134     if test $? -eq 0; then
 135        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 136     else
 137        INDENT="cat"
 138     fi
 139 fi
 140
 141 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 142
 143 if test -z "$PYTHON2"; then
 144     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 145         AC_MSG_ERROR([Python not found - unable to generate sources])
 146     fi
 147 else
 148     if test "x$acv_mako_found" = xno; then
 149         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 150             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 151         fi
 152     fi
 153 fi
 154
 155 AC_PROG_INSTALL
 156
 157 dnl We need a POSIX shell for parts of the build. Assume we have one
 158 dnl in most cases.
 159 case "$host_os" in
 160 solaris*)
 161     # Solaris /bin/sh is too old/non-POSIX compliant
 162     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 163     SHELL="$POSIX_SHELL"
 164     ;;
 165 esac
 166
 167 dnl clang is mostly GCC-compatible, but its version is much lower,
 168 dnl so we have to check for it.
 169 AC_MSG_CHECKING([if compiling with clang])
 170
 171 AC_COMPILE_IFELSE(
 172 [AC_LANG_PROGRAM([], [[
 173 #ifndef __clang__
 174        not clang
 175 #endif
 176 ]])],
 177 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 178
 179 AC_MSG_RESULT([$acv_mesa_CLANG])
 180
 181 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 182 dnl versions are explictly not supported.
 183 GEN_ASM_OFFSETS=no
 184 USE_GNU99=no
 185 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 186     AC_MSG_CHECKING([whether gcc version is sufficient])
 187     major=0
 188     minor=0
 189
 190     GCC_VERSION=`$CC -dumpversion`
 191     if test $? -eq 0; then
 192         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 193         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 194     fi
 195
 196     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 197         AC_MSG_RESULT([no])
 198         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 199     else
 200         AC_MSG_RESULT([yes])
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 204         USE_GNU99=yes
 205     fi
 206     if test "x$cross_compiling" = xyes; then
 207         GEN_ASM_OFFSETS=yes
 208     fi
 209 fi
 210
 211 dnl We don't support building Mesa with Sun C compiler
 212 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 213 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 214 if test "x$SUNCC" = xyes; then
 215     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 216 fi
 217
 218 dnl Check for compiler builtins
 219 AX_GCC_BUILTIN([__builtin_bswap32])
 220 AX_GCC_BUILTIN([__builtin_bswap64])
 221 AX_GCC_BUILTIN([__builtin_clz])
 222 AX_GCC_BUILTIN([__builtin_clzll])
 223 AX_GCC_BUILTIN([__builtin_ctz])
 224 AX_GCC_BUILTIN([__builtin_expect])
 225 AX_GCC_BUILTIN([__builtin_ffs])
 226 AX_GCC_BUILTIN([__builtin_ffsll])
 227 AX_GCC_BUILTIN([__builtin_popcount])
 228 AX_GCC_BUILTIN([__builtin_popcountll])
 229 AX_GCC_BUILTIN([__builtin_unreachable])
 230
 231 AX_GCC_FUNC_ATTRIBUTE([const])
 232 AX_GCC_FUNC_ATTRIBUTE([flatten])
 233 AX_GCC_FUNC_ATTRIBUTE([format])
 234 AX_GCC_FUNC_ATTRIBUTE([malloc])
 235 AX_GCC_FUNC_ATTRIBUTE([packed])
 236 AX_GCC_FUNC_ATTRIBUTE([pure])
 237 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 238 AX_GCC_FUNC_ATTRIBUTE([unused])
 239 AX_GCC_FUNC_ATTRIBUTE([visibility])
 240 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 241 AX_GCC_FUNC_ATTRIBUTE([weak])
 242 AX_GCC_FUNC_ATTRIBUTE([alias])
 243
 244 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 245
 246 dnl Make sure the pkg-config macros are defined
 247 m4_ifndef([PKG_PROG_PKG_CONFIG],
 248     [m4_fatal([Could not locate the pkg-config autoconf macros.
 249   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 250   are in a different location, try setting the environment variable
 251   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 252 PKG_PROG_PKG_CONFIG()
 253
 254 dnl LIB_DIR - library basename
 255 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 256 AC_SUBST([LIB_DIR])
 257
 258 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 259 _SAVE_LDFLAGS="$LDFLAGS"
 260 _SAVE_CPPFLAGS="$CPPFLAGS"
 261
 262 dnl Compiler macros
 263 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 264 AC_SUBST([DEFINES])
 265 android=no
 266 case "$host_os" in
 267 *-android)
 268     android=yes
 269     ;;
 270 linux*|*-gnu*|gnu*|cygwin*)
 271     DEFINES="$DEFINES -D_GNU_SOURCE"
 272     ;;
 273 solaris*)
 274     DEFINES="$DEFINES -DSVR4"
 275     ;;
 276 esac
 277
 278 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 279
 280 dnl Add flags for gcc and g++
 281 if test "x$GCC" = xyes; then
 282     CFLAGS="$CFLAGS -Wall"
 283
 284     if test "x$USE_GNU99" = xyes; then
 285         CFLAGS="$CFLAGS -std=gnu99"
 286     else
 287         CFLAGS="$CFLAGS -std=c99"
 288     fi
 289
 290     # Enable -Werror=implicit-function-declaration and
 291     # -Werror=missing-prototypes, if available, or otherwise, just
 292     # -Wmissing-prototypes.  This is particularly useful to avoid
 293     # generating a loadable driver module that has undefined symbols.
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 296     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 297     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 299                    AC_MSG_RESULT([yes]),
 300                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 301                     AC_MSG_RESULT([no])]);
 302
 303     # Enable -fvisibility=hidden if using a gcc that supports it
 304     save_CFLAGS="$CFLAGS"
 305     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 306     VISIBILITY_CFLAGS="-fvisibility=hidden"
 307     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 308     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 309                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 310
 311     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 312     CFLAGS=$save_CFLAGS
 313
 314     # We don't want floating-point math functions to set errno or trap
 315     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 316
 317     # Flags to help ensure that certain portions of the code -- and only those
 318     # portions -- can be built with MSVC:
 319     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 320     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 321     #   supports most of C99)
 322     # - the rest has no compiler compiler restrictions
 323     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 324     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 325
 326     # Enable -Werror=vla if compiler supports it
 327     save_CFLAGS="$CFLAGS"
 328     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 329     CFLAGS="$CFLAGS -Werror=vla"
 330     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 331                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 332                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 333                     AC_MSG_RESULT([yes])],
 334                     AC_MSG_RESULT([no]));
 335     CFLAGS="$save_CFLAGS"
 336 fi
 337 if test "x$GXX" = xyes; then
 338     CXXFLAGS="$CXXFLAGS -Wall"
 339
 340     # Enable -fvisibility=hidden if using a gcc that supports it
 341     save_CXXFLAGS="$CXXFLAGS"
 342     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 343     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 344     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 345     AC_LANG_PUSH([C++])
 346     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 347                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 348     AC_LANG_POP([C++])
 349
 350     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 351     CXXFLAGS=$save_CXXFLAGS
 352
 353     # We don't want floating-point math functions to set errno or trap
 354     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 355 fi
 356
 357 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 358 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 359
 360 dnl even if the compiler appears to support it, using visibility attributes isn't
 361 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 362 case "$host_os" in
 363 cygwin*)
 364     VISIBILITY_CFLAGS=""
 365     VISIBILITY_CXXFLAGS=""
 366     ;;
 367 esac
 368
 369 AC_SUBST([VISIBILITY_CFLAGS])
 370 AC_SUBST([VISIBILITY_CXXFLAGS])
 371
 372 dnl
 373 dnl Optional flags, check for compiler support
 374 dnl
 375 SSE41_CFLAGS="-msse4.1"
 376 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 377 dnl stack, but on x86-32 such alignment is not guaranteed.
 378 case "$target_cpu" in
 379 i?86)
 380     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 381     ;;
 382 esac
 383 save_CFLAGS="$CFLAGS"
 384 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 385 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 386 #include <smmintrin.h>
 387 int param;
 388 int main () {
 389     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 390     c = _mm_max_epu32(a, b);
 391     return _mm_cvtsi128_si32(c);
 392 }]])], SSE41_SUPPORTED=1)
 393 CFLAGS="$save_CFLAGS"
 394 if test "x$SSE41_SUPPORTED" = x1; then
 395     DEFINES="$DEFINES -DUSE_SSE41"
 396 fi
 397 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 398 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 399
 400 dnl Check for new-style atomic builtins
 401 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 402 int main() {
 403     int n;
 404     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 405 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 406 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 407     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 408 fi
 409 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 410
 411 dnl Check for Endianness
 412 AC_C_BIGENDIAN(
 413    little_endian=no,
 414    little_endian=yes,
 415    little_endian=no,
 416    little_endian=no
 417 )
 418
 419 dnl Check for POWER8 Architecture
 420 PWR8_CFLAGS="-mpower8-vector"
 421 have_pwr8_intrinsics=no
 422 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 423 save_CFLAGS=$CFLAGS
 424 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 425 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 426 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 427 #error "Need GCC >= 4.8 for sane POWER8 support"
 428 #endif
 429 #include <altivec.h>
 430 int main () {
 431     vector unsigned char r;
 432     vector unsigned int v = vec_splat_u32 (1);
 433     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 434     return 0;
 435 }]])], have_pwr8_intrinsics=yes)
 436 CFLAGS=$save_CFLAGS
 437
 438 AC_ARG_ENABLE(pwr8,
 439    [AC_HELP_STRING([--disable-pwr8-inst],
 440                    [disable POWER8-specific instructions])],
 441    [enable_pwr8=$enableval], [enable_pwr8=auto])
 442
 443 if test "x$enable_pwr8" = xno ; then
 444    have_pwr8_intrinsics=disabled
 445 fi
 446
 447 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 448    DEFINES="$DEFINES -D_ARCH_PWR8"
 449    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 450    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 451 else
 452    PWR8_CFLAGS=
 453 fi
 454
 455 AC_MSG_RESULT($have_pwr8_intrinsics)
 456 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 457    AC_MSG_ERROR([POWER8 compiler support not detected])
 458 fi
 459
 460 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 461    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 462 fi
 463
 464 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 465
 466 dnl Can't have static and shared libraries, default to static if user
 467 dnl explicitly requested. If both disabled, set to static since shared
 468 dnl was explicitly requested.
 469 case "x$enable_static$enable_shared" in
 470 xyesyes)
 471     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 472     enable_shared=no
 473     ;;
 474 xnono)
 475     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 476     enable_shared=yes
 477     ;;
 478 esac
 479
 480 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 481
 482 dnl
 483 dnl other compiler options
 484 dnl
 485 AC_ARG_ENABLE([debug],
 486     [AS_HELP_STRING([--enable-debug],
 487         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 488     [enable_debug="$enableval"],
 489     [enable_debug=no]
 490 )
 491
 492 AC_ARG_ENABLE([profile],
 493     [AS_HELP_STRING([--enable-profile],
 494         [enable profiling of code @<:@default=disabled@:>@])],
 495     [enable_profile="$enableval"],
 496     [enable_profile=no]
 497 )
 498
 499 if test "x$enable_profile" = xyes; then
 500     DEFINES="$DEFINES -DPROFILE"
 501     if test "x$GCC" = xyes; then
 502         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 503     fi
 504     if test "x$GXX" = xyes; then
 505         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 506     fi
 507 fi
 508
 509 if test "x$enable_debug" = xyes; then
 510     DEFINES="$DEFINES -DDEBUG"
 511     if test "x$enable_profile" = xyes; then
 512         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 513     fi
 514     if test "x$GCC" = xyes; then
 515         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 516             CFLAGS="$CFLAGS -g"
 517         fi
 518         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 519             CFLAGS="$CFLAGS -O0"
 520         fi
 521     fi
 522     if test "x$GXX" = xyes; then
 523         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 524             CXXFLAGS="$CXXFLAGS -g"
 525         fi
 526         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 527             CXXFLAGS="$CXXFLAGS -O0"
 528         fi
 529     fi
 530 else
 531    DEFINES="$DEFINES -DNDEBUG"
 532 fi
 533
 534 DEFAULT_GL_LIB_NAME=GL
 535
 536 dnl
 537 dnl Check if linker supports -Bsymbolic
 538 dnl
 539 save_LDFLAGS=$LDFLAGS
 540 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 541 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 542 AC_LINK_IFELSE(
 543     [AC_LANG_SOURCE([int main() { return 0;}])],
 544     [AC_MSG_RESULT([yes])
 545         BSYMBOLIC="-Wl,-Bsymbolic";],
 546     [AC_MSG_RESULT([no])
 547         BSYMBOLIC="";])
 548 LDFLAGS=$save_LDFLAGS
 549
 550 AC_SUBST([BSYMBOLIC])
 551
 552 dnl
 553 dnl Check if linker supports garbage collection
 554 dnl
 555 save_LDFLAGS=$LDFLAGS
 556 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 557 AC_MSG_CHECKING([whether ld supports --gc-sections])
 558 AC_LINK_IFELSE(
 559     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 560     [AC_MSG_RESULT([yes])
 561         GC_SECTIONS="-Wl,--gc-sections";],
 562     [AC_MSG_RESULT([no])
 563         GC_SECTIONS="";])
 564 LDFLAGS=$save_LDFLAGS
 565
 566 AC_SUBST([GC_SECTIONS])
 567
 568 dnl
 569 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 570 dnl so when these flags are passed to ld via libtool the checks will fail
 571 dnl
 572 case "$host_os" in
 573 openbsd* | darwin* )
 574     LD_NO_UNDEFINED="" ;;
 575 *)
 576     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 577 esac
 578
 579 AC_SUBST([LD_NO_UNDEFINED])
 580
 581 dnl
 582 dnl Check if linker supports version scripts
 583 dnl
 584 AC_MSG_CHECKING([if the linker supports version-scripts])
 585 save_LDFLAGS=$LDFLAGS
 586 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 587 cat > conftest.map <<EOF
 588 VERSION_1 {
 589      global:
 590          main;
 591
 592      local:
 593          *;
 594 };
 595 EOF
 596 AC_LINK_IFELSE(
 597     [AC_LANG_SOURCE([int main() { return 0;}])],
 598     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 599     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 600 LDFLAGS=$save_LDFLAGS
 601 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 602
 603 dnl
 604 dnl Check if linker supports dynamic list files
 605 dnl
 606 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 607 save_LDFLAGS=$LDFLAGS
 608 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 609 cat > conftest.dyn <<EOF
 610 {
 611         radeon_drm_winsys_create;
 612 };
 613 EOF
 614 AC_LINK_IFELSE(
 615     [AC_LANG_SOURCE([int main() { return 0;}])],
 616     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 617     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 618 LDFLAGS=$save_LDFLAGS
 619 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 620
 621 dnl
 622 dnl compatibility symlinks
 623 dnl
 624 case "$host_os" in
 625 linux* )
 626     HAVE_COMPAT_SYMLINKS=yes ;;
 627 * )
 628     HAVE_COMPAT_SYMLINKS=no ;;
 629 esac
 630
 631 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 632
 633 DEFAULT_GL_LIB_NAME=GL
 634
 635 dnl
 636 dnl Libglvnd configuration
 637 dnl
 638 AC_ARG_ENABLE([libglvnd],
 639     [AS_HELP_STRING([--enable-libglvnd],
 640         [Build for libglvnd @<:@default=disabled@:>@])],
 641     [enable_libglvnd="$enableval"],
 642     [enable_libglvnd=no])
 643 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 644 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 645 if test "x$enable_libglvnd" = xyes ; then
 646     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 647     DEFAULT_GL_LIB_NAME=GLX_mesa
 648 fi
 649
 650 dnl
 651 dnl library names
 652 dnl
 653 dnl Unfortunately we need to do a few things that libtool can't help us with,
 654 dnl so we need some knowledge of shared library filenames:
 655 dnl
 656 dnl LIB_EXT is the extension used when creating symlinks for alternate
 657 dnl filenames for a shared library which will be dynamically loaded
 658 dnl
 659 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 660 dnl the file for a shared library we wish to link with
 661 dnl
 662 case "$host_os" in
 663 darwin* )
 664     LIB_EXT='dylib'
 665     IMP_LIB_EXT=$LIB_EXT
 666     ;;
 667 cygwin* )
 668     LIB_EXT='dll'
 669     IMP_LIB_EXT='dll.a'
 670     ;;
 671 aix* )
 672     LIB_EXT='a'
 673     IMP_LIB_EXT=$LIB_EXT
 674     ;;
 675 * )
 676     LIB_EXT='so'
 677     IMP_LIB_EXT=$LIB_EXT
 678     ;;
 679 esac
 680
 681 AC_SUBST([LIB_EXT])
 682
 683 AC_ARG_WITH([gl-lib-name],
 684   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 685     [specify GL library name @<:@default=GL@:>@])],
 686   [GL_LIB=$withval],
 687   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 688 AC_ARG_WITH([osmesa-lib-name],
 689   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 690     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 691   [OSMESA_LIB=$withval],
 692   [OSMESA_LIB=OSMesa])
 693 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 694 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 695
 696 dnl
 697 dnl Mangled Mesa support
 698 dnl
 699 AC_ARG_ENABLE([mangling],
 700   [AS_HELP_STRING([--enable-mangling],
 701     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 702   [enable_mangling="${enableval}"],
 703   [enable_mangling=no]
 704 )
 705 if test "x${enable_mangling}" = "xyes" ; then
 706   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 707   GL_LIB="Mangled${GL_LIB}"
 708   OSMESA_LIB="Mangled${OSMESA_LIB}"
 709 fi
 710 AC_SUBST([GL_LIB])
 711 AC_SUBST([OSMESA_LIB])
 712
 713 dnl
 714 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 715 dnl
 716 AC_ARG_ENABLE([texture-float],
 717     [AS_HELP_STRING([--enable-texture-float],
 718         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 719     [enable_texture_float="$enableval"],
 720     [enable_texture_float=no]
 721 )
 722 if test "x$enable_texture_float" = xyes; then
 723     AC_MSG_WARN([Floating-point textures enabled.])
 724     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 725     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 726 fi
 727
 728 dnl
 729 dnl Arch/platform-specific settings
 730 dnl
 731 AC_ARG_ENABLE([asm],
 732     [AS_HELP_STRING([--disable-asm],
 733         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 734     [enable_asm="$enableval"],
 735     [enable_asm=yes]
 736 )
 737 asm_arch=""
 738 AC_MSG_CHECKING([whether to enable assembly])
 739 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 740 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 741 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 742     case "$host_cpu" in
 743     i?86 | x86_64 | amd64)
 744         if test "x$host_cpu" != "x$target_cpu"; then
 745             enable_asm=no
 746             AC_MSG_RESULT([no, cross compiling])
 747         fi
 748         ;;
 749     esac
 750 fi
 751 # check for supported arches
 752 if test "x$enable_asm" = xyes; then
 753     case "$host_cpu" in
 754     i?86)
 755         case "$host_os" in
 756         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 757             asm_arch=x86
 758             ;;
 759         esac
 760         ;;
 761     x86_64|amd64)
 762         case "$host_os" in
 763         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 764             asm_arch=x86_64
 765             ;;
 766         esac
 767         ;;
 768     sparc*)
 769         case "$host_os" in
 770         linux*)
 771             asm_arch=sparc
 772             ;;
 773         esac
 774         ;;
 775     esac
 776
 777     case "$asm_arch" in
 778     x86)
 779         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 780         AC_MSG_RESULT([yes, x86])
 781         ;;
 782     x86_64|amd64)
 783         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 784         AC_MSG_RESULT([yes, x86_64])
 785         ;;
 786     sparc)
 787         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 788         AC_MSG_RESULT([yes, sparc])
 789         ;;
 790     *)
 791         AC_MSG_RESULT([no, platform not supported])
 792         ;;
 793     esac
 794 fi
 795
 796 AC_HEADER_MAJOR
 797 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 798 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 799 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 800 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 801
 802 dnl Check to see if dlopen is in default libraries (like Solaris, which
 803 dnl has it in libc), or if libdl is needed to get it.
 804 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 805     [AC_CHECK_LIB([dl], [dlopen],
 806        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 807 AC_SUBST([DLOPEN_LIBS])
 808
 809 dnl Check if that library also has dladdr
 810 save_LIBS="$LIBS"
 811 LIBS="$LIBS $DLOPEN_LIBS"
 812 AC_CHECK_FUNCS([dladdr])
 813 LIBS="$save_LIBS"
 814
 815 case "$host_os" in
 816 darwin*)
 817     ;;
 818 *)
 819     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 820                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 821                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 822     AC_SUBST([CLOCK_LIB])
 823     ;;
 824 esac
 825
 826 dnl See if posix_memalign is available
 827 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 828
 829 dnl Check for pthreads
 830 AX_PTHREAD
 831 if test "x$ax_pthread_ok" = xno; then
 832     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 833 fi
 834 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 835 dnl to -pthread, which causes problems if we need -lpthread to appear in
 836 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 837 dnl is not valid for that platform.
 838 if test "x$android" = xno; then
 839     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 840 fi
 841
 842 dnl pthread-stubs is mandatory on targets where it exists
 843 case "$host_os" in
 844 cygwin* )
 845     pthread_stubs_possible="no"
 846     ;;
 847 * )
 848     pthread_stubs_possible="yes"
 849     ;;
 850 esac
 851
 852 if test "x$pthread_stubs_possible" = xyes; then
 853     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 854     AC_SUBST(PTHREADSTUBS_CFLAGS)
 855     AC_SUBST(PTHREADSTUBS_LIBS)
 856 fi
 857
 858 dnl SELinux awareness.
 859 AC_ARG_ENABLE([selinux],
 860     [AS_HELP_STRING([--enable-selinux],
 861         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 862     [MESA_SELINUX="$enableval"],
 863     [MESA_SELINUX=no])
 864 if test "x$enable_selinux" = "xyes"; then
 865     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 866         [AC_CHECK_HEADER([selinux/selinux.h],[],
 867                          [AC_MSG_ERROR([SELinux headers not found])])
 868          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 869                       [AC_MSG_ERROR([SELinux library not found])])
 870          SELINUX_LIBS="-lselinux"])
 871     DEFINES="$DEFINES -DMESA_SELINUX"
 872 fi
 873 AC_SUBST([SELINUX_CFLAGS])
 874 AC_SUBST([SELINUX_LIBS])
 875
 876 dnl
 877 dnl LLVM
 878 dnl
 879 AC_ARG_ENABLE([llvm-shared-libs],
 880     [AS_HELP_STRING([--enable-llvm-shared-libs],
 881         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 882     [enable_llvm_shared_libs="$enableval"],
 883     [enable_llvm_shared_libs=yes])
 884
 885 AC_ARG_WITH([llvm-prefix],
 886     [AS_HELP_STRING([--with-llvm-prefix],
 887         [Prefix for LLVM installations in non-standard locations])],
 888     [llvm_prefix="$withval"],
 889     [llvm_prefix=''])
 890
 891 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 892 if test "x$have_libelf" = xno; then
 893    LIBELF_LIBS=''
 894    LIBELF_CFLAGS=''
 895    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 896    AC_SUBST([LIBELF_LIBS])
 897    AC_SUBST([LIBELF_CFLAGS])
 898 fi
 899
 900 if test -z "$LLVM_CONFIG"; then
 901     if test -n "$llvm_prefix"; then
 902         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 903     else
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 905     fi
 906 fi
 907
 908 llvm_add_component() {
 909     new_llvm_component=$1
 910     driver_name=$2
 911
 912     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 913         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 914     else
 915         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 916     fi
 917 }
 918
 919 llvm_add_default_components() {
 920     driver_name=$1
 921
 922     # Required default components
 923     llvm_add_component "bitwriter" $driver_name
 924     llvm_add_component "engine" $driver_name
 925     llvm_add_component "mcdisassembler" $driver_name
 926     llvm_add_component "mcjit" $driver_name
 927
 928     # Optional default components
 929     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 930         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 931     fi
 932 }
 933
 934 llvm_add_target() {
 935     new_llvm_target=$1
 936     driver_name=$2
 937
 938     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 939         llvm_add_component $new_llvm_target $driver_name
 940     else
 941         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 942     fi
 943 }
 944
 945 # Call this inside ` ` to get the return value.
 946 # $1 is the llvm-config command with arguments.
 947 strip_unwanted_llvm_flags() {
 948     # Use \> (marks the end of the word)
 949     echo `$1` | sed \
 950         -e 's/-march=\S*//g' \
 951         -e 's/-mtune=\S*//g' \
 952         -e 's/-mcpu=\S*//g' \
 953         -e 's/-DNDEBUG\>//g' \
 954         -e 's/-D_GNU_SOURCE\>//g' \
 955         -e 's/-pedantic\>//g' \
 956         -e 's/-Wcovered-switch-default\>//g' \
 957         -e 's/-O.\>//g' \
 958         -e 's/-g\>//g' \
 959         -e 's/-Wall\>//g' \
 960         -e 's/-Wcast-qual\>//g' \
 961         -e 's/-Woverloaded-virtual\>//g' \
 962         -e 's/-fcolor-diagnostics\>//g' \
 963         -e 's/-fdata-sections\>//g' \
 964         -e 's/-ffunction-sections\>//g' \
 965         -e 's/-fno-exceptions\>//g' \
 966         -e 's/-fomit-frame-pointer\>//g' \
 967         -e 's/-fvisibility-inlines-hidden\>//g' \
 968         -e 's/-fPIC\>//g' \
 969         -e 's/-fstack-protector-strong\>//g'
 970 }
 971
 972 llvm_set_environment_variables() {
 973     if test "x$LLVM_CONFIG" != xno; then
 974         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 975         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 976         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 977         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 978         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 979         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 980         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 981         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 982
 983         # We need to respect LLVM_CFLAGS when compiling LLVM headers.
 984         save_CFLAGS="$CFLAGS"
 985         CFLAGS="$CFLAGS $LLVM_CFLAGS"
 986
 987         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 988             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 989         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 990             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 991         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 992             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 993
 994         CFLAGS="$save_CFLAGS"
 995
 996         # Only needed for LLVM < 3.6.0
 997         if test -z "$LLVM_VERSION_PATCH"; then
 998             LLVM_VERSION_PATCH=0
 999         fi
1000
1001         if test "$LLVM_VERSION_MINOR" -lt 10; then
1002             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1003         else
1004             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}"
1005         fi
1006
1007         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1008         MESA_LLVM=1
1009     else
1010         MESA_LLVM=0
1011         LLVM_VERSION_INT=0
1012     fi
1013 }
1014
1015 llvm_check_version_for() {
1016     if test "x$MESA_LLVM" = x0; then
1017         AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1018         return
1019     fi
1020
1021     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1022     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1023     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1024
1025     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1026         # major > required major
1027         #  --> OK
1028         return
1029     fi
1030
1031     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1032         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1033             # major = required major and
1034             # minor > required minor
1035             #  --> OK
1036             return
1037         else
1038             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1039                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1040                     # major = required major and
1041                     # minor = required minor and
1042                     # patch >= required patch
1043                     #  --> OK
1044                     return
1045                 fi
1046             fi
1047         fi
1048     fi
1049
1050     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1051 }
1052
1053 radeon_llvm_check() {
1054     if test ${LLVM_VERSION_INT} -lt 307; then
1055         amdgpu_llvm_target_name='r600'
1056     else
1057         amdgpu_llvm_target_name='amdgpu'
1058     fi
1059
1060     llvm_check_version_for $*
1061
1062     llvm_add_target $amdgpu_llvm_target_name $2
1063
1064     llvm_add_default_components $2
1065     llvm_add_component "bitreader" $2
1066     llvm_add_component "ipo" $2
1067
1068     NEED_RADEON_LLVM=yes
1069     if test "x$have_libelf" != xyes; then
1070        AC_MSG_ERROR([$1 requires libelf when using llvm])
1071     fi
1072 }
1073
1074 llvm_set_environment_variables
1075
1076 AC_SUBST([MESA_LLVM])
1077 AC_SUBST([LLVM_BINDIR])
1078 AC_SUBST([LLVM_CFLAGS])
1079 AC_SUBST([LLVM_CPPFLAGS])
1080 AC_SUBST([LLVM_CXXFLAGS])
1081 AC_SUBST([LLVM_LIBDIR])
1082 AC_SUBST([LLVM_LIBS])
1083 AC_SUBST([LLVM_LDFLAGS])
1084 AC_SUBST([LLVM_INCLUDEDIR])
1085 AC_SUBST([LLVM_VERSION])
1086
1087 dnl Options for APIs
1088 AC_ARG_ENABLE([opengl],
1089     [AS_HELP_STRING([--disable-opengl],
1090         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1091     [enable_opengl="$enableval"],
1092     [enable_opengl=yes])
1093 AC_ARG_ENABLE([gles1],
1094     [AS_HELP_STRING([--disable-gles1],
1095         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1096     [enable_gles1="$enableval"],
1097     [enable_gles1=yes])
1098 AC_ARG_ENABLE([gles2],
1099     [AS_HELP_STRING([--disable-gles2],
1100         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1101     [enable_gles2="$enableval"],
1102     [enable_gles2=yes])
1103
1104 AC_ARG_ENABLE([dri],
1105     [AS_HELP_STRING([--enable-dri],
1106         [enable DRI modules @<:@default=enabled@:>@])],
1107     [enable_dri="$enableval"],
1108     [enable_dri=yes])
1109
1110 AC_ARG_ENABLE([gallium-extra-hud],
1111     [AS_HELP_STRING([--enable-gallium-extra-hud],
1112         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1113     [enable_gallium_extra_hud="$enableval"],
1114     [enable_gallium_extra_hud=no])
1115 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1116 if test "x$enable_gallium_extra_hud" = xyes ; then
1117     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1118 fi
1119
1120 #TODO: no pkgconfig .pc available for libsensors.
1121 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1122 AC_ARG_ENABLE([lmsensors],
1123     [AS_HELP_STRING([--enable-lmsensors],
1124         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1125     [enable_lmsensors="$enableval"],
1126     [enable_lmsensors=no])
1127 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1128 if test "x$enable_lmsensors" = xyes ; then
1129     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1130     LIBSENSORS_LIBS="-lsensors"
1131 else
1132     LIBSENSORS_LIBS=""
1133 fi
1134 AC_SUBST(LIBSENSORS_LIBS)
1135
1136 case "$host_os" in
1137 linux*)
1138     dri3_default=yes
1139     ;;
1140 *)
1141     dri3_default=no
1142     ;;
1143 esac
1144
1145 if test "x$enable_dri" = xno; then
1146     dri3_default=no
1147 fi
1148
1149 AC_ARG_ENABLE([dri3],
1150     [AS_HELP_STRING([--enable-dri3],
1151         [enable DRI3 @<:@default=auto@:>@])],
1152     [enable_dri3="$enableval"],
1153     [enable_dri3="$dri3_default"])
1154 AC_ARG_ENABLE([glx],
1155     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1156         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1157     [enable_glx="$enableval"],
1158     [enable_glx=yes])
1159 AC_ARG_ENABLE([osmesa],
1160     [AS_HELP_STRING([--enable-osmesa],
1161         [enable OSMesa library @<:@default=disabled@:>@])],
1162     [enable_osmesa="$enableval"],
1163     [enable_osmesa=no])
1164 AC_ARG_ENABLE([gallium-osmesa],
1165     [AS_HELP_STRING([--enable-gallium-osmesa],
1166         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1167     [enable_gallium_osmesa="$enableval"],
1168     [enable_gallium_osmesa=no])
1169 AC_ARG_ENABLE([egl],
1170     [AS_HELP_STRING([--disable-egl],
1171         [disable EGL library @<:@default=enabled@:>@])],
1172     [enable_egl="$enableval"],
1173     [enable_egl=yes])
1174
1175 AC_ARG_ENABLE([xa],
1176     [AS_HELP_STRING([--enable-xa],
1177         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1178     [enable_xa="$enableval"],
1179     [enable_xa=no])
1180 AC_ARG_ENABLE([gbm],
1181    [AS_HELP_STRING([--enable-gbm],
1182          [enable gbm library @<:@default=yes except cygwin@:>@])],
1183    [enable_gbm="$enableval"],
1184    [case "$host_os" in
1185        cygwin*)
1186           enable_gbm=no
1187           ;;
1188        *)
1189           enable_gbm=yes
1190           ;;
1191     esac])
1192 AC_ARG_ENABLE([nine],
1193     [AS_HELP_STRING([--enable-nine],
1194         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1195     [enable_nine="$enableval"],
1196     [enable_nine=no])
1197
1198 AC_ARG_ENABLE([xvmc],
1199    [AS_HELP_STRING([--enable-xvmc],
1200          [enable xvmc library @<:@default=auto@:>@])],
1201    [enable_xvmc="$enableval"],
1202    [enable_xvmc=auto])
1203 AC_ARG_ENABLE([vdpau],
1204    [AS_HELP_STRING([--enable-vdpau],
1205          [enable vdpau library @<:@default=auto@:>@])],
1206    [enable_vdpau="$enableval"],
1207    [enable_vdpau=auto])
1208 AC_ARG_ENABLE([omx],
1209    [AS_HELP_STRING([--enable-omx],
1210          [enable OpenMAX library @<:@default=disabled@:>@])],
1211    [enable_omx="$enableval"],
1212    [enable_omx=no])
1213 AC_ARG_ENABLE([va],
1214    [AS_HELP_STRING([--enable-va],
1215          [enable va library @<:@default=auto@:>@])],
1216    [enable_va="$enableval"],
1217    [enable_va=auto])
1218 AC_ARG_ENABLE([opencl],
1219    [AS_HELP_STRING([--enable-opencl],
1220          [enable OpenCL library @<:@default=disabled@:>@])],
1221    [enable_opencl="$enableval"],
1222    [enable_opencl=no])
1223 AC_ARG_ENABLE([opencl_icd],
1224    [AS_HELP_STRING([--enable-opencl-icd],
1225           [Build an OpenCL ICD library to be loaded by an ICD implementation
1226            @<:@default=disabled@:>@])],
1227     [enable_opencl_icd="$enableval"],
1228     [enable_opencl_icd=no])
1229
1230 AC_ARG_ENABLE([gallium-tests],
1231     [AS_HELP_STRING([--enable-gallium-tests],
1232         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1233     [enable_gallium_tests="$enableval"],
1234     [enable_gallium_tests=no])
1235
1236 # Option for Gallium drivers
1237
1238 # Keep this in sync with the --with-gallium-drivers help string default value
1239 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1240
1241 AC_ARG_WITH([gallium-drivers],
1242     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1243         [comma delimited Gallium drivers list, e.g.
1244         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl,etnaviv,imx"
1245         @<:@default=r300,r600,svga,swrast@:>@])],
1246     [with_gallium_drivers="$withval"],
1247     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1248
1249 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1250 # here so that the script doesn't choke on an unknown driver name later.
1251 case "$with_gallium_drivers" in
1252     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1253     no) with_gallium_drivers='' ;;
1254 esac
1255
1256 if test "x$enable_opengl" = xno -a \
1257         "x$enable_gles1" = xno -a \
1258         "x$enable_gles2" = xno -a \
1259         "x$enable_nine" = xno -a \
1260         "x$enable_xa" = xno -a \
1261         "x$enable_xvmc" = xno -a \
1262         "x$enable_vdpau" = xno -a \
1263         "x$enable_omx" = xno -a \
1264         "x$enable_va" = xno -a \
1265         "x$enable_opencl" = xno; then
1266     AC_MSG_ERROR([at least one API should be enabled])
1267 fi
1268
1269 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1270 if test "x$enable_opengl" = xno -a \
1271         "x$enable_gles1" = xyes; then
1272     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1273 fi
1274
1275 if test "x$enable_opengl" = xno -a \
1276         "x$enable_gles2" = xyes; then
1277     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1278 fi
1279
1280 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1281 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1282 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1283 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1284                                         "x$enable_gles1" = xyes -o \
1285                                         "x$enable_gles2" = xyes)
1286
1287 # Validate GLX options
1288 if test "x$enable_glx" = xyes; then
1289     if test "x$enable_dri" = xyes; then
1290         enable_glx=dri
1291     elif test -n "$with_gallium_drivers"; then
1292         enable_glx=gallium-xlib
1293     else
1294         enable_glx=xlib
1295     fi
1296 fi
1297 case "x$enable_glx" in
1298 xdri | xxlib | xgallium-xlib)
1299     # GLX requires OpenGL
1300     if test "x$enable_opengl" = xno; then
1301         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1302     fi
1303
1304     # Check individual dependencies
1305     case "x$enable_glx" in
1306     xdri)
1307         if test "x$enable_dri" = xno; then
1308             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1309         fi
1310         ;;
1311     xxlib)
1312         if test "x$enable_dri" = xyes; then
1313             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1314         fi
1315         ;;
1316     xgallium-xlib )
1317         if test "x$enable_dri" = xyes; then
1318             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1319         fi
1320         if test -z "$with_gallium_drivers"; then
1321             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1322         fi
1323         ;;
1324     esac
1325     ;;
1326 xno)
1327     ;;
1328 *)
1329     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1330     ;;
1331 esac
1332
1333 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1334 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1335 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1336 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1337
1338 dnl
1339 dnl Libglvnd configuration
1340 dnl
1341 AC_ARG_ENABLE([libglvnd],
1342     [AS_HELP_STRING([--enable-libglvnd],
1343         [Build for libglvnd @<:@default=disabled@:>@])],
1344     [enable_libglvnd="$enableval"],
1345     [enable_libglvnd=no])
1346 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1347 if test "x$enable_libglvnd" = xyes ; then
1348     dnl XXX: update once we can handle more than libGL/glx.
1349     dnl Namely: we should error out if neither of the glvnd enabled libraries
1350     dnl are built
1351     case "x$enable_glx" in
1352     xno)
1353         AC_MSG_ERROR([cannot build libglvnd without GLX])
1354         ;;
1355     xxlib | xgallium-xlib )
1356         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1357         ;;
1358     xdri)
1359         ;;
1360     esac
1361
1362     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1363     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1364     DEFAULT_GL_LIB_NAME=GLX_mesa
1365 fi
1366
1367 # Check for libdrm
1368 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1369                   [have_libdrm=yes], [have_libdrm=no])
1370 if test "x$have_libdrm" = xyes; then
1371         DEFINES="$DEFINES -DHAVE_LIBDRM"
1372 fi
1373
1374 require_libdrm() {
1375     if test "x$have_libdrm" != xyes; then
1376        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1377     fi
1378 }
1379
1380
1381 # Select which platform-dependent DRI code gets built
1382 case "$host_os" in
1383 darwin*)
1384     dri_platform='apple' ;;
1385 cygwin*)
1386     dri_platform='windows' ;;
1387 gnu*)
1388     dri_platform='none' ;;
1389 *)
1390     dri_platform='drm' ;;
1391 esac
1392
1393 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1394     have_drisw_kms='yes'
1395 fi
1396
1397 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1398 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1399 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1400 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1401 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1402 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1403 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1404 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1405 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1406
1407 AC_ARG_ENABLE([shared-glapi],
1408     [AS_HELP_STRING([--enable-shared-glapi],
1409         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1410     [enable_shared_glapi="$enableval"],
1411     [enable_shared_glapi=yes])
1412
1413 case "x$enable_opengl$enable_gles1$enable_gles2" in
1414 x*yes*yes*)
1415     if test "x$enable_shared_glapi" = xno; then
1416         AC_MSG_ERROR([shared GLAPI required when building two or more of
1417                       the following APIs - opengl, gles1 gles2])
1418     fi
1419     ;;
1420 esac
1421
1422 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1423
1424 # Build the pipe-drivers as separate libraries/modules.
1425 # Do not touch this unless you know what you are doing.
1426 # XXX: Expose via configure option ?
1427 enable_shared_pipe_drivers=no
1428
1429 dnl
1430 dnl Driver specific build directories
1431 dnl
1432
1433 if test "x$enable_gallium_osmesa" = xyes; then
1434     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1435         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1436     fi
1437     if test "x$enable_osmesa" = xyes; then
1438         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1439     fi
1440 fi
1441
1442 # SHA1 hashing
1443 AC_ARG_WITH([sha1],
1444         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1445         [choose SHA1 implementation])])
1446 case "x$with_sha1" in
1447 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1448   ;;
1449 *)
1450         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1451 esac
1452
1453 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1454 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1455         with_sha1=libc
1456 fi
1457 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1458         AC_MSG_ERROR([sha1 in libc requested but not found])
1459 fi
1460 if test "x$with_sha1" = xlibc; then
1461         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1462                 [Use libc SHA1 functions])
1463         SHA1_LIBS=""
1464 fi
1465 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1466 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1467         with_sha1=CommonCrypto
1468 fi
1469 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1470         AC_MSG_ERROR([CommonCrypto requested but not found])
1471 fi
1472 if test "x$with_sha1" = xCommonCrypto; then
1473         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1474                 [Use CommonCrypto SHA1 functions])
1475         SHA1_LIBS=""
1476 fi
1477 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1478 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1479 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1480         with_sha1=CryptoAPI
1481 fi
1482 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1483         AC_MSG_ERROR([CryptoAPI requested but not found])
1484 fi
1485 if test "x$with_sha1" = xCryptoAPI; then
1486         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1487                 [Use CryptoAPI SHA1 functions])
1488         SHA1_LIBS=""
1489 fi
1490 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1491 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1492         with_sha1=libmd
1493 fi
1494 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1495         AC_MSG_ERROR([libmd requested but not found])
1496 fi
1497 if test "x$with_sha1" = xlibmd; then
1498         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1499                   [Use libmd SHA1 functions])
1500         SHA1_LIBS=-lmd
1501 fi
1502 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1503 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1504    with_sha1=libsha1
1505 fi
1506 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1507         AC_MSG_ERROR([libsha1 requested but not found])
1508 fi
1509 if test "x$with_sha1" = xlibsha1; then
1510         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1511                   [Use libsha1 for SHA1])
1512         SHA1_LIBS=-lsha1
1513 fi
1514 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1515 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1516         with_sha1=libnettle
1517 fi
1518 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1519         AC_MSG_ERROR([libnettle requested but not found])
1520 fi
1521 if test "x$with_sha1" = xlibnettle; then
1522         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1523                   [Use libnettle SHA1 functions])
1524         SHA1_LIBS=-lnettle
1525 fi
1526 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1527 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1528         with_sha1=libgcrypt
1529 fi
1530 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1531         AC_MSG_ERROR([libgcrypt requested but not found])
1532 fi
1533 if test "x$with_sha1" = xlibgcrypt; then
1534         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1535                   [Use libgcrypt SHA1 functions])
1536         SHA1_LIBS=-lgcrypt
1537 fi
1538 # We don't need all of the OpenSSL libraries, just libcrypto
1539 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1540 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1541                   [HAVE_OPENSSL_PKC=no])
1542 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1543         if test "x$with_sha1" = x; then
1544                 with_sha1=libcrypto
1545         fi
1546 else
1547         if test "x$with_sha1" = xlibcrypto; then
1548                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1549         fi
1550 fi
1551 if test "x$with_sha1" = xlibcrypto; then
1552         if test "x$HAVE_LIBCRYPTO" = xyes; then
1553                 SHA1_LIBS=-lcrypto
1554         else
1555                 SHA1_LIBS="$OPENSSL_LIBS"
1556                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1557         fi
1558 fi
1559 AC_MSG_CHECKING([for SHA1 implementation])
1560 AC_MSG_RESULT([$with_sha1])
1561 AC_SUBST(SHA1_LIBS)
1562 AC_SUBST(SHA1_CFLAGS)
1563
1564 # Enable a define for SHA1
1565 if test "x$with_sha1" != "x"; then
1566         DEFINES="$DEFINES -DHAVE_SHA1"
1567 fi
1568
1569 # Allow user to configure out the shader-cache feature
1570 AC_ARG_ENABLE([shader-cache],
1571     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1572     [enable_shader_cache="$enableval"],
1573     [if test "x$with_sha1" != "x"; then
1574         enable_shader_cache=yes
1575      else
1576         enable_shader_cache=no
1577      fi])
1578 if test "x$with_sha1" = "x"; then
1579     if test "x$enable_shader_cache" = "xyes"; then
1580         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1581     fi
1582 fi
1583 if test "x$enable_shader_cache" = "xyes"; then
1584    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1585 fi
1586
1587 if test "x$enable_dri" = xyes; then
1588     if test "$enable_static" = yes; then
1589         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1590     fi
1591
1592     # not a hard requirement as swrast does not depend on it
1593     if test "x$have_libdrm" = xyes; then
1594         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1595     fi
1596 fi
1597
1598 AC_ARG_ENABLE([driglx-direct],
1599     [AS_HELP_STRING([--disable-driglx-direct],
1600         [disable direct rendering in GLX and EGL for DRI \
1601             @<:@default=auto@:>@])],
1602     [driglx_direct="$enableval"],
1603     [driglx_direct="yes"])
1604
1605 dnl
1606 dnl libGL configuration per driver
1607 dnl
1608 if test "x$enable_glx" != xno; then
1609     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1610 fi
1611 case "x$enable_glx" in
1612 xxlib | xgallium-xlib)
1613     # Xlib-based GLX
1614     dri_modules="x11 xext xcb"
1615     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1616     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1617     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1618     GL_LIB_DEPS="$XLIBGL_LIBS"
1619     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1620     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1621     ;;
1622 xdri)
1623     # DRI-based GLX
1624
1625     # find the DRI deps for libGL
1626     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1627
1628     if test x"$driglx_direct" = xyes; then
1629         if test x"$dri_platform" = xdrm ; then
1630             DEFINES="$DEFINES -DGLX_USE_DRM"
1631             require_libdrm "Direct rendering"
1632
1633             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1634             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1635             if test x"$enable_dri3" = xyes; then
1636                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1637                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1638             fi
1639
1640             if test x"$enable_dri" = xyes; then
1641                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1642             fi
1643
1644             if test x"$enable_dri3" = xyes; then
1645                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1646                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1647                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1648             fi
1649         fi
1650         if test x"$dri_platform" = xapple ; then
1651             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1652         fi
1653         if test x"$dri_platform" = xwindows ; then
1654             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1655         fi
1656     fi
1657
1658     # add xf86vidmode if available
1659     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1660     if test "$HAVE_XF86VIDMODE" = yes ; then
1661         dri_modules="$dri_modules xxf86vm"
1662     fi
1663
1664     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1665     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1666     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1667     GL_LIB_DEPS="$DRIGL_LIBS"
1668
1669     # need DRM libs, $PTHREAD_LIBS, etc.
1670     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1671     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1672     ;;
1673 esac
1674
1675 # This is outside the case (above) so that it is invoked even for non-GLX
1676 # builds.
1677 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1678
1679 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1680 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1681 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1682 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1683
1684 AC_SUBST([X11_INCLUDES])
1685 AC_SUBST([GL_LIB_DEPS])
1686 AC_SUBST([GL_PC_REQ_PRIV])
1687 AC_SUBST([GL_PC_LIB_PRIV])
1688 AC_SUBST([GL_PC_CFLAGS])
1689 AC_SUBST([DRI_PC_REQ_PRIV])
1690 AC_SUBST([GLESv1_CM_LIB_DEPS])
1691 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1692 AC_SUBST([GLESv2_LIB_DEPS])
1693 AC_SUBST([GLESv2_PC_LIB_PRIV])
1694
1695 AC_SUBST([HAVE_XF86VIDMODE])
1696
1697 dnl
1698 dnl More GLX setup
1699 dnl
1700 case "x$enable_glx" in
1701 xxlib | xgallium-xlib)
1702     DEFINES="$DEFINES -DUSE_XSHM"
1703     ;;
1704 xdri)
1705     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1706     if test "x$driglx_direct" = xyes; then
1707         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1708     fi
1709     ;;
1710 esac
1711
1712 dnl
1713 dnl TLS detection
1714 dnl
1715
1716 AC_ARG_ENABLE([glx-tls],
1717     [AS_HELP_STRING([--enable-glx-tls],
1718         [enable TLS support in GLX @<:@default=enabled@:>@])],
1719     [GLX_USE_TLS="$enableval"],
1720     [GLX_USE_TLS=yes])
1721 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1722
1723 if test "x$GLX_USE_TLS" = xyes; then
1724     DEFINES="$DEFINES -DGLX_USE_TLS"
1725 fi
1726
1727 dnl Read-only text section on x86 hardened platforms
1728 AC_ARG_ENABLE([glx-read-only-text],
1729     [AS_HELP_STRING([--enable-glx-read-only-text],
1730         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1731     [enable_glx_read_only_text="$enableval"],
1732     [enable_glx_read_only_text=no])
1733 if test "x$enable_glx_read_only_text" = xyes; then
1734     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1735 fi
1736
1737 dnl
1738 dnl More DRI setup
1739 dnl
1740 dnl Directory for DRI drivers
1741 AC_ARG_WITH([dri-driverdir],
1742     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1743         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1744     [DRI_DRIVER_INSTALL_DIR="$withval"],
1745     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1746 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1747 dnl Extra search path for DRI drivers
1748 AC_ARG_WITH([dri-searchpath],
1749     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1750         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1751     [DRI_DRIVER_SEARCH_DIR="$withval"],
1752     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1753 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1754 dnl Which drivers to build - default is chosen by platform
1755 AC_ARG_WITH([dri-drivers],
1756     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1757         [comma delimited classic DRI drivers list, e.g.
1758         "swrast,i965,radeon" @<:@default=auto@:>@])],
1759     [with_dri_drivers="$withval"],
1760     [with_dri_drivers=auto])
1761
1762 if test "x$with_dri_drivers" = xauto; then
1763     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1764         with_dri_drivers="yes"
1765     else
1766         with_dri_drivers="no"
1767     fi
1768 fi
1769 if test "x$with_dri_drivers" = xno; then
1770     with_dri_drivers=''
1771 fi
1772
1773 dnl If $with_dri_drivers is yes, drivers will be added through
1774 dnl platform checks. Set DEFINES and LIB_DEPS
1775 if test "x$enable_dri" = xyes; then
1776     # Platform specific settings and drivers to build
1777     case "$host_os" in
1778     linux*)
1779         if test "x$enable_dri3" = xyes; then
1780             DEFINES="$DEFINES -DHAVE_DRI3"
1781         fi
1782
1783         case "$host_cpu" in
1784         powerpc* | sparc*)
1785             # Build only the drivers for cards that exist on PowerPC/sparc
1786             if test "x$with_dri_drivers" = "xyes"; then
1787                 with_dri_drivers="r200 radeon swrast"
1788             fi
1789             ;;
1790         esac
1791         ;;
1792     cygwin*)
1793         if test "x$with_dri_drivers" = "xyes"; then
1794             with_dri_drivers="swrast"
1795         fi
1796         ;;
1797     darwin*)
1798         DEFINES="$DEFINES -DBUILDING_MESA"
1799         if test "x$with_dri_drivers" = "xyes"; then
1800             with_dri_drivers="swrast"
1801         fi
1802         ;;
1803     esac
1804
1805     # default drivers
1806     if test "x$with_dri_drivers" = "xyes"; then
1807         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1808     fi
1809
1810     # Check for expat
1811     PKG_CHECK_MODULES([EXPAT], [expat], [],
1812         # expat version 2.0 and earlier do not provide expat.pc
1813         [AC_CHECK_HEADER([expat.h],[],
1814                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1815          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1816                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1817          EXPAT_LIBS="-lexpat"])
1818
1819     # put all the necessary libs together
1820     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1821 fi
1822
1823 AC_SUBST([DRI_LIB_DEPS])
1824
1825 DRI_DIRS=''
1826 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1827 if test -n "$with_dri_drivers"; then
1828     if test "x$enable_opengl" != xyes; then
1829         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1830     fi
1831
1832     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1833     for driver in $dri_drivers; do
1834         DRI_DIRS="$DRI_DIRS $driver"
1835         case "x$driver" in
1836         xi915)
1837             HAVE_I915_DRI=yes;
1838             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1839             ;;
1840         xi965)
1841             HAVE_I965_DRI=yes;
1842             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1843             ;;
1844         xnouveau)
1845             HAVE_NOUVEAU_DRI=yes;
1846             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1847             ;;
1848         xradeon)
1849             HAVE_RADEON_DRI=yes;
1850             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1851             ;;
1852         xr200)
1853             HAVE_R200_DRI=yes;
1854             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1855             ;;
1856         xswrast)
1857             HAVE_SWRAST_DRI=yes;
1858             ;;
1859         *)
1860             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1861             ;;
1862         esac
1863     done
1864     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1865 fi
1866
1867
1868 #
1869 # Vulkan driver configuration
1870 #
1871
1872 AC_ARG_WITH([vulkan-drivers],
1873     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1874         [comma delimited Vulkan drivers list, e.g.
1875         "intel"
1876         @<:@default=no@:>@])],
1877     [with_vulkan_drivers="$withval"],
1878     [with_vulkan_drivers="no"])
1879
1880 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1881 # here so that the script doesn't choke on an unknown driver name later.
1882 case "x$with_vulkan_drivers" in
1883     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1884     xno) with_vulkan_drivers='' ;;
1885 esac
1886
1887 AC_ARG_WITH([vulkan-icddir],
1888     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1889         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1890     [VULKAN_ICD_INSTALL_DIR="$withval"],
1891     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1892 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1893
1894 if test -n "$with_vulkan_drivers"; then
1895     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1896     for driver in $VULKAN_DRIVERS; do
1897         case "x$driver" in
1898         xintel)
1899             if test "x$HAVE_I965_DRI" != xyes; then
1900                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1901             fi
1902             if test "x$with_sha1" == "x"; then
1903                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1904             fi
1905             HAVE_INTEL_VULKAN=yes;
1906
1907             ;;
1908         xradeon)
1909             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1910             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1911             HAVE_RADEON_VULKAN=yes;
1912             if test "x$with_sha1" == "x"; then
1913                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1914             fi
1915             ;;
1916         *)
1917             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1918             ;;
1919         esac
1920     done
1921     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1922 fi
1923
1924
1925 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1926 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1927                                   "x$enable_osmesa" = xyes -o \
1928                                   -n "$DRI_DIRS")
1929
1930 dnl
1931 dnl OSMesa configuration
1932 dnl
1933
1934 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1935 AC_ARG_WITH([osmesa-bits],
1936     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1937         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1938     [osmesa_bits="$withval"],
1939     [osmesa_bits=8])
1940 if test "x$osmesa_bits" != x8; then
1941     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1942         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1943         osmesa_bits=8
1944     fi
1945 fi
1946 case "x$osmesa_bits" in
1947 x8)
1948     OSMESA_LIB="${OSMESA_LIB}"
1949     ;;
1950 x16|x32)
1951     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1952     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1953     ;;
1954 *)
1955     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1956     ;;
1957 esac
1958
1959 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1960     # only link libraries with osmesa if shared
1961     if test "$enable_static" = no; then
1962         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1963     else
1964         OSMESA_LIB_DEPS=""
1965     fi
1966     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1967 fi
1968
1969 AC_SUBST([OSMESA_LIB_DEPS])
1970 AC_SUBST([OSMESA_PC_REQ])
1971 AC_SUBST([OSMESA_PC_LIB_PRIV])
1972
1973 dnl
1974 dnl gbm configuration
1975 dnl
1976 if test "x$enable_gbm" = xyes; then
1977     if test "x$enable_static" = xyes; then
1978         AC_MSG_ERROR([gbm cannot be build as static library])
1979     fi
1980
1981     if test "x$enable_dri" = xyes; then
1982         if test "x$enable_shared_glapi" = xno; then
1983             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1984         fi
1985     else
1986         # Strictly speaking libgbm does not require --enable-dri, although
1987         # both of its backends do. Thus one can build libgbm without any
1988         # backends if --disable-dri is set.
1989         # To avoid unnecessary complexity of checking if at least one backend
1990         # is available when building, just mandate --enable-dri.
1991         AC_MSG_ERROR([gbm requires --enable-dri])
1992     fi
1993 fi
1994 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1995 # FINISHME: GBM has a number of dependencies which we should add below
1996 GBM_PC_REQ_PRIV=""
1997 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1998 AC_SUBST([GBM_PC_REQ_PRIV])
1999 AC_SUBST([GBM_PC_LIB_PRIV])
2000
2001 dnl
2002 dnl EGL configuration
2003 dnl
2004
2005 if test "x$enable_egl" = xyes; then
2006     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2007
2008     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2009
2010     if test "x$enable_static" = xyes; then
2011         AC_MSG_ERROR([egl cannot be build as static library])
2012     fi
2013
2014     if test "x$enable_dri" = xyes; then
2015         if test "x$enable_shared_glapi" = xno; then
2016             AC_MSG_ERROR([egl_dri requires --enable-shared-glapi])
2017         fi
2018     else
2019         # Avoid building an "empty" libEGL. Drop/update this
2020         # when other backends (haiku?) come along.
2021         AC_MSG_ERROR([egl requires --enable-dri])
2022     fi
2023 fi
2024 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2025 AC_SUBST([EGL_LIB_DEPS])
2026
2027 gallium_st="mesa"
2028
2029 dnl
2030 dnl XA configuration
2031 dnl
2032 if test "x$enable_xa" = xyes; then
2033     if test "x$with_gallium_drivers" = xswrast; then
2034        AC_MSG_ERROR([
2035           Building xa requires at least one non swrast gallium driver.
2036           If you are looking to use libxatracker.so with the VMware driver,
2037           make sure to include svga in the gallium drivers list, apart from
2038           enabling XA.
2039           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2040     fi
2041     gallium_st="$gallium_st xa"
2042 fi
2043 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2044
2045 dnl
2046 dnl Gallium G3DVL configuration
2047 dnl
2048 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2049     if test "x$enable_xvmc" = xauto; then
2050         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2051     fi
2052
2053     if test "x$enable_vdpau" = xauto; then
2054         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2055     fi
2056
2057     if test "x$enable_omx" = xauto; then
2058         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2059     fi
2060
2061     if test "x$enable_va" = xauto; then
2062         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2063     fi
2064 fi
2065
2066 if test "x$enable_dri" = xyes -o \
2067         "x$enable_xvmc" = xyes -o \
2068         "x$enable_vdpau" = xyes -o \
2069         "x$enable_omx" = xyes -o \
2070         "x$enable_va" = xyes; then
2071     need_gallium_vl=yes
2072 fi
2073 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2074
2075 if test "x$enable_xvmc" = xyes -o \
2076         "x$enable_vdpau" = xyes -o \
2077         "x$enable_omx" = xyes -o \
2078         "x$enable_va" = xyes; then
2079     if test x"$enable_dri3" = xyes; then
2080         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2081                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2082     else
2083         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2084     fi
2085     need_gallium_vl_winsys=yes
2086 fi
2087 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2088
2089 if test "x$enable_xvmc" = xyes; then
2090     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2091     gallium_st="$gallium_st xvmc"
2092 fi
2093 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2094
2095 if test "x$enable_vdpau" = xyes; then
2096     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2097     gallium_st="$gallium_st vdpau"
2098     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2099 fi
2100 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2101
2102 if test "x$enable_omx" = xyes; then
2103     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2104     gallium_st="$gallium_st omx"
2105 fi
2106 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2107
2108 if test "x$enable_va" = xyes; then
2109     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2110     gallium_st="$gallium_st va"
2111 fi
2112 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2113
2114 dnl
2115 dnl Nine Direct3D9 configuration
2116 dnl
2117 if test "x$enable_nine" = xyes; then
2118     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2119         AC_MSG_ERROR([nine requires the gallium swrast driver])
2120     fi
2121     if test "x$with_gallium_drivers" = xswrast; then
2122         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2123     fi
2124     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2125         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2126     fi
2127
2128     if test "x$enable_dri3" = xno; then
2129         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2130     fi
2131
2132     gallium_st="$gallium_st nine"
2133 fi
2134 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2135
2136 dnl
2137 dnl OpenCL configuration
2138 dnl
2139
2140 AC_ARG_WITH([clang-libdir],
2141    [AS_HELP_STRING([--with-clang-libdir],
2142          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2143    [CLANG_LIBDIR="$withval"],
2144    [CLANG_LIBDIR=''])
2145
2146 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2147
2148 if test "x$enable_opencl" = xyes; then
2149     if test -z "$with_gallium_drivers"; then
2150         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2151     fi
2152
2153     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2154         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2155     fi
2156
2157     if test "x$have_libclc" = xno; then
2158         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2159                     Make sure the directory containing libclc.pc is specified in your
2160                     PKG_CONFIG_PATH environment variable.
2161                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2162     else
2163         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2164         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2165         AC_SUBST([LIBCLC_INCLUDEDIR])
2166         AC_SUBST([LIBCLC_LIBEXECDIR])
2167     fi
2168
2169     gallium_st="$gallium_st clover"
2170
2171     if test "x$enable_opencl_icd" = xyes; then
2172         OPENCL_LIBNAME="MesaOpenCL"
2173     else
2174         OPENCL_LIBNAME="OpenCL"
2175     fi
2176
2177     if test "x$have_libelf" != xyes; then
2178        AC_MSG_ERROR([Clover requires libelf])
2179     fi
2180
2181     llvm_check_version_for $LLVM_REQUIRED_OPENCL "opencl"
2182
2183     llvm_add_default_components "opencl"
2184     llvm_add_component "all-targets" "opencl"
2185     llvm_add_component "linker" "opencl"
2186     llvm_add_component "instrumentation" "opencl"
2187     llvm_add_component "ipo" "opencl"
2188     llvm_add_component "irreader" "opencl"
2189     llvm_add_component "option" "opencl"
2190     llvm_add_component "objcarcopts" "opencl"
2191     llvm_add_component "profiledata" "opencl"
2192
2193     dnl Check for Clang internal headers
2194     if test -z "$CLANG_LIBDIR"; then
2195         CLANG_LIBDIR=${LLVM_LIBDIR}
2196     fi
2197     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2198     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2199         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2200 fi
2201 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2202 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2203 AC_SUBST([OPENCL_LIBNAME])
2204 AC_SUBST([CLANG_RESOURCE_DIR])
2205
2206 dnl
2207 dnl Gallium configuration
2208 dnl
2209 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2210
2211 dnl
2212 dnl EGL Platforms configuration
2213 dnl
2214 AC_ARG_WITH([egl-platforms],
2215     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2216         [comma delimited native platforms libEGL supports, e.g.
2217         "x11,drm" @<:@default=auto@:>@])],
2218     [with_egl_platforms="$withval"],
2219     [if test "x$enable_egl" = xyes; then
2220         if test "x$enable_gbm" = xyes; then
2221            with_egl_platforms="x11,drm"
2222         else
2223            with_egl_platforms="x11"
2224         fi
2225     else
2226         with_egl_platforms=""
2227     fi])
2228
2229 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2230     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2231 fi
2232
2233 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2234         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2235         WAYLAND_SCANNER='')
2236 if test "x$WAYLAND_SCANNER" = x; then
2237     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2238 fi
2239
2240 # Do per-EGL platform setups and checks
2241 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2242 for plat in $egl_platforms; do
2243         case "$plat" in
2244         wayland)
2245
2246                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2247
2248                 if test "x$WAYLAND_SCANNER" = x; then
2249                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2250                 fi
2251                 ;;
2252
2253         x11)
2254                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2255                 ;;
2256
2257         drm)
2258                 test "x$enable_gbm" = "xno" &&
2259                         AC_MSG_ERROR([EGL platform drm needs gbm])
2260                 ;;
2261
2262         surfaceless)
2263                 ;;
2264
2265         android)
2266                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2267                 ;;
2268
2269         *)
2270                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2271                 ;;
2272         esac
2273
2274         case "$plat" in
2275         wayland|drm|surfaceless)
2276                 require_libdrm "Platform $plat"
2277                 ;;
2278         esac
2279 done
2280
2281 # libEGL wants to default to the first platform specified in
2282 # ./configure.  parse that here.
2283 if test "x$egl_platforms" != "x"; then
2284     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2285     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2286 else
2287     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2288 fi
2289
2290 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2291 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2292 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2293 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2294 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2295
2296 AC_SUBST([EGL_NATIVE_PLATFORM])
2297 AC_SUBST([EGL_CFLAGS])
2298
2299 # If we don't have the X11 platform, set this define so we don't try to include
2300 # the X11 headers.
2301 if ! echo "$egl_platforms" | grep -q 'x11'; then
2302     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2303     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2304 fi
2305
2306 dnl
2307 dnl Gallium LLVM
2308 dnl
2309 AC_ARG_ENABLE([gallium-llvm],
2310     [AS_HELP_STRING([--enable-gallium-llvm],
2311         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2312     [enable_gallium_llvm="$enableval"],
2313     [enable_gallium_llvm=auto])
2314
2315 if test -z "$with_gallium_drivers"; then
2316     enable_gallium_llvm=no
2317 fi
2318 if test "x$enable_gallium_llvm" = xauto; then
2319     case "$host_cpu" in
2320     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2321     esac
2322 fi
2323
2324 dnl Directory for XVMC libs
2325 AC_ARG_WITH([xvmc-libdir],
2326     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2327         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2328     [XVMC_LIB_INSTALL_DIR="$withval"],
2329     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2330 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2331
2332 dnl
2333 dnl Gallium Tests
2334 dnl
2335 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2336
2337 dnl Directory for VDPAU libs
2338 AC_ARG_WITH([vdpau-libdir],
2339     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2340         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2341     [VDPAU_LIB_INSTALL_DIR="$withval"],
2342     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2343 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2344
2345 dnl Directory for OMX libs
2346
2347 AC_ARG_WITH([omx-libdir],
2348     [AS_HELP_STRING([--with-omx-libdir=DIR],
2349         [directory for the OMX libraries])],
2350     [OMX_LIB_INSTALL_DIR="$withval"],
2351     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2352 AC_SUBST([OMX_LIB_INSTALL_DIR])
2353
2354 dnl Directory for VA libs
2355
2356 AC_ARG_WITH([va-libdir],
2357     [AS_HELP_STRING([--with-va-libdir=DIR],
2358         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2359     [VA_LIB_INSTALL_DIR="$withval"],
2360     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2361 AC_SUBST([VA_LIB_INSTALL_DIR])
2362
2363 AC_ARG_WITH([d3d-libdir],
2364     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2365         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2366     [D3D_DRIVER_INSTALL_DIR="$withval"],
2367     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2368 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2369
2370 dnl
2371 dnl Gallium helper functions
2372 dnl
2373 gallium_require_llvm() {
2374     if test "x$enable_gallium_llvm" = "xyes"; then
2375         llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2376     else
2377         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2378     fi
2379 }
2380
2381 dnl
2382 dnl DRM is needed by X, Wayland, and offscreen rendering.
2383 dnl Surfaceless is an alternative for the last one.
2384 dnl
2385 require_basic_egl() {
2386     case "$with_egl_platforms" in
2387         *drm*|*surfaceless*)
2388             ;;
2389         *)
2390             AC_MSG_ERROR([$1 requires one of these:
2391                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2392                   2) --with-egl-platforms=surfaceless (offscreen only)
2393                   Recommended options: drm,x11])
2394             ;;
2395     esac
2396 }
2397
2398 radeon_gallium_llvm_check() {
2399     if test "x$enable_gallium_llvm" != "xyes"; then
2400         AC_MSG_ERROR([--enable-gallium-llvm is required when building $2])
2401     fi
2402     radeon_llvm_check $*
2403 }
2404
2405 swr_require_cxx_feature_flags() {
2406     feature_name="$1"
2407     preprocessor_test="$2"
2408     option_list="$3"
2409     output_var="$4"
2410
2411     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2412     AC_LANG_PUSH([C++])
2413     save_CXXFLAGS="$CXXFLAGS"
2414     save_IFS="$IFS"
2415     IFS=","
2416     found=0
2417     for opts in $option_list
2418     do
2419         unset IFS
2420         CXXFLAGS="$opts $save_CXXFLAGS"
2421         AC_COMPILE_IFELSE(
2422             [AC_LANG_PROGRAM(
2423                 [   #if !($preprocessor_test)
2424                     #error
2425                     #endif
2426                 ])],
2427             [found=1; break],
2428             [])
2429         IFS=","
2430     done
2431     IFS="$save_IFS"
2432     CXXFLAGS="$save_CXXFLAGS"
2433     AC_LANG_POP([C++])
2434     if test $found -eq 1; then
2435         AC_MSG_RESULT([$opts])
2436         eval "$output_var=\$opts"
2437         return 0
2438     fi
2439     AC_MSG_RESULT([no])
2440     AC_MSG_ERROR([swr requires $feature_name support])
2441     return 1
2442 }
2443
2444 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2445 if test -n "$with_gallium_drivers"; then
2446     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2447     for driver in $gallium_drivers; do
2448         case "x$driver" in
2449         xsvga)
2450             HAVE_GALLIUM_SVGA=yes
2451             require_libdrm "svga"
2452             ;;
2453         xi915)
2454             HAVE_GALLIUM_I915=yes
2455             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2456             require_libdrm "Gallium i915"
2457             ;;
2458         xilo)
2459             HAVE_GALLIUM_ILO=yes
2460             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2461             require_libdrm "Gallium i965/ilo"
2462             ;;
2463         xr300)
2464             HAVE_GALLIUM_R300=yes
2465             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2466             require_libdrm "r300"
2467             gallium_require_llvm "r300"
2468             ;;
2469         xr600)
2470             HAVE_GALLIUM_R600=yes
2471             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2472             require_libdrm "r600"
2473             if test "x$enable_opencl" = xyes; then
2474                 radeon_gallium_llvm_check $LLVM_REQUIRED_R600 "r600"
2475
2476                 llvm_add_component "asmparser" "r600"
2477                 llvm_add_component "bitreader" "r600"
2478             fi
2479             ;;
2480         xradeonsi)
2481             HAVE_GALLIUM_RADEONSI=yes
2482             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2483             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2484             require_libdrm "radeonsi"
2485             radeon_gallium_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2486             require_basic_egl "radeonsi"
2487             ;;
2488         xnouveau)
2489             HAVE_GALLIUM_NOUVEAU=yes
2490             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2491             require_libdrm "nouveau"
2492             ;;
2493         xfreedreno)
2494             HAVE_GALLIUM_FREEDRENO=yes
2495             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2496             require_libdrm "freedreno"
2497             ;;
2498         xetnaviv)
2499             HAVE_GALLIUM_ETNAVIV=yes
2500             PKG_CHECK_MODULES([ETNAVIV], [libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2501             require_libdrm "etnaviv"
2502             ;;
2503        ximx)
2504             HAVE_GALLIUM_IMX=yes
2505             ;;
2506         xswrast)
2507             HAVE_GALLIUM_SOFTPIPE=yes
2508             if test "x$MESA_LLVM" = x1 && test "x$enable_gallium_llvm" == "xyes";  then
2509                 HAVE_GALLIUM_LLVMPIPE=yes
2510             fi
2511             ;;
2512         xswr)
2513             llvm_check_version_for $LLVM_REQUIRED_SWR "swr"
2514             gallium_require_llvm "swr"
2515
2516             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2517                 ",-std=c++11" \
2518                 SWR_CXX11_CXXFLAGS
2519             AC_SUBST([SWR_CXX11_CXXFLAGS])
2520
2521             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2522                 ",-mavx,-march=core-avx" \
2523                 SWR_AVX_CXXFLAGS
2524             AC_SUBST([SWR_AVX_CXXFLAGS])
2525
2526             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2527                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2528                 SWR_AVX2_CXXFLAGS
2529             AC_SUBST([SWR_AVX2_CXXFLAGS])
2530
2531             HAVE_GALLIUM_SWR=yes
2532             ;;
2533         xvc4)
2534             HAVE_GALLIUM_VC4=yes
2535             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2536             require_libdrm "vc4"
2537
2538             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2539                               [USE_VC4_SIMULATOR=yes;
2540                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2541                               [USE_VC4_SIMULATOR=no])
2542             ;;
2543         xvirgl)
2544             HAVE_GALLIUM_VIRGL=yes
2545             require_libdrm "virgl"
2546             require_basic_egl "virgl"
2547             ;;
2548         *)
2549             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2550             ;;
2551         esac
2552     done
2553 fi
2554
2555 if test "x$enable_gallium_llvm" == "xyes"; then
2556     llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2557     llvm_add_default_components "gallium"
2558 fi
2559
2560 dnl We need to validate some needed dependencies for renderonly drivers.
2561
2562 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" == xyes  ; then
2563     AC_ERROR([Building with imx requires etnaviv])
2564 fi
2565
2566 dnl Set LLVM_LIBS - This is done after the driver configuration so
2567 dnl that drivers can add additional components to LLVM_COMPONENTS.
2568 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2569 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2570 dnl this was causing the same libraries to be appear multiple times
2571 dnl in LLVM_LIBS.
2572
2573 if test "x$MESA_LLVM" != x0; then
2574
2575     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2576        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2577     fi
2578     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2579
2580     dnl llvm-config may not give the right answer when llvm is a built as a
2581     dnl single shared library, so we must work the library name out for
2582     dnl ourselves.
2583     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2584     if test "x$enable_llvm_shared_libs" = xyes; then
2585         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2586         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2587         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2588
2589         if test "x$llvm_have_one_so" = xyes; then
2590             dnl LLVM was built using auto*, so there is only one shared object.
2591             LLVM_LIBS="-l$LLVM_SO_NAME"
2592         else
2593             dnl If LLVM was built with CMake, there will be one shared object per
2594             dnl component.
2595             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2596                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2597         Please make sure you have built llvm with the --enable-shared option
2598         and that your llvm libraries are installed in $LLVM_LIBDIR
2599         If you have installed your llvm libraries to a different directory you
2600         can use the --with-llvm-prefix= configure flag to specify this directory.
2601         NOTE: Mesa is attempting to use llvm shared libraries by default.
2602         If you do not want to build with llvm shared libraries and instead want to
2603         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2604         invocation and rebuild.])])
2605
2606            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2607            dnl install uses a shared object for each component and we have
2608            dnl already added all of these objects to LLVM_LIBS.
2609         fi
2610     else
2611         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2612         dnl We need to link to llvm system libs when using static libs
2613         dnl However, only llvm 3.5+ provides --system-libs
2614         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2615             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2616         fi
2617     fi
2618 fi
2619
2620 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2621 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2622 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2624 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2625 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2626 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2627                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2628 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2629 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2630 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2631 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2632 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2633 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2634 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2635 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2636                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2637                                          "x$HAVE_GALLIUM_SWR" = xyes)
2638 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2639 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2640
2641 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2642
2643 if test "x$enable_dri" = xyes; then
2644     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2645 fi
2646
2647 if test "x$have_drisw_kms" = xyes; then
2648     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2649 fi
2650 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2651
2652 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2653 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2654 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2655 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2656 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2657 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2658
2659 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2660 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2661
2662 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2663                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2664                                       "x$HAVE_RADEON_VULKAN" = xyes)
2665
2666 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2667                                         "x$HAVE_I965_DRI" = xyes)
2668
2669 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2670                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2671                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2672 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2673 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2674 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2675 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$MESA_LLVM" = x1 -a \
2676                                        "x$enable_gallium_llvm" = xyes)
2677 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2678 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2679     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2680 fi
2681
2682 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2683 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2684 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2685 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2686                                         "x$enable_gallium_osmesa" = xyes)
2687
2688 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2689 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2690 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2691
2692 AC_SUBST([NINE_MAJOR], 1)
2693 AC_SUBST([NINE_MINOR], 0)
2694 AC_SUBST([NINE_TINY], 0)
2695 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2696
2697 AC_SUBST([VDPAU_MAJOR], 1)
2698 AC_SUBST([VDPAU_MINOR], 0)
2699
2700 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2701 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2702 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2703 AC_SUBST([VA_MINOR], $VA_MINOR)
2704
2705 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2706
2707 AC_SUBST([XVMC_MAJOR], 1)
2708 AC_SUBST([XVMC_MINOR], 0)
2709
2710 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2711 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2712 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2713 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2714
2715 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2716 AC_SUBST([XA_MINOR], $XA_MINOR)
2717 AC_SUBST([XA_TINY], $XA_TINY)
2718 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2719
2720 AC_ARG_ENABLE(valgrind,
2721               [AS_HELP_STRING([--enable-valgrind],
2722                              [Build mesa with valgrind support (default: auto)])],
2723                              [VALGRIND=$enableval], [VALGRIND=auto])
2724 if test "x$VALGRIND" != xno; then
2725         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2726 fi
2727 AC_MSG_CHECKING([whether to enable Valgrind support])
2728 if test "x$VALGRIND" = xauto; then
2729         VALGRIND="$have_valgrind"
2730 fi
2731
2732 if test "x$VALGRIND" = "xyes"; then
2733         if ! test "x$have_valgrind" = xyes; then
2734                 AC_MSG_ERROR([Valgrind support required but not present])
2735         fi
2736         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2737 fi
2738
2739 AC_MSG_RESULT([$VALGRIND])
2740
2741 dnl Restore LDFLAGS and CPPFLAGS
2742 LDFLAGS="$_SAVE_LDFLAGS"
2743 CPPFLAGS="$_SAVE_CPPFLAGS"
2744
2745 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2746 if test "x$acv_mesa_CLANG" = xyes; then
2747     CFLAGS="$CFLAGS -Qunused-arguments"
2748     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2749 fi
2750
2751 dnl Add user CFLAGS and CXXFLAGS
2752 CFLAGS="$CFLAGS $USER_CFLAGS"
2753 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2754
2755 dnl Substitute the config
2756 AC_CONFIG_FILES([Makefile
2757                 src/Makefile
2758                 src/amd/Makefile
2759                 src/amd/vulkan/Makefile
2760                 src/compiler/Makefile
2761                 src/egl/Makefile
2762                 src/egl/main/egl.pc
2763                 src/egl/wayland/wayland-drm/Makefile
2764                 src/egl/wayland/wayland-egl/Makefile
2765                 src/egl/wayland/wayland-egl/wayland-egl.pc
2766                 src/gallium/Makefile
2767                 src/gallium/auxiliary/Makefile
2768                 src/gallium/auxiliary/pipe-loader/Makefile
2769                 src/gallium/drivers/freedreno/Makefile
2770                 src/gallium/drivers/ddebug/Makefile
2771                 src/gallium/drivers/i915/Makefile
2772                 src/gallium/drivers/ilo/Makefile
2773                 src/gallium/drivers/llvmpipe/Makefile
2774                 src/gallium/drivers/noop/Makefile
2775                 src/gallium/drivers/nouveau/Makefile
2776                 src/gallium/drivers/r300/Makefile
2777                 src/gallium/drivers/r600/Makefile
2778                 src/gallium/drivers/radeon/Makefile
2779                 src/gallium/drivers/radeonsi/Makefile
2780                 src/gallium/drivers/rbug/Makefile
2781                 src/gallium/drivers/softpipe/Makefile
2782                 src/gallium/drivers/svga/Makefile
2783                 src/gallium/drivers/swr/Makefile
2784                 src/gallium/drivers/trace/Makefile
2785                 src/gallium/drivers/etnaviv/Makefile
2786                 src/gallium/drivers/imx/Makefile
2787                 src/gallium/drivers/vc4/Makefile
2788                 src/gallium/drivers/virgl/Makefile
2789                 src/gallium/state_trackers/clover/Makefile
2790                 src/gallium/state_trackers/dri/Makefile
2791                 src/gallium/state_trackers/glx/xlib/Makefile
2792                 src/gallium/state_trackers/nine/Makefile
2793                 src/gallium/state_trackers/omx/Makefile
2794                 src/gallium/state_trackers/osmesa/Makefile
2795                 src/gallium/state_trackers/va/Makefile
2796                 src/gallium/state_trackers/vdpau/Makefile
2797                 src/gallium/state_trackers/xa/Makefile
2798                 src/gallium/state_trackers/xvmc/Makefile
2799                 src/gallium/targets/d3dadapter9/Makefile
2800                 src/gallium/targets/d3dadapter9/d3d.pc
2801                 src/gallium/targets/dri/Makefile
2802                 src/gallium/targets/libgl-xlib/Makefile
2803                 src/gallium/targets/omx/Makefile
2804                 src/gallium/targets/opencl/Makefile
2805                 src/gallium/targets/opencl/mesa.icd
2806                 src/gallium/targets/osmesa/Makefile
2807                 src/gallium/targets/osmesa/osmesa.pc
2808                 src/gallium/targets/pipe-loader/Makefile
2809                 src/gallium/targets/va/Makefile
2810                 src/gallium/targets/vdpau/Makefile
2811                 src/gallium/targets/xa/Makefile
2812                 src/gallium/targets/xa/xatracker.pc
2813                 src/gallium/targets/xvmc/Makefile
2814                 src/gallium/tests/trivial/Makefile
2815                 src/gallium/tests/unit/Makefile
2816                 src/gallium/winsys/etnaviv/drm/Makefile
2817                 src/gallium/winsys/imx/drm/Makefile
2818                 src/gallium/winsys/freedreno/drm/Makefile
2819                 src/gallium/winsys/i915/drm/Makefile
2820                 src/gallium/winsys/intel/drm/Makefile
2821                 src/gallium/winsys/nouveau/drm/Makefile
2822                 src/gallium/winsys/radeon/drm/Makefile
2823                 src/gallium/winsys/amdgpu/drm/Makefile
2824                 src/gallium/winsys/svga/drm/Makefile
2825                 src/gallium/winsys/sw/dri/Makefile
2826                 src/gallium/winsys/sw/kms-dri/Makefile
2827                 src/gallium/winsys/sw/null/Makefile
2828                 src/gallium/winsys/sw/wrapper/Makefile
2829                 src/gallium/winsys/sw/xlib/Makefile
2830                 src/gallium/winsys/vc4/drm/Makefile
2831                 src/gallium/winsys/virgl/drm/Makefile
2832                 src/gallium/winsys/virgl/vtest/Makefile
2833                 src/gbm/Makefile
2834                 src/gbm/main/gbm.pc
2835                 src/glx/Makefile
2836                 src/glx/apple/Makefile
2837                 src/glx/tests/Makefile
2838                 src/glx/windows/Makefile
2839                 src/glx/windows/windowsdriproto.pc
2840                 src/gtest/Makefile
2841                 src/intel/Makefile
2842                 src/intel/tools/Makefile
2843                 src/intel/vulkan/Makefile
2844                 src/loader/Makefile
2845                 src/mapi/Makefile
2846                 src/mapi/es1api/glesv1_cm.pc
2847                 src/mapi/es2api/glesv2.pc
2848                 src/mapi/glapi/gen/Makefile
2849                 src/mesa/Makefile
2850                 src/mesa/gl.pc
2851                 src/mesa/drivers/dri/dri.pc
2852                 src/mesa/drivers/dri/common/Makefile
2853                 src/mesa/drivers/dri/common/xmlpool/Makefile
2854                 src/mesa/drivers/dri/i915/Makefile
2855                 src/mesa/drivers/dri/i965/Makefile
2856                 src/mesa/drivers/dri/Makefile
2857                 src/mesa/drivers/dri/nouveau/Makefile
2858                 src/mesa/drivers/dri/r200/Makefile
2859                 src/mesa/drivers/dri/radeon/Makefile
2860                 src/mesa/drivers/dri/swrast/Makefile
2861                 src/mesa/drivers/osmesa/Makefile
2862                 src/mesa/drivers/osmesa/osmesa.pc
2863                 src/mesa/drivers/x11/Makefile
2864                 src/mesa/main/tests/Makefile
2865                 src/util/Makefile
2866                 src/util/tests/hash_table/Makefile
2867                 src/vulkan/wsi/Makefile])
2868
2869 AC_OUTPUT
2870
2871 # Fix up dependencies in *.Plo files, where we changed the extension of a
2872 # source file
2873 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2874
2875
2876 dnl
2877 dnl Output some configuration info for the user
2878 dnl
2879 echo ""
2880 echo "        prefix:          $prefix"
2881 echo "        exec_prefix:     $exec_prefix"
2882 echo "        libdir:          $libdir"
2883 echo "        includedir:      $includedir"
2884
2885 dnl API info
2886 echo ""
2887 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2888
2889 dnl Driver info
2890 echo ""
2891 case "x$enable_osmesa$enable_gallium_osmesa" in
2892 xnoyes)
2893         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2894         ;;
2895 xyesno)
2896         echo "        OSMesa:          lib$OSMESA_LIB"
2897         ;;
2898 xnono)
2899         echo "        OSMesa:          no"
2900         ;;
2901 esac
2902
2903 echo ""
2904 if test "x$enable_dri" != xno; then
2905         echo "        DRI platform:    $dri_platform"
2906         if test -z "$DRI_DIRS"; then
2907             echo "        DRI drivers:     no"
2908         else
2909             echo "        DRI drivers:     $DRI_DIRS"
2910         fi
2911         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2912 fi
2913
2914 case "x$enable_glx" in
2915 xdri)
2916     echo "        GLX:             DRI-based"
2917     ;;
2918 xxlib)
2919     echo "        GLX:             Xlib-based"
2920     ;;
2921 xgallium-xlib)
2922     echo "        GLX:             Xlib-based (Gallium)"
2923     ;;
2924 *)
2925     echo "        GLX:             $enable_glx"
2926     ;;
2927 esac
2928
2929 dnl EGL
2930 echo ""
2931 echo "        EGL:             $enable_egl"
2932 if test "$enable_egl" = yes; then
2933     echo "        EGL platforms:   $egl_platforms"
2934
2935     egl_drivers=""
2936     if test "x$enable_dri" != "xno"; then
2937         egl_drivers="$egl_drivers builtin:egl_dri2"
2938     fi
2939     if test "x$enable_dri3" != "xno"; then
2940         egl_drivers="$egl_drivers builtin:egl_dri3"
2941     fi
2942
2943     echo "        EGL drivers:    $egl_drivers"
2944 fi
2945 if test "x$enable_gbm" = xyes; then
2946     echo "        GBM:             yes"
2947 else
2948     echo "        GBM:             no"
2949 fi
2950
2951 # Vulkan
2952 echo ""
2953 if test "x$VULKAN_DRIVERS" != x; then
2954     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2955     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2956 else
2957     echo "        Vulkan drivers:  no"
2958 fi
2959
2960 echo ""
2961 if test "x$MESA_LLVM" = x1; then
2962     echo "        llvm:            yes"
2963     echo "        llvm-config:     $LLVM_CONFIG"
2964     echo "        llvm-version:    $LLVM_VERSION"
2965 else
2966     echo "        llvm:            no"
2967 fi
2968
2969 echo ""
2970 if test -n "$with_gallium_drivers"; then
2971     echo "        Gallium drivers: $gallium_drivers"
2972     echo "        Gallium st:      $gallium_st"
2973 else
2974     echo "        Gallium:         no"
2975 fi
2976
2977 echo ""
2978 if test "x$enable_gallium_extra_hud" != xyes; then
2979     echo "        HUD extra stats: no"
2980 else
2981     echo "        HUD extra stats: yes"
2982 fi
2983
2984 if test "x$enable_lmsensors" != xyes; then
2985     echo "        HUD lmsensors:   no"
2986 else
2987     echo "        HUD lmsensors:   yes"
2988 fi
2989
2990 dnl Shader cache
2991 echo ""
2992 echo "        Shader cache:    $enable_shader_cache"
2993 if test "x$enable_shader_cache" = "xyes"; then
2994     echo "        With SHA1 from:  $with_sha1"
2995 fi
2996
2997 dnl Libraries
2998 echo ""
2999 echo "        Shared libs:     $enable_shared"
3000 echo "        Static libs:     $enable_static"
3001 echo "        Shared-glapi:    $enable_shared_glapi"
3002
3003 dnl Compiler options
3004 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
3005 cflags=`echo $CFLAGS | \
3006     $SED 's/^ *//;s/  */ /;s/ *$//'`
3007 cxxflags=`echo $CXXFLAGS | \
3008     $SED 's/^ *//;s/  */ /;s/ *$//'`
3009 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3010 echo ""
3011 echo "        CFLAGS:          $cflags"
3012 echo "        CXXFLAGS:        $cxxflags"
3013 echo "        Macros:          $defines"
3014 echo ""
3015 if test "x$MESA_LLVM" = x1; then
3016     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3017     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3018     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3019     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3020     echo ""
3021 fi
3022 echo "        PYTHON2:         $PYTHON2"
3023
3024 echo ""
3025 echo "        Run '${MAKE-make}' to build Mesa"
3026 echo ""