configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.3
  22 DRI2PROTO_REQUIRED=1.99.3
  23
  24 dnl Check for progs
  25 AC_PROG_CPP
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_CHECK_PROGS([MAKE], [gmake make])
  29 AC_PATH_PROG([MKDEP], [makedepend])
  30 AC_PATH_PROG([SED], [sed])
  31
  32 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  33 dnl configuration in that case.
  34 AC_PROG_INSTALL
  35 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  36
  37 dnl We need a POSIX shell for parts of the build. Assume we have one
  38 dnl in most cases.
  39 case "$host_os" in
  40 solaris*)
  41     # Solaris /bin/sh is too old/non-POSIX compliant
  42     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  43     SHELL="$POSIX_SHELL"
  44     ;;
  45 esac
  46
  47 MKDEP_OPTIONS=-fdepend
  48 dnl Ask gcc where it's keeping its secret headers
  49 if test "x$GCC" = xyes; then
  50     for dir in include include-fixed; do
  51         GCC_INCLUDES=`$CC -print-file-name=$dir`
  52         if test "x$GCC_INCLUDES" != x && \
  53            test "$GCC_INCLUDES" != "$dir" && \
  54            test -d "$GCC_INCLUDES"; then
  55             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  56         fi
  57     done
  58 fi
  59 AC_SUBST([MKDEP_OPTIONS])
  60
  61 dnl Make sure the pkg-config macros are defined
  62 m4_ifndef([PKG_PROG_PKG_CONFIG],
  63     [m4_fatal([Could not locate the pkg-config autoconf macros.
  64   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  65   are in a different location, try setting the environment variable
  66   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  67 PKG_PROG_PKG_CONFIG()
  68
  69 dnl LIB_DIR - library basename
  70 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  71 AC_SUBST([LIB_DIR])
  72
  73 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  74 _SAVE_LDFLAGS="$LDFLAGS"
  75 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  76 AC_SUBST([EXTRA_LIB_PATH])
  77
  78 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  79 _SAVE_CPPFLAGS="$CPPFLAGS"
  80 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  81 AC_SUBST([X11_INCLUDES])
  82
  83 dnl Compiler macros
  84 DEFINES=""
  85 AC_SUBST([DEFINES])
  86 case "$host_os" in
  87 linux*|*-gnu*|gnu*)
  88     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  89     ;;
  90 solaris*)
  91     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  92     ;;
  93 esac
  94
  95 dnl Add flags for gcc and g++
  96 if test "x$GCC" = xyes; then
  97     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
  98
  99     # Work around aliasing bugs - developers should comment this out
 100     CFLAGS="$CFLAGS -fno-strict-aliasing"
 101 fi
 102 if test "x$GXX" = xyes; then
 103     CXXFLAGS="$CXXFLAGS -Wall"
 104
 105     # Work around aliasing bugs - developers should comment this out
 106     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 107 fi
 108
 109 dnl These should be unnecessary, but let the user set them if they want
 110 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 111     Default is to use CFLAGS.])
 112 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 113     compiler. Default is to use CFLAGS.])
 114 AC_SUBST([OPT_FLAGS])
 115 AC_SUBST([ARCH_FLAGS])
 116
 117 dnl
 118 dnl Hacks to enable 32 or 64 bit build
 119 dnl
 120 AC_ARG_ENABLE([32-bit],
 121     [AS_HELP_STRING([--enable-32-bit],
 122         [build 32-bit libraries @<:@default=auto@:>@])],
 123     [enable_32bit="$enableval"],
 124     [enable_32bit=auto]
 125 )
 126 if test "x$enable_32bit" = xyes; then
 127     if test "x$GCC" = xyes; then
 128         CFLAGS="$CFLAGS -m32"
 129     fi
 130     if test "x$GXX" = xyes; then
 131         CXXFLAGS="$CXXFLAGS -m32"
 132     fi
 133 fi
 134 AC_ARG_ENABLE([64-bit],
 135     [AS_HELP_STRING([--enable-64-bit],
 136         [build 64-bit libraries @<:@default=auto@:>@])],
 137     [enable_64bit="$enableval"],
 138     [enable_64bit=auto]
 139 )
 140 if test "x$enable_64bit" = xyes; then
 141     if test "x$GCC" = xyes; then
 142         CFLAGS="$CFLAGS -m64"
 143     fi
 144     if test "x$GXX" = xyes; then
 145         CXXFLAGS="$CXXFLAGS -m64"
 146     fi
 147 fi
 148
 149 dnl
 150 dnl shared/static libraries, mimic libtool options
 151 dnl
 152 AC_ARG_ENABLE([static],
 153     [AS_HELP_STRING([--enable-static],
 154         [build static libraries @<:@default=disabled@:>@])],
 155     [enable_static="$enableval"],
 156     [enable_static=no]
 157 )
 158 case "x$enable_static" in
 159 xyes|xno ) ;;
 160 x ) enable_static=no ;;
 161 * )
 162     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 163     ;;
 164 esac
 165 AC_ARG_ENABLE([shared],
 166     [AS_HELP_STRING([--disable-shared],
 167         [build shared libraries @<:@default=enabled@:>@])],
 168     [enable_shared="$enableval"],
 169     [enable_shared=yes]
 170 )
 171 case "x$enable_shared" in
 172 xyes|xno ) ;;
 173 x ) enable_shared=yes ;;
 174 * )
 175     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 176     ;;
 177 esac
 178
 179 dnl Can't have static and shared libraries, default to static if user
 180 dnl explicitly requested. If both disabled, set to static since shared
 181 dnl was explicitly requirested.
 182 case "x$enable_static$enable_shared" in
 183 xyesyes )
 184     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 185     enable_shared=no
 186     ;;
 187 xnono )
 188     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 189     enable_static=yes
 190     ;;
 191 esac
 192
 193 dnl
 194 dnl mklib options
 195 dnl
 196 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 197 if test "$enable_static" = yes; then
 198     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 199 fi
 200 AC_SUBST([MKLIB_OPTIONS])
 201
 202 dnl
 203 dnl other compiler options
 204 dnl
 205 AC_ARG_ENABLE([debug],
 206     [AS_HELP_STRING([--enable-debug],
 207         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 208     [enable_debug="$enableval"],
 209     [enable_debug=no]
 210 )
 211 if test "x$enable_debug" = xyes; then
 212     DEFINES="$DEFINES -DDEBUG"
 213     if test "x$GCC" = xyes; then
 214         CFLAGS="$CFLAGS -g"
 215     fi
 216     if test "x$GXX" = xyes; then
 217         CXXFLAGS="$CXXFLAGS -g"
 218     fi
 219 fi
 220
 221 dnl
 222 dnl library names
 223 dnl
 224 if test "$enable_static" = yes; then
 225     LIB_EXTENSION='a'
 226 else
 227     case "$host_os" in
 228     darwin* )
 229         LIB_EXTENSION='dylib' ;;
 230     cygwin* )
 231         LIB_EXTENSION='dll' ;;
 232     * )
 233         LIB_EXTENSION='so' ;;
 234     esac
 235 fi
 236
 237 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 238 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 239 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 240 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 241 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 242
 243 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 244 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 245 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 246 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 247 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 248
 249 AC_SUBST([GL_LIB_NAME])
 250 AC_SUBST([GLU_LIB_NAME])
 251 AC_SUBST([GLUT_LIB_NAME])
 252 AC_SUBST([GLW_LIB_NAME])
 253 AC_SUBST([OSMESA_LIB_NAME])
 254
 255 AC_SUBST([GL_LIB_GLOB])
 256 AC_SUBST([GLU_LIB_GLOB])
 257 AC_SUBST([GLUT_LIB_GLOB])
 258 AC_SUBST([GLW_LIB_GLOB])
 259 AC_SUBST([OSMESA_LIB_GLOB])
 260
 261 dnl
 262 dnl Arch/platform-specific settings
 263 dnl
 264 AC_ARG_ENABLE([asm],
 265     [AS_HELP_STRING([--disable-asm],
 266         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 267     [enable_asm="$enableval"],
 268     [enable_asm=yes]
 269 )
 270 asm_arch=""
 271 ASM_FLAGS=""
 272 MESA_ASM_SOURCES=""
 273 GLAPI_ASM_SOURCES=""
 274 AC_MSG_CHECKING([whether to enable assembly])
 275 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 276 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 277 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 278     case "$host_cpu" in
 279     i?86 | x86_64)
 280         enable_asm=no
 281         AC_MSG_RESULT([no, cross compiling])
 282         ;;
 283     esac
 284 fi
 285 # check for supported arches
 286 if test "x$enable_asm" = xyes; then
 287     case "$host_cpu" in
 288     i?86)
 289         case "$host_os" in
 290         linux* | *freebsd* | dragonfly*)
 291             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 292             ;;
 293         esac
 294         ;;
 295     x86_64)
 296         case "$host_os" in
 297         linux* | *freebsd* | dragonfly*)
 298             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 299             ;;
 300         esac
 301         ;;
 302     powerpc)
 303         case "$host_os" in
 304         linux*)
 305             asm_arch=ppc
 306             ;;
 307         esac
 308         ;;
 309     sparc*)
 310         case "$host_os" in
 311         linux*)
 312             asm_arch=sparc
 313             ;;
 314         esac
 315         ;;
 316     esac
 317
 318     case "$asm_arch" in
 319     x86)
 320         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 321         MESA_ASM_SOURCES='$(X86_SOURCES)'
 322         GLAPI_ASM_SOURCES='$(X86_API)'
 323         AC_MSG_RESULT([yes, x86])
 324         ;;
 325     x86_64)
 326         ASM_FLAGS="-DUSE_X86_64_ASM"
 327         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 328         GLAPI_ASM_SOURCES='$(X86-64_API)'
 329         AC_MSG_RESULT([yes, x86_64])
 330         ;;
 331     ppc)
 332         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 333         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 334         AC_MSG_RESULT([yes, ppc])
 335         ;;
 336     sparc)
 337         ASM_FLAGS="-DUSE_SPARC_ASM"
 338         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 339         GLAPI_ASM_SOURCES='$(SPARC_API)'
 340         AC_MSG_RESULT([yes, sparc])
 341         ;;
 342     *)
 343         AC_MSG_RESULT([no, platform not supported])
 344         ;;
 345     esac
 346 fi
 347 AC_SUBST([ASM_FLAGS])
 348 AC_SUBST([MESA_ASM_SOURCES])
 349 AC_SUBST([GLAPI_ASM_SOURCES])
 350
 351 dnl PIC code macro
 352 MESA_PIC_FLAGS
 353
 354 dnl Check to see if dlopen is in default libraries (like Solaris, which
 355 dnl has it in libc), or if libdl is needed to get it.
 356 AC_CHECK_FUNC([dlopen], [],
 357     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 358
 359 dnl See if posix_memalign is available
 360 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 361
 362 dnl SELinux awareness.
 363 AC_ARG_ENABLE([selinux],
 364     [AS_HELP_STRING([--enable-selinux],
 365         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 366     [MESA_SELINUX="$enableval"],
 367     [MESA_SELINUX=no])
 368 if test "x$enable_selinux" = "xyes"; then
 369     AC_CHECK_HEADER([selinux/selinux.h],[],
 370                     [AC_MSG_ERROR([SELinux headers not found])])
 371     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 372                  [AC_MSG_ERROR([SELinux library not found])])
 373     SELINUX_LIBS="-lselinux"
 374     DEFINES="$DEFINES -DMESA_SELINUX"
 375 fi
 376
 377 dnl
 378 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 379 dnl More later: directfb, fbdev, ...
 380 dnl
 381 default_driver="xlib"
 382
 383 case "$host_os" in
 384 linux*)
 385     case "$host_cpu" in
 386     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 387     esac
 388     ;;
 389 *freebsd* | dragonfly*)
 390     case "$host_cpu" in
 391     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 392     esac
 393     ;;
 394 esac
 395
 396 AC_ARG_WITH([driver],
 397     [AS_HELP_STRING([--with-driver=DRIVER],
 398         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 399     [mesa_driver="$withval"],
 400     [mesa_driver="$default_driver"])
 401 dnl Check for valid option
 402 case "x$mesa_driver" in
 403 xxlib|xdri|xosmesa)
 404     ;;
 405 *)
 406     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 407     ;;
 408 esac
 409
 410 dnl
 411 dnl Driver specific build directories
 412 dnl
 413 SRC_DIRS="mesa glew"
 414 GLU_DIRS="sgi"
 415 WINDOW_SYSTEM=""
 416 GALLIUM_DIRS="auxiliary drivers state_trackers"
 417 GALLIUM_WINSYS_DIRS=""
 418 GALLIUM_WINSYS_DRM_DIRS=""
 419 GALLIUM_AUXILIARY_DIRS="rbug draw translate cso_cache pipebuffer tgsi sct rtasm util indices"
 420 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 421 GALLIUM_STATE_TRACKERS_DIRS=""
 422
 423 case "$mesa_driver" in
 424 xlib)
 425     DRIVER_DIRS="x11"
 426     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 427     ;;
 428 dri)
 429     SRC_DIRS="glx/x11 $SRC_DIRS"
 430     DRIVER_DIRS="dri"
 431     WINDOW_SYSTEM="dri"
 432     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 433     ;;
 434 osmesa)
 435     DRIVER_DIRS="osmesa"
 436     ;;
 437 esac
 438 AC_SUBST([SRC_DIRS])
 439 AC_SUBST([GLU_DIRS])
 440 AC_SUBST([DRIVER_DIRS])
 441 AC_SUBST([WINDOW_SYSTEM])
 442 AC_SUBST([GALLIUM_DIRS])
 443 AC_SUBST([GALLIUM_WINSYS_DIRS])
 444 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 445 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 446 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 447 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 448
 449 dnl
 450 dnl User supplied program configuration
 451 dnl
 452 if test -d "$srcdir/progs/demos"; then
 453     default_demos=yes
 454 else
 455     default_demos=no
 456 fi
 457 AC_ARG_WITH([demos],
 458     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 459         [optional comma delimited demo directories to build
 460         @<:@default=auto if source available@:>@])],
 461     [with_demos="$withval"],
 462     [with_demos="$default_demos"])
 463 if test "x$with_demos" = x; then
 464     with_demos=no
 465 fi
 466
 467 dnl If $with_demos is yes, directories will be added as libs available
 468 PROGRAM_DIRS=""
 469 case "$with_demos" in
 470 no) ;;
 471 yes)
 472     # If the driver isn't osmesa, we have libGL and can build xdemos
 473     if test "$mesa_driver" != osmesa; then
 474         PROGRAM_DIRS="xdemos"
 475     fi
 476     ;;
 477 *)
 478     # verify the requested demos directories exist
 479     demos=`IFS=,; echo $with_demos`
 480     for demo in $demos; do
 481         test -d "$srcdir/progs/$demo" || \
 482             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 483     done
 484     PROGRAM_DIRS="$demos"
 485     ;;
 486 esac
 487
 488 dnl
 489 dnl Find out if X is available. The variable have_x is set if libX11 is
 490 dnl found to mimic AC_PATH_XTRA.
 491 dnl
 492 if test -n "$PKG_CONFIG"; then
 493     AC_MSG_CHECKING([pkg-config files for X11 are available])
 494     PKG_CHECK_EXISTS([x11],[
 495         x11_pkgconfig=yes
 496         have_x=yes
 497         ],[
 498         x11_pkgconfig=no
 499     ])
 500     AC_MSG_RESULT([$x11_pkgconfig])
 501 else
 502     x11_pkgconfig=no
 503 fi
 504 dnl Use the autoconf macro if no pkg-config files
 505 if test "$x11_pkgconfig" = no; then
 506     AC_PATH_XTRA
 507 fi
 508
 509 dnl Try to tell the user that the --x-* options are only used when
 510 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 511 m4_divert_once([HELP_BEGIN],
 512 [These options are only used when the X libraries cannot be found by the
 513 pkg-config utility.])
 514
 515 dnl We need X for xlib and dri, so bomb now if it's not found
 516 case "$mesa_driver" in
 517 xlib|dri)
 518     if test "$no_x" = yes; then
 519         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 520     fi
 521     ;;
 522 esac
 523
 524 dnl XCB - this is only used for GLX right now
 525 AC_ARG_ENABLE([xcb],
 526     [AS_HELP_STRING([--enable-xcb],
 527         [use XCB for GLX @<:@default=disabled@:>@])],
 528     [enable_xcb="$enableval"],
 529     [enable_xcb=no])
 530 if test "x$enable_xcb" = xyes; then
 531     DEFINES="$DEFINES -DUSE_XCB"
 532 else
 533     enable_xcb=no
 534 fi
 535
 536 dnl
 537 dnl libGL configuration per driver
 538 dnl
 539 case "$mesa_driver" in
 540 xlib)
 541     if test "$x11_pkgconfig" = yes; then
 542         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 543         GL_PC_REQ_PRIV="x11 xext"
 544         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 545         GL_LIB_DEPS="$XLIBGL_LIBS"
 546     else
 547         # should check these...
 548         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 549         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 550         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 551         GL_PC_CFLAGS="$X11_INCLUDES"
 552     fi
 553     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 554     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 555
 556     # if static, move the external libraries to the programs
 557     # and empty the libraries for libGL
 558     if test "$enable_static" = yes; then
 559         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 560         GL_LIB_DEPS=""
 561     fi
 562     ;;
 563 dri)
 564     # DRI must be shared, I think
 565     if test "$enable_static" = yes; then
 566         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 567     fi
 568
 569     # Check for libdrm
 570     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 571     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 572     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 573     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 574
 575     # find the DRI deps for libGL
 576     if test "$x11_pkgconfig" = yes; then
 577         # add xcb modules if necessary
 578         dri_modules="x11 xext xxf86vm xdamage xfixes"
 579         if test "$enable_xcb" = yes; then
 580             dri_modules="$dri_modules x11-xcb xcb-glx"
 581         fi
 582
 583         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 584         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 585         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 586         GL_LIB_DEPS="$DRIGL_LIBS"
 587     else
 588         # should check these...
 589         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 590         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 591         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 592         GL_PC_CFLAGS="$X11_INCLUDES"
 593
 594         # XCB can only be used from pkg-config
 595         if test "$enable_xcb" = yes; then
 596             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 597             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 598             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 599             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 600         fi
 601     fi
 602
 603     # need DRM libs, -lpthread, etc.
 604     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 605     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 606     ;;
 607 osmesa)
 608     # No libGL for osmesa
 609     GL_LIB_DEPS=""
 610     ;;
 611 esac
 612 AC_SUBST([GL_LIB_DEPS])
 613 AC_SUBST([GL_PC_REQ_PRIV])
 614 AC_SUBST([GL_PC_LIB_PRIV])
 615 AC_SUBST([GL_PC_CFLAGS])
 616 AC_SUBST([DRI_PC_REQ_PRIV])
 617
 618 dnl
 619 dnl More X11 setup
 620 dnl
 621 if test "$mesa_driver" = xlib; then
 622     DEFINES="$DEFINES -DUSE_XSHM"
 623 fi
 624
 625 dnl
 626 dnl More DRI setup
 627 dnl
 628 AC_ARG_ENABLE([glx-tls],
 629     [AS_HELP_STRING([--enable-glx-tls],
 630         [enable TLS support in GLX @<:@default=disabled@:>@])],
 631     [GLX_USE_TLS="$enableval"],
 632     [GLX_USE_TLS=no])
 633 dnl Directory for DRI drivers
 634 AC_ARG_WITH([dri-driverdir],
 635     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 636         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 637     [DRI_DRIVER_INSTALL_DIR="$withval"],
 638     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 639 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 640 dnl Direct rendering or just indirect rendering
 641 AC_ARG_ENABLE([driglx-direct],
 642     [AS_HELP_STRING([--disable-driglx-direct],
 643         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 644     [driglx_direct="$enableval"],
 645     [driglx_direct="yes"])
 646 dnl Which drivers to build - default is chosen by platform
 647 AC_ARG_WITH([dri-drivers],
 648     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 649         [comma delimited DRI drivers list, e.g.
 650         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 651     [with_dri_drivers="$withval"],
 652     [with_dri_drivers=yes])
 653 if test "x$with_dri_drivers" = x; then
 654     with_dri_drivers=no
 655 fi
 656
 657 dnl If $with_dri_drivers is yes, directories will be added through
 658 dnl platform checks
 659 DRI_DIRS=""
 660 case "$with_dri_drivers" in
 661 no) ;;
 662 yes)
 663     DRI_DIRS="yes"
 664     ;;
 665 *)
 666     # verify the requested driver directories exist
 667     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 668     for driver in $dri_drivers; do
 669         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 670             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 671     done
 672     DRI_DIRS="$dri_drivers"
 673     ;;
 674 esac
 675
 676 dnl Just default to no EGL for now
 677 USING_EGL=0
 678 AC_SUBST([USING_EGL])
 679
 680 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 681 if test "$mesa_driver" = dri; then
 682     # Use TLS in GLX?
 683     if test "x$GLX_USE_TLS" = xyes; then
 684         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 685     fi
 686
 687     if test "x$USING_EGL" = x1; then
 688         PROGRAM_DIRS="egl"
 689     fi
 690
 691     # Platform specific settings and drivers to build
 692     case "$host_os" in
 693     linux*)
 694         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 695         if test "x$driglx_direct" = xyes; then
 696             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 697         fi
 698         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 699
 700         case "$host_cpu" in
 701         x86_64)
 702             # ffb, gamma, and sis are missing because they have not be
 703             # converted to use the new interface.  i810 are missing
 704             # because there is no x86-64 system where they could *ever*
 705             # be used.
 706             if test "x$DRI_DIRS" = "xyes"; then
 707                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 708                     savage tdfx unichrome swrast"
 709             fi
 710             ;;
 711         powerpc*)
 712             # Build only the drivers for cards that exist on PowerPC.
 713             # At some point MGA will be added, but not yet.
 714             if test "x$DRI_DIRS" = "xyes"; then
 715                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 716             fi
 717             ;;
 718         sparc*)
 719             # Build only the drivers for cards that exist on sparc`
 720             if test "x$DRI_DIRS" = "xyes"; then
 721                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 722             fi
 723             ;;
 724         esac
 725         ;;
 726     freebsd* | dragonfly*)
 727         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 728         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 729         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 730         if test "x$driglx_direct" = xyes; then
 731             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 732         fi
 733         if test "x$GXX" = xyes; then
 734             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 735         fi
 736
 737         # ffb and gamma are missing because they have not been converted
 738         # to use the new interface.
 739         if test "x$DRI_DIRS" = "xyes"; then
 740             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 741                 unichrome savage sis swrast"
 742         fi
 743         ;;
 744     gnu*)
 745         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 746         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 747         ;;
 748     solaris*)
 749         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 750         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 751         if test "x$driglx_direct" = xyes; then
 752             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 753         fi
 754         ;;
 755     esac
 756
 757     # default drivers
 758     if test "x$DRI_DIRS" = "xyes"; then
 759         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 760             savage sis tdfx trident unichrome ffb swrast"
 761     fi
 762
 763     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 764
 765     # Check for expat
 766     EXPAT_INCLUDES=""
 767     EXPAT_LIB=-lexpat
 768     AC_ARG_WITH([expat],
 769         [AS_HELP_STRING([--with-expat=DIR],
 770             [expat install directory])],[
 771         EXPAT_INCLUDES="-I$withval/include"
 772         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 773         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 774         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 775         ])
 776     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 777     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 778         [AC_MSG_ERROR([Expat required for DRI.])])
 779
 780     # put all the necessary libs together
 781     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 782 fi
 783 AC_SUBST([DRI_DIRS])
 784 AC_SUBST([EXPAT_INCLUDES])
 785 AC_SUBST([DRI_LIB_DEPS])
 786
 787 dnl
 788 dnl OSMesa configuration
 789 dnl
 790 if test "$mesa_driver" = xlib; then
 791     default_gl_osmesa=yes
 792 else
 793     default_gl_osmesa=no
 794 fi
 795 AC_ARG_ENABLE([gl-osmesa],
 796     [AS_HELP_STRING([--enable-gl-osmesa],
 797         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 798     [gl_osmesa="$enableval"],
 799     [gl_osmesa="$default_gl_osmesa"])
 800 if test "x$gl_osmesa" = xyes; then
 801     if test "$mesa_driver" = osmesa; then
 802         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 803     else
 804         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 805     fi
 806 fi
 807
 808 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 809 AC_ARG_WITH([osmesa-bits],
 810     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 811         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 812     [osmesa_bits="$withval"],
 813     [osmesa_bits=8])
 814 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 815     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 816     osmesa_bits=8
 817 fi
 818 case "x$osmesa_bits" in
 819 x8)
 820     OSMESA_LIB=OSMesa
 821     ;;
 822 x16|x32)
 823     OSMESA_LIB="OSMesa$osmesa_bits"
 824     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 825     ;;
 826 *)
 827     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 828     ;;
 829 esac
 830 AC_SUBST([OSMESA_LIB])
 831
 832 case "$mesa_driver" in
 833 osmesa)
 834     # only link libraries with osmesa if shared
 835     if test "$enable_static" = no; then
 836         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 837     else
 838         OSMESA_LIB_DEPS=""
 839     fi
 840     OSMESA_MESA_DEPS=""
 841     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 842     ;;
 843 *)
 844     # Link OSMesa to libGL otherwise
 845     OSMESA_LIB_DEPS=""
 846     # only link libraries with osmesa if shared
 847     if test "$enable_static" = no; then
 848         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 849     else
 850         OSMESA_MESA_DEPS=""
 851     fi
 852     OSMESA_PC_REQ="gl"
 853     ;;
 854 esac
 855 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 856 AC_SUBST([OSMESA_LIB_DEPS])
 857 AC_SUBST([OSMESA_MESA_DEPS])
 858 AC_SUBST([OSMESA_PC_REQ])
 859 AC_SUBST([OSMESA_PC_LIB_PRIV])
 860
 861 dnl
 862 dnl EGL configuration
 863 dnl
 864 AC_ARG_ENABLE([egl],
 865     [AS_HELP_STRING([--disable-egl],
 866         [disable EGL library @<:@default=enabled@:>@])],
 867     [enable_egl="$enableval"],
 868     [enable_egl=yes])
 869 if test "x$enable_egl" = xyes; then
 870     SRC_DIRS="$SRC_DIRS egl"
 871
 872     if test "$x11_pkgconfig" = yes; then
 873         PKG_CHECK_MODULES([EGL], [x11])
 874         EGL_LIB_DEPS="$EGL_LIBS"
 875     else
 876         # should check these...
 877         EGL_LIB_DEPS="$X_LIBS -lX11"
 878     fi
 879     EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS"
 880 fi
 881 AC_SUBST([EGL_LIB_DEPS])
 882
 883 dnl
 884 dnl GLU configuration
 885 dnl
 886 AC_ARG_ENABLE([glu],
 887     [AS_HELP_STRING([--disable-glu],
 888         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 889     [enable_glu="$enableval"],
 890     [enable_glu=yes])
 891 if test "x$enable_glu" = xyes; then
 892     SRC_DIRS="$SRC_DIRS glu"
 893
 894     case "$mesa_driver" in
 895     osmesa)
 896         # If GLU is available and we have libOSMesa (not 16 or 32),
 897         # we can build the osdemos
 898         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 899             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 900         fi
 901
 902         # Link libGLU to libOSMesa instead of libGL
 903         GLU_LIB_DEPS=""
 904         GLU_PC_REQ="osmesa"
 905         if test "$enable_static" = no; then
 906             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 907         else
 908             GLU_MESA_DEPS=""
 909         fi
 910         ;;
 911     *)
 912         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 913         GLU_PC_REQ="gl"
 914         GLU_PC_LIB_PRIV="-lm"
 915         if test "$enable_static" = no; then
 916             GLU_LIB_DEPS="-lm"
 917             GLU_MESA_DEPS='-l$(GL_LIB)'
 918         else
 919             GLU_LIB_DEPS=""
 920             GLU_MESA_DEPS=""
 921             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 922         fi
 923         ;;
 924     esac
 925 fi
 926 if test "$enable_static" = no; then
 927     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 928 fi
 929 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 930 AC_SUBST([GLU_LIB_DEPS])
 931 AC_SUBST([GLU_MESA_DEPS])
 932 AC_SUBST([GLU_PC_REQ])
 933 AC_SUBST([GLU_PC_REQ_PRIV])
 934 AC_SUBST([GLU_PC_LIB_PRIV])
 935 AC_SUBST([GLU_PC_CFLAGS])
 936
 937 dnl
 938 dnl GLw configuration
 939 dnl
 940 AC_ARG_ENABLE([glw],
 941     [AS_HELP_STRING([--disable-glw],
 942         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 943     [enable_glw="$enableval"],
 944     [enable_glw=yes])
 945 dnl Don't build GLw on osmesa
 946 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 947     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 948     enable_glw=no
 949 fi
 950 AC_ARG_ENABLE([motif],
 951     [AS_HELP_STRING([--enable-motif],
 952         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 953     [enable_motif="$enableval"],
 954     [enable_motif=no])
 955
 956 if test "x$enable_glw" = xyes; then
 957     SRC_DIRS="$SRC_DIRS glw"
 958     if test "$x11_pkgconfig" = yes; then
 959         PKG_CHECK_MODULES([GLW],[x11 xt])
 960         GLW_PC_REQ_PRIV="x11 xt"
 961         GLW_LIB_DEPS="$GLW_LIBS"
 962     else
 963         # should check these...
 964         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 965         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 966         GLW_PC_CFLAGS="$X11_INCLUDES"
 967     fi
 968
 969     GLW_SOURCES="GLwDrawA.c"
 970     MOTIF_CFLAGS=
 971     if test "x$enable_motif" = xyes; then
 972         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 973         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 974         if test "x$MOTIF_CONFIG" != xno; then
 975             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 976             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 977         else
 978             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 979                 [AC_MSG_ERROR([Can't locate Motif headers])])
 980             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 981                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 982         fi
 983         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 984         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 985         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 986         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 987     fi
 988
 989     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 990     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
 991     if test "$enable_static" = no; then
 992         GLW_MESA_DEPS='-l$(GL_LIB)'
 993         GLW_LIB_DEPS="$GLW_LIB_DEPS"
 994     else
 995         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 996         GLW_LIB_DEPS=""
 997         GLW_MESA_DEPS=""
 998     fi
 999 fi
1000 AC_SUBST([GLW_LIB_DEPS])
1001 AC_SUBST([GLW_MESA_DEPS])
1002 AC_SUBST([GLW_SOURCES])
1003 AC_SUBST([MOTIF_CFLAGS])
1004 AC_SUBST([GLW_PC_REQ_PRIV])
1005 AC_SUBST([GLW_PC_LIB_PRIV])
1006 AC_SUBST([GLW_PC_CFLAGS])
1007
1008 dnl
1009 dnl GLUT configuration
1010 dnl
1011 if test -f "$srcdir/include/GL/glut.h"; then
1012     default_glut=yes
1013 else
1014     default_glut=no
1015 fi
1016 AC_ARG_ENABLE([glut],
1017     [AS_HELP_STRING([--disable-glut],
1018         [enable GLUT library @<:@default=enabled if source available@:>@])],
1019     [enable_glut="$enableval"],
1020     [enable_glut="$default_glut"])
1021
1022 dnl Can't build glut if GLU not available
1023 if test "x$enable_glu$enable_glut" = xnoyes; then
1024     AC_MSG_WARN([Disabling glut since GLU is disabled])
1025     enable_glut=no
1026 fi
1027 dnl Don't build glut on osmesa
1028 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1029     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1030     enable_glut=no
1031 fi
1032
1033 if test "x$enable_glut" = xyes; then
1034     SRC_DIRS="$SRC_DIRS glut/glx"
1035     GLUT_CFLAGS=""
1036     if test "x$GCC" = xyes; then
1037         GLUT_CFLAGS="-fexceptions"
1038     fi
1039     if test "$x11_pkgconfig" = yes; then
1040         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1041         GLUT_PC_REQ_PRIV="x11 xmu xi"
1042         GLUT_LIB_DEPS="$GLUT_LIBS"
1043     else
1044         # should check these...
1045         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1046         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1047         GLUT_PC_CFLAGS="$X11_INCLUDES"
1048     fi
1049     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1050     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1051
1052     # If glut is available, we can build most programs
1053     if test "$with_demos" = yes; then
1054         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1055     fi
1056
1057     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1058     if test "$enable_static" = no; then
1059         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1060     else
1061         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1062         GLUT_LIB_DEPS=""
1063         GLUT_MESA_DEPS=""
1064     fi
1065 fi
1066 AC_SUBST([GLUT_LIB_DEPS])
1067 AC_SUBST([GLUT_MESA_DEPS])
1068 AC_SUBST([GLUT_CFLAGS])
1069 AC_SUBST([GLUT_PC_REQ_PRIV])
1070 AC_SUBST([GLUT_PC_LIB_PRIV])
1071 AC_SUBST([GLUT_PC_CFLAGS])
1072
1073 dnl
1074 dnl Program library dependencies
1075 dnl    Only libm is added here if necessary as the libraries should
1076 dnl    be pulled in by the linker
1077 dnl
1078 if test "x$APP_LIB_DEPS" = x; then
1079     case "$host_os" in
1080     solaris*)
1081         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1082         ;;
1083     cygwin*)
1084         APP_LIB_DEPS="-lX11"
1085         ;;
1086     *)
1087         APP_LIB_DEPS="-lm"
1088         ;;
1089     esac
1090 fi
1091 AC_SUBST([APP_LIB_DEPS])
1092 AC_SUBST([PROGRAM_DIRS])
1093
1094 dnl
1095 dnl Gallium configuration
1096 dnl
1097 AC_ARG_ENABLE([gallium],
1098     [AS_HELP_STRING([--disable-gallium],
1099         [build gallium @<:@default=enabled@:>@])],
1100     [enable_gallium="$enableval"],
1101     [enable_gallium=yes])
1102 if test "x$enable_gallium" = xyes; then
1103     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1104 fi
1105
1106 dnl
1107 dnl Gallium state trackers configuration
1108 dnl
1109 AC_ARG_WITH([state-trackers],
1110     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1111         [comma delimited state_trackers list, e.g.
1112         "egl,glx" @<:@default=auto@:>@])],
1113     [with_state_trackers="$withval"],
1114     [with_state_trackers=yes])
1115
1116 case "$with_state_trackers" in
1117 no)
1118     GALLIUM_STATE_TRACKERS_DIRS=""
1119     ;;
1120 yes)
1121     # look at what else is built
1122     case "$mesa_driver" in
1123     xlib)
1124         GALLIUM_STATE_TRACKERS_DIRS=glx
1125         ;;
1126     dri)
1127         test "x$enable_egl" = xyes && GALLIUM_STATE_TRACKERS_DIRS=egl
1128         ;;
1129     esac
1130     ;;
1131 *)
1132     # verify the requested state tracker exist
1133     state_trackers=`IFS=', '; echo $with_state_trackers`
1134     for tracker in $state_trackers; do
1135         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1136             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1137
1138         if test "$tracker" = egl && test "x$enable_egl" != xyes; then
1139             AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1140         fi
1141     done
1142     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1143     ;;
1144 esac
1145
1146 AC_ARG_WITH([xorg-driver-dir],
1147     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1148                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1149     [XORG_DRIVER_INSTALL_DIR="$withval"],
1150     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1151 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1152
1153 dnl
1154 dnl Gallium Intel configuration
1155 dnl
1156 AC_ARG_ENABLE([gallium-intel],
1157     [AS_HELP_STRING([--disable-gallium-intel],
1158         [build gallium intel @<:@default=enabled@:>@])],
1159     [enable_gallium_intel="$enableval"],
1160     [enable_gallium_intel=yes])
1161 if test "x$enable_gallium_intel" = xyes; then
1162     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1163     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1164 fi
1165
1166 dnl
1167 dnl Gallium Radeon configuration
1168 dnl
1169 AC_ARG_ENABLE([gallium-radeon],
1170     [AS_HELP_STRING([--enable-gallium-radeon],
1171         [build gallium radeon @<:@default=disabled@:>@])],
1172     [enable_gallium_radeon="$enableval"],
1173     [enable_gallium_radeon=no])
1174 if test "x$enable_gallium_radeon" = xyes; then
1175     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1176     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1177 fi
1178
1179 dnl
1180 dnl Gallium Radeon configuration
1181 dnl
1182 AC_ARG_ENABLE([gallium-nouveau],
1183     [AS_HELP_STRING([--enable-gallium-nouveau],
1184         [build gallium nouveau @<:@default=disabled@:>@])],
1185     [enable_gallium_nouveau="$enableval"],
1186     [enable_gallium_nouveau=no])
1187 if test "x$enable_gallium_nouveau" = xyes; then
1188     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1189     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv04 nv10 nv20 nv30 nv40 nv50"
1190 fi
1191
1192
1193 dnl Restore LDFLAGS and CPPFLAGS
1194 LDFLAGS="$_SAVE_LDFLAGS"
1195 CPPFLAGS="$_SAVE_CPPFLAGS"
1196
1197 dnl Substitute the config
1198 AC_CONFIG_FILES([configs/autoconf])
1199
1200 dnl Replace the configs/current symlink
1201 AC_CONFIG_COMMANDS([configs],[
1202 if test -f configs/current || test -L configs/current; then
1203     rm -f configs/current
1204 fi
1205 ln -s autoconf configs/current
1206 ])
1207
1208 AC_OUTPUT
1209
1210 dnl
1211 dnl Output some configuration info for the user
1212 dnl
1213 echo ""
1214 echo "        prefix:          $prefix"
1215 echo "        exec_prefix:     $exec_prefix"
1216 echo "        libdir:          $libdir"
1217 echo "        includedir:      $includedir"
1218
1219 dnl Driver info
1220 echo ""
1221 echo "        Driver:          $mesa_driver"
1222 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1223     echo "        OSMesa:          lib$OSMESA_LIB"
1224 else
1225     echo "        OSMesa:          no"
1226 fi
1227 if test "$mesa_driver" = dri; then
1228     # cleanup the drivers var
1229     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1230 if test "x$DRI_DIRS" = x; then
1231     echo "        DRI drivers:     no"
1232 else
1233     echo "        DRI drivers:     $dri_dirs"
1234 fi
1235     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1236 fi
1237 echo "        Use XCB:         $enable_xcb"
1238
1239 echo ""
1240 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1241     echo "        Gallium:         yes"
1242     echo "        Gallium dirs:    $GALLIUM_DIRS"
1243     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1244     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1245     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1246     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1247     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1248 else
1249     echo "        Gallium:         no"
1250 fi
1251
1252 dnl Libraries
1253 echo ""
1254 echo "        Shared libs:     $enable_shared"
1255 echo "        Static libs:     $enable_static"
1256 echo "        EGL:             $enable_egl"
1257 echo "        GLU:             $enable_glu"
1258 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1259 echo "        glut:            $enable_glut"
1260
1261 dnl Programs
1262 # cleanup the programs var for display
1263 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1264 if test "x$program_dirs" = x; then
1265     echo "        Demos:           no"
1266 else
1267     echo "        Demos:           $program_dirs"
1268 fi
1269
1270 dnl Compiler options
1271 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1272 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1273     $SED 's/^ *//;s/  */ /;s/ *$//'`
1274 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1275     $SED 's/^ *//;s/  */ /;s/ *$//'`
1276 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1277 echo ""
1278 echo "        CFLAGS:          $cflags"
1279 echo "        CXXFLAGS:        $cxxflags"
1280 echo "        Macros:          $defines"
1281
1282 echo ""
1283 echo "        Run '${MAKE-make}' to build Mesa"
1284 echo ""