configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 LIBVA_REQUIRED=0.35.0
  43 VDPAU_REQUIRED=0.4.1
  44 WAYLAND_REQUIRED=1.2.0
  45 XCB_REQUIRED=1.9.3
  46 XCBDRI2_REQUIRED=1.8
  47 XCBGLX_REQUIRED=1.8.1
  48 XSHMFENCE_REQUIRED=1.1
  49 XVMC_REQUIRED=1.0.6
  50
  51 dnl Check for progs
  52 AC_PROG_CPP
  53 AC_PROG_CC
  54 AC_PROG_CXX
  55 AM_PROG_CC_C_O
  56 AM_PROG_AS
  57 AX_CHECK_GNU_MAKE
  58 AC_CHECK_PROGS([PYTHON2], [python2 python])
  59 AC_PROG_SED
  60 AC_PROG_MKDIR_P
  61
  62 AC_SYS_LARGEFILE
  63
  64 LT_PREREQ([2.2])
  65 LT_INIT([disable-static])
  66
  67 AX_PROG_BISON([],
  68               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  69                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  70 AX_PROG_FLEX([],
  71              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  72                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  73
  74 AC_CHECK_PROG(INDENT, indent, indent, cat)
  75 if test "x$INDENT" != "xcat"; then
  76     # Only GNU indent is supported
  77     INDENT_VERSION=`indent --version | grep GNU`
  78     if test $? -eq 0; then
  79        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  80     else
  81        INDENT="cat"
  82     fi
  83 fi
  84
  85 AX_CHECK_PYTHON_MAKO_MODULE(0.3.4)
  86
  87 AC_PROG_INSTALL
  88
  89 dnl We need a POSIX shell for parts of the build. Assume we have one
  90 dnl in most cases.
  91 case "$host_os" in
  92 solaris*)
  93     # Solaris /bin/sh is too old/non-POSIX compliant
  94     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  95     SHELL="$POSIX_SHELL"
  96     ;;
  97 esac
  98
  99 dnl clang is mostly GCC-compatible, but its version is much lower,
 100 dnl so we have to check for it.
 101 AC_MSG_CHECKING([if compiling with clang])
 102
 103 AC_COMPILE_IFELSE(
 104 [AC_LANG_PROGRAM([], [[
 105 #ifndef __clang__
 106        not clang
 107 #endif
 108 ]])],
 109 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 110
 111 AC_MSG_RESULT([$acv_mesa_CLANG])
 112
 113 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 114 dnl versions are explictly not supported.
 115 GEN_ASM_OFFSETS=no
 116 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 117     AC_MSG_CHECKING([whether gcc version is sufficient])
 118     major=0
 119     minor=0
 120
 121     GCC_VERSION=`$CC -dumpversion`
 122     if test $? -eq 0; then
 123         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 124         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 125     fi
 126
 127     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 128         AC_MSG_RESULT([no])
 129         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 130     else
 131         AC_MSG_RESULT([yes])
 132     fi
 133
 134     if test "x$cross_compiling" = xyes; then
 135         GEN_ASM_OFFSETS=yes
 136     fi
 137 fi
 138
 139 dnl Check for compiler builtins
 140 AX_GCC_BUILTIN([__builtin_bswap32])
 141 AX_GCC_BUILTIN([__builtin_bswap64])
 142 AX_GCC_BUILTIN([__builtin_clz])
 143 AX_GCC_BUILTIN([__builtin_clzll])
 144 AX_GCC_BUILTIN([__builtin_ctz])
 145 AX_GCC_BUILTIN([__builtin_expect])
 146 AX_GCC_BUILTIN([__builtin_ffs])
 147 AX_GCC_BUILTIN([__builtin_ffsll])
 148 AX_GCC_BUILTIN([__builtin_popcount])
 149 AX_GCC_BUILTIN([__builtin_popcountll])
 150 AX_GCC_BUILTIN([__builtin_unreachable])
 151
 152 AX_GCC_FUNC_ATTRIBUTE([flatten])
 153 AX_GCC_FUNC_ATTRIBUTE([format])
 154 AX_GCC_FUNC_ATTRIBUTE([malloc])
 155 AX_GCC_FUNC_ATTRIBUTE([packed])
 156
 157 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 158
 159 dnl Make sure the pkg-config macros are defined
 160 m4_ifndef([PKG_PROG_PKG_CONFIG],
 161     [m4_fatal([Could not locate the pkg-config autoconf macros.
 162   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 163   are in a different location, try setting the environment variable
 164   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 165 PKG_PROG_PKG_CONFIG()
 166
 167 dnl LIB_DIR - library basename
 168 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 169 AC_SUBST([LIB_DIR])
 170
 171 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 172 _SAVE_LDFLAGS="$LDFLAGS"
 173 _SAVE_CPPFLAGS="$CPPFLAGS"
 174
 175 dnl Compiler macros
 176 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 177 AC_SUBST([DEFINES])
 178 case "$host_os" in
 179 linux*|*-gnu*|gnu*)
 180     DEFINES="$DEFINES -D_GNU_SOURCE"
 181     ;;
 182 solaris*)
 183     DEFINES="$DEFINES -DSVR4"
 184     ;;
 185 cygwin*)
 186     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 187     ;;
 188 esac
 189
 190 dnl Add flags for gcc and g++
 191 if test "x$GCC" = xyes; then
 192     CFLAGS="$CFLAGS -Wall -std=c99"
 193
 194     # Enable -Werror=implicit-function-declaration and
 195     # -Werror=missing-prototypes, if available, or otherwise, just
 196     # -Wmissing-prototypes.  This is particularly useful to avoid
 197     # generating a loadable driver module that has undefined symbols.
 198     save_CFLAGS="$CFLAGS"
 199     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 200     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 201     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 202     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 203                    AC_MSG_RESULT([yes]),
 204                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 205                     AC_MSG_RESULT([no])]);
 206
 207     # Enable -fvisibility=hidden if using a gcc that supports it
 208     save_CFLAGS="$CFLAGS"
 209     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 210     VISIBILITY_CFLAGS="-fvisibility=hidden"
 211     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 214
 215     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 216     CFLAGS=$save_CFLAGS
 217
 218     # Work around aliasing bugs - developers should comment this out
 219     CFLAGS="$CFLAGS -fno-strict-aliasing"
 220
 221     # gcc's builtin memcmp is slower than glibc's
 222     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 223     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 224 fi
 225 if test "x$GXX" = xyes; then
 226     CXXFLAGS="$CXXFLAGS -Wall"
 227
 228     # Enable -fvisibility=hidden if using a gcc that supports it
 229     save_CXXFLAGS="$CXXFLAGS"
 230     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 231     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 232     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 233     AC_LANG_PUSH([C++])
 234     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 235                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 236     AC_LANG_POP([C++])
 237
 238     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 239     CXXFLAGS=$save_CXXFLAGS
 240
 241     # Work around aliasing bugs - developers should comment this out
 242     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 243
 244     # gcc's builtin memcmp is slower than glibc's
 245     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 246     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 247 fi
 248
 249 dnl even if the compiler appears to support it, using visibility attributes isn't
 250 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 251 case "$host_os" in
 252 cygwin*)
 253     VISIBILITY_CFLAGS=""
 254     VISIBILITY_CXXFLAGS=""
 255     ;;
 256 esac
 257
 258 AC_SUBST([VISIBILITY_CFLAGS])
 259 AC_SUBST([VISIBILITY_CXXFLAGS])
 260
 261 dnl
 262 dnl Optional flags, check for compiler support
 263 dnl
 264 SSE41_CFLAGS="-msse4.1"
 265 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 266 dnl stack, but on x86-32 such alignment is not guaranteed.
 267 case "$target_cpu" in
 268 i?86)
 269     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 270     ;;
 271 esac
 272 save_CFLAGS="$CFLAGS"
 273 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 274 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 275 #include <smmintrin.h>
 276 int main () {
 277     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 278     c = _mm_max_epu32(a, b);
 279     return 0;
 280 }]])], SSE41_SUPPORTED=1)
 281 CFLAGS="$save_CFLAGS"
 282 if test "x$SSE41_SUPPORTED" = x1; then
 283     DEFINES="$DEFINES -DUSE_SSE41"
 284 fi
 285 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 286 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 287
 288 dnl Can't have static and shared libraries, default to static if user
 289 dnl explicitly requested. If both disabled, set to static since shared
 290 dnl was explicitly requested.
 291 case "x$enable_static$enable_shared" in
 292 xyesyes)
 293     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 294     enable_shared=no
 295     ;;
 296 xnono)
 297     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 298     enable_shared=yes
 299     ;;
 300 esac
 301
 302 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 303
 304 dnl
 305 dnl other compiler options
 306 dnl
 307 AC_ARG_ENABLE([debug],
 308     [AS_HELP_STRING([--enable-debug],
 309         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 310     [enable_debug="$enableval"],
 311     [enable_debug=no]
 312 )
 313 if test "x$enable_debug" = xyes; then
 314     DEFINES="$DEFINES -DDEBUG"
 315     if test "x$GCC" = xyes; then
 316         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 317             CFLAGS="$CFLAGS -g"
 318         fi
 319         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 320             CFLAGS="$CFLAGS -O0"
 321         fi
 322     fi
 323     if test "x$GXX" = xyes; then
 324         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 325             CXXFLAGS="$CXXFLAGS -g"
 326         fi
 327         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 328             CXXFLAGS="$CXXFLAGS -O0"
 329         fi
 330     fi
 331 fi
 332
 333 dnl
 334 dnl Check if linker supports -Bsymbolic
 335 dnl
 336 save_LDFLAGS=$LDFLAGS
 337 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 338 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 339 AC_LINK_IFELSE(
 340     [AC_LANG_SOURCE([int main() { return 0;}])],
 341     [AC_MSG_RESULT([yes])
 342         BSYMBOLIC="-Wl,-Bsymbolic";],
 343     [AC_MSG_RESULT([no])
 344         BSYMBOLIC="";])
 345 LDFLAGS=$save_LDFLAGS
 346
 347 AC_SUBST([BSYMBOLIC])
 348
 349 dnl
 350 dnl Check if linker supports garbage collection
 351 dnl
 352 save_LDFLAGS=$LDFLAGS
 353 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 354 AC_MSG_CHECKING([whether ld supports --gc-sections])
 355 AC_LINK_IFELSE(
 356     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 357     [AC_MSG_RESULT([yes])
 358         GC_SECTIONS="-Wl,--gc-sections";],
 359     [AC_MSG_RESULT([no])
 360         GC_SECTIONS="";])
 361 LDFLAGS=$save_LDFLAGS
 362
 363 AC_SUBST([GC_SECTIONS])
 364
 365 dnl
 366 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 367 dnl so when these flags are passed to ld via libtool the checks will fail
 368 dnl
 369 case "$host_os" in
 370 openbsd* | darwin* )
 371     LD_NO_UNDEFINED="" ;;
 372 *)
 373     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 374 esac
 375
 376 AC_SUBST([LD_NO_UNDEFINED])
 377
 378 dnl
 379 dnl Check if linker supports version scripts
 380 dnl
 381 AC_MSG_CHECKING([if the linker supports version-scripts])
 382 save_LDFLAGS=$LDFLAGS
 383 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 384 cat > conftest.map <<EOF
 385 VERSION_1 {
 386      global:
 387          main;
 388
 389      local:
 390          *;
 391 };
 392 EOF
 393 AC_LINK_IFELSE(
 394     [AC_LANG_SOURCE([int main() { return 0;}])],
 395     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 396     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 397 LDFLAGS=$save_LDFLAGS
 398 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 399
 400 dnl
 401 dnl Check if linker supports dynamic list files
 402 dnl
 403 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 404 save_LDFLAGS=$LDFLAGS
 405 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 406 cat > conftest.dyn <<EOF
 407 {
 408         radeon_drm_winsys_create;
 409 };
 410 EOF
 411 AC_LINK_IFELSE(
 412     [AC_LANG_SOURCE([int main() { return 0;}])],
 413     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 414     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 415 LDFLAGS=$save_LDFLAGS
 416 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 417
 418 dnl
 419 dnl compatibility symlinks
 420 dnl
 421 case "$host_os" in
 422 linux* )
 423     HAVE_COMPAT_SYMLINKS=yes ;;
 424 * )
 425     HAVE_COMPAT_SYMLINKS=no ;;
 426 esac
 427
 428 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 429
 430 dnl
 431 dnl library names
 432 dnl
 433 case "$host_os" in
 434 darwin* )
 435     LIB_EXT='dylib' ;;
 436 cygwin* )
 437     LIB_EXT='dll' ;;
 438 aix* )
 439     LIB_EXT='a' ;;
 440 * )
 441     LIB_EXT='so' ;;
 442 esac
 443
 444 AC_SUBST([LIB_EXT])
 445
 446 AC_ARG_WITH([gl-lib-name],
 447   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 448     [specify GL library name @<:@default=GL@:>@])],
 449   [GL_LIB=$withval],
 450   [GL_LIB=GL])
 451 AC_ARG_WITH([osmesa-lib-name],
 452   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 453     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 454   [OSMESA_LIB=$withval],
 455   [OSMESA_LIB=OSMesa])
 456 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 457 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 458
 459 dnl
 460 dnl Mangled Mesa support
 461 dnl
 462 AC_ARG_ENABLE([mangling],
 463   [AS_HELP_STRING([--enable-mangling],
 464     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 465   [enable_mangling="${enableval}"],
 466   [enable_mangling=no]
 467 )
 468 if test "x${enable_mangling}" = "xyes" ; then
 469   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 470   GL_LIB="Mangled${GL_LIB}"
 471   OSMESA_LIB="Mangled${OSMESA_LIB}"
 472 fi
 473 AC_SUBST([GL_LIB])
 474 AC_SUBST([OSMESA_LIB])
 475
 476 dnl
 477 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 478 dnl
 479 AC_ARG_ENABLE([texture-float],
 480     [AS_HELP_STRING([--enable-texture-float],
 481         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 482     [enable_texture_float="$enableval"],
 483     [enable_texture_float=no]
 484 )
 485 if test "x$enable_texture_float" = xyes; then
 486     AC_MSG_WARN([Floating-point textures enabled.])
 487     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 488     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 489 fi
 490
 491 dnl
 492 dnl Arch/platform-specific settings
 493 dnl
 494 AC_ARG_ENABLE([asm],
 495     [AS_HELP_STRING([--disable-asm],
 496         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 497     [enable_asm="$enableval"],
 498     [enable_asm=yes]
 499 )
 500 asm_arch=""
 501 AC_MSG_CHECKING([whether to enable assembly])
 502 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 503 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 504 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 505     case "$host_cpu" in
 506     i?86 | x86_64 | amd64)
 507         enable_asm=no
 508         AC_MSG_RESULT([no, cross compiling])
 509         ;;
 510     esac
 511 fi
 512 # check for supported arches
 513 if test "x$enable_asm" = xyes; then
 514     case "$host_cpu" in
 515     i?86)
 516         case "$host_os" in
 517         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 518             asm_arch=x86
 519             ;;
 520         esac
 521         ;;
 522     x86_64|amd64)
 523         case "$host_os" in
 524         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 525             asm_arch=x86_64
 526             ;;
 527         esac
 528         ;;
 529     sparc*)
 530         case "$host_os" in
 531         linux*)
 532             asm_arch=sparc
 533             ;;
 534         esac
 535         ;;
 536     esac
 537
 538     case "$asm_arch" in
 539     x86)
 540         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 541         AC_MSG_RESULT([yes, x86])
 542         ;;
 543     x86_64|amd64)
 544         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 545         AC_MSG_RESULT([yes, x86_64])
 546         ;;
 547     sparc)
 548         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 549         AC_MSG_RESULT([yes, sparc])
 550         ;;
 551     *)
 552         AC_MSG_RESULT([no, platform not supported])
 553         ;;
 554     esac
 555 fi
 556
 557 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 558 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 559
 560 dnl Check to see if dlopen is in default libraries (like Solaris, which
 561 dnl has it in libc), or if libdl is needed to get it.
 562 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 563     [AC_CHECK_LIB([dl], [dlopen],
 564        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 565 AC_SUBST([DLOPEN_LIBS])
 566
 567 dnl Check if that library also has dladdr
 568 save_LIBS="$LIBS"
 569 LIBS="$LIBS $DLOPEN_LIBS"
 570 AC_CHECK_FUNCS([dladdr])
 571 LIBS="$save_LIBS"
 572
 573 case "$host_os" in
 574 darwin*|mingw*)
 575     ;;
 576 *)
 577     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 578                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 579                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 580     AC_SUBST([CLOCK_LIB])
 581     ;;
 582 esac
 583
 584 dnl See if posix_memalign is available
 585 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 586
 587 dnl Check for pthreads
 588 case "$host_os" in
 589 mingw*)
 590     ;;
 591 *)
 592     AX_PTHREAD
 593     ;;
 594 esac
 595 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 596 dnl to -pthread, which causes problems if we need -lpthread to appear in
 597 dnl pkgconfig files.
 598 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 599
 600 dnl SELinux awareness.
 601 AC_ARG_ENABLE([selinux],
 602     [AS_HELP_STRING([--enable-selinux],
 603         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 604     [MESA_SELINUX="$enableval"],
 605     [MESA_SELINUX=no])
 606 if test "x$enable_selinux" = "xyes"; then
 607     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 608         [AC_CHECK_HEADER([selinux/selinux.h],[],
 609                          [AC_MSG_ERROR([SELinux headers not found])])
 610          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 611                       [AC_MSG_ERROR([SELinux library not found])])
 612          SELINUX_LIBS="-lselinux"])
 613     DEFINES="$DEFINES -DMESA_SELINUX"
 614 fi
 615 AC_SUBST([SELINUX_CFLAGS])
 616 AC_SUBST([SELINUX_LIBS])
 617
 618 dnl Options for APIs
 619 AC_ARG_ENABLE([opengl],
 620     [AS_HELP_STRING([--disable-opengl],
 621         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 622     [enable_opengl="$enableval"],
 623     [enable_opengl=yes])
 624 AC_ARG_ENABLE([gles1],
 625     [AS_HELP_STRING([--enable-gles1],
 626         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 627     [enable_gles1="$enableval"],
 628     [enable_gles1=no])
 629 AC_ARG_ENABLE([gles2],
 630     [AS_HELP_STRING([--enable-gles2],
 631         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 632     [enable_gles2="$enableval"],
 633     [enable_gles2=no])
 634 AC_ARG_ENABLE([openvg],
 635     [AS_HELP_STRING([--enable-openvg],
 636         [enable support for OpenVG API @<:@default=disabled@:>@])],
 637     [enable_openvg="$enableval"],
 638     [enable_openvg=no])
 639
 640 AC_ARG_ENABLE([dri],
 641     [AS_HELP_STRING([--enable-dri],
 642         [enable DRI modules @<:@default=enabled@:>@])],
 643     [enable_dri="$enableval"],
 644     [enable_dri=yes])
 645
 646 case "$host_os" in
 647 linux*)
 648     dri3_default=yes
 649     ;;
 650 *)
 651     dri3_default=no
 652     ;;
 653 esac
 654 AC_ARG_ENABLE([dri3],
 655     [AS_HELP_STRING([--enable-dri3],
 656         [enable DRI3 @<:@default=auto@:>@])],
 657     [enable_dri3="$enableval"],
 658     [enable_dri3="$dri3_default"])
 659 AC_ARG_ENABLE([glx],
 660     [AS_HELP_STRING([--enable-glx],
 661         [enable GLX library @<:@default=enabled@:>@])],
 662     [enable_glx="$enableval"],
 663     [enable_glx=yes])
 664 AC_ARG_ENABLE([osmesa],
 665     [AS_HELP_STRING([--enable-osmesa],
 666         [enable OSMesa library @<:@default=disabled@:>@])],
 667     [enable_osmesa="$enableval"],
 668     [enable_osmesa=no])
 669 AC_ARG_ENABLE([gallium-osmesa],
 670     [AS_HELP_STRING([--enable-gallium-osmesa],
 671         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 672     [enable_gallium_osmesa="$enableval"],
 673     [enable_gallium_osmesa=no])
 674 AC_ARG_ENABLE([egl],
 675     [AS_HELP_STRING([--disable-egl],
 676         [disable EGL library @<:@default=enabled@:>@])],
 677     [enable_egl="$enableval"],
 678     [enable_egl=yes])
 679
 680 AC_ARG_ENABLE([xa],
 681     [AS_HELP_STRING([--enable-xa],
 682         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 683     [enable_xa="$enableval"],
 684     [enable_xa=no])
 685 AC_ARG_ENABLE([gbm],
 686    [AS_HELP_STRING([--enable-gbm],
 687          [enable gbm library @<:@default=auto@:>@])],
 688    [enable_gbm="$enableval"],
 689    [enable_gbm=auto])
 690 AC_ARG_ENABLE([nine],
 691     [AS_HELP_STRING([--enable-nine],
 692         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 693     [enable_nine="$enableval"],
 694     [enable_nine=no])
 695
 696 AC_ARG_ENABLE([xvmc],
 697    [AS_HELP_STRING([--enable-xvmc],
 698          [enable xvmc library @<:@default=auto@:>@])],
 699    [enable_xvmc="$enableval"],
 700    [enable_xvmc=auto])
 701 AC_ARG_ENABLE([vdpau],
 702    [AS_HELP_STRING([--enable-vdpau],
 703          [enable vdpau library @<:@default=auto@:>@])],
 704    [enable_vdpau="$enableval"],
 705    [enable_vdpau=auto])
 706 AC_ARG_ENABLE([omx],
 707    [AS_HELP_STRING([--enable-omx],
 708          [enable OpenMAX library @<:@default=disabled@:>@])],
 709    [enable_omx="$enableval"],
 710    [enable_omx=no])
 711 AC_ARG_ENABLE([va],
 712    [AS_HELP_STRING([--enable-va],
 713          [enable va library @<:@default=auto@:>@])],
 714    [enable_va="$enableval"],
 715    [enable_va=auto])
 716 AC_ARG_ENABLE([opencl],
 717    [AS_HELP_STRING([--enable-opencl],
 718          [enable OpenCL library @<:@default=disabled@:>@])],
 719    [enable_opencl="$enableval"],
 720    [enable_opencl=no])
 721 AC_ARG_ENABLE([opencl_icd],
 722    [AS_HELP_STRING([--enable-opencl-icd],
 723           [Build an OpenCL ICD library to be loaded by an ICD implementation
 724            @<:@default=disabled@:>@])],
 725     [enable_opencl_icd="$enableval"],
 726     [enable_opencl_icd=no])
 727 AC_ARG_ENABLE([xlib-glx],
 728     [AS_HELP_STRING([--enable-xlib-glx],
 729         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 730     [enable_xlib_glx="$enableval"],
 731     [enable_xlib_glx=no])
 732
 733 AC_ARG_ENABLE([r600-llvm-compiler],
 734     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 735         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 736     [enable_r600_llvm="$enableval"],
 737     [enable_r600_llvm=no])
 738
 739 AC_ARG_ENABLE([gallium-tests],
 740     [AS_HELP_STRING([--enable-gallium-tests],
 741         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 742     [enable_gallium_tests="$enableval"],
 743     [enable_gallium_tests=no])
 744
 745 # Option for Gallium drivers
 746
 747 # Keep this in sync with the --with-gallium-drivers help string default value
 748 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 749
 750 AC_ARG_WITH([gallium-drivers],
 751     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 752         [comma delimited Gallium drivers list, e.g.
 753         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 754         @<:@default=r300,r600,svga,swrast@:>@])],
 755     [with_gallium_drivers="$withval"],
 756     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 757
 758 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 759 # here so that the script doesn't choke on an unknown driver name later.
 760 case "$with_gallium_drivers" in
 761     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 762     no) with_gallium_drivers='' ;;
 763 esac
 764
 765 if test "x$enable_opengl" = xno -a \
 766         "x$enable_gles1" = xno -a \
 767         "x$enable_gles2" = xno -a \
 768         "x$enable_nine" = xno -a \
 769         "x$enable_openvg" = xno -a \
 770         "x$enable_xa" = xno -a \
 771         "x$enable_xvmc" = xno -a \
 772         "x$enable_vdpau" = xno -a \
 773         "x$enable_omx" = xno -a \
 774         "x$enable_va" = xno -a \
 775         "x$enable_opencl" = xno; then
 776     AC_MSG_ERROR([at least one API should be enabled])
 777 fi
 778
 779 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 780 if test "x$enable_opengl" = xno -a \
 781         "x$enable_gles1" = xyes; then
 782     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 783 fi
 784
 785 if test "x$enable_opengl" = xno -a \
 786         "x$enable_gles2" = xyes; then
 787     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 788 fi
 789
 790 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 791 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 792 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 793 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 794                                         "x$enable_gles1" = xyes -o \
 795                                         "x$enable_gles2" = xyes)
 796
 797 if test "x$enable_glx" = xno; then
 798     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 799     enable_xlib_glx=no
 800 fi
 801
 802 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 803     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 804 fi
 805
 806 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 807     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 808 fi
 809
 810 # Disable GLX if OpenGL is not enabled
 811 if test "x$enable_glx$enable_opengl" = xyesno; then
 812     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 813     enable_glx=no
 814 fi
 815
 816 # Disable GLX if DRI and Xlib-GLX are not enabled
 817 if test "x$enable_glx" = xyes -a \
 818         "x$enable_dri" = xno -a \
 819         "x$enable_xlib_glx" = xno; then
 820     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 821     enable_glx=no
 822 fi
 823
 824 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 825                                   "x$enable_dri" = xyes)
 826
 827 # Select which platform-dependent DRI code gets built
 828 case "$host_os" in
 829 darwin*)
 830     dri_platform='apple' ;;
 831 gnu*|mingw*|cygwin*)
 832     dri_platform='none' ;;
 833 *)
 834     dri_platform='drm' ;;
 835 esac
 836
 837 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 838 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 839 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 840 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 841 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 842
 843 AC_ARG_ENABLE([shared-glapi],
 844     [AS_HELP_STRING([--enable-shared-glapi],
 845         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 846     [enable_shared_glapi="$enableval"],
 847     [enable_shared_glapi=yes])
 848
 849 case "x$enable_opengl$enable_gles1$enable_gles2" in
 850 x*yes*yes*)
 851     if test "x$enable_shared_glapi" = xno; then
 852         AC_MSG_ERROR([shared GLAPI required when building two or more of
 853                       the following APIs - opengl, gles1 gles2])
 854     fi
 855     ;;
 856 esac
 857
 858 # Building Xlib-GLX requires shared glapi to be disabled.
 859 if test "x$enable_xlib_glx" = xyes; then
 860     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 861     enable_shared_glapi=no
 862 fi
 863
 864 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 865
 866 # Build the pipe-drivers as separate libraries/modules.
 867 # Do not touch this unless you know what you are doing.
 868 # XXX: Expose via configure option ?
 869 enable_shared_pipe_drivers=no
 870
 871 dnl
 872 dnl Driver specific build directories
 873 dnl
 874
 875 case "x$enable_glx$enable_xlib_glx" in
 876 xyesyes)
 877     NEED_WINSYS_XLIB="yes"
 878     ;;
 879 esac
 880
 881 if test "x$enable_dri" = xyes; then
 882     enable_gallium_loader="$enable_shared_pipe_drivers"
 883 fi
 884
 885 if test "x$enable_gallium_osmesa" = xyes; then
 886     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 887         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 888     fi
 889     if test "x$enable_osmesa" = xyes; then
 890         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 891     fi
 892 fi
 893
 894 AC_SUBST([MESA_LLVM])
 895
 896 # Check for libdrm
 897 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 898                   [have_libdrm=yes], [have_libdrm=no])
 899 if test "x$have_libdrm" = xyes; then
 900         DEFINES="$DEFINES -DHAVE_LIBDRM"
 901 fi
 902
 903 case "$host_os" in
 904 linux*)
 905     need_pci_id=yes ;;
 906 *)
 907     need_pci_id=no ;;
 908 esac
 909
 910 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 911                   have_libudev=yes, have_libudev=no)
 912
 913 AC_ARG_ENABLE([sysfs],
 914     [AS_HELP_STRING([--enable-sysfs],
 915         [enable /sys PCI identification @<:@default=disabled@:>@])],
 916     [have_sysfs="$enableval"],
 917     [have_sysfs=no]
 918 )
 919
 920 if test "x$enable_dri" = xyes; then
 921     if test "$enable_static" = yes; then
 922         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 923     fi
 924
 925     # not a hard requirement as swrast does not depend on it
 926     if test "x$have_libdrm" = xyes; then
 927         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 928     fi
 929 fi
 930
 931 AC_ARG_ENABLE([driglx-direct],
 932     [AS_HELP_STRING([--disable-driglx-direct],
 933         [disable direct rendering in GLX and EGL for DRI \
 934             @<:@default=auto@:>@])],
 935     [driglx_direct="$enableval"],
 936     [driglx_direct="yes"])
 937
 938 dnl
 939 dnl libGL configuration per driver
 940 dnl
 941 case "x$enable_glx$enable_xlib_glx" in
 942 xyesyes)
 943     # Xlib-based GLX
 944     dri_modules="x11 xext xcb"
 945     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 946     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 947     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 948     GL_LIB_DEPS="$XLIBGL_LIBS"
 949     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 950     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 951     ;;
 952 xyesno)
 953     # DRI-based GLX
 954     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 955
 956     # find the DRI deps for libGL
 957     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 958
 959     if test x"$driglx_direct" = xyes; then
 960         if test x"$dri_platform" = xdrm ; then
 961             DEFINES="$DEFINES -DGLX_USE_DRM"
 962             if test "x$have_libdrm" != xyes; then
 963                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 964             fi
 965
 966             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 967             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 968             if test x"$enable_dri3" = xyes; then
 969                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 970                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 971             fi
 972
 973             if test x"$enable_dri" = xyes; then
 974                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 975             fi
 976
 977             if test x"$enable_dri3" = xyes; then
 978                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 979                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 980             fi
 981         fi
 982         if test x"$dri_platform" = xapple ; then
 983             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 984         fi
 985     fi
 986
 987     # add xf86vidmode if available
 988     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 989     if test "$HAVE_XF86VIDMODE" = yes ; then
 990         dri_modules="$dri_modules xxf86vm"
 991     fi
 992
 993     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 994     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 995     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 996     GL_LIB_DEPS="$DRIGL_LIBS"
 997
 998     # need DRM libs, $PTHREAD_LIBS, etc.
 999     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1000     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1001     ;;
1002 esac
1003
1004 have_pci_id=no
1005 if test "$have_libudev" = yes; then
1006     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1007     have_pci_id=yes
1008 fi
1009
1010 if test "$have_sysfs" = yes; then
1011     DEFINES="$DEFINES -DHAVE_SYSFS"
1012     have_pci_id=yes
1013 fi
1014
1015 # This is outside the case (above) so that it is invoked even for non-GLX
1016 # builds.
1017 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1018
1019 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1020 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1021 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1022 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1023
1024 AC_SUBST([X11_INCLUDES])
1025 AC_SUBST([GL_LIB_DEPS])
1026 AC_SUBST([GL_PC_REQ_PRIV])
1027 AC_SUBST([GL_PC_LIB_PRIV])
1028 AC_SUBST([GL_PC_CFLAGS])
1029 AC_SUBST([DRI_PC_REQ_PRIV])
1030 AC_SUBST([GLESv1_CM_LIB_DEPS])
1031 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1032 AC_SUBST([GLESv2_LIB_DEPS])
1033 AC_SUBST([GLESv2_PC_LIB_PRIV])
1034
1035 AC_SUBST([HAVE_XF86VIDMODE])
1036
1037 dnl
1038 dnl More GLX setup
1039 dnl
1040 case "x$enable_glx$enable_xlib_glx" in
1041 xyesyes)
1042     DEFINES="$DEFINES -DUSE_XSHM"
1043     ;;
1044 xyesno)
1045     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1046     if test "x$driglx_direct" = xyes; then
1047         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1048     fi
1049     ;;
1050 esac
1051
1052 dnl
1053 dnl TLS detection
1054 dnl
1055
1056 AC_ARG_ENABLE([glx-tls],
1057     [AS_HELP_STRING([--enable-glx-tls],
1058         [enable TLS support in GLX @<:@default=disabled@:>@])],
1059     [GLX_USE_TLS="$enableval"],
1060     [GLX_USE_TLS=no])
1061 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1062
1063 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1064       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1065
1066 dnl
1067 dnl More DRI setup
1068 dnl
1069 dnl Directory for DRI drivers
1070 AC_ARG_WITH([dri-driverdir],
1071     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1072         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1073     [DRI_DRIVER_INSTALL_DIR="$withval"],
1074     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1075 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1076 dnl Extra search path for DRI drivers
1077 AC_ARG_WITH([dri-searchpath],
1078     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1079         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1080     [DRI_DRIVER_SEARCH_DIR="$withval"],
1081     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1082 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1083 dnl Which drivers to build - default is chosen by platform
1084 AC_ARG_WITH([dri-drivers],
1085     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1086         [comma delimited classic DRI drivers list, e.g.
1087         "swrast,i965,radeon" @<:@default=auto@:>@])],
1088     [with_dri_drivers="$withval"],
1089     [with_dri_drivers=auto])
1090
1091 if test "x$with_dri_drivers" = xauto; then
1092     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1093         with_dri_drivers="yes"
1094     else
1095         with_dri_drivers="no"
1096     fi
1097 fi
1098 if test "x$with_dri_drivers" = xno; then
1099     with_dri_drivers=''
1100 fi
1101
1102 dnl If $with_dri_drivers is yes, drivers will be added through
1103 dnl platform checks. Set DEFINES and LIB_DEPS
1104 if test "x$enable_dri" = xyes; then
1105     # Platform specific settings and drivers to build
1106     case "$host_os" in
1107     linux*)
1108         DEFINES="$DEFINES -DHAVE_ALIAS"
1109         if test "x$enable_dri3" = xyes; then
1110             DEFINES="$DEFINES -DHAVE_DRI3"
1111         fi
1112
1113         if test "x$have_pci_id" != xyes; then
1114             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1115         fi
1116
1117         case "$host_cpu" in
1118         powerpc* | sparc*)
1119             # Build only the drivers for cards that exist on PowerPC/sparc
1120             if test "x$with_dri_drivers" = "xyes"; then
1121                 with_dri_drivers="r200 radeon swrast"
1122             fi
1123             ;;
1124         esac
1125         ;;
1126     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1127         DEFINES="$DEFINES -DHAVE_ALIAS"
1128         ;;
1129     gnu*)
1130         DEFINES="$DEFINES -DHAVE_ALIAS"
1131         ;;
1132     cygwin*)
1133         if test "x$with_dri_drivers" = "xyes"; then
1134             with_dri_drivers="swrast"
1135         fi
1136         ;;
1137     darwin*)
1138         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1139         if test "x$with_dri_drivers" = "xyes"; then
1140             with_dri_drivers="swrast"
1141         fi
1142         ;;
1143     esac
1144
1145     # default drivers
1146     if test "x$with_dri_drivers" = "xyes"; then
1147         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1148     fi
1149
1150     # Check for expat
1151     PKG_CHECK_MODULES([EXPAT], [expat], [],
1152         # expat version 2.0 and earlier do not provide expat.pc
1153         [AC_CHECK_HEADER([expat.h],[],
1154                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1155          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1156                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1157          EXPAT_LIBS="-lexpat"])
1158
1159     DRICOMMON_NEED_LIBDRM=no
1160     # If we are building any DRI driver other than swrast.
1161     if test -n "$with_dri_drivers"; then
1162         if test "x$with_dri_drivers" != xswrast; then
1163             # ... libdrm is required
1164             if test "x$have_libdrm" != xyes; then
1165                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1166             fi
1167             DRICOMMON_NEED_LIBDRM=yes
1168         fi
1169     fi
1170
1171     # If we're building any gallium DRI driver other than swrast
1172     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1173         if test "x$with_gallium_drivers" != xswrast; then
1174             # ... build a libdrm aware dricommon
1175             DRICOMMON_NEED_LIBDRM=yes
1176         fi
1177     fi
1178
1179     # put all the necessary libs together
1180     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1181 fi
1182
1183 AC_SUBST([DRI_LIB_DEPS])
1184
1185 DRI_DIRS=''
1186 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1187 if test -n "$with_dri_drivers"; then
1188     if test "x$enable_opengl" != xyes; then
1189         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1190     fi
1191
1192     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1193     for driver in $dri_drivers; do
1194         DRI_DIRS="$DRI_DIRS $driver"
1195         case "x$driver" in
1196         xi915)
1197             HAVE_I915_DRI=yes;
1198             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1199             ;;
1200         xi965)
1201             HAVE_I965_DRI=yes;
1202             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1203             ;;
1204         xnouveau)
1205             HAVE_NOUVEAU_DRI=yes;
1206             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1207             ;;
1208         xradeon)
1209             HAVE_RADEON_DRI=yes;
1210             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1211             ;;
1212         xr200)
1213             HAVE_R200_DRI=yes;
1214             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1215             ;;
1216         xswrast)
1217             HAVE_SWRAST_DRI=yes;
1218             ;;
1219         *)
1220             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1221             ;;
1222         esac
1223     done
1224     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1225 fi
1226
1227 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1228 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1229                                   "x$enable_osmesa" = xyes -o \
1230                                   -n "$DRI_DIRS")
1231
1232 dnl
1233 dnl OSMesa configuration
1234 dnl
1235
1236 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1237 AC_ARG_WITH([osmesa-bits],
1238     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1239         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1240     [osmesa_bits="$withval"],
1241     [osmesa_bits=8])
1242 if test "x$osmesa_bits" != x8; then
1243     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1244         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1245         osmesa_bits=8
1246     fi
1247 fi
1248 case "x$osmesa_bits" in
1249 x8)
1250     OSMESA_LIB="${OSMESA_LIB}"
1251     ;;
1252 x16|x32)
1253     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1254     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1255     ;;
1256 *)
1257     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1258     ;;
1259 esac
1260
1261 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1262     # only link libraries with osmesa if shared
1263     if test "$enable_static" = no; then
1264         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1265     else
1266         OSMESA_LIB_DEPS=""
1267     fi
1268     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1269 fi
1270
1271 AC_SUBST([OSMESA_LIB_DEPS])
1272 AC_SUBST([OSMESA_PC_REQ])
1273 AC_SUBST([OSMESA_PC_LIB_PRIV])
1274
1275 dnl
1276 dnl gbm configuration
1277 dnl
1278 if test "x$enable_gbm" = xauto; then
1279     case "$with_egl_platforms" in
1280         *drm*)
1281             enable_gbm=yes ;;
1282          *)
1283             enable_gbm=no ;;
1284     esac
1285 fi
1286 if test "x$enable_gbm" = xyes; then
1287     if test "x$need_pci_id$have_pci_id" = xyesno; then
1288         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1289     fi
1290
1291     if test "x$enable_dri" = xyes; then
1292         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1293         if test "x$enable_shared_glapi" = xno; then
1294             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1295         fi
1296     else
1297         # Strictly speaking libgbm does not require --enable-dri, although
1298         # both of its backends do. Thus one can build libgbm without any
1299         # backends if --disable-dri is set.
1300         # To avoid unnecessary complexity of checking if at least one backend
1301         # is available when building, just mandate --enable-dri.
1302         AC_MSG_ERROR([gbm requires --enable-dri])
1303     fi
1304 fi
1305 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1306 if test "x$need_pci_id$have_libudev" = xyesyes; then
1307     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1308 else
1309     GBM_PC_REQ_PRIV=""
1310 fi
1311 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1312 AC_SUBST([GBM_PC_REQ_PRIV])
1313 AC_SUBST([GBM_PC_LIB_PRIV])
1314
1315 dnl
1316 dnl EGL configuration
1317 dnl
1318 EGL_CLIENT_APIS=""
1319
1320 if test "x$enable_egl" = xyes; then
1321     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1322
1323     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1324
1325     if test "$enable_static" != yes; then
1326         if test "x$enable_dri" = xyes; then
1327             HAVE_EGL_DRIVER_DRI2=1
1328         fi
1329
1330     fi
1331 fi
1332 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1333 AC_SUBST([EGL_LIB_DEPS])
1334
1335 dnl
1336 dnl XA configuration
1337 dnl
1338 if test "x$enable_xa" = xyes; then
1339     if test "x$with_gallium_drivers" = xswrast; then
1340        AC_MSG_ERROR([
1341           Building xa requires at least one non swrast gallium driver.
1342           If you are looking to use libxatracker.so with the VMware driver,
1343           make sure to include svga in the gallium drivers list, apart from
1344           enabling XA.
1345           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1346     fi
1347     enable_gallium_loader=$enable_shared_pipe_drivers
1348 fi
1349 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1350
1351 dnl
1352 dnl OpenVG configuration
1353 dnl
1354 VG_LIB_DEPS=""
1355
1356 if test "x$enable_openvg" = xyes; then
1357     if test "x$enable_egl" = xno; then
1358         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1359     fi
1360     if test -z "$with_gallium_drivers"; then
1361         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1362     fi
1363
1364     AC_MSG_ERROR([Cannot enable OpenVG, because egl_gallium has been removed and
1365                   OpenVG has not been integrated into standard libEGL yet])
1366
1367     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1368     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1369     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1370     AC_SUBST([VG_PC_LIB_PRIV])
1371 fi
1372 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1373
1374 dnl
1375 dnl Gallium G3DVL configuration
1376 dnl
1377 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1378     if test "x$enable_xvmc" = xauto; then
1379         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1380     fi
1381
1382     if test "x$enable_vdpau" = xauto; then
1383         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1384     fi
1385
1386     if test "x$enable_omx" = xauto; then
1387         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1388     fi
1389
1390     if test "x$enable_va" = xauto; then
1391         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1392     fi
1393 fi
1394
1395 if test "x$enable_xvmc" = xyes -o \
1396         "x$enable_vdpau" = xyes -o \
1397         "x$enable_omx" = xyes -o \
1398         "x$enable_va" = xyes; then
1399     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1400     need_gallium_vl=yes
1401 fi
1402 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1403
1404 if test "x$enable_xvmc" = xyes; then
1405     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1406     enable_gallium_loader=$enable_shared_pipe_drivers
1407 fi
1408 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1409
1410 if test "x$enable_vdpau" = xyes; then
1411     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1412     enable_gallium_loader=$enable_shared_pipe_drivers
1413 fi
1414 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1415
1416 if test "x$enable_omx" = xyes; then
1417     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1418     enable_gallium_loader=$enable_shared_pipe_drivers
1419 fi
1420 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1421
1422 if test "x$enable_va" = xyes; then
1423     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1424     enable_gallium_loader=$enable_shared_pipe_drivers
1425 fi
1426 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1427
1428 dnl
1429 dnl Nine Direct3D9 configuration
1430 dnl
1431 if test "x$enable_nine" = xyes; then
1432     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1433         AC_MSG_ERROR([nine requires the gallium swrast driver])
1434     fi
1435     if test "x$with_gallium_drivers" == xswrast; then
1436         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1437     fi
1438     if test "x$enable_dri3" = xno; then
1439         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1440     fi
1441
1442     enable_gallium_loader=$enable_shared_pipe_drivers
1443 fi
1444 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1445
1446 dnl
1447 dnl OpenCL configuration
1448 dnl
1449
1450 AC_ARG_WITH([libclc-path],
1451    [AS_HELP_STRING([--with-libclc-path],
1452          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1453    [LIBCLC_PATH="$withval"],
1454    [LIBCLC_PATH=''])
1455
1456 if test -n "$LIBCLC_PATH"; then
1457    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1458                   Please review the updated build instructions for clover:
1459                   http://dri.freedesktop.org/wiki/GalliumCompute])
1460 fi
1461
1462
1463 AC_ARG_WITH([clang-libdir],
1464    [AS_HELP_STRING([--with-clang-libdir],
1465          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1466    [CLANG_LIBDIR="$withval"],
1467    [CLANG_LIBDIR=''])
1468
1469 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1470 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1471
1472 if test "x$enable_opencl" = xyes; then
1473     if test -z "$with_gallium_drivers"; then
1474         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1475     fi
1476
1477     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1478         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1479     fi
1480
1481     if test "x$have_libclc" = xno; then
1482         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1483                     Make sure the directory containing libclc.pc is specified in your
1484                     PKG_CONFIG_PATH environment variable.
1485                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1486     else
1487         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1488         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1489         AC_SUBST([LIBCLC_INCLUDEDIR])
1490         AC_SUBST([LIBCLC_LIBEXECDIR])
1491     fi
1492
1493     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1494     enable_gallium_loader=yes
1495
1496     if test "x$enable_opencl_icd" = xyes; then
1497         OPENCL_LIBNAME="MesaOpenCL"
1498     else
1499         OPENCL_LIBNAME="OpenCL"
1500     fi
1501
1502     if test "x$have_libelf" != xyes; then
1503        AC_MSG_ERROR([Clover requires libelf])
1504     fi
1505 fi
1506 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1507 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1508 AC_SUBST([OPENCL_LIBNAME])
1509
1510 dnl
1511 dnl Gallium configuration
1512 dnl
1513 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1514
1515 AC_SUBST([LLVM_BINDIR])
1516 AC_SUBST([LLVM_CFLAGS])
1517 AC_SUBST([LLVM_CPPFLAGS])
1518 AC_SUBST([LLVM_CXXFLAGS])
1519 AC_SUBST([LLVM_LIBDIR])
1520 AC_SUBST([LLVM_LIBS])
1521 AC_SUBST([LLVM_LDFLAGS])
1522 AC_SUBST([LLVM_INCLUDEDIR])
1523 AC_SUBST([LLVM_VERSION])
1524 AC_SUBST([CLANG_RESOURCE_DIR])
1525
1526 case "x$enable_opengl$enable_gles1$enable_gles2" in
1527 x*yes*)
1528     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1529     ;;
1530 esac
1531
1532 AC_SUBST([VG_LIB_DEPS])
1533 AC_SUBST([EGL_CLIENT_APIS])
1534
1535 dnl
1536 dnl EGL Platforms configuration
1537 dnl
1538 AC_ARG_WITH([egl-platforms],
1539     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1540         [comma delimited native platforms libEGL supports, e.g.
1541         "x11,drm" @<:@default=auto@:>@])],
1542     [with_egl_platforms="$withval"],
1543     [if test "x$enable_egl" = xyes; then
1544         with_egl_platforms="x11"
1545     else
1546         with_egl_platforms=""
1547     fi])
1548
1549 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1550     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1551 fi
1552
1553 # Do per-EGL platform setups and checks
1554 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1555 for plat in $egl_platforms; do
1556         case "$plat" in
1557         wayland)
1558                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1559
1560                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1561                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1562                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1563                 ;;
1564
1565         x11)
1566                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1567                 ;;
1568
1569         drm)
1570                 test "x$enable_gbm" = "xno" &&
1571                         AC_MSG_ERROR([EGL platform drm needs gbm])
1572                 test "x$have_libdrm" != xyes &&
1573                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1574                 ;;
1575
1576         android|fbdev|gdi|null)
1577                 ;;
1578
1579         *)
1580                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1581                 ;;
1582         esac
1583
1584         case "$plat$need_pci_id$have_pci_id" in
1585                 waylandyesno|drmyesno)
1586                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1587         esac
1588 done
1589
1590 # libEGL wants to default to the first platform specified in
1591 # ./configure.  parse that here.
1592 if test "x$egl_platforms" != "x"; then
1593     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1594     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1595 else
1596     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1597 fi
1598
1599 if echo "$egl_platforms" | grep -q 'x11'; then
1600     NEED_WINSYS_XLIB=yes
1601 fi
1602 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1603 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1604 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1605 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1606 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1607
1608 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1609
1610 AC_SUBST([EGL_NATIVE_PLATFORM])
1611 AC_SUBST([EGL_CFLAGS])
1612
1613 # If we don't have the X11 platform, set this define so we don't try to include
1614 # the X11 headers.
1615 if ! echo "$egl_platforms" | grep -q 'x11'; then
1616     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1617     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1618 fi
1619
1620 AC_ARG_WITH([max-width],
1621     [AS_HELP_STRING([--with-max-width=N],
1622                     [Maximum framebuffer width (4096)])],
1623     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1624      AS_IF([test "${withval}" -gt "4096"],
1625            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1626 )
1627 AC_ARG_WITH([max-height],
1628     [AS_HELP_STRING([--with-max-height=N],
1629                     [Maximum framebuffer height (4096)])],
1630     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1631      AS_IF([test "${withval}" -gt "4096"],
1632            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1633 )
1634
1635 dnl
1636 dnl Gallium LLVM
1637 dnl
1638 AC_ARG_ENABLE([gallium-llvm],
1639     [AS_HELP_STRING([--enable-gallium-llvm],
1640         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1641     [enable_gallium_llvm="$enableval"],
1642     [enable_gallium_llvm=auto])
1643
1644 AC_ARG_ENABLE([llvm-shared-libs],
1645     [AS_HELP_STRING([--enable-llvm-shared-libs],
1646         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1647     [enable_llvm_shared_libs="$enableval"],
1648     [enable_llvm_shared_libs=yes])
1649
1650 AC_ARG_WITH([llvm-prefix],
1651     [AS_HELP_STRING([--with-llvm-prefix],
1652         [Prefix for LLVM installations in non-standard locations])],
1653     [llvm_prefix="$withval"],
1654     [llvm_prefix=''])
1655
1656
1657 # Call this inside ` ` to get the return value.
1658 # $1 is the llvm-config command with arguments.
1659 strip_unwanted_llvm_flags() {
1660     # Use \> (marks the end of the word)
1661     echo `$1` | sed \
1662         -e 's/-DNDEBUG\>//g' \
1663         -e 's/-D_GNU_SOURCE\>//g' \
1664         -e 's/-pedantic\>//g' \
1665         -e 's/-Wcovered-switch-default\>//g' \
1666         -e 's/-O.\>//g' \
1667         -e 's/-g\>//g' \
1668         -e 's/-Wall\>//g' \
1669         -e 's/-Wcast-qual\>//g' \
1670         -e 's/-Woverloaded-virtual\>//g' \
1671         -e 's/-fcolor-diagnostics\>//g' \
1672         -e 's/-fdata-sections\>//g' \
1673         -e 's/-ffunction-sections\>//g' \
1674         -e 's/-fno-exceptions\>//g' \
1675         -e 's/-fomit-frame-pointer\>//g' \
1676         -e 's/-fvisibility-inlines-hidden\>//g' \
1677         -e 's/-fPIC\>//g' \
1678         -e 's/-fstack-protector-strong\>//g'
1679 }
1680
1681
1682 if test -z "$with_gallium_drivers"; then
1683     enable_gallium_llvm=no
1684 fi
1685 if test "x$enable_gallium_llvm" = xauto; then
1686     case "$host_cpu" in
1687     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1688     esac
1689 fi
1690 if test "x$enable_gallium_llvm" = xyes; then
1691     if test -n "$llvm_prefix"; then
1692         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1693     else
1694         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1695     fi
1696
1697     if test "x$LLVM_CONFIG" != xno; then
1698         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1699         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1700         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1701         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1702         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1703         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1704         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1705         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1706
1707         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1708             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1709         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1710             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1711
1712         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1713         if test -z "$LLVM_VERSION_PATCH"; then
1714             LLVM_VERSION_PATCH=0
1715         fi
1716
1717         if test -n "${LLVM_VERSION_MAJOR}"; then
1718             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1719         else
1720             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1721         fi
1722
1723         LLVM_REQUIRED_VERSION_MAJOR="3"
1724         LLVM_REQUIRED_VERSION_MINOR="3"
1725         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1726             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1727         fi
1728
1729         LLVM_COMPONENTS="engine bitwriter"
1730         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1731             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1732         fi
1733
1734         if test "x$enable_opencl" = xyes; then
1735             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1736             # LLVM 3.3 >= 177971 requires IRReader
1737             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1738                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1739             fi
1740             # LLVM 3.4 requires Option
1741             if $LLVM_CONFIG --components | grep -qw 'option'; then
1742                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1743             fi
1744             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1745             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1746                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1747             fi
1748             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1749                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1750             fi
1751         fi
1752         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1753         MESA_LLVM=1
1754
1755         dnl Check for Clang internal headers
1756         if test "x$enable_opencl" = xyes; then
1757             if test -z "$CLANG_LIBDIR"; then
1758                 CLANG_LIBDIR=${LLVM_LIBDIR}
1759             fi
1760             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1761             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1762                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1763         fi
1764     else
1765         MESA_LLVM=0
1766         LLVM_VERSION_INT=0
1767     fi
1768 else
1769     MESA_LLVM=0
1770     LLVM_VERSION_INT=0
1771
1772     if test "x$enable_opencl" = xyes; then
1773         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1774     fi
1775 fi
1776
1777 dnl Directory for XVMC libs
1778 AC_ARG_WITH([xvmc-libdir],
1779     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1780         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1781     [XVMC_LIB_INSTALL_DIR="$withval"],
1782     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1783 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1784
1785 dnl
1786 dnl Gallium Tests
1787 dnl
1788 if test "x$enable_gallium_tests" = xyes; then
1789     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1790     enable_gallium_loader=yes
1791 fi
1792 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1793
1794 dnl Directory for VDPAU libs
1795 AC_ARG_WITH([vdpau-libdir],
1796     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1797         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1798     [VDPAU_LIB_INSTALL_DIR="$withval"],
1799     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1800 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1801
1802 dnl Directory for OMX libs
1803
1804 AC_ARG_WITH([omx-libdir],
1805     [AS_HELP_STRING([--with-omx-libdir=DIR],
1806         [directory for the OMX libraries])],
1807     [OMX_LIB_INSTALL_DIR="$withval"],
1808     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1809 AC_SUBST([OMX_LIB_INSTALL_DIR])
1810
1811 dnl Directory for VA libs
1812
1813 AC_ARG_WITH([va-libdir],
1814     [AS_HELP_STRING([--with-va-libdir=DIR],
1815         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1816     [VA_LIB_INSTALL_DIR="$withval"],
1817     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
1818 AC_SUBST([VA_LIB_INSTALL_DIR])
1819
1820 AC_ARG_WITH([d3d-libdir],
1821     [AS_HELP_STRING([--with-d3d-libdir=DIR],
1822         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
1823     [D3D_DRIVER_INSTALL_DIR="$withval"],
1824     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
1825 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
1826
1827 dnl
1828 dnl Gallium helper functions
1829 dnl
1830 gallium_require_drm() {
1831     if test "x$have_libdrm" != xyes; then
1832        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1833     fi
1834 }
1835
1836 gallium_require_llvm() {
1837     if test "x$MESA_LLVM" = x0; then
1838         case "$host" in *gnux32) return;; esac
1839         case "$host_cpu" in
1840         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1841         esac
1842     fi
1843 }
1844
1845 gallium_require_drm_loader() {
1846     if test "x$enable_gallium_loader" = xyes; then
1847         if test "x$need_pci_id$have_pci_id" = xyesno; then
1848             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1849         fi
1850         enable_gallium_drm_loader=yes
1851     fi
1852     if test "x$enable_va" = xyes && test "x$7" != x; then
1853          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1854     fi
1855 }
1856
1857 require_egl_drm() {
1858     case "$with_egl_platforms" in
1859         *drm*)
1860             ;;
1861          *)
1862             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1863             ;;
1864     esac
1865     if test "x$enable_gbm" != xyes; then
1866             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1867     fi
1868 }
1869
1870 radeon_llvm_check() {
1871     if test "x$enable_gallium_llvm" != "xyes"; then
1872         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1873     fi
1874     LLVM_REQUIRED_VERSION_MAJOR="3"
1875     LLVM_REQUIRED_VERSION_MINOR="4"
1876     LLVM_REQUIRED_VERSION_PATCH="2"
1877     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1878         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1879     fi
1880     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1881         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1882                       sources with the --enable-experimental-targets=R600
1883                       configure flag])
1884     fi
1885     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1886     NEED_RADEON_LLVM=yes
1887     if test "x$have_libelf" != xyes; then
1888        AC_MSG_ERROR([$1 requires libelf when using llvm])
1889     fi
1890 }
1891
1892 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1893 if test -n "$with_gallium_drivers"; then
1894     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1895     for driver in $gallium_drivers; do
1896         case "x$driver" in
1897         xsvga)
1898             HAVE_GALLIUM_SVGA=yes
1899             gallium_require_drm "svga"
1900             gallium_require_drm_loader
1901             ;;
1902         xi915)
1903             HAVE_GALLIUM_I915=yes
1904             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1905             gallium_require_drm "Gallium i915"
1906             gallium_require_drm_loader
1907             ;;
1908         xilo)
1909             HAVE_GALLIUM_ILO=yes
1910             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1911             gallium_require_drm "Gallium i965/ilo"
1912             gallium_require_drm_loader
1913             ;;
1914         xr300)
1915             HAVE_GALLIUM_R300=yes
1916             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1917             gallium_require_drm "Gallium R300"
1918             gallium_require_drm_loader
1919             gallium_require_llvm "Gallium R300"
1920             ;;
1921         xr600)
1922             HAVE_GALLIUM_R600=yes
1923             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1924             gallium_require_drm "Gallium R600"
1925             gallium_require_drm_loader
1926             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1927                 radeon_llvm_check "r600g"
1928                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1929             fi
1930             if test "x$enable_r600_llvm" = xyes; then
1931                 USE_R600_LLVM_COMPILER=yes;
1932             fi
1933             if test "x$enable_opencl" = xyes; then
1934                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1935             fi
1936             ;;
1937         xradeonsi)
1938             HAVE_GALLIUM_RADEONSI=yes
1939             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1940             gallium_require_drm "radeonsi"
1941             gallium_require_drm_loader
1942             radeon_llvm_check "radeonsi"
1943             require_egl_drm "radeonsi"
1944             ;;
1945         xnouveau)
1946             HAVE_GALLIUM_NOUVEAU=yes
1947             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1948             gallium_require_drm "nouveau"
1949             gallium_require_drm_loader
1950             ;;
1951         xfreedreno)
1952             HAVE_GALLIUM_FREEDRENO=yes
1953             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1954             gallium_require_drm "freedreno"
1955             gallium_require_drm_loader
1956             ;;
1957         xswrast)
1958             HAVE_GALLIUM_SOFTPIPE=yes
1959             if test "x$MESA_LLVM" = x1; then
1960                 HAVE_GALLIUM_LLVMPIPE=yes
1961             fi
1962             ;;
1963         xvc4)
1964             HAVE_GALLIUM_VC4=yes
1965             gallium_require_drm "vc4"
1966             gallium_require_drm_loader
1967
1968             case "$host_cpu" in
1969                 i?86 | x86_64 | amd64)
1970                 USE_VC4_SIMULATOR=yes
1971                 ;;
1972             esac
1973             ;;
1974         *)
1975             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1976             ;;
1977         esac
1978     done
1979 fi
1980
1981 dnl Set LLVM_LIBS - This is done after the driver configuration so
1982 dnl that drivers can add additional components to LLVM_COMPONENTS.
1983 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1984 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1985 dnl this was causing the same libraries to be appear multiple times
1986 dnl in LLVM_LIBS.
1987
1988 if test "x$MESA_LLVM" != x0; then
1989
1990     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1991
1992     if test "x$enable_llvm_shared_libs" = xyes; then
1993         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1994         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1995         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1996
1997         if test "x$llvm_have_one_so" = xyes; then
1998             dnl LLVM was built using auto*, so there is only one shared object.
1999             LLVM_LIBS="-l$LLVM_SO_NAME"
2000         else
2001             dnl If LLVM was built with CMake, there will be one shared object per
2002             dnl component.
2003             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2004                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2005         Please make sure you have built llvm with the --enable-shared option
2006         and that your llvm libraries are installed in $LLVM_LIBDIR
2007         If you have installed your llvm libraries to a different directory you
2008         can use the --with-llvm-prefix= configure flag to specify this directory.
2009         NOTE: Mesa is attempting to use llvm shared libraries by default.
2010         If you do not want to build with llvm shared libraries and instead want to
2011         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2012         invocation and rebuild.])])
2013
2014            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2015            dnl install uses a shared object for each component and we have
2016            dnl already added all of these objects to LLVM_LIBS.
2017         fi
2018     else
2019         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2020         dnl We need to link to llvm system libs when using static libs
2021         dnl However, only llvm 3.5+ provides --system-libs
2022         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2023             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2024         fi
2025     fi
2026 fi
2027
2028 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2029 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2030 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2031 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2032 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2033 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2034 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2035                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2036 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2037 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2038 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2039 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2040 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2041
2042 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2043
2044 # NOTE: anything using xcb or other client side libs ends up in separate
2045 #       _CLIENT variables.  The pipe loader is built in two variants,
2046 #       one that is standalone and does not link any x client libs (for
2047 #       use by XA tracker in particular, but could be used in any case
2048 #       where communication with xserver is not desired).
2049 if test "x$enable_gallium_loader" = xyes; then
2050     if test "x$NEED_WINSYS_XLIB" = xyes; then
2051         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2052     fi
2053
2054     if test "x$enable_dri" = xyes; then
2055         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2056     fi
2057
2058     if test "x$enable_gallium_drm_loader" = xyes; then
2059         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2060         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2061                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2062         if test "x$pipe_loader_have_xcb" = xyes; then
2063             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2064             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2065         fi
2066     fi
2067
2068     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2069     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2070
2071     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2072     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2073     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2074     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2075 fi
2076
2077 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2078 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2079 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2080 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2081 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2082 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2083
2084 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2085                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2086                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2087 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2088 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2089 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2090 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2091 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2092 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2093 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2094 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2095 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2096     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2097 fi
2098
2099 AC_SUBST([ELF_LIB])
2100
2101 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2102 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2103 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2104 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2105 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2106
2107 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2108 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2109 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2110
2111 AC_SUBST([NINE_MAJOR], 1)
2112 AC_SUBST([NINE_MINOR], 0)
2113 AC_SUBST([NINE_TINY], 0)
2114 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2115
2116 AC_SUBST([VDPAU_MAJOR], 1)
2117 AC_SUBST([VDPAU_MINOR], 0)
2118
2119 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2120 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2121 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2122 AC_SUBST([VA_MINOR], $VA_MINOR)
2123
2124 AC_SUBST([XVMC_MAJOR], 1)
2125 AC_SUBST([XVMC_MINOR], 0)
2126
2127 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2128 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2129 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2130 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2131
2132 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2133 AC_SUBST([XA_MINOR], $XA_MINOR)
2134 AC_SUBST([XA_TINY], $XA_TINY)
2135 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2136
2137 dnl Restore LDFLAGS and CPPFLAGS
2138 LDFLAGS="$_SAVE_LDFLAGS"
2139 CPPFLAGS="$_SAVE_CPPFLAGS"
2140
2141 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2142 if test "x$acv_mesa_CLANG" = xyes; then
2143     CFLAGS="$CFLAGS -Qunused-arguments"
2144     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2145 fi
2146
2147 dnl Add user CFLAGS and CXXFLAGS
2148 CFLAGS="$CFLAGS $USER_CFLAGS"
2149 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2150
2151 dnl Substitute the config
2152 AC_CONFIG_FILES([Makefile
2153                 src/Makefile
2154                 src/egl/drivers/dri2/Makefile
2155                 src/egl/main/Makefile
2156                 src/egl/main/egl.pc
2157                 src/egl/wayland/wayland-drm/Makefile
2158                 src/egl/wayland/wayland-egl/Makefile
2159                 src/egl/wayland/wayland-egl/wayland-egl.pc
2160                 src/gallium/Makefile
2161                 src/gallium/auxiliary/Makefile
2162                 src/gallium/auxiliary/pipe-loader/Makefile
2163                 src/gallium/drivers/freedreno/Makefile
2164                 src/gallium/drivers/galahad/Makefile
2165                 src/gallium/drivers/i915/Makefile
2166                 src/gallium/drivers/identity/Makefile
2167                 src/gallium/drivers/ilo/Makefile
2168                 src/gallium/drivers/llvmpipe/Makefile
2169                 src/gallium/drivers/noop/Makefile
2170                 src/gallium/drivers/nouveau/Makefile
2171                 src/gallium/drivers/r300/Makefile
2172                 src/gallium/drivers/r600/Makefile
2173                 src/gallium/drivers/radeon/Makefile
2174                 src/gallium/drivers/radeonsi/Makefile
2175                 src/gallium/drivers/rbug/Makefile
2176                 src/gallium/drivers/softpipe/Makefile
2177                 src/gallium/drivers/svga/Makefile
2178                 src/gallium/drivers/trace/Makefile
2179                 src/gallium/drivers/vc4/Makefile
2180                 src/gallium/drivers/vc4/kernel/Makefile
2181                 src/gallium/state_trackers/clover/Makefile
2182                 src/gallium/state_trackers/dri/Makefile
2183                 src/gallium/state_trackers/glx/xlib/Makefile
2184                 src/gallium/state_trackers/nine/Makefile
2185                 src/gallium/state_trackers/omx/Makefile
2186                 src/gallium/state_trackers/osmesa/Makefile
2187                 src/gallium/state_trackers/va/Makefile
2188                 src/gallium/state_trackers/vdpau/Makefile
2189                 src/gallium/state_trackers/vega/Makefile
2190                 src/gallium/state_trackers/xa/Makefile
2191                 src/gallium/state_trackers/xvmc/Makefile
2192                 src/gallium/targets/d3dadapter9/Makefile
2193                 src/gallium/targets/d3dadapter9/d3d.pc
2194                 src/gallium/targets/dri/Makefile
2195                 src/gallium/targets/libgl-xlib/Makefile
2196                 src/gallium/targets/omx/Makefile
2197                 src/gallium/targets/opencl/Makefile
2198                 src/gallium/targets/osmesa/Makefile
2199                 src/gallium/targets/osmesa/osmesa.pc
2200                 src/gallium/targets/pipe-loader/Makefile
2201                 src/gallium/targets/va/Makefile
2202                 src/gallium/targets/vdpau/Makefile
2203                 src/gallium/targets/xa/Makefile
2204                 src/gallium/targets/xa/xatracker.pc
2205                 src/gallium/targets/xvmc/Makefile
2206                 src/gallium/tests/trivial/Makefile
2207                 src/gallium/tests/unit/Makefile
2208                 src/gallium/winsys/freedreno/drm/Makefile
2209                 src/gallium/winsys/i915/drm/Makefile
2210                 src/gallium/winsys/intel/drm/Makefile
2211                 src/gallium/winsys/nouveau/drm/Makefile
2212                 src/gallium/winsys/radeon/drm/Makefile
2213                 src/gallium/winsys/svga/drm/Makefile
2214                 src/gallium/winsys/sw/dri/Makefile
2215                 src/gallium/winsys/sw/fbdev/Makefile
2216                 src/gallium/winsys/sw/kms-dri/Makefile
2217                 src/gallium/winsys/sw/null/Makefile
2218                 src/gallium/winsys/sw/wayland/Makefile
2219                 src/gallium/winsys/sw/wrapper/Makefile
2220                 src/gallium/winsys/sw/xlib/Makefile
2221                 src/gallium/winsys/vc4/drm/Makefile
2222                 src/gbm/Makefile
2223                 src/gbm/main/gbm.pc
2224                 src/glsl/Makefile
2225                 src/glx/Makefile
2226                 src/glx/apple/Makefile
2227                 src/glx/tests/Makefile
2228                 src/gtest/Makefile
2229                 src/loader/Makefile
2230                 src/mapi/Makefile
2231                 src/mapi/es1api/glesv1_cm.pc
2232                 src/mapi/es2api/glesv2.pc
2233                 src/mapi/glapi/gen/Makefile
2234                 src/mapi/vgapi/Makefile
2235                 src/mapi/vgapi/vg.pc
2236                 src/mesa/Makefile
2237                 src/mesa/gl.pc
2238                 src/mesa/drivers/dri/dri.pc
2239                 src/mesa/drivers/dri/common/Makefile
2240                 src/mesa/drivers/dri/common/xmlpool/Makefile
2241                 src/mesa/drivers/dri/i915/Makefile
2242                 src/mesa/drivers/dri/i965/Makefile
2243                 src/mesa/drivers/dri/Makefile
2244                 src/mesa/drivers/dri/nouveau/Makefile
2245                 src/mesa/drivers/dri/r200/Makefile
2246                 src/mesa/drivers/dri/radeon/Makefile
2247                 src/mesa/drivers/dri/swrast/Makefile
2248                 src/mesa/drivers/osmesa/Makefile
2249                 src/mesa/drivers/osmesa/osmesa.pc
2250                 src/mesa/drivers/x11/Makefile
2251                 src/mesa/main/tests/Makefile
2252                 src/util/Makefile
2253                 src/util/tests/hash_table/Makefile])
2254
2255 AC_OUTPUT
2256
2257 dnl
2258 dnl Output some configuration info for the user
2259 dnl
2260 echo ""
2261 echo "        prefix:          $prefix"
2262 echo "        exec_prefix:     $exec_prefix"
2263 echo "        libdir:          $libdir"
2264 echo "        includedir:      $includedir"
2265
2266 dnl API info
2267 echo ""
2268 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2269 echo "        OpenVG:          $enable_openvg"
2270
2271 dnl Driver info
2272 echo ""
2273 case "x$enable_osmesa$enable_gallium_osmesa" in
2274 xnoyes)
2275         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2276         ;;
2277 xyesno)
2278         echo "        OSMesa:          lib$OSMESA_LIB"
2279         ;;
2280 xnono)
2281         echo "        OSMesa:          no"
2282         ;;
2283 esac
2284
2285 echo ""
2286 if test "x$enable_dri" != xno; then
2287         echo "        DRI platform:    $dri_platform"
2288         if test -z "$DRI_DIRS"; then
2289             echo "        DRI drivers:     no"
2290         else
2291             echo "        DRI drivers:     $DRI_DIRS"
2292         fi
2293         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2294 fi
2295
2296 case "x$enable_glx$enable_xlib_glx" in
2297 xyesyes)
2298     echo "        GLX:             Xlib-based"
2299     ;;
2300 xyesno)
2301     echo "        GLX:             DRI-based"
2302     ;;
2303 *)
2304     echo "        GLX:             $enable_glx"
2305     ;;
2306 esac
2307
2308 dnl EGL
2309 echo ""
2310 echo "        EGL:             $enable_egl"
2311 if test "$enable_egl" = yes; then
2312     echo "        EGL platforms:   $egl_platforms"
2313
2314     egl_drivers=""
2315     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2316         egl_drivers="$egl_drivers builtin:egl_dri2"
2317     fi
2318
2319     echo "        EGL drivers:    $egl_drivers"
2320 fi
2321
2322 echo ""
2323 if test "x$MESA_LLVM" = x1; then
2324     echo "        llvm:            yes"
2325     echo "        llvm-config:     $LLVM_CONFIG"
2326     echo "        llvm-version:    $LLVM_VERSION"
2327 else
2328     echo "        llvm:            no"
2329 fi
2330
2331 echo ""
2332 if test -n "$with_gallium_drivers"; then
2333     echo "        Gallium:         yes"
2334 else
2335     echo "        Gallium:         no"
2336 fi
2337
2338
2339 dnl Libraries
2340 echo ""
2341 echo "        Shared libs:     $enable_shared"
2342 echo "        Static libs:     $enable_static"
2343 echo "        Shared-glapi:    $enable_shared_glapi"
2344
2345 dnl Compiler options
2346 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2347 cflags=`echo $CFLAGS | \
2348     $SED 's/^ *//;s/  */ /;s/ *$//'`
2349 cxxflags=`echo $CXXFLAGS | \
2350     $SED 's/^ *//;s/  */ /;s/ *$//'`
2351 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2352 echo ""
2353 echo "        CFLAGS:          $cflags"
2354 echo "        CXXFLAGS:        $cxxflags"
2355 echo "        Macros:          $defines"
2356 echo ""
2357 if test "x$MESA_LLVM" = x1; then
2358     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2359     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2360     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2361     echo ""
2362 fi
2363 echo "        PYTHON2:         $PYTHON2"
2364
2365 echo ""
2366 echo "        Run '${MAKE-make}' to build Mesa"
2367 echo ""