configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  30 USER_CFLAGS="$CFLAGS"
  31 USER_CXXFLAGS="$CXXFLAGS"
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.31
  36 LIBDRM_INTEL_REQUIRED=2.4.37
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54 AC_PATH_PROG([MKDEP], [makedepend])
  55
  56 if test "x$MKDEP" = "x"; then
  57     AC_MSG_ERROR([makedepend is required to build Mesa])
  58 fi
  59
  60 AC_PROG_YACC
  61 AC_PATH_PROG([YACC_INST], $YACC)
  62 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  63     if test -z "$YACC_INST"; then
  64         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  65     fi
  66 fi
  67 AC_PROG_LEX
  68
  69 AC_PATH_PROG([PERL], [perl])
  70
  71 AC_CHECK_PROG(INDENT, indent, indent, cat)
  72 if test "x$INDENT" != "xcat"; then
  73     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  74 fi
  75
  76 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  77 dnl configuration in that case.
  78 AC_PROG_INSTALL
  79 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  80
  81 dnl We need a POSIX shell for parts of the build. Assume we have one
  82 dnl in most cases.
  83 case "$host_os" in
  84 solaris*)
  85     # Solaris /bin/sh is too old/non-POSIX compliant
  86     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  87     SHELL="$POSIX_SHELL"
  88     ;;
  89 esac
  90
  91 dnl clang is mostly GCC-compatible, but its version is much lower,
  92 dnl so we have to check for it.
  93 AC_MSG_CHECKING([if compiling with clang])
  94
  95 AC_COMPILE_IFELSE(
  96 [AC_LANG_PROGRAM([], [[
  97 #ifndef __clang__
  98        not clang
  99 #endif
 100 ]])],
 101 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 102
 103 AC_MSG_RESULT([$acv_mesa_CLANG])
 104
 105 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 106 dnl versions are explictly not supported.
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124 fi
 125
 126
 127 MKDEP_OPTIONS=-fdepend
 128 dnl Ask gcc where it's keeping its secret headers
 129 if test "x$GCC" = xyes; then
 130     for dir in include include-fixed; do
 131         GCC_INCLUDES=`$CC -print-file-name=$dir`
 132         if test "x$GCC_INCLUDES" != x && \
 133            test "$GCC_INCLUDES" != "$dir" && \
 134            test -d "$GCC_INCLUDES"; then
 135             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 136         fi
 137     done
 138 fi
 139 AC_SUBST([MKDEP_OPTIONS])
 140
 141 dnl Make sure the pkg-config macros are defined
 142 m4_ifndef([PKG_PROG_PKG_CONFIG],
 143     [m4_fatal([Could not locate the pkg-config autoconf macros.
 144   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 145   are in a different location, try setting the environment variable
 146   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 147 PKG_PROG_PKG_CONFIG()
 148
 149 dnl LIB_DIR - library basename
 150 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 151 AC_SUBST([LIB_DIR])
 152
 153 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 154 _SAVE_LDFLAGS="$LDFLAGS"
 155 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 156 AC_SUBST([EXTRA_LIB_PATH])
 157
 158 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 159 _SAVE_CPPFLAGS="$CPPFLAGS"
 160 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 161 AC_SUBST([X11_INCLUDES])
 162
 163 dnl Compiler macros
 164 DEFINES=""
 165 AC_SUBST([DEFINES])
 166 case "$host_os" in
 167 linux*|*-gnu*|gnu*)
 168     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 169     ;;
 170 solaris*)
 171     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 172     ;;
 173 cygwin*)
 174     DEFINES="$DEFINES -DPTHREADS"
 175     ;;
 176 esac
 177
 178 dnl Add flags for gcc and g++
 179 if test "x$GCC" = xyes; then
 180     CFLAGS="$CFLAGS -Wall -std=c99"
 181
 182     # Enable -Werror=implicit-function-declaration and
 183     # -Werror=missing-prototypes, if available, or otherwise, just
 184     # -Wmissing-prototypes.  This is particularly useful to avoid
 185     # generating a loadable driver module that has undefined symbols.
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 188     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 189     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 191                    AC_MSG_RESULT([yes]),
 192                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 193                     AC_MSG_RESULT([no])]);
 194
 195     # Enable -fvisibility=hidden if using a gcc that supports it
 196     save_CFLAGS="$CFLAGS"
 197     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 198     VISIBILITY_CFLAGS="-fvisibility=hidden"
 199     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 200     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 201                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 202
 203     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 204     CFLAGS=$save_CFLAGS
 205
 206     # Work around aliasing bugs - developers should comment this out
 207     CFLAGS="$CFLAGS -fno-strict-aliasing"
 208
 209     # gcc's builtin memcmp is slower than glibc's
 210     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 231
 232     # gcc's builtin memcmp is slower than glibc's
 233     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 234     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 235 fi
 236
 237 dnl even if the compiler appears to support it, using visibility attributes isn't
 238 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 239 case "$host_os" in
 240 cygwin*)
 241     VISIBILITY_CFLAGS=""
 242     VISIBILITY_CXXFLAGS=""
 243     ;;
 244 esac
 245
 246 AC_SUBST([VISIBILITY_CFLAGS])
 247 AC_SUBST([VISIBILITY_CXXFLAGS])
 248
 249 dnl These should be unnecessary, but let the user set them if they want
 250 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 251     Default is to use CFLAGS.])
 252 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 253     compiler. Default is to use CFLAGS.])
 254 AC_SUBST([OPT_FLAGS])
 255 AC_SUBST([ARCH_FLAGS])
 256
 257 dnl
 258 dnl Hacks to enable 32 or 64 bit build
 259 dnl
 260 AC_ARG_ENABLE([32-bit],
 261     [AS_HELP_STRING([--enable-32-bit],
 262         [build 32-bit libraries @<:@default=auto@:>@])],
 263     [enable_32bit="$enableval"],
 264     [enable_32bit=auto]
 265 )
 266 if test "x$enable_32bit" = xyes; then
 267     if test "x$GCC" = xyes; then
 268         CFLAGS="$CFLAGS -m32"
 269         ARCH_FLAGS="$ARCH_FLAGS -m32"
 270         CCASFLAGS="$CCASFLAGS -m32"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m32"
 274     fi
 275 fi
 276 AC_ARG_ENABLE([64-bit],
 277     [AS_HELP_STRING([--enable-64-bit],
 278         [build 64-bit libraries @<:@default=auto@:>@])],
 279     [enable_64bit="$enableval"],
 280     [enable_64bit=auto]
 281 )
 282 if test "x$enable_64bit" = xyes; then
 283     if test "x$GCC" = xyes; then
 284         CFLAGS="$CFLAGS -m64"
 285     fi
 286     if test "x$GXX" = xyes; then
 287         CXXFLAGS="$CXXFLAGS -m64"
 288     fi
 289 fi
 290
 291 dnl Can't have static and shared libraries, default to static if user
 292 dnl explicitly requested. If both disabled, set to static since shared
 293 dnl was explicitly requested.
 294 case "x$enable_static$enable_shared" in
 295 xyesyes )
 296     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 297     enable_shared=no
 298     ;;
 299 xnono )
 300     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 301     enable_static=yes
 302     ;;
 303 esac
 304
 305 dnl
 306 dnl mklib options
 307 dnl
 308 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 309 if test "$enable_static" = yes; then
 310     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 311 fi
 312 AC_SUBST([MKLIB_OPTIONS])
 313
 314 dnl
 315 dnl other compiler options
 316 dnl
 317 AC_ARG_ENABLE([debug],
 318     [AS_HELP_STRING([--enable-debug],
 319         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 320     [enable_debug="$enableval"],
 321     [enable_debug=no]
 322 )
 323 if test "x$enable_debug" = xyes; then
 324     DEFINES="$DEFINES -DDEBUG"
 325     if test "x$GCC" = xyes; then
 326         CFLAGS="$CFLAGS -g"
 327     fi
 328     if test "x$GXX" = xyes; then
 329         CXXFLAGS="$CXXFLAGS -g"
 330     fi
 331 fi
 332
 333 dnl
 334 dnl library names
 335 dnl
 336 LIB_PREFIX_GLOB='lib'
 337 LIB_VERSION_SEPARATOR='.'
 338 if test "$enable_static" = yes; then
 339     LIB_EXTENSION='a'
 340 else
 341     case "$host_os" in
 342     darwin* )
 343         LIB_EXTENSION='dylib' ;;
 344     cygwin* )
 345         dnl prefix can be 'cyg' or 'lib'
 346         LIB_PREFIX_GLOB='???'
 347         LIB_VERSION_SEPARATOR='-'
 348         LIB_EXTENSION='dll' ;;
 349     aix* )
 350         LIB_EXTENSION='a' ;;
 351     * )
 352         LIB_EXTENSION='so' ;;
 353     esac
 354 fi
 355 AC_ARG_WITH([gl-lib-name],
 356   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 357     [specify GL library name @<:@default=GL@:>@])],
 358   [GL_LIB=$withval],
 359   [GL_LIB=GL])
 360 AC_ARG_WITH([glu-lib-name],
 361   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 362     [specify GLU library name @<:@default=GLU@:>@])],
 363   [GLU_LIB=$withval],
 364   [GLU_LIB=GLU])
 365 AC_ARG_WITH([osmesa-lib-name],
 366   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 367     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 368   [OSMESA_LIB=$withval],
 369   [OSMESA_LIB=OSMesa])
 370 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 371 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 372 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 373
 374 dnl
 375 dnl Mangled Mesa support
 376 dnl
 377 AC_ARG_ENABLE([mangling],
 378   [AS_HELP_STRING([--enable-mangling],
 379     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 380   [enable_mangling="${enableval}"],
 381   [enable_mangling=no]
 382 )
 383 if test "x${enable_mangling}" = "xyes" ; then
 384   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 385   GL_LIB="Mangled${GL_LIB}"
 386   GLU_LIB="Mangled${GLU_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([GLU_LIB])
 391 AC_SUBST([OSMESA_LIB])
 392
 393 dnl
 394 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 395 dnl
 396 AC_ARG_ENABLE([texture-float],
 397     [AS_HELP_STRING([--enable-texture-float],
 398         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 399     [enable_texture_float="$enableval"],
 400     [enable_texture_float=no]
 401 )
 402 if test "x$enable_texture_float" = xyes; then
 403     AC_MSG_WARN([Floating-point textures enabled.])
 404     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 405     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 406 fi
 407
 408 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 409 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 410 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 411 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 412 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 413 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 414 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 415 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 416
 417 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 418 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 419 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 420 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 421 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 422 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 423 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 424 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 425
 426 AC_SUBST([GL_LIB_NAME])
 427 AC_SUBST([GLU_LIB_NAME])
 428 AC_SUBST([OSMESA_LIB_NAME])
 429 AC_SUBST([EGL_LIB_NAME])
 430 AC_SUBST([GLESv1_CM_LIB_NAME])
 431 AC_SUBST([GLESv2_LIB_NAME])
 432 AC_SUBST([VG_LIB_NAME])
 433 AC_SUBST([GLAPI_LIB_NAME])
 434
 435 AC_SUBST([GL_LIB_GLOB])
 436 AC_SUBST([GLU_LIB_GLOB])
 437 AC_SUBST([EGL_LIB_GLOB])
 438 AC_SUBST([GLESv1_CM_LIB_GLOB])
 439 AC_SUBST([GLESv2_LIB_GLOB])
 440 AC_SUBST([VG_LIB_GLOB])
 441 AC_SUBST([GLAPI_LIB_GLOB])
 442
 443 dnl
 444 dnl Arch/platform-specific settings
 445 dnl
 446 AC_ARG_ENABLE([asm],
 447     [AS_HELP_STRING([--disable-asm],
 448         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 449     [enable_asm="$enableval"],
 450     [enable_asm=yes]
 451 )
 452 asm_arch=""
 453 MESA_ASM_FILES=""
 454 AC_MSG_CHECKING([whether to enable assembly])
 455 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 456 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 457 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 458     case "$host_cpu" in
 459     i?86 | x86_64)
 460         enable_asm=no
 461         AC_MSG_RESULT([no, cross compiling])
 462         ;;
 463     esac
 464 fi
 465 # check for supported arches
 466 if test "x$enable_asm" = xyes; then
 467     case "$host_cpu" in
 468     i?86)
 469         case "$host_os" in
 470         linux* | *freebsd* | dragonfly* | *netbsd*)
 471             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 472             ;;
 473         esac
 474         ;;
 475     x86_64)
 476         case "$host_os" in
 477         linux* | *freebsd* | dragonfly* | *netbsd*)
 478             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 479             ;;
 480         esac
 481         ;;
 482     powerpc)
 483         case "$host_os" in
 484         linux*)
 485             asm_arch=ppc
 486             ;;
 487         esac
 488         ;;
 489     sparc*)
 490         case "$host_os" in
 491         linux*)
 492             asm_arch=sparc
 493             ;;
 494         esac
 495         ;;
 496     esac
 497
 498     case "$asm_arch" in
 499     x86)
 500         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 501         MESA_ASM_FILES='$(X86_FILES)'
 502         AC_MSG_RESULT([yes, x86])
 503         ;;
 504     x86_64)
 505         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 506         MESA_ASM_FILES='$(X86_64_FILES)'
 507         AC_MSG_RESULT([yes, x86_64])
 508         ;;
 509     sparc)
 510         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 511         MESA_ASM_FILES='$(SPARC_FILES)'
 512         AC_MSG_RESULT([yes, sparc])
 513         ;;
 514     *)
 515         AC_MSG_RESULT([no, platform not supported])
 516         ;;
 517     esac
 518 fi
 519 AC_SUBST([MESA_ASM_FILES])
 520
 521 dnl PIC code macro
 522 MESA_PIC_FLAGS
 523
 524 dnl Check to see if dlopen is in default libraries (like Solaris, which
 525 dnl has it in libc), or if libdl is needed to get it.
 526 AC_CHECK_FUNC([dlopen], [],
 527     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 528 AC_SUBST([DLOPEN_LIBS])
 529
 530 dnl See if posix_memalign is available
 531 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 532
 533 dnl SELinux awareness.
 534 AC_ARG_ENABLE([selinux],
 535     [AS_HELP_STRING([--enable-selinux],
 536         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 537     [MESA_SELINUX="$enableval"],
 538     [MESA_SELINUX=no])
 539 if test "x$enable_selinux" = "xyes"; then
 540     AC_CHECK_HEADER([selinux/selinux.h],[],
 541                     [AC_MSG_ERROR([SELinux headers not found])])
 542     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 543                  [AC_MSG_ERROR([SELinux library not found])])
 544     SELINUX_LIBS="-lselinux"
 545     DEFINES="$DEFINES -DMESA_SELINUX"
 546 fi
 547
 548 dnl Options for APIs
 549 AC_ARG_ENABLE([opengl],
 550     [AS_HELP_STRING([--disable-opengl],
 551         [disable support for standard OpenGL API @<:@default=no@:>@])],
 552     [enable_opengl="$enableval"],
 553     [enable_opengl=yes])
 554 AC_ARG_ENABLE([gles1],
 555     [AS_HELP_STRING([--enable-gles1],
 556         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 557     [enable_gles1="$enableval"],
 558     [enable_gles1=no])
 559 AC_ARG_ENABLE([gles2],
 560     [AS_HELP_STRING([--enable-gles2],
 561         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 562     [enable_gles2="$enableval"],
 563     [enable_gles2=no])
 564 AC_ARG_ENABLE([openvg],
 565     [AS_HELP_STRING([--enable-openvg],
 566         [enable support for OpenVG API @<:@default=no@:>@])],
 567     [enable_openvg="$enableval"],
 568     [enable_openvg=no])
 569
 570 AC_ARG_ENABLE([dri],
 571     [AS_HELP_STRING([--enable-dri],
 572         [enable DRI modules @<:@default=auto@:>@])],
 573     [enable_dri="$enableval"],
 574     [enable_dri=auto])
 575 AC_ARG_ENABLE([glx],
 576     [AS_HELP_STRING([--enable-glx],
 577         [enable GLX library @<:@default=auto@:>@])],
 578     [enable_glx="$enableval"],
 579     [enable_glx=auto])
 580 AC_ARG_ENABLE([osmesa],
 581     [AS_HELP_STRING([--enable-osmesa],
 582         [enable OSMesa library @<:@default=auto@:>@])],
 583     [enable_osmesa="$enableval"],
 584     [enable_osmesa=auto])
 585 AC_ARG_ENABLE([egl],
 586     [AS_HELP_STRING([--disable-egl],
 587         [disable EGL library @<:@default=enabled@:>@])],
 588     [enable_egl="$enableval"],
 589     [enable_egl=yes])
 590
 591 AC_ARG_ENABLE([xorg],
 592     [AS_HELP_STRING([--enable-xorg],
 593         [enable support for X.Org DDX API @<:@default=no@:>@])],
 594     [enable_xorg="$enableval"],
 595     [enable_xorg=no])
 596 AC_ARG_ENABLE([xa],
 597     [AS_HELP_STRING([--enable-xa],
 598         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 599     [enable_xa="$enableval"],
 600     [enable_xa=no])
 601 AC_ARG_ENABLE([d3d1x],
 602     [AS_HELP_STRING([--enable-d3d1x],
 603         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 604     [enable_d3d1x="$enableval"],
 605     [enable_d3d1x=no])
 606 AC_ARG_ENABLE([gbm],
 607    [AS_HELP_STRING([--enable-gbm],
 608          [enable gbm library @<:@default=auto@:>@])],
 609    [enable_gbm="$enableval"],
 610    [enable_gbm=auto])
 611
 612 AC_ARG_ENABLE([xvmc],
 613    [AS_HELP_STRING([--enable-xvmc],
 614          [enable xvmc library @<:@default=auto@:>@])],
 615    [enable_xvmc="$enableval"],
 616    [enable_xvmc=auto])
 617 AC_ARG_ENABLE([vdpau],
 618    [AS_HELP_STRING([--enable-vdpau],
 619          [enable vdpau library @<:@default=auto@:>@])],
 620    [enable_vdpau="$enableval"],
 621    [enable_vdpau=auto])
 622 AC_ARG_ENABLE([va],
 623    [AS_HELP_STRING([--enable-va],
 624          [enable va library @<:@default=auto@:>@])],
 625    [enable_va="$enableval"],
 626    [enable_va=auto])
 627 AC_ARG_ENABLE([opencl],
 628    [AS_HELP_STRING([--enable-opencl],
 629          [enable OpenCL library @<:@default=no@:>@])],
 630    [enable_opencl="$enableval"],
 631    [enable_opencl=no])
 632 AC_ARG_ENABLE([xlib_glx],
 633     [AS_HELP_STRING([--enable-xlib-glx],
 634         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 635     [enable_xlib_glx="$enableval"],
 636     [enable_xlib_glx=auto])
 637 AC_ARG_ENABLE([gallium_egl],
 638     [AS_HELP_STRING([--enable-gallium-egl],
 639         [enable optional EGL state tracker (not required
 640          for EGL support in Gallium with OpenGL and OpenGL ES)
 641          @<:@default=disable@:>@])],
 642     [enable_gallium_egl="$enableval"],
 643     [enable_gallium_egl=no])
 644 AC_ARG_ENABLE([gallium_gbm],
 645     [AS_HELP_STRING([--enable-gallium-gbm],
 646         [enable optional gbm state tracker (not required for
 647          gbm support in Gallium)
 648          @<:@default=auto@:>@])],
 649     [enable_gallium_gbm="$enableval"],
 650     [enable_gallium_gbm=auto])
 651
 652 AC_ARG_ENABLE([r600-llvm-compiler],
 653     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 654         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 655     [enable_r600_llvm="$enableval"],
 656     [enable_r600_llvm=no])
 657
 658 AC_ARG_ENABLE([gallium_tests],
 659     [AS_HELP_STRING([--enable-gallium-tests],
 660         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 661     [enable_gallium_tests="$enableval"],
 662     [enable_gallium_tests=no])
 663
 664 # Option for Gallium drivers
 665 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 666
 667 AC_ARG_WITH([gallium-drivers],
 668     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 669         [comma delimited Gallium drivers list, e.g.
 670         "i915,nouveau,r300,r600,svga,swrast"
 671         @<:@default=r300,r600,swrast@:>@])],
 672     [with_gallium_drivers="$withval"],
 673     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 674
 675 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 676 # here so that the script doesn't choke on an unknown driver name later.
 677 case "$with_gallium_drivers" in
 678     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 679     no) with_gallium_drivers='' ;;
 680 esac
 681
 682 if test "x$enable_opengl" = xno -a \
 683         "x$enable_gles1" = xno -a \
 684         "x$enable_gles2" = xno -a \
 685         "x$enable_openvg" = xno -a \
 686         "x$enable_xorg" = xno -a \
 687         "x$enable_xa" = xno -a \
 688         "x$enable_d3d1x" = xno -a \
 689         "x$enable_xvmc" = xno -a \
 690         "x$enable_vdpau" = xno -a \
 691         "x$enable_va" = xno -a \
 692         "x$enable_opencl" = xno; then
 693     AC_MSG_ERROR([at least one API should be enabled])
 694 fi
 695
 696 API_DEFINES=""
 697 if test "x$enable_opengl" = xno; then
 698     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 699 else
 700     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 701 fi
 702 if test "x$enable_gles1" = xyes; then
 703     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 704 fi
 705 if test "x$enable_gles2" = xyes; then
 706     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 707 fi
 708 AC_SUBST([API_DEFINES])
 709
 710 AC_ARG_ENABLE([shared-glapi],
 711     [AS_HELP_STRING([--enable-shared-glapi],
 712         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 713     [enable_shared_glapi="$enableval"],
 714     [enable_shared_glapi=no])
 715
 716 SHARED_GLAPI="0"
 717 if test "x$enable_shared_glapi" = xyes; then
 718     SHARED_GLAPI="1"
 719     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 720     # the remap table)
 721     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 722     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 723 fi
 724 AC_SUBST([SHARED_GLAPI])
 725 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 726
 727 dnl
 728 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 729 dnl More later: fbdev, ...
 730 dnl
 731 default_driver="xlib"
 732
 733 case "$host_os" in
 734 linux*)
 735     case "$host_cpu" in
 736     i*86|x86_64|powerpc*|sparc*|ia64*) default_driver="dri";;
 737     esac
 738     ;;
 739 *freebsd* | dragonfly* | *netbsd*)
 740     case "$host_cpu" in
 741     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 742     esac
 743     ;;
 744 esac
 745
 746 if test "x$enable_opengl" = xno; then
 747     default_driver="no"
 748 fi
 749
 750 AC_ARG_WITH([driver],
 751     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 752     [mesa_driver="$withval"],
 753     [mesa_driver=auto])
 754 dnl Check for valid option
 755 case "x$mesa_driver" in
 756 xxlib|xdri|xosmesa|xno)
 757     if test "x$enable_dri" != xauto -o \
 758             "x$enable_glx" != xauto -o \
 759             "x$enable_osmesa" != xauto -o \
 760             "x$enable_xlib_glx" != xauto; then
 761         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 762     fi
 763     ;;
 764 xauto)
 765     mesa_driver="$default_driver"
 766     ;;
 767 *)
 768     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 769     ;;
 770 esac
 771
 772 # map $mesa_driver to APIs
 773 if test "x$enable_dri" = xauto; then
 774     case "x$mesa_driver" in
 775     xdri) enable_dri=yes ;;
 776     *)    enable_dri=no ;;
 777     esac
 778 fi
 779
 780 if test "x$enable_glx" = xauto; then
 781     case "x$mesa_driver" in
 782     xdri|xxlib) enable_glx=yes ;;
 783     *)          enable_glx=no ;;
 784     esac
 785 fi
 786
 787 if test "x$enable_osmesa" = xauto; then
 788     case "x$mesa_driver" in
 789     xxlib|xosmesa) enable_osmesa=yes ;;
 790     *)             enable_osmesa=no ;;
 791     esac
 792 fi
 793
 794 if test "x$enable_xlib_glx" = xauto; then
 795     case "x$mesa_driver" in
 796     xxlib) enable_xlib_glx=yes ;;
 797     *)     enable_xlib_glx=no ;;
 798     esac
 799 fi
 800
 801 if test "x$enable_glx" = xno; then
 802     enable_xlib_glx=no
 803 fi
 804
 805 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 806
 807 dnl
 808 dnl Driver specific build directories
 809 dnl
 810
 811 dnl this variable will be prepended to SRC_DIRS and is not exported
 812 CORE_DIRS=""
 813
 814 SRC_DIRS="gtest"
 815 GLU_DIRS="sgi"
 816 GALLIUM_DIRS="auxiliary drivers state_trackers"
 817 GALLIUM_TARGET_DIRS=""
 818 GALLIUM_WINSYS_DIRS="sw"
 819 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 820 GALLIUM_STATE_TRACKERS_DIRS=""
 821
 822 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 823 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 824 x*yes*)
 825     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 826     ;;
 827 esac
 828
 829 # build glapi if OpenGL is enabled
 830 if test "x$enable_opengl" = xyes; then
 831     CORE_DIRS="$CORE_DIRS mapi/glapi"
 832 fi
 833
 834 # build es1api if OpenGL ES 1.x is enabled
 835 if test "x$enable_gles1" = xyes; then
 836     CORE_DIRS="$CORE_DIRS mapi/es1api"
 837 fi
 838
 839 # build es2api if OpenGL ES 2.x is enabled
 840 if test "x$enable_gles2" = xyes; then
 841     CORE_DIRS="$CORE_DIRS mapi/es2api"
 842 fi
 843
 844 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 845 case "x$enable_opengl$enable_gles1$enable_gles2" in
 846 x*yes*)
 847     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 848     ;;
 849 esac
 850
 851 case "x$enable_glx$enable_xlib_glx" in
 852 xyesyes)
 853     DRIVER_DIRS="$DRIVER_DIRS x11"
 854     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 855     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 856     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 857     HAVE_WINSYS_XLIB="yes"
 858     ;;
 859 xyesno)
 860     # DRI-based GLX
 861     SRC_DIRS="$SRC_DIRS glx"
 862     ;;
 863 esac
 864
 865 if test "x$enable_dri" = xyes; then
 866     DRIVER_DIRS="$DRIVER_DIRS dri"
 867
 868     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 869     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 870     HAVE_ST_DRI="yes"
 871 fi
 872
 873 if test "x$enable_osmesa" = xyes; then
 874     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 875 fi
 876
 877 AC_SUBST([SRC_DIRS])
 878 AC_SUBST([GLU_DIRS])
 879 AC_SUBST([DRIVER_DIRS])
 880 AC_SUBST([GALLIUM_DIRS])
 881 AC_SUBST([GALLIUM_TARGET_DIRS])
 882 AC_SUBST([GALLIUM_WINSYS_DIRS])
 883 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 884 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 885 AC_SUBST([MESA_LLVM])
 886
 887 # Check for libdrm
 888 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 889                   [have_libdrm=yes], [have_libdrm=no])
 890
 891 if test "x$enable_dri" = xyes; then
 892     # DRI must be shared, I think
 893     if test "$enable_static" = yes; then
 894         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 895     fi
 896
 897     # not a hard requirement as swrast does not depend on it
 898     if test "x$have_libdrm" = xyes; then
 899         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 900     fi
 901 fi
 902
 903 dnl
 904 dnl Find out if X is available. The variable have_x is set if libX11 is
 905 dnl found to mimic AC_PATH_XTRA.
 906 dnl
 907 if test -n "$PKG_CONFIG"; then
 908     AC_MSG_CHECKING([pkg-config files for X11 are available])
 909     PKG_CHECK_EXISTS([x11],[
 910         x11_pkgconfig=yes
 911         have_x=yes
 912         ],[
 913         x11_pkgconfig=no
 914     ])
 915     AC_MSG_RESULT([$x11_pkgconfig])
 916 else
 917     x11_pkgconfig=no
 918 fi
 919 dnl Use the autoconf macro if no pkg-config files
 920 if test "$x11_pkgconfig" = yes; then
 921     PKG_CHECK_MODULES([X11], [x11])
 922 else
 923     AC_PATH_XTRA
 924     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 925     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 926     AC_SUBST([X11_CFLAGS])
 927     AC_SUBST([X11_LIBS])
 928 fi
 929
 930 dnl Try to tell the user that the --x-* options are only used when
 931 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 932 m4_divert_once([HELP_BEGIN],
 933 [These options are only used when the X libraries cannot be found by the
 934 pkg-config utility.])
 935
 936 dnl We need X for xlib and dri, so bomb now if it's not found
 937 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 938     AC_MSG_ERROR([X11 development libraries needed for GLX])
 939 fi
 940
 941 if test "x$enable_glx" = xyes; then
 942     DEFINES="$DEFINES -DUSE_XCB"
 943 fi
 944
 945 dnl Direct rendering or just indirect rendering
 946 case "$host_os" in
 947 gnu*)
 948     dnl Disable by default on GNU/Hurd
 949     driglx_direct_default="no"
 950     ;;
 951 cygwin*)
 952     dnl Disable by default on cygwin
 953     driglx_direct_default="no"
 954     ;;
 955 *)
 956     driglx_direct_default="yes"
 957     ;;
 958 esac
 959 AC_ARG_ENABLE([driglx-direct],
 960     [AS_HELP_STRING([--disable-driglx-direct],
 961         [enable direct rendering in GLX and EGL for DRI \
 962             @<:@default=auto@:>@])],
 963     [driglx_direct="$enableval"],
 964     [driglx_direct="$driglx_direct_default"])
 965
 966 dnl
 967 dnl libGL configuration per driver
 968 dnl
 969 case "x$enable_glx$enable_xlib_glx" in
 970 xyesyes)
 971     # Xlib-based GLX
 972     if test "$x11_pkgconfig" = yes; then
 973         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 974         GL_PC_REQ_PRIV="x11 xext"
 975         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 976         GL_LIB_DEPS="$XLIBGL_LIBS"
 977     else
 978         # should check these...
 979         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 980         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 981         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 982         GL_PC_CFLAGS="$X11_INCLUDES"
 983     fi
 984     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 985     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 986     ;;
 987 xyesno)
 988     # DRI-based GLX
 989     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 990     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 991     if test x"$driglx_direct" = xyes; then
 992         if test "x$have_libdrm" != xyes; then
 993             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 994         fi
 995         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 996         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 997     fi
 998
 999     # find the DRI deps for libGL
1000     if test "$x11_pkgconfig" = yes; then
1001         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
1002
1003         # add xf86vidmode if available
1004         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1005         if test "$HAVE_XF86VIDMODE" = yes ; then
1006             dri_modules="$dri_modules xxf86vm"
1007         fi
1008
1009         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1010         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1011         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1012         GL_LIB_DEPS="$DRIGL_LIBS"
1013     else
1014         # should check these...
1015         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1016         if test "x$HAVE_XF86VIDMODE" == xyes; then
1017            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1018         else
1019            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1020         fi
1021         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1022         GL_PC_CFLAGS="$X11_INCLUDES"
1023
1024         # XCB can only be used from pkg-config
1025         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx >= 1.8.1])
1026         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1027         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1028         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1029     fi
1030
1031     # need DRM libs, -lpthread, etc.
1032     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1033     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1034     ;;
1035 esac
1036
1037 # This is outside the case (above) so that it is invoked even for non-GLX
1038 # builds.
1039 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1040
1041 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1042 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1043 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1044 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1045
1046 AC_SUBST([GL_LIB_DEPS])
1047 AC_SUBST([GL_PC_REQ_PRIV])
1048 AC_SUBST([GL_PC_LIB_PRIV])
1049 AC_SUBST([GL_PC_CFLAGS])
1050 AC_SUBST([DRI_PC_REQ_PRIV])
1051 AC_SUBST([GLESv1_CM_LIB_DEPS])
1052 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1053 AC_SUBST([GLESv2_LIB_DEPS])
1054 AC_SUBST([GLESv2_PC_LIB_PRIV])
1055
1056 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1057 AC_SUBST([GLAPI_LIB_DEPS])
1058
1059
1060 dnl dri libraries are linking with mesa
1061 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.la'
1062 GALLIUM_DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1063
1064 dnl ... or dricore?
1065 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1066     DRI_LIB_DEPS="\$(TOP)/src/mesa/libdricore/libdricore${VERSION}.la"
1067     GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
1068     HAVE_DRICORE=yes
1069 fi
1070 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
1071
1072 AC_SUBST([HAVE_XF86VIDMODE])
1073
1074 dnl
1075 dnl More GLX setup
1076 dnl
1077 case "x$enable_glx$enable_xlib_glx" in
1078 xyesyes)
1079     DEFINES="$DEFINES -DUSE_XSHM"
1080     ;;
1081 xyesno)
1082     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1083     if test "x$driglx_direct" = xyes; then
1084         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1085     fi
1086     ;;
1087 esac
1088
1089 dnl
1090 dnl TLS detection
1091 dnl
1092
1093 AC_ARG_ENABLE([glx-tls],
1094     [AS_HELP_STRING([--enable-glx-tls],
1095         [enable TLS support in GLX @<:@default=disabled@:>@])],
1096     [GLX_USE_TLS="$enableval"],
1097     [GLX_USE_TLS=no])
1098 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1099
1100 AS_IF([test "x$GLX_USE_TLS" = xyes],
1101       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1102
1103 dnl
1104 dnl More DRI setup
1105 dnl
1106 dnl Directory for DRI drivers
1107 AC_ARG_WITH([dri-driverdir],
1108     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1109         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1110     [DRI_DRIVER_INSTALL_DIR="$withval"],
1111     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1112 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1113 dnl Extra search path for DRI drivers
1114 AC_ARG_WITH([dri-searchpath],
1115     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1116         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1117     [DRI_DRIVER_SEARCH_DIR="$withval"],
1118     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1119 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1120 dnl Which drivers to build - default is chosen by platform
1121 AC_ARG_WITH([dri-drivers],
1122     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1123         [comma delimited DRI drivers list, e.g.
1124         "swrast,i965,radeon" @<:@default=auto@:>@])],
1125     [with_dri_drivers="$withval"],
1126     [with_dri_drivers=yes])
1127 if test "x$with_dri_drivers" = x; then
1128     with_dri_drivers=no
1129 fi
1130
1131 dnl If $with_dri_drivers is yes, directories will be added through
1132 dnl platform checks
1133 DRI_DIRS=""
1134 case "$with_dri_drivers" in
1135 no) ;;
1136 yes)
1137     # classic DRI drivers require FEATURE_GL to build
1138     if test "x$enable_opengl" = xyes; then
1139         DRI_DIRS="yes"
1140     fi
1141     ;;
1142 *)
1143     # verify the requested driver directories exist
1144     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1145     for driver in $dri_drivers; do
1146         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1147             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1148     done
1149     DRI_DIRS="$dri_drivers"
1150     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1151         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1152     fi
1153     ;;
1154 esac
1155
1156 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1157 if test "x$enable_dri" = xyes; then
1158     # Platform specific settings and drivers to build
1159     case "$host_os" in
1160     linux*)
1161         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1162         DEFINES="$DEFINES -DHAVE_ALIAS"
1163
1164         case "$host_cpu" in
1165         x86_64)
1166             if test "x$DRI_DIRS" = "xyes"; then
1167                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1168             fi
1169             ;;
1170         powerpc*)
1171             # Build only the drivers for cards that exist on PowerPC.
1172             if test "x$DRI_DIRS" = "xyes"; then
1173                 DRI_DIRS="r200 radeon swrast"
1174             fi
1175             ;;
1176         sparc*)
1177             # Build only the drivers for cards that exist on sparc
1178             if test "x$DRI_DIRS" = "xyes"; then
1179                 DRI_DIRS="r200 radeon swrast"
1180             fi
1181             ;;
1182         esac
1183         ;;
1184     freebsd* | dragonfly* | *netbsd*)
1185         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1186         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1187
1188         if test "x$DRI_DIRS" = "xyes"; then
1189             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1190         fi
1191         ;;
1192     gnu*)
1193         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1194         DEFINES="$DEFINES -DHAVE_ALIAS"
1195         ;;
1196     solaris*)
1197         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1198         ;;
1199     cygwin*)
1200         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1201         if test "x$DRI_DIRS" = "xyes"; then
1202             DRI_DIRS="swrast"
1203         fi
1204         ;;
1205     esac
1206
1207     # default drivers
1208     if test "x$DRI_DIRS" = "xyes"; then
1209         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1210     fi
1211
1212     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1213
1214     # Check for expat
1215     if test "x$enable_dri" = xyes; then
1216         EXPAT_INCLUDES=""
1217         EXPAT_LIB=-lexpat
1218         AC_ARG_WITH([expat],
1219             [AS_HELP_STRING([--with-expat=DIR],
1220                 [expat install directory])],[
1221             EXPAT_INCLUDES="-I$withval/include"
1222             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1223             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1224             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1225             ])
1226         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1227         save_LIBS="$LIBS"
1228         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1229             [AC_MSG_ERROR([Expat required for DRI.])])
1230         LIBS="$save_LIBS"
1231     fi
1232
1233     # if we are building any dri driver other than swrast ...
1234     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1235         # ... libdrm is required
1236         if test "x$have_libdrm" != xyes; then
1237             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1238         fi
1239         # ... and build dricommon
1240         HAVE_COMMON_DRI=yes
1241     fi
1242
1243     # put all the necessary libs together
1244     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1245     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1246 fi
1247 AC_SUBST([DRI_DIRS])
1248 AC_SUBST([EXPAT_INCLUDES])
1249 AC_SUBST([DRI_LIB_DEPS])
1250 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1251
1252 case $DRI_DIRS in
1253 *i915*|*i965*)
1254     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1255
1256     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1257         case $d in
1258         i915)
1259             HAVE_I915_DRI=yes;
1260             ;;
1261         i965)
1262             HAVE_I965_DRI=yes;
1263             ;;
1264         esac
1265     done
1266
1267     ;;
1268 esac
1269
1270 case $DRI_DIRS in
1271 *nouveau*)
1272     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1273     HAVE_NOUVEAU_DRI=yes;
1274     ;;
1275 esac
1276
1277 case $DRI_DIRS in
1278 *radeon*|*r200*)
1279     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1280
1281     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1282         case $d in
1283         radeon)
1284             HAVE_RADEON_DRI=yes;
1285             ;;
1286         r200)
1287             HAVE_R200_DRI=yes;
1288             ;;
1289         esac
1290     done
1291
1292     ;;
1293 esac
1294
1295 case $DRI_DIRS in
1296 *swrast*)
1297     HAVE_SWRAST_DRI=yes;
1298     ;;
1299 esac
1300
1301 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1302 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1303 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1304 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1305 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1306 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1307 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1308
1309 dnl
1310 dnl OSMesa configuration
1311 dnl
1312
1313 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1314 AC_ARG_WITH([osmesa-bits],
1315     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1316         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1317     [osmesa_bits="$withval"],
1318     [osmesa_bits=8])
1319 if test "x$osmesa_bits" != x8; then
1320     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1321         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1322         osmesa_bits=8
1323     fi
1324 fi
1325 case "x$osmesa_bits" in
1326 x8)
1327     OSMESA_LIB="${OSMESA_LIB}"
1328     ;;
1329 x16|x32)
1330     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1331     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1332     ;;
1333 *)
1334     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1335     ;;
1336 esac
1337
1338 if test "x$enable_osmesa" = xyes; then
1339     # only link libraries with osmesa if shared
1340     if test "$enable_static" = no; then
1341         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1342     else
1343         OSMESA_LIB_DEPS=""
1344     fi
1345     OSMESA_MESA_DEPS=""
1346     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1347 fi
1348
1349 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1350
1351 AC_SUBST([OSMESA_LIB_DEPS])
1352 AC_SUBST([OSMESA_MESA_DEPS])
1353 AC_SUBST([OSMESA_PC_REQ])
1354 AC_SUBST([OSMESA_PC_LIB_PRIV])
1355 AC_SUBST([OSMESA_VERSION])
1356
1357 dnl
1358 dnl gbm configuration
1359 dnl
1360 if test "x$enable_gbm" = xauto; then
1361     case "$with_egl_platforms" in
1362         *drm*)
1363             enable_gbm=yes ;;
1364          *)
1365             enable_gbm=no ;;
1366     esac
1367 fi
1368 if test "x$enable_gbm" = xyes; then
1369     SRC_DIRS="$SRC_DIRS gbm"
1370
1371     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1372                       AC_MSG_ERROR([gbm needs udev]))
1373
1374     if test "x$enable_dri" = xyes; then
1375         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1376         if test "$SHARED_GLAPI" -eq 0; then
1377             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1378         fi
1379     fi
1380 fi
1381 GBM_PC_REQ_PRIV="libudev"
1382 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1383 AC_SUBST([GBM_PC_REQ_PRIV])
1384 AC_SUBST([GBM_PC_LIB_PRIV])
1385
1386 dnl
1387 dnl EGL configuration
1388 dnl
1389 EGL_CLIENT_APIS=""
1390
1391 if test "x$enable_egl" = xyes; then
1392     SRC_DIRS="$SRC_DIRS egl"
1393     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1394
1395     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1396
1397     if test "$enable_static" != yes; then
1398         # build egl_glx when libGL is built
1399         if test "x$enable_glx" = xyes; then
1400             HAVE_EGL_DRIVER_GLX=1
1401         fi
1402
1403         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1404                           [have_libudev=yes],[have_libudev=no])
1405         if test "$have_libudev" = yes; then
1406             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1407         fi
1408
1409         if test "x$enable_dri" = xyes; then
1410             HAVE_EGL_DRIVER_DRI2=1
1411         fi
1412
1413     fi
1414 fi
1415 AC_SUBST([EGL_LIB_DEPS])
1416
1417 dnl
1418 dnl EGL Gallium configuration
1419 dnl
1420 if test "x$enable_gallium_egl" = xyes; then
1421     if test "x$with_gallium_drivers" = x; then
1422         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1423     fi
1424     if test "x$enable_egl" = xno; then
1425         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1426     fi
1427     if test "x$have_libdrm" != xyes; then
1428         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1429     fi
1430
1431     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1432     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1433     HAVE_ST_EGL="yes"
1434 fi
1435
1436 dnl
1437 dnl gbm Gallium configuration
1438 dnl
1439 if test "x$enable_gallium_gbm" = xauto; then
1440     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1441         yesyesyes*drm*)
1442             enable_gallium_gbm=yes ;;
1443          *)
1444             enable_gallium_gbm=no ;;
1445     esac
1446 fi
1447 if test "x$enable_gallium_gbm" = xyes; then
1448     if test "x$with_gallium_drivers" = x; then
1449         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1450     fi
1451     if test "x$enable_gbm" = xno; then
1452         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1453     fi
1454     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1455     if test "x$enable_dri" = xno; then
1456         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1457     fi
1458
1459     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1460     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1461     HAVE_ST_GBM="yes"
1462     enable_gallium_loader=yes
1463 fi
1464
1465 dnl
1466 dnl X.Org DDX configuration
1467 dnl
1468 if test "x$enable_xorg" = xyes; then
1469     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1470     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1471     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1472     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1473         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1474         HAVE_XEXTPROTO_71="no")
1475     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1476     HAVE_ST_XORG=yes
1477 fi
1478
1479 dnl
1480 dnl XA configuration
1481 dnl
1482 if test "x$enable_xa" = xyes; then
1483 AC_PROG_AWK
1484 AC_PROG_GREP
1485 AC_CHECK_PROG(NM, nm, "nm")
1486 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1487 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1488 enable_xa=no
1489 fi
1490 fi
1491 if test "x$enable_xa" = xyes; then
1492     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1493     HAVE_ST_XA=yes
1494     AC_SUBST(AWK)
1495     AC_SUBST(GREP)
1496     AC_SUBST(NM)
1497 fi
1498
1499 dnl
1500 dnl OpenVG configuration
1501 dnl
1502 VG_LIB_DEPS=""
1503
1504 if test "x$enable_openvg" = xyes; then
1505     if test "x$enable_egl" = xno; then
1506         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1507     fi
1508     if test "x$with_gallium_drivers" = x; then
1509         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1510     fi
1511     if test "x$enable_gallium_egl" = xno; then
1512         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1513     fi
1514
1515     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1516     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1517     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1518     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1519     HAVE_ST_VEGA=yes
1520 fi
1521
1522 dnl
1523 dnl D3D1X configuration
1524 dnl
1525
1526 if test "x$enable_d3d1x" = xyes; then
1527     if test "x$with_gallium_drivers" = x; then
1528         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1529     fi
1530
1531     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1532     HAVE_ST_D3D1X=yes
1533 fi
1534
1535 dnl
1536 dnl Gallium G3DVL configuration
1537 dnl
1538 AC_ARG_ENABLE([gallium-g3dvl],
1539     [AS_HELP_STRING([--enable-gallium-g3dvl],
1540         [build gallium g3dvl @<:@default=disabled@:>@])],
1541     [enable_gallium_g3dvl="$enableval"],
1542     [enable_gallium_g3dvl=no])
1543 if test "x$enable_gallium_g3dvl" = xyes; then
1544     if test "x$with_gallium_drivers" = x; then
1545         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1546     fi
1547
1548     if test "x$enable_xvmc" = xauto; then
1549         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1550     fi
1551
1552     if test "x$enable_vdpau" = xauto; then
1553         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1554     fi
1555
1556     if test "x$enable_va" = xauto; then
1557         #don't enable vaapi state tracker even if package exists
1558         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1559         enable_va=no
1560     fi
1561 fi
1562
1563 if test "x$enable_xvmc" = xyes; then
1564     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1565     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1566     HAVE_ST_XVMC="yes"
1567 fi
1568
1569 if test "x$enable_vdpau" = xyes; then
1570     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1571     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1572     HAVE_ST_VDPAU="yes"
1573 fi
1574
1575 if test "x$enable_va" = xyes; then
1576     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1577     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1578     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1579     HAVE_ST_VA="yes"
1580 fi
1581
1582 dnl
1583 dnl OpenCL configuration
1584 dnl
1585
1586 AC_ARG_WITH([libclc-path],
1587    [AS_HELP_STRING([--with-libclc-path],
1588          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1589    [LIBCLC_PATH="$withval"],
1590    [LIBCLC_PATH=""])
1591
1592 AC_ARG_WITH([clang-libdir],
1593    [AS_HELP_STRING([--with-clang-libdir],
1594          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1595    [CLANG_LIBDIR="$withval"],
1596    [CLANG_LIBDIR=""])
1597
1598 AC_SUBST([LIBCLC_PATH])
1599
1600 if test "x$enable_opencl" = xyes; then
1601     if test "x$with_gallium_drivers" = x; then
1602         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1603     fi
1604
1605     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1606         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1607     fi
1608
1609     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1610     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1611     enable_gallium_loader=yes
1612 fi
1613
1614 dnl
1615 dnl GLU configuration
1616 dnl
1617 AC_ARG_ENABLE([glu],
1618     [AS_HELP_STRING([--disable-glu],
1619         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1620     [enable_glu="$enableval"],
1621     [enable_glu=yes])
1622
1623 if test "x$enable_glu" = xyes; then
1624     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1625         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1626         enable_glu=no
1627     fi
1628 fi
1629
1630 if test "x$enable_glu" = xyes; then
1631     SRC_DIRS="$SRC_DIRS glu"
1632
1633     if test "x$enable_glx" = xno; then
1634         # Link libGLU to libOSMesa instead of libGL
1635         GLU_LIB_DEPS=""
1636         GLU_PC_REQ="osmesa"
1637         if test "$enable_static" = no; then
1638             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1639         else
1640             GLU_MESA_DEPS=""
1641         fi
1642     else
1643         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1644         GLU_PC_REQ="gl"
1645         GLU_PC_LIB_PRIV="-lm"
1646         if test "$enable_static" = no; then
1647             GLU_LIB_DEPS="-lm"
1648             GLU_MESA_DEPS='-l$(GL_LIB)'
1649         else
1650             GLU_LIB_DEPS=""
1651             GLU_MESA_DEPS=""
1652         fi
1653     fi
1654 fi
1655 if test "$enable_static" = no; then
1656     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1657 fi
1658 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1659 AC_SUBST([GLU_LIB_DEPS])
1660 AC_SUBST([GLU_MESA_DEPS])
1661 AC_SUBST([GLU_PC_REQ])
1662 AC_SUBST([GLU_PC_REQ_PRIV])
1663 AC_SUBST([GLU_PC_LIB_PRIV])
1664 AC_SUBST([GLU_PC_CFLAGS])
1665
1666 AC_SUBST([PROGRAM_DIRS])
1667
1668 dnl
1669 dnl Gallium configuration
1670 dnl
1671 if test "x$with_gallium_drivers" != x; then
1672     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1673 fi
1674
1675 AC_SUBST([LLVM_BINDIR])
1676 AC_SUBST([LLVM_CFLAGS])
1677 AC_SUBST([LLVM_CPPFLAGS])
1678 AC_SUBST([LLVM_CXXFLAGS])
1679 AC_SUBST([LLVM_LIBDIR])
1680 AC_SUBST([LLVM_LIBS])
1681 AC_SUBST([LLVM_LDFLAGS])
1682 AC_SUBST([LLVM_INCLUDEDIR])
1683 AC_SUBST([LLVM_VERSION])
1684 AC_SUBST([CLANG_RESOURCE_DIR])
1685
1686 case "x$enable_opengl$enable_gles1$enable_gles2" in
1687 x*yes*)
1688     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1689     ;;
1690 esac
1691
1692 AC_SUBST([VG_LIB_DEPS])
1693 AC_SUBST([EGL_CLIENT_APIS])
1694
1695 dnl
1696 dnl EGL Platforms configuration
1697 dnl
1698 AC_ARG_WITH([egl-platforms],
1699     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1700         [comma delimited native platforms libEGL supports, e.g.
1701         "x11,drm" @<:@default=auto@:>@])],
1702     [with_egl_platforms="$withval"],
1703     [if test "x$enable_egl" = xyes; then
1704         with_egl_platforms="x11"
1705     else
1706         with_egl_platforms=""
1707     fi])
1708
1709 EGL_PLATFORMS=""
1710
1711 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1712     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1713 fi
1714
1715 # Do per-EGL platform setups and checks
1716 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1717 for plat in $egl_platforms; do
1718         case "$plat" in
1719         fbdev|null)
1720                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1721                 ;;
1722
1723         wayland)
1724                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1725                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1726                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1727
1728                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1729                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1730                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1731                 ;;
1732
1733         x11)
1734                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1735                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1736                 save_LIBS="$LIBS"
1737                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1738                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1739                 LIBS="$save_LIBS"
1740                 ;;
1741
1742         drm)
1743                 test "x$enable_gbm" = "xno" &&
1744                         AC_MSG_ERROR([EGL platform drm needs gbm])
1745                 ;;
1746
1747         android|gdi)
1748                 ;;
1749
1750         *)
1751                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1752                 ;;
1753         esac
1754
1755         case "$plat$have_libudev" in
1756                 waylandno|drmno)
1757                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1758         esac
1759 done
1760
1761 # libEGL wants to default to the first platform specified in
1762 # ./configure.  parse that here.
1763 if test "x$egl_platforms" != "x"; then
1764     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1765     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1766 else
1767     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1768 fi
1769
1770 EGL_PLATFORMS="$egl_platforms"
1771
1772 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1773 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1774 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1775 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1776 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1777
1778 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1779 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1780
1781 AC_SUBST([EGL_NATIVE_PLATFORM])
1782 AC_SUBST([EGL_PLATFORMS])
1783 AC_SUBST([EGL_CFLAGS])
1784
1785 AC_ARG_WITH([egl-driver-dir],
1786     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1787                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1788     [EGL_DRIVER_INSTALL_DIR="$withval"],
1789     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1790 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1791
1792 AC_ARG_WITH([xorg-driver-dir],
1793     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1794                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1795     [XORG_DRIVER_INSTALL_DIR="$withval"],
1796     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1797 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1798
1799 AC_ARG_WITH([max-width],
1800     [AS_HELP_STRING([--with-max-width=N],
1801                     [Maximum framebuffer width (4096)])],
1802     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1803      AS_IF([test "${withval}" -gt "4096"],
1804            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1805 )
1806 AC_ARG_WITH([max-height],
1807     [AS_HELP_STRING([--with-max-height=N],
1808                     [Maximum framebuffer height (4096)])],
1809     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1810      AS_IF([test "${withval}" -gt "4096"],
1811            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1812 )
1813
1814 dnl
1815 dnl Gallium LLVM
1816 dnl
1817 AC_ARG_ENABLE([gallium-llvm],
1818     [AS_HELP_STRING([--enable-gallium-llvm],
1819         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1820     [enable_gallium_llvm="$enableval"],
1821     [enable_gallium_llvm=auto])
1822
1823 AC_ARG_WITH([llvm-shared-libs],
1824     [AS_HELP_STRING([--with-llvm-shared-libs],
1825         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1826     [with_llvm_shared_libs=yes],
1827     [with_llvm_shared_libs=no])
1828
1829 AC_ARG_WITH([llvm-prefix],
1830     [AS_HELP_STRING([--with-llvm-prefix],
1831         [Prefix for LLVM installations in non-standard locations])],
1832     [llvm_prefix="$withval"],
1833     [llvm_prefix=""])
1834
1835
1836 if test "x$with_gallium_drivers" = x; then
1837     enable_gallium_llvm=no
1838 fi
1839 if test "x$enable_gallium_llvm" = xauto; then
1840     case "$host_cpu" in
1841     i*86|x86_64) enable_gallium_llvm=yes;;
1842     esac
1843 fi
1844 if test "x$enable_gallium_llvm" = xyes; then
1845     if test "x$llvm_prefix" != x; then
1846         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1847     else
1848         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1849     fi
1850
1851     if test "x$LLVM_CONFIG" != xno; then
1852         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1853         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1854         if test "x$with_llvm_shared_libs" = xyes; then
1855             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1856             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1857         else
1858             LLVM_COMPONENTS="engine bitwriter"
1859             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1860                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1861             fi
1862             if test "x$enable_opencl" = xyes; then
1863                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1864             fi
1865             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1866         fi
1867         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1868         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1869         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1870         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1871         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1872         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1873         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1874         MESA_LLVM=1
1875
1876         dnl Check for Clang interanl headers
1877         if test "x$enable_opencl" = xyes; then
1878             if test "x$CLANG_LIBDIR" = x; then
1879                 CLANG_LIBDIR=${LLVM_LIBDIR}
1880             fi
1881             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1882             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1883                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1884         fi
1885     else
1886         MESA_LLVM=0
1887     fi
1888 else
1889     MESA_LLVM=0
1890 fi
1891
1892 dnl Directory for XVMC libs
1893 AC_ARG_WITH([xvmc-libdir],
1894     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1895         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1896     [XVMC_LIB_INSTALL_DIR="$withval"],
1897     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1898 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1899
1900 dnl
1901 dnl Gallium Tests
1902 dnl
1903 if test "x$enable_gallium_tests" = xyes; then
1904     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1905     enable_gallium_loader=yes
1906 fi
1907
1908 dnl Directory for VDPAU libs
1909 AC_ARG_WITH([vdpau-libdir],
1910     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1911         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1912     [VDPAU_LIB_INSTALL_DIR="$withval"],
1913     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1914 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1915
1916 dnl Directory for VA libs
1917 AC_ARG_WITH([va-libdir],
1918     [AS_HELP_STRING([--with-va-libdir=DIR],
1919         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1920     [VA_LIB_INSTALL_DIR="$withval"],
1921     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1922 AC_SUBST([VA_LIB_INSTALL_DIR])
1923
1924 dnl Directory for OpenCL libs
1925 AC_ARG_WITH([opencl-libdir],
1926     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1927         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1928     [OPENCL_LIB_INSTALL_DIR="$withval"],
1929     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1930 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1931
1932 dnl
1933 dnl Gallium helper functions
1934 dnl
1935 gallium_check_st() {
1936     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1937          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1938          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1939          if test "x$have_libdrm" != xyes; then
1940             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1941          fi
1942          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1943     fi
1944     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1945          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1946     fi
1947     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1948          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1949     fi
1950     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1951          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1952     fi
1953     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1954          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1955     fi
1956     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1957          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1958     fi
1959     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1960          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1961     fi
1962 }
1963
1964 gallium_require_llvm() {
1965     if test "x$MESA_LLVM" = x0; then
1966         case "$host_cpu" in
1967         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1968         esac
1969     fi
1970 }
1971
1972 gallium_require_drm_loader() {
1973     if test "x$enable_gallium_loader" = xyes; then
1974         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1975                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1976         if test "x$have_libdrm" != xyes; then
1977             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1978         fi
1979         enable_gallium_drm_loader=yes
1980     fi
1981 }
1982
1983 dnl Gallium drivers
1984 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1985 if test "x$with_gallium_drivers" != x; then
1986     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1987     for driver in $gallium_drivers; do
1988         case "x$driver" in
1989         xsvga)
1990             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1991             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1992             ;;
1993         xi915)
1994             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1995             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1996             if test "x$MESA_LLVM" = x1; then
1997                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1998             fi
1999             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
2000             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
2001             ;;
2002         xr300)
2003             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2004             gallium_require_llvm "Gallium R300"
2005             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
2006             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
2007             ;;
2008         xr600)
2009             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2010             gallium_require_drm_loader
2011             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
2012             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2013                 if test "x$LLVM_VERSION" != "x3.1"; then
2014                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
2015                 fi
2016                 NEED_RADEON_GALLIUM=yes;
2017             fi
2018             if test "x$enable_r600_llvm" = xyes; then
2019                 USE_R600_LLVM_COMPILER=yes;
2020             fi
2021             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
2022                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
2023             fi
2024             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
2025             ;;
2026         xradeonsi)
2027             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2028             gallium_require_drm_loader
2029             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
2030             if test "x$LLVM_VERSION" != "x3.1"; then
2031                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
2032             fi
2033             NEED_RADEON_GALLIUM=yes;
2034             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
2035             ;;
2036         xnouveau)
2037             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2038             gallium_require_drm_loader
2039             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
2040             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
2041             ;;
2042         xswrast)
2043             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2044             if test "x$MESA_LLVM" = x1; then
2045                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2046             fi
2047
2048             if test "x$HAVE_ST_DRI" = xyes; then
2049                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2050             fi
2051             if test "x$HAVE_ST_VDPAU" = xyes; then
2052                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2053             fi
2054             if test "x$HAVE_ST_XVMC" = xyes; then
2055                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2056             fi
2057             if test "x$HAVE_ST_VA" = xyes; then
2058                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2059             fi
2060             if test "x$HAVE_ST_VDPAU" = xyes ||
2061                test "x$HAVE_ST_XVMC" = xyes ||
2062                test "x$HAVE_ST_VA" = xyes; then
2063                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2064                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2065                fi
2066             fi
2067             ;;
2068         *)
2069             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2070             ;;
2071         esac
2072     done
2073 fi
2074
2075 if test "x$enable_gallium_loader" = xyes; then
2076     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2077     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2078     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2079     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2080
2081     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2082         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2083         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2084     fi
2085
2086     if test "x$enable_gallium_drm_loader" = xyes; then
2087         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2088         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2089                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2090         if test "x$pipe_loader_have_xcb" = xyes; then
2091             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
2092             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2093         fi
2094     fi
2095
2096     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2097     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2098 fi
2099
2100 dnl Tell Automake which drivers to build
2101 for driver in $GALLIUM_DRIVERS_DIRS; do
2102     case "x$driver" in
2103         xgalahad)
2104             HAVE_GALAHAD_GALLIUM=yes;
2105             ;;
2106         xidentity)
2107             HAVE_IDENTITY_GALLIUM=yes;
2108             ;;
2109         xnoop)
2110             HAVE_NOOP_GALLIUM=yes;
2111             ;;
2112         *)
2113             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2114             ;;
2115     esac
2116 done
2117
2118 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2119 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2120 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2121 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2122 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2123 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2124 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2125 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2126 AC_SUBST([GALLIUM_MAKE_DIRS])
2127
2128 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2129 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2130 AM_CONDITIONAL(HAVE_OSMESA_DRIVER, echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1)
2131
2132 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2133 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2134 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2135
2136 dnl prepend CORE_DIRS to SRC_DIRS
2137 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2138
2139 dnl Restore LDFLAGS and CPPFLAGS
2140 LDFLAGS="$_SAVE_LDFLAGS"
2141 CPPFLAGS="$_SAVE_CPPFLAGS"
2142
2143 dnl Add user CFLAGS and CXXFLAGS
2144 CFLAGS="$CFLAGS $USER_CFLAGS"
2145 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2146
2147 dnl Substitute the config
2148 AC_CONFIG_FILES([configs/current
2149                 Makefile
2150                 src/Makefile
2151                 src/gallium/Makefile
2152                 src/gallium/auxiliary/pipe-loader/Makefile
2153                 src/gallium/state_trackers/clover/Makefile
2154                 src/gallium/drivers/Makefile
2155                 src/gallium/drivers/r300/Makefile
2156                 src/gallium/drivers/r600/Makefile
2157                 src/gallium/targets/opencl/Makefile
2158                 src/gbm/Makefile
2159                 src/gbm/main/gbm.pc
2160                 src/egl/drivers/Makefile
2161                 src/egl/drivers/dri2/Makefile
2162                 src/egl/drivers/glx/Makefile
2163                 src/egl/Makefile
2164                 src/egl/main/Makefile
2165                 src/egl/main/egl.pc
2166                 src/egl/wayland/Makefile
2167                 src/egl/wayland/wayland-egl/Makefile
2168                 src/egl/wayland/wayland-egl/wayland-egl.pc
2169                 src/egl/wayland/wayland-drm/Makefile
2170                 src/glsl/Makefile
2171                 src/glsl/glcpp/Makefile
2172                 src/glsl/tests/Makefile
2173                 src/glx/Makefile
2174                 src/glx/tests/Makefile
2175                 src/mapi/glapi/Makefile
2176                 src/mapi/glapi/gen/Makefile
2177                 src/mapi/shared-glapi/Makefile
2178                 src/mapi/glapi/tests/Makefile
2179                 src/gtest/Makefile
2180                 src/mesa/Makefile
2181                 src/mesa/libdricore/Makefile
2182                 src/mesa/main/tests/Makefile
2183                 src/mesa/x86/Makefile
2184                 src/mesa/x86-64/Makefile
2185                 src/mesa/drivers/Makefile
2186                 src/mesa/drivers/dri/dri.pc
2187                 src/mesa/drivers/dri/Makefile
2188                 src/mesa/drivers/dri/common/Makefile
2189                 src/mesa/drivers/dri/i915/Makefile
2190                 src/mesa/drivers/dri/i965/Makefile
2191                 src/mesa/drivers/dri/nouveau/Makefile
2192                 src/mesa/drivers/dri/r200/Makefile
2193                 src/mesa/drivers/dri/radeon/Makefile
2194                 src/mesa/drivers/dri/swrast/Makefile
2195                 src/mesa/drivers/osmesa/Makefile
2196                 src/mesa/drivers/x11/Makefile
2197                 src/mesa/gl.pc
2198                 src/mesa/osmesa.pc])
2199
2200 dnl Sort the dirs alphabetically
2201 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2202 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2203 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2204 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2205 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2206
2207 AC_OUTPUT
2208
2209 dnl
2210 dnl Output some configuration info for the user
2211 dnl
2212 echo ""
2213 echo "        prefix:          $prefix"
2214 echo "        exec_prefix:     $exec_prefix"
2215 echo "        libdir:          $libdir"
2216 echo "        includedir:      $includedir"
2217
2218 dnl API info
2219 echo ""
2220 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2221 echo "        OpenVG:          $enable_openvg"
2222
2223 dnl Driver info
2224 echo ""
2225 if test "x$enable_osmesa" != xno; then
2226         echo "        OSMesa:          lib$OSMESA_LIB"
2227 else
2228         echo "        OSMesa:          no"
2229 fi
2230
2231 if test "x$enable_dri" != xno; then
2232         # cleanup the drivers var
2233         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2234         if test "x$DRI_DIRS" = x; then
2235             echo "        DRI drivers:     no"
2236         else
2237             echo "        DRI drivers:     $dri_dirs"
2238         fi
2239         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2240 fi
2241
2242 case "x$enable_glx$enable_xlib_glx" in
2243 xyesyes)
2244     echo "        GLX:             Xlib-based"
2245     ;;
2246 xyesno)
2247     echo "        GLX:             DRI-based"
2248     ;;
2249 *)
2250     echo "        GLX:             $enable_glx"
2251     ;;
2252 esac
2253
2254 echo ""
2255 echo "        GLU:             $enable_glu"
2256
2257 dnl EGL
2258 echo ""
2259 echo "        EGL:             $enable_egl"
2260 if test "$enable_egl" = yes; then
2261     echo "        EGL platforms:   $EGL_PLATFORMS"
2262
2263     egl_drivers=""
2264     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2265         egl_drivers="$egl_drivers builtin:egl_glx"
2266     fi
2267     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2268         egl_drivers="$egl_drivers builtin:egl_dri2"
2269     fi
2270
2271     if test "x$HAVE_ST_EGL" = xyes; then
2272         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2273         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2274     else
2275         echo "        EGL drivers:    $egl_drivers"
2276     fi
2277 fi
2278
2279 echo ""
2280 if test "x$MESA_LLVM" = x1; then
2281     echo "        llvm:            yes"
2282     echo "        llvm-config:     $LLVM_CONFIG"
2283     echo "        llvm-version:    $LLVM_VERSION"
2284 else
2285     echo "        llvm:            no"
2286 fi
2287
2288 echo ""
2289 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2290     echo "        Gallium:         yes"
2291     echo "        Gallium dirs:    $GALLIUM_DIRS"
2292     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2293     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2294     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2295     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2296 else
2297     echo "        Gallium:         no"
2298 fi
2299
2300
2301 dnl Libraries
2302 echo ""
2303 echo "        Shared libs:     $enable_shared"
2304 echo "        Static libs:     $enable_static"
2305
2306 dnl Compiler options
2307 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2308 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2309     $SED 's/^ *//;s/  */ /;s/ *$//'`
2310 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2311     $SED 's/^ *//;s/  */ /;s/ *$//'`
2312 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2313 echo ""
2314 echo "        CFLAGS:          $cflags"
2315 echo "        CXXFLAGS:        $cxxflags"
2316 echo "        Macros:          $defines"
2317 echo ""
2318 echo "        PYTHON2:         $PYTHON2"
2319
2320 echo ""
2321 echo "        Run '${MAKE-make}' to build Mesa"
2322 echo ""