configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.65
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.35.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2 python])
 102 AC_PROG_SED
 103 AC_PROG_MKDIR_P
 104
 105 AC_SYS_LARGEFILE
 106
 107 LT_PREREQ([2.2])
 108 LT_INIT([disable-static])
 109
 110 AX_PROG_BISON([],
 111               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 112                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 113 AX_PROG_FLEX([],
 114              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 115                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 116
 117 AC_CHECK_PROG(INDENT, indent, indent, cat)
 118 if test "x$INDENT" != "xcat"; then
 119     # Only GNU indent is supported
 120     INDENT_VERSION=`indent --version | grep GNU`
 121     if test $? -eq 0; then
 122        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 123     else
 124        INDENT="cat"
 125     fi
 126 fi
 127
 128 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 129
 130 if test -z "$PYTHON2"; then
 131     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 132         AC_MSG_ERROR([Python not found - unable to generate sources])
 133     fi
 134 else
 135     if test "x$acv_mako_found" = xno; then
 136         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 137             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 138         fi
 139     fi
 140 fi
 141
 142 AC_PROG_INSTALL
 143
 144 dnl We need a POSIX shell for parts of the build. Assume we have one
 145 dnl in most cases.
 146 case "$host_os" in
 147 solaris*)
 148     # Solaris /bin/sh is too old/non-POSIX compliant
 149     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 150     SHELL="$POSIX_SHELL"
 151     ;;
 152 esac
 153
 154 dnl clang is mostly GCC-compatible, but its version is much lower,
 155 dnl so we have to check for it.
 156 AC_MSG_CHECKING([if compiling with clang])
 157
 158 AC_COMPILE_IFELSE(
 159 [AC_LANG_PROGRAM([], [[
 160 #ifndef __clang__
 161        not clang
 162 #endif
 163 ]])],
 164 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 165
 166 AC_MSG_RESULT([$acv_mesa_CLANG])
 167
 168 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 169 dnl versions are explictly not supported.
 170 GEN_ASM_OFFSETS=no
 171 USE_GNU99=no
 172 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 173     AC_MSG_CHECKING([whether gcc version is sufficient])
 174     major=0
 175     minor=0
 176
 177     GCC_VERSION=`$CC -dumpversion`
 178     if test $? -eq 0; then
 179         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 180         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 181     fi
 182
 183     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 184         AC_MSG_RESULT([no])
 185         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 186     else
 187         AC_MSG_RESULT([yes])
 188     fi
 189
 190     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 191         USE_GNU99=yes
 192     fi
 193     if test "x$cross_compiling" = xyes; then
 194         GEN_ASM_OFFSETS=yes
 195     fi
 196 fi
 197
 198 dnl Check for compiler builtins
 199 AX_GCC_BUILTIN([__builtin_bswap32])
 200 AX_GCC_BUILTIN([__builtin_bswap64])
 201 AX_GCC_BUILTIN([__builtin_clz])
 202 AX_GCC_BUILTIN([__builtin_clzll])
 203 AX_GCC_BUILTIN([__builtin_ctz])
 204 AX_GCC_BUILTIN([__builtin_expect])
 205 AX_GCC_BUILTIN([__builtin_ffs])
 206 AX_GCC_BUILTIN([__builtin_ffsll])
 207 AX_GCC_BUILTIN([__builtin_popcount])
 208 AX_GCC_BUILTIN([__builtin_popcountll])
 209 AX_GCC_BUILTIN([__builtin_unreachable])
 210
 211 AX_GCC_FUNC_ATTRIBUTE([const])
 212 AX_GCC_FUNC_ATTRIBUTE([flatten])
 213 AX_GCC_FUNC_ATTRIBUTE([format])
 214 AX_GCC_FUNC_ATTRIBUTE([malloc])
 215 AX_GCC_FUNC_ATTRIBUTE([packed])
 216 AX_GCC_FUNC_ATTRIBUTE([pure])
 217 AX_GCC_FUNC_ATTRIBUTE([unused])
 218 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 219
 220 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 221
 222 dnl Make sure the pkg-config macros are defined
 223 m4_ifndef([PKG_PROG_PKG_CONFIG],
 224     [m4_fatal([Could not locate the pkg-config autoconf macros.
 225   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 226   are in a different location, try setting the environment variable
 227   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 228 PKG_PROG_PKG_CONFIG()
 229
 230 dnl LIB_DIR - library basename
 231 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 232 AC_SUBST([LIB_DIR])
 233
 234 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 235 _SAVE_LDFLAGS="$LDFLAGS"
 236 _SAVE_CPPFLAGS="$CPPFLAGS"
 237
 238 dnl Compiler macros
 239 DEFINES="-D__STDC_LIMIT_MACROS"
 240 AC_SUBST([DEFINES])
 241 case "$host_os" in
 242 linux*|*-gnu*|gnu*)
 243     DEFINES="$DEFINES -D_GNU_SOURCE"
 244     ;;
 245 solaris*)
 246     DEFINES="$DEFINES -DSVR4"
 247     ;;
 248 cygwin*)
 249     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 250     ;;
 251 esac
 252
 253 dnl Add flags for gcc and g++
 254 if test "x$GCC" = xyes; then
 255     CFLAGS="$CFLAGS -Wall"
 256
 257     if test "x$USE_GNU99" = xyes; then
 258         CFLAGS="$CFLAGS -std=gnu99"
 259     else
 260         CFLAGS="$CFLAGS -std=c99"
 261     fi
 262
 263     # Enable -Werror=implicit-function-declaration and
 264     # -Werror=missing-prototypes, if available, or otherwise, just
 265     # -Wmissing-prototypes.  This is particularly useful to avoid
 266     # generating a loadable driver module that has undefined symbols.
 267     save_CFLAGS="$CFLAGS"
 268     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 269     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 270     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 271     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 272                    AC_MSG_RESULT([yes]),
 273                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 274                     AC_MSG_RESULT([no])]);
 275
 276     # Enable -fvisibility=hidden if using a gcc that supports it
 277     save_CFLAGS="$CFLAGS"
 278     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 279     VISIBILITY_CFLAGS="-fvisibility=hidden"
 280     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 281     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 282                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 283
 284     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 285     CFLAGS=$save_CFLAGS
 286
 287     # Work around aliasing bugs - developers should comment this out
 288     CFLAGS="$CFLAGS -fno-strict-aliasing"
 289
 290     # We don't want floating-point math functions to set errno or trap
 291     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 292
 293     # gcc's builtin memcmp is slower than glibc's
 294     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 295     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 296
 297     # Flags to help ensure that certain portions of the code -- and only those
 298     # portions -- can be built with MSVC:
 299     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 300     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 301     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 302     #   supports most of C99)
 303     # - the rest has no compiler compiler restrictions
 304     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 305     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 306
 307     # Enable -Werror=vla if compiler supports it
 308     save_CFLAGS="$CFLAGS"
 309     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 310     CFLAGS="$CFLAGS -Werror=vla"
 311     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 312                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 313                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 314                     AC_MSG_RESULT([yes])],
 315                     AC_MSG_RESULT([no]));
 316     CFLAGS="$save_CFLAGS"
 317
 318     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 319     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 320 fi
 321 if test "x$GXX" = xyes; then
 322     CXXFLAGS="$CXXFLAGS -Wall"
 323
 324     # Enable -fvisibility=hidden if using a gcc that supports it
 325     save_CXXFLAGS="$CXXFLAGS"
 326     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 327     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 328     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 329     AC_LANG_PUSH([C++])
 330     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 331                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 332     AC_LANG_POP([C++])
 333
 334     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 335     CXXFLAGS=$save_CXXFLAGS
 336
 337     # Work around aliasing bugs - developers should comment this out
 338     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 339
 340     # gcc's builtin memcmp is slower than glibc's
 341     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 342     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 343 fi
 344
 345 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 346 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 347 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int main () {
 378     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 379     c = _mm_max_epu32(a, b);
 380     return 0;
 381 }]])], SSE41_SUPPORTED=1)
 382 CFLAGS="$save_CFLAGS"
 383 if test "x$SSE41_SUPPORTED" = x1; then
 384     DEFINES="$DEFINES -DUSE_SSE41"
 385 fi
 386 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 387 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 388
 389 dnl Can't have static and shared libraries, default to static if user
 390 dnl explicitly requested. If both disabled, set to static since shared
 391 dnl was explicitly requested.
 392 case "x$enable_static$enable_shared" in
 393 xyesyes)
 394     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 395     enable_shared=no
 396     ;;
 397 xnono)
 398     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 399     enable_shared=yes
 400     ;;
 401 esac
 402
 403 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 404
 405 dnl
 406 dnl other compiler options
 407 dnl
 408 AC_ARG_ENABLE([debug],
 409     [AS_HELP_STRING([--enable-debug],
 410         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 411     [enable_debug="$enableval"],
 412     [enable_debug=no]
 413 )
 414 if test "x$enable_debug" = xyes; then
 415     DEFINES="$DEFINES -DDEBUG"
 416     if test "x$GCC" = xyes; then
 417         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 418             CFLAGS="$CFLAGS -g"
 419         fi
 420         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 421             CFLAGS="$CFLAGS -O0"
 422         fi
 423     fi
 424     if test "x$GXX" = xyes; then
 425         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 426             CXXFLAGS="$CXXFLAGS -g"
 427         fi
 428         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 429             CXXFLAGS="$CXXFLAGS -O0"
 430         fi
 431     fi
 432 else
 433    DEFINES="$DEFINES -DNDEBUG"
 434 fi
 435
 436 dnl
 437 dnl Check if linker supports -Bsymbolic
 438 dnl
 439 save_LDFLAGS=$LDFLAGS
 440 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 441 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 442 AC_LINK_IFELSE(
 443     [AC_LANG_SOURCE([int main() { return 0;}])],
 444     [AC_MSG_RESULT([yes])
 445         BSYMBOLIC="-Wl,-Bsymbolic";],
 446     [AC_MSG_RESULT([no])
 447         BSYMBOLIC="";])
 448 LDFLAGS=$save_LDFLAGS
 449
 450 AC_SUBST([BSYMBOLIC])
 451
 452 dnl
 453 dnl Check if linker supports garbage collection
 454 dnl
 455 save_LDFLAGS=$LDFLAGS
 456 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 457 AC_MSG_CHECKING([whether ld supports --gc-sections])
 458 AC_LINK_IFELSE(
 459     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 460     [AC_MSG_RESULT([yes])
 461         GC_SECTIONS="-Wl,--gc-sections";],
 462     [AC_MSG_RESULT([no])
 463         GC_SECTIONS="";])
 464 LDFLAGS=$save_LDFLAGS
 465
 466 AC_SUBST([GC_SECTIONS])
 467
 468 dnl
 469 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 470 dnl so when these flags are passed to ld via libtool the checks will fail
 471 dnl
 472 case "$host_os" in
 473 openbsd* | darwin* )
 474     LD_NO_UNDEFINED="" ;;
 475 *)
 476     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 477 esac
 478
 479 AC_SUBST([LD_NO_UNDEFINED])
 480
 481 dnl
 482 dnl Check if linker supports version scripts
 483 dnl
 484 AC_MSG_CHECKING([if the linker supports version-scripts])
 485 save_LDFLAGS=$LDFLAGS
 486 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 487 cat > conftest.map <<EOF
 488 VERSION_1 {
 489      global:
 490          main;
 491
 492      local:
 493          *;
 494 };
 495 EOF
 496 AC_LINK_IFELSE(
 497     [AC_LANG_SOURCE([int main() { return 0;}])],
 498     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 499     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 500 LDFLAGS=$save_LDFLAGS
 501 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 502
 503 dnl
 504 dnl Check if linker supports dynamic list files
 505 dnl
 506 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 507 save_LDFLAGS=$LDFLAGS
 508 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 509 cat > conftest.dyn <<EOF
 510 {
 511         radeon_drm_winsys_create;
 512 };
 513 EOF
 514 AC_LINK_IFELSE(
 515     [AC_LANG_SOURCE([int main() { return 0;}])],
 516     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 517     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 518 LDFLAGS=$save_LDFLAGS
 519 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 520
 521 dnl
 522 dnl compatibility symlinks
 523 dnl
 524 case "$host_os" in
 525 linux* )
 526     HAVE_COMPAT_SYMLINKS=yes ;;
 527 * )
 528     HAVE_COMPAT_SYMLINKS=no ;;
 529 esac
 530
 531 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 532
 533 dnl
 534 dnl library names
 535 dnl
 536 dnl Unfortunately we need to do a few things that libtool can't help us with,
 537 dnl so we need some knowledge of shared library filenames:
 538 dnl
 539 dnl LIB_EXT is the extension used when creating symlinks for alternate
 540 dnl filenames for a shared library which will be dynamically loaded
 541 dnl
 542 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 543 dnl the file for a shared library we wish to link with
 544 dnl
 545 case "$host_os" in
 546 darwin* )
 547     LIB_EXT='dylib'
 548     IMP_LIB_EXT=$LIB_EXT
 549     ;;
 550 cygwin* )
 551     LIB_EXT='dll'
 552     IMP_LIB_EXT='dll.a'
 553     ;;
 554 aix* )
 555     LIB_EXT='a'
 556     IMP_LIB_EXT=$LIB_EXT
 557     ;;
 558 * )
 559     LIB_EXT='so'
 560     IMP_LIB_EXT=$LIB_EXT
 561     ;;
 562 esac
 563
 564 AC_SUBST([LIB_EXT])
 565
 566 AC_ARG_WITH([gl-lib-name],
 567   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 568     [specify GL library name @<:@default=GL@:>@])],
 569   [GL_LIB=$withval],
 570   [GL_LIB=GL])
 571 AC_ARG_WITH([osmesa-lib-name],
 572   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 573     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 574   [OSMESA_LIB=$withval],
 575   [OSMESA_LIB=OSMesa])
 576 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 577 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 578
 579 dnl
 580 dnl Mangled Mesa support
 581 dnl
 582 AC_ARG_ENABLE([mangling],
 583   [AS_HELP_STRING([--enable-mangling],
 584     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 585   [enable_mangling="${enableval}"],
 586   [enable_mangling=no]
 587 )
 588 if test "x${enable_mangling}" = "xyes" ; then
 589   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 590   GL_LIB="Mangled${GL_LIB}"
 591   OSMESA_LIB="Mangled${OSMESA_LIB}"
 592 fi
 593 AC_SUBST([GL_LIB])
 594 AC_SUBST([OSMESA_LIB])
 595
 596 dnl
 597 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 598 dnl
 599 AC_ARG_ENABLE([texture-float],
 600     [AS_HELP_STRING([--enable-texture-float],
 601         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 602     [enable_texture_float="$enableval"],
 603     [enable_texture_float=no]
 604 )
 605 if test "x$enable_texture_float" = xyes; then
 606     AC_MSG_WARN([Floating-point textures enabled.])
 607     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 608     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 609 fi
 610
 611 dnl
 612 dnl Arch/platform-specific settings
 613 dnl
 614 AC_ARG_ENABLE([asm],
 615     [AS_HELP_STRING([--disable-asm],
 616         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 617     [enable_asm="$enableval"],
 618     [enable_asm=yes]
 619 )
 620 asm_arch=""
 621 AC_MSG_CHECKING([whether to enable assembly])
 622 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 623 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 624 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 625     case "$host_cpu" in
 626     i?86 | x86_64 | amd64)
 627         enable_asm=no
 628         AC_MSG_RESULT([no, cross compiling])
 629         ;;
 630     esac
 631 fi
 632 # check for supported arches
 633 if test "x$enable_asm" = xyes; then
 634     case "$host_cpu" in
 635     i?86)
 636         case "$host_os" in
 637         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 638             asm_arch=x86
 639             ;;
 640         esac
 641         ;;
 642     x86_64|amd64)
 643         case "$host_os" in
 644         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 645             asm_arch=x86_64
 646             ;;
 647         esac
 648         ;;
 649     sparc*)
 650         case "$host_os" in
 651         linux*)
 652             asm_arch=sparc
 653             ;;
 654         esac
 655         ;;
 656     esac
 657
 658     case "$asm_arch" in
 659     x86)
 660         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 661         AC_MSG_RESULT([yes, x86])
 662         ;;
 663     x86_64|amd64)
 664         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 665         AC_MSG_RESULT([yes, x86_64])
 666         ;;
 667     sparc)
 668         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 669         AC_MSG_RESULT([yes, sparc])
 670         ;;
 671     *)
 672         AC_MSG_RESULT([no, platform not supported])
 673         ;;
 674     esac
 675 fi
 676
 677 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 678 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 679 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 680 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 681
 682 dnl Check to see if dlopen is in default libraries (like Solaris, which
 683 dnl has it in libc), or if libdl is needed to get it.
 684 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 685     [AC_CHECK_LIB([dl], [dlopen],
 686        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 687 AC_SUBST([DLOPEN_LIBS])
 688
 689 dnl Check if that library also has dladdr
 690 save_LIBS="$LIBS"
 691 LIBS="$LIBS $DLOPEN_LIBS"
 692 AC_CHECK_FUNCS([dladdr])
 693 LIBS="$save_LIBS"
 694
 695 case "$host_os" in
 696 darwin*)
 697     ;;
 698 *)
 699     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 700                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 701                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 702     AC_SUBST([CLOCK_LIB])
 703     ;;
 704 esac
 705
 706 dnl See if posix_memalign is available
 707 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 708
 709 dnl Check for pthreads
 710 AX_PTHREAD
 711 if test "x$ax_pthread_ok" = xno; then
 712     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 713 fi
 714 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 715 dnl to -pthread, which causes problems if we need -lpthread to appear in
 716 dnl pkgconfig files.
 717 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 718
 719 dnl SELinux awareness.
 720 AC_ARG_ENABLE([selinux],
 721     [AS_HELP_STRING([--enable-selinux],
 722         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 723     [MESA_SELINUX="$enableval"],
 724     [MESA_SELINUX=no])
 725 if test "x$enable_selinux" = "xyes"; then
 726     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 727         [AC_CHECK_HEADER([selinux/selinux.h],[],
 728                          [AC_MSG_ERROR([SELinux headers not found])])
 729          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 730                       [AC_MSG_ERROR([SELinux library not found])])
 731          SELINUX_LIBS="-lselinux"])
 732     DEFINES="$DEFINES -DMESA_SELINUX"
 733 fi
 734 AC_SUBST([SELINUX_CFLAGS])
 735 AC_SUBST([SELINUX_LIBS])
 736
 737 dnl Options for APIs
 738 AC_ARG_ENABLE([opengl],
 739     [AS_HELP_STRING([--disable-opengl],
 740         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 741     [enable_opengl="$enableval"],
 742     [enable_opengl=yes])
 743 AC_ARG_ENABLE([gles1],
 744     [AS_HELP_STRING([--disable-gles1],
 745         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 746     [enable_gles1="$enableval"],
 747     [enable_gles1=yes])
 748 AC_ARG_ENABLE([gles2],
 749     [AS_HELP_STRING([--disable-gles2],
 750         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 751     [enable_gles2="$enableval"],
 752     [enable_gles2=yes])
 753
 754 AC_ARG_ENABLE([dri],
 755     [AS_HELP_STRING([--enable-dri],
 756         [enable DRI modules @<:@default=enabled@:>@])],
 757     [enable_dri="$enableval"],
 758     [enable_dri=yes])
 759
 760 case "$host_os" in
 761 linux*)
 762     dri3_default=yes
 763     ;;
 764 *)
 765     dri3_default=no
 766     ;;
 767 esac
 768 AC_ARG_ENABLE([dri3],
 769     [AS_HELP_STRING([--enable-dri3],
 770         [enable DRI3 @<:@default=auto@:>@])],
 771     [enable_dri3="$enableval"],
 772     [enable_dri3="$dri3_default"])
 773 AC_ARG_ENABLE([glx],
 774     [AS_HELP_STRING([--enable-glx],
 775         [enable GLX library @<:@default=enabled@:>@])],
 776     [enable_glx="$enableval"],
 777     [enable_glx=yes])
 778 AC_ARG_ENABLE([osmesa],
 779     [AS_HELP_STRING([--enable-osmesa],
 780         [enable OSMesa library @<:@default=disabled@:>@])],
 781     [enable_osmesa="$enableval"],
 782     [enable_osmesa=no])
 783 AC_ARG_ENABLE([gallium-osmesa],
 784     [AS_HELP_STRING([--enable-gallium-osmesa],
 785         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 786     [enable_gallium_osmesa="$enableval"],
 787     [enable_gallium_osmesa=no])
 788 AC_ARG_ENABLE([egl],
 789     [AS_HELP_STRING([--disable-egl],
 790         [disable EGL library @<:@default=enabled@:>@])],
 791     [enable_egl="$enableval"],
 792     [enable_egl=yes])
 793
 794 AC_ARG_ENABLE([xa],
 795     [AS_HELP_STRING([--enable-xa],
 796         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 797     [enable_xa="$enableval"],
 798     [enable_xa=no])
 799 AC_ARG_ENABLE([gbm],
 800    [AS_HELP_STRING([--enable-gbm],
 801          [enable gbm library @<:@default=auto@:>@])],
 802    [enable_gbm="$enableval"],
 803    [enable_gbm=auto])
 804 AC_ARG_ENABLE([nine],
 805     [AS_HELP_STRING([--enable-nine],
 806         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 807     [enable_nine="$enableval"],
 808     [enable_nine=no])
 809
 810 AC_ARG_ENABLE([xvmc],
 811    [AS_HELP_STRING([--enable-xvmc],
 812          [enable xvmc library @<:@default=auto@:>@])],
 813    [enable_xvmc="$enableval"],
 814    [enable_xvmc=auto])
 815 AC_ARG_ENABLE([vdpau],
 816    [AS_HELP_STRING([--enable-vdpau],
 817          [enable vdpau library @<:@default=auto@:>@])],
 818    [enable_vdpau="$enableval"],
 819    [enable_vdpau=auto])
 820 AC_ARG_ENABLE([omx],
 821    [AS_HELP_STRING([--enable-omx],
 822          [enable OpenMAX library @<:@default=disabled@:>@])],
 823    [enable_omx="$enableval"],
 824    [enable_omx=no])
 825 AC_ARG_ENABLE([va],
 826    [AS_HELP_STRING([--enable-va],
 827          [enable va library @<:@default=auto@:>@])],
 828    [enable_va="$enableval"],
 829    [enable_va=auto])
 830 AC_ARG_ENABLE([opencl],
 831    [AS_HELP_STRING([--enable-opencl],
 832          [enable OpenCL library @<:@default=disabled@:>@])],
 833    [enable_opencl="$enableval"],
 834    [enable_opencl=no])
 835 AC_ARG_ENABLE([opencl_icd],
 836    [AS_HELP_STRING([--enable-opencl-icd],
 837           [Build an OpenCL ICD library to be loaded by an ICD implementation
 838            @<:@default=disabled@:>@])],
 839     [enable_opencl_icd="$enableval"],
 840     [enable_opencl_icd=no])
 841 AC_ARG_ENABLE([xlib-glx],
 842     [AS_HELP_STRING([--enable-xlib-glx],
 843         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 844     [enable_xlib_glx="$enableval"],
 845     [enable_xlib_glx=no])
 846
 847 AC_ARG_ENABLE([r600-llvm-compiler],
 848     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 849         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 850     [enable_r600_llvm="$enableval"],
 851     [enable_r600_llvm=no])
 852
 853 AC_ARG_ENABLE([gallium-tests],
 854     [AS_HELP_STRING([--enable-gallium-tests],
 855         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 856     [enable_gallium_tests="$enableval"],
 857     [enable_gallium_tests=no])
 858
 859 # Option for Gallium drivers
 860
 861 # Keep this in sync with the --with-gallium-drivers help string default value
 862 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 863
 864 AC_ARG_WITH([gallium-drivers],
 865     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 866         [comma delimited Gallium drivers list, e.g.
 867         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 868         @<:@default=r300,r600,svga,swrast@:>@])],
 869     [with_gallium_drivers="$withval"],
 870     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 871
 872 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 873 # here so that the script doesn't choke on an unknown driver name later.
 874 case "$with_gallium_drivers" in
 875     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 876     no) with_gallium_drivers='' ;;
 877 esac
 878
 879 if test "x$enable_opengl" = xno -a \
 880         "x$enable_gles1" = xno -a \
 881         "x$enable_gles2" = xno -a \
 882         "x$enable_nine" = xno -a \
 883         "x$enable_xa" = xno -a \
 884         "x$enable_xvmc" = xno -a \
 885         "x$enable_vdpau" = xno -a \
 886         "x$enable_omx" = xno -a \
 887         "x$enable_va" = xno -a \
 888         "x$enable_opencl" = xno; then
 889     AC_MSG_ERROR([at least one API should be enabled])
 890 fi
 891
 892 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 893 if test "x$enable_opengl" = xno -a \
 894         "x$enable_gles1" = xyes; then
 895     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 896 fi
 897
 898 if test "x$enable_opengl" = xno -a \
 899         "x$enable_gles2" = xyes; then
 900     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 901 fi
 902
 903 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 904 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 905 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 906 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 907                                         "x$enable_gles1" = xyes -o \
 908                                         "x$enable_gles2" = xyes)
 909
 910 if test "x$enable_glx" = xno; then
 911     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 912     enable_xlib_glx=no
 913 fi
 914
 915 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 916     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 917 fi
 918
 919 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 920     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 921 fi
 922
 923 # Disable GLX if OpenGL is not enabled
 924 if test "x$enable_glx$enable_opengl" = xyesno; then
 925     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 926     enable_glx=no
 927 fi
 928
 929 # Disable GLX if DRI and Xlib-GLX are not enabled
 930 if test "x$enable_glx" = xyes -a \
 931         "x$enable_dri" = xno -a \
 932         "x$enable_xlib_glx" = xno; then
 933     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 934     enable_glx=no
 935 fi
 936
 937 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 938                                   "x$enable_dri" = xyes)
 939
 940 # Check for libdrm
 941 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 942                   [have_libdrm=yes], [have_libdrm=no])
 943 if test "x$have_libdrm" = xyes; then
 944         DEFINES="$DEFINES -DHAVE_LIBDRM"
 945 fi
 946
 947 # Select which platform-dependent DRI code gets built
 948 case "$host_os" in
 949 darwin*)
 950     dri_platform='apple' ;;
 951 gnu*|cygwin*)
 952     dri_platform='none' ;;
 953 *)
 954     dri_platform='drm' ;;
 955 esac
 956
 957 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 958 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 959 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 960 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 961 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 962
 963 AC_ARG_ENABLE([shared-glapi],
 964     [AS_HELP_STRING([--enable-shared-glapi],
 965         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 966     [enable_shared_glapi="$enableval"],
 967     [enable_shared_glapi=yes])
 968
 969 case "x$enable_opengl$enable_gles1$enable_gles2" in
 970 x*yes*yes*)
 971     if test "x$enable_shared_glapi" = xno; then
 972         AC_MSG_ERROR([shared GLAPI required when building two or more of
 973                       the following APIs - opengl, gles1 gles2])
 974     fi
 975     ;;
 976 esac
 977
 978 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 979
 980 # Build the pipe-drivers as separate libraries/modules.
 981 # Do not touch this unless you know what you are doing.
 982 # XXX: Expose via configure option ?
 983 enable_shared_pipe_drivers=no
 984
 985 dnl
 986 dnl Driver specific build directories
 987 dnl
 988
 989 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
 990     NEED_WINSYS_XLIB="yes"
 991 fi
 992
 993 if test "x$enable_dri" = xyes; then
 994     enable_gallium_loader="$enable_shared_pipe_drivers"
 995 fi
 996
 997 if test "x$enable_gallium_osmesa" = xyes; then
 998     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 999         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1000     fi
1001     if test "x$enable_osmesa" = xyes; then
1002         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1003     fi
1004 fi
1005
1006 AC_SUBST([MESA_LLVM])
1007
1008 # SHA1 hashing
1009 AC_ARG_WITH([sha1],
1010         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1011         [choose SHA1 implementation])])
1012 case "x$with_sha1" in
1013 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1014   ;;
1015 *)
1016         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1017 esac
1018
1019 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1020 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1021         with_sha1=libc
1022 fi
1023 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1024         AC_MSG_ERROR([sha1 in libc requested but not found])
1025 fi
1026 if test "x$with_sha1" = xlibc; then
1027         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1028                 [Use libc SHA1 functions])
1029         SHA1_LIBS=""
1030 fi
1031 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1032 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1033         with_sha1=CommonCrypto
1034 fi
1035 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1036         AC_MSG_ERROR([CommonCrypto requested but not found])
1037 fi
1038 if test "x$with_sha1" = xCommonCrypto; then
1039         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1040                 [Use CommonCrypto SHA1 functions])
1041         SHA1_LIBS=""
1042 fi
1043 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1044 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1045 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1046         with_sha1=CryptoAPI
1047 fi
1048 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1049         AC_MSG_ERROR([CryptoAPI requested but not found])
1050 fi
1051 if test "x$with_sha1" = xCryptoAPI; then
1052         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1053                 [Use CryptoAPI SHA1 functions])
1054         SHA1_LIBS=""
1055 fi
1056 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1057 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1058         with_sha1=libmd
1059 fi
1060 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1061         AC_MSG_ERROR([libmd requested but not found])
1062 fi
1063 if test "x$with_sha1" = xlibmd; then
1064         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1065                   [Use libmd SHA1 functions])
1066         SHA1_LIBS=-lmd
1067 fi
1068 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1069 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1070    with_sha1=libsha1
1071 fi
1072 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1073         AC_MSG_ERROR([libsha1 requested but not found])
1074 fi
1075 if test "x$with_sha1" = xlibsha1; then
1076         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1077                   [Use libsha1 for SHA1])
1078         SHA1_LIBS=-lsha1
1079 fi
1080 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1081 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1082         with_sha1=libnettle
1083 fi
1084 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1085         AC_MSG_ERROR([libnettle requested but not found])
1086 fi
1087 if test "x$with_sha1" = xlibnettle; then
1088         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1089                   [Use libnettle SHA1 functions])
1090         SHA1_LIBS=-lnettle
1091 fi
1092 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1093 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1094         with_sha1=libgcrypt
1095 fi
1096 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1097         AC_MSG_ERROR([libgcrypt requested but not found])
1098 fi
1099 if test "x$with_sha1" = xlibgcrypt; then
1100         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1101                   [Use libgcrypt SHA1 functions])
1102         SHA1_LIBS=-lgcrypt
1103 fi
1104 # We don't need all of the OpenSSL libraries, just libcrypto
1105 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1106 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1107                   [HAVE_OPENSSL_PKC=no])
1108 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1109         if test "x$with_sha1" = x; then
1110                 with_sha1=libcrypto
1111         fi
1112 else
1113         if test "x$with_sha1" = xlibcrypto; then
1114                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1115         fi
1116 fi
1117 if test "x$with_sha1" = xlibcrypto; then
1118         if test "x$HAVE_LIBCRYPTO" = xyes; then
1119                 SHA1_LIBS=-lcrypto
1120         else
1121                 SHA1_LIBS="$OPENSSL_LIBS"
1122                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1123         fi
1124 fi
1125 AC_MSG_CHECKING([for SHA1 implementation])
1126 AC_MSG_RESULT([$with_sha1])
1127 AC_SUBST(SHA1_LIBS)
1128 AC_SUBST(SHA1_CFLAGS)
1129
1130 # Enable a define for SHA1
1131 if test "x$with_sha1" != "x"; then
1132         DEFINES="$DEFINES -DHAVE_SHA1"
1133 fi
1134
1135 # Allow user to configure out the shader-cache feature
1136 AC_ARG_ENABLE([shader-cache],
1137     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1138     [enable_shader_cache="$enableval"],
1139     [if test "x$with_sha1" != "x"; then
1140         enable_shader_cache=yes
1141      else
1142         enable_shader_cache=no
1143      fi])
1144 if test "x$with_sha1" = "x"; then
1145     if test "x$enable_shader_cache" = "xyes"; then
1146         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1147     fi
1148 fi
1149 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1150
1151 case "$host_os" in
1152 linux*)
1153     need_pci_id=yes ;;
1154 *)
1155     need_pci_id=no ;;
1156 esac
1157
1158 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1159                   have_libudev=yes, have_libudev=no)
1160
1161 AC_ARG_ENABLE([sysfs],
1162     [AS_HELP_STRING([--enable-sysfs],
1163         [enable /sys PCI identification @<:@default=disabled@:>@])],
1164     [have_sysfs="$enableval"],
1165     [have_sysfs=no]
1166 )
1167
1168 if test "x$enable_dri" = xyes; then
1169     if test "$enable_static" = yes; then
1170         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1171     fi
1172
1173     # not a hard requirement as swrast does not depend on it
1174     if test "x$have_libdrm" = xyes; then
1175         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1176     fi
1177 fi
1178
1179 AC_ARG_ENABLE([driglx-direct],
1180     [AS_HELP_STRING([--disable-driglx-direct],
1181         [disable direct rendering in GLX and EGL for DRI \
1182             @<:@default=auto@:>@])],
1183     [driglx_direct="$enableval"],
1184     [driglx_direct="yes"])
1185
1186 dnl
1187 dnl libGL configuration per driver
1188 dnl
1189 case "x$enable_glx$enable_xlib_glx" in
1190 xyesyes)
1191     # Xlib-based GLX
1192     dri_modules="x11 xext xcb"
1193     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1194     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1195     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1196     GL_LIB_DEPS="$XLIBGL_LIBS"
1197     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1198     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1199     ;;
1200 xyesno)
1201     # DRI-based GLX
1202     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1203
1204     # find the DRI deps for libGL
1205     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1206
1207     if test x"$driglx_direct" = xyes; then
1208         if test x"$dri_platform" = xdrm ; then
1209             DEFINES="$DEFINES -DGLX_USE_DRM"
1210             if test "x$have_libdrm" != xyes; then
1211                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1212             fi
1213
1214             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1215             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1216             if test x"$enable_dri3" = xyes; then
1217                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1218                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1219             fi
1220
1221             if test x"$enable_dri" = xyes; then
1222                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1223             fi
1224
1225             if test x"$enable_dri3" = xyes; then
1226                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1227                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1228             fi
1229         fi
1230         if test x"$dri_platform" = xapple ; then
1231             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1232         fi
1233     fi
1234
1235     # add xf86vidmode if available
1236     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1237     if test "$HAVE_XF86VIDMODE" = yes ; then
1238         dri_modules="$dri_modules xxf86vm"
1239     fi
1240
1241     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1242     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1243     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1244     GL_LIB_DEPS="$DRIGL_LIBS"
1245
1246     # need DRM libs, $PTHREAD_LIBS, etc.
1247     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1248     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1249     ;;
1250 esac
1251
1252 have_pci_id=no
1253 if test "$have_libudev" = yes; then
1254     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1255     have_pci_id=yes
1256 fi
1257
1258 if test "$have_sysfs" = yes; then
1259     DEFINES="$DEFINES -DHAVE_SYSFS"
1260     have_pci_id=yes
1261 fi
1262
1263 # This is outside the case (above) so that it is invoked even for non-GLX
1264 # builds.
1265 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1266
1267 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1268 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1269 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1270 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1271
1272 AC_SUBST([X11_INCLUDES])
1273 AC_SUBST([GL_LIB_DEPS])
1274 AC_SUBST([GL_PC_REQ_PRIV])
1275 AC_SUBST([GL_PC_LIB_PRIV])
1276 AC_SUBST([GL_PC_CFLAGS])
1277 AC_SUBST([DRI_PC_REQ_PRIV])
1278 AC_SUBST([GLESv1_CM_LIB_DEPS])
1279 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1280 AC_SUBST([GLESv2_LIB_DEPS])
1281 AC_SUBST([GLESv2_PC_LIB_PRIV])
1282
1283 AC_SUBST([HAVE_XF86VIDMODE])
1284
1285 dnl
1286 dnl More GLX setup
1287 dnl
1288 case "x$enable_glx$enable_xlib_glx" in
1289 xyesyes)
1290     DEFINES="$DEFINES -DUSE_XSHM"
1291     ;;
1292 xyesno)
1293     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1294     if test "x$driglx_direct" = xyes; then
1295         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1296     fi
1297     ;;
1298 esac
1299
1300 dnl
1301 dnl TLS detection
1302 dnl
1303
1304 AC_ARG_ENABLE([glx-tls],
1305     [AS_HELP_STRING([--enable-glx-tls],
1306         [enable TLS support in GLX @<:@default=disabled@:>@])],
1307     [GLX_USE_TLS="$enableval"],
1308     [GLX_USE_TLS=no])
1309 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1310
1311 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1312       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1313
1314 dnl Read-only text section on x86 hardened platforms
1315 AC_ARG_ENABLE([glx-read-only-text],
1316     [AS_HELP_STRING([--enable-glx-read-only-text],
1317         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1318     [enable_glx_read_only_text="$enableval"],
1319     [enable_glx_read_only_text=no])
1320 if test "x$enable_glx_read_only_text" = xyes; then
1321     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1322 fi
1323
1324 dnl
1325 dnl More DRI setup
1326 dnl
1327 dnl Directory for DRI drivers
1328 AC_ARG_WITH([dri-driverdir],
1329     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1330         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1331     [DRI_DRIVER_INSTALL_DIR="$withval"],
1332     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1333 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1334 dnl Extra search path for DRI drivers
1335 AC_ARG_WITH([dri-searchpath],
1336     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1337         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1338     [DRI_DRIVER_SEARCH_DIR="$withval"],
1339     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1340 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1341 dnl Which drivers to build - default is chosen by platform
1342 AC_ARG_WITH([dri-drivers],
1343     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1344         [comma delimited classic DRI drivers list, e.g.
1345         "swrast,i965,radeon" @<:@default=auto@:>@])],
1346     [with_dri_drivers="$withval"],
1347     [with_dri_drivers=auto])
1348
1349 if test "x$with_dri_drivers" = xauto; then
1350     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1351         with_dri_drivers="yes"
1352     else
1353         with_dri_drivers="no"
1354     fi
1355 fi
1356 if test "x$with_dri_drivers" = xno; then
1357     with_dri_drivers=''
1358 fi
1359
1360 dnl If $with_dri_drivers is yes, drivers will be added through
1361 dnl platform checks. Set DEFINES and LIB_DEPS
1362 if test "x$enable_dri" = xyes; then
1363     # Platform specific settings and drivers to build
1364     case "$host_os" in
1365     linux*)
1366         DEFINES="$DEFINES -DHAVE_ALIAS"
1367         if test "x$enable_dri3" = xyes; then
1368             DEFINES="$DEFINES -DHAVE_DRI3"
1369         fi
1370
1371         if test "x$have_pci_id" != xyes; then
1372             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1373         fi
1374
1375         case "$host_cpu" in
1376         powerpc* | sparc*)
1377             # Build only the drivers for cards that exist on PowerPC/sparc
1378             if test "x$with_dri_drivers" = "xyes"; then
1379                 with_dri_drivers="r200 radeon swrast"
1380             fi
1381             ;;
1382         esac
1383         ;;
1384     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1385         DEFINES="$DEFINES -DHAVE_ALIAS"
1386         ;;
1387     gnu*)
1388         DEFINES="$DEFINES -DHAVE_ALIAS"
1389         ;;
1390     cygwin*)
1391         if test "x$with_dri_drivers" = "xyes"; then
1392             with_dri_drivers="swrast"
1393         fi
1394         ;;
1395     darwin*)
1396         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1397         if test "x$with_dri_drivers" = "xyes"; then
1398             with_dri_drivers="swrast"
1399         fi
1400         ;;
1401     esac
1402
1403     # default drivers
1404     if test "x$with_dri_drivers" = "xyes"; then
1405         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1406     fi
1407
1408     # Check for expat
1409     PKG_CHECK_MODULES([EXPAT], [expat], [],
1410         # expat version 2.0 and earlier do not provide expat.pc
1411         [AC_CHECK_HEADER([expat.h],[],
1412                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1413          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1414                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1415          EXPAT_LIBS="-lexpat"])
1416
1417     # put all the necessary libs together
1418     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1419 fi
1420
1421 AC_SUBST([DRI_LIB_DEPS])
1422
1423 DRI_DIRS=''
1424 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1425 if test -n "$with_dri_drivers"; then
1426     if test "x$enable_opengl" != xyes; then
1427         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1428     fi
1429
1430     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1431     for driver in $dri_drivers; do
1432         DRI_DIRS="$DRI_DIRS $driver"
1433         case "x$driver" in
1434         xi915)
1435             HAVE_I915_DRI=yes;
1436             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1437             ;;
1438         xi965)
1439             HAVE_I965_DRI=yes;
1440             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1441             ;;
1442         xnouveau)
1443             HAVE_NOUVEAU_DRI=yes;
1444             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1445             ;;
1446         xradeon)
1447             HAVE_RADEON_DRI=yes;
1448             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1449             ;;
1450         xr200)
1451             HAVE_R200_DRI=yes;
1452             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1453             ;;
1454         xswrast)
1455             HAVE_SWRAST_DRI=yes;
1456             ;;
1457         *)
1458             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1459             ;;
1460         esac
1461     done
1462     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1463 fi
1464
1465 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1466 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1467                                   "x$enable_osmesa" = xyes -o \
1468                                   -n "$DRI_DIRS")
1469
1470 dnl
1471 dnl OSMesa configuration
1472 dnl
1473
1474 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1475 AC_ARG_WITH([osmesa-bits],
1476     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1477         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1478     [osmesa_bits="$withval"],
1479     [osmesa_bits=8])
1480 if test "x$osmesa_bits" != x8; then
1481     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1482         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1483         osmesa_bits=8
1484     fi
1485 fi
1486 case "x$osmesa_bits" in
1487 x8)
1488     OSMESA_LIB="${OSMESA_LIB}"
1489     ;;
1490 x16|x32)
1491     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1492     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1493     ;;
1494 *)
1495     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1496     ;;
1497 esac
1498
1499 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1500     # only link libraries with osmesa if shared
1501     if test "$enable_static" = no; then
1502         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1503     else
1504         OSMESA_LIB_DEPS=""
1505     fi
1506     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1507 fi
1508
1509 AC_SUBST([OSMESA_LIB_DEPS])
1510 AC_SUBST([OSMESA_PC_REQ])
1511 AC_SUBST([OSMESA_PC_LIB_PRIV])
1512
1513 dnl
1514 dnl gbm configuration
1515 dnl
1516 if test "x$enable_gbm" = xauto; then
1517     case "$with_egl_platforms" in
1518         *drm*)
1519             enable_gbm=yes ;;
1520          *)
1521             enable_gbm=no ;;
1522     esac
1523 fi
1524 if test "x$enable_gbm" = xyes; then
1525     if test "x$need_pci_id$have_pci_id" = xyesno; then
1526         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1527     fi
1528
1529     if test "x$enable_dri" = xyes; then
1530         if test "x$enable_shared_glapi" = xno; then
1531             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1532         fi
1533     else
1534         # Strictly speaking libgbm does not require --enable-dri, although
1535         # both of its backends do. Thus one can build libgbm without any
1536         # backends if --disable-dri is set.
1537         # To avoid unnecessary complexity of checking if at least one backend
1538         # is available when building, just mandate --enable-dri.
1539         AC_MSG_ERROR([gbm requires --enable-dri])
1540     fi
1541 fi
1542 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1543 if test "x$need_pci_id$have_libudev" = xyesyes; then
1544     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1545 else
1546     GBM_PC_REQ_PRIV=""
1547 fi
1548 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1549 AC_SUBST([GBM_PC_REQ_PRIV])
1550 AC_SUBST([GBM_PC_LIB_PRIV])
1551
1552 dnl
1553 dnl EGL configuration
1554 dnl
1555 EGL_CLIENT_APIS=""
1556
1557 if test "x$enable_egl" = xyes; then
1558     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1559
1560     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1561
1562     if test "$enable_static" != yes; then
1563         if test "x$enable_dri" = xyes; then
1564             HAVE_EGL_DRIVER_DRI2=1
1565             if test "x$enable_shared_glapi" = xno; then
1566                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1567             fi
1568         else
1569             # Avoid building an "empty" libEGL. Drop/update this
1570             # when other backends (haiku?) come along.
1571             AC_MSG_ERROR([egl requires --enable-dri])
1572         fi
1573
1574     fi
1575 fi
1576 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1577 AC_SUBST([EGL_LIB_DEPS])
1578
1579 gallium_st="mesa"
1580
1581 dnl
1582 dnl XA configuration
1583 dnl
1584 if test "x$enable_xa" = xyes; then
1585     if test "x$with_gallium_drivers" = xswrast; then
1586        AC_MSG_ERROR([
1587           Building xa requires at least one non swrast gallium driver.
1588           If you are looking to use libxatracker.so with the VMware driver,
1589           make sure to include svga in the gallium drivers list, apart from
1590           enabling XA.
1591           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1592     fi
1593     enable_gallium_loader=$enable_shared_pipe_drivers
1594     gallium_st="$gallium_st xa"
1595 fi
1596 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1597
1598 dnl
1599 dnl Gallium G3DVL configuration
1600 dnl
1601 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1602     if test "x$enable_xvmc" = xauto; then
1603         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1604     fi
1605
1606     if test "x$enable_vdpau" = xauto; then
1607         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1608     fi
1609
1610     if test "x$enable_omx" = xauto; then
1611         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1612     fi
1613
1614     if test "x$enable_va" = xauto; then
1615         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1616     fi
1617 fi
1618
1619 if test "x$enable_dri" = xyes -o \
1620         "x$enable_xvmc" = xyes -o \
1621         "x$enable_vdpau" = xyes -o \
1622         "x$enable_omx" = xyes -o \
1623         "x$enable_va" = xyes; then
1624     need_gallium_vl=yes
1625 fi
1626 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1627
1628 if test "x$enable_xvmc" = xyes -o \
1629         "x$enable_vdpau" = xyes -o \
1630         "x$enable_omx" = xyes -o \
1631         "x$enable_va" = xyes; then
1632     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1633     need_gallium_vl_winsys=yes
1634 fi
1635 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1636
1637 if test "x$enable_xvmc" = xyes; then
1638     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1639     enable_gallium_loader=$enable_shared_pipe_drivers
1640     gallium_st="$gallium_st xvmc"
1641 fi
1642 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1643
1644 if test "x$enable_vdpau" = xyes; then
1645     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1646     enable_gallium_loader=$enable_shared_pipe_drivers
1647     gallium_st="$gallium_st vdpau"
1648 fi
1649 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1650
1651 if test "x$enable_omx" = xyes; then
1652     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1653     enable_gallium_loader=$enable_shared_pipe_drivers
1654     gallium_st="$gallium_st omx"
1655 fi
1656 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1657
1658 if test "x$enable_va" = xyes; then
1659     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1660     enable_gallium_loader=$enable_shared_pipe_drivers
1661     gallium_st="$gallium_st va"
1662 fi
1663 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1664
1665 dnl
1666 dnl Nine Direct3D9 configuration
1667 dnl
1668 if test "x$enable_nine" = xyes; then
1669     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1670         AC_MSG_ERROR([nine requires the gallium swrast driver])
1671     fi
1672     if test "x$with_gallium_drivers" = xswrast; then
1673         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1674     fi
1675     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1676         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1677     fi
1678
1679     if test "x$enable_dri3" = xno; then
1680         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1681     fi
1682
1683     enable_gallium_loader=$enable_shared_pipe_drivers
1684     gallium_st="$gallium_st nine"
1685 fi
1686 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1687
1688 dnl
1689 dnl OpenCL configuration
1690 dnl
1691
1692 AC_ARG_WITH([clang-libdir],
1693    [AS_HELP_STRING([--with-clang-libdir],
1694          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1695    [CLANG_LIBDIR="$withval"],
1696    [CLANG_LIBDIR=''])
1697
1698 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1699 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1700
1701 if test "x$enable_opencl" = xyes; then
1702     if test -z "$with_gallium_drivers"; then
1703         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1704     fi
1705
1706     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1707         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1708     fi
1709
1710     if test "x$have_libclc" = xno; then
1711         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1712                     Make sure the directory containing libclc.pc is specified in your
1713                     PKG_CONFIG_PATH environment variable.
1714                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1715     else
1716         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1717         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1718         AC_SUBST([LIBCLC_INCLUDEDIR])
1719         AC_SUBST([LIBCLC_LIBEXECDIR])
1720     fi
1721
1722     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1723     enable_gallium_loader=yes
1724     gallium_st="$gallium_st clover"
1725
1726     if test "x$enable_opencl_icd" = xyes; then
1727         OPENCL_LIBNAME="MesaOpenCL"
1728     else
1729         OPENCL_LIBNAME="OpenCL"
1730     fi
1731
1732     if test "x$have_libelf" != xyes; then
1733        AC_MSG_ERROR([Clover requires libelf])
1734     fi
1735 fi
1736 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1737 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1738 AC_SUBST([OPENCL_LIBNAME])
1739
1740 dnl
1741 dnl Gallium configuration
1742 dnl
1743 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1744
1745 AC_SUBST([LLVM_BINDIR])
1746 AC_SUBST([LLVM_CFLAGS])
1747 AC_SUBST([LLVM_CPPFLAGS])
1748 AC_SUBST([LLVM_CXXFLAGS])
1749 AC_SUBST([LLVM_LIBDIR])
1750 AC_SUBST([LLVM_LIBS])
1751 AC_SUBST([LLVM_LDFLAGS])
1752 AC_SUBST([LLVM_INCLUDEDIR])
1753 AC_SUBST([LLVM_VERSION])
1754 AC_SUBST([CLANG_RESOURCE_DIR])
1755
1756 case "x$enable_opengl$enable_gles1$enable_gles2" in
1757 x*yes*)
1758     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1759     ;;
1760 esac
1761
1762 AC_SUBST([VG_LIB_DEPS])
1763 AC_SUBST([EGL_CLIENT_APIS])
1764
1765 dnl
1766 dnl EGL Platforms configuration
1767 dnl
1768 AC_ARG_WITH([egl-platforms],
1769     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1770         [comma delimited native platforms libEGL supports, e.g.
1771         "x11,drm" @<:@default=auto@:>@])],
1772     [with_egl_platforms="$withval"],
1773     [if test "x$enable_egl" = xyes; then
1774         with_egl_platforms="x11"
1775     else
1776         with_egl_platforms=""
1777     fi])
1778
1779 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1780     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1781 fi
1782
1783 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1784         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1785         WAYLAND_SCANNER='')
1786 if test "x$WAYLAND_SCANNER" = x; then
1787     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1788 fi
1789
1790 # Do per-EGL platform setups and checks
1791 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1792 for plat in $egl_platforms; do
1793         case "$plat" in
1794         wayland)
1795                 test "x$have_libdrm" != xyes &&
1796                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1797
1798                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1799
1800                 if test "x$WAYLAND_SCANNER" = x; then
1801                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1802                 fi
1803                 ;;
1804
1805         x11)
1806                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1807                 ;;
1808
1809         drm)
1810                 test "x$enable_gbm" = "xno" &&
1811                         AC_MSG_ERROR([EGL platform drm needs gbm])
1812                 test "x$have_libdrm" != xyes &&
1813                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1814                 ;;
1815
1816         surfaceless)
1817                 test "x$have_libdrm" != xyes &&
1818                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1819                 ;;
1820
1821         *)
1822                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1823                 ;;
1824         esac
1825
1826         case "$plat$need_pci_id$have_pci_id" in
1827                 waylandyesno|drmyesno)
1828                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1829         esac
1830 done
1831
1832 # libEGL wants to default to the first platform specified in
1833 # ./configure.  parse that here.
1834 if test "x$egl_platforms" != "x"; then
1835     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1836     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1837 else
1838     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1839 fi
1840
1841 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1842 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1843 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1844 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1845 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1846
1847 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1848
1849 AC_SUBST([EGL_NATIVE_PLATFORM])
1850 AC_SUBST([EGL_CFLAGS])
1851
1852 # If we don't have the X11 platform, set this define so we don't try to include
1853 # the X11 headers.
1854 if ! echo "$egl_platforms" | grep -q 'x11'; then
1855     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1856     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1857 fi
1858
1859 dnl
1860 dnl Gallium LLVM
1861 dnl
1862 AC_ARG_ENABLE([gallium-llvm],
1863     [AS_HELP_STRING([--enable-gallium-llvm],
1864         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1865     [enable_gallium_llvm="$enableval"],
1866     [enable_gallium_llvm=auto])
1867
1868 AC_ARG_ENABLE([llvm-shared-libs],
1869     [AS_HELP_STRING([--enable-llvm-shared-libs],
1870         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1871     [enable_llvm_shared_libs="$enableval"],
1872     [enable_llvm_shared_libs=yes])
1873
1874 AC_ARG_WITH([llvm-prefix],
1875     [AS_HELP_STRING([--with-llvm-prefix],
1876         [Prefix for LLVM installations in non-standard locations])],
1877     [llvm_prefix="$withval"],
1878     [llvm_prefix=''])
1879
1880
1881 # Call this inside ` ` to get the return value.
1882 # $1 is the llvm-config command with arguments.
1883 strip_unwanted_llvm_flags() {
1884     # Use \> (marks the end of the word)
1885     echo `$1` | sed \
1886         -e 's/-DNDEBUG\>//g' \
1887         -e 's/-D_GNU_SOURCE\>//g' \
1888         -e 's/-pedantic\>//g' \
1889         -e 's/-Wcovered-switch-default\>//g' \
1890         -e 's/-O.\>//g' \
1891         -e 's/-g\>//g' \
1892         -e 's/-Wall\>//g' \
1893         -e 's/-Wcast-qual\>//g' \
1894         -e 's/-Woverloaded-virtual\>//g' \
1895         -e 's/-fcolor-diagnostics\>//g' \
1896         -e 's/-fdata-sections\>//g' \
1897         -e 's/-ffunction-sections\>//g' \
1898         -e 's/-fno-exceptions\>//g' \
1899         -e 's/-fomit-frame-pointer\>//g' \
1900         -e 's/-fvisibility-inlines-hidden\>//g' \
1901         -e 's/-fPIC\>//g' \
1902         -e 's/-fstack-protector-strong\>//g'
1903 }
1904
1905 llvm_check_version_for() {
1906     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1907         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1908     fi
1909 }
1910
1911
1912
1913 if test -z "$with_gallium_drivers"; then
1914     enable_gallium_llvm=no
1915 fi
1916 if test "x$enable_gallium_llvm" = xauto; then
1917     case "$host_cpu" in
1918     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1919     esac
1920 fi
1921 if test "x$enable_gallium_llvm" = xyes; then
1922     if test -n "$llvm_prefix"; then
1923         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1924     else
1925         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1926     fi
1927
1928     if test "x$LLVM_CONFIG" != xno; then
1929         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1930         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1931         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1932         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1933         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1934         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1935         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1936         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1937
1938         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1939             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1940         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1941             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1942
1943         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1944         if test -z "$LLVM_VERSION_PATCH"; then
1945             LLVM_VERSION_PATCH=0
1946         fi
1947
1948         if test -n "${LLVM_VERSION_MAJOR}"; then
1949             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1950         else
1951             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1952         fi
1953
1954         LLVM_REQUIRED_VERSION_MAJOR="3"
1955         LLVM_REQUIRED_VERSION_MINOR="3"
1956         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1957             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1958         fi
1959
1960         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1961
1962         if test "x$enable_opencl" = xyes; then
1963             llvm_check_version_for "3" "5" "0" "opencl"
1964
1965             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1966             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1967         fi
1968         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1969         MESA_LLVM=1
1970
1971         dnl Check for Clang internal headers
1972         if test "x$enable_opencl" = xyes; then
1973             if test -z "$CLANG_LIBDIR"; then
1974                 CLANG_LIBDIR=${LLVM_LIBDIR}
1975             fi
1976             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1977             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1978                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1979         fi
1980     else
1981         MESA_LLVM=0
1982         LLVM_VERSION_INT=0
1983     fi
1984 else
1985     MESA_LLVM=0
1986     LLVM_VERSION_INT=0
1987
1988     if test "x$enable_opencl" = xyes; then
1989         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1990     fi
1991 fi
1992
1993 dnl Directory for XVMC libs
1994 AC_ARG_WITH([xvmc-libdir],
1995     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1996         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1997     [XVMC_LIB_INSTALL_DIR="$withval"],
1998     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1999 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2000
2001 dnl
2002 dnl Gallium Tests
2003 dnl
2004 if test "x$enable_gallium_tests" = xyes; then
2005     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
2006     enable_gallium_loader=yes
2007 fi
2008 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2009
2010 dnl Directory for VDPAU libs
2011 AC_ARG_WITH([vdpau-libdir],
2012     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2013         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2014     [VDPAU_LIB_INSTALL_DIR="$withval"],
2015     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2016 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2017
2018 dnl Directory for OMX libs
2019
2020 AC_ARG_WITH([omx-libdir],
2021     [AS_HELP_STRING([--with-omx-libdir=DIR],
2022         [directory for the OMX libraries])],
2023     [OMX_LIB_INSTALL_DIR="$withval"],
2024     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2025 AC_SUBST([OMX_LIB_INSTALL_DIR])
2026
2027 dnl Directory for VA libs
2028
2029 AC_ARG_WITH([va-libdir],
2030     [AS_HELP_STRING([--with-va-libdir=DIR],
2031         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2032     [VA_LIB_INSTALL_DIR="$withval"],
2033     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2034 AC_SUBST([VA_LIB_INSTALL_DIR])
2035
2036 AC_ARG_WITH([d3d-libdir],
2037     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2038         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2039     [D3D_DRIVER_INSTALL_DIR="$withval"],
2040     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2041 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2042
2043 dnl
2044 dnl Gallium helper functions
2045 dnl
2046 gallium_require_drm() {
2047     if test "x$have_libdrm" != xyes; then
2048        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2049     fi
2050 }
2051
2052 gallium_require_llvm() {
2053     if test "x$MESA_LLVM" = x0; then
2054         case "$host" in *gnux32) return;; esac
2055         case "$host_cpu" in
2056         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2057         esac
2058     fi
2059 }
2060
2061 gallium_require_drm_loader() {
2062     if test "x$enable_gallium_loader" = xyes; then
2063         if test "x$need_pci_id$have_pci_id" = xyesno; then
2064             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2065         fi
2066         enable_gallium_drm_loader=yes
2067     fi
2068     if test "x$enable_va" = xyes && test "x$7" != x; then
2069          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2070     fi
2071 }
2072
2073 require_egl_drm() {
2074     case "$with_egl_platforms" in
2075         *drm*)
2076             ;;
2077          *)
2078             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2079             ;;
2080     esac
2081     if test "x$enable_gbm" != xyes; then
2082             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2083     fi
2084 }
2085
2086 radeon_llvm_check() {
2087     if test ${LLVM_VERSION_INT} -lt 307; then
2088         amdgpu_llvm_target_name='r600'
2089     else
2090         amdgpu_llvm_target_name='amdgpu'
2091     fi
2092     if test "x$enable_gallium_llvm" != "xyes"; then
2093         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2094     fi
2095     llvm_check_version_for "3" "5" "0" $1
2096     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2097         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2098     fi
2099     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2100     NEED_RADEON_LLVM=yes
2101     if test "x$have_libelf" != xyes; then
2102        AC_MSG_ERROR([$1 requires libelf when using llvm])
2103     fi
2104 }
2105
2106 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2107 if test -n "$with_gallium_drivers"; then
2108     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2109     for driver in $gallium_drivers; do
2110         case "x$driver" in
2111         xsvga)
2112             HAVE_GALLIUM_SVGA=yes
2113             gallium_require_drm "svga"
2114             gallium_require_drm_loader
2115             ;;
2116         xi915)
2117             HAVE_GALLIUM_I915=yes
2118             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2119             gallium_require_drm "Gallium i915"
2120             gallium_require_drm_loader
2121             ;;
2122         xilo)
2123             HAVE_GALLIUM_ILO=yes
2124             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2125             gallium_require_drm "Gallium i965/ilo"
2126             gallium_require_drm_loader
2127             ;;
2128         xr300)
2129             HAVE_GALLIUM_R300=yes
2130             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2131             gallium_require_drm "Gallium R300"
2132             gallium_require_drm_loader
2133             gallium_require_llvm "Gallium R300"
2134             ;;
2135         xr600)
2136             HAVE_GALLIUM_R600=yes
2137             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2138             gallium_require_drm "Gallium R600"
2139             gallium_require_drm_loader
2140             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2141                 radeon_llvm_check "r600g"
2142                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2143             fi
2144             if test "x$enable_r600_llvm" = xyes; then
2145                 USE_R600_LLVM_COMPILER=yes;
2146             fi
2147             if test "x$enable_opencl" = xyes; then
2148                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2149             fi
2150             ;;
2151         xradeonsi)
2152             HAVE_GALLIUM_RADEONSI=yes
2153             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2154             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2155             gallium_require_drm "radeonsi"
2156             gallium_require_drm_loader
2157             radeon_llvm_check "radeonsi"
2158             require_egl_drm "radeonsi"
2159             ;;
2160         xnouveau)
2161             HAVE_GALLIUM_NOUVEAU=yes
2162             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2163             gallium_require_drm "nouveau"
2164             gallium_require_drm_loader
2165             ;;
2166         xfreedreno)
2167             HAVE_GALLIUM_FREEDRENO=yes
2168             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2169             gallium_require_drm "freedreno"
2170             gallium_require_drm_loader
2171             ;;
2172         xswrast)
2173             HAVE_GALLIUM_SOFTPIPE=yes
2174             if test "x$MESA_LLVM" = x1; then
2175                 HAVE_GALLIUM_LLVMPIPE=yes
2176             fi
2177             ;;
2178         xvc4)
2179             HAVE_GALLIUM_VC4=yes
2180             gallium_require_drm "vc4"
2181             gallium_require_drm_loader
2182
2183             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2184                               [USE_VC4_SIMULATOR=yes], [USE_VC4_SIMULATOR=no])
2185             ;;
2186         *)
2187             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2188             ;;
2189         esac
2190     done
2191 fi
2192
2193 dnl Set LLVM_LIBS - This is done after the driver configuration so
2194 dnl that drivers can add additional components to LLVM_COMPONENTS.
2195 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2196 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2197 dnl this was causing the same libraries to be appear multiple times
2198 dnl in LLVM_LIBS.
2199
2200 if test "x$MESA_LLVM" != x0; then
2201
2202     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2203
2204     dnl llvm-config may not give the right answer when llvm is a built as a
2205     dnl single shared library, so we must work the library name out for
2206     dnl ourselves.
2207     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2208     if test "x$enable_llvm_shared_libs" = xyes; then
2209         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2210         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2211         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2212
2213         if test "x$llvm_have_one_so" = xyes; then
2214             dnl LLVM was built using auto*, so there is only one shared object.
2215             LLVM_LIBS="-l$LLVM_SO_NAME"
2216         else
2217             dnl If LLVM was built with CMake, there will be one shared object per
2218             dnl component.
2219             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2220                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2221         Please make sure you have built llvm with the --enable-shared option
2222         and that your llvm libraries are installed in $LLVM_LIBDIR
2223         If you have installed your llvm libraries to a different directory you
2224         can use the --with-llvm-prefix= configure flag to specify this directory.
2225         NOTE: Mesa is attempting to use llvm shared libraries by default.
2226         If you do not want to build with llvm shared libraries and instead want to
2227         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2228         invocation and rebuild.])])
2229
2230            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2231            dnl install uses a shared object for each component and we have
2232            dnl already added all of these objects to LLVM_LIBS.
2233         fi
2234     else
2235         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2236         dnl We need to link to llvm system libs when using static libs
2237         dnl However, only llvm 3.5+ provides --system-libs
2238         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2239             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2240         fi
2241     fi
2242 fi
2243
2244 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2245 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2246 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2247 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2248 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2249 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2250 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2251                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2252 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2253 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2254 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2255 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2256 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2257
2258 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2259
2260 # NOTE: anything using xcb or other client side libs ends up in separate
2261 #       _CLIENT variables.  The pipe loader is built in two variants,
2262 #       one that is standalone and does not link any x client libs (for
2263 #       use by XA tracker in particular, but could be used in any case
2264 #       where communication with xserver is not desired).
2265 if test "x$enable_gallium_loader" = xyes; then
2266     if test "x$enable_dri" = xyes; then
2267         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2268     fi
2269
2270     if test "x$enable_gallium_drm_loader" = xyes; then
2271         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2272     fi
2273
2274     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2275 fi
2276
2277 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2278 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2279 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2280 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2281 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2282 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2283
2284 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2285                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2286                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2287 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2288 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2289 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2290 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2291 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2292 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2293 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2294 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2295 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2296     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2297 fi
2298
2299 AC_SUBST([ELF_LIB])
2300
2301 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2302 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2303 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2304 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2305
2306 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2307 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2308 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2309
2310 AC_SUBST([NINE_MAJOR], 1)
2311 AC_SUBST([NINE_MINOR], 0)
2312 AC_SUBST([NINE_TINY], 0)
2313 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2314
2315 AC_SUBST([VDPAU_MAJOR], 1)
2316 AC_SUBST([VDPAU_MINOR], 0)
2317
2318 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2319 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2320 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2321 AC_SUBST([VA_MINOR], $VA_MINOR)
2322
2323 AC_SUBST([XVMC_MAJOR], 1)
2324 AC_SUBST([XVMC_MINOR], 0)
2325
2326 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2327 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2328 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2329 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2330
2331 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2332 AC_SUBST([XA_MINOR], $XA_MINOR)
2333 AC_SUBST([XA_TINY], $XA_TINY)
2334 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2335
2336 dnl Restore LDFLAGS and CPPFLAGS
2337 LDFLAGS="$_SAVE_LDFLAGS"
2338 CPPFLAGS="$_SAVE_CPPFLAGS"
2339
2340 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2341 if test "x$acv_mesa_CLANG" = xyes; then
2342     CFLAGS="$CFLAGS -Qunused-arguments"
2343     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2344 fi
2345
2346 dnl Add user CFLAGS and CXXFLAGS
2347 CFLAGS="$CFLAGS $USER_CFLAGS"
2348 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2349
2350 dnl Substitute the config
2351 AC_CONFIG_FILES([Makefile
2352                 src/Makefile
2353                 src/egl/Makefile
2354                 src/egl/main/egl.pc
2355                 src/egl/wayland/wayland-drm/Makefile
2356                 src/egl/wayland/wayland-egl/Makefile
2357                 src/egl/wayland/wayland-egl/wayland-egl.pc
2358                 src/gallium/Makefile
2359                 src/gallium/auxiliary/Makefile
2360                 src/gallium/auxiliary/pipe-loader/Makefile
2361                 src/gallium/drivers/freedreno/Makefile
2362                 src/gallium/drivers/ddebug/Makefile
2363                 src/gallium/drivers/i915/Makefile
2364                 src/gallium/drivers/ilo/Makefile
2365                 src/gallium/drivers/llvmpipe/Makefile
2366                 src/gallium/drivers/noop/Makefile
2367                 src/gallium/drivers/nouveau/Makefile
2368                 src/gallium/drivers/r300/Makefile
2369                 src/gallium/drivers/r600/Makefile
2370                 src/gallium/drivers/radeon/Makefile
2371                 src/gallium/drivers/radeonsi/Makefile
2372                 src/gallium/drivers/rbug/Makefile
2373                 src/gallium/drivers/softpipe/Makefile
2374                 src/gallium/drivers/svga/Makefile
2375                 src/gallium/drivers/trace/Makefile
2376                 src/gallium/drivers/vc4/Makefile
2377                 src/gallium/state_trackers/clover/Makefile
2378                 src/gallium/state_trackers/dri/Makefile
2379                 src/gallium/state_trackers/glx/xlib/Makefile
2380                 src/gallium/state_trackers/nine/Makefile
2381                 src/gallium/state_trackers/omx/Makefile
2382                 src/gallium/state_trackers/osmesa/Makefile
2383                 src/gallium/state_trackers/va/Makefile
2384                 src/gallium/state_trackers/vdpau/Makefile
2385                 src/gallium/state_trackers/xa/Makefile
2386                 src/gallium/state_trackers/xvmc/Makefile
2387                 src/gallium/targets/d3dadapter9/Makefile
2388                 src/gallium/targets/d3dadapter9/d3d.pc
2389                 src/gallium/targets/dri/Makefile
2390                 src/gallium/targets/libgl-xlib/Makefile
2391                 src/gallium/targets/omx/Makefile
2392                 src/gallium/targets/opencl/Makefile
2393                 src/gallium/targets/opencl/mesa.icd
2394                 src/gallium/targets/osmesa/Makefile
2395                 src/gallium/targets/osmesa/osmesa.pc
2396                 src/gallium/targets/pipe-loader/Makefile
2397                 src/gallium/targets/va/Makefile
2398                 src/gallium/targets/vdpau/Makefile
2399                 src/gallium/targets/xa/Makefile
2400                 src/gallium/targets/xa/xatracker.pc
2401                 src/gallium/targets/xvmc/Makefile
2402                 src/gallium/tests/trivial/Makefile
2403                 src/gallium/tests/unit/Makefile
2404                 src/gallium/winsys/freedreno/drm/Makefile
2405                 src/gallium/winsys/i915/drm/Makefile
2406                 src/gallium/winsys/intel/drm/Makefile
2407                 src/gallium/winsys/nouveau/drm/Makefile
2408                 src/gallium/winsys/radeon/drm/Makefile
2409                 src/gallium/winsys/amdgpu/drm/Makefile
2410                 src/gallium/winsys/svga/drm/Makefile
2411                 src/gallium/winsys/sw/dri/Makefile
2412                 src/gallium/winsys/sw/kms-dri/Makefile
2413                 src/gallium/winsys/sw/null/Makefile
2414                 src/gallium/winsys/sw/wrapper/Makefile
2415                 src/gallium/winsys/sw/xlib/Makefile
2416                 src/gallium/winsys/vc4/drm/Makefile
2417                 src/gbm/Makefile
2418                 src/gbm/main/gbm.pc
2419                 src/glsl/Makefile
2420                 src/glx/Makefile
2421                 src/glx/apple/Makefile
2422                 src/glx/tests/Makefile
2423                 src/gtest/Makefile
2424                 src/loader/Makefile
2425                 src/mapi/Makefile
2426                 src/mapi/es1api/glesv1_cm.pc
2427                 src/mapi/es2api/glesv2.pc
2428                 src/mapi/glapi/gen/Makefile
2429                 src/mesa/Makefile
2430                 src/mesa/gl.pc
2431                 src/mesa/drivers/dri/dri.pc
2432                 src/mesa/drivers/dri/common/Makefile
2433                 src/mesa/drivers/dri/common/xmlpool/Makefile
2434                 src/mesa/drivers/dri/i915/Makefile
2435                 src/mesa/drivers/dri/i965/Makefile
2436                 src/mesa/drivers/dri/Makefile
2437                 src/mesa/drivers/dri/nouveau/Makefile
2438                 src/mesa/drivers/dri/r200/Makefile
2439                 src/mesa/drivers/dri/radeon/Makefile
2440                 src/mesa/drivers/dri/swrast/Makefile
2441                 src/mesa/drivers/osmesa/Makefile
2442                 src/mesa/drivers/osmesa/osmesa.pc
2443                 src/mesa/drivers/x11/Makefile
2444                 src/mesa/main/tests/Makefile
2445                 src/util/Makefile
2446                 src/util/tests/hash_table/Makefile])
2447
2448 AC_OUTPUT
2449
2450 dnl
2451 dnl Output some configuration info for the user
2452 dnl
2453 echo ""
2454 echo "        prefix:          $prefix"
2455 echo "        exec_prefix:     $exec_prefix"
2456 echo "        libdir:          $libdir"
2457 echo "        includedir:      $includedir"
2458
2459 dnl API info
2460 echo ""
2461 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2462
2463 dnl Driver info
2464 echo ""
2465 case "x$enable_osmesa$enable_gallium_osmesa" in
2466 xnoyes)
2467         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2468         ;;
2469 xyesno)
2470         echo "        OSMesa:          lib$OSMESA_LIB"
2471         ;;
2472 xnono)
2473         echo "        OSMesa:          no"
2474         ;;
2475 esac
2476
2477 echo ""
2478 if test "x$enable_dri" != xno; then
2479         echo "        DRI platform:    $dri_platform"
2480         if test -z "$DRI_DIRS"; then
2481             echo "        DRI drivers:     no"
2482         else
2483             echo "        DRI drivers:     $DRI_DIRS"
2484         fi
2485         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2486 fi
2487
2488 case "x$enable_glx$enable_xlib_glx" in
2489 xyesyes)
2490     echo "        GLX:             Xlib-based"
2491     ;;
2492 xyesno)
2493     echo "        GLX:             DRI-based"
2494     ;;
2495 *)
2496     echo "        GLX:             $enable_glx"
2497     ;;
2498 esac
2499
2500 dnl EGL
2501 echo ""
2502 echo "        EGL:             $enable_egl"
2503 if test "$enable_egl" = yes; then
2504     echo "        EGL platforms:   $egl_platforms"
2505
2506     egl_drivers=""
2507     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2508         egl_drivers="$egl_drivers builtin:egl_dri2"
2509     fi
2510
2511     echo "        EGL drivers:    $egl_drivers"
2512 fi
2513
2514 echo ""
2515 if test "x$MESA_LLVM" = x1; then
2516     echo "        llvm:            yes"
2517     echo "        llvm-config:     $LLVM_CONFIG"
2518     echo "        llvm-version:    $LLVM_VERSION"
2519 else
2520     echo "        llvm:            no"
2521 fi
2522
2523 echo ""
2524 if test -n "$with_gallium_drivers"; then
2525     echo "        Gallium drivers: $gallium_drivers"
2526     echo "        Gallium st:      $gallium_st"
2527 else
2528     echo "        Gallium:         no"
2529 fi
2530
2531 dnl Shader cache
2532 echo ""
2533 echo "        Shader cache:    $enable_shader_cache"
2534 if test "x$enable_shader_cache" = "xyes"; then
2535     echo "        With SHA1 from:  $with_sha1"
2536 fi
2537
2538 dnl Libraries
2539 echo ""
2540 echo "        Shared libs:     $enable_shared"
2541 echo "        Static libs:     $enable_static"
2542 echo "        Shared-glapi:    $enable_shared_glapi"
2543
2544 dnl Compiler options
2545 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2546 cflags=`echo $CFLAGS | \
2547     $SED 's/^ *//;s/  */ /;s/ *$//'`
2548 cxxflags=`echo $CXXFLAGS | \
2549     $SED 's/^ *//;s/  */ /;s/ *$//'`
2550 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2551 echo ""
2552 echo "        CFLAGS:          $cflags"
2553 echo "        CXXFLAGS:        $cxxflags"
2554 echo "        Macros:          $defines"
2555 echo ""
2556 if test "x$MESA_LLVM" = x1; then
2557     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2558     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2559     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2560     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2561     echo ""
2562 fi
2563 echo "        PYTHON2:         $PYTHON2"
2564
2565 echo ""
2566 echo "        Run '${MAKE-make}' to build Mesa"
2567 echo ""