contrib/analyze_brprob

   1 #!/usr/bin/awk -f
   2 # Script to analyze experimental results of our branch prediction heuristics
   3 # Contributed by Jan Hubicka, SuSE inc.
   4 # Copyright (C) 2001 Free Software Foundation, Inc.
   5 #
   6 # This file is part of GNU CC.
   7 #
   8 # GNU CC is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2, or (at your option)
  11 # any later version.
  12 #
  13 # GNU CC is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with GNU CC; see the file COPYING.  If not, write to
  20 # the Free Software Foundation, 59 Temple Place - Suite 330,
  21 # Boston, MA 02111-1307, USA.
  22 #
  23 #
  24 # This script is used to calculate two basic properties of the branch prediction
  25 # heuristics - coverage and hitrate.  Coverage is number of executions of given
  26 # branch matched by the heuristics and hitrate is probability that once branch is
  27 # predicted as taken it is really taken.
  28 #
  29 # These values are usefull to determine quality of given heuristics and hitrate
  30 # may be directly used in predict.c.
  31 #
  32 # Usage:
  33 #  step 1: compile and profile your program.  You need to use -fprofile-arcs
  34 #    flag to get the profiles
  35 #  step 2: Generate log files.  The information about given heuristics are
  36 #    saved into *.life dumps.  You need to pass -df swtich to compiler as well
  37 #    as -fbranch-probabilities to get results of profiling noted in the dumps.
  38 #    Ensure that there is no "Arc profiling: some edge counts were bad." warnings.
  39 #    Keep the -fprofile-arcs switch to ensure that CFGs match.
  40 #  step 3: Run this script to concatetation of all *.life files:
  41 #    analyze_brprob `find . -name *.life`
  42 #    the information is collected and print once all files are parsed.  This
  43 #    may take a while.
  44 #    Note that script does use bc to perform long arithmetic.
  45 #  step 4: Read the results.  Basically following table is printed:
  46 #  (this is just example from very early stages of branch prediction pass
  47 #   development, so please don't take these numbers seriously)
  48 #
  49 #HEURISTICS                  BRANCHES  (REL)  HITRATE             COVERAGE  (REL)
  50 #opcode                          2889  83.7%  94.96%/ 97.62%      7516383  75.3%
  51 #pointer                          246   7.1%  99.69%/ 99.86%       118791   1.2%
  52 #loop header                      449  13.0%  98.32%/ 99.07%        43553   0.4%
  53 #first match                     3450 100.0%  89.92%/ 97.27%      9979782 100.0%
  54 #loop exit                        924  26.8%  88.95%/ 95.58%      9026266  90.4%
  55 #error return                     150   4.3%  64.48%/ 86.81%       453542   4.5%
  56 #call                             803  23.3%  51.66%/ 98.61%      3614037  36.2%
  57 #loop branch                       51   1.5%  99.26%/ 99.27%        26854   0.3%
  58 #noreturn call                    951  27.6% 100.00%/100.00%      1759809  17.6%
  59 #
  60 #  The heuristics called "first match" is heuristics used by gcc branch
  61 #  prediction pass and it predicts 89.92% branches correctly.
  62 #
  63 #  The quality of heuristics can be rated using both, coverage and hitrate
  64 #  parameters.  For example "loop branch" heuristics (predicting loopback edge
  65 #  as taken) have both very high hitrate and coverage, so it is very usefull.
  66 #  On the other hand, "exit block" heuristics (predicting exit edges as not
  67 #  taken) have good hitrate, but poor coverage, so only 3 branches has been
  68 #  predicted.  The "loop header" heuristics have problem, since it tends to
  69 #  misspredict.
  70 #
  71 #  The implementation of this script is somewhat brute force.  My awk skills
  72 #  are limited.
  73
  74 function longeval(e)
  75 {
  76   e = "echo \"scale = 2 ;"e"\" | bc"
  77   e | getline res
  78   close (e)
  79   return res
  80 }
  81
  82 BEGIN {nnames = 0}
  83
  84 /^  .* heuristics: .*.$/ {
  85     name=$0
  86     sub (/^  /,"",name)
  87     sub (/ heuristics: .*.$/,"",name)
  88     if (!(name in branches))
  89       {
  90         names[nnames] = name
  91         branches[name]=0
  92         counts[name]=0
  93         hits[name]=0
  94         phits[name]=0
  95         nnames++
  96       }
  97     branches[name]+=1
  98   }
  99
 100 /^  .* heuristics: .*. exec [0-9]* hit [0-9]* (.*.)$/ {
 101     name=$0
 102     sub (/^  /,"",name)
 103     sub (/ heuristics: .*. exec [0-9]* hit [0-9]* (.*.)$/,"",name)
 104     pred=$0
 105     sub (/^  .* heuristics: /,"",pred)
 106     sub (/. exec [0-9]* hit [0-9]* (.*.)$/,"",pred)
 107     count=$0
 108     sub (/^  .* heuristics: .*. exec /,"",count)
 109     sub (/ hit [0-9]* (.*.)$/,"",count)
 110     hit=$0
 111     sub (/^  .* heuristics: .*. exec [0-9]* hit /,"",hit)
 112     sub (/ (.*.)$/,"",hit)
 113
 114     if (int(pred) < 50.0)
 115       {
 116         hit = count - hit;
 117       }
 118     counts[name]=counts[name] "+" count
 119     hits[name]=hits[name] "+" hit
 120     if (int (hit) < (int (count) / 2))
 121       hit = count - hit;
 122     phits[name]=phits[name] "+" hit
 123
 124     #BC crashes on long strings.  Irritating.
 125     if (length(counts[name]) > 4000)
 126       {
 127         counts[name] = longeval (counts[name])
 128         hits[name] = longeval (hits[name])
 129         phits[name] = longeval (phits[name])
 130       }
 131   }
 132 END {
 133   # Heuristics called combined predicts just everything.
 134   maxcounts = longeval (counts["first match"])
 135   maxbranches = branches["first match"]
 136   max = names["firat match"]
 137   printf("HEURISTICS                  BRANCHES  (REL)  HITRATE             COVERAGE  (REL)\n")
 138   for (i = 0; i < nnames ; i++)
 139    {
 140      name = names[i]
 141      counts[name] = longeval (counts[name])
 142      printf ("%-27s %8i %5.1f%% %6s%%/%6s%% %12s %5.1f%%\n",
 143              name,
 144              branches[name], branches[name] * 100 / maxbranches,
 145              longeval ("("hits[name]") * 100 /(" counts[name]"-0.00001)"),
 146              longeval ("("phits[name]") * 100 /(" counts[name]"-0.00001)"),
 147              counts[name], longeval (counts[name]" * 100 / ("maxcounts"-0.00001)"))
 148    }
 149 }