frontends/verilog/verilog_lexer.l

   1 /*
   2  *  yosys -- Yosys Open SYnthesis Suite
   3  *
   4  *  Copyright (C) 2012  Clifford Wolf <clifford@clifford.at>
   5  *
   6  *  Permission to use, copy, modify, and/or distribute this software for any
   7  *  purpose with or without fee is hereby granted, provided that the above
   8  *  copyright notice and this permission notice appear in all copies.
   9  *
  10  *  THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  11  *  WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  12  *  MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  13  *  ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  14  *  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  15  *  ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  16  *  OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  17  *
  18  *  ---
  19  *
  20  *  The Verilog frontend.
  21  *
  22  *  This frontend is using the AST frontend library (see frontends/ast/).
  23  *  Thus this frontend does not generate RTLIL code directly but creates an
  24  *  AST directly from the Verilog parse tree and then passes this AST to
  25  *  the AST frontend library.
  26  *
  27  *  ---
  28  *
  29  *  A simple lexer for Verilog code. Non-preprocessor compiler directives are
  30  *  handled here. The preprocessor stuff is handled in preproc.cc. Everything
  31  *  else is left to the bison parser (see parser.y).
  32  *
  33  */
  34
  35 %{
  36
  37 #ifdef __clang__
  38 // bison generates code using the 'register' storage class specifier
  39 #pragma clang diagnostic ignored "-Wdeprecated-register"
  40 #endif
  41
  42 #include "kernel/log.h"
  43 #include "frontends/verilog/verilog_frontend.h"
  44 #include "frontends/ast/ast.h"
  45 #include "verilog_parser.tab.hh"
  46
  47 USING_YOSYS_NAMESPACE
  48 using namespace AST;
  49 using namespace VERILOG_FRONTEND;
  50
  51 YOSYS_NAMESPACE_BEGIN
  52 namespace VERILOG_FRONTEND {
  53         std::vector<std::string> fn_stack;
  54         std::vector<int> ln_stack;
  55 }
  56 YOSYS_NAMESPACE_END
  57
  58 #define SV_KEYWORD(_tok) \
  59         if (sv_mode) return _tok; \
  60         log("Lexer warning: The SystemVerilog keyword `%s' (at %s:%d) is not "\
  61                         "recognized unless read_verilog is called with -sv!\n", yytext, \
  62                         AST::current_filename.c_str(), frontend_verilog_yyget_lineno()); \
  63         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext); \
  64         return TOK_ID;
  65
  66 #define NON_KEYWORD() \
  67         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext); \
  68         return TOK_ID;
  69
  70 #define YY_INPUT(buf,result,max_size) \
  71         result = readsome(*VERILOG_FRONTEND::lexin, buf, max_size)
  72
  73 %}
  74
  75 %option yylineno
  76 %option noyywrap
  77 %option nounput
  78 %option prefix="frontend_verilog_yy"
  79
  80 %x COMMENT
  81 %x STRING
  82 %x SYNOPSYS_TRANSLATE_OFF
  83 %x SYNOPSYS_FLAGS
  84 %x IMPORT_DPI
  85
  86 %%
  87
  88 <INITIAL,SYNOPSYS_TRANSLATE_OFF>"`file_push "[^\n]* {
  89         fn_stack.push_back(current_filename);
  90         ln_stack.push_back(frontend_verilog_yyget_lineno());
  91         current_filename = yytext+11;
  92         if (!current_filename.empty() && current_filename.front() == '"')
  93                 current_filename = current_filename.substr(1);
  94         if (!current_filename.empty() && current_filename.back() == '"')
  95                 current_filename = current_filename.substr(0, current_filename.size()-1);
  96         frontend_verilog_yyset_lineno(0);
  97 }
  98
  99 <INITIAL,SYNOPSYS_TRANSLATE_OFF>"`file_pop"[^\n]*\n {
 100         current_filename = fn_stack.back();
 101         fn_stack.pop_back();
 102         frontend_verilog_yyset_lineno(ln_stack.back());
 103         ln_stack.pop_back();
 104 }
 105
 106 <INITIAL,SYNOPSYS_TRANSLATE_OFF>"`line"[ \t]+[^ \t\r\n]+[ \t]+\"[^ \r\n]+\"[^\r\n]*\n {
 107         char *p = yytext + 5;
 108         while (*p == ' ' || *p == '\t') p++;
 109         frontend_verilog_yyset_lineno(atoi(p));
 110         while (*p && *p != ' ' && *p != '\t') p++;
 111         while (*p == ' ' || *p == '\t') p++;
 112         char *q = *p ? p + 1 : p;
 113         while (*q && *q != '"') q++;
 114         current_filename = std::string(p).substr(1, q-p-1);
 115 }
 116
 117 "`file_notfound "[^\n]* {
 118         log_error("Can't open include file `%s'!\n", yytext + 15);
 119 }
 120
 121 "`timescale"[ \t]+[^ \t\r\n/]+[ \t]*"/"[ \t]*[^ \t\r\n]* /* ignore timescale directive */
 122
 123 "`celldefine"[^\n]* /* ignore `celldefine */
 124 "`endcelldefine"[^\n]* /* ignore `endcelldefine */
 125
 126 "`default_nettype"[ \t]+[^ \t\r\n/]+ {
 127         char *p = yytext;
 128         while (*p != 0 && *p != ' ' && *p != '\t') p++;
 129         while (*p == ' ' || *p == '\t') p++;
 130         if (!strcmp(p, "none"))
 131                 VERILOG_FRONTEND::default_nettype_wire = false;
 132         else if (!strcmp(p, "wire"))
 133                 VERILOG_FRONTEND::default_nettype_wire = true;
 134         else
 135                 frontend_verilog_yyerror("Unsupported default nettype: %s", p);
 136 }
 137
 138 "`protect"[^\n]* /* ignore `protect*/
 139 "`endprotect"[^\n]* /* ignore `endprotect*/
 140
 141 "`"[a-zA-Z_$][a-zA-Z0-9_$]* {
 142         frontend_verilog_yyerror("Unimplemented compiler directive or undefined macro %s.", yytext);
 143 }
 144
 145 "module"       { return TOK_MODULE; }
 146 "endmodule"    { return TOK_ENDMODULE; }
 147 "function"     { return TOK_FUNCTION; }
 148 "endfunction"  { return TOK_ENDFUNCTION; }
 149 "task"         { return TOK_TASK; }
 150 "endtask"      { return TOK_ENDTASK; }
 151 "specify"      { return TOK_SPECIFY; }
 152 "endspecify"   { return TOK_ENDSPECIFY; }
 153 "specparam"    { return TOK_SPECPARAM; }
 154 "package"      { SV_KEYWORD(TOK_PACKAGE); }
 155 "endpackage"   { SV_KEYWORD(TOK_ENDPACKAGE); }
 156 "interface"    { SV_KEYWORD(TOK_INTERFACE); }
 157 "endinterface" { SV_KEYWORD(TOK_ENDINTERFACE); }
 158 "modport"      { SV_KEYWORD(TOK_MODPORT); }
 159 "parameter"    { return TOK_PARAMETER; }
 160 "localparam"   { return TOK_LOCALPARAM; }
 161 "defparam"     { return TOK_DEFPARAM; }
 162 "assign"       { return TOK_ASSIGN; }
 163 "always"       { return TOK_ALWAYS; }
 164 "initial"      { return TOK_INITIAL; }
 165 "begin"        { return TOK_BEGIN; }
 166 "end"          { return TOK_END; }
 167 "if"           { return TOK_IF; }
 168 "else"         { return TOK_ELSE; }
 169 "for"          { return TOK_FOR; }
 170 "posedge"      { return TOK_POSEDGE; }
 171 "negedge"      { return TOK_NEGEDGE; }
 172 "or"           { return TOK_OR; }
 173 "case"         { return TOK_CASE; }
 174 "casex"        { return TOK_CASEX; }
 175 "casez"        { return TOK_CASEZ; }
 176 "endcase"      { return TOK_ENDCASE; }
 177 "default"      { return TOK_DEFAULT; }
 178 "generate"     { return TOK_GENERATE; }
 179 "endgenerate"  { return TOK_ENDGENERATE; }
 180 "while"        { return TOK_WHILE; }
 181 "repeat"       { return TOK_REPEAT; }
 182 "automatic"    { return TOK_AUTOMATIC; }
 183
 184 "unique"       { SV_KEYWORD(TOK_UNIQUE); }
 185 "unique0"      { SV_KEYWORD(TOK_UNIQUE); }
 186 "priority"     { SV_KEYWORD(TOK_PRIORITY); }
 187
 188 "always_comb"  { SV_KEYWORD(TOK_ALWAYS); }
 189 "always_ff"    { SV_KEYWORD(TOK_ALWAYS); }
 190 "always_latch" { SV_KEYWORD(TOK_ALWAYS); }
 191
 192  /* use special token for labels on assert, assume, cover, and restrict because it's insanley complex
 193     to fix parsing of cells otherwise. (the current cell parser forces a reduce very early to update some
 194     global state.. its a mess) */
 195 [a-zA-Z_$][a-zA-Z0-9_$]*/[ \t\r\n]*:[ \t\r\n]*(assert|assume|cover|restrict)[^a-zA-Z0-9_$\.] {
 196         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext);
 197         return TOK_SVA_LABEL;
 198 }
 199
 200 "assert"     { if (formal_mode) return TOK_ASSERT; SV_KEYWORD(TOK_ASSERT); }
 201 "assume"     { if (formal_mode) return TOK_ASSUME; SV_KEYWORD(TOK_ASSUME); }
 202 "cover"      { if (formal_mode) return TOK_COVER; SV_KEYWORD(TOK_COVER); }
 203 "restrict"   { if (formal_mode) return TOK_RESTRICT; SV_KEYWORD(TOK_RESTRICT); }
 204 "property"   { if (formal_mode) return TOK_PROPERTY; SV_KEYWORD(TOK_PROPERTY); }
 205 "rand"       { if (formal_mode) return TOK_RAND; SV_KEYWORD(TOK_RAND); }
 206 "const"      { if (formal_mode) return TOK_CONST; SV_KEYWORD(TOK_CONST); }
 207 "checker"    { if (formal_mode) return TOK_CHECKER; SV_KEYWORD(TOK_CHECKER); }
 208 "endchecker" { if (formal_mode) return TOK_ENDCHECKER; SV_KEYWORD(TOK_ENDCHECKER); }
 209 "logic"      { SV_KEYWORD(TOK_LOGIC); }
 210 "bit"        { SV_KEYWORD(TOK_REG); }
 211
 212 "eventually"   { if (formal_mode) return TOK_EVENTUALLY; SV_KEYWORD(TOK_EVENTUALLY); }
 213 "s_eventually" { if (formal_mode) return TOK_EVENTUALLY; SV_KEYWORD(TOK_EVENTUALLY); }
 214
 215 "input"   { return TOK_INPUT; }
 216 "output"  { return TOK_OUTPUT; }
 217 "inout"   { return TOK_INOUT; }
 218 "wire"    { return TOK_WIRE; }
 219 "reg"     { return TOK_REG; }
 220 "integer" { return TOK_INTEGER; }
 221 "signed"  { return TOK_SIGNED; }
 222 "genvar"  { return TOK_GENVAR; }
 223 "real"    { return TOK_REAL; }
 224
 225 "enum"    { SV_KEYWORD(TOK_ENUM); }
 226 "typedef" { SV_KEYWORD(TOK_TYPEDEF); }
 227
 228 [0-9][0-9_]* {
 229         frontend_verilog_yylval.string = new std::string(yytext);
 230         return TOK_CONSTVAL;
 231 }
 232
 233 [0-9]*[ \t]*\'s?[bodhBODH][ \t\r\n]*[0-9a-fA-FzxZX?_]+ {
 234         frontend_verilog_yylval.string = new std::string(yytext);
 235         return TOK_CONSTVAL;
 236 }
 237
 238 [0-9][0-9_]*\.[0-9][0-9_]*([eE][-+]?[0-9_]+)? {
 239         frontend_verilog_yylval.string = new std::string(yytext);
 240         return TOK_REALVAL;
 241 }
 242
 243 [0-9][0-9_]*[eE][-+]?[0-9_]+ {
 244         frontend_verilog_yylval.string = new std::string(yytext);
 245         return TOK_REALVAL;
 246 }
 247
 248 \"              { BEGIN(STRING); }
 249 <STRING>\\.     { yymore(); }
 250 <STRING>\"      {
 251         BEGIN(0);
 252         char *yystr = strdup(yytext);
 253         yystr[strlen(yytext) - 1] = 0;
 254         int i = 0, j = 0;
 255         while (yystr[i]) {
 256                 if (yystr[i] == '\\' && yystr[i + 1]) {
 257                         i++;
 258                         if (yystr[i] == 'a')
 259                                 yystr[i] = '\a';
 260                         else if (yystr[i] == 'f')
 261                                 yystr[i] = '\f';
 262                         else if (yystr[i] == 'n')
 263                                 yystr[i] = '\n';
 264                         else if (yystr[i] == 'r')
 265                                 yystr[i] = '\r';
 266                         else if (yystr[i] == 't')
 267                                 yystr[i] = '\t';
 268                         else if (yystr[i] == 'v')
 269                                 yystr[i] = '\v';
 270                         else if ('0' <= yystr[i] && yystr[i] <= '7') {
 271                                 yystr[i] = yystr[i] - '0';
 272                                 if ('0' <= yystr[i + 1] && yystr[i + 1] <= '7') {
 273                                         yystr[i + 1] = yystr[i] * 8 + yystr[i + 1] - '0';
 274                                         i++;
 275                                 }
 276                                 if ('0' <= yystr[i + 1] && yystr[i + 1] <= '7') {
 277                                         yystr[i + 1] = yystr[i] * 8 + yystr[i + 1] - '0';
 278                                         i++;
 279                                 }
 280                         }
 281                 }
 282                 yystr[j++] = yystr[i++];
 283         }
 284         yystr[j] = 0;
 285         frontend_verilog_yylval.string = new std::string(yystr, j);
 286         free(yystr);
 287         return TOK_STRING;
 288 }
 289 <STRING>.       { yymore(); }
 290
 291 and|nand|or|nor|xor|xnor|not|buf|bufif0|bufif1|notif0|notif1 {
 292         frontend_verilog_yylval.string = new std::string(yytext);
 293         return TOK_PRIMITIVE;
 294 }
 295
 296 supply0 { return TOK_SUPPLY0; }
 297 supply1 { return TOK_SUPPLY1; }
 298
 299 "$"(display|write|strobe|monitor|time|stop|finish|dumpfile|dumpvars|dumpon|dumpoff|dumpall) {
 300         frontend_verilog_yylval.string = new std::string(yytext);
 301         return TOK_ID;
 302 }
 303
 304 "$signed"   { return TOK_TO_SIGNED; }
 305 "$unsigned" { return TOK_TO_UNSIGNED; }
 306
 307 [a-zA-Z_$][a-zA-Z0-9_$]* {
 308         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext);
 309         return TOK_ID;
 310 }
 311
 312 [a-zA-Z_$][a-zA-Z0-9_$\.]* {
 313         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext);
 314         return TOK_ID;
 315 }
 316
 317 "/*"[ \t]*(synopsys|synthesis)[ \t]*translate_off[ \t]*"*/" {
 318         static bool printed_warning = false;
 319         if (!printed_warning) {
 320                 log_warning("Found one of those horrible `(synopsys|synthesis) translate_off' comments.\n"
 321                                 "Yosys does support them but it is recommended to use `ifdef constructs instead!\n");
 322                 printed_warning = true;
 323         }
 324         BEGIN(SYNOPSYS_TRANSLATE_OFF);
 325 }
 326 <SYNOPSYS_TRANSLATE_OFF>.    /* ignore synopsys translate_off body */
 327 <SYNOPSYS_TRANSLATE_OFF>\n   /* ignore synopsys translate_off body */
 328 <SYNOPSYS_TRANSLATE_OFF>"/*"[ \t]*(synopsys|synthesis)[ \t]*"translate_on"[ \t]*"*/" { BEGIN(0); }
 329
 330 "/*"[ \t]*(synopsys|synthesis)[ \t]+ {
 331         BEGIN(SYNOPSYS_FLAGS);
 332 }
 333 <SYNOPSYS_FLAGS>full_case {
 334         static bool printed_warning = false;
 335         if (!printed_warning) {
 336                 log_warning("Found one of those horrible `(synopsys|synthesis) full_case' comments.\n"
 337                                 "Yosys does support them but it is recommended to use Verilog `full_case' attributes instead!\n");
 338                 printed_warning = true;
 339         }
 340         return TOK_SYNOPSYS_FULL_CASE;
 341 }
 342 <SYNOPSYS_FLAGS>parallel_case {
 343         static bool printed_warning = false;
 344         if (!printed_warning) {
 345                 log_warning("Found one of those horrible `(synopsys|synthesis) parallel_case' comments.\n"
 346                                 "Yosys does support them but it is recommended to use Verilog `parallel_case' attributes instead!\n");
 347                 printed_warning = true;
 348         }
 349         return TOK_SYNOPSYS_PARALLEL_CASE;
 350 }
 351 <SYNOPSYS_FLAGS>. /* ignore everything else */
 352 <SYNOPSYS_FLAGS>"*/" { BEGIN(0); }
 353
 354 import[ \t\r\n]+\"(DPI|DPI-C)\"[ \t\r\n]+function[ \t\r\n]+ {
 355         BEGIN(IMPORT_DPI);
 356         return TOK_DPI_FUNCTION;
 357 }
 358
 359 <IMPORT_DPI>[a-zA-Z_$][a-zA-Z0-9_$]* {
 360         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext);
 361         return TOK_ID;
 362 }
 363
 364 <IMPORT_DPI>[ \t\r\n] /* ignore whitespaces */
 365
 366 <IMPORT_DPI>";" {
 367         BEGIN(0);
 368         return *yytext;
 369 }
 370
 371 <IMPORT_DPI>. {
 372         return *yytext;
 373 }
 374
 375 "\\"[^ \t\r\n]+ {
 376         frontend_verilog_yylval.string = new std::string(yytext);
 377         return TOK_ID;
 378 }
 379
 380 "(*" { return ATTR_BEGIN; }
 381 "*)" { return ATTR_END; }
 382
 383 "{*"  { return DEFATTR_BEGIN; }
 384 "*}"  { return DEFATTR_END; }
 385
 386 "**" { return OP_POW; }
 387 "||" { return OP_LOR; }
 388 "&&" { return OP_LAND; }
 389 "==" { return OP_EQ; }
 390 "!=" { return OP_NE; }
 391 "<=" { return OP_LE; }
 392 ">=" { return OP_GE; }
 393
 394 "===" { return OP_EQX; }
 395 "!==" { return OP_NEX; }
 396
 397 "~&" { return OP_NAND; }
 398 "~|" { return OP_NOR;  }
 399 "~^" { return OP_XNOR; }
 400 "^~" { return OP_XNOR; }
 401
 402 "<<"  { return OP_SHL; }
 403 ">>"  { return OP_SHR; }
 404 "<<<" { return OP_SSHL; }
 405 ">>>" { return OP_SSHR; }
 406
 407 "::"  { return TOK_PACKAGESEP; }
 408 "++"  { return TOK_INCREMENT; }
 409 "--"  { return TOK_DECREMENT; }
 410
 411 "+:" { return TOK_POS_INDEXED; }
 412 "-:" { return TOK_NEG_INDEXED; }
 413
 414 "/*" { BEGIN(COMMENT); }
 415 <COMMENT>.    /* ignore comment body */
 416 <COMMENT>\n   /* ignore comment body */
 417 <COMMENT>"*/" { BEGIN(0); }
 418
 419 [ \t\r\n]               /* ignore whitespaces */
 420 \\[\r\n]                /* ignore continuation sequence */
 421 "//"[^\r\n]*            /* ignore one-line comments */
 422
 423 . { return *yytext; }
 424
 425 %%
 426
 427 // this is a hack to avoid the 'yyinput defined but not used' error msgs
 428 void *frontend_verilog_avoid_input_warnings() {
 429         return (void*)&yyinput;
 430 }
 431