frontends/verilog/verilog_lexer.l

   1 /*
   2  *  yosys -- Yosys Open SYnthesis Suite
   3  *
   4  *  Copyright (C) 2012  Clifford Wolf <clifford@clifford.at>
   5  *
   6  *  Permission to use, copy, modify, and/or distribute this software for any
   7  *  purpose with or without fee is hereby granted, provided that the above
   8  *  copyright notice and this permission notice appear in all copies.
   9  *
  10  *  THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  11  *  WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  12  *  MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  13  *  ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  14  *  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  15  *  ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  16  *  OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  17  *
  18  *  ---
  19  *
  20  *  The Verilog frontend.
  21  *
  22  *  This frontend is using the AST frontend library (see frontends/ast/).
  23  *  Thus this frontend does not generate RTLIL code directly but creates an
  24  *  AST directly from the Verilog parse tree and then passes this AST to
  25  *  the AST frontend library.
  26  *
  27  *  ---
  28  *
  29  *  A simple lexer for Verilog code. Non-preprocessor compiler directives are
  30  *  handled here. The preprocessor stuff is handled in preproc.cc. Everything
  31  *  else is left to the bison parser (see parser.y).
  32  *
  33  */
  34
  35 %{
  36
  37 #ifdef __clang__
  38 // bison generates code using the 'register' storage class specifier
  39 #pragma clang diagnostic ignored "-Wdeprecated-register"
  40 #endif
  41
  42 #include "kernel/log.h"
  43 #include "frontends/verilog/verilog_frontend.h"
  44 #include "frontends/ast/ast.h"
  45 #include "verilog_parser.tab.hh"
  46
  47 USING_YOSYS_NAMESPACE
  48 using namespace AST;
  49 using namespace VERILOG_FRONTEND;
  50
  51 YOSYS_NAMESPACE_BEGIN
  52 namespace VERILOG_FRONTEND {
  53         std::vector<std::string> fn_stack;
  54         std::vector<int> ln_stack;
  55 }
  56 YOSYS_NAMESPACE_END
  57
  58 #define SV_KEYWORD(_tok) \
  59         if (sv_mode) return _tok; \
  60         log("Lexer warning: The SystemVerilog keyword `%s' (at %s:%d) is not "\
  61                         "recognized unless read_verilog is called with -sv!\n", yytext, \
  62                         AST::current_filename.c_str(), frontend_verilog_yyget_lineno()); \
  63         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext); \
  64         return TOK_ID;
  65
  66 #define NON_KEYWORD() \
  67         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext); \
  68         return TOK_ID;
  69
  70 #define YY_INPUT(buf,result,max_size) \
  71         result = readsome(*VERILOG_FRONTEND::lexin, buf, max_size)
  72
  73 %}
  74
  75 %option yylineno
  76 %option noyywrap
  77 %option nounput
  78 %option prefix="frontend_verilog_yy"
  79
  80 %x COMMENT
  81 %x STRING
  82 %x SYNOPSYS_TRANSLATE_OFF
  83 %x SYNOPSYS_FLAGS
  84 %x IMPORT_DPI
  85
  86 %%
  87
  88 <INITIAL,SYNOPSYS_TRANSLATE_OFF>"`file_push "[^\n]* {
  89         fn_stack.push_back(current_filename);
  90         ln_stack.push_back(frontend_verilog_yyget_lineno());
  91         current_filename = yytext+11;
  92         if (!current_filename.empty() && current_filename.front() == '"')
  93                 current_filename = current_filename.substr(1);
  94         if (!current_filename.empty() && current_filename.back() == '"')
  95                 current_filename = current_filename.substr(0, current_filename.size()-1);
  96         frontend_verilog_yyset_lineno(0);
  97 }
  98
  99 <INITIAL,SYNOPSYS_TRANSLATE_OFF>"`file_pop"[^\n]*\n {
 100         current_filename = fn_stack.back();
 101         fn_stack.pop_back();
 102         frontend_verilog_yyset_lineno(ln_stack.back());
 103         ln_stack.pop_back();
 104 }
 105
 106 <INITIAL,SYNOPSYS_TRANSLATE_OFF>"`line"[ \t]+[^ \t\r\n]+[ \t]+\"[^ \r\n]+\"[^\r\n]*\n {
 107         char *p = yytext + 5;
 108         while (*p == ' ' || *p == '\t') p++;
 109         frontend_verilog_yyset_lineno(atoi(p));
 110         while (*p && *p != ' ' && *p != '\t') p++;
 111         while (*p == ' ' || *p == '\t') p++;
 112         char *q = *p ? p + 1 : p;
 113         while (*q && *q != '"') q++;
 114         current_filename = std::string(p).substr(1, q-p-1);
 115 }
 116
 117 "`file_notfound "[^\n]* {
 118         log_error("Can't open include file `%s'!\n", yytext + 15);
 119 }
 120
 121 "`timescale"[ \t]+[^ \t\r\n/]+[ \t]*"/"[ \t]*[^ \t\r\n]* /* ignore timescale directive */
 122
 123 "`celldefine"[^\n]* /* ignore `celldefine */
 124 "`endcelldefine"[^\n]* /* ignore `endcelldefine */
 125
 126 "`default_nettype"[ \t]+[^ \t\r\n/]+ {
 127         char *p = yytext;
 128         while (*p != 0 && *p != ' ' && *p != '\t') p++;
 129         while (*p == ' ' || *p == '\t') p++;
 130         if (!strcmp(p, "none"))
 131                 VERILOG_FRONTEND::default_nettype_wire = false;
 132         else if (!strcmp(p, "wire"))
 133                 VERILOG_FRONTEND::default_nettype_wire = true;
 134         else
 135                 frontend_verilog_yyerror("Unsupported default nettype: %s", p);
 136 }
 137
 138 "`protect"[^\n]* /* ignore `protect*/
 139 "`endprotect"[^\n]* /* ignore `endprotect*/
 140
 141 "`"[a-zA-Z_$][a-zA-Z0-9_$]* {
 142         frontend_verilog_yyerror("Unimplemented compiler directive or undefined macro %s.", yytext);
 143 }
 144
 145 "module"       { return TOK_MODULE; }
 146 "endmodule"    { return TOK_ENDMODULE; }
 147 "function"     { return TOK_FUNCTION; }
 148 "endfunction"  { return TOK_ENDFUNCTION; }
 149 "task"         { return TOK_TASK; }
 150 "endtask"      { return TOK_ENDTASK; }
 151 "specify"      { return TOK_SPECIFY; }
 152 "endspecify"   { return TOK_ENDSPECIFY; }
 153 "specparam"    { return TOK_SPECPARAM; }
 154 "package"      { SV_KEYWORD(TOK_PACKAGE); }
 155 "endpackage"   { SV_KEYWORD(TOK_ENDPACKAGE); }
 156 "interface"    { SV_KEYWORD(TOK_INTERFACE); }
 157 "endinterface" { SV_KEYWORD(TOK_ENDINTERFACE); }
 158 "modport"      { SV_KEYWORD(TOK_MODPORT); }
 159 "parameter"    { return TOK_PARAMETER; }
 160 "localparam"   { return TOK_LOCALPARAM; }
 161 "defparam"     { return TOK_DEFPARAM; }
 162 "assign"       { return TOK_ASSIGN; }
 163 "always"       { return TOK_ALWAYS; }
 164 "initial"      { return TOK_INITIAL; }
 165 "begin"        { return TOK_BEGIN; }
 166 "end"          { return TOK_END; }
 167 "if"           { return TOK_IF; }
 168 "else"         { return TOK_ELSE; }
 169 "for"          { return TOK_FOR; }
 170 "posedge"      { return TOK_POSEDGE; }
 171 "negedge"      { return TOK_NEGEDGE; }
 172 "or"           { return TOK_OR; }
 173 "case"         { return TOK_CASE; }
 174 "casex"        { return TOK_CASEX; }
 175 "casez"        { return TOK_CASEZ; }
 176 "endcase"      { return TOK_ENDCASE; }
 177 "default"      { return TOK_DEFAULT; }
 178 "generate"     { return TOK_GENERATE; }
 179 "endgenerate"  { return TOK_ENDGENERATE; }
 180 "while"        { return TOK_WHILE; }
 181 "repeat"       { return TOK_REPEAT; }
 182 "automatic"    { return TOK_AUTOMATIC; }
 183
 184 "unique"       { SV_KEYWORD(TOK_UNIQUE); }
 185 "unique0"      { SV_KEYWORD(TOK_UNIQUE); }
 186 "priority"     { SV_KEYWORD(TOK_PRIORITY); }
 187
 188 "always_comb"  { SV_KEYWORD(TOK_ALWAYS); }
 189 "always_ff"    { SV_KEYWORD(TOK_ALWAYS); }
 190 "always_latch" { SV_KEYWORD(TOK_ALWAYS); }
 191
 192 "assert"     { if (formal_mode) return TOK_ASSERT; SV_KEYWORD(TOK_ASSERT); }
 193 "assume"     { if (formal_mode) return TOK_ASSUME; SV_KEYWORD(TOK_ASSUME); }
 194 "cover"      { if (formal_mode) return TOK_COVER; SV_KEYWORD(TOK_COVER); }
 195 "restrict"   { if (formal_mode) return TOK_RESTRICT; SV_KEYWORD(TOK_RESTRICT); }
 196 "property"   { if (formal_mode) return TOK_PROPERTY; SV_KEYWORD(TOK_PROPERTY); }
 197 "rand"       { if (formal_mode) return TOK_RAND; SV_KEYWORD(TOK_RAND); }
 198 "const"      { if (formal_mode) return TOK_CONST; SV_KEYWORD(TOK_CONST); }
 199 "checker"    { if (formal_mode) return TOK_CHECKER; SV_KEYWORD(TOK_CHECKER); }
 200 "endchecker" { if (formal_mode) return TOK_ENDCHECKER; SV_KEYWORD(TOK_ENDCHECKER); }
 201 "logic"      { SV_KEYWORD(TOK_LOGIC); }
 202 "bit"        { SV_KEYWORD(TOK_REG); }
 203
 204 "eventually"   { if (formal_mode) return TOK_EVENTUALLY; SV_KEYWORD(TOK_EVENTUALLY); }
 205 "s_eventually" { if (formal_mode) return TOK_EVENTUALLY; SV_KEYWORD(TOK_EVENTUALLY); }
 206
 207 "input"   { return TOK_INPUT; }
 208 "output"  { return TOK_OUTPUT; }
 209 "inout"   { return TOK_INOUT; }
 210 "wire"    { return TOK_WIRE; }
 211 "reg"     { return TOK_REG; }
 212 "integer" { return TOK_INTEGER; }
 213 "signed"  { return TOK_SIGNED; }
 214 "genvar"  { return TOK_GENVAR; }
 215 "real"    { return TOK_REAL; }
 216
 217 "enum"    { SV_KEYWORD(TOK_ENUM); }
 218 "typedef" { SV_KEYWORD(TOK_TYPEDEF); }
 219
 220 [0-9][0-9_]* {
 221         frontend_verilog_yylval.string = new std::string(yytext);
 222         return TOK_CONSTVAL;
 223 }
 224
 225 [0-9]*[ \t]*\'s?[bodhBODH][ \t\r\n]*[0-9a-fA-FzxZX?_]+ {
 226         frontend_verilog_yylval.string = new std::string(yytext);
 227         return TOK_CONSTVAL;
 228 }
 229
 230 [0-9][0-9_]*\.[0-9][0-9_]*([eE][-+]?[0-9_]+)? {
 231         frontend_verilog_yylval.string = new std::string(yytext);
 232         return TOK_REALVAL;
 233 }
 234
 235 [0-9][0-9_]*[eE][-+]?[0-9_]+ {
 236         frontend_verilog_yylval.string = new std::string(yytext);
 237         return TOK_REALVAL;
 238 }
 239
 240 \"              { BEGIN(STRING); }
 241 <STRING>\\.     { yymore(); }
 242 <STRING>\"      {
 243         BEGIN(0);
 244         char *yystr = strdup(yytext);
 245         yystr[strlen(yytext) - 1] = 0;
 246         int i = 0, j = 0;
 247         while (yystr[i]) {
 248                 if (yystr[i] == '\\' && yystr[i + 1]) {
 249                         i++;
 250                         if (yystr[i] == 'a')
 251                                 yystr[i] = '\a';
 252                         else if (yystr[i] == 'f')
 253                                 yystr[i] = '\f';
 254                         else if (yystr[i] == 'n')
 255                                 yystr[i] = '\n';
 256                         else if (yystr[i] == 'r')
 257                                 yystr[i] = '\r';
 258                         else if (yystr[i] == 't')
 259                                 yystr[i] = '\t';
 260                         else if (yystr[i] == 'v')
 261                                 yystr[i] = '\v';
 262                         else if ('0' <= yystr[i] && yystr[i] <= '7') {
 263                                 yystr[i] = yystr[i] - '0';
 264                                 if ('0' <= yystr[i + 1] && yystr[i + 1] <= '7') {
 265                                         yystr[i + 1] = yystr[i] * 8 + yystr[i + 1] - '0';
 266                                         i++;
 267                                 }
 268                                 if ('0' <= yystr[i + 1] && yystr[i + 1] <= '7') {
 269                                         yystr[i + 1] = yystr[i] * 8 + yystr[i + 1] - '0';
 270                                         i++;
 271                                 }
 272                         }
 273                 }
 274                 yystr[j++] = yystr[i++];
 275         }
 276         yystr[j] = 0;
 277         frontend_verilog_yylval.string = new std::string(yystr);
 278         free(yystr);
 279         return TOK_STRING;
 280 }
 281 <STRING>.       { yymore(); }
 282
 283 and|nand|or|nor|xor|xnor|not|buf|bufif0|bufif1|notif0|notif1 {
 284         frontend_verilog_yylval.string = new std::string(yytext);
 285         return TOK_PRIMITIVE;
 286 }
 287
 288 supply0 { return TOK_SUPPLY0; }
 289 supply1 { return TOK_SUPPLY1; }
 290
 291 "$"(display|write|strobe|monitor|time|stop|finish|dumpfile|dumpvars|dumpon|dumpoff|dumpall) {
 292         frontend_verilog_yylval.string = new std::string(yytext);
 293         return TOK_ID;
 294 }
 295
 296 "$signed"   { return TOK_TO_SIGNED; }
 297 "$unsigned" { return TOK_TO_UNSIGNED; }
 298
 299 [a-zA-Z_$][a-zA-Z0-9_$]* {
 300         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext);
 301         return TOK_ID;
 302 }
 303
 304 [a-zA-Z_$][a-zA-Z0-9_$\.]* {
 305         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext);
 306     return TOK_ID;
 307 }
 308
 309 "/*"[ \t]*(synopsys|synthesis)[ \t]*translate_off[ \t]*"*/" {
 310         static bool printed_warning = false;
 311         if (!printed_warning) {
 312                 log_warning("Found one of those horrible `(synopsys|synthesis) translate_off' comments.\n"
 313                                 "Yosys does support them but it is recommended to use `ifdef constructs instead!\n");
 314                 printed_warning = true;
 315         }
 316         BEGIN(SYNOPSYS_TRANSLATE_OFF);
 317 }
 318 <SYNOPSYS_TRANSLATE_OFF>.    /* ignore synopsys translate_off body */
 319 <SYNOPSYS_TRANSLATE_OFF>\n   /* ignore synopsys translate_off body */
 320 <SYNOPSYS_TRANSLATE_OFF>"/*"[ \t]*(synopsys|synthesis)[ \t]*"translate_on"[ \t]*"*/" { BEGIN(0); }
 321
 322 "/*"[ \t]*(synopsys|synthesis)[ \t]+ {
 323         BEGIN(SYNOPSYS_FLAGS);
 324 }
 325 <SYNOPSYS_FLAGS>full_case {
 326         static bool printed_warning = false;
 327         if (!printed_warning) {
 328                 log_warning("Found one of those horrible `(synopsys|synthesis) full_case' comments.\n"
 329                                 "Yosys does support them but it is recommended to use Verilog `full_case' attributes instead!\n");
 330                 printed_warning = true;
 331         }
 332         return TOK_SYNOPSYS_FULL_CASE;
 333 }
 334 <SYNOPSYS_FLAGS>parallel_case {
 335         static bool printed_warning = false;
 336         if (!printed_warning) {
 337                 log_warning("Found one of those horrible `(synopsys|synthesis) parallel_case' comments.\n"
 338                                 "Yosys does support them but it is recommended to use Verilog `parallel_case' attributes instead!\n");
 339                 printed_warning = true;
 340         }
 341         return TOK_SYNOPSYS_PARALLEL_CASE;
 342 }
 343 <SYNOPSYS_FLAGS>. /* ignore everything else */
 344 <SYNOPSYS_FLAGS>"*/" { BEGIN(0); }
 345
 346 import[ \t\r\n]+\"(DPI|DPI-C)\"[ \t\r\n]+function[ \t\r\n]+ {
 347         BEGIN(IMPORT_DPI);
 348         return TOK_DPI_FUNCTION;
 349 }
 350
 351 <IMPORT_DPI>[a-zA-Z_$][a-zA-Z0-9_$]* {
 352         frontend_verilog_yylval.string = new std::string(std::string("\\") + yytext);
 353         return TOK_ID;
 354 }
 355
 356 <IMPORT_DPI>[ \t\r\n] /* ignore whitespaces */
 357
 358 <IMPORT_DPI>";" {
 359         BEGIN(0);
 360         return *yytext;
 361 }
 362
 363 <IMPORT_DPI>. {
 364         return *yytext;
 365 }
 366
 367 "\\"[^ \t\r\n]+ {
 368         frontend_verilog_yylval.string = new std::string(yytext);
 369         return TOK_ID;
 370 }
 371
 372 "(*" { return ATTR_BEGIN; }
 373 "*)" { return ATTR_END; }
 374
 375 "{*"  { return DEFATTR_BEGIN; }
 376 "*}"  { return DEFATTR_END; }
 377
 378 "**" { return OP_POW; }
 379 "||" { return OP_LOR; }
 380 "&&" { return OP_LAND; }
 381 "==" { return OP_EQ; }
 382 "!=" { return OP_NE; }
 383 "<=" { return OP_LE; }
 384 ">=" { return OP_GE; }
 385
 386 "===" { return OP_EQX; }
 387 "!==" { return OP_NEX; }
 388
 389 "~&" { return OP_NAND; }
 390 "~|" { return OP_NOR;  }
 391 "~^" { return OP_XNOR; }
 392 "^~" { return OP_XNOR; }
 393
 394 "<<"  { return OP_SHL; }
 395 ">>"  { return OP_SHR; }
 396 "<<<" { return OP_SSHL; }
 397 ">>>" { return OP_SSHR; }
 398
 399 "::"  { return TOK_PACKAGESEP; }
 400 "++"  { return TOK_INCREMENT; }
 401 "--"  { return TOK_DECREMENT; }
 402
 403 "+:" { return TOK_POS_INDEXED; }
 404 "-:" { return TOK_NEG_INDEXED; }
 405
 406 "/*" { BEGIN(COMMENT); }
 407 <COMMENT>.    /* ignore comment body */
 408 <COMMENT>\n   /* ignore comment body */
 409 <COMMENT>"*/" { BEGIN(0); }
 410
 411 [ \t\r\n]               /* ignore whitespaces */
 412 \\[\r\n]                /* ignore continuation sequence */
 413 "//"[^\r\n]*            /* ignore one-line comments */
 414
 415 . { return *yytext; }
 416
 417 %%
 418
 419 // this is a hack to avoid the 'yyinput defined but not used' error msgs
 420 void *frontend_verilog_avoid_input_warnings() {
 421         return (void*)&yyinput;
 422 }
 423