gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-*vms*)        fmt=evax ;;
 111       alpha-*-netware*)     fmt=ecoff ;;
 112       alpha-*-osf*)         fmt=ecoff ;;
 113       alpha-*-linuxecoff*)  fmt=ecoff ;;
 114       alpha-*-linux*)       fmt=elf em=linux ;;
 115
 116 # start-sanitize-arc
 117       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 118 # end-sanitize-arc
 119
 120       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 121       arm-*-aout)           fmt=aout
 122                             case "$endian" in
 123                               big)      targ=arm-big ;;
 124                               *)        targ=arm-lit ;;
 125                             esac
 126                             ;;
 127       arm-*-coff)           fmt=coff ;;
 128       arm-*-riscix*)        fmt=aout ;;
 129       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 130
 131 # start-sanitize-d10v
 132       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 133 # end-sanitize-d10v
 134
 135       hppa-*-*elf*)         fmt=elf em=hppa ;;
 136       hppa-*-lites*)        fmt=elf em=hppa ;;
 137       hppa-*-osf*)          fmt=som em=hppa ;;
 138       hppa-*-hpux*)         fmt=som em=hppa ;;
 139       hppa-*-bsd*)          fmt=som em=hppa ;;
 140       hppa-*-hiux*)         fmt=som em=hppa ;;
 141
 142       h8300-*-coff)         fmt=coff ;;
 143
 144       i386-ibm-aix*)        fmt=coff targ=i386coff
 145                              em=i386aix ;;
 146       i386-*-bsd*)          fmt=aout em=386bsd ;;
 147       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 148       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 149       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 150       i386-*-linux*coff*)   fmt=coff em=linux
 151                              targ=i386coff ;;
 152       i386-*-linux*)        fmt=elf em=linux ;;
 153       i386-*-lynxos*)       fmt=coff targ=i386coff
 154                              em=lynx ;;
 155       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 156                             fmt=elf ;;
 157       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 158       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 159                             fmt=coff targ=i386coff ;;
 160       i386-*-vsta)          fmt=aout ;;
 161       i386-*-go32)          fmt=coff targ=i386coff ;;
 162       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 163       i386-*-gnu*)          fmt=elf ;;
 164       i386-*-mach*)
 165                             fmt=aout em=mach bfd_gas=yes ;;
 166       i386-*-msdos*)        fmt=aout ;;
 167       i386-*-moss*)         fmt=elf ;;
 168       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 169       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 170       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 171       i960-*-bout)          fmt=bout ;;
 172       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 173       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 174       i960-*-nindy*)        fmt=bout ;;
 175       i960-*-vxworks4*)     fmt=bout ;;
 176       i960-*-vxworks5.0)    fmt=bout ;;
 177       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 178       i960-*-vxworks*)      fmt=bout ;;
 179
 180       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 181                             fmt=aout em=sun3 ;;
 182       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 183       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 184       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 185       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 186                             fmt=elf ;;
 187       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 188                             fmt=coff targ=m68kcoff ;;
 189       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 190       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 191       m68k-*-linux*)        fmt=elf em=linux ;;
 192       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 193                              em=lynx ;;
 194       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 195       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 196       m68k-*-psos*)         fmt=elf em=psos;;
 197
 198       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 199       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 200
 201       # don't change em like *-*-bsd does
 202       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 203       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 204       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 205       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 206       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 207       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 208       mips-*-ecoff*)        fmt=ecoff
 209                             case "$endian" in
 210                             big) targ=mips-big ;;
 211                             *)   targ=mips-lit ;;
 212                             esac
 213                             ;;
 214       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 215       mips-*-gnu*)          fmt=aout
 216                             case "$endian" in
 217                             big) targ=mips-big ;;
 218                             *)   targ=mips-lit ;;
 219                             esac
 220                             ;;
 221       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 222       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 223       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 224       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 225       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 226       mips-*-elf* | mips-*-rtems*)
 227                             fmt=elf
 228                             case "$endian" in
 229                             big) targ=mips-big ;;
 230                             *)   targ=mips-lit ;;
 231                             esac
 232                             ;;
 233       mn10x00-*-*)          fmt=elf bfd_gas=yes ;;
 234       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 235                             fmt=coff em=pe
 236                             case "$endian" in
 237                             big) targ=ppc-big ;;
 238                             *)   targ=ppc-lit ;;
 239                             esac
 240                             ;;
 241       ppc-*-aix*)           fmt=coff ;;
 242       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 243                             fmt=elf
 244                             case "$endian" in
 245                             big)  targ=ppc-big ;;
 246                             *)    targ=ppc-lit ;;
 247                             esac
 248                             ;;
 249       ppc-*-linux*)         fmt=elf
 250                             case "$endian" in
 251                             big)  targ=ppc-big ;;
 252                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 253                             esac
 254                             ;;
 255       ppc-*-solaris*)       fmt=elf
 256                             case "$endian" in
 257                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 258                             *)    targ=ppc-sol ;;
 259                             esac
 260                             ;;
 261       ppc-*-rtems*)
 262                             fmt=elf
 263                             case "$endian" in
 264                             big)  targ=ppc-big ;;
 265                             *)    targ=ppc-lit ;;
 266                             esac
 267                             ;;
 268       ppc-*-macos* | ppc-*-mpw*)
 269                             fmt=coff em=macos ;;
 270       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 271
 272       sh-*-elf*)            fmt=elf ;;
 273       sh-*-coff*)           fmt=coff ;;
 274
 275       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 276       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 277
 278       sparc-*-rtems*)       fmt=aout ;;
 279       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 280       sparc-*-aout | sparc*-*-vxworks*)
 281                             fmt=aout em=sparcaout ;;
 282       sparc-*-coff)         fmt=coff ;;
 283       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 284       sparc-fujitsu-none)   fmt=aout ;;
 285       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 286                             fmt=elf ;;
 287       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 288
 289       v850-*-*)             fmt=elf bfd_gas=yes ;;
 290
 291       vax-*-bsd* | vax-*-ultrix*)
 292                             fmt=aout ;;
 293       vax-*-vms)            fmt=vms ;;
 294
 295       z8k-*-coff | z8k-*-sim)
 296                             fmt=coff ;;
 297
 298       w65-*-*)              fmt=coff ;;
 299
 300       *-*-aout | *-*-scout)
 301                             fmt=aout ;;
 302       *-*-nindy*)
 303                             fmt=bout ;;
 304       *-*-bsd*)
 305                             fmt=aout em=sun3 ;;
 306       *-*-generic)          fmt=generic ;;
 307       *-*-xray | *-*-hms)   fmt=coff ;;
 308       *-*-sim)              fmt=coff ;;
 309       *-*-elf | *-*-sysv4* | *-*-solaris*)
 310                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 311                             fmt=elf dev=yes ;;
 312       *-*-vxworks)          fmt=aout ;;
 313       *-*-netware)          fmt=elf ;;
 314     esac
 315
 316     case ${cpu_type}-${fmt} in
 317       alpha-*)  bfd_gas=yes ;;
 318       arm-*)    bfd_gas=yes ;;
 319     # not yet
 320     # i386-aout)        bfd_gas=preferred ;;
 321       mips-*)   bfd_gas=yes ;;
 322       ns32k-*)  bfd_gas=yes ;;
 323       ppc-*)    bfd_gas=yes ;;
 324       sparc-*)  bfd_gas=yes ;;
 325       *-elf)    bfd_gas=yes ;;
 326       *-ecoff)  bfd_gas=yes ;;
 327       *-som)    bfd_gas=yes ;;
 328       *)                ;;
 329     esac
 330
 331 # Other random stuff.
 332
 333     # do we need the opcodes library?
 334     case ${cpu_type} in
 335       vax | i386)
 336         ;;
 337       *)
 338         need_opcodes=yes
 339         if test "${shared_opcodes}" = "true"; then
 340           # A shared libopcodes must be linked against libbfd.
 341           need_bfd=yes
 342         fi
 343         ;;
 344     esac
 345
 346     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 347
 348     case ${cpu}-${vendor}-${os} in
 349       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 350     esac
 351
 352     case ${cpu_type} in
 353       m68k)
 354         case ${extra_objects} in
 355         *m68k-parse.o*) ;;
 356         *) extra_objects="$extra_objects m68k-parse.o" ;;
 357         esac
 358         ;;
 359     esac
 360
 361 # See if we really can support this configuration with the emulation code.
 362
 363     if test $this_target = $target ; then
 364       primary_bfd_gas=$bfd_gas
 365       obj_format=$fmt
 366       gas_target=$targ
 367       te_file=$em
 368
 369       if test $bfd_gas = no ; then
 370         # Can't support other configurations this way.
 371         break
 372       fi
 373     elif test $bfd_gas = no ; then
 374       # Can't support this configuration.
 375       break
 376     fi
 377
 378 # From target name and format, produce a list of supported emulations.
 379
 380     case ${generic_target}-${fmt} in
 381       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 382       mips-*-*-ecoff)   case "$endian" in
 383                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 384                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 385                         esac ;;
 386       mips-*-*-elf)     case "$endian" in
 387                         big)    emulation="mipsbelf mipslelf mipself" ;;
 388                         *)      emulation="mipslelf mipsbelf mipself" ;;
 389                         esac ;;
 390     esac
 391
 392     emulations="$emulations $emulation"
 393
 394 done
 395
 396 # Assign floating point type.  Most processors with FP support
 397 # IEEE FP.  On those that don't support FP at all, usually IEEE
 398 # is emulated.
 399 case ${target_cpu} in
 400   vax | tahoe ) atof=${target_cpu} ;;
 401   *)            atof=ieee ;;
 402 esac
 403
 404 case "${obj_format}" in
 405   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 406 esac
 407
 408 dnl
 409 dnl Make sure the desired support files exist.
 410 dnl
 411
 412 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 413   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 414 fi
 415
 416 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 417   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 418 fi
 419
 420 # and target makefile frag
 421
 422 target_frag=${srcdir}/config/${gas_target}.mt
 423 if test ! -r ${target_frag}; then
 424   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 425 fi
 426 AC_SUBST_FILE(target_frag)
 427
 428 case ${user_bfd_gas}-${primary_bfd_gas} in
 429   yes-yes | no-no)
 430     # We didn't override user's choice.
 431     ;;
 432   no-yes)
 433     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 434     ;;
 435   no-preferred)
 436     primary_bfd_gas=no
 437     ;;
 438   *-preferred)
 439     primary_bfd_gas=yes
 440     ;;
 441   yes-*)
 442     primary_bfd_gas=yes
 443     ;;
 444   -*)
 445     # User specified nothing.
 446     ;;
 447 esac
 448
 449 # Some COFF configurations want these random other flags set.
 450 case ${obj_format} in
 451   coff)
 452     case ${target_cpu_type} in
 453       i386) AC_DEFINE(I386COFF) ;;
 454       m68k) AC_DEFINE(M68KCOFF) ;;
 455       m88k) AC_DEFINE(M88KCOFF) ;;
 456     esac
 457     ;;
 458 esac
 459
 460 # Getting this done right is going to be a bitch.  Each configuration specified
 461 # with --enable-targets=... should be checked for environment, format, cpu, and
 462 # bfd_gas setting.
 463 #
 464 # For each configuration, the necessary object file support code must be linked
 465 # in.  This might be only one, it might be up to four.  The necessary emulation
 466 # code needs to be provided, too.
 467 #
 468 # And then there's "--enable-targets=all"....
 469 #
 470 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 471
 472 formats="${obj_format}"
 473 emfiles=""
 474 EMULATIONS=""
 475 GAS_UNIQ(emulations)
 476 for em in . $emulations ; do
 477   case $em in
 478     .)  continue ;;
 479     mipsbelf | mipslelf)
 480         fmt=elf   file=mipself ;;
 481     mipsbecoff | mipslecoff)
 482         fmt=ecoff file=mipsecoff ;;
 483   esac
 484   formats="$formats $fmt"
 485   emfiles="$emfiles e-$file.o"
 486   EMULATIONS="$EMULATIONS &$em,"
 487 done
 488 GAS_UNIQ(formats)
 489 GAS_UNIQ(emfiles)
 490 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 491   for fmt in $formats ; do
 492     case $fmt in
 493       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 494       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 495       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 496       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 497       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 498       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 499       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 500       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 501       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 502       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 503     esac
 504     extra_objects="$extra_objects obj-$fmt.o"
 505   done
 506   obj_format=multi
 507 fi
 508 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 509   te_file=multi
 510   extra_objects="$extra_objects $emfiles"
 511   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 512   AC_DEFINE(USE_EMULATIONS)
 513 fi
 514 AC_SUBST(extra_objects)
 515 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 516 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 517
 518 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 519         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 520         config/te-${te_file}.h config/atof-${atof}.c \
 521         $extra_files"
 522 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 523         $extra_links"
 524
 525 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 526   yes-*-coff)   need_bfd=yes ;;
 527   no-*-coff)    need_bfd=yes
 528                 AC_DEFINE(MANY_SEGMENTS) ;;
 529 esac
 530
 531 reject_dev_configs=yes
 532
 533 case ${reject_dev_configs}-${dev} in
 534   yes-yes) # Oops.
 535     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 536     ;;
 537 esac
 538
 539 AC_SUBST(target_cpu_type)
 540 AC_SUBST(obj_format)
 541 AC_SUBST(atof)
 542 dnl AC_SUBST(emulation)
 543
 544 AC_LINK_FILES($files, $links)
 545
 546 case "${primary_bfd_gas}" in
 547   yes)  AC_DEFINE(BFD_ASSEMBLER)
 548         need_bfd=yes ;;
 549 esac
 550
 551 # do we need the opcodes library?
 552 case "${need_opcodes}" in
 553 yes)
 554   OPCODES_DEP=../opcodes/libopcodes.a
 555   OPCODES_LIB='-L../opcodes -lopcodes'
 556
 557   # We need to handle some special cases for shared libraries.
 558   case "${host}" in
 559   *-*-sunos*)
 560     # On SunOS, we must link against the name we are going to install,
 561     # not -lbfd, since SunOS does not support SONAME.
 562     if test "${shared_opcodes}" = "true"; then
 563       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 564     fi
 565     ;;
 566   alpha*-*-osf*)
 567     # On Alpha OSF/1, the native linker searches all the -L
 568     # directories for any LIB.so files, and only then searches for any
 569     # LIB.a files.  That means that if there is an installed
 570     # libbfd.so, but this build is not done with --enable-shared, the
 571     # link will wind up being against the install libbfd.so rather
 572     # than the newly built libbfd.  To avoid this, we must explicitly
 573     # link against libbfd.a when --enable-shared is not used.
 574     if test "${shared_opcodes}" != "true"; then
 575       OPCODES_LIB='../opcodes/libopcodes.a'
 576     fi
 577     ;;
 578   esac
 579   ;;
 580 esac
 581 AC_SUBST(OPCODES_DEP)
 582 AC_SUBST(OPCODES_LIB)
 583
 584 case "${need_bfd}" in
 585 yes)
 586   BFDDEP=../bfd/libbfd.a
 587   BFDLIB='-L../bfd -lbfd'
 588   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 589
 590   # We need to handle some special cases for shared libraries
 591   case "${host}" in
 592   *-*-sunos*)
 593     # On SunOS, we must link against the name we are going to install,
 594     # not -lbfd, since SunOS does not support SONAME.
 595     if test "${shared_bfd}" = "true"; then
 596       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 597     fi
 598     ;;
 599   alpha*-*-osf*)
 600     # On Alpha OSF/1, the native linker searches all the -L
 601     # directories for any LIB.so files, and only then searches for any
 602     # LIB.a files.  That means that if there is an installed
 603     # libbfd.so, but this build is not done with --enable-shared, the
 604     # link will wind up being against the install libbfd.so rather
 605     # than the newly built libbfd.  To avoid this, we must explicitly
 606     # link against libbfd.a when --enable-shared is not used.
 607     if test "${shared_bfd}" != "true"; then
 608       BFDLIB='../bfd/libbfd.a'
 609     fi
 610     ;;
 611   esac
 612   ;;
 613 esac
 614 AC_SUBST(BFDDEP)
 615 AC_SUBST(BFDLIB)
 616 AC_SUBST(ALL_OBJ_DEPS)
 617
 618 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 619 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 620 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 621 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 622 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 623
 624 AC_PROG_CC
 625 AC_PROG_INSTALL
 626
 627 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 628
 629 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 630 # people who are not cross-compiling but are compiling cross-assemblers.
 631 AC_MSG_CHECKING(whether compiling a cross-assembler)
 632 if test "${host}" = "${target}"; then
 633   cross_gas=no
 634 else
 635   cross_gas=yes
 636   AC_DEFINE(CROSS_COMPILE)
 637 fi
 638 AC_MSG_RESULT($cross_gas)
 639
 640 dnl ansidecl.h will deal with const
 641 dnl AC_CONST
 642 AC_FUNC_ALLOCA
 643 AC_C_INLINE
 644
 645 # VMS doesn't have unlink.
 646 AC_CHECK_FUNCS(unlink remove, break)
 647
 648 # Some systems don't have sbrk().
 649 AC_CHECK_FUNCS(sbrk)
 650
 651 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 652 # enough, but on some of those systems, the assert macro relies on requoting
 653 # working properly!
 654 GAS_WORKING_ASSERT
 655
 656 # On some systems, the system header files may not declare malloc, realloc,
 657 # and free.  There are places where gas needs these functions to have been
 658 # declared -- such as when taking their addresses.
 659 gas_test_headers="
 660 #ifdef HAVE_MEMORY_H
 661 #include <memory.h>
 662 #endif
 663 #ifdef HAVE_STRING_H
 664 #include <string.h>
 665 #else
 666 #ifdef HAVE_STRINGS_H
 667 #include <strings.h>
 668 #endif
 669 #endif
 670 #ifdef HAVE_STDLIB_H
 671 #include <stdlib.h>
 672 #endif
 673 #ifdef HAVE_UNISTD_H
 674 #include <unistd.h>
 675 #endif
 676 "
 677 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 678 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 679 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 680 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 681
 682 # Does errno.h declare errno, or do we have to add a separate declaration
 683 # for it?
 684 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 685 #ifdef HAVE_ERRNO_H
 686 #include <errno.h>
 687 #endif
 688 ])
 689
 690 HLDFLAGS=
 691 HLDENV=
 692 RPATH_ENVVAR=LD_LIBRARY_PATH
 693 # If we have shared libraries, try to set rpath reasonably.
 694 if test "${shared}" = "true"; then
 695   case "${host}" in
 696   *-*-hpux*)
 697     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 698     RPATH_ENVVAR=SHLIB_PATH
 699     ;;
 700   *-*-irix5* | *-*-irix6*)
 701     HLDFLAGS='-Wl,-rpath,$(libdir)'
 702     ;;
 703   *-*-linux*aout*)
 704     ;;
 705   *-*-linux*)
 706     HLDFLAGS='-Wl,-rpath,$(libdir)'
 707     ;;
 708   *-*-solaris*)
 709     HLDFLAGS='-R $(libdir)'
 710     ;;
 711   *-*-sysv4*)
 712     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 713     ;;
 714   esac
 715 fi
 716
 717 # On SunOS, if the linker supports the -rpath option, use it to
 718 # prevent ../bfd and ../opcodes from being included in the run time
 719 # search path.
 720 case "${host}" in
 721   *-*-sunos*)
 722     echo 'main () { }' > conftest.c
 723     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 724     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 725       :
 726     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 727       :
 728     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 729       :
 730     elif test "${shared}" = "true"; then
 731       HLDFLAGS='-Wl,-rpath=$(libdir)'
 732     else
 733       HLDFLAGS='-Wl,-rpath='
 734     fi
 735     rm -f conftest.t conftest.c conftest
 736     ;;
 737 esac
 738 AC_SUBST(HLDFLAGS)
 739 AC_SUBST(HLDENV)
 740 AC_SUBST(RPATH_ENVVAR)
 741
 742 dnl This must come last.
 743 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)